configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 ## For the times when you want to build Emacs but don't have
 181 ## a suitable makeinfo, and can live without the manuals.
 182 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 183 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 184
 185 ## Makefile.in needs the cache file name.
 186 AC_SUBST(cache_file)
 187
 188 ## This is an option because I do not know if all info/man support
 189 ## compressed files, nor how to test if they do so.
 190 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 191 if test $with_compress_info = yes; then
 192    GZIP_INFO=yes
 193 else
 194    GZIP_INFO=
 195 fi
 196 AC_SUBST(GZIP_INFO)
 197
 198 AC_ARG_WITH([pkg-config-prog],dnl
 199 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 200                   [path to pkg-config for finding GTK and librsvg])])
 201 if test "X${with_pkg_config_prog}" != X; then
 202    if test "${with_pkg_config_prog}" != yes; then
 203       PKG_CONFIG="${with_pkg_config_prog}"
 204    fi
 205 fi
 206
 207 CRT_DIR=
 208 AC_ARG_WITH([crt-dir],dnl
 209 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 210 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 211 CRT_DIR="${with_crt_dir}"
 212
 213 AC_ARG_WITH(gameuser,dnl
 214 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 215 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 216   && gameuser="${with_gameuser}"
 217 test "X$gameuser" = X && gameuser=games
 218
 219 AC_ARG_WITH([gnustep-conf],dnl
 220 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 221 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 222   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 223 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 224      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 225
 226 AC_ARG_ENABLE(ns-self-contained,
 227 [AS_HELP_STRING([--disable-ns-self-contained],
 228                 [disable self contained build under NeXTstep])],
 229    EN_NS_SELF_CONTAINED=$enableval,
 230    EN_NS_SELF_CONTAINED=yes)
 231
 232 AC_ARG_ENABLE(asserts,
 233 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 234       USE_XASSERTS=$enableval,
 235       USE_XASSERTS=no)
 236
 237 AC_ARG_ENABLE(maintainer-mode,
 238 [AS_HELP_STRING([--disable-maintainer-mode],
 239                 [disable make rules and dependencies not useful (and sometimes
 240                  confusing) to the casual installer])],
 241       USE_MAINTAINER_MODE=$enableval,
 242       USE_MAINTAINER_MODE=yes)
 243 if test $USE_MAINTAINER_MODE = yes; then
 244   MAINT=
 245 else
 246   MAINT=#
 247 fi
 248 AC_SUBST(MAINT)
 249
 250 AC_ARG_ENABLE(locallisppath,
 251 [AS_HELP_STRING([--enable-locallisppath=PATH],
 252                 [directories Emacs should search for lisp files specific
 253                  to this site])],
 254 if test "${enableval}" = "no"; then
 255   locallisppath=
 256 elif test "${enableval}" != "yes"; then
 257   locallisppath=${enableval}
 258 fi)
 259
 260 AC_ARG_ENABLE(checking,
 261 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 262                 [enable expensive run-time checks.  With LIST,
 263                  enable only specific categories of checks.
 264                  Categories are: all,yes,no.
 265                  Flags are: stringbytes, stringoverrun, stringfreelist,
 266                  xmallocoverrun, conslist])],
 267 [ac_checking_flags="${enableval}"],[])
 268 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 269 for check in $ac_checking_flags
 270 do
 271         case $check in
 272         # these set all the flags to specific states
 273         yes)            ac_enable_checking=1 ;;
 274         no)             ac_enable_checking= ;
 275                         ac_gc_check_stringbytes= ;
 276                         ac_gc_check_string_overrun= ;
 277                         ac_gc_check_string_free_list= ;
 278                         ac_xmalloc_overrun= ;
 279                         ac_gc_check_cons_list= ;;
 280         all)            ac_enable_checking=1 ;
 281                         ac_gc_check_stringbytes=1 ;
 282                         ac_gc_check_string_overrun=1 ;
 283                         ac_gc_check_string_free_list=1 ;
 284                         ac_xmalloc_overrun=1 ;
 285                         ac_gc_check_cons_list=1 ;;
 286         # these enable particular checks
 287         stringbytes)    ac_gc_check_stringbytes=1 ;;
 288         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 289         stringfreelist) ac_gc_check_string_free_list=1 ;;
 290         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 291         conslist)       ac_gc_check_cons_list=1 ;;
 292         *)      AC_MSG_ERROR(unknown check category $check) ;;
 293         esac
 294 done
 295 IFS="$ac_save_IFS"
 296
 297 if test x$ac_enable_checking != x ; then
 298   AC_DEFINE(ENABLE_CHECKING, 1,
 299 [Enable expensive run-time checking of data types?])
 300 fi
 301 if test x$ac_gc_check_stringbytes != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 303 [Define this temporarily to hunt a bug.  If defined, the size of
 304    strings is redundantly recorded in sdata structures so that it can
 305    be compared to the sizes recorded in Lisp strings.])
 306 fi
 307 if test x$ac_gc_check_string_overrun != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 309 [Define this to check for short string overrun.])
 310 fi
 311 if test x$ac_gc_check_string_free_list != x ; then
 312   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 313 [Define this to check the string free list.])
 314 fi
 315 if test x$ac_xmalloc_overrun != x ; then
 316   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 317 [Define this to check for malloc buffer overrun.])
 318 fi
 319 if test x$ac_gc_check_cons_list != x ; then
 320   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 321 [Define this to check for errors in cons list.])
 322 fi
 323
 324 AC_ARG_ENABLE(use-lisp-union-type,
 325 [AS_HELP_STRING([--enable-use-lisp-union-type],
 326                 [use a union for the Lisp_Object data type.
 327                 This is only useful for development for catching certain types of bugs.])],
 328 if test "${enableval}" != "no"; then
 329    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 330    [Define this to use a lisp union for the Lisp_Object data type.])
 331 fi)
 332
 333
 334 AC_ARG_ENABLE(profiling,
 335 [AS_HELP_STRING([--enable-profiling],
 336                 [build emacs with profiling support.
 337                  This might not work on all platforms])],
 338 [ac_enable_profiling="${enableval}"],[])
 339 if test x$ac_enable_profiling != x ; then
 340    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 341 else
 342    PROFILING_CFLAGS=
 343 fi
 344 AC_SUBST(PROFILING_CFLAGS)
 345
 346 AC_ARG_ENABLE(autodepend,
 347 [AS_HELP_STRING([--enable-autodepend],
 348                 [automatically generate dependencies to .h-files.
 349                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 350                  found])],
 351 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 352
 353 #### Make srcdir absolute, if it isn't already.  It's important to
 354 #### avoid running the path through pwd unnecessarily, since pwd can
 355 #### give you automounter prefixes, which can go away.  We do all this
 356 #### so Emacs can find its files when run uninstalled.
 357 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 358 unset CDPATH
 359 case "${srcdir}" in
 360   /* ) ;;
 361   . )
 362     ## We may be able to use the $PWD environment variable to make this
 363     ## absolute.  But sometimes PWD is inaccurate.
 364     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 365     ## but that tested only for a well-formed and valid PWD,
 366     ## it did not object when PWD was well-formed and valid but just wrong.
 367     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 368     then
 369       srcdir="$PWD"
 370     else
 371       srcdir="`(cd ${srcdir}; pwd)`"
 372     fi
 373   ;;
 374   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 375 esac
 376
 377 #### Given the configuration name, set machfile and opsysfile to the
 378 #### names of the m/*.h and s/*.h files we should use.
 379
 380 ### Canonicalize the configuration name.
 381
 382 AC_CANONICAL_HOST
 383 canonical=$host
 384 configuration=${host_alias-${build_alias-$host}}
 385
 386 dnl This used to use changequote, but, apart from `changequote is evil'
 387 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 388 dnl the great gob of text.  Thus it's not processed for possible expansion.
 389 dnl Just make sure the brackets remain balanced.
 390 dnl
 391 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 392 dnl indicated by comments.
 393 dnl quotation begins
 394 [
 395
 396 ### If you add support for a new configuration, add code to this
 397 ### switch statement to recognize your configuration name and select
 398 ### the appropriate operating system and machine description files.
 399
 400 ### You would hope that you could choose an m/*.h file pretty much
 401 ### based on the machine portion of the configuration name, and an s/*.h
 402 ### file based on the operating system portion.  However, it turns out
 403 ### that each m/*.h file is pretty manufacturer-specific - for
 404 ### example mips.h is MIPS
 405 ### So we basically have to have a special case for each
 406 ### configuration name.
 407 ###
 408 ### As far as handling version numbers on operating systems is
 409 ### concerned, make sure things will fail in a fixable way.  If
 410 ### /etc/MACHINES doesn't say anything about version numbers, be
 411 ### prepared to handle anything reasonably.  If version numbers
 412 ### matter, be sure /etc/MACHINES says something about it.
 413
 414 machine='' opsys='' unported=no
 415 case "${canonical}" in
 416
 417   ## GNU/Linux and similar ports
 418   *-*-linux* )
 419     opsys=gnu-linux
 420     case ${canonical} in
 421       alpha*)   machine=alpha ;;
 422       s390x-*)  machine=ibms390x ;;
 423       powerpc*) machine=macppc ;;
 424       sparc*)   machine=sparc ;;
 425       ia64*)    machine=ia64 ;;
 426       m68k*)    machine=m68k ;;
 427       x86_64*)  machine=amdx86-64 ;;
 428     esac
 429   ;;
 430
 431   ## FreeBSD ports
 432   *-*-freebsd* )
 433     opsys=freebsd
 434     case "${canonical}" in
 435       alpha*)           machine=alpha ;;
 436       amd64-*|x86_64-*) machine=amdx86-64 ;;
 437       ia64-*)           machine=ia64 ;;
 438       i[3456]86-*)      machine=intel386 ;;
 439       powerpc-*)        machine=macppc ;;
 440       sparc-*)          machine=sparc ;;
 441       sparc64-*)        machine=sparc ;;
 442     esac
 443   ;;
 444
 445   ## FreeBSD kernel + glibc based userland
 446   *-*-kfreebsd*gnu* )
 447     opsys=gnu-kfreebsd
 448     case "${canonical}" in
 449       alpha*)           machine=alpha ;;
 450       amd64-*|x86_64-*) machine=amdx86-64 ;;
 451       ia64-*)           machine=ia64 ;;
 452       i[3456]86-*)      machine=intel386 ;;
 453       powerpc-*)        machine=macppc ;;
 454       sparc-*)          machine=sparc ;;
 455       sparc64-*)        machine=sparc ;;
 456     esac
 457   ;;
 458
 459   ## NetBSD ports
 460   *-*-netbsd* )
 461     opsys=netbsd
 462     case "${canonical}" in
 463       alpha*)      machine=alpha ;;
 464       x86_64-*)    machine=amdx86-64 ;;
 465       i[3456]86-*) machine=intel386 ;;
 466       m68k-*)      machine=m68k ;;
 467       powerpc-*)   machine=macppc ;;
 468       sparc*-)     machine=sparc ;;
 469       vax-*)       machine=vax ;;
 470     esac
 471   ;;
 472
 473   ## OpenBSD ports
 474   *-*-openbsd* )
 475     opsys=openbsd
 476     case "${canonical}" in
 477       alpha*)    machine=alpha ;;
 478       x86_64-*)  machine=amdx86-64 ;;
 479       i386-*)    machine=intel386 ;;
 480       powerpc-*) machine=macppc ;;
 481       sparc*)    machine=sparc ;;
 482       vax-*)     machine=vax ;;
 483     esac
 484   ;;
 485
 486   ## Apple Darwin / Mac OS X
 487   *-apple-darwin* )
 488     case "${canonical}" in
 489       i[3456]86-* )  machine=intel386 ;;
 490       powerpc-* )    machine=macppc ;;
 491       x86_64-* )     machine=amdx86-64 ;;
 492       * )            unported=yes ;;
 493     esac
 494     opsys=darwin
 495     # Define CPP as follows to make autoconf work correctly.
 496     CPP="${CC-cc} -E -no-cpp-precomp"
 497     # Use fink packages if available.
 498     if test -d /sw/include && test -d /sw/lib; then
 499       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 500       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 501       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 502     fi
 503   ;;
 504
 505   ## HP 9000 series 700 and 800, running HP/UX
 506   hppa*-hp-hpux10.2* )
 507     opsys=hpux10-20
 508   ;;
 509   hppa*-hp-hpux1[1-9]* )
 510     opsys=hpux11
 511     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 512   ;;
 513
 514   ## IBM machines
 515   rs6000-ibm-aix4.[23]* )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   powerpc-ibm-aix4.[23]*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   rs6000-ibm-aix[56]* )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524   powerpc-ibm-aix[56]*  )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527
 528   ## Silicon Graphics machines
 529   ## Iris 4D
 530   mips-sgi-irix6.5 )
 531     opsys=irix6-5
 532     # Without defining _LANGUAGE_C, things get masked out in the headers
 533     # so that, for instance, grepping for `free' in stdlib.h fails and
 534     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 535     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 536     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 537   ;;
 538
 539   ## Suns
 540   *-sun-solaris* \
 541     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 542     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 543     case "${canonical}" in
 544       i[3456]86-*-* )     machine=intel386 ;;
 545       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 546       sparc* )          machine=sparc ;;
 547       * )               unported=yes ;;
 548     esac
 549     case "${canonical}" in
 550       *-sunos5.6* | *-solaris2.6* )
 551                 opsys=sol2-6
 552                 NON_GNU_CPP=/usr/ccs/lib/cpp
 553                 RANLIB="ar -ts"
 554                 ;;
 555       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 556                 opsys=sol2-6
 557                 emacs_check_sunpro_c=yes
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 ;;
 560       *-sunos5* | *-solaris* )
 561                 opsys=sol2-10
 562                 emacs_check_sunpro_c=yes
 563                 NON_GNU_CPP=/usr/ccs/lib/cpp
 564                 ;;
 565     esac
 566     ## Watch out for a compiler that we know will not work.
 567     case "${canonical}" in
 568      *-solaris* | *-sunos5* )
 569                 if [ "x$CC" = x/usr/ucb/cc ]; then
 570                   ## /usr/ucb/cc doesn't work;
 571                   ## we should find some other compiler that does work.
 572                   unset CC
 573                 fi
 574                 ;;
 575       *) ;;
 576     esac
 577   ;;
 578
 579   ## Intel 386 machines where we don't care about the manufacturer.
 580   i[3456]86-*-* )
 581     machine=intel386
 582     case "${canonical}" in
 583       *-cygwin )                opsys=cygwin ;;
 584       *-darwin* )               opsys=darwin
 585                                 CPP="${CC-cc} -E -no-cpp-precomp"
 586                                 ;;
 587       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 588       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 589       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 591     esac
 592   ;;
 593
 594   * )
 595     unported=yes
 596   ;;
 597 esac
 598
 599 ### If the code above didn't choose an operating system, just choose
 600 ### an operating system based on the configuration name.  You really
 601 ### only want to use this when you have no idea what the right
 602 ### operating system is; if you know what operating systems a machine
 603 ### runs, it's cleaner to make it explicit in the case statement
 604 ### above.
 605 if test x"${opsys}" = x; then
 606   case "${canonical}" in
 607     *-gnu* )                            opsys=gnu ;;
 608     * )
 609       unported=yes
 610     ;;
 611   esac
 612 fi
 613
 614 ]
 615 dnl quotation ends
 616
 617 if test $unported = yes; then
 618   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 619 Check `etc/MACHINES' for recognized configuration names.])
 620 fi
 621
 622 if test -n "$machine"; then
 623   machfile="m/${machine}.h"
 624 else
 625   machfile=
 626 fi
 627 opsysfile="s/${opsys}.h"
 628
 629
 630 #### Choose a compiler.
 631 test -n "$CC" && cc_specified=yes
 632
 633 # Save the value of CFLAGS that the user specified.
 634 SPECIFIED_CFLAGS="$CFLAGS"
 635
 636 dnl Sets GCC=yes if using gcc.
 637 AC_PROG_CC
 638 AM_PROG_CC_C_O
 639
 640 # Initialize gnulib right after verifying that the C compiler works.
 641 gl_EARLY
 642
 643 # On Suns, sometimes $CPP names a directory.
 644 if test -n "$CPP" && test -d "$CPP"; then
 645   CPP=
 646 fi
 647
 648 ## If not using gcc, and on Solaris, and no CPP specified, see if
 649 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 650 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 651  test x"$CPP" = x; then
 652   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 653   AC_CACHE_VAL(emacs_cv_sunpro_c,
 654   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 655 [[#ifndef __SUNPRO_C
 656 fail;
 657 #endif
 658 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 659   AC_MSG_RESULT($emacs_cv_sunpro_c)
 660
 661   if test x"$emacs_cv_sunpro_c" = xyes; then
 662     NON_GNU_CPP="$CC -E -Xs"
 663   fi
 664 fi
 665
 666 #### Some systems specify a CPP to use unless we are using GCC.
 667 #### Now that we know whether we are using GCC, we can decide whether
 668 #### to use that one.
 669 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 670 then
 671   CPP="$NON_GNU_CPP"
 672 fi
 673
 674 #### Some systems specify a CC to use unless we are using GCC.
 675 #### Now that we know whether we are using GCC, we can decide whether
 676 #### to use that one.
 677 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 678   test x$cc_specified != xyes
 679 then
 680   CC="$NON_GNU_CC"
 681 fi
 682
 683 if test x$GCC = xyes; then
 684   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 685 else
 686   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 687 fi
 688
 689 ### Use -Wdeclaration-after-statement if the compiler supports it
 690 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 691 SAVE_CFLAGS="$CFLAGS"
 692 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 693 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 694 if test $has_option = yes; then
 695    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 696 fi
 697 AC_MSG_RESULT($has_option)
 698 CFLAGS="$SAVE_CFLAGS"
 699 unset has_option
 700 unset SAVE_CFLAGS
 701
 702 ### Use -Wold-style-definition if the compiler supports it
 703 # This can be removed when conversion to standard C is finished.
 704 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 705 SAVE_CFLAGS="$CFLAGS"
 706 CFLAGS="$CFLAGS -Wold-style-definition"
 707 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 708 if test $has_option = yes; then
 709    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 710 fi
 711 AC_MSG_RESULT($has_option)
 712 CFLAGS="$SAVE_CFLAGS"
 713 unset has_option
 714 unset SAVE_CFLAGS
 715
 716 ### Use -Wimplicit-function-declaration if the compiler supports it
 717 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 718 SAVE_CFLAGS="$CFLAGS"
 719 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 720 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 721 if test $has_option = yes; then
 722    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 723 fi
 724 AC_MSG_RESULT($has_option)
 725 CFLAGS="$SAVE_CFLAGS"
 726 unset has_option
 727 unset SAVE_CFLAGS
 728
 729 AC_SUBST(C_WARNINGS_SWITCH)
 730
 731
 732 #### Some other nice autoconf tests.
 733
 734 dnl checks for programs
 735 AC_PROG_CPP
 736 AC_PROG_INSTALL
 737 if test "x$RANLIB" = x; then
 738   AC_PROG_RANLIB
 739 fi
 740
 741 ## Although we're running on an amd64 kernel, we're actually compiling for
 742 ## the x86 architecture.  The user should probably have provided an
 743 ## explicit --build to `configure', but if everything else than the kernel
 744 ## is running in i386 mode, we can help them out.
 745 if test "$machine" = "amdx86-64"; then
 746   AC_CHECK_DECL([i386])
 747   if test "$ac_cv_have_decl_i386" = "yes"; then
 748     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 749     machine=intel386
 750     machfile="m/${machine}.h"
 751   fi
 752   AC_CHECK_DECL([__ILP32__], [machfile="m/intel386.h"])
 753 fi
 754
 755 AC_PATH_PROG(INSTALL_INFO, install-info)
 756 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 757 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 758 dnl Don't use GZIP, which is used by gzip for additional parameters.
 759 AC_PATH_PROG(GZIP_PROG, gzip)
 760
 761
 762 ## Need makeinfo >= 4.6 (?) to build the manuals.
 763 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 764 dnl By this stage, configure has already checked for egrep and set EGREP,
 765 dnl or exited with an error if no egrep was found.
 766 if test "$MAKEINFO" != "no" && \
 767   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 768    MAKEINFO=no
 769 fi
 770
 771 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 772 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 773 ## therefore in the category of "special tools" not normally required, which
 774 ## configure does not have to check for (eg autoconf itself).
 775 ## In a Bazaar checkout on the other hand, the manuals are not included.
 776 ## So makeinfo is a requirement to build from Bazaar, and configure
 777 ## should test for it as it does for any other build requirement.
 778 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 779 ## with pre-built manuals, from a Bazaar checkout.
 780 HAVE_MAKEINFO=yes
 781
 782 if test "$MAKEINFO" = "no"; then
 783   MAKEINFO=makeinfo
 784   if test "x${with_makeinfo}" = "xno"; then
 785     HAVE_MAKEINFO=no
 786   elif test ! -e $srcdir/info/emacs; then
 787     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 788 source tree does not seem to have pre-built manuals in the `info' directory.
 789 Either install a suitable version of makeinfo, or re-run configure
 790 with the `--without-makeinfo' option to build without the manuals.] )
 791   fi
 792 fi
 793 AC_SUBST(HAVE_MAKEINFO)
 794
 795 dnl Add our options to ac_link now, after it is set up.
 796
 797 if test x$GCC = xyes; then
 798   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 799     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 800 else
 801   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 802     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 803 fi
 804
 805 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 806 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 807 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 808 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 809 dnl if not built to support GNU ld.
 810
 811 late_LDFLAGS=$LDFLAGS
 812 if test x$GCC = xyes; then
 813   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 814 else
 815   LDFLAGS="$LDFLAGS -znocombreloc"
 816 fi
 817
 818 AC_MSG_CHECKING([for -znocombreloc])
 819 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 820   [AC_MSG_RESULT(yes)],
 821   LDFLAGS=$late_LDFLAGS
 822   [AC_MSG_RESULT(no)])
 823
 824
 825 # The value of CPP is a quoted variable reference, so we need to do this
 826 # to get its actual value...
 827 CPP=`eval "echo $CPP"`
 828
 829
 830 dnl The function dump-emacs will not be defined and temacs will do
 831 dnl (load "loadup") automatically unless told otherwise.
 832 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 833 case "$opsys" in
 834   your-opsys-here) CANNOT_DUMP=yes ;;
 835 esac
 836
 837 test "$CANNOT_DUMP" = "yes" && \
 838   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 839
 840 AC_SUBST(CANNOT_DUMP)
 841
 842
 843 UNEXEC_OBJ=unexelf.o
 844 case "$opsys" in
 845   # MSDOS uses unexcoff.o
 846   # MSWindows uses unexw32.o
 847   aix4-2)
 848    UNEXEC_OBJ=unexaix.o
 849    ;;
 850   cygwin)
 851    UNEXEC_OBJ=unexcw.o
 852    ;;
 853   darwin)
 854    UNEXEC_OBJ=unexmacosx.o
 855    ;;
 856   hpux10-20 | hpux11)
 857    UNEXEC_OBJ=unexhp9k800.o
 858    ;;
 859   sol2-10)
 860    # Use the Solaris dldump() function, called from unexsol.c, to dump
 861    # emacs, instead of the generic ELF dump code found in unexelf.c.
 862    # The resulting binary has a complete symbol table, and is better
 863    # for debugging and other observability tools (debuggers, pstack, etc).
 864    #
 865    # If you encounter a problem using dldump(), please consider sending
 866    # a message to the OpenSolaris tools-linking mailing list:
 867    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 868    #
 869    # It is likely that dldump() works with older Solaris too, but this has
 870    # not been tested, so for now this change is for Solaris 10 or newer.
 871    UNEXEC_OBJ=unexsol.o
 872    ;;
 873 esac
 874
 875 LD_SWITCH_SYSTEM=
 876 case "$opsys" in
 877   freebsd)
 878    ## Let `ld' find image libs and similar things in /usr/local/lib.
 879    ## The system compiler, GCC, has apparently been modified to not
 880    ## look there, contrary to what a stock GCC would do.
 881    LD_SWITCH_SYSTEM=-L/usr/local/lib
 882    ;;
 883
 884   gnu-linux)
 885    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 886    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 887    ;;
 888
 889   netbsd)
 890    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 891    ;;
 892
 893   openbsd)
 894    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 895    ## otherwise Emacs dumps core on elf systems.
 896    LD_SWITCH_SYSTEM="-Z"
 897    ;;
 898 esac
 899 AC_SUBST(LD_SWITCH_SYSTEM)
 900
 901 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 902
 903 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 904 ## which has not been defined yet.  When this was handled with cpp,
 905 ## it was expanded to null when configure sourced the s/*.h file.
 906 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 907 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 908 ## (or somesuch), but because it is supposed to go at the _front_
 909 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 910 ## Compare with the gnu-linux case below, which added to the end
 911 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 912 ## LD_SWITCH_SYSTEM_TEMACS.
 913 case "$opsys" in
 914   netbsd|openbsd)
 915    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 916    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 917 esac
 918
 919
 920 C_SWITCH_MACHINE=
 921 if test "$machine" = "alpha"; then
 922   AC_CHECK_DECL([__ELF__])
 923   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 924     ## With ELF, make sure that all common symbols get allocated to in the
 925     ## data section.  Otherwise, the dump of temacs may miss variables in
 926     ## the shared library that have been initialized.  For example, with
 927     ## GNU libc, __malloc_initialized would normally be resolved to the
 928     ## shared library's .bss section, which is fatal.
 929     if test "x$GCC" = "xyes"; then
 930       C_SWITCH_MACHINE="-fno-common"
 931     else
 932       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 933     fi
 934   else
 935     UNEXEC_OBJ=unexalpha.o
 936   fi
 937 fi
 938 AC_SUBST(C_SWITCH_MACHINE)
 939
 940 AC_SUBST(UNEXEC_OBJ)
 941
 942 C_SWITCH_SYSTEM=
 943 ## Some programs in src produce warnings saying certain subprograms
 944 ## are too complex and need a MAXMEM value greater than 2000 for
 945 ## additional optimization.  --nils@exp-math.uni-essen.de
 946 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 947   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 948 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 949 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 950 AC_SUBST(C_SWITCH_SYSTEM)
 951
 952
 953 LIBS_SYSTEM=
 954 case "$opsys" in
 955   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 956   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 957
 958   freebsd) LIBS_SYSTEM="-lutil" ;;
 959
 960   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 961
 962   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 963
 964   ## Motif needs -lgen.
 965   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 966 esac
 967 AC_SUBST(LIBS_SYSTEM)
 968
 969
 970 ### Make sure subsequent tests use flags consistent with the build flags.
 971
 972 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 973   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 974 else
 975   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 976 fi
 977
 978 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 979 AC_DEFUN([AC_TYPE_SIZE_T])
 980 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 981 AC_DEFUN([AC_TYPE_UID_T])
 982
 983 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 984 AC_SYS_LARGEFILE
 985
 986
 987 LIB_MATH=-lm
 988 LIB_STANDARD=
 989 START_FILES=
 990
 991 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 992 case $opsys in
 993   cygwin )
 994     LIB_MATH=
 995     START_FILES='pre-crt0.o'
 996     ;;
 997   darwin )
 998     ## Adding -lm confuses the dynamic linker, so omit it.
 999     LIB_MATH=
1000     START_FILES='pre-crt0.o'
1001     ;;
1002   freebsd )
1003     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1004     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1005     ;;
1006   gnu-linux | gnu-kfreebsd )
1007     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1008     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1009     ;;
1010   hpux10-20 | hpux11 )
1011     LIB_STANDARD=-lc
1012     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1013     ;;
1014   dnl NB this may be adjusted below.
1015   netbsd | openbsd )
1016     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1017     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1018     ;;
1019 esac
1020
1021 AC_SUBST(LIB_MATH)
1022 AC_SUBST(START_FILES)
1023
1024 dnl Not all platforms use crtn.o files.  Check if the current one does.
1025 crt_files=
1026
1027 for file in x $LIB_STANDARD $START_FILES; do
1028   case "$file" in
1029     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1030   esac
1031 done
1032
1033 if test "x$crt_files" != x; then
1034
1035   ## If user specified a crt-dir, use that unconditionally.
1036   crt_gcc=no
1037
1038   if test "X$CRT_DIR" = "X"; then
1039
1040     CRT_DIR=/usr/lib            # default
1041
1042     case "$canonical" in
1043       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1044       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1045       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1046       ## For anything else (eg /usr/lib32), it is up the user to specify
1047       ## the location (bug#5655).
1048       ## Test for crtn.o, not just the directory, because sometimes the
1049       ## directory exists but does not have the relevant files (bug#1287).
1050       ## FIXME better to test for binary compatibility somehow.
1051       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1052       ;;
1053
1054       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1055     esac
1056
1057     case "$opsys" in
1058       hpux10-20) CRT_DIR=/lib ;;
1059     esac
1060
1061     test "x${GCC}" = xyes && crt_gcc=yes
1062
1063   fi                            # CRT_DIR = ""
1064
1065   crt_missing=
1066
1067   for file in $crt_files; do
1068
1069     ## If we're using gcc, try to determine it automatically by asking
1070     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1071     ## system-dependent default from above.]
1072     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1073
1074        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1075        case "$crt_file" in
1076          */*)
1077            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1078            ;;
1079        esac
1080     fi
1081
1082     dnl We expect all the files to be in a single directory, so after the
1083     dnl first there is no point asking gcc.
1084     crt_gcc=no
1085
1086     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1087   done                          # $crt_files
1088
1089   test "x$crt_missing" = x || \
1090     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1091 Try using the --with-crt-dir option.])
1092
1093 fi                              # crt_files != ""
1094
1095 AC_SUBST(CRT_DIR)
1096
1097 case $opsys in
1098   netbsd | openbsd )
1099     if test -f $CRT_DIR/crti.o; then
1100
1101         test -f $CRT_DIR/crtn.o || \
1102           AC_MSG_ERROR([Required file not found: crtn.o])
1103
1104         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1105         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1106     fi
1107     ;;
1108 esac
1109
1110
1111 dnl This function definition taken from Gnome 2.0
1112 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1113 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1114 dnl also defines GSTUFF_PKG_ERRORS on error
1115 AC_DEFUN([PKG_CHECK_MODULES], [
1116   succeeded=no
1117
1118   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1119
1120   if test "$PKG_CONFIG" = "no" ; then
1121      ifelse([$4], , [AC_MSG_ERROR([
1122       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1123   else
1124      PKG_CONFIG_MIN_VERSION=0.9.0
1125      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1126         AC_MSG_CHECKING(for $2)
1127
1128         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1129             AC_MSG_RESULT(yes)
1130             succeeded=yes
1131
1132             AC_MSG_CHECKING($1_CFLAGS)
1133             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1134             AC_MSG_RESULT($$1_CFLAGS)
1135
1136             AC_MSG_CHECKING($1_LIBS)
1137             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1138             AC_MSG_RESULT($$1_LIBS)
1139         else
1140             AC_MSG_RESULT(no)
1141             $1_CFLAGS=""
1142             $1_LIBS=""
1143             ## If we have a custom action on failure, don't print errors, but
1144             ## do set a variable so people can do so.
1145             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1146             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1147         fi
1148
1149         AC_SUBST($1_CFLAGS)
1150         AC_SUBST($1_LIBS)
1151      else
1152         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1153         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1154      fi
1155   fi
1156
1157   if test $succeeded = yes; then
1158      ifelse([$3], , :, [$3])
1159   else
1160      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1161   fi
1162 ])
1163
1164
1165 if test "${with_sound}" != "no"; then
1166   # Sound support for GNU/Linux and the free BSDs.
1167   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1168     have_sound_header=yes)
1169   # Emulation library used on NetBSD.
1170   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1171   AC_SUBST(LIBSOUND)
1172
1173   ALSA_REQUIRED=1.0.0
1174   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1175   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1176   if test $HAVE_ALSA = yes; then
1177     SAVE_CFLAGS="$CFLAGS"
1178     SAVE_LIBS="$LIBS"
1179     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1180     LIBS="$ALSA_LIBS $LIBS"
1181     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1182                     emacs_alsa_normal=yes,
1183                     emacs_alsa_normal=no)
1184     if test "$emacs_alsa_normal" != yes; then
1185       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1186                      [[snd_lib_error_set_handler (0);]])],
1187                      emacs_alsa_subdir=yes,
1188                      emacs_alsa_subdir=no)
1189       if test "$emacs_alsa_subdir" != yes; then
1190         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1191       fi
1192       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1193     fi
1194
1195     CFLAGS="$SAVE_CFLAGS"
1196     LIBS="$SAVE_LIBS"
1197     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1198     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1199     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1200   fi
1201
1202   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1203   dnl compiles only on the specified platforms.  For others, it
1204   dnl probably doesn't make sense to try.
1205   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1206      case "$opsys" in
1207        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1208        gnu-linux|freebsd|netbsd)
1209          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1210          ;;
1211      esac
1212   fi
1213
1214   AC_SUBST(CFLAGS_SOUND)
1215 fi
1216
1217 dnl checks for header files
1218 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1219   linux/version.h sys/systeminfo.h \
1220   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1221   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1222   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1223
1224 AC_MSG_CHECKING(if personality LINUX32 can be set)
1225 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1226                emacs_cv_personality_linux32=yes,
1227                emacs_cv_personality_linux32=no)
1228 AC_MSG_RESULT($emacs_cv_personality_linux32)
1229
1230 if test $emacs_cv_personality_linux32 = yes; then
1231   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1232             [Define to 1 if personality LINUX32 can be set.])
1233 fi
1234
1235 dnl On Solaris 8 there's a compilation warning for term.h because
1236 dnl it doesn't define `bool'.
1237 AC_CHECK_HEADERS(term.h, , , -)
1238 AC_HEADER_TIME
1239 AC_CHECK_DECLS([sys_siglist])
1240 if test $ac_cv_have_decl_sys_siglist != yes; then
1241   # For Tru64, at least:
1242   AC_CHECK_DECLS([__sys_siglist])
1243   if test $ac_cv_have_decl___sys_siglist = yes; then
1244     AC_DEFINE(sys_siglist, __sys_siglist,
1245               [Define to any substitute for sys_siglist.])
1246   fi
1247 fi
1248 AC_HEADER_SYS_WAIT
1249
1250 dnl Some systems have utime.h but don't declare the struct anyplace.
1251 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1252 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1253 #include <sys/time.h>
1254 #include <time.h>
1255 #else
1256 #ifdef HAVE_SYS_TIME_H
1257 #include <sys/time.h>
1258 #else
1259 #include <time.h>
1260 #endif
1261 #endif
1262 #ifdef HAVE_UTIME_H
1263 #include <utime.h>
1264 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1265   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1266 if test $emacs_cv_struct_utimbuf = yes; then
1267   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1268 fi
1269
1270 dnl Check for speed_t typedef.
1271 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1272   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1273     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1274 if test $emacs_cv_speed_t = yes; then
1275   AC_DEFINE(HAVE_SPEED_T, 1,
1276            [Define to 1 if `speed_t' is declared by <termios.h>.])
1277 fi
1278
1279 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1280 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1281 #include <sys/time.h>
1282 #include <time.h>
1283 #else
1284 #ifdef HAVE_SYS_TIME_H
1285 #include <sys/time.h>
1286 #else
1287 #include <time.h>
1288 #endif
1289 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1290   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1291 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1292 if test $emacs_cv_struct_timeval = yes; then
1293   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1294 fi
1295
1296 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1297 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1298 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1299   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1300 HAVE_EXCEPTION=$emacs_cv_struct_exception
1301 if test $emacs_cv_struct_exception != yes; then
1302   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1303 fi
1304
1305 AC_CHECK_HEADERS(sys/socket.h)
1306 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1307 #if HAVE_SYS_SOCKET_H
1308 #include <sys/socket.h>
1309 #endif])
1310 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1311 #if HAVE_SYS_SOCKET_H
1312 #include <sys/socket.h>
1313 #endif])
1314 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1315 #if HAVE_SYS_SOCKET_H
1316 #include <sys/socket.h>
1317 #endif])
1318 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1319
1320 dnl checks for structure members
1321 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1322                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1323                   struct ifreq.ifr_addr,
1324                   struct ifreq.ifr_addr.sa_len], , ,
1325                  [AC_INCLUDES_DEFAULT
1326 #if HAVE_SYS_SOCKET_H
1327 #include <sys/socket.h>
1328 #endif
1329 #if HAVE_NET_IF_H
1330 #include <net/if.h>
1331 #endif])
1332
1333 dnl checks for compiler characteristics
1334
1335 dnl Testing __STDC__ to determine prototype support isn't good enough.
1336 dnl DEC C, for instance, doesn't define it with default options, and
1337 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1338 dnl and void *.
1339 AC_C_PROTOTYPES
1340 AC_C_VOLATILE
1341 AC_C_CONST
1342 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1343   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1344                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1345 if test $emacs_cv_void_star = yes; then
1346   AC_DEFINE(POINTER_TYPE, void)
1347 else
1348   AC_DEFINE(POINTER_TYPE, char)
1349 fi
1350 AH_TEMPLATE(POINTER_TYPE,
1351             [Define as `void' if your compiler accepts `void *'; otherwise
1352              define as `char'.])dnl
1353
1354 dnl Check for endianness.
1355 AC_C_BIGENDIAN
1356
1357 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1358   [emacs_cv_attribute_aligned],
1359   [AC_COMPILE_IFELSE(
1360      [AC_LANG_PROGRAM(
1361         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1362         [[]])],
1363      [emacs_cv_attribute_aligned=yes],
1364      [emacs_cv_attribute_aligned=no])])
1365 if test $emacs_cv_attribute_aligned = yes; then
1366   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1367     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1368 fi
1369
1370 dnl check for Make feature
1371 AC_PROG_MAKE_SET
1372
1373 DEPFLAGS=
1374 MKDEPDIR=":"
1375 deps_frag=deps.mk
1376 dnl check for GNU Make if we have GCC and autodepend is on.
1377 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1378    AC_MSG_CHECKING([whether we are using GNU Make])
1379    HAVE_GNU_MAKE=no
1380    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1381    if test "x$testval" != x; then
1382       HAVE_GNU_MAKE=yes
1383    else
1384       ac_enable_autodepend=no
1385    fi
1386    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1387    if test $HAVE_GNU_MAKE = yes; then
1388       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1389       SAVE_CFLAGS="$CFLAGS"
1390       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1391       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1392       CFLAGS="$SAVE_CFLAGS"
1393       test -f deps.d || ac_enable_autodepend=no
1394       rm -rf deps.d
1395       AC_MSG_RESULT([$ac_enable_autodepend])
1396    fi
1397    if test $ac_enable_autodepend = yes; then
1398       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1399       ## In parallel builds, another make might create depdir between
1400       ## the first test and mkdir, so stick another test on the end.
1401       ## Or use install-sh -d?  mkdir -p is not portable.
1402       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1403       deps_frag=autodeps.mk
1404    fi
1405 fi
1406 deps_frag=$srcdir/src/$deps_frag
1407 AC_SUBST(MKDEPDIR)
1408 AC_SUBST(DEPFLAGS)
1409 AC_SUBST_FILE(deps_frag)
1410
1411
1412 lisp_frag=$srcdir/src/lisp.mk
1413 AC_SUBST_FILE(lisp_frag)
1414
1415
1416 dnl checks for operating system services
1417 AC_SYS_LONG_FILE_NAMES
1418
1419 #### Choose a window system.
1420
1421 AC_PATH_X
1422 if test "$no_x" = yes; then
1423   window_system=none
1424 else
1425   window_system=x11
1426 fi
1427
1428 ## Workaround for bug in autoconf <= 2.62.
1429 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1430 ## No need to do anything special for these standard directories.
1431 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1432
1433    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1434
1435 fi
1436
1437 LD_SWITCH_X_SITE_AUX=
1438 LD_SWITCH_X_SITE_AUX_RPATH=
1439 if test "${x_libraries}" != NONE; then
1440   if test -n "${x_libraries}"; then
1441     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1442     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1443     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1444   fi
1445   x_default_search_path=""
1446   x_search_path=${x_libraries}
1447   if test -z "${x_search_path}"; then
1448     x_search_path=/usr/lib
1449   fi
1450   for x_library in `echo ${x_search_path}: | \
1451                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1452     x_search_path="\
1453 ${x_library}/X11/%L/%T/%N%C%S:\
1454 ${x_library}/X11/%l/%T/%N%C%S:\
1455 ${x_library}/X11/%T/%N%C%S:\
1456 ${x_library}/X11/%L/%T/%N%S:\
1457 ${x_library}/X11/%l/%T/%N%S:\
1458 ${x_library}/X11/%T/%N%S"
1459     if test x"${x_default_search_path}" = x; then
1460       x_default_search_path=${x_search_path}
1461     else
1462       x_default_search_path="${x_search_path}:${x_default_search_path}"
1463     fi
1464   done
1465 fi
1466 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1467 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1468
1469 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1470   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1471 fi
1472
1473 if test x"${x_includes}" = x; then
1474   bitmapdir=/usr/include/X11/bitmaps
1475 else
1476   # accumulate include directories that have X11 bitmap subdirectories
1477   bmd_acc="dummyval"
1478   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1479     if test -d "${bmd}/X11/bitmaps"; then
1480       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1481     fi
1482     if test -d "${bmd}/bitmaps"; then
1483       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1484     fi
1485   done
1486   if test ${bmd_acc} != "dummyval"; then
1487     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1488   fi
1489 fi
1490
1491 HAVE_NS=no
1492 NS_IMPL_COCOA=no
1493 NS_IMPL_GNUSTEP=no
1494 tmp_CPPFLAGS="$CPPFLAGS"
1495 tmp_CFLAGS="$CFLAGS"
1496 CPPFLAGS="$CPPFLAGS -x objective-c"
1497 CFLAGS="$CFLAGS -x objective-c"
1498 TEMACS_LDFLAGS2="\${LDFLAGS}"
1499 GNU_OBJC_CFLAGS=
1500 dnl I don't think it's especially important, but src/Makefile.in
1501 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1502 dnl trailing "/" to it, so now we do it here.
1503 if test "${with_ns}" != no; then
1504   if test "${opsys}" = darwin; then
1505      NS_IMPL_COCOA=yes
1506      ns_appdir=`pwd`/nextstep/Emacs.app
1507      ns_appbindir=${ns_appdir}/Contents/MacOS/
1508      ns_appresdir=${ns_appdir}/Contents/Resources
1509      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1510   elif test -f $GNUSTEP_CONFIG_FILE; then
1511      NS_IMPL_GNUSTEP=yes
1512      ns_appdir=`pwd`/nextstep/Emacs.app
1513      ns_appbindir=${ns_appdir}/
1514      ns_appresdir=${ns_appdir}/Resources
1515      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1516      dnl FIXME sourcing this several times in subshells seems inefficient.
1517      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1518      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1519      dnl I seemed to need these as well with GNUstep-startup 0.25.
1520      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1521      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1522      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1523        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1524      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1525        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1526      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1527      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1528      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1529      LIB_STANDARD=
1530      START_FILES=
1531      TEMACS_LDFLAGS2=
1532      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1533      dnl If they had chosen to either define it or not, we could have
1534      dnl just used AC_CHECK_DECL here.
1535      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1536        emacs_cv_objc_exceptions,
1537 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1538 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1539 1;
1540 #else
1541 fail;
1542 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1543      if test $emacs_cv_objc_exceptions = yes; then
1544        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1545        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1546          [Define if GNUstep uses ObjC exceptions.])
1547        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1548      fi
1549   fi
1550
1551   dnl This is only used while we test the NS headers, it gets reset below.
1552   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1553
1554   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1555                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1556   files are missing or cannot be compiled.])])
1557   NS_HAVE_NSINTEGER=yes
1558   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1559                                      [NSInteger i;])],
1560                     ns_have_nsinteger=yes,
1561                     ns_have_nsinteger=no)
1562   if test $ns_have_nsinteger = no; then
1563     NS_HAVE_NSINTEGER=no
1564   fi
1565 fi
1566 AC_SUBST(TEMACS_LDFLAGS2)
1567
1568 ns_frag=/dev/null
1569 NS_OBJ=
1570 NS_OBJC_OBJ=
1571 if test "${HAVE_NS}" = yes; then
1572   if test "$with_toolkit_scroll_bars" = "no"; then
1573     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1574   fi
1575
1576   window_system=nextstep
1577   with_xft=no
1578   # set up packaging dirs
1579   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1580      prefix=${ns_appresdir}
1581      exec_prefix=${ns_appbindir}
1582      libexecdir=${ns_appbindir}/libexec
1583   fi
1584   ns_frag=$srcdir/src/ns.mk
1585   NS_OBJ="fontset.o fringe.o image.o"
1586   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1587 fi
1588 CFLAGS="$tmp_CFLAGS"
1589 CPPFLAGS="$tmp_CPPFLAGS"
1590 AC_SUBST(NS_OBJ)
1591 AC_SUBST(NS_OBJC_OBJ)
1592 AC_SUBST(LIB_STANDARD)
1593 AC_SUBST_FILE(ns_frag)
1594
1595 case "${window_system}" in
1596   x11 )
1597     HAVE_X_WINDOWS=yes
1598     HAVE_X11=yes
1599     case "${with_x_toolkit}" in
1600       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1601       motif ) USE_X_TOOLKIT=MOTIF ;;
1602       gtk ) with_gtk=yes
1603 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1604 dnl USE_X_TOOLKIT is set.
1605             USE_X_TOOLKIT=none ;;
1606       gtk3 ) with_gtk3=yes
1607              USE_X_TOOLKIT=none ;;
1608       no ) USE_X_TOOLKIT=none ;;
1609 dnl If user did not say whether to use a toolkit, make this decision later:
1610 dnl use the toolkit if we have gtk, or X11R5 or newer.
1611       * ) USE_X_TOOLKIT=maybe ;;
1612     esac
1613   ;;
1614   nextstep | none )
1615     HAVE_X_WINDOWS=no
1616     HAVE_X11=no
1617     USE_X_TOOLKIT=none
1618   ;;
1619 esac
1620
1621 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1622    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1623    if test "$HAVE_XSERVER" = true ||
1624       test -n "$DISPLAY" ||
1625       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1626         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1627 were found.  You should install the relevant development files for X
1628 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1629 sure you have development files for image handling, i.e.
1630 tiff, gif, jpeg, png and xpm.
1631 If you are sure you want Emacs compiled without X window support, pass
1632   --without-x
1633 to configure.])
1634    fi
1635 fi
1636
1637 ### If we're using X11, we should use the X menu package.
1638 HAVE_MENUS=no
1639 case ${HAVE_X11} in
1640   yes ) HAVE_MENUS=yes ;;
1641 esac
1642
1643 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1644 # Assume not, until told otherwise.
1645 GNU_MALLOC=yes
1646 doug_lea_malloc=yes
1647 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1648 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1649 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1650                emacs_cv_var___after_morecore_hook,
1651 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1652   emacs_cv_var___after_morecore_hook=yes,
1653   emacs_cv_var___after_morecore_hook=no)])
1654 if test $emacs_cv_var___after_morecore_hook = no; then
1655   doug_lea_malloc=no
1656 fi
1657
1658
1659 dnl See comments in aix4-2.h about maybe using system malloc there.
1660 system_malloc=no
1661 case "$opsys" in
1662   ## darwin ld insists on the use of malloc routines in the System framework.
1663   darwin|sol2-10) system_malloc=yes ;;
1664 esac
1665
1666 if test "${system_malloc}" = "yes"; then
1667   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1668   GNU_MALLOC=no
1669   GNU_MALLOC_reason="
1670     (The GNU allocators don't work with this system configuration.)"
1671   GMALLOC_OBJ=
1672   VMLIMIT_OBJ=
1673 else
1674   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1675   VMLIMIT_OBJ=vm-limit.o
1676 fi
1677 AC_SUBST(GMALLOC_OBJ)
1678 AC_SUBST(VMLIMIT_OBJ)
1679
1680 if test "$doug_lea_malloc" = "yes" ; then
1681   if test "$GNU_MALLOC" = yes ; then
1682     GNU_MALLOC_reason="
1683       (Using Doug Lea's new malloc from the GNU C Library.)"
1684   fi
1685   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1686             [Define to 1 if you are using the GNU C Library.])
1687
1688   ## Use mmap directly for allocating larger buffers.
1689   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1690   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1691   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1692   case "$opsys" in
1693     gnu*) REL_ALLOC=no ;;
1694   esac
1695 fi
1696
1697 if test x"${REL_ALLOC}" = x; then
1698   REL_ALLOC=${GNU_MALLOC}
1699 fi
1700
1701 use_mmap_for_buffers=no
1702 case "$opsys" in
1703   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1704 esac
1705
1706 AC_FUNC_MMAP
1707 if test $use_mmap_for_buffers = yes; then
1708   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1709   REL_ALLOC=no
1710 fi
1711
1712 LIBS="$LIBS_SYSTEM $LIBS"
1713
1714 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1715 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1716 AC_CHECK_LIB(dnet, dnet_ntoa)
1717 dnl This causes -lresolv to get used in subsequent tests,
1718 dnl which causes failures on some systems such as HPUX 9.
1719 dnl AC_CHECK_LIB(resolv, gethostbyname)
1720
1721 dnl FIXME replace main with a function we actually want from this library.
1722 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1723
1724 dnl Check if pthreads is available.
1725 LIB_PTHREAD=
1726 AC_CHECK_HEADERS(pthread.h)
1727 if test "$ac_cv_header_pthread_h"; then
1728   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1729   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1730   dnl testing for pthread_self if Emacs uses gmalloc.c.
1731   if test "$GMALLOC_OBJ" = gmalloc.o; then
1732     emacs_pthread_function=pthread_atfork
1733   else
1734     emacs_pthread_function=pthread_self
1735   fi
1736   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1737 fi
1738 if test "$HAVE_PTHREAD" = yes; then
1739   case "${canonical}" in
1740     *-hpux*) ;;
1741     *) LIB_PTHREAD="-lpthread"
1742        LIBS="$LIB_PTHREAD $LIBS" ;;
1743   esac
1744   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1745 fi
1746 AC_SUBST([LIB_PTHREAD])
1747
1748 AC_CHECK_LIB(pthreads, cma_open)
1749
1750 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1751 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1752 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1753 ## added to LIBS in configure would never contain the pthreads part,
1754 ## but the value used in Makefiles might.  FIXME?
1755 ##
1756 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1757 ## be harmless on older versions of X where it happens to exist.
1758 test "$opsys" = "aix4-2" && \
1759   test $ac_cv_lib_pthreads_cma_open = yes && \
1760   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1761
1762 dnl Check for need for bigtoc support on IBM AIX
1763
1764 case ${host_os} in
1765 aix*)
1766   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1767     case $GCC in
1768     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1769     *) gdb_cv_bigtoc=-bbigtoc ;;
1770     esac
1771
1772     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1773     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1774   ])
1775   ;;
1776 esac
1777
1778 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1779 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1780 # REAL_CPPFLAGS later on.
1781
1782 REAL_CFLAGS="$CFLAGS"
1783 REAL_CPPFLAGS="$CPPFLAGS"
1784
1785 if test "${HAVE_X11}" = "yes"; then
1786   DEFS="$C_SWITCH_X_SITE $DEFS"
1787   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1788   LIBS="-lX11 $LIBS"
1789   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1790   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1791
1792   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1793   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1794   # but it's more convenient here to set LD_RUN_PATH
1795   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1796   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1797     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1798     export LD_RUN_PATH
1799   fi
1800
1801   if test "${opsys}" = "gnu-linux"; then
1802     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1803     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1804      [[XOpenDisplay ("foo");]])],
1805      [xgnu_linux_first_failure=no],
1806      [xgnu_linux_first_failure=yes])
1807     if test "${xgnu_linux_first_failure}" = "yes"; then
1808       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1809       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1810       OLD_CPPFLAGS="$CPPFLAGS"
1811       OLD_LIBS="$LIBS"
1812       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1813       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1814       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1815       LIBS="$LIBS -b i486-linuxaout"
1816       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1817        [[XOpenDisplay ("foo");]])],
1818        [xgnu_linux_second_failure=no],
1819        [xgnu_linux_second_failure=yes])
1820       if test "${xgnu_linux_second_failure}" = "yes"; then
1821         # If we get the same failure with -b, there is no use adding -b.
1822         # So take it out.  This plays safe.
1823         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1824         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1825         CPPFLAGS="$OLD_CPPFLAGS"
1826         LIBS="$OLD_LIBS"
1827         AC_MSG_RESULT(no)
1828       else
1829         AC_MSG_RESULT(yes)
1830       fi
1831     else
1832       AC_MSG_RESULT(no)
1833     fi
1834   fi
1835
1836   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1837   # header files included from there.
1838   AC_MSG_CHECKING(for Xkb)
1839   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1840 #include <X11/XKBlib.h>]],
1841         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1842         emacs_xkb=yes, emacs_xkb=no)
1843   AC_MSG_RESULT($emacs_xkb)
1844   if test $emacs_xkb = yes; then
1845     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1846   fi
1847
1848   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1849 XScreenNumberOfScreen XSetWMProtocols)
1850 fi
1851
1852 if test "${window_system}" = "x11"; then
1853   AC_MSG_CHECKING(X11 version 6)
1854   AC_CACHE_VAL(emacs_cv_x11_version_6,
1855   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1856 [[#if XlibSpecificationRelease < 6
1857 fail;
1858 #endif
1859 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1860   if test $emacs_cv_x11_version_6 = yes; then
1861     AC_MSG_RESULT(6 or newer)
1862     AC_DEFINE(HAVE_X11R6, 1,
1863               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1864     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1865     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1866     ## XIM support.
1867     case "$opsys" in
1868       sol2-*) : ;;
1869       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1870            [Define if you have usable X11R6-style XIM support.])
1871          ;;
1872     esac
1873   else
1874     AC_MSG_RESULT(before 6)
1875   fi
1876 fi
1877
1878
1879 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1880 HAVE_RSVG=no
1881 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1882   if test "${with_rsvg}" != "no"; then
1883     RSVG_REQUIRED=2.11.0
1884     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1885
1886     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1887     AC_SUBST(RSVG_CFLAGS)
1888     AC_SUBST(RSVG_LIBS)
1889
1890     if test $HAVE_RSVG = yes; then
1891       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1892       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1893       LIBS="$RSVG_LIBS $LIBS"
1894     fi
1895   fi
1896 fi
1897
1898 HAVE_IMAGEMAGICK=no
1899 if test "${HAVE_X11}" = "yes"; then
1900   if test "${with_imagemagick}" != "no"; then
1901     ## 6.2.8 is the earliest version known to work, but earlier versions
1902     ## might work - let us know if you find one.
1903     ## 6.0.7 does not work.  See bug#7955.
1904     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1905     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1906     AC_SUBST(IMAGEMAGICK_CFLAGS)
1907     AC_SUBST(IMAGEMAGICK_LIBS)
1908
1909     if test $HAVE_IMAGEMAGICK = yes; then
1910       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1911       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1912       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1913       AC_CHECK_FUNCS(MagickExportImagePixels)
1914     fi
1915   fi
1916 fi
1917
1918
1919 HAVE_GTK=no
1920 GTK_OBJ=
1921 if test "${with_gtk3}" = "yes"; then
1922   GLIB_REQUIRED=2.28
1923   GTK_REQUIRED=3.0
1924   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1925
1926   dnl Checks for libraries.
1927   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1928   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1929      AC_MSG_ERROR($GTK_PKG_ERRORS)
1930   fi
1931   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1932   GTK_OBJ=emacsgtkfixed.o
1933 fi
1934
1935 if test "$pkg_check_gtk" != "yes"; then
1936   HAVE_GTK=no
1937 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1938   GLIB_REQUIRED=2.10
1939   GTK_REQUIRED=2.10
1940   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1941
1942   dnl Checks for libraries.
1943   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1944   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1945      AC_MSG_ERROR($GTK_PKG_ERRORS)
1946   fi
1947 fi
1948 fi
1949
1950 if test x"$pkg_check_gtk" = xyes; then
1951
1952   AC_SUBST(GTK_CFLAGS)
1953   AC_SUBST(GTK_LIBS)
1954   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1955   CFLAGS="$CFLAGS $GTK_CFLAGS"
1956   LIBS="$GTK_LIBS $LIBS"
1957   dnl Try to compile a simple GTK program.
1958   GTK_COMPILES=no
1959   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1960   if test "${GTK_COMPILES}" != "yes"; then
1961     if test "$USE_X_TOOLKIT" != "maybe"; then
1962       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1963     fi
1964   else
1965     HAVE_GTK=yes
1966     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1967     GTK_OBJ="gtkutil.o $GTK_OBJ"
1968     USE_X_TOOLKIT=none
1969     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1970       :
1971     else
1972       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1973        closing open displays.  This is no problem if you just use
1974        one display, but if you use more than one and close one of them
1975        Emacs may crash.]])
1976       sleep 3
1977     fi
1978   fi
1979
1980 fi
1981 AC_SUBST(GTK_OBJ)
1982
1983
1984 if test "${HAVE_GTK}" = "yes"; then
1985
1986   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1987   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1988   if test "$with_toolkit_scroll_bars" != no; then
1989     with_toolkit_scroll_bars=yes
1990   fi
1991
1992   dnl  Check if we have the old file selection dialog declared and
1993   dnl  in the link library.  In 2.x it may be in the library,
1994   dnl  but not declared if deprecated featured has been selected out.
1995   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1996   HAVE_GTK_FILE_SELECTION=no
1997   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1998                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1999 #include <gtk/gtk.h>])
2000   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2001     AC_CHECK_FUNCS(gtk_file_selection_new)
2002   fi
2003
2004
2005   dnl Check for functions introduced in 2.14 and later.
2006   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2007                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2008                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2009                  gtk_orientable_set_orientation \
2010                  gtk_window_set_has_resize_grip)
2011 fi
2012
2013 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2014 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
2015 dnl also not configured.
2016 HAVE_DBUS=no
2017 DBUS_OBJ=
2018 if test "${with_dbus}" = "yes"; then
2019    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2020    if test "$HAVE_DBUS" = yes; then
2021      LIBS="$LIBS $DBUS_LIBS"
2022      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2023      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
2024      DBUS_OBJ=dbusbind.o
2025    fi
2026 fi
2027 AC_SUBST(DBUS_OBJ)
2028
2029 dnl GSettings has been tested under GNU/Linux only.
2030 HAVE_GSETTINGS=no
2031 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2032    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2033    if test "$HAVE_GSETTINGS" = "yes"; then
2034       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2035       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2036       SETTINGS_LIBS="$GSETTINGS_LIBS"
2037    fi
2038 fi
2039
2040 dnl GConf has been tested under GNU/Linux only.
2041 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2042 HAVE_GCONF=no
2043 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2044    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2045    if test "$HAVE_GCONF" = yes; then
2046       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2047       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2048       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2049       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2050    fi
2051 fi
2052
2053 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2054     SAVE_CFLAGS="$CFLAGS"
2055     SAVE_LIBS="$LIBS"
2056     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2057     LIBS="$SETTINGS_LIBS $LIBS"
2058     AC_CHECK_FUNCS([g_type_init])
2059     CFLAGS="$SAVE_CFLAGS"
2060     LIBS="$SAVE_LIBS"
2061 fi
2062 AC_SUBST(SETTINGS_CFLAGS)
2063 AC_SUBST(SETTINGS_LIBS)
2064
2065
2066 dnl SELinux is available for GNU/Linux only.
2067 HAVE_LIBSELINUX=no
2068 LIBSELINUX_LIBS=
2069 if test "${with_selinux}" = "yes"; then
2070    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2071    if test "$HAVE_LIBSELINUX" = yes; then
2072       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2073       LIBSELINUX_LIBS=-lselinux
2074    fi
2075 fi
2076 AC_SUBST(LIBSELINUX_LIBS)
2077
2078 HAVE_GNUTLS=no
2079 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2080 if test "${with_gnutls}" = "yes" ; then
2081   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2082   if test "${HAVE_GNUTLS}" = "yes"; then
2083     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2084   fi
2085
2086   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2087   LIBS="$LIBGNUTLS_LIBS $LIBS"
2088   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2089
2090   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2091     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2092   fi
2093 fi
2094
2095 AC_SUBST(LIBGNUTLS_LIBS)
2096 AC_SUBST(LIBGNUTLS_CFLAGS)
2097
2098 dnl Do not put whitespace before the #include statements below.
2099 dnl Older compilers (eg sunos4 cc) choke on it.
2100 HAVE_XAW3D=no
2101 LUCID_LIBW=
2102 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2103   if test "$with_xaw3d" != no; then
2104     AC_MSG_CHECKING(for xaw3d)
2105     AC_CACHE_VAL(emacs_cv_xaw3d,
2106     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2107 #include <X11/Intrinsic.h>
2108 #include <X11/Xaw3d/Simple.h>]],
2109       [[]])],
2110       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2111                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2112       emacs_cv_xaw3d=no)])
2113   else
2114     emacs_cv_xaw3d=no
2115   fi
2116   if test $emacs_cv_xaw3d = yes; then
2117     AC_MSG_RESULT([yes; using Lucid toolkit])
2118     USE_X_TOOLKIT=LUCID
2119     HAVE_XAW3D=yes
2120     LUCID_LIBW=-lXaw3d
2121     AC_DEFINE(HAVE_XAW3D, 1,
2122               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2123   else
2124     AC_MSG_RESULT(no)
2125     AC_MSG_CHECKING(for libXaw)
2126     AC_CACHE_VAL(emacs_cv_xaw,
2127     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2128 #include <X11/Intrinsic.h>
2129 #include <X11/Xaw/Simple.h>]],
2130       [[]])],
2131       emacs_cv_xaw=yes,
2132       emacs_cv_xaw=no)])
2133     if test $emacs_cv_xaw = yes; then
2134       AC_MSG_RESULT([yes; using Lucid toolkit])
2135       USE_X_TOOLKIT=LUCID
2136       LUCID_LIBW=-lXaw
2137     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2138       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2139     else
2140       AC_MSG_ERROR([No X toolkit could be found.
2141 If you are sure you want Emacs compiled without an X toolkit, pass
2142   --with-x-toolkit=no
2143 to configure.  Otherwise, install the development libraries for the toolkit
2144 that you want to use (e.g. Gtk+) and re-run configure.])
2145     fi
2146   fi
2147 fi
2148
2149 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2150
2151 LIBXTR6=
2152 if test "${USE_X_TOOLKIT}" != "none"; then
2153   AC_MSG_CHECKING(X11 toolkit version)
2154   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2155   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2156 [[#if XtSpecificationRelease < 6
2157 fail;
2158 #endif
2159 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2160   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2161   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2162     AC_MSG_RESULT(6 or newer)
2163     AC_DEFINE(HAVE_X11XTR6, 1,
2164               [Define to 1 if you have the X11R6 or newer version of Xt.])
2165     LIBXTR6="-lSM -lICE"
2166     case "$opsys" in
2167       ## Use libw.a along with X11R6 Xt.
2168       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2169     esac
2170   else
2171     AC_MSG_RESULT(before 6)
2172   fi
2173
2174 dnl If using toolkit, check whether libXmu.a exists.
2175 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2176   OLDLIBS="$LIBS"
2177   if test x$HAVE_X11XTR6 = xyes; then
2178     LIBS="-lXt -lSM -lICE $LIBS"
2179   else
2180     LIBS="-lXt $LIBS"
2181   fi
2182   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2183   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2184 fi
2185 AC_SUBST(LIBXTR6)
2186
2187 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2188 dnl Why not just test for libxmu in the normal way?
2189 LIBXMU=-lXmu
2190 case $opsys in
2191   ## These systems don't supply Xmu.
2192   hpux* | aix4-2 )
2193     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2194     ;;
2195 esac
2196 AC_SUBST(LIBXMU)
2197
2198 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2199 if test "${HAVE_X11}" = "yes"; then
2200   if test "${USE_X_TOOLKIT}" != "none"; then
2201     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2202   fi
2203 fi
2204
2205 LIBXP=
2206 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2207   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2208   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2209     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2210 int x = 5;
2211 #else
2212 Motif version prior to 2.1.
2213 #endif]])],
2214     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2215   if test $emacs_cv_motif_version_2_1 = yes; then
2216     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2217   else
2218     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2219     # We put this in CFLAGS temporarily to precede other -I options
2220     # that might be in CFLAGS temporarily.
2221     # We put this in CPPFLAGS where it precedes the other -I options.
2222     OLD_CPPFLAGS=$CPPFLAGS
2223     OLD_CFLAGS=$CFLAGS
2224     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2225     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2226     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2227       [[int x = 5;]])],
2228       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2229     if test $emacs_cv_lesstif = yes; then
2230       # Make sure this -I option remains in CPPFLAGS after it is set
2231       # back to REAL_CPPFLAGS.
2232       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2233       # have those other -I options anyway.  Ultimately, having this
2234       # directory ultimately in CPPFLAGS will be enough.
2235       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2236       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2237     else
2238       CFLAGS=$OLD_CFLAGS
2239       CPPFLAGS=$OLD_CPPFLAGS
2240     fi
2241   fi
2242   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2243     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2244 fi
2245
2246 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2247 dnl using Motif or Xaw3d is available, and unless
2248 dnl --with-toolkit-scroll-bars=no was specified.
2249
2250 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2251             [Define to 1 if we should use toolkit scroll bars.])dnl
2252 USE_TOOLKIT_SCROLL_BARS=no
2253 if test "${with_toolkit_scroll_bars}" != "no"; then
2254   if test "${USE_X_TOOLKIT}" != "none"; then
2255     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2256       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2257       HAVE_XAW3D=no
2258       USE_TOOLKIT_SCROLL_BARS=yes
2259     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2260       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2261       USE_TOOLKIT_SCROLL_BARS=yes
2262     fi
2263   elif test "${HAVE_GTK}" = "yes"; then
2264     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2265     USE_TOOLKIT_SCROLL_BARS=yes
2266   elif test "${HAVE_NS}" = "yes"; then
2267     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2268     USE_TOOLKIT_SCROLL_BARS=yes
2269   fi
2270 fi
2271
2272 dnl See if XIM is available.
2273 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2274           #include <X11/Xlib.h>
2275           #include <X11/Xresource.h>]],
2276          [[XIMProc  callback;]])],
2277          [HAVE_XIM=yes
2278          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2279          HAVE_XIM=no)
2280
2281 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2282
2283 if test "${with_xim}" != "no"; then
2284   AC_DEFINE(USE_XIM, 1,
2285             [Define to 1 if we should use XIM, if it is available.])
2286 fi
2287
2288
2289 if test "${HAVE_XIM}" != "no"; then
2290   late_CFLAGS=$CFLAGS
2291   if test "$GCC" = yes; then
2292     CFLAGS="$CFLAGS --pedantic-errors"
2293   fi
2294   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2295 #include <X11/Xlib.h>
2296 #include <X11/Xresource.h>]],
2297 [[Display *display;
2298 XrmDatabase db;
2299 char *res_name;
2300 char *res_class;
2301 XIMProc  callback;
2302 XPointer *client_data;
2303 #ifndef __GNUC__
2304 /* If we're not using GCC, it's probably not XFree86, and this is
2305    probably right, but we can't use something like --pedantic-errors.  */
2306 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2307                                            char*, XIMProc, XPointer*);
2308 #endif
2309 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2310    client_data);]])],
2311     [emacs_cv_arg6_star=yes])
2312   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2313          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2314 either XPointer or XPointer*.])dnl
2315   if test "$emacs_cv_arg6_star" = yes; then
2316     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2317   else
2318     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2319   fi
2320   CFLAGS=$late_CFLAGS
2321 fi
2322
2323 ### Start of font-backend (under any platform) section.
2324 # (nothing here yet -- this is a placeholder)
2325 ### End of font-backend (under any platform) section.
2326
2327 ### Start of font-backend (under X11) section.
2328 if test "${HAVE_X11}" = "yes"; then
2329    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2330
2331    ## Use -lXft if available, unless `--with-xft=no'.
2332    HAVE_XFT=maybe
2333     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2334       with_xft="no";
2335     fi
2336     if test "x${with_xft}" != "xno"; then
2337
2338       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2339       ## Because xftfont.c uses XRenderQueryExtension, we also
2340       ## need to link to -lXrender.
2341       HAVE_XRENDER=no
2342       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2343       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2344         OLD_CPPFLAGS="$CPPFLAGS"
2345         OLD_CFLAGS="$CFLAGS"
2346         OLD_LIBS="$LIBS"
2347         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2348         CFLAGS="$CFLAGS $XFT_CFLAGS"
2349         XFT_LIBS="-lXrender $XFT_LIBS"
2350         LIBS="$XFT_LIBS $LIBS"
2351         AC_CHECK_HEADER(X11/Xft/Xft.h,
2352           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2353
2354         if test "${HAVE_XFT}" = "yes"; then
2355           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2356             AC_SUBST(XFT_LIBS)
2357           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2358         else
2359           CPPFLAGS="$OLD_CPPFLAGS"
2360           CFLAGS="$OLD_CFLAGS"
2361           LIBS="$OLD_LIBS"
2362         fi                        # "${HAVE_XFT}" = "yes"
2363       fi                          # "$HAVE_XFT" != no
2364     fi                            # "x${with_xft}" != "xno"
2365
2366     ## We used to allow building with FreeType and without Xft.
2367     ## However, the ftx font backend driver is not in good shape.
2368     if test "$HAVE_XFT" != "yes"; then
2369        dnl For the "Does Emacs use" message at the end.
2370        HAVE_XFT=no
2371        HAVE_FREETYPE=no
2372     else
2373        dnl Strict linkers fail with
2374        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2375        dnl if -lfreetype is not specified.
2376        dnl The following is needed to set FREETYPE_LIBS.
2377        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2378                          HAVE_FREETYPE=no)
2379
2380        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2381     fi
2382
2383     HAVE_LIBOTF=no
2384     if test "${HAVE_FREETYPE}" = "yes"; then
2385       AC_DEFINE(HAVE_FREETYPE, 1,
2386                 [Define to 1 if using the freetype and fontconfig libraries.])
2387       if test "${with_libotf}" != "no"; then
2388         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2389                           HAVE_LIBOTF=no)
2390         if test "$HAVE_LIBOTF" = "yes"; then
2391           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2392           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2393                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2394                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2395           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2396             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2397                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2398           fi
2399         fi
2400       fi
2401     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2402     dnl Does the new font backend require it, or can it work without it?
2403     fi
2404
2405     HAVE_M17N_FLT=no
2406     if test "${HAVE_LIBOTF}" = yes; then
2407       if test "${with_m17n_flt}" != "no"; then
2408         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2409         if test "$HAVE_M17N_FLT" = "yes"; then
2410           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2411         fi
2412       fi
2413     fi
2414 else
2415     HAVE_XFT=no
2416     HAVE_FREETYPE=no
2417     HAVE_LIBOTF=no
2418     HAVE_M17N_FLT=no
2419 fi
2420
2421 ### End of font-backend (under X11) section.
2422
2423 AC_SUBST(FREETYPE_CFLAGS)
2424 AC_SUBST(FREETYPE_LIBS)
2425 AC_SUBST(FONTCONFIG_CFLAGS)
2426 AC_SUBST(FONTCONFIG_LIBS)
2427 AC_SUBST(LIBOTF_CFLAGS)
2428 AC_SUBST(LIBOTF_LIBS)
2429 AC_SUBST(M17N_FLT_CFLAGS)
2430 AC_SUBST(M17N_FLT_LIBS)
2431
2432 ### Use -lXpm if available, unless `--with-xpm=no'.
2433 HAVE_XPM=no
2434 LIBXPM=
2435 if test "${HAVE_X11}" = "yes"; then
2436   if test "${with_xpm}" != "no"; then
2437     AC_CHECK_HEADER(X11/xpm.h,
2438       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2439     if test "${HAVE_XPM}" = "yes"; then
2440       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2441       AC_EGREP_CPP(no_return_alloc_pixels,
2442       [#include "X11/xpm.h"
2443 #ifndef XpmReturnAllocPixels
2444 no_return_alloc_pixels
2445 #endif
2446       ], HAVE_XPM=no, HAVE_XPM=yes)
2447
2448       if test "${HAVE_XPM}" = "yes"; then
2449         AC_MSG_RESULT(yes)
2450       else
2451         AC_MSG_RESULT(no)
2452       fi
2453     fi
2454   fi
2455
2456   if test "${HAVE_XPM}" = "yes"; then
2457     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2458     LIBXPM=-lXpm
2459   fi
2460 fi
2461 AC_SUBST(LIBXPM)
2462
2463 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2464 HAVE_JPEG=no
2465 LIBJPEG=
2466 if test "${HAVE_X11}" = "yes"; then
2467   if test "${with_jpeg}" != "no"; then
2468     dnl Checking for jpeglib.h can lose because of a redefinition of
2469     dnl  HAVE_STDLIB_H.
2470     AC_CHECK_HEADER(jerror.h,
2471       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2472   fi
2473
2474   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2475   if test "${HAVE_JPEG}" = "yes"; then
2476     AC_DEFINE(HAVE_JPEG)
2477     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2478         [#include <jpeglib.h>
2479          version=JPEG_LIB_VERSION
2480 ],
2481         [AC_DEFINE(HAVE_JPEG)],
2482         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2483         HAVE_JPEG=no])
2484   fi
2485   if test "${HAVE_JPEG}" = "yes"; then
2486     LIBJPEG=-ljpeg
2487   fi
2488 fi
2489 AC_SUBST(LIBJPEG)
2490
2491 ### Use -lpng if available, unless `--with-png=no'.
2492 HAVE_PNG=no
2493 LIBPNG=
2494 if test "${HAVE_X11}" = "yes"; then
2495   if test "${with_png}" != "no"; then
2496     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2497     # in /usr/include/libpng.
2498     AC_CHECK_HEADERS(png.h libpng/png.h)
2499     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2500       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2501     fi
2502   fi
2503
2504   if test "${HAVE_PNG}" = "yes"; then
2505     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2506     LIBPNG="-lpng -lz -lm"
2507   fi
2508 fi
2509 AC_SUBST(LIBPNG)
2510
2511 ### Use -ltiff if available, unless `--with-tiff=no'.
2512 HAVE_TIFF=no
2513 LIBTIFF=
2514 if test "${HAVE_X11}" = "yes"; then
2515   if test "${with_tiff}" != "no"; then
2516     AC_CHECK_HEADER(tiffio.h,
2517       [tifflibs="-lz -lm"
2518       # At least one tiff package requires the jpeg library.
2519       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2520       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2521   fi
2522
2523   if test "${HAVE_TIFF}" = "yes"; then
2524     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2525     dnl FIXME -lz -lm, as per libpng?
2526     LIBTIFF=-ltiff
2527   fi
2528 fi
2529 AC_SUBST(LIBTIFF)
2530
2531 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2532 HAVE_GIF=no
2533 LIBGIF=
2534 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2535   AC_CHECK_HEADER(gif_lib.h,
2536 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2537 # Earlier versions can crash Emacs.
2538     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2539
2540   if test "$HAVE_GIF" = yes; then
2541     LIBGIF=-lgif
2542   elif test "$HAVE_GIF" = maybe; then
2543 # If gif_lib.h but no libgif, try libungif.
2544     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2545     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2546   fi
2547
2548   if test "${HAVE_GIF}" = "yes"; then
2549     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2550   fi
2551 fi
2552 AC_SUBST(LIBGIF)
2553
2554 dnl Check for required libraries.
2555 if test "${HAVE_X11}" = "yes"; then
2556   MISSING=""
2557   WITH_NO=""
2558   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2559     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2560   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2561     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2562   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2563     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2564   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2565     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2566   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2567     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2568
2569   if test "X${MISSING}" != X; then
2570     AC_MSG_ERROR([The following required libraries were not found:
2571     $MISSING
2572 Maybe some development libraries/packages are missing?
2573 If you don't want to link with them give
2574     $WITH_NO
2575 as options to configure])
2576   fi
2577 fi
2578
2579 ### Use -lgpm if available, unless `--with-gpm=no'.
2580 HAVE_GPM=no
2581 LIBGPM=
2582 if test "${with_gpm}" != "no"; then
2583   AC_CHECK_HEADER(gpm.h,
2584     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2585
2586   if test "${HAVE_GPM}" = "yes"; then
2587     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2588     LIBGPM=-lgpm
2589   fi
2590 fi
2591 AC_SUBST(LIBGPM)
2592
2593 dnl Check for malloc/malloc.h on darwin
2594 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2595
2596 C_SWITCH_X_SYSTEM=
2597 ### Use NeXTstep API to implement GUI.
2598 if test "${HAVE_NS}" = "yes"; then
2599   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2600   if test "${NS_IMPL_COCOA}" = "yes"; then
2601     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2602   fi
2603   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2604     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2605     # See also .m.o rule in Makefile.in */
2606     # FIXME: are all these flags really needed?  Document here why.  */
2607     dnl FIXME this should be renamed to GNUSTEP_CFLAGS, and only
2608     dnl used in src/Makefile.in.
2609     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2610     ## Extra CFLAGS applied to src/*.m files.
2611     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2612   fi
2613   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2614     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2615   fi
2616   # We also have mouse menus.
2617   HAVE_MENUS=yes
2618   OTHER_FILES=ns-app
2619 fi
2620
2621
2622 ### Use session management (-lSM -lICE) if available
2623 HAVE_X_SM=no
2624 LIBXSM=
2625 if test "${HAVE_X11}" = "yes"; then
2626   AC_CHECK_HEADER(X11/SM/SMlib.h,
2627     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2628
2629   if test "${HAVE_X_SM}" = "yes"; then
2630     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2631     LIBXSM="-lSM -lICE"
2632     case "$LIBS" in
2633       *-lSM*) ;;
2634       *)      LIBS="$LIBXSM $LIBS" ;;
2635     esac
2636   fi
2637 fi
2638 AC_SUBST(LIBXSM)
2639
2640 ### Use libxml (-lxml2) if available
2641 HAVE_LIBXML2=no
2642 if test "${with_xml2}" != "no"; then
2643   ### I'm not sure what the version number should be, so I just guessed.
2644   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2645   if test "${HAVE_LIBXML2}" = "yes"; then
2646     LIBS="$LIBXML2_LIBS $LIBS"
2647     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2648     if test "${HAVE_LIBXML2}" = "yes"; then
2649       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2650     else
2651       LIBXML2_LIBS=""
2652       LIBXML2_CFLAGS=""
2653     fi
2654   fi
2655 fi
2656 AC_SUBST(LIBXML2_LIBS)
2657 AC_SUBST(LIBXML2_CFLAGS)
2658
2659 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2660 AC_CACHE_CHECK(whether netdb declares h_errno,
2661                emacs_cv_netdb_declares_h_errno,
2662 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2663   [[return h_errno;]])],
2664   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2665 if test $emacs_cv_netdb_declares_h_errno = yes; then
2666   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2667 fi
2668
2669 # fmod, logb, and frexp are found in -lm on most systems.
2670 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2671 AC_CHECK_LIB(m, sqrt)
2672
2673 # Check for mail-locking functions in a "mail" library.  Probably this should
2674 # have the same check as for liblockfile below.
2675 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2676 if test $have_mail = yes; then
2677   LIBS_MAIL=-lmail
2678   LIBS="$LIBS_MAIL $LIBS"
2679   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2680 else
2681   LIBS_MAIL=
2682 fi
2683 dnl Debian, at least:
2684 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2685 if test $have_lockfile = yes; then
2686    LIBS_MAIL=-llockfile
2687    LIBS="$LIBS_MAIL $LIBS"
2688    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2689 else
2690 # If we have the shared liblockfile, assume we must use it for mail
2691 # locking (e.g. Debian).  If we couldn't link against liblockfile
2692 # (no liblockfile.a installed), ensure that we don't need to.
2693   dnl This works for files generally, not just executables.
2694   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2695   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2696                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2697   if test $ac_cv_prog_liblockfile = yes; then
2698     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2699 This probably means that movemail could lose mail.
2700 There may be a `development' package to install containing liblockfile.])
2701   fi
2702 fi
2703 AC_CHECK_FUNCS(touchlock)
2704 AC_CHECK_HEADERS(maillock.h)
2705 AC_SUBST(LIBS_MAIL)
2706
2707 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2708 ## interlock access to the mail spool.  The alternative is a lock file named
2709 ## /usr/spool/mail/$USER.lock.
2710 mail_lock=no
2711 case "$opsys" in
2712   aix4-2) mail_lock="lockf" ;;
2713
2714   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2715
2716   ## On GNU/Linux systems, both methods are used by various mail programs.
2717   ## I assume most people are using newer mailers that have heard of flock.
2718   ## Change this if you need to.
2719   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2720   ## configure gets the right answers, and that means *NOT* using flock.
2721   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2722   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2723   ## Debian maintainer hasn't provided a clean fix for Emacs.
2724   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2725   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2726   ## correct logic.  -- fx
2727   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2728   ## liblockfile is a Free Software replacement for libmail, used on
2729   ## Debian systems and elsewhere. -rfr.
2730   gnu-*)
2731     mail_lock="flock"
2732     if test $have_mail = yes || test $have_lockfile = yes; then
2733       test $ac_cv_header_maillock_h = yes && mail_lock=no
2734     fi
2735     ;;
2736 esac
2737
2738 BLESSMAIL_TARGET=
2739 case "$mail_lock" in
2740   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2741
2742   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2743
2744   *) BLESSMAIL_TARGET="need-blessmail" ;;
2745 esac
2746 AC_SUBST(BLESSMAIL_TARGET)
2747
2748
2749 AC_CHECK_FUNCS(gethostname getdomainname \
2750 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2751 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2752 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2753 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2754 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2755 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2756 gai_strerror mkstemp getline getdelim mremap fsync sync \
2757 difftime mempcpy mblen mbrlen posix_memalign \
2758 cfmakeraw cfsetspeed copysign __executable_start)
2759
2760 dnl Cannot use AC_CHECK_FUNCS
2761 AC_CACHE_CHECK([for __builtin_unwind_init],
2762                emacs_cv_func___builtin_unwind_init,
2763 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2764                 emacs_cv_func___builtin_unwind_init=yes,
2765                 emacs_cv_func___builtin_unwind_init=no)])
2766 if test $emacs_cv_func___builtin_unwind_init = yes; then
2767   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2768             [Define to 1 if you have the `__builtin_unwind_init' function.])
2769 fi
2770
2771 AC_CHECK_HEADERS(sys/un.h)
2772
2773 AC_FUNC_FSEEKO
2774
2775 AC_FUNC_GETPGRP
2776
2777 # UNIX98 PTYs.
2778 AC_CHECK_FUNCS(grantpt)
2779
2780 # PTY-related GNU extensions.
2781 AC_CHECK_FUNCS(getpt)
2782
2783 # Check this now, so that we will NOT find the above functions in ncurses.
2784 # That is because we have not set up to link ncurses in lib-src.
2785 # It's better to believe a function is not available
2786 # than to expect to find it in ncurses.
2787 # Also we need tputs and friends to be able to build at all.
2788 AC_MSG_CHECKING([for library containing tputs])
2789 # Run a test program that contains a call to tputs, a call that is
2790 # never executed.  This tests whether a pre-'main' dynamic linker
2791 # works with the library.  It's too much trouble to actually call
2792 # tputs in the test program, due to portability hassles.  When
2793 # cross-compiling, assume the test program will run if it links.
2794 AC_DEFUN([tputs_link_source], [
2795   AC_LANG_SOURCE(
2796      [[extern void tputs (const char *, int, int (*)(int));
2797        int main (int argc, char **argv)
2798        {
2799           if (argc == 10000)
2800             tputs (argv[0], 0, 0);
2801           return 0;
2802        }]])
2803 ])
2804 # Maybe curses should be tried earlier?
2805 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2806 for tputs_library in '' ncurses terminfo termcap curses; do
2807   OLIBS=$LIBS
2808   if test -z "$tputs_library"; then
2809     LIBS_TERMCAP=
2810     msg='none required'
2811   else
2812     LIBS_TERMCAP=-l$tputs_library
2813     msg=$LIBS_TERMCAP
2814     LIBS="$LIBS_TERMCAP $LIBS"
2815   fi
2816   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2817     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2818   LIBS=$OLIBS
2819   if test "X$msg" != Xno; then
2820     break
2821   fi
2822 done
2823 AC_MSG_RESULT([$msg])
2824 if test "X$msg" = Xno; then
2825   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2826 These libraries were tried: libncurses, libterminfo, libtermcap, libcurses.
2827 Please try installing whichever of these libraries is most appropriate
2828 for your system, together with its header files.
2829 For example, a libncurses-dev(el) or similar package.])
2830 fi
2831 # Must define this when any termcap library is found.
2832 AC_DEFINE(HAVE_LIBNCURSES, 1,
2833           [Define to 1 if you have the `ncurses' library (-lncurses).])
2834 ## FIXME This was the cpp logic, but I am not sure it is right.
2835 ## The above test has not necessarily found libncurses.
2836 HAVE_LIBNCURSES=yes
2837
2838 ## Use terminfo instead of termcap?
2839 ## Note only system files NOT using terminfo are:
2840 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2841 ## darwin|gnu without ncurses.
2842 TERMINFO=no
2843 case "$opsys" in
2844   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2845   ## hpux10-20: Use the system provided termcap(3) library.
2846   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2847   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2848   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2849
2850   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2851   ##  The ncurses library has been moved out of the System framework in
2852   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2853   ##  option to use it.
2854   darwin|gnu*)
2855     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2856     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2857       TERMINFO=yes
2858       LIBS_TERMCAP="-lncurses"
2859     fi
2860     ;;
2861
2862   freebsd)
2863     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2864     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2865     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2866 [[#if __FreeBSD_version < 400000
2867 fail;
2868 #endif
2869 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2870
2871     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2872
2873     if test $emacs_cv_freebsd_terminfo = yes; then
2874       TERMINFO=yes
2875       LIBS_TERMCAP="-lncurses"
2876     else
2877       LIBS_TERMCAP="-ltermcap"
2878     fi
2879     ;;
2880
2881   netbsd)
2882     if test "x$LIBS_TERMCAP" = "x-lterminfo"; then
2883       TERMINFO=yes
2884     else
2885       LIBS_TERMCAP="-ltermcap"
2886     fi
2887     ;;
2888
2889 esac
2890
2891 case "$opsys" in
2892   ## hpux: Make sure we get select from libc rather than from libcurses
2893   ##  because libcurses on HPUX 10.10 has a broken version of select.
2894   ##  We used to use -lc -lcurses, but this may be cleaner.
2895   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2896
2897   openbsd) LIBS_TERMCAP="-lncurses" ;;
2898
2899   ## Must use system termcap, if we use any termcap.  It does special things.
2900   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2901 esac
2902
2903 TERMCAP_OBJ=tparam.o
2904 if test $TERMINFO = yes; then
2905   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2906   TERMCAP_OBJ=terminfo.o
2907 fi
2908 AC_SUBST(LIBS_TERMCAP)
2909 AC_SUBST(TERMCAP_OBJ)
2910
2911
2912 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2913 resolv=no
2914 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2915 #include <arpa/nameser.h>
2916 #include <resolv.h>]],
2917     [[return res_init();]])],
2918     have_res_init=yes, have_res_init=no)
2919 if test "$have_res_init" = no; then
2920   OLIBS="$LIBS"
2921   LIBS="$LIBS -lresolv"
2922   AC_MSG_CHECKING(for res_init with -lresolv)
2923   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2924 #include <arpa/nameser.h>
2925 #include <resolv.h>]],
2926     [[return res_init();]])],
2927     have_res_init=yes, have_res_init=no)
2928   AC_MSG_RESULT($have_res_init)
2929   if test "$have_res_init" = yes ; then
2930     resolv=yes
2931   fi
2932   LIBS="$OLIBS"
2933 fi
2934
2935 if test "$have_res_init" = yes; then
2936   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2937 fi
2938
2939 # Do we need the Hesiod library to provide the support routines?
2940 LIBHESIOD=
2941 if test "$with_hesiod" != no ; then
2942   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2943   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2944      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2945                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2946   if test "$resolv" = yes ; then
2947     RESOLVLIB=-lresolv
2948   else
2949     RESOLVLIB=
2950   fi
2951   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2952         hesiod=yes, :, $RESOLVLIB)])
2953
2954   if test x"$hesiod" = xyes; then
2955     AC_DEFINE(HAVE_LIBHESIOD, 1,
2956               [Define to 1 if you have the hesiod library (-lhesiod).])
2957     LIBHESIOD=-lhesiod
2958   fi
2959 fi
2960 AC_SUBST(LIBHESIOD)
2961
2962 # Do we need libresolv (due to res_init or Hesiod)?
2963 if test "$resolv" = yes ; then
2964   AC_DEFINE(HAVE_LIBRESOLV, 1,
2965             [Define to 1 if you have the resolv library (-lresolv).])
2966   LIBRESOLV=-lresolv
2967 else
2968   LIBRESOLV=
2969 fi
2970 AC_SUBST(LIBRESOLV)
2971
2972 # These tell us which Kerberos-related libraries to use.
2973 COM_ERRLIB=
2974 CRYPTOLIB=
2975 KRB5LIB=
2976 DESLIB=
2977 KRB4LIB=
2978
2979 if test "${with_kerberos}" != no; then
2980   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2981   if test $have_com_err = yes; then
2982     COM_ERRLIB=-lcom_err
2983     LIBS="$COM_ERRLIB $LIBS"
2984     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2985   fi
2986   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2987   if test $have_crypto = yes; then
2988     CRYPTOLIB=-lcrypto
2989     LIBS="$CRYPTOLIB $LIBS"
2990     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2991   fi
2992   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2993   if test $have_k5crypto = yes; then
2994     CRYPTOLIB=-lk5crypto
2995     LIBS="$CRYPTOLIB $LIBS"
2996     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2997   fi
2998   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2999   if test $have_krb5=yes; then
3000     KRB5LIB=-lkrb5
3001     LIBS="$KRB5LIB $LIBS"
3002     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3003   fi
3004   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3005   if test "${with_kerberos5}" = no; then
3006     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3007     if test $have_des425 = yes; then
3008       DESLIB=-ldes425
3009       LIBS="$DESLIB $LIBS"
3010       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3011     else
3012       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3013       if test $have_des = yes; then
3014         DESLIB=-ldes
3015         LIBS="$DESLIB $LIBS"
3016         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3017       fi
3018     fi
3019     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3020     if test $have_krb4 = yes; then
3021       KRB4LIB=-lkrb4
3022       LIBS="$KRB4LIB $LIBS"
3023       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3024     else
3025       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3026       if test $have_krb = yes; then
3027         KRB4LIB=-lkrb
3028         LIBS="$KRB4LIB $LIBS"
3029         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3030       fi
3031     fi
3032   fi
3033
3034   if test "${with_kerberos5}" != no; then
3035     AC_CHECK_HEADERS(krb5.h,
3036       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3037                         [#include <krb5.h>])])
3038   else
3039     AC_CHECK_HEADERS(des.h,,
3040                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3041                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3042     AC_CHECK_HEADERS(krb.h,,
3043                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3044                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3045   fi
3046   AC_CHECK_HEADERS(com_err.h)
3047 fi
3048
3049 AC_SUBST(COM_ERRLIB)
3050 AC_SUBST(CRYPTOLIB)
3051 AC_SUBST(KRB5LIB)
3052 AC_SUBST(DESLIB)
3053 AC_SUBST(KRB4LIB)
3054
3055 AC_MSG_CHECKING(whether localtime caches TZ)
3056 AC_CACHE_VAL(emacs_cv_localtime_cache,
3057 [if test x$ac_cv_func_tzset = xyes; then
3058 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3059 char TZ_GMT0[] = "TZ=GMT0";
3060 char TZ_PST8[] = "TZ=PST8";
3061 main()
3062 {
3063   time_t now = time ((time_t *) 0);
3064   int hour_GMT0, hour_unset;
3065   if (putenv (TZ_GMT0) != 0)
3066     exit (1);
3067   hour_GMT0 = localtime (&now)->tm_hour;
3068   unsetenv("TZ");
3069   hour_unset = localtime (&now)->tm_hour;
3070   if (putenv (TZ_PST8) != 0)
3071     exit (1);
3072   if (localtime (&now)->tm_hour == hour_GMT0)
3073     exit (1);
3074   unsetenv("TZ");
3075   if (localtime (&now)->tm_hour != hour_unset)
3076     exit (1);
3077   exit (0);
3078 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3079 [# If we have tzset, assume the worst when cross-compiling.
3080 emacs_cv_localtime_cache=yes])
3081 else
3082         # If we lack tzset, report that localtime does not cache TZ,
3083         # since we can't invalidate the cache if we don't have tzset.
3084         emacs_cv_localtime_cache=no
3085 fi])dnl
3086 AC_MSG_RESULT($emacs_cv_localtime_cache)
3087 if test $emacs_cv_localtime_cache = yes; then
3088   AC_DEFINE(LOCALTIME_CACHE, 1,
3089             [Define to 1 if localtime caches TZ.])
3090 fi
3091
3092 if test "x$HAVE_TIMEVAL" = xyes; then
3093   AC_CHECK_FUNCS(gettimeofday)
3094   if test $ac_cv_func_gettimeofday = yes; then
3095     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3096                    emacs_cv_gettimeofday_two_arguments,
3097     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3098 #ifdef TIME_WITH_SYS_TIME
3099 #include <sys/time.h>
3100 #include <time.h>
3101 #else
3102 #ifdef HAVE_SYS_TIME_H
3103 #include <sys/time.h>
3104 #else
3105 #include <time.h>
3106 #endif
3107 #endif]],
3108       [[struct timeval time;
3109        gettimeofday (&time, 0);]])],
3110       emacs_cv_gettimeofday_two_arguments=yes,
3111       emacs_cv_gettimeofday_two_arguments=no)])
3112     if test $emacs_cv_gettimeofday_two_arguments = no; then
3113       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3114                 [Define to 1 if gettimeofday accepts only one argument.])
3115     fi
3116   fi
3117 fi
3118
3119 ok_so_far=yes
3120 AC_CHECK_FUNC(socket, , ok_so_far=no)
3121 if test $ok_so_far = yes; then
3122   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3123 fi
3124 if test $ok_so_far = yes; then
3125   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3126 fi
3127 if test $ok_so_far = yes; then
3128 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3129   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3130             [Define to 1 if you have inet sockets.])
3131 fi
3132
3133 if test -f /usr/lpp/X11/bin/smt.exp; then
3134   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3135             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3136 fi
3137
3138 AC_MSG_CHECKING(whether system supports dynamic ptys)
3139 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3140   AC_MSG_RESULT(yes)
3141   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3142 else
3143   AC_MSG_RESULT(no)
3144 fi
3145
3146 AC_FUNC_FORK
3147
3148 AC_CHECK_FUNCS(snprintf)
3149
3150 dnl Adapted from Haible's version.
3151 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3152   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3153     [[char* cs = nl_langinfo(CODESET);]])],
3154     emacs_cv_langinfo_codeset=yes,
3155     emacs_cv_langinfo_codeset=no)
3156   ])
3157 if test $emacs_cv_langinfo_codeset = yes; then
3158   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3159     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3160 fi
3161
3162 AC_TYPE_MBSTATE_T
3163
3164 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3165   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3166                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3167 if test "$emacs_cv_c_restrict_arr" = yes; then
3168   AC_DEFINE(__restrict_arr, __restrict,
3169     [Define to compiler's equivalent of C99 restrict keyword in array
3170      declarations.  Define as empty for no equivalent.])
3171 fi
3172
3173 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3174 dnl how the tty code is related to POSIX and/or other versions of termios.
3175 dnl The following looks like a useful start.
3176 dnl
3177 dnl AC_SYS_POSIX_TERMIOS
3178 dnl if test $ac_cv_sys_posix_termios = yes; then
3179 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3180 dnl                                and macros for terminal control.])
3181 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3182 dnl fi
3183
3184 # Set up the CFLAGS for real compilation, so we can substitute it.
3185 CFLAGS="$REAL_CFLAGS"
3186 CPPFLAGS="$REAL_CPPFLAGS"
3187
3188 ## Hack to detect a buggy GCC version.
3189 if test "x$GCC" = xyes \
3190    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3191    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3192    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3193    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3194 fi
3195
3196 version=$PACKAGE_VERSION
3197
3198 ### Specify what sort of things we'll be editing into Makefile and config.h.
3199 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3200 AC_SUBST(version)
3201 AC_SUBST(configuration)
3202 ## Unused?
3203 AC_SUBST(canonical)
3204 AC_SUBST(srcdir)
3205 AC_SUBST(prefix)
3206 AC_SUBST(exec_prefix)
3207 AC_SUBST(bindir)
3208 AC_SUBST(datadir)
3209 AC_SUBST(sharedstatedir)
3210 AC_SUBST(libexecdir)
3211 AC_SUBST(mandir)
3212 AC_SUBST(infodir)
3213 AC_SUBST(lispdir)
3214 AC_SUBST(locallisppath)
3215 AC_SUBST(lisppath)
3216 AC_SUBST(x_default_search_path)
3217 AC_SUBST(etcdir)
3218 AC_SUBST(archlibdir)
3219 AC_SUBST(docdir)
3220 AC_SUBST(bitmapdir)
3221 AC_SUBST(gamedir)
3222 AC_SUBST(gameuser)
3223 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3224 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3225 ## end of LIBX_BASE, but nothing ever set it.
3226 AC_SUBST(LD_SWITCH_X_SITE)
3227 AC_SUBST(C_SWITCH_X_SITE)
3228 AC_SUBST(C_SWITCH_X_SYSTEM)
3229 AC_SUBST(CFLAGS)
3230 ## Used in lwlib/Makefile.in.
3231 AC_SUBST(X_TOOLKIT_TYPE)
3232 if test -n "${machfile}"; then
3233   M_FILE="\$(srcdir)/${machfile}"
3234 else
3235   M_FILE=
3236 fi
3237 S_FILE="\$(srcdir)/${opsysfile}"
3238 AC_SUBST(M_FILE)
3239 AC_SUBST(S_FILE)
3240 AC_SUBST(ns_appdir)
3241 AC_SUBST(ns_appbindir)
3242 AC_SUBST(ns_appresdir)
3243 AC_SUBST(ns_appsrc)
3244 AC_SUBST(GNU_OBJC_CFLAGS)
3245 AC_SUBST(OTHER_FILES)
3246
3247 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3248                    [Define to the canonical Emacs configuration name.])
3249 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3250                    [Define to the options passed to configure.])
3251 if test -n "$machfile"; then
3252   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3253                      [Define to the used machine dependent file.])
3254 fi
3255 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3256                    [Define to the used os dependent file.])
3257
3258 XMENU_OBJ=
3259 XOBJ=
3260 FONT_OBJ=
3261 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3262   AC_DEFINE(HAVE_X_WINDOWS, 1,
3263             [Define to 1 if you want to use the X window system.])
3264   XMENU_OBJ=xmenu.o
3265   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3266   FONT_OBJ=xfont.o
3267   if test "$HAVE_XFT" = "yes"; then
3268     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3269   elif test "$HAVE_FREETYPE" = "yes"; then
3270     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3271   fi
3272   AC_SUBST(FONT_OBJ)
3273 fi
3274 AC_SUBST(XMENU_OBJ)
3275 AC_SUBST(XOBJ)
3276 AC_SUBST(FONT_OBJ)
3277
3278 WIDGET_OBJ=
3279 MOTIF_LIBW=
3280 if test "${USE_X_TOOLKIT}" != "none" ; then
3281   WIDGET_OBJ=widget.o
3282   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3283   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3284     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3285   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3286     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3287     MOTIF_LIBW=-lXm
3288     case "$opsys" in
3289       gnu-linux)
3290         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3291         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3292         ;;
3293
3294       unixware)
3295         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3296         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3297         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3298         ;;
3299
3300       aix4-2)
3301         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3302         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3303         ;;
3304     esac
3305     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3306   fi
3307 fi
3308 AC_SUBST(WIDGET_OBJ)
3309
3310 TOOLKIT_LIBW=
3311 case "$USE_X_TOOLKIT" in
3312   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3313   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3314   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3315 esac
3316 AC_SUBST(TOOLKIT_LIBW)
3317
3318 if test "$USE_X_TOOLKIT" = "none"; then
3319   LIBXT_OTHER="\$(LIBXSM)"
3320   OLDXMENU_TARGET="really-oldXMenu"
3321 else
3322   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3323   OLDXMENU_TARGET="really-lwlib"
3324 fi
3325 AC_SUBST(LIBXT_OTHER)
3326
3327 ## The X Menu stuff is present in the X10 distribution, but missing
3328 ## from X11.  If we have X10, just use the installed library;
3329 ## otherwise, use our own copy.
3330 if test "${HAVE_X11}" = "yes" ; then
3331   AC_DEFINE(HAVE_X11, 1,
3332             [Define to 1 if you want to use version 11 of X windows.
3333              Otherwise, Emacs expects to use version 10.])
3334
3335   if test "$USE_X_TOOLKIT" = "none"; then
3336     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3337   else
3338     OLDXMENU="\${lwlibdir}/liblw.a"
3339   fi
3340   LIBXMENU="\$(OLDXMENU)"
3341   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3342   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3343 else
3344   ## For a syntactically valid Makefile; not actually used for anything.
3345   ## See comments in src/Makefile.in.
3346   OLDXMENU=nothing
3347   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3348   if test "${HAVE_X_WINDOWS}" = "yes"; then
3349     LIBXMENU="-lXMenu"
3350   else
3351     LIBXMENU=
3352   fi
3353   LIBX_OTHER=
3354   OLDXMENU_DEPS=
3355 fi
3356
3357 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3358   OLDXMENU_TARGET=
3359   OLDXMENU=nothing
3360   LIBXMENU=
3361   OLDXMENU_DEPS=
3362 fi
3363
3364 AC_SUBST(OLDXMENU_TARGET)
3365 AC_SUBST(OLDXMENU)
3366 AC_SUBST(LIBXMENU)
3367 AC_SUBST(LIBX_OTHER)
3368 AC_SUBST(OLDXMENU_DEPS)
3369
3370 if test "${HAVE_MENUS}" = "yes" ; then
3371   AC_DEFINE(HAVE_MENUS, 1,
3372             [Define to 1 if you have mouse menus.
3373              (This is automatic if you use X, but the option to specify it remains.)
3374              It is also defined with other window systems that support xmenu.c.])
3375 fi
3376
3377 if test "${GNU_MALLOC}" = "yes" ; then
3378   AC_DEFINE(GNU_MALLOC, 1,
3379             [Define to 1 if you want to use the GNU memory allocator.])
3380 fi
3381
3382 RALLOC_OBJ=
3383 if test "${REL_ALLOC}" = "yes" ; then
3384   AC_DEFINE(REL_ALLOC, 1,
3385             [Define REL_ALLOC if you want to use the relocating allocator for
3386              buffer space.])
3387
3388   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3389 fi
3390 AC_SUBST(RALLOC_OBJ)
3391
3392 if test "$opsys" = "cygwin"; then
3393   CYGWIN_OBJ="sheap.o"
3394   ## Cygwin differs because of its unexec().
3395   PRE_ALLOC_OBJ=
3396   POST_ALLOC_OBJ=lastfile.o
3397 else
3398   CYGWIN_OBJ=
3399   PRE_ALLOC_OBJ=lastfile.o
3400   POST_ALLOC_OBJ=
3401 fi
3402 AC_SUBST(CYGWIN_OBJ)
3403 AC_SUBST(PRE_ALLOC_OBJ)
3404 AC_SUBST(POST_ALLOC_OBJ)
3405
3406 # Configure gnulib here, now that we know LIBS.
3407 gl_ASSERT_NO_GNULIB_POSIXCHECK
3408 gl_ASSERT_NO_GNULIB_TESTS
3409 gl_INIT
3410
3411 case "$opsys" in
3412   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3413
3414   darwin)
3415    ## The -headerpad option tells ld (see man page) to leave room at the
3416    ## end of the header for adding load commands.  Needed for dumping.
3417    ## 0x690 is the total size of 30 segment load commands (at 56
3418    ## each); under Cocoa 31 commands are required.
3419    if test "$HAVE_NS" = "yes"; then
3420      libs_nsgui="-framework AppKit"
3421      headerpad_extra=6C8
3422    else
3423      libs_nsgui=
3424      headerpad_extra=690
3425    fi
3426    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3427
3428    ## This is here because src/Makefile.in did some extra fiddling around
3429    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3430    ##   #ifndef LD_SWITCH_SYSTEM
3431    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3432    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3433    ## not using gcc, darwin system not on an alpha (ie darwin, since
3434    ## darwin + alpha does not occur).
3435    ## Because this was done in src/Makefile.in, the resulting part of
3436    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3437    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3438    ## rather than LD_SWITCH_SYSTEM.
3439    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3440      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3441    ;;
3442
3443   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3444   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3445   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3446   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3447   ## had different values in configure (in ac_link) and src/Makefile.in.
3448   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3449   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX_RPATH)" ;;
3450
3451   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3452 esac
3453
3454 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3455   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3456 fi
3457
3458 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3459
3460
3461 LD_FIRSTFLAG=
3462 ORDINARY_LINK=
3463 case "$opsys" in
3464   ## gnu: GNU needs its own crt0.
3465   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3466
3467   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3468   ## library search parth, i.e. it won't search /usr/lib for libc and
3469   ## friends.  Using -nostartfiles instead avoids this problem, and
3470   ## will also work on earlier NetBSD releases.
3471   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3472
3473   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3474   ##   MkLinux/LinuxPPC needs this.
3475   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3476   gnu-*)
3477     case "$machine" in
3478       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3479     esac
3480     ;;
3481 esac
3482
3483
3484 if test "x$ORDINARY_LINK" = "xyes"; then
3485
3486   LD_FIRSTFLAG=""
3487   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3488
3489 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3490 ## freebsd, gnu-* not on macppc|ibms390x.
3491 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3492
3493   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3494   ## places that are difficult to figure out at make time.  Fortunately,
3495   ## these same versions allow you to pass arbitrary flags on to the
3496   ## linker, so there is no reason not to use it as a linker.
3497   ##
3498   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3499   ## searching for libraries in its internal directories, so we have to
3500   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3501   LD_FIRSTFLAG="-nostdlib"
3502 fi
3503
3504 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3505 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3506
3507 AC_SUBST(LD_FIRSTFLAG)
3508
3509
3510 ## FIXME? The logic here is not precisely the same as that above.
3511 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3512 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3513 LIB_GCC=
3514 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3515
3516   case "$opsys" in
3517     freebsd|netbsd|openbsd) LIB_GCC= ;;
3518
3519     gnu-*)
3520       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3521       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3522       case $host_cpu in
3523       arm*)
3524         LIB_GCC="-lgcc_s"
3525         ;;
3526       *)
3527         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3528         ## immediately undefine it again and redefine it to empty.
3529         ## Was the C_SWITCH_X_SITE part really necessary?
3530 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3531         LIB_GCC=
3532         ;;
3533       esac
3534       ;;
3535
3536     ## Ask GCC where to find libgcc.a.
3537     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3538   esac
3539 fi                              dnl if $GCC
3540 AC_SUBST(LIB_GCC)
3541
3542
3543 ## If we're using X11/GNUstep, define some consequences.
3544 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3545   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3546   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3547 fi
3548
3549
3550 AH_TOP([/* GNU Emacs site configuration template file.
3551
3552 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3553   Free Software Foundation, Inc.
3554
3555 This file is part of GNU Emacs.
3556
3557 GNU Emacs is free software: you can redistribute it and/or modify
3558 it under the terms of the GNU General Public License as published by
3559 the Free Software Foundation, either version 3 of the License, or
3560 (at your option) any later version.
3561
3562 GNU Emacs is distributed in the hope that it will be useful,
3563 but WITHOUT ANY WARRANTY; without even the implied warranty of
3564 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3565 GNU General Public License for more details.
3566
3567 You should have received a copy of the GNU General Public License
3568 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3569
3570
3571 /* No code in Emacs #includes config.h twice, but some bits of code
3572    intended to work with other packages as well (like gmalloc.c)
3573    think they can include it as many times as they like.  */
3574 #ifndef EMACS_CONFIG_H
3575 #define EMACS_CONFIG_H
3576 ])dnl
3577
3578 AH_BOTTOM([
3579 /* On AIX 3 this must be included before any other include file.  */
3580 #include <alloca.h>
3581 #if ! HAVE_ALLOCA
3582 # error "alloca not available on this machine"
3583 #endif
3584
3585 /* Define AMPERSAND_FULL_NAME if you use the convention
3586    that & in the full name stands for the login id.  */
3587 /* Turned on June 1996 supposing nobody will mind it.  */
3588 #define AMPERSAND_FULL_NAME
3589
3590 /* `subprocesses' should be defined if you want to
3591    have code for asynchronous subprocesses
3592    (as used in M-x compile and M-x shell).
3593    Only MSDOS does not support this (it overrides
3594    this in its config_opsysfile below).  */
3595
3596 #define subprocesses
3597
3598 /* Include the os and machine dependent files.  */
3599 #include config_opsysfile
3600 #ifdef config_machfile
3601 # include config_machfile
3602 #endif
3603
3604 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3605    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3606   (There is probably a better place to do this, but right now the
3607    Cocoa side does this in s/darwin.h and we cannot parallel this
3608    exactly since GNUstep is multi-OS.  */
3609 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3610 #  define SYSTEM_PURESIZE_EXTRA 30000
3611 #endif
3612
3613 #ifdef emacs /* Don't do this for lib-src.  */
3614 /* Tell regex.c to use a type compatible with Emacs.  */
3615 #define RE_TRANSLATE_TYPE Lisp_Object
3616 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3617 #ifdef make_number
3618 /* If make_number is a macro, use it.  */
3619 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3620 #else
3621 /* If make_number is a function, avoid it.  */
3622 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3623 #endif
3624 #endif
3625
3626 /* These default definitions are good for almost all machines.
3627    Any exceptions should override them in m/MACHINE.h.
3628    They must be usable in preprocessor conditionals.  */
3629
3630 #ifndef BITS_PER_CHAR
3631 #define BITS_PER_CHAR 8
3632 #endif
3633
3634 #ifndef BITS_PER_SHORT
3635 #define BITS_PER_SHORT 16
3636 #endif
3637
3638 #ifndef BITS_PER_INT
3639 #define BITS_PER_INT 32
3640 #endif
3641
3642 #ifndef BITS_PER_LONG
3643 #ifdef _LP64
3644 #define BITS_PER_LONG 64
3645 #else
3646 #define BITS_PER_LONG 32
3647 #endif
3648 #endif
3649
3650 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3651 #define BITS_PER_LONG_LONG 64
3652 #endif
3653
3654 /* Define if the compiler supports function prototypes.  It may do so but
3655    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3656 #undef PROTOTYPES
3657
3658 #include <string.h>
3659 #include <stdlib.h>
3660
3661 #if defined __GNUC__ && (__GNUC__ > 2 \
3662                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3663 #define NO_RETURN       __attribute__ ((__noreturn__))
3664 #else
3665 #define NO_RETURN       /* nothing */
3666 #endif
3667
3668 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3669 #define NO_INLINE __attribute__((noinline))
3670 #else
3671 #define NO_INLINE
3672 #endif
3673
3674 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3675 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3676 #else
3677 #define EXTERNALLY_VISIBLE
3678 #endif
3679
3680 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3681 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3682 #else
3683 # define ATTRIBUTE_FORMAT(spec) /* empty */
3684 #endif
3685
3686 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3687 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3688    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3689 #else
3690 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3691    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3692 #endif
3693
3694 /* Some versions of GNU/Linux define noinline in their headers.  */
3695 #ifdef noinline
3696 #undef noinline
3697 #endif
3698
3699 /* These won't be used automatically yet.  We also need to know, at least,
3700    that the stack is continuous.  */
3701 #ifdef __GNUC__
3702 #  ifndef GC_SETJMP_WORKS
3703   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3704 #    define GC_SETJMP_WORKS 1
3705 #  endif
3706 #endif
3707
3708 #endif /* EMACS_CONFIG_H */
3709
3710 /*
3711 Local Variables:
3712 mode: c
3713 End:
3714 */
3715 ])dnl
3716
3717 #### Report on what we decided to do.
3718 #### Report GTK as a toolkit, even if it doesn't use Xt.
3719 #### It makes printing result more understandable as using GTK sets
3720 #### toolkit_scroll_bars to yes by default.
3721 if test "${HAVE_GTK}" = "yes"; then
3722   USE_X_TOOLKIT=GTK
3723 fi
3724
3725 and_machfile=
3726 if test -n "$machfile"; then
3727   and_machfile=" and \`${machfile}'"
3728 fi
3729
3730 echo "
3731 Configured for \`${canonical}'.
3732
3733   Where should the build process find the source code?    ${srcdir}
3734   What operating system and machine description files should Emacs use?
3735         \`${opsysfile}'${and_machfile}
3736   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3737   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3738   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3739   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3740   What window system should Emacs use?                    ${window_system}
3741   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3742
3743 if test -n "${x_includes}"; then
3744 echo "  Where do we find X Windows header files?                ${x_includes}"
3745 else
3746 echo "  Where do we find X Windows header files?                Standard dirs"
3747 fi
3748 if test -n "${x_libraries}"; then
3749 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3750 else
3751 echo "  Where do we find X Windows libraries?                   Standard dirs"
3752 fi
3753
3754 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3755 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3756 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3757 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3758 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3759 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3760 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3761 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3762
3763 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3764 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3765 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3766 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3767 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3768 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3769 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3770
3771 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3772 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3773 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3774 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3775
3776 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3777 echo
3778
3779 if test -n "${EMACSDATA}"; then
3780    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3781 fi
3782 if test -n "${EMACSDOC}"; then
3783    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3784 fi
3785
3786 if test $USE_XASSERTS = yes; then
3787    echo "  Compiling with asserts turned on."
3788    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3789 fi
3790
3791 echo
3792
3793 if test "$HAVE_NS" = "yes"; then
3794    echo
3795    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3796 The installed application will go to nextstep/Emacs.app and can be
3797 run or moved from there."
3798    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3799       echo "The application will be fully self-contained."
3800     else
3801       echo "The lisp resources for the application will be installed under ${prefix}.
3802 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3803 to run if these resources are not installed."
3804    fi
3805    echo
3806 fi
3807
3808
3809 # Remove any trailing slashes in these variables.
3810 [test "${prefix}" != NONE &&
3811   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3812 test "${exec_prefix}" != NONE &&
3813   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3814
3815 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3816 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3817 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3818 dnl (else you get "no `Makefile.am' found for any configure output").
3819 dnl This will work, but you get a config.status that is not quite right
3820 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3821 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3822 dnl it seems better to just live with the duplication.
3823 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3824
3825 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3826        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3827        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3828        leim/Makefile])
3829
3830 dnl test/ is not present in release tarfiles.
3831 opt_makefile=test/automated/Makefile
3832
3833 if test -f $srcdir/${opt_makefile}.in; then
3834   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3835   dnl Again, it's best not to use a variable.  Though you can add
3836   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3837   AC_CONFIG_FILES([test/automated/Makefile])
3838 fi
3839
3840 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3841
3842 AC_SUBST(SUBDIR_MAKEFILES_IN)
3843
3844 dnl Make the necessary directories, if they don't exist.
3845 AC_CONFIG_COMMANDS([mkdirs], [
3846 for dir in etc lisp ; do
3847   test -d ${dir} || mkdir ${dir}
3848 done
3849 ])
3850
3851 dnl You might wonder (I did) why epaths.h is generated by running make,
3852 dnl rather than just letting configure generate it from epaths.in.
3853 dnl One reason is that the various paths are not fully expanded (see above);
3854 dnl eg gamedir=${prefix}/var/games/emacs.
3855 dnl Secondly, the GNU Coding standards require that one should be able
3856 dnl to run `make prefix=/some/where/else' and override the values set
3857 dnl by configure.  This also explains the `move-if-change' test and
3858 dnl the use of force in the `epaths-force' rule in Makefile.in.
3859 AC_CONFIG_COMMANDS([epaths], [
3860 echo creating src/epaths.h
3861 ${MAKE-make} epaths-force
3862 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3863
3864 AC_CONFIG_COMMANDS([gdbinit], [
3865 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3866   echo creating src/.gdbinit
3867   echo source $srcdir/src/.gdbinit > src/.gdbinit
3868 fi
3869 ])
3870
3871 AC_OUTPUT
3872
3873 dnl configure.in ends here