configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.50)
  26
  27 dnl We get MINGW64 with MSYS2
  28 if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64"
  29 then
  30   . $srcdir/nt/mingw-cfg.site
  31
  32   case $srcdir in
  33     /* | ?:*)
  34       # srcdir is an absolute path.  In this case, force the format
  35       # "/c/foo/bar", to simplify later conversions to native Windows
  36       # format ("c:/foo/bar")
  37       srcdir=`cd "${srcdir}" && pwd -W`
  38       srcdir="/${srcdir:0:1}${srcdir:2}"
  39       ;;
  40   esac
  41 fi
  42
  43 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  44 dnl and then quoted again for a C string.  Separate options with spaces.
  45 dnl Add some environment variables, if they were passed via the environment
  46 dnl rather than on the command-line.
  47 emacs_config_options=
  48 optsep=
  49 dnl This is the documented way to record the args passed to configure,
  50 dnl rather than $ac_configure_args.
  51 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  52   case $opt in
  53     -n | --no-create | --no-recursion)
  54       continue ;;
  55     CFLAGS | CPPFLAGS | LDFLAGS)
  56       eval 'test "${'$opt'+set}" = set' || continue
  57       case " $*" in
  58         *" $opt="*) continue ;;
  59       esac
  60       eval opt=$opt=\$$opt ;;
  61   esac
  62
  63   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  64   case $opt in
  65     *[["$emacs_shell_specials"]]*)
  66       case $opt in
  67         *\'*)
  68           emacs_quote_apostrophes="s/'/'\\\\''/g"
  69           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  70       esac
  71       opt="'$opt'"
  72       case $opt in
  73         *[['"\\']]*)
  74           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  75           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  76       esac ;;
  77   esac
  78   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  79   optsep=' '
  80 done
  81
  82 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  83 AC_CONFIG_SRCDIR(src/lisp.h)
  84 AC_CONFIG_AUX_DIR(build-aux)
  85
  86 xcsdkdir=
  87 AC_CHECK_PROGS(XCRUN, [xcrun])
  88 if test -n "$XCRUN"; then
  89   if test -z "$MAKE"; then
  90     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  91     dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses.
  92     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  93     if test -z "$MAKE_PROG"; then
  94       MAKE="$XCRUN MAKE"
  95       export MAKE
  96       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  97     fi
  98   fi
  99 fi
 100
 101 dnl Fairly arbitrary, older versions might work too.
 102 AM_INIT_AUTOMAKE(1.11)
 103
 104 dnl Support for --program-prefix, --program-suffix and
 105 dnl --program-transform-name options
 106 AC_ARG_PROGRAM
 107
 108 dnl It is important that variables on the RHS not be expanded here,
 109 dnl hence the single quotes.  This is per the GNU coding standards, see
 110 dnl (autoconf) Installation Directory Variables
 111 dnl See also epaths.h below.
 112 lispdir='${datadir}/emacs/${version}/lisp'
 113 standardlisppath='${lispdir}'
 114 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 115 '${datadir}/emacs/site-lisp'
 116 lisppath='${locallisppath}:${standardlisppath}'
 117 etcdir='${datadir}/emacs/${version}/etc'
 118 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 119 etcdocdir='${datadir}/emacs/${version}/etc'
 120 gamedir='${localstatedir}/games/emacs'
 121
 122 dnl Special option to disable the most of other options.
 123 AC_ARG_WITH(all,
 124 [AS_HELP_STRING([--without-all],
 125                 [omit almost all features and build
 126                 small executable with minimal dependencies])],
 127   [with_features=$withval],
 128   [with_features=yes])
 129
 130 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 131 dnl Create a new --with option that defaults to being disabled.
 132 dnl NAME is the base name of the option.  The shell variable with_NAME
 133 dnl   will be set to either the user's value (if the option is
 134 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 135 dnl   option is not specified).  Note that the shell variable name is
 136 dnl   constructed as autoconf does, by replacing non-alphanumeric
 137 dnl   characters with "_".
 138 dnl HELP-STRING is the help text for the option.
 139 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 140   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 141     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 142 ])dnl
 143
 144 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 145 dnl Create a new --with option that defaults to $with_features.
 146 dnl NAME is the base name of the option.  The shell variable with_NAME
 147 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 148 dnl   'yes' (if the option is not specified).  Note that the shell
 149 dnl   variable name is constructed as autoconf does, by replacing
 150 dnl   non-alphanumeric characters with "_".
 151 dnl HELP-STRING is the help text for the option.
 152 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 153   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 154    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 155 ])dnl
 156
 157 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 158 if test "$with_pop" = yes; then
 159    AC_DEFINE(MAIL_USE_POP)
 160 fi
 161 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 162
 163 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 164 if test "$with_kerberos" != no; then
 165    AC_DEFINE(KERBEROS)
 166 fi
 167 AH_TEMPLATE(KERBEROS,
 168             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 169
 170 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 171 if test "${with_kerberos5}" != no; then
 172   if test "${with_kerberos}" = no; then
 173     with_kerberos=yes
 174     AC_DEFINE(KERBEROS)
 175   fi
 176   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 177 fi
 178
 179 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 180 dnl FIXME hesiod support may not be present, so it seems like an error
 181 dnl to define, or at least use, this unconditionally.
 182 if test "$with_hesiod" != no; then
 183   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 184 fi
 185
 186 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 187 if test "$with_mmdf" != no; then
 188    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 189 fi
 190
 191 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 192 if test "$with_mail_unlink" != no; then
 193    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 194 fi
 195
 196 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 197     [string giving default POP mail host])],
 198     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 199
 200 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 201   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 202 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 203   [ case "${withval}" in
 204       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 205       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 206 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 207       ;;
 208     esac
 209     with_sound=$val
 210   ],
 211   [with_sound=$with_features])
 212
 213 dnl FIXME currently it is not the last.
 214 dnl This should be the last --with option, because --with-x is
 215 dnl added later on when we find the file name of X, and it's best to
 216 dnl keep them together visually.
 217 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 218  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 219 [         case "${withval}" in
 220             y | ye | yes )      val=gtk ;;
 221             n | no )            val=no  ;;
 222             l | lu | luc | luci | lucid )       val=lucid ;;
 223             a | at | ath | athe | athen | athena )      val=athena ;;
 224             m | mo | mot | moti | motif )       val=motif ;;
 225             g | gt | gtk  )     val=gtk ;;
 226             gtk2  )     val=gtk2 ;;
 227             gtk3  )     val=gtk3 ;;
 228             * )
 229 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 230 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 231 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 232 `athena' and `lucid' are synonyms.])
 233             ;;
 234           esac
 235           with_x_toolkit=$val
 236 ])
 237
 238 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 239 if test "$with_wide_int" = yes; then
 240   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 241 fi
 242
 243 dnl _ON results in a '--without' option in the --help output, so
 244 dnl the help text should refer to "don't compile", etc.
 245 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 246 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 247 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 248 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 249 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 250 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 251 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 252 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 253
 254 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 255 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 256 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 257
 258 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 259 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 260 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 261 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 262 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 263
 264 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 265 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 266 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 267 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 268 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 269 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 270 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 271
 272 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 273  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 274  [ case "${withval}" in
 275     y | ye | yes )      val=yes ;;
 276     n | no )            val=no  ;;
 277     g | gf | gfi | gfil | gfile )       val=gfile ;;
 278     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 279     w | w3 | w32 )      val=w32 ;;
 280     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 281 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 282 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 283 otherwise for the first of `gfile' or `inotify' that is usable.])
 284     ;;
 285    esac
 286    with_file_notification=$val
 287  ],
 288  [with_file_notification=$with_features])
 289
 290 ## For the times when you want to build Emacs but don't have
 291 ## a suitable makeinfo, and can live without the manuals.
 292 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 293 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 294
 295 ## Makefile.in needs the cache file name.
 296 AC_SUBST(cache_file)
 297
 298 ## This is an option because I do not know if all info/man support
 299 ## compressed files, nor how to test if they do so.
 300 OPTION_DEFAULT_ON([compress-install],
 301   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 302 make GZIP_PROG= install])
 303
 304 AC_ARG_WITH([pkg-config-prog],dnl
 305 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 306                   [file name of pkg-config for finding GTK and librsvg])])
 307 if test "X${with_pkg_config_prog}" != X; then
 308    if test "${with_pkg_config_prog}" != yes; then
 309       PKG_CONFIG="${with_pkg_config_prog}"
 310    fi
 311 fi
 312
 313 AC_ARG_WITH(gameuser,dnl
 314 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 315 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 316   && gameuser="${with_gameuser}"
 317 test "X$gameuser" = X && gameuser=games
 318
 319 AC_ARG_WITH([gnustep-conf],dnl
 320 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 321    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 322 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 323   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 324 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 325      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 326
 327 AC_ARG_ENABLE(ns-self-contained,
 328 [AS_HELP_STRING([--disable-ns-self-contained],
 329                 [disable self contained build under NeXTstep])],
 330    EN_NS_SELF_CONTAINED=$enableval,
 331    EN_NS_SELF_CONTAINED=yes)
 332
 333 AC_ARG_ENABLE(locallisppath,
 334 [AS_HELP_STRING([--enable-locallisppath=PATH],
 335                 [directories Emacs should search for lisp files specific
 336                  to this site])],
 337 if test "${enableval}" = "no"; then
 338   locallisppath=
 339 elif test "${enableval}" != "yes"; then
 340   locallisppath=${enableval}
 341 fi)
 342
 343 AC_ARG_ENABLE(checking,
 344 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 345                 [enable expensive run-time checks.  With LIST,
 346                  enable only specific categories of checks.
 347                  Categories are: all,yes,no.
 348                  Flags are: stringbytes, stringoverrun, stringfreelist,
 349                  xmallocoverrun, conslist, glyphs])],
 350 [ac_checking_flags="${enableval}"],[])
 351 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 352 for check in $ac_checking_flags
 353 do
 354         case $check in
 355         # these set all the flags to specific states
 356         yes)            ac_enable_checking=1 ;;
 357         no)             ac_enable_checking= ;
 358                         ac_gc_check_stringbytes= ;
 359                         ac_gc_check_string_overrun= ;
 360                         ac_gc_check_string_free_list= ;
 361                         ac_xmalloc_overrun= ;
 362                         ac_gc_check_cons_list= ;
 363                         ac_glyphs_debug= ;;
 364         all)            ac_enable_checking=1 ;
 365                         ac_gc_check_stringbytes=1 ;
 366                         ac_gc_check_string_overrun=1 ;
 367                         ac_gc_check_string_free_list=1 ;
 368                         ac_xmalloc_overrun=1 ;
 369                         ac_gc_check_cons_list=1 ;
 370                         ac_glyphs_debug=1 ;;
 371         # these enable particular checks
 372         stringbytes)    ac_gc_check_stringbytes=1 ;;
 373         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 374         stringfreelist) ac_gc_check_string_free_list=1 ;;
 375         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 376         conslist)       ac_gc_check_cons_list=1 ;;
 377         glyphs)         ac_glyphs_debug=1 ;;
 378         *)      AC_MSG_ERROR(unknown check category $check) ;;
 379         esac
 380 done
 381 IFS="$ac_save_IFS"
 382
 383 if test x$ac_enable_checking != x ; then
 384   AC_DEFINE(ENABLE_CHECKING, 1,
 385 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 386 fi
 387 if test x$ac_gc_check_stringbytes != x ; then
 388   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 389 [Define this temporarily to hunt a bug.  If defined, the size of
 390    strings is redundantly recorded in sdata structures so that it can
 391    be compared to the sizes recorded in Lisp strings.])
 392 fi
 393 if test x$ac_gc_check_string_overrun != x ; then
 394   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 395 [Define this to check for short string overrun.])
 396 fi
 397 if test x$ac_gc_check_string_free_list != x ; then
 398   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 399 [Define this to check the string free list.])
 400 fi
 401 if test x$ac_xmalloc_overrun != x ; then
 402   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 403 [Define this to check for malloc buffer overrun.])
 404 fi
 405 if test x$ac_gc_check_cons_list != x ; then
 406   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 407 [Define this to check for errors in cons list.])
 408 fi
 409 if test x$ac_glyphs_debug != x ; then
 410   AC_DEFINE(GLYPH_DEBUG, 1,
 411 [Define this to enable glyphs debugging code.])
 412 fi
 413
 414 AC_ARG_ENABLE(check-lisp-object-type,
 415 [AS_HELP_STRING([--enable-check-lisp-object-type],
 416                 [enable compile time checks for the Lisp_Object data type.
 417                 This is useful for development for catching certain types of bugs.])],
 418 if test "${enableval}" != "no"; then
 419    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 420    [Define this to enable compile time checks for the Lisp_Object data type.])
 421 fi)
 422
 423
 424 dnl The name of this option is unfortunate.  It predates, and has no
 425 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 426 dnl Actually, it stops it working.
 427 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 428 AC_ARG_ENABLE(profiling,
 429 [AS_HELP_STRING([--enable-profiling],
 430                 [build emacs with low-level, gprof profiling support.
 431                 Mainly useful for debugging Emacs itself.  May not work on
 432                 all platforms.  Stops profiler.el working.])],
 433 [ac_enable_profiling="${enableval}"],[])
 434 if test x$ac_enable_profiling != x ; then
 435    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 436 else
 437    PROFILING_CFLAGS=
 438 fi
 439 AC_SUBST(PROFILING_CFLAGS)
 440
 441 AC_ARG_ENABLE(autodepend,
 442 [AS_HELP_STRING([--enable-autodepend],
 443                 [automatically generate dependencies to .h-files.
 444                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 445                  found])],
 446 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 447
 448 AC_ARG_ENABLE(gtk-deprecation-warnings,
 449 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 450                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 451 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 452
 453 ### Canonicalize the configuration name.
 454
 455 AC_CANONICAL_HOST
 456 canonical=$host
 457 configuration=${host_alias-${build_alias-$host}}
 458
 459 dnl This used to use changequote, but, apart from `changequote is evil'
 460 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 461 dnl the great gob of text.  Thus it's not processed for possible expansion.
 462 dnl Just make sure the brackets remain balanced.
 463 dnl
 464 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 465 dnl indicated by comments.
 466 dnl quotation begins
 467 [
 468
 469 ### If you add support for a new configuration, add code to this
 470 ### switch statement to recognize your configuration name and select
 471 ### the appropriate opsys.
 472
 473 ### As far as handling version numbers on operating systems is
 474 ### concerned, make sure things will fail in a fixable way.  If
 475 ### /etc/MACHINES doesn't say anything about version numbers, be
 476 ### prepared to handle anything reasonably.  If version numbers
 477 ### matter, be sure /etc/MACHINES says something about it.
 478
 479 opsys='' unported=no
 480 case "${canonical}" in
 481
 482   ## GNU/Linux and similar ports
 483   *-*-linux* )
 484     opsys=gnu-linux
 485   ;;
 486
 487   ## FreeBSD ports
 488   *-*-freebsd* )
 489     opsys=freebsd
 490   ;;
 491
 492   ## DragonFly ports
 493   *-*-dragonfly* )
 494     opsys=dragonfly
 495   ;;
 496
 497   ## FreeBSD kernel + glibc based userland
 498   *-*-kfreebsd*gnu* )
 499     opsys=gnu-kfreebsd
 500   ;;
 501
 502   ## NetBSD ports
 503   *-*-netbsd* )
 504     opsys=netbsd
 505   ;;
 506
 507   ## OpenBSD ports
 508   *-*-openbsd* )
 509     opsys=openbsd
 510   ;;
 511
 512   ## Apple Darwin / Mac OS X
 513   *-apple-darwin* )
 514     case "${canonical}" in
 515       i[3456]86-* )  ;;
 516       powerpc-* )    ;;
 517       x86_64-* )     ;;
 518       * )            unported=yes ;;
 519     esac
 520     opsys=darwin
 521     ## Use fink packages if available.
 522     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 523 ##    if test -d /sw/include && test -d /sw/lib; then
 524 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 525 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 526 ##    fi
 527   ;;
 528
 529   ## Cygwin ports
 530   *-*-cygwin )
 531     opsys=cygwin
 532   ;;
 533
 534   ## HP 9000 series 700 and 800, running HP/UX
 535   hppa*-hp-hpux10.2* )
 536     opsys=hpux10-20
 537   ;;
 538   hppa*-hp-hpux1[1-9]* )
 539     opsys=hpux11
 540     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 541   ;;
 542
 543   ## IBM machines
 544   rs6000-ibm-aix4.[23]* )
 545     opsys=aix4-2
 546   ;;
 547   powerpc-ibm-aix4.[23]*  )
 548     opsys=aix4-2
 549   ;;
 550   rs6000-ibm-aix[56]* )
 551     opsys=aix4-2
 552   ;;
 553   powerpc-ibm-aix[56]*  )
 554     opsys=aix4-2
 555   ;;
 556
 557   ## Silicon Graphics machines
 558   ## Iris 4D
 559   mips-sgi-irix6.5 )
 560     opsys=irix6-5
 561     # Without defining _LANGUAGE_C, things get masked out in the headers
 562     # so that, for instance, grepping for `free' in stdlib.h fails and
 563     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 564     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 565   ;;
 566
 567   ## Suns
 568   *-sun-solaris* \
 569     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 570     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 571     case "${canonical}" in
 572       i[3456]86-*-* )   ;;
 573       amd64-*-*|x86_64-*-*) ;;
 574       sparc* )          ;;
 575       * )               unported=yes ;;
 576     esac
 577     case "${canonical}" in
 578       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 ;;
 582       *-sunos5.6* | *-solaris2.6* )
 583                 opsys=sol2-6
 584                 RANLIB="ar -ts"
 585                 ;;
 586       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 587                 opsys=sol2-6
 588                 emacs_check_sunpro_c=yes
 589                 ;;
 590     esac
 591     ## Watch out for a compiler that we know will not work.
 592     case "${canonical}" in
 593      *-solaris* | *-sunos5* )
 594                 if [ "x$CC" = x/usr/ucb/cc ]; then
 595                   ## /usr/ucb/cc doesn't work;
 596                   ## we should find some other compiler that does work.
 597                   unset CC
 598                 fi
 599                 ;;
 600       *) ;;
 601     esac
 602   ;;
 603
 604   ## Intel 386 machines where we don't care about the manufacturer.
 605   i[3456]86-*-* )
 606     case "${canonical}" in
 607       *-darwin* )               opsys=darwin ;;
 608       *-mingw32 )
 609                 opsys=mingw32
 610                 # MinGW overrides and adds some system headers in nt/inc.
 611                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 612                 ;;
 613       *-sysv4.2uw* )            opsys=unixware ;;
 614       *-sysv5uw* )              opsys=unixware ;;
 615       *-sysv5OpenUNIX* )        opsys=unixware ;;
 616       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 617     esac
 618   ;;
 619
 620   # MinGW64
 621   x86_64-*-* )
 622     case "${canonical}" in
 623       *-mingw32 )
 624                 opsys=mingw32
 625                 # MinGW overrides and adds some system headers in nt/inc.
 626                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 627                 ;;
 628       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 629     esac
 630   ;;
 631
 632   * )
 633     unported=yes
 634   ;;
 635 esac
 636
 637 ### If the code above didn't choose an operating system, just choose
 638 ### an operating system based on the configuration name.  You really
 639 ### only want to use this when you have no idea what the right
 640 ### operating system is; if you know what operating systems a machine
 641 ### runs, it's cleaner to make it explicit in the case statement
 642 ### above.
 643 if test x"${opsys}" = x; then
 644   case "${canonical}" in
 645     *-gnu* )                            opsys=gnu ;;
 646     * )
 647       unported=yes
 648     ;;
 649   esac
 650 fi
 651
 652 ]
 653 dnl quotation ends
 654
 655 if test $unported = yes; then
 656   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 657 If you think it should, please send a report to bug-gnu-emacs@gnu.org.
 658 Check `etc/MACHINES' for recognized configuration names.])
 659 fi
 660
 661
 662 #### Choose a compiler.
 663
 664 dnl Sets GCC=yes if using gcc.
 665 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 666 if test -n "$XCRUN"; then
 667   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 668   test -n "$AR" && export AR
 669 fi
 670
 671 AM_PROG_CC_C_O
 672
 673 if test x$GCC = xyes; then
 674   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 675 else
 676   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 677 fi
 678
 679 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 680 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 681 dnl that clash with MinGW.
 682 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 683
 684 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 685 AC_DEFUN([gl_CRYPTO_CHECK])
 686 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 687 # as we don't use them.
 688 AC_DEFUN([gl_FCNTL_O_FLAGS])
 689 # Avoid gnulib's threadlib module, as we do threads our own way.
 690 AC_DEFUN([gl_THREADLIB])
 691
 692 # Initialize gnulib right after choosing the compiler.
 693 dnl Amongst other things, this sets AR and ARFLAGS.
 694 gl_EARLY
 695
 696 if test "$ac_test_CFLAGS" != set; then
 697   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 698   # if -g3 works and the user does not specify CFLAGS.
 699   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 700   case $CFLAGS in
 701     '-g')
 702       emacs_g3_CFLAGS='-g3';;
 703     '-g -O2')
 704       emacs_g3_CFLAGS='-g3 -O2';;
 705     *)
 706       emacs_g3_CFLAGS='';;
 707   esac
 708   if test -n "$emacs_g3_CFLAGS"; then
 709     emacs_save_CFLAGS=$CFLAGS
 710     CFLAGS=$emacs_g3_CFLAGS
 711     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 712       [emacs_cv_prog_cc_g3],
 713       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 714          [emacs_cv_prog_cc_g3=yes],
 715          [emacs_cv_prog_cc_g3=no])])
 716     if test $emacs_cv_prog_cc_g3 != yes; then
 717       CFLAGS=$emacs_save_CFLAGS
 718     fi
 719     if test $opsys = mingw32; then
 720       CFLAGS="$CFLAGS -gdwarf-2"
 721     fi
 722   fi
 723
 724   case $CFLAGS in
 725     *-O*) ;;
 726     *)
 727       # No optimization flag was inferred for this non-GCC compiler.
 728       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 729       emacs_save_CFLAGS=$CFLAGS
 730       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 731       CFLAGS=${CFLAGS}-O
 732       AC_CACHE_CHECK([whether $CC accepts -O],
 733         [emacs_cv_prog_cc_o],
 734         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 735            [emacs_cv_prog_cc_o=yes],
 736            [emacs_cv_prog_cc_o=no])])
 737       if test $emacs_cv_prog_cc_o != yes; then
 738         CFLAGS=$emacs_save_CFLAGS
 739       fi ;;
 740   esac
 741 fi
 742
 743 AC_ARG_ENABLE([gcc-warnings],
 744   [AS_HELP_STRING([--enable-gcc-warnings],
 745                   [turn on lots of GCC warnings/errors. This is intended for
 746                    developers, and may generate false alarms when used
 747                    with older or non-GNU development tools.])],
 748   [case $enableval in
 749      yes|no) ;;
 750      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 751    esac
 752    gl_gcc_warnings=$enableval],
 753   [gl_gcc_warnings=no]
 754 )
 755
 756 AC_ARG_ENABLE(link-time-optimization,
 757 [AS_HELP_STRING([--enable-link-time-optimization],
 758                 [build emacs with link-time optimization.
 759                  This is supported only for GCC since 4.5.0.])],
 760 if test "${enableval}" != "no"; then
 761    AC_MSG_CHECKING([whether link-time optimization is supported])
 762    ac_lto_supported=no
 763    if test x$GCC = xyes; then
 764       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 765       if test x$CPUS != x; then
 766          LTO="-flto=$CPUS"
 767       else
 768          LTO="-flto"
 769       fi
 770       old_CFLAGS=$CFLAGS
 771       CFLAGS="$CFLAGS $LTO"
 772       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 773         [ac_lto_supported=yes], [ac_lto_supported=no])
 774       CFLAGS="$old_CFLAGS"
 775    fi
 776    AC_MSG_RESULT([$ac_lto_supported])
 777    if test "$ac_lto_supported" = "yes"; then
 778       CFLAGS="$CFLAGS $LTO"
 779    fi
 780 fi)
 781
 782 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 783 # ------------------------------------------------
 784 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 785 # Otherwise, run RUN-IF-NOT-FOUND.
 786 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 787   [AC_PREPROC_IFELSE(
 788     [AC_LANG_PROGRAM(
 789       [[
 790 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 791 /* ok */
 792 #else
 793 # error "your version of gcc is older than $1.$2"
 794 #endif
 795       ]]),
 796     ], [$3], [$4])
 797   ]
 798 )
 799
 800 # clang is unduly picky about some things.
 801 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 802   [AC_COMPILE_IFELSE(
 803      [AC_LANG_PROGRAM([[
 804           #ifndef __clang__
 805             #error "not clang"
 806           #endif
 807         ]])],
 808      [emacs_cv_clang=yes],
 809      [emacs_cv_clang=no])])
 810
 811 # When compiling with GCC, prefer -isystem to -I when including system
 812 # include files, to avoid generating useless diagnostics for the files.
 813 if test "$gl_gcc_warnings" != yes; then
 814   isystem='-I'
 815   if test "$emacs_cv_clang" = yes
 816   then
 817      # Turn off some warnings if supported.
 818      gl_WARN_ADD([-Wno-switch])
 819      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 820      gl_WARN_ADD([-Wno-pointer-sign])
 821   fi
 822 else
 823   isystem='-isystem '
 824
 825   # This, $nw, is the list of warnings we disable.
 826   nw=
 827
 828   case $with_x_toolkit in
 829     lucid | athena | motif)
 830        # Old toolkits mishandle 'const'.
 831        nw="$nw -Wwrite-strings"
 832        ;;
 833     *)
 834        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 835        ;;
 836   esac
 837   AC_SUBST([WERROR_CFLAGS])
 838
 839   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 840   nw="$nw -Woverlength-strings"     # Not a problem these days
 841   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 842   nw="$nw -Wformat-nonliteral"      # we do this a lot
 843   nw="$nw -Wvla"                    # warnings in gettext.h
 844   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 845   nw="$nw -Wswitch-default"         # Too many warnings for now
 846   nw="$nw -Winline"                 # OK to ignore 'inline'
 847   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 848   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 849                                     # signed overflow has undefined behavior
 850   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 851   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 852   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 853
 854   # Emacs doesn't care about shadowing; see
 855   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 856   nw="$nw -Wshadow"
 857
 858   # Emacs's use of alloca inhibits protecting the stack.
 859   nw="$nw -Wstack-protector"
 860
 861   # The following line should be removable at some point.
 862   nw="$nw -Wsuggest-attribute=pure"
 863
 864   # This part is merely for shortening the command line,
 865   # since -Wno-FOO needs to be added below regardless.
 866   nw="$nw -Wmissing-field-initializers"
 867   nw="$nw -Wswitch"
 868   nw="$nw -Wtype-limits"
 869   nw="$nw -Wunused-parameter"
 870
 871   if test $emacs_cv_clang = yes; then
 872     nw="$nw -Wcast-align"
 873   fi
 874
 875   gl_MANYWARN_ALL_GCC([ws])
 876   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 877   for w in $ws; do
 878     gl_WARN_ADD([$w])
 879   done
 880   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 881   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 882   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 883   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 884   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 885   gl_WARN_ADD([-Wno-format-nonliteral])
 886
 887   # In spite of excluding -Wlogical-op above, it is enabled, as of
 888   # gcc 4.5.0 20090517.
 889   gl_WARN_ADD([-Wno-logical-op])
 890
 891   # More things that clang is unduly picky about.
 892   if test $emacs_cv_clang = yes; then
 893     gl_WARN_ADD([-Wno-format-extra-args])
 894     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 895     gl_WARN_ADD([-Wno-unused-command-line-argument])
 896     gl_WARN_ADD([-Wno-unused-value])
 897   fi
 898
 899   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 900   AH_VERBATIM([FORTIFY_SOURCE],
 901   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 902       without upsetting glibc 2.15+. */
 903    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 904    # define _FORTIFY_SOURCE 2
 905    #endif
 906   ])
 907   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 908
 909   # We use a slightly smaller set of warning options for lib/.
 910   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 911   nw=
 912   nw="$nw -Wunused-macros"
 913
 914   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 915   AC_SUBST([GNULIB_WARN_CFLAGS])
 916 fi
 917
 918
 919
 920 dnl Some other nice autoconf tests.
 921 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 922 dnl AC_PROG_INSTALL
 923 dnl AC_PROG_MKDIR_P
 924 dnl if test "x$RANLIB" = x; then
 925 dnl   AC_PROG_RANLIB
 926 dnl fi
 927
 928
 929 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 930 dnl can be made to directories.  This is not relevant for our usage, and
 931 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 932 dnl hosted on AFS, both examples where simple links work, but links to
 933 dnl directories fail.  We use a cut-down version instead.
 934 dnl AC_PROG_LN_S
 935
 936 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 937 rm -f conf$$ conf$$.file
 938
 939 LN_S_FILEONLY='cp -p'
 940
 941 if (echo >conf$$.file) 2>/dev/null; then
 942   if ln -s conf$$.file conf$$ 2>/dev/null; then
 943     LN_S_FILEONLY='ln -s'
 944   elif ln conf$$.file conf$$ 2>/dev/null; then
 945     LN_S_FILEONLY=ln
 946   fi
 947 fi
 948
 949 rm -f conf$$ conf$$.file
 950
 951 if test "$LN_S_FILEONLY" = "ln -s"; then
 952    AC_MSG_RESULT([yes])
 953 else
 954    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 955 fi
 956
 957 AC_SUBST(LN_S_FILEONLY)
 958
 959
 960 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 961 dnl doesn't support links to directories, as in "ln file dir".  But that
 962 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 963 dnl executables at "make install" time.
 964 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 965 dnl for more details.
 966 if test "$opsys" = "mingw32"; then
 967   LN_S="ln"
 968 fi
 969
 970 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 971   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 972 dnl Don't use GZIP, which is used by gzip for additional parameters.
 973 AC_PATH_PROG(GZIP_PROG, gzip)
 974
 975 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
 976    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
 977
 978 if test $opsys = gnu-linux; then
 979   AC_PATH_PROG(PAXCTL, paxctl,,
 980     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 981   if test "X$PAXCTL" != X; then
 982     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 983     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 984       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 985       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 986   fi
 987
 988   if test "${SETFATTR+set}" != set; then
 989     AC_CACHE_CHECK([for setfattr],
 990       [emacs_cv_prog_setfattr],
 991       [touch conftest.tmp
 992        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
 993          emacs_cv_prog_setfattr=yes
 994        else
 995          emacs_cv_prog_setfattr=no
 996        fi])
 997     if test "$emacs_cv_prog_setfattr" = yes; then
 998       SETFATTR=setfattr
 999     else
1000       SETFATTR=
1001     fi
1002     rm -f conftest.tmp
1003     AC_SUBST([SETFATTR])
1004   fi
1005 fi
1006
1007 ## Need makeinfo >= 4.7 (?) to build the manuals.
1008 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1009 dnl By this stage, configure has already checked for egrep and set EGREP,
1010 dnl or exited with an error if no egrep was found.
1011 if test "$MAKEINFO" != "no"; then
1012   case `
1013     $MAKEINFO --version 2> /dev/null |
1014     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1015   ` in
1016     '') MAKEINFO=no;;
1017   esac
1018 fi
1019
1020 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1021 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1022 ## therefore in the category of "special tools" not normally required, which
1023 ## configure does not have to check for (eg autoconf itself).
1024 ## In a repository checkout on the other hand, the manuals are not included.
1025 ## So makeinfo is a requirement to build from the repository, and configure
1026 ## should test for it as it does for any other build requirement.
1027 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1028 ## with pre-built manuals, from a repository checkout.
1029 HAVE_MAKEINFO=yes
1030
1031 if test "$MAKEINFO" = "no"; then
1032   MAKEINFO=makeinfo
1033   if test "x${with_makeinfo}" = "xno"; then
1034     HAVE_MAKEINFO=no
1035   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1036     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1037 source tree does not seem to have pre-built manuals in the `info' directory.
1038 Either install a suitable version of makeinfo, or re-run configure
1039 with the `--without-makeinfo' option to build without the manuals.] )
1040   fi
1041 fi
1042 AC_SUBST(HAVE_MAKEINFO)
1043
1044 dnl Just so that there is only a single place we need to edit.
1045 INFO_EXT=.info
1046 INFO_OPTS=--no-split
1047 AC_SUBST(INFO_EXT)
1048 AC_SUBST(INFO_OPTS)
1049
1050 if test $opsys = mingw32; then
1051    DOCMISC_W32=efaq-w32
1052 else
1053    DOCMISC_W32=
1054 fi
1055 AC_SUBST(DOCMISC_W32)
1056
1057 dnl Add our options to ac_link now, after it is set up.
1058
1059 if test x$GCC = xyes; then
1060   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1061     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1062 else
1063   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1064     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1065 fi
1066
1067 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1068 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1069 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1070 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1071 dnl if not built to support GNU ld.
1072
1073 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1074 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1075 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1076 dnl   Eg "make LDFLAGS=... all" could run into problems,
1077 dnl   http://bugs.debian.org/684788
1078 dnl * unnecessary, since temacs is the only thing that actually needs it.
1079 dnl   Indeed this is where it was originally, prior to:
1080 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1081 late_LDFLAGS="$LDFLAGS"
1082 if test x$GCC = xyes; then
1083   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1084 else
1085   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1086 fi
1087
1088 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1089
1090 AC_MSG_CHECKING([for -znocombreloc])
1091 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1092   [AC_MSG_RESULT(yes)],
1093   LDFLAGS_NOCOMBRELOC=
1094   [AC_MSG_RESULT(no)])
1095
1096 LDFLAGS="$late_LDFLAGS"
1097
1098 AC_CACHE_CHECK([whether addresses are sanitized],
1099   [emacs_cv_sanitize_address],
1100   [AC_COMPILE_IFELSE(
1101      [AC_LANG_PROGRAM(
1102         [[#ifndef __has_feature
1103           #define __has_feature(f) 0
1104           #endif
1105           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1106           #else
1107            #error "Addresses are not sanitized."
1108           #endif
1109         ]])],
1110      [emacs_cv_sanitize_address=yes],
1111      [emacs_cv_sanitize_address=no])])
1112
1113 dnl The function dump-emacs will not be defined and temacs will do
1114 dnl (load "loadup") automatically unless told otherwise.
1115 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1116 case "$opsys" in
1117   your-opsys-here) CANNOT_DUMP=yes ;;
1118 esac
1119
1120 if test "$CANNOT_DUMP" = "yes"; then
1121   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1122 elif test "$emacs_cv_sanitize_address" = yes; then
1123   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1124 fi
1125
1126 AC_SUBST(CANNOT_DUMP)
1127
1128
1129 UNEXEC_OBJ=unexelf.o
1130 case "$opsys" in
1131   # MSDOS uses unexcoff.o
1132   aix4-2)
1133    UNEXEC_OBJ=unexaix.o
1134    ;;
1135   cygwin)
1136    UNEXEC_OBJ=unexcw.o
1137    ;;
1138   darwin)
1139    UNEXEC_OBJ=unexmacosx.o
1140    ;;
1141   hpux10-20 | hpux11)
1142    UNEXEC_OBJ=unexhp9k800.o
1143    ;;
1144   mingw32)
1145    UNEXEC_OBJ=unexw32.o
1146    ;;
1147   sol2-10)
1148    # Use the Solaris dldump() function, called from unexsol.c, to dump
1149    # emacs, instead of the generic ELF dump code found in unexelf.c.
1150    # The resulting binary has a complete symbol table, and is better
1151    # for debugging and other observability tools (debuggers, pstack, etc).
1152    #
1153    # If you encounter a problem using dldump(), please consider sending
1154    # a message to the OpenSolaris tools-linking mailing list:
1155    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1156    #
1157    # It is likely that dldump() works with older Solaris too, but this has
1158    # not been tested, so for now this change is for Solaris 10 or newer.
1159    UNEXEC_OBJ=unexsol.o
1160    ;;
1161 esac
1162
1163 LD_SWITCH_SYSTEM=
1164 case "$opsys" in
1165   freebsd|dragonfly)
1166    ## Let `ld' find image libs and similar things in /usr/local/lib.
1167    ## The system compiler, GCC, has apparently been modified to not
1168    ## look there, contrary to what a stock GCC would do.
1169 ### It's not our place to do this.  See bug#10313#17.
1170 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1171       :
1172    ;;
1173
1174   gnu-linux)
1175    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1176    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1177    ;;
1178
1179   netbsd)
1180 ### It's not our place to do this.  See bug#10313#17.
1181 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1182       :
1183    ;;
1184
1185   openbsd)
1186    ## Han Boetes <han@boetes.org> says this is necessary,
1187    ## otherwise Emacs dumps core on elf systems.
1188    LD_SWITCH_SYSTEM="-Z"
1189    ;;
1190 esac
1191 AC_SUBST(LD_SWITCH_SYSTEM)
1192
1193 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1194
1195 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1196 ## which has not been defined yet.  When this was handled with cpp,
1197 ## it was expanded to null when configure sourced the s/*.h file.
1198 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1199 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1200 ## (or somesuch), but because it is supposed to go at the _front_
1201 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1202 ## Compare with the gnu-linux case below, which added to the end
1203 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1204 ## LD_SWITCH_SYSTEM_TEMACS.
1205 case "$opsys" in
1206   netbsd|openbsd)
1207    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1208 esac
1209
1210
1211 C_SWITCH_MACHINE=
1212 case $canonical in
1213  alpha*)
1214   AC_CHECK_DECL([__ELF__])
1215   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1216     ## With ELF, make sure that all common symbols get allocated to in the
1217     ## data section.  Otherwise, the dump of temacs may miss variables in
1218     ## the shared library that have been initialized.  For example, with
1219     ## GNU libc, __malloc_initialized would normally be resolved to the
1220     ## shared library's .bss section, which is fatal.
1221     if test "x$GCC" = "xyes"; then
1222       C_SWITCH_MACHINE="-fno-common"
1223     else
1224       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1225     fi
1226   else
1227       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1228       dnl albeit under the mistaken assumption that said file
1229       dnl was no longer used.
1230       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1231   fi
1232   ;;
1233 esac
1234 AC_SUBST(C_SWITCH_MACHINE)
1235
1236 AC_SUBST(UNEXEC_OBJ)
1237
1238 C_SWITCH_SYSTEM=
1239 ## Some programs in src produce warnings saying certain subprograms
1240 ## are too complex and need a MAXMEM value greater than 2000 for
1241 ## additional optimization.  --nils@exp-math.uni-essen.de
1242 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1243   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1244 if test "$opsys" = "mingw32"; then
1245   case "$canonical" in
1246     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1247     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1248   esac
1249 fi
1250 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1251 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1252 AC_SUBST(C_SWITCH_SYSTEM)
1253
1254
1255 LIBS_SYSTEM=
1256 case "$opsys" in
1257   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1258   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1259
1260   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1261
1262   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1263
1264   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1265
1266   ## Motif needs -lgen.
1267   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1268 esac
1269
1270 AC_SUBST(LIBS_SYSTEM)
1271
1272 ### Make sure subsequent tests use flags consistent with the build flags.
1273
1274 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1275   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1276 else
1277   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1278 fi
1279
1280 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1281 AC_DEFUN([AC_TYPE_SIZE_T])
1282 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1283 AC_DEFUN([AC_TYPE_UID_T])
1284
1285
1286 LIB_MATH=-lm
1287 dnl Current possibilities handled by sed (aix4-2 -> aix,
1288 dnl gnu-linux -> gnu/linux, etc.):
1289 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1290 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1291 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1292
1293 case $opsys in
1294   cygwin )
1295     LIB_MATH=
1296     ;;
1297   darwin )
1298     ## Adding -lm confuses the dynamic linker, so omit it.
1299     LIB_MATH=
1300     ;;
1301   freebsd | dragonfly )
1302     SYSTEM_TYPE=berkeley-unix
1303     ;;
1304   gnu-linux | gnu-kfreebsd )
1305     ;;
1306   hpux10-20 | hpux11 )
1307     ;;
1308   mingw32 )
1309     LIB_MATH=
1310     SYSTEM_TYPE=windows-nt
1311     ;;
1312   dnl NB this may be adjusted below.
1313   netbsd | openbsd )
1314     SYSTEM_TYPE=berkeley-unix
1315     ;;
1316
1317   sol2* | unixware )
1318     SYSTEM_TYPE=usg-unix-v
1319     ;;
1320
1321 esac
1322
1323 AC_SUBST(LIB_MATH)
1324 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1325   [The type of system you are compiling for; sets `system-type'.])
1326
1327
1328 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1329 pre_PKG_CONFIG_LIBS=$LIBS
1330
1331 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1332
1333 dnl This function definition taken from Gnome 2.0
1334 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1335 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1336 dnl also defines GSTUFF_PKG_ERRORS on error
1337 AC_DEFUN([PKG_CHECK_MODULES], [
1338   succeeded=no
1339
1340   if test "$PKG_CONFIG" = "no" ; then
1341      ifelse([$4], , [AC_MSG_ERROR([
1342       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1343   else
1344      PKG_CONFIG_MIN_VERSION=0.9.0
1345      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1346         AC_MSG_CHECKING(for $2)
1347
1348         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1349            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1350            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1351             edit_cflags="
1352               s,///*,/,g
1353               s/^/ /
1354               s/ -I/ $isystem/g
1355               s/^ //
1356             "
1357             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1358             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1359             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1360             succeeded=yes
1361         else
1362             AC_MSG_RESULT(no)
1363             $1_CFLAGS=""
1364             $1_LIBS=""
1365             ## If we have a custom action on failure, don't print errors, but
1366             ## do set a variable so people can do so.  Do it in a subshell
1367             ## to capture any diagnostics in invoking pkg-config.
1368             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1369             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1370         fi
1371
1372         AC_SUBST($1_CFLAGS)
1373         AC_SUBST($1_LIBS)
1374      else
1375         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1376         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1377      fi
1378   fi
1379
1380   if test $succeeded = yes; then
1381      ifelse([$3], , :, [$3])
1382   else
1383      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1384   fi
1385 ])
1386
1387 HAVE_SOUND=no
1388 if test "${with_sound}" != "no"; then
1389   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1390   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1391     have_sound_header=yes, [], [
1392     #ifdef __MINGW32__
1393     #define WIN32_LEAN_AND_MEAN
1394     #include <windows.h>
1395     #endif
1396     ])
1397   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1398     AC_MSG_ERROR([OSS sound support requested but not found.])
1399
1400   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1401     # Emulation library used on NetBSD.
1402     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1403     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1404       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1405     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1406     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1407   fi
1408   AC_SUBST(LIBSOUND)
1409
1410   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1411     ALSA_REQUIRED=1.0.0
1412     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1413     PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1414     if test $HAVE_ALSA = yes; then
1415       SAVE_CFLAGS="$CFLAGS"
1416       SAVE_LIBS="$LIBS"
1417       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1418       LIBS="$ALSA_LIBS $LIBS"
1419       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1420                       emacs_alsa_normal=yes,
1421                     emacs_alsa_normal=no)
1422       if test "$emacs_alsa_normal" != yes; then
1423         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1424                        [[snd_lib_error_set_handler (0);]])],
1425                        emacs_alsa_subdir=yes,
1426                      emacs_alsa_subdir=no)
1427         if test "$emacs_alsa_subdir" != yes; then
1428           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1429         fi
1430         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1431       fi
1432
1433       CFLAGS="$SAVE_CFLAGS"
1434       LIBS="$SAVE_LIBS"
1435       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1436       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1437       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1438     elif test "${with_sound}" = "alsa"; then
1439       AC_MSG_ERROR([ALSA sound support requested but not found.])
1440     fi
1441   fi                            dnl with_sound = alsa|yes
1442
1443   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1444   dnl compiles only on the specified platforms.  For others, it
1445   dnl probably doesn't make sense to try.
1446   dnl FIXME So surely we should bypass this whole section if not using
1447   dnl one of these platforms?
1448   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1449      case "$opsys" in
1450        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1451        dnl Adjust the --with-sound help text if you change this.
1452        gnu-linux|freebsd|netbsd|mingw32)
1453          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1454          HAVE_SOUND=yes
1455          ;;
1456      esac
1457   fi
1458
1459   AC_SUBST(CFLAGS_SOUND)
1460 fi
1461
1462 dnl checks for header files
1463 AC_CHECK_HEADERS_ONCE(
1464   sys/systeminfo.h
1465   coff.h pty.h
1466   sys/resource.h
1467   sys/utsname.h pwd.h utmp.h util.h)
1468
1469 AC_MSG_CHECKING(if personality LINUX32 can be set)
1470 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1471                emacs_cv_personality_linux32=yes,
1472                emacs_cv_personality_linux32=no)
1473 AC_MSG_RESULT($emacs_cv_personality_linux32)
1474
1475 if test $emacs_cv_personality_linux32 = yes; then
1476   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1477             [Define to 1 if personality LINUX32 can be set.])
1478 fi
1479
1480 dnl On Solaris 8 there's a compilation warning for term.h because
1481 dnl it doesn't define `bool'.
1482 AC_CHECK_HEADERS(term.h, , , -)
1483 AC_HEADER_TIME
1484 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1485                                       ]])
1486 if test $ac_cv_have_decl_sys_siglist != yes; then
1487   # For Tru64, at least:
1488   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1489                                           ]])
1490 fi
1491 AC_HEADER_SYS_WAIT
1492
1493 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1494 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1495 #if HAVE_SYS_SOCKET_H
1496 #include <sys/socket.h>
1497 #endif])
1498 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1499 #if HAVE_SYS_SOCKET_H
1500 #include <sys/socket.h>
1501 #endif])
1502 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1503 #if HAVE_SYS_SOCKET_H
1504 #include <sys/socket.h>
1505 #endif])
1506
1507 dnl checks for structure members
1508 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1509                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1510                   struct ifreq.ifr_addr,
1511                   struct ifreq.ifr_addr.sa_len], , ,
1512                  [AC_INCLUDES_DEFAULT
1513 #if HAVE_SYS_SOCKET_H
1514 #include <sys/socket.h>
1515 #endif
1516 #if HAVE_NET_IF_H
1517 #include <net/if.h>
1518 #endif])
1519
1520 dnl Check for endianness.
1521 dnl AC_C_BIGENDIAN is done by gnulib.
1522
1523 dnl check for Make feature
1524 dnl AC_PROG_MAKE_SET is done by Automake.
1525
1526 DEPFLAGS=
1527 MKDEPDIR=":"
1528 deps_frag=deps.mk
1529 dnl check for GNU Make if we have GCC and autodepend is on.
1530 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1531    AC_MSG_CHECKING([whether we are using GNU Make])
1532    HAVE_GNU_MAKE=no
1533    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1534    if test "x$testval" != x; then
1535       HAVE_GNU_MAKE=yes
1536    else
1537       ac_enable_autodepend=no
1538    fi
1539    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1540    if test $HAVE_GNU_MAKE = yes; then
1541       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1542       SAVE_CFLAGS="$CFLAGS"
1543       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1544       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1545       CFLAGS="$SAVE_CFLAGS"
1546       test -f deps.d || ac_enable_autodepend=no
1547       rm -rf deps.d
1548       AC_MSG_RESULT([$ac_enable_autodepend])
1549    fi
1550    if test $ac_enable_autodepend = yes; then
1551       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1552       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1553       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1554       deps_frag=autodeps.mk
1555    fi
1556 fi
1557 deps_frag=$srcdir/src/$deps_frag
1558 AC_SUBST(MKDEPDIR)
1559 AC_SUBST(DEPFLAGS)
1560 AC_SUBST_FILE(deps_frag)
1561
1562
1563 lisp_frag=$srcdir/src/lisp.mk
1564 AC_SUBST_FILE(lisp_frag)
1565
1566
1567 dnl checks for operating system services
1568 AC_SYS_LONG_FILE_NAMES
1569
1570 #### Choose a window system.
1571
1572 ## We leave window_system equal to none if
1573 ## we end up building without one.  Any new window system should
1574 ## set window_system to an appropriate value and add objects to
1575 ## window-system-specific substs.
1576
1577 window_system=none
1578 AC_PATH_X
1579 if test "$no_x" != yes; then
1580   window_system=x11
1581 fi
1582
1583 LD_SWITCH_X_SITE_RPATH=
1584 if test "${x_libraries}" != NONE; then
1585   if test -n "${x_libraries}"; then
1586     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1587     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1588   fi
1589   x_default_search_path=""
1590   x_search_path=${x_libraries}
1591   if test -z "${x_search_path}"; then
1592     x_search_path=/usr/lib
1593   fi
1594   for x_library in `echo ${x_search_path}: | \
1595                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1596     x_search_path="\
1597 ${x_library}/X11/%L/%T/%N%C%S:\
1598 ${x_library}/X11/%l/%T/%N%C%S:\
1599 ${x_library}/X11/%T/%N%C%S:\
1600 ${x_library}/X11/%L/%T/%N%S:\
1601 ${x_library}/X11/%l/%T/%N%S:\
1602 ${x_library}/X11/%T/%N%S"
1603     if test x"${x_default_search_path}" = x; then
1604       x_default_search_path=${x_search_path}
1605     else
1606       x_default_search_path="${x_search_path}:${x_default_search_path}"
1607     fi
1608   done
1609 fi
1610 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1611
1612 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1613   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1614 fi
1615
1616 if test x"${x_includes}" = x; then
1617   bitmapdir=/usr/include/X11/bitmaps
1618 else
1619   # accumulate include directories that have X11 bitmap subdirectories
1620   bmd_acc="dummyval"
1621   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1622     if test -d "${bmd}/X11/bitmaps"; then
1623       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1624     fi
1625     if test -d "${bmd}/bitmaps"; then
1626       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1627     fi
1628   done
1629   if test ${bmd_acc} != "dummyval"; then
1630     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1631   fi
1632 fi
1633
1634 HAVE_NS=no
1635 NS_IMPL_COCOA=no
1636 NS_IMPL_GNUSTEP=no
1637 tmp_CPPFLAGS="$CPPFLAGS"
1638 tmp_CFLAGS="$CFLAGS"
1639 CPPFLAGS="$CPPFLAGS -x objective-c"
1640 CFLAGS="$CFLAGS -x objective-c"
1641 GNU_OBJC_CFLAGS=
1642 LIBS_GNUSTEP=
1643 if test "${with_ns}" != no; then
1644   if test "${opsys}" = darwin; then
1645      NS_IMPL_COCOA=yes
1646      ns_appdir=`pwd`/nextstep/Emacs.app
1647      ns_appbindir=${ns_appdir}/Contents/MacOS
1648      ns_appresdir=${ns_appdir}/Contents/Resources
1649      ns_appsrc=Cocoa/Emacs.base
1650   elif test -f $GNUSTEP_CONFIG_FILE; then
1651      NS_IMPL_GNUSTEP=yes
1652      ns_appdir=`pwd`/nextstep/Emacs.app
1653      ns_appbindir=${ns_appdir}
1654      ns_appresdir=${ns_appdir}/Resources
1655      ns_appsrc=GNUstep/Emacs.base
1656      dnl FIXME sourcing this several times in subshells seems inefficient.
1657      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1658      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1659      dnl I seemed to need these as well with GNUstep-startup 0.25.
1660      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1661      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1662      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1663        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1664      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1665        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1666      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1667      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1668      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1669      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1670      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1671      dnl If they had chosen to either define it or not, we could have
1672      dnl just used AC_CHECK_DECL here.
1673      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1674        emacs_cv_objc_exceptions,
1675 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1676 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1677 1;
1678 #else
1679 fail;
1680 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1681      if test $emacs_cv_objc_exceptions = yes; then
1682        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1683        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1684          [Define if GNUstep uses ObjC exceptions.])
1685        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1686      fi
1687   fi
1688
1689   dnl This is only used while we test the NS headers, it gets reset below.
1690   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1691
1692   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1693                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1694   files are missing or cannot be compiled.])])
1695
1696   macfont_file=""
1697   if test "${NS_IMPL_COCOA}" = "yes"; then
1698     AC_MSG_CHECKING([for OSX 10.4 or newer])
1699     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1700                                      [
1701 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1702 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1703  ; /* OK */
1704 #else
1705 #error "OSX 10.4 or newer required"
1706 #endif
1707 #endif
1708                     ])],
1709                     ns_osx_have_104=yes,
1710                     ns_osx_have_104=no)
1711     AC_MSG_RESULT([$ns_osx_have_104])
1712
1713     if test $ns_osx_have_104 = no; then
1714        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1715     fi
1716     AC_MSG_CHECKING([for OSX 10.5 or newer])
1717     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1718                                      [
1719 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1720 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1721  ; /* OK */
1722 #else
1723 #error "OSX 10.5 not found"
1724 #endif
1725 #endif
1726                     ])],
1727                     ns_osx_have_105=yes,
1728                     ns_osx_have_105=no)
1729     AC_MSG_RESULT([$ns_osx_have_105])
1730     if test $ns_osx_have_105 = yes; then
1731       macfont_file="macfont.o"
1732     fi
1733   fi
1734   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1735                                      [NSInteger i;])],
1736                     ns_have_nsinteger=yes,
1737                     ns_have_nsinteger=no)
1738   if test $ns_have_nsinteger = yes; then
1739     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1740   fi
1741 fi
1742
1743 AC_SUBST(LIBS_GNUSTEP)
1744
1745 INSTALL_ARCH_INDEP_EXTRA=install-etc
1746 ns_self_contained=no
1747 NS_OBJ=
1748 NS_OBJC_OBJ=
1749 if test "${HAVE_NS}" = yes; then
1750   if test "$with_toolkit_scroll_bars" = "no"; then
1751     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1752   fi
1753
1754   window_system=nextstep
1755   # set up packaging dirs
1756   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1757      ns_self_contained=yes
1758      prefix=${ns_appresdir}
1759      exec_prefix=${ns_appbindir}
1760      dnl This one isn't really used, only archlibdir is.
1761      libexecdir="\${ns_appbindir}/libexec"
1762      archlibdir="\${ns_appbindir}/libexec"
1763      etcdocdir="\${ns_appresdir}/etc"
1764      etcdir="\${ns_appresdir}/etc"
1765      dnl FIXME maybe set datarootdir instead.
1766      dnl That would also get applications, icons, man.
1767      infodir="\${ns_appresdir}/info"
1768      mandir="\${ns_appresdir}/man"
1769      lispdir="\${ns_appresdir}/lisp"
1770      INSTALL_ARCH_INDEP_EXTRA=
1771   fi
1772
1773   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1774 fi
1775 CFLAGS="$tmp_CFLAGS"
1776 CPPFLAGS="$tmp_CPPFLAGS"
1777 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1778 AC_SUBST(ns_self_contained)
1779 AC_SUBST(NS_OBJ)
1780 AC_SUBST(NS_OBJC_OBJ)
1781
1782 HAVE_W32=no
1783 W32_OBJ=
1784 W32_LIBS=
1785 EMACSRES=
1786 CLIENTRES=
1787 CLIENTW=
1788 W32_RES_LINK=
1789 EMACS_MANIFEST=
1790 UPDATE_MANIFEST=
1791 if test "${with_w32}" != no; then
1792   case "${opsys}" in
1793     cygwin)
1794       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1795              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1796                    cannot be found.])])
1797     ;;
1798     mingw32)
1799     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1800     ;;
1801     *)
1802       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1803     ;;
1804   esac
1805 fi
1806
1807 if test "${opsys}" = "mingw32"; then
1808   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1809   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1810      #include <windows.h>
1811      #include <usp10.h>]],
1812    [[PIMAGE_NT_HEADERS pHeader;
1813      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1814    [emacs_cv_w32api=yes
1815     HAVE_W32=yes],
1816    emacs_cv_w32api=no)
1817   AC_MSG_RESULT($emacs_cv_w32api)
1818   if test "${emacs_cv_w32api}" = "no"; then
1819     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1820   fi
1821 fi
1822
1823 FIRSTFILE_OBJ=
1824 NTDIR=
1825 LIBS_ECLIENT=
1826 LIB_WSOCK32=
1827 NTLIB=
1828 CM_OBJ="cm.o"
1829 XARGS_LIMIT=
1830 if test "${HAVE_W32}" = "yes"; then
1831   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1832   AC_CHECK_TOOL(WINDRES, [windres],
1833                 [AC_MSG_ERROR([No resource compiler found.])])
1834   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1835   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1836   EMACSRES="emacs.res"
1837   case "$canonical" in
1838     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1839     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1840   esac
1841   UPDATE_MANIFEST=update-game-score.exe.manifest
1842   if test "${opsys}" = "cygwin"; then
1843     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1844     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1845     # Tell the linker that emacs.res is an object (which we compile from
1846     # the rc file), not a linker script.
1847     W32_RES_LINK="-Wl,emacs.res"
1848   else
1849     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1850     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1851     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1852     W32_RES_LINK="\$(EMACSRES)"
1853     CLIENTRES="emacsclient.res"
1854     CLIENTW="emacsclientw\$(EXEEXT)"
1855     FIRSTFILE_OBJ=firstfile.o
1856     NTDIR=nt
1857     CM_OBJ=
1858     LIBS_ECLIENT="-lcomctl32"
1859     LIB_WSOCK32="-lwsock32"
1860     NTLIB="ntlib.$ac_objext"
1861     XARGS_LIMIT="-s 10000"
1862   fi
1863 fi
1864 AC_SUBST(W32_OBJ)
1865 AC_SUBST(W32_LIBS)
1866 AC_SUBST(EMACSRES)
1867 AC_SUBST(EMACS_MANIFEST)
1868 AC_SUBST(UPDATE_MANIFEST)
1869 AC_SUBST(CLIENTRES)
1870 AC_SUBST(CLIENTW)
1871 AC_SUBST(W32_RES_LINK)
1872 AC_SUBST(FIRSTFILE_OBJ)
1873 AC_SUBST(NTDIR)
1874 AC_SUBST(CM_OBJ)
1875 AC_SUBST(LIBS_ECLIENT)
1876 AC_SUBST(LIB_WSOCK32)
1877 AC_SUBST(NTLIB)
1878 AC_SUBST(XARGS_LIMIT)
1879
1880 if test "${HAVE_W32}" = "yes"; then
1881   window_system=w32
1882   with_xft=no
1883 fi
1884
1885 ## $window_system is now set to the window system we will
1886 ## ultimately use.
1887
1888 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1889    # Too many warnings for now.
1890    nw=
1891    nw="$nw -Wsuggest-attribute=const"
1892    nw="$nw -Wsuggest-attribute=noreturn"
1893    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1894
1895    gl_WARN_ADD([-Wno-unused-variable])
1896    gl_WARN_ADD([-Wno-unused-but-set-variable])
1897    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1898 fi
1899
1900 term_header=
1901 HAVE_X_WINDOWS=no
1902 HAVE_X11=no
1903 USE_X_TOOLKIT=none
1904
1905 case "${window_system}" in
1906   x11 )
1907     HAVE_X_WINDOWS=yes
1908     HAVE_X11=yes
1909     term_header=xterm.h
1910     case "${with_x_toolkit}" in
1911       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1912       motif ) USE_X_TOOLKIT=MOTIF ;;
1913       gtk ) with_gtk=yes
1914             term_header=gtkutil.h
1915 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1916 dnl USE_X_TOOLKIT is set.
1917             USE_X_TOOLKIT=none ;;
1918       gtk2 ) with_gtk2=yes
1919              term_header=gtkutil.h
1920              USE_X_TOOLKIT=none ;;
1921       gtk3 ) with_gtk3=yes
1922              term_header=gtkutil.h
1923              USE_X_TOOLKIT=none ;;
1924       no ) USE_X_TOOLKIT=none ;;
1925 dnl If user did not say whether to use a toolkit, make this decision later:
1926 dnl use the toolkit if we have gtk, or X11R5 or newer.
1927       * ) USE_X_TOOLKIT=maybe ;;
1928     esac
1929   ;;
1930   nextstep )
1931     term_header=nsterm.h
1932   ;;
1933   w32 )
1934     term_header=w32term.h
1935   ;;
1936 esac
1937
1938 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1939    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1940    if test "$HAVE_XSERVER" = true ||
1941       test -n "$DISPLAY" ||
1942       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1943         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1944 were found.  You should install the relevant development files for X
1945 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1946 sure you have development files for image handling, i.e.
1947 tiff, gif, jpeg, png and xpm.
1948 If you are sure you want Emacs compiled without X window support, pass
1949   --without-x
1950 to configure.])
1951    fi
1952 fi
1953
1954 # Does the opsystem file prohibit the use of the GNU malloc?
1955 # Assume not, until told otherwise.
1956 GNU_MALLOC=yes
1957
1958 AC_CACHE_CHECK(
1959   [whether malloc is Doug Lea style],
1960   [emacs_cv_var_doug_lea_malloc],
1961   [emacs_cv_var_doug_lea_malloc=no
1962    dnl Hooks do not work with address sanitization.
1963    if test "$emacs_cv_sanitize_address" != yes; then
1964      AC_LINK_IFELSE(
1965        [AC_LANG_PROGRAM(
1966           [[#include <malloc.h>
1967             static void hook (void) {}]],
1968           [[malloc_set_state (malloc_get_state ());
1969             __after_morecore_hook = hook;
1970             __malloc_initialize_hook = hook;]])],
1971        [emacs_cv_var_doug_lea_malloc=yes])])
1972    fi
1973 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1974
1975 system_malloc=$emacs_cv_sanitize_address
1976 case "$opsys" in
1977   ## darwin ld insists on the use of malloc routines in the System framework.
1978   darwin|sol2-10) system_malloc=yes ;;
1979 esac
1980
1981 GMALLOC_OBJ=
1982 if test "${system_malloc}" = "yes"; then
1983   AC_DEFINE([SYSTEM_MALLOC], 1,
1984     [Define to 1 to use the system memory allocator, even if it is not
1985      Doug Lea style.])
1986   GNU_MALLOC=no
1987   GNU_MALLOC_reason="
1988     (The GNU allocators don't work with this system configuration.)"
1989   VMLIMIT_OBJ=
1990 else
1991   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1992   VMLIMIT_OBJ=vm-limit.o
1993
1994   AC_CHECK_HEADERS([sys/vlimit.h])
1995   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1996     [AC_LINK_IFELSE(
1997        [AC_LANG_PROGRAM(
1998          [[extern char data_start[]; char ch;]],
1999          [[return data_start < &ch;]])],
2000        [emacs_cv_data_start=yes],
2001        [emacs_cv_data_start=no])])
2002   if test $emacs_cv_data_start = yes; then
2003     AC_DEFINE([HAVE_DATA_START], 1,
2004       [Define to 1 if data_start is the address of the start
2005        of the main data segment.])
2006   fi
2007 fi
2008 AC_SUBST(GMALLOC_OBJ)
2009 AC_SUBST(VMLIMIT_OBJ)
2010
2011 if test "$doug_lea_malloc" = "yes" ; then
2012   if test "$GNU_MALLOC" = yes ; then
2013     GNU_MALLOC_reason="
2014       (Using Doug Lea's new malloc from the GNU C Library.)"
2015   fi
2016   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2017     [Define to 1 if the system memory allocator is Doug Lea style,
2018      with malloc hooks and malloc_set_state.])
2019
2020   ## Use mmap directly for allocating larger buffers.
2021   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2022   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2023   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2024   case "$opsys" in
2025     gnu*) REL_ALLOC=no ;;
2026   esac
2027 fi
2028
2029 if test x"${REL_ALLOC}" = x; then
2030   REL_ALLOC=${GNU_MALLOC}
2031 fi
2032
2033 use_mmap_for_buffers=no
2034 case "$opsys" in
2035   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2036 esac
2037
2038 AC_FUNC_MMAP
2039 if test $use_mmap_for_buffers = yes; then
2040   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2041   REL_ALLOC=no
2042 fi
2043
2044 LIBS="$LIBS_SYSTEM $LIBS"
2045
2046 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
2047 AC_CHECK_LIB(dnet, dnet_ntoa)
2048 dnl This causes -lresolv to get used in subsequent tests,
2049 dnl which causes failures on some systems such as HPUX 9.
2050 dnl AC_CHECK_LIB(resolv, gethostbyname)
2051
2052 dnl FIXME replace main with a function we actually want from this library.
2053 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2054
2055 dnl Check if pthreads is available.
2056 LIB_PTHREAD=
2057 AC_CHECK_HEADERS_ONCE(pthread.h)
2058 if test "$ac_cv_header_pthread_h"; then
2059   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2060   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2061   dnl testing for pthread_self if Emacs uses gmalloc.c.
2062   if test "$GMALLOC_OBJ" = gmalloc.o; then
2063     emacs_pthread_function=pthread_atfork
2064   else
2065     emacs_pthread_function=pthread_self
2066   fi
2067   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
2068 fi
2069 if test "$HAVE_PTHREAD" = yes; then
2070   case "${canonical}" in
2071     *-hpux*) ;;
2072     *) LIB_PTHREAD="-lpthread"
2073        LIBS="$LIB_PTHREAD $LIBS" ;;
2074   esac
2075   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
2076 fi
2077 AC_SUBST([LIB_PTHREAD])
2078
2079 AC_CHECK_LIB(pthreads, cma_open)
2080
2081 ## Note: when using cpp in s/aix4.2.h, this definition depended on
2082 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
2083 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
2084 ## added to LIBS in configure would never contain the pthreads part,
2085 ## but the value used in Makefiles might.  FIXME?
2086 ##
2087 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
2088 ## be harmless on older versions of X where it happens to exist.
2089 test "$opsys" = "aix4-2" && \
2090   test $ac_cv_lib_pthreads_cma_open = yes && \
2091   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
2092
2093 dnl Check for need for bigtoc support on IBM AIX
2094
2095 case ${host_os} in
2096 aix*)
2097   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2098     case $GCC in
2099     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2100     *) gdb_cv_bigtoc=-bbigtoc ;;
2101     esac
2102
2103     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2104     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2105   ])
2106   ;;
2107 esac
2108
2109 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
2110 # used for the tests that follow.  We set them back to REAL_CFLAGS and
2111 # REAL_CPPFLAGS later on.
2112
2113 REAL_CFLAGS="$CFLAGS"
2114 REAL_CPPFLAGS="$CPPFLAGS"
2115
2116 if test "${HAVE_X11}" = "yes"; then
2117   DEFS="$C_SWITCH_X_SITE $DEFS"
2118   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2119   LIBS="-lX11 $LIBS"
2120   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2121   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2122
2123   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2124   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2125   # but it's more convenient here to set LD_RUN_PATH since this
2126   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2127   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2128     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2129     export LD_RUN_PATH
2130   fi
2131
2132   if test "${opsys}" = "gnu-linux"; then
2133     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2134     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2135      [[XOpenDisplay ("foo");]])],
2136      [xgnu_linux_first_failure=no],
2137      [xgnu_linux_first_failure=yes])
2138     if test "${xgnu_linux_first_failure}" = "yes"; then
2139       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2140       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2141       OLD_CPPFLAGS="$CPPFLAGS"
2142       OLD_LIBS="$LIBS"
2143       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2144       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2145       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2146       LIBS="$LIBS -b i486-linuxaout"
2147       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2148        [[XOpenDisplay ("foo");]])],
2149        [xgnu_linux_second_failure=no],
2150        [xgnu_linux_second_failure=yes])
2151       if test "${xgnu_linux_second_failure}" = "yes"; then
2152         # If we get the same failure with -b, there is no use adding -b.
2153         # So take it out.  This plays safe.
2154         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2155         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2156         CPPFLAGS="$OLD_CPPFLAGS"
2157         LIBS="$OLD_LIBS"
2158         AC_MSG_RESULT(no)
2159       else
2160         AC_MSG_RESULT(yes)
2161       fi
2162     else
2163       AC_MSG_RESULT(no)
2164     fi
2165   fi
2166
2167   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2168   # header files included from there.
2169   AC_MSG_CHECKING(for Xkb)
2170   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2171 #include <X11/XKBlib.h>]],
2172         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2173         emacs_xkb=yes, emacs_xkb=no)
2174   AC_MSG_RESULT($emacs_xkb)
2175   if test $emacs_xkb = yes; then
2176     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2177   fi
2178
2179   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2180 XScreenNumberOfScreen)
2181 fi
2182
2183 if test "${window_system}" = "x11"; then
2184   AC_MSG_CHECKING(X11 version 6)
2185   AC_CACHE_VAL(emacs_cv_x11_version_6,
2186   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2187 [[#if XlibSpecificationRelease < 6
2188 fail;
2189 #endif
2190 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2191   if test $emacs_cv_x11_version_6 = yes; then
2192     AC_MSG_RESULT(6 or newer)
2193     AC_DEFINE(HAVE_X11R6, 1,
2194               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2195     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2196     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2197     ## XIM support.
2198     case "$opsys" in
2199       sol2-*) : ;;
2200       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2201            [Define if you have usable X11R6-style XIM support.])
2202          ;;
2203     esac
2204   else
2205     AC_MSG_RESULT(before 6)
2206   fi
2207 fi
2208
2209
2210 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2211 HAVE_RSVG=no
2212 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2213   if test "${with_rsvg}" != "no"; then
2214     RSVG_REQUIRED=2.11.0
2215     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2216
2217     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2218     AC_SUBST(RSVG_CFLAGS)
2219     AC_SUBST(RSVG_LIBS)
2220
2221     if test $HAVE_RSVG = yes; then
2222       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2223       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2224       # Windows loads librsvg dynamically
2225       if test "${opsys}" = "mingw32"; then
2226         RSVG_LIBS=
2227       fi
2228       LIBS="$RSVG_LIBS $LIBS"
2229     fi
2230   fi
2231 fi
2232
2233 HAVE_IMAGEMAGICK=no
2234 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2235   if test "${with_imagemagick}" != "no"; then
2236     ## 6.2.8 is the earliest version known to work, but earlier versions
2237     ## might work - let us know if you find one.
2238     ## 6.0.7 does not work.  See bug#7955.
2239     ## 6.8.2 makes Emacs crash; see Bug#13867.
2240     IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2"
2241     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2242     AC_SUBST(IMAGEMAGICK_CFLAGS)
2243     AC_SUBST(IMAGEMAGICK_LIBS)
2244
2245     if test $HAVE_IMAGEMAGICK = yes; then
2246       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2247       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2248       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2249       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2250     fi
2251   fi
2252 fi
2253
2254
2255 HAVE_GTK=no
2256 GTK_OBJ=
2257 gtk_term_header=$term_header
2258 check_gtk2=no
2259 gtk3_pkg_errors=
2260 if test "${opsys}" != "mingw32"; then
2261   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2262     GLIB_REQUIRED=2.28
2263     GTK_REQUIRED=3.0
2264     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2265
2266     dnl Checks for libraries.
2267     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2268     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2269        AC_MSG_ERROR($GTK_PKG_ERRORS)
2270     fi
2271     if test "$pkg_check_gtk" = "yes"; then
2272        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2273        GTK_OBJ=emacsgtkfixed.o
2274        gtk_term_header=gtkutil.h
2275        USE_GTK_TOOLKIT="GTK3"
2276        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2277          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2278            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2279          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2280            [Define to 1 to disable Glib deprecation warnings.])
2281        fi
2282     else
2283        check_gtk2=yes
2284        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2285     fi
2286   fi
2287
2288   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2289     GLIB_REQUIRED=2.10
2290     GTK_REQUIRED=2.10
2291     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2292
2293     dnl Checks for libraries.
2294     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2295     if test "$pkg_check_gtk" = "no" &&
2296        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2297     then
2298       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2299     fi
2300     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2301   fi
2302 fi
2303
2304 if test x"$pkg_check_gtk" = xyes; then
2305
2306   AC_SUBST(GTK_LIBS)
2307   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2308   CFLAGS="$CFLAGS $GTK_CFLAGS"
2309   LIBS="$GTK_LIBS $LIBS"
2310   dnl Try to compile a simple GTK program.
2311   AC_MSG_CHECKING([whether GTK compiles])
2312   GTK_COMPILES=no
2313   AC_LINK_IFELSE(
2314     [AC_LANG_PROGRAM(
2315        [[/* Check the Gtk and Glib APIs.  */
2316          #include <gtk/gtk.h>
2317          #include <glib-object.h>
2318          static void
2319          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2320          {}
2321        ]],
2322        [[
2323          GtkSettings *gs = 0;
2324          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2325             strict C prohibits this.  Use gtk_main_iteration to test that the
2326             libraries are there.  */
2327          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2328                                     0, 0, 0, G_CALLBACK (callback), 0))
2329            gtk_main_iteration ();
2330        ]])],
2331     [GTK_COMPILES=yes])
2332   AC_MSG_RESULT([$GTK_COMPILES])
2333   if test "${GTK_COMPILES}" != "yes"; then
2334     GTK_OBJ=
2335     if test "$USE_X_TOOLKIT" != "maybe"; then
2336       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2337     fi
2338   else
2339     HAVE_GTK=yes
2340     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2341     GTK_OBJ="gtkutil.o $GTK_OBJ"
2342     term_header=$gtk_term_header
2343     USE_X_TOOLKIT=none
2344     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2345       :
2346     else
2347       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2348        closing open displays.  This is no problem if you just use
2349        one display, but if you use more than one and close one of them
2350        Emacs may crash.]])
2351       sleep 3
2352     fi
2353   fi
2354
2355 fi
2356 AC_SUBST(GTK_OBJ)
2357
2358
2359 if test "${HAVE_GTK}" = "yes"; then
2360
2361   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2362   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2363   if test "$with_toolkit_scroll_bars" != no; then
2364     with_toolkit_scroll_bars=yes
2365   fi
2366
2367   dnl  Check if we have the old file selection dialog declared and
2368   dnl  in the link library.  In 2.x it may be in the library,
2369   dnl  but not declared if deprecated featured has been selected out.
2370   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2371   HAVE_GTK_FILE_SELECTION=no
2372   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2373                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2374 #include <gtk/gtk.h>])
2375   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2376     AC_CHECK_FUNCS(gtk_file_selection_new)
2377   fi
2378
2379   dnl Same as above for gtk_handle_box.
2380   HAVE_GTK_HANDLE_BOX=no
2381   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2382                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2383 #include <gtk/gtk.h>])
2384   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2385     AC_CHECK_FUNCS(gtk_handle_box_new)
2386   fi
2387
2388   dnl Same as above for gtk_tearoff_menu_item.
2389   HAVE_GTK_TEAROFF_MENU_ITEM=no
2390   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2391                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2392 #include <gtk/gtk.h>])
2393   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2394     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2395   fi
2396
2397   dnl Check for functions introduced in 2.14 and later.
2398   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2399                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2400                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2401                  gtk_orientable_set_orientation \
2402                  gtk_window_set_has_resize_grip)
2403
2404  term_header=gtkutil.h
2405 fi
2406
2407 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2408 dnl other platforms.
2409 HAVE_DBUS=no
2410 DBUS_OBJ=
2411 if test "${with_dbus}" = "yes"; then
2412    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2413    if test "$HAVE_DBUS" = yes; then
2414      LIBS="$LIBS $DBUS_LIBS"
2415      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2416      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2417      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2418      dnl D-Bus 1.5.12.
2419      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2420                     dbus_type_is_valid \
2421                     dbus_validate_bus_name \
2422                     dbus_validate_path \
2423                     dbus_validate_interface \
2424                     dbus_validate_member)
2425      DBUS_OBJ=dbusbind.o
2426    fi
2427 fi
2428 AC_SUBST(DBUS_OBJ)
2429
2430 dnl GSettings has been tested under GNU/Linux only.
2431 HAVE_GSETTINGS=no
2432 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2433    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2434    if test "$HAVE_GSETTINGS" = "yes"; then
2435       AC_MSG_CHECKING([whether GSettings is in gio])
2436       GSETTINGS_COMPILES=no
2437       AC_LINK_IFELSE(
2438          [AC_LANG_PROGRAM(
2439              [[/* Check that gsettings really is present.  */
2440              #include <glib-object.h>
2441              #include <gio/gio.h>
2442              ]],
2443              [[
2444                GSettings *settings;
2445                GVariant *val = g_settings_get_value (settings, "");
2446              ]])],
2447          [GSETTINGS_COMPILES=yes])
2448       AC_MSG_RESULT([$GSETTINGS_COMPILES])
2449
2450       if test "$$GSETTINGS_COMPILES" = "yes"; then
2451         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2452         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2453         SETTINGS_LIBS="$GSETTINGS_LIBS"
2454       fi
2455    fi
2456 fi
2457
2458 dnl GConf has been tested under GNU/Linux only.
2459 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2460 HAVE_GCONF=no
2461 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2462    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2463    if test "$HAVE_GCONF" = yes; then
2464       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2465       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2466       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2467       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2468    fi
2469 fi
2470
2471 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2472     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2473     if test "$HAVE_GOBJECT" = "yes"; then
2474        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2475        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2476     fi
2477     SAVE_CFLAGS="$CFLAGS"
2478     SAVE_LIBS="$LIBS"
2479     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2480     LIBS="$SETTINGS_LIBS $LIBS"
2481     CFLAGS="$SAVE_CFLAGS"
2482     LIBS="$SAVE_LIBS"
2483 fi
2484 AC_SUBST(SETTINGS_CFLAGS)
2485 AC_SUBST(SETTINGS_LIBS)
2486
2487
2488 dnl SELinux is available for GNU/Linux only.
2489 HAVE_LIBSELINUX=no
2490 LIBSELINUX_LIBS=
2491 if test "${with_selinux}" = "yes"; then
2492    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2493    if test "$HAVE_LIBSELINUX" = yes; then
2494       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2495       LIBSELINUX_LIBS=-lselinux
2496    fi
2497 fi
2498 AC_SUBST(LIBSELINUX_LIBS)
2499
2500 HAVE_GNUTLS=no
2501 HAVE_GNUTLS3=no
2502 if test "${with_gnutls}" = "yes" ; then
2503   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0], HAVE_GNUTLS3=yes, HAVE_GNUTLS3=no)
2504   if test "${HAVE_GNUTLS3}" = "yes"; then
2505     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2506     HAVE_GNUTLS="yes"
2507   else
2508     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2509   fi
2510   if test "${HAVE_GNUTLS}" = "yes"; then
2511     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2512   fi
2513
2514   # Windows loads GnuTLS dynamically
2515   if test "${opsys}" = "mingw32"; then
2516     LIBGNUTLS_LIBS=
2517   else
2518     CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2519     LIBS="$LIBGNUTLS_LIBS $LIBS"
2520   fi
2521 fi
2522
2523 AC_SUBST(LIBGNUTLS_LIBS)
2524 AC_SUBST(LIBGNUTLS_CFLAGS)
2525
2526 NOTIFY_OBJ=
2527 NOTIFY_SUMMARY=no
2528
2529 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2530 dnl a particular library.  This doesn't make much sense?
2531 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2532   with_file_notification=no
2533 fi
2534
2535 dnl MS Windows native file monitor is available for mingw32 only.
2536 case $with_file_notification,$opsys in
2537   w32,* | yes,mingw32)
2538     AC_CHECK_HEADER(windows.h)
2539     if test "$ac_cv_header_windows_h" = yes ; then
2540        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2541        NOTIFY_OBJ=w32notify.o
2542        NOTIFY_SUMMARY="yes (w32)"
2543     fi ;;
2544 esac
2545
2546 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2547 dnl has been added in glib 2.24.  It has been tested under
2548 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2549 dnl only sense when glib has been compiled with inotify support.  How
2550 dnl to check?
2551 case $with_file_notification,$NOTIFY_OBJ in
2552   gfile, | yes,)
2553     PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2554     if test "$HAVE_GFILENOTIFY" = "yes"; then
2555        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2556        NOTIFY_OBJ=gfilenotify.o
2557        NOTIFY_SUMMARY="yes -lgio (gfile)"
2558     fi ;;
2559 esac
2560
2561 dnl inotify is only available on GNU/Linux.
2562 case $with_file_notification,$NOTIFY_OBJ in
2563   inotify, | yes,)
2564     AC_CHECK_HEADER(sys/inotify.h)
2565     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2566         AC_CHECK_FUNC(inotify_init1)
2567         if test "$ac_cv_func_inotify_init1" = yes; then
2568           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2569           NOTIFY_OBJ=inotify.o
2570           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2571        fi
2572     fi ;;
2573 esac
2574
2575 case $with_file_notification,$NOTIFY_OBJ in
2576   yes,* | no,* | *,?*) ;;
2577   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2578 esac
2579
2580 if test -n "$NOTIFY_OBJ"; then
2581    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2582 fi
2583 AC_SUBST(NOTIFY_OBJ)
2584 AC_SUBST(GFILENOTIFY_CFLAGS)
2585 AC_SUBST(GFILENOTIFY_LIBS)
2586
2587 dnl Do not put whitespace before the #include statements below.
2588 dnl Older compilers (eg sunos4 cc) choke on it.
2589 HAVE_XAW3D=no
2590 LUCID_LIBW=
2591 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2592   if test "$with_xaw3d" != no; then
2593     AC_CACHE_VAL(emacs_cv_xaw3d,
2594     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2595 #include <X11/Intrinsic.h>
2596 #include <X11/Xaw3d/Simple.h>]],
2597       [[]])],
2598       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2599                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2600       emacs_cv_xaw3d=no)])
2601   else
2602     emacs_cv_xaw3d=no
2603   fi
2604   if test $emacs_cv_xaw3d = yes; then
2605     AC_MSG_CHECKING(for xaw3d)
2606     AC_MSG_RESULT([yes; using Lucid toolkit])
2607     USE_X_TOOLKIT=LUCID
2608     HAVE_XAW3D=yes
2609     LUCID_LIBW=-lXaw3d
2610     AC_DEFINE(HAVE_XAW3D, 1,
2611               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2612   else
2613     AC_MSG_CHECKING(for xaw3d)
2614     AC_MSG_RESULT(no)
2615     AC_MSG_CHECKING(for libXaw)
2616     AC_CACHE_VAL(emacs_cv_xaw,
2617     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2618 #include <X11/Intrinsic.h>
2619 #include <X11/Xaw/Simple.h>]],
2620       [[]])],
2621       emacs_cv_xaw=yes,
2622       emacs_cv_xaw=no)])
2623     if test $emacs_cv_xaw = yes; then
2624       AC_MSG_RESULT([yes; using Lucid toolkit])
2625       USE_X_TOOLKIT=LUCID
2626       LUCID_LIBW=-lXaw
2627     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2628       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2629     else
2630       AC_MSG_ERROR([No X toolkit could be found.
2631 If you are sure you want Emacs compiled without an X toolkit, pass
2632   --with-x-toolkit=no
2633 to configure.  Otherwise, install the development libraries for the toolkit
2634 that you want to use (e.g. Gtk+) and re-run configure.])
2635     fi
2636   fi
2637 fi
2638
2639 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2640
2641 LIBXTR6=
2642 if test "${USE_X_TOOLKIT}" != "none"; then
2643   AC_MSG_CHECKING(X11 toolkit version)
2644   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2645   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2646 [[#if XtSpecificationRelease < 6
2647 fail;
2648 #endif
2649 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2650   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2651   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2652     AC_MSG_RESULT(6 or newer)
2653     AC_DEFINE(HAVE_X11XTR6, 1,
2654               [Define to 1 if you have the X11R6 or newer version of Xt.])
2655     LIBXTR6="-lSM -lICE"
2656     case "$opsys" in
2657       ## Use libw.a along with X11R6 Xt.
2658       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2659     esac
2660   else
2661     AC_MSG_RESULT(before 6)
2662   fi
2663
2664 dnl If using toolkit, check whether libXmu.a exists.
2665 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2666   OLDLIBS="$LIBS"
2667   if test x$HAVE_X11XTR6 = xyes; then
2668     LIBS="-lXt -lSM -lICE $LIBS"
2669   else
2670     LIBS="-lXt $LIBS"
2671   fi
2672   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2673   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2674   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2675 fi
2676 AC_SUBST(LIBXTR6)
2677
2678 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2679 dnl Why not just test for libxmu in the normal way?
2680 LIBXMU=-lXmu
2681 case $opsys in
2682   ## These systems don't supply Xmu.
2683   hpux* | aix4-2 )
2684     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2685     ;;
2686   mingw32 )
2687     LIBXMU=
2688     ;;
2689 esac
2690 AC_SUBST(LIBXMU)
2691
2692 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2693 if test "${HAVE_X11}" = "yes"; then
2694   if test "${USE_X_TOOLKIT}" != "none"; then
2695     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2696   fi
2697 fi
2698
2699 LIBXP=
2700 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2701   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2702   if test -d /usr/include/openmotif; then
2703     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2704     emacs_cv_openmotif=yes
2705     case "$canonical" in
2706       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2707       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2708       ;;
2709       *)
2710       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2711     esac
2712   else
2713     emacs_cv_openmotif=no
2714   fi
2715   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2716   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2717     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2718 int x = 5;
2719 #else
2720 Motif version prior to 2.1.
2721 #endif]])],
2722     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2723   if test $emacs_cv_motif_version_2_1 = yes; then
2724     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2725     if test x$emacs_cv_openmotif = xyes; then
2726       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2727     fi
2728   else
2729     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2730     # We put this in CFLAGS temporarily to precede other -I options
2731     # that might be in CFLAGS temporarily.
2732     # We put this in CPPFLAGS where it precedes the other -I options.
2733     OLD_CPPFLAGS=$CPPFLAGS
2734     OLD_CFLAGS=$CFLAGS
2735     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2736     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2737     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2738       [[int x = 5;]])],
2739       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2740     if test $emacs_cv_lesstif = yes; then
2741       # Make sure this -I option remains in CPPFLAGS after it is set
2742       # back to REAL_CPPFLAGS.
2743       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2744       # have those other -I options anyway.  Ultimately, having this
2745       # directory ultimately in CPPFLAGS will be enough.
2746       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2747       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2748     else
2749       CFLAGS=$OLD_CFLAGS
2750       CPPFLAGS=$OLD_CPPFLAGS
2751     fi
2752   fi
2753   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2754     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2755 fi
2756
2757 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2758 dnl using Motif or Xaw3d is available, and unless
2759 dnl --with-toolkit-scroll-bars=no was specified.
2760
2761 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2762             [Define to 1 if we should use toolkit scroll bars.])dnl
2763 USE_TOOLKIT_SCROLL_BARS=no
2764 if test "${with_toolkit_scroll_bars}" != "no"; then
2765   if test "${USE_X_TOOLKIT}" != "none"; then
2766     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2767       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2768       HAVE_XAW3D=no
2769       USE_TOOLKIT_SCROLL_BARS=yes
2770     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2771       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2772       USE_TOOLKIT_SCROLL_BARS=yes
2773     fi
2774   elif test "${HAVE_GTK}" = "yes"; then
2775     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2776     USE_TOOLKIT_SCROLL_BARS=yes
2777   elif test "${HAVE_NS}" = "yes"; then
2778     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2779     USE_TOOLKIT_SCROLL_BARS=yes
2780   elif test "${HAVE_W32}" = "yes"; then
2781     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2782     USE_TOOLKIT_SCROLL_BARS=yes
2783   fi
2784 fi
2785
2786 dnl See if XIM is available.
2787 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2788           #include <X11/Xlib.h>
2789           #include <X11/Xresource.h>]],
2790          [[XIMProc  callback;]])],
2791          [HAVE_XIM=yes
2792          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2793          HAVE_XIM=no)
2794
2795 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2796
2797 if test "${with_xim}" != "no"; then
2798   AC_DEFINE(USE_XIM, 1,
2799             [Define to 1 if we should use XIM, if it is available.])
2800 fi
2801
2802
2803 if test "${HAVE_XIM}" != "no"; then
2804   late_CFLAGS=$CFLAGS
2805   if test "$GCC" = yes; then
2806     CFLAGS="$CFLAGS --pedantic-errors"
2807   fi
2808   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2809 #include <X11/Xlib.h>
2810 #include <X11/Xresource.h>]],
2811 [[Display *display;
2812 XrmDatabase db;
2813 char *res_name;
2814 char *res_class;
2815 XIMProc  callback;
2816 XPointer *client_data;
2817 #ifndef __GNUC__
2818 /* If we're not using GCC, it's probably not XFree86, and this is
2819    probably right, but we can't use something like --pedantic-errors.  */
2820 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2821                                            char*, XIMProc, XPointer*);
2822 #endif
2823 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2824    client_data);]])],
2825     [emacs_cv_arg6_star=yes])
2826   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2827          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2828 either XPointer or XPointer*.])dnl
2829   if test "$emacs_cv_arg6_star" = yes; then
2830     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2831   else
2832     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2833   fi
2834   CFLAGS=$late_CFLAGS
2835 fi
2836
2837 ### Start of font-backend (under any platform) section.
2838 # (nothing here yet -- this is a placeholder)
2839 ### End of font-backend (under any platform) section.
2840
2841 ### Start of font-backend (under X11) section.
2842 if test "${HAVE_X11}" = "yes"; then
2843    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2844
2845    ## Use -lXft if available, unless `--with-xft=no'.
2846    HAVE_XFT=maybe
2847     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2848       with_xft="no";
2849     fi
2850     if test "x${with_xft}" != "xno"; then
2851
2852       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2853       ## Because xftfont.c uses XRenderQueryExtension, we also
2854       ## need to link to -lXrender.
2855       HAVE_XRENDER=no
2856       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2857       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2858         OLD_CPPFLAGS="$CPPFLAGS"
2859         OLD_CFLAGS="$CFLAGS"
2860         OLD_LIBS="$LIBS"
2861         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2862         CFLAGS="$CFLAGS $XFT_CFLAGS"
2863         XFT_LIBS="-lXrender $XFT_LIBS"
2864         LIBS="$XFT_LIBS $LIBS"
2865         AC_CHECK_HEADER(X11/Xft/Xft.h,
2866           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2867           [[#include <X11/X.h>]])
2868
2869         if test "${HAVE_XFT}" = "yes"; then
2870           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2871             AC_SUBST(XFT_LIBS)
2872           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2873         else
2874           CPPFLAGS="$OLD_CPPFLAGS"
2875           CFLAGS="$OLD_CFLAGS"
2876           LIBS="$OLD_LIBS"
2877         fi                        # "${HAVE_XFT}" = "yes"
2878       fi                          # "$HAVE_XFT" != no
2879     fi                            # "x${with_xft}" != "xno"
2880
2881     ## We used to allow building with FreeType and without Xft.
2882     ## However, the ftx font backend driver is not in good shape.
2883     if test "$HAVE_XFT" != "yes"; then
2884        dnl For the "Does Emacs use" message at the end.
2885        HAVE_XFT=no
2886        HAVE_FREETYPE=no
2887     else
2888        dnl Strict linkers fail with
2889        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2890        dnl if -lfreetype is not specified.
2891        dnl The following is needed to set FREETYPE_LIBS.
2892        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2893                          HAVE_FREETYPE=no)
2894
2895        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2896     fi
2897
2898     HAVE_LIBOTF=no
2899     if test "${HAVE_FREETYPE}" = "yes"; then
2900       AC_DEFINE(HAVE_FREETYPE, 1,
2901                 [Define to 1 if using the freetype and fontconfig libraries.])
2902       if test "${with_libotf}" != "no"; then
2903         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2904                           HAVE_LIBOTF=no)
2905         if test "$HAVE_LIBOTF" = "yes"; then
2906           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2907           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2908                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2909                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2910           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2911             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2912                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2913           fi
2914         fi
2915       fi
2916     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2917     dnl Does the new font backend require it, or can it work without it?
2918     fi
2919
2920     HAVE_M17N_FLT=no
2921     if test "${HAVE_LIBOTF}" = yes; then
2922       if test "${with_m17n_flt}" != "no"; then
2923         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2924         if test "$HAVE_M17N_FLT" = "yes"; then
2925           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2926         fi
2927       fi
2928     fi
2929 else
2930     HAVE_XFT=no
2931     HAVE_FREETYPE=no
2932     HAVE_LIBOTF=no
2933     HAVE_M17N_FLT=no
2934 fi
2935
2936 ### End of font-backend (under X11) section.
2937
2938 AC_SUBST(FREETYPE_CFLAGS)
2939 AC_SUBST(FREETYPE_LIBS)
2940 AC_SUBST(FONTCONFIG_CFLAGS)
2941 AC_SUBST(FONTCONFIG_LIBS)
2942 AC_SUBST(LIBOTF_CFLAGS)
2943 AC_SUBST(LIBOTF_LIBS)
2944 AC_SUBST(M17N_FLT_CFLAGS)
2945 AC_SUBST(M17N_FLT_LIBS)
2946
2947 ### Use -lXpm if available, unless `--with-xpm=no'.
2948 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2949 HAVE_XPM=no
2950 LIBXPM=
2951 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2952   if test "${with_xpm}" != "no"; then
2953     SAVE_CPPFLAGS="$CPPFLAGS"
2954     SAVE_LDFLAGS="$LDFLAGS"
2955     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2956     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2957     AC_CHECK_HEADER(X11/xpm.h,
2958       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2959     if test "${HAVE_XPM}" = "yes"; then
2960       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2961       AC_EGREP_CPP(no_return_alloc_pixels,
2962       [#include "X11/xpm.h"
2963 #ifndef XpmReturnAllocPixels
2964 no_return_alloc_pixels
2965 #endif
2966       ], HAVE_XPM=no, HAVE_XPM=yes)
2967
2968       if test "${HAVE_XPM}" = "yes"; then
2969         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2970         AC_MSG_RESULT(yes)
2971       else
2972         AC_MSG_RESULT(no)
2973         CPPFLAGS="$SAVE_CPPFLAGS"
2974         LDFLAGS="$SAVE_LDFLAGS"
2975       fi
2976     fi
2977   fi
2978
2979   if test "${HAVE_XPM}" = "yes"; then
2980     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2981     LIBXPM=-lXpm
2982   fi
2983 fi
2984
2985 if test "${HAVE_X11}" = "yes"; then
2986   if test "${with_xpm}" != "no"; then
2987     AC_CHECK_HEADER(X11/xpm.h,
2988       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2989     if test "${HAVE_XPM}" = "yes"; then
2990       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2991       AC_EGREP_CPP(no_return_alloc_pixels,
2992       [#include "X11/xpm.h"
2993 #ifndef XpmReturnAllocPixels
2994 no_return_alloc_pixels
2995 #endif
2996       ], HAVE_XPM=no, HAVE_XPM=yes)
2997
2998       if test "${HAVE_XPM}" = "yes"; then
2999         AC_MSG_RESULT(yes)
3000       else
3001         AC_MSG_RESULT(no)
3002       fi
3003     fi
3004   fi
3005
3006   if test "${HAVE_XPM}" = "yes"; then
3007     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3008     LIBXPM=-lXpm
3009   fi
3010 fi
3011
3012 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3013 ### slightly different requirements wrt image libraries (it doesn't
3014 ### use -lXpm because it loads the xpm shared library dynamically at
3015 ### run time).
3016 if test "${opsys}" = "mingw32"; then
3017   if test "${with_xpm}" != "no"; then
3018     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3019 #define FOR_MSW 1])
3020   fi
3021
3022   if test "${HAVE_XPM}" = "yes"; then
3023     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3024   fi
3025 fi
3026
3027 AC_SUBST(LIBXPM)
3028
3029 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3030 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3031 HAVE_JPEG=no
3032 LIBJPEG=
3033 if test "${opsys}" = "mingw32"; then
3034   if test "${with_jpeg}" != "no"; then
3035     dnl Checking for jpeglib.h can lose because of a redefinition of
3036     dnl HAVE_STDLIB_H.
3037     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3038   fi
3039   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3040   if test "${HAVE_JPEG}" = "yes"; then
3041     AC_DEFINE(HAVE_JPEG)
3042     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3043         [#include <jpeglib.h>
3044          version=JPEG_LIB_VERSION
3045 ],
3046         [AC_DEFINE(HAVE_JPEG)],
3047         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3048         HAVE_JPEG=no])
3049   fi
3050 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3051   if test "${with_jpeg}" != "no"; then
3052     dnl Checking for jpeglib.h can lose because of a redefinition of
3053     dnl  HAVE_STDLIB_H.
3054     AC_CHECK_HEADER(jerror.h,
3055       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3056   fi
3057
3058   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3059   if test "${HAVE_JPEG}" = "yes"; then
3060     AC_DEFINE(HAVE_JPEG)
3061     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3062         [#include <jpeglib.h>
3063          version=JPEG_LIB_VERSION
3064 ],
3065         [AC_DEFINE(HAVE_JPEG)],
3066         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3067         HAVE_JPEG=no])
3068   fi
3069   if test "${HAVE_JPEG}" = "yes"; then
3070     LIBJPEG=-ljpeg
3071   fi
3072 fi
3073 AC_SUBST(LIBJPEG)
3074
3075 ### Use -lpng if available, unless `--with-png=no'.
3076 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
3077 HAVE_PNG=no
3078 LIBPNG=
3079 if test "${opsys}" = "mingw32"; then
3080   if test "${with_png}" != "no"; then
3081     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
3082   fi
3083   if test "${HAVE_PNG}" = "yes"; then
3084     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3085
3086     AC_CHECK_DECL(png_longjmp,
3087       [],
3088       [AC_DEFINE(PNG_DEPSTRUCT, [],
3089          [Define to empty to suppress deprecation warnings when building
3090           with --enable-gcc-warnings and with libpng versions before 1.5,
3091           which lack png_longjmp.])],
3092       [[#ifdef HAVE_LIBPNG_PNG_H
3093         # include <libpng/png.h>
3094         #else
3095         # include <png.h>
3096         #endif
3097       ]])
3098   fi
3099 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3100   if test "${with_png}" != "no"; then
3101     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3102     # in /usr/include/libpng.
3103     AC_CHECK_HEADERS(png.h libpng/png.h, break)
3104     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
3105       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
3106     fi
3107   fi
3108
3109   if test "${HAVE_PNG}" = "yes"; then
3110     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3111     LIBPNG="-lpng -lz -lm"
3112
3113     AC_CHECK_DECL(png_longjmp,
3114       [],
3115       [AC_DEFINE(PNG_DEPSTRUCT, [],
3116          [Define to empty to suppress deprecation warnings when building
3117           with --enable-gcc-warnings and with libpng versions before 1.5,
3118           which lack png_longjmp.])],
3119       [[#ifdef HAVE_LIBPNG_PNG_H
3120         # include <libpng/png.h>
3121         #else
3122         # include <png.h>
3123         #endif
3124       ]])
3125   fi
3126 fi
3127 AC_SUBST(LIBPNG)
3128
3129 HAVE_ZLIB=no
3130 LIBZ=
3131 if test "${with_zlib}" != "no"; then
3132   OLIBS=$LIBS
3133   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3134   LIBS=$OLIBS
3135   case $ac_cv_search_inflateEnd in
3136     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3137   esac
3138 fi
3139 if test "${HAVE_ZLIB}" = "yes"; then
3140   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3141   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3142   if test "${opsys}" = "mingw32"; then
3143      LIBZ=
3144   fi
3145 fi
3146 AC_SUBST(LIBZ)
3147
3148
3149 ### Use -ltiff if available, unless `--with-tiff=no'.
3150 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3151 HAVE_TIFF=no
3152 LIBTIFF=
3153 if test "${opsys}" = "mingw32"; then
3154   if test "${with_tiff}" != "no"; then
3155     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3156   fi
3157   if test "${HAVE_TIFF}" = "yes"; then
3158     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3159   fi
3160 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3161   if test "${with_tiff}" != "no"; then
3162     AC_CHECK_HEADER(tiffio.h,
3163       [tifflibs="-lz -lm"
3164       # At least one tiff package requires the jpeg library.
3165       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3166       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3167   fi
3168
3169   if test "${HAVE_TIFF}" = "yes"; then
3170     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3171     dnl FIXME -lz -lm, as per libpng?
3172     LIBTIFF=-ltiff
3173   fi
3174 fi
3175 AC_SUBST(LIBTIFF)
3176
3177 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3178 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3179 HAVE_GIF=no
3180 LIBGIF=
3181 if test "${opsys}" = "mingw32"; then
3182   if test "${with_gif}" != "no"; then
3183     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3184   fi
3185   if test "${HAVE_GIF}" = "yes"; then
3186     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3187   fi
3188 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3189         || test "${HAVE_W32}" = "yes"; then
3190   AC_CHECK_HEADER(gif_lib.h,
3191 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3192 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3193     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3194         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3195
3196   if test "$HAVE_GIF" = yes; then
3197     LIBGIF=-lgif
3198   elif test "$HAVE_GIF" = maybe; then
3199 # If gif_lib.h but no libgif, try libungif.
3200     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3201     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3202   fi
3203
3204   if test "${HAVE_GIF}" = "yes"; then
3205     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3206   fi
3207 fi
3208 AC_SUBST(LIBGIF)
3209
3210 dnl Check for required libraries.
3211 if test "${HAVE_X11}" = "yes"; then
3212   MISSING=""
3213   WITH_NO=""
3214   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3215     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3216   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3217     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3218   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3219     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3220   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3221     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3222   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3223     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3224
3225   if test "X${MISSING}" != X; then
3226     AC_MSG_ERROR([The following required libraries were not found:
3227     $MISSING
3228 Maybe some development libraries/packages are missing?
3229 If you don't want to link with them give
3230     $WITH_NO
3231 as options to configure])
3232   fi
3233 fi
3234
3235 ### Use -lgpm if available, unless `--with-gpm=no'.
3236 HAVE_GPM=no
3237 LIBGPM=
3238 if test "${with_gpm}" != "no"; then
3239   AC_CHECK_HEADER(gpm.h,
3240     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3241
3242   if test "${HAVE_GPM}" = "yes"; then
3243     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3244     LIBGPM=-lgpm
3245   fi
3246 fi
3247 AC_SUBST(LIBGPM)
3248
3249 dnl Check for malloc/malloc.h on darwin
3250 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3251
3252 GNUSTEP_CFLAGS=
3253 ### Use NeXTstep API to implement GUI.
3254 if test "${HAVE_NS}" = "yes"; then
3255   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3256   if test "${NS_IMPL_COCOA}" = "yes"; then
3257     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3258   fi
3259   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3260     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3261     # See also .m.o rule in Makefile.in */
3262     # FIXME: are all these flags really needed?  Document here why.  */
3263     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3264     ## Extra CFLAGS applied to src/*.m files.
3265     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3266   fi
3267   OTHER_FILES=ns-app
3268 fi
3269
3270 ### Use session management (-lSM -lICE) if available
3271 HAVE_X_SM=no
3272 LIBXSM=
3273 if test "${HAVE_X11}" = "yes"; then
3274   AC_CHECK_HEADER(X11/SM/SMlib.h,
3275     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3276
3277   if test "${HAVE_X_SM}" = "yes"; then
3278     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3279     LIBXSM="-lSM -lICE"
3280     case "$LIBS" in
3281       *-lSM*) ;;
3282       *)      LIBS="$LIBXSM $LIBS" ;;
3283     esac
3284   fi
3285 fi
3286 AC_SUBST(LIBXSM)
3287
3288 ### Use XRandr (-lXrandr) if available
3289 HAVE_XRANDR=no
3290 if test "${HAVE_X11}" = "yes"; then
3291   XRANDR_REQUIRED=1.2.2
3292   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3293   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3294   if test $HAVE_XRANDR = no; then
3295     # Test old way in case pkg-config doesn't have it (older machines).
3296     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3297       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3298     if test $HAVE_XRANDR = yes; then
3299       XRANDR_LIBS=-lXrandr
3300       AC_SUBST(XRANDR_LIBS)
3301     fi
3302   fi
3303   if test $HAVE_XRANDR = yes; then
3304     SAVE_CFLAGS="$CFLAGS"
3305     SAVE_LIBS="$LIBS"
3306     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3307     LIBS="$XRANDR_LIBS $LIBS"
3308     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3309     CFLAGS="$SAVE_CFLAGS"
3310     LIBS="$SAVE_LIBS"
3311
3312     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3313   fi
3314 fi
3315
3316 ### Use Xinerama (-lXinerama) if available
3317 HAVE_XINERAMA=no
3318 if test "${HAVE_X11}" = "yes"; then
3319   XINERAMA_REQUIRED=1.0.2
3320   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3321   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3322                     HAVE_XINERAMA=no)
3323   if test $HAVE_XINERAMA = no; then
3324     # Test old way in case pkg-config doesn't have it (older machines).
3325     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3326       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3327     if test $HAVE_XINERAMA = yes; then
3328       XINERAMA_LIBS=-lXinerama
3329       AC_SUBST(XINERAMA_LIBS)
3330     fi
3331   fi
3332   if test $HAVE_XINERAMA = yes; then
3333     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3334   fi
3335 fi
3336
3337
3338 ### Use libxml (-lxml2) if available
3339 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3340 HAVE_LIBXML2=no
3341 if test "${with_xml2}" != "no"; then
3342   ### I'm not sure what the version number should be, so I just guessed.
3343   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3344   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3345   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3346     SAVE_CPPFLAGS="$CPPFLAGS"
3347     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3348     AC_CHECK_HEADER(libxml/HTMLparser.h,
3349       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3350                      [#include <libxml/HTMLparser.h>])])
3351     CPPFLAGS="$SAVE_CPPFLAGS"
3352     if test "${HAVE_LIBXML2}" = "yes"; then
3353       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3354       LIBXML2_LIBS="-lxml2"
3355     fi
3356   fi
3357   if test "${HAVE_LIBXML2}" = "yes"; then
3358     if test "${opsys}" != "mingw32"; then
3359       LIBS="$LIBXML2_LIBS $LIBS"
3360       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3361     else
3362       LIBXML2_LIBS=""
3363     fi
3364     if test "${HAVE_LIBXML2}" = "yes"; then
3365       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3366     else
3367       LIBXML2_LIBS=""
3368       LIBXML2_CFLAGS=""
3369     fi
3370   fi
3371 fi
3372 AC_SUBST(LIBXML2_LIBS)
3373 AC_SUBST(LIBXML2_CFLAGS)
3374
3375 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3376 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3377 if test "${opsys}" = "mingw32"; then
3378   emacs_cv_netdb_declares_h_errno=yes
3379 fi
3380 AC_CACHE_CHECK(whether netdb declares h_errno,
3381                emacs_cv_netdb_declares_h_errno,
3382 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3383   [[return h_errno;]])],
3384   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3385 if test $emacs_cv_netdb_declares_h_errno = yes; then
3386   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3387 fi
3388
3389 # sqrt and other floating-point functions such as fmod and frexp
3390 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3391 if test "${opsys}" != "mingw32"; then
3392   AC_CHECK_LIB(m, sqrt)
3393 fi
3394
3395 # Check for mail-locking functions in a "mail" library.  Probably this should
3396 # have the same check as for liblockfile below.
3397 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3398 if test $have_mail = yes; then
3399   LIBS_MAIL=-lmail
3400   LIBS="$LIBS_MAIL $LIBS"
3401   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3402 else
3403   LIBS_MAIL=
3404 fi
3405 dnl Debian, at least:
3406 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3407 if test $have_lockfile = yes; then
3408    LIBS_MAIL=-llockfile
3409    LIBS="$LIBS_MAIL $LIBS"
3410    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3411 else
3412 # If we have the shared liblockfile, assume we must use it for mail
3413 # locking (e.g. Debian).  If we couldn't link against liblockfile
3414 # (no liblockfile.a installed), ensure that we don't need to.
3415   dnl This works for files generally, not just executables.
3416   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3417   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3418                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3419   if test $ac_cv_prog_liblockfile = yes; then
3420     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3421 This probably means that movemail could lose mail.
3422 There may be a `development' package to install containing liblockfile.])
3423   fi
3424 fi
3425 AC_CHECK_HEADERS_ONCE(maillock.h)
3426 AC_SUBST(LIBS_MAIL)
3427
3428 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3429 ## interlock access to the mail spool.  The alternative is a lock file named
3430 ## /usr/spool/mail/$USER.lock.
3431 mail_lock=no
3432 case "$opsys" in
3433   aix4-2) mail_lock="lockf" ;;
3434
3435   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3436
3437   ## On GNU/Linux systems, both methods are used by various mail programs.
3438   ## I assume most people are using newer mailers that have heard of flock.
3439   ## Change this if you need to.
3440   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3441   ## configure gets the right answers, and that means *NOT* using flock.
3442   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3443   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3444   ## Debian maintainer hasn't provided a clean fix for Emacs.
3445   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3446   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3447   ## correct logic.  -- fx
3448   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3449   ## liblockfile is a Free Software replacement for libmail, used on
3450   ## Debian systems and elsewhere. -rfr.
3451   gnu-*)
3452     mail_lock="flock"
3453     if test $have_mail = yes || test $have_lockfile = yes; then
3454       test $ac_cv_header_maillock_h = yes && mail_lock=no
3455     fi
3456     ;;
3457
3458   mingw32)
3459     mail_lock="none-needed" ;;
3460 esac
3461
3462 BLESSMAIL_TARGET=
3463 case "$mail_lock" in
3464   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3465
3466   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3467
3468   none-needed) ;;
3469
3470   *) BLESSMAIL_TARGET="need-blessmail" ;;
3471 esac
3472 AC_SUBST(BLESSMAIL_TARGET)
3473
3474
3475 AC_CHECK_FUNCS(accept4 gethostname \
3476 getrusage get_current_dir_name \
3477 lrand48 \
3478 select getpagesize setlocale \
3479 getrlimit setrlimit shutdown getaddrinfo \
3480 strsignal setitimer \
3481 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3482 gai_strerror getline getdelim sync \
3483 getpwent endpwent getgrent endgrent \
3484 touchlock \
3485 cfmakeraw cfsetspeed copysign __executable_start log2)
3486
3487 dnl No need to check for aligned_alloc and posix_memalign if using
3488 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3489 dnl Darwin as they are incompatible with unexmacosx.c.
3490 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3491   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3492 fi
3493
3494 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3495 ## has a broken `rint' in some library versions including math library
3496 ## version number A.09.05.
3497 ## You can fix the math library by installing patch number PHSS_4630.
3498 ## But we can fix it more reliably for Emacs by just not using rint.
3499 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3500 case $opsys in
3501    hpux*) : ;;
3502    *) AC_CHECK_FUNCS(random rint) ;;
3503 esac
3504
3505 dnl Cannot use AC_CHECK_FUNCS
3506 AC_CACHE_CHECK([for __builtin_unwind_init],
3507                emacs_cv_func___builtin_unwind_init,
3508 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3509                 emacs_cv_func___builtin_unwind_init=yes,
3510                 emacs_cv_func___builtin_unwind_init=no)])
3511 if test $emacs_cv_func___builtin_unwind_init = yes; then
3512   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3513             [Define to 1 if you have the `__builtin_unwind_init' function.])
3514 fi
3515
3516 AC_CHECK_HEADERS_ONCE(sys/un.h)
3517
3518 AC_FUNC_FSEEKO
3519
3520 # UNIX98 PTYs.
3521 AC_CHECK_FUNCS(grantpt)
3522
3523 # PTY-related GNU extensions.
3524 AC_CHECK_FUNCS(getpt posix_openpt)
3525
3526 # Check this now, so that we will NOT find the above functions in ncurses.
3527 # That is because we have not set up to link ncurses in lib-src.
3528 # It's better to believe a function is not available
3529 # than to expect to find it in ncurses.
3530 # Also we need tputs and friends to be able to build at all.
3531 AC_MSG_CHECKING([for library containing tputs])
3532 # Run a test program that contains a call to tputs, a call that is
3533 # never executed.  This tests whether a pre-'main' dynamic linker
3534 # works with the library.  It's too much trouble to actually call
3535 # tputs in the test program, due to portability hassles.  When
3536 # cross-compiling, assume the test program will run if it links.
3537 AC_DEFUN([tputs_link_source], [
3538   AC_LANG_SOURCE(
3539      [[extern void tputs (const char *, int, int (*)(int));
3540        int main (int argc, char **argv)
3541        {
3542           if (argc == 10000)
3543             tputs (argv[0], 0, 0);
3544           return 0;
3545        }]])
3546 ])
3547 if test "${opsys}" = "mingw32"; then
3548   msg='none required'
3549 else
3550   # Maybe curses should be tried earlier?
3551   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3552   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3553     OLIBS=$LIBS
3554     if test -z "$tputs_library"; then
3555       LIBS_TERMCAP=
3556       msg='none required'
3557     else
3558       LIBS_TERMCAP=-l$tputs_library
3559       msg=$LIBS_TERMCAP
3560       LIBS="$LIBS_TERMCAP $LIBS"
3561     fi
3562     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3563       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3564     LIBS=$OLIBS
3565     if test "X$msg" != Xno; then
3566       break
3567     fi
3568   done
3569 fi
3570 AC_MSG_RESULT([$msg])
3571 if test "X$msg" = Xno; then
3572   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3573 The following libraries were tried (in order):
3574   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3575 Please try installing whichever of these libraries is most appropriate
3576 for your system, together with its header files.
3577 For example, a libncurses-dev(el) or similar package.])
3578 fi
3579
3580 ## Use termcap instead of terminfo?
3581 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3582 TERMINFO=yes
3583 ## FIXME?  In the cases below where we unconditionally set
3584 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3585 ## if that was found above to have tputs.
3586 ## Should we use the gnu* logic everywhere?
3587 case "$opsys" in
3588   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3589   ##  The ncurses library has been moved out of the System framework in
3590   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3591   ##  option to use it.
3592   darwin) LIBS_TERMCAP="-lncurses" ;;
3593
3594   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3595
3596   freebsd)
3597     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3598     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3599     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3600 [[#if __FreeBSD_version < 400000
3601 fail;
3602 #endif
3603 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3604
3605     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3606
3607     if test $emacs_cv_freebsd_terminfo = yes; then
3608       LIBS_TERMCAP="-lncurses"
3609     else
3610       TERMINFO=no
3611       LIBS_TERMCAP="-ltermcap"
3612     fi
3613     ;;
3614
3615   mingw32)
3616     TERMINFO=no
3617     LIBS_TERMCAP=
3618     ;;
3619
3620   netbsd)
3621     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3622       TERMINFO=no
3623       LIBS_TERMCAP="-ltermcap"
3624     fi
3625     ;;
3626
3627   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3628
3629   ## hpux: Make sure we get select from libc rather than from libcurses
3630   ##  because libcurses on HPUX 10.10 has a broken version of select.
3631   ##  We used to use -lc -lcurses, but this may be cleaner.
3632   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3633   # set that way, now it uses the default).  Isn't this a contradiction?
3634   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3635
3636 esac
3637
3638 TERMCAP_OBJ=tparam.o
3639 if test $TERMINFO = yes; then
3640   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3641   TERMCAP_OBJ=terminfo.o
3642 fi
3643 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3644   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3645 fi
3646 AC_SUBST(LIBS_TERMCAP)
3647 AC_SUBST(TERMCAP_OBJ)
3648
3649
3650 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3651 # On Darwin, res_init appears not to be useful: see bug#562 and
3652 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3653 resolv=no
3654
3655 if test $opsys != darwin; then
3656
3657   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3658 #include <arpa/nameser.h>
3659 #include <resolv.h>]],
3660     [[return res_init();]])],
3661     have_res_init=yes, have_res_init=no)
3662   if test "$have_res_init" = no; then
3663     OLIBS="$LIBS"
3664     LIBS="$LIBS -lresolv"
3665     AC_MSG_CHECKING(for res_init with -lresolv)
3666     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3667 #include <arpa/nameser.h>
3668 #include <resolv.h>]],
3669       [[return res_init();]])],
3670       have_res_init=yes, have_res_init=no)
3671     AC_MSG_RESULT($have_res_init)
3672     if test "$have_res_init" = yes ; then
3673       resolv=yes
3674     fi
3675     LIBS="$OLIBS"
3676   fi
3677
3678   if test "$have_res_init" = yes; then
3679     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3680   fi
3681 fi                              dnl !darwin
3682
3683 # Do we need the Hesiod library to provide the support routines?
3684 dnl FIXME?  Should we be skipping this on Darwin too?
3685 LIBHESIOD=
3686 if test "$with_hesiod" != no ; then
3687   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3688   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3689      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3690                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3691   if test "$resolv" = yes ; then
3692     RESOLVLIB=-lresolv
3693   else
3694     RESOLVLIB=
3695   fi
3696   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3697         hesiod=yes, :, $RESOLVLIB)])
3698
3699   if test x"$hesiod" = xyes; then
3700     LIBHESIOD=-lhesiod
3701   fi
3702 fi
3703 AC_SUBST(LIBHESIOD)
3704
3705 # Do we need libresolv (due to res_init or Hesiod)?
3706 if test "$resolv" = yes && test $opsys != darwin; then
3707   LIBRESOLV=-lresolv
3708 else
3709   LIBRESOLV=
3710 fi
3711 AC_SUBST(LIBRESOLV)
3712
3713 # These tell us which Kerberos-related libraries to use.
3714 COM_ERRLIB=
3715 CRYPTOLIB=
3716 KRB5LIB=
3717 DESLIB=
3718 KRB4LIB=
3719
3720 if test "${with_kerberos}" != no; then
3721   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3722   if test $have_com_err = yes; then
3723     COM_ERRLIB=-lcom_err
3724     LIBS="$COM_ERRLIB $LIBS"
3725   fi
3726   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3727   if test $have_crypto = yes; then
3728     CRYPTOLIB=-lcrypto
3729     LIBS="$CRYPTOLIB $LIBS"
3730   fi
3731   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3732   if test $have_k5crypto = yes; then
3733     CRYPTOLIB=-lk5crypto
3734     LIBS="$CRYPTOLIB $LIBS"
3735   fi
3736   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3737   if test $have_krb5=yes; then
3738     KRB5LIB=-lkrb5
3739     LIBS="$KRB5LIB $LIBS"
3740   fi
3741   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3742   if test "${with_kerberos5}" = no; then
3743     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3744     if test $have_des425 = yes; then
3745       DESLIB=-ldes425
3746       LIBS="$DESLIB $LIBS"
3747     else
3748       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3749       if test $have_des = yes; then
3750         DESLIB=-ldes
3751         LIBS="$DESLIB $LIBS"
3752       fi
3753     fi
3754     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3755     if test $have_krb4 = yes; then
3756       KRB4LIB=-lkrb4
3757       LIBS="$KRB4LIB $LIBS"
3758     else
3759       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3760       if test $have_krb = yes; then
3761         KRB4LIB=-lkrb
3762         LIBS="$KRB4LIB $LIBS"
3763       fi
3764     fi
3765   fi
3766
3767   if test "${with_kerberos5}" != no; then
3768     AC_CHECK_HEADERS(krb5.h,
3769       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3770                         [#include <krb5.h>])])
3771   else
3772     AC_CHECK_HEADERS(krb.h,,
3773                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3774                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3775   fi
3776   AC_CHECK_HEADERS(com_err.h)
3777 fi
3778
3779 AC_SUBST(COM_ERRLIB)
3780 AC_SUBST(CRYPTOLIB)
3781 AC_SUBST(KRB5LIB)
3782 AC_SUBST(DESLIB)
3783 AC_SUBST(KRB4LIB)
3784
3785 AC_CHECK_HEADERS(valgrind/valgrind.h)
3786
3787 AC_CHECK_FUNCS_ONCE(tzset)
3788 AC_MSG_CHECKING(whether localtime caches TZ)
3789 AC_CACHE_VAL(emacs_cv_localtime_cache,
3790 [if test x$ac_cv_func_tzset = xyes; then
3791 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3792 char TZ_GMT0[] = "TZ=GMT0";
3793 char TZ_PST8[] = "TZ=PST8";
3794 main()
3795 {
3796   time_t now = time ((time_t *) 0);
3797   int hour_GMT0, hour_unset;
3798   if (putenv (TZ_GMT0) != 0)
3799     exit (1);
3800   hour_GMT0 = localtime (&now)->tm_hour;
3801   unsetenv("TZ");
3802   hour_unset = localtime (&now)->tm_hour;
3803   if (putenv (TZ_PST8) != 0)
3804     exit (1);
3805   if (localtime (&now)->tm_hour == hour_GMT0)
3806     exit (1);
3807   unsetenv("TZ");
3808   if (localtime (&now)->tm_hour != hour_unset)
3809     exit (1);
3810   exit (0);
3811 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3812 [# If we have tzset, assume the worst when cross-compiling.
3813 emacs_cv_localtime_cache=yes])
3814 else
3815         # If we lack tzset, report that localtime does not cache TZ,
3816         # since we can't invalidate the cache if we don't have tzset.
3817         emacs_cv_localtime_cache=no
3818 fi])dnl
3819 AC_MSG_RESULT($emacs_cv_localtime_cache)
3820 if test $emacs_cv_localtime_cache = yes; then
3821   AC_DEFINE(LOCALTIME_CACHE, 1,
3822             [Define to 1 if localtime caches TZ.])
3823 fi
3824
3825 ok_so_far=yes
3826 AC_CHECK_FUNC(socket, , ok_so_far=no)
3827 if test $ok_so_far = yes; then
3828   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3829 fi
3830 if test $ok_so_far = yes; then
3831   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3832 fi
3833 if test $ok_so_far = yes; then
3834 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3835   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3836             [Define to 1 if you have inet sockets.])
3837 fi
3838
3839 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3840 dnl This can be removed once we assume Autoconf 2.70.
3841 case $canonical in
3842   *-solaris2.4 | *-solaris2.4.*)
3843     dnl Disable the Autoconf-generated vfork test.
3844     : ${ac_cv_func_vfork_works=no};;
3845 esac
3846
3847 AC_FUNC_FORK
3848
3849 AC_CHECK_FUNCS(snprintf)
3850
3851 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3852 dnl Emacs uses.
3853 XGSELOBJ=
3854 OLDCFLAGS="$CFLAGS"
3855 OLDLIBS="$LIBS"
3856 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3857 LIBS="$LIBS $GFILENOTIFY_LIBS"
3858 AC_MSG_CHECKING([whether GLib is linked in])
3859 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3860         [[#include <glib.h>
3861         ]],
3862         [[g_print ("Hello world");]])],
3863      [links_glib=yes],
3864      [links_glib=no])
3865 AC_MSG_RESULT([$links_glib])
3866 if test "${links_glib}" = "yes"; then
3867   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3868   if test "$HAVE_NS" = no;then
3869     XGSELOBJ=xgselect.o
3870   fi
3871 fi
3872 CFLAGS="$OLDCFLAGS"
3873 LIBS="$OLDLIBS"
3874 AC_SUBST(XGSELOBJ)
3875
3876 dnl Adapted from Haible's version.
3877 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3878   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3879     [[char* cs = nl_langinfo(CODESET);]])],
3880     emacs_cv_langinfo_codeset=yes,
3881     emacs_cv_langinfo_codeset=no)
3882   ])
3883 if test $emacs_cv_langinfo_codeset = yes; then
3884   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3885     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3886 fi
3887
3888 AC_TYPE_MBSTATE_T
3889
3890 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3891   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3892                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3893 if test "$emacs_cv_c_restrict_arr" = yes; then
3894   AC_DEFINE(__restrict_arr, __restrict,
3895     [Define to compiler's equivalent of C99 restrict keyword in array
3896      declarations.  Define as empty for no equivalent.])
3897 fi
3898
3899 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3900 dnl how the tty code is related to POSIX and/or other versions of termios.
3901 dnl The following looks like a useful start.
3902 dnl
3903 dnl AC_SYS_POSIX_TERMIOS
3904 dnl if test $ac_cv_sys_posix_termios = yes; then
3905 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3906 dnl                                and macros for terminal control.])
3907 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3908 dnl fi
3909
3910 dnl Turned on June 1996 supposing nobody will mind it.
3911 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3912 if test "${opsys}" != "mingw32"; then
3913    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3914      in the full name stands for the login id.])
3915 fi
3916
3917 dnl Every platform that uses configure supports this.
3918 dnl There is a create-lockfiles option you can
3919 dnl customize if you do not want the lock files to be written.
3920 dnl So it is not clear that this #define still needs to exist.
3921 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3922   so that Emacs can tell instantly when you try to modify a file that
3923   someone else has modified in his/her Emacs.])
3924
3925 dnl Everybody supports this, except MS.
3926 dnl Seems like the kind of thing we should be testing for, though.
3927 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3928 if test "${opsys}" != "mingw32"; then
3929   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3930 fi
3931
3932 dnl Everybody supports this, except MS-DOS.
3933 dnl Seems like the kind of thing we should be testing for, though.
3934 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3935 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3936   4.2-compatible sockets.])
3937
3938 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3939
3940 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3941   a null file, or a data sink.])
3942 if test "${opsys}" = "mingw32"; then
3943   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3944 else
3945   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3946 fi
3947
3948 if test "${opsys}" = "mingw32"; then
3949   SEPCHAR=';'
3950 else
3951   SEPCHAR=':'
3952 fi
3953 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
3954 dnl This is for MinGW, and is used in test/automated/Makefile.in.
3955 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
3956 dnl decides that a command-line argument to be passed to a MinGW program
3957 dnl is a PATH-style list of directories.  But that heuristics plays it
3958 dnl safe, and only does the replacement when it is _absolutely_ sure it
3959 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
3960 dnl which breaks in-tree builds.  So we do this manually instead.
3961 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
3962 dnl be computed as ':' in MSYS Bash.
3963 AC_SUBST(SEPCHAR)
3964
3965 dnl Everybody supports this, except MS-DOS.
3966 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3967
3968 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3969
3970
3971 AC_DEFINE(DIRECTORY_SEP, ['/'],
3972   [Character that separates directories in a file name.])
3973
3974 if test "${opsys}" = "mingw32"; then
3975   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3976     [Returns true if character is a device separator.])
3977
3978   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3979     [Returns true if character is a directory separator.])
3980
3981   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3982     [Returns true if character is any form of separator.])
3983 else
3984   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3985     [Returns true if character is a device separator.])
3986
3987   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3988     [Returns true if character is a directory separator.])
3989
3990   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3991     [Returns true if character is any form of separator.])
3992 fi
3993
3994 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3995
3996 case $opsys in
3997   aix4-2)
3998     dnl Unfortunately without libXmu we cannot support EditRes.
3999     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
4000       AC_DEFINE(NO_EDITRES, 1)
4001     fi
4002     ;;
4003
4004   hpux*)
4005     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4006     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4007     AC_DEFINE(NO_EDITRES, 1)
4008     ;;
4009 esac
4010
4011
4012 case $opsys in
4013   irix6-5 | sol2* | unixware )
4014     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4015     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4016     dnl need the constant to dimension an array.  So wire in the appropriate
4017     dnl value here.
4018     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4019     ;;
4020 esac
4021
4022 emacs_broken_SIGIO=no
4023
4024 case $opsys in
4025   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4026   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4027   hpux* | irix6-5 | openbsd | sol2* | unixware )
4028     emacs_broken_SIGIO=yes
4029     ;;
4030
4031   aix4-2)
4032     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4033     dnl the way this system works, libc functions that return malloced
4034     dnl memory use the libc malloc implementation. Calling xfree or
4035     dnl xrealloc on the results of such functions results in a crash.
4036     dnl
4037     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4038     dnl but that does not currently work on this system.
4039     dnl
4040     dnl It is possible to completely override the malloc implementation on
4041     dnl AIX, but that involves putting the malloc functions in a shared
4042     dnl library and setting the MALLOCTYPE environment variable to point to
4043     dnl that shared library.
4044     dnl
4045     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4046     dnl to avoid a crash just use the Emacs implementation for that function.
4047     dnl
4048     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4049     dnl of this file, so that we do not check for get_current_dir_name
4050     dnl on AIX.  But that might be fragile if something else ends
4051     dnl up testing for get_current_dir_name as a dependency.
4052     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4053       get_current_dir_name should not be used.])
4054     ;;
4055
4056   freebsd)
4057     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4058     dnl writes/reads on a PTY, read(2) returns bogus data:
4059     dnl
4060     dnl write(2)  1022 bytes
4061     dnl write(2)   954 bytes, get EAGAIN
4062     dnl read(2)   1024 bytes in process_read_output
4063     dnl read(2)     11 bytes in process_read_output
4064     dnl
4065     dnl That is, read(2) returns more bytes than have ever been written
4066     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4067     dnl successfully after processing (for example with CRs added if the
4068     dnl terminal is set up that way which it is here).  The same bytes will
4069     dnl be seen again in a later read(2), without the CRs.
4070     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4071       work around an issue when reading from a PTY.])
4072     ;;
4073 esac
4074
4075 case $opsys in
4076   gnu-* | sol2-10 )
4077     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4078     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4079   ;;
4080 esac
4081
4082 case $opsys in
4083   darwin | dragonfly | freebsd | netbsd | openbsd )
4084     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4085       close a pty to make it a controlling terminal (it is already a
4086       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4087   ;;
4088 esac
4089
4090 dnl FIXME Surely we can test for this rather than hard-code it.
4091 case $opsys in
4092   netbsd | openbsd) sound_device="/dev/audio" ;;
4093   *) sound_device="/dev/dsp" ;;
4094 esac
4095
4096 dnl Used in sound.c
4097 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4098   [Name of the default sound device.])
4099
4100
4101 dnl Emacs can read input using SIGIO and buffering characters itself,
4102 dnl or using CBREAK mode and making C-g cause SIGINT.
4103 dnl The choice is controlled by the variable interrupt_input.
4104 dnl
4105 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4106 dnl
4107 dnl Emacs uses the presence of the USABLE_SIGIO macro
4108 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4109 dnl INTERRUPT_INPUT to decide whether to use it by default.
4110 dnl
4111 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4112 dnl CBREAK mode has two disadvantages
4113 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4114 dnl I hear that in system V this problem does not exist.
4115 dnl 2) Control-G causes output to be discarded.
4116 dnl I do not know whether this can be fixed in system V.
4117 dnl
4118 dnl Another method of doing input is planned but not implemented.
4119 dnl It would have Emacs fork off a separate process
4120 dnl to read the input and send it to the true Emacs process
4121 dnl through a pipe.
4122 case $opsys in
4123   darwin | gnu-linux | gnu-kfreebsd )
4124     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4125   ;;
4126 esac
4127
4128
4129 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4130 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4131 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4132 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4133 dnl taking float or double parameters.
4134 case $opsys in
4135   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4136     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4137       file defines `NeedWidePrototypes' as `NO'.])
4138   ;;
4139 esac
4140
4141
4142 dnl Used in process.c, this must be a loop, even if it only runs once.
4143 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4144 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4145 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4146 dnl trying suffixes 0-16.
4147 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4148   first PTY, if PTYs are supported.])
4149 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4150 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4151   end of a PTY, if non-standard.])
4152 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4153   end of a PTY, if non-standard.])
4154
4155 case $opsys in
4156   aix4-2 )
4157     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4158     dnl You allocate a pty by opening /dev/ptc to get the master side.
4159     dnl To get the name of the slave side, you just ttyname() the master side.
4160     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4161     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4162     ;;
4163
4164   cygwin )
4165     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4166     dnl multi-line AC_DEFINEs are hard. :(
4167     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4168     AC_DEFINE(PTY_NAME_SPRINTF, [])
4169     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4170     ;;
4171
4172   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4173   darwin )
4174     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4175     dnl Not used, because PTY_ITERATION is defined.
4176     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4177     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4178     dnl But we don't have to block SIGCHLD because it is blocked in the
4179     dnl implementation of grantpt.
4180     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4181     AC_DEFINE(PTY_NAME_SPRINTF, [])
4182     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4183     ;;
4184
4185   gnu | openbsd )
4186     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4187     ;;
4188
4189   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4190     dnl if HAVE_GRANTPT
4191     if test "x$ac_cv_func_grantpt" = xyes; then
4192       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4193       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4194       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4195       dnl to prevent sigchld_handler from intercepting the child's death.
4196       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4197       dnl if HAVE_POSIX_OPENPT
4198       if test "x$ac_cv_func_posix_openpt" = xyes; then
4199         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4200         AC_DEFINE(PTY_NAME_SPRINTF, [])
4201       dnl if HAVE_GETPT
4202       elif test "x$ac_cv_func_getpt" = xyes; then
4203         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4204         AC_DEFINE(PTY_NAME_SPRINTF, [])
4205       else
4206         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4207       fi
4208     else
4209       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4210     fi
4211     ;;
4212
4213   hpux*)
4214     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4215     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4216     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4217     ;;
4218
4219   irix6-5 )
4220     dnl It looks like this cannot be right, because it is not a loop.
4221     dnl However, process.c actually does this:
4222     dnl # ifndef __sgi
4223     dnl   continue;
4224     dnl # else
4225     dnl   return -1;
4226     dnl # endif
4227     dnl which presumably makes it OK, since irix == sgi (?).
4228     dnl FIXME it seems like this special treatment is unnecessary?
4229     dnl Why can't irix use a single-trip loop like eg cygwin?
4230     AC_DEFINE(PTY_ITERATION, [])
4231     dnl Not used, because PTY_ITERATION is defined.
4232     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4233     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4234     dnl No need to get the pty name at all.
4235     AC_DEFINE(PTY_NAME_SPRINTF, [])
4236     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4237     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4238     ;;
4239
4240   sol2* )
4241     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4242     dnl from intercepting that death.  If any child but grantpt's should die
4243     dnl within, it should be caught after sigrelse(2).
4244     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4245     ;;
4246
4247   unixware )
4248     dnl Comments are as per sol2*.
4249     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4250     ;;
4251 esac
4252
4253
4254 case $opsys in
4255   sol2* | unixware )
4256     dnl This change means that we don't loop through allocate_pty too
4257     dnl many times in the (rare) event of a failure.
4258     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4259     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4260     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4261     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4262     ;;
4263 esac
4264
4265
4266 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4267 "typing" a signal character on the pty.])
4268
4269 case $opsys in
4270   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4271   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4272   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4273     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4274     ;;
4275
4276   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4277   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4278   gnu-linux | gnu-kfreebsd )
4279
4280     AC_MSG_CHECKING([for signals via characters])
4281     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4282 #include <linux/version.h>
4283 #if LINUX_VERSION_CODE < 0x20400
4284 # error "Linux version too old"
4285 #endif
4286       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4287
4288     AC_MSG_RESULT([$emacs_signals_via_chars])
4289     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4290     ;;
4291 esac
4292
4293
4294 dnl Used in lisp.h, emacs.c, vm-limit.c
4295 dnl NEWS.18 describes this as "a number which contains
4296 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4297 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4298 stored in a Lisp_Object.])
4299 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4300
4301 case $opsys in
4302   aix*)
4303     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4304     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4305     ;;
4306   hpux*)
4307     dnl The data segment on this machine always starts at address 0x40000000.
4308     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4309     ;;
4310   irix6-5)
4311     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4312     ;;
4313 esac
4314
4315
4316 AH_TEMPLATE(TAB3, [Undocumented.])
4317
4318 case $opsys in
4319   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4320
4321   gnu | dragonfly | freebsd | netbsd | openbsd )
4322     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4323     AC_DEFINE(TAB3, OXTABS)
4324     ;;
4325
4326   gnu-linux | gnu-kfreebsd )
4327     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4328 #ifndef __ia64__
4329 # error "not ia64"
4330 #endif
4331       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4332         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4333         [Mark a secondary stack, like the register stack on the ia64.]), [])
4334     ;;
4335
4336   hpux*)
4337     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4338       run_time_remap; for HPUX.])
4339     ;;
4340 esac
4341
4342
4343 dnl This won't be used automatically yet.  We also need to know, at least,
4344 dnl that the stack is continuous.
4345 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4346   registers relevant for conservative garbage collection in the jmp_buf.])
4347
4348
4349 case $opsys in
4350   dnl Not all the architectures are tested, but there are Debian packages
4351   dnl for SCM and/or Guile on them, so the technique must work.  See also
4352   dnl comments in alloc.c concerning setjmp and gcc.
4353   dnl Fixme: it's probably safe to just use the GCC conditional below.
4354   gnu-linux | gnu-kfreebsd )
4355     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4356 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4357   || defined __alpha__ || defined __mips__ || defined __s390__ \
4358   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4359   || defined __ia64__ || defined __sh__
4360 /* ok */
4361 #else
4362 # error "setjmp not known to work on this arch"
4363 #endif
4364     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4365     ;;
4366 esac
4367
4368
4369 if test x$GCC = xyes; then
4370    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4371    AC_DEFINE(GC_SETJMP_WORKS, 1)
4372 else
4373   case $opsys in
4374     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4375     dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4376       AC_DEFINE(GC_SETJMP_WORKS, 1)
4377       ;;
4378   esac
4379 fi                              dnl GCC?
4380
4381 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4382 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4383   [AC_LINK_IFELSE(
4384      [AC_LANG_PROGRAM(
4385        [[#include <setjmp.h>
4386          #ifdef __MINGW32__
4387          # define _longjmp longjmp
4388          #endif
4389        ]],
4390        [[jmp_buf j;
4391          if (! _setjmp (j))
4392            _longjmp (j, 1);]])],
4393      [emacs_cv_func__setjmp=yes],
4394      [emacs_cv_func__setjmp=no])])
4395 if test $emacs_cv_func__setjmp = yes; then
4396   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4397 else
4398   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4399     [AC_LINK_IFELSE(
4400        [AC_LANG_PROGRAM(
4401          [[#include <setjmp.h>
4402          ]],
4403          [[sigjmp_buf j;
4404            if (! sigsetjmp (j, 1))
4405              siglongjmp (j, 1);]])],
4406        [emacs_cv_func_sigsetjmp=yes],
4407        [emacs_cv_func_sigsetjmp=no])])
4408   if test $emacs_cv_func_sigsetjmp = yes; then
4409     AC_DEFINE([HAVE_SIGSETJMP], 1,
4410       [Define to 1 if sigsetjmp and siglongjmp work.
4411        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4412   fi
4413 fi
4414
4415 case $opsys in
4416   sol2* | unixware )
4417     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4418     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4419     dnl and this is all we need.
4420     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4421     ;;
4422 esac
4423
4424
4425 case $opsys in
4426   hpux* | sol2* )
4427     dnl Used in xfaces.c.
4428     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4429       some systems, where it requires time.h.])
4430     ;;
4431 esac
4432
4433
4434 dnl Define symbols to identify the version of Unix this is.
4435 dnl Define all the symbols that apply correctly.
4436 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4437 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4438 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4439 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4440
4441 case $opsys in
4442   aix4-2)
4443     AC_DEFINE(USG, [])
4444     dnl This symbol should be defined on AIX Version 3  ???????
4445     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4446 #ifndef _AIX
4447 # error "_AIX not defined"
4448 #endif
4449     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4450     ;;
4451
4452   cygwin)
4453     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4454     ;;
4455
4456   darwin)
4457     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4458     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4459     dnl distinguish OS X from pure Darwin.
4460     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4461     ;;
4462
4463   gnu-linux | gnu-kfreebsd )
4464     AC_DEFINE(USG, [])
4465     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4466     ;;
4467
4468   hpux*)
4469     AC_DEFINE(USG, [])
4470     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4471     ;;
4472
4473   irix6-5)
4474     AC_DEFINE(USG, [])
4475     AC_DEFINE(USG5_4, [])
4476     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4477     ;;
4478
4479   mingw32)
4480     AC_DEFINE(DOS_NT, [])
4481     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4482     if test "x$ac_enable_checking" != "x" ; then
4483       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4484     fi
4485     ;;
4486
4487   sol2*)
4488     AC_DEFINE(USG, [])
4489     AC_DEFINE(USG5_4, [])
4490     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4491     ;;
4492
4493   unixware)
4494     AC_DEFINE(USG, [])
4495     AC_DEFINE(USG5_4, [])
4496     ;;
4497 esac
4498
4499 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4500   [case $opsys in
4501      aix4-2)
4502        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4503        emacs_cv_usable_FIONREAD=no
4504        ;;
4505
4506      mingw32)
4507        emacs_cv_usable_FIONREAD=yes
4508        ;;
4509
4510      *)
4511        AC_COMPILE_IFELSE(
4512          [AC_LANG_PROGRAM([[#include <sys/types.h>
4513                             #include <sys/ioctl.h>
4514                             #ifdef USG5_4
4515                             # include <sys/filio.h>
4516                             #endif
4517                           ]],
4518                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4519          [emacs_cv_usable_FIONREAD=yes],
4520          [emacs_cv_usable_FIONREAD=no])
4521        ;;
4522    esac])
4523 if test $emacs_cv_usable_FIONREAD = yes; then
4524   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4525
4526   if test $emacs_broken_SIGIO = no; then
4527     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4528       [AC_COMPILE_IFELSE(
4529          [AC_LANG_PROGRAM([[#include <fcntl.h>
4530                             #include <signal.h>
4531                           ]],
4532                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4533          [emacs_cv_usable_SIGIO=yes],
4534          [emacs_cv_usable_SIGIO=no])],
4535       [emacs_cv_usable_SIGIO=yes],
4536       [emacs_cv_usable_SIGIO=no])
4537     if test $emacs_cv_usable_SIGIO = yes; then
4538       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4539     fi
4540   fi
4541 fi
4542
4543
4544 case $opsys in
4545   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4546   dnl and on Cygwin prior to version 1.7.24 that becomes the
4547   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4548   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4549   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4550   dnl needed starting with cygwin-1.7.24, and it is no longer
4551   dnl effective starting with glib-2.36. */
4552   cygwin)
4553     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4554       G_SLICE environment variable to "always-malloc" at startup.])
4555     ;;
4556
4557   hpux11)
4558     dnl It works to open the pty's tty in the parent (Emacs), then
4559     dnl close and reopen it in the child.
4560     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4561       works to open a pty's tty in the parent process, then close and
4562       reopen it in the child.])
4563     ;;
4564
4565   irix6-5)
4566     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4567       use VSUSP instead of VSWTCH.])
4568     ;;
4569
4570   sol2-10)
4571     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4572       on Solaris.])
4573     ;;
4574 esac
4575
4576 # Set up the CFLAGS for real compilation, so we can substitute it.
4577 CFLAGS="$REAL_CFLAGS"
4578 CPPFLAGS="$REAL_CPPFLAGS"
4579
4580 ## Hack to detect a buggy GCC version.
4581 if test "x$GCC" = xyes \
4582    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4583    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4584    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4585    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4586 fi
4587
4588 version=$PACKAGE_VERSION
4589
4590 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4591 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4592   [Short copyright string for this version of Emacs.])
4593 AC_SUBST(copyright)
4594
4595 ### Specify what sort of things we'll be editing into Makefile and config.h.
4596 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4597 AC_SUBST(version)
4598 AC_SUBST(configuration)
4599 ## Unused?
4600 AC_SUBST(canonical)
4601 AC_SUBST(srcdir)
4602 AC_SUBST(prefix)
4603 AC_SUBST(exec_prefix)
4604 AC_SUBST(bindir)
4605 AC_SUBST(datadir)
4606 AC_SUBST(sharedstatedir)
4607 AC_SUBST(libexecdir)
4608 AC_SUBST(mandir)
4609 AC_SUBST(infodir)
4610 AC_SUBST(lispdir)
4611 AC_SUBST(standardlisppath)
4612 AC_SUBST(locallisppath)
4613 AC_SUBST(lisppath)
4614 AC_SUBST(x_default_search_path)
4615 AC_SUBST(etcdir)
4616 AC_SUBST(archlibdir)
4617 AC_SUBST(etcdocdir)
4618 AC_SUBST(bitmapdir)
4619 AC_SUBST(gamedir)
4620 AC_SUBST(gameuser)
4621 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4622 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4623 ## end of LIBX_BASE, but nothing ever set it.
4624 AC_SUBST(LD_SWITCH_X_SITE)
4625 AC_SUBST(C_SWITCH_X_SITE)
4626 AC_SUBST(GNUSTEP_CFLAGS)
4627 AC_SUBST(CFLAGS)
4628 ## Used in lwlib/Makefile.in.
4629 AC_SUBST(X_TOOLKIT_TYPE)
4630 AC_SUBST(ns_appdir)
4631 AC_SUBST(ns_appbindir)
4632 AC_SUBST(ns_appresdir)
4633 AC_SUBST(ns_appsrc)
4634 AC_SUBST(GNU_OBJC_CFLAGS)
4635 AC_SUBST(OTHER_FILES)
4636
4637 if test -n "${term_header}"; then
4638     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4639         [Define to the header for the built-in window system.])
4640 fi
4641
4642 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4643                    [Define to the canonical Emacs configuration name.])
4644 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4645                    [Define to the options passed to configure.])
4646 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4647   define this to include extra configuration information.])
4648
4649 case $opsys in
4650   mingw32)
4651     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4652     ;;
4653 esac
4654
4655 XMENU_OBJ=
4656 XOBJ=
4657 FONT_OBJ=
4658 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4659   AC_DEFINE(HAVE_X_WINDOWS, 1,
4660             [Define to 1 if you want to use the X window system.])
4661   XMENU_OBJ=xmenu.o
4662   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4663   FONT_OBJ=xfont.o
4664   if test "$HAVE_XFT" = "yes"; then
4665     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4666   elif test "$HAVE_FREETYPE" = "yes"; then
4667     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4668   fi
4669   AC_SUBST(FONT_OBJ)
4670 fi
4671 AC_SUBST(XMENU_OBJ)
4672 AC_SUBST(XOBJ)
4673 AC_SUBST(FONT_OBJ)
4674
4675 WIDGET_OBJ=
4676 MOTIF_LIBW=
4677 if test "${USE_X_TOOLKIT}" != "none" ; then
4678   WIDGET_OBJ=widget.o
4679   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4680   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4681     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4682   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4683     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4684     MOTIF_LIBW=-lXm
4685     case "$opsys" in
4686       gnu-linux)
4687         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4688         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4689         ;;
4690
4691       unixware)
4692         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4693         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4694         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4695         ;;
4696
4697       aix4-2)
4698         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4699         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4700         ;;
4701     esac
4702     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4703   fi
4704 fi
4705 AC_SUBST(WIDGET_OBJ)
4706
4707 TOOLKIT_LIBW=
4708 case "$USE_X_TOOLKIT" in
4709   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4710   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4711   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4712 esac
4713 AC_SUBST(TOOLKIT_LIBW)
4714
4715 if test "${opsys}" != "mingw32"; then
4716   if test "$USE_X_TOOLKIT" = "none"; then
4717     LIBXT_OTHER="\$(LIBXSM)"
4718   else
4719     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4720   fi
4721 fi
4722 AC_SUBST(LIBXT_OTHER)
4723
4724 if test "${HAVE_X11}" = "yes" ; then
4725   AC_DEFINE(HAVE_X11, 1,
4726             [Define to 1 if you want to use version 11 of X windows.])
4727   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4728 else
4729   LIBX_OTHER=
4730 fi
4731 AC_SUBST(LIBX_OTHER)
4732
4733 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4734   LIBXMENU=
4735 elif test "$USE_X_TOOLKIT" = none; then
4736   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4737 else
4738   LIBXMENU='$(lwlibdir)/liblw.a'
4739 fi
4740 AC_SUBST(LIBXMENU)
4741
4742 if test "${GNU_MALLOC}" = "yes" ; then
4743   AC_DEFINE(GNU_MALLOC, 1,
4744             [Define to 1 if you want to use the GNU memory allocator.])
4745 fi
4746
4747 RALLOC_OBJ=
4748 if test "${REL_ALLOC}" = "yes" ; then
4749   AC_DEFINE(REL_ALLOC, 1,
4750             [Define REL_ALLOC if you want to use the relocating allocator for
4751              buffer space.])
4752
4753   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4754 fi
4755 AC_SUBST(RALLOC_OBJ)
4756
4757 if test "$opsys" = "cygwin"; then
4758   CYGWIN_OBJ="sheap.o cygw32.o"
4759   ## Cygwin differs because of its unexec().
4760   PRE_ALLOC_OBJ=
4761   POST_ALLOC_OBJ=lastfile.o
4762 elif test "$opsys" = "mingw32"; then
4763   CYGWIN_OBJ=
4764   PRE_ALLOC_OBJ=
4765   POST_ALLOC_OBJ=lastfile.o
4766 else
4767   CYGWIN_OBJ=
4768   PRE_ALLOC_OBJ=lastfile.o
4769   POST_ALLOC_OBJ=
4770 fi
4771 AC_SUBST(CYGWIN_OBJ)
4772 AC_SUBST(PRE_ALLOC_OBJ)
4773 AC_SUBST(POST_ALLOC_OBJ)
4774
4775 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4776 dnl verbatim defined above.  The tricky name is apropos, as this hack
4777 dnl makes Fortify go sour!
4778 AH_VERBATIM([FORTIFY_SOUR],
4779 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4780    The workaround disables some useful run-time checking, so it
4781    should be conditional to the platforms with the performance bug.
4782    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4783 #if defined __APPLE__ && defined __GNUC__
4784 # ifndef _DONT_USE_CTYPE_INLINE_
4785 #  define _DONT_USE_CTYPE_INLINE_
4786 # endif
4787 # ifndef _FORTIFY_SOURCE
4788 #  define _FORTIFY_SOURCE 0
4789 # endif
4790 #endif
4791 ])
4792
4793 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4794 # it temporarily reverts them to their pre-pkg-config values,
4795 # because gnulib needs to work with both src (which uses the
4796 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4797 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4798 # and it therefore needs to run in an environment where LIBS does not
4799 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4800 # for some package unrelated to lib-src.
4801 SAVE_CFLAGS=$CFLAGS
4802 SAVE_LIBS=$LIBS
4803 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4804 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4805 gl_ASSERT_NO_GNULIB_POSIXCHECK
4806 gl_ASSERT_NO_GNULIB_TESTS
4807 gl_INIT
4808 CFLAGS=$SAVE_CFLAGS
4809 LIBS=$SAVE_LIBS
4810
4811 if test "${opsys}" = "mingw32"; then
4812   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4813   # Remove unneeded switches from the value of CC that goes to Makefiles
4814   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4815 fi
4816
4817 case "$opsys" in
4818   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4819
4820   darwin)
4821    ## The -headerpad option tells ld (see man page) to leave room at the
4822    ## end of the header for adding load commands.  Needed for dumping.
4823    ## 0x690 is the total size of 30 segment load commands (at 56
4824    ## each); under Cocoa 31 commands are required.
4825    if test "$HAVE_NS" = "yes"; then
4826      libs_nsgui="-framework AppKit"
4827      if test "$NS_IMPL_COCOA" = "yes"; then
4828         libs_nsgui="$libs_nsgui -framework IOKit"
4829      fi
4830      headerpad_extra=6C8
4831    else
4832      libs_nsgui=
4833      headerpad_extra=690
4834    fi
4835    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4836
4837    ## This is here because src/Makefile.in did some extra fiddling around
4838    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4839    ## LD_SWITCH_SYSTEM_TEMACS instead,
4840    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4841      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4842    ;;
4843
4844   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4845   ## find X at run-time.
4846   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4847   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4848   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4849   ## had different values in configure (in ac_link) and src/Makefile.in.
4850   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4851   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4852
4853   mingw32)
4854    ## MinGW64 does not prepend an underscore to symbols, so we must
4855    ## pass a different -entry switch to linker.  FIXME: It is better
4856    ## to make the entry points the same by changing unexw32.c.
4857    case "$canonical" in
4858      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4859      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4860    esac
4861    ;;
4862
4863   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4864
4865   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4866 esac
4867
4868 if test x$ac_enable_profiling != x ; then
4869   case $opsys in
4870     *freebsd | gnu-linux) ;;
4871     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4872   esac
4873 fi
4874
4875 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4876
4877 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4878
4879 ## MinGW-specific post-link processing of temacs.
4880 TEMACS_POST_LINK=":"
4881 ADDSECTION=
4882 EMACS_HEAPSIZE=
4883 if test "${opsys}" = "mingw32"; then
4884   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4885   ADDSECTION="../nt/addsection\$(EXEEXT)"
4886   ## Preload heap size of temacs.exe in MB.
4887   case "$canonical" in
4888     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4889     *) EMACS_HEAPSIZE=27 ;;
4890   esac
4891 fi
4892
4893 AC_SUBST(ADDSECTION)
4894 AC_SUBST(TEMACS_POST_LINK)
4895 AC_SUBST(EMACS_HEAPSIZE)
4896
4897 ## Common for all window systems
4898 if test "$window_system" != "none"; then
4899   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4900   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4901 fi
4902
4903 AC_SUBST(WINDOW_SYSTEM_OBJ)
4904
4905 AH_TOP([/* GNU Emacs site configuration template file.
4906
4907 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4908   Free Software Foundation, Inc.
4909
4910 This file is part of GNU Emacs.
4911
4912 GNU Emacs is free software: you can redistribute it and/or modify
4913 it under the terms of the GNU General Public License as published by
4914 the Free Software Foundation, either version 3 of the License, or
4915 (at your option) any later version.
4916
4917 GNU Emacs is distributed in the hope that it will be useful,
4918 but WITHOUT ANY WARRANTY; without even the implied warranty of
4919 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4920 GNU General Public License for more details.
4921
4922 You should have received a copy of the GNU General Public License
4923 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4924
4925
4926 /* No code in Emacs #includes config.h twice, but some bits of code
4927    intended to work with other packages as well (like gmalloc.c)
4928    think they can include it as many times as they like.  */
4929 #ifndef EMACS_CONFIG_H
4930 #define EMACS_CONFIG_H
4931 ])dnl
4932
4933 AH_BOTTOM([#include <conf_post.h>
4934
4935 #endif /* EMACS_CONFIG_H */
4936
4937 /*
4938 Local Variables:
4939 mode: c
4940 End:
4941 */
4942 ])dnl
4943
4944 #### Report on what we decided to do.
4945 #### Report GTK as a toolkit, even if it doesn't use Xt.
4946 #### It makes printing result more understandable as using GTK sets
4947 #### toolkit_scroll_bars to yes by default.
4948 if test "${HAVE_GTK}" = "yes"; then
4949   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4950 fi
4951
4952 if test $USE_ACL -ne 0; then
4953   acl_summary="yes $LIB_ACL"
4954 else
4955   acl_summary=no
4956 fi
4957
4958 echo "
4959 Configured for \`${canonical}'.
4960
4961   Where should the build process find the source code?    ${srcdir}
4962   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4963   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4964   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4965   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4966   What window system should Emacs use?                    ${window_system}
4967   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4968
4969 if test -n "${x_includes}"; then
4970 echo "  Where do we find X Windows header files?                ${x_includes}"
4971 else
4972 echo "  Where do we find X Windows header files?                Standard dirs"
4973 fi
4974 if test -n "${x_libraries}"; then
4975 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4976 else
4977 echo "  Where do we find X Windows libraries?                   Standard dirs"
4978 fi
4979
4980 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4981 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4982 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4983 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4984 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4985 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4986 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4987 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4988
4989 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
4990
4991 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4992 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4993 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4994 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4995 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
4996 echo "  Does Emacs use access control lists?                    ${acl_summary}"
4997 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4998 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4999 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5000
5001 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5002 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5003 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5004 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5005 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5006
5007 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5008 echo
5009
5010 if test -n "${EMACSDATA}"; then
5011    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5012 fi
5013 if test -n "${EMACSDOC}"; then
5014    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5015 fi
5016
5017 echo
5018
5019 if test "$HAVE_NS" = "yes"; then
5020    echo
5021    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5022 The installed application will go to nextstep/Emacs.app and can be
5023 run or moved from there."
5024    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5025       echo "The application will be fully self-contained."
5026     else
5027       echo "The lisp resources for the application will be installed under ${prefix}.
5028 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5029 to run if these resources are not installed."
5030    fi
5031    echo
5032 fi
5033
5034 if test "${opsys}" = "cygwin"; then
5035   case `uname -r` in
5036     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5037            echo
5038            ;;
5039   esac
5040 fi
5041
5042 # Remove any trailing slashes in these variables.
5043 [test "${prefix}" != NONE &&
5044   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5045 test "${exec_prefix}" != NONE &&
5046   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5047
5048 if test "$HAVE_NS" = "yes"; then
5049   if test "$NS_IMPL_GNUSTEP" = yes; then
5050     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5051       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5052     ns_check_file=Resources/Info-gnustep.plist
5053   else
5054     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5055       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5056     ns_check_file=Contents/Info.plist
5057   fi
5058   AC_SUBST(ns_check_file)
5059 fi
5060
5061 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5062 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5063 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5064 dnl (else you get "no `Makefile.am' found for any configure output").
5065 dnl This will work, but you get a config.status that is not quite right
5066 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5067 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5068 dnl it seems better to just live with the duplication.
5069 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5070
5071 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5072        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5073        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5074        leim/Makefile nextstep/Makefile nt/Makefile])
5075
5076 dnl test/ is not present in release tarfiles.
5077 opt_makefile=test/automated/Makefile
5078
5079 if test -f "$srcdir/$opt_makefile.in"; then
5080   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5081   dnl Again, it's best not to use a variable.  Though you can add
5082   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5083   AC_CONFIG_FILES([test/automated/Makefile])
5084 fi
5085
5086
5087 dnl The admin/ directory used to be excluded from tarfiles.
5088 if test -d $srcdir/admin; then
5089   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5090   AC_CONFIG_FILES([admin/unidata/Makefile])
5091   AC_CONFIG_FILES([admin/grammars/Makefile])
5092 fi                              dnl -d admin
5093
5094
5095 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5096
5097 AC_SUBST(SUBDIR_MAKEFILES_IN)
5098
5099 dnl You might wonder (I did) why epaths.h is generated by running make,
5100 dnl rather than just letting configure generate it from epaths.in.
5101 dnl One reason is that the various paths are not fully expanded (see above);
5102 dnl eg gamedir=${prefix}/var/games/emacs.
5103 dnl Secondly, the GNU Coding standards require that one should be able
5104 dnl to run `make prefix=/some/where/else' and override the values set
5105 dnl by configure.  This also explains the `move-if-change' test and
5106 dnl the use of force in the `epaths-force' rule in Makefile.in.
5107 AC_CONFIG_COMMANDS([src/epaths.h], [
5108 if test "${opsys}" = "mingw32"; then
5109   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5110 else
5111   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5112 fi
5113 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5114
5115 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5116 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5117 dnl or a symlink?
5118 AC_CONFIG_COMMANDS([src/.gdbinit], [
5119 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5120   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5121 fi
5122 ])
5123
5124 AC_OUTPUT