lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996-1999, 2004-2012  Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 ;; (require 'url)
  27 (require 'url-parse)
  28 ;; (require 'url-util)
  29 (eval-when-compile (require 'mm-decode))
  30 ;; (require 'mailcap)
  31 ;; The following functions in the byte compiler's warnings are known not
  32 ;; to cause any real problem for the following reasons:
  33 ;; - mm-save-part-to-file, mm-destroy-parts: always used
  34 ;;   after mm-dissect-buffer and defined in the same file.
  35 ;; The following are autoloaded instead of `require'd to avoid eagerly
  36 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  37 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  38 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  39 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  40
  41 ;; Implementation status
  42 ;; ---------------------
  43 ;; Function                             Status
  44 ;; ------------------------------------------------------------
  45 ;; add-name-to-file                     Needs DAV Bindings
  46 ;; copy-file                            Broken (assumes 1st item is URL)
  47 ;; delete-directory                     Finished (DAV)
  48 ;; delete-file                          Finished (DAV)
  49 ;; diff-latest-backup-file
  50 ;; directory-file-name                  unnecessary (what about VMS)?
  51 ;; directory-files                      Finished (DAV)
  52 ;; dired-call-process
  53 ;; dired-compress-file
  54 ;; dired-uncache
  55 ;; expand-file-name                     Finished
  56 ;; file-accessible-directory-p
  57 ;; file-attributes                      Finished, better with DAV
  58 ;; file-directory-p                     Needs DAV, finished
  59 ;; file-executable-p                    Finished
  60 ;; file-exists-p                        Finished
  61 ;; file-local-copy
  62 ;; file-modes
  63 ;; file-name-all-completions            Finished (DAV)
  64 ;; file-name-as-directory
  65 ;; file-name-completion                 Finished (DAV)
  66 ;; file-name-directory
  67 ;; file-name-nondirectory
  68 ;; file-name-sans-versions              why?
  69 ;; file-newer-than-file-p
  70 ;; file-ownership-preserved-p           No way to know
  71 ;; file-readable-p                      Finished
  72 ;; file-regular-p                       !directory_p
  73 ;; file-remote-p                        Finished
  74 ;; file-symlink-p                       Needs DAV bindings
  75 ;; file-truename                        Needs DAV bindings
  76 ;; file-writable-p                      Check for LOCK?
  77 ;; find-backup-file-name                why?
  78 ;; get-file-buffer                      why?
  79 ;; insert-directory                     Use DAV
  80 ;; insert-file-contents                 Finished
  81 ;; load
  82 ;; make-directory                       Finished (DAV)
  83 ;; make-symbolic-link                   Needs DAV bindings
  84 ;; rename-file                          Finished (DAV)
  85 ;; set-file-modes                       Use mod_dav specific executable flag?
  86 ;; set-visited-file-modtime             Impossible?
  87 ;; shell-command                        Impossible?
  88 ;; unhandled-file-name-directory
  89 ;; vc-registered                        Finished (DAV)
  90 ;; verify-visited-file-modtime
  91 ;; write-region
  92
  93 (defvar url-handler-regexp) ; defined below to avoid recursive load (revno:108572)
  94
  95 ;;;###autoload
  96 (define-minor-mode url-handler-mode
  97   "Toggle using `url' library for URL filenames (URL Handler mode).
  98 With a prefix argument ARG, enable URL Handler mode if ARG is
  99 positive, and disable it otherwise.  If called from Lisp, enable
 100 the mode if ARG is omitted or nil."
 101   :global t :group 'url
 102   ;; Remove old entry, if any.
 103   (setq file-name-handler-alist
 104         (delq (rassq 'url-file-handler file-name-handler-alist)
 105               file-name-handler-alist))
 106   (if url-handler-mode
 107       (push (cons url-handler-regexp 'url-file-handler)
 108             file-name-handler-alist)))
 109
 110 (defcustom url-handler-regexp "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
 111   "Regular expression for URLs handled by `url-handler-mode'.
 112 When URL Handler mode is enabled, this regular expression is
 113 added to `file-name-handler-alist'.
 114
 115 Some valid URL protocols just do not make sense to visit
 116 interactively \(about, data, info, irc, mailto, etc\).  This
 117 regular expression avoids conflicts with local files that look
 118 like URLs \(Gnus is particularly bad at this\)."
 119   :group 'url
 120   :type 'regexp
 121   :set (lambda (symbol value)
 122          (let ((enable url-handler-mode))
 123            (url-handler-mode 0)
 124            (set-default symbol value)
 125            (if enable
 126                (url-handler-mode)))))
 127
 128 (defun url-run-real-handler (operation args)
 129   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 130                                           (if (eq operation inhibit-file-name-operation)
 131                                               inhibit-file-name-handlers)))
 132         (inhibit-file-name-operation operation))
 133     (apply operation args)))
 134
 135 ;;;###autoload
 136 (defun url-file-handler (operation &rest args)
 137   "Function called from the `file-name-handler-alist' routines.
 138 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 139 the arguments that would have been passed to OPERATION."
 140   (let ((fn (get operation 'url-file-handlers))
 141         (val nil)
 142         (hooked nil))
 143     (if (and (not fn) (intern-soft (format "url-%s" operation))
 144              (fboundp (intern-soft (format "url-%s" operation))))
 145         (error "Missing URL handler mapping for %s" operation))
 146     (if fn
 147         (setq hooked t
 148               val (save-match-data (apply fn args)))
 149       (setq hooked nil
 150             val (url-run-real-handler operation args)))
 151     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 152                operation args val)
 153     val))
 154
 155 (defun url-file-handler-identity (&rest args)
 156   ;; Identity function
 157   (car args))
 158
 159 ;; These are operations that we can fully support
 160 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 161 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 162 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 163 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 164 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 165 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 166 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 167 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 168
 169 ;; These are operations that we do not support yet (DAV!!!)
 170 (put 'file-writable-p 'url-file-handlers 'ignore)
 171 (put 'file-symlink-p 'url-file-handlers 'ignore)
 172 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 173 ;; files and such since we can't do anything clever with them anyway.
 174 (put 'vc-registered 'url-file-handlers 'ignore)
 175
 176 (defun url-handler-expand-file-name (file &optional base)
 177   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 178   ;; there are two interpretations possible: either it's a local "/foo/bar"
 179   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 180   ;; interpretation is the right one, but when working with Emacs file
 181   ;; names, the first is preferred.
 182   (if (file-name-absolute-p file)
 183       (expand-file-name file "/")
 184     (url-expand-file-name file base)))
 185
 186 ;; directory-file-name and file-name-as-directory are kind of hard to
 187 ;; implement really right for URLs since URLs can have repeated / chars.
 188 ;; We'd want the following behavior:
 189 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 190 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 191 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 192 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 193 (defun url-handler-directory-file-name (dir)
 194   ;; When there's more than a single /, just don't touch the slashes at all.
 195   (if (string-match "//\\'" dir) dir
 196     (url-run-real-handler 'directory-file-name (list dir))))
 197
 198 (defun url-handler-unhandled-file-name-directory (filename)
 199   (let ((url (url-generic-parse-url filename)))
 200     (if (equal (url-type url) "file")
 201         ;; `file' URLs are actually local.  The filename part may be ""
 202         ;; which really stands for "/".
 203         ;; FIXME: maybe we should check that the host part is "" or "localhost"
 204         ;; or some name that represents the local host?
 205         (or (file-name-directory (url-filename url)) "/")
 206       ;; All other URLs are not expected to be directly accessible from
 207       ;; a local process.
 208       nil)))
 209
 210 (defun url-handler-file-remote-p (filename &optional identification connected)
 211   (let ((url (url-generic-parse-url filename)))
 212     (if (and (url-type url) (not (equal (url-type url) "file")))
 213         ;; Maybe we can find a suitable check for CONNECTED.  For now,
 214         ;; we ignore it.
 215         (cond
 216          ((eq identification 'method) (url-type url))
 217          ((eq identification 'user) (url-user url))
 218          ((eq identification 'host) (url-host url))
 219          ((eq identification 'localname) (url-filename url))
 220          (t (url-recreate-url
 221              (url-parse-make-urlobj (url-type url) (url-user url) nil
 222                                     (url-host url) (url-port url)))))
 223       ;; If there is no URL type, or it is a "file://" URL, the
 224       ;; filename is expected to be non remote.  A more subtle check
 225       ;; for "file://" URLs could be applied, as said in
 226       ;; `url-handler-unhandled-file-name-directory'.
 227       nil)))
 228
 229 ;; The actual implementation
 230 ;;;###autoload
 231 (defun url-copy-file (url newname &optional ok-if-already-exists
 232                           keep-time preserve-uid-gid)
 233   "Copy URL to NEWNAME.  Both args must be strings.
 234 Signals a `file-already-exists' error if file NEWNAME already exists,
 235 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 236 A number as third arg means request confirmation if NEWNAME already exists.
 237 This is what happens in interactive use with M-x.
 238 Fourth arg KEEP-TIME non-nil means give the new file the same
 239 last-modified time as the old one.  (This works on only some systems.)
 240 Fifth arg PRESERVE-UID-GID is ignored.
 241 A prefix arg makes KEEP-TIME non-nil."
 242   (if (and (file-exists-p newname)
 243            (not ok-if-already-exists))
 244       (error "Opening output file: File already exists, %s" newname))
 245   (let ((buffer (url-retrieve-synchronously url))
 246         (handle nil))
 247     (if (not buffer)
 248         (error "Opening input file: No such file or directory, %s" url))
 249     (with-current-buffer buffer
 250       (setq handle (mm-dissect-buffer t)))
 251     (mm-save-part-to-file handle newname)
 252     (kill-buffer buffer)
 253     (mm-destroy-parts handle)))
 254 (put 'copy-file 'url-file-handlers 'url-copy-file)
 255
 256 ;;;###autoload
 257 (defun url-file-local-copy (url &rest ignored)
 258   "Copy URL into a temporary file on this machine.
 259 Returns the name of the local copy, or nil, if FILE is directly
 260 accessible."
 261   (let ((filename (make-temp-file "url")))
 262     (url-copy-file url filename 'ok-if-already-exists)
 263     filename))
 264 (put 'file-local-copy 'url-file-handlers 'url-file-local-copy)
 265
 266 (defun url-insert (buffer &optional beg end)
 267   "Insert the body of a URL object.
 268 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 269 If the headers specify a coding-system, it is applied to the body before it is inserted.
 270 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 271 of the inserted text and CHARSET is the charset that was specified in the header,
 272 or nil if none was found.
 273 BEG and END can be used to only insert a subpart of the body.
 274 They count bytes from the beginning of the body."
 275   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 276          (data (with-current-buffer (mm-handle-buffer handle)
 277                  (if beg
 278                      (buffer-substring (+ (point-min) beg)
 279                                        (if end (+ (point-min) end) (point-max)))
 280                    (buffer-string))))
 281          (charset (mail-content-type-get (mm-handle-type handle)
 282                                           'charset)))
 283     (mm-destroy-parts handle)
 284     (if charset
 285         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 286       (insert data))
 287     (list (length data) charset)))
 288
 289 ;;;###autoload
 290 (defun url-insert-file-contents (url &optional visit beg end replace)
 291   (let ((buffer (url-retrieve-synchronously url)))
 292     (if (not buffer)
 293         (error "Opening input file: No such file or directory, %s" url))
 294     (if visit (setq buffer-file-name url))
 295     (save-excursion
 296       (let* ((start (point))
 297              (size-and-charset (url-insert buffer beg end)))
 298         (kill-buffer buffer)
 299         (when replace
 300           (delete-region (point-min) start)
 301           (delete-region (point) (point-max)))
 302         (unless (cadr size-and-charset)
 303           ;; If the headers don't specify any particular charset, use the
 304           ;; usual heuristic/rules that we apply to files.
 305           (decode-coding-inserted-region start (point) url visit beg end replace))
 306         (list url (car size-and-charset))))))
 307 (put 'insert-file-contents 'url-file-handlers 'url-insert-file-contents)
 308
 309 (defun url-file-name-completion (url directory &optional predicate)
 310   (error "Unimplemented"))
 311 (put 'file-name-completion 'url-file-handlers 'url-file-name-completion)
 312
 313 (defun url-file-name-all-completions (file directory)
 314   (error "Unimplemented"))
 315 (put 'file-name-all-completions
 316      'url-file-handlers 'url-file-name-all-completions)
 317
 318 ;; All other handlers map onto their respective backends.
 319 (defmacro url-handlers-create-wrapper (method args)
 320   `(progn
 321      (defun ,(intern (format "url-%s" method)) ,args
 322        ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 323                 (or (documentation method t) "No original documentation."))
 324        (setq url (url-generic-parse-url url))
 325        (when (url-type url)
 326          (funcall (url-scheme-get-property (url-type url) (quote ,method))
 327                   ,@(remove '&rest (remove '&optional args)))))
 328      (unless (get ',method 'url-file-handlers)
 329        (put ',method 'url-file-handlers ',(intern (format "url-%s" method))))))
 330
 331 (url-handlers-create-wrapper file-exists-p (url))
 332 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 333 (url-handlers-create-wrapper file-symlink-p (url))
 334 (url-handlers-create-wrapper file-writable-p (url))
 335 (url-handlers-create-wrapper file-directory-p (url))
 336 (url-handlers-create-wrapper file-executable-p (url))
 337 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 338 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 339
 340 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 341
 342 (defun url-handlers-set-buffer-mode ()
 343   "Set correct modes for the current buffer if visiting a remote file."
 344   (and (stringp buffer-file-name)
 345        (string-match url-handler-regexp buffer-file-name)
 346        (auto-save-mode 0)))
 347
 348 (provide 'url-handlers)
 349
 350 ;;; url-handlers.el ends here