configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 165
 166 ## For the times when you want to build Emacs but don't have
 167 ## a suitable makeinfo, and can live without the manuals.
 168 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 169 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 170
 171 dnl Can remove these in Emacs 24.
 172 AC_ARG_WITH([gtk],,
 173   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 174 specify a toolkit.])],,)
 175
 176 AC_ARG_WITH([gcc],,
 177   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 178 variable to specify a compiler.])],,)
 179
 180 AC_ARG_WITH([pkg-config-prog],dnl
 181 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 182                   [path to pkg-config for finding GTK and librsvg])])
 183 if test "X${with_pkg_config_prog}" != X; then
 184    if test "${with_pkg_config_prog}" != yes; then
 185       PKG_CONFIG="${with_pkg_config_prog}"
 186    fi
 187 fi
 188
 189 CRT_DIR=
 190 AC_ARG_WITH([crt-dir],dnl
 191 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 192 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 193 CRT_DIR="${with_crt_dir}"
 194
 195 AC_ARG_WITH([gnustep-conf],dnl
 196 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 197 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 198   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 199 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 200      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 201
 202 AC_ARG_ENABLE(ns-self-contained,
 203 [AS_HELP_STRING([--disable-ns-self-contained],
 204                 [disable self contained build under NeXTstep])],
 205    EN_NS_SELF_CONTAINED=$enableval,
 206    EN_NS_SELF_CONTAINED=yes)
 207
 208 AC_ARG_ENABLE(asserts,
 209 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 210       USE_XASSERTS=$enableval,
 211       USE_XASSERTS=no)
 212
 213 AC_ARG_ENABLE(maintainer-mode,
 214 [AS_HELP_STRING([--enable-maintainer-mode],
 215                 [enable make rules and dependencies not useful (and sometimes
 216                  confusing) to the casual installer])],
 217       USE_MAINTAINER_MODE=$enableval,
 218       USE_MAINTAINER_MODE=no)
 219 if test $USE_MAINTAINER_MODE = yes; then
 220   MAINT=
 221 else
 222   MAINT=#
 223 fi
 224 AC_SUBST(MAINT)
 225
 226 AC_ARG_ENABLE(locallisppath,
 227 [AS_HELP_STRING([--enable-locallisppath=PATH],
 228                 [directories Emacs should search for lisp files specific
 229                  to this site])],
 230 if test "${enableval}" = "no"; then
 231   locallisppath=
 232 elif test "${enableval}" != "yes"; then
 233   locallisppath=${enableval}
 234 fi)
 235
 236 AC_ARG_ENABLE(checking,
 237 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 238                 [enable expensive run-time checks.  With LIST,
 239                  enable only specific categories of checks.
 240                  Categories are: all,yes,no.
 241                  Flags are: stringbytes, stringoverrun, stringfreelist,
 242                  xmallocoverrun, conslist])],
 243 [ac_checking_flags="${enableval}"],[])
 244 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 245 for check in $ac_checking_flags
 246 do
 247         case $check in
 248         # these set all the flags to specific states
 249         yes)            ac_enable_checking=1 ;;
 250         no)             ac_enable_checking= ;
 251                         ac_gc_check_stringbytes= ;
 252                         ac_gc_check_string_overrun= ;
 253                         ac_gc_check_string_free_list= ;
 254                         ac_xmalloc_overrun= ;
 255                         ac_gc_check_cons_list= ;;
 256         all)            ac_enable_checking=1 ;
 257                         ac_gc_check_stringbytes=1 ;
 258                         ac_gc_check_string_overrun=1 ;
 259                         ac_gc_check_string_free_list=1 ;
 260                         ac_xmalloc_overrun=1 ;
 261                         ac_gc_check_cons_list=1 ;;
 262         # these enable particular checks
 263         stringbytes)    ac_gc_check_stringbytes=1 ;;
 264         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 265         stringfreelist) ac_gc_check_string_free_list=1 ;;
 266         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 267         conslist)       ac_gc_check_cons_list=1 ;;
 268         *)      AC_MSG_ERROR(unknown check category $check) ;;
 269         esac
 270 done
 271 IFS="$ac_save_IFS"
 272
 273 if test x$ac_enable_checking != x ; then
 274   AC_DEFINE(ENABLE_CHECKING, 1,
 275 [Enable expensive run-time checking of data types?])
 276 fi
 277 if test x$ac_gc_check_stringbytes != x ; then
 278   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 279 [Define this temporarily to hunt a bug.  If defined, the size of
 280    strings is redundantly recorded in sdata structures so that it can
 281    be compared to the sizes recorded in Lisp strings.])
 282 fi
 283 if test x$ac_gc_check_stringoverrun != x ; then
 284   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 285 [Define this to check for short string overrun.])
 286 fi
 287 if test x$ac_gc_check_string_free_list != x ; then
 288   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 289 [Define this to check the string free list.])
 290 fi
 291 if test x$ac_xmalloc_overrun != x ; then
 292   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 293 [Define this to check for malloc buffer overrun.])
 294 fi
 295 if test x$ac_gc_check_cons_list != x ; then
 296   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 297 [Define this to check for errors in cons list.])
 298 fi
 299
 300 AC_ARG_ENABLE(profiling,
 301 [AS_HELP_STRING([--enable-profiling],
 302                 [build emacs with profiling support.
 303                  This might not work on all platforms])],
 304 [ac_enable_profiling="${enableval}"],[])
 305 if test x$ac_enable_profiling != x ; then
 306    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 307    PROFILING_LDFLAGS="-pg"
 308 else
 309    PROFILING_CFLAGS=
 310    PROFILING_LDFLAGS=
 311 fi
 312
 313 AC_ARG_ENABLE(autodepend,
 314 [AS_HELP_STRING([--enable-autodepend],
 315                 [automatically generate dependencies to .h-files.
 316                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 317                  found])],
 318 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 319
 320 #### Make srcdir absolute, if it isn't already.  It's important to
 321 #### avoid running the path through pwd unnecessarily, since pwd can
 322 #### give you automounter prefixes, which can go away.  We do all this
 323 #### so Emacs can find its files when run uninstalled.
 324 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 325 unset CDPATH
 326 case "${srcdir}" in
 327   /* ) ;;
 328   . )
 329     ## We may be able to use the $PWD environment variable to make this
 330     ## absolute.  But sometimes PWD is inaccurate.
 331     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 332     ## but that tested only for a well-formed and valid PWD,
 333     ## it did not object when PWD was well-formed and valid but just wrong.
 334     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 335     then
 336       srcdir="$PWD"
 337     else
 338       srcdir="`(cd ${srcdir}; pwd)`"
 339     fi
 340   ;;
 341   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 342 esac
 343
 344 #### Check if the source directory already has a configured system in it.
 345 if test `pwd` != `(cd ${srcdir} && pwd)` \
 346    && test -f "${srcdir}/src/config.h" ; then
 347   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 348    as a build directory right now; it has been configured in its own
 349    right.  To configure in another directory as well, you MUST
 350    use GNU make.  If you do not have GNU make, then you must
 351    now do `make distclean' in ${srcdir},
 352    and then run $0 again.]])
 353 fi
 354
 355 #### Given the configuration name, set machfile and opsysfile to the
 356 #### names of the m/*.h and s/*.h files we should use.
 357
 358 ### Canonicalize the configuration name.
 359
 360 AC_CANONICAL_HOST
 361 canonical=$host
 362 configuration=${host_alias-${build_alias-$host}}
 363
 364 dnl This used to use changequote, but, apart from `changequote is evil'
 365 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 366 dnl the great gob of text.  Thus it's not processed for possible expansion.
 367 dnl Just make sure the brackets remain balanced.
 368 dnl
 369 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 370 dnl indicated by comments.
 371 dnl quotation begins
 372 [
 373
 374 ### If you add support for a new configuration, add code to this
 375 ### switch statement to recognize your configuration name and select
 376 ### the appropriate operating system and machine description files.
 377
 378 ### You would hope that you could choose an m/*.h file pretty much
 379 ### based on the machine portion of the configuration name, and an s-
 380 ### file based on the operating system portion.  However, it turns out
 381 ### that each m/*.h file is pretty manufacturer-specific - for
 382 ### example mips.h is MIPS
 383 ### So we basically have to have a special case for each
 384 ### configuration name.
 385 ###
 386 ### As far as handling version numbers on operating systems is
 387 ### concerned, make sure things will fail in a fixable way.  If
 388 ### /etc/MACHINES doesn't say anything about version numbers, be
 389 ### prepared to handle anything reasonably.  If version numbers
 390 ### matter, be sure /etc/MACHINES says something about it.
 391 ###
 392 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 393 ### "System V Release 4"; he writes, "The old convention encouraged
 394 ### confusion between `system' and `release' levels'."
 395
 396 machine='' opsys='' unported=no
 397 case "${canonical}" in
 398
 399   ## FreeBSD ports
 400   *-*-freebsd* )
 401     opsys=freebsd
 402     case "${canonical}" in
 403       alpha*-*-freebsd*)        machine=alpha ;;
 404       arm*-*-freebsd*)          machine=arm ;;
 405       ia64-*-freebsd*)          machine=ia64 ;;
 406       sparc-*-freebsd*)         machine=sparc ;;
 407       sparc64-*-freebsd*)       machine=sparc ;;
 408       powerpc-*-freebsd*)       machine=macppc ;;
 409       i[3456]86-*-freebsd*)     machine=intel386 ;;
 410       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 411     esac
 412   ;;
 413
 414   ## FreeBSD kernel + glibc based userland
 415   *-*-kfreebsd*gnu* )
 416     opsys=gnu-kfreebsd
 417     case "${canonical}" in
 418       alpha*-*-kfreebsd*)       machine=alpha ;;
 419       ia64-*-kfreebsd*)         machine=ia64 ;;
 420       sparc-*-kfreebsd*)        machine=sparc ;;
 421       sparc64-*-kfreebsd*)      machine=sparc ;;
 422       powerpc-*-kfreebsd*)      machine=macppc ;;
 423       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 424       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## NetBSD ports
 429   *-*-netbsd* )
 430     opsys=netbsd
 431     case "${canonical}" in
 432       alpha*-*-netbsd*) machine=alpha ;;
 433       i[3456]86-*-netbsd*) machine=intel386 ;;
 434       mips-*-netbsd*)   machine=mips ;;
 435       mipsel-*-netbsd*) machine=mips ;;
 436       mipseb-*-netbsd*) machine=mips ;;
 437       powerpc-*-netbsd*) machine=macppc ;;
 438       sparc*-*-netbsd*) machine=sparc ;;
 439       vax-*-netbsd*)    machine=vax ;;
 440       arm-*-netbsd*)    machine=arm ;;
 441       x86_64-*-netbsd*) machine=amdx86-64 ;;
 442       hppa-*-netbsd*)   machine=hp800 ;;
 443       m68k-*-netbsd*)   machine=m68k ;;
 444     esac
 445   ;;
 446
 447   ## OpenBSD ports
 448   *-*-openbsd* )
 449     opsys=openbsd
 450     case "${canonical}" in
 451       alpha*-*-openbsd*)        machine=alpha ;;
 452       arm-*-openbsd*)          machine=arm ;;
 453       i386-*-openbsd*)         machine=intel386 ;;
 454       powerpc-*-openbsd*)      machine=macppc ;;
 455       sparc*-*-openbsd*)       machine=sparc ;;
 456       vax-*-openbsd*)          machine=vax ;;
 457       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 458       hppa-*-openbsd*)         machine=hp800 ;;
 459     esac
 460   ;;
 461
 462   alpha*-*-linux-gnu* )
 463     machine=alpha opsys=gnu-linux
 464   ;;
 465
 466   arm*-*-linux-gnu* )
 467     machine=arm opsys=gnu-linux
 468   ;;
 469
 470   ## Apple Darwin / Mac OS X
 471   *-apple-darwin* )
 472     case "${canonical}" in
 473       i[3456]86-* )  machine=intel386 ;;
 474       powerpc-* )    machine=macppc ;;
 475       x86_64-* )     machine=amdx86-64 ;;
 476       * )            unported=yes ;;
 477     esac
 478     opsys=darwin
 479     # Define CPP as follows to make autoconf work correctly.
 480     CPP="${CC-cc} -E -no-cpp-precomp"
 481     # Use fink packages if available.
 482     if test -d /sw/include && test -d /sw/lib; then
 483       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 484       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 485       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 486     fi
 487   ;;
 488
 489   ## HP 9000 series 700 and 800, running HP/UX
 490   hppa*-hp-hpux10.2* )
 491     machine=hp800 opsys=hpux10-20
 492   ;;
 493   hppa*-hp-hpux1[1-9]* )
 494     machine=hp800 opsys=hpux11
 495     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 496   ;;
 497
 498   hppa*-*-linux-gnu* )
 499     machine=hp800 opsys=gnu-linux
 500   ;;
 501
 502   ## IBM machines
 503   s390-*-linux-gnu* )
 504     machine=ibms390 opsys=gnu-linux
 505   ;;
 506   s390x-*-linux-gnu* )
 507     machine=ibms390x opsys=gnu-linux
 508   ;;
 509   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 510     machine=ibmrs6000 opsys=aix4-2
 511   ;;
 512   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521
 522   ## Macintosh PowerPC
 523   powerpc*-*-linux-gnu* )
 524     machine=macppc opsys=gnu-linux
 525   ;;
 526
 527   ## Silicon Graphics machines
 528   ## Iris 4D
 529   mips-sgi-irix6.5 )
 530     machine=iris4d opsys=irix6-5
 531     # Without defining _LANGUAGE_C, things get masked out in the headers
 532     # so that, for instance, grepping for `free' in stdlib.h fails and
 533     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 534     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 535     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 536   ;;
 537
 538   ## Suns
 539   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 540     machine=sparc opsys=gnu-linux
 541   ;;
 542
 543   *-sun-solaris* \
 544     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 545     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 546     case "${canonical}" in
 547       i[3456]86-*-* )     machine=intel386 ;;
 548       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 549       sparc* )          machine=sparc ;;
 550       * )               unported=yes ;;
 551     esac
 552     case "${canonical}" in
 553       *-sunos5.6* | *-solaris2.6* )
 554                 opsys=sol2-6
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 RANLIB="ar -ts"
 557                 ;;
 558       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 559                 opsys=sol2-6
 560                 emacs_check_sunpro_c=yes
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 ;;
 563       *-sunos5* | *-solaris* )
 564                 opsys=sol2-10
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568     esac
 569     ## Watch out for a compiler that we know will not work.
 570     case "${canonical}" in
 571      *-solaris* | *-sunos5* )
 572                 if [ "x$CC" = x/usr/ucb/cc ]; then
 573                   ## /usr/ucb/cc doesn't work;
 574                   ## we should find some other compiler that does work.
 575                   unset CC
 576                 fi
 577                 ;;
 578       *) ;;
 579     esac
 580   ;;
 581
 582   ## IA-64
 583   ia64*-*-linux* )
 584     machine=ia64 opsys=gnu-linux
 585   ;;
 586
 587   ## Intel 386 machines where we don't care about the manufacturer
 588   i[3456]86-*-* )
 589     machine=intel386
 590     case "${canonical}" in
 591       *-cygwin )                opsys=cygwin ;;
 592       *-darwin* )               opsys=darwin
 593                                 CPP="${CC-cc} -E -no-cpp-precomp"
 594                                 ;;
 595       *-linux-gnu* )            opsys=gnu-linux ;;
 596       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 600     esac
 601   ;;
 602
 603   ## m68k Linux-based GNU system
 604   m68k-*-linux-gnu* )
 605     machine=m68k opsys=gnu-linux
 606   ;;
 607
 608   ## Mips Linux-based GNU system
 609   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 610     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 611     machine=mips opsys=gnu-linux
 612   ;;
 613
 614   ## AMD x86-64 Linux-based GNU system
 615   x86_64-*-linux-gnu* )
 616     machine=amdx86-64 opsys=gnu-linux
 617   ;;
 618
 619   ## Tensilica Xtensa Linux-based GNU system
 620   xtensa*-*-linux-gnu* )
 621     machine=xtensa opsys=gnu-linux
 622     ;;
 623
 624   ## SuperH Linux-based GNU system
 625   sh[34]*-*-linux-gnu* )
 626     machine=sh3 opsys=gnu-linux
 627   ;;
 628
 629   * )
 630     unported=yes
 631   ;;
 632 esac
 633
 634 ### If the code above didn't choose an operating system, just choose
 635 ### an operating system based on the configuration name.  You really
 636 ### only want to use this when you have no idea what the right
 637 ### operating system is; if you know what operating systems a machine
 638 ### runs, it's cleaner to make it explicit in the case statement
 639 ### above.
 640 if test x"${opsys}" = x; then
 641   case "${canonical}" in
 642     *-gnu* )                            opsys=gnu ;;
 643     * )
 644       unported=yes
 645     ;;
 646   esac
 647 fi
 648
 649 ]
 650 dnl quotation ends
 651
 652 if test $unported = yes; then
 653   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 654 Check `etc/MACHINES' for recognized configuration names.])
 655 fi
 656
 657 machfile="m/${machine}.h"
 658 opsysfile="s/${opsys}.h"
 659
 660
 661 #### Choose a compiler.
 662 test -n "$CC" && cc_specified=yes
 663
 664 # Save the value of CFLAGS that the user specified.
 665 SPECIFIED_CFLAGS="$CFLAGS"
 666
 667 dnl Sets GCC=yes if using gcc.
 668 AC_PROG_CC
 669
 670 # On Suns, sometimes $CPP names a directory.
 671 if test -n "$CPP" && test -d "$CPP"; then
 672   CPP=
 673 fi
 674
 675 ## If not using gcc, and on Solaris, and no CPP specified, see if
 676 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 677 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 678  test x"$CPP" = x; then
 679   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 680   AC_CACHE_VAL(emacs_cv_sunpro_c,
 681   [AC_TRY_LINK([],
 682 [#ifndef __SUNPRO_C
 683 fail;
 684 #endif
 685 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 686   AC_MSG_RESULT($emacs_cv_sunpro_c)
 687
 688   if test x"$emacs_cv_sunpro_c" = xyes; then
 689     NON_GNU_CPP="$CC -E -Xs"
 690   fi
 691 fi
 692
 693 #### Some systems specify a CPP to use unless we are using GCC.
 694 #### Now that we know whether we are using GCC, we can decide whether
 695 #### to use that one.
 696 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 697 then
 698   CPP="$NON_GNU_CPP"
 699 fi
 700
 701 #### Some systems specify a CC to use unless we are using GCC.
 702 #### Now that we know whether we are using GCC, we can decide whether
 703 #### to use that one.
 704 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 705   test x$cc_specified != xyes
 706 then
 707   CC="$NON_GNU_CC"
 708 fi
 709
 710 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 711 then
 712   CC="$CC $GCC_TEST_OPTIONS"
 713 fi
 714
 715 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 716 then
 717   CC="$CC $NON_GCC_TEST_OPTIONS"
 718 fi
 719
 720 dnl checks for Unix variants
 721 AC_USE_SYSTEM_EXTENSIONS
 722
 723 ### Use -Wno-pointer-sign if the compiler supports it
 724 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 725 SAVE_CFLAGS="$CFLAGS"
 726 CFLAGS="$CFLAGS -Wno-pointer-sign"
 727 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 728 if test $has_option = yes; then
 729    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 730 fi
 731 AC_MSG_RESULT($has_option)
 732 CFLAGS="$SAVE_CFLAGS"
 733 unset has_option
 734 unset SAVE_CFLAGS
 735
 736 ### Use -Wdeclaration-after-statement if the compiler supports it
 737 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 738 SAVE_CFLAGS="$CFLAGS"
 739 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 740 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 741 if test $has_option = yes; then
 742    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 743 fi
 744 AC_MSG_RESULT($has_option)
 745 CFLAGS="$SAVE_CFLAGS"
 746 unset has_option
 747 unset SAVE_CFLAGS
 748
 749 #### Some other nice autoconf tests.
 750
 751 dnl checks for programs
 752 AC_PROG_CPP
 753 AC_PROG_INSTALL
 754 if test "x$RANLIB" = x; then
 755   AC_PROG_RANLIB
 756 fi
 757
 758 ## Although we're running on an amd64 kernel, we're actually compiling for
 759 ## the x86 architecture.  The user should probably have provided an
 760 ## explicit --build to `configure', but if everything else than the kernel
 761 ## is running in i386 mode, we can help them out.
 762 if test "$machine" = "amdx86-64"; then
 763   AC_CHECK_DECL([i386])
 764   if test "$ac_cv_have_decl_i386" = "yes"; then
 765     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 766     machine=intel386
 767     machfile="m/${machine}.h"
 768   fi
 769 fi
 770
 771 AC_PATH_PROG(INSTALL_INFO, install-info)
 772 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 773 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 774 dnl Don't use GZIP, which is used by gzip for additional parameters.
 775 AC_PATH_PROG(GZIP_PROG, gzip)
 776
 777
 778 ## Need makeinfo >= 4.6 (?) to build the manuals.
 779 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 780 dnl By this stage, configure has already checked for egrep and set EGREP,
 781 dnl or exited with an error if no egrep was found.
 782 if test "$MAKEINFO" != "no" && \
 783   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 784    MAKEINFO=no
 785 fi
 786
 787 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 788 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 789 ## therefore in the category of "special tools" not normally required, which
 790 ## configure does not have to check for (eg autoconf itself).
 791 ## In a Bazaar checkout on the other hand, the manuals are not included.
 792 ## So makeinfo is a requirement to build from Bazaar, and configure
 793 ## should test for it as it does for any other build requirement.
 794 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 795 ## with pre-built manuals, from a Bazaar checkout.
 796 if test "$MAKEINFO" = "no"; then
 797   if test "x${with_makeinfo}" = "xno"; then
 798     MAKEINFO=off
 799   elif test ! -e $srcdir/info/emacs; then
 800     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 801 source tree does not seem to have pre-built manuals in the `info' directory.
 802 Either install a suitable version of makeinfo, or re-run configure
 803 with the `--without-makeinfo' option to build without the manuals.] )
 804   fi
 805 fi
 806
 807 dnl Add our options to ac_link now, after it is set up.
 808
 809 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 810 then
 811   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 812 fi
 813
 814 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 815 then
 816   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 817 fi
 818
 819 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 820 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 821 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 822 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 823 dnl if not built to support GNU ld.
 824
 825 late_LDFLAGS=$LDFLAGS
 826 if test "$GCC" = yes; then
 827   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 828 else
 829   LDFLAGS="$LDFLAGS -znocombreloc"
 830 fi
 831
 832 AC_MSG_CHECKING([for -znocombreloc])
 833 AC_LINK_IFELSE([main(){return 0;}],
 834   [AC_MSG_RESULT(yes)],
 835   LDFLAGS=$late_LDFLAGS
 836   [AC_MSG_RESULT(no)])
 837
 838 #### Extract some information from the operating system and machine files.
 839
 840 AC_CHECKING([the machine- and system-dependent files to find out
 841  - which libraries the lib-src programs will want, and
 842  - whether the GNU malloc routines are usable])
 843
 844 ### First figure out CFLAGS (which we use for running the compiler here)
 845 ### and REAL_CFLAGS (which we use for real compilation).
 846 ### The two are the same except on a few systems, where they are made
 847 ### different to work around various lossages.  For example,
 848 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 849 ### as implying static linking.
 850
 851 ### If the CFLAGS env var is specified, we use that value
 852 ### instead of the default.
 853
 854 ### It's not important that this name contain the PID; you can't run
 855 ### two configures in the same directory and have anything work
 856 ### anyway.
 857 tempcname="conftest.c"
 858
 859 echo '
 860 #include "'${srcdir}'/src/'${opsysfile}'"
 861 #include "'${srcdir}'/src/'${machfile}'"
 862 #ifndef LIBS_SYSTEM
 863 #define LIBS_SYSTEM
 864 #endif
 865 configure___ libsrc_libs=LIBS_SYSTEM
 866
 867 configure___ LIBX=-lX11
 868
 869 configure___ unexec=UNEXEC
 870
 871 #ifdef SYSTEM_MALLOC
 872 configure___ system_malloc=yes
 873 #else
 874 configure___ system_malloc=no
 875 #endif
 876
 877 #ifdef USE_MMAP_FOR_BUFFERS
 878 configure___ use_mmap_for_buffers=yes
 879 #else
 880 configure___ use_mmap_for_buffers=no
 881 #endif
 882
 883 #ifndef C_OPTIMIZE_SWITCH
 884 #ifdef __GNUC__
 885 #define C_OPTIMIZE_SWITCH -O2
 886 #else
 887 #define C_OPTIMIZE_SWITCH -O
 888 #endif
 889 #endif
 890
 891 #ifndef C_WARNINGS_SWITCH
 892 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 893 #endif
 894
 895 #ifdef THIS_IS_CONFIGURE
 896
 897 /* Get the CFLAGS for tests in configure.  */
 898 #ifdef __GNUC__
 899 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 900 #else
 901 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 902 #endif
 903
 904 #else /* not THIS_IS_CONFIGURE */
 905
 906 /* Get the CFLAGS for real compilation.  */
 907 #ifdef __GNUC__
 908 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 909 #else
 910 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 911 #endif
 912
 913 #endif /* not THIS_IS_CONFIGURE */
 914 ' > ${tempcname}
 915
 916 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 917
 918 # The value of CPP is a quoted variable reference, so we need to do this
 919 # to get its actual value...
 920 CPP=`eval "echo $CPP"`
 921 [eval `${CPP} -Isrc ${tempcname} \
 922        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 923 if test "x$SPECIFIED_CFLAGS" = x; then
 924   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 925          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 926 else
 927   REAL_CFLAGS="$CFLAGS"
 928 fi]
 929 rm ${tempcname}
 930
 931
 932 LD_SWITCH_SYSTEM=
 933 case "$opsys" in
 934   freebsd)
 935    ## Let `ld' find image libs and similar things in /usr/local/lib.
 936    ## The system compiler, GCC, has apparently been modified to not
 937    ## look there, contrary to what a stock GCC would do.
 938    LD_SWITCH_SYSTEM=-L/usr/local/lib
 939    ;;
 940
 941   gnu-linux)
 942    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 943    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 944    ;;
 945
 946   netbsd)
 947    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 948    ;;
 949
 950   openbsd)
 951    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 952    ## otherwise Emacs dumps core on elf systems.
 953    LD_SWITCH_SYSTEM="-Z"
 954    ;;
 955 esac
 956 AC_SUBST(LD_SWITCH_SYSTEM)
 957
 958 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 959
 960 ## This is fun.  Some settings of LD_SWITCH_SYSTEM reference
 961 ## LD_SWITCH_X_SITE_AUX, which has not been defined yet.  When using
 962 ## cpp, it was expanded to null.  Thus LD_SWITCH_SYSTEM had different
 963 ## values in configure and the Makefiles.  How helpful.
 964 ## FIXME why not use LD_SWITCH_SYSTEM_TEMACS (or somesuch) instead?
 965 case "$opsys" in
 966   gnu-linux)
 967    ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
 968    LD_SWITCH_SYSTEM="$LD_SWITCH_SYSTEM \$(LD_SWITCH_X_SITE_AUX)" ;;
 969
 970   netbsd|openbsd)
 971    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 972    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 973 esac
 974
 975
 976 C_SWITCH_MACHINE=
 977 if test "$machine" = "alpha"; then
 978   AC_CHECK_DECL([__ELF__])
 979   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 980     ## With ELF, make sure that all common symbols get allocated to in the
 981     ## data section.  Otherwise, the dump of temacs may miss variables in
 982     ## the shared library that have been initialized.  For example, with
 983     ## GNU libc, __malloc_initialized would normally be resolved to the
 984     ## shared library's .bss section, which is fatal.
 985     if test "x$GCC" = "xyes"; then
 986       C_SWITCH_MACHINE="-fno-common"
 987     else
 988       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 989     fi
 990   fi
 991 fi
 992 AC_SUBST(C_SWITCH_MACHINE)
 993
 994
 995 C_SWITCH_SYSTEM=
 996 ## Some programs in src produce warnings saying certain subprograms
 997 ## are too complex and need a MAXMEM value greater than 2000 for
 998 ## additional optimization.  --nils@exp-math.uni-essen.de
 999 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1000   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1001 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1002 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1003 AC_SUBST(C_SWITCH_SYSTEM)
1004
1005
1006 ### Make sure subsequent tests use flags consistent with the build flags.
1007
1008 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1009   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1010 else
1011   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1012 fi
1013
1014 dnl For AC_FUNC_GETLOADAVG, at least:
1015 AC_CONFIG_LIBOBJ_DIR(src)
1016
1017 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1018 AC_SYS_LARGEFILE
1019
1020
1021 ## If user specified a crt-dir, use that unconditionally.
1022 if test "X$CRT_DIR" = "X"; then
1023
1024   case "$canonical" in
1025     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1026     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1027     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1028     ## For anything else (eg /usr/lib32), it is up the user to specify
1029     ## the location (bug#5655).
1030     ## Test for crtn.o, not just the directory, because sometimes the
1031     ## directory exists but does not have the relevant files (bug#1287).
1032     ## FIXME better to test for binary compatibility somehow.
1033     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1034     ;;
1035
1036     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1037   esac
1038
1039   case "$opsys" in
1040     hpux10-20) CRT_DIR=/lib ;;
1041   esac
1042
1043   ## Default is /usr/lib.
1044   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1045
1046 else
1047
1048   ## Some platforms don't use any of these files, so it is not
1049   ## appropriate to put this test outside the if block.
1050   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1051     AC_MSG_ERROR([crt*.o not found in specified location.])
1052
1053 fi
1054
1055 AC_SUBST(CRT_DIR)
1056
1057 LIB_MATH=-lm
1058 LIB_STANDARD=
1059 START_FILES=
1060
1061 case $opsys in
1062   cygwin )
1063     LIB_MATH=
1064     START_FILES='ecrt0.o'
1065     ;;
1066   darwin )
1067     ## Adding -lm confuses the dynamic linker, so omit it.
1068     LIB_MATH=
1069     START_FILES='pre-crt0.o'
1070     ;;
1071   freebsd )
1072     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1073     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1074     ;;
1075   gnu-linux | gnu-kfreebsd )
1076     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1077     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1078     ;;
1079   hpux10-20 | hpux11 )
1080     LIB_STANDARD=-lc
1081     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1082     ;;
1083   netbsd | openbsd )
1084     if test -f $(CRT_DIR)/crti.o; then
1085         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1086         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1087     else
1088         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1089         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1090     fi
1091     ;;
1092 esac
1093
1094 AC_SUBST(LIB_MATH)
1095 AC_SUBST(START_FILES)
1096
1097 dnl This function definition taken from Gnome 2.0
1098 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1099 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1100 dnl also defines GSTUFF_PKG_ERRORS on error
1101 AC_DEFUN([PKG_CHECK_MODULES], [
1102   succeeded=no
1103
1104   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1105
1106   if test "$PKG_CONFIG" = "no" ; then
1107      ifelse([$4], , [AC_MSG_ERROR([
1108       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1109   else
1110      PKG_CONFIG_MIN_VERSION=0.9.0
1111      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1112         AC_MSG_CHECKING(for $2)
1113
1114         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1115             AC_MSG_RESULT(yes)
1116             succeeded=yes
1117
1118             AC_MSG_CHECKING($1_CFLAGS)
1119             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1120             AC_MSG_RESULT($$1_CFLAGS)
1121
1122             AC_MSG_CHECKING($1_LIBS)
1123             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1124             AC_MSG_RESULT($$1_LIBS)
1125         else
1126             AC_MSG_RESULT(no)
1127             $1_CFLAGS=""
1128             $1_LIBS=""
1129             ## If we have a custom action on failure, don't print errors, but
1130             ## do set a variable so people can do so.
1131             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1132             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1133         fi
1134
1135         AC_SUBST($1_CFLAGS)
1136         AC_SUBST($1_LIBS)
1137      else
1138         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1139         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1140      fi
1141   fi
1142
1143   if test $succeeded = yes; then
1144      ifelse([$3], , :, [$3])
1145   else
1146      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1147   fi
1148 ])
1149
1150
1151 if test "${with_sound}" != "no"; then
1152   # Sound support for GNU/Linux and the free BSDs.
1153   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1154   # Emulation library used on NetBSD.
1155   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1156   AC_SUBST(LIBSOUND)
1157
1158   ALSA_REQUIRED=1.0.0
1159   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1160   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1161   if test $HAVE_ALSA = yes; then
1162     SAVE_CFLAGS="$CFLAGS"
1163     SAVE_LDFLAGS="$LDFLAGS"
1164     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1165     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1166     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1167                     emacs_alsa_normal=yes,
1168                     emacs_alsa_normal=no)
1169     if test "$emacs_alsa_normal" != yes; then
1170       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1171                      [snd_lib_error_set_handler (0);],
1172                      emacs_alsa_subdir=yes,
1173                      emacs_alsa_subdir=no)
1174       if test "$emacs_alsa_subdir" != yes; then
1175         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1176       fi
1177       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1178     fi
1179
1180     CFLAGS="$SAVE_CFLAGS"
1181     LDFLAGS="$SAVE_LDFLAGS"
1182     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1183     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1184     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1185   fi
1186   AC_SUBST(CFLAGS_SOUND)
1187 fi
1188
1189 dnl checks for header files
1190 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1191   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1192   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1193   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1194   sys/utsname.h pwd.h utmp.h)
1195
1196 AC_MSG_CHECKING(if personality LINUX32 can be set)
1197 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1198                emacs_cv_personality_linux32=yes,
1199                emacs_cv_personality_linux32=no)
1200 AC_MSG_RESULT($emacs_cv_personality_linux32)
1201
1202 if test $emacs_cv_personality_linux32 = yes; then
1203   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1204             [Define to 1 if personality LINUX32 can be set.])
1205 fi
1206
1207 dnl On Solaris 8 there's a compilation warning for term.h because
1208 dnl it doesn't define `bool'.
1209 AC_CHECK_HEADERS(term.h, , , -)
1210 AC_HEADER_STDC
1211 AC_HEADER_TIME
1212 AC_CHECK_DECLS([sys_siglist])
1213 if test $ac_cv_have_decl_sys_siglist != yes; then
1214   # For Tru64, at least:
1215   AC_CHECK_DECLS([__sys_siglist])
1216   if test $ac_cv_have_decl___sys_siglist = yes; then
1217     AC_DEFINE(sys_siglist, __sys_siglist,
1218               [Define to any substitute for sys_siglist.])
1219   fi
1220 fi
1221 AC_HEADER_SYS_WAIT
1222
1223 dnl Some systems have utime.h but don't declare the struct anyplace.
1224 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1225 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1226 #include <sys/time.h>
1227 #include <time.h>
1228 #else
1229 #ifdef HAVE_SYS_TIME_H
1230 #include <sys/time.h>
1231 #else
1232 #include <time.h>
1233 #endif
1234 #endif
1235 #ifdef HAVE_UTIME_H
1236 #include <utime.h>
1237 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1238   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1239 if test $emacs_cv_struct_utimbuf = yes; then
1240   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1241 fi
1242
1243 dnl checks for typedefs
1244 AC_TYPE_SIGNAL
1245
1246 dnl Check for speed_t typedef.
1247 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1248   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1249     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1250 if test $emacs_cv_speed_t = yes; then
1251   AC_DEFINE(HAVE_SPEED_T, 1,
1252            [Define to 1 if `speed_t' is declared by <termios.h>.])
1253 fi
1254
1255 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1256 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1257 #include <sys/time.h>
1258 #include <time.h>
1259 #else
1260 #ifdef HAVE_SYS_TIME_H
1261 #include <sys/time.h>
1262 #else
1263 #include <time.h>
1264 #endif
1265 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1266   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1267 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1268 if test $emacs_cv_struct_timeval = yes; then
1269   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1270 fi
1271
1272 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1273 AC_TRY_COMPILE([#include <math.h>],
1274 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1275   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1276 HAVE_EXCEPTION=$emacs_cv_struct_exception
1277 if test $emacs_cv_struct_exception != yes; then
1278   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1279 fi
1280
1281 AC_CHECK_HEADERS(sys/socket.h)
1282 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1283 #if HAVE_SYS_SOCKET_H
1284 #include <sys/socket.h>
1285 #endif])
1286
1287 dnl checks for structure members
1288 AC_STRUCT_TM
1289 AC_STRUCT_TIMEZONE
1290 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1291                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1292                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1293                 [#include <time.h>])
1294 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1295                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1296                   struct ifreq.ifr_addr], , ,
1297                  [AC_INCLUDES_DEFAULT
1298 #if HAVE_SYS_SOCKET_H
1299 #include <sys/socket.h>
1300 #endif
1301 #if HAVE_NET_IF_H
1302 #include <net/if.h>
1303 #endif])
1304
1305 dnl checks for compiler characteristics
1306
1307 dnl Testing __STDC__ to determine prototype support isn't good enough.
1308 dnl DEC C, for instance, doesn't define it with default options, and
1309 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1310 dnl and void *.
1311 AC_C_PROTOTYPES
1312 AC_C_VOLATILE
1313 AC_C_CONST
1314 dnl This isn't useful because we can't turn on use of `inline' unless
1315 dnl the compiler groks `extern inline'.
1316 dnl AC_C_INLINE
1317 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1318   [AC_TRY_COMPILE(, [void * foo;],
1319                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1320 if test $emacs_cv_void_star = yes; then
1321   AC_DEFINE(POINTER_TYPE, void)
1322 else
1323   AC_DEFINE(POINTER_TYPE, char)
1324 fi
1325 AH_TEMPLATE(POINTER_TYPE,
1326             [Define as `void' if your compiler accepts `void *'; otherwise
1327              define as `char'.])dnl
1328
1329
1330
1331 dnl This could be used for targets which can have both byte sexes.
1332 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1333 dnl AC_C_BIGENDIAN
1334
1335 dnl check for Make feature
1336 AC_PROG_MAKE_SET
1337
1338 dnl check for GNU Make if we have GCC and autodepend is on.
1339 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1340    AC_MSG_CHECKING([whether we are using GNU Make])
1341    HAVE_GNU_MAKE=no
1342    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1343    if test "x$testval" != x; then
1344       HAVE_GNU_MAKE=yes
1345    else
1346       ac_enable_autodepend=no
1347    fi
1348    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1349    if test $HAVE_GNU_MAKE = yes; then
1350       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1351       SAVE_CFLAGS="$CFLAGS"
1352       CFLAGS="$CFLAGS -MMD -MF deps.d"
1353       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1354       CFLAGS="$SAVE_CFLAGS"
1355       test -f deps.d || ac_enable_autodepend=no
1356       rm -rf deps.d
1357       AC_MSG_RESULT([$ac_enable_autodepend])
1358    fi
1359    if test $ac_enable_autodepend = yes; then
1360       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1361    fi
1362 fi
1363
1364 dnl checks for operating system services
1365 AC_SYS_LONG_FILE_NAMES
1366
1367 #### Choose a window system.
1368
1369 AC_PATH_X
1370 if test "$no_x" = yes; then
1371   window_system=none
1372 else
1373   window_system=x11
1374 fi
1375
1376 ## Workaround for bug in autoconf <= 2.62.
1377 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1378 ## No need to do anything special for these standard directories.
1379 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1380
1381    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1382
1383 fi
1384
1385 LD_SWITCH_X_SITE_AUX=
1386 LD_SWITCH_X_SITE_AUX_RPATH=
1387 if test "${x_libraries}" != NONE; then
1388   if test -n "${x_libraries}"; then
1389     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1390     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1391     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1392   fi
1393   x_default_search_path=""
1394   x_search_path=${x_libraries}
1395   if test -z "${x_search_path}"; then
1396     x_search_path=/usr/lib
1397   fi
1398   for x_library in `echo ${x_search_path}: | \
1399                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1400     x_search_path="\
1401 ${x_library}/X11/%L/%T/%N%C%S:\
1402 ${x_library}/X11/%l/%T/%N%C%S:\
1403 ${x_library}/X11/%T/%N%C%S:\
1404 ${x_library}/X11/%L/%T/%N%S:\
1405 ${x_library}/X11/%l/%T/%N%S:\
1406 ${x_library}/X11/%T/%N%S"
1407     if test x"${x_default_search_path}" = x; then
1408       x_default_search_path=${x_search_path}
1409     else
1410       x_default_search_path="${x_search_path}:${x_default_search_path}"
1411     fi
1412   done
1413 fi
1414 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1415 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1416
1417 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1418   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1419 fi
1420
1421 if test x"${x_includes}" = x; then
1422   bitmapdir=/usr/include/X11/bitmaps
1423 else
1424   # accumulate include directories that have X11 bitmap subdirectories
1425   bmd_acc="dummyval"
1426   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1427     if test -d "${bmd}/X11/bitmaps"; then
1428       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1429     fi
1430     if test -d "${bmd}/bitmaps"; then
1431       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1432     fi
1433   done
1434   if test ${bmd_acc} != "dummyval"; then
1435     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1436   fi
1437 fi
1438
1439 HAVE_NS=no
1440 NS_IMPL_COCOA=no
1441 NS_IMPL_GNUSTEP=no
1442 tmp_CPPFLAGS="$CPPFLAGS"
1443 tmp_CFLAGS="$CFLAGS"
1444 CPPFLAGS="$CPPFLAGS -x objective-c"
1445 CFLAGS="$CFLAGS -x objective-c"
1446 if test "${with_ns}" != no; then
1447   if test "${opsys}" = darwin; then
1448      NS_IMPL_COCOA=yes
1449      ns_appdir=`pwd`/nextstep/Emacs.app
1450      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1451      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1452      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1453   elif test -f $GNUSTEP_CONFIG_FILE; then
1454      NS_IMPL_GNUSTEP=yes
1455      ns_appdir=`pwd`/nextstep/Emacs.app
1456      ns_appbindir=`pwd`/nextstep/Emacs.app
1457      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1458      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1459      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1460      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1461      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1462      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1463      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1464      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1465      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1466      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1467      LIB_STANDARD=
1468   fi
1469   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1470                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1471   files are missing or cannot be compiled.])])
1472   NS_HAVE_NSINTEGER=yes
1473   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1474                                      [NSInteger i;])],
1475                     ns_have_nsinteger=yes,
1476                     ns_have_nsinteger=no)
1477   if test $ns_have_nsinteger = no; then
1478     NS_HAVE_NSINTEGER=no
1479   fi
1480 fi
1481
1482 NS_OBJ=
1483 NS_SUPPORT=
1484 if test "${HAVE_NS}" = yes; then
1485   window_system=nextstep
1486   with_xft=no
1487   # set up packaging dirs
1488   exec_prefix=${ns_appbindir}
1489   libexecdir=${ns_appbindir}/libexec
1490   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1491      prefix=${ns_appresdir}
1492   fi
1493   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1494   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1495 fi
1496 CFLAGS="$tmp_CFLAGS"
1497 CPPFLAGS="$tmp_CPPFLAGS"
1498 AC_SUBST(NS_OBJ)
1499 AC_SUBST(NS_SUPPORT)
1500 AC_SUBST(LIB_STANDARD)
1501
1502 case "${window_system}" in
1503   x11 )
1504     HAVE_X_WINDOWS=yes
1505     HAVE_X11=yes
1506     case "${with_x_toolkit}" in
1507       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1508       motif ) USE_X_TOOLKIT=MOTIF ;;
1509       gtk ) with_gtk=yes
1510 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1511 dnl USE_X_TOOLKIT is set.
1512             USE_X_TOOLKIT=none ;;
1513       no ) USE_X_TOOLKIT=none ;;
1514 dnl If user did not say whether to use a toolkit, make this decision later:
1515 dnl use the toolkit if we have gtk, or X11R5 or newer.
1516       * ) USE_X_TOOLKIT=maybe ;;
1517     esac
1518   ;;
1519   nextstep | none )
1520     HAVE_X_WINDOWS=no
1521     HAVE_X11=no
1522     USE_X_TOOLKIT=none
1523   ;;
1524 esac
1525
1526 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1527    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1528    if test "$HAVE_XSERVER" = true ||
1529       test -n "$DISPLAY" ||
1530       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1531         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1532 were found.  You should install the relevant development files for X
1533 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1534 sure you have development files for image handling, i.e.
1535 tiff, gif, jpeg, png and xpm.
1536 If you are sure you want Emacs compiled without X window support, pass
1537   --without-x
1538 to configure.])
1539    fi
1540 fi
1541
1542 ### If we're using X11, we should use the X menu package.
1543 HAVE_MENUS=no
1544 case ${HAVE_X11} in
1545   yes ) HAVE_MENUS=yes ;;
1546 esac
1547
1548 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1549 # Assume not, until told otherwise.
1550 GNU_MALLOC=yes
1551 doug_lea_malloc=yes
1552 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1553 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1554 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1555                emacs_cv_var___after_morecore_hook,
1556 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1557   emacs_cv_var___after_morecore_hook=yes,
1558   emacs_cv_var___after_morecore_hook=no)])
1559 if test $emacs_cv_var___after_morecore_hook = no; then
1560   doug_lea_malloc=no
1561 fi
1562 if test "${system_malloc}" = "yes"; then
1563   GNU_MALLOC=no
1564   GNU_MALLOC_reason="
1565     (The GNU allocators don't work with this system configuration.)"
1566 fi
1567 if test "$doug_lea_malloc" = "yes" ; then
1568   if test "$GNU_MALLOC" = yes ; then
1569     GNU_MALLOC_reason="
1570       (Using Doug Lea's new malloc from the GNU C Library.)"
1571   fi
1572   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1573             [Define to 1 if you are using the GNU C Library.])
1574 fi
1575
1576 if test x"${REL_ALLOC}" = x; then
1577   REL_ALLOC=${GNU_MALLOC}
1578 fi
1579
1580 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1581 dnl the system configuration file (s/*.h) to turn the use of mmap
1582 dnl in the relocating allocator on.
1583
1584 AC_FUNC_MMAP
1585 if test $use_mmap_for_buffers = yes; then
1586   REL_ALLOC=no
1587 fi
1588
1589 LIBS="$libsrc_libs $LIBS"
1590
1591 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1592 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1593 AC_CHECK_LIB(dnet, dnet_ntoa)
1594 dnl This causes -lresolv to get used in subsequent tests,
1595 dnl which causes failures on some systems such as HPUX 9.
1596 dnl AC_CHECK_LIB(resolv, gethostbyname)
1597
1598 dnl FIXME replace main with a function we actually want from this library.
1599 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1600
1601 AC_CHECK_LIB(pthreads, cma_open)
1602
1603 dnl Check for need for bigtoc support on IBM AIX
1604
1605 case ${host_os} in
1606 aix*)
1607   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1608     case $GCC in
1609     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1610     *) gdb_cv_bigtoc=-bbigtoc ;;
1611     esac
1612
1613     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1614     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1615   ])
1616   ;;
1617 esac
1618
1619 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1620 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1621 # REAL_CPPFLAGS later on.
1622
1623 REAL_CPPFLAGS="$CPPFLAGS"
1624
1625 if test "${HAVE_X11}" = "yes"; then
1626   DEFS="$C_SWITCH_X_SITE $DEFS"
1627   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1628   LIBS="$LIBX $LIBS"
1629   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1630   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1631
1632   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1633   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1634   # but it's more convenient here to set LD_RUN_PATH
1635   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1636   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1637     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1638     export LD_RUN_PATH
1639   fi
1640
1641   if test "${opsys}" = "gnu-linux"; then
1642     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1643     AC_TRY_LINK([],
1644      [XOpenDisplay ("foo");],
1645      [xlinux_first_failure=no],
1646      [xlinux_first_failure=yes])
1647     if test "${xlinux_first_failure}" = "yes"; then
1648       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1649       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1650       OLD_CPPFLAGS="$CPPFLAGS"
1651       OLD_LIBS="$LIBS"
1652       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1653       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1654       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1655       LIBS="$LIBS -b i486-linuxaout"
1656       AC_TRY_LINK([],
1657        [XOpenDisplay ("foo");],
1658        [xlinux_second_failure=no],
1659        [xlinux_second_failure=yes])
1660       if test "${xlinux_second_failure}" = "yes"; then
1661         # If we get the same failure with -b, there is no use adding -b.
1662         # So take it out.  This plays safe.
1663         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1664         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1665         CPPFLAGS="$OLD_CPPFLAGS"
1666         LIBS="$OLD_LIBS"
1667         AC_MSG_RESULT(no)
1668       else
1669         AC_MSG_RESULT(yes)
1670       fi
1671     else
1672       AC_MSG_RESULT(no)
1673     fi
1674   fi
1675
1676   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1677   # header files included from there.
1678   AC_MSG_CHECKING(for Xkb)
1679   AC_TRY_LINK([#include <X11/Xlib.h>
1680 #include <X11/XKBlib.h>],
1681         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1682         emacs_xkb=yes, emacs_xkb=no)
1683   AC_MSG_RESULT($emacs_xkb)
1684   if test $emacs_xkb = yes; then
1685     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1686   fi
1687
1688   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1689 XScreenNumberOfScreen XSetWMProtocols)
1690 fi
1691
1692 if test "${window_system}" = "x11"; then
1693   AC_MSG_CHECKING(X11 version 6)
1694   AC_CACHE_VAL(emacs_cv_x11_version_6,
1695   [AC_TRY_LINK([#include <X11/Xlib.h>],
1696 [#if XlibSpecificationRelease < 6
1697 fail;
1698 #endif
1699 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1700   if test $emacs_cv_x11_version_6 = yes; then
1701     AC_MSG_RESULT(6 or newer)
1702     AC_DEFINE(HAVE_X11R6, 1,
1703               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1704   else
1705     AC_MSG_RESULT(before 6)
1706   fi
1707 fi
1708
1709
1710 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1711 HAVE_RSVG=no
1712 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1713   if test "${with_rsvg}" != "no"; then
1714     RSVG_REQUIRED=2.11.0
1715     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1716
1717     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1718     AC_SUBST(RSVG_CFLAGS)
1719     AC_SUBST(RSVG_LIBS)
1720
1721     if test ".${RSVG_CFLAGS}" != "."; then
1722       HAVE_RSVG=yes
1723       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1724       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1725       LIBS="$RSVG_LIBS $LIBS"
1726     fi
1727   fi
1728 fi
1729
1730
1731 HAVE_GTK=no
1732 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1733   GLIB_REQUIRED=2.6
1734   GTK_REQUIRED=2.6
1735   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1736
1737   dnl Checks for libraries.
1738   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1739   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1740      AC_MSG_ERROR($GTK_PKG_ERRORS)
1741   fi
1742 fi
1743
1744
1745 GTK_OBJ=
1746 if test x"$pkg_check_gtk" = xyes; then
1747
1748   AC_SUBST(GTK_CFLAGS)
1749   AC_SUBST(GTK_LIBS)
1750   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1751   CFLAGS="$CFLAGS $GTK_CFLAGS"
1752   LIBS="$GTK_LIBS $LIBS"
1753   dnl Try to compile a simple GTK program.
1754   GTK_COMPILES=no
1755   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1756   if test "${GTK_COMPILES}" != "yes"; then
1757     if test "$USE_X_TOOLKIT" != "maybe"; then
1758       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1759     fi
1760   else
1761     HAVE_GTK=yes
1762     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1763     GTK_OBJ=gtkutil.o
1764     USE_X_TOOLKIT=none
1765     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1766       :
1767     else
1768       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1769        closing open displays.  This is no problem if you just use
1770        one display, but if you use more than one and close one of them
1771        Emacs may crash.]])
1772       sleep 3
1773     fi
1774   fi
1775
1776 fi
1777 AC_SUBST(GTK_OBJ)
1778
1779
1780 if test "${HAVE_GTK}" = "yes"; then
1781
1782   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1783   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1784   if test "$with_toolkit_scroll_bars" != no; then
1785     with_toolkit_scroll_bars=yes
1786   fi
1787
1788   dnl  Check if we can use multiple displays with this GTK version.
1789   dnl  If gdk_display_open exists, assume all others are there also.
1790   HAVE_GTK_MULTIDISPLAY=no
1791   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1792   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1793     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1794               [Define to 1 if GTK can handle more than one display.])
1795   fi
1796
1797   dnl  Check if we have the old file selection dialog declared and
1798   dnl  in the link library.  In 2.x it may be in the library,
1799   dnl  but not declared if deprecated featured has been selected out.
1800   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1801   HAVE_GTK_FILE_SELECTION=no
1802   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1803                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1804 #include <gtk/gtk.h>])
1805   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1806     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1807                    HAVE_GTK_FILE_SELECTION=no)
1808   fi
1809
1810   dnl  Check if we have the new file chooser dialog
1811   HAVE_GTK_FILE_CHOOSER=no
1812   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1813                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1814 #include <gtk/gtk.h>])
1815   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1816     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1817                    HAVE_GTK_FILE_CHOOSER=no)
1818   fi
1819
1820   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1821      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1822     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1823               [Define to 1 if GTK has both file selection and chooser dialog.])
1824   fi
1825
1826   dnl Check if pthreads are available.  Emacs only needs this when using
1827   dnl gtk_file_chooser under Gnome.
1828   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1829     HAVE_GTK_AND_PTHREAD=no
1830     AC_CHECK_HEADERS(pthread.h)
1831     if test "$ac_cv_header_pthread_h"; then
1832       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1833     fi
1834     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1835       case "${canonical}" in
1836         *-hpux*) ;;
1837         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1838       esac
1839       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1840                [Define to 1 if you have GTK and pthread (-lpthread).])
1841     fi
1842   fi
1843 fi
1844
1845 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1846 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1847 dnl also not configured.
1848 HAVE_DBUS=no
1849 DBUS_OBJ=
1850 if test "${with_dbus}" = "yes"; then
1851    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1852    if test "$HAVE_DBUS" = yes; then
1853      LIBS="$LIBS $DBUS_LIBS"
1854      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1855      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1856      DBUS_OBJ=dbusbind.o
1857    fi
1858 fi
1859 AC_SUBST(DBUS_OBJ)
1860
1861 dnl GConf has been tested under GNU/Linux only.
1862 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1863 HAVE_GCONF=no
1864 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1865    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1866    if test "$HAVE_GCONF" = yes; then
1867       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1868    fi
1869 fi
1870
1871 dnl SELinux is available for GNU/Linux only.
1872 HAVE_LIBSELINUX=no
1873 LIBSELINUX_LIBS=
1874 if test "${with_selinux}" = "yes"; then
1875    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1876    if test "$HAVE_LIBSELINUX" = yes; then
1877       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1878       LIBSELINUX_LIBS=-lselinux
1879    fi
1880 fi
1881 AC_SUBST(LIBSELINUX_LIBS)
1882
1883 dnl Do not put whitespace before the #include statements below.
1884 dnl Older compilers (eg sunos4 cc) choke on it.
1885 HAVE_XAW3D=no
1886 LUCID_LIBW=
1887 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1888   if test "$with_xaw3d" != no; then
1889     AC_MSG_CHECKING(for xaw3d)
1890     AC_CACHE_VAL(emacs_cv_xaw3d,
1891     [AC_TRY_LINK([
1892 #include <X11/Intrinsic.h>
1893 #include <X11/Xaw3d/Simple.h>],
1894       [],
1895       emacs_cv_xaw3d=yes,
1896       emacs_cv_xaw3d=no)])
1897   else
1898     emacs_cv_xaw3d=no
1899   fi
1900   if test $emacs_cv_xaw3d = yes; then
1901     AC_MSG_RESULT([yes; using Lucid toolkit])
1902     USE_X_TOOLKIT=LUCID
1903     HAVE_XAW3D=yes
1904     LUCID_LIBW=-lXaw3d
1905     AC_DEFINE(HAVE_XAW3D, 1,
1906               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1907   else
1908     AC_MSG_RESULT(no)
1909     AC_MSG_CHECKING(for libXaw)
1910     AC_CACHE_VAL(emacs_cv_xaw,
1911     [AC_TRY_LINK([
1912 #include <X11/Intrinsic.h>
1913 #include <X11/Xaw/Simple.h>],
1914       [],
1915       emacs_cv_xaw=yes,
1916       emacs_cv_xaw=no)])
1917     if test $emacs_cv_xaw = yes; then
1918       AC_MSG_RESULT([yes; using Lucid toolkit])
1919       USE_X_TOOLKIT=LUCID
1920       LUCID_LIBW=-lXaw
1921     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1922       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1923     else
1924       AC_MSG_RESULT([no; do not use toolkit by default])
1925       USE_X_TOOLKIT=none
1926     fi
1927   fi
1928 fi
1929
1930 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1931
1932 LIBXTR6=
1933 if test "${USE_X_TOOLKIT}" != "none"; then
1934   AC_MSG_CHECKING(X11 toolkit version)
1935   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1936   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1937 [#if XtSpecificationRelease < 6
1938 fail;
1939 #endif
1940 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1941   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1942   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1943     AC_MSG_RESULT(6 or newer)
1944     AC_DEFINE(HAVE_X11XTR6, 1,
1945               [Define to 1 if you have the X11R6 or newer version of Xt.])
1946     LIBXTR6="-lSM -lICE"
1947     case "$opsys" in
1948       ## Use libw.a along with X11R6 Xt.
1949       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
1950     esac
1951   else
1952     AC_MSG_RESULT(before 6)
1953   fi
1954
1955 dnl If using toolkit, check whether libXmu.a exists.
1956 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1957   OLDLIBS="$LIBS"
1958   if test x$HAVE_X11XTR6 = xyes; then
1959     LIBS="-lXt -lSM -lICE $LIBS"
1960   else
1961     LIBS="-lXt $LIBS"
1962   fi
1963   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1964   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1965 fi
1966 AC_SUBST(LIBXTR6)
1967
1968 dnl FIXME the logic here seems weird, but this is what cpp was doing.
1969 dnl Why not just test for libxmu in the normal way?
1970 LIBXMU=-lXmu
1971 case "$machine" in
1972   ## These machines don't supply Xmu.
1973   hpux* | aix4-2 )
1974     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
1975     ;;
1976 esac
1977 AC_SUBST(LIBXMU)
1978
1979 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1980 if test "${HAVE_X11}" = "yes"; then
1981   if test "${USE_X_TOOLKIT}" != "none"; then
1982     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1983   fi
1984 fi
1985
1986 LIBXP=
1987 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1988   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1989   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1990     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1991 int x = 5;
1992 #else
1993 Motif version prior to 2.1.
1994 #endif],
1995     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1996   if test $emacs_cv_motif_version_2_1 = yes; then
1997     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
1998   else
1999     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2000     # We put this in CFLAGS temporarily to precede other -I options
2001     # that might be in CFLAGS temporarily.
2002     # We put this in CPPFLAGS where it precedes the other -I options.
2003     OLD_CPPFLAGS=$CPPFLAGS
2004     OLD_CFLAGS=$CFLAGS
2005     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2006     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2007     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2008       [int x = 5;],
2009       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2010     if test $emacs_cv_lesstif = yes; then
2011       # Make sure this -I option remains in CPPFLAGS after it is set
2012       # back to REAL_CPPFLAGS.
2013       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2014       # have those other -I options anyway.  Ultimately, having this
2015       # directory ultimately in CPPFLAGS will be enough.
2016       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2017       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2018     else
2019       CFLAGS=$OLD_CFLAGS
2020       CPPFLAGS=$OLD_CPPFLAGS
2021     fi
2022   fi
2023 fi
2024
2025 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2026 dnl using Motif or Xaw3d is available, and unless
2027 dnl --with-toolkit-scroll-bars=no was specified.
2028
2029 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2030             [Define to 1 if we should use toolkit scroll bars.])dnl
2031 USE_TOOLKIT_SCROLL_BARS=no
2032 if test "${with_toolkit_scroll_bars}" != "no"; then
2033   if test "${USE_X_TOOLKIT}" != "none"; then
2034     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2035       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2036       HAVE_XAW3D=no
2037       USE_TOOLKIT_SCROLL_BARS=yes
2038     elif test "${HAVE_XAW3D}" = "yes"; then
2039       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2040       USE_TOOLKIT_SCROLL_BARS=yes
2041     fi
2042   elif test "${HAVE_GTK}" = "yes"; then
2043     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2044     USE_TOOLKIT_SCROLL_BARS=yes
2045   elif test "${HAVE_NS}" = "yes"; then
2046     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2047     USE_TOOLKIT_SCROLL_BARS=yes
2048   fi
2049 fi
2050
2051 dnl See if XIM is available.
2052 AC_TRY_COMPILE([
2053           #include <X11/Xlib.h>
2054           #include <X11/Xresource.h>],
2055          [XIMProc  callback;],
2056          [HAVE_XIM=yes
2057          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2058          HAVE_XIM=no)
2059
2060 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2061
2062 if test "${with_xim}" != "no"; then
2063   AC_DEFINE(USE_XIM, 1,
2064             [Define to 1 if we should use XIM, if it is available.])
2065 fi
2066
2067
2068 if test "${HAVE_XIM}" != "no"; then
2069   late_CFLAGS=$CFLAGS
2070   if test "$GCC" = yes; then
2071     CFLAGS="$CFLAGS --pedantic-errors"
2072   fi
2073   AC_TRY_COMPILE([
2074 #include <X11/Xlib.h>
2075 #include <X11/Xresource.h>],
2076 [Display *display;
2077 XrmDatabase db;
2078 char *res_name;
2079 char *res_class;
2080 XIMProc  callback;
2081 XPointer *client_data;
2082 #ifndef __GNUC__
2083 /* If we're not using GCC, it's probably not XFree86, and this is
2084    probably right, but we can't use something like --pedantic-errors.  */
2085 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2086                                            char*, XIMProc, XPointer*);
2087 #endif
2088 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2089    client_data);],
2090     [emacs_cv_arg6_star=yes])
2091   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2092          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2093 either XPointer or XPointer*.])dnl
2094   if test "$emacs_cv_arg6_star" = yes; then
2095     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2096   else
2097     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2098   fi
2099   CFLAGS=$late_CFLAGS
2100 fi
2101
2102 ### Start of font-backend (under any platform) section.
2103 # (nothing here yet -- this is a placeholder)
2104 ### End of font-backend (under any platform) section.
2105
2106 ### Start of font-backend (under X11) section.
2107 if test "${HAVE_X11}" = "yes"; then
2108    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2109
2110    ## Use -lXft if available, unless `--with-xft=no'.
2111    HAVE_XFT=maybe
2112     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2113       with_xft="no";
2114     fi
2115     if test "x${with_xft}" != "xno"; then
2116
2117       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2118       ## Because xftfont.c uses XRenderQueryExtension, we also
2119       ## need to link to -lXrender.
2120       HAVE_XRENDER=no
2121       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2122       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2123         OLD_CPPFLAGS="$CPPFLAGS"
2124         OLD_CFLAGS="$CFLAGS"
2125         OLD_LIBS="$LIBS"
2126         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2127         CFLAGS="$CFLAGS $XFT_CFLAGS"
2128         XFT_LIBS="-lXrender $XFT_LIBS"
2129         LIBS="$XFT_LIBS $LIBS"
2130         AC_CHECK_HEADER(X11/Xft/Xft.h,
2131           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2132
2133         if test "${HAVE_XFT}" = "yes"; then
2134           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2135             AC_SUBST(XFT_LIBS)
2136           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2137         else
2138           CPPFLAGS="$OLD_CPPFLAGS"
2139           CFLAGS="$OLD_CFLAGS"
2140           LIBS="$OLD_LIBS"
2141         fi                        # "${HAVE_XFT}" = "yes"
2142       fi                          # "$HAVE_XFT" != no
2143     fi                            # "x${with_xft}" != "xno"
2144
2145     dnl For the "Does Emacs use" message at the end.
2146     if test "$HAVE_XFT" != "yes"; then
2147        HAVE_XFT=no
2148     fi
2149
2150
2151     HAVE_FREETYPE=no
2152     ## We used to allow building with FreeType and without Xft.
2153     ## However, the ftx font backend driver is not in good shape.
2154     if test "${HAVE_XFT}" = "yes"; then
2155       dnl As we use Xft, we anyway use freetype.
2156       dnl There's no need for additional CFLAGS and LIBS.
2157       HAVE_FREETYPE=yes
2158       FONTCONFIG_CFLAGS=
2159       FONTCONFIG_LIBS=
2160     fi
2161
2162     HAVE_LIBOTF=no
2163     if test "${HAVE_FREETYPE}" = "yes"; then
2164       AC_DEFINE(HAVE_FREETYPE, 1,
2165                 [Define to 1 if using the freetype and fontconfig libraries.])
2166       if test "${with_libotf}" != "no"; then
2167         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2168                           HAVE_LIBOTF=no)
2169         if test "$HAVE_LIBOTF" = "yes"; then
2170           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2171           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2172                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2173                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2174           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2175             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2176                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2177           fi
2178         fi
2179       fi
2180     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2181     dnl Does the new font backend require it, or can it work without it?
2182     fi
2183
2184     HAVE_M17N_FLT=no
2185     if test "${HAVE_LIBOTF}" = yes; then
2186       if test "${with_m17n_flt}" != "no"; then
2187         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2188         if test "$HAVE_M17N_FLT" = "yes"; then
2189           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2190         fi
2191       fi
2192     fi
2193 else
2194     HAVE_XFT=no
2195     HAVE_FREETYPE=no
2196     HAVE_LIBOTF=no
2197     HAVE_M17N_FLT=no
2198 fi
2199
2200 FONT_OBJ=xfont.o
2201 if test "$HAVE_XFT" = "yes"; then
2202   FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
2203 elif test "$HAVE_FREETYPE" = "yes"; then
2204   FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
2205 fi
2206 AC_SUBST(FONT_OBJ)
2207
2208 ### End of font-backend (under X11) section.
2209
2210 AC_SUBST(FREETYPE_CFLAGS)
2211 AC_SUBST(FREETYPE_LIBS)
2212 AC_SUBST(FONTCONFIG_CFLAGS)
2213 AC_SUBST(FONTCONFIG_LIBS)
2214 AC_SUBST(LIBOTF_CFLAGS)
2215 AC_SUBST(LIBOTF_LIBS)
2216 AC_SUBST(M17N_FLT_CFLAGS)
2217 AC_SUBST(M17N_FLT_LIBS)
2218
2219 ### Use -lXpm if available, unless `--with-xpm=no'.
2220 HAVE_XPM=no
2221 LIBXPM=
2222 if test "${HAVE_X11}" = "yes"; then
2223   if test "${with_xpm}" != "no"; then
2224     AC_CHECK_HEADER(X11/xpm.h,
2225       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2226     if test "${HAVE_XPM}" = "yes"; then
2227       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2228       AC_EGREP_CPP(no_return_alloc_pixels,
2229       [#include "X11/xpm.h"
2230 #ifndef XpmReturnAllocPixels
2231 no_return_alloc_pixels
2232 #endif
2233       ], HAVE_XPM=no, HAVE_XPM=yes)
2234
2235       if test "${HAVE_XPM}" = "yes"; then
2236         AC_MSG_RESULT(yes)
2237       else
2238         AC_MSG_RESULT(no)
2239       fi
2240     fi
2241   fi
2242
2243   if test "${HAVE_XPM}" = "yes"; then
2244     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2245     LIBXPM=-lXpm
2246   fi
2247 fi
2248 AC_SUBST(LIBXPM)
2249
2250 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2251 HAVE_JPEG=no
2252 LIBJPEG=
2253 if test "${HAVE_X11}" = "yes"; then
2254   if test "${with_jpeg}" != "no"; then
2255     dnl Checking for jpeglib.h can lose because of a redefinition of
2256     dnl  HAVE_STDLIB_H.
2257     AC_CHECK_HEADER(jerror.h,
2258       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2259   fi
2260
2261   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2262   if test "${HAVE_JPEG}" = "yes"; then
2263     AC_DEFINE(HAVE_JPEG)
2264     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2265         [#include <jpeglib.h>
2266          version=JPEG_LIB_VERSION
2267 ],
2268         [AC_DEFINE(HAVE_JPEG)],
2269         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2270         HAVE_JPEG=no])
2271   fi
2272   if test "${HAVE_JPEG}" = "yes"; then
2273     LIBJPEG=-ljpeg
2274   fi
2275 fi
2276 AC_SUBST(LIBJPEG)
2277
2278 ### Use -lpng if available, unless `--with-png=no'.
2279 HAVE_PNG=no
2280 LIBPNG=
2281 if test "${HAVE_X11}" = "yes"; then
2282   if test "${with_png}" != "no"; then
2283     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2284     # in /usr/include/libpng.
2285     AC_CHECK_HEADERS(png.h libpng/png.h)
2286     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2287       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2288     fi
2289   fi
2290
2291   if test "${HAVE_PNG}" = "yes"; then
2292     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2293     LIBPNG="-lpng -lz -lm"
2294   fi
2295 fi
2296 AC_SUBST(LIBPNG)
2297
2298 ### Use -ltiff if available, unless `--with-tiff=no'.
2299 HAVE_TIFF=no
2300 LIBTIFF=
2301 if test "${HAVE_X11}" = "yes"; then
2302   if test "${with_tiff}" != "no"; then
2303     AC_CHECK_HEADER(tiffio.h,
2304       [tifflibs="-lz -lm"
2305       # At least one tiff package requires the jpeg library.
2306       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2307       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2308   fi
2309
2310   if test "${HAVE_TIFF}" = "yes"; then
2311     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2312     dnl FIXME -lz -lm, as per libpng?
2313     LIBTIFF=-ltiff
2314   fi
2315 fi
2316 AC_SUBST(LIBTIFF)
2317
2318 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2319 HAVE_GIF=no
2320 LIBGIF=
2321 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2322   AC_CHECK_HEADER(gif_lib.h,
2323 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2324 # Earlier versions can crash Emacs.
2325     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2326
2327   if test "$HAVE_GIF" = yes; then
2328     LIBGIF=-lgif
2329   elif test "$HAVE_GIF" = maybe; then
2330 # If gif_lib.h but no libgif, try libungif.
2331     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2332     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2333   fi
2334
2335   if test "${HAVE_GIF}" = "yes"; then
2336     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2337   fi
2338 fi
2339 AC_SUBST(LIBGIF)
2340
2341 dnl Check for required libraries.
2342 if test "${HAVE_X11}" = "yes"; then
2343   MISSING=""
2344   WITH_NO=""
2345   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2346     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2347   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2348     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2349   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2350     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2351   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2352     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2353   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2354     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2355
2356   if test "X${MISSING}" != X; then
2357     AC_MSG_ERROR([The following required libraries were not found:
2358     $MISSING
2359 Maybe some development libraries/packages are missing?
2360 If you don't want to link with them give
2361     $WITH_NO
2362 as options to configure])
2363   fi
2364 fi
2365
2366 ### Use -lgpm if available, unless `--with-gpm=no'.
2367 HAVE_GPM=no
2368 LIBGPM=
2369 GPM_MOUSE_SUPPORT=
2370 if test "${with_gpm}" != "no"; then
2371   AC_CHECK_HEADER(gpm.h,
2372     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2373
2374   if test "${HAVE_GPM}" = "yes"; then
2375     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2376     LIBGPM=-lgpm
2377     GPM_MOUSE_SUPPORT="\${lispsource}mouse.elc"
2378   fi
2379 fi
2380 AC_SUBST(LIBGPM)
2381 AC_SUBST(GPM_MOUSE_SUPPORT)
2382
2383 dnl Check for malloc/malloc.h on darwin
2384 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2385
2386 C_SWITCH_X_SYSTEM=
2387 ### Use NeXTstep API to implement GUI.
2388 if test "${HAVE_NS}" = "yes"; then
2389   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2390   if test "${NS_IMPL_COCOA}" = "yes"; then
2391     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2392     GNU_OBJC_CFLAGS=
2393   fi
2394   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2395     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2396     # See also .m.o rule in Makefile.in */
2397     # FIXME: are all these flags really needed?  Document here why.  */
2398     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2399     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2400   fi
2401   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2402     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2403   fi
2404   # We also have mouse menus.
2405   HAVE_MENUS=yes
2406   OTHER_FILES=ns-app
2407 fi
2408
2409
2410 ### Use session management (-lSM -lICE) if available
2411 HAVE_X_SM=no
2412 LIBXSM=
2413 if test "${HAVE_X11}" = "yes"; then
2414   AC_CHECK_HEADER(X11/SM/SMlib.h,
2415     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2416
2417   if test "${HAVE_X_SM}" = "yes"; then
2418     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2419     LIBXSM="-lSM -lICE"
2420     case "$LIBS" in
2421       *-lSM*) ;;
2422       *)      LIBS="$LIBXSM $LIBS" ;;
2423     esac
2424   fi
2425 fi
2426 AC_SUBST(LIBXSM)
2427
2428 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2429 AC_CACHE_CHECK(whether netdb declares h_errno,
2430                emacs_cv_netdb_declares_h_errno,
2431 [AC_TRY_LINK([#include <netdb.h>],
2432   [return h_errno;],
2433   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2434 if test $emacs_cv_netdb_declares_h_errno = yes; then
2435   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2436 fi
2437
2438 AC_FUNC_ALLOCA
2439
2440 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2441 dnl FIXME is there an autoconf test that does the right thing, without
2442 dnl needing to call A_M_E afterwards?
2443 if test x"$ac_cv_func_alloca_works" != xyes; then
2444    AC_MSG_ERROR( [a system implementation of alloca is required] )
2445 fi
2446
2447 # fmod, logb, and frexp are found in -lm on most systems.
2448 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2449 AC_CHECK_LIB(m, sqrt)
2450
2451 # Check for mail-locking functions in a "mail" library.  Probably this should
2452 # have the same check as for liblockfile below.
2453 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2454 if test $have_mail = yes; then
2455   LIBS_MAIL=-lmail
2456   LIBS="$LIBS_MAIL $LIBS"
2457   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2458 else
2459   LIBS_MAIL=
2460 fi
2461 dnl Debian, at least:
2462 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2463 if test $have_lockfile = yes; then
2464    LIBS_MAIL=-llockfile
2465    LIBS="$LIBS_MAIL $LIBS"
2466    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2467 else
2468 # If we have the shared liblockfile, assume we must use it for mail
2469 # locking (e.g. Debian).  If we couldn't link against liblockfile
2470 # (no liblockfile.a installed), ensure that we don't need to.
2471   dnl This works for files generally, not just executables.
2472   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2473   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2474                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2475   if test $ac_cv_prog_liblockfile = yes; then
2476     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2477 This probably means that movemail could lose mail.
2478 There may be a `development' package to install containing liblockfile.])
2479   fi
2480 fi
2481 AC_CHECK_FUNCS(touchlock)
2482 AC_CHECK_HEADERS(maillock.h)
2483 AC_SUBST(LIBS_MAIL)
2484
2485 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2486 ## interlock access to the mail spool.  The alternative is a lock file named
2487 ## /usr/spool/mail/$USER.lock.
2488 mail_lock=no
2489 case "$opsys" in
2490   aix4-2) mail_lock="lockf" ;;
2491
2492   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2493
2494   ## On GNU/Linux systems, both methods are used by various mail programs.
2495   ## I assume most people are using newer mailers that have heard of flock.
2496   ## Change this if you need to.
2497   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2498   ## configure gets the right answers, and that means *NOT* using flock.
2499   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2500   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2501   ## Debian maintainer hasn't provided a clean fix for Emacs.
2502   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2503   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2504   ## correct logic.  -- fx
2505   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2506   ## liblockfile is a Free Software replacement for libmail, used on
2507   ## Debian systems and elsewhere. -rfr.
2508   gnu-*)
2509     mail_lock="flock"
2510     if test $have_mail = yes || test $have_lockfile = yes; then
2511       test $ac_cv_header_maillock_h = yes && mail_lock=no
2512     fi
2513     ;;
2514 esac
2515
2516 BLESSMAIL_TARGET=
2517 case "$mail_lock" in
2518   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2519
2520   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2521
2522   *) BLESSMAIL_TARGET="need-blessmail" ;;
2523 esac
2524 AC_SUBST(BLESSMAIL_TARGET)
2525
2526
2527 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2528 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2529 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2530 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2531 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2532 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2533 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2534 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2535 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2536 cfmakeraw cfsetspeed isnan copysign)
2537
2538 AC_CHECK_HEADERS(sys/un.h)
2539
2540 AC_FUNC_MKTIME
2541 if test "$ac_cv_func_working_mktime" = no; then
2542   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2543 fi
2544
2545 AC_FUNC_GETLOADAVG
2546
2547 AC_FUNC_FSEEKO
2548
2549 # Configure getopt.
2550 m4_include([m4/getopt.m4])
2551 gl_GETOPT_IFELSE([
2552   gl_GETOPT_SUBSTITUTE_HEADER
2553   gl_PREREQ_GETOPT
2554   GETOPTOBJS='getopt.o getopt1.o'
2555 ])
2556 AC_SUBST(GETOPTOBJS)
2557
2558 AC_FUNC_GETPGRP
2559
2560 AC_FUNC_STRFTIME
2561
2562 # UNIX98 PTYs.
2563 AC_CHECK_FUNCS(grantpt)
2564
2565 # PTY-related GNU extensions.
2566 AC_CHECK_FUNCS(getpt)
2567
2568 # Check this now, so that we will NOT find the above functions in ncurses.
2569 # That is because we have not set up to link ncurses in lib-src.
2570 # It's better to believe a function is not available
2571 # than to expect to find it in ncurses.
2572 # Also we need tputs and friends to be able to build at all.
2573 have_tputs_et_al=true
2574 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2575 if test "$have_tputs_et_al" != true; then
2576   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2577 Maybe some development libraries/packages are missing?  Try installing
2578 libncurses-dev(el), libterminfo-dev(el) or similar.])
2579 fi
2580 # Must define this when any termcap library is found.
2581 AC_DEFINE(HAVE_LIBNCURSES, 1,
2582           [Define to 1 if you have the `ncurses' library (-lncurses).])
2583 ## FIXME This was the cpp logic, but I am not sure it is right.
2584 ## The above test has not necessarily found libncurses.
2585 HAVE_LIBNCURSES=yes
2586
2587 ## Use terminfo instead of termcap?
2588 ## Note only system files NOT using terminfo are:
2589 ## bsd-common, freebsd < 40000, ms-w32, msdos, netbsd, and
2590 ## darwin|gnu without ncurses.
2591 TERMINFO=no
2592 LIBS_TERMCAP=
2593 case "$opsys" in
2594   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2595   ## hpux10-20: Use the system provided termcap(3) library.
2596   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2597   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2598   aix4-2|cygwin|hpux*|irix6-5|openbsd|usg5-4|sol2*|unixware) TERMINFO=yes ;;
2599
2600   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2601   ##  The ncurses library has been moved out of the System framework in
2602   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2603   ##  option to use it.
2604   darwin|gnu*)
2605     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2606     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2607       TERMINFO=yes
2608       LIBS_TERMCAP="-lncurses"
2609     fi
2610     ;;
2611
2612   freebsd)
2613     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2614     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2615     [AC_TRY_LINK([#include <osreldate.h>],
2616 [#if __FreeBSD_version < 400000
2617 fail;
2618 #endif
2619 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2620
2621     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2622
2623     if test $emacs_cv_freebsd_terminfo = yes; then
2624       TERMINFO=yes
2625       LIBS_TERMCAP="-lncurses"
2626     else
2627       LIBS_TERMCAP="-ltermcap"
2628     fi
2629     ;;
2630
2631 esac
2632
2633 case "$opsys" in
2634   ## hpux: Make sure we get select from libc rather than from libcurses
2635   ##  because libcurses on HPUX 10.10 has a broken version of select.
2636   ##  We used to use -lc -lcurses, but this may be cleaner.
2637   hpux*|netbsd) LIBS_TERMCAP="-ltermcap" ;;
2638
2639   openbsd) LIBS_TERMCAP="-lncurses" ;;
2640
2641   ## Must use system termcap, if we use any termcap.  It does special things.
2642   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2643 esac
2644
2645 TERMCAP_OBJ=tparam.o
2646 if test $TERMINFO = yes; then
2647   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2648
2649   ## Default used to be -ltermcap.  Add a case above if need something else.
2650   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2651
2652   TERMCAP_OBJ=terminfo.o
2653 fi
2654 AC_SUBST(LIBS_TERMCAP)
2655 AC_SUBST(TERMCAP_OBJ)
2656
2657
2658 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2659 resolv=no
2660 AC_TRY_LINK([#include <netinet/in.h>
2661 #include <arpa/nameser.h>
2662 #include <resolv.h>],
2663     [return res_init();],
2664     have_res_init=yes, have_res_init=no)
2665 if test "$have_res_init" = no; then
2666   OLIBS="$LIBS"
2667   LIBS="$LIBS -lresolv"
2668   AC_MSG_CHECKING(for res_init with -lresolv)
2669   AC_TRY_LINK([#include <netinet/in.h>
2670 #include <arpa/nameser.h>
2671 #include <resolv.h>],
2672     [return res_init();],
2673     have_res_init=yes, have_res_init=no)
2674   AC_MSG_RESULT($have_res_init)
2675   if test "$have_res_init" = yes ; then
2676     resolv=yes
2677   fi
2678   LIBS="$OLIBS"
2679 fi
2680
2681 if test "$have_res_init" = yes; then
2682   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2683 fi
2684
2685 # Do we need the Hesiod library to provide the support routines?
2686 LIBHESIOD=
2687 if test "$with_hesiod" != no ; then
2688   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2689   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2690      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2691                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2692   if test "$resolv" = yes ; then
2693     RESOLVLIB=-lresolv
2694   else
2695     RESOLVLIB=
2696   fi
2697   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2698         hesiod=yes, :, $RESOLVLIB)])
2699
2700   if test x"$hesiod" = xyes; then
2701     AC_DEFINE(HAVE_LIBHESIOD, 1,
2702               [Define to 1 if you have the hesiod library (-lhesiod).])
2703     LIBHESIOD=-lhesiod
2704   fi
2705 fi
2706 AC_SUBST(LIBHESIOD)
2707
2708 # Do we need libresolv (due to res_init or Hesiod)?
2709 if test "$resolv" = yes ; then
2710   AC_DEFINE(HAVE_LIBRESOLV, 1,
2711             [Define to 1 if you have the resolv library (-lresolv).])
2712   LIBRESOLV=-lresolv
2713 else
2714   LIBRESOLV=
2715 fi
2716 AC_SUBST(LIBRESOLV)
2717
2718 # These tell us which Kerberos-related libraries to use.
2719 COM_ERRLIB=
2720 CRYPTOLIB=
2721 KRB5LIB=
2722 DESLIB=
2723 KRB4LIB=
2724
2725 if test "${with_kerberos}" != no; then
2726   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2727   if test $have_com_err = yes; then
2728     COM_ERRLIB=-lcom_err
2729     LIBS="$COM_ERRLIB $LIBS"
2730     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2731   fi
2732   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2733   if test $have_crypto = yes; then
2734     CRYPTOLIB=-lcrypto
2735     LIBS="$CRYPTOLIB $LIBS"
2736     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2737   fi
2738   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2739   if test $have_k5crypto = yes; then
2740     CRYPTOLIB=-lk5crypto
2741     LIBS="$CRYPTOLIB $LIBS"
2742     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2743   fi
2744   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2745   if test $have_krb5=yes; then
2746     KRB5LIB=-lkrb5
2747     LIBS="$KRB5LIB $LIBS"
2748     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2749   fi
2750   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2751   if test "${with_kerberos5}" = no; then
2752     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2753     if test $have_des425 = yes; then
2754       DESLIB=-ldes425
2755       LIBS="$DESLIB $LIBS"
2756       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2757     else
2758       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2759       if test $have_des = yes; then
2760         DESLIB=-ldes
2761         LIBS="$DESLIB $LIBS"
2762         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2763       fi
2764     fi
2765     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2766     if test $have_krb4 = yes; then
2767       KRB4LIB=-lkrb4
2768       LIBS="$KRB4LIB $LIBS"
2769       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2770     else
2771       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2772       if test $have_krb = yes; then
2773         KRB4LIB=-lkrb
2774         LIBS="$KRB4LIB $LIBS"
2775         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2776       fi
2777     fi
2778   fi
2779
2780   if test "${with_kerberos5}" != no; then
2781     AC_CHECK_HEADERS(krb5.h,
2782       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2783                         [#include <krb5.h>])])
2784   else
2785     AC_CHECK_HEADERS(des.h,,
2786                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2787                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2788     AC_CHECK_HEADERS(krb.h,,
2789                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2790                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2791   fi
2792   AC_CHECK_HEADERS(com_err.h)
2793 fi
2794
2795 AC_SUBST(COM_ERRLIB)
2796 AC_SUBST(CRYPTOLIB)
2797 AC_SUBST(KRB5LIB)
2798 AC_SUBST(DESLIB)
2799 AC_SUBST(KRB4LIB)
2800
2801 # Solaris requires -lintl if you want strerror (which calls dgettext)
2802 # to return localized messages.
2803 AC_CHECK_LIB(intl, dgettext)
2804
2805 AC_MSG_CHECKING(whether localtime caches TZ)
2806 AC_CACHE_VAL(emacs_cv_localtime_cache,
2807 [if test x$ac_cv_func_tzset = xyes; then
2808 AC_TRY_RUN([#include <time.h>
2809 extern char **environ;
2810 unset_TZ ()
2811 {
2812   char **from, **to;
2813   for (to = from = environ; (*to = *from); from++)
2814     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2815       to++;
2816 }
2817 char TZ_GMT0[] = "TZ=GMT0";
2818 char TZ_PST8[] = "TZ=PST8";
2819 main()
2820 {
2821   time_t now = time ((time_t *) 0);
2822   int hour_GMT0, hour_unset;
2823   if (putenv (TZ_GMT0) != 0)
2824     exit (1);
2825   hour_GMT0 = localtime (&now)->tm_hour;
2826   unset_TZ ();
2827   hour_unset = localtime (&now)->tm_hour;
2828   if (putenv (TZ_PST8) != 0)
2829     exit (1);
2830   if (localtime (&now)->tm_hour == hour_GMT0)
2831     exit (1);
2832   unset_TZ ();
2833   if (localtime (&now)->tm_hour != hour_unset)
2834     exit (1);
2835   exit (0);
2836 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2837 [# If we have tzset, assume the worst when cross-compiling.
2838 emacs_cv_localtime_cache=yes])
2839 else
2840         # If we lack tzset, report that localtime does not cache TZ,
2841         # since we can't invalidate the cache if we don't have tzset.
2842         emacs_cv_localtime_cache=no
2843 fi])dnl
2844 AC_MSG_RESULT($emacs_cv_localtime_cache)
2845 if test $emacs_cv_localtime_cache = yes; then
2846   AC_DEFINE(LOCALTIME_CACHE, 1,
2847             [Define to 1 if localtime caches TZ.])
2848 fi
2849
2850 if test "x$HAVE_TIMEVAL" = xyes; then
2851   AC_CHECK_FUNCS(gettimeofday)
2852   if test $ac_cv_func_gettimeofday = yes; then
2853     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2854                    emacs_cv_gettimeofday_two_arguments,
2855     [AC_TRY_COMPILE([
2856 #ifdef TIME_WITH_SYS_TIME
2857 #include <sys/time.h>
2858 #include <time.h>
2859 #else
2860 #ifdef HAVE_SYS_TIME_H
2861 #include <sys/time.h>
2862 #else
2863 #include <time.h>
2864 #endif
2865 #endif],
2866       [struct timeval time;
2867        gettimeofday (&time, 0);],
2868       emacs_cv_gettimeofday_two_arguments=yes,
2869       emacs_cv_gettimeofday_two_arguments=no)])
2870     if test $emacs_cv_gettimeofday_two_arguments = no; then
2871       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2872                 [Define to 1 if gettimeofday accepts only one argument.])
2873     fi
2874   fi
2875 fi
2876
2877 ok_so_far=yes
2878 AC_CHECK_FUNC(socket, , ok_so_far=no)
2879 if test $ok_so_far = yes; then
2880   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2881 fi
2882 if test $ok_so_far = yes; then
2883   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2884 fi
2885 if test $ok_so_far = yes; then
2886 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2887   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2888             [Define to 1 if you have inet sockets.])
2889 fi
2890
2891 AC_CHECK_HEADERS(sys/ioctl.h)
2892
2893 if test -f /usr/lpp/X11/bin/smt.exp; then
2894   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2895             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2896 fi
2897
2898 AC_MSG_CHECKING(whether system supports dynamic ptys)
2899 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2900   AC_MSG_RESULT(yes)
2901   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2902 else
2903   AC_MSG_RESULT(no)
2904 fi
2905
2906 AC_FUNC_FORK
2907
2908 dnl Adapted from Haible's version.
2909 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2910   [AC_TRY_LINK([#include <langinfo.h>],
2911     [char* cs = nl_langinfo(CODESET);],
2912     emacs_cv_langinfo_codeset=yes,
2913     emacs_cv_langinfo_codeset=no)
2914   ])
2915 if test $emacs_cv_langinfo_codeset = yes; then
2916   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2917     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2918 fi
2919
2920 AC_CHECK_TYPES(size_t)
2921
2922 AC_TYPE_MBSTATE_T
2923
2924 dnl Restrict could probably be used effectively other than in regex.c.
2925 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2926   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2927                   emacs_cv_c_restrict=yes,
2928                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2929                                   emacs_cv_c_restrict=__restrict,
2930                                   emacs_cv_c_restrict=no)])])
2931 case "$emacs_cv_c_restrict" in
2932   yes) emacs_restrict=restrict;;
2933   no) emacs_restrict="";;
2934   *) emacs_restrict="$emacs_cv_c_restrict";;
2935 esac
2936 if test "$emacs_restrict" != __restrict; then
2937   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2938     [Define to compiler's equivalent of C99 restrict keyword.
2939      Don't define if equivalent is `__restrict'.])
2940 fi
2941
2942 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2943   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2944                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2945 if test "$emacs_cv_c_restrict_arr" = yes; then
2946   AC_DEFINE(__restrict_arr, __restrict,
2947     [Define to compiler's equivalent of C99 restrict keyword in array
2948      declarations.  Define as empty for no equivalent.])
2949 fi
2950
2951 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2952 dnl how the tty code is related to POSIX and/or other versions of termios.
2953 dnl The following looks like a useful start.
2954 dnl
2955 dnl AC_SYS_POSIX_TERMIOS
2956 dnl if test $ac_cv_sys_posix_termios = yes; then
2957 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2958 dnl                                and macros for terminal control.])
2959 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2960 dnl fi
2961
2962 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2963
2964 # Set up the CFLAGS for real compilation, so we can substitute it.
2965 CFLAGS="$REAL_CFLAGS"
2966 CPPFLAGS="$REAL_CPPFLAGS"
2967
2968 ## Hack to detect a buggy GCC version.
2969 if test "x$GCC" = xyes \
2970    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
2971    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
2972    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
2973    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
2974 fi
2975
2976 #### Find out which version of Emacs this is.
2977 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2978          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2979 if test x"${version}" = x; then
2980   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2981 fi
2982 if test x"${version}" != x"$PACKAGE_VERSION"; then
2983   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2984 fi
2985
2986 ### Specify what sort of things we'll be editing into Makefile and config.h.
2987 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2988 AC_SUBST(version)
2989 AC_SUBST(configuration)
2990 AC_SUBST(canonical)
2991 AC_SUBST(srcdir)
2992 AC_SUBST(prefix)
2993 AC_SUBST(exec_prefix)
2994 AC_SUBST(bindir)
2995 AC_SUBST(datadir)
2996 AC_SUBST(sharedstatedir)
2997 AC_SUBST(libexecdir)
2998 AC_SUBST(mandir)
2999 AC_SUBST(infodir)
3000 AC_SUBST(lispdir)
3001 AC_SUBST(locallisppath)
3002 AC_SUBST(lisppath)
3003 AC_SUBST(x_default_search_path)
3004 AC_SUBST(etcdir)
3005 AC_SUBST(archlibdir)
3006 AC_SUBST(docdir)
3007 AC_SUBST(bitmapdir)
3008 AC_SUBST(gamedir)
3009 AC_SUBST(gameuser)
3010 AC_SUBST(unexec)
3011 AC_SUBST(LD_SWITCH_X_SITE)
3012 AC_SUBST(C_SWITCH_X_SITE)
3013 AC_SUBST(C_SWITCH_X_SYSTEM)
3014 AC_SUBST(CFLAGS)
3015 ## Used in lwlib/Makefile.in.
3016 AC_SUBST(X_TOOLKIT_TYPE)
3017 AC_SUBST(machfile)
3018 AC_SUBST(opsysfile)
3019 AC_SUBST(GETLOADAVG_LIBS)
3020 AC_SUBST(ns_appdir)
3021 AC_SUBST(ns_appbindir)
3022 AC_SUBST(ns_appresdir)
3023 AC_SUBST(ns_appsrc)
3024 AC_SUBST(GNUSTEP_MAKEFILES)
3025 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
3026 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
3027 AC_SUBST(GNU_OBJC_CFLAGS)
3028 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
3029 AC_SUBST(OTHER_FILES)
3030
3031 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3032                    [Define to the canonical Emacs configuration name.])
3033 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3034                    [Define to the options passed to configure.])
3035 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3036                    [Define to the used machine dependent file.])
3037 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3038                    [Define to the used os dependent file.])
3039 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
3040 [Define LD_SWITCH_X_SITE to contain any special flags your loader
3041  may need to deal with X Windows.  For instance, if you've defined
3042  HAVE_X_WINDOWS above and your X libraries aren't in a place that
3043  your loader can find on its own, you might want to add "-L/..." or
3044  something similar.])
3045 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
3046 [Define C_SWITCH_X_SITE to contain any special flags your compiler
3047  may need to deal with X Windows.  For instance, if you've defined
3048  HAVE_X_WINDOWS above and your X include files aren't in a place
3049  that your compiler can find on its own, you might want to add
3050  "-I/..." or something similar.])
3051
3052 XMENU_OBJ=
3053 XOBJ=
3054 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3055   AC_DEFINE(HAVE_X_WINDOWS, 1,
3056             [Define to 1 if you want to use the X window system.])
3057   XMENU_OBJ=xmenu.o
3058   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3059 fi
3060 AC_SUBST(XMENU_OBJ)
3061 AC_SUBST(XOBJ)
3062
3063 WIDGET_OBJ=
3064 MOTIF_LIBW=
3065 if test "${USE_X_TOOLKIT}" != "none" ; then
3066   WIDGET_OBJ=widget.o
3067   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3068   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3069     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3070   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3071     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3072     MOTIF_LIBW=-lXm
3073     case "$opsys" in
3074       gnu-linux)
3075         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3076         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3077         ;;
3078
3079       unixware)
3080         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3081         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3082         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3083         ;;
3084
3085       aix4-2)
3086         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3087         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3088         ;;
3089     esac
3090     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3091   fi
3092 fi
3093 AC_SUBST(WIDGET_OBJ)
3094
3095 TOOLKIT_LIBW=
3096 case "$USE_X_TOOLKIT" in
3097   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3098   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3099   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3100 esac
3101 AC_SUBST(TOOLKIT_LIBW)
3102
3103 if test "$USE_X_TOOLKIT" = "none"; then
3104   LIBXT_OTHER="\$(LIBXSM)"
3105 else
3106   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3107 fi
3108 AC_SUBST(LIBXT_OTHER)
3109
3110 ## The X Menu stuff is present in the X10 distribution, but missing
3111 ## from X11.  If we have X10, just use the installed library;
3112 ## otherwise, use our own copy.
3113 if test "${HAVE_X11}" = "yes" ; then
3114   AC_DEFINE(HAVE_X11, 1,
3115             [Define to 1 if you want to use version 11 of X windows.
3116              Otherwise, Emacs expects to use version 10.])
3117
3118   if test "$USE_X_TOOLKIT" = "none"; then
3119     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3120   else
3121     OLDXMENU="\${lwlibdir}liblw.a"
3122   fi
3123   LIBXMENU="\$(OLDXMENU)"
3124   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3125 else
3126   OLDXMENU=
3127   LIBXMENU="-lXMenu"
3128   LIBX_OTHER=
3129 fi
3130
3131 if test "$HAVE_GTK" = "yes"; then
3132   OLDXMENU=
3133   LIBXMENU=
3134 fi
3135
3136 AC_SUBST(OLDXMENU)
3137 AC_SUBST(LIBXMENU)
3138 AC_SUBST(LIBX_OTHER)
3139
3140 if test "${HAVE_MENUS}" = "yes" ; then
3141   AC_DEFINE(HAVE_MENUS, 1,
3142             [Define to 1 if you have mouse menus.
3143              (This is automatic if you use X, but the option to specify it remains.)
3144              It is also defined with other window systems that support xmenu.c.])
3145 fi
3146 if test "${GNU_MALLOC}" = "yes" ; then
3147   AC_DEFINE(GNU_MALLOC, 1,
3148             [Define to 1 if you want to use the GNU memory allocator.])
3149 fi
3150 if test "${REL_ALLOC}" = "yes" ; then
3151   AC_DEFINE(REL_ALLOC, 1,
3152             [Define REL_ALLOC if you want to use the relocating allocator for
3153              buffer space.])
3154 fi
3155
3156
3157 if test "$opsys" = "cygwin"; then
3158   CYGWIN_OBJ="sheap.o"
3159   ## Cygwin differs because of its unexec().
3160   PRE_ALLOC_OBJ=
3161   POST_ALLOC_OBJ="lastfile.o vm-limit.o"
3162 else
3163   CYGWIN_OBJ=
3164   PRE_ALLOC_OBJ=lastfile.o
3165   POST_ALLOC_OBJ="\$(vmlimitobj)"
3166 fi
3167 AC_SUBST(CYGWIN_OBJ)
3168 AC_SUBST(PRE_ALLOC_OBJ)
3169 AC_SUBST(POST_ALLOC_OBJ)
3170
3171
3172 case "$opsys" in
3173   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3174
3175   darwin)
3176   ## The -headerpad option tells ld (see man page) to leave room at the
3177   ## end of the header for adding load commands.  Needed for dumping.
3178   ## 0x690 is the total size of 30 segment load commands (at 56
3179   ## each); under Cocoa 31 commands are required.
3180   if test "$HAVE_NS" = "yes"; then
3181     libs_nsgui="-framework AppKit"
3182     headerpad_extra=6C8
3183   else
3184     libs_nsgui=
3185     headerpad_extra=690
3186   fi
3187   LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3188   ;;
3189
3190   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3191 esac
3192 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3193
3194
3195 ## This exists because src/Makefile.in did some extra fiddling around
3196 ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3197 ##   #ifndef LD_SWITCH_SYSTEM
3198 ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3199 ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3200 ## not using gcc, darwin system not on an alpha (ie darwin, since
3201 ## darwin + alpha does not occur).
3202 ## Note that unlike L_S_S, this is not used in ac_link.
3203 if test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3204    test "$opsys" = "darwin"; then
3205   LD_SWITCH_SYSTEM_EXTRA="-X"
3206 else
3207   LD_SWITCH_SYSTEM_EXTRA=
3208 fi
3209 AC_SUBST(LD_SWITCH_SYSTEM_EXTRA)
3210
3211
3212 AH_TOP([/* GNU Emacs site configuration template file.
3213    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3214      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3215
3216 This file is part of GNU Emacs.
3217
3218 GNU Emacs is free software: you can redistribute it and/or modify
3219 it under the terms of the GNU General Public License as published by
3220 the Free Software Foundation, either version 3 of the License, or
3221 (at your option) any later version.
3222
3223 GNU Emacs is distributed in the hope that it will be useful,
3224 but WITHOUT ANY WARRANTY; without even the implied warranty of
3225 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3226 GNU General Public License for more details.
3227
3228 You should have received a copy of the GNU General Public License
3229 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3230
3231
3232 /* No code in Emacs #includes config.h twice, but some bits of code
3233    intended to work with other packages as well (like gmalloc.c)
3234    think they can include it as many times as they like.  */
3235 #ifndef EMACS_CONFIG_H
3236 #define EMACS_CONFIG_H
3237 ])dnl
3238
3239 AH_BOTTOM([
3240 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
3241 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
3242 #define HAVE_WINDOW_SYSTEM
3243 #define HAVE_MOUSE
3244 #endif
3245
3246 /* Define AMPERSAND_FULL_NAME if you use the convention
3247    that & in the full name stands for the login id.  */
3248 /* Turned on June 1996 supposing nobody will mind it.  */
3249 #define AMPERSAND_FULL_NAME
3250
3251 /* Define HAVE_SOUND if we have sound support.  We know it works
3252    and compiles only on the specified platforms.   For others,
3253    it probably doesn't make sense to try.  */
3254
3255 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3256 #ifdef HAVE_MACHINE_SOUNDCARD_H
3257 #define HAVE_SOUND 1
3258 #endif
3259 #ifdef HAVE_SYS_SOUNDCARD_H
3260 #define HAVE_SOUND 1
3261 #endif
3262 #ifdef HAVE_SOUNDCARD_H
3263 #define HAVE_SOUND 1
3264 #endif
3265 #ifdef HAVE_ALSA
3266 #define HAVE_SOUND 1
3267 #endif
3268 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3269
3270 /* If using GNU, then support inline function declarations. */
3271 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3272    generally, because even if non-gcc compilers accept `inline', they
3273    may reject `extern inline'.  */
3274 #if defined (__GNUC__) && defined (OPTIMIZE)
3275 #define INLINE __inline__
3276 #else
3277 #define INLINE
3278 #endif
3279
3280 /* `subprocesses' should be defined if you want to
3281    have code for asynchronous subprocesses
3282    (as used in M-x compile and M-x shell).
3283    Only MSDOS does not support this (it overrides
3284    this in its config_opsysfile below).  */
3285
3286 #define subprocesses
3287
3288 /* Include the os and machine dependent files.  */
3289 #include config_opsysfile
3290 #include config_machfile
3291
3292 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3293   (There is probably a better place to do this, but right now the Cocoa
3294    side does this in s/darwin.h and we cannot
3295    parallel this exactly since GNUstep is multi-OS. */
3296 #ifdef HAVE_NS
3297 # ifdef NS_IMPL_GNUSTEP
3298 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3299 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3300 #  define SYSTEM_PURESIZE_EXTRA 30000
3301 # endif /* NS_IMPL_GNUSTEP */
3302 #endif /* HAVE_NS */
3303
3304 /* SIGTYPE is the macro we actually use.  */
3305 #ifndef SIGTYPE
3306 #define SIGTYPE RETSIGTYPE
3307 #endif
3308
3309 #ifdef emacs /* Don't do this for lib-src.  */
3310 /* Tell regex.c to use a type compatible with Emacs.  */
3311 #define RE_TRANSLATE_TYPE Lisp_Object
3312 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3313 #ifdef make_number
3314 /* If make_number is a macro, use it.  */
3315 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3316 #else
3317 /* If make_number is a function, avoid it.  */
3318 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3319 #endif
3320 #endif
3321
3322 /* Avoid link-time collision with system mktime if we will use our own.  */
3323 #if ! HAVE_MKTIME || BROKEN_MKTIME
3324 #define mktime emacs_mktime
3325 #endif
3326
3327 #define my_strftime nstrftime   /* for strftime.c */
3328
3329 /* The rest of the code currently tests the CPP symbol BSTRING.
3330    Override any claims made by the system-description files.
3331    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3332 #undef BSTRING
3333 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3334 #define BSTRING
3335 #endif
3336
3337 /* Some of the files of Emacs which are intended for use with other
3338    programs assume that if you have a config.h file, you must declare
3339    the type of getenv.
3340
3341    This declaration shouldn't appear when alloca.s or Makefile.in
3342    includes config.h.  */
3343 #ifndef NOT_C_CODE
3344 extern char *getenv ();
3345 #endif
3346
3347 /* These default definitions are good for almost all machines.
3348    The exceptions override them in m/MACHINE.h.  */
3349
3350 #ifndef BITS_PER_CHAR
3351 #define BITS_PER_CHAR 8
3352 #endif
3353
3354 #ifndef BITS_PER_SHORT
3355 #define BITS_PER_SHORT 16
3356 #endif
3357
3358 /* Note that lisp.h uses this in a preprocessor conditional, so it
3359    would not work to use sizeof.  That being so, we do all of them
3360    without sizeof, for uniformity's sake.  */
3361 #ifndef BITS_PER_INT
3362 #define BITS_PER_INT 32
3363 #endif
3364
3365 #ifndef BITS_PER_LONG
3366 #ifdef _LP64
3367 #define BITS_PER_LONG 64
3368 #else
3369 #define BITS_PER_LONG 32
3370 #endif
3371 #endif
3372
3373 /* Define if the compiler supports function prototypes.  It may do so
3374    but not define __STDC__ (e.g. DEC C by default) or may define it as
3375    zero.  */
3376 #undef PROTOTYPES
3377 /* For mktime.c:  */
3378 #ifndef __P
3379 # if defined PROTOTYPES
3380 #  define __P(args) args
3381 # else
3382 #  define __P(args) ()
3383 # endif  /* GCC.  */
3384 #endif /* __P */
3385
3386 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3387 #ifndef NOT_C_CODE
3388 #ifdef HAVE_STRING_H
3389 #include "string.h"
3390 #endif
3391 #ifdef HAVE_STRINGS_H
3392 #include "strings.h"  /* May be needed for bcopy & al. */
3393 #endif
3394 #ifdef HAVE_STDLIB_H
3395 #include <stdlib.h>
3396 #endif
3397 #ifndef __GNUC__
3398 # ifdef HAVE_ALLOCA_H
3399 #  include <alloca.h>
3400 # else /* AIX files deal with #pragma.  */
3401 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3402 char *alloca ();
3403 #  endif
3404 # endif /* HAVE_ALLOCA_H */
3405 #endif /* __GNUC__ */
3406 #ifndef HAVE_SIZE_T
3407 typedef unsigned size_t;
3408 #endif
3409 #endif /* NOT_C_CODE */
3410
3411 /* Define HAVE_X_I18N if we have usable i18n support.  */
3412
3413 #ifdef HAVE_X11R6
3414 #define HAVE_X_I18N
3415 #elif !defined X11R5_INHIBIT_I18N
3416 #define HAVE_X_I18N
3417 #endif
3418
3419 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3420
3421 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3422 #define HAVE_X11R6_XIM
3423 #endif
3424
3425 #if defined __GNUC__ && (__GNUC__ > 2 \
3426                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3427 #define NO_RETURN       __attribute__ ((__noreturn__))
3428 #else
3429 #define NO_RETURN       /* nothing */
3430 #endif
3431
3432 /* These won't be used automatically yet.  We also need to know, at least,
3433    that the stack is continuous.  */
3434 #ifdef __GNUC__
3435 #  ifndef GC_SETJMP_WORKS
3436   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3437      see NON_SAVING_SETJMP in the target descriptions.  */
3438   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3439      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3440      Fixme: Deal with SVR3.  */
3441 #    define GC_SETJMP_WORKS 1
3442 #  endif
3443 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3444 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3445 #  endif
3446 #endif
3447
3448 #ifndef HAVE_BCOPY
3449 #define bcopy(a,b,s) memcpy (b,a,s)
3450 #endif
3451 #ifndef HAVE_BZERO
3452 #define bzero(a,s) memset (a,0,s)
3453 #endif
3454 #ifndef HAVE_BCMP
3455 #define BCMP memcmp
3456 #endif
3457
3458 #endif /* EMACS_CONFIG_H */
3459
3460 /*
3461 Local Variables:
3462 mode: c
3463 End:
3464 */
3465 ])dnl
3466
3467 #### Report on what we decided to do.
3468 #### Report GTK as a toolkit, even if it doesn't use Xt.
3469 #### It makes printing result more understandable as using GTK sets
3470 #### toolkit_scroll_bars to yes by default.
3471 if test "${HAVE_GTK}" = "yes"; then
3472   USE_X_TOOLKIT=GTK
3473 fi
3474
3475 echo "
3476 Configured for \`${canonical}'.
3477
3478   Where should the build process find the source code?    ${srcdir}
3479   What operating system and machine description files should Emacs use?
3480         \`${opsysfile}' and \`${machfile}'
3481   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3482   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3483   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3484   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3485   What window system should Emacs use?                    ${window_system}
3486   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3487
3488 if test -n "${x_includes}"; then
3489 echo "  Where do we find X Windows header files?                ${x_includes}"
3490 else
3491 echo "  Where do we find X Windows header files?                Standard dirs"
3492 fi
3493 if test -n "${x_libraries}"; then
3494 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3495 else
3496 echo "  Where do we find X Windows libraries?                   Standard dirs"
3497 fi
3498
3499 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3500 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3501 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3502 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3503 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3504 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3505 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3506 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3507 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3508 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3509 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3510
3511 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3512 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3513 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3514 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3515
3516 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3517 echo
3518
3519 if test $USE_XASSERTS = yes; then
3520    echo "  Compiling with asserts turned on."
3521    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3522 fi
3523
3524 echo
3525
3526 if test "$HAVE_NS" = "yes"; then
3527    echo
3528    echo "You must run \"make install\" in order to test the built application.
3529 The installed application will go to nextstep/Emacs.app and can be
3530 run or moved from there."
3531    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3532       echo "The application will be fully self-contained."
3533     else
3534       echo "The lisp resources for the application will be installed under ${prefix}.
3535 You may need to run \"make install\" with sudo.  The application will fail
3536 to run if these resources are not installed."
3537    fi
3538    echo
3539 fi
3540
3541 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3542   echo "D-Bus integration has been tested for GNU/Linux only."
3543   echo
3544 fi
3545
3546
3547 # Remove any trailing slashes in these variables.
3548 [test "${prefix}" != NONE &&
3549   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3550 test "${exec_prefix}" != NONE &&
3551   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3552
3553 # Now get this: Some word that is part of the ${srcdir} directory name
3554 # or the ${configuration} value might, just might, happen to be an
3555 # identifier like `sun4' or `i386' or something, and be predefined by
3556 # the C preprocessor to some helpful value like 1, or maybe the empty
3557 # string.  Needless to say consequent macro substitutions are less
3558 # than conducive to the makefile finding the correct directory.
3559 [cpp_undefs="`echo $srcdir $configuration $canonical unix |
3560   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3561   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3562
3563 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3564 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3565 ## from Makefile.c can correctly provide the arg `-traditional' to the
3566 ## C preprocessor.
3567
3568 AC_EGREP_CPP(yes..yes,
3569         [yes..yes],
3570         CPP_NEED_TRADITIONAL=no,
3571         CPP_NEED_TRADITIONAL=yes)
3572
3573 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3574         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3575         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3576         lwlib/Makefile lisp/Makefile leim/Makefile, [
3577
3578 ### Make the necessary directories, if they don't exist.
3579 for dir in etc lisp ; do
3580   test -d ${dir} || mkdir ${dir}
3581 done
3582
3583 # Build src/Makefile from ${srcdir}/src/Makefile.c
3584 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3585 # This must be done after src/config.h is built, since we rely on that file.
3586
3587 echo creating src/epaths.h
3588 ${MAKE-make} epaths-force
3589
3590 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3591 # `..' to `. .'  unless invoked with -traditional
3592
3593 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3594   CPPFLAGS="$CPPFLAGS -traditional"
3595 fi
3596
3597 echo creating lib-src/Makefile
3598 ( cd lib-src
3599   rm -f junk.c junk1.c junk2.c
3600   sed -e '/start of cpp stuff/q' \
3601       < Makefile.c > junk1.c
3602   sed -e '1,/start of cpp stuff/d'\
3603       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3604       < Makefile.c > junk.c
3605   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3606       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3607   cat junk1.c junk2.c > Makefile.new
3608   rm -f junk.c junk1.c junk2.c
3609   chmod 444 Makefile.new
3610   mv -f Makefile.new Makefile
3611 )
3612
3613 echo creating src/Makefile
3614 ( cd src
3615   rm -f junk.c junk1.c junk2.c
3616   sed -e '/start of cpp stuff/q' \
3617       < Makefile.c > junk1.c
3618   sed -e '1,/start of cpp stuff/d'\
3619       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3620       < Makefile.c > junk.c
3621   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3622       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3623   cat junk1.c junk2.c > Makefile.new
3624   rm -f junk.c junk1.c junk2.c
3625   chmod 444 Makefile.new
3626   mv -f Makefile.new Makefile
3627 )
3628
3629 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3630   echo creating src/.gdbinit
3631   echo source $srcdir/src/.gdbinit > src/.gdbinit
3632 fi
3633
3634 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3635
3636 m4_if(dnl       Do not change this comment
3637    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3638 )dnl