lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 ;; Functions
  36
  37 ;;;###autoload
  38 (defun describe-function (function)
  39   "Display the full documentation of FUNCTION (a symbol)."
  40   (interactive
  41    (let ((fn (function-called-at-point))
  42          (enable-recursive-minibuffers t)
  43          val)
  44      (setq val (completing-read (if fn
  45                                     (format "Describe function (default %s): " fn)
  46                                   "Describe function: ")
  47                                 obarray 'fboundp t nil nil
  48                                 (and fn (symbol-name fn))))
  49      (list (if (equal val "")
  50                fn (intern val)))))
  51   (if (null function)
  52       (message "You didn't specify a function")
  53     (help-setup-xref (list #'describe-function function)
  54                      (called-interactively-p 'interactive))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info.
  69 DEF is the function whose usage we're looking for in DOCSTRING."
  70   ;; Functions can get the calling sequence at the end of the doc string.
  71   ;; In cases where `function' has been fset to a subr we can't search for
  72   ;; function's name in the doc string so we use `fn' as the anonymous
  73   ;; function name instead.
  74   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  75     (cons (format "(%s%s"
  76                   ;; Replace `fn' with the actual function name.
  77                   (if (consp def) "anonymous" def)
  78                   (match-string 1 docstring))
  79           (substring docstring 0 (match-beginning 0)))))
  80
  81 (defun help-add-fundoc-usage (docstring arglist)
  82   "Add the usage info to DOCSTRING.
  83 If DOCSTRING already has a usage info, then just return it unchanged.
  84 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  85 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  86   (unless (stringp docstring) (setq docstring "Not documented"))
  87   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  88       docstring
  89     (concat docstring
  90             (if (string-match "\n?\n\\'" docstring)
  91                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  92               "\n\n")
  93             (if (and (stringp arglist)
  94                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  95                 (concat "(fn" (match-string 1 arglist) ")")
  96               (format "%S" (help-make-usage 'fn arglist))))))
  97
  98 (defun help-function-arglist (def)
  99   ;; Handle symbols aliased to other symbols.
 100   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 101   ;; If definition is a macro, find the function inside it.
 102   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 103   ;; and do the same for interpreted closures
 104   (if (eq (car-safe def) 'closure) (setq def (cddr def)))
 105   (cond
 106    ((byte-code-function-p def) (aref def 0))
 107    ((eq (car-safe def) 'lambda) (nth 1 def))
 108    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 109     "[Arg list not available until function definition is loaded.]")
 110    (t t)))
 111
 112 (defun help-make-usage (function arglist)
 113   (cons (if (symbolp function) function 'anonymous)
 114         (mapcar (lambda (arg)
 115                   (if (not (symbolp arg))
 116                       (if (and (consp arg) (symbolp (car arg)))
 117                           ;; CL style default values for optional args.
 118                           (cons (intern (upcase (symbol-name (car arg))))
 119                                 (cdr arg))
 120                         arg)
 121                     (let ((name (symbol-name arg)))
 122                       (if (string-match "\\`&" name) arg
 123                         (intern (upcase name))))))
 124                 arglist)))
 125
 126 ;; Could be this, if we make symbol-file do the work below.
 127 ;; (defun help-C-file-name (subr-or-var kind)
 128 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 129 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 130 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 131 ;;               (subr-name subr-or-var))
 132 ;;             (if (eq kind 'var) 'defvar 'defun)))
 133 ;;;###autoload
 134 (defun help-C-file-name (subr-or-var kind)
 135   "Return the name of the C file where SUBR-OR-VAR is defined.
 136 KIND should be `var' for a variable or `subr' for a subroutine."
 137   (let ((docbuf (get-buffer-create " *DOC*"))
 138         (name (if (eq 'var kind)
 139                   (concat "V" (symbol-name subr-or-var))
 140                 (concat "F" (subr-name subr-or-var)))))
 141     (with-current-buffer docbuf
 142       (goto-char (point-min))
 143       (if (eobp)
 144           (insert-file-contents-literally
 145            (expand-file-name internal-doc-file-name doc-directory)))
 146       (let ((file (catch 'loop
 147                     (while t
 148                       (let ((pnt (search-forward (concat "\1f" name "\n"))))
 149                         (re-search-backward "\1fS\\(.*\\)")
 150                         (let ((file (match-string 1)))
 151                           (if (member file build-files)
 152                               (throw 'loop file)
 153                             (goto-char pnt))))))))
 154         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 155             (setq file (replace-match ".m" t t file 1))
 156           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 157               (setq file (replace-match ".c" t t file))))
 158         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 159             (concat "src/" file)
 160           file)))))
 161
 162 (defcustom help-downcase-arguments nil
 163   "If non-nil, argument names in *Help* buffers are downcased."
 164   :type 'boolean
 165   :group 'help
 166   :version "23.2")
 167
 168 (defun help-highlight-arg (arg)
 169   "Highlight ARG as an argument name for a *Help* buffer.
 170 Return ARG in face `help-argument-name'; ARG is also downcased
 171 if the variable `help-downcase-arguments' is non-nil."
 172   (propertize (if help-downcase-arguments (downcase arg) arg)
 173               'face 'help-argument-name))
 174
 175 (defun help-do-arg-highlight (doc args)
 176   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 177     (modify-syntax-entry ?\- "w")
 178     (dolist (arg args doc)
 179       (setq doc (replace-regexp-in-string
 180                  ;; This is heuristic, but covers all common cases
 181                  ;; except ARG1-ARG2
 182                  (concat "\\<"                   ; beginning of word
 183                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 184                          "\\("
 185                          (regexp-quote arg)
 186                          "\\)"
 187                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 188                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 189                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 190                          "\\>")                  ; end of word
 191                  (help-highlight-arg arg)
 192                  doc t t 1)))))
 193
 194 (defun help-highlight-arguments (usage doc &rest args)
 195   (when (and usage (string-match "^(" usage))
 196     (with-temp-buffer
 197       (insert usage)
 198       (goto-char (point-min))
 199       (let ((case-fold-search nil)
 200             (next (not (or args (looking-at "\\["))))
 201             (opt nil))
 202         ;; Make a list of all arguments
 203         (skip-chars-forward "^ ")
 204         (while next
 205           (or opt (not (looking-at " &")) (setq opt t))
 206           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 207               (setq next nil)
 208             (setq args (cons (match-string 2) args))
 209             (when (and opt (string= (match-string 1) "("))
 210               ;; A pesky CL-style optional argument with default value,
 211               ;; so let's skip over it
 212               (search-backward "(")
 213               (goto-char (scan-sexps (point) 1)))))
 214         ;; Highlight aguments in the USAGE string
 215         (setq usage (help-do-arg-highlight (buffer-string) args))
 216         ;; Highlight arguments in the DOC string
 217         (setq doc (and doc (help-do-arg-highlight doc args))))))
 218   ;; Return value is like the one from help-split-fundoc, but highlighted
 219   (cons usage doc))
 220
 221 ;; The following function was compiled from the former functions
 222 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 223 ;; some excerpts from `describe-function-1' and `describe-variable'.
 224 ;; The only additional twists provided are (1) locate the defining file
 225 ;; for autoloaded functions, and (2) give preference to files in the
 226 ;; "install directory" (directories found via `load-path') rather than
 227 ;; to files in the "compile directory" (directories found by searching
 228 ;; the loaddefs.el file).  We autoload it because it's also used by
 229 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 230
 231 ;;;###autoload
 232 (defun find-lisp-object-file-name (object type)
 233   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 234 OBJECT should be a symbol associated with a function, variable, or face;
 235   alternatively, it can be a function definition.
 236 If TYPE is `defvar', search for a variable definition.
 237 If TYPE is `defface', search for a face definition.
 238 If TYPE is the value returned by `symbol-function' for a function symbol,
 239  search for a function definition.
 240
 241 The return value is the absolute name of a readable file where OBJECT is
 242 defined.  If several such files exist, preference is given to a file
 243 found via `load-path'.  The return value can also be `C-source', which
 244 means that OBJECT is a function or variable defined in C.  If no
 245 suitable file is found, return nil."
 246   (let* ((autoloaded (eq (car-safe type) 'autoload))
 247          (file-name (or (and autoloaded (nth 1 type))
 248                         (symbol-file
 249                          object (if (memq type (list 'defvar 'defface))
 250                                     type
 251                                   'defun)))))
 252     (cond
 253      (autoloaded
 254       ;; An autoloaded function: Locate the file since `symbol-function'
 255       ;; has only returned a bare string here.
 256       (setq file-name
 257             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 258      ((and (stringp file-name)
 259            (string-match "[.]*loaddefs.el\\'" file-name))
 260       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 261       ;; and try to extract the defining file.  The following form is
 262       ;; from `describe-function-1' and `describe-variable'.
 263       (let ((location
 264              (condition-case nil
 265                  (find-function-search-for-symbol object nil file-name)
 266                (error nil))))
 267         (when (cdr location)
 268           (with-current-buffer (car location)
 269             (goto-char (cdr location))
 270             (when (re-search-backward
 271                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 272               (setq file-name
 273                     (locate-file
 274                      (file-name-sans-extension
 275                       (match-string-no-properties 1))
 276                      load-path '(".el" ".elc") 'readable))))))))
 277
 278     (cond
 279      ((and (not file-name) (subrp type))
 280       ;; A built-in function.  The form is from `describe-function-1'.
 281       (if (get-buffer " *DOC*")
 282           (help-C-file-name type 'subr)
 283         'C-source))
 284      ((and (not file-name) (symbolp object)
 285            (integerp (get object 'variable-documentation)))
 286       ;; A variable defined in C.  The form is from `describe-variable'.
 287       (if (get-buffer " *DOC*")
 288           (help-C-file-name object 'var)
 289         'C-source))
 290      ((not (stringp file-name))
 291       ;; If we don't have a file-name string by now, we lost.
 292       nil)
 293      ;; Now, `file-name' should have become an absolute file name.
 294      ;; For files loaded from ~/.emacs.elc, try ~/.emacs.
 295      ((let (fn)
 296         (and (string-equal file-name
 297                            (expand-file-name ".emacs.elc" "~"))
 298              (file-readable-p (setq fn (expand-file-name ".emacs" "~")))
 299              fn)))
 300      ;; When the Elisp source file can be found in the install
 301      ;; directory, return the name of that file.
 302      ((let ((lib-name
 303              (if (string-match "[.]elc\\'" file-name)
 304                  (substring-no-properties file-name 0 -1)
 305                file-name)))
 306         (or (and (file-readable-p lib-name) lib-name)
 307             ;; The library might be compressed.
 308             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 309      ((let* ((lib-name (file-name-nondirectory file-name))
 310              ;; The next form is from `describe-simplify-lib-file-name'.
 311              (file-name
 312               ;; Try converting the absolute file name to a library
 313               ;; name, convert that back to a file name and see if we
 314               ;; get the original one.  If so, they are equivalent.
 315               (if (equal file-name (locate-file lib-name load-path '("")))
 316                   (if (string-match "[.]elc\\'" lib-name)
 317                       (substring-no-properties lib-name 0 -1)
 318                     lib-name)
 319                 file-name))
 320              ;; The next three forms are from `find-source-lisp-file'.
 321              (elc-file (locate-file
 322                         (concat file-name
 323                                 (if (string-match "\\.el\\'" file-name)
 324                                     "c"
 325                                   ".elc"))
 326                         load-path nil 'readable))
 327              (str (when elc-file
 328                     (with-temp-buffer
 329                       (insert-file-contents-literally elc-file nil 0 256)
 330                       (buffer-string))))
 331              (src-file (and str
 332                             (string-match ";;; from file \\(.*\\.el\\)" str)
 333                             (match-string 1 str))))
 334         (and src-file (file-readable-p src-file) src-file))))))
 335
 336 (declare-function ad-get-advice-info "advice" (function))
 337
 338 ;;;###autoload
 339 (defun describe-function-1 (function)
 340   (let* ((advised (and (symbolp function) (featurep 'advice)
 341                        (ad-get-advice-info function)))
 342          ;; If the function is advised, use the symbol that has the
 343          ;; real definition, if that symbol is already set up.
 344          (real-function
 345           (or (and advised
 346                    (let ((origname (cdr (assq 'origname advised))))
 347                      (and (fboundp origname) origname)))
 348               function))
 349          ;; Get the real definition.
 350          (def (if (symbolp real-function)
 351                   (symbol-function real-function)
 352                 function))
 353          file-name string
 354          (beg (if (commandp def) "an interactive " "a "))
 355          (pt1 (with-current-buffer (help-buffer) (point)))
 356          errtype)
 357     (setq string
 358           (cond ((or (stringp def) (vectorp def))
 359                  "a keyboard macro")
 360                 ((subrp def)
 361                  (if (eq 'unevalled (cdr (subr-arity def)))
 362                      (concat beg "special form")
 363                    (concat beg "built-in function")))
 364                 ((byte-code-function-p def)
 365                  (concat beg "compiled Lisp function"))
 366                 ((symbolp def)
 367                  (while (and (fboundp def)
 368                              (symbolp (symbol-function def)))
 369                    (setq def (symbol-function def)))
 370                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 371                  (or (fboundp def) (setq errtype 'alias))
 372                  (format "an alias for `%s'" def))
 373                 ((eq (car-safe def) 'lambda)
 374                  (concat beg "Lisp function"))
 375                 ((eq (car-safe def) 'macro)
 376                  "a Lisp macro")
 377                 ((eq (car-safe def) 'closure)
 378                  (concat beg "Lisp closure"))
 379                 ((eq (car-safe def) 'autoload)
 380                  (format "%s autoloaded %s"
 381                          (if (commandp def) "an interactive" "an")
 382                          (if (eq (nth 4 def) 'keymap) "keymap"
 383                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 384                 ((keymapp def)
 385                  (let ((is-full nil)
 386                        (elts (cdr-safe def)))
 387                    (while elts
 388                      (if (char-table-p (car-safe elts))
 389                          (setq is-full t
 390                                elts nil))
 391                      (setq elts (cdr-safe elts)))
 392                    (if is-full
 393                        "a full keymap"
 394                      "a sparse keymap")))
 395                 (t "")))
 396     (princ string)
 397     (if (eq errtype 'alias)
 398         (princ ",\nwhich is not defined.  Please make a bug report.")
 399       (with-current-buffer standard-output
 400         (save-excursion
 401           (save-match-data
 402             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 403               (help-xref-button 1 'help-function def)))))
 404
 405       (setq file-name (find-lisp-object-file-name function def))
 406       (when file-name
 407         (princ " in `")
 408         ;; We used to add .el to the file name,
 409         ;; but that's completely wrong when the user used load-file.
 410         (princ (if (eq file-name 'C-source)
 411                    "C source code"
 412                  (file-name-nondirectory file-name)))
 413         (princ "'")
 414         ;; Make a hyperlink to the library.
 415         (with-current-buffer standard-output
 416           (save-excursion
 417             (re-search-backward "`\\([^`']+\\)'" nil t)
 418             (help-xref-button 1 'help-function-def function file-name))))
 419       (princ ".")
 420       (with-current-buffer (help-buffer)
 421         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 422                                   (point)))
 423       (terpri)(terpri)
 424       (when (commandp function)
 425         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 426               (remapped (command-remapping function)))
 427           (unless (memq remapped '(ignore undefined))
 428             (let ((keys (where-is-internal
 429                          (or remapped function) overriding-local-map nil nil))
 430                   non-modified-keys)
 431               (if (and (eq function 'self-insert-command)
 432                        (vectorp (car-safe keys))
 433                        (consp (aref (car keys) 0)))
 434                   (princ "It is bound to many ordinary text characters.\n")
 435                 ;; Which non-control non-meta keys run this command?
 436                 (dolist (key keys)
 437                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 438                       (push key non-modified-keys)))
 439                 (when remapped
 440                   (princ "It is remapped to `")
 441                   (princ (symbol-name remapped))
 442                   (princ "'"))
 443
 444                 (when keys
 445                   (princ (if remapped ", which is bound to " "It is bound to "))
 446                   ;; If lots of ordinary text characters run this command,
 447                   ;; don't mention them one by one.
 448                   (if (< (length non-modified-keys) 10)
 449                       (princ (mapconcat 'key-description keys ", "))
 450                     (dolist (key non-modified-keys)
 451                       (setq keys (delq key keys)))
 452                     (if keys
 453                         (progn
 454                           (princ (mapconcat 'key-description keys ", "))
 455                           (princ ", and many ordinary text characters"))
 456                       (princ "many ordinary text characters"))))
 457                 (when (or remapped keys non-modified-keys)
 458                   (princ ".")
 459                   (terpri)))))
 460
 461           (with-current-buffer (help-buffer)
 462             (fill-region-as-paragraph pt2 (point))
 463             (unless (looking-back "\n\n")
 464               (terpri)))))
 465       ;; Note that list* etc do not get this property until
 466       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 467       (when (and (symbolp function)
 468                  (eq (get function 'byte-compile)
 469                      'cl-byte-compile-compiler-macro))
 470         (princ "This function has a compiler macro")
 471         (let ((lib (get function 'compiler-macro-file)))
 472           (when (stringp lib)
 473             (princ (format " in `%s'" lib))
 474             (with-current-buffer standard-output
 475               (save-excursion
 476                 (re-search-backward "`\\([^`']+\\)'" nil t)
 477                 (help-xref-button 1 'help-function-cmacro function lib)))))
 478         (princ ".\n\n"))
 479       (let* ((advertised (gethash def advertised-signature-table t))
 480              (arglist (if (listp advertised)
 481                           advertised (help-function-arglist def)))
 482              (doc (documentation function))
 483              (usage (help-split-fundoc doc function)))
 484         (with-current-buffer standard-output
 485           ;; If definition is a keymap, skip arglist note.
 486           (unless (keymapp function)
 487             (if usage (setq doc (cdr usage)))
 488             (let* ((use (cond
 489                          ((and usage (not (listp advertised))) (car usage))
 490                          ((listp arglist)
 491                           (format "%S" (help-make-usage function arglist)))
 492                          ((stringp arglist) arglist)
 493                          ;; Maybe the arglist is in the docstring of a symbol
 494                          ;; this one is aliased to.
 495                          ((let ((fun real-function))
 496                             (while (and (symbolp fun)
 497                                         (setq fun (symbol-function fun))
 498                                         (not (setq usage (help-split-fundoc
 499                                                           (documentation fun)
 500                                                           function)))))
 501                             usage)
 502                           (car usage))
 503                          ((or (stringp def)
 504                               (vectorp def))
 505                           (format "\nMacro: %s" (format-kbd-macro def)))
 506                          (t "[Missing arglist.  Please make a bug report.]")))
 507                    (high (help-highlight-arguments use doc)))
 508               (let ((fill-begin (point)))
 509                 (insert (car high) "\n")
 510                 (fill-region fill-begin (point)))
 511               (setq doc (cdr high))))
 512           (let* ((obsolete (and
 513                             ;; function might be a lambda construct.
 514                             (symbolp function)
 515                             (get function 'byte-obsolete-info)))
 516                  (use (car obsolete)))
 517             (when obsolete
 518               (princ "\nThis function is obsolete")
 519               (when (nth 2 obsolete)
 520                 (insert (format " since %s" (nth 2 obsolete))))
 521               (insert (cond ((stringp use) (concat ";\n" use))
 522                             (use (format ";\nuse `%s' instead." use))
 523                             (t "."))
 524                       "\n"))
 525             (insert "\n"
 526                     (or doc "Not documented."))))))))
 527
 528 \f
 529 ;; Variables
 530
 531 ;;;###autoload
 532 (defun variable-at-point (&optional any-symbol)
 533   "Return the bound variable symbol found at or before point.
 534 Return 0 if there is no such symbol.
 535 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 536   (with-syntax-table emacs-lisp-mode-syntax-table
 537     (or (condition-case ()
 538             (save-excursion
 539               (or (not (zerop (skip-syntax-backward "_w")))
 540                   (eq (char-syntax (following-char)) ?w)
 541                   (eq (char-syntax (following-char)) ?_)
 542                   (forward-sexp -1))
 543               (skip-chars-forward "'")
 544               (let ((obj (read (current-buffer))))
 545                 (and (symbolp obj) (boundp obj) obj)))
 546           (error nil))
 547         (let* ((str (find-tag-default))
 548                (sym (if str (intern-soft str))))
 549           (if (and sym (or any-symbol (boundp sym)))
 550               sym
 551             (save-match-data
 552               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 553                 (setq sym (intern-soft (match-string 1 str)))
 554                 (and (or any-symbol (boundp sym)) sym)))))
 555         0)))
 556
 557 (defun describe-variable-custom-version-info (variable)
 558   (let ((custom-version (get variable 'custom-version))
 559         (cpv (get variable 'custom-package-version))
 560         (output nil))
 561     (if custom-version
 562         (setq output
 563               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 564                       custom-version))
 565       (when cpv
 566         (let* ((package (car-safe cpv))
 567                (version (if (listp (cdr-safe cpv))
 568                             (car (cdr-safe cpv))
 569                           (cdr-safe cpv)))
 570                (pkg-versions (assq package customize-package-emacs-version-alist))
 571                (emacsv (cdr (assoc version pkg-versions))))
 572           (if (and package version)
 573               (setq output
 574                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 575                                     (if emacsv
 576                                         (format " that is part of Emacs %s" emacsv))
 577                                     ".\n")
 578                             version package))))))
 579     output))
 580
 581 ;;;###autoload
 582 (defun describe-variable (variable &optional buffer frame)
 583   "Display the full documentation of VARIABLE (a symbol).
 584 Returns the documentation as a string, also.
 585 If VARIABLE has a buffer-local value in BUFFER or FRAME
 586 \(default to the current buffer and current frame),
 587 it is displayed along with the global value."
 588   (interactive
 589    (let ((v (variable-at-point))
 590          (enable-recursive-minibuffers t)
 591          val)
 592      (setq val (completing-read (if (symbolp v)
 593                                     (format
 594                                      "Describe variable (default %s): " v)
 595                                   "Describe variable: ")
 596                                 obarray
 597                                 '(lambda (vv)
 598                                    (or (boundp vv)
 599                                        (get vv 'variable-documentation)))
 600                                 t nil nil
 601                                 (if (symbolp v) (symbol-name v))))
 602      (list (if (equal val "")
 603                v (intern val)))))
 604   (let (file-name)
 605     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 606     (unless (frame-live-p frame) (setq frame (selected-frame)))
 607     (if (not (symbolp variable))
 608         (message "You did not specify a variable")
 609       (save-excursion
 610         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 611               val val-start-pos locus)
 612           ;; Extract the value before setting up the output buffer,
 613           ;; in case `buffer' *is* the output buffer.
 614           (unless valvoid
 615             (with-selected-frame frame
 616               (with-current-buffer buffer
 617                 (setq val (symbol-value variable)
 618                       locus (variable-binding-locus variable)))))
 619           (help-setup-xref (list #'describe-variable variable buffer)
 620                            (called-interactively-p 'interactive))
 621           (with-help-window (help-buffer)
 622             (with-current-buffer buffer
 623               (prin1 variable)
 624               (setq file-name (find-lisp-object-file-name variable 'defvar))
 625
 626               (if file-name
 627                   (progn
 628                     (princ " is a variable defined in `")
 629                     (princ (if (eq file-name 'C-source)
 630                                "C source code"
 631                              (file-name-nondirectory file-name)))
 632                     (princ "'.\n")
 633                     (with-current-buffer standard-output
 634                       (save-excursion
 635                         (re-search-backward "`\\([^`']+\\)'" nil t)
 636                         (help-xref-button 1 'help-variable-def
 637                                           variable file-name)))
 638                     (if valvoid
 639                         (princ "It is void as a variable.")
 640                       (princ "Its ")))
 641                 (if valvoid
 642                     (princ " is void as a variable.")
 643                   (princ "'s "))))
 644             (unless valvoid
 645               (with-current-buffer standard-output
 646                 (setq val-start-pos (point))
 647                 (princ "value is ")
 648                 (let ((from (point)))
 649                   (terpri)
 650                   (pp val)
 651                   (if (< (point) (+ 68 (line-beginning-position 0)))
 652                       (delete-region from (1+ from))
 653                     (delete-region (1- from) from))
 654                   (let* ((sv (get variable 'standard-value))
 655                          (origval (and (consp sv)
 656                                        (condition-case nil
 657                                            (eval (car sv))
 658                                          (error :help-eval-error)))))
 659                     (when (and (consp sv)
 660                                (not (equal origval val))
 661                                (not (equal origval :help-eval-error)))
 662                       (princ "\nOriginal value was \n")
 663                       (setq from (point))
 664                       (pp origval)
 665                       (if (< (point) (+ from 20))
 666                           (delete-region (1- from) from)))))))
 667             (terpri)
 668             (when locus
 669               (if (bufferp locus)
 670                   (princ (format "%socal in buffer %s; "
 671                                  (if (get variable 'permanent-local)
 672                                      "Permanently l" "L")
 673                                  (buffer-name)))
 674                 (princ (format "It is a frame-local variable; ")))
 675               (if (not (default-boundp variable))
 676                   (princ "globally void")
 677                 (let ((val (default-value variable)))
 678                   (with-current-buffer standard-output
 679                     (princ "global value is ")
 680                     (terpri)
 681                     ;; Fixme: pp can take an age if you happen to
 682                     ;; ask for a very large expression.  We should
 683                     ;; probably print it raw once and check it's a
 684                     ;; sensible size before prettyprinting.  -- fx
 685                     (let ((from (point)))
 686                       (pp val)
 687                       ;; See previous comment for this function.
 688                       ;; (help-xref-on-pp from (point))
 689                       (if (< (point) (+ from 20))
 690                           (delete-region (1- from) from))))))
 691               (terpri))
 692
 693             ;; If the value is large, move it to the end.
 694             (with-current-buffer standard-output
 695               (when (> (count-lines (point-min) (point-max)) 10)
 696                 ;; Note that setting the syntax table like below
 697                 ;; makes forward-sexp move over a `'s' at the end
 698                 ;; of a symbol.
 699                 (set-syntax-table emacs-lisp-mode-syntax-table)
 700                 (goto-char val-start-pos)
 701                 ;; The line below previously read as
 702                 ;; (delete-region (point) (progn (end-of-line) (point)))
 703                 ;; which suppressed display of the buffer local value for
 704                 ;; large values.
 705                 (when (looking-at "value is") (replace-match ""))
 706                 (save-excursion
 707                   (insert "\n\nValue:")
 708                   (set (make-local-variable 'help-button-cache)
 709                        (point-marker)))
 710                 (insert "value is shown ")
 711                 (insert-button "below"
 712                                'action help-button-cache
 713                                'follow-link t
 714                                'help-echo "mouse-2, RET: show value")
 715                 (insert ".\n")))
 716             (terpri)
 717
 718             (let* ((alias (condition-case nil
 719                               (indirect-variable variable)
 720                             (error variable)))
 721                    (obsolete (get variable 'byte-obsolete-variable))
 722                    (use (car obsolete))
 723                    (safe-var (get variable 'safe-local-variable))
 724                    (doc (or (documentation-property variable 'variable-documentation)
 725                             (documentation-property alias 'variable-documentation)))
 726                    (extra-line nil))
 727               ;; Add a note for variables that have been make-var-buffer-local.
 728               (when (and (local-variable-if-set-p variable)
 729                          (or (not (local-variable-p variable))
 730                              (with-temp-buffer
 731                                (local-variable-if-set-p variable))))
 732                 (setq extra-line t)
 733                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 734
 735               ;; Mention if it's an alias
 736               (unless (eq alias variable)
 737                 (setq extra-line t)
 738                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 739
 740               (when obsolete
 741                 (setq extra-line t)
 742                 (princ "  This variable is obsolete")
 743                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 744                 (princ (cond ((stringp use) (concat ";\n  " use))
 745                              (use (format ";\n  use `%s' instead." (car obsolete)))
 746                              (t ".")))
 747                 (terpri))
 748
 749               (when (member (cons variable val) file-local-variables-alist)
 750                 (setq extra-line t)
 751                 (if (member (cons variable val) dir-local-variables-alist)
 752                     (let ((file (and (buffer-file-name)
 753                                      (not (file-remote-p (buffer-file-name)))
 754                                      (dir-locals-find-file (buffer-file-name)))))
 755                       (princ "  This variable is a directory local variable")
 756                       (when file
 757                         (princ (concat "\n  from the file \""
 758                                        (if (consp file)
 759                                            (car file)
 760                                          file)
 761                                        "\"")))
 762                       (princ ".\n"))
 763                   (princ "  This variable is a file local variable.\n")))
 764
 765               (when (memq variable ignored-local-variables)
 766                 (setq extra-line t)
 767                 (princ "  This variable is ignored when used as a file local \
 768 variable.\n"))
 769
 770               ;; Can be both risky and safe, eg auto-fill-function.
 771               (when (risky-local-variable-p variable)
 772                 (setq extra-line t)
 773                 (princ "  This variable is potentially risky when used as a \
 774 file local variable.\n")
 775                 (when (assq variable safe-local-variable-values)
 776                   (princ "  However, you have added it to \
 777 `safe-local-variable-values'.\n")))
 778
 779               (when safe-var
 780                 (setq extra-line t)
 781                 (princ "  This variable is safe as a file local variable ")
 782                 (princ "if its value\n  satisfies the predicate ")
 783                 (princ (if (byte-code-function-p safe-var)
 784                            "which is byte-compiled expression.\n"
 785                          (format "`%s'.\n" safe-var))))
 786
 787               (if extra-line (terpri))
 788               (princ "Documentation:\n")
 789               (with-current-buffer standard-output
 790                 (insert (or doc "Not documented as a variable."))))
 791
 792             ;; Make a link to customize if this variable can be customized.
 793             (when (custom-variable-p variable)
 794               (let ((customize-label "customize"))
 795                 (terpri)
 796                 (terpri)
 797                 (princ (concat "You can " customize-label " this variable."))
 798                 (with-current-buffer standard-output
 799                   (save-excursion
 800                     (re-search-backward
 801                      (concat "\\(" customize-label "\\)") nil t)
 802                     (help-xref-button 1 'help-customize-variable variable))))
 803               ;; Note variable's version or package version
 804               (let ((output (describe-variable-custom-version-info variable)))
 805                 (when output
 806                   (terpri)
 807                   (terpri)
 808                   (princ output))))
 809
 810             (with-current-buffer standard-output
 811               ;; Return the text we displayed.
 812               (buffer-string))))))))
 813
 814
 815 ;;;###autoload
 816 (defun describe-syntax (&optional buffer)
 817   "Describe the syntax specifications in the syntax table of BUFFER.
 818 The descriptions are inserted in a help buffer, which is then displayed.
 819 BUFFER defaults to the current buffer."
 820   (interactive)
 821   (setq buffer (or buffer (current-buffer)))
 822   (help-setup-xref (list #'describe-syntax buffer)
 823                    (called-interactively-p 'interactive))
 824   (with-help-window (help-buffer)
 825     (let ((table (with-current-buffer buffer (syntax-table))))
 826       (with-current-buffer standard-output
 827         (describe-vector table 'internal-describe-syntax-value)
 828         (while (setq table (char-table-parent table))
 829           (insert "\nThe parent syntax table is:")
 830           (describe-vector table 'internal-describe-syntax-value))))))
 831
 832 (defun help-describe-category-set (value)
 833   (insert (cond
 834            ((null value) "default")
 835            ((char-table-p value) "deeper char-table ...")
 836            (t (condition-case err
 837                   (category-set-mnemonics value)
 838                 (error "invalid"))))))
 839
 840 ;;;###autoload
 841 (defun describe-categories (&optional buffer)
 842   "Describe the category specifications in the current category table.
 843 The descriptions are inserted in a buffer, which is then displayed.
 844 If BUFFER is non-nil, then describe BUFFER's category table instead.
 845 BUFFER should be a buffer or a buffer name."
 846   (interactive)
 847   (setq buffer (or buffer (current-buffer)))
 848   (help-setup-xref (list #'describe-categories buffer)
 849                    (called-interactively-p 'interactive))
 850   (with-help-window (help-buffer)
 851     (let* ((table (with-current-buffer buffer (category-table)))
 852            (docs (char-table-extra-slot table 0)))
 853       (if (or (not (vectorp docs)) (/= (length docs) 95))
 854           (error "Invalid first extra slot in this category table\n"))
 855       (with-current-buffer standard-output
 856         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 857         (let ((pos (point)) (items 0) lines n)
 858           (dotimes (i 95)
 859             (if (aref docs i) (setq items (1+ items))))
 860           (setq lines (1+ (/ (1- items) 4)))
 861           (setq n 0)
 862           (dotimes (i 95)
 863             (let ((elt (aref docs i)))
 864               (when elt
 865                 (string-match ".*" elt)
 866                 (setq elt (match-string 0 elt))
 867                 (if (>= (length elt) 17)
 868                     (setq elt (concat (substring elt 0 14) "...")))
 869                 (if (< (point) (point-max))
 870                     (move-to-column (* 20 (/ n lines)) t))
 871                 (insert (+ i ?\s) ?: elt)
 872                 (if (< (point) (point-max))
 873                     (forward-line 1)
 874                   (insert "\n"))
 875                 (setq n (1+ n))
 876                 (if (= (% n lines) 0)
 877                     (goto-char pos))))))
 878         (goto-char (point-max))
 879         (insert "\n"
 880                 "character(s)\tcategory mnemonics\n"
 881                 "------------\t------------------")
 882         (describe-vector table 'help-describe-category-set)
 883         (insert "Legend of category mnemonics:\n")
 884         (dotimes (i 95)
 885           (let ((elt (aref docs i)))
 886             (when elt
 887               (if (string-match "\n" elt)
 888                   (setq elt (substring elt (match-end 0))))
 889               (insert (+ i ?\s) ": " elt "\n"))))
 890         (while (setq table (char-table-parent table))
 891           (insert "\nThe parent category table is:")
 892           (describe-vector table 'help-describe-category-set))))))
 893
 894 \f
 895 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
 896
 897 ;; Replaces lib-src/digest-doc.c.
 898 ;;;###autoload
 899 (defun doc-file-to-man (file)
 900   "Produce an nroff buffer containing the doc-strings from the DOC file."
 901   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 902                                      internal-doc-file-name t)))
 903   (or (file-readable-p file)
 904       (error "Cannot read file `%s'" file))
 905   (pop-to-buffer (generate-new-buffer "*man-doc*"))
 906   (setq buffer-undo-list t)
 907   (insert ".TH \"Command Summary for GNU Emacs\"\n"
 908           ".AU Richard M. Stallman\n")
 909   (insert-file-contents file)
 910   (let (notfirst)
 911     (while (search-forward "\1f" nil 'move)
 912       (if (looking-at "S")
 913           (delete-region (1- (point)) (line-end-position))
 914         (delete-char -1)
 915         (if notfirst
 916             (insert "\n.DE\n")
 917           (setq notfirst t))
 918         (insert "\n.SH ")
 919         (insert (if (looking-at "F") "Function " "Variable "))
 920         (delete-char 1)
 921         (forward-line 1)
 922         (insert ".DS L\n"))))
 923   (insert "\n.DE\n")
 924   (setq buffer-undo-list nil)
 925   (nroff-mode))
 926
 927 ;; Replaces lib-src/sorted-doc.c.
 928 ;;;###autoload
 929 (defun doc-file-to-info (file)
 930   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
 931   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 932                                      internal-doc-file-name t)))
 933   (or (file-readable-p file)
 934       (error "Cannot read file `%s'" file))
 935   (let ((i 0) type name doc alist)
 936     (with-temp-buffer
 937       (insert-file-contents file)
 938       ;; The characters "@{}" need special treatment.
 939       (while (re-search-forward "[@{}]" nil t)
 940         (backward-char)
 941         (insert "@")
 942         (forward-char 1))
 943       (goto-char (point-min))
 944       (while (search-forward "\1f" nil t)
 945         (unless (looking-at "S")
 946           (setq type (char-after)
 947                 name (buffer-substring (1+ (point)) (line-end-position))
 948                 doc (buffer-substring (line-beginning-position 2)
 949                                       (if (search-forward  "\1f" nil 'move)
 950                                           (1- (point))
 951                                         (point)))
 952                 alist (cons (list name type doc) alist))
 953           (backward-char 1))))
 954     (pop-to-buffer (generate-new-buffer "*info-doc*"))
 955     (setq buffer-undo-list t)
 956     ;; Write the output header.
 957     (insert "\\input texinfo  @c -*-texinfo-*-\n"
 958             "@setfilename emacsdoc.info\n"
 959             "@settitle Command Summary for GNU Emacs\n"
 960             "@finalout\n"
 961             "\n@node Top\n"
 962             "@unnumbered Command Summary for GNU Emacs\n\n"
 963             "@table @asis\n\n"
 964             "@iftex\n"
 965             "@global@let@ITEM@item\n"
 966             "@def@item{@filbreak@vskip5pt@ITEM}\n"
 967             "@font@tensy cmsy10 scaled @magstephalf\n"
 968             "@font@teni cmmi10 scaled @magstephalf\n"
 969             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
 970             "@def|{{@tensy@char106}}\n"
 971             "@def@{{{@tensy@char102}}\n"
 972             "@def@}{{@tensy@char103}}\n"
 973             "@def<{{@teni@char62}}\n"
 974             "@def>{{@teni@char60}}\n"
 975             "@chardef@@64\n"
 976             "@catcode43=12\n"
 977             "@tableindent-0.2in\n"
 978             "@end iftex\n")
 979     ;; Sort the array by name; within each name, by type (functions first).
 980     (setq alist (sort alist (lambda (e1 e2)
 981                               (if (string-equal (car e1) (car e2))
 982                                   (<= (cadr e1) (cadr e2))
 983                                 (string-lessp (car e1) (car e2))))))
 984     ;; Print each function.
 985     (dolist (e alist)
 986       (insert "\n@item "
 987               (if (char-equal (cadr e) ?\F) "Function" "Variable")
 988               " @code{" (car e) "}\n@display\n"
 989               (nth 2 e)
 990               "\n@end display\n")
 991       ;; Try to avoid a save size overflow in the TeX output routine.
 992       (if (zerop (setq i (% (1+ i) 100)))
 993           (insert "\n@end table\n@table @asis\n")))
 994     (insert "@end table\n"
 995             "@bye\n")
 996     (setq buffer-undo-list nil)
 997     (texinfo-mode)))
 998
 999 (provide 'help-fns)
1000
1001 ;;; help-fns.el ends here