lisp/textmodes/page.el

   1 ;;; page.el --- page motion commands for emacs.
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Code:
  24
  25 (defun forward-page (&optional count)
  26   "Move forward to page boundary.  With arg, repeat, or go back if negative.
  27 A page boundary is any line whose beginning matches the regexp
  28 `page-delimiter'."
  29   (interactive "p")
  30   (or count (setq count 1))
  31   (while (and (> count 0) (not (eobp)))
  32     ;; In case the page-delimiter matches the null string,
  33     ;; don't find a match without moving.
  34     (if (bolp) (forward-char 1))
  35     (if (re-search-forward page-delimiter nil t)
  36         nil
  37       (goto-char (point-max)))
  38     (setq count (1- count)))
  39   (while (and (< count 0) (not (bobp)))
  40     (forward-char -1)
  41     (if (re-search-backward page-delimiter nil t)
  42         (goto-char (match-end 0))
  43       (goto-char (point-min)))
  44     (setq count (1+ count))))
  45
  46 (defun backward-page (&optional count)
  47   "Move backward to page boundary.  With arg, repeat, or go fwd if negative.
  48 A page boundary is any line whose beginning matches the regexp
  49 `page-delimiter'."
  50   (interactive "p")
  51   (or count (setq count 1))
  52   (forward-page (- count)))
  53
  54 (defun mark-page (&optional arg)
  55   "Put mark at end of page, point at beginning.
  56 A numeric arg specifies to move forward or backward by that many pages,
  57 thus marking a page other than the one point was originally in."
  58   (interactive "P")
  59   (setq arg (if arg (prefix-numeric-value arg) 0))
  60   (if (> arg 0)
  61       (forward-page arg)
  62     (if (< arg 0)
  63         (forward-page (1- arg))))
  64   (forward-page)
  65   (push-mark nil t)
  66   (forward-page -1))
  67
  68 (defun narrow-to-page (&optional arg)
  69   "Make text outside current page invisible.
  70 A numeric arg specifies to move forward or backward by that many pages,
  71 thus showing a page other than the one point was originally in."
  72   (interactive "P")
  73   (setq arg (if arg (prefix-numeric-value arg) 0))
  74   (save-excursion
  75     (widen)
  76     (if (> arg 0)
  77         (forward-page arg)
  78       (if (< arg 0)
  79           (forward-page (1- arg))))
  80     ;; Find the end of the page.
  81     (forward-page)
  82     ;; If we stopped due to end of buffer, stay there.
  83     ;; If we stopped after a page delimiter, put end of restriction
  84     ;; at the beginning of that line.
  85     (if (save-excursion (beginning-of-line)
  86                         (looking-at page-delimiter))
  87         (beginning-of-line))
  88     (narrow-to-region (point)
  89                       (progn
  90                         ;; Find the top of the page.
  91                         (forward-page -1)
  92                         ;; If we found beginning of buffer, stay there.
  93                         ;; If extra text follows page delimiter on same line,
  94                         ;; include it.
  95                         ;; Otherwise, show text starting with following line.
  96                         (if (and (eolp) (not (bobp)))
  97                             (forward-line 1))
  98                         (point)))))
  99 (put 'narrow-to-page 'disabled t)
 100
 101 (defun count-lines-page ()
 102   "Report number of lines on current page, and how many are before or after point."
 103   (interactive)
 104   (save-excursion
 105     (let ((opoint (point)) beg end
 106           total before after)
 107       (forward-page)
 108       (beginning-of-line)
 109       (or (looking-at page-delimiter)
 110           (end-of-line))
 111       (setq end (point))
 112       (backward-page)
 113       (setq beg (point))
 114       (setq total (count-lines beg end)
 115             before (count-lines beg opoint)
 116             after (count-lines opoint end))
 117       (message "Page has %d lines (%d + %d)" total before after))))
 118
 119 (defun what-page ()
 120   "Print page and line number of point."
 121   (interactive)
 122   (save-restriction
 123     (widen)
 124     (save-excursion
 125       (beginning-of-line)
 126       (let ((count 1)
 127             (opoint (point)))
 128         (goto-char 1)
 129         (while (re-search-forward page-delimiter opoint t)
 130           (setq count (1+ count)))
 131         (message "Page %d, line %d"
 132                  count
 133                  (1+ (count-lines (point) opoint)))))))
 134
 135 ;;; page.el ends here