configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 23.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147
 148 ## For the times when you want to build Emacs but don't have
 149 ## a suitable makeinfo, and can live without the manuals.
 150 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 151 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 152
 153 dnl Can remove these in Emacs 24.
 154 AC_ARG_WITH([gtk],,
 155   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 156 specify a toolkit.])],,)
 157
 158 AC_ARG_WITH([gcc],,
 159   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 160 variable to specify a compiler.])],,)
 161
 162 AC_ARG_WITH([pkg-config-prog],dnl
 163 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 164                   [path to pkg-config for finding GTK and librsvg])])
 165 if test "X${with_pkg_config_prog}" != X; then
 166    if test "${with_pkg_config_prog}" != yes; then
 167       PKG_CONFIG="${with_pkg_config_prog}"
 168    fi
 169 fi
 170
 171 AC_ARG_WITH([gnustep-conf],dnl
 172 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 173 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 174   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 175 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 176      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 177
 178 AC_ARG_ENABLE(ns-self-contained,
 179 [AS_HELP_STRING([--disable-ns-self-contained],
 180                 [disable self contained build under NeXTstep])],
 181    EN_NS_SELF_CONTAINED=$enableval,
 182    EN_NS_SELF_CONTAINED=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 AC_ARG_ENABLE(checking,
 213 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 214                 [enable expensive run-time checks.  With LIST,
 215                  enable only specific categories of checks.
 216                  Categories are: all,yes,no.
 217                  Flags are: stringbytes, stringoverrun, stringfreelist,
 218                  xmallocoverrun, conslist])],
 219 [ac_checking_flags="${enableval}"],[])
 220 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 221 for check in $ac_checking_flags
 222 do
 223         case $check in
 224         # these set all the flags to specific states
 225         yes)            ac_enable_checking=1 ;;
 226         no)             ac_enable_checking= ;
 227                         ac_gc_check_stringbytes= ;
 228                         ac_gc_check_string_overrun= ;
 229                         ac_gc_check_string_free_list= ;
 230                         ac_xmalloc_overrun= ;
 231                         ac_gc_check_cons_list= ;;
 232         all)            ac_enable_checking=1 ;
 233                         ac_gc_check_stringbytes=1 ;
 234                         ac_gc_check_string_overrun=1 ;
 235                         ac_gc_check_string_free_list=1 ;
 236                         ac_xmalloc_overrun=1 ;
 237                         ac_gc_check_cons_list=1 ;;
 238         # these enable particular checks
 239         stringbytes)    ac_gc_check_stringbytes=1 ;;
 240         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 241         stringfreelist) ac_gc_check_string_free_list=1 ;;
 242         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 243         conslist)       ac_gc_check_cons_list=1 ;;
 244         *)      AC_MSG_ERROR(unknown check category $check) ;;
 245         esac
 246 done
 247 IFS="$ac_save_IFS"
 248
 249 if test x$ac_enable_checking != x ; then
 250   AC_DEFINE(ENABLE_CHECKING, 1,
 251 [Enable expensive run-time checking of data types?])
 252 fi
 253 if test x$ac_gc_check_stringbytes != x ; then
 254   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 255 [Define this temporarily to hunt a bug.  If defined, the size of
 256    strings is redundantly recorded in sdata structures so that it can
 257    be compared to the sizes recorded in Lisp strings.])
 258 fi
 259 if test x$ac_gc_check_stringoverrun != x ; then
 260   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 261 [Define this to check for short string overrun.])
 262 fi
 263 if test x$ac_gc_check_string_free_list != x ; then
 264   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 265 [Define this to check the string free list.])
 266 fi
 267 if test x$ac_xmalloc_overrun != x ; then
 268   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 269 [Define this to check for malloc buffer overrun.])
 270 fi
 271 if test x$ac_gc_check_cons_list != x ; then
 272   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 273 [Define this to check for errors in cons list.])
 274 fi
 275
 276 AC_ARG_ENABLE(profiling,
 277 [AS_HELP_STRING([--enable-profiling],
 278                 [build emacs with profiling support.
 279                  This might not work on all platforms])],
 280 [ac_enable_profiling="${enableval}"],[])
 281 if test x$ac_enable_profiling != x ; then
 282    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 283    PROFILING_LDFLAGS="-pg"
 284 else
 285    PROFILING_CFLAGS=
 286    PROFILING_LDFLAGS=
 287 fi
 288
 289 #### Make srcdir absolute, if it isn't already.  It's important to
 290 #### avoid running the path through pwd unnecessarily, since pwd can
 291 #### give you automounter prefixes, which can go away.  We do all this
 292 #### so Emacs can find its files when run uninstalled.
 293 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 294 unset CDPATH
 295 case "${srcdir}" in
 296   /* ) ;;
 297   . )
 298     ## We may be able to use the $PWD environment variable to make this
 299     ## absolute.  But sometimes PWD is inaccurate.
 300     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 301     ## but that tested only for a well-formed and valid PWD,
 302     ## it did not object when PWD was well-formed and valid but just wrong.
 303     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 304     then
 305       srcdir="$PWD"
 306     else
 307       srcdir="`(cd ${srcdir}; pwd)`"
 308     fi
 309   ;;
 310   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 311 esac
 312
 313 #### Check if the source directory already has a configured system in it.
 314 if test `pwd` != `(cd ${srcdir} && pwd)` \
 315    && test -f "${srcdir}/src/config.h" ; then
 316   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 317    as a build directory right now; it has been configured in its own
 318    right.  To configure in another directory as well, you MUST
 319    use GNU make.  If you do not have GNU make, then you must
 320    now do `make distclean' in ${srcdir},
 321    and then run $0 again.]])
 322 fi
 323
 324 #### Given the configuration name, set machfile and opsysfile to the
 325 #### names of the m/*.h and s/*.h files we should use.
 326
 327 ### Canonicalize the configuration name.
 328
 329 AC_CANONICAL_HOST
 330 canonical=$host
 331 configuration=${host_alias-${build_alias-$host}}
 332
 333 dnl This used to use changequote, but, apart from `changequote is evil'
 334 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 335 dnl the great gob of text.  Thus it's not processed for possible expansion.
 336 dnl Just make sure the brackets remain balanced.
 337 dnl
 338 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 339 dnl indicated by comments.
 340 dnl quotation begins
 341 [
 342
 343 ### If you add support for a new configuration, add code to this
 344 ### switch statement to recognize your configuration name and select
 345 ### the appropriate operating system and machine description files.
 346
 347 ### You would hope that you could choose an m/*.h file pretty much
 348 ### based on the machine portion of the configuration name, and an s-
 349 ### file based on the operating system portion.  However, it turns out
 350 ### that each m/*.h file is pretty manufacturer-specific - for
 351 ### example mips.h is MIPS
 352 ### So we basically have to have a special case for each
 353 ### configuration name.
 354 ###
 355 ### As far as handling version numbers on operating systems is
 356 ### concerned, make sure things will fail in a fixable way.  If
 357 ### /etc/MACHINES doesn't say anything about version numbers, be
 358 ### prepared to handle anything reasonably.  If version numbers
 359 ### matter, be sure /etc/MACHINES says something about it.
 360 ###
 361 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 362 ### "System V Release 4"; he writes, "The old convention encouraged
 363 ### confusion between `system' and `release' levels'."
 364
 365 machine='' opsys='' unported=no
 366 case "${canonical}" in
 367
 368   ## FreeBSD ports
 369   *-*-freebsd* )
 370     opsys=freebsd
 371     case "${canonical}" in
 372       alpha*-*-freebsd*)        machine=alpha ;;
 373       arm*-*-freebsd*)          machine=arm ;;
 374       ia64-*-freebsd*)          machine=ia64 ;;
 375       sparc-*-freebsd*)         machine=sparc ;;
 376       sparc64-*-freebsd*)       machine=sparc ;;
 377       powerpc-*-freebsd*)       machine=macppc ;;
 378       i[3456]86-*-freebsd*)     machine=intel386 ;;
 379       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 380     esac
 381   ;;
 382
 383   ## FreeBSD kernel + glibc based userland
 384   *-*-kfreebsd*gnu* )
 385     opsys=gnu-kfreebsd
 386     case "${canonical}" in
 387       alpha*-*-kfreebsd*)       machine=alpha ;;
 388       ia64-*-kfreebsd*)         machine=ia64 ;;
 389       sparc-*-kfreebsd*)        machine=sparc ;;
 390       sparc64-*-kfreebsd*)      machine=sparc ;;
 391       powerpc-*-kfreebsd*)      machine=macppc ;;
 392       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 393       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 394     esac
 395   ;;
 396
 397   ## NetBSD ports
 398   *-*-netbsd* )
 399     opsys=netbsd
 400     if test -f /usr/lib/crti.o; then]
 401 dnl The close and open brackets here are because this section is quoted --
 402 dnl see the `changequote' comment above.
 403       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 404 [   fi
 405
 406     case "${canonical}" in
 407       alpha*-*-netbsd*) machine=alpha ;;
 408       i[3456]86-*-netbsd*) machine=intel386 ;;
 409       mips-*-netbsd*)   machine=mips ;;
 410       mipsel-*-netbsd*) machine=mips ;;
 411       mipseb-*-netbsd*) machine=mips ;;
 412       powerpc-*-netbsd*) machine=macppc ;;
 413       sparc*-*-netbsd*) machine=sparc ;;
 414       vax-*-netbsd*)    machine=vax ;;
 415       arm-*-netbsd*)    machine=arm ;;
 416       x86_64-*-netbsd*) machine=amdx86-64 ;;
 417       hppa-*-netbsd*)   machine=hp800 ;;
 418       m68k-*-netbsd*)   machine=m68k ;;
 419     esac
 420   ;;
 421
 422   ## OpenBSD ports
 423   *-*-openbsd* )
 424     opsys=openbsd
 425     case "${canonical}" in
 426       alpha*-*-openbsd*)        machine=alpha ;;
 427       arm-*-openbsd*)          machine=arm ;;
 428       i386-*-openbsd*)         machine=intel386 ;;
 429       powerpc-*-openbsd*)      machine=macppc ;;
 430       sparc*-*-openbsd*)       machine=sparc ;;
 431       vax-*-openbsd*)          machine=vax ;;
 432       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 433       hppa-*-openbsd*)         machine=hp800 ;;
 434     esac
 435   ;;
 436
 437   ## LynxOS ports
 438   *-*-lynxos* )
 439     opsys=lynxos
 440     case "${canonical}" in
 441       i[3456]86-*-lynxos*) machine=intel386 ;;
 442       powerpc-*-lynxos*) machine=powerpc ;;
 443     esac
 444   ;;
 445
 446   alpha*-*-linux-gnu* )
 447     machine=alpha opsys=gnu-linux
 448   ;;
 449
 450   arm*-*-linux-gnu* )
 451     machine=arm opsys=gnu-linux
 452   ;;
 453
 454   ## Apple Darwin / Mac OS X
 455   *-apple-darwin* )
 456     case "${canonical}" in
 457       i[3456]86-* )  machine=intel386 ;;
 458       powerpc-* )    machine=macppc ;;
 459       x86_64-* )     machine=amdx86-64 ;;
 460       * )            unported=yes ;;
 461     esac
 462     opsys=darwin
 463     # Define CPP as follows to make autoconf work correctly.
 464     CPP="${CC-cc} -E -no-cpp-precomp"
 465     # Use fink packages if available.
 466     if test -d /sw/include && test -d /sw/lib; then
 467       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 468       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 469       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 470     fi
 471   ;;
 472
 473   ## HP 9000 series 700 and 800, running HP/UX
 474   hppa*-hp-hpux10.2* )
 475     machine=hp800 opsys=hpux10-20
 476   ;;
 477   hppa*-hp-hpux1[1-9]* )
 478     machine=hp800 opsys=hpux11
 479     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 480   ;;
 481
 482   hppa*-*-linux-gnu* )
 483     machine=hp800 opsys=gnu-linux
 484   ;;
 485
 486   ## IBM machines
 487   s390-*-linux-gnu* )
 488     machine=ibms390 opsys=gnu-linux
 489   ;;
 490   s390x-*-linux-gnu* )
 491     machine=ibms390x opsys=gnu-linux
 492   ;;
 493   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 494     machine=ibmrs6000 opsys=aix4-2
 495   ;;
 496   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 497     machine=ibmrs6000 opsys=aix4-2
 498   ;;
 499   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 500     machine=ibmrs6000 opsys=aix4-2
 501   ;;
 502   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 503     machine=ibmrs6000 opsys=aix4-2
 504   ;;
 505
 506   ## Macintosh PowerPC
 507   powerpc*-*-linux-gnu* )
 508     machine=macppc opsys=gnu-linux
 509   ;;
 510
 511   ## Silicon Graphics machines
 512   ## Iris 4D
 513   mips-sgi-irix6.5 )
 514     machine=iris4d opsys=irix6-5
 515     # Without defining _LANGUAGE_C, things get masked out in the headers
 516     # so that, for instance, grepping for `free' in stdlib.h fails and
 517     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 518     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 519     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 520   ;;
 521
 522   ## Suns
 523   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 524     machine=sparc opsys=gnu-linux
 525   ;;
 526
 527   *-sun-solaris* \
 528     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 529     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 530     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 531     case "${canonical}" in
 532       i[3456]86-*-* )     machine=intel386 ;;
 533       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 534       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 535       sparc* )          machine=sparc ;;
 536       * )               unported=yes ;;
 537     esac
 538     case "${canonical}" in
 539       *-sunos5.3* | *-solaris2.3* )
 540                 opsys=sol2-3
 541                 NON_GNU_CPP=/usr/ccs/lib/cpp
 542                 ;;
 543       *-sunos5.4* | *-solaris2.4* )
 544                 opsys=sol2-4
 545                 NON_GNU_CPP=/usr/ccs/lib/cpp
 546                 RANLIB="ar -ts"
 547                 ;;
 548       *-sunos5.5* | *-solaris2.5* )
 549                 opsys=sol2-5
 550                 NON_GNU_CPP=/usr/ccs/lib/cpp
 551                 RANLIB="ar -ts"
 552                 ;;
 553       *-sunos5.6* | *-solaris2.6* )
 554                 opsys=sol2-6
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 RANLIB="ar -ts"
 557                 ;;
 558       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 559                 opsys=sol2-6
 560                 emacs_check_sunpro_c=yes
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 ;;
 563       *-sunos5* | *-solaris* )
 564                 opsys=sol2-10
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568     esac
 569     ## Watch out for a compiler that we know will not work.
 570     case "${canonical}" in
 571      *-solaris* | *-sunos5* )
 572                 if [ "x$CC" = x/usr/ucb/cc ]; then
 573                   ## /usr/ucb/cc doesn't work;
 574                   ## we should find some other compiler that does work.
 575                   unset CC
 576                 fi
 577                 ;;
 578       *) ;;
 579     esac
 580   ;;
 581
 582   ## IA-64
 583   ia64*-*-linux* )
 584     machine=ia64 opsys=gnu-linux
 585   ;;
 586
 587   ## Intel 386 machines where we don't care about the manufacturer
 588   i[3456]86-*-* )
 589     machine=intel386
 590     case "${canonical}" in
 591       *-cygwin )                opsys=cygwin ;;
 592       *-darwin* )               opsys=darwin
 593                                 CPP="${CC-cc} -E -no-cpp-precomp"
 594                                 ;;
 595       *-linux-gnu* )            opsys=gnu-linux ;;
 596       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 600     esac
 601   ;;
 602
 603   ## m68k Linux-based GNU system
 604   m68k-*-linux-gnu* )
 605     machine=m68k opsys=gnu-linux
 606   ;;
 607
 608   ## Mips Linux-based GNU system
 609   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 610     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 611     machine=mips opsys=gnu-linux
 612   ;;
 613
 614   ## AMD x86-64 Linux-based GNU system
 615   x86_64-*-linux-gnu* )
 616     machine=amdx86-64 opsys=gnu-linux
 617   ;;
 618
 619   ## Tensilica Xtensa Linux-based GNU system
 620   xtensa*-*-linux-gnu* )
 621     machine=xtensa opsys=gnu-linux
 622     ;;
 623
 624   ## SuperH Linux-based GNU system
 625   sh[34]*-*-linux-gnu* )
 626     machine=sh3 opsys=gnu-linux
 627   ;;
 628
 629   * )
 630     unported=yes
 631   ;;
 632 esac
 633
 634 ### If the code above didn't choose an operating system, just choose
 635 ### an operating system based on the configuration name.  You really
 636 ### only want to use this when you have no idea what the right
 637 ### operating system is; if you know what operating systems a machine
 638 ### runs, it's cleaner to make it explicit in the case statement
 639 ### above.
 640 if test x"${opsys}" = x; then
 641   case "${canonical}" in
 642     *-gnu* )                            opsys=gnu ;;
 643     *-sysv4.2uw* )                      opsys=unixware ;;
 644     *-sysv5uw* )                        opsys=unixware ;;
 645     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 646     *-sysv4.1* | *-sysvr4.1* )
 647         NON_GNU_CPP=/usr/lib/cpp
 648         opsys=usg5-4 ;;
 649     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 650         if [ x$NON_GNU_CPP = x ]; then
 651           if [ -f /usr/ccs/lib/cpp ]; then
 652             NON_GNU_CPP=/usr/ccs/lib/cpp
 653           else
 654             NON_GNU_CPP=/lib/cpp
 655           fi
 656         fi
 657         opsys=usg5-4-2 ;;
 658     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 659     * )
 660       unported=yes
 661     ;;
 662   esac
 663 fi
 664
 665 ]
 666 dnl quotation ends
 667
 668 if test $unported = yes; then
 669   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 670 Check `etc/MACHINES' for recognized configuration names.])
 671 fi
 672
 673 machfile="m/${machine}.h"
 674 opsysfile="s/${opsys}.h"
 675
 676
 677 #### Choose a compiler.
 678 test -n "$CC" && cc_specified=yes
 679
 680 # Save the value of CFLAGS that the user specified.
 681 SPECIFIED_CFLAGS="$CFLAGS"
 682
 683 dnl Sets GCC=yes if using gcc.
 684 AC_PROG_CC
 685
 686 # On Suns, sometimes $CPP names a directory.
 687 if test -n "$CPP" && test -d "$CPP"; then
 688   CPP=
 689 fi
 690
 691 ## If not using gcc, and on Solaris, and no CPP specified, see if
 692 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 693 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 694  test x"$CPP" = x; then
 695   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 696   AC_CACHE_VAL(emacs_cv_sunpro_c,
 697   [AC_TRY_LINK([],
 698 [#ifndef __SUNPRO_C
 699 fail;
 700 #endif
 701 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 702   AC_MSG_RESULT($emacs_cv_sunpro_c)
 703
 704   if test x"$emacs_cv_sunpro_c" = xyes; then
 705     NON_GNU_CPP="$CC -E -Xs"
 706   fi
 707 fi
 708
 709 #### Some systems specify a CPP to use unless we are using GCC.
 710 #### Now that we know whether we are using GCC, we can decide whether
 711 #### to use that one.
 712 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 713 then
 714   CPP="$NON_GNU_CPP"
 715 fi
 716
 717 #### Some systems specify a CC to use unless we are using GCC.
 718 #### Now that we know whether we are using GCC, we can decide whether
 719 #### to use that one.
 720 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 721   test x$cc_specified != xyes
 722 then
 723   CC="$NON_GNU_CC"
 724 fi
 725
 726 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 727 then
 728   CC="$CC $GCC_TEST_OPTIONS"
 729 fi
 730
 731 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 732 then
 733   CC="$CC $NON_GCC_TEST_OPTIONS"
 734 fi
 735
 736 dnl checks for Unix variants
 737 AC_USE_SYSTEM_EXTENSIONS
 738
 739 ### Use -Wno-pointer-sign if the compiler supports it
 740 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 741 SAVE_CFLAGS="$CFLAGS"
 742 CFLAGS="$CFLAGS -Wno-pointer-sign"
 743 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 744 if test $has_option = yes; then
 745    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 746 fi
 747 AC_MSG_RESULT($has_option)
 748 CFLAGS="$SAVE_CFLAGS"
 749 unset has_option
 750 unset SAVE_CFLAGS
 751
 752 #### Some other nice autoconf tests.
 753
 754 dnl checks for programs
 755 AC_PROG_LN_S
 756 AC_PROG_CPP
 757 AC_PROG_INSTALL
 758 if test "x$RANLIB" = x; then
 759   AC_PROG_RANLIB
 760 fi
 761 AC_PATH_PROG(INSTALL_INFO, install-info)
 762 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 763 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 764 dnl Don't use GZIP, which is used by gzip for additional parameters.
 765 AC_PATH_PROG(GZIP_PROG, gzip)
 766
 767
 768 ## Need makeinfo >= 4.6 (?) to build the manuals.
 769 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 770 dnl By this stage, configure has already checked for egrep and set EGREP,
 771 dnl or exited with an error if no egrep was found.
 772 if test "$MAKEINFO" != "no" && \
 773   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 774    MAKEINFO=no
 775 fi
 776
 777 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 778 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 779 ## therefore in the category of "special tools" not normally required, which
 780 ## configure does not have to check for (eg autoconf itself).
 781 ## In a CVS checkout on the other hand, the manuals are not included.
 782 ## So makeinfo is a requirement to build from CVS, and configure
 783 ## should test for it as it does for any other build requirement.
 784 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 785 ## with pre-built manuals, from a CVS checkout.
 786 if test "$MAKEINFO" = "no"; then
 787   if test "x${with_makeinfo}" = "xno"; then
 788     MAKEINFO=off
 789   elif ! test -e $srcdir/info/emacs; then
 790     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 791 source tree does not seem to have pre-built manuals in the `info' directory.
 792 Either install a suitable version of makeinfo, or re-run configure
 793 with the `--without-makeinfo' option to build without the manuals.] )
 794   fi
 795 fi
 796
 797 dnl Add our options to ac_link now, after it is set up.
 798
 799 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 800 then
 801   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 802 fi
 803
 804 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 805 then
 806   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 807 fi
 808
 809 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 810 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 811 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 812 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 813 dnl if not built to support GNU ld.
 814
 815 late_LDFLAGS=$LDFLAGS
 816 if test "$GCC" = yes; then
 817   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 818 else
 819   LDFLAGS="$LDFLAGS -znocombreloc"
 820 fi
 821
 822 AC_MSG_CHECKING([for -znocombreloc])
 823 AC_LINK_IFELSE([main(){return 0;}],
 824   [AC_MSG_RESULT(yes)],
 825   LDFLAGS=$late_LDFLAGS
 826   [AC_MSG_RESULT(no)])
 827
 828 #### Extract some information from the operating system and machine files.
 829
 830 AC_CHECKING([the machine- and system-dependent files to find out
 831  - which libraries the lib-src programs will want, and
 832  - whether the GNU malloc routines are usable])
 833
 834 ### First figure out CFLAGS (which we use for running the compiler here)
 835 ### and REAL_CFLAGS (which we use for real compilation).
 836 ### The two are the same except on a few systems, where they are made
 837 ### different to work around various lossages.  For example,
 838 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 839 ### as implying static linking.
 840
 841 ### If the CFLAGS env var is specified, we use that value
 842 ### instead of the default.
 843
 844 ### It's not important that this name contain the PID; you can't run
 845 ### two configures in the same directory and have anything work
 846 ### anyway.
 847 tempcname="conftest.c"
 848
 849 echo '
 850 #include "'${srcdir}'/src/'${opsysfile}'"
 851 #include "'${srcdir}'/src/'${machfile}'"
 852 #ifndef LIBS_MACHINE
 853 #define LIBS_MACHINE
 854 #endif
 855 #ifndef LIBS_SYSTEM
 856 #define LIBS_SYSTEM
 857 #endif
 858 #ifndef C_SWITCH_SYSTEM
 859 #define C_SWITCH_SYSTEM
 860 #endif
 861 #ifndef C_SWITCH_MACHINE
 862 #define C_SWITCH_MACHINE
 863 #endif
 864 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 865 configure___ c_switch_system=C_SWITCH_SYSTEM
 866 configure___ c_switch_machine=C_SWITCH_MACHINE
 867
 868 #ifndef LIB_X11_LIB
 869 #define LIB_X11_LIB -lX11
 870 #endif
 871
 872 #ifndef LIBX11_SYSTEM
 873 #define LIBX11_SYSTEM
 874 #endif
 875 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 876
 877 #ifdef UNEXEC
 878 configure___ unexec=UNEXEC
 879 #else
 880 configure___ unexec=unexec.o
 881 #endif
 882
 883 #ifdef SYSTEM_MALLOC
 884 configure___ system_malloc=yes
 885 #else
 886 configure___ system_malloc=no
 887 #endif
 888
 889 #ifdef USE_MMAP_FOR_BUFFERS
 890 configure___ use_mmap_for_buffers=yes
 891 #else
 892 configure___ use_mmap_for_buffers=no
 893 #endif
 894
 895 #ifndef C_DEBUG_SWITCH
 896 #define C_DEBUG_SWITCH -g
 897 #endif
 898
 899 #ifndef C_OPTIMIZE_SWITCH
 900 #ifdef __GNUC__
 901 #define C_OPTIMIZE_SWITCH -O2
 902 #else
 903 #define C_OPTIMIZE_SWITCH -O
 904 #endif
 905 #endif
 906
 907 #ifndef C_WARNINGS_SWITCH
 908 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 909 #endif
 910
 911 #ifndef LD_SWITCH_MACHINE
 912 #define LD_SWITCH_MACHINE
 913 #endif
 914
 915 #ifndef LD_SWITCH_SYSTEM
 916 #define LD_SWITCH_SYSTEM
 917 #endif
 918
 919 #ifndef LD_SWITCH_X_SITE_AUX
 920 #define LD_SWITCH_X_SITE_AUX
 921 #endif
 922
 923 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 924 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 925
 926 #ifdef THIS_IS_CONFIGURE
 927
 928 /* Get the CFLAGS for tests in configure.  */
 929 #ifdef __GNUC__
 930 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 931 #else
 932 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 933 #endif
 934
 935 #else /* not THIS_IS_CONFIGURE */
 936
 937 /* Get the CFLAGS for real compilation.  */
 938 #ifdef __GNUC__
 939 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 940 #else
 941 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 942 #endif
 943
 944 #endif /* not THIS_IS_CONFIGURE */
 945 ' > ${tempcname}
 946
 947 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 948
 949 # The value of CPP is a quoted variable reference, so we need to do this
 950 # to get its actual value...
 951 CPP=`eval "echo $CPP"`
 952 [eval `${CPP} -Isrc ${tempcname} \
 953        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 954 if test "x$SPECIFIED_CFLAGS" = x; then
 955   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 956          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 957 else
 958   REAL_CFLAGS="$CFLAGS"
 959 fi]
 960 rm ${tempcname}
 961
 962 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 963
 964 ### Make sure subsequent tests use flags consistent with the build flags.
 965
 966 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 967   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 968 else
 969   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 970 fi
 971
 972 dnl For AC_FUNC_GETLOADAVG, at least:
 973 AC_CONFIG_LIBOBJ_DIR(src)
 974
 975 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 976 AC_SYS_LARGEFILE
 977
 978
 979 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 980 ### be located in either /usr/lib64 or /usr/lib.
 981 ### In some rare cases, /usr/lib64 exists but does not contain the
 982 ### relevant files (bug#1287).  Hence test for crtn.o.
 983 case "${canonical}" in
 984   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 985     if test -e /usr/lib64/crtn.o; then
 986       AC_DEFINE(HAVE_LIB64_DIR, 1,
 987         [Define to 1 if the directory /usr/lib64 exists.])
 988 fi
 989 esac
 990
 991 dnl This function defintion taken from Gnome 2.0
 992 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 993 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 994 dnl also defines GSTUFF_PKG_ERRORS on error
 995 AC_DEFUN([PKG_CHECK_MODULES], [
 996   succeeded=no
 997
 998   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 999
1000   if test "$PKG_CONFIG" = "no" ; then
1001      ifelse([$4], , [AC_MSG_ERROR([
1002       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1003   else
1004      PKG_CONFIG_MIN_VERSION=0.9.0
1005      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1006         AC_MSG_CHECKING(for $2)
1007
1008         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1009             AC_MSG_RESULT(yes)
1010             succeeded=yes
1011
1012             AC_MSG_CHECKING($1_CFLAGS)
1013             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1014             AC_MSG_RESULT($$1_CFLAGS)
1015
1016             AC_MSG_CHECKING($1_LIBS)
1017             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1018             AC_MSG_RESULT($$1_LIBS)
1019         else
1020             AC_MSG_RESULT(no)
1021             $1_CFLAGS=""
1022             $1_LIBS=""
1023             ## If we have a custom action on failure, don't print errors, but
1024             ## do set a variable so people can do so.
1025             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1026             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1027         fi
1028
1029         AC_SUBST($1_CFLAGS)
1030         AC_SUBST($1_LIBS)
1031      else
1032         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1033         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1034      fi
1035   fi
1036
1037   if test $succeeded = yes; then
1038      ifelse([$3], , :, [$3])
1039   else
1040      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1041   fi
1042 ])
1043
1044
1045 if test "${with_sound}" != "no"; then
1046   # Sound support for GNU/Linux and the free BSDs.
1047   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1048   # Emulation library used on NetBSD.
1049   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1050   AC_SUBST(LIBSOUND)
1051
1052   ALSA_REQUIRED=1.0.0
1053   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1054   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1055   if test $HAVE_ALSA = yes; then
1056     SAVE_CFLAGS="$CFLAGS"
1057     SAVE_LDFLAGS="$LDFLAGS"
1058     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1059     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1060     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1061                     emacs_alsa_normal=yes,
1062                     emacs_alsa_normal=no)
1063     if test "$emacs_alsa_normal" != yes; then
1064       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1065                      [snd_lib_error_set_handler (0);],
1066                      emacs_alsa_subdir=yes,
1067                      emacs_alsa_subdir=no)
1068       if test "$emacs_alsa_subdir" != yes; then
1069         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1070       fi
1071       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1072     fi
1073
1074     CFLAGS="$SAVE_CFLAGS"
1075     LDFLAGS="$SAVE_LDFLAGS"
1076     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1077     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1078     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1079   fi
1080   AC_SUBST(CFLAGS_SOUND)
1081 fi
1082
1083 dnl checks for header files
1084 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1085   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1086   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1087   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1088   sys/utsname.h pwd.h)
1089
1090 AC_MSG_CHECKING(if personality LINUX32 can be set)
1091 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1092                emacs_cv_personality_linux32=yes,
1093                emacs_cv_personality_linux32=no)
1094 AC_MSG_RESULT($emacs_cv_personality_linux32)
1095
1096 if test $emacs_cv_personality_linux32 = yes; then
1097   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1098             [Define to 1 if personality LINUX32 can be set.])
1099 fi
1100
1101 dnl On Solaris 8 there's a compilation warning for term.h because
1102 dnl it doesn't define `bool'.
1103 AC_CHECK_HEADERS(term.h, , , -)
1104 AC_HEADER_STDC
1105 AC_HEADER_TIME
1106 AC_CHECK_DECLS([sys_siglist])
1107 if test $ac_cv_have_decl_sys_siglist != yes; then
1108   # For Tru64, at least:
1109   AC_CHECK_DECLS([__sys_siglist])
1110   if test $ac_cv_have_decl___sys_siglist = yes; then
1111     AC_DEFINE(sys_siglist, __sys_siglist,
1112               [Define to any substitute for sys_siglist.])
1113   fi
1114 fi
1115 AC_HEADER_SYS_WAIT
1116
1117 dnl Some systems have utime.h but don't declare the struct anyplace.
1118 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1119 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1120 #include <sys/time.h>
1121 #include <time.h>
1122 #else
1123 #ifdef HAVE_SYS_TIME_H
1124 #include <sys/time.h>
1125 #else
1126 #include <time.h>
1127 #endif
1128 #endif
1129 #ifdef HAVE_UTIME_H
1130 #include <utime.h>
1131 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1132   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1133 if test $emacs_cv_struct_utimbuf = yes; then
1134   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1135 fi
1136
1137 dnl checks for typedefs
1138 AC_TYPE_SIGNAL
1139
1140 dnl Check for speed_t typedef.
1141 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1142   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1143     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1144 if test $emacs_cv_speed_t = yes; then
1145   AC_DEFINE(HAVE_SPEED_T, 1,
1146            [Define to 1 if `speed_t' is declared by <termios.h>.])
1147 fi
1148
1149 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1150 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1151 #include <sys/time.h>
1152 #include <time.h>
1153 #else
1154 #ifdef HAVE_SYS_TIME_H
1155 #include <sys/time.h>
1156 #else
1157 #include <time.h>
1158 #endif
1159 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1160   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1161 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1162 if test $emacs_cv_struct_timeval = yes; then
1163   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1164 fi
1165
1166 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1167 AC_TRY_COMPILE([#include <math.h>],
1168 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1169   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1170 HAVE_EXCEPTION=$emacs_cv_struct_exception
1171 if test $emacs_cv_struct_exception != yes; then
1172   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1173 fi
1174
1175 AC_CHECK_HEADERS(sys/socket.h)
1176 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1177 #if HAVE_SYS_SOCKET_H
1178 #include <sys/socket.h>
1179 #endif])
1180
1181 dnl checks for structure members
1182 AC_STRUCT_TM
1183 AC_STRUCT_TIMEZONE
1184 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1185                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1186                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1187                 [#include <time.h>])
1188 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1189                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1190                   struct ifreq.ifr_addr], , ,
1191                  [AC_INCLUDES_DEFAULT
1192 #if HAVE_SYS_SOCKET_H
1193 #include <sys/socket.h>
1194 #endif
1195 #if HAVE_NET_IF_H
1196 #include <net/if.h>
1197 #endif])
1198
1199 dnl checks for compiler characteristics
1200
1201 dnl Testing __STDC__ to determine prototype support isn't good enough.
1202 dnl DEC C, for instance, doesn't define it with default options, and
1203 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1204 dnl and void *.
1205 AC_C_PROTOTYPES
1206 AC_C_VOLATILE
1207 AC_C_CONST
1208 dnl This isn't useful because we can't turn on use of `inline' unless
1209 dnl the compiler groks `extern inline'.
1210 dnl AC_C_INLINE
1211 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1212   [AC_TRY_COMPILE(, [void * foo;],
1213                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1214 if test $emacs_cv_void_star = yes; then
1215   AC_DEFINE(POINTER_TYPE, void)
1216 else
1217   AC_DEFINE(POINTER_TYPE, char)
1218 fi
1219 AH_TEMPLATE(POINTER_TYPE,
1220             [Define as `void' if your compiler accepts `void *'; otherwise
1221              define as `char'.])dnl
1222
1223
1224
1225 dnl This could be used for targets which can have both byte sexes.
1226 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1227 dnl AC_C_BIGENDIAN
1228
1229 dnl check for Make feature
1230 AC_PROG_MAKE_SET
1231
1232 dnl checks for operating system services
1233 AC_SYS_LONG_FILE_NAMES
1234
1235 #### Choose a window system.
1236
1237 AC_PATH_X
1238 if test "$no_x" = yes; then
1239   window_system=none
1240 else
1241   window_system=x11
1242 fi
1243
1244 ## Workaround for bug in autoconf <= 2.62.
1245 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1246 ## No need to do anything special for these standard directories.
1247 ## This is an experiment, take it out if it causes problems.
1248 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1249
1250    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1251
1252 fi
1253
1254 if test "${x_libraries}" != NONE; then
1255   if test -n "${x_libraries}"; then
1256     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1257     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1258   fi
1259   x_default_search_path=""
1260   x_search_path=${x_libraries}
1261   if test -z "${x_search_path}"; then
1262     x_search_path=/usr/lib
1263   fi
1264   for x_library in `echo ${x_search_path}: | \
1265                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1266     x_search_path="\
1267 ${x_library}/X11/%L/%T/%N%C%S:\
1268 ${x_library}/X11/%l/%T/%N%C%S:\
1269 ${x_library}/X11/%T/%N%C%S:\
1270 ${x_library}/X11/%L/%T/%N%S:\
1271 ${x_library}/X11/%l/%T/%N%S:\
1272 ${x_library}/X11/%T/%N%S"
1273     if test x"${x_default_search_path}" = x; then
1274       x_default_search_path=${x_search_path}
1275     else
1276       x_default_search_path="${x_search_path}:${x_default_search_path}"
1277     fi
1278   done
1279 fi
1280 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1281   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1282 fi
1283
1284 if test x"${x_includes}" = x; then
1285   bitmapdir=/usr/include/X11/bitmaps
1286 else
1287   # accumulate include directories that have X11 bitmap subdirectories
1288   bmd_acc="dummyval"
1289   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1290     if test -d "${bmd}/X11/bitmaps"; then
1291       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1292     fi
1293     if test -d "${bmd}/bitmaps"; then
1294       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1295     fi
1296   done
1297   if test ${bmd_acc} != "dummyval"; then
1298     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1299   fi
1300 fi
1301
1302 HAVE_NS=no
1303 NS_IMPL_COCOA=no
1304 NS_IMPL_GNUSTEP=no
1305 tmp_CPPFLAGS="$CPPFLAGS"
1306 tmp_CFLAGS="$CFLAGS"
1307 CPPFLAGS="$CPPFLAGS -x objective-c"
1308 CFLAGS="$CFLAGS -x objective-c"
1309 if test "${with_ns}" != no; then
1310   if test "${opsys}" = darwin; then
1311      NS_IMPL_COCOA=yes
1312      ns_appdir=`pwd`/nextstep/Emacs.app
1313      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1314      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1315      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1316   elif test -f $GNUSTEP_CONFIG_FILE; then
1317      NS_IMPL_GNUSTEP=yes
1318      ns_appdir=`pwd`/nextstep/Emacs.app
1319      ns_appbindir=`pwd`/nextstep/Emacs.app
1320      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1321      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1322      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1323      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1324      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1325      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1326      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1327      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1328      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1329      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1330   fi
1331   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1332                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1333   files are missing or cannot be compiled.])])
1334   NS_HAVE_NSINTEGER=yes
1335   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1336                                      [NSInteger i;])],
1337                     ns_have_nsinteger=yes,
1338                     ns_have_nsinteger=no)
1339   if test $ns_have_nsinteger = no; then
1340     NS_HAVE_NSINTEGER=no
1341   fi
1342 fi
1343 if test "${HAVE_NS}" = yes; then
1344   window_system=nextstep
1345   with_xft=no
1346   # set up packaging dirs
1347   exec_prefix=${ns_appbindir}
1348   libexecdir=${ns_appbindir}/libexec
1349   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1350      prefix=${ns_appresdir}
1351   fi
1352 fi
1353 CFLAGS="$tmp_CFLAGS"
1354 CPPFLAGS="$tmp_CPPFLAGS"
1355
1356 case "${window_system}" in
1357   x11 )
1358     HAVE_X_WINDOWS=yes
1359     HAVE_X11=yes
1360     case "${with_x_toolkit}" in
1361       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1362       motif ) USE_X_TOOLKIT=MOTIF ;;
1363       gtk ) with_gtk=yes
1364 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1365 dnl USE_X_TOOLKIT is set.
1366             USE_X_TOOLKIT=none ;;
1367       no ) USE_X_TOOLKIT=none ;;
1368 dnl If user did not say whether to use a toolkit, make this decision later:
1369 dnl use the toolkit if we have gtk, or X11R5 or newer.
1370       * ) USE_X_TOOLKIT=maybe ;;
1371     esac
1372   ;;
1373   nextstep | none )
1374     HAVE_X_WINDOWS=no
1375     HAVE_X11=no
1376     USE_X_TOOLKIT=none
1377   ;;
1378 esac
1379
1380 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1381    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1382    if test "$HAVE_XSERVER" = true ||
1383       test -n "$DISPLAY" ||
1384       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1385         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1386 were found.  You should install the relevant development files for X
1387 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1388 sure you have development files for image handling, i.e.
1389 tiff, gif, jpeg, png and xpm.
1390 If you are sure you want Emacs compiled without X window support, pass
1391   --without-x
1392 to configure.])
1393    fi
1394 fi
1395
1396 ### If we're using X11, we should use the X menu package.
1397 HAVE_MENUS=no
1398 case ${HAVE_X11} in
1399   yes ) HAVE_MENUS=yes ;;
1400 esac
1401
1402 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1403 # Assume not, until told otherwise.
1404 GNU_MALLOC=yes
1405 doug_lea_malloc=yes
1406 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1407 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1408 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1409                emacs_cv_var___after_morecore_hook,
1410 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1411   emacs_cv_var___after_morecore_hook=yes,
1412   emacs_cv_var___after_morecore_hook=no)])
1413 if test $emacs_cv_var___after_morecore_hook = no; then
1414   doug_lea_malloc=no
1415 fi
1416 if test "${system_malloc}" = "yes"; then
1417   GNU_MALLOC=no
1418   GNU_MALLOC_reason="
1419     (The GNU allocators don't work with this system configuration.)"
1420 fi
1421 if test "$doug_lea_malloc" = "yes" ; then
1422   if test "$GNU_MALLOC" = yes ; then
1423     GNU_MALLOC_reason="
1424       (Using Doug Lea's new malloc from the GNU C Library.)"
1425   fi
1426   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1427             [Define to 1 if you are using the GNU C Library.])
1428 fi
1429
1430 if test x"${REL_ALLOC}" = x; then
1431   REL_ALLOC=${GNU_MALLOC}
1432 fi
1433
1434 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1435 dnl the system configuration file (s/*.h) to turn the use of mmap
1436 dnl in the relocating allocator on.
1437
1438 AC_FUNC_MMAP
1439 if test $use_mmap_for_buffers = yes; then
1440   REL_ALLOC=no
1441 fi
1442
1443 LIBS="$libsrc_libs $LIBS"
1444
1445 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1446 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1447 AC_CHECK_LIB(dnet, dnet_ntoa)
1448 dnl This causes -lresolv to get used in subsequent tests,
1449 dnl which causes failures on some systems such as HPUX 9.
1450 dnl AC_CHECK_LIB(resolv, gethostbyname)
1451
1452 dnl FIXME replace main with a function we actually want from this library.
1453 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1454
1455 AC_CHECK_LIB(pthreads, cma_open)
1456
1457 dnl Check for need for bigtoc support on IBM AIX
1458
1459 case ${host_os} in
1460 aix*)
1461   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1462     case $GCC in
1463     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1464     *) gdb_cv_bigtoc=-bbigtoc ;;
1465     esac
1466
1467     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1468     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1469   ])
1470   ;;
1471 esac
1472
1473 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1474 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1475 # REAL_CPPFLAGS later on.
1476
1477 REAL_CPPFLAGS="$CPPFLAGS"
1478
1479 if test "${HAVE_X11}" = "yes"; then
1480   DEFS="$C_SWITCH_X_SITE $DEFS"
1481   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1482   LIBS="$LIBX $LIBS"
1483   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1484   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1485
1486   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1487   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1488   # but it's more convenient here to set LD_RUN_PATH
1489   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1490   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1491     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1492     export LD_RUN_PATH
1493   fi
1494
1495   if test "${opsys}" = "gnu-linux"; then
1496     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1497     AC_TRY_LINK([],
1498      [XOpenDisplay ("foo");],
1499      [xlinux_first_failure=no],
1500      [xlinux_first_failure=yes])
1501     if test "${xlinux_first_failure}" = "yes"; then
1502       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1503       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1504       OLD_CPPFLAGS="$CPPFLAGS"
1505       OLD_LIBS="$LIBS"
1506       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1507       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1508       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1509       LIBS="$LIBS -b i486-linuxaout"
1510       AC_TRY_LINK([],
1511        [XOpenDisplay ("foo");],
1512        [xlinux_second_failure=no],
1513        [xlinux_second_failure=yes])
1514       if test "${xlinux_second_failure}" = "yes"; then
1515         # If we get the same failure with -b, there is no use adding -b.
1516         # So take it out.  This plays safe.
1517         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1518         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1519         CPPFLAGS="$OLD_CPPFLAGS"
1520         LIBS="$OLD_LIBS"
1521         AC_MSG_RESULT(no)
1522       else
1523         AC_MSG_RESULT(yes)
1524       fi
1525     else
1526       AC_MSG_RESULT(no)
1527     fi
1528   fi
1529
1530   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1531   # header files included from there.
1532   AC_MSG_CHECKING(for Xkb)
1533   AC_TRY_LINK([#include <X11/Xlib.h>
1534 #include <X11/XKBlib.h>],
1535         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1536         emacs_xkb=yes, emacs_xkb=no)
1537   AC_MSG_RESULT($emacs_xkb)
1538   if test $emacs_xkb = yes; then
1539     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1540   fi
1541
1542   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1543 XScreenNumberOfScreen XSetWMProtocols)
1544 fi
1545
1546 if test "${window_system}" = "x11"; then
1547   AC_MSG_CHECKING(X11 version 6)
1548   AC_CACHE_VAL(emacs_cv_x11_version_6,
1549   [AC_TRY_LINK([#include <X11/Xlib.h>],
1550 [#if XlibSpecificationRelease < 6
1551 fail;
1552 #endif
1553 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1554   if test $emacs_cv_x11_version_6 = yes; then
1555     AC_MSG_RESULT(6 or newer)
1556     AC_DEFINE(HAVE_X11R6, 1,
1557               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1558   else
1559     AC_MSG_RESULT(before 6)
1560   fi
1561 fi
1562
1563
1564 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1565 HAVE_RSVG=no
1566 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1567   if test "${with_rsvg}" != "no"; then
1568     RSVG_REQUIRED=2.11.0
1569     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1570
1571     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1572     AC_SUBST(RSVG_CFLAGS)
1573     AC_SUBST(RSVG_LIBS)
1574
1575     if test ".${RSVG_CFLAGS}" != "."; then
1576       HAVE_RSVG=yes
1577       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1578       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1579       LIBS="$RSVG_LIBS $LIBS"
1580     fi
1581   fi
1582 fi
1583
1584
1585 HAVE_GTK=no
1586 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1587   GLIB_REQUIRED=2.6
1588   GTK_REQUIRED=2.6
1589   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1590
1591   dnl Checks for libraries.
1592   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1593   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1594      AC_MSG_ERROR($GTK_PKG_ERRORS)
1595   fi
1596 fi
1597
1598
1599 if test x"$pkg_check_gtk" = xyes; then
1600
1601   AC_SUBST(GTK_CFLAGS)
1602   AC_SUBST(GTK_LIBS)
1603   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1604   CFLAGS="$CFLAGS $GTK_CFLAGS"
1605   LIBS="$GTK_LIBS $LIBS"
1606   dnl Try to compile a simple GTK program.
1607   GTK_COMPILES=no
1608   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1609   if test "${GTK_COMPILES}" != "yes"; then
1610     if test "$USE_X_TOOLKIT" != "maybe"; then
1611       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1612     fi
1613   else
1614     HAVE_GTK=yes
1615     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1616     USE_X_TOOLKIT=none
1617     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1618       :
1619     else
1620       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1621        closing open displays.  This is no problem if you just use
1622        one display, but if you use more than one and close one of them
1623        Emacs may crash.]])
1624       sleep 3
1625     fi
1626   fi
1627
1628 fi
1629
1630
1631 if test "${HAVE_GTK}" = "yes"; then
1632
1633   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1634   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1635   if test "$with_toolkit_scroll_bars" != no; then
1636     with_toolkit_scroll_bars=yes
1637   fi
1638
1639   dnl  Check if we can use multiple displays with this GTK version.
1640   dnl  If gdk_display_open exists, assume all others are there also.
1641   HAVE_GTK_MULTIDISPLAY=no
1642   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1643   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1644     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1645               [Define to 1 if GTK can handle more than one display.])
1646   fi
1647
1648   dnl  Check if we have the old file selection dialog declared and
1649   dnl  in the link library.  In 2.x it may be in the library,
1650   dnl  but not declared if deprecated featured has been selected out.
1651   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1652   HAVE_GTK_FILE_SELECTION=no
1653   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1654                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1655 #include <gtk/gtk.h>])
1656   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1657     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1658                    HAVE_GTK_FILE_SELECTION=no)
1659   fi
1660
1661   dnl  Check if we have the new file chooser dialog
1662   HAVE_GTK_FILE_CHOOSER=no
1663   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1664                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1665 #include <gtk/gtk.h>])
1666   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1667     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1668                    HAVE_GTK_FILE_CHOOSER=no)
1669   fi
1670
1671   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1672      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1673     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1674               [Define to 1 if GTK has both file selection and chooser dialog.])
1675   fi
1676
1677   dnl Check if pthreads are available.  Emacs only needs this when using
1678   dnl gtk_file_chooser under Gnome.
1679   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1680     HAVE_GTK_AND_PTHREAD=no
1681     AC_CHECK_HEADERS(pthread.h)
1682     if test "$ac_cv_header_pthread_h"; then
1683       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1684     fi
1685     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1686       case "${canonical}" in
1687         *-hpux*) ;;
1688         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1689       esac
1690       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1691                [Define to 1 if you have GTK and pthread (-lpthread).])
1692     fi
1693   fi
1694 fi
1695
1696 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1697 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1698 dnl also not configured.
1699 HAVE_DBUS=no
1700 if test "${with_dbus}" = "yes"; then
1701    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1702    if test "$HAVE_DBUS" = yes; then
1703      LIBS="$LIBS $DBUS_LIBS"
1704      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1705      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1706    fi
1707 fi
1708
1709 dnl Do not put whitespace before the #include statements below.
1710 dnl Older compilers (eg sunos4 cc) choke on it.
1711 HAVE_XAW3D=no
1712 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1713   if test "$with_xaw3d" != no; then
1714     AC_MSG_CHECKING(for xaw3d)
1715     AC_CACHE_VAL(emacs_cv_xaw3d,
1716     [AC_TRY_LINK([
1717 #include <X11/Intrinsic.h>
1718 #include <X11/Xaw3d/Simple.h>],
1719       [],
1720       emacs_cv_xaw3d=yes,
1721       emacs_cv_xaw3d=no)])
1722   else
1723     emacs_cv_xaw3d=no
1724   fi
1725   if test $emacs_cv_xaw3d = yes; then
1726     AC_MSG_RESULT([yes; using Lucid toolkit])
1727     USE_X_TOOLKIT=LUCID
1728     HAVE_XAW3D=yes
1729     AC_DEFINE(HAVE_XAW3D, 1,
1730               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1731   else
1732     AC_MSG_RESULT(no)
1733     AC_MSG_CHECKING(for libXaw)
1734     AC_CACHE_VAL(emacs_cv_xaw,
1735     [AC_TRY_LINK([
1736 #include <X11/Intrinsic.h>
1737 #include <X11/Xaw/Simple.h>],
1738       [],
1739       emacs_cv_xaw=yes,
1740       emacs_cv_xaw=no)])
1741     if test $emacs_cv_xaw = yes; then
1742       AC_MSG_RESULT([yes; using Lucid toolkit])
1743       USE_X_TOOLKIT=LUCID
1744     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1745       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1746     else
1747       AC_MSG_RESULT([no; do not use toolkit by default])
1748       USE_X_TOOLKIT=none
1749     fi
1750   fi
1751 fi
1752
1753 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1754
1755 if test "${USE_X_TOOLKIT}" != "none"; then
1756   AC_MSG_CHECKING(X11 toolkit version)
1757   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1758   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1759 [#if XtSpecificationRelease < 6
1760 fail;
1761 #endif
1762 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1763   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1764   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1765     AC_MSG_RESULT(6 or newer)
1766     AC_DEFINE(HAVE_X11XTR6, 1,
1767               [Define to 1 if you have the X11R6 or newer version of Xt.])
1768   else
1769     AC_MSG_RESULT(before 6)
1770   fi
1771
1772 dnl If using toolkit, check whether libXmu.a exists.
1773 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1774   OLDLIBS="$LIBS"
1775   if test x$HAVE_X11XTR6 = xyes; then
1776     LIBS="-lXt -lSM -lICE $LIBS"
1777   else
1778     LIBS="-lXt $LIBS"
1779   fi
1780   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1781   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1782 fi
1783
1784 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1785 if test "${HAVE_X11}" = "yes"; then
1786   if test "${USE_X_TOOLKIT}" != "none"; then
1787     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1788   fi
1789 fi
1790
1791 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1792   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1793   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1794     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1795 int x = 5;
1796 #else
1797 Motif version prior to 2.1.
1798 #endif],
1799     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1800   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1801   if test $emacs_cv_motif_version_2_1 = yes; then
1802     HAVE_LIBXP=no
1803     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1804               [Define to 1 if you have Motif 2.1 or newer.])
1805     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1806     if test ${HAVE_LIBXP} = yes; then
1807       AC_DEFINE(HAVE_LIBXP, 1,
1808                 [Define to 1 if you have the Xp library (-lXp).])
1809     fi
1810   else
1811     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1812     # We put this in CFLAGS temporarily to precede other -I options
1813     # that might be in CFLAGS temporarily.
1814     # We put this in CPPFLAGS where it precedes the other -I options.
1815     OLD_CPPFLAGS=$CPPFLAGS
1816     OLD_CFLAGS=$CFLAGS
1817     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1818     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1819     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1820       [int x = 5;],
1821       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1822     if test $emacs_cv_lesstif = yes; then
1823       # Make sure this -I option remains in CPPFLAGS after it is set
1824       # back to REAL_CPPFLAGS.
1825       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1826       # have those other -I options anyway.  Ultimately, having this
1827       # directory ultimately in CPPFLAGS will be enough.
1828       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1829       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1830     else
1831       CFLAGS=$OLD_CFLAGS
1832       CPPFLAGS=$OLD_CPPFLAGS
1833     fi
1834   fi
1835 fi
1836
1837 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1838 dnl using Motif or Xaw3d is available, and unless
1839 dnl --with-toolkit-scroll-bars=no was specified.
1840
1841 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1842             [Define to 1 if we should use toolkit scroll bars.])dnl
1843 USE_TOOLKIT_SCROLL_BARS=no
1844 if test "${with_toolkit_scroll_bars}" != "no"; then
1845   if test "${USE_X_TOOLKIT}" != "none"; then
1846     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1847       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1848       HAVE_XAW3D=no
1849       USE_TOOLKIT_SCROLL_BARS=yes
1850     elif test "${HAVE_XAW3D}" = "yes"; then
1851       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1852       USE_TOOLKIT_SCROLL_BARS=yes
1853     fi
1854   elif test "${HAVE_GTK}" = "yes"; then
1855     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1856     USE_TOOLKIT_SCROLL_BARS=yes
1857   elif test "${HAVE_NS}" = "yes"; then
1858     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1859     USE_TOOLKIT_SCROLL_BARS=yes
1860   fi
1861 fi
1862
1863 dnl See if XIM is available.
1864 AC_TRY_COMPILE([
1865           #include <X11/Xlib.h>
1866           #include <X11/Xresource.h>],
1867          [XIMProc  callback;],
1868          [HAVE_XIM=yes
1869          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1870          HAVE_XIM=no)
1871
1872 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1873
1874 if test "${with_xim}" != "no"; then
1875   AC_DEFINE(USE_XIM, 1,
1876             [Define to 1 if we should use XIM, if it is available.])
1877 fi
1878
1879
1880 if test "${HAVE_XIM}" != "no"; then
1881   late_CFLAGS=$CFLAGS
1882   if test "$GCC" = yes; then
1883     CFLAGS="$CFLAGS --pedantic-errors"
1884   fi
1885   AC_TRY_COMPILE([
1886 #include <X11/Xlib.h>
1887 #include <X11/Xresource.h>],
1888 [Display *display;
1889 XrmDatabase db;
1890 char *res_name;
1891 char *res_class;
1892 XIMProc  callback;
1893 XPointer *client_data;
1894 #ifndef __GNUC__
1895 /* If we're not using GCC, it's probably not XFree86, and this is
1896    probably right, but we can't use something like --pedantic-errors.  */
1897 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1898                                            char*, XIMProc, XPointer*);
1899 #endif
1900 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1901    client_data);],
1902     [emacs_cv_arg6_star=yes])
1903   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1904          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1905 either XPointer or XPointer*.])dnl
1906   if test "$emacs_cv_arg6_star" = yes; then
1907     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1908   else
1909     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1910   fi
1911   CFLAGS=$late_CFLAGS
1912 fi
1913
1914 ### Start of font-backend (under any platform) section.
1915 # (nothing here yet -- this is a placeholder)
1916 ### End of font-backend (under any platform) section.
1917
1918 ### Start of font-backend (under X11) section.
1919 if test "${HAVE_X11}" = "yes"; then
1920    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1921
1922    ## Use -lXft if available, unless `--with-xft=no'.
1923    HAVE_XFT=maybe
1924     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1925       with_xft="no";
1926     fi
1927     if test "x${with_xft}" != "xno"; then
1928
1929       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1930       if test "$HAVE_XFT" != no; then
1931         OLD_CPPFLAGS="$CPPFLAGS"
1932         OLD_CFLAGS="$CFLAGS"
1933         OLD_LIBS="$LIBS"
1934         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1935         CFLAGS="$CFLAGS $XFT_CFLAGS"
1936         LIBS="$XFT_LIBS $LIBS"
1937         AC_CHECK_HEADER(X11/Xft/Xft.h,
1938           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1939
1940         if test "${HAVE_XFT}" = "yes"; then
1941           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1942             AC_SUBST(XFT_LIBS)
1943           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1944         else
1945           CPPFLAGS="$OLD_CPPFLAGS"
1946           CFLAGS="$OLD_CFLAGS"
1947           LIBS="$OLD_LIBS"
1948         fi                        # "${HAVE_XFT}" = "yes"
1949       fi                          # "$HAVE_XFT" != no
1950     fi                            # "x${with_xft}" != "xno"
1951
1952     dnl For the "Does Emacs use" message at the end.
1953     if test "$HAVE_XFT" != "yes"; then
1954        HAVE_XFT=no
1955     fi
1956
1957
1958     HAVE_FREETYPE=no
1959     ## We used to allow building with FreeType and without Xft.
1960     ## However, the ftx font backend driver is not in good shape.
1961     if test "${HAVE_XFT}" = "yes"; then
1962       dnl As we use Xft, we anyway use freetype.
1963       dnl There's no need for additional CFLAGS and LIBS.
1964       HAVE_FREETYPE=yes
1965       FONTCONFIG_CFLAGS=
1966       FONTCONFIG_LIBS=
1967     fi
1968
1969     HAVE_LIBOTF=no
1970     if test "${HAVE_FREETYPE}" = "yes"; then
1971       AC_DEFINE(HAVE_FREETYPE, 1,
1972                 [Define to 1 if using the freetype and fontconfig libraries.])
1973       if test "${with_libotf}" != "no"; then
1974         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1975                           HAVE_LIBOTF=no)
1976         if test "$HAVE_LIBOTF" = "yes"; then
1977           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1978           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
1979                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
1980                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
1981           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
1982             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
1983                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
1984           fi
1985         fi
1986       fi
1987     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1988     dnl Does the new font backend require it, or can it work without it?
1989     fi
1990
1991     HAVE_M17N_FLT=no
1992     if test "${HAVE_LIBOTF}" = yes; then
1993       if test "${with_m17n_flt}" != "no"; then
1994         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1995         if test "$HAVE_M17N_FLT" = "yes"; then
1996           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1997         fi
1998       fi
1999     fi
2000 else
2001     HAVE_XFT=no
2002     HAVE_FREETYPE=no
2003     HAVE_LIBOTF=no
2004     HAVE_M17N_FLT=no
2005 fi
2006 ### End of font-backend (under X11) section.
2007
2008 AC_SUBST(FREETYPE_CFLAGS)
2009 AC_SUBST(FREETYPE_LIBS)
2010 AC_SUBST(FONTCONFIG_CFLAGS)
2011 AC_SUBST(FONTCONFIG_LIBS)
2012 AC_SUBST(LIBOTF_CFLAGS)
2013 AC_SUBST(LIBOTF_LIBS)
2014 AC_SUBST(M17N_FLT_CFLAGS)
2015 AC_SUBST(M17N_FLT_LIBS)
2016
2017 ### Use -lXpm if available, unless `--with-xpm=no'.
2018 HAVE_XPM=no
2019 if test "${HAVE_X11}" = "yes"; then
2020   if test "${with_xpm}" != "no"; then
2021     AC_CHECK_HEADER(X11/xpm.h,
2022       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2023     if test "${HAVE_XPM}" = "yes"; then
2024       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2025       AC_EGREP_CPP(no_return_alloc_pixels,
2026       [#include "X11/xpm.h"
2027 #ifndef XpmReturnAllocPixels
2028 no_return_alloc_pixels
2029 #endif
2030       ], HAVE_XPM=no, HAVE_XPM=yes)
2031
2032       if test "${HAVE_XPM}" = "yes"; then
2033         AC_MSG_RESULT(yes)
2034       else
2035         AC_MSG_RESULT(no)
2036       fi
2037     fi
2038   fi
2039
2040   if test "${HAVE_XPM}" = "yes"; then
2041     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2042   fi
2043 fi
2044
2045 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2046 HAVE_JPEG=no
2047 if test "${HAVE_X11}" = "yes"; then
2048   if test "${with_jpeg}" != "no"; then
2049     dnl Checking for jpeglib.h can lose because of a redefinition of
2050     dnl  HAVE_STDLIB_H.
2051     AC_CHECK_HEADER(jerror.h,
2052       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2053   fi
2054
2055   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2056   if test "${HAVE_JPEG}" = "yes"; then
2057     AC_DEFINE(HAVE_JPEG)
2058     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2059         [#include <jpeglib.h>
2060          version=JPEG_LIB_VERSION
2061 ],
2062         [AC_DEFINE(HAVE_JPEG)],
2063         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2064         HAVE_JPEG=no])
2065   fi
2066 fi
2067
2068 ### Use -lpng if available, unless `--with-png=no'.
2069 HAVE_PNG=no
2070 if test "${HAVE_X11}" = "yes"; then
2071   if test "${with_png}" != "no"; then
2072     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2073     # in /usr/include/libpng.
2074     AC_CHECK_HEADERS(png.h libpng/png.h)
2075     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2076       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2077     fi
2078   fi
2079
2080   if test "${HAVE_PNG}" = "yes"; then
2081     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2082   fi
2083 fi
2084
2085 ### Use -ltiff if available, unless `--with-tiff=no'.
2086 HAVE_TIFF=no
2087 if test "${HAVE_X11}" = "yes"; then
2088   if test "${with_tiff}" != "no"; then
2089     AC_CHECK_HEADER(tiffio.h,
2090       [tifflibs="-lz -lm"
2091       # At least one tiff package requires the jpeg library.
2092       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2093       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2094   fi
2095
2096   if test "${HAVE_TIFF}" = "yes"; then
2097     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2098   fi
2099 fi
2100
2101 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2102 HAVE_GIF=no
2103 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2104   AC_CHECK_HEADER(gif_lib.h,
2105 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2106 # Earlier versions can crash Emacs.
2107     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2108
2109   if test "$HAVE_GIF" = yes; then
2110       ac_gif_lib_name="-lgif"
2111   fi
2112
2113 # If gif_lib.h but no libgif, try libungif.
2114   if test x"$try_libungif" = xyes; then
2115     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2116
2117     if test "$HAVE_GIF" = yes; then
2118       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2119       ac_gif_lib_name="-lungif"
2120     fi
2121   fi
2122
2123   if test "${HAVE_GIF}" = "yes"; then
2124     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2125   fi
2126 fi
2127
2128 dnl Check for required libraries.
2129 if test "${HAVE_X11}" = "yes"; then
2130   MISSING=""
2131   WITH_NO=""
2132   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2133     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2134   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2135     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2136   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2137     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2138   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2139     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2140   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2141     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2142
2143   if test "X${MISSING}" != X; then
2144     AC_MSG_ERROR([The following required libraries were not found:
2145     $MISSING
2146 Maybe some development libraries/packages are missing?
2147 If you don't want to link with them give
2148     $WITH_NO
2149 as options to configure])
2150   fi
2151 fi
2152
2153 ### Use -lgpm if available, unless `--with-gpm=no'.
2154 HAVE_GPM=no
2155 if test "${with_gpm}" != "no"; then
2156   AC_CHECK_HEADER(gpm.h,
2157     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2158 fi
2159
2160 if test "${HAVE_GPM}" = "yes"; then
2161   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2162 fi
2163
2164 dnl Check for malloc/malloc.h on darwin
2165 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2166
2167 ### Use NeXTstep API to implement GUI.
2168 if test "${HAVE_NS}" = "yes"; then
2169   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2170   if test "${NS_IMPL_COCOA}" = "yes"; then
2171     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2172     GNU_OBJC_CFLAGS=
2173   fi
2174   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2175     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2176     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2177   fi
2178   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2179     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2180   fi
2181   # We also have mouse menus.
2182   HAVE_MENUS=yes
2183   OTHER_FILES=ns-app
2184 fi
2185
2186
2187 ### Use session management (-lSM -lICE) if available
2188 HAVE_X_SM=no
2189 if test "${HAVE_X11}" = "yes"; then
2190   AC_CHECK_HEADER(X11/SM/SMlib.h,
2191     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2192
2193   if test "${HAVE_X_SM}" = "yes"; then
2194     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2195     case "$LIBS" in
2196       *-lSM*) ;;
2197       *)      LIBS="-lSM -lICE $LIBS" ;;
2198     esac
2199   fi
2200 fi
2201
2202 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2203 AC_CACHE_CHECK(whether netdb declares h_errno,
2204                emacs_cv_netdb_declares_h_errno,
2205 [AC_TRY_LINK([#include <netdb.h>],
2206   [return h_errno;],
2207   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2208 if test $emacs_cv_netdb_declares_h_errno = yes; then
2209   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2210 fi
2211
2212 AC_FUNC_ALLOCA
2213
2214 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2215 dnl FIXME is there an autoconf test that does the right thing, without
2216 dnl needing to call A_M_E afterwards?
2217 if test x"$ac_cv_func_alloca_works" != xyes; then
2218    AC_MSG_ERROR( [a system implementation of alloca is required] )
2219 fi
2220
2221 # fmod, logb, and frexp are found in -lm on most systems.
2222 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2223 AC_CHECK_LIB(m, sqrt)
2224
2225 # Check for mail-locking functions in a "mail" library.  Probably this should
2226 # have the same check as for liblockfile below.
2227 AC_CHECK_LIB(mail, maillock)
2228 dnl Debian, at least:
2229 AC_CHECK_LIB(lockfile, maillock)
2230 # If we have the shared liblockfile, assume we must use it for mail
2231 # locking (e.g. Debian).  If we couldn't link against liblockfile
2232 # (no liblockfile.a installed), ensure that we don't need to.
2233 if test "$ac_cv_lib_lockfile_maillock" = no; then
2234   dnl This works for files generally, not just executables.
2235   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2236   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2237                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2238   if test $ac_cv_prog_liblockfile = yes; then
2239     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2240 This probably means that movemail could lose mail.
2241 There may be a `development' package to install containing liblockfile.])
2242   else :
2243   fi
2244 fi
2245 AC_CHECK_FUNCS(touchlock)
2246 AC_CHECK_HEADERS(maillock.h)
2247
2248 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2249 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2250 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2251 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2252 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2253 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2254 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2255 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2256 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2257 cfmakeraw cfsetspeed)
2258
2259 AC_CHECK_HEADERS(sys/un.h)
2260
2261 AC_FUNC_MKTIME
2262 if test "$ac_cv_func_working_mktime" = no; then
2263   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2264 fi
2265
2266 AC_FUNC_GETLOADAVG
2267
2268 AC_FUNC_FSEEKO
2269
2270 # Configure getopt.
2271 m4_include([m4/getopt.m4])
2272 gl_GETOPT_IFELSE([
2273   gl_GETOPT_SUBSTITUTE_HEADER
2274   gl_PREREQ_GETOPT
2275   GETOPTOBJS='getopt.o getopt1.o'
2276 ])
2277 AC_SUBST(GETOPTOBJS)
2278
2279 AC_FUNC_GETPGRP
2280
2281 AC_FUNC_STRFTIME
2282
2283 # UNIX98 PTYs.
2284 AC_CHECK_FUNCS(grantpt)
2285
2286 # PTY-related GNU extensions.
2287 AC_CHECK_FUNCS(getpt)
2288
2289 # Check this now, so that we will NOT find the above functions in ncurses.
2290 # That is because we have not set up to link ncurses in lib-src.
2291 # It's better to believe a function is not available
2292 # than to expect to find it in ncurses.
2293 AC_CHECK_LIB(ncurses, tparm)
2294
2295 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2296
2297 resolv=no
2298 AC_TRY_LINK([#include <netinet/in.h>
2299 #include <arpa/nameser.h>
2300 #include <resolv.h>],
2301     [return res_init();],
2302     have_res_init=yes, have_res_init=no)
2303 if test "$have_res_init" = no; then
2304   OLIBS="$LIBS"
2305   LIBS="$LIBS -lresolv"
2306   AC_MSG_CHECKING(for res_init with -lresolv)
2307   AC_TRY_LINK([#include <netinet/in.h>
2308 #include <arpa/nameser.h>
2309 #include <resolv.h>],
2310     [return res_init();],
2311     have_res_init=yes, have_res_init=no)
2312   AC_MSG_RESULT($have_res_init)
2313   if test "$have_res_init" = yes ; then
2314     resolv=yes
2315   fi
2316   LIBS="$OLIBS"
2317 fi
2318
2319 if test "$have_res_init" = yes; then
2320   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2321 fi
2322
2323 # Do we need the Hesiod library to provide the support routines?
2324 if test "$with_hesiod" != no ; then
2325   # Don't set $LIBS here -- see comments above.
2326   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2327      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2328                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2329   if test "$resolv" = yes ; then
2330     RESOLVLIB=-lresolv
2331   else
2332     RESOLVLIB=
2333   fi
2334   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2335         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2336                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2337         :, $RESOLVLIB)])
2338 fi
2339
2340 # Do we need libresolv (due to res_init or Hesiod)?
2341 if test "$resolv" = yes ; then
2342   AC_DEFINE(HAVE_LIBRESOLV, 1,
2343             [Define to 1 if you have the resolv library (-lresolv).])
2344 fi
2345
2346 # These tell us which Kerberos-related libraries to use.
2347 if test "${with_kerberos}" != no; then
2348   AC_CHECK_LIB(com_err, com_err)
2349   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2350   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2351   AC_CHECK_LIB(krb5, krb5_init_context)
2352   if test "${with_kerberos5}" = no; then
2353     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2354                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2355     AC_CHECK_LIB(krb4, krb_get_cred,,
2356                  [AC_CHECK_LIB(krb, krb_get_cred)])
2357   fi
2358
2359   if test "${with_kerberos5}" != no; then
2360     AC_CHECK_HEADERS(krb5.h,
2361       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2362                         [#include <krb5.h>])])
2363   else
2364     AC_CHECK_HEADERS(des.h,,
2365                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2366                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2367     AC_CHECK_HEADERS(krb.h,,
2368                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2369                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2370   fi
2371   AC_CHECK_HEADERS(com_err.h)
2372 fi
2373
2374 # Solaris requires -lintl if you want strerror (which calls dgettext)
2375 # to return localized messages.
2376 AC_CHECK_LIB(intl, dgettext)
2377
2378 AC_MSG_CHECKING(whether localtime caches TZ)
2379 AC_CACHE_VAL(emacs_cv_localtime_cache,
2380 [if test x$ac_cv_func_tzset = xyes; then
2381 AC_TRY_RUN([#include <time.h>
2382 extern char **environ;
2383 unset_TZ ()
2384 {
2385   char **from, **to;
2386   for (to = from = environ; (*to = *from); from++)
2387     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2388       to++;
2389 }
2390 char TZ_GMT0[] = "TZ=GMT0";
2391 char TZ_PST8[] = "TZ=PST8";
2392 main()
2393 {
2394   time_t now = time ((time_t *) 0);
2395   int hour_GMT0, hour_unset;
2396   if (putenv (TZ_GMT0) != 0)
2397     exit (1);
2398   hour_GMT0 = localtime (&now)->tm_hour;
2399   unset_TZ ();
2400   hour_unset = localtime (&now)->tm_hour;
2401   if (putenv (TZ_PST8) != 0)
2402     exit (1);
2403   if (localtime (&now)->tm_hour == hour_GMT0)
2404     exit (1);
2405   unset_TZ ();
2406   if (localtime (&now)->tm_hour != hour_unset)
2407     exit (1);
2408   exit (0);
2409 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2410 [# If we have tzset, assume the worst when cross-compiling.
2411 emacs_cv_localtime_cache=yes])
2412 else
2413         # If we lack tzset, report that localtime does not cache TZ,
2414         # since we can't invalidate the cache if we don't have tzset.
2415         emacs_cv_localtime_cache=no
2416 fi])dnl
2417 AC_MSG_RESULT($emacs_cv_localtime_cache)
2418 if test $emacs_cv_localtime_cache = yes; then
2419   AC_DEFINE(LOCALTIME_CACHE, 1,
2420             [Define to 1 if localtime caches TZ.])
2421 fi
2422
2423 if test "x$HAVE_TIMEVAL" = xyes; then
2424   AC_CHECK_FUNCS(gettimeofday)
2425   if test $ac_cv_func_gettimeofday = yes; then
2426     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2427                    emacs_cv_gettimeofday_two_arguments,
2428     [AC_TRY_COMPILE([
2429 #ifdef TIME_WITH_SYS_TIME
2430 #include <sys/time.h>
2431 #include <time.h>
2432 #else
2433 #ifdef HAVE_SYS_TIME_H
2434 #include <sys/time.h>
2435 #else
2436 #include <time.h>
2437 #endif
2438 #endif],
2439       [struct timeval time;
2440        gettimeofday (&time, 0);],
2441       emacs_cv_gettimeofday_two_arguments=yes,
2442       emacs_cv_gettimeofday_two_arguments=no)])
2443     if test $emacs_cv_gettimeofday_two_arguments = no; then
2444       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2445                 [Define to 1 if gettimeofday accepts only one argument.])
2446     fi
2447   fi
2448 fi
2449
2450 ok_so_far=yes
2451 AC_CHECK_FUNC(socket, , ok_so_far=no)
2452 if test $ok_so_far = yes; then
2453   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2454 fi
2455 if test $ok_so_far = yes; then
2456   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2457 fi
2458 if test $ok_so_far = yes; then
2459 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2460   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2461             [Define to 1 if you have inet sockets.])
2462 fi
2463
2464 AC_CHECK_HEADERS(sys/ioctl.h)
2465
2466 if test -f /usr/lpp/X11/bin/smt.exp; then
2467   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2468             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2469 fi
2470
2471 AC_MSG_CHECKING(whether system supports dynamic ptys)
2472 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2473   AC_MSG_RESULT(yes)
2474   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2475 else
2476   AC_MSG_RESULT(no)
2477 fi
2478
2479 AC_FUNC_FORK
2480
2481 dnl Adapted from Haible's version.
2482 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2483   [AC_TRY_LINK([#include <langinfo.h>],
2484     [char* cs = nl_langinfo(CODESET);],
2485     emacs_cv_langinfo_codeset=yes,
2486     emacs_cv_langinfo_codeset=no)
2487   ])
2488 if test $emacs_cv_langinfo_codeset = yes; then
2489   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2490     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2491 fi
2492
2493 AC_CHECK_TYPES(size_t)
2494
2495 AC_TYPE_MBSTATE_T
2496
2497 dnl Restrict could probably be used effectively other than in regex.c.
2498 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2499   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2500                   emacs_cv_c_restrict=yes,
2501                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2502                                   emacs_cv_c_restrict=__restrict,
2503                                   emacs_cv_c_restrict=no)])])
2504 case "$emacs_cv_c_restrict" in
2505   yes) emacs_restrict=restrict;;
2506   no) emacs_restrict="";;
2507   *) emacs_restrict="$emacs_cv_c_restrict";;
2508 esac
2509 if test "$emacs_restrict" != __restrict; then
2510   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2511     [Define to compiler's equivalent of C99 restrict keyword.
2512      Don't define if equivalent is `__restrict'.])
2513 fi
2514
2515 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2516   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2517                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2518 if test "$emacs_cv_c_restrict_arr" = yes; then
2519   AC_DEFINE(__restrict_arr, __restrict,
2520     [Define to compiler's equivalent of C99 restrict keyword in array
2521      declarations.  Define as empty for no equivalent.])
2522 fi
2523
2524 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2525 dnl how the tty code is related to POSIX and/or other versions of termios.
2526 dnl The following looks like a useful start.
2527 dnl
2528 dnl AC_SYS_POSIX_TERMIOS
2529 dnl if test $ac_cv_sys_posix_termios = yes; then
2530 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2531 dnl                                and macros for terminal control.])
2532 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2533 dnl fi
2534
2535 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2536
2537 # Set up the CFLAGS for real compilation, so we can substitute it.
2538 CFLAGS="$REAL_CFLAGS"
2539 CPPFLAGS="$REAL_CPPFLAGS"
2540
2541 #### Find out which version of Emacs this is.
2542 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2543          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2544 if test x"${version}" = x; then
2545   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2546 fi
2547 if test x"${version}" != x"$PACKAGE_VERSION"; then
2548   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2549 fi
2550
2551 ### Specify what sort of things we'll be editing into Makefile and config.h.
2552 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2553 AC_SUBST(version)
2554 AC_SUBST(configuration)
2555 AC_SUBST(canonical)
2556 AC_SUBST(srcdir)
2557 AC_SUBST(prefix)
2558 AC_SUBST(exec_prefix)
2559 AC_SUBST(bindir)
2560 AC_SUBST(datadir)
2561 AC_SUBST(sharedstatedir)
2562 AC_SUBST(libexecdir)
2563 AC_SUBST(mandir)
2564 AC_SUBST(infodir)
2565 AC_SUBST(lispdir)
2566 AC_SUBST(locallisppath)
2567 AC_SUBST(lisppath)
2568 AC_SUBST(x_default_search_path)
2569 AC_SUBST(etcdir)
2570 AC_SUBST(archlibdir)
2571 AC_SUBST(docdir)
2572 AC_SUBST(bitmapdir)
2573 AC_SUBST(gamedir)
2574 AC_SUBST(gameuser)
2575 AC_SUBST(c_switch_system)
2576 AC_SUBST(c_switch_machine)
2577 AC_SUBST(LD_SWITCH_X_SITE)
2578 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2579 AC_SUBST(C_SWITCH_X_SITE)
2580 AC_SUBST(CFLAGS)
2581 AC_SUBST(X_TOOLKIT_TYPE)
2582 AC_SUBST(machfile)
2583 AC_SUBST(opsysfile)
2584 AC_SUBST(GETLOADAVG_LIBS)
2585 AC_SUBST(ns_appdir)
2586 AC_SUBST(ns_appbindir)
2587 AC_SUBST(ns_appresdir)
2588 AC_SUBST(ns_appsrc)
2589 AC_SUBST(GNUSTEP_MAKEFILES)
2590 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2591 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2592 AC_SUBST(GNU_OBJC_CFLAGS)
2593 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2594 AC_SUBST(OTHER_FILES)
2595
2596 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2597                    [Define to the canonical Emacs configuration name.])
2598 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2599                    [Define to the options passed to configure.])
2600 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2601                    [Define to the used machine dependent file.])
2602 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2603                    [Define to the used os dependent file.])
2604 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2605 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2606  may need to deal with X Windows.  For instance, if you've defined
2607  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2608  your loader can find on its own, you might want to add "-L/..." or
2609  something similar.])
2610 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2611                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2612                     in case it's needed (for Solaris, for example).])
2613 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2614 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2615  may need to deal with X Windows.  For instance, if you've defined
2616  HAVE_X_WINDOWS above and your X include files aren't in a place
2617  that your compiler can find on its own, you might want to add
2618  "-I/..." or something similar.])
2619 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2620                    [Define to the unexec source file name.])
2621
2622 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2623   AC_DEFINE(HAVE_X_WINDOWS, 1,
2624             [Define to 1 if you want to use the X window system.])
2625 fi
2626 if test "${USE_X_TOOLKIT}" != "none" ; then
2627   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2628   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2629     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2630   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2631     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2632   fi
2633 fi
2634 if test "${HAVE_X11}" = "yes" ; then
2635   AC_DEFINE(HAVE_X11, 1,
2636             [Define to 1 if you want to use version 11 of X windows.
2637              Otherwise, Emacs expects to use version 10.])
2638 fi
2639 if test "${HAVE_MENUS}" = "yes" ; then
2640   AC_DEFINE(HAVE_MENUS, 1,
2641             [Define to 1 if you have mouse menus.
2642              (This is automatic if you use X, but the option to specify it remains.)
2643              It is also defined with other window systems that support xmenu.c.])
2644 fi
2645 if test "${GNU_MALLOC}" = "yes" ; then
2646   AC_DEFINE(GNU_MALLOC, 1,
2647             [Define to 1 if you want to use the GNU memory allocator.])
2648 fi
2649 if test "${REL_ALLOC}" = "yes" ; then
2650   AC_DEFINE(REL_ALLOC, 1,
2651             [Define REL_ALLOC if you want to use the relocating allocator for
2652              buffer space.])
2653 fi
2654
2655
2656 AH_TOP([/* GNU Emacs site configuration template file.
2657    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2658      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2659
2660 This file is part of GNU Emacs.
2661
2662 GNU Emacs is free software: you can redistribute it and/or modify
2663 it under the terms of the GNU General Public License as published by
2664 the Free Software Foundation, either version 3 of the License, or
2665 (at your option) any later version.
2666
2667 GNU Emacs is distributed in the hope that it will be useful,
2668 but WITHOUT ANY WARRANTY; without even the implied warranty of
2669 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2670 GNU General Public License for more details.
2671
2672 You should have received a copy of the GNU General Public License
2673 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2674
2675
2676 /* No code in Emacs #includes config.h twice, but some bits of code
2677    intended to work with other packages as well (like gmalloc.c)
2678    think they can include it as many times as they like.  */
2679 #ifndef EMACS_CONFIG_H
2680 #define EMACS_CONFIG_H
2681 ])dnl
2682
2683 AH_BOTTOM([
2684 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2685 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2686 #define HAVE_WINDOW_SYSTEM
2687 #define HAVE_MOUSE
2688 #endif
2689
2690 /* Define AMPERSAND_FULL_NAME if you use the convention
2691    that & in the full name stands for the login id.  */
2692 /* Turned on June 1996 supposing nobody will mind it.  */
2693 #define AMPERSAND_FULL_NAME
2694
2695 /* Define HAVE_SOUND if we have sound support.  We know it works
2696    and compiles only on the specified platforms.   For others,
2697    it probably doesn't make sense to try.  */
2698
2699 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2700 #ifdef HAVE_MACHINE_SOUNDCARD_H
2701 #define HAVE_SOUND 1
2702 #endif
2703 #ifdef HAVE_SYS_SOUNDCARD_H
2704 #define HAVE_SOUND 1
2705 #endif
2706 #ifdef HAVE_SOUNDCARD_H
2707 #define HAVE_SOUND 1
2708 #endif
2709 #ifdef HAVE_ALSA
2710 #define HAVE_SOUND 1
2711 #endif
2712 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2713
2714 /* If using GNU, then support inline function declarations. */
2715 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2716    generally, because even if non-gcc compilers accept `inline', they
2717    may reject `extern inline'.  */
2718 #if defined (__GNUC__) && defined (OPTIMIZE)
2719 #define INLINE __inline__
2720 #else
2721 #define INLINE
2722 #endif
2723
2724 /* `subprocesses' should be defined if you want to
2725    have code for asynchronous subprocesses
2726    (as used in M-x compile and M-x shell).
2727    Only MSDOS does not support this (it overrides
2728    this in its config_opsysfile below).  */
2729
2730 #define subprocesses
2731
2732 /* Include the os and machine dependent files.  */
2733 #include config_opsysfile
2734 #include config_machfile
2735
2736 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2737   (There is probably a better place to do this, but right now the Cocoa
2738    side does this in s/darwin.h and we cannot
2739    parallel this exactly since GNUstep is multi-OS. */
2740 #ifdef HAVE_NS
2741 # ifdef NS_IMPL_GNUSTEP
2742 /* See also .m.o rule in Makefile.in */
2743 /* FIXME: are all these flags really needed?  Document here why.  */
2744 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2745 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2746 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2747 #  define SYSTEM_PURESIZE_EXTRA 30000
2748 # endif /* NS_IMPL_GNUSTEP */
2749 #endif /* HAVE_NS */
2750
2751 /* SIGTYPE is the macro we actually use.  */
2752 #ifndef SIGTYPE
2753 #define SIGTYPE RETSIGTYPE
2754 #endif
2755
2756 #ifdef emacs /* Don't do this for lib-src.  */
2757 /* Tell regex.c to use a type compatible with Emacs.  */
2758 #define RE_TRANSLATE_TYPE Lisp_Object
2759 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2760 #ifdef make_number
2761 /* If make_number is a macro, use it.  */
2762 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2763 #else
2764 /* If make_number is a function, avoid it.  */
2765 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2766 #endif
2767 #endif
2768
2769 /* Avoid link-time collision with system mktime if we will use our own.  */
2770 #if ! HAVE_MKTIME || BROKEN_MKTIME
2771 #define mktime emacs_mktime
2772 #endif
2773
2774 #define my_strftime nstrftime   /* for strftime.c */
2775
2776 /* The rest of the code currently tests the CPP symbol BSTRING.
2777    Override any claims made by the system-description files.
2778    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2779 #undef BSTRING
2780 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2781 #define BSTRING
2782 #endif
2783
2784 /* Some of the files of Emacs which are intended for use with other
2785    programs assume that if you have a config.h file, you must declare
2786    the type of getenv.
2787
2788    This declaration shouldn't appear when alloca.s or Makefile.in
2789    includes config.h.  */
2790 #ifndef NOT_C_CODE
2791 extern char *getenv ();
2792 #endif
2793
2794 /* These default definitions are good for almost all machines.
2795    The exceptions override them in m/MACHINE.h.  */
2796
2797 #ifndef BITS_PER_CHAR
2798 #define BITS_PER_CHAR 8
2799 #endif
2800
2801 #ifndef BITS_PER_SHORT
2802 #define BITS_PER_SHORT 16
2803 #endif
2804
2805 /* Note that lisp.h uses this in a preprocessor conditional, so it
2806    would not work to use sizeof.  That being so, we do all of them
2807    without sizeof, for uniformity's sake.  */
2808 #ifndef BITS_PER_INT
2809 #define BITS_PER_INT 32
2810 #endif
2811
2812 #ifndef BITS_PER_LONG
2813 #ifdef _LP64
2814 #define BITS_PER_LONG 64
2815 #else
2816 #define BITS_PER_LONG 32
2817 #endif
2818 #endif
2819
2820 /* Define if the compiler supports function prototypes.  It may do so
2821    but not define __STDC__ (e.g. DEC C by default) or may define it as
2822    zero.  */
2823 #undef PROTOTYPES
2824 /* For mktime.c:  */
2825 #ifndef __P
2826 # if defined PROTOTYPES
2827 #  define __P(args) args
2828 # else
2829 #  define __P(args) ()
2830 # endif  /* GCC.  */
2831 #endif /* __P */
2832
2833 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2834 #ifndef NOT_C_CODE
2835 #ifdef HAVE_STRING_H
2836 #include "string.h"
2837 #endif
2838 #ifdef HAVE_STRINGS_H
2839 #include "strings.h"  /* May be needed for bcopy & al. */
2840 #endif
2841 #ifdef HAVE_STDLIB_H
2842 #include <stdlib.h>
2843 #endif
2844 #ifndef __GNUC__
2845 # ifdef HAVE_ALLOCA_H
2846 #  include <alloca.h>
2847 # else /* AIX files deal with #pragma.  */
2848 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2849 char *alloca ();
2850 #  endif
2851 # endif /* HAVE_ALLOCA_H */
2852 #endif /* __GNUC__ */
2853 #ifndef HAVE_SIZE_T
2854 typedef unsigned size_t;
2855 #endif
2856 #endif /* NOT_C_CODE */
2857
2858 /* Define HAVE_X_I18N if we have usable i18n support.  */
2859
2860 #ifdef HAVE_X11R6
2861 #define HAVE_X_I18N
2862 #elif !defined X11R5_INHIBIT_I18N
2863 #define HAVE_X_I18N
2864 #endif
2865
2866 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2867
2868 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2869 #define HAVE_X11R6_XIM
2870 #endif
2871
2872 #if defined __GNUC__ && (__GNUC__ > 2 \
2873                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2874 #define NO_RETURN       __attribute__ ((__noreturn__))
2875 #else
2876 #define NO_RETURN       /* nothing */
2877 #endif
2878
2879 /* These won't be used automatically yet.  We also need to know, at least,
2880    that the stack is continuous.  */
2881 #ifdef __GNUC__
2882 #  ifndef GC_SETJMP_WORKS
2883   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2884      see NON_SAVING_SETJMP in the target descriptions.  */
2885   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2886      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2887      Fixme: Deal with SVR3.  */
2888 #    define GC_SETJMP_WORKS 1
2889 #  endif
2890 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2891 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2892 #  endif
2893 #endif
2894
2895 #ifndef HAVE_BCOPY
2896 #define bcopy(a,b,s) memcpy (b,a,s)
2897 #endif
2898 #ifndef HAVE_BZERO
2899 #define bzero(a,s) memset (a,0,s)
2900 #endif
2901 #ifndef HAVE_BCMP
2902 #define BCMP memcmp
2903 #endif
2904
2905 #endif /* EMACS_CONFIG_H */
2906
2907 /*
2908 Local Variables:
2909 mode: c
2910 End:
2911 */
2912 ])dnl
2913
2914 #### Report on what we decided to do.
2915 #### Report GTK as a toolkit, even if it doesn't use Xt.
2916 #### It makes printing result more understandable as using GTK sets
2917 #### toolkit_scroll_bars to yes by default.
2918 if test "${HAVE_GTK}" = "yes"; then
2919   USE_X_TOOLKIT=GTK
2920 fi
2921
2922 echo "
2923 Configured for \`${canonical}'.
2924
2925   Where should the build process find the source code?    ${srcdir}
2926   What operating system and machine description files should Emacs use?
2927         \`${opsysfile}' and \`${machfile}'
2928   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2929   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2930   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2931   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2932   What window system should Emacs use?                    ${window_system}
2933   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2934
2935 if test -n "${x_includes}"; then
2936 echo "  Where do we find X Windows header files?                ${x_includes}"
2937 else
2938 echo "  Where do we find X Windows header files?                Standard dirs"
2939 fi
2940 if test -n "${x_libraries}"; then
2941 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2942 else
2943 echo "  Where do we find X Windows libraries?                   Standard dirs"
2944 fi
2945
2946 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2947 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2948 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2949 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2950 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2951 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2952 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2953 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2954 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2955
2956 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2957 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2958 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2959 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2960
2961 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2962 echo
2963
2964 if test $USE_XASSERTS = yes; then
2965    echo "  Compiling with asserts turned on."
2966    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2967 fi
2968
2969 echo
2970
2971 if test "$USE_X_TOOLKIT" = GTK; then
2972   case "$canonical" in
2973   *cygwin*)
2974     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2975   will probably get a crash on startup.  If this happens, please use another
2976   toolkit for Emacs.  See etc/PROBLEMS for more information."
2977   ;;
2978   esac
2979 fi
2980
2981 if test "$HAVE_NS" = "yes"; then
2982    echo
2983    echo "You must run \"make install\" in order to test the built application.
2984 The installed application will go to nextstep/Emacs.app and can be
2985 run or moved from there."
2986    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2987       echo "The application will be fully self-contained."
2988     else
2989       echo "The lisp resources for the application will be installed under ${prefix}.
2990 You may need to run \"make install\" with sudo.  The application will fail
2991 to run if these resources are not installed."
2992    fi
2993    echo
2994 fi
2995
2996 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2997   echo "D-Bus integration has been tested for GNU/Linux only."
2998   echo
2999 fi
3000
3001
3002 # Remove any trailing slashes in these variables.
3003 [test "${prefix}" != NONE &&
3004   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3005 test "${exec_prefix}" != NONE &&
3006   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3007
3008 # Now get this: Some word that is part of the ${srcdir} directory name
3009 # or the ${configuration} value might, just might, happen to be an
3010 # identifier like `sun4' or `i386' or something, and be predefined by
3011 # the C preprocessor to some helpful value like 1, or maybe the empty
3012 # string.  Needless to say consequent macro substitutions are less
3013 # than conducive to the makefile finding the correct directory.
3014 [cpp_undefs="`echo $srcdir $configuration $canonical |
3015   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3016   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3017
3018 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3019 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3020 ## from Makefile.c can correctly provide the arg `-traditional' to the
3021 ## C preprocessor.
3022
3023 AC_EGREP_CPP(yes..yes,
3024         [yes..yes],
3025         CPP_NEED_TRADITIONAL=no,
3026         CPP_NEED_TRADITIONAL=yes)
3027
3028 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3029         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3030         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3031         lwlib/Makefile lisp/Makefile leim/Makefile, [
3032
3033 ### Make the necessary directories, if they don't exist.
3034 for dir in etc lisp ; do
3035   test -d ${dir} || mkdir ${dir}
3036 done
3037
3038 # Build src/Makefile from ${srcdir}/src/Makefile.c
3039 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3040 # This must be done after src/config.h is built, since we rely on that file.
3041
3042 echo creating src/epaths.h
3043 ${MAKE-make} epaths-force
3044
3045 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3046 # `..' to `. .'  unless invoked with -traditional
3047
3048 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3049   CPPFLAGS="$CPPFLAGS -traditional"
3050 fi
3051
3052 echo creating lib-src/Makefile
3053 ( cd lib-src
3054   rm -f junk.c junk1.c junk2.c
3055   sed -e '/start of cpp stuff/q' \
3056       < Makefile.c > junk1.c
3057   sed -e '1,/start of cpp stuff/d'\
3058       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3059       < Makefile.c > junk.c
3060   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3061       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3062   cat junk1.c junk2.c > Makefile.new
3063   rm -f junk.c junk1.c junk2.c
3064   chmod 444 Makefile.new
3065   mv -f Makefile.new Makefile
3066 )
3067
3068 echo creating src/Makefile
3069 ( cd src
3070   rm -f junk.c junk1.c junk2.c
3071   sed -e '/start of cpp stuff/q' \
3072       < Makefile.c > junk1.c
3073   sed -e '1,/start of cpp stuff/d'\
3074       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3075       < Makefile.c > junk.c
3076   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3077       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3078   cat junk1.c junk2.c > Makefile.new
3079   rm -f junk.c junk1.c junk2.c
3080   chmod 444 Makefile.new
3081   mv -f Makefile.new Makefile
3082 )
3083
3084 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3085   echo creating src/.gdbinit
3086   echo source $srcdir/src/.gdbinit > src/.gdbinit
3087 fi
3088
3089 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3090
3091 m4_if(dnl       Do not change this comment
3092    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3093 )dnl