configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.60)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" = yes; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" = yes; then
  88   if test "${with_kerberos}" != yes; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 if test "$with_hesiod" = yes; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 101
 102 OPTION_DEFAULT_ON([sync-input],[Process async input synchronously])
 103 if test "$with_sync_input" = yes; then
 104    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 105 fi
 106
 107 dnl FIXME currently it is not the last.
 108 dnl This should be the last --with option, because --with-x is
 109 dnl added later on when we find the path of X, and it's best to
 110 dnl keep them together visually.
 111 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 112  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 113 [         case "${withval}" in
 114             y | ye | yes )      val=gtk ;;
 115             n | no )            val=no  ;;
 116             l | lu | luc | luci | lucid )       val=lucid ;;
 117             a | at | ath | athe | athen | athena )      val=athena ;;
 118             m | mo | mot | moti | motif )       val=motif ;;
 119             g | gt | gtk  )     val=gtk ;;
 120             * )
 121 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 122 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 123 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 124             ;;
 125           esac
 126           with_x_toolkit=$val
 127 ])
 128
 129 dnl _ON results in a '--without' option in the --help output, so
 130 dnl the help text should refer to "don't compile", etc.
 131 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 132 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 133 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 134 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 135 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 136 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 137
 138 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 139 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 140 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 141 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 142
 143 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 144 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 145 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 146 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 147
 148 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 149 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 150
 151 dnl Can remove these in Emacs 24.
 152 AC_ARG_WITH([gtk],,
 153   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 154 specify a toolkit.]),,)
 155
 156 AC_ARG_WITH([gcc],,
 157   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 158   variable to specify a compiler.]),,)
 159
 160 AC_ARG_WITH([pkg-config-prog],dnl
 161 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 162                   [Path to pkg-config for finding GTK and librsvg])])
 163 if test "X${with_pkg_config_prog}" != X; then
 164    if test "${with_pkg_config_prog}" != yes; then
 165       PKG_CONFIG="${with_pkg_config_prog}"
 166    fi
 167 fi
 168
 169 AC_ARG_ENABLE(carbon-app,
 170 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 171                 [specify install directory for Emacs.app on Mac OS X
 172                  [DIR=/Application]])],
 173 [ carbon_appdir_x=${enableval}])
 174
 175 ## Enabled by default.
 176 AC_ARG_ENABLE(font-backend,
 177 [AS_HELP_STRING([--disable-font-backend],[don't compile font-backend support])],
 178       USE_FONT_BACKEND=$enableval,
 179       USE_FONT_BACKEND=yes)
 180
 181 AC_ARG_ENABLE(asserts,
 182 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 183       USE_XASSERTS=$enableval,
 184       USE_XASSERTS=no)
 185
 186 AC_ARG_ENABLE(maintainer-mode,
 187 [AS_HELP_STRING([--enable-maintainer-mode],
 188                 [enable make rules and dependencies not useful (and sometimes
 189                  confusing) to the casual installer])],
 190       USE_MAINTAINER_MODE=$enableval,
 191       USE_MAINTAINER_MODE=no)
 192 if test $USE_MAINTAINER_MODE = yes; then
 193   MAINT=
 194 else
 195   MAINT=#
 196 fi
 197 AC_SUBST(MAINT)
 198
 199 AC_ARG_ENABLE(locallisppath,
 200 [AS_HELP_STRING([--enable-locallisppath=PATH],
 201                 [directories Emacs should search for lisp files specific
 202                  to this site])],
 203 if test "${enableval}" = "no"; then
 204   locallisppath=
 205 elif test "${enableval}" != "yes"; then
 206   locallisppath=${enableval}
 207 fi)
 208
 209 #### Make srcdir absolute, if it isn't already.  It's important to
 210 #### avoid running the path through pwd unnecessarily, since pwd can
 211 #### give you automounter prefixes, which can go away.  We do all this
 212 #### so Emacs can find its files when run uninstalled.
 213 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 214 unset CDPATH
 215 case "${srcdir}" in
 216   /* ) ;;
 217   . )
 218     ## We may be able to use the $PWD environment variable to make this
 219     ## absolute.  But sometimes PWD is inaccurate.
 220     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 221     ## but that tested only for a well-formed and valid PWD,
 222     ## it did not object when PWD was well-formed and valid but just wrong.
 223     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 224     then
 225       srcdir="$PWD"
 226     else
 227       srcdir="`(cd ${srcdir}; pwd)`"
 228     fi
 229   ;;
 230   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 231 esac
 232
 233 #### Check if the source directory already has a configured system in it.
 234 if test `pwd` != `(cd ${srcdir} && pwd)` \
 235    && test -f "${srcdir}/src/config.h" ; then
 236   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 237    as a build directory right now; it has been configured in its own
 238    right.  To configure in another directory as well, you MUST
 239    use GNU make.  If you do not have GNU make, then you must
 240    now do `make distclean' in ${srcdir},
 241    and then run $0 again.]])
 242 fi
 243
 244 #### Given the configuration name, set machfile and opsysfile to the
 245 #### names of the m/*.h and s/*.h files we should use.
 246
 247 ### Canonicalize the configuration name.
 248
 249 AC_CANONICAL_HOST
 250 canonical=$host
 251 configuration=${host_alias-${build_alias-$host}}
 252
 253 dnl This used to use changequote, but, apart from `changequote is evil'
 254 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 255 dnl the great gob of text.  Thus it's not processed for possible expansion.
 256 dnl Just make sure the brackets remain balanced.
 257 dnl
 258 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 259 dnl indicated by comments.
 260 dnl quotation begins
 261 [
 262
 263 ### If you add support for a new configuration, add code to this
 264 ### switch statement to recognize your configuration name and select
 265 ### the appropriate operating system and machine description files.
 266
 267 ### You would hope that you could choose an m/*.h file pretty much
 268 ### based on the machine portion of the configuration name, and an s-
 269 ### file based on the operating system portion.  However, it turns out
 270 ### that each m/*.h file is pretty manufacturer-specific - for
 271 ### example hp9000s300.h is a 68000 machine;
 272 ### mips.h, pmax.h are all MIPS
 273 ### machines.  So we basically have to have a special case for each
 274 ### configuration name.
 275 ###
 276 ### As far as handling version numbers on operating systems is
 277 ### concerned, make sure things will fail in a fixable way.  If
 278 ### /etc/MACHINES doesn't say anything about version numbers, be
 279 ### prepared to handle anything reasonably.  If version numbers
 280 ### matter, be sure /etc/MACHINES says something about it.
 281 ###
 282 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 283 ### "System V Release 4"; he writes, "The old convention encouraged
 284 ### confusion between `system' and `release' levels'."
 285
 286 machine='' opsys='' unported=no
 287 case "${canonical}" in
 288
 289   ## FreeBSD ports
 290   *-*-freebsd* )
 291     opsys=freebsd
 292     case "${canonical}" in
 293       alpha*-*-freebsd*)        machine=alpha ;;
 294       arm*-*-freebsd*)          machine=arm ;;
 295       ia64-*-freebsd*)          machine=ia64 ;;
 296       sparc64-*-freebsd*)       machine=sparc ;;
 297       powerpc-*-freebsd*)       machine=macppc ;;
 298       i[3456]86-*-freebsd*)     machine=intel386 ;;
 299       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 300     esac
 301   ;;
 302
 303   ## FreeBSD kernel + glibc based userland
 304   *-*-kfreebsd*gnu* )
 305     opsys=gnu-kfreebsd
 306     case "${canonical}" in
 307       alpha*-*-kfreebsd*)       machine=alpha ;;
 308       ia64-*-kfreebsd*)         machine=ia64 ;;
 309       sparc64-*-kfreebsd*)      machine=sparc ;;
 310       powerpc-*-kfreebsd*)      machine=macppc ;;
 311       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 312       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 313     esac
 314   ;;
 315
 316   ## NetBSD ports
 317   *-*-netbsd* )
 318     opsys=netbsd
 319     if test -f /usr/lib/crti.o; then]
 320 dnl The close and open brackets here are because this section is quoted --
 321 dnl see the `changequote' comment above.
 322       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 323 [   fi
 324
 325     case "${canonical}" in
 326       alpha*-*-netbsd*) machine=alpha ;;
 327       i[3456]86-*-netbsd*) machine=intel386 ;;
 328       m68k-*-netbsd*)
 329                         # This is somewhat bogus.
 330                         machine=hp9000s300 ;;
 331       mips-*-netbsd*)   machine=pmax ;;
 332       mipsel-*-netbsd*) machine=pmax ;;
 333       mipseb-*-netbsd*) machine=pmax ;;
 334       powerpc-*-netbsd*) machine=macppc ;;
 335       sparc*-*-netbsd*) machine=sparc ;;
 336       vax-*-netbsd*)    machine=vax ;;
 337       arm-*-netbsd*)    machine=arm ;;
 338       x86_64-*-netbsd*) machine=amdx86-64 ;;
 339       hppa-*-netbsd*)   machine=hp800 ;;
 340     esac
 341   ;;
 342
 343   ## OpenBSD ports
 344   *-*-openbsd* )
 345     opsys=openbsd
 346     case "${canonical}" in
 347       alpha*-*-openbsd*)        machine=alpha ;;
 348       arm-*-openbsd*)          machine=arm ;;
 349       hppa-*-openbsd*)         machine=hp9000s300 ;;
 350       i386-*-openbsd*)         machine=intel386 ;;
 351       m68k-*-openbsd*)         machine=hp9000s300 ;;
 352       powerpc-*-openbsd*)      machine=macppc ;;
 353       sparc*-*-openbsd*)       machine=sparc ;;
 354       vax-*-openbsd*)          machine=vax ;;
 355       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 356     esac
 357   ;;
 358
 359   ## LynxOS ports
 360   *-*-lynxos* )
 361     opsys=lynxos
 362     case "${canonical}" in
 363       i[3456]86-*-lynxos*) machine=intel386 ;;
 364       powerpc-*-lynxos*) machine=powerpc ;;
 365     esac
 366   ;;
 367
 368   ## BSDI ports
 369   *-*-bsdi* )
 370     opsys=bsdi
 371     case "${canonical}" in
 372       i[345]86-*-bsdi*) machine=intel386 ;;
 373       sparc-*-bsdi*)  machine=sparc ;;
 374       powerpc-*-bsdi*)  machine=macppc ;;
 375     esac
 376     case "${canonical}" in
 377       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 378       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 379       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 380       *-*-bsdi3* )              opsys=bsdos3 ;;
 381       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 382     esac
 383   ;;
 384
 385   alpha*-*-linux-gnu* )
 386     machine=alpha opsys=gnu-linux
 387   ;;
 388
 389   arm*-*-linux-gnu* )
 390     machine=arm opsys=gnu-linux
 391   ;;
 392
 393   ## Apple Darwin / Mac OS X
 394   *-apple-darwin* )
 395     case "${canonical}" in
 396       i[3456]86-* )  machine=intel386 ;;
 397       powerpc-* )    machine=powermac ;;
 398       * )            unported=yes ;;
 399     esac
 400     opsys=darwin
 401     # Define CPP as follows to make autoconf work correctly.
 402     CPP="${CC-cc} -E -no-cpp-precomp"
 403     # Use fink packages if available.
 404     if test -d /sw/include && test -d /sw/lib; then
 405       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 406       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 407       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 408     fi
 409   ;;
 410
 411   ## Cubix QBx/386
 412   i[3456]86-cubix-sysv* )
 413     machine=intel386 opsys=usg5-3
 414   ;;
 415
 416   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 417     machine=pmax opsys=bsd4-2
 418   ;;
 419   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 420     machine=pmax opsys=bsd4-3
 421   ;;
 422   mips-dec-ultrix* )
 423     machine=pmax opsys=ultrix4-3
 424   ;;
 425   ## HP 9000 series 200 or 300
 426   m68*-hp-bsd* )
 427     machine=hp9000s300 opsys=bsd4-3
 428   ;;
 429   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 430   m68*-hp-hpux* )
 431     case "`uname -r`" in
 432       ## Someone's system reports A.B8.05 for this.
 433       ## I wonder what other possibilities there are.
 434       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 435       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 436       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 437       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 438       *) machine=hp9000s300 opsys=hpux ;;
 439     esac
 440   ;;
 441
 442   ## HP 9000 series 700 and 800, running HP/UX
 443   hppa*-hp-hpux7* )
 444     machine=hp800 opsys=hpux
 445   ;;
 446   hppa*-hp-hpux8* )
 447     machine=hp800 opsys=hpux8
 448   ;;
 449   hppa*-hp-hpux9shr* )
 450     machine=hp800 opsys=hpux9shr
 451   ;;
 452   hppa*-hp-hpux9* )
 453     machine=hp800 opsys=hpux9
 454   ;;
 455   hppa*-hp-hpux10.2* )
 456     machine=hp800 opsys=hpux10-20
 457   ;;
 458   hppa*-hp-hpux10* )
 459     machine=hp800 opsys=hpux10
 460   ;;
 461   hppa*-hp-hpux1[1-9]* )
 462     machine=hp800 opsys=hpux11
 463     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 464   ;;
 465
 466   hppa*-*-linux-gnu* )
 467     machine=hp800 opsys=gnu-linux
 468   ;;
 469
 470   ## HP 9000 series 700 and 800, running HP/UX
 471   hppa*-hp-hpux* )
 472     ## Cross-compilation?  Nah!
 473     case "`uname -r`" in
 474       ## Someone's system reports A.B8.05 for this.
 475       ## I wonder what other possibilities there are.
 476       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 477       *.08.* ) machine=hp800 opsys=hpux8 ;;
 478       *.09.* ) machine=hp800 opsys=hpux9 ;;
 479       *) machine=hp800 opsys=hpux10 ;;
 480     esac
 481   ;;
 482   hppa*-*-nextstep* )
 483     machine=hp800 opsys=nextstep
 484   ;;
 485
 486   ## IBM machines
 487   i370-ibm-aix*)
 488     machine=ibm370aix opsys=usg5-3
 489   ;;
 490   s390-*-linux-gnu* )
 491     machine=ibms390 opsys=gnu-linux
 492   ;;
 493   s390x-*-linux-gnu* )
 494     machine=ibms390x opsys=gnu-linux
 495   ;;
 496   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 497     machine=ibmrs6000 opsys=aix3-1
 498   ;;
 499   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 500     machine=ibmrs6000 opsys=aix3-2-5
 501   ;;
 502   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 503     machine=ibmrs6000 opsys=aix4-1
 504   ;;
 505   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 506     machine=ibmrs6000 opsys=aix4-2
 507   ;;
 508   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 515     machine=ibmrs6000 opsys=aix4-2
 516   ;;
 517   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 518     machine=ibmrs6000 opsys=aix4
 519   ;;
 520   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 521     machine=ibmrs6000 opsys=aix4-1
 522   ;;
 523   rs6000-ibm-aix* | powerpc-ibm-aix* )
 524     machine=ibmrs6000 opsys=aix3-2
 525   ;;
 526
 527   ## Prime EXL
 528   i[3456]86-prime-sysv* )
 529     machine=i386 opsys=usg5-3
 530   ;;
 531
 532   ## ncr machine running svr4.3.
 533   i[3456]86-ncr-sysv4.3 )
 534     machine=ncr386 opsys=usg5-4-3
 535   ;;
 536
 537   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 538   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 539   i[3456]86-ncr-sysv* )
 540     machine=ncr386 opsys=usg5-4-2
 541   ;;
 542
 543   ## Macintosh PowerPC
 544   powerpc*-*-linux-gnu* )
 545     machine=macppc opsys=gnu-linux
 546   ;;
 547
 548   ## Workstations sold by MIPS
 549   ## This is not necessarily all workstations using the MIPS processor -
 550   ## Irises are produced by SGI, and DECstations by DEC.
 551
 552   mips-mips-bsd* )
 553     machine=mips opsys=bsd4-3
 554   ;;
 555   mips-mips-* )
 556     machine=mips opsys=usg5-2-2
 557   ;;
 558
 559   ## NeXT
 560   m68*-next-* | m68k-*-nextstep* )
 561     machine=m68k opsys=nextstep
 562   ;;
 563
 564   ## NEC EWS4800
 565   mips-nec-sysv4*)
 566   machine=ews4800 opsys=ux4800
 567   ;;
 568
 569   ## Siemens Nixdorf
 570   mips-siemens-sysv* | mips-sni-sysv*)
 571     machine=mips-siemens opsys=usg5-4
 572     NON_GNU_CC=/usr/ccs/bin/cc
 573     NON_GNU_CPP=/usr/ccs/lib/cpp
 574   ;;
 575
 576   ## Silicon Graphics machines
 577   ## Iris 4D
 578   mips-sgi-irix6.5 )
 579     machine=iris4d opsys=irix6-5
 580     # Without defining _LANGUAGE_C, things get masked out in the headers
 581     # so that, for instance, grepping for `free' in stdlib.h fails and
 582     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 583     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 584     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 585   ;;
 586
 587   ## Suns
 588   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 589     machine=sparc opsys=gnu-linux
 590   ;;
 591
 592   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 593     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 594     | rs6000-*-solaris2*)
 595     case "${canonical}" in
 596       i[3456]86-*-* )     machine=intel386 ;;
 597       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 598       powerpcle* )      machine=powerpcle ;;
 599       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 600       sparc* )          machine=sparc ;;
 601       * )               unported=yes ;;
 602     esac
 603     case "${canonical}" in
 604       *-sunos5.3* | *-solaris2.3* )
 605                 opsys=sol2-3
 606                 NON_GNU_CPP=/usr/ccs/lib/cpp
 607                 ;;
 608       *-sunos5.4* | *-solaris2.4* )
 609                 opsys=sol2-4
 610                 NON_GNU_CPP=/usr/ccs/lib/cpp
 611                 RANLIB="ar -ts"
 612                 ;;
 613       *-sunos5.5* | *-solaris2.5* )
 614                 opsys=sol2-5
 615                 NON_GNU_CPP=/usr/ccs/lib/cpp
 616                 RANLIB="ar -ts"
 617                 ;;
 618       *-sunos5.6* | *-solaris2.6* )
 619                 opsys=sol2-6
 620                 NON_GNU_CPP=/usr/ccs/lib/cpp
 621                 RANLIB="ar -ts"
 622                 ;;
 623       *-sunos5* | *-solaris* )
 624                 opsys=sol2-6
 625                 emacs_check_sunpro_c=yes
 626                 NON_GNU_CPP=/usr/ccs/lib/cpp
 627                 ;;
 628       *                   ) opsys=bsd4-2   ;;
 629     esac
 630     ## Watch out for a compiler that we know will not work.
 631     case "${canonical}" in
 632      *-solaris* | *-sunos5* )
 633                 if [ "x$CC" = x/usr/ucb/cc ]; then
 634                   ## /usr/ucb/cc doesn't work;
 635                   ## we should find some other compiler that does work.
 636                   unset CC
 637                 fi
 638                 ;;
 639       *) ;;
 640     esac
 641   ;;
 642   sparc-*-nextstep* )
 643     machine=sparc opsys=nextstep
 644   ;;
 645
 646   ## Tandem Integrity S2
 647   mips-tandem-sysv* )
 648     machine=tandem-s2 opsys=usg5-3
 649   ;;
 650
 651   ## Vaxen.
 652   vax-dec-* )
 653     machine=vax
 654     case "${canonical}" in
 655       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 656       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 657       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 658       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 659       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 660       *-vms* )                                          opsys=vms ;;
 661       * )                                               unported=yes
 662     esac
 663   ;;
 664
 665   ## IA-64
 666   ia64*-*-linux* )
 667     machine=ia64 opsys=gnu-linux
 668   ;;
 669
 670   ## Intel 386 machines where we don't care about the manufacturer
 671   i[3456]86-*-* )
 672     machine=intel386
 673     case "${canonical}" in
 674       *-cygwin )                opsys=cygwin ;;
 675       *-darwin* )               opsys=darwin
 676                                 CPP="${CC-cc} -E -no-cpp-precomp"
 677                                 ;;
 678       *-linux-gnu* )            opsys=gnu-linux ;;
 679       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 680       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 681       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 682       *-386bsd* )               opsys=386bsd ;;
 683       *-nextstep* )             opsys=nextstep ;;
 684       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 685     esac
 686   ;;
 687
 688   ## m68k Linux-based GNU system
 689   m68k-*-linux-gnu* )
 690     machine=m68k opsys=gnu-linux
 691   ;;
 692
 693   ## Mips Linux-based GNU system
 694   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 695     machine=mips opsys=gnu-linux
 696   ;;
 697
 698   ## UXP/DS
 699   sparc-fujitsu-sysv4* )
 700     machine=sparc opsys=uxpds
 701     NON_GNU_CPP=/usr/ccs/lib/cpp
 702     RANLIB="ar -ts"
 703   ;;
 704
 705   ## AMD x86-64 Linux-based GNU system
 706   x86_64-*-linux-gnu* )
 707     machine=amdx86-64 opsys=gnu-linux
 708   ;;
 709
 710   ## Tensilica Xtensa Linux-based GNU system
 711   xtensa*-*-linux-gnu* )
 712     machine=xtensa opsys=gnu-linux
 713     ;;
 714
 715   * )
 716     unported=yes
 717   ;;
 718 esac
 719
 720 ### If the code above didn't choose an operating system, just choose
 721 ### an operating system based on the configuration name.  You really
 722 ### only want to use this when you have no idea what the right
 723 ### operating system is; if you know what operating systems a machine
 724 ### runs, it's cleaner to make it explicit in the case statement
 725 ### above.
 726 if test x"${opsys}" = x; then
 727   case "${canonical}" in
 728     *-gnu* )                            opsys=gnu ;;
 729     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 730     *-bsd4.2 )                          opsys=bsd4-2 ;;
 731     *-bsd4.3 )                          opsys=bsd4-3 ;;
 732     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 733     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 734     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 735     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 736     *-sysv4.2uw* )                      opsys=unixware ;;
 737     *-sysv5uw* )                        opsys=unixware ;;
 738     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 739     *-sysv4.1* | *-sysvr4.1* )
 740         NON_GNU_CPP=/usr/lib/cpp
 741         opsys=usg5-4 ;;
 742     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 743         if [ x$NON_GNU_CPP = x ]; then
 744           if [ -f /usr/ccs/lib/cpp ]; then
 745             NON_GNU_CPP=/usr/ccs/lib/cpp
 746           else
 747             NON_GNU_CPP=/lib/cpp
 748           fi
 749         fi
 750         opsys=usg5-4-2 ;;
 751     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 752     * )
 753       unported=yes
 754     ;;
 755   esac
 756 fi
 757
 758 ### Tests for sytems that we beleive are obsolete and should be desupported.
 759
 760 case "${machine}" in
 761      pmax | hp9000s300 | ibm370aix | ncr386 | ews4800 | mips-siemens | powerpcle | tandem-s2 )
 762           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 763           echo "and it is planned to be desupported in the next version of Emacs"
 764           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 765           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 766           echo "exit 33 line.  After that you can run configure again and 'complete' the build."
 767           exit 33
 768           ;;
 769 esac
 770
 771 case "${opsys}" in
 772      bsd386 | bsdos2-1 |  bsdos2 | bsdos3 | bsdos4 | bsd4-1 | bsd4-2 | bsd4-3 | usg5-0 | usg5-2-2 | usg5-2 | usg5-3 | ultrix4-3 | 386bsd | hpux | hpux8 | hpux9 | hpux9shr | hpux10 | aix3-1 | aix3-2-5 | aix3-2 | aix4-1 | nextstep | ux4800 | uxpds | uxpv )
 773           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 774           echo "and it is planned to be desupported in the next version of Emacs"
 775           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 776           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 777           echo "'exit 44' line.  After that you can run 'configure' again and complete the build."
 778           exit 44
 779           ;;
 780 esac
 781
 782 ]
 783 dnl quotation ends
 784
 785 if test $unported = yes; then
 786   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 787 Check `etc/MACHINES' for recognized configuration names.])
 788 fi
 789
 790 machfile="m/${machine}.h"
 791 opsysfile="s/${opsys}.h"
 792
 793
 794 #### Choose a compiler.
 795 test -n "$CC" && cc_specified=yes
 796
 797 # Save the value of CFLAGS that the user specified.
 798 SPECIFIED_CFLAGS="$CFLAGS"
 799
 800 dnl Sets GCC=yes if using gcc.
 801 AC_PROG_CC
 802
 803 # On Suns, sometimes $CPP names a directory.
 804 if test -n "$CPP" && test -d "$CPP"; then
 805   CPP=
 806 fi
 807
 808 ## If not using gcc, and on Solaris, and no CPP specified, see if
 809 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 810 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 811  test x"$CPP" = x; then
 812   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 813   AC_CACHE_VAL(emacs_cv_sunpro_c,
 814   [AC_TRY_LINK([],
 815 [#ifndef __SUNPRO_C
 816 fail;
 817 #endif
 818 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 819   AC_MSG_RESULT($emacs_cv_sunpro_c)
 820
 821   if test x"$emacs_cv_sunpro_c" = xyes; then
 822     NON_GNU_CPP="$CC -E -Xs"
 823   fi
 824 fi
 825
 826 #### Some systems specify a CPP to use unless we are using GCC.
 827 #### Now that we know whether we are using GCC, we can decide whether
 828 #### to use that one.
 829 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 830 then
 831   CPP="$NON_GNU_CPP"
 832 fi
 833
 834 #### Some systems specify a CC to use unless we are using GCC.
 835 #### Now that we know whether we are using GCC, we can decide whether
 836 #### to use that one.
 837 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 838   test x$cc_specified != xyes
 839 then
 840   CC="$NON_GNU_CC"
 841 fi
 842
 843 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 844 then
 845   CC="$CC $GCC_TEST_OPTIONS"
 846 fi
 847
 848 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 849 then
 850   CC="$CC $NON_GCC_TEST_OPTIONS"
 851 fi
 852
 853 dnl checks for Unix variants
 854 AC_USE_SYSTEM_EXTENSIONS
 855
 856 ### Use -Wno-pointer-sign if the compiler supports it
 857 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 858 SAVE_CFLAGS="$CFLAGS"
 859 CFLAGS="$CFLAGS -Wno-pointer-sign"
 860 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 861 if test $has_option = yes; then
 862    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 863 fi
 864 AC_MSG_RESULT($has_option)
 865 CFLAGS="$SAVE_CFLAGS"
 866 unset has_option
 867 unset SAVE_CFLAGS
 868
 869 #### Some other nice autoconf tests.
 870
 871 dnl checks for programs
 872 AC_PROG_LN_S
 873 AC_PROG_CPP
 874 AC_PROG_INSTALL
 875 if test "x$RANLIB" = x; then
 876   AC_PROG_RANLIB
 877 fi
 878 AC_PATH_PROG(INSTALL_INFO, install-info)
 879 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 880 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 881 dnl Don't use GZIP, which is used by gzip for additional parameters.
 882 AC_PATH_PROG(GZIP_PROG, gzip)
 883
 884
 885 ## Need makeinfo >= 4.6 (?) to build the manuals.
 886 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 887 dnl By this stage, configure has already checked for egrep and set EGREP,
 888 dnl or exited with an error if no egrep was found.
 889 if test "$MAKEINFO" != "no" && \
 890   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 891    MAKEINFO=no
 892 fi
 893
 894 if test "$MAKEINFO" = "no"; then
 895   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 896 fi
 897
 898
 899 dnl Add our options to ac_link now, after it is set up.
 900
 901 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 902 then
 903   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 904 fi
 905
 906 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 907 then
 908   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 909 fi
 910
 911 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 912 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 913 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 914 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 915 dnl if not built to support GNU ld.
 916
 917 late_LDFLAGS=$LDFLAGS
 918 if test "$GCC" = yes; then
 919   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 920 else
 921   LDFLAGS="$LDFLAGS -znocombreloc"
 922 fi
 923
 924 AC_MSG_CHECKING([for -znocombreloc])
 925 AC_LINK_IFELSE([main(){return 0;}],
 926   [AC_MSG_RESULT(yes)],
 927   LDFLAGS=$late_LDFLAGS
 928   [AC_MSG_RESULT(no)])
 929
 930 #### Extract some information from the operating system and machine files.
 931
 932 AC_CHECKING([the machine- and system-dependent files to find out
 933  - which libraries the lib-src programs will want, and
 934  - whether the GNU malloc routines are usable])
 935
 936 ### First figure out CFLAGS (which we use for running the compiler here)
 937 ### and REAL_CFLAGS (which we use for real compilation).
 938 ### The two are the same except on a few systems, where they are made
 939 ### different to work around various lossages.  For example,
 940 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 941 ### as implying static linking.
 942
 943 ### If the CFLAGS env var is specified, we use that value
 944 ### instead of the default.
 945
 946 ### It's not important that this name contain the PID; you can't run
 947 ### two configures in the same directory and have anything work
 948 ### anyway.
 949 tempcname="conftest.c"
 950
 951 echo '
 952 #include "'${srcdir}'/src/'${opsysfile}'"
 953 #include "'${srcdir}'/src/'${machfile}'"
 954 #ifndef LIBS_MACHINE
 955 #define LIBS_MACHINE
 956 #endif
 957 #ifndef LIBS_SYSTEM
 958 #define LIBS_SYSTEM
 959 #endif
 960 #ifndef C_SWITCH_SYSTEM
 961 #define C_SWITCH_SYSTEM
 962 #endif
 963 #ifndef C_SWITCH_MACHINE
 964 #define C_SWITCH_MACHINE
 965 #endif
 966 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 967 configure___ c_switch_system=C_SWITCH_SYSTEM
 968 configure___ c_switch_machine=C_SWITCH_MACHINE
 969
 970 #ifndef LIB_X11_LIB
 971 #define LIB_X11_LIB -lX11
 972 #endif
 973
 974 #ifndef LIBX11_SYSTEM
 975 #define LIBX11_SYSTEM
 976 #endif
 977 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 978
 979 #ifdef UNEXEC
 980 configure___ unexec=UNEXEC
 981 #else
 982 configure___ unexec=unexec.o
 983 #endif
 984
 985 #ifdef SYSTEM_MALLOC
 986 configure___ system_malloc=yes
 987 #else
 988 configure___ system_malloc=no
 989 #endif
 990
 991 #ifdef USE_MMAP_FOR_BUFFERS
 992 configure___ use_mmap_for_buffers=yes
 993 #else
 994 configure___ use_mmap_for_buffers=no
 995 #endif
 996
 997 #ifndef C_DEBUG_SWITCH
 998 #define C_DEBUG_SWITCH -g
 999 #endif
1000
1001 #ifndef C_OPTIMIZE_SWITCH
1002 #ifdef __GNUC__
1003 #define C_OPTIMIZE_SWITCH -O2
1004 #else
1005 #define C_OPTIMIZE_SWITCH -O
1006 #endif
1007 #endif
1008
1009 #ifndef C_WARNINGS_SWITCH
1010 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1011 #endif
1012
1013 #ifndef LD_SWITCH_MACHINE
1014 #define LD_SWITCH_MACHINE
1015 #endif
1016
1017 #ifndef LD_SWITCH_SYSTEM
1018 #define LD_SWITCH_SYSTEM
1019 #endif
1020
1021 #ifndef LD_SWITCH_X_SITE_AUX
1022 #define LD_SWITCH_X_SITE_AUX
1023 #endif
1024
1025 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1026 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1027
1028 #ifdef THIS_IS_CONFIGURE
1029
1030 /* Get the CFLAGS for tests in configure.  */
1031 #ifdef __GNUC__
1032 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1033 #else
1034 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1035 #endif
1036
1037 #else /* not THIS_IS_CONFIGURE */
1038
1039 /* Get the CFLAGS for real compilation.  */
1040 #ifdef __GNUC__
1041 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1042 #else
1043 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1044 #endif
1045
1046 #endif /* not THIS_IS_CONFIGURE */
1047 ' > ${tempcname}
1048
1049 # The value of CPP is a quoted variable reference, so we need to do this
1050 # to get its actual value...
1051 CPP=`eval "echo $CPP"`
1052 [eval `${CPP} -Isrc ${tempcname} \
1053        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1054 if test "x$SPECIFIED_CFLAGS" = x; then
1055   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1056          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1057 else
1058   REAL_CFLAGS="$CFLAGS"
1059 fi]
1060 rm ${tempcname}
1061
1062 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1063
1064 ### Make sure subsequent tests use flags consistent with the build flags.
1065
1066 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1067   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1068 else
1069   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1070 fi
1071
1072 dnl For AC_FUNC_GETLOADAVG, at least:
1073 AC_CONFIG_LIBOBJ_DIR(src)
1074
1075 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1076 AC_SYS_LARGEFILE
1077
1078
1079 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1080 ### be located in either /usr/lib64 or /usr/lib.
1081 case "${canonical}" in
1082   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1083     if test -d /usr/lib64; then
1084       AC_DEFINE(HAVE_LIB64_DIR, 1,
1085         [Define to 1 if the directory /usr/lib64 exists.])
1086 fi
1087 esac
1088
1089 dnl This function defintion taken from Gnome 2.0
1090 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1091 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1092 dnl also defines GSTUFF_PKG_ERRORS on error
1093 AC_DEFUN([PKG_CHECK_MODULES], [
1094   succeeded=no
1095
1096   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1097
1098   if test "$PKG_CONFIG" = "no" ; then
1099      ifelse([$4], , [AC_MSG_ERROR([
1100       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1101   else
1102      PKG_CONFIG_MIN_VERSION=0.9.0
1103      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1104         AC_MSG_CHECKING(for $2)
1105
1106         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1107             AC_MSG_RESULT(yes)
1108             succeeded=yes
1109
1110             AC_MSG_CHECKING($1_CFLAGS)
1111             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1112             AC_MSG_RESULT($$1_CFLAGS)
1113
1114             AC_MSG_CHECKING($1_LIBS)
1115             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1116             AC_MSG_RESULT($$1_LIBS)
1117         else
1118             AC_MSG_RESULT(no)
1119             $1_CFLAGS=""
1120             $1_LIBS=""
1121             ## If we have a custom action on failure, don't print errors, but
1122             ## do set a variable so people can do so.
1123             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1124             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1125         fi
1126
1127         AC_SUBST($1_CFLAGS)
1128         AC_SUBST($1_LIBS)
1129      else
1130         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1131         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1132      fi
1133   fi
1134
1135   if test $succeeded = yes; then
1136      ifelse([$3], , :, [$3])
1137   else
1138      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1139   fi
1140 ])
1141
1142
1143 if test "${with_sound}" != "no"; then
1144   # Sound support for GNU/Linux and the free BSDs.
1145   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1146   # Emulation library used on NetBSD.
1147   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1148   AC_SUBST(LIBSOUND)
1149
1150   ALSA_REQUIRED=1.0.0
1151   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1152   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1153   if test $HAVE_ALSA = yes; then
1154     SAVE_CFLAGS="$CFLAGS"
1155     SAVE_LDFLAGS="$LDFLAGS"
1156     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1157     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1158     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1159                     emacs_alsa_normal=yes,
1160                     emacs_alsa_normal=no)
1161     if test "$emacs_alsa_normal" != yes; then
1162       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1163                      [snd_lib_error_set_handler (0);],
1164                      emacs_alsa_subdir=yes,
1165                      emacs_alsa_subdir=no)
1166       if test "$emacs_alsa_subdir" != yes; then
1167         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1168       fi
1169       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1170     fi
1171
1172     CFLAGS="$SAVE_CFLAGS"
1173     LDFLAGS="$SAVE_LDFLAGS"
1174     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1175     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1176     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1177   fi
1178   AC_SUBST(CFLAGS_SOUND)
1179 fi
1180
1181 dnl checks for header files
1182 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1183   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1184   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1185   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1186   sys/utsname.h pwd.h)
1187
1188 AC_MSG_CHECKING(if personality LINUX32 can be set)
1189 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1190                emacs_cv_personality_linux32=yes,
1191                emacs_cv_personality_linux32=no)
1192 AC_MSG_RESULT($emacs_cv_personality_linux32)
1193
1194 if test $emacs_cv_personality_linux32 = yes; then
1195   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1196             [Define to 1 if personality LINUX32 can be set.])
1197 fi
1198
1199 dnl On Solaris 8 there's a compilation warning for term.h because
1200 dnl it doesn't define `bool'.
1201 AC_CHECK_HEADERS(term.h, , , -)
1202 AC_HEADER_STDC
1203 AC_HEADER_TIME
1204 AC_CHECK_DECLS([sys_siglist])
1205 if test $ac_cv_have_decl_sys_siglist != yes; then
1206   # For Tru64, at least:
1207   AC_CHECK_DECLS([__sys_siglist])
1208   if test $ac_cv_have_decl___sys_siglist = yes; then
1209     AC_DEFINE(sys_siglist, __sys_siglist,
1210               [Define to any substitute for sys_siglist.])
1211   fi
1212 fi
1213 AC_HEADER_SYS_WAIT
1214
1215 dnl Some systems have utime.h but don't declare the struct anyplace.
1216 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1217 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1218 #include <sys/time.h>
1219 #include <time.h>
1220 #else
1221 #ifdef HAVE_SYS_TIME_H
1222 #include <sys/time.h>
1223 #else
1224 #include <time.h>
1225 #endif
1226 #endif
1227 #ifdef HAVE_UTIME_H
1228 #include <utime.h>
1229 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1230   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1231 if test $emacs_cv_struct_utimbuf = yes; then
1232   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1233 fi
1234
1235 dnl checks for typedefs
1236 AC_TYPE_SIGNAL
1237
1238 dnl Check for speed_t typedef.
1239 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1240   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1241     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1242 if test $emacs_cv_speed_t = yes; then
1243   AC_DEFINE(HAVE_SPEED_T, 1,
1244            [Define to 1 if `speed_t' is declared by <termios.h>.])
1245 fi
1246
1247 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1248 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1249 #include <sys/time.h>
1250 #include <time.h>
1251 #else
1252 #ifdef HAVE_SYS_TIME_H
1253 #include <sys/time.h>
1254 #else
1255 #include <time.h>
1256 #endif
1257 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1258   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1259 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1260 if test $emacs_cv_struct_timeval = yes; then
1261   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1262 fi
1263
1264 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1265 AC_TRY_COMPILE([#include <math.h>],
1266 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1267   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1268 HAVE_EXCEPTION=$emacs_cv_struct_exception
1269 if test $emacs_cv_struct_exception != yes; then
1270   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1271 fi
1272
1273 AC_CHECK_HEADERS(sys/socket.h)
1274 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1275 #if HAVE_SYS_SOCKET_H
1276 #include <sys/socket.h>
1277 #endif])
1278
1279 dnl checks for structure members
1280 AC_STRUCT_TM
1281 AC_STRUCT_TIMEZONE
1282 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1283                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1284                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1285                 [#include <time.h>])
1286 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1287                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1288                   struct ifreq.ifr_addr], , ,
1289                  [AC_INCLUDES_DEFAULT
1290 #if HAVE_SYS_SOCKET_H
1291 #include <sys/socket.h>
1292 #endif
1293 #if HAVE_NET_IF_H
1294 #include <net/if.h>
1295 #endif])
1296
1297 dnl checks for compiler characteristics
1298
1299 dnl Testing __STDC__ to determine prototype support isn't good enough.
1300 dnl DEC C, for instance, doesn't define it with default options, and
1301 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1302 dnl and void *.
1303 AC_C_PROTOTYPES
1304 AC_C_VOLATILE
1305 AC_C_CONST
1306 dnl This isn't useful because we can't turn on use of `inline' unless
1307 dnl the compiler groks `extern inline'.
1308 dnl AC_C_INLINE
1309 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1310   [AC_TRY_COMPILE(, [void * foo;],
1311                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1312 if test $emacs_cv_void_star = yes; then
1313   AC_DEFINE(POINTER_TYPE, void)
1314 else
1315   AC_DEFINE(POINTER_TYPE, char)
1316 fi
1317 AH_TEMPLATE(POINTER_TYPE,
1318             [Define as `void' if your compiler accepts `void *'; otherwise
1319              define as `char'.])dnl
1320
1321
1322
1323 dnl This could be used for targets which can have both byte sexes.
1324 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1325 dnl AC_C_BIGENDIAN
1326
1327 dnl check for Make feature
1328 AC_PROG_MAKE_SET
1329
1330 dnl checks for operating system services
1331 AC_SYS_LONG_FILE_NAMES
1332
1333 #### Choose a window system.
1334
1335 AC_PATH_X
1336 if test "$no_x" = yes; then
1337   window_system=none
1338 else
1339   window_system=x11
1340 fi
1341
1342 if test "${x_libraries}" != NONE; then
1343   if test -n "${x_libraries}"; then
1344     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1345     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1346   fi
1347   x_default_search_path=""
1348   x_search_path=${x_libraries}
1349   if test -z "${x_search_path}"; then
1350     x_search_path=/usr/lib
1351   fi
1352   for x_library in `echo ${x_search_path}: | \
1353                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1354     x_search_path="\
1355 ${x_library}/X11/%L/%T/%N%C%S:\
1356 ${x_library}/X11/%l/%T/%N%C%S:\
1357 ${x_library}/X11/%T/%N%C%S:\
1358 ${x_library}/X11/%L/%T/%N%S:\
1359 ${x_library}/X11/%l/%T/%N%S:\
1360 ${x_library}/X11/%T/%N%S"
1361     if test x"${x_default_search_path}" = x; then
1362       x_default_search_path=${x_search_path}
1363     else
1364       x_default_search_path="${x_search_path}:${x_default_search_path}"
1365     fi
1366   done
1367 fi
1368 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1369   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1370 fi
1371
1372 if test x"${x_includes}" = x; then
1373   bitmapdir=/usr/include/X11/bitmaps
1374 else
1375   # accumulate include directories that have X11 bitmap subdirectories
1376   bmd_acc="dummyval"
1377   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1378     if test -d "${bmd}/X11/bitmaps"; then
1379       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1380     fi
1381     if test -d "${bmd}/bitmaps"; then
1382       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1383     fi
1384   done
1385   if test ${bmd_acc} != "dummyval"; then
1386     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1387   fi
1388 fi
1389
1390 HAVE_CARBON=no
1391 if test "${with_carbon}" != no; then
1392   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1393 fi
1394 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1395   if test "${with_carbon+set}" != set \
1396      && test "${carbon_appdir_x+set}" != set; then
1397     for var in with_x with_x_toolkit with_xim \
1398                with_xpm with_jpeg with_tiff with_gif with_png; do
1399       if eval test \"\${$var+set}\" = set; then
1400         HAVE_CARBON=no
1401         break
1402       fi
1403     done
1404   fi
1405 fi
1406 if test "${HAVE_CARBON}" = yes; then
1407   window_system=mac
1408 fi
1409
1410 case "${window_system}" in
1411   x11 )
1412     HAVE_X_WINDOWS=yes
1413     HAVE_X11=yes
1414     case "${with_x_toolkit}" in
1415       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1416       motif ) USE_X_TOOLKIT=MOTIF ;;
1417       gtk ) with_gtk=yes
1418 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1419 dnl USE_X_TOOLKIT is set.
1420             USE_X_TOOLKIT=none ;;
1421       no ) USE_X_TOOLKIT=none ;;
1422 dnl If user did not say whether to use a toolkit, make this decision later:
1423 dnl use the toolkit if we have gtk, or X11R5 or newer.
1424       * ) USE_X_TOOLKIT=maybe ;;
1425     esac
1426   ;;
1427   mac | none )
1428     HAVE_X_WINDOWS=no
1429     HAVE_X11=no
1430     USE_X_TOOLKIT=none
1431   ;;
1432 esac
1433
1434 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1435    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1436    if test "$HAVE_XSERVER" = true ||
1437       test -n "$DISPLAY" ||
1438       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1439         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1440 were found.  You should install the relevant development files for X
1441 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1442 sure you have development files for image handling, i.e.
1443 tiff, gif, jpeg, png and xpm.
1444 If you are sure you want Emacs compiled without X window support, pass
1445   --without-x
1446 to configure.])
1447    fi
1448 fi
1449
1450 ### If we're using X11, we should use the X menu package.
1451 HAVE_MENUS=no
1452 case ${HAVE_X11} in
1453   yes ) HAVE_MENUS=yes ;;
1454 esac
1455
1456 ### Compute the unexec source name from the object name.
1457 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1458
1459 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1460 # Assume not, until told otherwise.
1461 GNU_MALLOC=yes
1462 doug_lea_malloc=yes
1463 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1464 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1465 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1466                emacs_cv_var___after_morecore_hook,
1467 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1468   emacs_cv_var___after_morecore_hook=yes,
1469   emacs_cv_var___after_morecore_hook=no)])
1470 if test $emacs_cv_var___after_morecore_hook = no; then
1471   doug_lea_malloc=no
1472 fi
1473 if test "${system_malloc}" = "yes"; then
1474   GNU_MALLOC=no
1475   GNU_MALLOC_reason="
1476     (The GNU allocators don't work with this system configuration.)"
1477 fi
1478 if test "$doug_lea_malloc" = "yes" ; then
1479   if test "$GNU_MALLOC" = yes ; then
1480     GNU_MALLOC_reason="
1481       (Using Doug Lea's new malloc from the GNU C Library.)"
1482   fi
1483   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1484             [Define to 1 if you are using the GNU C Library.])
1485 fi
1486
1487 if test x"${REL_ALLOC}" = x; then
1488   REL_ALLOC=${GNU_MALLOC}
1489 fi
1490
1491 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1492 dnl the system configuration file (s/*.h) to turn the use of mmap
1493 dnl in the relocating allocator on.
1494
1495 AC_FUNC_MMAP
1496 if test $use_mmap_for_buffers = yes; then
1497   REL_ALLOC=no
1498 fi
1499
1500 LIBS="$libsrc_libs $LIBS"
1501
1502 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1503 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1504 AC_CHECK_LIB(dnet, dnet_ntoa)
1505 dnl This causes -lresolv to get used in subsequent tests,
1506 dnl which causes failures on some systems such as HPUX 9.
1507 dnl AC_CHECK_LIB(resolv, gethostbyname)
1508
1509 dnl FIXME replace main with a function we actually want from this library.
1510 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1511
1512 AC_CHECK_LIB(pthreads, cma_open)
1513
1514 dnl Check for need for bigtoc support on IBM AIX
1515
1516 case ${host_os} in
1517 aix*)
1518   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1519     case $GCC in
1520     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1521     *) gdb_cv_bigtoc=-bbigtoc ;;
1522     esac
1523
1524     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1525     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1526   ])
1527   ;;
1528 esac
1529
1530 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1531 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1532 # REAL_CPPFLAGS later on.
1533
1534 REAL_CPPFLAGS="$CPPFLAGS"
1535
1536 if test "${HAVE_X11}" = "yes"; then
1537   DEFS="$C_SWITCH_X_SITE $DEFS"
1538   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1539   LIBS="$LIBX $LIBS"
1540   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1541   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1542
1543   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1544   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1545   # but it's more convenient here to set LD_RUN_PATH
1546   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1547   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1548     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1549     export LD_RUN_PATH
1550   fi
1551
1552   if test "${opsys}" = "gnu-linux"; then
1553     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1554     AC_TRY_LINK([],
1555      [XOpenDisplay ("foo");],
1556      [xlinux_first_failure=no],
1557      [xlinux_first_failure=yes])
1558     if test "${xlinux_first_failure}" = "yes"; then
1559       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1560       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1561       OLD_CPPFLAGS="$CPPFLAGS"
1562       OLD_LIBS="$LIBS"
1563       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1564       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1565       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1566       LIBS="$LIBS -b i486-linuxaout"
1567       AC_TRY_LINK([],
1568        [XOpenDisplay ("foo");],
1569        [xlinux_second_failure=no],
1570        [xlinux_second_failure=yes])
1571       if test "${xlinux_second_failure}" = "yes"; then
1572         # If we get the same failure with -b, there is no use adding -b.
1573         # So take it out.  This plays safe.
1574         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1575         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1576         CPPFLAGS="$OLD_CPPFLAGS"
1577         LIBS="$OLD_LIBS"
1578         AC_MSG_RESULT(no)
1579       else
1580         AC_MSG_RESULT(yes)
1581       fi
1582     else
1583       AC_MSG_RESULT(no)
1584     fi
1585   fi
1586
1587   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1588   # header files included from there.
1589   AC_MSG_CHECKING(for Xkb)
1590   AC_TRY_LINK([#include <X11/Xlib.h>
1591 #include <X11/XKBlib.h>],
1592         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1593         emacs_xkb=yes, emacs_xkb=no)
1594   AC_MSG_RESULT($emacs_xkb)
1595   if test $emacs_xkb = yes; then
1596     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1597   fi
1598
1599   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1600 XScreenNumberOfScreen XSetWMProtocols)
1601 fi
1602
1603 if test "${window_system}" = "x11"; then
1604   AC_MSG_CHECKING(X11 version 6)
1605   AC_CACHE_VAL(emacs_cv_x11_version_6,
1606   [AC_TRY_LINK([#include <X11/Xlib.h>],
1607 [#if XlibSpecificationRelease < 6
1608 fail;
1609 #endif
1610 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1611   if test $emacs_cv_x11_version_6 = yes; then
1612     AC_MSG_RESULT(6 or newer)
1613     AC_DEFINE(HAVE_X11R6, 1,
1614               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1615   else
1616     AC_MSG_RESULT(before 6)
1617   fi
1618 fi
1619
1620
1621 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1622 HAVE_RSVG=no
1623 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1624   if test "${with_rsvg}" != "no"; then
1625     RSVG_REQUIRED=2.0.0
1626     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1627
1628     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1629     AC_SUBST(RSVG_CFLAGS)
1630     AC_SUBST(RSVG_LIBS)
1631
1632     if test ".${RSVG_CFLAGS}" != "."; then
1633       HAVE_RSVG=yes
1634       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1635       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1636       LIBS="$RSVG_LIBS $LIBS"
1637     fi
1638   fi
1639 fi
1640
1641
1642 HAVE_GTK=no
1643 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1644   GLIB_REQUIRED=2.6
1645   GTK_REQUIRED=2.6
1646   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1647
1648   dnl Checks for libraries.
1649   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1650   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1651      AC_MSG_ERROR($GTK_PKG_ERRORS)
1652   fi
1653 fi
1654
1655
1656 if test x"$pkg_check_gtk" = xyes; then
1657
1658   AC_SUBST(GTK_CFLAGS)
1659   AC_SUBST(GTK_LIBS)
1660   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1661   CFLAGS="$CFLAGS $GTK_CFLAGS"
1662   LIBS="$GTK_LIBS $LIBS"
1663   dnl Try to compile a simple GTK program.
1664   GTK_COMPILES=no
1665   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1666   if test "${GTK_COMPILES}" != "yes"; then
1667     if test "$USE_X_TOOLKIT" != "maybe"; then
1668       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1669     fi
1670   else
1671     HAVE_GTK=yes
1672     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1673     USE_X_TOOLKIT=none
1674     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1675       :
1676     else
1677       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1678        closing open displays.  This is no problem if you just use
1679        one display, but if you use more than one and close one of them
1680        Emacs may crash.]])
1681       sleep 3
1682     fi
1683   fi
1684
1685 fi
1686
1687
1688 if test "${HAVE_GTK}" = "yes"; then
1689
1690   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1691   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1692   if test "$with_toolkit_scroll_bars" != no; then
1693     with_toolkit_scroll_bars=yes
1694   fi
1695
1696   dnl  Check if we can use multiple displays with this GTK version.
1697   dnl  If gdk_display_open exists, assume all others are there also.
1698   HAVE_GTK_MULTIDISPLAY=no
1699   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1700   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1701     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1702               [Define to 1 if GTK can handle more than one display.])
1703   fi
1704
1705   dnl  Check if we have the old file selection dialog.
1706   dnl  If gdk_display_open exists, assume all others are there also.
1707   HAVE_GTK_FILE_SELECTION=no
1708   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1709
1710   dnl  Check if we have the new file chooser dialog
1711   dnl  If gdk_display_open exists, assume all others are there also.
1712   HAVE_GTK_FILE_CHOOSER=no
1713   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1714
1715   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1716      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1717     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1718               [Define to 1 if GTK has both file selection and chooser dialog.])
1719   fi
1720
1721   dnl Check if pthreads are available.  Emacs only needs this when using
1722   dnl gtk_file_chooser under Gnome.
1723   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1724     HAVE_GTK_AND_PTHREAD=no
1725     AC_CHECK_HEADERS(pthread.h)
1726     if test "$ac_cv_header_pthread_h"; then
1727       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1728     fi
1729     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1730       case "${canonical}" in
1731         *-hpux*) ;;
1732         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1733       esac
1734       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1735                [Define to 1 if you have GTK and pthread (-lpthread).])
1736     fi
1737   fi
1738 fi
1739
1740 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1741 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1742 dnl also not configured.
1743 HAVE_DBUS=no
1744 if test "${with_dbus}" = "yes"; then
1745    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1746    if test "$HAVE_DBUS" = yes; then
1747       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1748    fi
1749 fi
1750
1751 dnl Do not put whitespace before the #include statements below.
1752 dnl Older compilers (eg sunos4 cc) choke on it.
1753 HAVE_XAW3D=no
1754 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1755   if test "$with_xaw3d" != no; then
1756     AC_MSG_CHECKING(for xaw3d)
1757     AC_CACHE_VAL(emacs_cv_xaw3d,
1758     [AC_TRY_LINK([
1759 #include <X11/Intrinsic.h>
1760 #include <X11/Xaw3d/Simple.h>],
1761       [],
1762       emacs_cv_xaw3d=yes,
1763       emacs_cv_xaw3d=no)])
1764   else
1765     emacs_cv_xaw3d=no
1766   fi
1767   if test $emacs_cv_xaw3d = yes; then
1768     AC_MSG_RESULT([yes; using Lucid toolkit])
1769     USE_X_TOOLKIT=LUCID
1770     HAVE_XAW3D=yes
1771     AC_DEFINE(HAVE_XAW3D, 1,
1772               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1773   else
1774     AC_MSG_RESULT(no)
1775     AC_MSG_CHECKING(for libXaw)
1776     AC_CACHE_VAL(emacs_cv_xaw,
1777     [AC_TRY_LINK([
1778 #include <X11/Intrinsic.h>
1779 #include <X11/Xaw/Simple.h>],
1780       [],
1781       emacs_cv_xaw=yes,
1782       emacs_cv_xaw=no)])
1783     if test $emacs_cv_xaw = yes; then
1784       AC_MSG_RESULT([yes; using Lucid toolkit])
1785       USE_X_TOOLKIT=LUCID
1786     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1787       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1788     else
1789       AC_MSG_RESULT([no; do not use toolkit by default])
1790       USE_X_TOOLKIT=none
1791     fi
1792   fi
1793 fi
1794
1795 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1796
1797 if test "${USE_X_TOOLKIT}" != "none"; then
1798   AC_MSG_CHECKING(X11 toolkit version)
1799   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1800   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1801 [#if XtSpecificationRelease < 6
1802 fail;
1803 #endif
1804 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1805   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1806   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1807     AC_MSG_RESULT(6 or newer)
1808     AC_DEFINE(HAVE_X11XTR6, 1,
1809               [Define to 1 if you have the X11R6 or newer version of Xt.])
1810   else
1811     AC_MSG_RESULT(before 6)
1812   fi
1813
1814 dnl If using toolkit, check whether libXmu.a exists.
1815 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1816   OLDLIBS="$LIBS"
1817   if test x$HAVE_X11XTR6 = xyes; then
1818     LIBS="-lXt -lSM -lICE $LIBS"
1819   else
1820     LIBS="-lXt $LIBS"
1821   fi
1822   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1823   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1824 fi
1825
1826 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1827 if test "${HAVE_X11}" = "yes"; then
1828   if test "${USE_X_TOOLKIT}" != "none"; then
1829     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1830   fi
1831 fi
1832
1833 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1834   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1835   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1836     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1837 int x = 5;
1838 #else
1839 Motif version prior to 2.1.
1840 #endif],
1841     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1842   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1843   if test $emacs_cv_motif_version_2_1 = yes; then
1844     HAVE_LIBXP=no
1845     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1846               [Define to 1 if you have Motif 2.1 or newer.])
1847     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1848     if test ${HAVE_LIBXP} = yes; then
1849       AC_DEFINE(HAVE_LIBXP, 1,
1850                 [Define to 1 if you have the Xp library (-lXp).])
1851     fi
1852   else
1853     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1854     # We put this in CFLAGS temporarily to precede other -I options
1855     # that might be in CFLAGS temporarily.
1856     # We put this in CPPFLAGS where it precedes the other -I options.
1857     OLD_CPPFLAGS=$CPPFLAGS
1858     OLD_CFLAGS=$CFLAGS
1859     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1860     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1861     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1862       [int x = 5;],
1863       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1864     if test $emacs_cv_lesstif = yes; then
1865       # Make sure this -I option remains in CPPFLAGS after it is set
1866       # back to REAL_CPPFLAGS.
1867       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1868       # have those other -I options anyway.  Ultimately, having this
1869       # directory ultimately in CPPFLAGS will be enough.
1870       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1871       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1872     else
1873       CFLAGS=$OLD_CFLAGS
1874       CPPFLAGS=$OLD_CPPFLAGS
1875     fi
1876   fi
1877 fi
1878
1879 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1880 dnl using Motif or Xaw3d is available, and unless
1881 dnl --with-toolkit-scroll-bars=no was specified.
1882
1883 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1884             [Define to 1 if we should use toolkit scroll bars.])dnl
1885 USE_TOOLKIT_SCROLL_BARS=no
1886 if test "${with_toolkit_scroll_bars}" != "no"; then
1887   if test "${USE_X_TOOLKIT}" != "none"; then
1888     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1889       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1890       HAVE_XAW3D=no
1891       USE_TOOLKIT_SCROLL_BARS=yes
1892     elif test "${HAVE_XAW3D}" = "yes"; then
1893       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1894       USE_TOOLKIT_SCROLL_BARS=yes
1895     fi
1896   elif test "${HAVE_GTK}" = "yes"; then
1897     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1898     USE_TOOLKIT_SCROLL_BARS=yes
1899   elif test "${HAVE_CARBON}" = "yes"; then
1900     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1901     USE_TOOLKIT_SCROLL_BARS=yes
1902   fi
1903 fi
1904
1905 dnl See if XIM is available.
1906 AC_TRY_COMPILE([
1907           #include <X11/Xlib.h>
1908           #include <X11/Xresource.h>],
1909          [XIMProc  callback;],
1910          [HAVE_XIM=yes
1911          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1912          HAVE_XIM=no)
1913
1914 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1915
1916 if test "${with_xim}" != "no"; then
1917   AC_DEFINE(USE_XIM, 1,
1918             [Define to 1 if we should use XIM, if it is available.])
1919 fi
1920
1921
1922 if test "${HAVE_XIM}" != "no"; then
1923   late_CFLAGS=$CFLAGS
1924   if test "$GCC" = yes; then
1925     CFLAGS="$CFLAGS --pedantic-errors"
1926   fi
1927   AC_TRY_COMPILE([
1928 #include <X11/Xlib.h>
1929 #include <X11/Xresource.h>],
1930 [Display *display;
1931 XrmDatabase db;
1932 char *res_name;
1933 char *res_class;
1934 XIMProc  callback;
1935 XPointer *client_data;
1936 #ifndef __GNUC__
1937 /* If we're not using GCC, it's probably not XFree86, and this is
1938    probably right, but we can't use something like --pedantic-errors.  */
1939 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1940                                            char*, XIMProc, XPointer*);
1941 #endif
1942 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1943    client_data);],
1944     [emacs_cv_arg6_star=yes])
1945   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1946          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1947 either XPointer or XPointer*.])dnl
1948   if test "$emacs_cv_arg6_star" = yes; then
1949     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1950   else
1951     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1952   fi
1953   CFLAGS=$late_CFLAGS
1954 fi
1955
1956 ### Start of font-backend section.
1957 if test "${HAVE_X11}" != "yes"; then
1958   USE_FONT_BACKEND=no
1959 fi
1960
1961 if test "${USE_FONT_BACKEND}" = "yes"; then
1962   AC_DEFINE(USE_FONT_BACKEND, 1, [Define to 1 if we should use font-backend.])
1963
1964   ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1965   HAVE_XFT=maybe
1966   if test "x${with_freetype}" = "xno"; then
1967     with_xft="no";
1968   fi
1969   if test "x${with_xft}" != "xno"; then
1970
1971     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1972     if test "$HAVE_XFT" != no; then
1973       OLD_CPPFLAGS="$CPPFLAGS"
1974       OLD_CFLAGS="$CFLAGS"
1975       OLD_LIBS="$LIBS"
1976       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1977       CFLAGS="$CFLAGS $XFT_CFLAGS"
1978       LIBS="$XFT_LIBS $LIBS"
1979       AC_CHECK_HEADER(X11/Xft/Xft.h,
1980         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1981
1982       if test "${HAVE_XFT}" = "yes"; then
1983         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1984         AC_SUBST(XFT_LIBS)
1985         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1986       else
1987         CPPFLAGS="$OLD_CPPFLAGS"
1988         CFLAGS="$OLD_CFLAGS"
1989         LIBS="$OLD_LIBS"
1990       fi                        # "${HAVE_XFT}" = "yes"
1991     fi                          # "$HAVE_XFT" != no
1992   fi                            # "x${with_xft}" != "xno"
1993
1994   dnl For the "Does Emacs use" message at the end.
1995   if test "$HAVE_XFT" != "yes"; then
1996      HAVE_XFT=no
1997   fi
1998
1999
2000   HAVE_FREETYPE=no
2001   ### Use -lfreetype if available, unless `--with-freetype=no'.
2002   if test "${HAVE_XFT}" = "yes"; then
2003     dnl As we use Xft, we anyway use freetype.
2004     dnl In this case, there's no need of additional CFLAGS and LIBS.
2005     HAVE_FREETYPE=yes
2006   elif test "x${with_freetype}" != "xno"; then
2007
2008     PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2009     if test "${HAVE_FREETYPE}" = "yes"; then
2010       PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2011       if test "${HAVE_FC}" = "no"; then
2012         dnl Without fontconfig, we can't use freetype at the moment.
2013         HAVE_FREETYPE=no
2014       fi
2015     fi
2016   fi
2017
2018   HAVE_LIBOTF=no
2019   if test "${HAVE_FREETYPE}" = "yes"; then
2020     AC_DEFINE(HAVE_FREETYPE, 1,
2021               [Define to 1 if using the freetype and fontconfig libraries.])
2022     if test "${with_libotf}" != "no"; then
2023       PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2024                         HAVE_LIBOTF=no)
2025       if test "$HAVE_LIBOTF" = "yes"; then
2026         AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2027       fi
2028     fi
2029 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2030 dnl Does the new font backend require it, or can it work without it?
2031   fi
2032
2033   HAVE_M17N_FLT=no
2034   if test "${with_m17n_flt}" != "no"; then
2035     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2036     if test "$HAVE_M17N_FLT" = "yes"; then
2037       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2038     fi
2039   fi
2040
2041   AC_SUBST(FREETYPE_CFLAGS)
2042   AC_SUBST(FREETYPE_LIBS)
2043   AC_SUBST(FONTCONFIG_CFLAGS)
2044   AC_SUBST(FONTCONFIG_LIBS)
2045   AC_SUBST(LIBOTF_CFLAGS)
2046   AC_SUBST(LIBOTF_LIBS)
2047   AC_SUBST(M17N_FLT_CFLAGS)
2048   AC_SUBST(M17N_FLT_LIBS)
2049
2050 fi                              # "${USE_FONT_BACKEND}" = "yes"
2051 ### End of font-backend section.
2052
2053 ### Use -lXpm if available, unless `--with-xpm=no'.
2054 HAVE_XPM=no
2055 if test "${HAVE_X11}" = "yes"; then
2056   if test "${with_xpm}" != "no"; then
2057     AC_CHECK_HEADER(X11/xpm.h,
2058       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2059     if test "${HAVE_XPM}" = "yes"; then
2060       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2061       AC_EGREP_CPP(no_return_alloc_pixels,
2062       [#include "X11/xpm.h"
2063 #ifndef XpmReturnAllocPixels
2064 no_return_alloc_pixels
2065 #endif
2066       ], HAVE_XPM=no, HAVE_XPM=yes)
2067
2068       if test "${HAVE_XPM}" = "yes"; then
2069         AC_MSG_RESULT(yes)
2070       else
2071         AC_MSG_RESULT(no)
2072       fi
2073     fi
2074   fi
2075
2076   if test "${HAVE_XPM}" = "yes"; then
2077     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2078   fi
2079 fi
2080
2081 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2082 HAVE_JPEG=no
2083 if test "${HAVE_X11}" = "yes"; then
2084   if test "${with_jpeg}" != "no"; then
2085     dnl Checking for jpeglib.h can lose because of a redefinition of
2086     dnl  HAVE_STDLIB_H.
2087     AC_CHECK_HEADER(jerror.h,
2088       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2089   fi
2090
2091   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2092   if test "${HAVE_JPEG}" = "yes"; then
2093     AC_DEFINE(HAVE_JPEG)
2094     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2095         [#include <jpeglib.h>
2096          version=JPEG_LIB_VERSION
2097 ],
2098         [AC_DEFINE(HAVE_JPEG)],
2099         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2100         HAVE_JPEG=no])
2101   fi
2102 fi
2103
2104 ### Use -lpng if available, unless `--with-png=no'.
2105 HAVE_PNG=no
2106 if test "${HAVE_X11}" = "yes"; then
2107   if test "${with_png}" != "no"; then
2108     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2109     # in /usr/include/libpng.
2110     AC_CHECK_HEADERS(png.h libpng/png.h)
2111     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2112       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2113     fi
2114   fi
2115
2116   if test "${HAVE_PNG}" = "yes"; then
2117     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2118   fi
2119 fi
2120
2121 ### Use -ltiff if available, unless `--with-tiff=no'.
2122 HAVE_TIFF=no
2123 if test "${HAVE_X11}" = "yes"; then
2124   if test "${with_tiff}" != "no"; then
2125     AC_CHECK_HEADER(tiffio.h,
2126       [tifflibs="-lz -lm"
2127       # At least one tiff package requires the jpeg library.
2128       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2129       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2130   fi
2131
2132   if test "${HAVE_TIFF}" = "yes"; then
2133     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2134   fi
2135 fi
2136
2137 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2138 HAVE_GIF=no
2139 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2140   AC_CHECK_HEADER(gif_lib.h,
2141 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2142 # Earlier versions can crash Emacs.
2143     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2144
2145   if test "$HAVE_GIF" = yes; then
2146       ac_gif_lib_name="-lgif"
2147   fi
2148
2149 # If gif_lib.h but no libgif, try libungif.
2150   if test x"$try_libungif" = xyes; then
2151     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2152
2153     if test "$HAVE_GIF" = yes; then
2154       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2155       ac_gif_lib_name="-lungif"
2156     fi
2157   fi
2158
2159   if test "${HAVE_GIF}" = "yes"; then
2160     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2161   fi
2162 fi
2163
2164 dnl Check for required libraries.
2165 if test "${HAVE_X11}" = "yes"; then
2166   MISSING=""
2167   WITH_NO=""
2168   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2169     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2170   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2171     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2172   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2173     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2174   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2175     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2176   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2177     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2178
2179   if test "X${MISSING}" != X; then
2180     AC_MSG_ERROR([The following required libraries were not found:
2181     $MISSING
2182 Maybe some development libraries/packages are missing?
2183 If you don't want to link with them give
2184     $WITH_NO
2185 as options to configure])
2186   fi
2187 fi
2188
2189 ### Use -lgpm if available, unless `--with-gpm=no'.
2190 HAVE_GPM=no
2191 if test "${with_gpm}" != "no"; then
2192   AC_CHECK_HEADER(gpm.h,
2193     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2194 fi
2195
2196 if test "${HAVE_GPM}" = "yes"; then
2197   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2198 fi
2199
2200 dnl Check for malloc/malloc.h on darwin
2201 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2202
2203 ### Use Mac OS X Carbon API to implement GUI.
2204 if test "${HAVE_CARBON}" = "yes"; then
2205   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2206   ## Specify the install directory
2207   carbon_appdir=
2208   if test "${carbon_appdir_x}" != ""; then
2209     case ${carbon_appdir_x} in
2210       y | ye | yes)  carbon_appdir=/Applications ;;
2211       * ) carbon_appdir=${carbon_appdir_x} ;;
2212     esac
2213   fi
2214   # We also have mouse menus.
2215   HAVE_MENUS=yes
2216 fi
2217
2218 ### Use session management (-lSM -lICE) if available
2219 HAVE_X_SM=no
2220 if test "${HAVE_X11}" = "yes"; then
2221   AC_CHECK_HEADER(X11/SM/SMlib.h,
2222     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2223
2224   if test "${HAVE_X_SM}" = "yes"; then
2225     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2226     case "$LIBS" in
2227       *-lSM*) ;;
2228       *)      LIBS="-lSM -lICE $LIBS" ;;
2229     esac
2230   fi
2231 fi
2232
2233 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2234 AC_CACHE_CHECK(whether netdb declares h_errno,
2235                emacs_cv_netdb_declares_h_errno,
2236 [AC_TRY_LINK([#include <netdb.h>],
2237   [return h_errno;],
2238   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2239 if test $emacs_cv_netdb_declares_h_errno = yes; then
2240   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2241 fi
2242
2243 AC_FUNC_ALLOCA
2244
2245 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2246 dnl FIXME is there an autoconf test that does the right thing, without
2247 dnl needing to call A_M_E afterwards?
2248 if test x"$ac_cv_func_alloca_works" != xyes; then
2249    AC_MSG_ERROR( [a system implementation of alloca is required] )
2250 fi
2251
2252 # fmod, logb, and frexp are found in -lm on most systems.
2253 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2254 AC_CHECK_LIB(m, sqrt)
2255
2256 # Check for mail-locking functions in a "mail" library.  Probably this should
2257 # have the same check as for liblockfile below.
2258 AC_CHECK_LIB(mail, maillock)
2259 dnl Debian, at least:
2260 AC_CHECK_LIB(lockfile, maillock)
2261 # If we have the shared liblockfile, assume we must use it for mail
2262 # locking (e.g. Debian).  If we couldn't link against liblockfile
2263 # (no liblockfile.a installed), ensure that we don't need to.
2264 if test "$ac_cv_lib_lockfile_maillock" = no; then
2265   dnl This works for files generally, not just executables.
2266   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2267   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2268                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2269   if test $ac_cv_prog_liblockfile = yes; then
2270     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2271 This probably means that movemail could lose mail.
2272 There may be a `development' package to install containing liblockfile.])
2273   else :
2274   fi
2275 fi
2276 AC_CHECK_FUNCS(touchlock)
2277 AC_CHECK_HEADERS(maillock.h)
2278
2279 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2280 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2281 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2282 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2283 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2284 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2285 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2286 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2287 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2288
2289 AC_CHECK_HEADERS(sys/un.h)
2290
2291 AC_FUNC_MKTIME
2292 if test "$ac_cv_func_working_mktime" = no; then
2293   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2294 fi
2295
2296 AC_FUNC_GETLOADAVG
2297
2298 AC_FUNC_FSEEKO
2299
2300 # Configure getopt.
2301 m4_include([m4/getopt.m4])
2302 gl_GETOPT_IFELSE([
2303   gl_GETOPT_SUBSTITUTE_HEADER
2304   gl_PREREQ_GETOPT
2305   GETOPTOBJS='getopt.o getopt1.o'
2306 ])
2307 AC_SUBST(GETOPTOBJS)
2308
2309 AC_FUNC_GETPGRP
2310
2311 AC_FUNC_STRFTIME
2312
2313 # UNIX98 PTYs.
2314 AC_CHECK_FUNCS(grantpt)
2315
2316 # PTY-related GNU extensions.
2317 AC_CHECK_FUNCS(getpt)
2318
2319 # Check this now, so that we will NOT find the above functions in ncurses.
2320 # That is because we have not set up to link ncurses in lib-src.
2321 # It's better to believe a function is not available
2322 # than to expect to find it in ncurses.
2323 AC_CHECK_LIB(ncurses, tparm)
2324
2325 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2326
2327 resolv=no
2328 AC_TRY_LINK([#include <netinet/in.h>
2329 #include <arpa/nameser.h>
2330 #include <resolv.h>],
2331     [return res_init();],
2332     have_res_init=yes, have_res_init=no)
2333 if test "$have_res_init" = no; then
2334   OLIBS="$LIBS"
2335   LIBS="$LIBS -lresolv"
2336   AC_MSG_CHECKING(for res_init with -lresolv)
2337   AC_TRY_LINK([#include <netinet/in.h>
2338 #include <arpa/nameser.h>
2339 #include <resolv.h>],
2340     [return res_init();],
2341     have_res_init=yes, have_res_init=no)
2342   AC_MSG_RESULT($have_res_init)
2343   if test "$have_res_init" = yes ; then
2344     resolv=yes
2345   fi
2346   LIBS="$OLIBS"
2347 fi
2348
2349 if test "$have_res_init" = yes; then
2350   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2351 fi
2352
2353 # Do we need the Hesiod library to provide the support routines?
2354 if test "$with_hesiod" = yes ; then
2355   # Don't set $LIBS here -- see comments above.
2356   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2357      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2358                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2359   if test "$resolv" = yes ; then
2360     RESOLVLIB=-lresolv
2361   else
2362     RESOLVLIB=
2363   fi
2364   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2365         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2366                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2367         :, $RESOLVLIB)])
2368 fi
2369
2370 # Do we need libresolv (due to res_init or Hesiod)?
2371 if test "$resolv" = yes ; then
2372   AC_DEFINE(HAVE_LIBRESOLV, 1,
2373             [Define to 1 if you have the resolv library (-lresolv).])
2374 fi
2375
2376 # These tell us which Kerberos-related libraries to use.
2377 if test "${with_kerberos+set}" = set; then
2378   AC_CHECK_LIB(com_err, com_err)
2379   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2380   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2381   AC_CHECK_LIB(krb5, krb5_init_context)
2382   if test "${with_kerberos5+set}" != set; then
2383     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2384                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2385     AC_CHECK_LIB(krb4, krb_get_cred,,
2386                  [AC_CHECK_LIB(krb, krb_get_cred)])
2387   fi
2388
2389   if test "${with_kerberos5+set}" = set; then
2390     AC_CHECK_HEADERS(krb5.h)
2391   else
2392     AC_CHECK_HEADERS(des.h,,
2393                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2394                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2395     AC_CHECK_HEADERS(krb.h,,
2396                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2397                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2398   fi
2399   AC_CHECK_HEADERS(com_err.h)
2400 fi
2401
2402 # Solaris requires -lintl if you want strerror (which calls dgettext)
2403 # to return localized messages.
2404 AC_CHECK_LIB(intl, dgettext)
2405
2406 AC_MSG_CHECKING(whether localtime caches TZ)
2407 AC_CACHE_VAL(emacs_cv_localtime_cache,
2408 [if test x$ac_cv_func_tzset = xyes; then
2409 AC_TRY_RUN([#include <time.h>
2410 extern char **environ;
2411 unset_TZ ()
2412 {
2413   char **from, **to;
2414   for (to = from = environ; (*to = *from); from++)
2415     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2416       to++;
2417 }
2418 char TZ_GMT0[] = "TZ=GMT0";
2419 char TZ_PST8[] = "TZ=PST8";
2420 main()
2421 {
2422   time_t now = time ((time_t *) 0);
2423   int hour_GMT0, hour_unset;
2424   if (putenv (TZ_GMT0) != 0)
2425     exit (1);
2426   hour_GMT0 = localtime (&now)->tm_hour;
2427   unset_TZ ();
2428   hour_unset = localtime (&now)->tm_hour;
2429   if (putenv (TZ_PST8) != 0)
2430     exit (1);
2431   if (localtime (&now)->tm_hour == hour_GMT0)
2432     exit (1);
2433   unset_TZ ();
2434   if (localtime (&now)->tm_hour != hour_unset)
2435     exit (1);
2436   exit (0);
2437 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2438 [# If we have tzset, assume the worst when cross-compiling.
2439 emacs_cv_localtime_cache=yes])
2440 else
2441         # If we lack tzset, report that localtime does not cache TZ,
2442         # since we can't invalidate the cache if we don't have tzset.
2443         emacs_cv_localtime_cache=no
2444 fi])dnl
2445 AC_MSG_RESULT($emacs_cv_localtime_cache)
2446 if test $emacs_cv_localtime_cache = yes; then
2447   AC_DEFINE(LOCALTIME_CACHE, 1,
2448             [Define to 1 if localtime caches TZ.])
2449 fi
2450
2451 if test "x$HAVE_TIMEVAL" = xyes; then
2452   AC_CHECK_FUNCS(gettimeofday)
2453   if test $ac_cv_func_gettimeofday = yes; then
2454     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2455                    emacs_cv_gettimeofday_two_arguments,
2456     [AC_TRY_COMPILE([
2457 #ifdef TIME_WITH_SYS_TIME
2458 #include <sys/time.h>
2459 #include <time.h>
2460 #else
2461 #ifdef HAVE_SYS_TIME_H
2462 #include <sys/time.h>
2463 #else
2464 #include <time.h>
2465 #endif
2466 #endif],
2467       [struct timeval time;
2468        gettimeofday (&time, 0);],
2469       emacs_cv_gettimeofday_two_arguments=yes,
2470       emacs_cv_gettimeofday_two_arguments=no)])
2471     if test $emacs_cv_gettimeofday_two_arguments = no; then
2472       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2473                 [Define to 1 if gettimeofday accepts only one argument.])
2474     fi
2475   fi
2476 fi
2477
2478 ok_so_far=yes
2479 AC_CHECK_FUNC(socket, , ok_so_far=no)
2480 if test $ok_so_far = yes; then
2481   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2482 fi
2483 if test $ok_so_far = yes; then
2484   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2485 fi
2486 if test $ok_so_far = yes; then
2487 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2488   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2489             [Define to 1 if you have inet sockets.])
2490 fi
2491
2492 AC_CHECK_HEADERS(sys/ioctl.h)
2493
2494 if test -f /usr/lpp/X11/bin/smt.exp; then
2495   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2496             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2497 fi
2498
2499 AC_MSG_CHECKING(whether system supports dynamic ptys)
2500 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2501   AC_MSG_RESULT(yes)
2502   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2503 else
2504   AC_MSG_RESULT(no)
2505 fi
2506
2507 AC_FUNC_FORK
2508
2509 dnl Adapted from Haible's version.
2510 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2511   [AC_TRY_LINK([#include <langinfo.h>],
2512     [char* cs = nl_langinfo(CODESET);],
2513     emacs_cv_langinfo_codeset=yes,
2514     emacs_cv_langinfo_codeset=no)
2515   ])
2516 if test $emacs_cv_langinfo_codeset = yes; then
2517   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2518     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2519 fi
2520
2521 AC_CHECK_TYPES(size_t)
2522
2523 AC_TYPE_MBSTATE_T
2524
2525 dnl Restrict could probably be used effectively other than in regex.c.
2526 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2527   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2528                   emacs_cv_c_restrict=yes,
2529                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2530                                   emacs_cv_c_restrict=__restrict,
2531                                   emacs_cv_c_restrict=no)])])
2532 case "$emacs_cv_c_restrict" in
2533   yes) emacs_restrict=restrict;;
2534   no) emacs_restrict="";;
2535   *) emacs_restrict="$emacs_cv_c_restrict";;
2536 esac
2537 if test "$emacs_restrict" != __restrict; then
2538   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2539     [Define to compiler's equivalent of C99 restrict keyword.
2540      Don't define if equivalent is `__restrict'.])
2541 fi
2542
2543 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2544   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2545                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2546 if test "$emacs_cv_c_restrict_arr" = yes; then
2547   AC_DEFINE(__restrict_arr, __restrict,
2548     [Define to compiler's equivalent of C99 restrict keyword in array
2549      declarations.  Define as empty for no equivalent.])
2550 fi
2551
2552 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2553 dnl how the tty code is related to POSIX and/or other versions of termios.
2554 dnl The following looks like a useful start.
2555 dnl
2556 dnl AC_SYS_POSIX_TERMIOS
2557 dnl if test $ac_cv_sys_posix_termios = yes; then
2558 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2559 dnl                                and macros for terminal control.])
2560 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2561 dnl fi
2562
2563 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2564
2565 # Set up the CFLAGS for real compilation, so we can substitute it.
2566 CFLAGS="$REAL_CFLAGS"
2567 CPPFLAGS="$REAL_CPPFLAGS"
2568
2569 #### Find out which version of Emacs this is.
2570 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2571          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2572 if test x"${version}" = x; then
2573   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2574 fi
2575
2576 ### Specify what sort of things we'll be editing into Makefile and config.h.
2577 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2578 AC_SUBST(version)
2579 AC_SUBST(configuration)
2580 AC_SUBST(canonical)
2581 AC_SUBST(srcdir)
2582 AC_SUBST(prefix)
2583 AC_SUBST(exec_prefix)
2584 AC_SUBST(bindir)
2585 AC_SUBST(datadir)
2586 AC_SUBST(sharedstatedir)
2587 AC_SUBST(libexecdir)
2588 AC_SUBST(mandir)
2589 AC_SUBST(infodir)
2590 AC_SUBST(lispdir)
2591 AC_SUBST(locallisppath)
2592 AC_SUBST(lisppath)
2593 AC_SUBST(x_default_search_path)
2594 AC_SUBST(etcdir)
2595 AC_SUBST(archlibdir)
2596 AC_SUBST(docdir)
2597 AC_SUBST(bitmapdir)
2598 AC_SUBST(gamedir)
2599 AC_SUBST(gameuser)
2600 AC_SUBST(c_switch_system)
2601 AC_SUBST(c_switch_machine)
2602 AC_SUBST(LD_SWITCH_X_SITE)
2603 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2604 AC_SUBST(C_SWITCH_X_SITE)
2605 AC_SUBST(CFLAGS)
2606 AC_SUBST(X_TOOLKIT_TYPE)
2607 AC_SUBST(machfile)
2608 AC_SUBST(opsysfile)
2609 AC_SUBST(GETLOADAVG_LIBS)
2610 AC_SUBST(carbon_appdir)
2611
2612 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2613                    [Define to the canonical Emacs configuration name.])
2614 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2615                    [Define to the options passed to configure.])
2616 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2617                    [Define to the used machine dependent file.])
2618 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2619                    [Define to the used os dependent file.])
2620 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2621 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2622  may need to deal with X Windows.  For instance, if you've defined
2623  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2624  your loader can find on its own, you might want to add "-L/..." or
2625  something similar.])
2626 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2627                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2628                     in case it's needed (for Solaris, for example).])
2629 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2630 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2631  may need to deal with X Windows.  For instance, if you've defined
2632  HAVE_X_WINDOWS above and your X include files aren't in a place
2633  that your compiler can find on its own, you might want to add
2634  "-I/..." or something similar.])
2635 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2636                    [Define to the unexec source file name.])
2637
2638 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2639   AC_DEFINE(HAVE_X_WINDOWS, 1,
2640             [Define to 1 if you want to use the X window system.])
2641 fi
2642 if test "${USE_X_TOOLKIT}" != "none" ; then
2643   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2644   if test "${USE_X_TOOLKIT}" == "LUCID"; then
2645     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2646   elif test "${USE_X_TOOLKIT}" == "MOTIF"; then
2647     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2648   fi
2649 fi
2650 if test "${HAVE_X11}" = "yes" ; then
2651   AC_DEFINE(HAVE_X11, 1,
2652             [Define to 1 if you want to use version 11 of X windows.
2653              Otherwise, Emacs expects to use version 10.])
2654 fi
2655 if test "${HAVE_MENUS}" = "yes" ; then
2656   AC_DEFINE(HAVE_MENUS, 1,
2657             [Define to 1 if you have mouse menus.
2658              (This is automatic if you use X, but the option to specify it remains.)
2659              It is also defined with other window systems that support xmenu.c.])
2660 fi
2661 if test "${GNU_MALLOC}" = "yes" ; then
2662   AC_DEFINE(GNU_MALLOC, 1,
2663             [Define to 1 if you want to use the GNU memory allocator.])
2664 fi
2665 if test "${REL_ALLOC}" = "yes" ; then
2666   AC_DEFINE(REL_ALLOC, 1,
2667             [Define REL_ALLOC if you want to use the relocating allocator for
2668              buffer space.])
2669 fi
2670
2671
2672 AH_TOP([/* GNU Emacs site configuration template file.
2673    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2674      2006, 2007, 2008  Free Software Foundation, Inc.
2675
2676 This file is part of GNU Emacs.
2677
2678 GNU Emacs is free software; you can redistribute it and/or modify
2679 it under the terms of the GNU General Public License as published by
2680 the Free Software Foundation; either version 3, or (at your option)
2681 any later version.
2682
2683 GNU Emacs is distributed in the hope that it will be useful,
2684 but WITHOUT ANY WARRANTY; without even the implied warranty of
2685 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2686 GNU General Public License for more details.
2687
2688 You should have received a copy of the GNU General Public License
2689 along with GNU Emacs; see the file COPYING.  If not, write to the
2690 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2691 Boston, MA 02110-1301, USA.  */
2692
2693
2694 /* No code in Emacs #includes config.h twice, but some bits of code
2695    intended to work with other packages as well (like gmalloc.c)
2696    think they can include it as many times as they like.  */
2697 #ifndef EMACS_CONFIG_H
2698 #define EMACS_CONFIG_H
2699 ])dnl
2700
2701 AH_BOTTOM([
2702 /* If we're using any sort of window system, define some consequences.  */
2703 #ifdef HAVE_X_WINDOWS
2704 #define HAVE_WINDOW_SYSTEM
2705 #define MULTI_KBOARD
2706 #define HAVE_MOUSE
2707 #endif
2708
2709 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2710    on unconditionally. */
2711 #ifndef MULTI_KBOARD
2712 #define MULTI_KBOARD
2713 #endif
2714
2715 /* If we're using the Carbon API on Mac OS X, define a few more
2716    variables as well.  */
2717 #ifdef HAVE_CARBON
2718 #define HAVE_WINDOW_SYSTEM
2719 #define HAVE_MOUSE
2720 #endif
2721
2722 /* Define USER_FULL_NAME to return a string
2723    that is the user's full name.
2724    It can assume that the variable `pw'
2725    points to the password file entry for this user.
2726
2727    At some sites, the pw_gecos field contains
2728    the user's full name.  If neither this nor any other
2729    field contains the right thing, use pw_name,
2730    giving the user's login name, since that is better than nothing.  */
2731 #define USER_FULL_NAME pw->pw_gecos
2732
2733 /* Define AMPERSAND_FULL_NAME if you use the convention
2734    that & in the full name stands for the login id.  */
2735 /* Turned on June 1996 supposing nobody will mind it.  */
2736 #define AMPERSAND_FULL_NAME
2737
2738 /* We have blockinput.h.  */
2739 #define DO_BLOCK_INPUT
2740
2741 /* Define HAVE_SOUND if we have sound support.  We know it works
2742    and compiles only on the specified platforms.   For others,
2743    it probably doesn't make sense to try.  */
2744
2745 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2746 #ifdef HAVE_MACHINE_SOUNDCARD_H
2747 #define HAVE_SOUND 1
2748 #endif
2749 #ifdef HAVE_SYS_SOUNDCARD_H
2750 #define HAVE_SOUND 1
2751 #endif
2752 #ifdef HAVE_SOUNDCARD_H
2753 #define HAVE_SOUND 1
2754 #endif
2755 #ifdef HAVE_ALSA
2756 #define HAVE_SOUND 1
2757 #endif
2758 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2759
2760 /* If using GNU, then support inline function declarations. */
2761 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2762    generally, because even if non-gcc compilers accept `inline', they
2763    may reject `extern inline'.  */
2764 #if defined (__GNUC__) && defined (OPTIMIZE)
2765 #define INLINE __inline__
2766 #else
2767 #define INLINE
2768 #endif
2769
2770 /* Include the os and machine dependent files.  */
2771 #include config_opsysfile
2772 #include config_machfile
2773
2774 /* If no remapping takes place, static variables cannot be dumped as
2775    pure, so don't worry about the `static' keyword. */
2776 #ifdef NO_REMAP
2777 #undef static
2778 #endif
2779
2780 /* Define `subprocesses' should be defined if you want to
2781    have code for asynchronous subprocesses
2782    (as used in M-x compile and M-x shell).
2783    These do not work for some USG systems yet;
2784    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2785
2786 #ifndef VMS
2787 #ifndef USG
2788 /* #define subprocesses */
2789 #endif
2790 #endif
2791
2792 /* SIGTYPE is the macro we actually use.  */
2793 #ifndef SIGTYPE
2794 #define SIGTYPE RETSIGTYPE
2795 #endif
2796
2797 #ifdef emacs /* Don't do this for lib-src.  */
2798 /* Tell regex.c to use a type compatible with Emacs.  */
2799 #define RE_TRANSLATE_TYPE Lisp_Object
2800 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2801 #ifdef make_number
2802 /* If make_number is a macro, use it.  */
2803 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2804 #else
2805 /* If make_number is a function, avoid it.  */
2806 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2807 #endif
2808 #endif
2809
2810 /* Avoid link-time collision with system mktime if we will use our own.  */
2811 #if ! HAVE_MKTIME || BROKEN_MKTIME
2812 #define mktime emacs_mktime
2813 #endif
2814
2815 #define my_strftime nstrftime   /* for strftime.c */
2816
2817 /* The rest of the code currently tests the CPP symbol BSTRING.
2818    Override any claims made by the system-description files.
2819    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2820 #undef BSTRING
2821 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2822 #define BSTRING
2823 #endif
2824
2825 /* Some of the files of Emacs which are intended for use with other
2826    programs assume that if you have a config.h file, you must declare
2827    the type of getenv.
2828
2829    This declaration shouldn't appear when alloca.s or Makefile.in
2830    includes config.h.  */
2831 #ifndef NOT_C_CODE
2832 extern char *getenv ();
2833 #endif
2834
2835 /* These default definitions are good for almost all machines.
2836    The exceptions override them in m/MACHINE.h.  */
2837
2838 #ifndef BITS_PER_CHAR
2839 #define BITS_PER_CHAR 8
2840 #endif
2841
2842 #ifndef BITS_PER_SHORT
2843 #define BITS_PER_SHORT 16
2844 #endif
2845
2846 /* Note that lisp.h uses this in a preprocessor conditional, so it
2847    would not work to use sizeof.  That being so, we do all of them
2848    without sizeof, for uniformity's sake.  */
2849 #ifndef BITS_PER_INT
2850 #define BITS_PER_INT 32
2851 #endif
2852
2853 #ifndef BITS_PER_LONG
2854 #ifdef _LP64
2855 #define BITS_PER_LONG 64
2856 #else
2857 #define BITS_PER_LONG 32
2858 #endif
2859 #endif
2860
2861 /* Define if the compiler supports function prototypes.  It may do so
2862    but not define __STDC__ (e.g. DEC C by default) or may define it as
2863    zero.  */
2864 #undef PROTOTYPES
2865 /* For mktime.c:  */
2866 #ifndef __P
2867 # if defined PROTOTYPES
2868 #  define __P(args) args
2869 # else
2870 #  define __P(args) ()
2871 # endif  /* GCC.  */
2872 #endif /* __P */
2873
2874 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2875 #ifndef NOT_C_CODE
2876 #ifdef HAVE_STRING_H
2877 #include "string.h"
2878 #endif
2879 #ifdef HAVE_STRINGS_H
2880 #include "strings.h"  /* May be needed for bcopy & al. */
2881 #endif
2882 #ifdef HAVE_STDLIB_H
2883 #include <stdlib.h>
2884 #endif
2885 #ifndef __GNUC__
2886 # ifdef HAVE_ALLOCA_H
2887 #  include <alloca.h>
2888 # else /* AIX files deal with #pragma.  */
2889 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2890 char *alloca ();
2891 #  endif
2892 # endif /* HAVE_ALLOCA_H */
2893 #endif /* __GNUC__ */
2894 #ifndef HAVE_SIZE_T
2895 typedef unsigned size_t;
2896 #endif
2897 #endif /* NOT_C_CODE */
2898
2899 /* Define HAVE_X_I18N if we have usable i18n support.  */
2900
2901 #ifdef HAVE_X11R6
2902 #define HAVE_X_I18N
2903 #elif !defined X11R5_INHIBIT_I18N
2904 #define HAVE_X_I18N
2905 #endif
2906
2907 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2908
2909 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2910 #define HAVE_X11R6_XIM
2911 #endif
2912
2913 /* Should we enable expensive run-time checking of data types?  */
2914 #undef ENABLE_CHECKING
2915
2916 #if defined __GNUC__ && (__GNUC__ > 2 \
2917                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2918 #define NO_RETURN       __attribute__ ((__noreturn__))
2919 #else
2920 #define NO_RETURN       /* nothing */
2921 #endif
2922
2923 /* These won't be used automatically yet.  We also need to know, at least,
2924    that the stack is continuous.  */
2925 #ifdef __GNUC__
2926 #  ifndef GC_SETJMP_WORKS
2927   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2928      see NON_SAVING_SETJMP in the target descriptions.  */
2929   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2930      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2931      Fixme: Deal with SVR3.  */
2932 #    define GC_SETJMP_WORKS 1
2933 #  endif
2934 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2935 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2936 #  endif
2937 #endif
2938
2939 #ifndef HAVE_BCOPY
2940 #define bcopy(a,b,s) memcpy (b,a,s)
2941 #endif
2942 #ifndef HAVE_BZERO
2943 #define bzero(a,s) memset (a,0,s)
2944 #endif
2945 #ifndef HAVE_BCMP
2946 #define BCMP memcmp
2947 #endif
2948
2949 #endif /* EMACS_CONFIG_H */
2950
2951 /*
2952 Local Variables:
2953 mode: c
2954 End:
2955 */
2956 ])dnl
2957
2958 #### Report on what we decided to do.
2959 #### Report GTK as a toolkit, even if it doesn't use Xt.
2960 #### It makes printing result more understandable as using GTK sets
2961 #### toolkit_scroll_bars to yes by default.
2962 if test "${HAVE_GTK}" = "yes"; then
2963   USE_X_TOOLKIT=GTK
2964 fi
2965
2966 echo "
2967 Configured for \`${canonical}'.
2968
2969   Where should the build process find the source code?    ${srcdir}
2970   What operating system and machine description files should Emacs use?
2971         \`${opsysfile}' and \`${machfile}'
2972   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2973   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2974   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2975   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2976   What window system should Emacs use?                    ${window_system}
2977   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2978
2979 if test -n "${x_includes}"; then
2980 echo "  Where do we find X Windows header files?                ${x_includes}"
2981 else
2982 echo "  Where do we find X Windows header files?                Standard dirs"
2983 fi
2984 if test -n "${x_libraries}"; then
2985 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2986 else
2987 echo "  Where do we find X Windows libraries?                   Standard dirs"
2988 fi
2989
2990 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2991 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2992 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2993 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2994 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2995 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2996 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2997 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2998 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2999 echo "  Does Emacs use a font backend?                          ${USE_FONT_BACKEND}"
3000
3001 if test "${USE_FONT_BACKEND}" = "yes"; then
3002   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3003   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3004   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3005   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3006 fi
3007 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3008 echo
3009
3010 if test $USE_XASSERTS = yes; then
3011    echo "  Compiling with asserts turned on."
3012    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3013 fi
3014
3015 echo
3016
3017 if test "$USE_X_TOOLKIT" = GTK; then
3018   case "$canonical" in
3019   *cygwin*)
3020     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3021   will probably get a crash on startup.  If this happens, please use another
3022   toolkit for Emacs.  See etc/PROBLEMS for more information."
3023   ;;
3024   esac
3025 fi
3026
3027
3028 if test "$HAVE_CARBON" = "yes"; then
3029    echo
3030    echo "Warning: The Mac Carbon port is currently unsupported and has
3031 known problems.  It is not recommended for use by non-developers.
3032 Read the emacs-devel archives for more information."
3033    echo
3034 fi
3035
3036 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3037   echo "D-Bus integration has been tested for GNU/Linux only."
3038   echo
3039 fi
3040
3041
3042 # Remove any trailing slashes in these variables.
3043 [test "${prefix}" != NONE &&
3044   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3045 test "${exec_prefix}" != NONE &&
3046   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3047
3048 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3049 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3050 ## from Makefile.c can correctly provide the arg `-traditional' to the
3051 ## C preprocessor.
3052
3053 AC_EGREP_CPP(yes..yes,
3054         [yes..yes],
3055         CPP_NEED_TRADITIONAL=no,
3056         CPP_NEED_TRADITIONAL=yes)
3057
3058 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3059         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3060         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3061         lwlib/Makefile lisp/Makefile leim/Makefile, [
3062
3063 ### Make the necessary directories, if they don't exist.
3064 for dir in etc lisp ; do
3065   test -d ${dir} || mkdir ${dir}
3066 done
3067
3068 # Build src/Makefile from ${srcdir}/src/Makefile.c
3069 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3070 # This must be done after src/config.h is built, since we rely on that file.
3071
3072 # Now get this: Some word that is part of the ${srcdir} directory name
3073 # or the ${configuration} value might, just might, happen to be an
3074 # identifier like `sun4' or `i386' or something, and be predefined by
3075 # the C preprocessor to some helpful value like 1, or maybe the empty
3076 # string.  Needless to say consequent macro substitutions are less
3077 # than conducive to the makefile finding the correct directory.
3078 [undefs="`echo $top_srcdir $configuration $canonical |
3079 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3080     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3081 `"]
3082
3083 echo creating src/epaths.h
3084 ${MAKE-make} epaths-force
3085
3086 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3087 # `..' to `. .'  unless invoked with -traditional
3088
3089 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3090   CPPFLAGS="$CPPFLAGS -traditional"
3091 fi
3092
3093 echo creating lib-src/Makefile
3094 ( cd lib-src
3095   rm -f junk.c junk1.c junk2.c
3096   sed -e '/start of cpp stuff/q' \
3097       < Makefile.c > junk1.c
3098   sed -e '1,/start of cpp stuff/d'\
3099       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3100       < Makefile.c > junk.c
3101   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3102       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3103   cat junk1.c junk2.c > Makefile.new
3104   rm -f junk.c junk1.c junk2.c
3105   chmod 444 Makefile.new
3106   mv -f Makefile.new Makefile
3107 )
3108
3109 echo creating src/Makefile
3110 ( cd src
3111   rm -f junk.c junk1.c junk2.c
3112   sed -e '/start of cpp stuff/q' \
3113       < Makefile.c > junk1.c
3114   sed -e '1,/start of cpp stuff/d'\
3115       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3116       < Makefile.c > junk.c
3117   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3118       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3119   cat junk1.c junk2.c > Makefile.new
3120   rm -f junk.c junk1.c junk2.c
3121   chmod 444 Makefile.new
3122   mv -f Makefile.new Makefile
3123 )
3124
3125 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3126   echo creating src/.gdbinit
3127   echo source $srcdir/src/.gdbinit > src/.gdbinit
3128 fi
3129
3130 # This is how we know whether to re-run configure in certain cases.
3131 touch src/config.stamp
3132
3133 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3134
3135 m4_if(dnl       Do not change this comment
3136    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3137 )dnl