*** empty log message ***
[bpt/emacs.git] / lisp / url / url-handlers.el
1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
2
3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
4 ;; 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
5
6 ;; Keywords: comm, data, processes, hypermedia
7
8 ;; This file is part of GNU Emacs.
9 ;;
10 ;; GNU Emacs is free software; you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation; either version 3, or (at your option)
13 ;; any later version.
14 ;;
15 ;; GNU Emacs is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 ;; GNU General Public License for more details.
19 ;;
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs; see the file COPYING. If not, write to the
22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
23 ;; Boston, MA 02110-1301, USA.
24
25 ;;; Commentary:
26
27 ;;; Code:
28
29 ;; (require 'url)
30 (require 'url-parse)
31 ;; (require 'url-util)
32 (eval-when-compile (require 'mm-decode))
33 ;; (require 'mailcap)
34 ;; The following functions in the byte compiler's warnings are known not
35 ;; to cause any real problem for the following reasons:
36 ;; - mm-save-part-to-file, mm-destroy-parts: always used
37 ;; after mm-dissect-buffer and defined in the same file.
38 ;; The following are autoloaded instead of `require'd to avoid eagerly
39 ;; loading all of URL when turning on url-handler-mode in the .emacs.
40 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
41 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
42 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
43
44 ;; Implementation status
45 ;; ---------------------
46 ;; Function Status
47 ;; ------------------------------------------------------------
48 ;; add-name-to-file Needs DAV Bindings
49 ;; copy-file Broken (assumes 1st item is URL)
50 ;; delete-directory Finished (DAV)
51 ;; delete-file Finished (DAV)
52 ;; diff-latest-backup-file
53 ;; directory-file-name unnecessary (what about VMS)?
54 ;; directory-files Finished (DAV)
55 ;; dired-call-process
56 ;; dired-compress-file
57 ;; dired-uncache
58 ;; expand-file-name Finished
59 ;; file-accessible-directory-p
60 ;; file-attributes Finished, better with DAV
61 ;; file-directory-p Needs DAV, finished
62 ;; file-executable-p Finished
63 ;; file-exists-p Finished
64 ;; file-local-copy
65 ;; file-modes
66 ;; file-name-all-completions Finished (DAV)
67 ;; file-name-as-directory
68 ;; file-name-completion Finished (DAV)
69 ;; file-name-directory
70 ;; file-name-nondirectory
71 ;; file-name-sans-versions why?
72 ;; file-newer-than-file-p
73 ;; file-ownership-preserved-p No way to know
74 ;; file-readable-p Finished
75 ;; file-regular-p !directory_p
76 ;; file-symlink-p Needs DAV bindings
77 ;; file-truename Needs DAV bindings
78 ;; file-writable-p Check for LOCK?
79 ;; find-backup-file-name why?
80 ;; get-file-buffer why?
81 ;; insert-directory Use DAV
82 ;; insert-file-contents Finished
83 ;; load
84 ;; make-directory Finished (DAV)
85 ;; make-symbolic-link Needs DAV bindings
86 ;; rename-file Finished (DAV)
87 ;; set-file-modes Use mod_dav specific executable flag?
88 ;; set-visited-file-modtime Impossible?
89 ;; shell-command Impossible?
90 ;; unhandled-file-name-directory
91 ;; vc-registered Finished (DAV)
92 ;; verify-visited-file-modtime
93 ;; write-region
94
95 (defvar url-handler-regexp
96 "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
97 "*A regular expression for matching URLs handled by file-name-handler-alist.
98 Some valid URL protocols just do not make sense to visit interactively
99 \(about, data, info, irc, mailto, etc\). This regular expression
100 avoids conflicts with local files that look like URLs \(Gnus is
101 particularly bad at this\).")
102
103 ;;;###autoload
104 (define-minor-mode url-handler-mode
105 "Use URL to handle URL-like file names."
106 :global t :group 'url
107 (if (not (boundp 'file-name-handler-alist))
108 ;; Can't be turned ON anyway.
109 (setq url-handler-mode nil)
110 ;; Remove old entry, if any.
111 (setq file-name-handler-alist
112 (delq (rassq 'url-file-handler file-name-handler-alist)
113 file-name-handler-alist))
114 (if url-handler-mode
115 (push (cons url-handler-regexp 'url-file-handler)
116 file-name-handler-alist))))
117
118 (defun url-run-real-handler (operation args)
119 (let ((inhibit-file-name-handlers (cons 'url-file-handler
120 (if (eq operation inhibit-file-name-operation)
121 inhibit-file-name-handlers)))
122 (inhibit-file-name-operation operation))
123 (apply operation args)))
124
125 ;;;###autoload
126 (defun url-file-handler (operation &rest args)
127 "Function called from the `file-name-handler-alist' routines.
128 OPERATION is what needs to be done (`file-exists-p', etc). ARGS are
129 the arguments that would have been passed to OPERATION."
130 (let ((fn (or (get operation 'url-file-handlers)
131 (intern-soft (format "url-%s" operation))))
132 (val nil)
133 (hooked nil))
134 (if (and fn (fboundp fn))
135 (setq hooked t
136 val (apply fn args))
137 (setq hooked nil
138 val (url-run-real-handler operation args)))
139 (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
140 operation args val)
141 val))
142
143 (defun url-file-handler-identity (&rest args)
144 ;; Identity function
145 (car args))
146
147 ;; These are operations that we can fully support
148 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
149 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
150 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
151 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
152 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
153 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
154 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
155
156 ;; These are operations that we do not support yet (DAV!!!)
157 (put 'file-writable-p 'url-file-handlers 'ignore)
158 (put 'file-symlink-p 'url-file-handlers 'ignore)
159 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
160 ;; files and such since we can't do anything clever with them anyway.
161 (put 'vc-registered 'url-file-handlers 'ignore)
162
163 (defun url-handler-expand-file-name (file &optional base)
164 ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
165 ;; there are two interpretations possible: either it's a local "/foo/bar"
166 ;; or it's "http:/bla/foo/bar". When working with URLs, the second
167 ;; interpretation is the right one, but when working with Emacs file
168 ;; names, the first is preferred.
169 (if (file-name-absolute-p file)
170 (expand-file-name file "/")
171 (url-expand-file-name file base)))
172
173 ;; directory-file-name and file-name-as-directory are kind of hard to
174 ;; implement really right for URLs since URLs can have repeated / chars.
175 ;; We'd want the following behavior:
176 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
177 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
178 ;; reversible: (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
179 ;; reversible: (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
180 (defun url-handler-directory-file-name (dir)
181 ;; When there's more than a single /, just don't touch the slashes at all.
182 (if (string-match "//\\'" dir) dir
183 (url-run-real-handler 'directory-file-name (list dir))))
184
185 (defun url-handler-unhandled-file-name-directory (filename)
186 ;; Copied from tramp.el. This is used as the cwd for subprocesses:
187 ;; without it running call-process or start-process in a URL directory
188 ;; signals an error.
189 ;; FIXME: we can do better if `filename' is a "file://" URL.
190 (expand-file-name "~/"))
191
192 ;; The actual implementation
193 ;;;###autoload
194 (defun url-copy-file (url newname &optional ok-if-already-exists keep-time)
195 "Copy URL to NEWNAME. Both args must be strings.
196 Signals a `file-already-exists' error if file NEWNAME already exists,
197 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
198 A number as third arg means request confirmation if NEWNAME already exists.
199 This is what happens in interactive use with M-x.
200 Fourth arg KEEP-TIME non-nil means give the new file the same
201 last-modified time as the old one. (This works on only some systems.)
202 A prefix arg makes KEEP-TIME non-nil."
203 (if (and (file-exists-p newname)
204 (not ok-if-already-exists))
205 (error "Opening output file: File already exists, %s" newname))
206 (let ((buffer (url-retrieve-synchronously url))
207 (handle nil))
208 (if (not buffer)
209 (error "Opening input file: No such file or directory, %s" url))
210 (with-current-buffer buffer
211 (setq handle (mm-dissect-buffer t)))
212 (mm-save-part-to-file handle newname)
213 (kill-buffer buffer)
214 (mm-destroy-parts handle)))
215
216 ;;;###autoload
217 (defun url-file-local-copy (url &rest ignored)
218 "Copy URL into a temporary file on this machine.
219 Returns the name of the local copy, or nil, if FILE is directly
220 accessible."
221 (let ((filename (make-temp-file "url")))
222 (url-copy-file url filename 'ok-if-already-exists)
223 filename))
224
225 (defun url-insert (buffer &optional beg end)
226 "Insert the body of a URL object.
227 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
228 If the headers specify a coding-system, it is applied to the body before it is inserted.
229 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
230 of the inserted text and CHARSET is the charset that was specified in the header,
231 or nil if none was found.
232 BEG and END can be used to only insert a subpart of the body.
233 They count bytes from the beginning of the body."
234 (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
235 (data (with-current-buffer (mm-handle-buffer handle)
236 (if beg
237 (buffer-substring (+ (point-min) beg)
238 (if end (+ (point-min) end) (point-max)))
239 (buffer-string))))
240 (charset (mail-content-type-get (mm-handle-type handle)
241 'charset)))
242 (mm-destroy-parts handle)
243 (if charset
244 (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
245 (insert data))
246 (list (length data) charset)))
247
248 ;;;###autoload
249 (defun url-insert-file-contents (url &optional visit beg end replace)
250 (let ((buffer (url-retrieve-synchronously url)))
251 (if (not buffer)
252 (error "Opening input file: No such file or directory, %s" url))
253 (if visit (setq buffer-file-name url))
254 (save-excursion
255 (let* ((start (point))
256 (size-and-charset (url-insert buffer beg end)))
257 (kill-buffer buffer)
258 (when replace
259 (delete-region (point-min) start)
260 (delete-region (point) (point-max)))
261 (unless (cadr size-and-charset)
262 ;; If the headers don't specify any particular charset, use the
263 ;; usual heuristic/rules that we apply to files.
264 (decode-coding-inserted-region start (point) url visit beg end replace))
265 (list url (car size-and-charset))))))
266
267 (defun url-file-name-completion (url directory)
268 (error "Unimplemented"))
269
270 (defun url-file-name-all-completions (file directory)
271 (error "Unimplemented"))
272
273 ;; All other handlers map onto their respective backends.
274 (defmacro url-handlers-create-wrapper (method args)
275 `(defun ,(intern (format "url-%s" method)) ,args
276 ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
277 (or (documentation method t) "No original documentation."))
278 (setq url (url-generic-parse-url url))
279 (when (url-type url)
280 (funcall (url-scheme-get-property (url-type url) (quote ,method))
281 ,@(remove '&rest (remove '&optional args))))))
282
283 (url-handlers-create-wrapper file-exists-p (url))
284 (url-handlers-create-wrapper file-attributes (url &optional id-format))
285 (url-handlers-create-wrapper file-symlink-p (url))
286 (url-handlers-create-wrapper file-writable-p (url))
287 (url-handlers-create-wrapper file-directory-p (url))
288 (url-handlers-create-wrapper file-executable-p (url))
289 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
290 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
291
292 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
293
294 (defun url-handlers-set-buffer-mode ()
295 "Set correct modes for the current buffer if visiting a remote file."
296 (and (stringp buffer-file-name)
297 (string-match url-handler-regexp buffer-file-name)
298 (auto-save-mode 0)))
299
300 (provide 'url-handlers)
301
302 ;; arch-tag: 7300b99c-cc83-42ff-9147-79b2723c62ac
303 ;;; url-handlers.el ends here