lisp/map-ynp.el

   1 ;;; map-ynp.el --- General-purpose boolean question-asker.
   2
   3 ;;; Copyright (C) 1991, 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Roland McGrath <roland@gnu.ai.mit.edu>
   6 ;; Keywords: lisp, extensions
   7
   8 ;;; This program is free software; you can redistribute it and/or modify
   9 ;;; it under the terms of the GNU General Public License as published by
  10 ;;; the Free Software Foundation; either version 2, or (at your option)
  11 ;;; any later version.
  12 ;;;
  13 ;;; This program is distributed in the hope that it will be useful,
  14 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;;; GNU General Public License for more details.
  17 ;;;
  18 ;;; A copy of the GNU General Public License can be obtained from this
  19 ;;; program's author (send electronic mail to roland@ai.mit.edu) or from
  20 ;;; the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA
  21 ;;; 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; map-y-or-n-p is a general-purpose question-asking function.
  26 ;;; It asks a series of y/n questions (a la y-or-n-p), and decides to
  27 ;;; applies an action to each element of a list based on the answer.
  28 ;;; The nice thing is that you also get some other possible answers
  29 ;;; to use, reminiscent of query-replace: ! to answer y to all remaining
  30 ;;; questions; ESC or q to answer n to all remaining questions; . to answer
  31 ;;; y once and then n for the remainder; and you can get help with C-h.
  32
  33 ;;; Code:
  34
  35 ;;;###autoload
  36 (defun map-y-or-n-p (prompter actor list &optional help action-alist)
  37   "Ask a series of boolean questions.
  38 Takes args PROMPTER ACTOR LIST, and optional args HELP and ACTION-ALIST.
  39
  40 LIST is a list of objects, or a function of no arguments to return the next
  41 object or nil.
  42
  43 If PROMPTER is a string, the prompt is \(format PROMPTER OBJECT\).  If not
  44 a string, PROMPTER is a function of one arg (an object from LIST), which
  45 returns a string to be used as the prompt for that object.  If the return
  46 value is not a string, it is eval'd to get the answer; it may be nil to
  47 ignore the object, t to act on the object without asking the user, or a
  48 form to do a more complex prompt.
  49
  50 ACTOR is a function of one arg (an object from LIST),
  51 which gets called with each object that the user answers `yes' for.
  52
  53 If HELP is given, it is a list (OBJECT OBJECTS ACTION),
  54 where OBJECT is a string giving the singular noun for an elt of LIST;
  55 OBJECTS is the plural noun for elts of LIST, and ACTION is a transitive
  56 verb describing ACTOR.  The default is \(\"object\" \"objects\" \"act on\"\).
  57
  58 At the prompts, the user may enter y, Y, or SPC to act on that object;
  59 n, N, or DEL to skip that object; ! to act on all following objects;
  60 ESC or q to exit (skip all following objects); . (period) to act on the
  61 current object and then exit; or \\[help-command] to get help.
  62
  63 If ACTION-ALIST is given, it is an alist (KEY FUNCTION HELP) of extra keys
  64 that will be accepted.  KEY is a character; FUNCTION is a function of one
  65 arg (an object from LIST); HELP is a string.  When the user hits KEY,
  66 FUNCTION is called.  If it returns non-nil, the object is considered
  67 \"acted upon\", and the next object from LIST is processed.  If it returns
  68 nil, the prompt is repeated for the same object.
  69
  70 This function uses `query-replace-map' to define the standard responses,
  71 but not all of the responses which `query-replace' understands
  72 are meaningful here.
  73
  74 Returns the number of actions taken."
  75   (let* ((user-keys (if action-alist
  76                         (concat (mapconcat (function
  77                                             (lambda (elt)
  78                                               (key-description
  79                                                (char-to-string (car elt)))))
  80                                            action-alist ", ")
  81                                 " ")
  82                       ""))
  83          ;; Make a map that defines all the user keys as `user'.
  84          (map (cons 'keymap
  85                     (append (mapcar (function
  86                                      (lambda (elt)
  87                                        (cons (car elt) 'user)))
  88                                     action-alist)
  89                             query-replace-map)))
  90          (actions 0)
  91          prompt char elt tail def
  92          (next (if (or (symbolp list)
  93                        (subrp list)
  94                        (byte-code-function-p list)
  95                        (and (consp list)
  96                             (eq (car list) 'lambda)))
  97                    (function (lambda ()
  98                                (setq elt (funcall list))))
  99                  (function (lambda ()
 100                              (if list
 101                                  (progn
 102                                    (setq elt (car list)
 103                                          list (cdr list))
 104                                    t)
 105                                nil))))))
 106
 107     (if (stringp prompter)
 108         (setq prompter (` (lambda (object)
 109                             (format (, prompter) object)))))
 110     (while (funcall next)
 111       (setq prompt (funcall prompter elt))
 112       (if (stringp prompt)
 113           (progn
 114             (setq quit-flag nil)
 115             ;; Prompt the user about this object.
 116             (let ((cursor-in-echo-area t))
 117               (message "%s(y, n, !, ., q, %sor %s) "
 118                        prompt user-keys
 119                        (key-description (char-to-string help-char)))
 120               (setq char (read-event)))
 121             (setq def (lookup-key map (vector char)))
 122             (cond ((eq def 'exit)
 123                    (setq next (function (lambda () nil))))
 124                   ((eq def 'act)
 125                    ;; Act on the object.
 126                    (funcall actor elt)
 127                    (setq actions (1+ actions)))
 128                   ((eq def 'skip)
 129                    ;; Skip the object.
 130                    )
 131                   ((eq def 'act-and-exit)
 132                    ;; Act on the object and then exit.
 133                    (funcall actor elt)
 134                    (setq actions (1+ actions)
 135                          next (function (lambda () nil))))
 136                   ((eq def 'quit)
 137                    (setq quit-flag t)
 138                    (setq next (` (lambda ()
 139                                    (setq next '(, next))
 140                                    '(, elt)))))
 141                   ((eq def 'automatic)
 142                    ;; Act on this and all following objects.
 143                    (if (eval (funcall prompter elt))
 144                        (progn
 145                          (funcall actor elt)
 146                          (setq actions (1+ actions))))
 147                    (while (funcall next)
 148                      (if (eval (funcall prompter elt))
 149                          (progn
 150                            (funcall actor elt)
 151                            (setq actions (1+ actions))))))
 152                   ((eq def 'help)
 153                    (with-output-to-temp-buffer "*Help*"
 154                      (princ
 155                       (let ((object (if help (nth 0 help) "object"))
 156                             (objects (if help (nth 1 help) "objects"))
 157                             (action (if help (nth 2 help) "act on")))
 158                         (concat (format "Type SPC or `y' to %s the current %s;
 159 DEL or `n' to skip the current %s;
 160 ! to %s all remaining %s;
 161 ESC or `q' to exit;\n"
 162                                         action object object action objects)
 163                                 (mapconcat (function
 164                                             (lambda (elt)
 165                                               (format "%c to %s"
 166                                                       (nth 0 elt)
 167                                                       (nth 2 elt))))
 168                                            action-alist
 169                                            ";\n")
 170                                 (if action-alist ";\n")
 171                                 (format "or . (period) to %s \
 172 the current %s and exit."
 173                                         action object)))))
 174
 175                    (setq next (` (lambda ()
 176                                    (setq next '(, next))
 177                                    '(, elt)))))
 178                   ((eq def 'user)
 179                    ;; A user-defined key.
 180                    (if (funcall (nth 1 tail) elt) ;Call its function.
 181                        ;; The function has eaten this object.
 182                        (setq actions (1+ actions))
 183                      ;; Regurgitated; try again.
 184                      (setq next (` (lambda ()
 185                                      (setq next '(, next))
 186                                      '(, elt))))))
 187                   (t
 188                    ;; Random char.
 189                    (message "Type %s for help."
 190                             (key-description (char-to-string help-char)))
 191                    (beep)
 192                    (sit-for 1)
 193                    (setq next (` (lambda ()
 194                                    (setq next '(, next))
 195                                    '(, elt)))))))
 196         (if (eval prompt)
 197             (progn
 198               (funcall actor elt)
 199               (setq actions (1+ actions))))))
 200     ;; Clear the last prompt from the minibuffer.
 201     (message "")
 202     ;; Return the number of actions that were taken.
 203     actions))
 204
 205 ;;; map-ynp.el ends here