configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.0)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h)
   8
   9 bindir='${exec_prefix}/bin'
  10 datadir='${prefix}/share'
  11 sharedstatedir='${prefix}/com'
  12 libexecdir='${exec_prefix}/libexec'
  13 mandir='${prefix}/man/man1'
  14 infodir='${prefix}/info'
  15 lispdir='${datadir}/emacs/${version}/lisp'
  16 locallisppath='${datadir}/emacs/site-lisp'
  17 lisppath='${locallisppath}:${lispdir}'
  18 etcdir='${datadir}/emacs/${version}/etc'
  19 lockdir='${sharedstatedir}/emacs/lock'
  20 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  21 docdir='${datadir}/emacs/${version}/etc'
  22
  23 AC_ARG_WITH(gcc,
  24 [  --with-gcc              use GCC to compile Emacs])
  25 AC_ARG_WITH(pop,
  26 [  --with-pop              support POP for mail retrieval],
  27 [AC_DEFINE(MAIL_USE_POP)])
  28 AC_ARG_WITH(kerberos,
  29 [  --with-kerberos         support Kerberos-authenticated POP],
  30 [AC_DEFINE(KERBEROS)])
  31 AC_ARG_WITH(hesiod,
  32 [  --with-hesiod           support Hesiod to get the POP server host],
  33 [AC_DEFINE(HESIOD)])
  34 dnl This should be the last --with option, because --with-x is
  35 dnl added later on when we find the path of X, and it's best to
  36 dnl keep them together visually.
  37 AC_ARG_WITH(x-toolkit,
  38 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif)],
  39 [         case "${withval}" in
  40             y | ye | yes )      val=athena ;;
  41             n | no )            val=no  ;;
  42             l | lu | luc | luci | lucid )       val=lucid ;;
  43             a | at | ath | athe | athena )      val=athena ;;
  44             m | mo | mot | moti | motif )       val=motif ;;
  45 dnl These don't currently work.
  46 dnl         o | op | ope | open | open- | open-l | open-lo \
  47 dnl             | open-loo | open-look )        val=open-look ;;
  48             * )
  49 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  50 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  51 AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  52 which is \`yes', \`no', \`lucid', \`athena', or \`motif'.
  53 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  54             ;;
  55           esac
  56           with_x_toolkit=$val
  57 ])
  58
  59 #### Make srcdir absolute, if it isn't already.  It's important to
  60 #### avoid running the path through pwd unnecessary, since pwd can
  61 #### give you automounter prefixes, which can go away.  We do all this
  62 #### so Emacs can find its files when run uninstalled.
  63 case "${srcdir}" in
  64   /* ) ;;
  65   . )
  66     ## We may be able to use the $PWD environment variable to make this
  67     ## absolute.  But sometimes PWD is inaccurate.
  68     ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
  69     CDPATH=
  70     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  71     then
  72       srcdir="$PWD"
  73     else
  74       srcdir="`(cd ${srcdir}; pwd)`"
  75     fi
  76   ;;
  77   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  78 esac
  79
  80 #### Check if the source directory already has a configured system in it.
  81 if test `pwd` != `(cd ${srcdir} && pwd)` \
  82    && test -f "${srcdir}/src/config.h" ; then
  83   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  84    as a build directory right now; it has been configured in its own
  85    right.  To configure in another directory as well, you MUST
  86    use GNU make.  If you do not have GNU make, then you must
  87    now do \`make distclean' in ${srcdir},
  88    and then run $0 again.])
  89
  90 changequote(, )dnl
  91   extrasub='/^VPATH[     ]*=/c\
  92 changequote([, ])dnl
  93 vpath %.c $(srcdir)\
  94 vpath %.h $(srcdir)\
  95 vpath %.y $(srcdir)\
  96 vpath %.l $(srcdir)\
  97 vpath %.s $(srcdir)\
  98 vpath %.in $(srcdir)'
  99 fi
 100
 101 #### Given the configuration name, set machfile and opsysfile to the
 102 #### names of the m/*.h and s/*.h files we should use.
 103
 104 ### Canonicalize the configuration name.
 105
 106 AC_CANONICAL_HOST
 107 canonical=$host
 108 configuration=$host_alias
 109
 110 changequote(, )dnl
 111
 112 ### If you add support for a new configuration, add code to this
 113 ### switch statement to recognize your configuration name and select
 114 ### the appropriate operating system and machine description files.
 115
 116 ### You would hope that you could choose an m/*.h file pretty much
 117 ### based on the machine portion of the configuration name, and an s-
 118 ### file based on the operating system portion.  However, it turns out
 119 ### that each m/*.h file is pretty manufacturer-specific - for
 120 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 121 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 122 ### machines.  So we basically have to have a special case for each
 123 ### configuration name.
 124 ###
 125 ### As far as handling version numbers on operating systems is
 126 ### concerned, make sure things will fail in a fixable way.  If
 127 ### /etc/MACHINES doesn't say anything about version numbers, be
 128 ### prepared to handle anything reasonably.  If version numbers
 129 ### matter, be sure /etc/MACHINES says something about it.
 130 ###
 131 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 132 ### "System V Release 4"; he writes, "The old convention encouraged
 133 ### confusion between `system' and `release' levels'."
 134
 135 machine='' opsys='' unported=no
 136 case "${canonical}" in
 137
 138   ## NetBSD ports
 139   *-*-netbsd* )
 140     opsys=netbsd
 141     case "${canonical}" in
 142       i[345]86-*-netbsd*) machine=intel386 ;;
 143       m68k-*-netbsd*)
 144                         # This is somewhat bogus.
 145                         machine=hp9000s300 ;;
 146       mips-*-netbsd*)   machine=pmax ;;
 147       ns32k-*-netbsd*)  machine=ns32000 ;;
 148       sparc-*-netbsd*)  machine=sparc ;;
 149     esac
 150   ;;
 151
 152   ## Acorn RISCiX:
 153   arm-acorn-riscix1.1* )
 154     machine=acorn opsys=riscix1-1
 155   ;;
 156   arm-acorn-riscix1.2* | arm-acorn-riscix )
 157     machine=acorn opsys=riscix1-2
 158   ;;
 159
 160   ## Alliant machines
 161   ## Strictly speaking, we need the version of the alliant operating
 162   ## system to choose the right machine file, but currently the
 163   ## configuration name doesn't tell us enough to choose the right
 164   ## one; we need to give alliants their own operating system name to
 165   ## do this right.  When someone cares, they can help us.
 166   fx80-alliant-* )
 167     machine=alliant4 opsys=bsd4-2
 168   ;;
 169   i860-alliant-* )
 170     machine=alliant-2800 opsys=bsd4-3
 171   ;;
 172
 173   alpha-dec-osf* )
 174     machine=alpha opsys=osf1
 175   ;;
 176
 177   ## Altos 3068
 178   m68*-altos-sysv* )
 179     machine=altos opsys=usg5-2
 180   ;;
 181
 182   ## Amdahl UTS
 183   580-amdahl-sysv* )
 184     machine=amdahl opsys=usg5-2-2
 185   ;;
 186
 187   ## Apollo, Domain/OS
 188   m68*-apollo-* )
 189     machine=apollo opsys=bsd4-3
 190   ;;
 191
 192   ## AT&T 3b2, 3b5, 3b15, 3b20
 193   we32k-att-sysv* )
 194     machine=att3b opsys=usg5-2-2
 195   ;;
 196
 197   ## AT&T 3b1 - The Mighty Unix PC!
 198   m68*-att-sysv* )
 199     machine=7300 opsys=usg5-2-2
 200   ;;
 201
 202   ## Bull dpx20
 203   rs6000-bull-bosx* )
 204     machine=ibmrs6000 opsys=aix3-2
 205   ;;
 206
 207   ## Bull dpx2
 208   m68*-bull-sysv3* )
 209     machine=dpx2 opsys=usg5-3
 210   ;;
 211
 212   ## Bull sps7
 213   m68*-bull-sysv2* )
 214     machine=sps7 opsys=usg5-2
 215   ;;
 216
 217   ## CCI 5/32, 6/32 -- see "Tahoe".
 218
 219   ## Celerity
 220   ## I don't know what configuration name to use for this; config.sub
 221   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 222   ## in touch with us!
 223   celerity-celerity-bsd* )
 224     machine=celerity opsys=bsd4-2
 225   ;;
 226
 227   ## Clipper
 228   ## What operating systems does this chip run that Emacs has been
 229   ## tested on?
 230   clipper-* )
 231     machine=clipper
 232     ## We'll use the catch-all code at the bottom to guess the
 233     ## operating system.
 234   ;;
 235
 236   ## Convex
 237   *-convex-bsd* | *-convex-convexos* )
 238     machine=convex opsys=bsd4-3
 239     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 240     NON_GNU_CPP="cc -E -P"
 241   ;;
 242
 243   ## Cubix QBx/386
 244   i[345]86-cubix-sysv* )
 245     machine=intel386 opsys=usg5-3
 246   ;;
 247
 248   ## Cydra 5
 249   cydra*-cydrome-sysv* )
 250     machine=cydra5 opsys=usg5-3
 251   ;;
 252
 253   ## Data General AViiON Machines
 254   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 255     machine=aviion opsys=dgux5-4r3
 256   ;;
 257   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 258     machine=aviion opsys=dgux5-4r2
 259   ;;
 260   m88k-dg-dgux* )
 261     machine=aviion opsys=dgux
 262   ;;
 263
 264   ## DECstations
 265   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 266     machine=pmax opsys=bsd4-2
 267   ;;
 268   mips-dec-ultrix* | mips-dec-bsd* )
 269     machine=pmax opsys=bsd4-3
 270   ;;
 271   mips-dec-osf* )
 272     machine=pmax opsys=osf1
 273   ;;
 274
 275   ## Motorola Delta machines
 276   m68k-motorola-sysv* | m68000-motorola-sysv* )
 277     machine=delta opsys=usg5-3
 278     if test -z "`type gnucc | grep 'not found'`"
 279     then
 280       if test -s /etc/167config
 281       then CC="gnucc -m68040"
 282       else CC="gnucc -m68881"
 283       fi
 284     else
 285       if test -z "`type gcc | grep 'not found'`"
 286       then CC=gcc
 287       else CC=cc
 288       fi
 289     fi
 290   ;;
 291   m88k-motorola-sysv4* )
 292     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 293     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 294     # I hope there are not other 4.0 versions for this machine
 295     # which really need usg5-4 instead.
 296     machine=delta88k opsys=usg5-4-2
 297   ;;
 298   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 299     machine=delta88k opsys=usg5-3
 300   ;;
 301
 302   ## Dual machines
 303   m68*-dual-sysv* )
 304     machine=dual opsys=usg5-2
 305   ;;
 306   m68*-dual-uniplus* )
 307     machine=dual opsys=unipl5-2
 308   ;;
 309
 310   ## Elxsi 6400
 311   elxsi-elxsi-sysv* )
 312     machine=elxsi opsys=usg5-2
 313   ;;
 314
 315   ## Encore machines
 316   ns16k-encore-bsd* )
 317     machine=ns16000 opsys=umax
 318   ;;
 319
 320   ## The GEC 93 - apparently, this port isn't really finished yet.
 321
 322   ## Gould Power Node and NP1
 323   pn-gould-bsd4.2* )
 324     machine=gould opsys=bsd4-2
 325   ;;
 326   pn-gould-bsd4.3* )
 327     machine=gould opsys=bsd4-3
 328   ;;
 329   np1-gould-bsd* )
 330     machine=gould-np1 opsys=bsd4-3
 331   ;;
 332
 333   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 334   ## as far as Emacs is concerned).
 335   m88k-harris-cxux* )
 336     # Build needs to be different on 7.0 and later releases
 337     case "`uname -r`" in
 338        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 339        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 340     esac
 341   ;;
 342   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 343   m68k-harris-cxux* )
 344     machine=nh3000 opsys=cxux
 345   ;;
 346
 347   ## Honeywell XPS100
 348   xps*-honeywell-sysv* )
 349     machine=xps100 opsys=usg5-2
 350   ;;
 351
 352   ## HP 9000 series 200 or 300
 353   m68*-hp-bsd* )
 354     machine=hp9000s300 opsys=bsd4-3
 355   ;;
 356   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 357   m68*-hp-hpux* )
 358     case "`uname -r`" in
 359       ## Someone's system reports A.B8.05 for this.
 360       ## I wonder what other possibilities there are.
 361       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 362       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 363       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 364       *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
 365       *) machine=hp9000s300 opsys=hpux ;;
 366     esac
 367   ;;
 368
 369   ## HP 9000 series 700 and 800, running HP/UX
 370   hppa*-hp-hpux7* )
 371     machine=hp800 opsys=hpux
 372   ;;
 373   hppa*-hp-hpux8* )
 374     machine=hp800 opsys=hpux8
 375   ;;
 376   hppa*-hp-hpux9shr* )
 377     machine=hp800 opsys=hpux9shr
 378   ;;
 379   hppa*-hp-hpux9* )
 380     machine=hp800 opsys=hpux9
 381   ;;
 382   hppa*-hp-hpux10* )
 383     machine=hp800 opsys=hpux9shr
 384   ;;
 385
 386   ## HP 9000 series 700 and 800, running HP/UX
 387   hppa*-hp-hpux* )
 388     ## Cross-compilation?  Nah!
 389     case "`uname -r`" in
 390       ## Someone's system reports A.B8.05 for this.
 391       ## I wonder what other possibilities there are.
 392       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 393       *.08.* ) machine=hp800 opsys=hpux8 ;;
 394       *.09.* ) machine=hp800 opsys=hpux9 ;;
 395       *) machine=hp800 opsys=hpux ;;
 396     esac
 397   ;;
 398
 399   ## Orion machines
 400   orion-orion-bsd* )
 401     machine=orion opsys=bsd4-2
 402   ;;
 403   clipper-orion-bsd* )
 404     machine=orion105 opsys=bsd4-2
 405   ;;
 406
 407   ## IBM machines
 408   i[345]86-ibm-aix1.1* )
 409     machine=ibmps2-aix opsys=usg5-2-2
 410   ;;
 411   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 412     machine=ibmps2-aix opsys=usg5-3
 413   ;;
 414   i370-ibm-aix*)
 415     machine=ibm370aix opsys=usg5-3
 416   ;;
 417   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 418     machine=ibmrs6000 opsys=aix3-1
 419   ;;
 420   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 421     machine=ibmrs6000 opsys=aix3-2-5
 422   ;;
 423   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 424     machine=ibmrs6000 opsys=aix4-1
 425   ;;
 426   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 427     machine=ibmrs6000 opsys=aix4
 428   ;;
 429   rs6000-ibm-aix* | powerpc-ibm-aix* )
 430     machine=ibmrs6000 opsys=aix3-2
 431   ;;
 432   romp-ibm-bsd4.3* )
 433     machine=ibmrt opsys=bsd4-3
 434   ;;
 435   romp-ibm-bsd4.2* )
 436     machine=ibmrt opsys=bsd4-2
 437   ;;
 438   romp-ibm-aos4.3* )
 439     machine=ibmrt opsys=bsd4-3
 440   ;;
 441   romp-ibm-aos4.2* )
 442     machine=ibmrt opsys=bsd4-2
 443   ;;
 444   romp-ibm-aos* )
 445     machine=ibmrt opsys=bsd4-3
 446   ;;
 447   romp-ibm-bsd* )
 448     machine=ibmrt opsys=bsd4-3
 449   ;;
 450   romp-ibm-aix* )
 451     machine=ibmrt-aix opsys=usg5-2-2
 452   ;;
 453
 454   ## Integrated Solutions `Optimum V'
 455   m68*-isi-bsd4.2* )
 456     machine=isi-ov opsys=bsd4-2
 457   ;;
 458   m68*-isi-bsd4.3* )
 459     machine=isi-ov opsys=bsd4-3
 460   ;;
 461
 462   ## Intel 386 machines where we do care about the manufacturer
 463   i[345]86-intsys-sysv* )
 464     machine=is386 opsys=usg5-2-2
 465   ;;
 466
 467   ## Prime EXL
 468   i[345]86-prime-sysv* )
 469     machine=i386 opsys=usg5-3
 470   ;;
 471
 472   ## Sequent Symmetry running Dynix
 473   i[345]86-sequent-bsd* )
 474     machine=symmetry opsys=bsd4-3
 475   ;;
 476
 477   ## Sequent Symmetry running DYNIX/ptx
 478   ## Use the old cpp rather than the newer ANSI one.
 479   i[345]86-sequent-ptx* )
 480     machine=sequent-ptx opsys=ptx
 481     NON_GNU_CPP="/lib/cpp"
 482   ;;
 483
 484   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 485   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 486   i[345]86-ncr-sysv* )
 487     machine=ncr386 opsys=usg5-4-2
 488   ;;
 489
 490   ## Intel Paragon OSF/1
 491   i860-intel-osf1* )
 492     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 493   ;;
 494
 495   ## Intel 860
 496   i860-*-sysv4* )
 497     machine=i860 opsys=usg5-4
 498     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 499     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 500   ;;
 501
 502   ## Masscomp machines
 503   m68*-masscomp-rtu* )
 504     machine=masscomp opsys=rtu
 505   ;;
 506
 507   ## Megatest machines
 508   m68*-megatest-bsd* )
 509     machine=mega68 opsys=bsd4-2
 510   ;;
 511
 512   ## Workstations sold by MIPS
 513   ## This is not necessarily all workstations using the MIPS processor -
 514   ## Irises are produced by SGI, and DECstations by DEC.
 515
 516   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 517   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 518   ## it gives for choosing between the alternatives seems to be "Use
 519   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 520   ## the BSD world."  I'll assume that these are instructions for
 521   ## handling two odd situations, and that every other situation
 522   ## should use mips.h and usg5-2-2, they being listed first.
 523   mips-mips-usg* )
 524     machine=mips4
 525     ## Fall through to the general code at the bottom to decide on the OS.
 526   ;;
 527   mips-mips-riscos4* )
 528     machine=mips4 opsys=bsd4-3
 529     NON_GNU_CC="cc -systype bsd43"
 530     NON_GNU_CPP="cc -systype bsd43 -E"
 531   ;;
 532   mips-mips-bsd* )
 533     machine=mips opsys=bsd4-3
 534   ;;
 535   mips-mips-* )
 536     machine=mips opsys=usg5-2-2
 537   ;;
 538
 539   ## NeXT
 540   m68*-next-* | i[345]86-next-* )
 541     machine=next opsys=mach2
 542   ;;
 543
 544   ## The complete machine from National Semiconductor
 545   ns32k-ns-genix* )
 546     machine=ns32000 opsys=usg5-2
 547   ;;
 548
 549   ## NCR machines
 550   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 551     machine=tower32 opsys=usg5-2-2
 552   ;;
 553   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 554     machine=tower32v3 opsys=usg5-3
 555   ;;
 556
 557   ## Nixdorf Targon 31
 558   m68*-nixdorf-sysv* )
 559     machine=targon31 opsys=usg5-2-2
 560   ;;
 561
 562   ## Nu (TI or LMI)
 563   m68*-nu-sysv* )
 564     machine=nu opsys=usg5-2
 565   ;;
 566
 567   ## Plexus
 568   m68*-plexus-sysv* )
 569     machine=plexus opsys=usg5-2
 570   ;;
 571
 572   ## Pyramid machines
 573   ## I don't really have any idea what sort of processor the Pyramid has,
 574   ## so I'm assuming it is its own architecture.
 575   pyramid-pyramid-bsd* )
 576     machine=pyramid opsys=bsd4-2
 577   ;;
 578
 579   ## Sequent Balance
 580   ns32k-sequent-bsd4.2* )
 581     machine=sequent opsys=bsd4-2
 582   ;;
 583   ns32k-sequent-bsd4.3* )
 584     machine=sequent opsys=bsd4-3
 585   ;;
 586
 587   ## Siemens Nixdorf
 588   mips-siemens-sysv* )
 589     machine=mips-siemens opsys=usg5-4
 590     NON_GNU_CC=/usr/ccs/bin/cc
 591     NON_GNU_CPP=/usr/ccs/lib/cpp
 592   ;;
 593
 594   ## Silicon Graphics machines
 595   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 596   m68*-sgi-iris3.5* )
 597     machine=irist opsys=iris3-5
 598   ;;
 599   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 600     machine=irist opsys=iris3-6
 601   ;;
 602   ## Iris 4D
 603   mips-sgi-irix3* )
 604     machine=iris4d opsys=irix3-3
 605   ;;
 606   mips-sgi-irix4* )
 607     machine=iris4d opsys=irix4-0
 608   ;;
 609   mips-sgi-irix6* )
 610     machine=iris4d opsys=irix6-0
 611   ;;
 612   mips-sgi-irix5.[01]* )
 613     machine=iris4d opsys=irix5-0
 614   ;;
 615   mips-sgi-irix5* | mips-sgi-irix* )
 616     machine=iris4d opsys=irix5-2
 617   ;;
 618
 619   ## SONY machines
 620   m68*-sony-bsd4.2* )
 621     machine=news opsys=bsd4-2
 622   ;;
 623   m68*-sony-bsd4.3* )
 624     machine=news opsys=bsd4-3
 625   ;;
 626   m68*-sony-newsos3* | m68*-sony-news3*)
 627     machine=news opsys=bsd4-3
 628   ;;
 629   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 630     machine=news-risc opsys=bsd4-3
 631   ;;
 632   mips-sony-news* )
 633     machine=news-risc opsys=newsos5
 634   ;;
 635
 636   ## Stride
 637   m68*-stride-sysv* )
 638     machine=stride opsys=usg5-2
 639   ;;
 640
 641   ## Suns
 642   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* | i[345]86-*-solaris2* | i[345]86-*-sunos5* )
 643     case "${canonical}" in
 644       m68*-sunos1* )    machine=sun1 ;;
 645       m68*-sunos2* )    machine=sun2 ;;
 646       m68* )            machine=sun3 ;;
 647       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 648       i[345]86-*-* )     machine=intel386 ;;
 649       sparc* )          machine=sparc ;;
 650       * )               unported=yes ;;
 651     esac
 652     case "${canonical}" in
 653       ## The Sun386 didn't get past 4.0.
 654       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 655       *-sunos4.0*         ) opsys=sunos4-0 ;;
 656       *-sunos4.1.3* | *-sunos4shr*  ) opsys=sunos4shr
 657                 NON_GNU_CPP=/usr/lib/cpp
 658                 ;;
 659       *-sunos4* | *-sunos ) opsys=sunos4-1
 660                 NON_GCC_TEST_OPTIONS=-Bstatic
 661                 GCC_TEST_OPTIONS=-static
 662                 ;;
 663       *-sunos5.3* | *-solaris2.3* )
 664                 opsys=sol2-3
 665                 NON_GNU_CPP=/usr/ccs/lib/cpp
 666                 ;;
 667       *-sunos5.4* | *-solaris2.4* )
 668                 opsys=sol2-4
 669                 NON_GNU_CPP=/usr/ccs/lib/cpp
 670                 ;;
 671       *-sunos5* | *-solaris* )
 672                 opsys=sol2
 673                 NON_GNU_CPP=/usr/ccs/lib/cpp
 674                 ;;
 675       *                   ) opsys=bsd4-2   ;;
 676     esac
 677   ;;
 678
 679   ## Tadpole 68k
 680   m68*-tadpole-sysv* )
 681     machine=tad68k opsys=usg5-3
 682   ;;
 683
 684   ## Tahoe machines
 685   tahoe-tahoe-bsd4.2* )
 686     machine=tahoe opsys=bsd4-2
 687   ;;
 688   tahoe-tahoe-bsd4.3* )
 689     machine=tahoe opsys=bsd4-3
 690   ;;
 691
 692   ## Tandem Integrity S2
 693   mips-tandem-sysv* )
 694     machine=tandem-s2 opsys=usg5-3
 695   ;;
 696
 697   ## Tektronix XD88
 698   m88k-tektronix-sysv3* )
 699   machine=tekxd88 opsys=usg5-3
 700   ;;
 701
 702   ## Tektronix 16000 box (6130?)
 703   ns16k-tektronix-bsd* )
 704     machine=ns16000 opsys=bsd4-2
 705   ;;
 706   ## Tektronix 4300
 707   ## src/m/tek4300.h hints that this is a m68k machine.
 708   m68*-tektronix-bsd* )
 709     machine=tek4300 opsys=bsd4-3
 710   ;;
 711
 712   ## Titan P2 or P3
 713   ## We seem to have lost the machine-description file titan.h!
 714   titan-titan-sysv* )
 715     machine=titan opsys=usg5-3
 716   ;;
 717
 718   ## Ustation E30 (SS5E)
 719   m68*-unisys-uniplus* )
 720     machine=ustation opsystem=unipl5-2
 721   ;;
 722
 723   ## Vaxen.
 724   vax-dec-* )
 725     machine=vax
 726     case "${canonical}" in
 727       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 728       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 729       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 730       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 731       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 732       *-vms* )                                          opsys=vms ;;
 733       * )                                               unported=yes
 734     esac
 735   ;;
 736
 737   ## Whitechapel MG1
 738   ns16k-whitechapel-* )
 739     machine=mg1
 740     ## We don't know what sort of OS runs on these; we'll let the
 741     ## operating system guessing code below try.
 742   ;;
 743
 744   ## Wicat
 745   m68*-wicat-sysv* )
 746     machine=wicat opsys=usg5-2
 747   ;;
 748
 749   ## Intel 386 machines where we don't care about the manufacturer
 750   i[345]86-*-* )
 751     machine=intel386
 752     case "${canonical}" in
 753       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 754       *-isc2.2* )               opsys=isc2-2 ;;
 755       *-isc4.0* )               opsys=isc4-0 ;;
 756       *-isc4.* )                opsys=isc4-1 ;;
 757       *-isc* )                  opsys=isc3-0 ;;
 758       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 759       *-esix* )                 opsys=esix ;;
 760       *-xenix* )                opsys=xenix ;;
 761       *-linux* )                opsys=linux ;;
 762       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 763       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
 764       *-bsdi2* )                opsys=bsdos2 ;;
 765       *-386bsd* )               opsys=386bsd ;;
 766       *-freebsd* )              opsys=freebsd ;;
 767       *-nextstep* )             opsys=mach2 ;;
 768       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 769     esac
 770   ;;
 771
 772   * )
 773     unported=yes
 774   ;;
 775 esac
 776
 777 ### If the code above didn't choose an operating system, just choose
 778 ### an operating system based on the configuration name.  You really
 779 ### only want to use this when you have no idea what the right
 780 ### operating system is; if you know what operating systems a machine
 781 ### runs, it's cleaner to make it explicit in the case statement
 782 ### above.
 783 if test x"${opsys}" = x; then
 784   case "${canonical}" in
 785     *-gnu* )                            opsys=gnu ;;
 786     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 787     *-bsd4.2 )                          opsys=bsd4-2 ;;
 788     *-bsd4.3 )                          opsys=bsd4-3 ;;
 789     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 790     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 791     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 792     *-sysv3 | *-sysvr3 )                opsys=usg5-3 ;;
 793     *-sysv4 | *-sysvr4 )                opsys=usg5-4 ;;
 794     *-sysv4.1 | *-sysvr4.1 )
 795         NON_GNU_CPP=/usr/lib/cpp
 796         opsys=usg5-4 ;;
 797     *-sysv4.2 | *-sysvr4.2 )
 798         if [ x$NON_GNU_CPP = x ]; then
 799           NON_GNU_CPP=/usr/ccs/lib/cpp
 800         fi
 801         opsys=usg5-4-2 ;;
 802     * )
 803       unported=yes
 804     ;;
 805   esac
 806 fi
 807
 808 changequote([, ])dnl
 809
 810 if test $unported = yes; then
 811   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 812 Check \`etc/MACHINES' for recognized configuration names.])
 813 fi
 814
 815 machfile="m/${machine}.h"
 816 opsysfile="s/${opsys}.h"
 817
 818
 819 #### Choose a compiler.
 820 test -n "$CC" && cc_specified=yes
 821
 822 case ${with_gcc} in
 823   "yes" ) CC="gcc" GCC=yes ;;
 824   "no"  ) : ${CC=cc} ;;
 825   * ) AC_PROG_CC
 826 esac
 827
 828 # On Suns, sometimes $CPP names a directory.
 829 if test -n "$CPP" && test -d "$CPP"; then
 830   CPP=
 831 fi
 832
 833 #### Some systems specify a CPP to use unless we are using GCC.
 834 #### Now that we know whether we are using GCC, we can decide whether
 835 #### to use that one.
 836 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 837 then
 838   CPP="$NON_GNU_CPP"
 839 fi
 840
 841 #### Some systems specify a CC to use unless we are using GCC.
 842 #### Now that we know whether we are using GCC, we can decide whether
 843 #### to use that one.
 844 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 845   test x$cc_specified != xyes
 846 then
 847   CC="$NON_GNU_CC"
 848 fi
 849
 850 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 851 then
 852   CC="$CC $GCC_TEST_OPTIONS"
 853 fi
 854
 855 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 856 then
 857   CC="$CC $NON_GCC_TEST_OPTIONS"
 858 fi
 859
 860 #### Some other nice autoconf tests.  If you add a test here which
 861 #### should make an entry in src/config.h, don't forget to add an
 862 #### #undef clause to src/config.h.in for autoconf to modify.
 863
 864 dnl checks for programs
 865 AC_PROG_LN_S
 866 AC_PROG_CPP
 867 AC_PROG_INSTALL
 868 AC_PROG_YACC
 869
 870 dnl checks for Unix variants
 871 AC_AIX
 872
 873 dnl checks for header files
 874 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h)
 875 AC_HEADER_STDC
 876 AC_HEADER_TIME
 877 AC_DECL_SYS_SIGLIST
 878
 879 dnl Some systems have utime.h but don't declare the struct anyplace.
 880 AC_MSG_CHECKING(for struct utimbuf)
 881 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 882 #include <sys/time.h>
 883 #include <time.h>
 884 #else
 885 #ifdef HAVE_SYS_TIME_H
 886 #include <sys/time.h>
 887 #else
 888 #include <time.h>
 889 #endif
 890 #endif
 891 #ifdef HAVE_UTIME_H
 892 #include <utime.h>
 893 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 894   [AC_MSG_RESULT(yes)
 895    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 896   AC_MSG_RESULT(no))
 897
 898 dnl checks for typedefs
 899 AC_TYPE_SIGNAL
 900
 901 AC_MSG_CHECKING(for struct timeval)
 902 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 903 #include <sys/time.h>
 904 #include <time.h>
 905 #else
 906 #ifdef HAVE_SYS_TIME_H
 907 #include <sys/time.h>
 908 #else
 909 #include <time.h>
 910 #endif
 911 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 912   [AC_MSG_RESULT(yes)
 913    AC_DEFINE(HAVE_TIMEVAL)],
 914   AC_MSG_RESULT(no))
 915
 916 dnl checks for structure members
 917 AC_STRUCT_TM
 918 AC_STRUCT_TIMEZONE
 919
 920 dnl checks for compiler characteristics
 921 AC_C_CONST
 922
 923 dnl check for Make feature
 924 AC_PROG_MAKE_SET
 925
 926 dnl checks for operating system services
 927 AC_SYS_LONG_FILE_NAMES
 928
 929 #### Choose a window system.
 930
 931 AC_PATH_X
 932 if test "$no_x" = yes; then
 933   window_system=none
 934 else
 935   window_system=x11
 936 fi
 937
 938 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
 939   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
 940   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
 941 fi
 942 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
 943   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
 944 fi
 945
 946 if test x"${x_includes}" = x; then
 947   bitmapdir=/usr/include/X11/bitmaps
 948 else
 949   # accumulate include directories that have X11 bitmap sudirectories
 950   bmd_acc="dummyval"
 951   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
 952     if test -d "${bmd}/X11/bitmaps"; then
 953       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
 954     elif test -d "${bmd}/bitmaps"; then
 955       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
 956     fi
 957   done
 958   if test ${bmd_acc} != "dummyval"; then
 959     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
 960   fi
 961 fi
 962
 963 case "${window_system}" in
 964   x11 )
 965     HAVE_X_WINDOWS=yes
 966     HAVE_X11=yes
 967     case "${with_x_toolkit}" in
 968       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
 969       motif ) USE_X_TOOLKIT=MOTIF ;;
 970 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
 971       * ) USE_X_TOOLKIT=none ;;
 972     esac
 973   ;;
 974   none )
 975     HAVE_X_WINDOWS=no
 976     HAVE_X11=no
 977     USE_X_TOOLKIT=none
 978   ;;
 979 esac
 980 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
 981
 982 ### If we're using X11, we should use the X menu package.
 983 HAVE_X_MENU=no
 984 case ${HAVE_X11} in
 985   yes ) HAVE_X_MENU=yes ;;
 986 esac
 987
 988 #### Extract some information from the operating system and machine files.
 989
 990 AC_CHECKING([the machine- and system-dependent files to find out
 991  - which libraries the lib-src programs will want, and
 992  - whether the GNU malloc routines are usable])
 993
 994 ### First figure out CFLAGS (which we use for running the compiler here)
 995 ### and REAL_CFLAGS (which we use for real compilation).
 996 ### The two are the same except on a few systems, where they are made
 997 ### different to work around various lossages.  For example,
 998 ### GCC 2.5 on Linux needs them to be different because it treats -g
 999 ### as implying static linking.
1000
1001 ### If the CFLAGS env var is specified, we use that value
1002 ### instead of the default.
1003
1004 ### It's not important that this name contain the PID; you can't run
1005 ### two configures in the same directory and have anything work
1006 ### anyway.
1007 tempcname="conftest.c"
1008
1009 echo '
1010 #include "'${srcdir}'/src/'${opsysfile}'"
1011 #include "'${srcdir}'/src/'${machfile}'"
1012 #ifndef LIBS_MACHINE
1013 #define LIBS_MACHINE
1014 #endif
1015 #ifndef LIBS_SYSTEM
1016 #define LIBS_SYSTEM
1017 #endif
1018 #ifndef C_SWITCH_SYSTEM
1019 #define C_SWITCH_SYSTEM
1020 #endif
1021 #ifndef C_SWITCH_MACHINE
1022 #define C_SWITCH_MACHINE
1023 #endif
1024 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1025 configure___ c_switch_system=C_SWITCH_SYSTEM
1026 configure___ c_switch_machine=C_SWITCH_MACHINE
1027
1028 #ifndef LIB_X11_LIB
1029 #define LIB_X11_LIB -lX11
1030 #endif
1031
1032 #ifndef LIBX11_MACHINE
1033 #define LIBX11_MACHINE
1034 #endif
1035
1036 #ifndef LIBX11_SYSTEM
1037 #define LIBX11_SYSTEM
1038 #endif
1039 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1040
1041 #ifdef UNEXEC
1042 configure___ unexec=UNEXEC
1043 #else
1044 configure___ unexec=unexec.o
1045 #endif
1046
1047 #ifdef SYSTEM_MALLOC
1048 configure___ system_malloc=yes
1049 #else
1050 configure___ system_malloc=no
1051 #endif
1052
1053 #ifndef C_DEBUG_SWITCH
1054 #define C_DEBUG_SWITCH -g
1055 #endif
1056
1057 #ifndef C_OPTIMIZE_SWITCH
1058 #define C_OPTIMIZE_SWITCH -O
1059 #endif
1060
1061 #ifdef THIS_IS_CONFIGURE
1062
1063 /* Get the CFLAGS for tests in configure.  */
1064 #ifdef __GNUC__
1065 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1066 #else
1067 configure___ CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1068 #endif
1069
1070 #else /* not THIS_IS_CONFIGURE */
1071
1072 /* Get the CFLAGS for real compilation.  */
1073 #ifdef __GNUC__
1074 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1075 #else
1076 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1077 #endif
1078
1079 #endif /* not THIS_IS_CONFIGURE */
1080 ' > ${tempcname}
1081
1082 # The value of CPP is a quoted variable reference, so we need to do this
1083 # to get its actual value...
1084 CPP=`eval "echo $CPP"`
1085 changequote(, )dnl
1086 eval `${CPP} -Isrc ${tempcname} \
1087        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1088 if test "x$CFLAGS" = x; then
1089   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1090          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1091 else
1092   REAL_CFLAGS="$CFLAGS"
1093 fi
1094 changequote([, ])dnl
1095 rm ${tempcname}
1096
1097 ### Compute the unexec source name from the object name.
1098 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1099
1100 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1101 # Assume not, until told otherwise.
1102 GNU_MALLOC=yes
1103 if test "${system_malloc}" = "yes"; then
1104   GNU_MALLOC=no
1105   GNU_MALLOC_reason="
1106   (The GNU allocators don't work with this system configuration.)"
1107 fi
1108
1109 if test x"${REL_ALLOC}" = x; then
1110   REL_ALLOC=${GNU_MALLOC}
1111 fi
1112
1113 LISP_FLOAT_TYPE=yes
1114
1115
1116 #### Add the libraries to LIBS and check for some functions.
1117
1118 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1119 LIBS="$libsrc_libs"
1120
1121 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1122 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1123 AC_CHECK_LIB(dnet, dnet_ntoa)
1124 dnl This causes -lresolv to get used in subsequent tests,
1125 dnl which causes failures on some systems such as HPUX 9.
1126 dnl AC_CHECK_LIB(resolv, gethostbyname)
1127
1128 dnl FIXME replace main with a function we actually want from this library.
1129 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1130
1131 AC_MSG_CHECKING(for XFree86)
1132 if test -d /usr/X386/include; then
1133   HAVE_XFREE386=yes
1134   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1135 else
1136   HAVE_XFREE386=no
1137 fi
1138 AC_MSG_RESULT($HAVE_XFREE386)
1139
1140 # We change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1141 # for the tests that follow.
1142
1143 if test "${HAVE_X11}" = "yes"; then
1144   DEFS="$C_SWITCH_X_SITE $DEFS"
1145   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1146   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1147   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1148 XScreenNumberOfScreen XSetWMProtocols)
1149 fi
1150
1151 if test "${USE_X_TOOLKIT}" != "none"; then
1152   AC_MSG_CHECKING(X11 toolkit version)
1153   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1154 [#if XtSpecificationRelease < 6
1155 fail;
1156 #endif
1157 ], [AC_MSG_RESULT(6)
1158     AC_DEFINE(HAVE_X11XTR6)],
1159    [AC_MSG_RESULT(not 6)])
1160 fi
1161
1162 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1163 AC_MSG_CHECKING(whether netdb declares h_errno)
1164 AC_TRY_LINK([#include <netdb.h>],
1165   [return h_errno;],
1166   [AC_MSG_RESULT(yes)
1167    AC_DEFINE(HAVE_H_ERRNO)],
1168   [AC_MSG_RESULT(no)])
1169
1170 AC_FUNC_ALLOCA
1171
1172 # fmod, logb, and frexp are found in -lm on most systems.
1173 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1174 AC_CHECK_LIB(m, sqrt(0.0) + t)
1175 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1176 random lrand48 bcopy bcmp logb frexp fmod drem ftime res_init setsid \
1177 strerror fpathconf select mktime eaccess getpagesize)
1178
1179 ok_so_far=yes
1180 AC_CHECK_FUNC(socket, , ok_so_far=no)
1181 if test $ok_so_far = yes; then
1182   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1183 fi
1184 if test $ok_so_far = yes; then
1185   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1186 fi
1187 if test $ok_so_far = yes; then
1188   AC_DEFINE(HAVE_INET_SOCKETS)
1189 fi
1190
1191 if test -f /usr/lpp/X11/bin/smt.exp; then
1192   AC_DEFINE(HAVE_AIX_SMT_EXP)
1193 fi
1194
1195 # Set up the CFLAGS for real compilation, so we can substitute it.
1196 CFLAGS="$REAL_CFLAGS"
1197
1198 changequote(, )dnl
1199 #### Find out which version of Emacs this is.
1200 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1201          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1202 changequote([, ])dnl
1203 if test x"${version}" = x; then
1204   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1205 fi
1206
1207 ### Specify what sort of things we'll be editing into Makefile and config.h.
1208 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1209 AC_SUBST(version)
1210 AC_SUBST(configuration)
1211 AC_SUBST(canonical)
1212 AC_SUBST(srcdir)
1213 AC_SUBST(prefix)
1214 AC_SUBST(exec_prefix)
1215 AC_SUBST(bindir)
1216 AC_SUBST(datadir)
1217 AC_SUBST(sharedstatedir)
1218 AC_SUBST(libexecdir)
1219 AC_SUBST(mandir)
1220 AC_SUBST(infodir)
1221 AC_SUBST(lispdir)
1222 AC_SUBST(locallisppath)
1223 AC_SUBST(lisppath)
1224 AC_SUBST(etcdir)
1225 AC_SUBST(lockdir)
1226 AC_SUBST(archlibdir)
1227 AC_SUBST(docdir)
1228 AC_SUBST(bitmapdir)
1229 AC_SUBST(c_switch_system)
1230 AC_SUBST(c_switch_machine)
1231 AC_SUBST(LD_SWITCH_X_SITE)
1232 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1233 AC_SUBST(C_SWITCH_X_SITE)
1234 AC_SUBST(CFLAGS)
1235 AC_SUBST(X_TOOLKIT_TYPE)
1236 AC_SUBST(machfile)
1237 AC_SUBST(opsysfile)
1238
1239 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1240 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1241 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1242 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1243 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1244 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1245 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1246 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1247
1248 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1249   AC_DEFINE(HAVE_X_WINDOWS)
1250 fi
1251 if test "${USE_X_TOOLKIT}" != "none" ; then
1252   AC_DEFINE(USE_X_TOOLKIT)
1253 fi
1254 if test "${HAVE_X11}" = "yes" ; then
1255   AC_DEFINE(HAVE_X11)
1256 fi
1257 if test "${HAVE_XFREE386}" = "yes" ; then
1258   AC_DEFINE(HAVE_XFREE386)
1259 fi
1260 if test "${HAVE_X_MENU}" = "yes" ; then
1261   AC_DEFINE(HAVE_X_MENU)
1262 fi
1263 if test "${GNU_MALLOC}" = "yes" ; then
1264   AC_DEFINE(GNU_MALLOC)
1265 fi
1266 if test "${REL_ALLOC}" = "yes" ; then
1267   AC_DEFINE(REL_ALLOC)
1268 fi
1269 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1270   AC_DEFINE(LISP_FLOAT_TYPE)
1271 fi
1272
1273 #### Report on what we decided to do.
1274 echo "
1275
1276 Configured for \`${canonical}'.
1277
1278   Where should the build process find the source code?    ${srcdir}
1279   What operating system and machine description files should Emacs use?
1280         \`${opsysfile}' and \`${machfile}'
1281   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1282   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1283   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1284   What window system should Emacs use?                    ${window_system}
1285   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}${x_includes+
1286   Where do we find X Windows header files?                }${x_includes}${x_libraries+
1287   Where do we find X Windows libraries?                   }${x_libraries}
1288
1289 "
1290
1291 # Remove any trailing slashes in these variables.
1292 changequote(, )dnl
1293 test "${prefix}" != NONE &&
1294   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1295 test "${exec_prefix}" != NONE &&
1296   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1297 changequote([, ])dnl
1298
1299 AC_OUTPUT(Makefile lib-src/Makefile.in oldXMenu/Makefile \
1300         man/Makefile lwlib/Makefile src/Makefile.in, [
1301
1302 ### Make the necessary directories, if they don't exist.
1303 for dir in cpp etc ; do
1304   test -d ${dir} || mkdir ${dir}
1305 done
1306
1307 # Build src/Makefile from ${srcdir}/src/Makefile.in.  This must be done
1308 # after src/config.h is built, since we rely on that file.
1309
1310 changequote(, )dnl The horror, the horror.
1311 # Now get this: Some word that is part of the ${srcdir} directory name
1312 # or the ${configuration} value might, just might, happen to be an
1313 # identifier like `sun4' or `i386' or something, and be predefined by
1314 # the C preprocessor to some helpful value like 1, or maybe the empty
1315 # string.  Needless to say consequent macro substitutions are less
1316 # than conducive to the makefile finding the correct directory.
1317 undefs="`echo $top_srcdir $configuration $canonical |
1318 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1319     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1320 `"
1321 changequote([, ])dnl
1322
1323 echo creating lib-src/Makefile
1324 ( cd lib-src
1325   rm -f junk.c junk1.c junk2.c
1326   sed -e '/start of cpp stuff/q' \
1327       < Makefile.in > junk1.c
1328   sed -e '1,/start of cpp stuff/d'\
1329       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1330       < Makefile.in > junk.c
1331   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1332       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1333   cat junk1.c junk2.c > Makefile.new
1334   rm -f junk.c junk1.c junk2.c
1335   chmod 444 Makefile.new
1336   mv -f Makefile.new Makefile
1337 )
1338
1339 echo creating src/Makefile
1340 ( cd src
1341   rm -f junk.c junk1.c junk2.c
1342   sed -e '/start of cpp stuff/q' \
1343       < Makefile.in > junk1.c
1344   sed -e '1,/start of cpp stuff/d'\
1345       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1346       < Makefile.in > junk.c
1347   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1348       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1349   cat junk1.c junk2.c > Makefile.new
1350   rm -f junk.c junk1.c junk2.c
1351   chmod 444 Makefile.new
1352   mv -f Makefile.new Makefile
1353 )
1354
1355 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1356   echo creating src/.gdbinit
1357   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1358 fi
1359
1360 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])