configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.91)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 ## For the times when you want to build Emacs but don't have
 181 ## a suitable makeinfo, and can live without the manuals.
 182 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 183 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 184
 185 ## This is an option because I do not know if all info/man support
 186 ## compressed files, nor how to test if they do so.
 187 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 188 if test $with_compress_info = yes; then
 189    GZIP_INFO=yes
 190 else
 191    GZIP_INFO=
 192 fi
 193 AC_SUBST(GZIP_INFO)
 194
 195 AC_ARG_WITH([pkg-config-prog],dnl
 196 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 197                   [path to pkg-config for finding GTK and librsvg])])
 198 if test "X${with_pkg_config_prog}" != X; then
 199    if test "${with_pkg_config_prog}" != yes; then
 200       PKG_CONFIG="${with_pkg_config_prog}"
 201    fi
 202 fi
 203
 204 CRT_DIR=
 205 AC_ARG_WITH([crt-dir],dnl
 206 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 207 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 208 CRT_DIR="${with_crt_dir}"
 209
 210 AC_ARG_WITH(gameuser,dnl
 211 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 212 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 213   && gameuser="${with_gameuser}"
 214 test "X$gameuser" = X && gameuser=games
 215
 216 AC_ARG_WITH([gnustep-conf],dnl
 217 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 218 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 219   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 220 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 221      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 222
 223 AC_ARG_ENABLE(ns-self-contained,
 224 [AS_HELP_STRING([--disable-ns-self-contained],
 225                 [disable self contained build under NeXTstep])],
 226    EN_NS_SELF_CONTAINED=$enableval,
 227    EN_NS_SELF_CONTAINED=yes)
 228
 229 AC_ARG_ENABLE(asserts,
 230 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 231       USE_XASSERTS=$enableval,
 232       USE_XASSERTS=no)
 233
 234 AC_ARG_ENABLE(maintainer-mode,
 235 [AS_HELP_STRING([--disable-maintainer-mode],
 236                 [disable make rules and dependencies not useful (and sometimes
 237                  confusing) to the casual installer])],
 238       USE_MAINTAINER_MODE=$enableval,
 239       USE_MAINTAINER_MODE=yes)
 240 if test $USE_MAINTAINER_MODE = yes; then
 241   MAINT=
 242 else
 243   MAINT=#
 244 fi
 245 AC_SUBST(MAINT)
 246
 247 AC_ARG_ENABLE(locallisppath,
 248 [AS_HELP_STRING([--enable-locallisppath=PATH],
 249                 [directories Emacs should search for lisp files specific
 250                  to this site])],
 251 if test "${enableval}" = "no"; then
 252   locallisppath=
 253 elif test "${enableval}" != "yes"; then
 254   locallisppath=${enableval}
 255 fi)
 256
 257 AC_ARG_ENABLE(checking,
 258 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 259                 [enable expensive run-time checks.  With LIST,
 260                  enable only specific categories of checks.
 261                  Categories are: all,yes,no.
 262                  Flags are: stringbytes, stringoverrun, stringfreelist,
 263                  xmallocoverrun, conslist])],
 264 [ac_checking_flags="${enableval}"],[])
 265 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 266 for check in $ac_checking_flags
 267 do
 268         case $check in
 269         # these set all the flags to specific states
 270         yes)            ac_enable_checking=1 ;;
 271         no)             ac_enable_checking= ;
 272                         ac_gc_check_stringbytes= ;
 273                         ac_gc_check_string_overrun= ;
 274                         ac_gc_check_string_free_list= ;
 275                         ac_xmalloc_overrun= ;
 276                         ac_gc_check_cons_list= ;;
 277         all)            ac_enable_checking=1 ;
 278                         ac_gc_check_stringbytes=1 ;
 279                         ac_gc_check_string_overrun=1 ;
 280                         ac_gc_check_string_free_list=1 ;
 281                         ac_xmalloc_overrun=1 ;
 282                         ac_gc_check_cons_list=1 ;;
 283         # these enable particular checks
 284         stringbytes)    ac_gc_check_stringbytes=1 ;;
 285         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 286         stringfreelist) ac_gc_check_string_free_list=1 ;;
 287         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 288         conslist)       ac_gc_check_cons_list=1 ;;
 289         *)      AC_MSG_ERROR(unknown check category $check) ;;
 290         esac
 291 done
 292 IFS="$ac_save_IFS"
 293
 294 if test x$ac_enable_checking != x ; then
 295   AC_DEFINE(ENABLE_CHECKING, 1,
 296 [Enable expensive run-time checking of data types?])
 297 fi
 298 if test x$ac_gc_check_stringbytes != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 300 [Define this temporarily to hunt a bug.  If defined, the size of
 301    strings is redundantly recorded in sdata structures so that it can
 302    be compared to the sizes recorded in Lisp strings.])
 303 fi
 304 if test x$ac_gc_check_string_overrun != x ; then
 305   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 306 [Define this to check for short string overrun.])
 307 fi
 308 if test x$ac_gc_check_string_free_list != x ; then
 309   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 310 [Define this to check the string free list.])
 311 fi
 312 if test x$ac_xmalloc_overrun != x ; then
 313   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 314 [Define this to check for malloc buffer overrun.])
 315 fi
 316 if test x$ac_gc_check_cons_list != x ; then
 317   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 318 [Define this to check for errors in cons list.])
 319 fi
 320
 321 AC_ARG_ENABLE(use-lisp-union-type,
 322 [AS_HELP_STRING([--enable-use-lisp-union-type],
 323                 [use a union for the Lisp_Object data type.
 324                 This is only useful for development for catching certain types of bugs.])],
 325 if test "${enableval}" != "no"; then
 326    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 327    [Define this to use a lisp union for the Lisp_Object data type.])
 328 fi)
 329
 330
 331 AC_ARG_ENABLE(profiling,
 332 [AS_HELP_STRING([--enable-profiling],
 333                 [build emacs with profiling support.
 334                  This might not work on all platforms])],
 335 [ac_enable_profiling="${enableval}"],[])
 336 if test x$ac_enable_profiling != x ; then
 337    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 338 else
 339    PROFILING_CFLAGS=
 340 fi
 341 AC_SUBST(PROFILING_CFLAGS)
 342
 343 AC_ARG_ENABLE(autodepend,
 344 [AS_HELP_STRING([--enable-autodepend],
 345                 [automatically generate dependencies to .h-files.
 346                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 347                  found])],
 348 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 349
 350 #### Make srcdir absolute, if it isn't already.  It's important to
 351 #### avoid running the path through pwd unnecessarily, since pwd can
 352 #### give you automounter prefixes, which can go away.  We do all this
 353 #### so Emacs can find its files when run uninstalled.
 354 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 355 unset CDPATH
 356 case "${srcdir}" in
 357   /* ) ;;
 358   . )
 359     ## We may be able to use the $PWD environment variable to make this
 360     ## absolute.  But sometimes PWD is inaccurate.
 361     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 362     ## but that tested only for a well-formed and valid PWD,
 363     ## it did not object when PWD was well-formed and valid but just wrong.
 364     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 365     then
 366       srcdir="$PWD"
 367     else
 368       srcdir="`(cd ${srcdir}; pwd)`"
 369     fi
 370   ;;
 371   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 372 esac
 373
 374 #### Given the configuration name, set machfile and opsysfile to the
 375 #### names of the m/*.h and s/*.h files we should use.
 376
 377 ### Canonicalize the configuration name.
 378
 379 AC_CANONICAL_HOST
 380 canonical=$host
 381 configuration=${host_alias-${build_alias-$host}}
 382
 383 dnl This used to use changequote, but, apart from `changequote is evil'
 384 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 385 dnl the great gob of text.  Thus it's not processed for possible expansion.
 386 dnl Just make sure the brackets remain balanced.
 387 dnl
 388 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 389 dnl indicated by comments.
 390 dnl quotation begins
 391 [
 392
 393 ### If you add support for a new configuration, add code to this
 394 ### switch statement to recognize your configuration name and select
 395 ### the appropriate operating system and machine description files.
 396
 397 ### You would hope that you could choose an m/*.h file pretty much
 398 ### based on the machine portion of the configuration name, and an s/*.h
 399 ### file based on the operating system portion.  However, it turns out
 400 ### that each m/*.h file is pretty manufacturer-specific - for
 401 ### example mips.h is MIPS
 402 ### So we basically have to have a special case for each
 403 ### configuration name.
 404 ###
 405 ### As far as handling version numbers on operating systems is
 406 ### concerned, make sure things will fail in a fixable way.  If
 407 ### /etc/MACHINES doesn't say anything about version numbers, be
 408 ### prepared to handle anything reasonably.  If version numbers
 409 ### matter, be sure /etc/MACHINES says something about it.
 410
 411 machine='' opsys='' unported=no
 412 case "${canonical}" in
 413
 414   ## GNU/Linux and similar ports
 415   *-*-linux* )
 416     opsys=gnu-linux
 417     case ${canonical} in
 418       alpha*)   machine=alpha ;;
 419       s390x-*)  machine=ibms390x ;;
 420       powerpc*) machine=macppc ;;
 421       sparc*)   machine=sparc ;;
 422       ia64*)    machine=ia64 ;;
 423       m68k*)    machine=m68k ;;
 424       x86_64*)  machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## FreeBSD ports
 429   *-*-freebsd* )
 430     opsys=freebsd
 431     case "${canonical}" in
 432       alpha*)           machine=alpha ;;
 433       amd64-*|x86_64-*) machine=amdx86-64 ;;
 434       ia64-*)           machine=ia64 ;;
 435       i[3456]86-*)      machine=intel386 ;;
 436       powerpc-*)        machine=macppc ;;
 437       sparc-*)          machine=sparc ;;
 438       sparc64-*)        machine=sparc ;;
 439     esac
 440   ;;
 441
 442   ## FreeBSD kernel + glibc based userland
 443   *-*-kfreebsd*gnu* )
 444     opsys=gnu-kfreebsd
 445     case "${canonical}" in
 446       alpha*)           machine=alpha ;;
 447       amd64-*|x86_64-*) machine=amdx86-64 ;;
 448       ia64-*)           machine=ia64 ;;
 449       i[3456]86-*)      machine=intel386 ;;
 450       powerpc-*)        machine=macppc ;;
 451       sparc-*)          machine=sparc ;;
 452       sparc64-*)        machine=sparc ;;
 453     esac
 454   ;;
 455
 456   ## NetBSD ports
 457   *-*-netbsd* )
 458     opsys=netbsd
 459     case "${canonical}" in
 460       alpha*)      machine=alpha ;;
 461       x86_64-*)    machine=amdx86-64 ;;
 462       i[3456]86-*) machine=intel386 ;;
 463       m68k-*)      machine=m68k ;;
 464       powerpc-*)   machine=macppc ;;
 465       sparc*-)     machine=sparc ;;
 466       vax-*)       machine=vax ;;
 467     esac
 468   ;;
 469
 470   ## OpenBSD ports
 471   *-*-openbsd* )
 472     opsys=openbsd
 473     case "${canonical}" in
 474       alpha*)    machine=alpha ;;
 475       x86_64-*)  machine=amdx86-64 ;;
 476       i386-*)    machine=intel386 ;;
 477       powerpc-*) machine=macppc ;;
 478       sparc*)    machine=sparc ;;
 479       vax-*)     machine=vax ;;
 480     esac
 481   ;;
 482
 483   ## Apple Darwin / Mac OS X
 484   *-apple-darwin* )
 485     case "${canonical}" in
 486       i[3456]86-* )  machine=intel386 ;;
 487       powerpc-* )    machine=macppc ;;
 488       x86_64-* )     machine=amdx86-64 ;;
 489       * )            unported=yes ;;
 490     esac
 491     opsys=darwin
 492     # Define CPP as follows to make autoconf work correctly.
 493     CPP="${CC-cc} -E -no-cpp-precomp"
 494     # Use fink packages if available.
 495     if test -d /sw/include && test -d /sw/lib; then
 496       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 497       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 498       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 499     fi
 500   ;;
 501
 502   ## HP 9000 series 700 and 800, running HP/UX
 503   hppa*-hp-hpux10.2* )
 504     opsys=hpux10-20
 505   ;;
 506   hppa*-hp-hpux1[1-9]* )
 507     opsys=hpux11
 508     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 509   ;;
 510
 511   ## IBM machines
 512   rs6000-ibm-aix4.[23]* )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   powerpc-ibm-aix4.[23]*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix[56]* )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   powerpc-ibm-aix[56]*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524
 525   ## Silicon Graphics machines
 526   ## Iris 4D
 527   mips-sgi-irix6.5 )
 528     opsys=irix6-5
 529     # Without defining _LANGUAGE_C, things get masked out in the headers
 530     # so that, for instance, grepping for `free' in stdlib.h fails and
 531     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 532     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 533     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 534   ;;
 535
 536   ## Suns
 537   *-sun-solaris* \
 538     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 539     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 540     case "${canonical}" in
 541       i[3456]86-*-* )     machine=intel386 ;;
 542       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 543       sparc* )          machine=sparc ;;
 544       * )               unported=yes ;;
 545     esac
 546     case "${canonical}" in
 547       *-sunos5.6* | *-solaris2.6* )
 548                 opsys=sol2-6
 549                 NON_GNU_CPP=/usr/ccs/lib/cpp
 550                 RANLIB="ar -ts"
 551                 ;;
 552       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 553                 opsys=sol2-6
 554                 emacs_check_sunpro_c=yes
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 ;;
 557       *-sunos5* | *-solaris* )
 558                 opsys=sol2-10
 559                 emacs_check_sunpro_c=yes
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 ;;
 562     esac
 563     ## Watch out for a compiler that we know will not work.
 564     case "${canonical}" in
 565      *-solaris* | *-sunos5* )
 566                 if [ "x$CC" = x/usr/ucb/cc ]; then
 567                   ## /usr/ucb/cc doesn't work;
 568                   ## we should find some other compiler that does work.
 569                   unset CC
 570                 fi
 571                 ;;
 572       *) ;;
 573     esac
 574   ;;
 575
 576   ## Intel 386 machines where we don't care about the manufacturer.
 577   i[3456]86-*-* )
 578     machine=intel386
 579     case "${canonical}" in
 580       *-cygwin )                opsys=cygwin ;;
 581       *-darwin* )               opsys=darwin
 582                                 CPP="${CC-cc} -E -no-cpp-precomp"
 583                                 ;;
 584       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 585       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 586       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 587       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 588     esac
 589   ;;
 590
 591   * )
 592     unported=yes
 593   ;;
 594 esac
 595
 596 ### If the code above didn't choose an operating system, just choose
 597 ### an operating system based on the configuration name.  You really
 598 ### only want to use this when you have no idea what the right
 599 ### operating system is; if you know what operating systems a machine
 600 ### runs, it's cleaner to make it explicit in the case statement
 601 ### above.
 602 if test x"${opsys}" = x; then
 603   case "${canonical}" in
 604     *-gnu* )                            opsys=gnu ;;
 605     * )
 606       unported=yes
 607     ;;
 608   esac
 609 fi
 610
 611 ]
 612 dnl quotation ends
 613
 614 if test $unported = yes; then
 615   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 616 Check `etc/MACHINES' for recognized configuration names.])
 617 fi
 618
 619 if test -n "$machine"; then
 620   machfile="m/${machine}.h"
 621 else
 622   machfile=
 623 fi
 624 opsysfile="s/${opsys}.h"
 625
 626
 627 #### Choose a compiler.
 628 test -n "$CC" && cc_specified=yes
 629
 630 # Save the value of CFLAGS that the user specified.
 631 SPECIFIED_CFLAGS="$CFLAGS"
 632
 633 dnl Sets GCC=yes if using gcc.
 634 AC_PROG_CC
 635 AM_PROG_CC_C_O
 636
 637 # Initialize gnulib right after verifying that the C compiler works.
 638 gl_EARLY
 639
 640 # On Suns, sometimes $CPP names a directory.
 641 if test -n "$CPP" && test -d "$CPP"; then
 642   CPP=
 643 fi
 644
 645 ## If not using gcc, and on Solaris, and no CPP specified, see if
 646 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 647 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 648  test x"$CPP" = x; then
 649   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 650   AC_CACHE_VAL(emacs_cv_sunpro_c,
 651   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 652 [[#ifndef __SUNPRO_C
 653 fail;
 654 #endif
 655 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 656   AC_MSG_RESULT($emacs_cv_sunpro_c)
 657
 658   if test x"$emacs_cv_sunpro_c" = xyes; then
 659     NON_GNU_CPP="$CC -E -Xs"
 660   fi
 661 fi
 662
 663 #### Some systems specify a CPP to use unless we are using GCC.
 664 #### Now that we know whether we are using GCC, we can decide whether
 665 #### to use that one.
 666 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 667 then
 668   CPP="$NON_GNU_CPP"
 669 fi
 670
 671 #### Some systems specify a CC to use unless we are using GCC.
 672 #### Now that we know whether we are using GCC, we can decide whether
 673 #### to use that one.
 674 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 675   test x$cc_specified != xyes
 676 then
 677   CC="$NON_GNU_CC"
 678 fi
 679
 680 if test x$GCC = xyes; then
 681   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 682 else
 683   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 684 fi
 685
 686 ### Use -Wdeclaration-after-statement if the compiler supports it
 687 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 688 SAVE_CFLAGS="$CFLAGS"
 689 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 690 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 691 if test $has_option = yes; then
 692    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 693 fi
 694 AC_MSG_RESULT($has_option)
 695 CFLAGS="$SAVE_CFLAGS"
 696 unset has_option
 697 unset SAVE_CFLAGS
 698
 699 ### Use -Wold-style-definition if the compiler supports it
 700 # This can be removed when conversion to standard C is finished.
 701 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 702 SAVE_CFLAGS="$CFLAGS"
 703 CFLAGS="$CFLAGS -Wold-style-definition"
 704 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 705 if test $has_option = yes; then
 706    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 707 fi
 708 AC_MSG_RESULT($has_option)
 709 CFLAGS="$SAVE_CFLAGS"
 710 unset has_option
 711 unset SAVE_CFLAGS
 712
 713 ### Use -Wimplicit-function-declaration if the compiler supports it
 714 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 715 SAVE_CFLAGS="$CFLAGS"
 716 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 717 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 718 if test $has_option = yes; then
 719    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 720 fi
 721 AC_MSG_RESULT($has_option)
 722 CFLAGS="$SAVE_CFLAGS"
 723 unset has_option
 724 unset SAVE_CFLAGS
 725
 726 AC_SUBST(C_WARNINGS_SWITCH)
 727
 728
 729 #### Some other nice autoconf tests.
 730
 731 dnl checks for programs
 732 AC_PROG_CPP
 733 AC_PROG_INSTALL
 734 if test "x$RANLIB" = x; then
 735   AC_PROG_RANLIB
 736 fi
 737
 738 ## Although we're running on an amd64 kernel, we're actually compiling for
 739 ## the x86 architecture.  The user should probably have provided an
 740 ## explicit --build to `configure', but if everything else than the kernel
 741 ## is running in i386 mode, we can help them out.
 742 if test "$machine" = "amdx86-64"; then
 743   AC_CHECK_DECL([i386])
 744   if test "$ac_cv_have_decl_i386" = "yes"; then
 745     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 746     machine=intel386
 747     machfile="m/${machine}.h"
 748   fi
 749 fi
 750
 751 AC_PATH_PROG(INSTALL_INFO, install-info)
 752 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 753 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 754 dnl Don't use GZIP, which is used by gzip for additional parameters.
 755 AC_PATH_PROG(GZIP_PROG, gzip)
 756
 757
 758 ## Need makeinfo >= 4.6 (?) to build the manuals.
 759 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 760 dnl By this stage, configure has already checked for egrep and set EGREP,
 761 dnl or exited with an error if no egrep was found.
 762 if test "$MAKEINFO" != "no" && \
 763   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 764    MAKEINFO=no
 765 fi
 766
 767 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 768 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 769 ## therefore in the category of "special tools" not normally required, which
 770 ## configure does not have to check for (eg autoconf itself).
 771 ## In a Bazaar checkout on the other hand, the manuals are not included.
 772 ## So makeinfo is a requirement to build from Bazaar, and configure
 773 ## should test for it as it does for any other build requirement.
 774 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 775 ## with pre-built manuals, from a Bazaar checkout.
 776 HAVE_MAKEINFO=yes
 777
 778 if test "$MAKEINFO" = "no"; then
 779   MAKEINFO=makeinfo
 780   if test "x${with_makeinfo}" = "xno"; then
 781     HAVE_MAKEINFO=no
 782   elif test ! -e $srcdir/info/emacs; then
 783     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 784 source tree does not seem to have pre-built manuals in the `info' directory.
 785 Either install a suitable version of makeinfo, or re-run configure
 786 with the `--without-makeinfo' option to build without the manuals.] )
 787   fi
 788 fi
 789 AC_SUBST(HAVE_MAKEINFO)
 790
 791 dnl Add our options to ac_link now, after it is set up.
 792
 793 if test x$GCC = xyes; then
 794   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 795     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 796 else
 797   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 798     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 799 fi
 800
 801 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 802 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 803 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 804 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 805 dnl if not built to support GNU ld.
 806
 807 late_LDFLAGS=$LDFLAGS
 808 if test x$GCC = xyes; then
 809   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 810 else
 811   LDFLAGS="$LDFLAGS -znocombreloc"
 812 fi
 813
 814 AC_MSG_CHECKING([for -znocombreloc])
 815 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 816   [AC_MSG_RESULT(yes)],
 817   LDFLAGS=$late_LDFLAGS
 818   [AC_MSG_RESULT(no)])
 819
 820
 821 # The value of CPP is a quoted variable reference, so we need to do this
 822 # to get its actual value...
 823 CPP=`eval "echo $CPP"`
 824
 825
 826 dnl The function dump-emacs will not be defined and temacs will do
 827 dnl (load "loadup") automatically unless told otherwise.
 828 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 829 case "$opsys" in
 830   your-opsys-here) CANNOT_DUMP=yes ;;
 831 esac
 832
 833 test "$CANNOT_DUMP" = "yes" && \
 834   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 835
 836 AC_SUBST(CANNOT_DUMP)
 837
 838
 839 UNEXEC_OBJ=unexelf.o
 840 case "$opsys" in
 841   # MSDOS uses unexcoff.o
 842   # MSWindows uses unexw32.o
 843   aix4-2)
 844    UNEXEC_OBJ=unexaix.o
 845    ;;
 846   cygwin)
 847    UNEXEC_OBJ=unexcw.o
 848    ;;
 849   darwin)
 850    UNEXEC_OBJ=unexmacosx.o
 851    ;;
 852   hpux10-20 | hpux11)
 853    UNEXEC_OBJ=unexhp9k800.o
 854    ;;
 855   sol2-10)
 856    # Use the Solaris dldump() function, called from unexsol.c, to dump
 857    # emacs, instead of the generic ELF dump code found in unexelf.c.
 858    # The resulting binary has a complete symbol table, and is better
 859    # for debugging and other observability tools (debuggers, pstack, etc).
 860    #
 861    # If you encounter a problem using dldump(), please consider sending
 862    # a message to the OpenSolaris tools-linking mailing list:
 863    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 864    #
 865    # It is likely that dldump() works with older Solaris too, but this has
 866    # not been tested, so for now this change is for Solaris 10 or newer.
 867    UNEXEC_OBJ=unexsol.o
 868    ;;
 869 esac
 870
 871 LD_SWITCH_SYSTEM=
 872 case "$opsys" in
 873   freebsd)
 874    ## Let `ld' find image libs and similar things in /usr/local/lib.
 875    ## The system compiler, GCC, has apparently been modified to not
 876    ## look there, contrary to what a stock GCC would do.
 877    LD_SWITCH_SYSTEM=-L/usr/local/lib
 878    ;;
 879
 880   gnu-linux)
 881    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 882    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 883    ;;
 884
 885   netbsd)
 886    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 887    ;;
 888
 889   openbsd)
 890    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 891    ## otherwise Emacs dumps core on elf systems.
 892    LD_SWITCH_SYSTEM="-Z"
 893    ;;
 894 esac
 895 AC_SUBST(LD_SWITCH_SYSTEM)
 896
 897 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 898
 899 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 900 ## which has not been defined yet.  When this was handled with cpp,
 901 ## it was expanded to null when configure sourced the s/*.h file.
 902 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 903 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 904 ## (or somesuch), but because it is supposed to go at the _front_
 905 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 906 ## Compare with the gnu-linux case below, which added to the end
 907 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 908 ## LD_SWITCH_SYSTEM_TEMACS.
 909 case "$opsys" in
 910   netbsd|openbsd)
 911    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 912    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 913 esac
 914
 915
 916 C_SWITCH_MACHINE=
 917 if test "$machine" = "alpha"; then
 918   AC_CHECK_DECL([__ELF__])
 919   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 920     ## With ELF, make sure that all common symbols get allocated to in the
 921     ## data section.  Otherwise, the dump of temacs may miss variables in
 922     ## the shared library that have been initialized.  For example, with
 923     ## GNU libc, __malloc_initialized would normally be resolved to the
 924     ## shared library's .bss section, which is fatal.
 925     if test "x$GCC" = "xyes"; then
 926       C_SWITCH_MACHINE="-fno-common"
 927     else
 928       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 929     fi
 930   else
 931     UNEXEC_OBJ=unexalpha.o
 932   fi
 933 fi
 934 AC_SUBST(C_SWITCH_MACHINE)
 935
 936 AC_SUBST(UNEXEC_OBJ)
 937
 938 C_SWITCH_SYSTEM=
 939 ## Some programs in src produce warnings saying certain subprograms
 940 ## are too complex and need a MAXMEM value greater than 2000 for
 941 ## additional optimization.  --nils@exp-math.uni-essen.de
 942 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 943   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 944 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 945 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 946 AC_SUBST(C_SWITCH_SYSTEM)
 947
 948
 949 LIBS_SYSTEM=
 950 case "$opsys" in
 951   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 952   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 953
 954   freebsd) LIBS_SYSTEM="-lutil" ;;
 955
 956   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 957
 958   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 959
 960   ## Motif needs -lgen.
 961   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 962 esac
 963 AC_SUBST(LIBS_SYSTEM)
 964
 965
 966 ### Make sure subsequent tests use flags consistent with the build flags.
 967
 968 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 969   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 970 else
 971   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 972 fi
 973
 974 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 975 AC_DEFUN([AC_TYPE_SIZE_T])
 976 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 977 AC_DEFUN([AC_TYPE_UID_T])
 978
 979 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 980 AC_SYS_LARGEFILE
 981
 982
 983 LIB_MATH=-lm
 984 LIB_STANDARD=
 985 START_FILES=
 986
 987 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 988 case $opsys in
 989   cygwin )
 990     LIB_MATH=
 991     START_FILES='pre-crt0.o'
 992     ;;
 993   darwin )
 994     ## Adding -lm confuses the dynamic linker, so omit it.
 995     LIB_MATH=
 996     START_FILES='pre-crt0.o'
 997     ;;
 998   freebsd )
 999     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1000     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1001     ;;
1002   gnu-linux | gnu-kfreebsd )
1003     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1004     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1005     ;;
1006   hpux10-20 | hpux11 )
1007     LIB_STANDARD=-lc
1008     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1009     ;;
1010   dnl NB this may be adjusted below.
1011   netbsd | openbsd )
1012     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1013     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1014     ;;
1015 esac
1016
1017 AC_SUBST(LIB_MATH)
1018 AC_SUBST(START_FILES)
1019
1020 dnl Not all platforms use crtn.o files.  Check if the current one does.
1021 crt_files=
1022
1023 for file in x $LIB_STANDARD $START_FILES; do
1024   case "$file" in
1025     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1026   esac
1027 done
1028
1029 if test "x$crt_files" != x; then
1030
1031   ## If user specified a crt-dir, use that unconditionally.
1032   crt_gcc=no
1033
1034   if test "X$CRT_DIR" = "X"; then
1035
1036     CRT_DIR=/usr/lib            # default
1037
1038     case "$canonical" in
1039       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1040       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1041       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1042       ## For anything else (eg /usr/lib32), it is up the user to specify
1043       ## the location (bug#5655).
1044       ## Test for crtn.o, not just the directory, because sometimes the
1045       ## directory exists but does not have the relevant files (bug#1287).
1046       ## FIXME better to test for binary compatibility somehow.
1047       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1048       ;;
1049
1050       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1051     esac
1052
1053     case "$opsys" in
1054       hpux10-20) CRT_DIR=/lib ;;
1055     esac
1056
1057     test "x${GCC}" = xyes && crt_gcc=yes
1058
1059   fi                            # CRT_DIR = ""
1060
1061   crt_missing=
1062
1063   for file in $crt_files; do
1064
1065     ## If we're using gcc, try to determine it automatically by asking
1066     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1067     ## system-dependent default from above.]
1068     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1069
1070        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1071        case "$crt_file" in
1072          */*)
1073            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1074            ;;
1075        esac
1076     fi
1077
1078     dnl We expect all the files to be in a single directory, so after the
1079     dnl first there is no point asking gcc.
1080     crt_gcc=no
1081
1082     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1083   done                          # $crt_files
1084
1085   test "x$crt_missing" = x || \
1086     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1087 Try using the --with-crt-dir option.])
1088
1089 fi                              # crt_files != ""
1090
1091 AC_SUBST(CRT_DIR)
1092
1093 case $opsys in
1094   netbsd | openbsd )
1095     if test -f $CRT_DIR/crti.o; then
1096
1097         test -f $CRT_DIR/crtn.o || \
1098           AC_MSG_ERROR([Required file not found: crtn.o])
1099
1100         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1101         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1102     fi
1103     ;;
1104 esac
1105
1106
1107 dnl This function definition taken from Gnome 2.0
1108 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1109 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1110 dnl also defines GSTUFF_PKG_ERRORS on error
1111 AC_DEFUN([PKG_CHECK_MODULES], [
1112   succeeded=no
1113
1114   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1115
1116   if test "$PKG_CONFIG" = "no" ; then
1117      ifelse([$4], , [AC_MSG_ERROR([
1118       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1119   else
1120      PKG_CONFIG_MIN_VERSION=0.9.0
1121      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1122         AC_MSG_CHECKING(for $2)
1123
1124         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1125             AC_MSG_RESULT(yes)
1126             succeeded=yes
1127
1128             AC_MSG_CHECKING($1_CFLAGS)
1129             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1130             AC_MSG_RESULT($$1_CFLAGS)
1131
1132             AC_MSG_CHECKING($1_LIBS)
1133             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1134             AC_MSG_RESULT($$1_LIBS)
1135         else
1136             AC_MSG_RESULT(no)
1137             $1_CFLAGS=""
1138             $1_LIBS=""
1139             ## If we have a custom action on failure, don't print errors, but
1140             ## do set a variable so people can do so.
1141             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1142             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1143         fi
1144
1145         AC_SUBST($1_CFLAGS)
1146         AC_SUBST($1_LIBS)
1147      else
1148         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1149         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1150      fi
1151   fi
1152
1153   if test $succeeded = yes; then
1154      ifelse([$3], , :, [$3])
1155   else
1156      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1157   fi
1158 ])
1159
1160
1161 if test "${with_sound}" != "no"; then
1162   # Sound support for GNU/Linux and the free BSDs.
1163   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1164     have_sound_header=yes)
1165   # Emulation library used on NetBSD.
1166   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1167   AC_SUBST(LIBSOUND)
1168
1169   ALSA_REQUIRED=1.0.0
1170   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1171   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1172   if test $HAVE_ALSA = yes; then
1173     SAVE_CFLAGS="$CFLAGS"
1174     SAVE_LDFLAGS="$LDFLAGS"
1175     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1176     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1177     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1178                     emacs_alsa_normal=yes,
1179                     emacs_alsa_normal=no)
1180     if test "$emacs_alsa_normal" != yes; then
1181       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1182                      [[snd_lib_error_set_handler (0);]])],
1183                      emacs_alsa_subdir=yes,
1184                      emacs_alsa_subdir=no)
1185       if test "$emacs_alsa_subdir" != yes; then
1186         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1187       fi
1188       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1189     fi
1190
1191     CFLAGS="$SAVE_CFLAGS"
1192     LDFLAGS="$SAVE_LDFLAGS"
1193     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1194     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1195     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1196   fi
1197
1198   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1199   dnl compiles only on the specified platforms.  For others, it
1200   dnl probably doesn't make sense to try.
1201   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1202      case "$opsys" in
1203        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1204        gnu-linux|freebsd|netbsd)
1205          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1206          ;;
1207      esac
1208   fi
1209
1210   AC_SUBST(CFLAGS_SOUND)
1211 fi
1212
1213 dnl checks for header files
1214 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1215   linux/version.h sys/systeminfo.h \
1216   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1217   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1218   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1219
1220 AC_MSG_CHECKING(if personality LINUX32 can be set)
1221 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1222                emacs_cv_personality_linux32=yes,
1223                emacs_cv_personality_linux32=no)
1224 AC_MSG_RESULT($emacs_cv_personality_linux32)
1225
1226 if test $emacs_cv_personality_linux32 = yes; then
1227   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1228             [Define to 1 if personality LINUX32 can be set.])
1229 fi
1230
1231 dnl On Solaris 8 there's a compilation warning for term.h because
1232 dnl it doesn't define `bool'.
1233 AC_CHECK_HEADERS(term.h, , , -)
1234 AC_HEADER_TIME
1235 AC_CHECK_DECLS([sys_siglist])
1236 if test $ac_cv_have_decl_sys_siglist != yes; then
1237   # For Tru64, at least:
1238   AC_CHECK_DECLS([__sys_siglist])
1239   if test $ac_cv_have_decl___sys_siglist = yes; then
1240     AC_DEFINE(sys_siglist, __sys_siglist,
1241               [Define to any substitute for sys_siglist.])
1242   fi
1243 fi
1244 AC_HEADER_SYS_WAIT
1245
1246 dnl Some systems have utime.h but don't declare the struct anyplace.
1247 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1248 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1249 #include <sys/time.h>
1250 #include <time.h>
1251 #else
1252 #ifdef HAVE_SYS_TIME_H
1253 #include <sys/time.h>
1254 #else
1255 #include <time.h>
1256 #endif
1257 #endif
1258 #ifdef HAVE_UTIME_H
1259 #include <utime.h>
1260 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1261   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1262 if test $emacs_cv_struct_utimbuf = yes; then
1263   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1264 fi
1265
1266 dnl Check for speed_t typedef.
1267 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1268   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1269     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1270 if test $emacs_cv_speed_t = yes; then
1271   AC_DEFINE(HAVE_SPEED_T, 1,
1272            [Define to 1 if `speed_t' is declared by <termios.h>.])
1273 fi
1274
1275 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1276 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1277 #include <sys/time.h>
1278 #include <time.h>
1279 #else
1280 #ifdef HAVE_SYS_TIME_H
1281 #include <sys/time.h>
1282 #else
1283 #include <time.h>
1284 #endif
1285 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1286   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1287 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1288 if test $emacs_cv_struct_timeval = yes; then
1289   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1290 fi
1291
1292 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1293 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1294 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1295   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1296 HAVE_EXCEPTION=$emacs_cv_struct_exception
1297 if test $emacs_cv_struct_exception != yes; then
1298   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1299 fi
1300
1301 AC_CHECK_HEADERS(sys/socket.h)
1302 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1303 #if HAVE_SYS_SOCKET_H
1304 #include <sys/socket.h>
1305 #endif])
1306 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1307 #if HAVE_SYS_SOCKET_H
1308 #include <sys/socket.h>
1309 #endif])
1310 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1311 #if HAVE_SYS_SOCKET_H
1312 #include <sys/socket.h>
1313 #endif])
1314 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1315
1316 dnl checks for structure members
1317 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1318                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1319                   struct ifreq.ifr_addr,
1320                   struct ifreq.ifr_addr.sa_len], , ,
1321                  [AC_INCLUDES_DEFAULT
1322 #if HAVE_SYS_SOCKET_H
1323 #include <sys/socket.h>
1324 #endif
1325 #if HAVE_NET_IF_H
1326 #include <net/if.h>
1327 #endif])
1328
1329 dnl checks for compiler characteristics
1330
1331 dnl Testing __STDC__ to determine prototype support isn't good enough.
1332 dnl DEC C, for instance, doesn't define it with default options, and
1333 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1334 dnl and void *.
1335 AC_C_PROTOTYPES
1336 AC_C_VOLATILE
1337 AC_C_CONST
1338 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1339   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1340                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1341 if test $emacs_cv_void_star = yes; then
1342   AC_DEFINE(POINTER_TYPE, void)
1343 else
1344   AC_DEFINE(POINTER_TYPE, char)
1345 fi
1346 AH_TEMPLATE(POINTER_TYPE,
1347             [Define as `void' if your compiler accepts `void *'; otherwise
1348              define as `char'.])dnl
1349
1350 dnl Check for endianness.
1351 AC_C_BIGENDIAN
1352
1353 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1354   [emacs_cv_attribute_aligned],
1355   [AC_COMPILE_IFELSE(
1356      [AC_LANG_PROGRAM(
1357         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1358         [[]])],
1359      [emacs_cv_attribute_aligned=yes],
1360      [emacs_cv_attribute_aligned=no])])
1361 if test $emacs_cv_attribute_aligned = yes; then
1362   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1363     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1364 fi
1365
1366 dnl check for Make feature
1367 AC_PROG_MAKE_SET
1368
1369 DEPFLAGS=
1370 MKDEPDIR=":"
1371 deps_frag=deps.mk
1372 dnl check for GNU Make if we have GCC and autodepend is on.
1373 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1374    AC_MSG_CHECKING([whether we are using GNU Make])
1375    HAVE_GNU_MAKE=no
1376    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1377    if test "x$testval" != x; then
1378       HAVE_GNU_MAKE=yes
1379    else
1380       ac_enable_autodepend=no
1381    fi
1382    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1383    if test $HAVE_GNU_MAKE = yes; then
1384       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1385       SAVE_CFLAGS="$CFLAGS"
1386       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1387       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1388       CFLAGS="$SAVE_CFLAGS"
1389       test -f deps.d || ac_enable_autodepend=no
1390       rm -rf deps.d
1391       AC_MSG_RESULT([$ac_enable_autodepend])
1392    fi
1393    if test $ac_enable_autodepend = yes; then
1394       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1395       ## In parallel builds, another make might create depdir between
1396       ## the first test and mkdir, so stick another test on the end.
1397       ## Or use install-sh -d?  mkdir -p is not portable.
1398       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1399       deps_frag=autodeps.mk
1400    fi
1401 fi
1402 deps_frag=$srcdir/src/$deps_frag
1403 AC_SUBST(MKDEPDIR)
1404 AC_SUBST(DEPFLAGS)
1405 AC_SUBST_FILE(deps_frag)
1406
1407
1408 lisp_frag=$srcdir/src/lisp.mk
1409 AC_SUBST_FILE(lisp_frag)
1410
1411
1412 dnl checks for operating system services
1413 AC_SYS_LONG_FILE_NAMES
1414
1415 #### Choose a window system.
1416
1417 AC_PATH_X
1418 if test "$no_x" = yes; then
1419   window_system=none
1420 else
1421   window_system=x11
1422 fi
1423
1424 ## Workaround for bug in autoconf <= 2.62.
1425 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1426 ## No need to do anything special for these standard directories.
1427 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1428
1429    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1430
1431 fi
1432
1433 LD_SWITCH_X_SITE_AUX=
1434 LD_SWITCH_X_SITE_AUX_RPATH=
1435 if test "${x_libraries}" != NONE; then
1436   if test -n "${x_libraries}"; then
1437     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1438     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1439     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1440   fi
1441   x_default_search_path=""
1442   x_search_path=${x_libraries}
1443   if test -z "${x_search_path}"; then
1444     x_search_path=/usr/lib
1445   fi
1446   for x_library in `echo ${x_search_path}: | \
1447                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1448     x_search_path="\
1449 ${x_library}/X11/%L/%T/%N%C%S:\
1450 ${x_library}/X11/%l/%T/%N%C%S:\
1451 ${x_library}/X11/%T/%N%C%S:\
1452 ${x_library}/X11/%L/%T/%N%S:\
1453 ${x_library}/X11/%l/%T/%N%S:\
1454 ${x_library}/X11/%T/%N%S"
1455     if test x"${x_default_search_path}" = x; then
1456       x_default_search_path=${x_search_path}
1457     else
1458       x_default_search_path="${x_search_path}:${x_default_search_path}"
1459     fi
1460   done
1461 fi
1462 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1463 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1464
1465 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1466   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1467 fi
1468
1469 if test x"${x_includes}" = x; then
1470   bitmapdir=/usr/include/X11/bitmaps
1471 else
1472   # accumulate include directories that have X11 bitmap subdirectories
1473   bmd_acc="dummyval"
1474   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1475     if test -d "${bmd}/X11/bitmaps"; then
1476       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1477     fi
1478     if test -d "${bmd}/bitmaps"; then
1479       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1480     fi
1481   done
1482   if test ${bmd_acc} != "dummyval"; then
1483     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1484   fi
1485 fi
1486
1487 HAVE_NS=no
1488 NS_IMPL_COCOA=no
1489 NS_IMPL_GNUSTEP=no
1490 tmp_CPPFLAGS="$CPPFLAGS"
1491 tmp_CFLAGS="$CFLAGS"
1492 CPPFLAGS="$CPPFLAGS -x objective-c"
1493 CFLAGS="$CFLAGS -x objective-c"
1494 TEMACS_LDFLAGS2="\${LDFLAGS}"
1495 GNU_OBJC_CFLAGS=
1496 dnl I don't think it's especially important, but src/Makefile.in
1497 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1498 dnl trailing "/" to it, so now we do it here.
1499 if test "${with_ns}" != no; then
1500   if test "${opsys}" = darwin; then
1501      NS_IMPL_COCOA=yes
1502      ns_appdir=`pwd`/nextstep/Emacs.app
1503      ns_appbindir=${ns_appdir}/Contents/MacOS/
1504      ns_appresdir=${ns_appdir}/Contents/Resources
1505      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1506   elif test -f $GNUSTEP_CONFIG_FILE; then
1507      NS_IMPL_GNUSTEP=yes
1508      ns_appdir=`pwd`/nextstep/Emacs.app
1509      ns_appbindir=${ns_appdir}/
1510      ns_appresdir=${ns_appdir}/Resources
1511      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1512      dnl FIXME sourcing this several times in subshells seems inefficient.
1513      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1514      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1515      dnl I seemed to need these as well with GNUstep-startup 0.25.
1516      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1517      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1518      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1519        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1520      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1521        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1522      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1523      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1524      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1525      LIB_STANDARD=
1526      START_FILES=
1527      TEMACS_LDFLAGS2=
1528      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1529      dnl If they had chosen to either define it or not, we could have
1530      dnl just used AC_CHECK_DECL here.
1531      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1532        emacs_cv_objc_exceptions,
1533 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1534 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1535 1;
1536 #else
1537 fail;
1538 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1539      if test $emacs_cv_objc_exceptions = yes; then
1540        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1541        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1542          [Define if GNUstep uses ObjC exceptions.])
1543        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1544      fi
1545   fi
1546
1547   dnl This is only used while we test the NS headers, it gets reset below.
1548   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1549
1550   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1551                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1552   files are missing or cannot be compiled.])])
1553   NS_HAVE_NSINTEGER=yes
1554   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1555                                      [NSInteger i;])],
1556                     ns_have_nsinteger=yes,
1557                     ns_have_nsinteger=no)
1558   if test $ns_have_nsinteger = no; then
1559     NS_HAVE_NSINTEGER=no
1560   fi
1561 fi
1562 AC_SUBST(TEMACS_LDFLAGS2)
1563
1564 ns_frag=/dev/null
1565 NS_OBJ=
1566 NS_OBJC_OBJ=
1567 if test "${HAVE_NS}" = yes; then
1568   window_system=nextstep
1569   with_xft=no
1570   # set up packaging dirs
1571   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1572      prefix=${ns_appresdir}
1573      exec_prefix=${ns_appbindir}
1574      libexecdir=${ns_appbindir}/libexec
1575   fi
1576   ns_frag=$srcdir/src/ns.mk
1577   NS_OBJ="fontset.o fringe.o image.o"
1578   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1579 fi
1580 CFLAGS="$tmp_CFLAGS"
1581 CPPFLAGS="$tmp_CPPFLAGS"
1582 AC_SUBST(NS_OBJ)
1583 AC_SUBST(NS_OBJC_OBJ)
1584 AC_SUBST(LIB_STANDARD)
1585 AC_SUBST_FILE(ns_frag)
1586
1587 case "${window_system}" in
1588   x11 )
1589     HAVE_X_WINDOWS=yes
1590     HAVE_X11=yes
1591     case "${with_x_toolkit}" in
1592       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1593       motif ) USE_X_TOOLKIT=MOTIF ;;
1594       gtk ) with_gtk=yes
1595 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1596 dnl USE_X_TOOLKIT is set.
1597             USE_X_TOOLKIT=none ;;
1598       gtk3 ) with_gtk3=yes
1599              USE_X_TOOLKIT=none ;;
1600       no ) USE_X_TOOLKIT=none ;;
1601 dnl If user did not say whether to use a toolkit, make this decision later:
1602 dnl use the toolkit if we have gtk, or X11R5 or newer.
1603       * ) USE_X_TOOLKIT=maybe ;;
1604     esac
1605   ;;
1606   nextstep | none )
1607     HAVE_X_WINDOWS=no
1608     HAVE_X11=no
1609     USE_X_TOOLKIT=none
1610   ;;
1611 esac
1612
1613 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1614    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1615    if test "$HAVE_XSERVER" = true ||
1616       test -n "$DISPLAY" ||
1617       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1618         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1619 were found.  You should install the relevant development files for X
1620 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1621 sure you have development files for image handling, i.e.
1622 tiff, gif, jpeg, png and xpm.
1623 If you are sure you want Emacs compiled without X window support, pass
1624   --without-x
1625 to configure.])
1626    fi
1627 fi
1628
1629 ### If we're using X11, we should use the X menu package.
1630 HAVE_MENUS=no
1631 case ${HAVE_X11} in
1632   yes ) HAVE_MENUS=yes ;;
1633 esac
1634
1635 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1636 # Assume not, until told otherwise.
1637 GNU_MALLOC=yes
1638 doug_lea_malloc=yes
1639 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1640 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1641 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1642                emacs_cv_var___after_morecore_hook,
1643 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1644   emacs_cv_var___after_morecore_hook=yes,
1645   emacs_cv_var___after_morecore_hook=no)])
1646 if test $emacs_cv_var___after_morecore_hook = no; then
1647   doug_lea_malloc=no
1648 fi
1649
1650
1651 dnl See comments in aix4-2.h about maybe using system malloc there.
1652 system_malloc=no
1653 case "$opsys" in
1654   ## darwin ld insists on the use of malloc routines in the System framework.
1655   darwin|sol2-10) system_malloc=yes ;;
1656 esac
1657
1658 if test "${system_malloc}" = "yes"; then
1659   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1660   GNU_MALLOC=no
1661   GNU_MALLOC_reason="
1662     (The GNU allocators don't work with this system configuration.)"
1663   GMALLOC_OBJ=
1664   VMLIMIT_OBJ=
1665 else
1666   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1667   VMLIMIT_OBJ=vm-limit.o
1668 fi
1669 AC_SUBST(GMALLOC_OBJ)
1670 AC_SUBST(VMLIMIT_OBJ)
1671
1672 if test "$doug_lea_malloc" = "yes" ; then
1673   if test "$GNU_MALLOC" = yes ; then
1674     GNU_MALLOC_reason="
1675       (Using Doug Lea's new malloc from the GNU C Library.)"
1676   fi
1677   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1678             [Define to 1 if you are using the GNU C Library.])
1679
1680   ## Use mmap directly for allocating larger buffers.
1681   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1682   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1683   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1684   case "$opsys" in
1685     gnu*) REL_ALLOC=no ;;
1686   esac
1687 fi
1688
1689 if test x"${REL_ALLOC}" = x; then
1690   REL_ALLOC=${GNU_MALLOC}
1691 fi
1692
1693 use_mmap_for_buffers=no
1694 case "$opsys" in
1695   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1696 esac
1697
1698 AC_FUNC_MMAP
1699 if test $use_mmap_for_buffers = yes; then
1700   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1701   REL_ALLOC=no
1702 fi
1703
1704 LIBS="$LIBS_SYSTEM $LIBS"
1705
1706 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1707 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1708 AC_CHECK_LIB(dnet, dnet_ntoa)
1709 dnl This causes -lresolv to get used in subsequent tests,
1710 dnl which causes failures on some systems such as HPUX 9.
1711 dnl AC_CHECK_LIB(resolv, gethostbyname)
1712
1713 dnl FIXME replace main with a function we actually want from this library.
1714 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1715
1716 dnl Check if pthreads is available.
1717 LIB_PTHREAD=
1718 AC_CHECK_HEADERS(pthread.h)
1719 if test "$ac_cv_header_pthread_h"; then
1720   AC_CHECK_LIB(pthread, pthread_self, HAVE_PTHREAD=yes)
1721 fi
1722 if test "$HAVE_PTHREAD" = yes; then
1723   case "${canonical}" in
1724     *-hpux*) ;;
1725     *) LIB_PTHREAD="-lpthread"
1726        LIBS="$LIB_PTHREAD $LIBS" ;;
1727   esac
1728   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1729 fi
1730 AC_SUBST([LIB_PTHREAD])
1731
1732 AC_CHECK_LIB(pthreads, cma_open)
1733
1734 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1735 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1736 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1737 ## added to LIBS in configure would never contain the pthreads part,
1738 ## but the value used in Makefiles might.  FIXME?
1739 ##
1740 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1741 ## be harmless on older versions of X where it happens to exist.
1742 test "$opsys" = "aix4-2" && \
1743   test $ac_cv_lib_pthreads_cma_open = yes && \
1744   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1745
1746 dnl Check for need for bigtoc support on IBM AIX
1747
1748 case ${host_os} in
1749 aix*)
1750   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1751     case $GCC in
1752     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1753     *) gdb_cv_bigtoc=-bbigtoc ;;
1754     esac
1755
1756     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1757     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1758   ])
1759   ;;
1760 esac
1761
1762 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1763 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1764 # REAL_CPPFLAGS later on.
1765
1766 REAL_CFLAGS="$CFLAGS"
1767 REAL_CPPFLAGS="$CPPFLAGS"
1768
1769 if test "${HAVE_X11}" = "yes"; then
1770   DEFS="$C_SWITCH_X_SITE $DEFS"
1771   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1772   LIBS="-lX11 $LIBS"
1773   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1774   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1775
1776   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1777   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1778   # but it's more convenient here to set LD_RUN_PATH
1779   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1780   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1781     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1782     export LD_RUN_PATH
1783   fi
1784
1785   if test "${opsys}" = "gnu-linux"; then
1786     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1787     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1788      [[XOpenDisplay ("foo");]])],
1789      [xgnu_linux_first_failure=no],
1790      [xgnu_linux_first_failure=yes])
1791     if test "${xgnu_linux_first_failure}" = "yes"; then
1792       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1793       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1794       OLD_CPPFLAGS="$CPPFLAGS"
1795       OLD_LIBS="$LIBS"
1796       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1797       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1798       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1799       LIBS="$LIBS -b i486-linuxaout"
1800       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1801        [[XOpenDisplay ("foo");]])],
1802        [xgnu_linux_second_failure=no],
1803        [xgnu_linux_second_failure=yes])
1804       if test "${xgnu_linux_second_failure}" = "yes"; then
1805         # If we get the same failure with -b, there is no use adding -b.
1806         # So take it out.  This plays safe.
1807         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1808         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1809         CPPFLAGS="$OLD_CPPFLAGS"
1810         LIBS="$OLD_LIBS"
1811         AC_MSG_RESULT(no)
1812       else
1813         AC_MSG_RESULT(yes)
1814       fi
1815     else
1816       AC_MSG_RESULT(no)
1817     fi
1818   fi
1819
1820   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1821   # header files included from there.
1822   AC_MSG_CHECKING(for Xkb)
1823   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1824 #include <X11/XKBlib.h>]],
1825         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1826         emacs_xkb=yes, emacs_xkb=no)
1827   AC_MSG_RESULT($emacs_xkb)
1828   if test $emacs_xkb = yes; then
1829     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1830   fi
1831
1832   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1833 XScreenNumberOfScreen XSetWMProtocols)
1834 fi
1835
1836 if test "${window_system}" = "x11"; then
1837   AC_MSG_CHECKING(X11 version 6)
1838   AC_CACHE_VAL(emacs_cv_x11_version_6,
1839   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1840 [[#if XlibSpecificationRelease < 6
1841 fail;
1842 #endif
1843 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1844   if test $emacs_cv_x11_version_6 = yes; then
1845     AC_MSG_RESULT(6 or newer)
1846     AC_DEFINE(HAVE_X11R6, 1,
1847               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1848     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1849     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1850     ## XIM support.
1851     case "$opsys" in
1852       sol2-*) : ;;
1853       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1854            [Define if you have usable X11R6-style XIM support.])
1855          ;;
1856     esac
1857   else
1858     AC_MSG_RESULT(before 6)
1859   fi
1860 fi
1861
1862
1863 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1864 HAVE_RSVG=no
1865 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1866   if test "${with_rsvg}" != "no"; then
1867     RSVG_REQUIRED=2.11.0
1868     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1869
1870     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1871     AC_SUBST(RSVG_CFLAGS)
1872     AC_SUBST(RSVG_LIBS)
1873
1874     if test $HAVE_RSVG = yes; then
1875       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1876       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1877       LIBS="$RSVG_LIBS $LIBS"
1878     fi
1879   fi
1880 fi
1881
1882 HAVE_IMAGEMAGICK=no
1883 if test "${HAVE_X11}" = "yes"; then
1884   if test "${with_imagemagick}" != "no"; then
1885     ## 6.2.8 is the earliest version known to work, but earlier versions
1886     ## might work - let us know if you find one.
1887     ## 6.0.7 does not work.  See bug#7955.
1888     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1889     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1890     AC_SUBST(IMAGEMAGICK_CFLAGS)
1891     AC_SUBST(IMAGEMAGICK_LIBS)
1892
1893     if test $HAVE_IMAGEMAGICK = yes; then
1894       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1895       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1896       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1897       AC_CHECK_FUNCS(MagickExportImagePixels)
1898     fi
1899   fi
1900 fi
1901
1902
1903 HAVE_GTK=no
1904 GTK_OBJ=
1905 if test "${with_gtk3}" = "yes"; then
1906   GLIB_REQUIRED=2.28
1907   GTK_REQUIRED=3.0
1908   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1909
1910   dnl Checks for libraries.
1911   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1912   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1913      AC_MSG_ERROR($GTK_PKG_ERRORS)
1914   fi
1915   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1916   GTK_OBJ=emacsgtkfixed.o
1917 fi
1918
1919 if test "$pkg_check_gtk" != "yes"; then
1920   HAVE_GTK=no
1921 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1922   GLIB_REQUIRED=2.10
1923   GTK_REQUIRED=2.10
1924   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1925
1926   dnl Checks for libraries.
1927   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1928   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1929      AC_MSG_ERROR($GTK_PKG_ERRORS)
1930   fi
1931 fi
1932 fi
1933
1934 if test x"$pkg_check_gtk" = xyes; then
1935
1936   AC_SUBST(GTK_CFLAGS)
1937   AC_SUBST(GTK_LIBS)
1938   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1939   CFLAGS="$CFLAGS $GTK_CFLAGS"
1940   LIBS="$GTK_LIBS $LIBS"
1941   dnl Try to compile a simple GTK program.
1942   GTK_COMPILES=no
1943   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1944   if test "${GTK_COMPILES}" != "yes"; then
1945     if test "$USE_X_TOOLKIT" != "maybe"; then
1946       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1947     fi
1948   else
1949     HAVE_GTK=yes
1950     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1951     GTK_OBJ="gtkutil.o $GTK_OBJ"
1952     USE_X_TOOLKIT=none
1953     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1954       :
1955     else
1956       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1957        closing open displays.  This is no problem if you just use
1958        one display, but if you use more than one and close one of them
1959        Emacs may crash.]])
1960       sleep 3
1961     fi
1962   fi
1963
1964 fi
1965 AC_SUBST(GTK_OBJ)
1966
1967
1968 if test "${HAVE_GTK}" = "yes"; then
1969
1970   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1971   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1972   if test "$with_toolkit_scroll_bars" != no; then
1973     with_toolkit_scroll_bars=yes
1974   fi
1975
1976   dnl  Check if we have the old file selection dialog declared and
1977   dnl  in the link library.  In 2.x it may be in the library,
1978   dnl  but not declared if deprecated featured has been selected out.
1979   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1980   HAVE_GTK_FILE_SELECTION=no
1981   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1982                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1983 #include <gtk/gtk.h>])
1984   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1985     AC_CHECK_FUNCS(gtk_file_selection_new)
1986   fi
1987
1988
1989   dnl Check for functions introduced in 2.14 and later.
1990   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1991                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1992                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1993                  gtk_orientable_set_orientation)
1994
1995 fi
1996
1997 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1998 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1999 dnl also not configured.
2000 HAVE_DBUS=no
2001 DBUS_OBJ=
2002 if test "${with_dbus}" = "yes"; then
2003    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2004    if test "$HAVE_DBUS" = yes; then
2005      LIBS="$LIBS $DBUS_LIBS"
2006      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2007      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
2008      DBUS_OBJ=dbusbind.o
2009    fi
2010 fi
2011 AC_SUBST(DBUS_OBJ)
2012
2013 dnl GSettings has been tested under GNU/Linux only.
2014 HAVE_GSETTINGS=no
2015 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2016    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2017    if test "$HAVE_GSETTINGS" = "yes"; then
2018       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2019       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2020       SETTINGS_LIBS="$GSETTINGS_LIBS"
2021    fi
2022 fi
2023
2024 dnl GConf has been tested under GNU/Linux only.
2025 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2026 HAVE_GCONF=no
2027 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2028    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2029    if test "$HAVE_GCONF" = yes; then
2030       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2031       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2032       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2033       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2034    fi
2035 fi
2036
2037 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2038     SAVE_CFLAGS="$CFLAGS"
2039     SAVE_LDFLAGS="$LDFLAGS"
2040     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2041     LDFLAGS="$SETTINGS_LIBS $LDFLAGS"
2042     AC_CHECK_FUNCS([g_type_init])
2043     CFLAGS="$SAVE_CFLAGS"
2044     LDFLAGS="$SAVE_LDFLAGS"
2045 fi
2046 AC_SUBST(SETTINGS_CFLAGS)
2047 AC_SUBST(SETTINGS_LIBS)
2048
2049
2050 dnl SELinux is available for GNU/Linux only.
2051 HAVE_LIBSELINUX=no
2052 LIBSELINUX_LIBS=
2053 if test "${with_selinux}" = "yes"; then
2054    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2055    if test "$HAVE_LIBSELINUX" = yes; then
2056       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2057       LIBSELINUX_LIBS=-lselinux
2058    fi
2059 fi
2060 AC_SUBST(LIBSELINUX_LIBS)
2061
2062 HAVE_GNUTLS=no
2063 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2064 if test "${with_gnutls}" = "yes" ; then
2065   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2066   if test "${HAVE_GNUTLS}" = "yes"; then
2067     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2068   fi
2069
2070   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2071   LIBS="$LIBGNUTLS_LIBS $LIBS"
2072   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2073
2074   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2075     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2076   fi
2077 fi
2078
2079 AC_SUBST(LIBGNUTLS_LIBS)
2080 AC_SUBST(LIBGNUTLS_CFLAGS)
2081
2082 dnl Do not put whitespace before the #include statements below.
2083 dnl Older compilers (eg sunos4 cc) choke on it.
2084 HAVE_XAW3D=no
2085 LUCID_LIBW=
2086 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2087   if test "$with_xaw3d" != no; then
2088     AC_MSG_CHECKING(for xaw3d)
2089     AC_CACHE_VAL(emacs_cv_xaw3d,
2090     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2091 #include <X11/Intrinsic.h>
2092 #include <X11/Xaw3d/Simple.h>]],
2093       [[]])],
2094       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2095                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2096       emacs_cv_xaw3d=no)])
2097   else
2098     emacs_cv_xaw3d=no
2099   fi
2100   if test $emacs_cv_xaw3d = yes; then
2101     AC_MSG_RESULT([yes; using Lucid toolkit])
2102     USE_X_TOOLKIT=LUCID
2103     HAVE_XAW3D=yes
2104     LUCID_LIBW=-lXaw3d
2105     AC_DEFINE(HAVE_XAW3D, 1,
2106               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2107   else
2108     AC_MSG_RESULT(no)
2109     AC_MSG_CHECKING(for libXaw)
2110     AC_CACHE_VAL(emacs_cv_xaw,
2111     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2112 #include <X11/Intrinsic.h>
2113 #include <X11/Xaw/Simple.h>]],
2114       [[]])],
2115       emacs_cv_xaw=yes,
2116       emacs_cv_xaw=no)])
2117     if test $emacs_cv_xaw = yes; then
2118       AC_MSG_RESULT([yes; using Lucid toolkit])
2119       USE_X_TOOLKIT=LUCID
2120       LUCID_LIBW=-lXaw
2121     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2122       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2123     else
2124       AC_MSG_ERROR([No X toolkit could be found.
2125 If you are sure you want Emacs compiled without an X toolkit, pass
2126   --with-x-toolkit=no
2127 to configure.  Otherwise, install the development libraries for the toolkit
2128 that you want to use (e.g. Gtk+) and re-run configure.])
2129     fi
2130   fi
2131 fi
2132
2133 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2134
2135 LIBXTR6=
2136 if test "${USE_X_TOOLKIT}" != "none"; then
2137   AC_MSG_CHECKING(X11 toolkit version)
2138   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2139   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2140 [[#if XtSpecificationRelease < 6
2141 fail;
2142 #endif
2143 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2144   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2145   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2146     AC_MSG_RESULT(6 or newer)
2147     AC_DEFINE(HAVE_X11XTR6, 1,
2148               [Define to 1 if you have the X11R6 or newer version of Xt.])
2149     LIBXTR6="-lSM -lICE"
2150     case "$opsys" in
2151       ## Use libw.a along with X11R6 Xt.
2152       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2153     esac
2154   else
2155     AC_MSG_RESULT(before 6)
2156   fi
2157
2158 dnl If using toolkit, check whether libXmu.a exists.
2159 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2160   OLDLIBS="$LIBS"
2161   if test x$HAVE_X11XTR6 = xyes; then
2162     LIBS="-lXt -lSM -lICE $LIBS"
2163   else
2164     LIBS="-lXt $LIBS"
2165   fi
2166   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2167   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2168 fi
2169 AC_SUBST(LIBXTR6)
2170
2171 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2172 dnl Why not just test for libxmu in the normal way?
2173 LIBXMU=-lXmu
2174 case $opsys in
2175   ## These systems don't supply Xmu.
2176   hpux* | aix4-2 )
2177     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2178     ;;
2179 esac
2180 AC_SUBST(LIBXMU)
2181
2182 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2183 if test "${HAVE_X11}" = "yes"; then
2184   if test "${USE_X_TOOLKIT}" != "none"; then
2185     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2186   fi
2187 fi
2188
2189 LIBXP=
2190 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2191   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2192   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2193     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2194 int x = 5;
2195 #else
2196 Motif version prior to 2.1.
2197 #endif]])],
2198     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2199   if test $emacs_cv_motif_version_2_1 = yes; then
2200     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2201   else
2202     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2203     # We put this in CFLAGS temporarily to precede other -I options
2204     # that might be in CFLAGS temporarily.
2205     # We put this in CPPFLAGS where it precedes the other -I options.
2206     OLD_CPPFLAGS=$CPPFLAGS
2207     OLD_CFLAGS=$CFLAGS
2208     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2209     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2210     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2211       [[int x = 5;]])],
2212       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2213     if test $emacs_cv_lesstif = yes; then
2214       # Make sure this -I option remains in CPPFLAGS after it is set
2215       # back to REAL_CPPFLAGS.
2216       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2217       # have those other -I options anyway.  Ultimately, having this
2218       # directory ultimately in CPPFLAGS will be enough.
2219       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2220       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2221     else
2222       CFLAGS=$OLD_CFLAGS
2223       CPPFLAGS=$OLD_CPPFLAGS
2224     fi
2225   fi
2226 fi
2227
2228 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2229 dnl using Motif or Xaw3d is available, and unless
2230 dnl --with-toolkit-scroll-bars=no was specified.
2231
2232 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2233             [Define to 1 if we should use toolkit scroll bars.])dnl
2234 USE_TOOLKIT_SCROLL_BARS=no
2235 if test "${with_toolkit_scroll_bars}" != "no"; then
2236   if test "${USE_X_TOOLKIT}" != "none"; then
2237     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2238       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2239       HAVE_XAW3D=no
2240       USE_TOOLKIT_SCROLL_BARS=yes
2241     elif test "${HAVE_XAW3D}" = "yes"; then
2242       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2243       USE_TOOLKIT_SCROLL_BARS=yes
2244     fi
2245   elif test "${HAVE_GTK}" = "yes"; then
2246     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2247     USE_TOOLKIT_SCROLL_BARS=yes
2248   elif test "${HAVE_NS}" = "yes"; then
2249     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2250     USE_TOOLKIT_SCROLL_BARS=yes
2251   fi
2252 fi
2253
2254 dnl See if XIM is available.
2255 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2256           #include <X11/Xlib.h>
2257           #include <X11/Xresource.h>]],
2258          [[XIMProc  callback;]])],
2259          [HAVE_XIM=yes
2260          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2261          HAVE_XIM=no)
2262
2263 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2264
2265 if test "${with_xim}" != "no"; then
2266   AC_DEFINE(USE_XIM, 1,
2267             [Define to 1 if we should use XIM, if it is available.])
2268 fi
2269
2270
2271 if test "${HAVE_XIM}" != "no"; then
2272   late_CFLAGS=$CFLAGS
2273   if test "$GCC" = yes; then
2274     CFLAGS="$CFLAGS --pedantic-errors"
2275   fi
2276   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2277 #include <X11/Xlib.h>
2278 #include <X11/Xresource.h>]],
2279 [[Display *display;
2280 XrmDatabase db;
2281 char *res_name;
2282 char *res_class;
2283 XIMProc  callback;
2284 XPointer *client_data;
2285 #ifndef __GNUC__
2286 /* If we're not using GCC, it's probably not XFree86, and this is
2287    probably right, but we can't use something like --pedantic-errors.  */
2288 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2289                                            char*, XIMProc, XPointer*);
2290 #endif
2291 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2292    client_data);]])],
2293     [emacs_cv_arg6_star=yes])
2294   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2295          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2296 either XPointer or XPointer*.])dnl
2297   if test "$emacs_cv_arg6_star" = yes; then
2298     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2299   else
2300     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2301   fi
2302   CFLAGS=$late_CFLAGS
2303 fi
2304
2305 ### Start of font-backend (under any platform) section.
2306 # (nothing here yet -- this is a placeholder)
2307 ### End of font-backend (under any platform) section.
2308
2309 ### Start of font-backend (under X11) section.
2310 if test "${HAVE_X11}" = "yes"; then
2311    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2312
2313    ## Use -lXft if available, unless `--with-xft=no'.
2314    HAVE_XFT=maybe
2315     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2316       with_xft="no";
2317     fi
2318     if test "x${with_xft}" != "xno"; then
2319
2320       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2321       ## Because xftfont.c uses XRenderQueryExtension, we also
2322       ## need to link to -lXrender.
2323       HAVE_XRENDER=no
2324       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2325       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2326         OLD_CPPFLAGS="$CPPFLAGS"
2327         OLD_CFLAGS="$CFLAGS"
2328         OLD_LIBS="$LIBS"
2329         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2330         CFLAGS="$CFLAGS $XFT_CFLAGS"
2331         XFT_LIBS="-lXrender $XFT_LIBS"
2332         LIBS="$XFT_LIBS $LIBS"
2333         AC_CHECK_HEADER(X11/Xft/Xft.h,
2334           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2335
2336         if test "${HAVE_XFT}" = "yes"; then
2337           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2338             AC_SUBST(XFT_LIBS)
2339           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2340         else
2341           CPPFLAGS="$OLD_CPPFLAGS"
2342           CFLAGS="$OLD_CFLAGS"
2343           LIBS="$OLD_LIBS"
2344         fi                        # "${HAVE_XFT}" = "yes"
2345       fi                          # "$HAVE_XFT" != no
2346     fi                            # "x${with_xft}" != "xno"
2347
2348     ## We used to allow building with FreeType and without Xft.
2349     ## However, the ftx font backend driver is not in good shape.
2350     if test "$HAVE_XFT" != "yes"; then
2351        dnl For the "Does Emacs use" message at the end.
2352        HAVE_XFT=no
2353        HAVE_FREETYPE=no
2354     else
2355        dnl Strict linkers fail with
2356        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2357        dnl if -lfreetype is not specified.
2358        dnl The following is needed to set FREETYPE_LIBS.
2359        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2360                          HAVE_FREETYPE=no)
2361
2362        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2363     fi
2364
2365     HAVE_LIBOTF=no
2366     if test "${HAVE_FREETYPE}" = "yes"; then
2367       AC_DEFINE(HAVE_FREETYPE, 1,
2368                 [Define to 1 if using the freetype and fontconfig libraries.])
2369       if test "${with_libotf}" != "no"; then
2370         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2371                           HAVE_LIBOTF=no)
2372         if test "$HAVE_LIBOTF" = "yes"; then
2373           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2374           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2375                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2376                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2377           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2378             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2379                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2380           fi
2381         fi
2382       fi
2383     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2384     dnl Does the new font backend require it, or can it work without it?
2385     fi
2386
2387     HAVE_M17N_FLT=no
2388     if test "${HAVE_LIBOTF}" = yes; then
2389       if test "${with_m17n_flt}" != "no"; then
2390         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2391         if test "$HAVE_M17N_FLT" = "yes"; then
2392           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2393         fi
2394       fi
2395     fi
2396 else
2397     HAVE_XFT=no
2398     HAVE_FREETYPE=no
2399     HAVE_LIBOTF=no
2400     HAVE_M17N_FLT=no
2401 fi
2402
2403 ### End of font-backend (under X11) section.
2404
2405 AC_SUBST(FREETYPE_CFLAGS)
2406 AC_SUBST(FREETYPE_LIBS)
2407 AC_SUBST(FONTCONFIG_CFLAGS)
2408 AC_SUBST(FONTCONFIG_LIBS)
2409 AC_SUBST(LIBOTF_CFLAGS)
2410 AC_SUBST(LIBOTF_LIBS)
2411 AC_SUBST(M17N_FLT_CFLAGS)
2412 AC_SUBST(M17N_FLT_LIBS)
2413
2414 ### Use -lXpm if available, unless `--with-xpm=no'.
2415 HAVE_XPM=no
2416 LIBXPM=
2417 if test "${HAVE_X11}" = "yes"; then
2418   if test "${with_xpm}" != "no"; then
2419     AC_CHECK_HEADER(X11/xpm.h,
2420       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2421     if test "${HAVE_XPM}" = "yes"; then
2422       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2423       AC_EGREP_CPP(no_return_alloc_pixels,
2424       [#include "X11/xpm.h"
2425 #ifndef XpmReturnAllocPixels
2426 no_return_alloc_pixels
2427 #endif
2428       ], HAVE_XPM=no, HAVE_XPM=yes)
2429
2430       if test "${HAVE_XPM}" = "yes"; then
2431         AC_MSG_RESULT(yes)
2432       else
2433         AC_MSG_RESULT(no)
2434       fi
2435     fi
2436   fi
2437
2438   if test "${HAVE_XPM}" = "yes"; then
2439     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2440     LIBXPM=-lXpm
2441   fi
2442 fi
2443 AC_SUBST(LIBXPM)
2444
2445 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2446 HAVE_JPEG=no
2447 LIBJPEG=
2448 if test "${HAVE_X11}" = "yes"; then
2449   if test "${with_jpeg}" != "no"; then
2450     dnl Checking for jpeglib.h can lose because of a redefinition of
2451     dnl  HAVE_STDLIB_H.
2452     AC_CHECK_HEADER(jerror.h,
2453       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2454   fi
2455
2456   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2457   if test "${HAVE_JPEG}" = "yes"; then
2458     AC_DEFINE(HAVE_JPEG)
2459     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2460         [#include <jpeglib.h>
2461          version=JPEG_LIB_VERSION
2462 ],
2463         [AC_DEFINE(HAVE_JPEG)],
2464         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2465         HAVE_JPEG=no])
2466   fi
2467   if test "${HAVE_JPEG}" = "yes"; then
2468     LIBJPEG=-ljpeg
2469   fi
2470 fi
2471 AC_SUBST(LIBJPEG)
2472
2473 ### Use -lpng if available, unless `--with-png=no'.
2474 HAVE_PNG=no
2475 LIBPNG=
2476 if test "${HAVE_X11}" = "yes"; then
2477   if test "${with_png}" != "no"; then
2478     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2479     # in /usr/include/libpng.
2480     AC_CHECK_HEADERS(png.h libpng/png.h)
2481     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2482       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2483     fi
2484   fi
2485
2486   if test "${HAVE_PNG}" = "yes"; then
2487     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2488     LIBPNG="-lpng -lz -lm"
2489   fi
2490 fi
2491 AC_SUBST(LIBPNG)
2492
2493 ### Use -ltiff if available, unless `--with-tiff=no'.
2494 HAVE_TIFF=no
2495 LIBTIFF=
2496 if test "${HAVE_X11}" = "yes"; then
2497   if test "${with_tiff}" != "no"; then
2498     AC_CHECK_HEADER(tiffio.h,
2499       [tifflibs="-lz -lm"
2500       # At least one tiff package requires the jpeg library.
2501       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2502       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2503   fi
2504
2505   if test "${HAVE_TIFF}" = "yes"; then
2506     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2507     dnl FIXME -lz -lm, as per libpng?
2508     LIBTIFF=-ltiff
2509   fi
2510 fi
2511 AC_SUBST(LIBTIFF)
2512
2513 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2514 HAVE_GIF=no
2515 LIBGIF=
2516 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2517   AC_CHECK_HEADER(gif_lib.h,
2518 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2519 # Earlier versions can crash Emacs.
2520     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2521
2522   if test "$HAVE_GIF" = yes; then
2523     LIBGIF=-lgif
2524   elif test "$HAVE_GIF" = maybe; then
2525 # If gif_lib.h but no libgif, try libungif.
2526     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2527     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2528   fi
2529
2530   if test "${HAVE_GIF}" = "yes"; then
2531     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2532   fi
2533 fi
2534 AC_SUBST(LIBGIF)
2535
2536 dnl Check for required libraries.
2537 if test "${HAVE_X11}" = "yes"; then
2538   MISSING=""
2539   WITH_NO=""
2540   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2541     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2542   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2543     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2544   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2545     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2546   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2547     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2548   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2549     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2550
2551   if test "X${MISSING}" != X; then
2552     AC_MSG_ERROR([The following required libraries were not found:
2553     $MISSING
2554 Maybe some development libraries/packages are missing?
2555 If you don't want to link with them give
2556     $WITH_NO
2557 as options to configure])
2558   fi
2559 fi
2560
2561 ### Use -lgpm if available, unless `--with-gpm=no'.
2562 HAVE_GPM=no
2563 LIBGPM=
2564 if test "${with_gpm}" != "no"; then
2565   AC_CHECK_HEADER(gpm.h,
2566     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2567
2568   if test "${HAVE_GPM}" = "yes"; then
2569     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2570     LIBGPM=-lgpm
2571   fi
2572 fi
2573 AC_SUBST(LIBGPM)
2574
2575 dnl Check for malloc/malloc.h on darwin
2576 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2577
2578 C_SWITCH_X_SYSTEM=
2579 ### Use NeXTstep API to implement GUI.
2580 if test "${HAVE_NS}" = "yes"; then
2581   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2582   if test "${NS_IMPL_COCOA}" = "yes"; then
2583     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2584   fi
2585   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2586     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2587     # See also .m.o rule in Makefile.in */
2588     # FIXME: are all these flags really needed?  Document here why.  */
2589     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2590     ## Extra CFLAGS applied to src/*.m files.
2591     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2592   fi
2593   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2594     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2595   fi
2596   # We also have mouse menus.
2597   HAVE_MENUS=yes
2598   OTHER_FILES=ns-app
2599 fi
2600
2601
2602 ### Use session management (-lSM -lICE) if available
2603 HAVE_X_SM=no
2604 LIBXSM=
2605 if test "${HAVE_X11}" = "yes"; then
2606   AC_CHECK_HEADER(X11/SM/SMlib.h,
2607     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2608
2609   if test "${HAVE_X_SM}" = "yes"; then
2610     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2611     LIBXSM="-lSM -lICE"
2612     case "$LIBS" in
2613       *-lSM*) ;;
2614       *)      LIBS="$LIBXSM $LIBS" ;;
2615     esac
2616   fi
2617 fi
2618 AC_SUBST(LIBXSM)
2619
2620 ### Use libxml (-lxml2) if available
2621 HAVE_LIBXML2=no
2622 if test "${with_xml2}" != "no"; then
2623   ### I'm not sure what the version number should be, so I just guessed.
2624   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2625   if test "${HAVE_LIBXML2}" = "yes"; then
2626     LIBS="$LIBXML2_LIBS $LIBS"
2627     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2628     if test "${HAVE_LIBXML2}" = "yes"; then
2629       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2630     else
2631       LIBXML2_LIBS=""
2632       LIBXML2_CFLAGS=""
2633     fi
2634   fi
2635 fi
2636 AC_SUBST(LIBXML2_LIBS)
2637 AC_SUBST(LIBXML2_CFLAGS)
2638
2639 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2640 AC_CACHE_CHECK(whether netdb declares h_errno,
2641                emacs_cv_netdb_declares_h_errno,
2642 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2643   [[return h_errno;]])],
2644   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2645 if test $emacs_cv_netdb_declares_h_errno = yes; then
2646   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2647 fi
2648
2649 # fmod, logb, and frexp are found in -lm on most systems.
2650 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2651 AC_CHECK_LIB(m, sqrt)
2652
2653 # Check for mail-locking functions in a "mail" library.  Probably this should
2654 # have the same check as for liblockfile below.
2655 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2656 if test $have_mail = yes; then
2657   LIBS_MAIL=-lmail
2658   LIBS="$LIBS_MAIL $LIBS"
2659   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2660 else
2661   LIBS_MAIL=
2662 fi
2663 dnl Debian, at least:
2664 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2665 if test $have_lockfile = yes; then
2666    LIBS_MAIL=-llockfile
2667    LIBS="$LIBS_MAIL $LIBS"
2668    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2669 else
2670 # If we have the shared liblockfile, assume we must use it for mail
2671 # locking (e.g. Debian).  If we couldn't link against liblockfile
2672 # (no liblockfile.a installed), ensure that we don't need to.
2673   dnl This works for files generally, not just executables.
2674   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2675   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2676                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2677   if test $ac_cv_prog_liblockfile = yes; then
2678     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2679 This probably means that movemail could lose mail.
2680 There may be a `development' package to install containing liblockfile.])
2681   fi
2682 fi
2683 AC_CHECK_FUNCS(touchlock)
2684 AC_CHECK_HEADERS(maillock.h)
2685 AC_SUBST(LIBS_MAIL)
2686
2687 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2688 ## interlock access to the mail spool.  The alternative is a lock file named
2689 ## /usr/spool/mail/$USER.lock.
2690 mail_lock=no
2691 case "$opsys" in
2692   aix4-2) mail_lock="lockf" ;;
2693
2694   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2695
2696   ## On GNU/Linux systems, both methods are used by various mail programs.
2697   ## I assume most people are using newer mailers that have heard of flock.
2698   ## Change this if you need to.
2699   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2700   ## configure gets the right answers, and that means *NOT* using flock.
2701   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2702   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2703   ## Debian maintainer hasn't provided a clean fix for Emacs.
2704   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2705   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2706   ## correct logic.  -- fx
2707   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2708   ## liblockfile is a Free Software replacement for libmail, used on
2709   ## Debian systems and elsewhere. -rfr.
2710   gnu-*)
2711     mail_lock="flock"
2712     if test $have_mail = yes || test $have_lockfile = yes; then
2713       test $ac_cv_header_maillock_h = yes && mail_lock=no
2714     fi
2715     ;;
2716 esac
2717
2718 BLESSMAIL_TARGET=
2719 case "$mail_lock" in
2720   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2721
2722   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2723
2724   *) BLESSMAIL_TARGET="need-blessmail" ;;
2725 esac
2726 AC_SUBST(BLESSMAIL_TARGET)
2727
2728
2729 AC_CHECK_FUNCS(gethostname getdomainname \
2730 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2731 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2732 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2733 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2734 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2735 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2736 gai_strerror mkstemp getline getdelim mremap fsync sync \
2737 difftime mempcpy mblen mbrlen posix_memalign \
2738 cfmakeraw cfsetspeed copysign __executable_start)
2739
2740 dnl Cannot use AC_CHECK_FUNCS
2741 AC_CACHE_CHECK([for __builtin_unwind_init],
2742                emacs_cv_func___builtin_unwind_init,
2743 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2744                 emacs_cv_func___builtin_unwind_init=yes,
2745                 emacs_cv_func___builtin_unwind_init=no)])
2746 if test $emacs_cv_func___builtin_unwind_init = yes; then
2747   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2748             [Define to 1 if you have the `__builtin_unwind_init' function.])
2749 fi
2750
2751 AC_CHECK_HEADERS(sys/un.h)
2752
2753 AC_FUNC_FSEEKO
2754
2755 AC_FUNC_GETPGRP
2756
2757 # UNIX98 PTYs.
2758 AC_CHECK_FUNCS(grantpt)
2759
2760 # PTY-related GNU extensions.
2761 AC_CHECK_FUNCS(getpt)
2762
2763 # Check this now, so that we will NOT find the above functions in ncurses.
2764 # That is because we have not set up to link ncurses in lib-src.
2765 # It's better to believe a function is not available
2766 # than to expect to find it in ncurses.
2767 # Also we need tputs and friends to be able to build at all.
2768 have_tputs_et_al=true
2769 # Maybe curses should be tried earlier?
2770 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2771 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap curses], , have_tputs_et_al=false)
2772 if test "$have_tputs_et_al" != true; then
2773   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2774 These libraries were tried: libncurses, libterminfo, libtermcap, libcurses.
2775 Please try installing whichever of these libraries is most appropriate
2776 for your system, together with its header files.
2777 For example, a libncurses-dev(el) or similar package.])
2778 fi
2779 # Must define this when any termcap library is found.
2780 AC_DEFINE(HAVE_LIBNCURSES, 1,
2781           [Define to 1 if you have the `ncurses' library (-lncurses).])
2782 ## FIXME This was the cpp logic, but I am not sure it is right.
2783 ## The above test has not necessarily found libncurses.
2784 HAVE_LIBNCURSES=yes
2785
2786 ## Use terminfo instead of termcap?
2787 ## Note only system files NOT using terminfo are:
2788 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2789 ## darwin|gnu without ncurses.
2790 TERMINFO=no
2791 LIBS_TERMCAP=
2792 case "$opsys" in
2793   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2794   ## hpux10-20: Use the system provided termcap(3) library.
2795   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2796   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2797   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2798
2799   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2800   ##  The ncurses library has been moved out of the System framework in
2801   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2802   ##  option to use it.
2803   darwin|gnu*)
2804     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2805     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2806       TERMINFO=yes
2807       LIBS_TERMCAP="-lncurses"
2808     fi
2809     ;;
2810
2811   freebsd)
2812     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2813     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2814     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2815 [[#if __FreeBSD_version < 400000
2816 fail;
2817 #endif
2818 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2819
2820     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2821
2822     if test $emacs_cv_freebsd_terminfo = yes; then
2823       TERMINFO=yes
2824       LIBS_TERMCAP="-lncurses"
2825     else
2826       LIBS_TERMCAP="-ltermcap"
2827     fi
2828     ;;
2829
2830   netbsd)
2831     if test $ac_cv_search_tputs = -lterminfo; then
2832       TERMINFO=yes
2833       LIBS_TERMCAP="-lterminfo"
2834     else
2835       LIBS_TERMCAP="-ltermcap"
2836     fi
2837     ;;
2838
2839 esac
2840
2841 case "$opsys" in
2842   ## hpux: Make sure we get select from libc rather than from libcurses
2843   ##  because libcurses on HPUX 10.10 has a broken version of select.
2844   ##  We used to use -lc -lcurses, but this may be cleaner.
2845   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2846
2847   openbsd) LIBS_TERMCAP="-lncurses" ;;
2848
2849   ## Must use system termcap, if we use any termcap.  It does special things.
2850   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2851 esac
2852
2853 TERMCAP_OBJ=tparam.o
2854 if test $TERMINFO = yes; then
2855   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2856
2857   ## Default used to be -ltermcap.  Add a case above if need something else.
2858   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2859
2860   TERMCAP_OBJ=terminfo.o
2861 fi
2862 AC_SUBST(LIBS_TERMCAP)
2863 AC_SUBST(TERMCAP_OBJ)
2864
2865
2866 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2867 resolv=no
2868 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2869 #include <arpa/nameser.h>
2870 #include <resolv.h>]],
2871     [[return res_init();]])],
2872     have_res_init=yes, have_res_init=no)
2873 if test "$have_res_init" = no; then
2874   OLIBS="$LIBS"
2875   LIBS="$LIBS -lresolv"
2876   AC_MSG_CHECKING(for res_init with -lresolv)
2877   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2878 #include <arpa/nameser.h>
2879 #include <resolv.h>]],
2880     [[return res_init();]])],
2881     have_res_init=yes, have_res_init=no)
2882   AC_MSG_RESULT($have_res_init)
2883   if test "$have_res_init" = yes ; then
2884     resolv=yes
2885   fi
2886   LIBS="$OLIBS"
2887 fi
2888
2889 if test "$have_res_init" = yes; then
2890   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2891 fi
2892
2893 # Do we need the Hesiod library to provide the support routines?
2894 LIBHESIOD=
2895 if test "$with_hesiod" != no ; then
2896   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2897   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2898      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2899                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2900   if test "$resolv" = yes ; then
2901     RESOLVLIB=-lresolv
2902   else
2903     RESOLVLIB=
2904   fi
2905   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2906         hesiod=yes, :, $RESOLVLIB)])
2907
2908   if test x"$hesiod" = xyes; then
2909     AC_DEFINE(HAVE_LIBHESIOD, 1,
2910               [Define to 1 if you have the hesiod library (-lhesiod).])
2911     LIBHESIOD=-lhesiod
2912   fi
2913 fi
2914 AC_SUBST(LIBHESIOD)
2915
2916 # Do we need libresolv (due to res_init or Hesiod)?
2917 if test "$resolv" = yes ; then
2918   AC_DEFINE(HAVE_LIBRESOLV, 1,
2919             [Define to 1 if you have the resolv library (-lresolv).])
2920   LIBRESOLV=-lresolv
2921 else
2922   LIBRESOLV=
2923 fi
2924 AC_SUBST(LIBRESOLV)
2925
2926 # These tell us which Kerberos-related libraries to use.
2927 COM_ERRLIB=
2928 CRYPTOLIB=
2929 KRB5LIB=
2930 DESLIB=
2931 KRB4LIB=
2932
2933 if test "${with_kerberos}" != no; then
2934   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2935   if test $have_com_err = yes; then
2936     COM_ERRLIB=-lcom_err
2937     LIBS="$COM_ERRLIB $LIBS"
2938     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2939   fi
2940   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2941   if test $have_crypto = yes; then
2942     CRYPTOLIB=-lcrypto
2943     LIBS="$CRYPTOLIB $LIBS"
2944     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2945   fi
2946   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2947   if test $have_k5crypto = yes; then
2948     CRYPTOLIB=-lk5crypto
2949     LIBS="$CRYPTOLIB $LIBS"
2950     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2951   fi
2952   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2953   if test $have_krb5=yes; then
2954     KRB5LIB=-lkrb5
2955     LIBS="$KRB5LIB $LIBS"
2956     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2957   fi
2958   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2959   if test "${with_kerberos5}" = no; then
2960     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2961     if test $have_des425 = yes; then
2962       DESLIB=-ldes425
2963       LIBS="$DESLIB $LIBS"
2964       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2965     else
2966       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2967       if test $have_des = yes; then
2968         DESLIB=-ldes
2969         LIBS="$DESLIB $LIBS"
2970         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2971       fi
2972     fi
2973     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2974     if test $have_krb4 = yes; then
2975       KRB4LIB=-lkrb4
2976       LIBS="$KRB4LIB $LIBS"
2977       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2978     else
2979       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2980       if test $have_krb = yes; then
2981         KRB4LIB=-lkrb
2982         LIBS="$KRB4LIB $LIBS"
2983         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2984       fi
2985     fi
2986   fi
2987
2988   if test "${with_kerberos5}" != no; then
2989     AC_CHECK_HEADERS(krb5.h,
2990       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2991                         [#include <krb5.h>])])
2992   else
2993     AC_CHECK_HEADERS(des.h,,
2994                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2995                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2996     AC_CHECK_HEADERS(krb.h,,
2997                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2998                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2999   fi
3000   AC_CHECK_HEADERS(com_err.h)
3001 fi
3002
3003 AC_SUBST(COM_ERRLIB)
3004 AC_SUBST(CRYPTOLIB)
3005 AC_SUBST(KRB5LIB)
3006 AC_SUBST(DESLIB)
3007 AC_SUBST(KRB4LIB)
3008
3009 AC_MSG_CHECKING(whether localtime caches TZ)
3010 AC_CACHE_VAL(emacs_cv_localtime_cache,
3011 [if test x$ac_cv_func_tzset = xyes; then
3012 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3013 char TZ_GMT0[] = "TZ=GMT0";
3014 char TZ_PST8[] = "TZ=PST8";
3015 main()
3016 {
3017   time_t now = time ((time_t *) 0);
3018   int hour_GMT0, hour_unset;
3019   if (putenv (TZ_GMT0) != 0)
3020     exit (1);
3021   hour_GMT0 = localtime (&now)->tm_hour;
3022   unsetenv("TZ");
3023   hour_unset = localtime (&now)->tm_hour;
3024   if (putenv (TZ_PST8) != 0)
3025     exit (1);
3026   if (localtime (&now)->tm_hour == hour_GMT0)
3027     exit (1);
3028   unsetenv("TZ");
3029   if (localtime (&now)->tm_hour != hour_unset)
3030     exit (1);
3031   exit (0);
3032 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3033 [# If we have tzset, assume the worst when cross-compiling.
3034 emacs_cv_localtime_cache=yes])
3035 else
3036         # If we lack tzset, report that localtime does not cache TZ,
3037         # since we can't invalidate the cache if we don't have tzset.
3038         emacs_cv_localtime_cache=no
3039 fi])dnl
3040 AC_MSG_RESULT($emacs_cv_localtime_cache)
3041 if test $emacs_cv_localtime_cache = yes; then
3042   AC_DEFINE(LOCALTIME_CACHE, 1,
3043             [Define to 1 if localtime caches TZ.])
3044 fi
3045
3046 if test "x$HAVE_TIMEVAL" = xyes; then
3047   AC_CHECK_FUNCS(gettimeofday)
3048   if test $ac_cv_func_gettimeofday = yes; then
3049     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3050                    emacs_cv_gettimeofday_two_arguments,
3051     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3052 #ifdef TIME_WITH_SYS_TIME
3053 #include <sys/time.h>
3054 #include <time.h>
3055 #else
3056 #ifdef HAVE_SYS_TIME_H
3057 #include <sys/time.h>
3058 #else
3059 #include <time.h>
3060 #endif
3061 #endif]],
3062       [[struct timeval time;
3063        gettimeofday (&time, 0);]])],
3064       emacs_cv_gettimeofday_two_arguments=yes,
3065       emacs_cv_gettimeofday_two_arguments=no)])
3066     if test $emacs_cv_gettimeofday_two_arguments = no; then
3067       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3068                 [Define to 1 if gettimeofday accepts only one argument.])
3069     fi
3070   fi
3071 fi
3072
3073 ok_so_far=yes
3074 AC_CHECK_FUNC(socket, , ok_so_far=no)
3075 if test $ok_so_far = yes; then
3076   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3077 fi
3078 if test $ok_so_far = yes; then
3079   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3080 fi
3081 if test $ok_so_far = yes; then
3082 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3083   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3084             [Define to 1 if you have inet sockets.])
3085 fi
3086
3087 if test -f /usr/lpp/X11/bin/smt.exp; then
3088   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3089             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3090 fi
3091
3092 AC_MSG_CHECKING(whether system supports dynamic ptys)
3093 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3094   AC_MSG_RESULT(yes)
3095   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3096 else
3097   AC_MSG_RESULT(no)
3098 fi
3099
3100 AC_FUNC_FORK
3101
3102 AC_CHECK_FUNCS(snprintf)
3103
3104 dnl Adapted from Haible's version.
3105 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3106   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3107     [[char* cs = nl_langinfo(CODESET);]])],
3108     emacs_cv_langinfo_codeset=yes,
3109     emacs_cv_langinfo_codeset=no)
3110   ])
3111 if test $emacs_cv_langinfo_codeset = yes; then
3112   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3113     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3114 fi
3115
3116 AC_TYPE_MBSTATE_T
3117
3118 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3119   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3120                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3121 if test "$emacs_cv_c_restrict_arr" = yes; then
3122   AC_DEFINE(__restrict_arr, __restrict,
3123     [Define to compiler's equivalent of C99 restrict keyword in array
3124      declarations.  Define as empty for no equivalent.])
3125 fi
3126
3127 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3128 dnl how the tty code is related to POSIX and/or other versions of termios.
3129 dnl The following looks like a useful start.
3130 dnl
3131 dnl AC_SYS_POSIX_TERMIOS
3132 dnl if test $ac_cv_sys_posix_termios = yes; then
3133 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3134 dnl                                and macros for terminal control.])
3135 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3136 dnl fi
3137
3138 # Set up the CFLAGS for real compilation, so we can substitute it.
3139 CFLAGS="$REAL_CFLAGS"
3140 CPPFLAGS="$REAL_CPPFLAGS"
3141
3142 ## Hack to detect a buggy GCC version.
3143 if test "x$GCC" = xyes \
3144    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3145    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3146    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3147    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3148 fi
3149
3150 version=$PACKAGE_VERSION
3151
3152 ### Specify what sort of things we'll be editing into Makefile and config.h.
3153 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3154 AC_SUBST(version)
3155 AC_SUBST(configuration)
3156 ## Unused?
3157 AC_SUBST(canonical)
3158 AC_SUBST(srcdir)
3159 AC_SUBST(prefix)
3160 AC_SUBST(exec_prefix)
3161 AC_SUBST(bindir)
3162 AC_SUBST(datadir)
3163 AC_SUBST(sharedstatedir)
3164 AC_SUBST(libexecdir)
3165 AC_SUBST(mandir)
3166 AC_SUBST(infodir)
3167 AC_SUBST(lispdir)
3168 AC_SUBST(locallisppath)
3169 AC_SUBST(lisppath)
3170 AC_SUBST(x_default_search_path)
3171 AC_SUBST(etcdir)
3172 AC_SUBST(archlibdir)
3173 AC_SUBST(docdir)
3174 AC_SUBST(bitmapdir)
3175 AC_SUBST(gamedir)
3176 AC_SUBST(gameuser)
3177 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3178 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3179 ## end of LIBX_BASE, but nothing ever set it.
3180 AC_SUBST(LD_SWITCH_X_SITE)
3181 AC_SUBST(C_SWITCH_X_SITE)
3182 AC_SUBST(C_SWITCH_X_SYSTEM)
3183 AC_SUBST(CFLAGS)
3184 ## Used in lwlib/Makefile.in.
3185 AC_SUBST(X_TOOLKIT_TYPE)
3186 if test -n "${machfile}"; then
3187   M_FILE="\$(srcdir)/${machfile}"
3188 else
3189   M_FILE=
3190 fi
3191 S_FILE="\$(srcdir)/${opsysfile}"
3192 AC_SUBST(M_FILE)
3193 AC_SUBST(S_FILE)
3194 AC_SUBST(ns_appdir)
3195 AC_SUBST(ns_appbindir)
3196 AC_SUBST(ns_appresdir)
3197 AC_SUBST(ns_appsrc)
3198 AC_SUBST(GNU_OBJC_CFLAGS)
3199 AC_SUBST(OTHER_FILES)
3200
3201 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3202                    [Define to the canonical Emacs configuration name.])
3203 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3204                    [Define to the options passed to configure.])
3205 if test -n "$machfile"; then
3206   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3207                      [Define to the used machine dependent file.])
3208 fi
3209 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3210                    [Define to the used os dependent file.])
3211
3212 XMENU_OBJ=
3213 XOBJ=
3214 FONT_OBJ=
3215 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3216   AC_DEFINE(HAVE_X_WINDOWS, 1,
3217             [Define to 1 if you want to use the X window system.])
3218   XMENU_OBJ=xmenu.o
3219   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3220   FONT_OBJ=xfont.o
3221   if test "$HAVE_XFT" = "yes"; then
3222     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3223   elif test "$HAVE_FREETYPE" = "yes"; then
3224     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3225   fi
3226   AC_SUBST(FONT_OBJ)
3227 fi
3228 AC_SUBST(XMENU_OBJ)
3229 AC_SUBST(XOBJ)
3230 AC_SUBST(FONT_OBJ)
3231
3232 WIDGET_OBJ=
3233 MOTIF_LIBW=
3234 if test "${USE_X_TOOLKIT}" != "none" ; then
3235   WIDGET_OBJ=widget.o
3236   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3237   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3238     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3239   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3240     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3241     MOTIF_LIBW=-lXm
3242     case "$opsys" in
3243       gnu-linux)
3244         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3245         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3246         ;;
3247
3248       unixware)
3249         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3250         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3251         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3252         ;;
3253
3254       aix4-2)
3255         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3256         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3257         ;;
3258     esac
3259     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3260   fi
3261 fi
3262 AC_SUBST(WIDGET_OBJ)
3263
3264 TOOLKIT_LIBW=
3265 case "$USE_X_TOOLKIT" in
3266   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3267   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3268   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3269 esac
3270 AC_SUBST(TOOLKIT_LIBW)
3271
3272 if test "$USE_X_TOOLKIT" = "none"; then
3273   LIBXT_OTHER="\$(LIBXSM)"
3274   OLDXMENU_TARGET="really-oldXMenu"
3275 else
3276   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3277   OLDXMENU_TARGET="really-lwlib"
3278 fi
3279 AC_SUBST(LIBXT_OTHER)
3280
3281 ## The X Menu stuff is present in the X10 distribution, but missing
3282 ## from X11.  If we have X10, just use the installed library;
3283 ## otherwise, use our own copy.
3284 if test "${HAVE_X11}" = "yes" ; then
3285   AC_DEFINE(HAVE_X11, 1,
3286             [Define to 1 if you want to use version 11 of X windows.
3287              Otherwise, Emacs expects to use version 10.])
3288
3289   if test "$USE_X_TOOLKIT" = "none"; then
3290     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3291   else
3292     OLDXMENU="\${lwlibdir}/liblw.a"
3293   fi
3294   LIBXMENU="\$(OLDXMENU)"
3295   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3296   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3297 else
3298   ## For a syntactically valid Makefile; not actually used for anything.
3299   ## See comments in src/Makefile.in.
3300   OLDXMENU=nothing
3301   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3302   if test "${HAVE_X_WINDOWS}" = "yes"; then
3303     LIBXMENU="-lXMenu"
3304   else
3305     LIBXMENU=
3306   fi
3307   LIBX_OTHER=
3308   OLDXMENU_DEPS=
3309 fi
3310
3311 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3312   OLDXMENU_TARGET=
3313   OLDXMENU=nothing
3314   LIBXMENU=
3315   OLDXMENU_DEPS=
3316 fi
3317
3318 AC_SUBST(OLDXMENU_TARGET)
3319 AC_SUBST(OLDXMENU)
3320 AC_SUBST(LIBXMENU)
3321 AC_SUBST(LIBX_OTHER)
3322 AC_SUBST(OLDXMENU_DEPS)
3323
3324 if test "${HAVE_MENUS}" = "yes" ; then
3325   AC_DEFINE(HAVE_MENUS, 1,
3326             [Define to 1 if you have mouse menus.
3327              (This is automatic if you use X, but the option to specify it remains.)
3328              It is also defined with other window systems that support xmenu.c.])
3329 fi
3330
3331 if test "${GNU_MALLOC}" = "yes" ; then
3332   AC_DEFINE(GNU_MALLOC, 1,
3333             [Define to 1 if you want to use the GNU memory allocator.])
3334 fi
3335
3336 RALLOC_OBJ=
3337 if test "${REL_ALLOC}" = "yes" ; then
3338   AC_DEFINE(REL_ALLOC, 1,
3339             [Define REL_ALLOC if you want to use the relocating allocator for
3340              buffer space.])
3341
3342   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3343 fi
3344 AC_SUBST(RALLOC_OBJ)
3345
3346 if test "$opsys" = "cygwin"; then
3347   CYGWIN_OBJ="sheap.o"
3348   ## Cygwin differs because of its unexec().
3349   PRE_ALLOC_OBJ=
3350   POST_ALLOC_OBJ=lastfile.o
3351 else
3352   CYGWIN_OBJ=
3353   PRE_ALLOC_OBJ=lastfile.o
3354   POST_ALLOC_OBJ=
3355 fi
3356 AC_SUBST(CYGWIN_OBJ)
3357 AC_SUBST(PRE_ALLOC_OBJ)
3358 AC_SUBST(POST_ALLOC_OBJ)
3359
3360 # Configure gnulib here, now that we know LIBS.
3361 gl_ASSERT_NO_GNULIB_POSIXCHECK
3362 gl_ASSERT_NO_GNULIB_TESTS
3363 gl_INIT
3364
3365 case "$opsys" in
3366   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3367
3368   darwin)
3369    ## The -headerpad option tells ld (see man page) to leave room at the
3370    ## end of the header for adding load commands.  Needed for dumping.
3371    ## 0x690 is the total size of 30 segment load commands (at 56
3372    ## each); under Cocoa 31 commands are required.
3373    if test "$HAVE_NS" = "yes"; then
3374      libs_nsgui="-framework AppKit"
3375      headerpad_extra=6C8
3376    else
3377      libs_nsgui=
3378      headerpad_extra=690
3379    fi
3380    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3381
3382    ## This is here because src/Makefile.in did some extra fiddling around
3383    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3384    ##   #ifndef LD_SWITCH_SYSTEM
3385    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3386    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3387    ## not using gcc, darwin system not on an alpha (ie darwin, since
3388    ## darwin + alpha does not occur).
3389    ## Because this was done in src/Makefile.in, the resulting part of
3390    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3391    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3392    ## rather than LD_SWITCH_SYSTEM.
3393    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3394      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3395    ;;
3396
3397   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3398   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3399   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3400   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3401   ## had different values in configure (in ac_link) and src/Makefile.in.
3402   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3403   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3404
3405   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3406 esac
3407
3408 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3409   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3410 fi
3411
3412 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3413
3414
3415 LD_FIRSTFLAG=
3416 ORDINARY_LINK=
3417 case "$opsys" in
3418   ## gnu: GNU needs its own crt0.
3419   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3420
3421   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3422   ## library search parth, i.e. it won't search /usr/lib for libc and
3423   ## friends.  Using -nostartfiles instead avoids this problem, and
3424   ## will also work on earlier NetBSD releases.
3425   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3426
3427   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3428   ##   MkLinux/LinuxPPC needs this.
3429   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3430   gnu-*)
3431     case "$machine" in
3432       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3433     esac
3434     ;;
3435 esac
3436
3437
3438 if test "x$ORDINARY_LINK" = "xyes"; then
3439
3440   LD_FIRSTFLAG=""
3441   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3442
3443 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3444 ## freebsd, gnu-* not on macppc|ibms390x.
3445 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3446
3447   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3448   ## places that are difficult to figure out at make time.  Fortunately,
3449   ## these same versions allow you to pass arbitrary flags on to the
3450   ## linker, so there is no reason not to use it as a linker.
3451   ##
3452   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3453   ## searching for libraries in its internal directories, so we have to
3454   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3455   LD_FIRSTFLAG="-nostdlib"
3456 fi
3457
3458 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3459 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3460
3461 AC_SUBST(LD_FIRSTFLAG)
3462
3463
3464 ## FIXME? The logic here is not precisely the same as that above.
3465 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3466 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3467 LIB_GCC=
3468 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3469
3470   case "$opsys" in
3471     freebsd|netbsd|openbsd) LIB_GCC= ;;
3472
3473     gnu-*)
3474       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3475       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3476       case $host_cpu in
3477       arm*)
3478         LIB_GCC="-lgcc_s"
3479         ;;
3480       *)
3481         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3482         ## immediately undefine it again and redefine it to empty.
3483         ## Was the C_SWITCH_X_SITE part really necessary?
3484 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3485         LIB_GCC=
3486         ;;
3487       esac
3488       ;;
3489
3490     ## Ask GCC where to find libgcc.a.
3491     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3492   esac
3493 fi                              dnl if $GCC
3494 AC_SUBST(LIB_GCC)
3495
3496
3497 ## If we're using X11/GNUstep, define some consequences.
3498 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3499   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3500   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3501 fi
3502
3503
3504 AH_TOP([/* GNU Emacs site configuration template file.
3505
3506 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3507   Free Software Foundation, Inc.
3508
3509 This file is part of GNU Emacs.
3510
3511 GNU Emacs is free software: you can redistribute it and/or modify
3512 it under the terms of the GNU General Public License as published by
3513 the Free Software Foundation, either version 3 of the License, or
3514 (at your option) any later version.
3515
3516 GNU Emacs is distributed in the hope that it will be useful,
3517 but WITHOUT ANY WARRANTY; without even the implied warranty of
3518 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3519 GNU General Public License for more details.
3520
3521 You should have received a copy of the GNU General Public License
3522 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3523
3524
3525 /* No code in Emacs #includes config.h twice, but some bits of code
3526    intended to work with other packages as well (like gmalloc.c)
3527    think they can include it as many times as they like.  */
3528 #ifndef EMACS_CONFIG_H
3529 #define EMACS_CONFIG_H
3530 ])dnl
3531
3532 AH_BOTTOM([
3533 /* On AIX 3 this must be included before any other include file.  */
3534 #include <alloca.h>
3535 #if ! HAVE_ALLOCA
3536 # error "alloca not available on this machine"
3537 #endif
3538
3539 /* Define AMPERSAND_FULL_NAME if you use the convention
3540    that & in the full name stands for the login id.  */
3541 /* Turned on June 1996 supposing nobody will mind it.  */
3542 #define AMPERSAND_FULL_NAME
3543
3544 /* `subprocesses' should be defined if you want to
3545    have code for asynchronous subprocesses
3546    (as used in M-x compile and M-x shell).
3547    Only MSDOS does not support this (it overrides
3548    this in its config_opsysfile below).  */
3549
3550 #define subprocesses
3551
3552 /* Include the os and machine dependent files.  */
3553 #include config_opsysfile
3554 #ifdef config_machfile
3555 # include config_machfile
3556 #endif
3557
3558 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3559    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3560   (There is probably a better place to do this, but right now the
3561    Cocoa side does this in s/darwin.h and we cannot parallel this
3562    exactly since GNUstep is multi-OS.  */
3563 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3564 #  define SYSTEM_PURESIZE_EXTRA 30000
3565 #endif
3566
3567 #ifdef emacs /* Don't do this for lib-src.  */
3568 /* Tell regex.c to use a type compatible with Emacs.  */
3569 #define RE_TRANSLATE_TYPE Lisp_Object
3570 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3571 #ifdef make_number
3572 /* If make_number is a macro, use it.  */
3573 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3574 #else
3575 /* If make_number is a function, avoid it.  */
3576 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3577 #endif
3578 #endif
3579
3580 /* These default definitions are good for almost all machines.
3581    Any exceptions should override them in m/MACHINE.h.
3582    They must be usable in preprocessor conditionals.  */
3583
3584 #ifndef BITS_PER_CHAR
3585 #define BITS_PER_CHAR 8
3586 #endif
3587
3588 #ifndef BITS_PER_SHORT
3589 #define BITS_PER_SHORT 16
3590 #endif
3591
3592 #ifndef BITS_PER_INT
3593 #define BITS_PER_INT 32
3594 #endif
3595
3596 #ifndef BITS_PER_LONG
3597 #ifdef _LP64
3598 #define BITS_PER_LONG 64
3599 #else
3600 #define BITS_PER_LONG 32
3601 #endif
3602 #endif
3603
3604 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3605 #define BITS_PER_LONG_LONG 64
3606 #endif
3607
3608 /* Define if the compiler supports function prototypes.  It may do so but
3609    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3610 #undef PROTOTYPES
3611
3612 #include <string.h>
3613 #include <stdlib.h>
3614
3615 #if defined __GNUC__ && (__GNUC__ > 2 \
3616                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3617 #define NO_RETURN       __attribute__ ((__noreturn__))
3618 #else
3619 #define NO_RETURN       /* nothing */
3620 #endif
3621
3622 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3623 #define NO_INLINE __attribute__((noinline))
3624 #else
3625 #define NO_INLINE
3626 #endif
3627
3628 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3629 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3630 #else
3631 #define EXTERNALLY_VISIBLE
3632 #endif
3633
3634 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3635 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3636 #else
3637 # define ATTRIBUTE_FORMAT(spec) /* empty */
3638 #endif
3639
3640 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3641 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3642    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3643 #else
3644 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3645    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3646 #endif
3647
3648 /* Some versions of GNU/Linux define noinline in their headers.  */
3649 #ifdef noinline
3650 #undef noinline
3651 #endif
3652
3653 /* These won't be used automatically yet.  We also need to know, at least,
3654    that the stack is continuous.  */
3655 #ifdef __GNUC__
3656 #  ifndef GC_SETJMP_WORKS
3657   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3658 #    define GC_SETJMP_WORKS 1
3659 #  endif
3660 #endif
3661
3662 #endif /* EMACS_CONFIG_H */
3663
3664 /*
3665 Local Variables:
3666 mode: c
3667 End:
3668 */
3669 ])dnl
3670
3671 #### Report on what we decided to do.
3672 #### Report GTK as a toolkit, even if it doesn't use Xt.
3673 #### It makes printing result more understandable as using GTK sets
3674 #### toolkit_scroll_bars to yes by default.
3675 if test "${HAVE_GTK}" = "yes"; then
3676   USE_X_TOOLKIT=GTK
3677 fi
3678
3679 and_machfile=
3680 if test -n "$machfile"; then
3681   and_machfile=" and \`${machfile}'"
3682 fi
3683
3684 echo "
3685 Configured for \`${canonical}'.
3686
3687   Where should the build process find the source code?    ${srcdir}
3688   What operating system and machine description files should Emacs use?
3689         \`${opsysfile}'${and_machfile}
3690   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3691   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3692   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3693   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3694   What window system should Emacs use?                    ${window_system}
3695   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3696
3697 if test -n "${x_includes}"; then
3698 echo "  Where do we find X Windows header files?                ${x_includes}"
3699 else
3700 echo "  Where do we find X Windows header files?                Standard dirs"
3701 fi
3702 if test -n "${x_libraries}"; then
3703 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3704 else
3705 echo "  Where do we find X Windows libraries?                   Standard dirs"
3706 fi
3707
3708 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3709 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3710 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3711 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3712 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3713 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3714 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3715 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3716
3717 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3718 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3719 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3720 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3721 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3722 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3723 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3724
3725 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3726 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3727 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3728 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3729
3730 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3731 echo
3732
3733 if test $USE_XASSERTS = yes; then
3734    echo "  Compiling with asserts turned on."
3735    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3736 fi
3737
3738 echo
3739
3740 if test "$HAVE_NS" = "yes"; then
3741    echo
3742    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3743 The installed application will go to nextstep/Emacs.app and can be
3744 run or moved from there."
3745    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3746       echo "The application will be fully self-contained."
3747     else
3748       echo "The lisp resources for the application will be installed under ${prefix}.
3749 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3750 to run if these resources are not installed."
3751    fi
3752    echo
3753 fi
3754
3755
3756 # Remove any trailing slashes in these variables.
3757 [test "${prefix}" != NONE &&
3758   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3759 test "${exec_prefix}" != NONE &&
3760   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3761
3762 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3763 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3764 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3765 dnl (else you get "no `Makefile.am' found for any configure output").
3766 dnl This will work, but you get a config.status that is not quite right
3767 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3768 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3769 dnl it seems better to just live with the duplication.
3770 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3771
3772 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3773        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3774        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3775        leim/Makefile])
3776
3777 dnl test/ is not present in release tarfiles.
3778 opt_makefile=test/automated/Makefile
3779
3780 if test -f $srcdir/${opt_makefile}.in; then
3781   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3782   dnl Again, it's best not to use a variable.  Though you can add
3783   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3784   AC_CONFIG_FILES([test/automated/Makefile])
3785 fi
3786
3787 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3788
3789 AC_SUBST(SUBDIR_MAKEFILES_IN)
3790
3791 dnl Make the necessary directories, if they don't exist.
3792 AC_CONFIG_COMMANDS([mkdirs], [
3793 for dir in etc lisp ; do
3794   test -d ${dir} || mkdir ${dir}
3795 done
3796 ])
3797
3798 dnl You might wonder (I did) why epaths.h is generated by running make,
3799 dnl rather than just letting configure generate it from epaths.in.
3800 dnl One reason is that the various paths are not fully expanded (see above);
3801 dnl eg gamedir=${prefix}/var/games/emacs.
3802 dnl Secondly, the GNU Coding standards require that one should be able
3803 dnl to run `make prefix=/some/where/else' and override the values set
3804 dnl by configure.  This also explains the `move-if-change' test and
3805 dnl the use of force in the `epaths-force' rule in Makefile.in.
3806 AC_CONFIG_COMMANDS([epaths], [
3807 echo creating src/epaths.h
3808 ${MAKE-make} epaths-force
3809 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3810
3811 AC_CONFIG_COMMANDS([gdbinit], [
3812 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3813   echo creating src/.gdbinit
3814   echo source $srcdir/src/.gdbinit > src/.gdbinit
3815 fi
3816 ])
3817
3818 AC_OUTPUT
3819
3820 dnl configure.in ends here