lisp/wdired.el

   1 ;;; wdired.el --- Rename files editing their names in dired buffers
   2
   3 ;; Copyright (C) 2004-2012  Free Software Foundation, Inc.
   4
   5 ;; Filename: wdired.el
   6 ;; Author: Juan León Lahoz García <juanleon1@gmail.com>
   7 ;; Version: 2.0
   8 ;; Keywords: dired, environment, files, renaming
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; wdired.el (the "w" is for writable) provides an alternative way of
  28 ;; renaming files.
  29 ;;
  30 ;; Have you ever wished to use C-x r t (string-rectangle), M-%
  31 ;; (query-replace), M-c (capitalize-word), etc... to change the name of
  32 ;; the files in a "dired" buffer? Now you can do this.  All the power
  33 ;; of Emacs commands are available to renaming files!
  34 ;;
  35 ;; This package provides a function that makes the filenames of a
  36 ;; dired buffer editable, by changing the buffer mode (which inhibits
  37 ;; all of the commands of dired mode). Here you can edit the names of
  38 ;; one or more files and directories, and when you press C-c C-c, the
  39 ;; renaming takes effect and you are back to dired mode.
  40 ;;
  41 ;; Another things you can do with WDired:
  42 ;;
  43 ;; - To move files to another directory (by typing their path,
  44 ;;   absolute or relative, as a part of the new filename).
  45 ;;
  46 ;; - To change the target of symbolic links.
  47 ;;
  48 ;; - To change the permission bits of the filenames (in systems with a
  49 ;;   working unix-alike `dired-chmod-program'). See and customize the
  50 ;;   variable `wdired-allow-to-change-permissions'.  To change a single
  51 ;;   char (toggling between its two more usual values) you can press
  52 ;;   the space bar over it or left-click the mouse.  To set any char to
  53 ;;   an specific value (this includes the SUID, SGID and STI bits) you
  54 ;;   can use the key labeled as the letter you want.  Please note that
  55 ;;   permissions of the links cannot be changed in that way, because
  56 ;;   the change would affect to their targets, and this would not be
  57 ;;   WYSIWYG :-).
  58 ;;
  59 ;; - To mark files for deletion, by deleting their whole filename.
  60
  61 ;;; Usage:
  62
  63 ;; You can edit the names of the files by typing C-x C-q or by
  64 ;; executing M-x wdired-change-to-wdired-mode.  Use C-c C-c when
  65 ;; finished or C-c C-k to abort.  While editing filenames, a new
  66 ;; submenu "WDired" is available at top level.  You can customize the
  67 ;; behavior of this package from this menu.
  68
  69 ;;; Change Log:
  70
  71 ;; Google is your friend (previous versions with complete changelogs
  72 ;; were posted to gnu.emacs.sources)
  73
  74 ;;; Code:
  75
  76 (defvar dired-backup-overwrite) ; Only in Emacs 20.x this is a custom var
  77
  78 (require 'dired)
  79 (autoload 'dired-do-create-files-regexp "dired-aux")
  80
  81 (defgroup wdired nil
  82   "Mode to rename files by editing their names in dired buffers."
  83   :group 'dired)
  84
  85 (defcustom wdired-use-interactive-rename nil
  86   "If non-nil, WDired requires confirmation before actually renaming files.
  87 If nil, WDired doesn't require confirmation to change the file names,
  88 and the variable `wdired-confirm-overwrite' controls whether it is ok
  89 to overwrite files without asking."
  90   :type 'boolean
  91   :group 'wdired)
  92
  93 (defcustom wdired-confirm-overwrite t
  94   "If nil the renames can overwrite files without asking.
  95 This variable has no effect at all if `wdired-use-interactive-rename'
  96 is not nil."
  97   :type 'boolean
  98   :group 'wdired)
  99
 100 (defcustom wdired-use-dired-vertical-movement nil
 101   "If t, the \"up\" and \"down\" movement works as in Dired mode.
 102 That is, always move the point to the beginning of the filename at line.
 103
 104 If `sometimes', only move to the beginning of filename if the point is
 105 before it, and `track-eol' is non-nil.  This behavior is very handy
 106 when editing several filenames.
 107
 108 If nil, \"up\" and \"down\" movement is done as in any other buffer."
 109   :type '(choice (const :tag "As in any other mode" nil)
 110                  (const :tag "Smart cursor placement" sometimes)
 111                  (other :tag "As in dired mode" t))
 112   :group 'wdired)
 113
 114 (defcustom wdired-allow-to-redirect-links t
 115   "If non-nil, the target of the symbolic links are editable.
 116 In systems without symbolic links support, this variable has no effect
 117 at all."
 118   :type 'boolean
 119   :group 'wdired)
 120
 121 (defcustom wdired-allow-to-change-permissions nil
 122   "If non-nil, the permissions bits of the files are editable.
 123
 124 If t, to change a single bit, put the cursor over it and press the
 125 space bar, or left click over it.  You can also hit the letter you want
 126 to set: if this value is allowed, the character in the buffer will be
 127 changed.  Anyway, the point is advanced one position, so, for example,
 128 you can keep the <x> key pressed to give execution permissions to
 129 everybody to that file.
 130
 131 If `advanced', the bits are freely editable.  You can use
 132 `string-rectangle', `query-replace', etc.  You can put any value (even
 133 newlines), but if you want your changes to be useful, you better put a
 134 intelligible value.
 135
 136 Anyway, the real change of the permissions is done by the external
 137 program `dired-chmod-program', which must exist."
 138   :type '(choice (const :tag "Not allowed" nil)
 139                  (const :tag "Toggle/set bits" t)
 140                  (other :tag "Bits freely editable" advanced))
 141   :group 'wdired)
 142
 143 (defvar wdired-mode-map
 144   (let ((map (make-sparse-keymap)))
 145     (define-key map "\C-x\C-s" 'wdired-finish-edit)
 146     (define-key map "\C-c\C-c" 'wdired-finish-edit)
 147     (define-key map "\C-c\C-k" 'wdired-abort-changes)
 148     (define-key map "\C-c\C-[" 'wdired-abort-changes)
 149     (define-key map "\C-x\C-q" 'wdired-exit)
 150     (define-key map "\C-m"     'ignore)
 151     (define-key map "\C-j"     'ignore)
 152     (define-key map "\C-o"     'ignore)
 153     (define-key map [up]       'wdired-previous-line)
 154     (define-key map "\C-p"     'wdired-previous-line)
 155     (define-key map [down]     'wdired-next-line)
 156     (define-key map "\C-n"     'wdired-next-line)
 157
 158     (define-key map [menu-bar wdired]
 159       (cons "WDired" (make-sparse-keymap "WDired")))
 160     (define-key map [menu-bar wdired wdired-customize]
 161       '("Options" . wdired-customize))
 162     (define-key map [menu-bar wdired dashes]
 163       '("--"))
 164     (define-key map [menu-bar wdired wdired-abort-changes]
 165       '(menu-item "Abort Changes" wdired-abort-changes
 166                   :help "Abort changes and return to dired mode"))
 167     (define-key map [menu-bar wdired wdired-finish-edit]
 168       '("Commit Changes" . wdired-finish-edit))
 169
 170     (define-key map [remap upcase-word] 'wdired-upcase-word)
 171     (define-key map [remap capitalize-word] 'wdired-capitalize-word)
 172     (define-key map [remap downcase-word] 'wdired-downcase-word)
 173
 174     map))
 175
 176 (defvar wdired-mode-hook nil
 177   "Hooks run when changing to WDired mode.")
 178
 179 ;; Local variables (put here to avoid compilation gripes)
 180 (defvar wdired-col-perm) ;; Column where the permission bits start
 181 (defvar wdired-old-content)
 182 (defvar wdired-old-point)
 183 (defvar wdired-old-marks)
 184
 185 (defun wdired-mode ()
 186   "Writable Dired (WDired) mode.
 187 \\<wdired-mode-map>
 188 In WDired mode, you can edit the names of the files in the
 189 buffer, the target of the links, and the permission bits of the
 190 files.
 191
 192 Type \\[wdired-finish-edit] to exit WDired mode, returning to
 193 Dired mode, and make your edits \"take effect\" by modifying the
 194 file and directory names, link targets, and/or file permissions
 195 on disk.  If you delete the filename of a file, it is flagged for
 196 deletion in the Dired buffer.
 197
 198 Type \\[wdired-abort-changes] to abort your edits and exit WDired mode.
 199
 200 Type \\[customize-group] RET wdired to customize WDired behavior.
 201
 202 The only editable texts in a WDired buffer are filenames,
 203 symbolic link targets, and filenames permission."
 204   (interactive)
 205   (error "This mode can be enabled only by `wdired-change-to-wdired-mode'"))
 206 (put 'wdired-mode 'mode-class 'special)
 207
 208
 209 ;;;###autoload
 210 (defun wdired-change-to-wdired-mode ()
 211   "Put a Dired buffer in Writable Dired (WDired) mode.
 212 \\<wdired-mode-map>
 213 In WDired mode, you can edit the names of the files in the
 214 buffer, the target of the links, and the permission bits of the
 215 files.  After typing \\[wdired-finish-edit], Emacs modifies the files and
 216 directories to reflect your edits.
 217
 218 See `wdired-mode'."
 219   (interactive)
 220   (unless (eq major-mode 'dired-mode)
 221     (error "Not a Dired buffer"))
 222   (set (make-local-variable 'wdired-old-content)
 223        (buffer-substring (point-min) (point-max)))
 224   (set (make-local-variable 'wdired-old-marks)
 225        (dired-remember-marks (point-min) (point-max)))
 226   (set (make-local-variable 'wdired-old-point) (point))
 227   (set (make-local-variable 'query-replace-skip-read-only) t)
 228   (set (make-local-variable 'isearch-filter-predicate)
 229        'wdired-isearch-filter-read-only)
 230   (use-local-map wdired-mode-map)
 231   (force-mode-line-update)
 232   (setq buffer-read-only nil)
 233   (dired-unadvertise default-directory)
 234   (add-hook 'kill-buffer-hook 'wdired-check-kill-buffer nil t)
 235   (setq major-mode 'wdired-mode)
 236   (setq mode-name "Editable Dired")
 237   (setq revert-buffer-function 'wdired-revert)
 238   ;; I temp disable undo for performance: since I'm going to clear the
 239   ;; undo list, it can save more than a 9% of time with big
 240   ;; directories because setting properties modify the undo-list.
 241   (buffer-disable-undo)
 242   (wdired-preprocess-files)
 243   (if wdired-allow-to-change-permissions
 244       (wdired-preprocess-perms))
 245   (if (and wdired-allow-to-redirect-links (fboundp 'make-symbolic-link))
 246       (wdired-preprocess-symlinks))
 247   (buffer-enable-undo) ; Performance hack. See above.
 248   (set-buffer-modified-p nil)
 249   (setq buffer-undo-list nil)
 250   (run-mode-hooks 'wdired-mode-hook)
 251   (message "%s" (substitute-command-keys
 252                  "Press \\[wdired-finish-edit] when finished \
 253 or \\[wdired-abort-changes] to abort changes")))
 254
 255 (defun wdired-isearch-filter-read-only (beg end)
 256   "Skip matches that have a read-only property."
 257   (and (isearch-filter-visible beg end)
 258        (not (text-property-not-all (min beg end) (max beg end)
 259                                    'read-only nil))))
 260
 261 ;; Protect the buffer so only the filenames can be changed, and put
 262 ;; properties so filenames (old and new) can be easily found.
 263 (defun wdired-preprocess-files ()
 264   (put-text-property (point-min) (1+ (point-min))'front-sticky t)
 265   (save-excursion
 266     (goto-char (point-min))
 267     (let ((b-protection (point))
 268           filename)
 269       (while (not (eobp))
 270         (setq filename (dired-get-filename nil t))
 271         (when (and filename
 272                    (not (member (file-name-nondirectory filename) '("." ".."))))
 273           (dired-move-to-filename)
 274           ;; The rear-nonsticky property below shall ensure that text preceding
 275           ;; the filename can't be modified.
 276           (add-text-properties
 277            (1- (point)) (point) `(old-name ,filename rear-nonsticky (read-only)))
 278           (put-text-property b-protection (point) 'read-only t)
 279           (setq b-protection (dired-move-to-end-of-filename t))
 280           (put-text-property (point) (1+ (point)) 'end-name t))
 281         (forward-line))
 282       (put-text-property b-protection (point-max) 'read-only t))))
 283
 284 ;; This code is a copy of some dired-get-filename lines.
 285 (defsubst wdired-normalize-filename (file)
 286   (setq file
 287         ;; FIXME: shouldn't we check for a `b' argument or somesuch before
 288         ;; doing such unquoting?  --Stef
 289         (read (concat
 290                "\"" (replace-regexp-in-string
 291                      "\\([^\\]\\|\\`\\)\"" "\\1\\\\\"" file)
 292                "\"")))
 293   (and file buffer-file-coding-system
 294        (not file-name-coding-system)
 295        (not default-file-name-coding-system)
 296        (setq file (encode-coding-string file buffer-file-coding-system)))
 297   file)
 298
 299 (defun wdired-get-filename (&optional no-dir old)
 300   "Return the filename at line.
 301 Similar to `dired-get-filename' but it doesn't rely on regexps.  It
 302 relies on WDired buffer's properties.  Optional arg NO-DIR with value
 303 non-nil means don't include directory.  Optional arg OLD with value
 304 non-nil means return old filename."
 305   ;; FIXME: Use dired-get-filename's new properties.
 306   (let (beg end file)
 307     (save-excursion
 308       (setq end (line-end-position))
 309       (beginning-of-line)
 310       (setq beg (next-single-property-change (point) 'old-name nil end))
 311       (unless (eq beg end)
 312         (if old
 313             (setq file (get-text-property beg 'old-name))
 314           ;; In the following form changed `(1+ beg)' to `beg' so that
 315           ;; the filename end is found even when the filename is empty.
 316           ;; Fixes error and spurious newlines when marking files for
 317           ;; deletion.
 318           (setq end (next-single-property-change beg 'end-name))
 319           (setq file (buffer-substring-no-properties (1+ beg) end)))
 320         (and file (setq file (wdired-normalize-filename file))))
 321       (if (or no-dir old)
 322           file
 323         (and file (> (length file) 0)
 324              (concat (dired-current-directory) file))))))
 325
 326
 327 (defun wdired-change-to-dired-mode ()
 328   "Change the mode back to dired."
 329   (or (eq major-mode 'wdired-mode)
 330       (error "Not a Wdired buffer"))
 331   (let ((inhibit-read-only t))
 332     (remove-text-properties
 333      (point-min) (point-max)
 334      '(front-sticky nil rear-nonsticky nil read-only nil keymap nil)))
 335   (use-local-map dired-mode-map)
 336   (force-mode-line-update)
 337   (setq buffer-read-only t)
 338   (setq major-mode 'dired-mode)
 339   (setq mode-name "Dired")
 340   (dired-advertise)
 341   (remove-hook 'kill-buffer-hook 'wdired-check-kill-buffer t)
 342   (set (make-local-variable 'revert-buffer-function) 'dired-revert))
 343
 344
 345 (defun wdired-abort-changes ()
 346   "Abort changes and return to dired mode."
 347   (interactive)
 348   (let ((inhibit-read-only t))
 349     (erase-buffer)
 350     (insert wdired-old-content)
 351     (goto-char wdired-old-point))
 352   (wdired-change-to-dired-mode)
 353   (set-buffer-modified-p nil)
 354   (setq buffer-undo-list nil)
 355   (message "Changes aborted"))
 356
 357 (defun wdired-finish-edit ()
 358   "Actually rename files based on your editing in the Dired buffer."
 359   (interactive)
 360   (wdired-change-to-dired-mode)
 361   (let ((changes nil)
 362         (errors 0)
 363         files-deleted
 364         files-renamed
 365         some-file-names-unchanged
 366         file-old file-new tmp-value)
 367     (save-excursion
 368       (when (and wdired-allow-to-redirect-links
 369                  (fboundp 'make-symbolic-link))
 370         (setq tmp-value (wdired-do-symlink-changes))
 371         (setq errors (cdr tmp-value))
 372         (setq changes (car tmp-value)))
 373       (when (and wdired-allow-to-change-permissions
 374                  (boundp 'wdired-col-perm)) ; could have been changed
 375         (setq tmp-value (wdired-do-perm-changes))
 376         (setq errors (+ errors (cdr tmp-value)))
 377         (setq changes (or changes (car tmp-value))))
 378       (goto-char (point-max))
 379       (while (not (bobp))
 380         (setq file-old (wdired-get-filename nil t))
 381         (when file-old
 382           (setq file-new (wdired-get-filename))
 383           (if (equal file-new file-old)
 384               (setq some-file-names-unchanged t)
 385             (setq changes t)
 386             (if (not file-new)          ;empty filename!
 387                 (push file-old files-deleted)
 388               (push (cons file-old (substitute-in-file-name file-new))
 389                     files-renamed))))
 390         (forward-line -1)))
 391     (when files-renamed
 392       (setq errors (+ errors (wdired-do-renames files-renamed))))
 393     (if changes
 394         (progn
 395           ;; If we are displaying a single file (rather than the
 396           ;; contents of a directory), change dired-directory if that
 397           ;; file was renamed.  (This ought to be generalized to
 398           ;; handle the multiple files case, but that's less trivial).
 399           (when (and (stringp dired-directory)
 400                      (not (file-directory-p dired-directory))
 401                      (null some-file-names-unchanged)
 402                      (= (length files-renamed) 1))
 403             (setq dired-directory (cdr (car files-renamed))))
 404           ;; Re-sort the buffer.
 405           (revert-buffer))
 406       (let ((inhibit-read-only t))
 407         (remove-text-properties (point-min) (point-max)
 408                                 '(old-name nil end-name nil old-link nil
 409                                            end-link nil end-perm nil
 410                                            old-perm nil perm-changed nil))
 411         (message "(No changes to be performed)")))
 412     (when files-deleted
 413       (wdired-flag-for-deletion files-deleted))
 414     (when (> errors 0)
 415       (dired-log-summary (format "%d rename actions failed" errors) nil)))
 416   (set-buffer-modified-p nil)
 417   (setq buffer-undo-list nil))
 418
 419 (defun wdired-do-renames (renames)
 420   "Perform RENAMES in parallel."
 421   (let ((residue ())
 422         (progress nil)
 423         (errors 0)
 424         (overwrite (or (not wdired-confirm-overwrite) 1)))
 425     (while (or renames
 426                ;; We've done one round through the renames, we have found
 427                ;; some residue, but we also made some progress, so maybe
 428                ;; some of the residue were resolved: try again.
 429                (prog1 (setq renames residue)
 430                  (setq progress nil)
 431                  (setq residue nil)))
 432       (let* ((rename (pop renames))
 433              (file-new (cdr rename)))
 434         (cond
 435          ((rassoc file-new renames)
 436           (error "Trying to rename 2 files to the same name"))
 437          ((assoc file-new renames)
 438           ;; Renaming to a file name that already exists but will itself be
 439           ;; renamed as well.  Let's wait until that one gets renamed.
 440           (push rename residue))
 441          ((and (assoc file-new residue)
 442                ;; Make sure the file really exists: if it doesn't it's
 443                ;; not really a conflict.  It might be a temp-file generated
 444                ;; specifically to break a circular renaming.
 445                (file-exists-p file-new))
 446           ;; Renaming to a file name that already exists, needed to be renamed,
 447           ;; but whose renaming could not be performed right away.
 448           (if (or progress renames)
 449               ;; There's still a chance the conflict will be resolved.
 450               (push rename residue)
 451             ;; We have not made any progress and we've reached the end of
 452             ;; the renames, so we really have a circular conflict, and we
 453             ;; have to forcefully break the cycle.
 454             (message "Circular renaming: using temporary file name")
 455             (let ((tmp (make-temp-name file-new)))
 456               (push (cons (car rename) tmp) renames)
 457               (push (cons tmp file-new) residue))))
 458          (t
 459           (setq progress t)
 460           (let* ((file-ori (car rename))
 461                  (old-mark (cdr (assoc file-ori wdired-old-marks))))
 462             (if wdired-use-interactive-rename
 463                 (wdired-search-and-rename file-ori file-new)
 464               ;; If dired-rename-file autoloads dired-aux while
 465               ;; dired-backup-overwrite is locally bound,
 466               ;; dired-backup-overwrite won't be initialized.
 467               ;; So we must ensure dired-aux is loaded.
 468               (require 'dired-aux)
 469               (condition-case err
 470                   (let ((dired-backup-overwrite nil))
 471                     (dired-rename-file file-ori file-new
 472                                        overwrite)
 473                     (dired-remove-file file-ori)
 474                     (dired-add-file file-new (if (integerp dired-keep-marker-rename)
 475                                                  dired-keep-marker-rename
 476                                                old-mark)))
 477                 (error
 478                  (setq errors (1+ errors))
 479                  (dired-log (concat "Rename `" file-ori "' to `"
 480                                     file-new "' failed:\n%s\n")
 481                             err)
 482                  (dired-add-entry file-ori old-mark)))))))))
 483     errors))
 484
 485
 486 (defun wdired-exit ()
 487   "Exit wdired and return to dired mode.
 488 Just return to dired mode if there are no changes.  Otherwise,
 489 ask a yes-or-no question whether to save or cancel changes,
 490 and proceed depending on the answer."
 491   (interactive)
 492   (if (buffer-modified-p)
 493       (if (y-or-n-p (format "Buffer %s modified; save changes? "
 494                             (current-buffer)))
 495           (wdired-finish-edit)
 496         (wdired-abort-changes))
 497     (wdired-change-to-dired-mode)
 498     (set-buffer-modified-p nil)
 499     (setq buffer-undo-list nil)
 500     (message "(No changes need to be saved)")))
 501
 502 ;; Rename a file, searching it in a modified dired buffer, in order
 503 ;; to be able to use `dired-do-create-files-regexp' and get its
 504 ;; "benefits".
 505 (defun wdired-search-and-rename (filename-ori filename-new)
 506   (save-excursion
 507     (goto-char (point-max))
 508     (forward-line -1)
 509     (let ((done nil)
 510           curr-filename)
 511       (while (and (not done) (not (bobp)))
 512         (setq curr-filename (wdired-get-filename nil t))
 513         (if (equal curr-filename filename-ori)
 514             (progn
 515               (setq done t)
 516               (let ((inhibit-read-only t))
 517                 (dired-move-to-filename)
 518                 (search-forward (wdired-get-filename t) nil t)
 519                 (replace-match (file-name-nondirectory filename-ori) t t))
 520               (dired-do-create-files-regexp
 521                (function dired-rename-file)
 522                "Move" 1 ".*" filename-new nil t))
 523           (forward-line -1))))))
 524
 525 ;; marks a list of files for deletion
 526 (defun wdired-flag-for-deletion (filenames-ori)
 527   (save-excursion
 528     (goto-char (point-min))
 529     (while (not (eobp))
 530       (if (member (dired-get-filename nil t) filenames-ori)
 531           (dired-flag-file-deletion 1)
 532         (forward-line)))))
 533
 534 (defun wdired-customize ()
 535   "Customize WDired options."
 536   (interactive)
 537   (customize-apropos "wdired" 'groups))
 538
 539 (defun wdired-revert (&optional _arg _noconfirm)
 540   "Discard changes in the buffer and update it based on changes on disk.
 541 Optional arguments are ignored."
 542   (wdired-change-to-dired-mode)
 543   (revert-buffer)
 544   (wdired-change-to-wdired-mode))
 545
 546 (defun wdired-check-kill-buffer ()
 547   ;; FIXME: Can't we use the normal mechanism for that?  --Stef
 548   (if (and
 549        (buffer-modified-p)
 550        (not (y-or-n-p "Buffer changed. Discard changes and kill buffer? ")))
 551       (error "Error")))
 552
 553 (defun wdired-next-line (arg)
 554   "Move down lines then position at filename or the current column.
 555 See `wdired-use-dired-vertical-movement'.  Optional prefix ARG
 556 says how many lines to move; default is one line."
 557   (interactive "p")
 558   (with-no-warnings (next-line arg))
 559   (if (or (eq wdired-use-dired-vertical-movement t)
 560           (and wdired-use-dired-vertical-movement
 561                (< (current-column)
 562                   (save-excursion (dired-move-to-filename)
 563                                   (current-column)))))
 564       (dired-move-to-filename)))
 565
 566 (defun wdired-previous-line (arg)
 567   "Move up lines then position at filename or the current column.
 568 See `wdired-use-dired-vertical-movement'.  Optional prefix ARG
 569 says how many lines to move; default is one line."
 570   (interactive "p")
 571   (with-no-warnings (previous-line arg))
 572   (if (or (eq wdired-use-dired-vertical-movement t)
 573           (and wdired-use-dired-vertical-movement
 574                (< (current-column)
 575                   (save-excursion (dired-move-to-filename)
 576                                   (current-column)))))
 577       (dired-move-to-filename)))
 578
 579 ;; Put the needed properties to allow the user to change links' targets
 580 (defun wdired-preprocess-symlinks ()
 581   (let ((inhibit-read-only t))
 582     (save-excursion
 583       (goto-char (point-min))
 584       (while (not (eobp))
 585         (if (looking-at dired-re-sym)
 586             (progn
 587               (re-search-forward " -> \\(.*\\)$")
 588               (put-text-property (- (match-beginning 1) 2)
 589                                  (1- (match-beginning 1)) 'old-link
 590                                  (match-string-no-properties 1))
 591               (put-text-property (match-end 1) (1+ (match-end 1)) 'end-link t)
 592               (put-text-property (1- (match-beginning 1))
 593                                  (match-beginning 1)
 594                                  'rear-nonsticky '(read-only))
 595               (put-text-property (match-beginning 1)
 596                                  (match-end 1) 'read-only nil)))
 597         (forward-line)
 598         (beginning-of-line)))))
 599
 600
 601 (defun wdired-get-previous-link (&optional old move)
 602   "Return the next symlink target.
 603 If OLD, return the old target.  If MOVE, move point before it."
 604   (let (beg end target)
 605     (setq beg (previous-single-property-change (point) 'old-link nil))
 606     (if beg
 607         (progn
 608           (if old
 609               (setq target (get-text-property (1- beg) 'old-link))
 610             (setq end (next-single-property-change beg 'end-link))
 611             (setq target (buffer-substring-no-properties (1+ beg) end)))
 612           (if move (goto-char (1- beg)))))
 613     (and target (wdired-normalize-filename target))))
 614
 615 (declare-function make-symbolic-link "fileio.c")
 616
 617 ;; Perform the changes in the target of the changed links.
 618 (defun wdired-do-symlink-changes ()
 619   (let ((changes nil)
 620         (errors 0)
 621         link-to-ori link-to-new link-from)
 622     (goto-char (point-max))
 623     (while (setq link-to-new (wdired-get-previous-link))
 624       (setq link-to-ori (wdired-get-previous-link t t))
 625       (setq link-from (wdired-get-filename nil t))
 626       (unless (equal link-to-new link-to-ori)
 627         (setq changes t)
 628         (if (equal link-to-new "") ;empty filename!
 629             (setq link-to-new "/dev/null"))
 630         (condition-case err
 631             (progn
 632               (delete-file link-from)
 633               (make-symbolic-link
 634                (substitute-in-file-name link-to-new) link-from))
 635           (error
 636            (setq errors (1+ errors))
 637            (dired-log (concat "Link `" link-from "' to `"
 638                               link-to-new "' failed:\n%s\n")
 639                       err)))))
 640     (cons changes errors)))
 641
 642 ;; Perform a "case command" skipping read-only words.
 643 (defun wdired-xcase-word (command arg)
 644   (if (< arg 0)
 645       (funcall command arg)
 646     (while (> arg 0)
 647       (condition-case nil
 648           (progn
 649             (funcall command 1)
 650             (setq arg (1- arg)))
 651         (error
 652          (if (forward-word)
 653              ;; Skip any non-word characters to avoid triggering a read-only
 654              ;; error which would cause skipping the next word characters too.
 655              (skip-syntax-forward "^w")
 656            (setq arg 0)))))))
 657
 658 (defun wdired-downcase-word (arg)
 659   "WDired version of `downcase-word'.
 660 Like original function but it skips read-only words."
 661   (interactive "p")
 662   (wdired-xcase-word 'downcase-word arg))
 663
 664 (defun wdired-upcase-word (arg)
 665   "WDired version of `upcase-word'.
 666 Like original function but it skips read-only words."
 667   (interactive "p")
 668   (wdired-xcase-word 'upcase-word arg))
 669
 670 (defun wdired-capitalize-word (arg)
 671   "WDired version of `capitalize-word'.
 672 Like original function but it skips read-only words."
 673   (interactive "p")
 674   (wdired-xcase-word 'capitalize-word arg))
 675
 676
 677 ;; The following code deals with changing the access bits (or
 678 ;; permissions) of the files.
 679
 680 (defvar wdired-perm-mode-map
 681   (let ((map (make-sparse-keymap)))
 682     (define-key map " " 'wdired-toggle-bit)
 683     (define-key map "r" 'wdired-set-bit)
 684     (define-key map "w" 'wdired-set-bit)
 685     (define-key map "x" 'wdired-set-bit)
 686     (define-key map "-" 'wdired-set-bit)
 687     (define-key map "S" 'wdired-set-bit)
 688     (define-key map "s" 'wdired-set-bit)
 689     (define-key map "T" 'wdired-set-bit)
 690     (define-key map "t" 'wdired-set-bit)
 691     (define-key map "s" 'wdired-set-bit)
 692     (define-key map "l" 'wdired-set-bit)
 693     (define-key map [down-mouse-1] 'wdired-mouse-toggle-bit)
 694     map))
 695
 696 ;; Put a keymap property to the permission bits of the files, and store the
 697 ;; original name and permissions as a property
 698 (defun wdired-preprocess-perms ()
 699   (let ((inhibit-read-only t))
 700     (set (make-local-variable 'wdired-col-perm) nil)
 701     (save-excursion
 702       (goto-char (point-min))
 703       (while (not (eobp))
 704         (when (and (not (looking-at dired-re-sym))
 705                    (wdired-get-filename)
 706                    (re-search-forward dired-re-perms (line-end-position) 'eol))
 707           (let ((begin (match-beginning 0))
 708                 (end (match-end 0)))
 709             (unless wdired-col-perm
 710               (setq wdired-col-perm (- (current-column) 9)))
 711             (if (eq wdired-allow-to-change-permissions 'advanced)
 712                 (progn
 713                   (put-text-property begin end 'read-only nil)
 714                   ;; make first permission bit writable
 715                   (put-text-property
 716                    (1- begin) begin 'rear-nonsticky '(read-only)))
 717               ;; avoid that keymap applies to text following permissions
 718               (add-text-properties
 719                (1+ begin) end
 720                `(keymap ,wdired-perm-mode-map rear-nonsticky (keymap))))
 721             (put-text-property end (1+ end) 'end-perm t)
 722             (put-text-property
 723              begin (1+ begin) 'old-perm (match-string-no-properties 0))))
 724         (forward-line)
 725         (beginning-of-line)))))
 726
 727 (defun wdired-perm-allowed-in-pos (char pos)
 728   (cond
 729    ((= char ?-)          t)
 730    ((= char ?r)          (= (% pos 3) 0))
 731    ((= char ?w)          (= (% pos 3) 1))
 732    ((= char ?x)          (= (% pos 3) 2))
 733    ((memq char '(?s ?S)) (memq pos '(2 5)))
 734    ((memq char '(?t ?T)) (= pos 8))
 735    ((= char ?l)          (= pos 5))))
 736
 737 (defun wdired-set-bit ()
 738   "Set a permission bit character."
 739   (interactive)
 740   (if (wdired-perm-allowed-in-pos last-command-event
 741                                   (- (current-column) wdired-col-perm))
 742       (let ((new-bit (char-to-string last-command-event))
 743             (inhibit-read-only t)
 744             (pos-prop (- (point) (- (current-column) wdired-col-perm))))
 745         (put-text-property 0 1 'keymap wdired-perm-mode-map new-bit)
 746         (put-text-property 0 1 'read-only t new-bit)
 747         (insert new-bit)
 748         (delete-char 1)
 749         (put-text-property (1- pos-prop) pos-prop 'perm-changed t)
 750         (put-text-property (1- (point)) (point) 'rear-nonsticky '(keymap)))
 751     (forward-char 1)))
 752
 753 (defun wdired-toggle-bit ()
 754   "Toggle the permission bit at point."
 755   (interactive)
 756   (let ((inhibit-read-only t)
 757         (new-bit "-")
 758         (pos-prop (- (point) (- (current-column) wdired-col-perm))))
 759     (if (eq (char-after (point)) ?-)
 760         (setq new-bit
 761               (if (= (% (- (current-column) wdired-col-perm) 3) 0) "r"
 762                 (if (= (% (- (current-column) wdired-col-perm) 3) 1) "w"
 763                   "x"))))
 764     (put-text-property 0 1 'keymap wdired-perm-mode-map new-bit)
 765     (put-text-property 0 1 'read-only t new-bit)
 766     (insert new-bit)
 767     (delete-char 1)
 768     (put-text-property (1- pos-prop) pos-prop 'perm-changed t)
 769     (put-text-property (1- (point)) (point) 'rear-nonsticky '(keymap))))
 770
 771 (defun wdired-mouse-toggle-bit (event)
 772   "Toggle the permission bit that was left clicked."
 773   (interactive "e")
 774   (mouse-set-point event)
 775   (wdired-toggle-bit))
 776
 777 ;; Allowed chars for 4000 bit are Ss  in position 3
 778 ;; Allowed chars for 2000 bit are Ssl in position 6
 779 ;; Allowed chars for 1000 bit are Tt  in position 9
 780 (defun wdired-perms-to-number (perms)
 781   (let ((nperm 0777))
 782     (if (= (elt perms 1) ?-) (setq nperm (- nperm 400)))
 783     (if (= (elt perms 2) ?-) (setq nperm (- nperm 200)))
 784     (let ((p-bit (elt perms 3)))
 785       (if (memq p-bit '(?- ?S)) (setq nperm (- nperm 100)))
 786       (if (memq p-bit '(?s ?S)) (setq nperm (+ nperm 4000))))
 787     (if (= (elt perms 4) ?-) (setq nperm (- nperm 40)))
 788     (if (= (elt perms 5) ?-) (setq nperm (- nperm 20)))
 789     (let ((p-bit (elt perms 6)))
 790       (if (memq p-bit '(?- ?S ?l)) (setq nperm (- nperm 10)))
 791       (if (memq p-bit '(?s ?S ?l)) (setq nperm (+ nperm 2000))))
 792     (if (= (elt perms 7) ?-) (setq nperm (- nperm 4)))
 793     (if (= (elt perms 8) ?-) (setq nperm (- nperm 2)))
 794     (let ((p-bit (elt perms 9)))
 795       (if (memq p-bit '(?- ?T)) (setq nperm (- nperm 1)))
 796       (if (memq p-bit '(?t ?T)) (setq nperm (+ nperm 1000))))
 797     nperm))
 798
 799 ;; Perform the changes in the permissions of the files that have
 800 ;; changed.
 801 (defun wdired-do-perm-changes ()
 802   (let ((changes nil)
 803         (errors 0)
 804         (prop-wanted (if (eq wdired-allow-to-change-permissions 'advanced)
 805                          'old-perm 'perm-changed))
 806         filename perms-ori perms-new perm-tmp)
 807     (goto-char (next-single-property-change (point-min) prop-wanted
 808                                             nil (point-max)))
 809     (while (not (eobp))
 810       (setq perms-ori (get-text-property (point) 'old-perm))
 811       (setq perms-new (buffer-substring-no-properties
 812                        (point) (next-single-property-change (point) 'end-perm)))
 813       (unless (equal perms-ori perms-new)
 814         (setq changes t)
 815         (setq filename (wdired-get-filename nil t))
 816         (if (= (length perms-new) 10)
 817             (progn
 818               (setq perm-tmp
 819                     (int-to-string (wdired-perms-to-number perms-new)))
 820               (unless (equal 0 (process-file dired-chmod-program
 821                                              nil nil nil perm-tmp filename))
 822                 (setq errors (1+ errors))
 823                 (dired-log (concat dired-chmod-program " " perm-tmp
 824                                    " `" filename "' failed\n\n"))))
 825           (setq errors (1+ errors))
 826           (dired-log (concat "Cannot parse permission `" perms-new
 827                              "' for file `" filename "'\n\n"))))
 828       (goto-char (next-single-property-change (1+ (point)) prop-wanted
 829                                               nil (point-max))))
 830     (cons changes errors)))
 831
 832 (provide 'wdired)
 833
 834 ;; Local Variables:
 835 ;; coding: latin-1
 836 ;; byte-compile-dynamic: t
 837 ;; End:
 838
 839 ;;; wdired.el ends here