lisp/filecache.el

   1 ;;; filecache.el --- Find files using a pre-loaded cache
   2 ;;
   3 ;; Author:  Peter Breton <pbreton@cs.umb.edu>
   4 ;; Created: Sun Nov 10 1996
   5 ;; Keywords: convenience
   6 ;; Time-stamp: <1998-04-29 22:38:56 pbreton>
   7 ;;
   8 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; The file-cache package is an attempt to make it easy to locate files
  30 ;; by name, without having to remember exactly where they are located.
  31 ;; This is very handy when working with source trees. You can also add
  32 ;; frequently used files to the cache to create a hotlist effect.
  33 ;; The cache can be used with any interactive command which takes a
  34 ;; filename as an argument.
  35 ;;
  36 ;; It is worth noting that this package works best when most of the files
  37 ;; in the cache have unique names, or (if they have the same name) exist in
  38 ;; only a few directories. The worst case is many files all with
  39 ;; the same name and in different directories, for example a big source tree
  40 ;; with a Makefile in each directory. In such a case, you should probably
  41 ;; use an alternate strategy to find the files.
  42 ;;
  43 ;; ADDING FILES TO THE CACHE:
  44 ;;
  45 ;; Use the following functions to add items to the file cache:
  46 ;;
  47 ;;   * `file-cache-add-file': Adds a single file to the cache
  48 ;;
  49 ;;   * `file-cache-add-file-list': Adds a list of files to the cache
  50 ;;
  51 ;; The following functions use the regular expressions in
  52 ;; `file-cache-delete-regexps' to eliminate unwanted files:
  53 ;;
  54 ;;   * `file-cache-add-directory': Adds the files in a directory to the
  55 ;;     cache. You can also specify a regular expression to match the files
  56 ;;     which should be added.
  57 ;;
  58 ;;   * `file-cache-add-directory-list': Same as above, but acts on a list
  59 ;;     of directories. You can use `load-path', `exec-path' and the like.
  60 ;;
  61 ;;   * `file-cache-add-directory-using-find': Uses the `find' command to
  62 ;;     add a directory tree to the cache.
  63 ;;
  64 ;;   * `file-cache-add-directory-using-locate': Uses the `locate' command to
  65 ;;     add files matching a pattern to the cache.
  66 ;;
  67 ;; Use the function `file-cache-clear-cache' to remove all items from the
  68 ;; cache. There are a number of `file-cache-delete' functions provided
  69 ;; as well, but in general it is probably better to not worry too much
  70 ;; about extra files in the cache.
  71 ;;
  72 ;; The most convenient way to initialize the cache is with an
  73 ;; `eval-after-load' function, as noted in the ADDING FILES
  74 ;; AUTOMATICALLY section.
  75 ;;
  76 ;; FINDING FILES USING THE CACHE:
  77 ;;
  78 ;; You can use the file-cache with any function that expects a filename as
  79 ;; an argument. For example:
  80 ;;
  81 ;; 1) Invoke a function which expects a filename as an argument:
  82 ;;    M-x find-file
  83 ;;
  84 ;; 2) Begin typing a file name.
  85 ;;
  86 ;; 3) Invoke `file-cache-minibuffer-complete' (bound by default to
  87 ;; C-TAB) to complete on the filename using the cache.
  88 ;;
  89 ;; 4) When you have found a unique completion, the minibuffer contents
  90 ;; will change to the full name of that file.
  91 ;;
  92 ;; If there are a number of directories which contain the completion,
  93 ;; invoking `file-cache-minibuffer-complete' repeatedly will cycle through
  94 ;; them.
  95 ;;
  96 ;; 5) You can then edit the minibuffer contents, or press RETURN.
  97 ;;
  98 ;; It is much easier to simply try it than trying to explain it :)
  99 ;;
 100 ;;; ADDING FILES AUTOMATICALLY
 101 ;;
 102 ;; For maximum utility, you should probably define an `eval-after-load'
 103 ;; form which loads your favorite files:
 104 ;;
 105 ;;      (eval-after-load
 106 ;;       "filecache"
 107 ;;       '(progn
 108 ;;          (message "Loading file cache...")
 109 ;;          (file-cache-add-directory-using-find "~/projects")
 110 ;;          (file-cache-add-directory-list load-path)
 111 ;;          (file-cache-add-directory "~/")
 112 ;;          (file-cache-add-file-list (list "~/foo/bar" "~/baz/bar"))
 113 ;;         ))
 114 ;;
 115 ;; If you clear and reload the cache frequently, it is probably easiest
 116 ;; to put your initializations in a function:
 117 ;;
 118 ;;   (eval-after-load
 119 ;;     "filecache"
 120 ;;      '(my-file-cache-initialize))
 121 ;;
 122 ;;   (defun my-file-cache-initialize ()
 123 ;;      (interactive)
 124 ;;      (message "Loading file cache...")
 125 ;;      (file-cache-add-directory-using-find "~/projects")
 126 ;;      (file-cache-add-directory-list load-path)
 127 ;;      (file-cache-add-directory "~/")
 128 ;;      (file-cache-add-file-list (list "~/foo/bar" "~/baz/bar"))
 129 ;;   ))
 130 ;;
 131 ;; Of course, you can still add files to the cache afterwards, via
 132 ;; Lisp functions.
 133 ;;
 134 ;; RELATED WORK:
 135 ;;
 136 ;; This package is a distant relative of Noah Friedman's fff utilities.
 137 ;; Our goal is pretty similar, but the implementation strategies are
 138 ;; different.
 139
 140 ;;; Code:
 141
 142 (defgroup file-cache nil
 143   "Find files using a pre-loaded cache."
 144   :group 'files
 145   :group 'convenience
 146   :prefix "file-cache-")
 147
 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 149 ;; Customization Variables
 150 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 151
 152 ;; User-modifiable variables
 153 (defcustom file-cache-filter-regexps
 154   (list "~$" "\\.o$" "\\.exe$" "\\.a$" "\\.elc$" ",v$" "\\.output$"
 155         "\\.$" "#$")
 156   "*List of regular expressions used as filters by the file cache.
 157 File names which match these expressions will not be added to the cache.
 158 Note that the functions `file-cache-add-file' and `file-cache-add-file-list'
 159 do not use this variable."
 160   :type '(repeat regexp)
 161   :group 'file-cache)
 162
 163 (defcustom file-cache-find-command "find"
 164   "*External program used by `file-cache-add-directory-using-find'."
 165   :type 'string
 166   :group 'file-cache)
 167
 168 (defcustom file-cache-locate-command "locate"
 169   "*External program used by `file-cache-add-directory-using-locate'."
 170   :type 'string
 171   :group 'file-cache)
 172
 173 ;; Minibuffer messages
 174 (defcustom file-cache-no-match-message " [File Cache: No match]"
 175   "Message to display when there is no completion."
 176   :type 'string
 177   :group 'file-cache)
 178
 179 (defcustom file-cache-sole-match-message " [File Cache: sole completion]"
 180   "Message to display when there is only one completion."
 181   :type 'string
 182   :group 'file-cache)
 183
 184 (defcustom file-cache-non-unique-message
 185   " [File Cache: complete but not unique]"
 186   "Message to display when there is a non-unique completion."
 187   :type 'string
 188   :group 'file-cache)
 189
 190 (defvar file-cache-multiple-directory-message nil)
 191
 192 ;; Internal variables
 193 ;; This should be named *Completions* because that's what the function
 194 ;; switch-to-completions in simple.el expects
 195 (defcustom file-cache-completions-buffer "*Completions*"
 196   "Buffer to display completions when using the file cache."
 197   :type 'string
 198   :group 'file-cache)
 199
 200 (defcustom file-cache-buffer "*File Cache*"
 201   "Buffer to hold the cache of file names."
 202   :type 'string
 203   :group 'file-cache)
 204
 205 (defcustom file-cache-buffer-default-regexp "^.+$"
 206   "Regexp to match files in `file-cache-buffer'."
 207   :type 'regexp
 208   :group 'file-cache)
 209
 210 (defvar file-cache-last-completion nil)
 211
 212 (defvar file-cache-alist nil
 213   "Internal data structure to hold cache of file names.")
 214
 215 (defvar file-cache-completions-keymap nil
 216   "Keymap for file cache completions buffer.")
 217
 218 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 219 ;; Functions to add files to the cache
 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 221
 222 (defun file-cache-add-directory (directory &optional regexp)
 223   "Add DIRECTORY to the file cache.
 224 If the optional REGEXP argument is non-nil, only files which match it will
 225 be added to the cache."
 226   (interactive "DAdd files from directory: ")
 227   ;; Not an error, because otherwise we can't use load-paths that
 228   ;; contain non-existent directories.
 229   (if (not (file-accessible-directory-p directory))
 230       (message "Directory %s does not exist" directory)
 231     (let* ((dir       (expand-file-name directory))
 232            (dir-files (directory-files dir t regexp))
 233            )
 234       ;; Filter out files we don't want to see
 235       (mapcar
 236        '(lambda (file)
 237         (mapcar
 238          '(lambda (regexp)
 239             (if (string-match regexp file)
 240                 (setq dir-files (delq file dir-files))))
 241          file-cache-filter-regexps))
 242        dir-files)
 243       (file-cache-add-file-list dir-files))))
 244
 245 (defun file-cache-add-directory-list (directory-list &optional regexp)
 246   "Add DIRECTORY-LIST (a list of directory names) to the file cache.
 247 If the optional REGEXP argument is non-nil, only files which match it
 248 will be added to the cache. Note that the REGEXP is applied to the files
 249 in each directory, not to the directory list itself."
 250   (interactive "XAdd files from directory list: ")
 251   (mapcar
 252    '(lambda (dir) (file-cache-add-directory dir regexp))
 253    directory-list))
 254
 255 (defun file-cache-add-file-list  (file-list)
 256   "Add FILE-LIST (a list of files names) to the file cache."
 257   (interactive "XFile List: ")
 258   (mapcar 'file-cache-add-file file-list))
 259
 260 ;; Workhorse function
 261 (defun file-cache-add-file (file)
 262   "Add FILE to the file cache."
 263   (interactive "fAdd File: ")
 264   (if (not (file-exists-p file))
 265       (message "File %s does not exist" file)
 266     (let* ((file-name (file-name-nondirectory file))
 267            (dir-name  (file-name-directory    file))
 268            (the-entry (assoc file-name file-cache-alist))
 269            )
 270       ;; Does the entry exist already?
 271       (if the-entry
 272           (if (or (and (stringp (cdr the-entry))
 273                        (string= dir-name (cdr the-entry)))
 274                   (and (listp (cdr the-entry))
 275                        (member dir-name (cdr the-entry))))
 276               nil
 277             (setcdr the-entry (append (list dir-name) (cdr the-entry)))
 278             )
 279         ;; If not, add it to the cache
 280         (setq file-cache-alist
 281               (cons (cons file-name (list dir-name))
 282                     file-cache-alist)))
 283       )))
 284
 285 (defun file-cache-add-directory-using-find (directory)
 286   "Use the `find' command to add files to the file cache.
 287 Find is run in DIRECTORY."
 288   (interactive "DAdd files under directory: ")
 289   (let ((dir (expand-file-name directory)))
 290     (set-buffer (get-buffer-create file-cache-buffer))
 291     (erase-buffer)
 292     (call-process file-cache-find-command nil
 293                   (get-buffer file-cache-buffer) nil
 294                   dir "-name"
 295                   (if (memq system-type
 296                             (list 'windows-nt 'ms-dos)) "'*'" "*")
 297                   "-print")
 298     (file-cache-add-from-file-cache-buffer)))
 299
 300 (defun file-cache-add-directory-using-locate (string)
 301   "Use the `locate' command to add files to the file cache.
 302 STRING is passed as an argument to the locate command."
 303   (interactive "sAdd files using locate string: ")
 304   (set-buffer (get-buffer-create file-cache-buffer))
 305   (erase-buffer)
 306   (call-process file-cache-locate-command nil
 307                 (get-buffer file-cache-buffer) nil
 308                 string)
 309   (file-cache-add-from-file-cache-buffer))
 310
 311 (defun file-cache-add-from-file-cache-buffer (&optional regexp)
 312   "Add any entries found in the file cache buffer.
 313 Each entry matches the regular expression `file-cache-buffer-default-regexp'
 314 or the optional REGEXP argument."
 315   (set-buffer file-cache-buffer)
 316   (mapcar
 317    (function (lambda (elt)
 318                (goto-char (point-min))
 319                (delete-matching-lines elt)))
 320    file-cache-filter-regexps)
 321   (goto-char (point-min))
 322   (let ((full-filename))
 323     (while (re-search-forward
 324             (or regexp file-cache-buffer-default-regexp)
 325             (point-max) t)
 326       (setq full-filename (buffer-substring-no-properties
 327                       (match-beginning 0) (match-end 0)))
 328       (file-cache-add-file full-filename))))
 329
 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 331 ;; Functions to delete from the cache
 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 333
 334 (defun file-cache-clear-cache ()
 335   "Clear the file cache."
 336   (interactive)
 337   (setq file-cache-alist nil))
 338
 339 ;; This clears *all* files with the given name
 340 (defun file-cache-delete-file (file)
 341   "Delete FILE from the file cache."
 342   (interactive
 343    (list (completing-read "Delete file from cache: " file-cache-alist)))
 344   (setq file-cache-alist
 345         (delq (assoc file file-cache-alist) file-cache-alist)))
 346
 347 (defun file-cache-delete-file-list (file-list)
 348   "Delete FILE-LIST (a list of files) from the file cache."
 349   (interactive "XFile List: ")
 350   (mapcar 'file-cache-delete-file file-list))
 351
 352 (defun file-cache-delete-file-regexp (regexp)
 353   "Delete files matching REGEXP from the file cache."
 354   (interactive "sRegexp: ")
 355   (let ((delete-list))
 356     (mapcar '(lambda (elt)
 357                (and (string-match regexp (car elt))
 358                     (setq delete-list (cons (car elt) delete-list))))
 359             file-cache-alist)
 360     (file-cache-delete-file-list delete-list)
 361     (message "Deleted %d files from file cache" (length delete-list))))
 362
 363 (defun file-cache-delete-directory (directory)
 364   "Delete DIRECTORY from the file cache."
 365   (interactive "DDelete directory from file cache: ")
 366   (let ((dir (expand-file-name directory))
 367         (result 0))
 368     (mapcar
 369      '(lambda (entry)
 370         (if (file-cache-do-delete-directory dir entry)
 371             (setq result (1+ result))))
 372      file-cache-alist)
 373     (if (zerop result)
 374         (error "No entries containing %s found in cache" directory)
 375       (message "Deleted %d entries" result))))
 376
 377 (defun file-cache-do-delete-directory (dir entry)
 378   (let ((directory-list (cdr entry))
 379         (directory (file-cache-canonical-directory dir))
 380         )
 381     (and (member directory directory-list)
 382          (if (equal 1 (length directory-list))
 383              (setq file-cache-alist
 384                    (delq entry file-cache-alist))
 385            (setcdr entry (delete directory directory-list)))
 386          )
 387     ))
 388
 389 (defun file-cache-delete-directory-list (directory-list)
 390   "Delete DIRECTORY-LIST (a list of directories) from the file cache."
 391   (interactive "XDirectory List: ")
 392   (mapcar 'file-cache-delete-directory directory-list))
 393
 394 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 395 ;; Utility functions
 396 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 397
 398 ;; Returns the name of a directory for a file in the cache
 399 (defun file-cache-directory-name  (file)
 400   (let* ((directory-list (cdr (assoc file file-cache-alist)))
 401          (len            (length directory-list))
 402          (directory)
 403          (num)
 404          )
 405     (if (not (listp directory-list))
 406         (error "Unknown type in file-cache-alist for key %s" file))
 407     (cond
 408      ;; Single element
 409      ((eq 1 len)
 410       (setq directory (elt directory-list 0)))
 411      ;; No elements
 412      ((eq 0 len)
 413       (error "No directory found for key %s" file))
 414      ;; Multiple elements
 415      (t
 416       (let* ((minibuffer-dir (file-name-directory (buffer-string)))
 417              (dir-list       (member minibuffer-dir directory-list))
 418              )
 419         (setq directory
 420               ;; If the directory is in the list, return the next element
 421               ;; Otherwise, return the first element
 422               (if dir-list
 423                   (or (elt directory-list
 424                            (setq num (1+ (- len (length dir-list)))))
 425                       (elt directory-list (setq num 0)))
 426                 (elt directory-list (setq num 0))))
 427         )
 428       )
 429      )
 430     ;; If there were multiple directories, set up a minibuffer message
 431     (setq file-cache-multiple-directory-message
 432           (and num (format " [%d of %d]" (1+ num) len)))
 433     directory))
 434
 435 ;; Returns the name of a file in the cache
 436 (defun file-cache-file-name  (file)
 437   (let ((directory (file-cache-directory-name file)))
 438     (concat directory file)))
 439
 440 ;; Return a canonical directory for comparison purposes.
 441 ;; Such a directory ends with a forward slash.
 442 (defun file-cache-canonical-directory (dir)
 443   (let ((directory dir))
 444     (if (not (char-equal ?/ (string-to-char (substring directory -1))))
 445         (concat directory "/")
 446       directory)))
 447
 448 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 449 ;; Minibuffer functions
 450 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 451
 452 ;; The prefix argument works around a bug in the minibuffer completion.
 453 ;; The completion function doesn't distinguish between the states:
 454 ;;
 455 ;;   "Multiple completions of name" (eg, Makefile, Makefile.in)
 456 ;;   "Name available in multiple directories" (/tmp/Makefile, ~me/Makefile)
 457 ;;
 458 ;; The default is to do the former; a prefix arg forces the latter.
 459
 460 ;;;###autoload
 461 (defun file-cache-minibuffer-complete (arg)
 462   "Complete a filename in the minibuffer using a preloaded cache.
 463 Filecache does two kinds of substitution: it completes on names in
 464 the cache, and, once it has found a unique name, it cycles through
 465 the directories that the name is available in.  With a prefix argument,
 466 the name is considered already unique; only the second substitution
 467 \(directories) is done."
 468   (interactive "P")
 469   (let*
 470       (
 471        (completion-ignore-case nil)
 472        (case-fold-search       nil)
 473        (string                 (file-name-nondirectory (buffer-string)))
 474        (completion-string      (try-completion string file-cache-alist))
 475        (completion-list)
 476        (len)
 477        (file-cache-string)
 478        )
 479     (cond
 480      ;; If it's the only match, replace the original contents
 481      ((or arg (eq completion-string t))
 482       (setq file-cache-string (file-cache-file-name string))
 483       (if (string= file-cache-string (buffer-string))
 484           (file-cache-temp-minibuffer-message file-cache-sole-match-message)
 485         (erase-buffer)
 486         (insert-string file-cache-string)
 487         (if file-cache-multiple-directory-message
 488             (file-cache-temp-minibuffer-message
 489              file-cache-multiple-directory-message))
 490       ))
 491
 492      ;; If it's the longest match, insert it
 493      ((stringp completion-string)
 494       ;; If we've already inserted a unique string, see if the user
 495       ;; wants to use that one
 496       (if (and (string= string completion-string)
 497                (assoc string file-cache-alist))
 498           (if (and (eq last-command this-command)
 499                    (string= file-cache-last-completion completion-string))
 500               (progn
 501                 (erase-buffer)
 502                 (insert-string (file-cache-file-name completion-string))
 503                 (setq file-cache-last-completion nil)
 504                 )
 505             (file-cache-temp-minibuffer-message file-cache-non-unique-message)
 506             (setq file-cache-last-completion string)
 507             )
 508         (setq file-cache-last-completion string)
 509         (setq completion-list (all-completions string file-cache-alist)
 510               len             (length completion-list))
 511         (if (> len 1)
 512             (progn
 513               (goto-char (point-max))
 514               (insert-string
 515                (substring completion-string (length string)))
 516               ;; Add our own setup function to the Completions Buffer
 517               (let ((completion-setup-hook
 518                    (reverse
 519                     (append (list 'file-cache-completion-setup-function)
 520                             completion-setup-hook)))
 521                     )
 522                 (with-output-to-temp-buffer file-cache-completions-buffer
 523                   (display-completion-list completion-list))
 524                 )
 525               )
 526           (setq file-cache-string (file-cache-file-name completion-string))
 527           (if (string= file-cache-string (buffer-string))
 528               (file-cache-temp-minibuffer-message
 529                file-cache-sole-match-message)
 530             (erase-buffer)
 531             (insert-string file-cache-string)
 532             (if file-cache-multiple-directory-message
 533                 (file-cache-temp-minibuffer-message
 534                  file-cache-multiple-directory-message)))
 535           )))
 536
 537      ;; No match
 538      ((eq completion-string nil)
 539       (file-cache-temp-minibuffer-message file-cache-no-match-message))
 540      )
 541 ))
 542
 543 ;; Lifted from "complete.el"
 544 (defun file-cache-temp-minibuffer-message (msg)
 545   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 546   (let ((savemax (point-max)))
 547     (save-excursion
 548       (goto-char (point-max))
 549       (insert msg))
 550     (let ((inhibit-quit t))
 551       (sit-for 2)
 552       (delete-region savemax (point-max))
 553       (if quit-flag
 554           (setq quit-flag nil
 555                 unread-command-events (list 7))))))
 556
 557 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 558 ;; Completion functions
 559 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 560
 561 (defun file-cache-completion-setup-function  ()
 562   (set-buffer file-cache-completions-buffer)
 563
 564   (if file-cache-completions-keymap
 565       nil
 566     (setq file-cache-completions-keymap
 567           (copy-keymap completion-list-mode-map))
 568     (define-key file-cache-completions-keymap [mouse-2]
 569       'file-cache-mouse-choose-completion)
 570     (define-key file-cache-completions-keymap "\C-m"
 571       'file-cache-choose-completion))
 572
 573     (use-local-map file-cache-completions-keymap)
 574     )
 575
 576 (defun file-cache-choose-completion  ()
 577   "Choose a completion in the `*Completions*' buffer."
 578   (interactive)
 579   (let ((completion-no-auto-exit t))
 580     (choose-completion)
 581     (select-window (active-minibuffer-window))
 582     (file-cache-minibuffer-complete nil)
 583     )
 584   )
 585
 586 (defun file-cache-mouse-choose-completion  (event)
 587   "Choose a completion with the mouse."
 588   (interactive "e")
 589   (let ((completion-no-auto-exit t))
 590     (mouse-choose-completion event)
 591     (select-window (active-minibuffer-window))
 592     (file-cache-minibuffer-complete nil)
 593     )
 594   )
 595
 596 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 597 ;; Debugging functions
 598 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 599
 600 (defun file-cache-debug-read-from-minibuffer (file)
 601   "Debugging function."
 602   (interactive
 603    (list (completing-read "File Cache: " file-cache-alist)))
 604   (message "%s" (assoc file file-cache-alist))
 605   )
 606
 607 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 608 ;; Keybindings
 609 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 610
 611 ;;;###autoload (define-key minibuffer-local-completion-map [C-tab] 'file-cache-minibuffer-complete)
 612 ;;;###autoload (define-key minibuffer-local-map [C-tab] 'file-cache-minibuffer-complete)
 613 ;;;###autoload (define-key minibuffer-local-must-match-map [C-tab] 'file-cache-minibuffer-complete)
 614
 615 (provide 'filecache)
 616
 617 ;;; filecache.el ends here