configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 159 OPTION_DEFAULT_OFF([imagemagick],[compile with ImageMagick image support])
 160
 161 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 162 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 163 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 164
 165 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 166 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 167 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 168 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 169
 170 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 171 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 172 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 173 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 174 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 175
 176 ## For the times when you want to build Emacs but don't have
 177 ## a suitable makeinfo, and can live without the manuals.
 178 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 179 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 180
 181 ## This is an option because I do not know if all info/man support
 182 ## compressed files, nor how to test if they do so.
 183 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 184 if test $with_compress_info = yes; then
 185    GZIP_INFO=yes
 186 else
 187    GZIP_INFO=
 188 fi
 189 AC_SUBST(GZIP_INFO)
 190
 191 AC_ARG_WITH([pkg-config-prog],dnl
 192 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 193                   [path to pkg-config for finding GTK and librsvg])])
 194 if test "X${with_pkg_config_prog}" != X; then
 195    if test "${with_pkg_config_prog}" != yes; then
 196       PKG_CONFIG="${with_pkg_config_prog}"
 197    fi
 198 fi
 199
 200 CRT_DIR=
 201 AC_ARG_WITH([crt-dir],dnl
 202 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 203 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 204 CRT_DIR="${with_crt_dir}"
 205
 206 AC_ARG_WITH([gnustep-conf],dnl
 207 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 208 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 209   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 210 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 211      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 212
 213 AC_ARG_ENABLE(ns-self-contained,
 214 [AS_HELP_STRING([--disable-ns-self-contained],
 215                 [disable self contained build under NeXTstep])],
 216    EN_NS_SELF_CONTAINED=$enableval,
 217    EN_NS_SELF_CONTAINED=yes)
 218
 219 AC_ARG_ENABLE(asserts,
 220 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 221       USE_XASSERTS=$enableval,
 222       USE_XASSERTS=no)
 223
 224 AC_ARG_ENABLE(maintainer-mode,
 225 [AS_HELP_STRING([--enable-maintainer-mode],
 226                 [enable make rules and dependencies not useful (and sometimes
 227                  confusing) to the casual installer])],
 228       USE_MAINTAINER_MODE=$enableval,
 229       USE_MAINTAINER_MODE=no)
 230 if test $USE_MAINTAINER_MODE = yes; then
 231   MAINT=
 232 else
 233   MAINT=#
 234 fi
 235 AC_SUBST(MAINT)
 236
 237 AC_ARG_ENABLE(locallisppath,
 238 [AS_HELP_STRING([--enable-locallisppath=PATH],
 239                 [directories Emacs should search for lisp files specific
 240                  to this site])],
 241 if test "${enableval}" = "no"; then
 242   locallisppath=
 243 elif test "${enableval}" != "yes"; then
 244   locallisppath=${enableval}
 245 fi)
 246
 247 AC_ARG_ENABLE(checking,
 248 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 249                 [enable expensive run-time checks.  With LIST,
 250                  enable only specific categories of checks.
 251                  Categories are: all,yes,no.
 252                  Flags are: stringbytes, stringoverrun, stringfreelist,
 253                  xmallocoverrun, conslist])],
 254 [ac_checking_flags="${enableval}"],[])
 255 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 256 for check in $ac_checking_flags
 257 do
 258         case $check in
 259         # these set all the flags to specific states
 260         yes)            ac_enable_checking=1 ;;
 261         no)             ac_enable_checking= ;
 262                         ac_gc_check_stringbytes= ;
 263                         ac_gc_check_string_overrun= ;
 264                         ac_gc_check_string_free_list= ;
 265                         ac_xmalloc_overrun= ;
 266                         ac_gc_check_cons_list= ;;
 267         all)            ac_enable_checking=1 ;
 268                         ac_gc_check_stringbytes=1 ;
 269                         ac_gc_check_string_overrun=1 ;
 270                         ac_gc_check_string_free_list=1 ;
 271                         ac_xmalloc_overrun=1 ;
 272                         ac_gc_check_cons_list=1 ;;
 273         # these enable particular checks
 274         stringbytes)    ac_gc_check_stringbytes=1 ;;
 275         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 276         stringfreelist) ac_gc_check_string_free_list=1 ;;
 277         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 278         conslist)       ac_gc_check_cons_list=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Enable expensive run-time checking of data types?])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_stringoverrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310
 311 AC_ARG_ENABLE(use-lisp-union-type,
 312 [AS_HELP_STRING([--enable-use-lisp-union-type],
 313                 [use a union for the Lisp_Object data type.
 314                 This is only useful for development for catching certain types of bugs.])],
 315 if test "${enableval}" != "no"; then
 316    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 317    [Define this to use a lisp union for the Lisp_Object data type.])
 318 fi)
 319
 320
 321 AC_ARG_ENABLE(profiling,
 322 [AS_HELP_STRING([--enable-profiling],
 323                 [build emacs with profiling support.
 324                  This might not work on all platforms])],
 325 [ac_enable_profiling="${enableval}"],[])
 326 if test x$ac_enable_profiling != x ; then
 327    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 328    PROFILING_LDFLAGS="-pg"
 329 else
 330    PROFILING_CFLAGS=
 331    PROFILING_LDFLAGS=
 332 fi
 333 AC_SUBST(PROFILING_CFLAGS)
 334 AC_SUBST(PROFILING_LDFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Check if the source directory already has a configured system in it.
 368 if test `pwd` != `(cd ${srcdir} && pwd)` \
 369    && test -f "${srcdir}/src/config.h" ; then
 370   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 371    as a build directory right now; it has been configured in its own
 372    right.  To configure in another directory as well, you MUST
 373    use GNU make.  If you do not have GNU make, then you must
 374    now do `make distclean' in ${srcdir},
 375    and then run $0 again.]])
 376 fi
 377
 378 #### Given the configuration name, set machfile and opsysfile to the
 379 #### names of the m/*.h and s/*.h files we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system and machine description files.
 400
 401 ### You would hope that you could choose an m/*.h file pretty much
 402 ### based on the machine portion of the configuration name, and an s/*.h
 403 ### file based on the operating system portion.  However, it turns out
 404 ### that each m/*.h file is pretty manufacturer-specific - for
 405 ### example mips.h is MIPS
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 machine='' opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## FreeBSD ports
 419   *-*-freebsd* )
 420     opsys=freebsd
 421     case "${canonical}" in
 422       alpha*)           machine=alpha ;;
 423       amd64-*|x86_64-*) machine=amdx86-64 ;;
 424       arm*)             machine=arm ;;
 425       ia64-*)           machine=ia64 ;;
 426       i[3456]86-*)      machine=intel386 ;;
 427       powerpc-*)        machine=macppc ;;
 428       sparc-*)          machine=sparc ;;
 429       sparc64-*)        machine=sparc ;;
 430     esac
 431   ;;
 432
 433   ## FreeBSD kernel + glibc based userland
 434   *-*-kfreebsd*gnu* )
 435     opsys=gnu-kfreebsd
 436     case "${canonical}" in
 437       alpha*)           machine=alpha ;;
 438       amd64-*|x86_64-*) machine=amdx86-64 ;;
 439       ia64-*)           machine=ia64 ;;
 440       i[3456]86-*)      machine=intel386 ;;
 441       powerpc-*)        machine=macppc ;;
 442       sparc-*)          machine=sparc ;;
 443       sparc64-*)        machine=sparc ;;
 444     esac
 445   ;;
 446
 447   ## NetBSD ports
 448   *-*-netbsd* )
 449     opsys=netbsd
 450     case "${canonical}" in
 451       alpha*)      machine=alpha ;;
 452       x86_64-*)    machine=amdx86-64 ;;
 453       arm-*)       machine=arm ;;
 454       hppa-*)      machine=hp800 ;;
 455       i[3456]86-*) machine=intel386 ;;
 456       m68k-*)      machine=m68k ;;
 457       powerpc-*)   machine=macppc ;;
 458       mips-*)      machine=mips ;;
 459       mipse[bl]-*) machine=mips ;;
 460       sparc*-)     machine=sparc ;;
 461       vax-*)       machine=vax ;;
 462     esac
 463   ;;
 464
 465   ## OpenBSD ports
 466   *-*-openbsd* )
 467     opsys=openbsd
 468     case "${canonical}" in
 469       alpha*)    machine=alpha ;;
 470       x86_64-*)  machine=amdx86-64 ;;
 471       arm-*)     machine=arm ;;
 472       hppa-*)    machine=hp800 ;;
 473       i386-*)    machine=intel386 ;;
 474       powerpc-*) machine=macppc ;;
 475       sparc*)    machine=sparc ;;
 476       vax-*)     machine=vax ;;
 477     esac
 478   ;;
 479
 480   alpha*-*-linux-gnu* )
 481     machine=alpha opsys=gnu-linux
 482   ;;
 483
 484   arm*-*-linux-gnu* )
 485     machine=arm opsys=gnu-linux
 486   ;;
 487
 488   ## Apple Darwin / Mac OS X
 489   *-apple-darwin* )
 490     case "${canonical}" in
 491       i[3456]86-* )  machine=intel386 ;;
 492       powerpc-* )    machine=macppc ;;
 493       x86_64-* )     machine=amdx86-64 ;;
 494       * )            unported=yes ;;
 495     esac
 496     opsys=darwin
 497     # Define CPP as follows to make autoconf work correctly.
 498     CPP="${CC-cc} -E -no-cpp-precomp"
 499     # Use fink packages if available.
 500     if test -d /sw/include && test -d /sw/lib; then
 501       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 502       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 503       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 504     fi
 505   ;;
 506
 507   ## HP 9000 series 700 and 800, running HP/UX
 508   hppa*-hp-hpux10.2* )
 509     machine=hp800 opsys=hpux10-20
 510   ;;
 511   hppa*-hp-hpux1[1-9]* )
 512     machine=hp800 opsys=hpux11
 513     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 514   ;;
 515
 516   hppa*-*-linux-gnu* )
 517     machine=hp800 opsys=gnu-linux
 518   ;;
 519
 520   ## IBM machines
 521   s390-*-linux-gnu* )
 522     machine=ibms390 opsys=gnu-linux
 523   ;;
 524   s390x-*-linux-gnu* )
 525     machine=ibms390x opsys=gnu-linux
 526   ;;
 527   rs6000-ibm-aix4.[23]* )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530   powerpc-ibm-aix4.[23]*  )
 531     machine=ibmrs6000 opsys=aix4-2
 532   ;;
 533   rs6000-ibm-aix[56]* )
 534     machine=ibmrs6000 opsys=aix4-2
 535   ;;
 536   powerpc-ibm-aix[56]*  )
 537     machine=ibmrs6000 opsys=aix4-2
 538   ;;
 539
 540   ## Macintosh PowerPC
 541   powerpc*-*-linux-gnu* )
 542     machine=macppc opsys=gnu-linux
 543   ;;
 544
 545   ## Silicon Graphics machines
 546   ## Iris 4D
 547   mips-sgi-irix6.5 )
 548     machine=iris4d opsys=irix6-5
 549     # Without defining _LANGUAGE_C, things get masked out in the headers
 550     # so that, for instance, grepping for `free' in stdlib.h fails and
 551     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 552     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 553     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 554   ;;
 555
 556   ## Suns
 557   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 558     machine=sparc opsys=gnu-linux
 559   ;;
 560
 561   *-sun-solaris* \
 562     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 563     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 564     case "${canonical}" in
 565       i[3456]86-*-* )     machine=intel386 ;;
 566       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 567       sparc* )          machine=sparc ;;
 568       * )               unported=yes ;;
 569     esac
 570     case "${canonical}" in
 571       *-sunos5.6* | *-solaris2.6* )
 572                 opsys=sol2-6
 573                 NON_GNU_CPP=/usr/ccs/lib/cpp
 574                 RANLIB="ar -ts"
 575                 ;;
 576       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 577                 opsys=sol2-6
 578                 emacs_check_sunpro_c=yes
 579                 NON_GNU_CPP=/usr/ccs/lib/cpp
 580                 ;;
 581       *-sunos5* | *-solaris* )
 582                 opsys=sol2-10
 583                 emacs_check_sunpro_c=yes
 584                 NON_GNU_CPP=/usr/ccs/lib/cpp
 585                 ;;
 586     esac
 587     ## Watch out for a compiler that we know will not work.
 588     case "${canonical}" in
 589      *-solaris* | *-sunos5* )
 590                 if [ "x$CC" = x/usr/ucb/cc ]; then
 591                   ## /usr/ucb/cc doesn't work;
 592                   ## we should find some other compiler that does work.
 593                   unset CC
 594                 fi
 595                 ;;
 596       *) ;;
 597     esac
 598   ;;
 599
 600   ## IA-64
 601   ia64*-*-linux* )
 602     machine=ia64 opsys=gnu-linux
 603   ;;
 604
 605   ## Intel 386 machines where we don't care about the manufacturer.
 606   i[3456]86-*-* )
 607     machine=intel386
 608     case "${canonical}" in
 609       *-cygwin )                opsys=cygwin ;;
 610       *-darwin* )               opsys=darwin
 611                                 CPP="${CC-cc} -E -no-cpp-precomp"
 612                                 ;;
 613       *-linux-gnu* )            opsys=gnu-linux ;;
 614       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 615       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 616       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 617       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 618     esac
 619   ;;
 620
 621   ## m68k Linux-based GNU system
 622   m68k-*-linux-gnu* )
 623     machine=m68k opsys=gnu-linux
 624   ;;
 625
 626   ## Mips Linux-based GNU system
 627   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 628     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 629     machine=mips opsys=gnu-linux
 630   ;;
 631
 632   ## AMD x86-64 Linux-based GNU system
 633   x86_64-*-linux-gnu* )
 634     machine=amdx86-64 opsys=gnu-linux
 635   ;;
 636
 637   ## Tensilica Xtensa Linux-based GNU system
 638   xtensa*-*-linux-gnu* )
 639     machine=xtensa opsys=gnu-linux
 640     ;;
 641
 642   ## SuperH Linux-based GNU system
 643   sh[34]*-*-linux-gnu* )
 644     machine=sh3 opsys=gnu-linux
 645   ;;
 646
 647   * )
 648     unported=yes
 649   ;;
 650 esac
 651
 652 ### If the code above didn't choose an operating system, just choose
 653 ### an operating system based on the configuration name.  You really
 654 ### only want to use this when you have no idea what the right
 655 ### operating system is; if you know what operating systems a machine
 656 ### runs, it's cleaner to make it explicit in the case statement
 657 ### above.
 658 if test x"${opsys}" = x; then
 659   case "${canonical}" in
 660     *-gnu* )                            opsys=gnu ;;
 661     * )
 662       unported=yes
 663     ;;
 664   esac
 665 fi
 666
 667 ]
 668 dnl quotation ends
 669
 670 if test $unported = yes; then
 671   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 672 Check `etc/MACHINES' for recognized configuration names.])
 673 fi
 674
 675 machfile="m/${machine}.h"
 676 opsysfile="s/${opsys}.h"
 677
 678
 679 #### Choose a compiler.
 680 test -n "$CC" && cc_specified=yes
 681
 682 # Save the value of CFLAGS that the user specified.
 683 SPECIFIED_CFLAGS="$CFLAGS"
 684
 685 dnl Sets GCC=yes if using gcc.
 686 AC_PROG_CC
 687
 688 # On Suns, sometimes $CPP names a directory.
 689 if test -n "$CPP" && test -d "$CPP"; then
 690   CPP=
 691 fi
 692
 693 ## If not using gcc, and on Solaris, and no CPP specified, see if
 694 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 695 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 696  test x"$CPP" = x; then
 697   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 698   AC_CACHE_VAL(emacs_cv_sunpro_c,
 699   [AC_TRY_LINK([],
 700 [#ifndef __SUNPRO_C
 701 fail;
 702 #endif
 703 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 704   AC_MSG_RESULT($emacs_cv_sunpro_c)
 705
 706   if test x"$emacs_cv_sunpro_c" = xyes; then
 707     NON_GNU_CPP="$CC -E -Xs"
 708   fi
 709 fi
 710
 711 #### Some systems specify a CPP to use unless we are using GCC.
 712 #### Now that we know whether we are using GCC, we can decide whether
 713 #### to use that one.
 714 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 715 then
 716   CPP="$NON_GNU_CPP"
 717 fi
 718
 719 #### Some systems specify a CC to use unless we are using GCC.
 720 #### Now that we know whether we are using GCC, we can decide whether
 721 #### to use that one.
 722 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 723   test x$cc_specified != xyes
 724 then
 725   CC="$NON_GNU_CC"
 726 fi
 727
 728 if test x$GCC = xyes; then
 729   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 730 else
 731   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 732 fi
 733
 734 dnl checks for Unix variants
 735 AC_USE_SYSTEM_EXTENSIONS
 736
 737 ### Use -Wno-pointer-sign if the compiler supports it
 738 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 739 SAVE_CFLAGS="$CFLAGS"
 740 CFLAGS="$CFLAGS -Wno-pointer-sign"
 741 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 742 if test $has_option = yes; then
 743    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 744 fi
 745 AC_MSG_RESULT($has_option)
 746 CFLAGS="$SAVE_CFLAGS"
 747 unset has_option
 748 unset SAVE_CFLAGS
 749
 750 ### Use -Wdeclaration-after-statement if the compiler supports it
 751 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 752 SAVE_CFLAGS="$CFLAGS"
 753 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 754 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 755 if test $has_option = yes; then
 756    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 757 fi
 758 AC_MSG_RESULT($has_option)
 759 CFLAGS="$SAVE_CFLAGS"
 760 unset has_option
 761 unset SAVE_CFLAGS
 762
 763 ### Use -Wold-style-definition if the compiler supports it
 764 # This can be removed when conversion to standard C is finished.
 765 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 766 SAVE_CFLAGS="$CFLAGS"
 767 CFLAGS="$CFLAGS -Wold-style-definition"
 768 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 769 if test $has_option = yes; then
 770    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 771 fi
 772 AC_MSG_RESULT($has_option)
 773 CFLAGS="$SAVE_CFLAGS"
 774 unset has_option
 775 unset SAVE_CFLAGS
 776
 777 ### Use -Wimplicit-function-declaration if the compiler supports it
 778 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 779 SAVE_CFLAGS="$CFLAGS"
 780 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 781 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 782 if test $has_option = yes; then
 783    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 784 fi
 785 AC_MSG_RESULT($has_option)
 786 CFLAGS="$SAVE_CFLAGS"
 787 unset has_option
 788 unset SAVE_CFLAGS
 789
 790 AC_SUBST(C_WARNINGS_SWITCH)
 791
 792
 793 #### Some other nice autoconf tests.
 794
 795 dnl checks for programs
 796 AC_PROG_CPP
 797 AC_PROG_INSTALL
 798 if test "x$RANLIB" = x; then
 799   AC_PROG_RANLIB
 800 fi
 801
 802 ## Although we're running on an amd64 kernel, we're actually compiling for
 803 ## the x86 architecture.  The user should probably have provided an
 804 ## explicit --build to `configure', but if everything else than the kernel
 805 ## is running in i386 mode, we can help them out.
 806 if test "$machine" = "amdx86-64"; then
 807   AC_CHECK_DECL([i386])
 808   if test "$ac_cv_have_decl_i386" = "yes"; then
 809     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 810     machine=intel386
 811     machfile="m/${machine}.h"
 812   fi
 813 fi
 814
 815 AC_PATH_PROG(INSTALL_INFO, install-info)
 816 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 817 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 818 dnl Don't use GZIP, which is used by gzip for additional parameters.
 819 AC_PATH_PROG(GZIP_PROG, gzip)
 820
 821
 822 ## Need makeinfo >= 4.6 (?) to build the manuals.
 823 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 824 dnl By this stage, configure has already checked for egrep and set EGREP,
 825 dnl or exited with an error if no egrep was found.
 826 if test "$MAKEINFO" != "no" && \
 827   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 828    MAKEINFO=no
 829 fi
 830
 831 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 832 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 833 ## therefore in the category of "special tools" not normally required, which
 834 ## configure does not have to check for (eg autoconf itself).
 835 ## In a Bazaar checkout on the other hand, the manuals are not included.
 836 ## So makeinfo is a requirement to build from Bazaar, and configure
 837 ## should test for it as it does for any other build requirement.
 838 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 839 ## with pre-built manuals, from a Bazaar checkout.
 840 if test "$MAKEINFO" = "no"; then
 841   if test "x${with_makeinfo}" = "xno"; then
 842     MAKEINFO=off
 843   elif test ! -e $srcdir/info/emacs; then
 844     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 845 source tree does not seem to have pre-built manuals in the `info' directory.
 846 Either install a suitable version of makeinfo, or re-run configure
 847 with the `--without-makeinfo' option to build without the manuals.] )
 848   fi
 849 fi
 850
 851 dnl Add our options to ac_link now, after it is set up.
 852
 853 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 854 then
 855   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 856 fi
 857
 858 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 859 then
 860   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 861 fi
 862
 863 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 864 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 865 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 866 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 867 dnl if not built to support GNU ld.
 868
 869 late_LDFLAGS=$LDFLAGS
 870 if test "$GCC" = yes; then
 871   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 872 else
 873   LDFLAGS="$LDFLAGS -znocombreloc"
 874 fi
 875
 876 AC_MSG_CHECKING([for -znocombreloc])
 877 AC_LINK_IFELSE([main(){return 0;}],
 878   [AC_MSG_RESULT(yes)],
 879   LDFLAGS=$late_LDFLAGS
 880   [AC_MSG_RESULT(no)])
 881
 882
 883 # The value of CPP is a quoted variable reference, so we need to do this
 884 # to get its actual value...
 885 CPP=`eval "echo $CPP"`
 886
 887
 888 dnl Not used by any currently supported platform.
 889 dnl The function dump-emacs will not be defined and temacs will do
 890 dnl (load "loadup") automatically unless told otherwise.
 891 CANNOT_DUMP=no
 892 case "$opsys" in
 893   your-opsys-here)
 894    CANNOT_DUMP=yes
 895    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 896   ;;
 897 esac
 898 AC_SUBST(CANNOT_DUMP)
 899
 900
 901 UNEXEC_OBJ=unexelf.o
 902 case "$opsys" in
 903   # MSDOS uses unexcoff.o
 904   # MSWindows uses unexw32.o
 905   aix4-2)
 906    UNEXEC_OBJ=unexaix.o
 907    ;;
 908   cygwin)
 909    UNEXEC_OBJ=unexcw.o
 910    ;;
 911   darwin)
 912    UNEXEC_OBJ=unexmacosx.o
 913    ;;
 914   hpux10-20 | hpux11)
 915    UNEXEC_OBJ=unexhp9k800.o
 916    ;;
 917   sol2-10)
 918    # Use the Solaris dldump() function, called from unexsol.c, to dump
 919    # emacs, instead of the generic ELF dump code found in unexelf.c.
 920    # The resulting binary has a complete symbol table, and is better
 921    # for debugging and other observability tools (debuggers, pstack, etc).
 922    #
 923    # If you encounter a problem using dldump(), please consider sending
 924    # a message to the OpenSolaris tools-linking mailing list:
 925    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 926    #
 927    # It is likely that dldump() works with older Solaris too, but this has
 928    # not been tested, so for now this change is for Solaris 10 or newer.
 929    UNEXEC_OBJ=unexsol.o
 930    ;;
 931 esac
 932
 933 LD_SWITCH_SYSTEM=
 934 case "$opsys" in
 935   freebsd)
 936    ## Let `ld' find image libs and similar things in /usr/local/lib.
 937    ## The system compiler, GCC, has apparently been modified to not
 938    ## look there, contrary to what a stock GCC would do.
 939    LD_SWITCH_SYSTEM=-L/usr/local/lib
 940    ;;
 941
 942   gnu-linux)
 943    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 944    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 945    ;;
 946
 947   netbsd)
 948    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 949    ;;
 950
 951   openbsd)
 952    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 953    ## otherwise Emacs dumps core on elf systems.
 954    LD_SWITCH_SYSTEM="-Z"
 955    ;;
 956 esac
 957 AC_SUBST(LD_SWITCH_SYSTEM)
 958
 959 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 960
 961 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 962 ## which has not been defined yet.  When this was handled with cpp,
 963 ## it was expanded to null when configure sourced the s/*.h file.
 964 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 965 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 966 ## (or somesuch), but because it is supposed to go at the _front_
 967 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 968 ## Compare with the gnu-linux case below, which added to the end
 969 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 970 ## LD_SWITCH_SYSTEM_TEMACS.
 971 case "$opsys" in
 972   netbsd|openbsd)
 973    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 974    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 975 esac
 976
 977
 978 C_SWITCH_MACHINE=
 979 if test "$machine" = "alpha"; then
 980   AC_CHECK_DECL([__ELF__])
 981   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 982     ## With ELF, make sure that all common symbols get allocated to in the
 983     ## data section.  Otherwise, the dump of temacs may miss variables in
 984     ## the shared library that have been initialized.  For example, with
 985     ## GNU libc, __malloc_initialized would normally be resolved to the
 986     ## shared library's .bss section, which is fatal.
 987     if test "x$GCC" = "xyes"; then
 988       C_SWITCH_MACHINE="-fno-common"
 989     else
 990       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 991     fi
 992   else
 993     UNEXEC_OBJ=unexalpha.o
 994   fi
 995 fi
 996 AC_SUBST(C_SWITCH_MACHINE)
 997
 998 AC_SUBST(UNEXEC_OBJ)
 999
1000 C_SWITCH_SYSTEM=
1001 ## Some programs in src produce warnings saying certain subprograms
1002 ## are too complex and need a MAXMEM value greater than 2000 for
1003 ## additional optimization.  --nils@exp-math.uni-essen.de
1004 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1005   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1006 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1007 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1008 AC_SUBST(C_SWITCH_SYSTEM)
1009
1010
1011 LIBS_SYSTEM=
1012 case "$opsys" in
1013   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1014   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1015
1016   freebsd) LIBS_SYSTEM="-lutil" ;;
1017
1018   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1019
1020   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1021
1022   ## Motif needs -lgen.
1023   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1024 esac
1025 AC_SUBST(LIBS_SYSTEM)
1026
1027
1028 ### Make sure subsequent tests use flags consistent with the build flags.
1029
1030 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1031   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1032 else
1033   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1034 fi
1035
1036 dnl For AC_FUNC_GETLOADAVG, at least:
1037 AC_CONFIG_LIBOBJ_DIR(src)
1038
1039 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1040 AC_SYS_LARGEFILE
1041
1042
1043 ## If user specified a crt-dir, use that unconditionally.
1044 if test "X$CRT_DIR" = "X"; then
1045
1046   case "$canonical" in
1047     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1048     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1049     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1050     ## For anything else (eg /usr/lib32), it is up the user to specify
1051     ## the location (bug#5655).
1052     ## Test for crtn.o, not just the directory, because sometimes the
1053     ## directory exists but does not have the relevant files (bug#1287).
1054     ## FIXME better to test for binary compatibility somehow.
1055     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1056     ;;
1057
1058     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1059   esac
1060
1061   case "$opsys" in
1062     hpux10-20) CRT_DIR=/lib ;;
1063   esac
1064
1065   ## Default is /usr/lib.
1066   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1067
1068 else
1069
1070   ## Some platforms don't use any of these files, so it is not
1071   ## appropriate to put this test outside the if block.
1072   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1073     AC_MSG_ERROR([crt*.o not found in specified location.])
1074
1075 fi
1076
1077 AC_SUBST(CRT_DIR)
1078
1079 LIB_MATH=-lm
1080 LIB_STANDARD=
1081 START_FILES=
1082
1083 case $opsys in
1084   cygwin )
1085     LIB_MATH=
1086     START_FILES='pre-crt0.o'
1087     ;;
1088   darwin )
1089     ## Adding -lm confuses the dynamic linker, so omit it.
1090     LIB_MATH=
1091     START_FILES='pre-crt0.o'
1092     ;;
1093   freebsd )
1094     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1095     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1096     ;;
1097   gnu-linux | gnu-kfreebsd )
1098     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1099     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1100     ;;
1101   hpux10-20 | hpux11 )
1102     LIB_STANDARD=-lc
1103     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1104     ;;
1105   netbsd | openbsd )
1106     if test -f $CRT_DIR/crti.o; then
1107         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1108         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1109     else
1110         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1111         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1112     fi
1113     ;;
1114 esac
1115
1116 AC_SUBST(LIB_MATH)
1117 AC_SUBST(START_FILES)
1118
1119 dnl This function definition taken from Gnome 2.0
1120 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1121 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1122 dnl also defines GSTUFF_PKG_ERRORS on error
1123 AC_DEFUN([PKG_CHECK_MODULES], [
1124   succeeded=no
1125
1126   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1127
1128   if test "$PKG_CONFIG" = "no" ; then
1129      ifelse([$4], , [AC_MSG_ERROR([
1130       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1131   else
1132      PKG_CONFIG_MIN_VERSION=0.9.0
1133      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1134         AC_MSG_CHECKING(for $2)
1135
1136         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1137             AC_MSG_RESULT(yes)
1138             succeeded=yes
1139
1140             AC_MSG_CHECKING($1_CFLAGS)
1141             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1142             AC_MSG_RESULT($$1_CFLAGS)
1143
1144             AC_MSG_CHECKING($1_LIBS)
1145             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1146             AC_MSG_RESULT($$1_LIBS)
1147         else
1148             AC_MSG_RESULT(no)
1149             $1_CFLAGS=""
1150             $1_LIBS=""
1151             ## If we have a custom action on failure, don't print errors, but
1152             ## do set a variable so people can do so.
1153             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1154             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1155         fi
1156
1157         AC_SUBST($1_CFLAGS)
1158         AC_SUBST($1_LIBS)
1159      else
1160         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1161         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1162      fi
1163   fi
1164
1165   if test $succeeded = yes; then
1166      ifelse([$3], , :, [$3])
1167   else
1168      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1169   fi
1170 ])
1171
1172
1173 if test "${with_sound}" != "no"; then
1174   # Sound support for GNU/Linux and the free BSDs.
1175   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1176     have_sound_header=yes)
1177   # Emulation library used on NetBSD.
1178   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1179   AC_SUBST(LIBSOUND)
1180
1181   ALSA_REQUIRED=1.0.0
1182   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1183   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1184   if test $HAVE_ALSA = yes; then
1185     SAVE_CFLAGS="$CFLAGS"
1186     SAVE_LDFLAGS="$LDFLAGS"
1187     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1188     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1189     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1190                     emacs_alsa_normal=yes,
1191                     emacs_alsa_normal=no)
1192     if test "$emacs_alsa_normal" != yes; then
1193       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1194                      [snd_lib_error_set_handler (0);],
1195                      emacs_alsa_subdir=yes,
1196                      emacs_alsa_subdir=no)
1197       if test "$emacs_alsa_subdir" != yes; then
1198         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1199       fi
1200       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1201     fi
1202
1203     CFLAGS="$SAVE_CFLAGS"
1204     LDFLAGS="$SAVE_LDFLAGS"
1205     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1206     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1207     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1208   fi
1209
1210   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1211   dnl compiles only on the specified platforms.  For others, it
1212   dnl probably doesn't make sense to try.
1213   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1214      case "$opsys" in
1215        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1216        gnu-linux|freebsd|netbsd)
1217          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1218          ;;
1219      esac
1220   fi
1221
1222   AC_SUBST(CFLAGS_SOUND)
1223 fi
1224
1225 dnl checks for header files
1226 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1227   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1228   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1229   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1230   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1231
1232 AC_MSG_CHECKING(if personality LINUX32 can be set)
1233 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1234                emacs_cv_personality_linux32=yes,
1235                emacs_cv_personality_linux32=no)
1236 AC_MSG_RESULT($emacs_cv_personality_linux32)
1237
1238 if test $emacs_cv_personality_linux32 = yes; then
1239   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1240             [Define to 1 if personality LINUX32 can be set.])
1241 fi
1242
1243 dnl On Solaris 8 there's a compilation warning for term.h because
1244 dnl it doesn't define `bool'.
1245 AC_CHECK_HEADERS(term.h, , , -)
1246 AC_HEADER_STDC
1247 AC_HEADER_TIME
1248 AC_CHECK_DECLS([sys_siglist])
1249 if test $ac_cv_have_decl_sys_siglist != yes; then
1250   # For Tru64, at least:
1251   AC_CHECK_DECLS([__sys_siglist])
1252   if test $ac_cv_have_decl___sys_siglist = yes; then
1253     AC_DEFINE(sys_siglist, __sys_siglist,
1254               [Define to any substitute for sys_siglist.])
1255   fi
1256 fi
1257 AC_HEADER_SYS_WAIT
1258
1259 dnl Some systems have utime.h but don't declare the struct anyplace.
1260 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1261 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1262 #include <sys/time.h>
1263 #include <time.h>
1264 #else
1265 #ifdef HAVE_SYS_TIME_H
1266 #include <sys/time.h>
1267 #else
1268 #include <time.h>
1269 #endif
1270 #endif
1271 #ifdef HAVE_UTIME_H
1272 #include <utime.h>
1273 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1274   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1275 if test $emacs_cv_struct_utimbuf = yes; then
1276   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1277 fi
1278
1279 dnl checks for typedefs
1280 AC_TYPE_SIGNAL
1281
1282 dnl Check for speed_t typedef.
1283 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1284   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1285     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1286 if test $emacs_cv_speed_t = yes; then
1287   AC_DEFINE(HAVE_SPEED_T, 1,
1288            [Define to 1 if `speed_t' is declared by <termios.h>.])
1289 fi
1290
1291 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1292 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1293 #include <sys/time.h>
1294 #include <time.h>
1295 #else
1296 #ifdef HAVE_SYS_TIME_H
1297 #include <sys/time.h>
1298 #else
1299 #include <time.h>
1300 #endif
1301 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1302   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1303 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1304 if test $emacs_cv_struct_timeval = yes; then
1305   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1306 fi
1307
1308 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1309 AC_TRY_COMPILE([#include <math.h>],
1310 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1311   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1312 HAVE_EXCEPTION=$emacs_cv_struct_exception
1313 if test $emacs_cv_struct_exception != yes; then
1314   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1315 fi
1316
1317 AC_CHECK_HEADERS(sys/socket.h)
1318 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1319 #if HAVE_SYS_SOCKET_H
1320 #include <sys/socket.h>
1321 #endif])
1322
1323 dnl checks for structure members
1324 AC_STRUCT_TM
1325 AC_STRUCT_TIMEZONE
1326 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1327                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1328                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1329                 [#include <time.h>])
1330 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1331                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1332                   struct ifreq.ifr_addr], , ,
1333                  [AC_INCLUDES_DEFAULT
1334 #if HAVE_SYS_SOCKET_H
1335 #include <sys/socket.h>
1336 #endif
1337 #if HAVE_NET_IF_H
1338 #include <net/if.h>
1339 #endif])
1340
1341 dnl checks for compiler characteristics
1342
1343 dnl Testing __STDC__ to determine prototype support isn't good enough.
1344 dnl DEC C, for instance, doesn't define it with default options, and
1345 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1346 dnl and void *.
1347 AC_C_PROTOTYPES
1348 AC_C_VOLATILE
1349 AC_C_CONST
1350 dnl This isn't useful because we can't turn on use of `inline' unless
1351 dnl the compiler groks `extern inline'.
1352 dnl AC_C_INLINE
1353 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1354   [AC_TRY_COMPILE(, [void * foo;],
1355                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1356 if test $emacs_cv_void_star = yes; then
1357   AC_DEFINE(POINTER_TYPE, void)
1358 else
1359   AC_DEFINE(POINTER_TYPE, char)
1360 fi
1361 AH_TEMPLATE(POINTER_TYPE,
1362             [Define as `void' if your compiler accepts `void *'; otherwise
1363              define as `char'.])dnl
1364
1365 dnl Check for endianess
1366 AC_C_BIGENDIAN
1367
1368 dnl check for Make feature
1369 AC_PROG_MAKE_SET
1370
1371 DEPFLAGS=
1372 MKDEPDIR=":"
1373 deps_frag=deps.mk
1374 dnl check for GNU Make if we have GCC and autodepend is on.
1375 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1376    AC_MSG_CHECKING([whether we are using GNU Make])
1377    HAVE_GNU_MAKE=no
1378    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1379    if test "x$testval" != x; then
1380       HAVE_GNU_MAKE=yes
1381    else
1382       ac_enable_autodepend=no
1383    fi
1384    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1385    if test $HAVE_GNU_MAKE = yes; then
1386       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1387       SAVE_CFLAGS="$CFLAGS"
1388       CFLAGS="$CFLAGS -MMD -MF deps.d"
1389       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1390       CFLAGS="$SAVE_CFLAGS"
1391       test -f deps.d || ac_enable_autodepend=no
1392       rm -rf deps.d
1393       AC_MSG_RESULT([$ac_enable_autodepend])
1394    fi
1395    if test $ac_enable_autodepend = yes; then
1396       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1397       ## In parallel builds, another make might create depdir between
1398       ## the first test and mkdir, so stick another test on the end.
1399       ## Or use mkinstalldirs?  mkdir -p is not portable.
1400       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1401       deps_frag=autodeps.mk
1402    fi
1403 fi
1404 deps_frag=$srcdir/src/$deps_frag
1405 AC_SUBST(MKDEPDIR)
1406 AC_SUBST(DEPFLAGS)
1407 AC_SUBST_FILE(deps_frag)
1408
1409
1410 dnl checks for operating system services
1411 AC_SYS_LONG_FILE_NAMES
1412
1413 #### Choose a window system.
1414
1415 AC_PATH_X
1416 if test "$no_x" = yes; then
1417   window_system=none
1418 else
1419   window_system=x11
1420 fi
1421
1422 ## Workaround for bug in autoconf <= 2.62.
1423 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1424 ## No need to do anything special for these standard directories.
1425 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1426
1427    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1428
1429 fi
1430
1431 LD_SWITCH_X_SITE_AUX=
1432 LD_SWITCH_X_SITE_AUX_RPATH=
1433 if test "${x_libraries}" != NONE; then
1434   if test -n "${x_libraries}"; then
1435     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1436     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1437     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1438   fi
1439   x_default_search_path=""
1440   x_search_path=${x_libraries}
1441   if test -z "${x_search_path}"; then
1442     x_search_path=/usr/lib
1443   fi
1444   for x_library in `echo ${x_search_path}: | \
1445                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1446     x_search_path="\
1447 ${x_library}/X11/%L/%T/%N%C%S:\
1448 ${x_library}/X11/%l/%T/%N%C%S:\
1449 ${x_library}/X11/%T/%N%C%S:\
1450 ${x_library}/X11/%L/%T/%N%S:\
1451 ${x_library}/X11/%l/%T/%N%S:\
1452 ${x_library}/X11/%T/%N%S"
1453     if test x"${x_default_search_path}" = x; then
1454       x_default_search_path=${x_search_path}
1455     else
1456       x_default_search_path="${x_search_path}:${x_default_search_path}"
1457     fi
1458   done
1459 fi
1460 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1461 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1462
1463 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1464   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1465 fi
1466
1467 if test x"${x_includes}" = x; then
1468   bitmapdir=/usr/include/X11/bitmaps
1469 else
1470   # accumulate include directories that have X11 bitmap subdirectories
1471   bmd_acc="dummyval"
1472   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1473     if test -d "${bmd}/X11/bitmaps"; then
1474       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1475     fi
1476     if test -d "${bmd}/bitmaps"; then
1477       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1478     fi
1479   done
1480   if test ${bmd_acc} != "dummyval"; then
1481     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1482   fi
1483 fi
1484
1485 HAVE_NS=no
1486 NS_IMPL_COCOA=no
1487 NS_IMPL_GNUSTEP=no
1488 tmp_CPPFLAGS="$CPPFLAGS"
1489 tmp_CFLAGS="$CFLAGS"
1490 CPPFLAGS="$CPPFLAGS -x objective-c"
1491 CFLAGS="$CFLAGS -x objective-c"
1492 TEMACS_LDFLAGS2="\${LDFLAGS} \${PROFILING_LDFLAGS}"
1493 dnl I don't think it's especially important, but src/Makefile.in
1494 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1495 dnl trailing "/" to it, so now we do it here.
1496 if test "${with_ns}" != no; then
1497   if test "${opsys}" = darwin; then
1498      NS_IMPL_COCOA=yes
1499      ns_appdir=`pwd`/nextstep/Emacs.app/
1500      ns_appbindir=${ns_appdir}Contents/MacOS/
1501      ns_appresdir=${ns_appdir}Contents/Resources
1502      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1503   elif test -f $GNUSTEP_CONFIG_FILE; then
1504      NS_IMPL_GNUSTEP=yes
1505      ns_appdir=`pwd`/nextstep/Emacs.app/
1506      ns_appbindir=${ns_appdir}
1507      ns_appresdir=${ns_appdir}Resources
1508      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1509      dnl FIXME sourcing this several times in subshells seems inefficient.
1510      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1511      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1512      dnl I seemed to need these as well with GNUstep-startup 0.25.
1513      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1514      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1515      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1516        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1517      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1518        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1519      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1520      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1521      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1522      LIB_STANDARD=
1523      START_FILES=
1524      TEMACS_LDFLAGS2=
1525   fi
1526   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1527                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1528   files are missing or cannot be compiled.])])
1529   NS_HAVE_NSINTEGER=yes
1530   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1531                                      [NSInteger i;])],
1532                     ns_have_nsinteger=yes,
1533                     ns_have_nsinteger=no)
1534   if test $ns_have_nsinteger = no; then
1535     NS_HAVE_NSINTEGER=no
1536   fi
1537 fi
1538 AC_SUBST(TEMACS_LDFLAGS2)
1539
1540 ns_frag=/dev/null
1541 NS_OBJ=
1542 NS_SUPPORT=
1543 if test "${HAVE_NS}" = yes; then
1544   window_system=nextstep
1545   with_xft=no
1546   # set up packaging dirs
1547   exec_prefix=${ns_appbindir}
1548   libexecdir=${ns_appbindir}/libexec
1549   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1550      prefix=${ns_appresdir}
1551   fi
1552   ns_frag=$srcdir/src/ns.mk
1553   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1554   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1555 fi
1556 CFLAGS="$tmp_CFLAGS"
1557 CPPFLAGS="$tmp_CPPFLAGS"
1558 AC_SUBST(NS_OBJ)
1559 AC_SUBST(NS_SUPPORT)
1560 AC_SUBST(LIB_STANDARD)
1561 AC_SUBST_FILE(ns_frag)
1562
1563 case "${window_system}" in
1564   x11 )
1565     HAVE_X_WINDOWS=yes
1566     HAVE_X11=yes
1567     case "${with_x_toolkit}" in
1568       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1569       motif ) USE_X_TOOLKIT=MOTIF ;;
1570       gtk ) with_gtk=yes
1571 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1572 dnl USE_X_TOOLKIT is set.
1573             USE_X_TOOLKIT=none ;;
1574       gtk3 ) with_gtk3=yes
1575              USE_X_TOOLKIT=none ;;
1576       no ) USE_X_TOOLKIT=none ;;
1577 dnl If user did not say whether to use a toolkit, make this decision later:
1578 dnl use the toolkit if we have gtk, or X11R5 or newer.
1579       * ) USE_X_TOOLKIT=maybe ;;
1580     esac
1581   ;;
1582   nextstep | none )
1583     HAVE_X_WINDOWS=no
1584     HAVE_X11=no
1585     USE_X_TOOLKIT=none
1586   ;;
1587 esac
1588
1589 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1590    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1591    if test "$HAVE_XSERVER" = true ||
1592       test -n "$DISPLAY" ||
1593       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1594         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1595 were found.  You should install the relevant development files for X
1596 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1597 sure you have development files for image handling, i.e.
1598 tiff, gif, jpeg, png and xpm.
1599 If you are sure you want Emacs compiled without X window support, pass
1600   --without-x
1601 to configure.])
1602    fi
1603 fi
1604
1605 ### If we're using X11, we should use the X menu package.
1606 HAVE_MENUS=no
1607 case ${HAVE_X11} in
1608   yes ) HAVE_MENUS=yes ;;
1609 esac
1610
1611 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1612 # Assume not, until told otherwise.
1613 GNU_MALLOC=yes
1614 doug_lea_malloc=yes
1615 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1616 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1617 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1618                emacs_cv_var___after_morecore_hook,
1619 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1620   emacs_cv_var___after_morecore_hook=yes,
1621   emacs_cv_var___after_morecore_hook=no)])
1622 if test $emacs_cv_var___after_morecore_hook = no; then
1623   doug_lea_malloc=no
1624 fi
1625
1626
1627 dnl See comments in aix4-2.h about maybe using system malloc there.
1628 system_malloc=no
1629 case "$opsys" in
1630   ## darwin ld insists on the use of malloc routines in the System framework.
1631   darwin|sol2-10) system_malloc=yes ;;
1632 esac
1633
1634 if test "${system_malloc}" = "yes"; then
1635   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1636   GNU_MALLOC=no
1637   GNU_MALLOC_reason="
1638     (The GNU allocators don't work with this system configuration.)"
1639   GMALLOC_OBJ=
1640   VMLIMIT_OBJ=
1641 else
1642   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1643   VMLIMIT_OBJ=vm-limit.o
1644 fi
1645 AC_SUBST(GMALLOC_OBJ)
1646 AC_SUBST(VMLIMIT_OBJ)
1647
1648 if test "$doug_lea_malloc" = "yes" ; then
1649   if test "$GNU_MALLOC" = yes ; then
1650     GNU_MALLOC_reason="
1651       (Using Doug Lea's new malloc from the GNU C Library.)"
1652   fi
1653   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1654             [Define to 1 if you are using the GNU C Library.])
1655
1656   ## Use mmap directly for allocating larger buffers.
1657   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1658   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1659   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1660   case "$opsys" in
1661     gnu*) REL_ALLOC=no ;;
1662   esac
1663 fi
1664
1665 if test x"${REL_ALLOC}" = x; then
1666   REL_ALLOC=${GNU_MALLOC}
1667 fi
1668
1669 use_mmap_for_buffers=no
1670 case "$opsys" in
1671   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1672 esac
1673
1674 AC_FUNC_MMAP
1675 if test $use_mmap_for_buffers = yes; then
1676   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1677   REL_ALLOC=no
1678 fi
1679
1680 LIBS="$LIBS_SYSTEM $LIBS"
1681
1682 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1683 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1684 AC_CHECK_LIB(dnet, dnet_ntoa)
1685 dnl This causes -lresolv to get used in subsequent tests,
1686 dnl which causes failures on some systems such as HPUX 9.
1687 dnl AC_CHECK_LIB(resolv, gethostbyname)
1688
1689 dnl FIXME replace main with a function we actually want from this library.
1690 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1691
1692 AC_CHECK_LIB(pthreads, cma_open)
1693
1694 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1695 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1696 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1697 ## added to LIBS in configure would never contain the pthreads part,
1698 ## but the value used in Makefiles might.  FIXME?
1699 ##
1700 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1701 ## be harmless on older versions of X where it happens to exist.
1702 test "$opsys" = "aix4-2" && \
1703   test $ac_cv_lib_pthreads_cma_open = yes && \
1704   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1705
1706 dnl Check for need for bigtoc support on IBM AIX
1707
1708 case ${host_os} in
1709 aix*)
1710   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1711     case $GCC in
1712     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1713     *) gdb_cv_bigtoc=-bbigtoc ;;
1714     esac
1715
1716     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1717     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1718   ])
1719   ;;
1720 esac
1721
1722 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1723 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1724 # REAL_CPPFLAGS later on.
1725
1726 REAL_CFLAGS="$CFLAGS"
1727 REAL_CPPFLAGS="$CPPFLAGS"
1728
1729 if test "${HAVE_X11}" = "yes"; then
1730   DEFS="$C_SWITCH_X_SITE $DEFS"
1731   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1732   LIBS="-lX11 $LIBS"
1733   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1734   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1735
1736   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1737   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1738   # but it's more convenient here to set LD_RUN_PATH
1739   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1740   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1741     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1742     export LD_RUN_PATH
1743   fi
1744
1745   if test "${opsys}" = "gnu-linux"; then
1746     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1747     AC_TRY_LINK([],
1748      [XOpenDisplay ("foo");],
1749      [xlinux_first_failure=no],
1750      [xlinux_first_failure=yes])
1751     if test "${xlinux_first_failure}" = "yes"; then
1752       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1753       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1754       OLD_CPPFLAGS="$CPPFLAGS"
1755       OLD_LIBS="$LIBS"
1756       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1757       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1758       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1759       LIBS="$LIBS -b i486-linuxaout"
1760       AC_TRY_LINK([],
1761        [XOpenDisplay ("foo");],
1762        [xlinux_second_failure=no],
1763        [xlinux_second_failure=yes])
1764       if test "${xlinux_second_failure}" = "yes"; then
1765         # If we get the same failure with -b, there is no use adding -b.
1766         # So take it out.  This plays safe.
1767         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1768         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1769         CPPFLAGS="$OLD_CPPFLAGS"
1770         LIBS="$OLD_LIBS"
1771         AC_MSG_RESULT(no)
1772       else
1773         AC_MSG_RESULT(yes)
1774       fi
1775     else
1776       AC_MSG_RESULT(no)
1777     fi
1778   fi
1779
1780   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1781   # header files included from there.
1782   AC_MSG_CHECKING(for Xkb)
1783   AC_TRY_LINK([#include <X11/Xlib.h>
1784 #include <X11/XKBlib.h>],
1785         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1786         emacs_xkb=yes, emacs_xkb=no)
1787   AC_MSG_RESULT($emacs_xkb)
1788   if test $emacs_xkb = yes; then
1789     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1790   fi
1791
1792   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1793 XScreenNumberOfScreen XSetWMProtocols)
1794 fi
1795
1796 if test "${window_system}" = "x11"; then
1797   AC_MSG_CHECKING(X11 version 6)
1798   AC_CACHE_VAL(emacs_cv_x11_version_6,
1799   [AC_TRY_LINK([#include <X11/Xlib.h>],
1800 [#if XlibSpecificationRelease < 6
1801 fail;
1802 #endif
1803 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1804   if test $emacs_cv_x11_version_6 = yes; then
1805     AC_MSG_RESULT(6 or newer)
1806     AC_DEFINE(HAVE_X11R6, 1,
1807               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1808     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1809     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1810     ## XIM support.
1811     case "$opsys" in
1812       sol2-*) : ;;
1813       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1814            [Define if you have usable X11R6-style XIM support.])
1815          ;;
1816     esac
1817   else
1818     AC_MSG_RESULT(before 6)
1819   fi
1820 fi
1821
1822
1823 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1824 HAVE_RSVG=no
1825 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1826   if test "${with_rsvg}" != "no"; then
1827     RSVG_REQUIRED=2.11.0
1828     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1829
1830     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1831     AC_SUBST(RSVG_CFLAGS)
1832     AC_SUBST(RSVG_LIBS)
1833
1834     if test $HAVE_RSVG = yes; then
1835       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1836       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1837       LIBS="$RSVG_LIBS $LIBS"
1838     fi
1839   fi
1840 fi
1841
1842 HAVE_IMAGEMAGICK=no
1843 if test "${with_imagemagick}" != "no"; then
1844   IMAGEMAGICK_MODULE="Wand"
1845   PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1846   AC_SUBST(IMAGEMAGICK_CFLAGS)
1847   AC_SUBST(IMAGEMAGICK_LIBS)
1848
1849   if test $HAVE_IMAGEMAGICK = yes; then
1850     AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1851     CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1852     LIBS="$IMAGEMAGICK_LIBS $LIBS"
1853     AC_CHECK_FUNCS(MagickExportImagePixels)
1854   fi
1855 fi
1856
1857
1858 HAVE_GTK=no
1859 if test "${with_gtk3}" = "yes"; then
1860   GLIB_REQUIRED=2.6
1861   GTK_REQUIRED=2.90
1862   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1863
1864   dnl Checks for libraries.
1865   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1866   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1867      AC_MSG_ERROR($GTK_PKG_ERRORS)
1868   fi
1869 fi
1870
1871 if test "$pkg_check_gtk" != "yes"; then
1872   HAVE_GTK=no
1873 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1874   GLIB_REQUIRED=2.6
1875   GTK_REQUIRED=2.6
1876   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1877
1878   dnl Checks for libraries.
1879   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1880   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1881      AC_MSG_ERROR($GTK_PKG_ERRORS)
1882   fi
1883 fi
1884 fi
1885
1886 GTK_OBJ=
1887 if test x"$pkg_check_gtk" = xyes; then
1888
1889   AC_SUBST(GTK_CFLAGS)
1890   AC_SUBST(GTK_LIBS)
1891   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1892   CFLAGS="$CFLAGS $GTK_CFLAGS"
1893   LIBS="$GTK_LIBS $LIBS"
1894   dnl Try to compile a simple GTK program.
1895   GTK_COMPILES=no
1896   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1897   if test "${GTK_COMPILES}" != "yes"; then
1898     if test "$USE_X_TOOLKIT" != "maybe"; then
1899       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1900     fi
1901   else
1902     HAVE_GTK=yes
1903     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1904     GTK_OBJ=gtkutil.o
1905     USE_X_TOOLKIT=none
1906     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1907       :
1908     else
1909       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1910        closing open displays.  This is no problem if you just use
1911        one display, but if you use more than one and close one of them
1912        Emacs may crash.]])
1913       sleep 3
1914     fi
1915   fi
1916
1917 fi
1918 AC_SUBST(GTK_OBJ)
1919
1920
1921 if test "${HAVE_GTK}" = "yes"; then
1922
1923   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1924   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1925   if test "$with_toolkit_scroll_bars" != no; then
1926     with_toolkit_scroll_bars=yes
1927   fi
1928
1929   dnl  Check if we have the old file selection dialog declared and
1930   dnl  in the link library.  In 2.x it may be in the library,
1931   dnl  but not declared if deprecated featured has been selected out.
1932   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1933   HAVE_GTK_FILE_SELECTION=no
1934   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1935                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1936 #include <gtk/gtk.h>])
1937   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1938     AC_CHECK_FUNCS(gtk_file_selection_new)
1939   fi
1940
1941   dnl Check if pthreads are available.  Emacs only needs this when using
1942   dnl gtk_file_chooser under Gnome.
1943     HAVE_GTK_AND_PTHREAD=no
1944     AC_CHECK_HEADERS(pthread.h)
1945     if test "$ac_cv_header_pthread_h"; then
1946       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1947     fi
1948     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1949       case "${canonical}" in
1950         *-hpux*) ;;
1951         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1952       esac
1953       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1954                [Define to 1 if you have GTK and pthread (-lpthread).])
1955     fi
1956
1957   dnl Check for functions introduced in 2.14 and later.
1958   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1959                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1960                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1961                  gtk_orientable_set_orientation)
1962
1963 fi
1964
1965 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1966 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1967 dnl also not configured.
1968 HAVE_DBUS=no
1969 DBUS_OBJ=
1970 if test "${with_dbus}" = "yes"; then
1971    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1972    if test "$HAVE_DBUS" = yes; then
1973      LIBS="$LIBS $DBUS_LIBS"
1974      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1975      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1976      DBUS_OBJ=dbusbind.o
1977    fi
1978 fi
1979 AC_SUBST(DBUS_OBJ)
1980
1981 dnl GConf has been tested under GNU/Linux only.
1982 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1983 HAVE_GCONF=no
1984 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1985    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1986    if test "$HAVE_GCONF" = yes; then
1987       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1988    fi
1989 fi
1990
1991 dnl SELinux is available for GNU/Linux only.
1992 HAVE_LIBSELINUX=no
1993 LIBSELINUX_LIBS=
1994 if test "${with_selinux}" = "yes"; then
1995    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1996    if test "$HAVE_LIBSELINUX" = yes; then
1997       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1998       LIBSELINUX_LIBS=-lselinux
1999    fi
2000 fi
2001 AC_SUBST(LIBSELINUX_LIBS)
2002
2003 HAVE_GNUTLS=no
2004 if test "${with_gnutls}" = "yes" ; then
2005   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4])
2006   AC_DEFINE(HAVE_GNUTLS)
2007   HAVE_GNUTLS=yes
2008 fi
2009
2010 dnl Do not put whitespace before the #include statements below.
2011 dnl Older compilers (eg sunos4 cc) choke on it.
2012 HAVE_XAW3D=no
2013 LUCID_LIBW=
2014 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2015   if test "$with_xaw3d" != no; then
2016     AC_MSG_CHECKING(for xaw3d)
2017     AC_CACHE_VAL(emacs_cv_xaw3d,
2018     [AC_TRY_LINK([
2019 #include <X11/Intrinsic.h>
2020 #include <X11/Xaw3d/Simple.h>],
2021       [],
2022       emacs_cv_xaw3d=yes,
2023       emacs_cv_xaw3d=no)])
2024   else
2025     emacs_cv_xaw3d=no
2026   fi
2027   if test $emacs_cv_xaw3d = yes; then
2028     AC_MSG_RESULT([yes; using Lucid toolkit])
2029     USE_X_TOOLKIT=LUCID
2030     HAVE_XAW3D=yes
2031     LUCID_LIBW=-lXaw3d
2032     AC_DEFINE(HAVE_XAW3D, 1,
2033               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2034   else
2035     AC_MSG_RESULT(no)
2036     AC_MSG_CHECKING(for libXaw)
2037     AC_CACHE_VAL(emacs_cv_xaw,
2038     [AC_TRY_LINK([
2039 #include <X11/Intrinsic.h>
2040 #include <X11/Xaw/Simple.h>],
2041       [],
2042       emacs_cv_xaw=yes,
2043       emacs_cv_xaw=no)])
2044     if test $emacs_cv_xaw = yes; then
2045       AC_MSG_RESULT([yes; using Lucid toolkit])
2046       USE_X_TOOLKIT=LUCID
2047       LUCID_LIBW=-lXaw
2048     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2049       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2050     else
2051       AC_MSG_RESULT([no; do not use toolkit by default])
2052       USE_X_TOOLKIT=none
2053     fi
2054   fi
2055 fi
2056
2057 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2058
2059 LIBXTR6=
2060 if test "${USE_X_TOOLKIT}" != "none"; then
2061   AC_MSG_CHECKING(X11 toolkit version)
2062   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2063   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2064 [#if XtSpecificationRelease < 6
2065 fail;
2066 #endif
2067 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2068   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2069   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2070     AC_MSG_RESULT(6 or newer)
2071     AC_DEFINE(HAVE_X11XTR6, 1,
2072               [Define to 1 if you have the X11R6 or newer version of Xt.])
2073     LIBXTR6="-lSM -lICE"
2074     case "$opsys" in
2075       ## Use libw.a along with X11R6 Xt.
2076       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2077     esac
2078   else
2079     AC_MSG_RESULT(before 6)
2080   fi
2081
2082 dnl If using toolkit, check whether libXmu.a exists.
2083 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2084   OLDLIBS="$LIBS"
2085   if test x$HAVE_X11XTR6 = xyes; then
2086     LIBS="-lXt -lSM -lICE $LIBS"
2087   else
2088     LIBS="-lXt $LIBS"
2089   fi
2090   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2091   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2092 fi
2093 AC_SUBST(LIBXTR6)
2094
2095 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2096 dnl Why not just test for libxmu in the normal way?
2097 LIBXMU=-lXmu
2098 case "$machine" in
2099   ## These machines don't supply Xmu.
2100   hpux* | aix4-2 )
2101     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2102     ;;
2103 esac
2104 AC_SUBST(LIBXMU)
2105
2106 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2107 if test "${HAVE_X11}" = "yes"; then
2108   if test "${USE_X_TOOLKIT}" != "none"; then
2109     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2110   fi
2111 fi
2112
2113 LIBXP=
2114 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2115   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2116   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2117     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2118 int x = 5;
2119 #else
2120 Motif version prior to 2.1.
2121 #endif],
2122     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2123   if test $emacs_cv_motif_version_2_1 = yes; then
2124     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2125   else
2126     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2127     # We put this in CFLAGS temporarily to precede other -I options
2128     # that might be in CFLAGS temporarily.
2129     # We put this in CPPFLAGS where it precedes the other -I options.
2130     OLD_CPPFLAGS=$CPPFLAGS
2131     OLD_CFLAGS=$CFLAGS
2132     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2133     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2134     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2135       [int x = 5;],
2136       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2137     if test $emacs_cv_lesstif = yes; then
2138       # Make sure this -I option remains in CPPFLAGS after it is set
2139       # back to REAL_CPPFLAGS.
2140       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2141       # have those other -I options anyway.  Ultimately, having this
2142       # directory ultimately in CPPFLAGS will be enough.
2143       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2144       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2145     else
2146       CFLAGS=$OLD_CFLAGS
2147       CPPFLAGS=$OLD_CPPFLAGS
2148     fi
2149   fi
2150 fi
2151
2152 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2153 dnl using Motif or Xaw3d is available, and unless
2154 dnl --with-toolkit-scroll-bars=no was specified.
2155
2156 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2157             [Define to 1 if we should use toolkit scroll bars.])dnl
2158 USE_TOOLKIT_SCROLL_BARS=no
2159 if test "${with_toolkit_scroll_bars}" != "no"; then
2160   if test "${USE_X_TOOLKIT}" != "none"; then
2161     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2162       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2163       HAVE_XAW3D=no
2164       USE_TOOLKIT_SCROLL_BARS=yes
2165     elif test "${HAVE_XAW3D}" = "yes"; then
2166       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2167       USE_TOOLKIT_SCROLL_BARS=yes
2168     fi
2169   elif test "${HAVE_GTK}" = "yes"; then
2170     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2171     USE_TOOLKIT_SCROLL_BARS=yes
2172   elif test "${HAVE_NS}" = "yes"; then
2173     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2174     USE_TOOLKIT_SCROLL_BARS=yes
2175   fi
2176 fi
2177
2178 dnl See if XIM is available.
2179 AC_TRY_COMPILE([
2180           #include <X11/Xlib.h>
2181           #include <X11/Xresource.h>],
2182          [XIMProc  callback;],
2183          [HAVE_XIM=yes
2184          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2185          HAVE_XIM=no)
2186
2187 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2188
2189 if test "${with_xim}" != "no"; then
2190   AC_DEFINE(USE_XIM, 1,
2191             [Define to 1 if we should use XIM, if it is available.])
2192 fi
2193
2194
2195 if test "${HAVE_XIM}" != "no"; then
2196   late_CFLAGS=$CFLAGS
2197   if test "$GCC" = yes; then
2198     CFLAGS="$CFLAGS --pedantic-errors"
2199   fi
2200   AC_TRY_COMPILE([
2201 #include <X11/Xlib.h>
2202 #include <X11/Xresource.h>],
2203 [Display *display;
2204 XrmDatabase db;
2205 char *res_name;
2206 char *res_class;
2207 XIMProc  callback;
2208 XPointer *client_data;
2209 #ifndef __GNUC__
2210 /* If we're not using GCC, it's probably not XFree86, and this is
2211    probably right, but we can't use something like --pedantic-errors.  */
2212 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2213                                            char*, XIMProc, XPointer*);
2214 #endif
2215 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2216    client_data);],
2217     [emacs_cv_arg6_star=yes])
2218   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2219          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2220 either XPointer or XPointer*.])dnl
2221   if test "$emacs_cv_arg6_star" = yes; then
2222     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2223   else
2224     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2225   fi
2226   CFLAGS=$late_CFLAGS
2227 fi
2228
2229 ### Start of font-backend (under any platform) section.
2230 # (nothing here yet -- this is a placeholder)
2231 ### End of font-backend (under any platform) section.
2232
2233 ### Start of font-backend (under X11) section.
2234 if test "${HAVE_X11}" = "yes"; then
2235    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2236
2237    ## Use -lXft if available, unless `--with-xft=no'.
2238    HAVE_XFT=maybe
2239     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2240       with_xft="no";
2241     fi
2242     if test "x${with_xft}" != "xno"; then
2243
2244       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2245       ## Because xftfont.c uses XRenderQueryExtension, we also
2246       ## need to link to -lXrender.
2247       HAVE_XRENDER=no
2248       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2249       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2250         OLD_CPPFLAGS="$CPPFLAGS"
2251         OLD_CFLAGS="$CFLAGS"
2252         OLD_LIBS="$LIBS"
2253         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2254         CFLAGS="$CFLAGS $XFT_CFLAGS"
2255         XFT_LIBS="-lXrender $XFT_LIBS"
2256         LIBS="$XFT_LIBS $LIBS"
2257         AC_CHECK_HEADER(X11/Xft/Xft.h,
2258           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2259
2260         if test "${HAVE_XFT}" = "yes"; then
2261           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2262             AC_SUBST(XFT_LIBS)
2263           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2264         else
2265           CPPFLAGS="$OLD_CPPFLAGS"
2266           CFLAGS="$OLD_CFLAGS"
2267           LIBS="$OLD_LIBS"
2268         fi                        # "${HAVE_XFT}" = "yes"
2269       fi                          # "$HAVE_XFT" != no
2270     fi                            # "x${with_xft}" != "xno"
2271
2272     dnl For the "Does Emacs use" message at the end.
2273     if test "$HAVE_XFT" != "yes"; then
2274        HAVE_XFT=no
2275     fi
2276
2277
2278     HAVE_FREETYPE=no
2279     ## We used to allow building with FreeType and without Xft.
2280     ## However, the ftx font backend driver is not in good shape.
2281     if test "${HAVE_XFT}" = "yes"; then
2282       dnl As we use Xft, we anyway use freetype.
2283       dnl There's no need for additional CFLAGS and LIBS.
2284       HAVE_FREETYPE=yes
2285       FONTCONFIG_CFLAGS=
2286       FONTCONFIG_LIBS=
2287     fi
2288
2289     HAVE_LIBOTF=no
2290     if test "${HAVE_FREETYPE}" = "yes"; then
2291       AC_DEFINE(HAVE_FREETYPE, 1,
2292                 [Define to 1 if using the freetype and fontconfig libraries.])
2293       if test "${with_libotf}" != "no"; then
2294         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2295                           HAVE_LIBOTF=no)
2296         if test "$HAVE_LIBOTF" = "yes"; then
2297           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2298           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2299                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2300                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2301           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2302             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2303                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2304           fi
2305         fi
2306       fi
2307     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2308     dnl Does the new font backend require it, or can it work without it?
2309     fi
2310
2311     HAVE_M17N_FLT=no
2312     if test "${HAVE_LIBOTF}" = yes; then
2313       if test "${with_m17n_flt}" != "no"; then
2314         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2315         if test "$HAVE_M17N_FLT" = "yes"; then
2316           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2317         fi
2318       fi
2319     fi
2320 else
2321     HAVE_XFT=no
2322     HAVE_FREETYPE=no
2323     HAVE_LIBOTF=no
2324     HAVE_M17N_FLT=no
2325 fi
2326
2327 ### End of font-backend (under X11) section.
2328
2329 AC_SUBST(FREETYPE_CFLAGS)
2330 AC_SUBST(FREETYPE_LIBS)
2331 AC_SUBST(FONTCONFIG_CFLAGS)
2332 AC_SUBST(FONTCONFIG_LIBS)
2333 AC_SUBST(LIBOTF_CFLAGS)
2334 AC_SUBST(LIBOTF_LIBS)
2335 AC_SUBST(M17N_FLT_CFLAGS)
2336 AC_SUBST(M17N_FLT_LIBS)
2337
2338 ### Use -lXpm if available, unless `--with-xpm=no'.
2339 HAVE_XPM=no
2340 LIBXPM=
2341 if test "${HAVE_X11}" = "yes"; then
2342   if test "${with_xpm}" != "no"; then
2343     AC_CHECK_HEADER(X11/xpm.h,
2344       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2345     if test "${HAVE_XPM}" = "yes"; then
2346       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2347       AC_EGREP_CPP(no_return_alloc_pixels,
2348       [#include "X11/xpm.h"
2349 #ifndef XpmReturnAllocPixels
2350 no_return_alloc_pixels
2351 #endif
2352       ], HAVE_XPM=no, HAVE_XPM=yes)
2353
2354       if test "${HAVE_XPM}" = "yes"; then
2355         AC_MSG_RESULT(yes)
2356       else
2357         AC_MSG_RESULT(no)
2358       fi
2359     fi
2360   fi
2361
2362   if test "${HAVE_XPM}" = "yes"; then
2363     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2364     LIBXPM=-lXpm
2365   fi
2366 fi
2367 AC_SUBST(LIBXPM)
2368
2369 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2370 HAVE_JPEG=no
2371 LIBJPEG=
2372 if test "${HAVE_X11}" = "yes"; then
2373   if test "${with_jpeg}" != "no"; then
2374     dnl Checking for jpeglib.h can lose because of a redefinition of
2375     dnl  HAVE_STDLIB_H.
2376     AC_CHECK_HEADER(jerror.h,
2377       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2378   fi
2379
2380   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2381   if test "${HAVE_JPEG}" = "yes"; then
2382     AC_DEFINE(HAVE_JPEG)
2383     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2384         [#include <jpeglib.h>
2385          version=JPEG_LIB_VERSION
2386 ],
2387         [AC_DEFINE(HAVE_JPEG)],
2388         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2389         HAVE_JPEG=no])
2390   fi
2391   if test "${HAVE_JPEG}" = "yes"; then
2392     LIBJPEG=-ljpeg
2393   fi
2394 fi
2395 AC_SUBST(LIBJPEG)
2396
2397 ### Use -lpng if available, unless `--with-png=no'.
2398 HAVE_PNG=no
2399 LIBPNG=
2400 if test "${HAVE_X11}" = "yes"; then
2401   if test "${with_png}" != "no"; then
2402     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2403     # in /usr/include/libpng.
2404     AC_CHECK_HEADERS(png.h libpng/png.h)
2405     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2406       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2407     fi
2408   fi
2409
2410   if test "${HAVE_PNG}" = "yes"; then
2411     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2412     LIBPNG="-lpng -lz -lm"
2413   fi
2414 fi
2415 AC_SUBST(LIBPNG)
2416
2417 ### Use -ltiff if available, unless `--with-tiff=no'.
2418 HAVE_TIFF=no
2419 LIBTIFF=
2420 if test "${HAVE_X11}" = "yes"; then
2421   if test "${with_tiff}" != "no"; then
2422     AC_CHECK_HEADER(tiffio.h,
2423       [tifflibs="-lz -lm"
2424       # At least one tiff package requires the jpeg library.
2425       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2426       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2427   fi
2428
2429   if test "${HAVE_TIFF}" = "yes"; then
2430     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2431     dnl FIXME -lz -lm, as per libpng?
2432     LIBTIFF=-ltiff
2433   fi
2434 fi
2435 AC_SUBST(LIBTIFF)
2436
2437 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2438 HAVE_GIF=no
2439 LIBGIF=
2440 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2441   AC_CHECK_HEADER(gif_lib.h,
2442 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2443 # Earlier versions can crash Emacs.
2444     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2445
2446   if test "$HAVE_GIF" = yes; then
2447     LIBGIF=-lgif
2448   elif test "$HAVE_GIF" = maybe; then
2449 # If gif_lib.h but no libgif, try libungif.
2450     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2451     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2452   fi
2453
2454   if test "${HAVE_GIF}" = "yes"; then
2455     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2456   fi
2457 fi
2458 AC_SUBST(LIBGIF)
2459
2460 dnl Check for required libraries.
2461 if test "${HAVE_X11}" = "yes"; then
2462   MISSING=""
2463   WITH_NO=""
2464   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2465     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2466   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2467     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2468   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2469     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2470   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2471     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2472   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2473     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2474
2475   if test "X${MISSING}" != X; then
2476     AC_MSG_ERROR([The following required libraries were not found:
2477     $MISSING
2478 Maybe some development libraries/packages are missing?
2479 If you don't want to link with them give
2480     $WITH_NO
2481 as options to configure])
2482   fi
2483 fi
2484
2485 ### Use -lgpm if available, unless `--with-gpm=no'.
2486 HAVE_GPM=no
2487 LIBGPM=
2488 MOUSE_SUPPORT=
2489 if test "${with_gpm}" != "no"; then
2490   AC_CHECK_HEADER(gpm.h,
2491     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2492
2493   if test "${HAVE_GPM}" = "yes"; then
2494     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2495     LIBGPM=-lgpm
2496     ## May be reset below.
2497     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2498   fi
2499 fi
2500 AC_SUBST(LIBGPM)
2501
2502 dnl Check for malloc/malloc.h on darwin
2503 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2504
2505 C_SWITCH_X_SYSTEM=
2506 ### Use NeXTstep API to implement GUI.
2507 if test "${HAVE_NS}" = "yes"; then
2508   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2509   if test "${NS_IMPL_COCOA}" = "yes"; then
2510     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2511     GNU_OBJC_CFLAGS=
2512   fi
2513   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2514     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2515     # See also .m.o rule in Makefile.in */
2516     # FIXME: are all these flags really needed?  Document here why.  */
2517     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2518     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2519   fi
2520   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2521     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2522   fi
2523   # We also have mouse menus.
2524   HAVE_MENUS=yes
2525   OTHER_FILES=ns-app
2526 fi
2527
2528
2529 ### Use session management (-lSM -lICE) if available
2530 HAVE_X_SM=no
2531 LIBXSM=
2532 if test "${HAVE_X11}" = "yes"; then
2533   AC_CHECK_HEADER(X11/SM/SMlib.h,
2534     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2535
2536   if test "${HAVE_X_SM}" = "yes"; then
2537     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2538     LIBXSM="-lSM -lICE"
2539     case "$LIBS" in
2540       *-lSM*) ;;
2541       *)      LIBS="$LIBXSM $LIBS" ;;
2542     esac
2543   fi
2544 fi
2545 AC_SUBST(LIBXSM)
2546
2547 ### Use libxml (-lxml2) if available
2548 if test "${with_xml2}" != "no"; then
2549   ### I'm not sure what the version number should be, so I just guessed.
2550   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.2.0, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2551   if test "${HAVE_LIBXML2}" = "yes"; then
2552     LIBS="$LIBXML2_LIBS $LIBS"
2553     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2554     if test "${HAVE_LIBXML2}" = "yes"; then
2555       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2556     else
2557       LIBXML2_LIBS=""
2558       LIBXML2_CFLAGS=""
2559     fi
2560   fi
2561 fi
2562 AC_SUBST(LIBXML2_LIBS)
2563 AC_SUBST(LIBXML2_CFLAGS)
2564
2565 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2566 AC_CACHE_CHECK(whether netdb declares h_errno,
2567                emacs_cv_netdb_declares_h_errno,
2568 [AC_TRY_LINK([#include <netdb.h>],
2569   [return h_errno;],
2570   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2571 if test $emacs_cv_netdb_declares_h_errno = yes; then
2572   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2573 fi
2574
2575 AC_FUNC_ALLOCA
2576
2577 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2578 dnl FIXME is there an autoconf test that does the right thing, without
2579 dnl needing to call A_M_E afterwards?
2580 if test x"$ac_cv_func_alloca_works" != xyes; then
2581    AC_MSG_ERROR( [a system implementation of alloca is required] )
2582 fi
2583
2584 # fmod, logb, and frexp are found in -lm on most systems.
2585 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2586 AC_CHECK_LIB(m, sqrt)
2587
2588 # Check for mail-locking functions in a "mail" library.  Probably this should
2589 # have the same check as for liblockfile below.
2590 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2591 if test $have_mail = yes; then
2592   LIBS_MAIL=-lmail
2593   LIBS="$LIBS_MAIL $LIBS"
2594   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2595 else
2596   LIBS_MAIL=
2597 fi
2598 dnl Debian, at least:
2599 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2600 if test $have_lockfile = yes; then
2601    LIBS_MAIL=-llockfile
2602    LIBS="$LIBS_MAIL $LIBS"
2603    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2604 else
2605 # If we have the shared liblockfile, assume we must use it for mail
2606 # locking (e.g. Debian).  If we couldn't link against liblockfile
2607 # (no liblockfile.a installed), ensure that we don't need to.
2608   dnl This works for files generally, not just executables.
2609   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2610   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2611                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2612   if test $ac_cv_prog_liblockfile = yes; then
2613     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2614 This probably means that movemail could lose mail.
2615 There may be a `development' package to install containing liblockfile.])
2616   fi
2617 fi
2618 AC_CHECK_FUNCS(touchlock)
2619 AC_CHECK_HEADERS(maillock.h)
2620 AC_SUBST(LIBS_MAIL)
2621
2622 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2623 ## interlock access to the mail spool.  The alternative is a lock file named
2624 ## /usr/spool/mail/$USER.lock.
2625 mail_lock=no
2626 case "$opsys" in
2627   aix4-2) mail_lock="lockf" ;;
2628
2629   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2630
2631   ## On GNU/Linux systems, both methods are used by various mail programs.
2632   ## I assume most people are using newer mailers that have heard of flock.
2633   ## Change this if you need to.
2634   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2635   ## configure gets the right answers, and that means *NOT* using flock.
2636   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2637   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2638   ## Debian maintainer hasn't provided a clean fix for Emacs.
2639   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2640   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2641   ## correct logic.  -- fx
2642   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2643   ## liblockfile is a Free Software replacement for libmail, used on
2644   ## Debian systems and elsewhere. -rfr.
2645   gnu-*)
2646     mail_lock="flock"
2647     if test $have_mail = yes || test $have_lockfile = yes; then
2648       test $ac_cv_header_maillock_h = yes && mail_lock=no
2649     fi
2650     ;;
2651 esac
2652
2653 BLESSMAIL_TARGET=
2654 case "$mail_lock" in
2655   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2656
2657   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2658
2659   *) BLESSMAIL_TARGET="need-blessmail" ;;
2660 esac
2661 AC_SUBST(BLESSMAIL_TARGET)
2662
2663
2664 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2665 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2666 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2667 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2668 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2669 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2670 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2671 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2672 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2673 cfmakeraw cfsetspeed isnan copysign __executable_start)
2674
2675 AC_CHECK_HEADERS(sys/un.h)
2676
2677 AC_FUNC_MKTIME
2678 if test "$ac_cv_func_working_mktime" = no; then
2679   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2680 fi
2681
2682 AC_FUNC_GETLOADAVG
2683
2684 AC_FUNC_FSEEKO
2685
2686 # Configure getopt.
2687 m4_include([m4/getopt.m4])
2688 gl_GETOPT_IFELSE([
2689   gl_GETOPT_SUBSTITUTE_HEADER
2690   gl_PREREQ_GETOPT
2691   GETOPTOBJS='getopt.o getopt1.o'
2692 ])
2693 AC_SUBST(GETOPTOBJS)
2694
2695 AC_FUNC_GETPGRP
2696
2697 AC_FUNC_STRFTIME
2698
2699 # UNIX98 PTYs.
2700 AC_CHECK_FUNCS(grantpt)
2701
2702 # PTY-related GNU extensions.
2703 AC_CHECK_FUNCS(getpt)
2704
2705 # Check this now, so that we will NOT find the above functions in ncurses.
2706 # That is because we have not set up to link ncurses in lib-src.
2707 # It's better to believe a function is not available
2708 # than to expect to find it in ncurses.
2709 # Also we need tputs and friends to be able to build at all.
2710 have_tputs_et_al=true
2711 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2712 if test "$have_tputs_et_al" != true; then
2713   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2714 Maybe some development libraries/packages are missing?  Try installing
2715 libncurses-dev(el), libterminfo-dev(el) or similar.])
2716 fi
2717 # Must define this when any termcap library is found.
2718 AC_DEFINE(HAVE_LIBNCURSES, 1,
2719           [Define to 1 if you have the `ncurses' library (-lncurses).])
2720 ## FIXME This was the cpp logic, but I am not sure it is right.
2721 ## The above test has not necessarily found libncurses.
2722 HAVE_LIBNCURSES=yes
2723
2724 ## Use terminfo instead of termcap?
2725 ## Note only system files NOT using terminfo are:
2726 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2727 ## darwin|gnu without ncurses.
2728 TERMINFO=no
2729 LIBS_TERMCAP=
2730 case "$opsys" in
2731   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2732   ## hpux10-20: Use the system provided termcap(3) library.
2733   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2734   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2735   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2736
2737   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2738   ##  The ncurses library has been moved out of the System framework in
2739   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2740   ##  option to use it.
2741   darwin|gnu*)
2742     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2743     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2744       TERMINFO=yes
2745       LIBS_TERMCAP="-lncurses"
2746     fi
2747     ;;
2748
2749   freebsd)
2750     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2751     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2752     [AC_TRY_LINK([#include <osreldate.h>],
2753 [#if __FreeBSD_version < 400000
2754 fail;
2755 #endif
2756 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2757
2758     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2759
2760     if test $emacs_cv_freebsd_terminfo = yes; then
2761       TERMINFO=yes
2762       LIBS_TERMCAP="-lncurses"
2763     else
2764       LIBS_TERMCAP="-ltermcap"
2765     fi
2766     ;;
2767
2768   netbsd)
2769     if test $ac_cv_search_tputs = -lterminfo; then
2770       TERMINFO=yes
2771       LIBS_TERMCAP="-lterminfo"
2772     else
2773       LIBS_TERMCAP="-ltermcap"
2774     fi
2775     ;;
2776
2777 esac
2778
2779 case "$opsys" in
2780   ## hpux: Make sure we get select from libc rather than from libcurses
2781   ##  because libcurses on HPUX 10.10 has a broken version of select.
2782   ##  We used to use -lc -lcurses, but this may be cleaner.
2783   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2784
2785   openbsd) LIBS_TERMCAP="-lncurses" ;;
2786
2787   ## Must use system termcap, if we use any termcap.  It does special things.
2788   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2789 esac
2790
2791 TERMCAP_OBJ=tparam.o
2792 if test $TERMINFO = yes; then
2793   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2794
2795   ## Default used to be -ltermcap.  Add a case above if need something else.
2796   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2797
2798   TERMCAP_OBJ=terminfo.o
2799 fi
2800 AC_SUBST(LIBS_TERMCAP)
2801 AC_SUBST(TERMCAP_OBJ)
2802
2803
2804 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2805 resolv=no
2806 AC_TRY_LINK([#include <netinet/in.h>
2807 #include <arpa/nameser.h>
2808 #include <resolv.h>],
2809     [return res_init();],
2810     have_res_init=yes, have_res_init=no)
2811 if test "$have_res_init" = no; then
2812   OLIBS="$LIBS"
2813   LIBS="$LIBS -lresolv"
2814   AC_MSG_CHECKING(for res_init with -lresolv)
2815   AC_TRY_LINK([#include <netinet/in.h>
2816 #include <arpa/nameser.h>
2817 #include <resolv.h>],
2818     [return res_init();],
2819     have_res_init=yes, have_res_init=no)
2820   AC_MSG_RESULT($have_res_init)
2821   if test "$have_res_init" = yes ; then
2822     resolv=yes
2823   fi
2824   LIBS="$OLIBS"
2825 fi
2826
2827 if test "$have_res_init" = yes; then
2828   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2829 fi
2830
2831 # Do we need the Hesiod library to provide the support routines?
2832 LIBHESIOD=
2833 if test "$with_hesiod" != no ; then
2834   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2835   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2836      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2837                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2838   if test "$resolv" = yes ; then
2839     RESOLVLIB=-lresolv
2840   else
2841     RESOLVLIB=
2842   fi
2843   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2844         hesiod=yes, :, $RESOLVLIB)])
2845
2846   if test x"$hesiod" = xyes; then
2847     AC_DEFINE(HAVE_LIBHESIOD, 1,
2848               [Define to 1 if you have the hesiod library (-lhesiod).])
2849     LIBHESIOD=-lhesiod
2850   fi
2851 fi
2852 AC_SUBST(LIBHESIOD)
2853
2854 # Do we need libresolv (due to res_init or Hesiod)?
2855 if test "$resolv" = yes ; then
2856   AC_DEFINE(HAVE_LIBRESOLV, 1,
2857             [Define to 1 if you have the resolv library (-lresolv).])
2858   LIBRESOLV=-lresolv
2859 else
2860   LIBRESOLV=
2861 fi
2862 AC_SUBST(LIBRESOLV)
2863
2864 # These tell us which Kerberos-related libraries to use.
2865 COM_ERRLIB=
2866 CRYPTOLIB=
2867 KRB5LIB=
2868 DESLIB=
2869 KRB4LIB=
2870
2871 if test "${with_kerberos}" != no; then
2872   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2873   if test $have_com_err = yes; then
2874     COM_ERRLIB=-lcom_err
2875     LIBS="$COM_ERRLIB $LIBS"
2876     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2877   fi
2878   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2879   if test $have_crypto = yes; then
2880     CRYPTOLIB=-lcrypto
2881     LIBS="$CRYPTOLIB $LIBS"
2882     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2883   fi
2884   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2885   if test $have_k5crypto = yes; then
2886     CRYPTOLIB=-lk5crypto
2887     LIBS="$CRYPTOLIB $LIBS"
2888     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2889   fi
2890   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2891   if test $have_krb5=yes; then
2892     KRB5LIB=-lkrb5
2893     LIBS="$KRB5LIB $LIBS"
2894     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2895   fi
2896   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2897   if test "${with_kerberos5}" = no; then
2898     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2899     if test $have_des425 = yes; then
2900       DESLIB=-ldes425
2901       LIBS="$DESLIB $LIBS"
2902       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2903     else
2904       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2905       if test $have_des = yes; then
2906         DESLIB=-ldes
2907         LIBS="$DESLIB $LIBS"
2908         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2909       fi
2910     fi
2911     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2912     if test $have_krb4 = yes; then
2913       KRB4LIB=-lkrb4
2914       LIBS="$KRB4LIB $LIBS"
2915       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2916     else
2917       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2918       if test $have_krb = yes; then
2919         KRB4LIB=-lkrb
2920         LIBS="$KRB4LIB $LIBS"
2921         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2922       fi
2923     fi
2924   fi
2925
2926   if test "${with_kerberos5}" != no; then
2927     AC_CHECK_HEADERS(krb5.h,
2928       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2929                         [#include <krb5.h>])])
2930   else
2931     AC_CHECK_HEADERS(des.h,,
2932                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2933                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2934     AC_CHECK_HEADERS(krb.h,,
2935                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2936                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2937   fi
2938   AC_CHECK_HEADERS(com_err.h)
2939 fi
2940
2941 AC_SUBST(COM_ERRLIB)
2942 AC_SUBST(CRYPTOLIB)
2943 AC_SUBST(KRB5LIB)
2944 AC_SUBST(DESLIB)
2945 AC_SUBST(KRB4LIB)
2946
2947 # Solaris requires -lintl if you want strerror (which calls dgettext)
2948 # to return localized messages.
2949 AC_CHECK_LIB(intl, dgettext)
2950
2951 AC_MSG_CHECKING(whether localtime caches TZ)
2952 AC_CACHE_VAL(emacs_cv_localtime_cache,
2953 [if test x$ac_cv_func_tzset = xyes; then
2954 AC_TRY_RUN([#include <time.h>
2955 extern char **environ;
2956 unset_TZ ()
2957 {
2958   char **from, **to;
2959   for (to = from = environ; (*to = *from); from++)
2960     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2961       to++;
2962 }
2963 char TZ_GMT0[] = "TZ=GMT0";
2964 char TZ_PST8[] = "TZ=PST8";
2965 main()
2966 {
2967   time_t now = time ((time_t *) 0);
2968   int hour_GMT0, hour_unset;
2969   if (putenv (TZ_GMT0) != 0)
2970     exit (1);
2971   hour_GMT0 = localtime (&now)->tm_hour;
2972   unset_TZ ();
2973   hour_unset = localtime (&now)->tm_hour;
2974   if (putenv (TZ_PST8) != 0)
2975     exit (1);
2976   if (localtime (&now)->tm_hour == hour_GMT0)
2977     exit (1);
2978   unset_TZ ();
2979   if (localtime (&now)->tm_hour != hour_unset)
2980     exit (1);
2981   exit (0);
2982 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2983 [# If we have tzset, assume the worst when cross-compiling.
2984 emacs_cv_localtime_cache=yes])
2985 else
2986         # If we lack tzset, report that localtime does not cache TZ,
2987         # since we can't invalidate the cache if we don't have tzset.
2988         emacs_cv_localtime_cache=no
2989 fi])dnl
2990 AC_MSG_RESULT($emacs_cv_localtime_cache)
2991 if test $emacs_cv_localtime_cache = yes; then
2992   AC_DEFINE(LOCALTIME_CACHE, 1,
2993             [Define to 1 if localtime caches TZ.])
2994 fi
2995
2996 if test "x$HAVE_TIMEVAL" = xyes; then
2997   AC_CHECK_FUNCS(gettimeofday)
2998   if test $ac_cv_func_gettimeofday = yes; then
2999     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3000                    emacs_cv_gettimeofday_two_arguments,
3001     [AC_TRY_COMPILE([
3002 #ifdef TIME_WITH_SYS_TIME
3003 #include <sys/time.h>
3004 #include <time.h>
3005 #else
3006 #ifdef HAVE_SYS_TIME_H
3007 #include <sys/time.h>
3008 #else
3009 #include <time.h>
3010 #endif
3011 #endif],
3012       [struct timeval time;
3013        gettimeofday (&time, 0);],
3014       emacs_cv_gettimeofday_two_arguments=yes,
3015       emacs_cv_gettimeofday_two_arguments=no)])
3016     if test $emacs_cv_gettimeofday_two_arguments = no; then
3017       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3018                 [Define to 1 if gettimeofday accepts only one argument.])
3019     fi
3020   fi
3021 fi
3022
3023 ok_so_far=yes
3024 AC_CHECK_FUNC(socket, , ok_so_far=no)
3025 if test $ok_so_far = yes; then
3026   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3027 fi
3028 if test $ok_so_far = yes; then
3029   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3030 fi
3031 if test $ok_so_far = yes; then
3032 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3033   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3034             [Define to 1 if you have inet sockets.])
3035 fi
3036
3037 AC_CHECK_HEADERS(sys/ioctl.h)
3038
3039 if test -f /usr/lpp/X11/bin/smt.exp; then
3040   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3041             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3042 fi
3043
3044 AC_MSG_CHECKING(whether system supports dynamic ptys)
3045 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3046   AC_MSG_RESULT(yes)
3047   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3048 else
3049   AC_MSG_RESULT(no)
3050 fi
3051
3052 AC_FUNC_FORK
3053
3054 dnl Adapted from Haible's version.
3055 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3056   [AC_TRY_LINK([#include <langinfo.h>],
3057     [char* cs = nl_langinfo(CODESET);],
3058     emacs_cv_langinfo_codeset=yes,
3059     emacs_cv_langinfo_codeset=no)
3060   ])
3061 if test $emacs_cv_langinfo_codeset = yes; then
3062   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3063     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3064 fi
3065
3066 AC_CHECK_TYPES(size_t)
3067
3068 AC_TYPE_MBSTATE_T
3069
3070 dnl Restrict could probably be used effectively other than in regex.c.
3071 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3072   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3073                   emacs_cv_c_restrict=yes,
3074                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3075                                   emacs_cv_c_restrict=__restrict,
3076                                   emacs_cv_c_restrict=no)])])
3077 case "$emacs_cv_c_restrict" in
3078   yes) emacs_restrict=restrict;;
3079   no) emacs_restrict="";;
3080   *) emacs_restrict="$emacs_cv_c_restrict";;
3081 esac
3082 if test "$emacs_restrict" != __restrict; then
3083   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3084     [Define to compiler's equivalent of C99 restrict keyword.
3085      Don't define if equivalent is `__restrict'.])
3086 fi
3087
3088 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3089   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3090                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3091 if test "$emacs_cv_c_restrict_arr" = yes; then
3092   AC_DEFINE(__restrict_arr, __restrict,
3093     [Define to compiler's equivalent of C99 restrict keyword in array
3094      declarations.  Define as empty for no equivalent.])
3095 fi
3096
3097 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3098 dnl how the tty code is related to POSIX and/or other versions of termios.
3099 dnl The following looks like a useful start.
3100 dnl
3101 dnl AC_SYS_POSIX_TERMIOS
3102 dnl if test $ac_cv_sys_posix_termios = yes; then
3103 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3104 dnl                                and macros for terminal control.])
3105 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3106 dnl fi
3107
3108 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3109
3110 # Set up the CFLAGS for real compilation, so we can substitute it.
3111 CFLAGS="$REAL_CFLAGS"
3112 CPPFLAGS="$REAL_CPPFLAGS"
3113
3114 ## Hack to detect a buggy GCC version.
3115 if test "x$GCC" = xyes \
3116    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3117    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3118    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3119    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3120 fi
3121
3122 #### Find out which version of Emacs this is.
3123 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3124          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3125 if test x"${version}" = x; then
3126   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3127 fi
3128 if test x"${version}" != x"$PACKAGE_VERSION"; then
3129   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3130 fi
3131
3132 ### Specify what sort of things we'll be editing into Makefile and config.h.
3133 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3134 AC_SUBST(version)
3135 AC_SUBST(configuration)
3136 ## Unused?
3137 AC_SUBST(canonical)
3138 AC_SUBST(srcdir)
3139 AC_SUBST(prefix)
3140 AC_SUBST(exec_prefix)
3141 AC_SUBST(bindir)
3142 AC_SUBST(datadir)
3143 AC_SUBST(sharedstatedir)
3144 AC_SUBST(libexecdir)
3145 AC_SUBST(mandir)
3146 AC_SUBST(infodir)
3147 AC_SUBST(lispdir)
3148 AC_SUBST(locallisppath)
3149 AC_SUBST(lisppath)
3150 AC_SUBST(x_default_search_path)
3151 AC_SUBST(etcdir)
3152 AC_SUBST(archlibdir)
3153 AC_SUBST(docdir)
3154 AC_SUBST(bitmapdir)
3155 AC_SUBST(gamedir)
3156 AC_SUBST(gameuser)
3157 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3158 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3159 ## end of LIBX_BASE, but nothing ever set it.
3160 AC_SUBST(LD_SWITCH_X_SITE)
3161 AC_SUBST(C_SWITCH_X_SITE)
3162 AC_SUBST(C_SWITCH_X_SYSTEM)
3163 AC_SUBST(CFLAGS)
3164 ## Used in lwlib/Makefile.in.
3165 AC_SUBST(X_TOOLKIT_TYPE)
3166 AC_SUBST(machfile)
3167 AC_SUBST(opsysfile)
3168 AC_SUBST(GETLOADAVG_LIBS)
3169 AC_SUBST(ns_appdir)
3170 AC_SUBST(ns_appbindir)
3171 AC_SUBST(ns_appresdir)
3172 AC_SUBST(ns_appsrc)
3173 AC_SUBST(GNU_OBJC_CFLAGS)
3174 AC_SUBST(OTHER_FILES)
3175
3176 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3177                    [Define to the canonical Emacs configuration name.])
3178 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3179                    [Define to the options passed to configure.])
3180 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3181                    [Define to the used machine dependent file.])
3182 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3183                    [Define to the used os dependent file.])
3184
3185 XMENU_OBJ=
3186 XOBJ=
3187 FONT_OBJ=
3188 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3189   AC_DEFINE(HAVE_X_WINDOWS, 1,
3190             [Define to 1 if you want to use the X window system.])
3191   XMENU_OBJ=xmenu.o
3192   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3193   FONT_OBJ=xfont.o
3194   if test "$HAVE_XFT" = "yes"; then
3195     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3196   elif test "$HAVE_FREETYPE" = "yes"; then
3197     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3198   fi
3199   AC_SUBST(FONT_OBJ)
3200 fi
3201 AC_SUBST(XMENU_OBJ)
3202 AC_SUBST(XOBJ)
3203 AC_SUBST(FONT_OBJ)
3204
3205 WIDGET_OBJ=
3206 MOTIF_LIBW=
3207 if test "${USE_X_TOOLKIT}" != "none" ; then
3208   WIDGET_OBJ=widget.o
3209   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3210   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3211     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3212   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3213     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3214     MOTIF_LIBW=-lXm
3215     case "$opsys" in
3216       gnu-linux)
3217         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3218         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3219         ;;
3220
3221       unixware)
3222         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3223         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3224         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3225         ;;
3226
3227       aix4-2)
3228         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3229         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3230         ;;
3231     esac
3232     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3233   fi
3234 fi
3235 AC_SUBST(WIDGET_OBJ)
3236
3237 TOOLKIT_LIBW=
3238 case "$USE_X_TOOLKIT" in
3239   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3240   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3241   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3242 esac
3243 AC_SUBST(TOOLKIT_LIBW)
3244
3245 if test "$USE_X_TOOLKIT" = "none"; then
3246   LIBXT_OTHER="\$(LIBXSM)"
3247   OLDXMENU_TARGET="really-oldXMenu"
3248 else
3249   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3250   OLDXMENU_TARGET="really-lwlib"
3251 fi
3252 AC_SUBST(LIBXT_OTHER)
3253
3254 ## The X Menu stuff is present in the X10 distribution, but missing
3255 ## from X11.  If we have X10, just use the installed library;
3256 ## otherwise, use our own copy.
3257 if test "${HAVE_X11}" = "yes" ; then
3258   AC_DEFINE(HAVE_X11, 1,
3259             [Define to 1 if you want to use version 11 of X windows.
3260              Otherwise, Emacs expects to use version 10.])
3261
3262   if test "$USE_X_TOOLKIT" = "none"; then
3263     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3264   else
3265     OLDXMENU="\${lwlibdir}liblw.a"
3266   fi
3267   LIBXMENU="\$(OLDXMENU)"
3268   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3269   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3270 else
3271   ## For a syntactically valid Makefile; not actually used for anything.
3272   ## See comments in src/Makefile.in.
3273   OLDXMENU=nothing
3274   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3275   if test "${HAVE_X_WINDOWS}" = "yes"; then
3276     LIBXMENU="-lXMenu"
3277   else
3278     LIBXMENU=
3279   fi
3280   LIBX_OTHER=
3281   OLDXMENU_DEPS=
3282 fi
3283
3284 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3285   OLDXMENU_TARGET=
3286   OLDXMENU=nothing
3287   LIBXMENU=
3288   OLDXMENU_DEPS=
3289 fi
3290
3291 AC_SUBST(OLDXMENU_TARGET)
3292 AC_SUBST(OLDXMENU)
3293 AC_SUBST(LIBXMENU)
3294 AC_SUBST(LIBX_OTHER)
3295 AC_SUBST(OLDXMENU_DEPS)
3296
3297 if test "${HAVE_MENUS}" = "yes" ; then
3298   AC_DEFINE(HAVE_MENUS, 1,
3299             [Define to 1 if you have mouse menus.
3300              (This is automatic if you use X, but the option to specify it remains.)
3301              It is also defined with other window systems that support xmenu.c.])
3302 fi
3303
3304 if test "${GNU_MALLOC}" = "yes" ; then
3305   AC_DEFINE(GNU_MALLOC, 1,
3306             [Define to 1 if you want to use the GNU memory allocator.])
3307 fi
3308
3309 RALLOC_OBJ=
3310 if test "${REL_ALLOC}" = "yes" ; then
3311   AC_DEFINE(REL_ALLOC, 1,
3312             [Define REL_ALLOC if you want to use the relocating allocator for
3313              buffer space.])
3314
3315   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3316 fi
3317 AC_SUBST(RALLOC_OBJ)
3318
3319 if test "$opsys" = "cygwin"; then
3320   CYGWIN_OBJ="sheap.o"
3321   ## Cygwin differs because of its unexec().
3322   PRE_ALLOC_OBJ=
3323   POST_ALLOC_OBJ=lastfile.o
3324 else
3325   CYGWIN_OBJ=
3326   PRE_ALLOC_OBJ=lastfile.o
3327   POST_ALLOC_OBJ=
3328 fi
3329 AC_SUBST(CYGWIN_OBJ)
3330 AC_SUBST(PRE_ALLOC_OBJ)
3331 AC_SUBST(POST_ALLOC_OBJ)
3332
3333
3334 case "$opsys" in
3335   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3336
3337   darwin)
3338    ## The -headerpad option tells ld (see man page) to leave room at the
3339    ## end of the header for adding load commands.  Needed for dumping.
3340    ## 0x690 is the total size of 30 segment load commands (at 56
3341    ## each); under Cocoa 31 commands are required.
3342    if test "$HAVE_NS" = "yes"; then
3343      libs_nsgui="-framework AppKit"
3344      headerpad_extra=6C8
3345    else
3346      libs_nsgui=
3347      headerpad_extra=690
3348    fi
3349    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3350
3351    ## This is here because src/Makefile.in did some extra fiddling around
3352    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3353    ##   #ifndef LD_SWITCH_SYSTEM
3354    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3355    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3356    ## not using gcc, darwin system not on an alpha (ie darwin, since
3357    ## darwin + alpha does not occur).
3358    ## Because this was done in src/Makefile.in, the resulting part of
3359    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3360    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3361    ## rather than LD_SWITCH_SYSTEM.
3362    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3363      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3364    ;;
3365
3366   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3367   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3368   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3369   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3370   ## had different values in configure (in ac_link) and src/Makefile.in.
3371   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3372   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3373
3374   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3375 esac
3376
3377 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3378   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3379 fi
3380
3381 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3382
3383
3384 LD_FIRSTFLAG=
3385 ORDINARY_LINK=
3386 case "$opsys" in
3387   ## gnu: GNU needs its own crt0.
3388   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3389
3390   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3391   ## library search parth, i.e. it won't search /usr/lib for libc and
3392   ## friends.  Using -nostartfiles instead avoids this problem, and
3393   ## will also work on earlier NetBSD releases.
3394   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3395
3396   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3397   ##   MkLinux/LinuxPPC needs this.
3398   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3399   gnu-*)
3400     case "$machine" in
3401       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3402     esac
3403     ;;
3404 esac
3405
3406
3407 if test "x$ORDINARY_LINK" = "xyes"; then
3408
3409   LD_FIRSTFLAG=""
3410   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3411
3412 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3413 ## freebsd, gnu-* not on macppc|ibms390x.
3414 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3415
3416   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3417   ## places that are difficult to figure out at make time.  Fortunately,
3418   ## these same versions allow you to pass arbitrary flags on to the
3419   ## linker, so there is no reason not to use it as a linker.
3420   ##
3421   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3422   ## searching for libraries in its internal directories, so we have to
3423   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3424   LD_FIRSTFLAG="-nostdlib"
3425 fi
3426
3427 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3428 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3429
3430 AC_SUBST(LD_FIRSTFLAG)
3431
3432
3433 ## FIXME? The logic here is not precisely the same as that above.
3434 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3435 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3436 LIB_GCC=
3437 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3438
3439   case "$opsys" in
3440     freebsd|netbsd|openbsd) LIB_GCC= ;;
3441
3442     gnu-*)
3443       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3444       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3445       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3446       if test "$machine" = "arm"; then
3447         LIB_GCC="-lgcc_s"
3448       else
3449         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3450         ## immediately undefine it again and redefine it to empty.
3451         ## Was the C_SWITCH_X_SITE part really necessary?
3452 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3453         LIB_GCC=
3454       fi
3455       ;;
3456
3457     ## Ask GCC where to find libgcc.a.
3458     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3459   esac
3460 fi                              dnl if $GCC
3461 AC_SUBST(LIB_GCC)
3462
3463
3464 TOOLTIP_SUPPORT=
3465 WINDOW_SUPPORT=
3466 ## If we're using X11/GNUstep, define some consequences.
3467 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3468   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3469   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3470   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3471   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3472
3473   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3474   test "$HAVE_X_WINDOWS" = "yes" && \
3475     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3476
3477 fi
3478 AC_SUBST(MOUSE_SUPPORT)
3479 AC_SUBST(TOOLTIP_SUPPORT)
3480 AC_SUBST(WINDOW_SUPPORT)
3481
3482
3483 AH_TOP([/* GNU Emacs site configuration template file.
3484    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3485      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3486
3487 This file is part of GNU Emacs.
3488
3489 GNU Emacs is free software: you can redistribute it and/or modify
3490 it under the terms of the GNU General Public License as published by
3491 the Free Software Foundation, either version 3 of the License, or
3492 (at your option) any later version.
3493
3494 GNU Emacs is distributed in the hope that it will be useful,
3495 but WITHOUT ANY WARRANTY; without even the implied warranty of
3496 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3497 GNU General Public License for more details.
3498
3499 You should have received a copy of the GNU General Public License
3500 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3501
3502
3503 /* No code in Emacs #includes config.h twice, but some bits of code
3504    intended to work with other packages as well (like gmalloc.c)
3505    think they can include it as many times as they like.  */
3506 #ifndef EMACS_CONFIG_H
3507 #define EMACS_CONFIG_H
3508 ])dnl
3509
3510 AH_BOTTOM([
3511 /* Define AMPERSAND_FULL_NAME if you use the convention
3512    that & in the full name stands for the login id.  */
3513 /* Turned on June 1996 supposing nobody will mind it.  */
3514 #define AMPERSAND_FULL_NAME
3515
3516 /* If using GNU, then support inline function declarations.  */
3517 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3518    generally, because even if non-gcc compilers accept `inline', they
3519    may reject `extern inline'.  */
3520 #if defined (__GNUC__) && defined (OPTIMIZE)
3521 #define INLINE __inline__
3522 #else
3523 #define INLINE
3524 #endif
3525
3526 /* `subprocesses' should be defined if you want to
3527    have code for asynchronous subprocesses
3528    (as used in M-x compile and M-x shell).
3529    Only MSDOS does not support this (it overrides
3530    this in its config_opsysfile below).  */
3531
3532 #define subprocesses
3533
3534 /* Include the os and machine dependent files.  */
3535 #include config_opsysfile
3536 #include config_machfile
3537
3538 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3539   (There is probably a better place to do this, but right now the Cocoa
3540    side does this in s/darwin.h and we cannot
3541    parallel this exactly since GNUstep is multi-OS.  */
3542 #ifdef HAVE_NS
3543 # ifdef NS_IMPL_GNUSTEP
3544 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3545 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3546 #  define SYSTEM_PURESIZE_EXTRA 30000
3547 # endif /* NS_IMPL_GNUSTEP */
3548 #endif /* HAVE_NS */
3549
3550 /* SIGTYPE is the macro we actually use.  */
3551 #ifndef SIGTYPE
3552 #define SIGTYPE RETSIGTYPE
3553 #endif
3554
3555 #ifdef emacs /* Don't do this for lib-src.  */
3556 /* Tell regex.c to use a type compatible with Emacs.  */
3557 #define RE_TRANSLATE_TYPE Lisp_Object
3558 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3559 #ifdef make_number
3560 /* If make_number is a macro, use it.  */
3561 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3562 #else
3563 /* If make_number is a function, avoid it.  */
3564 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3565 #endif
3566 #endif
3567
3568 /* Avoid link-time collision with system mktime if we will use our own.  */
3569 #if ! HAVE_MKTIME || BROKEN_MKTIME
3570 #define mktime emacs_mktime
3571 #endif
3572
3573 #define my_strftime nstrftime   /* for strftime.c */
3574
3575 /* These default definitions are good for almost all machines.
3576    The exceptions override them in m/MACHINE.h.  */
3577
3578 #ifndef BITS_PER_CHAR
3579 #define BITS_PER_CHAR 8
3580 #endif
3581
3582 #ifndef BITS_PER_SHORT
3583 #define BITS_PER_SHORT 16
3584 #endif
3585
3586 /* Note that lisp.h uses this in a preprocessor conditional, so it
3587    would not work to use sizeof.  That being so, we do all of them
3588    without sizeof, for uniformity's sake.  */
3589 #ifndef BITS_PER_INT
3590 #define BITS_PER_INT 32
3591 #endif
3592
3593 #ifndef BITS_PER_LONG
3594 #ifdef _LP64
3595 #define BITS_PER_LONG 64
3596 #else
3597 #define BITS_PER_LONG 32
3598 #endif
3599 #endif
3600
3601 /* Define if the compiler supports function prototypes.  It may do so but
3602    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3603 #undef PROTOTYPES
3604
3605 #ifdef HAVE_STRING_H
3606 #include <string.h>
3607 #endif
3608
3609 #ifdef HAVE_STDLIB_H
3610 #include <stdlib.h>
3611 #endif
3612
3613 #ifdef HAVE_ALLOCA_H
3614 # include <alloca.h>
3615 #elif defined __GNUC__
3616 # define alloca __builtin_alloca
3617 #elif defined _AIX
3618 # define alloca __alloca
3619 #else
3620 # include <stddef.h>
3621 # ifdef  __cplusplus
3622 extern "C"
3623 # endif
3624 void *alloca (size_t);
3625 #endif
3626
3627 #ifndef HAVE_SIZE_T
3628 typedef unsigned size_t;
3629 #endif
3630
3631 #ifndef HAVE_STRCHR
3632 #define strchr(a, b) index (a, b)
3633 #endif
3634
3635 #ifndef HAVE_STRRCHR
3636 #define strrchr(a, b) rindex (a, b)
3637 #endif
3638
3639 #if defined __GNUC__ && (__GNUC__ > 2 \
3640                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3641 #define NO_RETURN       __attribute__ ((__noreturn__))
3642 #else
3643 #define NO_RETURN       /* nothing */
3644 #endif
3645
3646 /* These won't be used automatically yet.  We also need to know, at least,
3647    that the stack is continuous.  */
3648 #ifdef __GNUC__
3649 #  ifndef GC_SETJMP_WORKS
3650   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3651 #    define GC_SETJMP_WORKS 1
3652 #  endif
3653 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3654 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3655 #  endif
3656 #endif
3657
3658 #endif /* EMACS_CONFIG_H */
3659
3660 /*
3661 Local Variables:
3662 mode: c
3663 End:
3664 */
3665 ])dnl
3666
3667 #### Report on what we decided to do.
3668 #### Report GTK as a toolkit, even if it doesn't use Xt.
3669 #### It makes printing result more understandable as using GTK sets
3670 #### toolkit_scroll_bars to yes by default.
3671 if test "${HAVE_GTK}" = "yes"; then
3672   USE_X_TOOLKIT=GTK
3673 fi
3674
3675 echo "
3676 Configured for \`${canonical}'.
3677
3678   Where should the build process find the source code?    ${srcdir}
3679   What operating system and machine description files should Emacs use?
3680         \`${opsysfile}' and \`${machfile}'
3681   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3682   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3683   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3684   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3685   What window system should Emacs use?                    ${window_system}
3686   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3687
3688 if test -n "${x_includes}"; then
3689 echo "  Where do we find X Windows header files?                ${x_includes}"
3690 else
3691 echo "  Where do we find X Windows header files?                Standard dirs"
3692 fi
3693 if test -n "${x_libraries}"; then
3694 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3695 else
3696 echo "  Where do we find X Windows libraries?                   Standard dirs"
3697 fi
3698
3699 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3700 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3701 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3702 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3703 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3704 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3705 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3706 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3707
3708 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3709 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3710 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3711 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3712 echo "  Does Emacs use -lgnutls (BROKEN)?                       ${HAVE_GNUTLS}"
3713 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3714
3715 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3716 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3717 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3718 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3719
3720 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3721 echo
3722
3723 if test $USE_XASSERTS = yes; then
3724    echo "  Compiling with asserts turned on."
3725    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3726 fi
3727
3728 echo
3729
3730 if test "$HAVE_NS" = "yes"; then
3731    echo
3732    echo "You must run \"make install\" in order to test the built application.
3733 The installed application will go to nextstep/Emacs.app and can be
3734 run or moved from there."
3735    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3736       echo "The application will be fully self-contained."
3737     else
3738       echo "The lisp resources for the application will be installed under ${prefix}.
3739 You may need to run \"make install\" with sudo.  The application will fail
3740 to run if these resources are not installed."
3741    fi
3742    echo
3743 fi
3744
3745 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3746   echo "D-Bus integration has been tested for GNU/Linux only."
3747   echo
3748 fi
3749
3750
3751 # Remove any trailing slashes in these variables.
3752 [test "${prefix}" != NONE &&
3753   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3754 test "${exec_prefix}" != NONE &&
3755   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3756
3757 dnl You might wonder (I did) why epaths.h is generated by running make,
3758 dnl rather than just letting configure generate it from epaths.in.
3759 dnl One reason is that the various paths are not fully expanded (see above);
3760 dnl eg gamedir=${prefix}/var/games/emacs.
3761 dnl Secondly, the GNU Coding standards require that one should be able
3762 dnl to run `make prefix=/some/where/else' and override the values set
3763 dnl by configure.  This also explains the `move-if-change' test and
3764 dnl the use of force in the `epaths-force' rule in Makefile.in.
3765 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3766         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3767         doc/lispref/Makefile src/Makefile \
3768         lwlib/Makefile lisp/Makefile leim/Makefile, [
3769
3770 ### Make the necessary directories, if they don't exist.
3771 for dir in etc lisp ; do
3772   test -d ${dir} || mkdir ${dir}
3773 done
3774
3775 echo creating src/epaths.h
3776 ${MAKE-make} epaths-force
3777
3778 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3779   echo creating src/.gdbinit
3780   echo source $srcdir/src/.gdbinit > src/.gdbinit
3781 fi
3782
3783 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3784
3785 m4_if(dnl       Do not change this comment
3786    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3787 )dnl