lisp/vc/log-view.el

   1 ;;; log-view.el --- Major mode for browsing RCS/CVS/SCCS log output
   2
   3 ;; Copyright (C) 1999-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords: rcs, sccs, cvs, log, vc, tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Major mode to browse revision log histories.
  26 ;; Currently supports the format output by:
  27 ;;  RCS, SCCS, CVS, Subversion, and DaRCS.
  28
  29 ;; Examples of log output:
  30
  31 ;;;; RCS/CVS:
  32
  33 ;; ----------------------------
  34 ;; revision 1.35        locked by: turlutut
  35 ;; date: 2005-03-22 18:48:38 +0000;  author: monnier;  state: Exp;  lines: +6 -8
  36 ;; (gnus-display-time-event-handler):
  37 ;; Check display-time-timer at runtime rather than only at load time
  38 ;; in case display-time-mode is turned off in the mean time.
  39 ;; ----------------------------
  40 ;; revision 1.34
  41 ;; date: 2005-02-09 15:50:38 +0000;  author: kfstorm;  state: Exp;  lines: +7 -7
  42 ;; branches:  1.34.2;
  43 ;; Change release version from 21.4 to 22.1 throughout.
  44 ;; Change development version from 21.3.50 to 22.0.50.
  45
  46 ;;;; SCCS:
  47
  48 ;;;; Subversion:
  49
  50 ;; ------------------------------------------------------------------------
  51 ;; r4622 | ckuethe | 2007-12-23 18:18:01 -0500 (Sun, 23 Dec 2007) | 2 lines
  52 ;;
  53 ;; uBlox AEK-4T in binary mode. Added to unstable because it breaks gpsfake
  54 ;;
  55 ;; ------------------------------------------------------------------------
  56 ;; r4621 | ckuethe | 2007-12-23 16:48:11 -0500 (Sun, 23 Dec 2007) | 3 lines
  57 ;;
  58 ;; Add a note about requiring usbfs to use the garmin gps18 (usb)
  59 ;; Mention firmware testing the AC12 with firmware BQ00 and BQ04
  60 ;;
  61 ;; ------------------------------------------------------------------------
  62 ;; r4620 | ckuethe | 2007-12-23 15:52:34 -0500 (Sun, 23 Dec 2007) | 1 line
  63 ;;
  64 ;; add link to latest hardware reference
  65 ;; ------------------------------------------------------------------------
  66 ;; r4619 | ckuethe | 2007-12-23 14:37:31 -0500 (Sun, 23 Dec 2007) | 1 line
  67 ;;
  68 ;; there is now a regression test for AC12 without raw data output
  69
  70 ;;;; Darcs:
  71
  72 ;; Changes to darcsum.el:
  73 ;;
  74 ;; Mon Nov 28 15:19:38 GMT 2005  Dave Love <fx@gnu.org>
  75 ;;   * Abstract process startup into darcsum-start-process.  Use TERM=dumb.
  76 ;;   TERM=dumb avoids escape characters, at least, for any old darcs that
  77 ;;   doesn't understand DARCS_DONT_COLOR & al.
  78 ;;
  79 ;; Thu Nov 24 15:20:45 GMT 2005  Dave Love <fx@gnu.org>
  80 ;;   * darcsum-mode-related changes.
  81 ;;   Don't call font-lock-mode (unnecessary) or use-local-map (redundant).
  82 ;;   Use mode-class 'special.  Add :group.
  83 ;;   Add trailing-whitespace option to mode hook and fix
  84 ;;   darcsum-display-changeset not to use trailing whitespace.
  85
  86 ;;;; Mercurial
  87
  88 ;; changeset:   11:8ff1a4166444
  89 ;; tag:         tip
  90 ;; user:        Eric S. Raymond <esr@thyrsus.com>
  91 ;; date:        Wed Dec 26 12:18:58 2007 -0500
  92 ;; summary:     Explain keywords.  Add markup fixes.
  93 ;;
  94 ;; changeset:   10:20abc7ab09c3
  95 ;; user:        Eric S. Raymond <esr@thyrsus.com>
  96 ;; date:        Wed Dec 26 11:37:28 2007 -0500
  97 ;; summary:     Typo fixes.
  98 ;;
  99 ;; changeset:   9:ada9f4da88aa
 100 ;; user:        Eric S. Raymond <esr@thyrsus.com>
 101 ;; date:        Wed Dec 26 11:23:00 2007 -0500
 102 ;; summary:     Add RCS example session.
 103
 104 ;;; Todo:
 105
 106 ;; - add ability to modify a log-entry (via cvs-mode-admin ;-)
 107 ;; - remove references to cvs-*
 108 ;; - make it easier to add support for new backends without changing the code.
 109
 110 ;;; Code:
 111
 112 (eval-when-compile (require 'cl))
 113 (require 'pcvs-util)
 114 (autoload 'vc-find-revision "vc")
 115 (autoload 'vc-diff-internal "vc")
 116
 117 (defvar cvs-minor-wrap-function)
 118
 119 (defgroup log-view nil
 120   "Major mode for browsing log output of RCS/CVS/SCCS."
 121   :group 'pcl-cvs
 122   :prefix "log-view-")
 123
 124 (easy-mmode-defmap log-view-mode-map
 125   '(
 126     ;; FIXME: (copy-keymap special-mode-map) instead
 127     ("z" . kill-this-buffer)
 128     ("q" . quit-window)
 129     ("g" . revert-buffer)
 130     ("\C-m" . log-view-toggle-entry-display)
 131
 132     ("m" . log-view-toggle-mark-entry)
 133     ("e" . log-view-modify-change-comment)
 134     ("d" . log-view-diff)
 135     ("=" . log-view-diff)
 136     ("D" . log-view-diff-changeset)
 137     ("a" . log-view-annotate-version)
 138     ("f" . log-view-find-revision)
 139     ("n" . log-view-msg-next)
 140     ("p" . log-view-msg-prev)
 141     ("\t" . log-view-msg-next)
 142     ([backtab] . log-view-msg-prev)
 143     ("N" . log-view-file-next)
 144     ("P" . log-view-file-prev)
 145     ("\M-n" . log-view-file-next)
 146     ("\M-p" . log-view-file-prev))
 147   "Log-View's keymap."
 148   :group 'log-view)
 149
 150 (easy-menu-define log-view-mode-menu log-view-mode-map
 151   "Log-View Display Menu"
 152   `("Log-View"
 153     ;; XXX Do we need menu entries for these?
 154     ;; ["Quit"  quit-window]
 155     ;; ["Kill This Buffer"  kill-this-buffer]
 156     ["Mark Log Entry for Diff"  set-mark-command
 157      :help ""]
 158     ["Diff Revisions"  log-view-diff
 159      :help "Get the diff between two revisions"]
 160     ["Changeset Diff"  log-view-diff-changeset
 161      :help "Get the changeset diff between two revisions"]
 162     ["Visit Version"  log-view-find-revision
 163      :help "Visit the version at point"]
 164     ["Annotate Version"  log-view-annotate-version
 165      :help "Annotate the version at point"]
 166     ["Modify Log Comment" log-view-modify-change-comment
 167      :help "Edit the change comment displayed at point"]
 168     ["Toggle Details at Point" log-view-toggle-entry-display
 169      :active log-view-expanded-log-entry-function]
 170     "-----"
 171     ["Next Log Entry"  log-view-msg-next
 172      :help "Go to the next count'th log message"]
 173     ["Previous Log Entry"  log-view-msg-prev
 174      :help "Go to the previous count'th log message"]
 175     ["Next File"  log-view-file-next
 176      :help "Go to the next count'th file"]
 177     ["Previous File"  log-view-file-prev
 178      :help "Go to the previous count'th file"]))
 179
 180 (defvar log-view-mode-hook nil
 181   "Hook run at the end of `log-view-mode'.")
 182
 183 (defvar log-view-expanded-log-entry-function nil
 184   "Function returning the detailed description of a Log View entry.
 185 It is called by the command `log-view-toggle-entry-display' with
 186 one arg, the revision tag (a string), and should return a string.
 187 If it is nil, `log-view-toggle-entry-display' does nothing.")
 188
 189 (defface log-view-file
 190   '((((class color) (background light))
 191      (:background "grey70" :weight bold))
 192     (t (:weight bold)))
 193   "Face for the file header line in `log-view-mode'."
 194   :group 'log-view)
 195 (define-obsolete-face-alias 'log-view-file-face 'log-view-file "22.1")
 196 (defvar log-view-file-face 'log-view-file)
 197
 198 (defface log-view-message
 199   '((((class color) (background light))
 200      (:background "grey85"))
 201     (t (:weight bold)))
 202   "Face for the message header line in `log-view-mode'."
 203   :group 'log-view)
 204 ;; backward-compatibility alias
 205 (define-obsolete-face-alias 'log-view-message-face 'log-view-message "22.1")
 206 (defvar log-view-message-face 'log-view-message)
 207
 208 (defvar log-view-file-re
 209   (concat "^\\(?:Working file: \\(?1:.+\\)"                ;RCS and CVS.
 210           ;; Subversion has no such thing??
 211           "\\|\\(?:SCCS/s\\.\\|Changes to \\)\\(?1:.+\\):" ;SCCS and Darcs.
 212           "\\)\n")                    ;Include the \n for font-lock reasons.
 213   "Regexp matching the text identifying the file.
 214 The match group number 1 should match the file name itself.")
 215
 216 (defvar log-view-per-file-logs t
 217   "Set if to t if the logs are shown one file at a time.")
 218
 219 (defvar log-view-message-re
 220   (concat "^\\(?:revision \\(?1:[.0-9]+\\)\\(?:\t.*\\)?" ; RCS and CVS.
 221           "\\|r\\(?1:[0-9]+\\) | .* | .*"                ; Subversion.
 222           "\\|D \\(?1:[.0-9]+\\) .*"                     ; SCCS.
 223           ;; Darcs doesn't have revision names.  VC-darcs uses patch names
 224           ;; instead.  Darcs patch names are hashcodes, which do not appear
 225           ;; in the log output :-(, but darcs accepts any prefix of the log
 226           ;; message as a patch name, so we match the first line of the log
 227           ;; message.
 228           ;; First loosely match the date format.
 229           (concat "\\|[^ \n].*[^0-9\n][0-9][0-9]:[0-9][0-9][^0-9\n].*[^ \n]"
 230                   ;;Email of user and finally Msg, used as revision name.
 231                   "  .*@.*\n\\(?:  \\* \\(?1:.*\\)\\)?")
 232           "\\)$")
 233   "Regexp matching the text identifying a revision.
 234 The match group number 1 should match the revision number itself.")
 235
 236 (defvar log-view-font-lock-keywords
 237   ;; We use `eval' so as to use the buffer-local value of log-view-file-re
 238   ;; and log-view-message-re, if applicable.
 239   '((eval . `(,log-view-file-re
 240               (1 (if (boundp 'cvs-filename-face) cvs-filename-face))
 241               (0 log-view-file-face append)))
 242     (eval . `(,log-view-message-re . log-view-message-face))))
 243
 244 (defconst log-view-font-lock-defaults
 245   '(log-view-font-lock-keywords t nil nil nil))
 246
 247 (defvar log-view-vc-fileset nil
 248   "Set this to the fileset corresponding to the current log.")
 249
 250 (defvar log-view-vc-backend nil
 251   "Set this to the VC backend that created the current log.")
 252
 253 ;;;;
 254 ;;;; Actual code
 255 ;;;;
 256
 257 ;;;###autoload
 258 (define-derived-mode log-view-mode special-mode "Log-View"
 259   "Major mode for browsing CVS log output."
 260   (setq buffer-read-only t)
 261   (set (make-local-variable 'font-lock-defaults) log-view-font-lock-defaults)
 262   (set (make-local-variable 'beginning-of-defun-function)
 263        'log-view-beginning-of-defun)
 264   (set (make-local-variable 'end-of-defun-function)
 265        'log-view-end-of-defun)
 266   (set (make-local-variable 'cvs-minor-wrap-function) 'log-view-minor-wrap)
 267   (hack-dir-local-variables-non-file-buffer))
 268
 269 ;;;;
 270 ;;;; Navigation
 271 ;;;;
 272
 273 ;; define log-view-{msg,file}-{next,prev}
 274 (easy-mmode-define-navigation log-view-msg log-view-message-re "log message")
 275 (easy-mmode-define-navigation log-view-file log-view-file-re "file")
 276
 277 (defun log-view-goto-rev (rev)
 278   (goto-char (point-min))
 279   (ignore-errors
 280     (while (not (equal rev (log-view-current-tag)))
 281       (log-view-msg-next))
 282     t))
 283
 284 ;;;;
 285 ;;;; Linkage to PCL-CVS (mostly copied from cvs-status.el)
 286 ;;;;
 287
 288 (defconst log-view-dir-re "^cvs[.ex]* [a-z]+: Logging \\(.+\\)$")
 289
 290 (defun log-view-current-file ()
 291   (save-excursion
 292     (forward-line 1)
 293     (or (re-search-backward log-view-file-re nil t)
 294         (re-search-forward log-view-file-re nil t)
 295         (error "Unable to determine the current file"))
 296     (let* ((file (match-string 1))
 297            (cvsdir (and (re-search-backward log-view-dir-re nil t)
 298                         (match-string 1)))
 299            (pcldir (and (boundp 'cvs-pcl-cvs-dirchange-re)
 300                         (re-search-backward cvs-pcl-cvs-dirchange-re nil t)
 301                         (match-string 1)))
 302            (dir ""))
 303       (let ((default-directory ""))
 304         (when pcldir (setq dir (expand-file-name pcldir dir)))
 305         (when cvsdir (setq dir (expand-file-name cvsdir dir))))
 306       (expand-file-name file dir))))
 307
 308 (defun log-view-current-entry (&optional pos move)
 309   "Return the position and revision tag of the Log View entry at POS.
 310 This is a list (BEG TAG), where BEG is a buffer position and TAG
 311 is a string.  If POS is nil or omitted, it defaults to point.
 312 If there is no entry at POS, return nil.
 313
 314 If optional arg MOVE is non-nil, move point to BEG if found.
 315 Otherwise, don't move point."
 316   (let ((looping t)
 317         result)
 318     (save-excursion
 319       (when pos (goto-char pos))
 320       (forward-line 1)
 321       (while looping
 322         (setq pos (re-search-backward log-view-message-re nil 'move)
 323               looping (and pos (log-view-inside-comment-p (point)))))
 324       (when pos
 325         (setq result
 326               (list pos (match-string-no-properties 1)))))
 327     (and move result (goto-char pos))
 328     result))
 329
 330 (defun log-view-inside-comment-p (pos)
 331   "Return non-nil if POS lies inside an expanded log entry."
 332   (eq (get-text-property pos 'log-view-comment) t))
 333
 334 (defun log-view-current-tag (&optional pos)
 335   "Return the revision tag (a string) of the Log View entry at POS.
 336 if POS is omitted or nil, it defaults to point."
 337   (cadr (log-view-current-entry pos)))
 338
 339 (defun log-view-toggle-mark-entry ()
 340   "Toggle the marked state for the log entry at point.
 341 Individual log entries can be marked and unmarked. The marked
 342 entries are denoted by changing their background color.
 343 `log-view-get-marked' returns the list of tags for the marked
 344 log entries."
 345   (interactive)
 346   (save-excursion
 347     (let* ((entry (log-view-current-entry nil t))
 348            (beg (car entry))
 349            found)
 350       (when entry
 351         ;; Look to see if the current entry is marked.
 352         (setq found (get-char-property beg 'log-view-self))
 353         (if found
 354             (delete-overlay found)
 355           ;; Create an overlay covering this entry and change its color.
 356           (let* ((end (if (get-text-property beg 'log-view-entry-expanded)
 357                           (next-single-property-change beg 'log-view-comment)
 358                         (log-view-end-of-defun)
 359                         (point)))
 360                  (ov (make-overlay beg end)))
 361             (overlay-put ov 'face 'log-view-file)
 362             ;; This is used to check if the overlay is present.
 363             (overlay-put ov 'log-view-self ov)
 364             (overlay-put ov 'log-view-marked (nth 1 entry))))))))
 365
 366 (defun log-view-get-marked ()
 367   "Return the list of tags for the marked log entries."
 368   (save-excursion
 369     (let ((pos (point-min))
 370           marked-list ov)
 371       (while (setq pos (next-single-property-change pos 'face))
 372         (when (setq ov (get-char-property pos 'log-view-self))
 373           (push (overlay-get ov 'log-view-marked) marked-list)
 374           (setq pos (overlay-end ov))))
 375       marked-list)))
 376
 377 (defun log-view-toggle-entry-display ()
 378   (interactive)
 379   ;; Don't do anything unless `log-view-expanded-log-entry-function'
 380   ;; is defined in this mode.
 381   (when (functionp log-view-expanded-log-entry-function)
 382     (let* ((opoint (point))
 383            (entry (log-view-current-entry nil t))
 384            (beg (car entry))
 385            (buffer-read-only nil))
 386       (when entry
 387         (if (get-text-property beg 'log-view-entry-expanded)
 388             ;; If the entry is expanded, collapse it.
 389             (let ((pos (next-single-property-change beg 'log-view-comment)))
 390               (unless (and pos (log-view-inside-comment-p pos))
 391                 (error "Broken markup in `log-view-toggle-entry-display'"))
 392               (delete-region pos
 393                              (next-single-property-change pos 'log-view-comment))
 394               (put-text-property beg (1+ beg) 'log-view-entry-expanded nil)
 395               (if (< opoint pos)
 396                   (goto-char opoint)))
 397           ;; Otherwise, expand the entry.
 398           (let ((long-entry (funcall log-view-expanded-log-entry-function
 399                                      (nth 1 entry))))
 400             (when long-entry
 401               (put-text-property beg (1+ beg) 'log-view-entry-expanded t)
 402               (log-view-end-of-defun)
 403               (setq beg (point))
 404               (insert long-entry "\n")
 405               (add-text-properties
 406                beg (point)
 407                '(font-lock-face font-lock-comment-face log-view-comment t))
 408               (goto-char opoint))))))))
 409
 410 (defun log-view-beginning-of-defun (&optional arg)
 411   "Move backward to the beginning of a Log View entry.
 412 With ARG, do it that many times.  Negative ARG means move forward
 413 to the beginning of the ARGth following entry.
 414
 415 This is Log View mode's default `beginning-of-defun-function'.
 416 It assumes that a log entry starts with a line matching
 417 `log-view-message-re'."
 418   (if (or (null arg) (zerop arg))
 419       (setq arg 1))
 420   (if (< arg 0)
 421       (dotimes (n (- arg))
 422         (log-view-end-of-defun))
 423     (catch 'beginning-of-buffer
 424       (dotimes (n arg)
 425         (or (log-view-current-entry nil t)
 426             (throw 'beginning-of-buffer nil)))
 427       (point))))
 428
 429 (defun log-view-end-of-defun ()
 430   "Move forward to the next Log View entry."
 431   (let ((looping t))
 432     (if (looking-at log-view-message-re)
 433         (goto-char (match-end 0)))
 434     (while looping
 435       (cond
 436        ((re-search-forward log-view-message-re nil 'move)
 437         (unless (log-view-inside-comment-p (point))
 438           (setq looping nil)
 439           (goto-char (match-beginning 0))))
 440        ;; Don't advance past the end buttons inserted by
 441        ;; `vc-print-log-setup-buttons'.
 442        ((looking-back "Show 2X entries    Show unlimited entries")
 443         (setq looping nil)
 444         (forward-line -1))))))
 445
 446 (defvar cvs-minor-current-files)
 447 (defvar cvs-branch-prefix)
 448 (defvar cvs-secondary-branch-prefix)
 449
 450 (defun log-view-minor-wrap (buf f)
 451   (let ((data (with-current-buffer buf
 452                 (let* ((beg (point))
 453                        (end (if mark-active (mark) (point)))
 454                        (fr (log-view-current-tag beg))
 455                        (to (log-view-current-tag end)))
 456                   (when (string-equal fr to)
 457                     (save-excursion
 458                       (goto-char end)
 459                       (log-view-msg-next)
 460                       (setq to (log-view-current-tag))))
 461                   (cons
 462                    ;; The first revision has to be the one at point, for
 463                    ;; operations that only take one revision
 464                    ;; (e.g. cvs-mode-edit).
 465                    (cons (log-view-current-file) fr)
 466                    (cons (log-view-current-file) to))))))
 467     (let ((cvs-branch-prefix (cdar data))
 468           (cvs-secondary-branch-prefix (and (cdar data) (cddr data)))
 469           (cvs-minor-current-files
 470            (cons (caar data)
 471                  (when (and (cadr data) (not (equal (caar data) (cadr data))))
 472                    (list (cadr data)))))
 473           ;; FIXME:  I need to force because the fileinfos are UNKNOWN
 474           (cvs-force-command "/F"))
 475       (funcall f))))
 476
 477 (defun log-view-find-revision (pos)
 478   "Visit the version at point."
 479   (interactive "d")
 480   (unless log-view-per-file-logs
 481     (when (> (length log-view-vc-fileset) 1)
 482       (error "Multiple files shown in this buffer, cannot use this command here")))
 483   (save-excursion
 484     (goto-char pos)
 485     (switch-to-buffer (vc-find-revision (if log-view-per-file-logs
 486                                             (log-view-current-file)
 487                                           (car log-view-vc-fileset))
 488                                         (log-view-current-tag)))))
 489
 490
 491 (defun log-view-extract-comment ()
 492   "Parse comment from around the current point in the log."
 493   (save-excursion
 494     (let (st en (backend (vc-backend (log-view-current-file))))
 495       (log-view-end-of-defun)
 496       (cond ((eq backend 'SVN)
 497              (forward-line -1)))
 498       (setq en (point))
 499       (log-view-beginning-of-defun)
 500       (cond ((memq backend '(SCCS RCS CVS MCVS SVN))
 501              (forward-line 2))
 502             ((eq backend 'Hg)
 503              (forward-line 4)
 504              (re-search-forward "summary: *" nil t)))
 505       (setq st (point))
 506       (buffer-substring st en))))
 507
 508 (declare-function vc-modify-change-comment "vc" (files rev oldcomment))
 509
 510 (defun log-view-modify-change-comment ()
 511   "Edit the change comment displayed at point."
 512   (interactive)
 513   (vc-modify-change-comment (list (if log-view-per-file-logs
 514                                       (log-view-current-file)
 515                                     (car log-view-vc-fileset)))
 516                             (log-view-current-tag)
 517                             (log-view-extract-comment)))
 518
 519 (defun log-view-annotate-version (pos)
 520   "Annotate the version at point."
 521   (interactive "d")
 522   (unless log-view-per-file-logs
 523     (when (> (length log-view-vc-fileset) 1)
 524       (error "Multiple files shown in this buffer, cannot use this command here")))
 525   (save-excursion
 526     (goto-char pos)
 527     (vc-annotate (if log-view-per-file-logs
 528                      (log-view-current-file)
 529                    (car log-view-vc-fileset))
 530                  (log-view-current-tag))))
 531
 532 ;;
 533 ;; diff
 534 ;;
 535
 536 (defun log-view-diff (beg end)
 537   "Get the diff between two revisions.
 538 If the mark is not active or the mark is on the revision at point,
 539 get the diff between the revision at point and its previous revision.
 540 Otherwise, get the diff between the revisions where the region starts
 541 and ends.
 542 Contrary to `log-view-diff-changeset', it will only show the part of the
 543 changeset that affected the currently considered file(s)."
 544   (interactive
 545    (list (if mark-active (region-beginning) (point))
 546          (if mark-active (region-end) (point))))
 547   (let ((fr (log-view-current-tag beg))
 548         (to (log-view-current-tag end)))
 549     (when (string-equal fr to)
 550       (save-excursion
 551         (goto-char end)
 552         (log-view-msg-next)
 553         (setq to (log-view-current-tag))))
 554     (vc-diff-internal
 555      t (list log-view-vc-backend
 556              (if log-view-per-file-logs
 557                  (list (log-view-current-file))
 558                log-view-vc-fileset))
 559      to fr)))
 560
 561 (declare-function vc-diff-internal "vc"
 562                   (async vc-fileset rev1 rev2 &optional verbose))
 563
 564 (defun log-view-diff-changeset (beg end)
 565   "Get the diff between two revisions.
 566 If the mark is not active or the mark is on the revision at point,
 567 get the diff between the revision at point and its previous revision.
 568 Otherwise, get the diff between the revisions where the region starts
 569 and ends.
 570 Contrary to `log-view-diff', it will show the whole changeset including
 571 the changes that affected other files than the currently considered file(s)."
 572   (interactive
 573    (list (if mark-active (region-beginning) (point))
 574          (if mark-active (region-end) (point))))
 575   (when (eq (vc-call-backend log-view-vc-backend 'revision-granularity) 'file)
 576     (error "The %s backend does not support changeset diffs" log-view-vc-backend))
 577   (let ((fr (log-view-current-tag beg))
 578         (to (log-view-current-tag end)))
 579     (when (string-equal fr to)
 580       ;; TO and FR are the same, look at the previous revision.
 581       (setq to (vc-call-backend log-view-vc-backend 'previous-revision nil fr)))
 582     (vc-diff-internal
 583      t
 584      ;; We want to see the diff for all the files in the changeset, so
 585      ;; pass NIL for the file list.  The value passed here should
 586      ;; follow what `vc-deduce-fileset' returns.
 587      (list log-view-vc-backend nil)
 588      to fr)))
 589
 590 (provide 'log-view)
 591
 592 ;;; log-view.el ends here