lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process.
   2
   3 ;; Copyright (C) 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   6 ;; Keywords: processes
   7
   8 ;; Changes by peck@sun.com and by rms.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; This Lisp code is run in Emacs when it is to operate as
  29 ;;; a server for other processes.
  30
  31 ;;; Load this library and do M-x server-edit to enable Emacs as a server.
  32 ;;; Emacs runs the program ../arch-lib/emacsserver as a subprocess
  33 ;;; for communication with clients.  If there are no client buffers to edit,
  34 ;;; server-edit acts like (switch-to-buffer (other-buffer))
  35
  36 ;;; When some other program runs "the editor" to edit a file,
  37 ;;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  38 ;;; This program transmits the file names to Emacs through
  39 ;;; the server subprocess, and Emacs visits them and lets you edit them.
  40
  41 ;;; Note that any number of clients may dispatch files to emacs to be edited.
  42
  43 ;;; When you finish editing a Server buffer, again call server-edit
  44 ;;; to mark that buffer as done for the client and switch to the next
  45 ;;; Server buffer.  When all the buffers for a client have been edited
  46 ;;; and exited with server-edit, the client "editor" will return
  47 ;;; to the program that invoked it.
  48
  49 ;;; Your editing commands and Emacs's display output go to and from
  50 ;;; the terminal in the usual way.  Thus, server operation is possible
  51 ;;; only when Emacs can talk to the terminal at the time you invoke
  52 ;;; the client.  This is possible in four cases:
  53
  54 ;;; 1. On a window system, where Emacs runs in one window and the
  55 ;;; program that wants to use "the editor" runs in another.
  56
  57 ;;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  58 ;;; program that wants to use "the editor" runs on another.
  59
  60 ;;; 3. When the program that wants to use "the editor" is running
  61 ;;; as a subprocess of Emacs.
  62
  63 ;;; 4. On a system with job control, when Emacs is suspended, the program
  64 ;;; that wants to use "the editor" will stop and display
  65 ;;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  66 ;;; brought into the foreground for editing.  When done editing, Emacs is
  67 ;;; suspended again, and the client program is brought into the foreground.
  68
  69 ;;; The buffer local variable "server-buffer-clients" lists
  70 ;;; the clients who are waiting for this buffer to be edited.
  71 ;;; The global variable "server-clients" lists all the waiting clients,
  72 ;;; and which files are yet to be edited for each.
  73
  74 ;;; Code:
  75 \f
  76 (defvar server-program "emacsserver"
  77   "*The program to use as the edit server")
  78
  79 (defvar server-visit-hook nil
  80   "*List of hooks to call when visiting a file for the Emacs server.")
  81
  82 (defvar server-switch-hook nil
  83   "*List of hooks to call when switching to a buffer for the Emacs server.")
  84
  85 (defvar server-process nil
  86   "the current server process")
  87
  88 (defvar server-previous-string "")
  89
  90 (defvar server-clients nil
  91   "List of current server clients.
  92 Each element is (CLIENTID FILES...) where CLIENTID is a string
  93 that can be given to the server process to identify a client.
  94 When a buffer is marked as \"done\", it is removed from this list.")
  95
  96 (defvar server-buffer-clients nil
  97   "List of clientids for clients requesting editing of current buffer.")
  98 ;; Changing major modes should not erase this local.
  99 (put 'server-buffer-clients 'permanent-local t)
 100
 101 (defvar server-temp-file-regexp "^/tmp/Re\\|/draft$"
 102   "*Regexp which should match filenames of temporary files
 103 which are deleted and reused after each edit
 104 by the programs that invoke the emacs server.")
 105
 106 (make-variable-buffer-local 'server-buffer-clients)
 107 (put 'server-buffer-clients 'permanent-local t)
 108 (setq-default server-buffer-clients nil)
 109 (or (assq 'server-buffer-clients minor-mode-alist)
 110     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
 111
 112 ;; If a *server* buffer exists,
 113 ;; write STRING to it for logging purposes.
 114 (defun server-log (string)
 115   (if (get-buffer "*server*")
 116       (save-excursion
 117         (set-buffer "*server*")
 118         (goto-char (point-max))
 119         (insert string)
 120         (or (bobp) (newline)))))
 121
 122 (defun server-sentinel (proc msg)
 123   (cond ((eq (process-status proc) 'exit)
 124          (server-log (message "Server subprocess exited")))
 125         ((eq (process-status proc) 'signal)
 126          (server-log (message "Server subprocess killed")))))
 127
 128 ;;;###autoload
 129 (defun server-start (&optional leave-dead)
 130   "Allow this Emacs process to be a server for client processes.
 131 This starts a server communications subprocess through which
 132 client \"editors\" can send your editing commands to this Emacs job.
 133 To use the server, set up the program `etc/emacsclient' in the
 134 Emacs distribution as your standard \"editor\".
 135
 136 Prefix arg means just kill any existing server communications subprocess."
 137   (interactive "P")
 138   ;; kill it dead!
 139   (if server-process
 140       (progn
 141         (set-process-sentinel server-process nil)
 142         (condition-case () (delete-process server-process) (error nil))))
 143   (condition-case () (delete-file "~/.emacs_server") (error nil))
 144   ;; If we already had a server, clear out associated status.
 145   (while server-clients
 146     (let ((buffer (nth 1 (car server-clients))))
 147       (server-buffer-done buffer)))
 148   (if leave-dead
 149       nil
 150     (if server-process
 151         (server-log (message "Restarting server")))
 152     (setq server-process (start-process "server" nil server-program))
 153     (set-process-sentinel server-process 'server-sentinel)
 154     (set-process-filter server-process 'server-process-filter)
 155     (process-kill-without-query server-process)))
 156 \f
 157 ;Process a request from the server to edit some files.
 158 ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n"
 159 (defun server-process-filter (proc string)
 160   (server-log string)
 161   (setq string (concat server-previous-string string))
 162   (if (not (and (eq ?\n (aref string (1- (length string))))
 163                 (eq 0 (string-match "Client: " string))))
 164       ;; If input is not complete, save it for later.
 165       (setq server-previous-string string)
 166     ;; If it is complete, process it now, and discard what was saved.
 167     (setq string (substring string (match-end 0)))
 168     (setq server-previous-string "")
 169     (let ((client (list (substring string 0 (string-match " " string))))
 170           (files nil)
 171           (lineno 1))
 172       (setq string (substring string (match-end 0)))
 173       (while (string-match "[^ ]+ " string)
 174         (let ((arg
 175                (substring string (match-beginning 0) (1- (match-end 0)))))
 176           (setq string (substring string (match-end 0)))
 177           (if (string-match "\\`\\+[0-9]+\\'" arg)
 178               (setq lineno (read (substring arg 1)))
 179             (setq files
 180                   (cons (list arg lineno)
 181                         files))
 182             (setq lineno 1))))
 183       (server-visit-files files client)
 184       ;; CLIENT is now a list (CLIENTNUM BUFFERS...)
 185       (setq server-clients (cons client server-clients))
 186       (switch-to-buffer (nth 1 client))
 187       (run-hooks 'server-switch-hook)
 188       (message (substitute-command-keys
 189                 "When done with a buffer, type \\[server-edit].")))))
 190
 191 (defun server-visit-files (files client)
 192   "Finds FILES and returns the list CLIENT with the buffers nconc'd.
 193 FILES is an alist whose elements are (FILENAME LINENUMBER)."
 194   (let (client-record)
 195     (while files
 196       (save-excursion
 197         ;; If there is an existing buffer modified or the file is modified,
 198         ;; revert it.
 199         ;; If there is an existing buffer with deleted file, offer to write it.
 200         (let* ((filen (car (car files)))
 201                (obuf (get-file-buffer filen)))
 202           (if (and obuf (set-buffer obuf))
 203               (if (file-exists-p filen)
 204                   (if (or (not (verify-visited-file-modtime obuf))
 205                           (buffer-modified-p obuf))
 206                       (revert-buffer t nil))
 207                 (if (y-or-n-p
 208                      (concat "File no longer exists: "
 209                              filen
 210                              ", write buffer to file? "))
 211                     (write-file filen)))
 212             (set-buffer (find-file-noselect filen))
 213             (run-hooks 'server-visit-hook)))
 214         (goto-line (nth 1 (car files)))
 215         (setq server-buffer-clients (cons (car client) server-buffer-clients))
 216         (setq client-record (cons (current-buffer) client-record)))
 217         (setq files (cdr files)))
 218     (nconc client client-record)))
 219 \f
 220 (defun server-buffer-done (buffer)
 221   "Mark BUFFER as \"done\" for its client(s).
 222 Buries the buffer, and returns another server buffer
 223 as a suggestion for what to select next."
 224   (let ((running (eq (process-status server-process) 'run))
 225         (next-buffer nil)
 226         (old-clients server-clients))
 227     (while old-clients
 228       (let ((client (car old-clients)))
 229         (or next-buffer
 230             (setq next-buffer (nth 1 (memq buffer client))))
 231         (delq buffer client)
 232         ;; If client now has no pending buffers,
 233         ;; tell it that it is done, and forget it entirely.
 234         (if (cdr client) nil
 235           (if running
 236               (progn
 237                 (send-string server-process
 238                              (format "Close: %s Done\n" (car client)))
 239                 (server-log (format "Close: %s Done\n" (car client)))))
 240           (setq server-clients (delq client server-clients))))
 241       (setq old-clients (cdr old-clients)))
 242     (if (buffer-name buffer)
 243         (save-excursion
 244           (set-buffer buffer)
 245           (setq server-buffer-clients nil)))
 246     (bury-buffer buffer)
 247     next-buffer))
 248
 249 (defun server-temp-file-p (buffer)
 250   "Return non-nil if BUFFER contains a file considered temporary.
 251 These are files whose names suggest they are repeatedly
 252 reused to pass information to another program.
 253
 254 The variable `server-temp-file-regexp' controls which filenames
 255 are considered temporary."
 256   (and (buffer-file-name buffer)
 257        (string-match server-temp-file-regexp (buffer-file-name buffer))))
 258
 259 (defun server-done ()
 260   "Offer to save current buffer, mark it as \"done\" for clients.
 261 Then bury it, and return a suggested buffer to select next."
 262   (let ((buffer (current-buffer)))
 263     (if server-buffer-clients
 264         (progn
 265           (if (server-temp-file-p buffer)
 266               (progn (save-buffer)
 267                      (write-region (point-min) (point-max)
 268                                    (concat buffer-file-name "~"))
 269                      (kill-buffer buffer))
 270             (if (and (buffer-modified-p)
 271                      (y-or-n-p (concat "Save file " buffer-file-name "? ")))
 272                 (save-buffer buffer)))
 273           (server-buffer-done buffer)))))
 274 \f
 275 (defun server-edit (&optional arg)
 276   "Switch to next server editing buffer; say \"Done\" for current buffer.
 277 If a server buffer is current, it is marked \"done\" and optionally saved.
 278 When all of a client's buffers are marked as \"done\", the client is notified.
 279
 280 Temporary files such as MH <draft> files are always saved and backed up,
 281 no questions asked.  The variable `server-temp-file-regexp' controls
 282 which filenames are considered temporary.
 283
 284 If invoked with a prefix argument, or if there is no server process running,
 285 starts server process and that is all.  Invoked by \\[server-edit]."
 286
 287   (interactive "P")
 288   (if (or arg
 289           (not server-process)
 290           (memq (process-status server-process) '(signal exit)))
 291       (server-start nil)
 292     (server-switch-buffer (server-done))))
 293
 294 (defun server-switch-buffer (next-buffer)
 295   "Switch to another buffer, preferably one that has a client.
 296 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it."
 297   (if next-buffer
 298       (if (and (bufferp next-buffer)
 299                (buffer-name next-buffer))
 300           (switch-to-buffer next-buffer)
 301         ;; If NEXT-BUFFER is a dead buffer,
 302         ;; remove the server records for it
 303         ;; and try the next surviving server buffer.
 304         (server-switch-buffer
 305          (server-buffer-done next-buffer)))
 306     (if server-clients
 307         (server-switch-buffer (nth 1 (car server-clients)))
 308       (switch-to-buffer (other-buffer)))))
 309
 310 (global-set-key "\C-x#" 'server-edit)
 311 \f
 312 (provide 'server)
 313
 314 ;;; server.el ends here