lisp/ediff-merg.el

   1 ;;; ediff-merg.el --- merging utilities
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Michael Kifer <kifer@cs.stonybrook.edu>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27
  28 ;; compiler pacifier
  29 (defvar ediff-window-A)
  30 (defvar ediff-window-B)
  31 (defvar ediff-window-C)
  32 (defvar ediff-merge-window-share)
  33 (defvar ediff-window-config-saved)
  34
  35 (eval-when-compile
  36   (require 'ediff-util))
  37 ;; end pacifier
  38
  39 (require 'ediff-init)
  40
  41 (defcustom ediff-quit-merge-hook 'ediff-maybe-save-and-delete-merge
  42   "Hooks to run before quitting a merge job.
  43 The most common use is to save and delete the merge buffer."
  44   :type 'hook
  45   :group 'ediff-merge)
  46
  47
  48 (defcustom ediff-default-variant 'combined
  49   "The variant to be used as a default for buffer C in merging.
  50 Valid values are the symbols `default-A', `default-B', and `combined'."
  51   :type '(radio (const default-A) (const default-B) (const combined))
  52   :group 'ediff-merge)
  53
  54 (defcustom ediff-combination-pattern
  55   '("<<<<<<< variant A" A ">>>>>>> variant B" B  "####### Ancestor" Ancestor "======= end")
  56   "Pattern to be used for combining difference regions in buffers A and B.
  57 The value must be a list of the form
  58 \(STRING1 bufspec1  STRING2 bufspec2 STRING3 bufspec3 STRING4)
  59 where bufspec is the symbol A, B, or Ancestor. For instance, if the value is
  60 '(STRING1 A  STRING2 Ancestor STRING3 B STRING4) then the
  61 combined text will look like this:
  62
  63 STRING1
  64 diff region from variant A
  65 STRING2
  66 diff region from the ancestor
  67 STRING3
  68 diff region from variant B
  69 STRING4
  70 "
  71   :type '(choice (list string symbol string symbol string)
  72                  (list string symbol string symbol string symbol string))
  73   :group 'ediff-merge)
  74
  75 (defcustom ediff-show-clashes-only nil
  76   "If t, show only those diff regions where both buffers disagree with the ancestor.
  77 This means that regions that have status prefer-A or prefer-B will be
  78 skipped over.  A value of nil means show all regions."
  79   :type 'boolean
  80   :group 'ediff-merge
  81   )
  82 (make-variable-buffer-local 'ediff-show-clashes-only)
  83
  84 (defcustom ediff-skip-merge-regions-that-differ-from-default nil
  85   "If t, show only the regions that have not been changed by the user.
  86 A region is considered to have been changed if it is different from the current
  87 default (`default-A', `default-B', `combined') and it hasn't been marked as
  88 `prefer-A' or `prefer-B'.
  89 A region is considered to have been changed also when it is marked as
  90 as `prefer-A', but is different from the corresponding difference region in
  91 Buffer A or if it is marked as `prefer-B' and is different from the region in
  92 Buffer B."
  93   :type 'boolean
  94   :group 'ediff-merge
  95   )
  96 (make-variable-buffer-local 'ediff-skip-merge-regions-that-differ-from-default)
  97
  98 ;; check if there is no clash between the ancestor and one of the variants.
  99 ;; if it is not a merge job then return true
 100 (defsubst ediff-merge-region-is-non-clash (n)
 101   (if (ediff-merge-job)
 102       (string-match "prefer" (or (ediff-get-state-of-merge n) ""))
 103     t))
 104
 105 ;; If ediff-show-clashes-only, check if there is no clash between the ancestor
 106 ;; and one of the variants.
 107 (defsubst ediff-merge-region-is-non-clash-to-skip (n)
 108   (and ediff-show-clashes-only
 109        (ediff-merge-region-is-non-clash n)))
 110
 111 ;; If ediff-skip-changed-regions, check if the merge region differs from
 112 ;; the current default. If a region is different from the default, it means
 113 ;; that the user has made determination as to how to merge for this particular
 114 ;; region.
 115 (defsubst ediff-skip-merge-region-if-changed-from-default-p (n)
 116   (and ediff-skip-merge-regions-that-differ-from-default
 117        (ediff-merge-changed-from-default-p n 'prefers-too)))
 118
 119
 120 (defun ediff-get-combined-region (n)
 121   (let ((pattern-list ediff-combination-pattern)
 122         (combo-region "")
 123         (err-msg
 124          "ediff-combination-pattern: Invalid format. Please consult the documentation")
 125         region-delim region-spec)
 126
 127     (if (< (length pattern-list) 5)
 128         (error err-msg))
 129
 130     (while (> (length pattern-list) 2)
 131       (setq region-delim (nth 0 pattern-list)
 132             region-spec (nth 1 pattern-list))
 133       (or (and (stringp region-delim) (memq region-spec '(A B Ancestor)))
 134           (error err-msg))
 135
 136       (condition-case nil
 137           (setq combo-region
 138                 (concat combo-region
 139                         region-delim "\n"
 140                         (ediff-get-region-contents
 141                          n region-spec ediff-control-buffer)))
 142         (error ""))
 143       (setq pattern-list (cdr (cdr pattern-list)))
 144       )
 145
 146     (setq region-delim (nth 0 pattern-list))
 147     (or (stringp region-delim)
 148         (error err-msg))
 149     (setq combo-region (concat combo-region region-delim "\n"))
 150   ))
 151
 152 ;;(defsubst ediff-make-combined-diff (regA regB)
 153 ;;  (concat (nth 0 ediff-combination-pattern) "\n"
 154 ;;        regA
 155 ;;        (nth 1 ediff-combination-pattern) "\n"
 156 ;;        regB
 157 ;;        (nth 2 ediff-combination-pattern) "\n"))
 158
 159 (defsubst ediff-set-state-of-all-diffs-in-all-buffers (ctl-buf)
 160   (let ((n 0))
 161     (while (< n ediff-number-of-differences)
 162       (ediff-set-state-of-diff-in-all-buffers n ctl-buf)
 163       (setq n (1+ n)))))
 164
 165 (defun ediff-set-state-of-diff-in-all-buffers (n ctl-buf)
 166   (let ((regA (ediff-get-region-contents n 'A ctl-buf))
 167         (regB (ediff-get-region-contents n 'B ctl-buf))
 168         (regC (ediff-get-region-contents n 'C ctl-buf)))
 169     (cond ((and (string= regA regB) (string= regA  regC))
 170            (ediff-set-state-of-diff n 'A "=diff(B)")
 171            (ediff-set-state-of-diff n 'B "=diff(C)")
 172            (ediff-set-state-of-diff n 'C "=diff(A)"))
 173           ((string= regA regB)
 174            (ediff-set-state-of-diff n 'A "=diff(B)")
 175            (ediff-set-state-of-diff n 'B "=diff(A)")
 176            (ediff-set-state-of-diff n 'C nil))
 177           ((string= regA regC)
 178            (ediff-set-state-of-diff n 'A "=diff(C)")
 179            (ediff-set-state-of-diff n 'C "=diff(A)")
 180            (ediff-set-state-of-diff n 'B nil))
 181           ((string= regB regC)
 182            (ediff-set-state-of-diff n 'C "=diff(B)")
 183            (ediff-set-state-of-diff n 'B "=diff(C)")
 184            (ediff-set-state-of-diff n 'A nil))
 185           ((string= regC (ediff-get-combined-region n))
 186            (ediff-set-state-of-diff n 'A nil)
 187              (ediff-set-state-of-diff n 'B nil)
 188              (ediff-set-state-of-diff n 'C "=diff(A+B)"))
 189           (t (ediff-set-state-of-diff n 'A nil)
 190              (ediff-set-state-of-diff n 'B nil)
 191              (ediff-set-state-of-diff n 'C nil)))
 192     ))
 193
 194 (defun ediff-set-merge-mode ()
 195   (normal-mode t)
 196   (remove-hook 'local-write-file-hooks 'ediff-set-merge-mode))
 197
 198
 199 ;; Go over all diffs starting with DIFF-NUM and copy regions into buffer C
 200 ;; according to the state of the difference.
 201 ;; Since ediff-copy-diff refuses to copy identical diff regions, there is
 202 ;; no need to optimize ediff-do-merge any further.
 203 ;;
 204 ;; If re-merging, change state of merge in all diffs starting with
 205 ;; DIFF-NUM, except those where the state is prefer-* or where it is
 206 ;; `default-*' or `combined' but the buf C region appears to be modified
 207 ;; since last set by default.
 208 (defun ediff-do-merge (diff-num &optional remerging)
 209   (if (< diff-num 0) (setq diff-num 0))
 210   (let ((n diff-num)
 211         ;;(default-state-of-merge (format "%S" ediff-default-variant))
 212         do-not-copy state-of-merge)
 213     (while (< n ediff-number-of-differences)
 214       (setq do-not-copy nil) ; reset after each cycle
 215       (if (= (mod n 10) 0)
 216           (message "%s buffers A & B into C ... region %d of %d"
 217                    (if remerging "Re-merging" "Merging")
 218                    n
 219                    ediff-number-of-differences))
 220
 221       (setq state-of-merge (ediff-get-state-of-merge n))
 222
 223       (if remerging
 224           ;;(let ((reg-A (ediff-get-region-contents n 'A ediff-control-buffer))
 225           ;;    (reg-B (ediff-get-region-contents n 'B ediff-control-buffer))
 226           ;;    (reg-C (ediff-get-region-contents n 'C ediff-control-buffer)))
 227           (let ()
 228
 229             ;; if region was edited since it was first set by default
 230             (if (or (ediff-merge-changed-from-default-p n)
 231                     ;; was preferred
 232                     (string-match "prefer" state-of-merge))
 233                 ;; then ignore
 234                 (setq do-not-copy t))
 235
 236             ;; change state of merge for this diff, if necessary
 237             (if (and (string-match "\\(default\\|combined\\)" state-of-merge)
 238                      (not do-not-copy))
 239                 (ediff-set-state-of-merge
 240                  n (format "%S" ediff-default-variant)))
 241             ))
 242
 243       ;; state-of-merge may have changed via ediff-set-state-of-merge, so
 244       ;; check it once again
 245       (setq state-of-merge (ediff-get-state-of-merge n))
 246
 247       (or do-not-copy
 248           (if (string= state-of-merge "combined")
 249               ;; use n+1 because ediff-combine-diffs works via user numbering
 250               ;; of diffs, which is 1+ to what ediff uses internally
 251               (ediff-combine-diffs (1+ n) 'batch)
 252             (ediff-copy-diff
 253              n (if (string-match "-A" state-of-merge) 'A 'B) 'C 'batch)))
 254       (setq n (1+ n)))
 255     (message "Merging buffers A & B into C ... Done")
 256     ))
 257
 258
 259 (defun ediff-re-merge ()
 260   "Remerge unmodified diff regions using a new default.  Start with the current region."
 261   (interactive)
 262   (let* ((default-variant-alist
 263            (list '("default-A") '("default-B") '("combined")))
 264          (actual-alist
 265           (delete (list (symbol-name ediff-default-variant))
 266                   default-variant-alist)))
 267     (setq ediff-default-variant
 268           (intern
 269            (completing-read
 270             (format "Current merge default is `%S'.  New default: "
 271                     ediff-default-variant)
 272             actual-alist nil 'must-match)))
 273     (ediff-do-merge ediff-current-difference 'remerge)
 274     (ediff-recenter)
 275   ))
 276
 277 (defun ediff-shrink-window-C (arg)
 278   "Shrink window C to just one line.
 279 With a prefix argument, returns window C to its normal size.
 280 Used only for merging jobs."
 281   (interactive "P")
 282   (if (not ediff-merge-job)
 283       (error "ediff-shrink-window-C can be used only for merging jobs"))
 284   (cond ((eq arg '-) (setq arg -1))
 285         ((not (numberp arg)) (setq arg nil)))
 286   (cond ((null arg)
 287          (let ((ediff-merge-window-share
 288                 (if (< (window-height ediff-window-C) 3)
 289                     ediff-merge-window-share 0)))
 290            (setq ediff-window-config-saved "") ; force redisplay
 291            (ediff-recenter 'no-rehighlight)))
 292         ((and (< arg 0) (> (window-height ediff-window-C) 2))
 293          (setq ediff-merge-window-share (* ediff-merge-window-share 0.9))
 294          (setq ediff-window-config-saved "") ; force redisplay
 295          (ediff-recenter 'no-rehighlight))
 296         ((and (> arg 0) (> (window-height ediff-window-A) 2))
 297          (setq ediff-merge-window-share (* ediff-merge-window-share 1.1))
 298          (setq ediff-window-config-saved "") ; force redisplay
 299          (ediff-recenter 'no-rehighlight))))
 300
 301
 302 ;; N here is the user's region number.  It is 1+ what Ediff uses internally.
 303 (defun ediff-combine-diffs (n &optional batch-invocation)
 304   "Combine Nth diff regions of buffers A and B and place the combination in C.
 305 N is a prefix argument.  If nil, combine the current difference regions.
 306 Combining is done according to the specifications in variable
 307 `ediff-combination-pattern'."
 308   (interactive "P")
 309   (setq n (if (numberp n) (1- n) ediff-current-difference))
 310
 311   (let (reg-combined)
 312     ;;(setq regA (ediff-get-region-contents n 'A ediff-control-buffer)
 313     ;;    regB (ediff-get-region-contents n 'B ediff-control-buffer))
 314     ;;(setq reg-combined (ediff-make-combined-diff regA regB))
 315     (setq reg-combined (ediff-get-combined-region n))
 316
 317     (ediff-copy-diff n nil 'C batch-invocation reg-combined))
 318     (or batch-invocation (ediff-jump-to-difference (1+ n))))
 319
 320
 321 ;; Checks if the region in buff C looks like a combination of the regions
 322 ;; in buffers A and B.  Return a list (reg-a-beg reg-a-end reg-b-beg reg-b-end)
 323 ;; These refer to where the delimiters for region A, B, Ancestor start and end
 324 ;; in buffer C
 325 (defun ediff-looks-like-combined-merge (region-num)
 326   (if ediff-merge-job
 327       (let ((combined (string-match (regexp-quote "(A+B)")
 328                                     (or (ediff-get-state-of-diff region-num 'C)
 329                                         "")))
 330             (mrgreg-beg (ediff-get-diff-posn 'C 'beg region-num))
 331             (mrgreg-end (ediff-get-diff-posn 'C 'end region-num))
 332             (pattern-list ediff-combination-pattern)
 333             delim reg-beg reg-end delim-regs-list)
 334
 335         (if combined
 336             (ediff-with-current-buffer ediff-buffer-C
 337               (while pattern-list
 338                 (goto-char mrgreg-beg)
 339                 (setq delim (nth 0 pattern-list))
 340                 (search-forward delim mrgreg-end 'noerror)
 341                 (setq reg-beg (match-beginning 0))
 342                 (setq reg-end (match-end 0))
 343                 (if (and reg-beg reg-end)
 344                     (setq delim-regs-list
 345                           ;; in reverse
 346                           (cons reg-end (cons reg-beg delim-regs-list))))
 347                 (if (> (length pattern-list) 1)
 348                     (setq pattern-list (cdr (cdr pattern-list)))
 349                   (setq pattern-list nil))
 350                 )))
 351
 352         (reverse delim-regs-list)
 353         )))
 354
 355 (defvar state-of-merge)                 ; dynamic var
 356
 357 ;; Check if the non-preferred merge has been modified since originally set.
 358 ;; This affects only the regions that are marked as default-A/B or combined.
 359 ;; If PREFERS-TOO is non-nil, then look at the regions marked as prefers-A/B as
 360 ;; well.
 361 (defun ediff-merge-changed-from-default-p (diff-num &optional prefers-too)
 362   (let ((reg-A (ediff-get-region-contents diff-num 'A ediff-control-buffer))
 363         (reg-B (ediff-get-region-contents diff-num 'B ediff-control-buffer))
 364         (reg-C (ediff-get-region-contents diff-num 'C ediff-control-buffer)))
 365
 366     (setq state-of-merge (ediff-get-state-of-merge diff-num))
 367
 368     ;; if region was edited since it was first set by default
 369     (or (and (string= state-of-merge "default-A")
 370              (not (string= reg-A reg-C)))
 371         (and (string= state-of-merge "default-B")
 372              (not (string= reg-B reg-C)))
 373         (and (string= state-of-merge "combined")
 374              ;;(not (string= (ediff-make-combined-diff reg-A reg-B) reg-C)))
 375              (not (string= (ediff-get-combined-region diff-num) reg-C)))
 376         (and prefers-too
 377              (string= state-of-merge "prefer-A")
 378              (not (string= reg-A reg-C)))
 379         (and prefers-too
 380              (string= state-of-merge "prefer-B")
 381              (not (string= reg-B reg-C)))
 382         )))
 383
 384
 385 (provide 'ediff-merg)
 386
 387
 388 ;;; Local Variables:
 389 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
 390 ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
 391 ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
 392 ;;; End:
 393
 394 ;; arch-tag: 9b798cf9-02ba-487f-a62e-b63aa823dbfb
 395 ;;; ediff-merg.el ends here