lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2003, 2004
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function nil
  31   "Window-system dependent function to call to create a new frame.
  32 The window system startup file should set this to its frame creation
  33 function, which should take an alist of parameters as its argument.")
  34
  35 ;; The initial value given here used to ask for a minibuffer.
  36 ;; But that's not necessary, because the default is to have one.
  37 ;; By not specifying it here, we let an X resource specify it.
  38 (defcustom initial-frame-alist nil
  39   "*Alist of frame parameters for creating the initial X window frame.
  40 You can set this in your `.emacs' file; for example,
  41  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  42 Parameters specified here supersede the values given in `default-frame-alist'.
  43
  44 If the value calls for a frame without a minibuffer, and you have not created
  45 a minibuffer frame on your own, one is created according to
  46 `minibuffer-frame-alist'.
  47
  48 You can specify geometry-related options for just the initial frame
  49 by setting this variable in your `.emacs' file; however, they won't
  50 take effect until Emacs reads `.emacs', which happens after first creating
  51 the frame.  If you want the frame to have the proper geometry as soon
  52 as it appears, you need to use this three-step process:
  53 * Specify X resources to give the geometry you want.
  54 * Set `default-frame-alist' to override these options so that they
  55   don't affect subsequent frames.
  56 * Set `initial-frame-alist' in a way that matches the X resources,
  57   to override what you put in `default-frame-alist'."
  58   :type '(repeat (cons :format "%v"
  59                        (symbol :tag "Parameter")
  60                        (sexp :tag "Value")))
  61   :group 'frames)
  62
  63 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  64   "*Alist of frame parameters for initially creating a minibuffer frame.
  65 You can set this in your `.emacs' file; for example,
  66  (setq minibuffer-frame-alist
  67    '((top . 1) (left . 1) (width . 80) (height . 2)))
  68 Parameters specified here supersede the values given in
  69 `default-frame-alist', for a minibuffer frame."
  70   :type '(repeat (cons :format "%v"
  71                        (symbol :tag "Parameter")
  72                        (sexp :tag "Value")))
  73   :group 'frames)
  74
  75 (defcustom pop-up-frame-alist nil
  76   "*Alist of frame parameters used when creating pop-up frames.
  77 Pop-up frames are used for completions, help, and the like.
  78 This variable can be set in your init file, like this:
  79   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  80 These supersede the values given in `default-frame-alist',
  81 for pop-up frames."
  82   :type '(repeat (cons :format "%v"
  83                        (symbol :tag "Parameter")
  84                        (sexp :tag "Value")))
  85   :group 'frames)
  86
  87 (setq pop-up-frame-function
  88       ;; Using `function' here caused some sort of problem.
  89       '(lambda ()
  90          (make-frame pop-up-frame-alist)))
  91
  92 (defcustom special-display-frame-alist
  93   '((height . 14) (width . 80) (unsplittable . t))
  94   "*Alist of frame parameters used when creating special frames.
  95 Special frames are used for buffers whose names are in
  96 `special-display-buffer-names' and for buffers whose names match
  97 one of the regular expressions in `special-display-regexps'.
  98 This variable can be set in your init file, like this:
  99   (setq special-display-frame-alist '((width . 80) (height . 20)))
 100 These supersede the values given in `default-frame-alist'."
 101   :type '(repeat (cons :format "%v"
 102                          (symbol :tag "Parameter")
 103                          (sexp :tag "Value")))
 104   :group 'frames)
 105
 106 (defun special-display-popup-frame (buffer &optional args)
 107   "Display BUFFER in its own frame, reusing an existing window if any.
 108 Return the window chosen.
 109 Currently we do not insist on selecting the window within its frame.
 110 If ARGS is an alist, use it as a list of frame parameter specs.
 111 If ARGS is a list whose car is a symbol,
 112 use (car ARGS) as a function to do the work.
 113 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 114   (if (and args (symbolp (car args)))
 115       (apply (car args) buffer (cdr args))
 116     (let ((window (get-buffer-window buffer 0)))
 117       (or
 118        ;; If we have a window already, make it visible.
 119        (when window
 120          (let ((frame (window-frame window)))
 121            (make-frame-visible frame)
 122            (raise-frame frame)
 123            window))
 124        ;; Reuse the current window if the user requested it.
 125        (when (cdr (assq 'same-window args))
 126          (condition-case nil
 127              (progn (switch-to-buffer buffer) (selected-window))
 128            (error nil)))
 129        ;; Stay on the same frame if requested.
 130        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 131          (let* ((pop-up-frames nil) (pop-up-windows t)
 132                 special-display-regexps special-display-buffer-names
 133                 (window (display-buffer buffer)))
 134            ;; Only do it if this is a new window:
 135            ;; (set-window-dedicated-p window t)
 136            window))
 137        ;; If no window yet, make one in a new frame.
 138        (let ((frame (make-frame (append args special-display-frame-alist))))
 139          (set-window-buffer (frame-selected-window frame) buffer)
 140          (set-window-dedicated-p (frame-selected-window frame) t)
 141          (frame-selected-window frame))))))
 142
 143 (defun handle-delete-frame (event)
 144   "Handle delete-frame events from the X server."
 145   (interactive "e")
 146   (let ((frame (posn-window (event-start event)))
 147         (i 0)
 148         (tail (frame-list)))
 149     (while tail
 150       (and (frame-visible-p (car tail))
 151            (not (eq (car tail) frame))
 152           (setq i (1+ i)))
 153       (setq tail (cdr tail)))
 154     (if (> i 0)
 155         (delete-frame frame t)
 156       ;; Gildea@x.org says it is ok to ask questions before terminating.
 157       (save-buffers-kill-emacs))))
 158 \f
 159 ;;;; Arrangement of frames at startup
 160
 161 ;; 1) Load the window system startup file from the lisp library and read the
 162 ;; high-priority arguments (-q and the like).  The window system startup
 163 ;; file should create any frames specified in the window system defaults.
 164 ;;
 165 ;; 2) If no frames have been opened, we open an initial text frame.
 166 ;;
 167 ;; 3) Once the init file is done, we apply any newly set parameters
 168 ;; in initial-frame-alist to the frame.
 169
 170 ;; These are now called explicitly at the proper times,
 171 ;; since that is easier to understand.
 172 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 173 ;; (add-hook 'before-init-hook 'frame-initialize)
 174 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 175
 176 ;; If we create the initial frame, this is it.
 177 (defvar frame-initial-frame nil)
 178
 179 ;; Record the parameters used in frame-initialize to make the initial frame.
 180 (defvar frame-initial-frame-alist)
 181
 182 (defvar frame-initial-geometry-arguments nil)
 183
 184 ;; startup.el calls this function before loading the user's init
 185 ;; file - if there is no frame with a minibuffer open now, create
 186 ;; one to display messages while loading the init file.
 187 (defun frame-initialize ()
 188   "Create an initial frame if necessary."
 189   ;; Are we actually running under a window system at all?
 190   (if (and window-system (not noninteractive) (not (eq window-system 'pc)))
 191       (progn
 192         ;; Turn on special-display processing only if there's a window system.
 193         (setq special-display-function 'special-display-popup-frame)
 194
 195         ;; If there is no frame with a minibuffer besides the terminal
 196         ;; frame, then we need to create the opening frame.  Make sure
 197         ;; it has a minibuffer, but let initial-frame-alist omit the
 198         ;; minibuffer spec.
 199         (or (delq terminal-frame (minibuffer-frame-list))
 200             (progn
 201               (setq frame-initial-frame-alist
 202                     (append initial-frame-alist default-frame-alist nil))
 203               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 204                   (setq frame-initial-frame-alist
 205                         (cons '(horizontal-scroll-bars . t)
 206                               frame-initial-frame-alist)))
 207               (setq default-minibuffer-frame
 208                     (setq frame-initial-frame
 209                           (make-frame frame-initial-frame-alist)))
 210               ;; Delete any specifications for window geometry parameters
 211               ;; so that we won't reapply them in frame-notice-user-settings.
 212               ;; It would be wrong to reapply them then,
 213               ;; because that would override explicit user resizing.
 214               (setq initial-frame-alist
 215                     (frame-remove-geometry-params initial-frame-alist))))
 216         ;; At this point, we know that we have a frame open, so we
 217         ;; can delete the terminal frame.
 218         (delete-frame terminal-frame)
 219         (setq terminal-frame nil))
 220
 221     ;; No, we're not running a window system.  Use make-terminal-frame if
 222     ;; we support that feature, otherwise arrange to cause errors.
 223     (or (eq window-system 'pc)
 224         (setq frame-creation-function
 225               (if (fboundp 'tty-create-frame-with-faces)
 226                   'tty-create-frame-with-faces
 227                 (function
 228                  (lambda (parameters)
 229                    (error
 230                     "Can't create multiple frames without a window system"))))))))
 231
 232 (defvar frame-notice-user-settings t
 233   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 234
 235 ;; startup.el calls this function after loading the user's init
 236 ;; file.  Now default-frame-alist and initial-frame-alist contain
 237 ;; information to which we must react; do what needs to be done.
 238 (defun frame-notice-user-settings ()
 239   "Act on user's init file settings of frame parameters.
 240 React to settings of `default-frame-alist', `initial-frame-alist' there."
 241   ;; Make menu-bar-mode and default-frame-alist consistent.
 242   (when (boundp 'menu-bar-mode)
 243     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 244       (if default
 245           (setq menu-bar-mode (not (eq (cdr default) 0)))
 246         (setq default-frame-alist
 247               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 248                     default-frame-alist)))))
 249
 250   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 251   ;; it in batch mode since that would leave a tool-bar-lines
 252   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 253   ;; what we want.
 254   (when (and (boundp 'tool-bar-mode)
 255              (not noninteractive))
 256     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 257       (if default
 258           (setq tool-bar-mode (not (eq (cdr default) 0)))
 259         (setq default-frame-alist
 260               (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 261                     default-frame-alist)))))
 262
 263   ;; Creating and deleting frames may shift the selected frame around,
 264   ;; and thus the current buffer.  Protect against that.  We don't
 265   ;; want to use save-excursion here, because that may also try to set
 266   ;; the buffer of the selected window, which fails when the selected
 267   ;; window is the minibuffer.
 268   (let ((old-buffer (current-buffer)))
 269
 270     (when (and frame-notice-user-settings
 271                (null frame-initial-frame))
 272       ;; This case happens when we don't have a window system, and
 273       ;; also for MS-DOS frames.
 274       (let ((parms (frame-parameters frame-initial-frame)))
 275         ;; Don't change the frame names.
 276         (setq parms (delq (assq 'name parms) parms))
 277         ;; Can't modify the minibuffer parameter, so don't try.
 278         (setq parms (delq (assq 'minibuffer parms) parms))
 279         (modify-frame-parameters nil
 280                                  (if (null window-system)
 281                                      (append initial-frame-alist
 282                                              default-frame-alist
 283                                              parms
 284                                              nil)
 285                                    ;; initial-frame-alist and
 286                                    ;; default-frame-alist were already
 287                                    ;; applied in pc-win.el.
 288                                    parms))
 289         (if (null window-system) ;; MS-DOS does this differently in pc-win.el
 290             (let ((newparms (frame-parameters))
 291                   (frame (selected-frame)))
 292               (tty-handle-reverse-video frame newparms)
 293               ;; If we changed the background color, we need to update
 294               ;; the background-mode parameter, and maybe some faces,
 295               ;; too.
 296               (when (assq 'background-color newparms)
 297                 (unless (or (assq 'background-mode initial-frame-alist)
 298                             (assq 'background-mode default-frame-alist))
 299                   (frame-set-background-mode frame))
 300                 (face-set-after-frame-default frame))))))
 301
 302     ;; If the initial frame is still around, apply initial-frame-alist
 303     ;; and default-frame-alist to it.
 304     (when (frame-live-p frame-initial-frame)
 305
 306       ;; When tool-bar has been switched off, correct the frame size
 307       ;; by the lines added in x-create-frame for the tool-bar and
 308       ;; switch `tool-bar-mode' off.
 309       (when (display-graphic-p)
 310         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 311                                   (assq 'tool-bar-lines default-frame-alist))))
 312           (when (and tool-bar-originally-present
 313                      (or (null tool-bar-lines)
 314                          (null (cdr tool-bar-lines))
 315                          (eq 0 (cdr tool-bar-lines))))
 316             (let* ((char-height (frame-char-height frame-initial-frame))
 317                    (image-height tool-bar-images-pixel-height)
 318                    (margin (cond ((and (consp tool-bar-button-margin)
 319                                        (integerp (cdr tool-bar-button-margin))
 320                                        (> tool-bar-button-margin 0))
 321                                   (cdr tool-bar-button-margin))
 322                                  ((and (integerp tool-bar-button-margin)
 323                                        (> tool-bar-button-margin 0))
 324                                   tool-bar-button-margin)
 325                                  (t 0)))
 326                    (relief (if (and (integerp tool-bar-button-relief)
 327                                     (> tool-bar-button-relief 0))
 328                                tool-bar-button-relief 3))
 329                    (lines (/ (+ image-height
 330                                 (* 2 margin)
 331                                 (* 2 relief)
 332                                 (1- char-height))
 333                              char-height))
 334                    (height (frame-parameter frame-initial-frame 'height))
 335                    (newparms (list (cons 'height (- height lines))))
 336                    (initial-top (cdr (assq 'top
 337                                            frame-initial-geometry-arguments)))
 338                    (top (frame-parameter frame-initial-frame 'top)))
 339               (when (and (consp initial-top) (eq '- (car initial-top)))
 340                 (let ((adjusted-top
 341                        (cond ((and (consp top)
 342                                    (eq '+ (car top)))
 343                               (list '+
 344                                     (+ (cadr top)
 345                                        (* lines char-height))))
 346                              ((and (consp top)
 347                                    (eq '- (car top)))
 348                               (list '-
 349                                     (- (cadr top)
 350                                        (* lines char-height))))
 351                              (t (+ top (* lines char-height))))))
 352                   (setq newparms
 353                         (append newparms
 354                                 `((top . ,adjusted-top))
 355                                 nil))))
 356               (modify-frame-parameters frame-initial-frame newparms)
 357               (tool-bar-mode -1)))))
 358
 359       ;; The initial frame we create above always has a minibuffer.
 360       ;; If the user wants to remove it, or make it a minibuffer-only
 361       ;; frame, then we'll have to delete the current frame and make a
 362       ;; new one; you can't remove or add a root window to/from an
 363       ;; existing frame.
 364       ;;
 365       ;; NOTE: default-frame-alist was nil when we created the
 366       ;; existing frame.  We need to explicitly include
 367       ;; default-frame-alist in the parameters of the screen we
 368       ;; create here, so that its new value, gleaned from the user's
 369       ;; .emacs file, will be applied to the existing screen.
 370       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 371                             (assq 'minibuffer default-frame-alist)
 372                             '(minibuffer . t)))
 373                    t))
 374           ;; Create the new frame.
 375           (let (parms new)
 376             ;; If the frame isn't visible yet, wait till it is.
 377             ;; If the user has to position the window,
 378             ;; Emacs doesn't know its real position until
 379             ;; the frame is seen to be visible.
 380             (while (not (cdr (assq 'visibility
 381                                    (frame-parameters frame-initial-frame))))
 382               (sleep-for 1))
 383             (setq parms (frame-parameters frame-initial-frame))
 384
 385             ;; Get rid of `name' unless it was specified explicitly before.
 386             (or (assq 'name frame-initial-frame-alist)
 387                 (setq parms (delq (assq 'name parms) parms)))
 388
 389             (setq parms (append initial-frame-alist
 390                                 default-frame-alist
 391                                 parms
 392                                 nil))
 393
 394             ;; Get rid of `reverse', because that was handled
 395             ;; when we first made the frame.
 396             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 397
 398             (if (assq 'height frame-initial-geometry-arguments)
 399                 (setq parms (assq-delete-all 'height parms)))
 400             (if (assq 'width frame-initial-geometry-arguments)
 401                 (setq parms (assq-delete-all 'width parms)))
 402             (if (assq 'left frame-initial-geometry-arguments)
 403                 (setq parms (assq-delete-all 'left parms)))
 404             (if (assq 'top frame-initial-geometry-arguments)
 405                 (setq parms (assq-delete-all 'top parms)))
 406             (setq new
 407                   (make-frame
 408                    ;; Use the geometry args that created the existing
 409                    ;; frame, rather than the parms we get for it.
 410                    (append frame-initial-geometry-arguments
 411                            '((user-size . t) (user-position . t))
 412                            parms)))
 413             ;; The initial frame, which we are about to delete, may be
 414             ;; the only frame with a minibuffer.  If it is, create a
 415             ;; new one.
 416             (or (delq frame-initial-frame (minibuffer-frame-list))
 417                 (make-initial-minibuffer-frame nil))
 418
 419             ;; If the initial frame is serving as a surrogate
 420             ;; minibuffer frame for any frames, we need to wean them
 421             ;; onto a new frame.  The default-minibuffer-frame
 422             ;; variable must be handled similarly.
 423             (let ((users-of-initial
 424                    (filtered-frame-list
 425                     (function (lambda (frame)
 426                                 (and (not (eq frame frame-initial-frame))
 427                                      (eq (window-frame
 428                                           (minibuffer-window frame))
 429                                          frame-initial-frame)))))))
 430               (if (or users-of-initial
 431                       (eq default-minibuffer-frame frame-initial-frame))
 432
 433                   ;; Choose an appropriate frame.  Prefer frames which
 434                   ;; are only minibuffers.
 435                   (let* ((new-surrogate
 436                           (car
 437                            (or (filtered-frame-list
 438                                 (function
 439                                  (lambda (frame)
 440                                    (eq (cdr (assq 'minibuffer
 441                                                   (frame-parameters frame)))
 442                                        'only))))
 443                                (minibuffer-frame-list))))
 444                          (new-minibuffer (minibuffer-window new-surrogate)))
 445
 446                     (if (eq default-minibuffer-frame frame-initial-frame)
 447                         (setq default-minibuffer-frame new-surrogate))
 448
 449                     ;; Wean the frames using frame-initial-frame as
 450                     ;; their minibuffer frame.
 451                     (mapcar
 452                      (function
 453                       (lambda (frame)
 454                         (modify-frame-parameters
 455                          frame (list (cons 'minibuffer new-minibuffer)))))
 456                      users-of-initial))))
 457
 458            ;; Redirect events enqueued at this frame to the new frame.
 459             ;; Is this a good idea?
 460             (redirect-frame-focus frame-initial-frame new)
 461
 462             ;; Finally, get rid of the old frame.
 463             (delete-frame frame-initial-frame t))
 464
 465         ;; Otherwise, we don't need all that rigamarole; just apply
 466         ;; the new parameters.
 467         (let (newparms allparms tail)
 468           (setq allparms (append initial-frame-alist
 469                                  default-frame-alist nil))
 470           (if (assq 'height frame-initial-geometry-arguments)
 471               (setq allparms (assq-delete-all 'height allparms)))
 472           (if (assq 'width frame-initial-geometry-arguments)
 473               (setq allparms (assq-delete-all 'width allparms)))
 474           (if (assq 'left frame-initial-geometry-arguments)
 475               (setq allparms (assq-delete-all 'left allparms)))
 476           (if (assq 'top frame-initial-geometry-arguments)
 477               (setq allparms (assq-delete-all 'top allparms)))
 478           (setq tail allparms)
 479           ;; Find just the parms that have changed since we first
 480           ;; made this frame.  Those are the ones actually set by
 481           ;; the init file.  For those parms whose values we already knew
 482           ;; (such as those spec'd by command line options)
 483           ;; it is undesirable to specify the parm again
 484           ;; once the user has seen the frame and been able to alter it
 485           ;; manually.
 486           (while tail
 487             (let (newval oldval)
 488               (setq oldval (assq (car (car tail))
 489                                  frame-initial-frame-alist))
 490               (setq newval (cdr (assq (car (car tail)) allparms)))
 491               (or (and oldval (eq (cdr oldval) newval))
 492                   (setq newparms
 493                         (cons (cons (car (car tail)) newval) newparms))))
 494             (setq tail (cdr tail)))
 495           (setq newparms (nreverse newparms))
 496           (modify-frame-parameters frame-initial-frame
 497                                    newparms)
 498           ;; If we changed the background color,
 499           ;; we need to update the background-mode parameter
 500           ;; and maybe some faces too.
 501           (when (assq 'background-color newparms)
 502             (unless (assq 'background-mode newparms)
 503               (frame-set-background-mode frame-initial-frame))
 504             (face-set-after-frame-default frame-initial-frame)))))
 505
 506     ;; Restore the original buffer.
 507     (set-buffer old-buffer)
 508
 509     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 510     ;; Make sure frame-notice-user-settings does nothing if called twice.
 511     (setq frame-notice-user-settings nil)
 512     (setq frame-initial-frame nil)))
 513
 514 (defun make-initial-minibuffer-frame (display)
 515   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 516     (if display
 517         (make-frame-on-display display parms)
 518       (make-frame parms))))
 519
 520 ;;;; Creation of additional frames, and other frame miscellanea
 521
 522 (defun modify-all-frames-parameters (alist)
 523   "Modify all current and future frames' parameters according to ALIST.
 524 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 525 See help of `modify-frame-parameters' for more information."
 526   (let (element)                        ;; temp
 527     (dolist (frame (frame-list))
 528       (modify-frame-parameters frame alist))
 529
 530     (dolist (pair alist)                ;; conses to add/replace
 531       ;; initial-frame-alist needs setting only when
 532       ;; frame-notice-user-settings is true
 533       (and frame-notice-user-settings
 534            (setq element (assoc (car pair) initial-frame-alist))
 535            (setq initial-frame-alist (delq element initial-frame-alist)))
 536       (and (setq element (assoc (car pair) default-frame-alist))
 537            (setq default-frame-alist (delq element default-frame-alist)))))
 538   (and frame-notice-user-settings
 539        (setq initial-frame-alist (append initial-frame-alist alist)))
 540   (setq default-frame-alist (append default-frame-alist alist)))
 541
 542 (defun get-other-frame ()
 543   "Return some frame other than the current frame.
 544 Create one if necessary.  Note that the minibuffer frame, if separate,
 545 is not considered (see `next-frame')."
 546   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 547                (make-frame)
 548              (next-frame (selected-frame)))))
 549     s))
 550
 551 (defun next-multiframe-window ()
 552   "Select the next window, regardless of which frame it is on."
 553   (interactive)
 554   (select-window (next-window (selected-window)
 555                               (> (minibuffer-depth) 0)
 556                               0))
 557   (select-frame-set-input-focus (selected-frame)))
 558
 559 (defun previous-multiframe-window ()
 560   "Select the previous window, regardless of which frame it is on."
 561   (interactive)
 562   (select-window (previous-window (selected-window)
 563                                   (> (minibuffer-depth) 0)
 564                                   0))
 565   (select-frame-set-input-focus (selected-frame)))
 566
 567 (defun make-frame-on-display (display &optional parameters)
 568   "Make a frame on display DISPLAY.
 569 The optional second argument PARAMETERS specifies additional frame parameters."
 570   (interactive "sMake frame on display: ")
 571   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 572       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 573   (make-frame (cons (cons 'display display) parameters)))
 574
 575 (defun make-frame-command ()
 576   "Make a new frame, and select it if the terminal displays only one frame."
 577   (interactive)
 578   (if (and window-system (not (eq window-system 'pc)))
 579       (make-frame)
 580     (select-frame (make-frame))))
 581
 582 (defvar before-make-frame-hook nil
 583   "Functions to run before a frame is created.")
 584
 585 (defvar after-make-frame-functions nil
 586   "Functions to run after a frame is created.
 587 The functions are run with one arg, the newly created frame.")
 588
 589 (defvar after-setting-font-hook nil
 590   "Functions to run after a frame's font has been changed.")
 591
 592 ;; Alias, kept temporarily.
 593 (defalias 'new-frame 'make-frame)
 594 (make-obsolete 'new-frame 'make-frame "21.4")
 595
 596 (defun make-frame (&optional parameters)
 597   "Return a newly created frame displaying the current buffer.
 598 Optional argument PARAMETERS is an alist of parameters for the new frame.
 599 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 600
 601  (name . STRING)        The frame should be named STRING.
 602
 603  (width . NUMBER)       The frame should be NUMBER characters in width.
 604  (height . NUMBER)      The frame should be NUMBER text lines high.
 605
 606 You cannot specify either `width' or `height', you must use neither or both.
 607
 608  (minibuffer . t)       The frame should have a minibuffer.
 609  (minibuffer . nil)     The frame should have no minibuffer.
 610  (minibuffer . only)    The frame should contain only a minibuffer.
 611  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 612
 613 Before the frame is created (via `frame-creation-function'), functions on the
 614 hook `before-make-frame-hook' are run.  After the frame is created, functions
 615 on `after-make-frame-functions' are run with one arg, the newly created frame.
 616
 617 This function itself does not make the new frame the selected frame.
 618 The previously selected frame remains selected.  However, the
 619 window system may select the new frame for its own reasons, for
 620 instance if the frame appears under the mouse pointer and your
 621 setup is for focus to follow the pointer."
 622   (interactive)
 623   (run-hooks 'before-make-frame-hook)
 624   (let ((frame (funcall frame-creation-function parameters)))
 625     (run-hook-with-args 'after-make-frame-functions frame)
 626     frame))
 627
 628 (defun filtered-frame-list (predicate)
 629   "Return a list of all live frames which satisfy PREDICATE."
 630   (let* ((frames (frame-list))
 631          (list frames))
 632     (while (consp frames)
 633       (unless (funcall predicate (car frames))
 634         (setcar frames nil))
 635       (setq frames (cdr frames)))
 636     (delq nil list)))
 637
 638 (defun minibuffer-frame-list ()
 639   "Return a list of all frames with their own minibuffers."
 640   (filtered-frame-list
 641    (function (lambda (frame)
 642                (eq frame (window-frame (minibuffer-window frame)))))))
 643
 644 (defun frames-on-display-list (&optional display)
 645   "Return a list of all frames on DISPLAY.
 646 DISPLAY is a name of a display, a string of the form HOST:SERVER.SCREEN.
 647 If DISPLAY is omitted or nil, it defaults to the selected frame's display."
 648   (let* ((display (or display (frame-parameter nil 'display)))
 649          (func #'(lambda (frame)
 650                    (equal (frame-parameter frame 'display) display))))
 651     (filtered-frame-list func)))
 652
 653 (defun framep-on-display (&optional display)
 654   "Return the type of frames on DISPLAY.
 655 DISPLAY may be a display name or a frame.  If it is a frame, its type is
 656 returned.
 657 If DISPLAY is omitted or nil, it defaults to the selected frame's display.
 658 All frames on a given display are of the same type."
 659   (or (framep display)
 660       (framep (car (frames-on-display-list display)))))
 661
 662 (defun frame-remove-geometry-params (param-list)
 663   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 664 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 665 `height', `user-size' and `user-position' parameters.
 666 Emacs uses this to avoid overriding explicit moves and resizings from
 667 the user during startup."
 668   (setq param-list (cons nil param-list))
 669   (let ((tail param-list))
 670     (while (consp (cdr tail))
 671       (if (and (consp (car (cdr tail)))
 672                (memq (car (car (cdr tail)))
 673                      '(height width top left user-position user-size)))
 674           (progn
 675             (setq frame-initial-geometry-arguments
 676                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 677             (setcdr tail (cdr (cdr tail))))
 678         (setq tail (cdr tail)))))
 679   (setq frame-initial-geometry-arguments
 680         (nreverse frame-initial-geometry-arguments))
 681   (cdr param-list))
 682
 683 (defcustom focus-follows-mouse t
 684   "*Non-nil if window system changes focus when you move the mouse.
 685 You should set this variable to tell Emacs how your window manager
 686 handles focus, since there is no way in general for Emacs to find out
 687 automatically."
 688   :type 'boolean
 689   :group 'frames
 690   :version "20.3")
 691
 692 (defun select-frame-set-input-focus (frame)
 693   "Select FRAME, raise it, and set input focus, if possible."
 694     (select-frame frame)
 695     (raise-frame frame)
 696     ;; Ensure, if possible, that frame gets input focus.
 697     (cond ((eq window-system 'x)
 698            (x-focus-frame frame))
 699           ((eq window-system 'w32)
 700            (w32-focus-frame frame)))
 701     (cond (focus-follows-mouse
 702            (set-mouse-position (selected-frame) (1- (frame-width)) 0))))
 703
 704 (defun other-frame (arg)
 705   "Select the ARG'th different visible frame on current display, and raise it.
 706 All frames are arranged in a cyclic order.
 707 This command selects the frame ARG steps away in that order.
 708 A negative ARG moves in the opposite order.
 709
 710 To make this command work properly, you must tell Emacs
 711 how the system (or the window manager) generally handles
 712 focus-switching between windows.  If moving the mouse onto a window
 713 selects it (gives it focus), set `focus-follows-mouse' to t.
 714 Otherwise, that variable should be nil."
 715   (interactive "p")
 716   (let ((frame (selected-frame)))
 717     (while (> arg 0)
 718       (setq frame (next-frame frame))
 719       (while (not (eq (frame-visible-p frame) t))
 720         (setq frame (next-frame frame)))
 721       (setq arg (1- arg)))
 722     (while (< arg 0)
 723       (setq frame (previous-frame frame))
 724       (while (not (eq (frame-visible-p frame) t))
 725         (setq frame (previous-frame frame)))
 726       (setq arg (1+ arg)))
 727     (select-frame-set-input-focus frame)))
 728
 729 (defun iconify-or-deiconify-frame ()
 730   "Iconify the selected frame, or deiconify if it's currently an icon."
 731   (interactive)
 732   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 733       (iconify-frame)
 734     (make-frame-visible)))
 735
 736 (defun make-frame-names-alist ()
 737   (let* ((current-frame (selected-frame))
 738          (falist
 739           (cons
 740            (cons (frame-parameter current-frame 'name) current-frame) nil))
 741          (frame (next-frame nil t)))
 742     (while (not (eq frame current-frame))
 743       (progn
 744         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 745         (setq frame (next-frame frame t))))
 746     falist))
 747
 748 (defvar frame-name-history nil)
 749 (defun select-frame-by-name (name)
 750   "Select the frame on the current terminal whose name is NAME and raise it.
 751 If there is no frame by that name, signal an error."
 752   (interactive
 753    (let* ((frame-names-alist (make-frame-names-alist))
 754            (default (car (car frame-names-alist)))
 755            (input (completing-read
 756                    (format "Select Frame (default %s): " default)
 757                    frame-names-alist nil t nil 'frame-name-history)))
 758      (if (= (length input) 0)
 759          (list default)
 760        (list input))))
 761   (let* ((frame-names-alist (make-frame-names-alist))
 762          (frame (cdr (assoc name frame-names-alist))))
 763     (or frame
 764         (error "There is no frame named `%s'" name))
 765     (make-frame-visible frame)
 766     (raise-frame frame)
 767     (select-frame frame)
 768     ;; Ensure, if possible, that frame gets input focus.
 769     (cond ((eq window-system 'x)
 770            (x-focus-frame frame))
 771           ((eq window-system 'w32)
 772            (w32-focus-frame frame)))
 773     (when focus-follows-mouse
 774       (set-mouse-position frame (1- (frame-width frame)) 0))))
 775 \f
 776 ;;;; Frame configurations
 777
 778 (defun current-frame-configuration ()
 779   "Return a list describing the positions and states of all frames.
 780 Its car is `frame-configuration'.
 781 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 782 where
 783   FRAME is a frame object,
 784   ALIST is an association list specifying some of FRAME's parameters, and
 785   WINDOW-CONFIG is a window configuration object for FRAME."
 786   (cons 'frame-configuration
 787         (mapcar (function
 788                  (lambda (frame)
 789                    (list frame
 790                          (frame-parameters frame)
 791                          (current-window-configuration frame))))
 792                 (frame-list))))
 793
 794 (defun set-frame-configuration (configuration &optional nodelete)
 795   "Restore the frames to the state described by CONFIGURATION.
 796 Each frame listed in CONFIGURATION has its position, size, window
 797 configuration, and other parameters set as specified in CONFIGURATION.
 798 However, this function does not restore deleted frames.
 799
 800 Ordinarily, this function deletes all existing frames not
 801 listed in CONFIGURATION.  But if optional second argument NODELETE
 802 is given and non-nil, the unwanted frames are iconified instead."
 803   (or (frame-configuration-p configuration)
 804       (signal 'wrong-type-argument
 805               (list 'frame-configuration-p configuration)))
 806   (let ((config-alist (cdr configuration))
 807         frames-to-delete)
 808     (mapcar (function
 809              (lambda (frame)
 810                (let ((parameters (assq frame config-alist)))
 811                  (if parameters
 812                      (progn
 813                        (modify-frame-parameters
 814                         frame
 815                         ;; Since we can't set a frame's minibuffer status,
 816                         ;; we might as well omit the parameter altogether.
 817                         (let* ((parms (nth 1 parameters))
 818                                (mini (assq 'minibuffer parms)))
 819                           (if mini (setq parms (delq mini parms)))
 820                           parms))
 821                        (set-window-configuration (nth 2 parameters)))
 822                    (setq frames-to-delete (cons frame frames-to-delete))))))
 823             (frame-list))
 824     (if nodelete
 825         ;; Note: making frames invisible here was tried
 826         ;; but led to some strange behavior--each time the frame
 827         ;; was made visible again, the window manager asked afresh
 828         ;; for where to put it.
 829         (mapcar 'iconify-frame frames-to-delete)
 830       (mapcar 'delete-frame frames-to-delete))))
 831 \f
 832 ;;;; Convenience functions for accessing and interactively changing
 833 ;;;; frame parameters.
 834
 835 (defun frame-height (&optional frame)
 836   "Return number of lines available for display on FRAME.
 837 If FRAME is omitted, describe the currently selected frame."
 838   (cdr (assq 'height (frame-parameters frame))))
 839
 840 (defun frame-width (&optional frame)
 841   "Return number of columns available for display on FRAME.
 842 If FRAME is omitted, describe the currently selected frame."
 843   (cdr (assq 'width (frame-parameters frame))))
 844
 845 (defalias 'set-default-font 'set-frame-font)
 846 (defun set-frame-font (font-name &optional keep-size)
 847   "Set the font of the selected frame to FONT-NAME.
 848 When called interactively, prompt for the name of the font to use.
 849 To get the frame's current default font, use `frame-parameters'.
 850
 851 The default behavior is to keep the numbers of lines and columns in
 852 the frame, thus may change its pixel size. If optional KEEP-SIZE is
 853 non-nil (interactively, prefix argument) the current frame size (in
 854 pixels) is kept by adjusting the numbers of the lines and columns."
 855   (interactive
 856    (let* ((completion-ignore-case t)
 857           (font (completing-read "Font name: "
 858                          (mapcar #'list
 859                                  ;; x-list-fonts will fail with an error
 860                                  ;; if this frame doesn't support fonts.
 861                                  (x-list-fonts "*" nil (selected-frame)))
 862                          nil nil nil nil
 863                          (frame-parameter nil 'font))))
 864      (list font current-prefix-arg)))
 865   (let (fht fwd)
 866     (if keep-size
 867         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
 868               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
 869     (modify-frame-parameters (selected-frame)
 870                              (list (cons 'font font-name)))
 871     (if keep-size
 872         (modify-frame-parameters
 873          (selected-frame)
 874          (list (cons 'height (round fht (frame-char-height)))
 875                (cons 'width (round fwd (frame-char-width)))))))
 876   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
 877
 878 (defun set-frame-parameter (frame parameter value)
 879   (modify-frame-parameters frame (list (cons parameter value))))
 880
 881 (defun set-background-color (color-name)
 882   "Set the background color of the selected frame to COLOR-NAME.
 883 When called interactively, prompt for the name of the color to use.
 884 To get the frame's current background color, use `frame-parameters'."
 885   (interactive (list (facemenu-read-color)))
 886   (modify-frame-parameters (selected-frame)
 887                            (list (cons 'background-color color-name)))
 888   (or window-system
 889       (face-set-after-frame-default (selected-frame))))
 890
 891 (defun set-foreground-color (color-name)
 892   "Set the foreground color of the selected frame to COLOR-NAME.
 893 When called interactively, prompt for the name of the color to use.
 894 To get the frame's current foreground color, use `frame-parameters'."
 895   (interactive (list (facemenu-read-color)))
 896   (modify-frame-parameters (selected-frame)
 897                            (list (cons 'foreground-color color-name)))
 898   (or window-system
 899       (face-set-after-frame-default (selected-frame))))
 900
 901 (defun set-cursor-color (color-name)
 902   "Set the text cursor color of the selected frame to COLOR-NAME.
 903 When called interactively, prompt for the name of the color to use.
 904 To get the frame's current cursor color, use `frame-parameters'."
 905   (interactive (list (facemenu-read-color)))
 906   (modify-frame-parameters (selected-frame)
 907                            (list (cons 'cursor-color color-name))))
 908
 909 (defun set-mouse-color (color-name)
 910   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
 911 When called interactively, prompt for the name of the color to use.
 912 To get the frame's current mouse color, use `frame-parameters'."
 913   (interactive (list (facemenu-read-color)))
 914   (modify-frame-parameters (selected-frame)
 915                            (list (cons 'mouse-color
 916                                        (or color-name
 917                                            (cdr (assq 'mouse-color
 918                                                       (frame-parameters))))))))
 919
 920 (defun set-border-color (color-name)
 921   "Set the color of the border of the selected frame to COLOR-NAME.
 922 When called interactively, prompt for the name of the color to use.
 923 To get the frame's current border color, use `frame-parameters'."
 924   (interactive (list (facemenu-read-color)))
 925   (modify-frame-parameters (selected-frame)
 926                            (list (cons 'border-color color-name))))
 927
 928 (defun auto-raise-mode (arg)
 929   "Toggle whether or not the selected frame should auto-raise.
 930 With arg, turn auto-raise mode on if and only if arg is positive.
 931 Note that this controls Emacs's own auto-raise feature.
 932 Some window managers allow you to enable auto-raise for certain windows.
 933 You can use that for Emacs windows if you wish, but if you do,
 934 that is beyond the control of Emacs and this command has no effect on it."
 935   (interactive "P")
 936   (if (null arg)
 937       (setq arg
 938             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
 939                 -1 1)))
 940   (if (> arg 0)
 941       (raise-frame (selected-frame)))
 942   (modify-frame-parameters (selected-frame)
 943                            (list (cons 'auto-raise (> arg 0)))))
 944
 945 (defun auto-lower-mode (arg)
 946   "Toggle whether or not the selected frame should auto-lower.
 947 With arg, turn auto-lower mode on if and only if arg is positive.
 948 Note that this controls Emacs's own auto-lower feature.
 949 Some window managers allow you to enable auto-lower for certain windows.
 950 You can use that for Emacs windows if you wish, but if you do,
 951 that is beyond the control of Emacs and this command has no effect on it."
 952   (interactive "P")
 953   (if (null arg)
 954       (setq arg
 955             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
 956                 -1 1)))
 957   (modify-frame-parameters (selected-frame)
 958                            (list (cons 'auto-lower (> arg 0)))))
 959 (defun set-frame-name (name)
 960   "Set the name of the selected frame to NAME.
 961 When called interactively, prompt for the name of the frame.
 962 The frame name is displayed on the modeline if the terminal displays only
 963 one frame, otherwise the name is displayed on the frame's caption bar."
 964   (interactive "sFrame name: ")
 965   (modify-frame-parameters (selected-frame)
 966                            (list (cons 'name name))))
 967
 968 (defun frame-current-scroll-bars (&optional frame)
 969   "Return the current scroll-bar settings in frame FRAME.
 970 Value is a cons (VERTICAL . HORISONTAL) where VERTICAL specifies the
 971 current location of the vertical scroll-bars (left, right, or nil),
 972 and HORISONTAL specifies the current location of the horisontal scroll
 973 bars (top, bottom, or nil)."
 974   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
 975         (hor nil))
 976     (unless (memq vert '(left right nil))
 977       (setq vert default-frame-scroll-bars))
 978     (cons vert hor)))
 979 \f
 980 ;;;; Frame/display capabilities.
 981 (defun display-mouse-p (&optional display)
 982   "Return non-nil if DISPLAY has a mouse available.
 983 DISPLAY can be a display name, a frame, or nil (meaning the selected
 984 frame's display)."
 985   (let ((frame-type (framep-on-display display)))
 986     (cond
 987      ((eq frame-type 'pc)
 988       (msdos-mouse-p))
 989      ((eq system-type 'windows-nt)
 990       (> w32-num-mouse-buttons 0))
 991      ((memq frame-type '(x mac))
 992       t)    ;; We assume X and Mac *always* have a pointing device
 993      (t
 994       (or (and (featurep 'xt-mouse)
 995                xterm-mouse-mode)
 996           ;; t-mouse is distributed with the GPM package.  It doesn't have
 997           ;; a toggle.
 998           (featurep 't-mouse))))))
 999
1000 (defun display-popup-menus-p (&optional display)
1001   "Return non-nil if popup menus are supported on DISPLAY.
1002 DISPLAY can be a display name, a frame, or nil (meaning the selected
1003 frame's display).
1004 Support for popup menus requires that the mouse be available."
1005   (and
1006    (let ((frame-type (framep-on-display display)))
1007      (memq frame-type '(x w32 pc mac)))
1008    (display-mouse-p display)))
1009
1010 (defun display-graphic-p (&optional display)
1011   "Return non-nil if DISPLAY is a graphic display.
1012 Graphical displays are those which are capable of displaying several
1013 frames and several different fonts at once.  This is true for displays
1014 that use a window system such as X, and false for text-only terminals.
1015 DISPLAY can be a display name, a frame, or nil (meaning the selected
1016 frame's display)."
1017   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1018
1019 (defun display-images-p (&optional display)
1020   "Return non-nil if DISPLAY can display images.
1021
1022 DISPLAY can be a display name, a frame, or nil (meaning the selected
1023 frame's display)."
1024   (and (display-graphic-p display)
1025        (fboundp 'image-mask-p)
1026        (fboundp 'image-size)))
1027
1028 (defalias 'display-multi-frame-p 'display-graphic-p)
1029 (defalias 'display-multi-font-p 'display-graphic-p)
1030
1031 (defun display-selections-p (&optional display)
1032   "Return non-nil if DISPLAY supports selections.
1033 A selection is a way to transfer text or other data between programs
1034 via special system buffers called `selection' or `cut buffer' or
1035 `clipboard'.
1036 DISPLAY can be a display name, a frame, or nil (meaning the selected
1037 frame's display)."
1038   (let ((frame-type (framep-on-display display)))
1039     (cond
1040      ((eq frame-type 'pc)
1041       ;; MS-DOG frames support selections when Emacs runs inside
1042       ;; the Windows' DOS Box.
1043       (not (null dos-windows-version)))
1044      ((memq frame-type '(x w32 mac))
1045       t)    ;; FIXME?
1046      (t
1047       nil))))
1048
1049 (defun display-screens (&optional display)
1050   "Return the number of screens associated with DISPLAY."
1051   (let ((frame-type (framep-on-display display)))
1052     (cond
1053      ((memq frame-type '(x w32))
1054       (x-display-screens display))
1055      (t ;; FIXME: is this correct for the Mac?
1056       1))))
1057
1058 (defun display-pixel-height (&optional display)
1059   "Return the height of DISPLAY's screen in pixels.
1060 For character terminals, each character counts as a single pixel."
1061   (let ((frame-type (framep-on-display display)))
1062     (cond
1063      ((memq frame-type '(x w32 mac))
1064       (x-display-pixel-height display))
1065      (t
1066       (frame-height (if (framep display) display (selected-frame)))))))
1067
1068 (defun display-pixel-width (&optional display)
1069   "Return the width of DISPLAY's screen in pixels.
1070 For character terminals, each character counts as a single pixel."
1071   (let ((frame-type (framep-on-display display)))
1072     (cond
1073      ((memq frame-type '(x w32 mac))
1074       (x-display-pixel-width display))
1075      (t
1076       (frame-width (if (framep display) display (selected-frame)))))))
1077
1078 (defun display-mm-height (&optional display)
1079   "Return the height of DISPLAY's screen in millimeters.
1080 If the information is unavailable, value is nil."
1081   (and (memq (framep-on-display display) '(x w32 mac))
1082        (x-display-mm-height display)))
1083
1084 (defun display-mm-width (&optional display)
1085   "Return the width of DISPLAY's screen in millimeters.
1086 If the information is unavailable, value is nil."
1087   (and (memq (framep-on-display display) '(x w32 mac))
1088        (x-display-mm-width display)))
1089
1090 (defun display-backing-store (&optional display)
1091   "Return the backing store capability of DISPLAY's screen.
1092 The value may be `always', `when-mapped', `not-useful', or nil if
1093 the question is inapplicable to a certain kind of display."
1094   (let ((frame-type (framep-on-display display)))
1095     (cond
1096      ((memq frame-type '(x w32 mac))
1097       (x-display-backing-store display))
1098      (t
1099       'not-useful))))
1100
1101 (defun display-save-under (&optional display)
1102   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1103   (let ((frame-type (framep-on-display display)))
1104     (cond
1105      ((memq frame-type '(x w32 mac))
1106       (x-display-save-under display))
1107      (t
1108       'not-useful))))
1109
1110 (defun display-planes (&optional display)
1111   "Return the number of planes supported by DISPLAY."
1112   (let ((frame-type (framep-on-display display)))
1113     (cond
1114      ((memq frame-type '(x w32 mac))
1115       (x-display-planes display))
1116      ((eq frame-type 'pc)
1117       4)
1118      (t
1119       (truncate (log (length (tty-color-alist)) 2))))))
1120
1121 (defun display-color-cells (&optional display)
1122   "Return the number of color cells supported by DISPLAY."
1123   (let ((frame-type (framep-on-display display)))
1124     (cond
1125      ((memq frame-type '(x w32 mac))
1126       (x-display-color-cells display))
1127      ((eq frame-type 'pc)
1128       16)
1129      (t
1130       (tty-display-color-cells)))))
1131
1132 (defun display-visual-class (&optional display)
1133   "Returns the visual class of DISPLAY.
1134 The value is one of the symbols `static-gray', `gray-scale',
1135 `static-color', `pseudo-color', `true-color', or `direct-color'."
1136   (let ((frame-type (framep-on-display display)))
1137     (cond
1138      ((memq frame-type '(x w32 mac))
1139       (x-display-visual-class display))
1140      ((and (memq frame-type '(pc t))
1141            (tty-display-color-p display))
1142       'static-color)
1143      (t
1144       'static-gray))))
1145
1146 \f
1147 ;;;; Aliases for backward compatibility with Emacs 18.
1148 (defalias 'screen-height 'frame-height)
1149 (defalias 'screen-width 'frame-width)
1150
1151 (defun set-screen-width (cols &optional pretend)
1152   "Obsolete function to change the size of the screen to COLS columns.
1153 Optional second arg non-nil means that redisplay should use COLS columns
1154 but that the idea of the actual width of the frame should not be changed.
1155 This function is provided only for compatibility with Emacs 18; new code
1156 should use `set-frame-width instead'."
1157   (set-frame-width (selected-frame) cols pretend))
1158
1159 (defun set-screen-height (lines &optional pretend)
1160   "Obsolete function to change the height of the screen to LINES lines.
1161 Optional second arg non-nil means that redisplay should use LINES lines
1162 but that the idea of the actual height of the screen should not be changed.
1163 This function is provided only for compatibility with Emacs 18; new code
1164 should use `set-frame-height' instead."
1165   (set-frame-height (selected-frame) lines pretend))
1166
1167 (defun delete-other-frames (&optional frame)
1168   "Delete all frames except FRAME.
1169 If FRAME uses another frame's minibuffer, the minibuffer frame is
1170 left untouched.  FRAME nil or omitted means use the selected frame."
1171   (interactive)
1172   (unless frame
1173     (setq frame (selected-frame)))
1174   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1175          (frames (delq mini-frame (delq frame (frame-list)))))
1176     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1177     ;; signals an error when trying to delete a mini-frame that's
1178     ;; still in use by another frame.
1179     (dolist (frame frames)
1180       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1181         (delete-frame frame)))
1182     ;; Delete minibuffer-only frames.
1183     (dolist (frame frames)
1184       (when (eq (frame-parameter frame 'minibuffer) 'only)
1185         (delete-frame frame)))))
1186
1187 (make-obsolete 'screen-height 'frame-height) ;before 19.15
1188 (make-obsolete 'screen-width  'frame-width) ;before 19.15
1189 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1190 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1191
1192 ;; miscellaneous obsolescence declarations
1193 (defvaralias 'delete-frame-hook 'delete-frame-functions)
1194 (make-obsolete-variable 'delete-frame-hook 'delete-frame-functions "21.4")
1195
1196 \f
1197 ;; Highlighting trailing whitespace.
1198
1199 (make-variable-buffer-local 'show-trailing-whitespace)
1200
1201 (defcustom show-trailing-whitespace nil
1202   "*Non-nil means highlight trailing whitespace.
1203 This is done in the face `trailing-whitespace'."
1204   :tag "Highlight trailing whitespace."
1205   :type 'boolean
1206   :group 'font-lock)
1207
1208
1209 \f
1210 ;; Scrolling
1211
1212 (defgroup scrolling nil
1213   "Scrolling windows."
1214   :version "21.1"
1215   :group 'frames)
1216
1217 (defcustom auto-hscroll-mode t
1218   "*Allow or disallow automatic scrolling windows horizontally.
1219 If non-nil, windows are automatically scrolled horizontally to make
1220 point visible."
1221   :version "21.1"
1222   :type 'boolean
1223   :group 'scrolling)
1224 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1225
1226 \f
1227 ;; Blinking cursor
1228
1229 (defgroup cursor nil
1230   "Displaying text cursors."
1231   :version "21.1"
1232   :group 'frames)
1233
1234 (defcustom blink-cursor-delay 0.5
1235   "*Seconds of idle time after which cursor starts to blink."
1236   :tag "Delay in seconds."
1237   :type 'number
1238   :group 'cursor)
1239
1240 (defcustom blink-cursor-interval 0.5
1241   "*Length of cursor blink interval in seconds."
1242   :tag "Blink interval in seconds."
1243   :type 'number
1244   :group 'cursor)
1245
1246 (defvar blink-cursor-idle-timer nil
1247   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1248 The function `blink-cursor-start' is called when the timer fires.")
1249
1250 (defvar blink-cursor-timer nil
1251   "Timer started from `blink-cursor-start'.
1252 This timer calls `blink-cursor' every `blink-cursor-interval' seconds.")
1253
1254 (defvar blink-cursor-mode nil
1255   "Non-nil means blinking cursor is active.")
1256
1257 (defun blink-cursor-mode (arg)
1258   "Toggle blinking cursor mode.
1259 With a numeric argument, turn blinking cursor mode on iff ARG is positive.
1260 When blinking cursor mode is enabled, the cursor of the selected
1261 window blinks.
1262
1263 Note that this command is effective only when Emacs
1264 displays through a window system, because then Emacs does its own
1265 cursor display.  On a text-only terminal, this is not implemented."
1266   (interactive "P")
1267   (let ((on-p (if (null arg)
1268                   (not blink-cursor-mode)
1269                 (> (prefix-numeric-value arg) 0))))
1270     (if blink-cursor-idle-timer
1271         (cancel-timer blink-cursor-idle-timer))
1272     (if blink-cursor-timer
1273         (cancel-timer blink-cursor-timer))
1274     (setq blink-cursor-idle-timer nil
1275           blink-cursor-timer nil
1276           blink-cursor-mode nil)
1277     (if on-p
1278         (progn
1279           ;; Hide the cursor.
1280           ;(internal-show-cursor nil nil)
1281           (setq blink-cursor-idle-timer
1282                 (run-with-idle-timer blink-cursor-delay
1283                                      blink-cursor-delay
1284                                      'blink-cursor-start))
1285           (setq blink-cursor-mode t))
1286       (internal-show-cursor nil t))))
1287
1288 ;; Note that this is really initialized from startup.el before
1289 ;; the init-file is read.
1290
1291 (defcustom blink-cursor nil
1292   "*Non-nil means blinking cursor mode is active."
1293   :group 'cursor
1294   :tag "Blinking cursor"
1295   :type 'boolean
1296   :set #'(lambda (symbol value)
1297            (set-default symbol value)
1298            (blink-cursor-mode (or value 0))))
1299
1300 (defun blink-cursor-start ()
1301   "Timer function called from the timer `blink-cursor-idle-timer'.
1302 This starts the timer `blink-cursor-timer', which makes the cursor blink
1303 if appropriate.  It also arranges to cancel that timer when the next
1304 command starts, by installing a pre-command hook."
1305   (when (null blink-cursor-timer)
1306     (add-hook 'pre-command-hook 'blink-cursor-end)
1307     (internal-show-cursor nil nil)
1308     (setq blink-cursor-timer
1309           (run-with-timer blink-cursor-interval blink-cursor-interval
1310                           'blink-cursor-timer-function))))
1311
1312 (defun blink-cursor-timer-function ()
1313   "Timer function of timer `blink-cursor-timer'."
1314   (internal-show-cursor nil (not (internal-show-cursor-p))))
1315
1316 (defun blink-cursor-end ()
1317   "Stop cursor blinking.
1318 This is installed as a pre-command hook by `blink-cursor-start'.
1319 When run, it cancels the timer `blink-cursor-timer' and removes
1320 itself as a pre-command hook."
1321   (remove-hook 'pre-command-hook 'blink-cursor-end)
1322   (internal-show-cursor nil t)
1323   (cancel-timer blink-cursor-timer)
1324   (setq blink-cursor-timer nil))
1325
1326
1327 \f
1328 ;; Hourglass pointer
1329
1330 (defcustom display-hourglass t
1331   "*Non-nil means show an hourglass pointer when running under a window system."
1332   :tag "Hourglass pointer"
1333   :type 'boolean
1334   :group 'cursor)
1335
1336 (defcustom hourglass-delay 1
1337   "*Seconds to wait before displaying an hourglass pointer."
1338   :tag "Hourglass delay"
1339   :type 'number
1340   :group 'cursor)
1341
1342 \f
1343 (defcustom cursor-in-non-selected-windows t
1344   "*Non-nil means show a hollow box cursor in non-selected-windows.
1345 If nil, don't show a cursor except in the selected window.
1346 Use Custom to set this variable to get the display updated."
1347   :tag "Cursor in non-selected windows"
1348   :type 'boolean
1349   :group 'cursor
1350   :set #'(lambda (symbol value)
1351            (set-default symbol value)
1352            (force-mode-line-update t)))
1353
1354 \f
1355 ;;;; Key bindings
1356
1357 (define-key ctl-x-5-map "2" 'make-frame-command)
1358 (define-key ctl-x-5-map "1" 'delete-other-frames)
1359 (define-key ctl-x-5-map "0" 'delete-frame)
1360 (define-key ctl-x-5-map "o" 'other-frame)
1361
1362 (provide 'frame)
1363
1364 ;;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1365 ;;; frame.el ends here