lisp/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is a mercurial version control backend
  26
  27 ;;; Thanks:
  28
  29 ;;; Bugs:
  30
  31 ;;; Installation:
  32
  33 ;;; Todo:
  34
  35 ;; 1) Implement the rest of the vc interface. See the comment at the
  36 ;; beginning of vc.el. The current status is:
  37
  38 ;; FUNCTION NAME                               STATUS
  39 ;; BACKEND PROPERTIES
  40 ;; * revision-granularity                      OK
  41 ;; STATE-QUERYING FUNCTIONS
  42 ;; * registered (file)                         OK
  43 ;; * state (file)                              OK
  44 ;; - state-heuristic (file)                    NOT NEEDED
  45 ;; - dir-status (dir update-function)          OK
  46 ;; - dir-status-files (dir files ds uf)        OK
  47 ;; - dir-extra-headers (dir)                   OK
  48 ;; - dir-printer (fileinfo)                    OK
  49 ;; * working-revision (file)                   OK
  50 ;; - latest-on-branch-p (file)                 ??
  51 ;; * checkout-model (files)                    OK
  52 ;; - workfile-unchanged-p (file)               OK
  53 ;; - mode-line-string (file)                   NOT NEEDED
  54 ;; STATE-CHANGING FUNCTIONS
  55 ;; * register (files &optional rev comment)    OK
  56 ;; * create-repo ()                            OK
  57 ;; - init-revision ()                          NOT NEEDED
  58 ;; - responsible-p (file)                      OK
  59 ;; - could-register (file)                     OK
  60 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  61 ;; - unregister (file)                         COMMENTED OUT, MAY BE INCORRECT
  62 ;; * checkin (files rev comment)               OK
  63 ;; * find-revision (file rev buffer)           OK
  64 ;; * checkout (file &optional editable rev)    OK
  65 ;; * revert (file &optional contents-done)     OK
  66 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  67 ;; - merge (file rev1 rev2)                    NEEDED
  68 ;; - merge-news (file)                         NEEDED
  69 ;; - steal-lock (file &optional revision)      NOT NEEDED
  70 ;; HISTORY FUNCTIONS
  71 ;; * print-log (files &optional buffer shortlog)OK
  72 ;; - log-view-mode ()                          OK
  73 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  74 ;; - comment-history (file)                    NOT NEEDED
  75 ;; - update-changelog (files)                  NOT NEEDED
  76 ;; * diff (files &optional rev1 rev2 buffer)   OK
  77 ;; - revision-completion-table (files)         OK?
  78 ;; - annotate-command (file buf &optional rev) OK
  79 ;; - annotate-time ()                          OK
  80 ;; - annotate-current-time ()                  NOT NEEDED
  81 ;; - annotate-extract-revision-at-line ()      OK
  82 ;; TAG SYSTEM
  83 ;; - create-tag (dir name branchp)             NEEDED
  84 ;; - retrieve-tag (dir name update)            NEEDED
  85 ;; MISCELLANEOUS
  86 ;; - make-version-backups-p (file)             ??
  87 ;; - repository-hostname (dirname)             ??
  88 ;; - previous-revision (file rev)              OK
  89 ;; - next-revision (file rev)                  OK
  90 ;; - check-headers ()                          ??
  91 ;; - clear-headers ()                          ??
  92 ;; - delete-file (file)                        TEST IT
  93 ;; - rename-file (old new)                     OK
  94 ;; - find-file-hook ()                         PROBABLY NOT NEEDED
  95
  96 ;; 2) Implement Stefan Monnier's advice:
  97 ;; vc-hg-registered and vc-hg-state
  98 ;; Both of those functions should be super extra careful to fail gracefully in
  99 ;; unexpected circumstances. The reason this is important is that any error
 100 ;; there will prevent the user from even looking at the file :-(
 101 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
 102 ;; mercurial's control and extracting the current revision should be done
 103 ;; without even using `hg' (this way even if you don't have `hg' installed,
 104 ;; Emacs is able to tell you this file is under mercurial's control).
 105
 106 ;;; History:
 107 ;;
 108
 109 ;;; Code:
 110
 111 (eval-when-compile
 112   (require 'cl)
 113   (require 'vc)
 114   (require 'vc-dir))
 115
 116 ;;; Customization options
 117
 118 (defcustom vc-hg-global-switches nil
 119   "Global switches to pass to any Hg command."
 120   :type '(choice (const :tag "None" nil)
 121          (string :tag "Argument String")
 122          (repeat :tag "Argument List" :value ("") string))
 123   :version "22.2"
 124   :group 'vc)
 125
 126 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 127   "String or list of strings specifying switches for Hg diff under VC.
 128 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 129   :type '(choice (const :tag "Unspecified" nil)
 130                  (const :tag "None" t)
 131                  (string :tag "Argument String")
 132                  (repeat :tag "Argument List" :value ("") string))
 133   :version "23.1"
 134   :group 'vc)
 135
 136 \f
 137 ;;; Properties of the backend
 138
 139 (defun vc-hg-revision-granularity () 'repository)
 140 (defun vc-hg-checkout-model (files) 'implicit)
 141
 142 ;;; State querying functions
 143
 144 ;;;###autoload (defun vc-hg-registered (file)
 145 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 146 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 147 ;;;###autoload       (progn
 148 ;;;###autoload         (load "vc-hg")
 149 ;;;###autoload         (vc-hg-registered file))))
 150
 151 ;; Modeled after the similar function in vc-bzr.el
 152 (defun vc-hg-registered (file)
 153   "Return non-nil if FILE is registered with hg."
 154   (when (vc-hg-root file)           ; short cut
 155     (let ((state (vc-hg-state file)))  ; expensive
 156       (and state (not (memq state '(ignored unregistered)))))))
 157
 158 (defun vc-hg-state (file)
 159   "Hg-specific version of `vc-state'."
 160   (let*
 161       ((status nil)
 162        (out
 163         (with-output-to-string
 164           (with-current-buffer
 165               standard-output
 166             (setq status
 167                   (condition-case nil
 168                       ;; Ignore all errors.
 169                       (call-process
 170                        "hg" nil t nil "--cwd" (file-name-directory file)
 171                        "status" "-A" (file-name-nondirectory file))
 172                     ;; Some problem happened.  E.g. We can't find an `hg'
 173                     ;; executable.
 174                     (error nil)))))))
 175     (when (eq 0 status)
 176         (when (null (string-match ".*: No such file or directory$" out))
 177           (let ((state (aref out 0)))
 178             (cond
 179              ((eq state ?=) 'up-to-date)
 180              ((eq state ?A) 'added)
 181              ((eq state ?M) 'edited)
 182              ((eq state ?I) 'ignored)
 183              ((eq state ?R) 'removed)
 184              ((eq state ?!) 'missing)
 185              ((eq state ??) 'unregistered)
 186              ((eq state ?C) 'up-to-date) ;; Older mercurials use this
 187              (t 'up-to-date)))))))
 188
 189 (defun vc-hg-working-revision (file)
 190   "Hg-specific version of `vc-working-revision'."
 191   (let*
 192       ((status nil)
 193        (out
 194         (with-output-to-string
 195           (with-current-buffer
 196               standard-output
 197             (setq status
 198                   (condition-case nil
 199                       ;; Ignore all errors.
 200                       (call-process
 201                        "hg" nil t nil "--cwd" (file-name-directory file)
 202                        "log" "-l1" (file-name-nondirectory file))
 203                     ;; Some problem happened.  E.g. We can't find an `hg'
 204                     ;; executable.
 205                     (error nil)))))))
 206     (when (eq 0 status)
 207       (if (string-match "changeset: *\\([0-9]*\\)" out)
 208           (match-string 1 out)
 209         "0"))))
 210
 211 ;;; History functions
 212
 213 (defcustom vc-hg-log-switches nil
 214   "String or list of strings specifying switches for hg log under VC."
 215   :type '(choice (const :tag "None" nil)
 216                  (string :tag "Argument String")
 217                  (repeat :tag "Argument List" :value ("") string))
 218   :group 'vc-hg)
 219
 220 (defun vc-hg-print-log (files &optional buffer shortlog)
 221   "Get change log associated with FILES."
 222   ;; `log-view-mode' needs to have the file names in order to function
 223   ;; correctly. "hg log" does not print it, so we insert it here by
 224   ;; hand.
 225
 226   ;; `vc-do-command' creates the buffer, but we need it before running
 227   ;; the command.
 228   (vc-setup-buffer buffer)
 229   ;; If the buffer exists from a previous invocation it might be
 230   ;; read-only.
 231   (let ((inhibit-read-only t))
 232     (with-current-buffer
 233         buffer
 234       (apply 'vc-hg-command buffer 0 files "log"
 235              (if shortlog
 236                  (append '("--style" "compact") vc-hg-log-switches)
 237                  vc-hg-log-switches)))))
 238
 239 (defvar log-view-message-re)
 240 (defvar log-view-file-re)
 241 (defvar log-view-font-lock-keywords)
 242 (defvar log-view-per-file-logs)
 243 (defvar vc-short-log)
 244
 245 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 246   (require 'add-log) ;; we need the add-log faces
 247   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 248   (set (make-local-variable 'log-view-per-file-logs) nil)
 249   (set (make-local-variable 'log-view-message-re)
 250        (if vc-short-log
 251            "^\\([0-9]+\\)\\(?:\\[.*\\]\\)? +\\([0-9a-z]\\{12\\}\\) +\\(\\(?:[0-9]+\\)-\\(?:[0-9]+\\)-\\(?:[0-9]+\\) \\(?:[0-9]+\\):\\(?:[0-9]+\\) \\(?:[-+0-9]+\\)\\) +\\(.*\\)$"
 252          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 253   (set (make-local-variable 'log-view-font-lock-keywords)
 254        (if vc-short-log
 255            (append `((,log-view-message-re
 256                       (1 'log-view-message-face)
 257                       (2 'log-view-message-face)
 258                       (3 'change-log-date)
 259                       (4 'change-log-name))))
 260        (append
 261         log-view-font-lock-keywords
 262         '(
 263           ;; Handle the case:
 264           ;; user: FirstName LastName <foo@bar>
 265           ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 266            (1 'change-log-name)
 267            (2 'change-log-email))
 268           ;; Handle the cases:
 269           ;; user: foo@bar
 270           ;; and
 271           ;; user: foo
 272           ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 273            (1 'change-log-email))
 274           ("^date: \\(.+\\)" (1 'change-log-date))
 275             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 276
 277 (defun vc-hg-diff (files &optional oldvers newvers buffer)
 278   "Get a difference report using hg between two revisions of FILES."
 279   (let* ((firstfile (car files))
 280          (cwd (if firstfile (file-name-directory firstfile)
 281                 (expand-file-name default-directory)))
 282          (working (and firstfile (vc-working-revision firstfile))))
 283     (when (and (equal oldvers working) (not newvers))
 284       (setq oldvers nil))
 285     (when (and (not oldvers) newvers)
 286       (setq oldvers working))
 287     (apply #'vc-hg-command (or buffer "*vc-diff*") nil
 288            (mapcar (lambda (file) (file-relative-name file cwd)) files)
 289            "--cwd" cwd
 290            "diff"
 291            (append
 292             (vc-switches 'hg 'diff)
 293             (when oldvers
 294               (if newvers
 295                   (list "-r" oldvers "-r" newvers)
 296                 (list "-r" oldvers)))))))
 297
 298 (defun vc-hg-revision-table (files)
 299   (let ((default-directory (file-name-directory (car files))))
 300     (with-temp-buffer
 301       (vc-hg-command t nil files "log" "--template" "{rev} ")
 302       (split-string
 303        (buffer-substring-no-properties (point-min) (point-max))))))
 304
 305 ;; Modeled after the similar function in vc-cvs.el
 306 (defun vc-hg-revision-completion-table (files)
 307   (lexical-let ((files files)
 308                 table)
 309     (setq table (lazy-completion-table
 310                  table (lambda () (vc-hg-revision-table files))))
 311     table))
 312
 313 (defun vc-hg-annotate-command (file buffer &optional revision)
 314   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 315 Optional arg REVISION is a revision to annotate from."
 316   (vc-hg-command buffer 0 file "annotate" "-d" "-n"
 317                  (when revision (concat "-r" revision)))
 318   (with-current-buffer buffer
 319     (goto-char (point-min))
 320     (re-search-forward "^[ \t]*[0-9]")
 321     (delete-region (point-min) (match-beginning 0))))
 322
 323 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 324
 325 ;; The format for one line output by "hg annotate -d -n" looks like this:
 326 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 327 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 328 ;; If the user has set the "--follow" option, the output looks like:
 329 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 330 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 331 (defconst vc-hg-annotate-re
 332   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)[^:\n]*\\(:[^ \n][^:\n]*\\)*: ")
 333
 334 (defun vc-hg-annotate-time ()
 335   (when (looking-at vc-hg-annotate-re)
 336     (goto-char (match-end 0))
 337     (vc-annotate-convert-time
 338      (date-to-time (match-string-no-properties 2)))))
 339
 340 (defun vc-hg-annotate-extract-revision-at-line ()
 341   (save-excursion
 342     (beginning-of-line)
 343     (when (looking-at vc-hg-annotate-re) (match-string-no-properties 1))))
 344
 345 (defun vc-hg-previous-revision (file rev)
 346   (let ((newrev (1- (string-to-number rev))))
 347     (when (>= newrev 0)
 348       (number-to-string newrev))))
 349
 350 (defun vc-hg-next-revision (file rev)
 351   (let ((newrev (1+ (string-to-number rev)))
 352         (tip-revision
 353          (with-temp-buffer
 354            (vc-hg-command t 0 nil "tip")
 355            (goto-char (point-min))
 356            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 357            (string-to-number (match-string-no-properties 1)))))
 358     ;; We don't want to exceed the maximum possible revision number, ie
 359     ;; the tip revision.
 360     (when (<= newrev tip-revision)
 361       (number-to-string newrev))))
 362
 363 ;; Modeled after the similar function in vc-bzr.el
 364 (defun vc-hg-delete-file (file)
 365   "Delete FILE and delete it in the hg repository."
 366   (condition-case ()
 367       (delete-file file)
 368     (file-error nil))
 369   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 370
 371 ;; Modeled after the similar function in vc-bzr.el
 372 (defun vc-hg-rename-file (old new)
 373   "Rename file from OLD to NEW using `hg mv'."
 374   (vc-hg-command nil 0 new "mv" old))
 375
 376 (defun vc-hg-register (files &optional rev comment)
 377   "Register FILES under hg.
 378 REV is ignored.
 379 COMMENT is ignored."
 380   (vc-hg-command nil 0 files "add"))
 381
 382 (defun vc-hg-create-repo ()
 383   "Create a new Mercurial repository."
 384   (vc-hg-command nil 0 nil "init"))
 385
 386 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 387
 388 ;; Modeled after the similar function in vc-bzr.el
 389 (defun vc-hg-could-register (file)
 390   "Return non-nil if FILE could be registered under hg."
 391   (and (vc-hg-responsible-p file)      ; shortcut
 392        (condition-case ()
 393            (with-temp-buffer
 394              (vc-hg-command t nil file "add" "--dry-run"))
 395              ;; The command succeeds with no output if file is
 396              ;; registered.
 397          (error))))
 398
 399 ;; FIXME: This would remove the file. Is that correct?
 400 ;; (defun vc-hg-unregister (file)
 401 ;;   "Unregister FILE from hg."
 402 ;;   (vc-hg-command nil nil file "remove"))
 403
 404 (defun vc-hg-checkin (files rev comment)
 405   "Hg-specific version of `vc-backend-checkin'.
 406 REV is ignored."
 407   (vc-hg-command nil 0 files  "commit" "-m" comment))
 408
 409 (defun vc-hg-find-revision (file rev buffer)
 410   (let ((coding-system-for-read 'binary)
 411         (coding-system-for-write 'binary))
 412     (if rev
 413         (vc-hg-command buffer 0 file "cat" "-r" rev)
 414       (vc-hg-command buffer 0 file "cat"))))
 415
 416 ;; Modeled after the similar function in vc-bzr.el
 417 (defun vc-hg-checkout (file &optional editable rev)
 418   "Retrieve a revision of FILE.
 419 EDITABLE is ignored.
 420 REV is the revision to check out into WORKFILE."
 421   (let ((coding-system-for-read 'binary)
 422         (coding-system-for-write 'binary))
 423   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 424     (if rev
 425         (vc-hg-command t 0 file "cat" "-r" rev)
 426       (vc-hg-command t 0 file "cat")))))
 427
 428 ;; Modeled after the similar function in vc-bzr.el
 429 (defun vc-hg-workfile-unchanged-p (file)
 430   (eq 'up-to-date (vc-hg-state file)))
 431
 432 ;; Modeled after the similar function in vc-bzr.el
 433 (defun vc-hg-revert (file &optional contents-done)
 434   (unless contents-done
 435     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 436
 437 ;;; Hg specific functionality.
 438
 439 (defvar vc-hg-extra-menu-map
 440   (let ((map (make-sparse-keymap)))
 441     (define-key map [incoming] '(menu-item "Show incoming" vc-hg-incoming))
 442     (define-key map [outgoing] '(menu-item "Show outgoing" vc-hg-outgoing))
 443     map))
 444
 445 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 446
 447 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 448
 449 (define-derived-mode vc-hg-outgoing-mode vc-hg-log-view-mode "Hg-Outgoing")
 450
 451 (define-derived-mode vc-hg-incoming-mode vc-hg-log-view-mode "Hg-Incoming")
 452
 453 (defstruct (vc-hg-extra-fileinfo
 454             (:copier nil)
 455             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 456             (:conc-name vc-hg-extra-fileinfo->))
 457   rename-state        ;; rename or copy state
 458   extra-name)         ;; original name for copies and rename targets, new name for
 459
 460 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 461
 462 (defun vc-hg-dir-printer (info)
 463   "Pretty-printer for the vc-dir-fileinfo structure."
 464   (let ((extra (vc-dir-fileinfo->extra info)))
 465     (vc-default-dir-printer 'Hg info)
 466     (when extra
 467       (insert (propertize
 468                (format "   (%s %s)"
 469                        (case (vc-hg-extra-fileinfo->rename-state extra)
 470                          ('copied "copied from")
 471                          ('renamed-from "renamed from")
 472                          ('renamed-to "renamed to"))
 473                        (vc-hg-extra-fileinfo->extra-name extra))
 474                'face 'font-lock-comment-face)))))
 475
 476 (defun vc-hg-after-dir-status (update-function)
 477   (let ((status-char nil)
 478         (file nil)
 479         (translation '((?= . up-to-date)
 480                        (?C . up-to-date)
 481                        (?A . added)
 482                        (?R . removed)
 483                        (?M . edited)
 484                        (?I . ignored)
 485                        (?! . missing)
 486                        (?  . copy-rename-line)
 487                        (?? . unregistered)))
 488         (translated nil)
 489         (result nil)
 490         (last-added nil)
 491         (last-line-copy nil))
 492       (goto-char (point-min))
 493       (while (not (eobp))
 494         (setq translated (cdr (assoc (char-after) translation)))
 495         (setq file
 496               (buffer-substring-no-properties (+ (point) 2)
 497                                               (line-end-position)))
 498         (cond ((not translated)
 499                (setq last-line-copy nil))
 500               ((eq translated 'up-to-date)
 501                (setq last-line-copy nil))
 502               ((eq translated 'copy-rename-line)
 503                ;; For copied files the output looks like this:
 504                ;; A COPIED_FILE_NAME
 505                ;;   ORIGINAL_FILE_NAME
 506                (setf (nth 2 last-added)
 507                      (vc-hg-create-extra-fileinfo 'copied file))
 508                (setq last-line-copy t))
 509               ((and last-line-copy (eq translated 'removed))
 510                ;; For renamed files the output looks like this:
 511                ;; A NEW_FILE_NAME
 512                ;;   ORIGINAL_FILE_NAME
 513                ;; R ORIGINAL_FILE_NAME
 514                ;; We need to adjust the previous entry to not think it is a copy.
 515                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 516                      'renamed-from)
 517                (push (list file translated
 518                            (vc-hg-create-extra-fileinfo
 519                             'renamed-to (nth 0 last-added))) result)
 520                (setq last-line-copy nil))
 521               (t
 522                (setq last-added (list file translated nil))
 523                (push last-added result)
 524                (setq last-line-copy nil)))
 525         (forward-line))
 526       (funcall update-function result)))
 527
 528 (defun vc-hg-dir-status (dir update-function)
 529   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 530   (vc-exec-after
 531    `(vc-hg-after-dir-status (quote ,update-function))))
 532
 533 (defun vc-hg-dir-status-files (dir files default-state update-function)
 534   (apply 'vc-hg-command (current-buffer) 'async dir "status" "-C" files)
 535   (vc-exec-after
 536    `(vc-hg-after-dir-status (quote ,update-function))))
 537
 538 (defun vc-hg-dir-extra-header (name &rest commands)
 539   (concat (propertize name 'face 'font-lock-type-face)
 540           (propertize
 541            (with-temp-buffer
 542              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 543              (buffer-substring-no-properties (point-min) (1- (point-max))))
 544            'face 'font-lock-variable-name-face)))
 545
 546 (defun vc-hg-dir-extra-headers (dir)
 547   "Generate extra status headers for a Mercurial tree."
 548   (let ((default-directory dir))
 549     (concat
 550      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 551      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 552      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 553      ;; these change after each commit
 554      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 555      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 556      )))
 557
 558 ;; FIXME: this adds another top level menu, instead figure out how to
 559 ;; replace the Log-View menu.
 560 (easy-menu-define log-view-mode-menu vc-hg-outgoing-mode-map
 561   "Hg-outgoing Display Menu"
 562   `("Hg-outgoing"
 563     ["Push selected"  vc-hg-push]))
 564
 565 (easy-menu-define log-view-mode-menu vc-hg-incoming-mode-map
 566   "Hg-incoming Display Menu"
 567   `("Hg-incoming"
 568     ["Pull selected"  vc-hg-pull]))
 569
 570 (defun vc-hg-outgoing ()
 571   (interactive)
 572   (let ((bname "*Hg outgoing*"))
 573     (vc-hg-command bname 0 nil "outgoing" "-n")
 574     (pop-to-buffer bname)
 575     (vc-hg-outgoing-mode)))
 576
 577 (defun vc-hg-incoming ()
 578   (interactive)
 579   (let ((bname "*Hg incoming*"))
 580     (vc-hg-command bname 0 nil "incoming" "-n")
 581     (pop-to-buffer bname)
 582     (vc-hg-incoming-mode)))
 583
 584 (declare-function log-view-get-marked "log-view" ())
 585
 586 ;; XXX maybe also add key bindings for these functions.
 587 (defun vc-hg-push ()
 588   (interactive)
 589   (let ((marked-list (log-view-get-marked)))
 590     (if marked-list
 591         (vc-hg-command
 592          nil 0 nil
 593          (cons "push"
 594                (apply 'nconc
 595                       (mapcar (lambda (arg) (list "-r" arg)) marked-list))))
 596          (error "No log entries selected for push"))))
 597
 598 (defun vc-hg-pull ()
 599   (interactive)
 600   (let ((marked-list (log-view-get-marked)))
 601     (if marked-list
 602         (vc-hg-command
 603          nil 0 nil
 604          (cons "pull"
 605                (apply 'nconc
 606                       (mapcar (lambda (arg) (list "-r" arg)) marked-list))))
 607       (error "No log entries selected for pull"))))
 608
 609 ;;; Internal functions
 610
 611 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 612   "A wrapper around `vc-do-command' for use in vc-hg.el.
 613 The difference to vc-do-command is that this function always invokes `hg',
 614 and that it passes `vc-hg-global-switches' to it before FLAGS."
 615   (apply 'vc-do-command (or buffer "*vc*") okstatus "hg" file-or-list
 616          (if (stringp vc-hg-global-switches)
 617              (cons vc-hg-global-switches flags)
 618            (append vc-hg-global-switches
 619                    flags))))
 620
 621 (defun vc-hg-root (file)
 622   (vc-find-root file ".hg"))
 623
 624 (provide 'vc-hg)
 625
 626 ;; arch-tag: bd094dc5-715a-434f-a331-37b9fb7cd954
 627 ;;; vc-hg.el ends here