lisp/url/url-http.el

   1 ;;; url-http.el --- HTTP retrieval routines
   2
   3 ;; Copyright (C) 1999, 2001, 2004-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Bill Perry <wmperry@gnu.org>
   6 ;; Keywords: comm, data, processes
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl-lib))
  28
  29 (defvar url-callback-arguments)
  30 (defvar url-callback-function)
  31 (defvar url-current-object)
  32 (defvar url-http-after-change-function)
  33 (defvar url-http-chunked-counter)
  34 (defvar url-http-chunked-length)
  35 (defvar url-http-chunked-start)
  36 (defvar url-http-connection-opened)
  37 (defvar url-http-content-length)
  38 (defvar url-http-content-type)
  39 (defvar url-http-data)
  40 (defvar url-http-end-of-headers)
  41 (defvar url-http-extra-headers)
  42 (defvar url-http-method)
  43 (defvar url-http-no-retry)
  44 (defvar url-http-process)
  45 (defvar url-http-proxy)
  46 (defvar url-http-response-status)
  47 (defvar url-http-response-version)
  48 (defvar url-http-target-url)
  49 (defvar url-http-transfer-encoding)
  50 (defvar url-http-end-of-headers)
  51 (defvar url-show-status)
  52
  53 (require 'url-gw)
  54 (require 'url-util)
  55 (require 'url-parse)
  56 (require 'url-cookie)
  57 (require 'mail-parse)
  58 (require 'url-auth)
  59 (require 'url)
  60 (autoload 'url-cache-create-filename "url-cache")
  61
  62 (defconst url-http-default-port 80 "Default HTTP port.")
  63 (defconst url-http-asynchronous-p t "HTTP retrievals are asynchronous.")
  64 (defalias 'url-http-expand-file-name 'url-default-expander)
  65
  66 (defvar url-http-real-basic-auth-storage nil)
  67 (defvar url-http-proxy-basic-auth-storage nil)
  68
  69 (defvar url-http-open-connections (make-hash-table :test 'equal
  70                                                    :size 17)
  71   "A hash table of all open network connections.")
  72
  73 (defvar url-http-version "1.1"
  74   "What version of HTTP we advertise, as a string.
  75 Valid values are 1.1 and 1.0.
  76 This is only useful when debugging the HTTP subsystem.
  77
  78 Setting this to 1.0 will tell servers not to send chunked encoding,
  79 and other HTTP/1.1 specific features.")
  80
  81 (defvar url-http-attempt-keepalives t
  82   "Whether to use a single TCP connection multiple times in HTTP.
  83 This is only useful when debugging the HTTP subsystem.  Setting to
  84 nil will explicitly close the connection to the server after every
  85 request.")
  86
  87 (defconst url-http-codes
  88   '((100 continue                        "Continue with request")
  89     (101 switching-protocols             "Switching protocols")
  90     (102 processing                      "Processing (Added by DAV)")
  91     (200 OK                              "OK")
  92     (201 created                         "Created")
  93     (202 accepted                        "Accepted")
  94     (203 non-authoritative               "Non-authoritative information")
  95     (204 no-content                      "No content")
  96     (205 reset-content                   "Reset content")
  97     (206 partial-content                 "Partial content")
  98     (207 multi-status                    "Multi-status (Added by DAV)")
  99     (300 multiple-choices                "Multiple choices")
 100     (301 moved-permanently               "Moved permanently")
 101     (302 found                           "Found")
 102     (303 see-other                       "See other")
 103     (304 not-modified                    "Not modified")
 104     (305 use-proxy                       "Use proxy")
 105     (307 temporary-redirect              "Temporary redirect")
 106     (400 bad-request                     "Bad Request")
 107     (401 unauthorized                    "Unauthorized")
 108     (402 payment-required                "Payment required")
 109     (403 forbidden                       "Forbidden")
 110     (404 not-found                       "Not found")
 111     (405 method-not-allowed              "Method not allowed")
 112     (406 not-acceptable                  "Not acceptable")
 113     (407 proxy-authentication-required   "Proxy authentication required")
 114     (408 request-timeout                 "Request time-out")
 115     (409 conflict                        "Conflict")
 116     (410 gone                            "Gone")
 117     (411 length-required                 "Length required")
 118     (412 precondition-failed             "Precondition failed")
 119     (413 request-entity-too-large        "Request entity too large")
 120     (414 request-uri-too-large           "Request-URI too large")
 121     (415 unsupported-media-type          "Unsupported media type")
 122     (416 requested-range-not-satisfiable "Requested range not satisfiable")
 123     (417 expectation-failed              "Expectation failed")
 124     (422 unprocessable-entity            "Unprocessable Entity (Added by DAV)")
 125     (423 locked                          "Locked")
 126     (424 failed-Dependency               "Failed Dependency")
 127     (500 internal-server-error           "Internal server error")
 128     (501 not-implemented                 "Not implemented")
 129     (502 bad-gateway                     "Bad gateway")
 130     (503 service-unavailable             "Service unavailable")
 131     (504 gateway-timeout                 "Gateway time-out")
 132     (505 http-version-not-supported      "HTTP version not supported")
 133     (507 insufficient-storage            "Insufficient storage"))
 134   "The HTTP return codes and their text.")
 135
 136 ;(eval-when-compile
 137 ;; These are all macros so that they are hidden from external sight
 138 ;; when the file is byte-compiled.
 139 ;;
 140 ;; This allows us to expose just the entry points we want.
 141
 142 ;; These routines will allow us to implement persistent HTTP
 143 ;; connections.
 144 (defsubst url-http-debug (&rest args)
 145   (if quit-flag
 146       (let ((proc (get-buffer-process (current-buffer))))
 147         ;; The user hit C-g, honor it!  Some things can get in an
 148         ;; incredibly tight loop (chunked encoding)
 149         (if proc
 150             (progn
 151               (set-process-sentinel proc nil)
 152               (set-process-filter proc nil)))
 153         (error "Transfer interrupted!")))
 154   (apply 'url-debug 'http args))
 155
 156 (defun url-http-mark-connection-as-busy (host port proc)
 157   (url-http-debug "Marking connection as busy: %s:%d %S" host port proc)
 158   (set-process-query-on-exit-flag proc t)
 159   (puthash (cons host port)
 160               (delq proc (gethash (cons host port) url-http-open-connections))
 161               url-http-open-connections)
 162   proc)
 163
 164 (defun url-http-mark-connection-as-free (host port proc)
 165   (url-http-debug "Marking connection as free: %s:%d %S" host port proc)
 166   (when (memq (process-status proc) '(open run connect))
 167     (set-process-buffer proc nil)
 168     (set-process-sentinel proc 'url-http-idle-sentinel)
 169     (set-process-query-on-exit-flag proc nil)
 170     (puthash (cons host port)
 171              (cons proc (gethash (cons host port) url-http-open-connections))
 172              url-http-open-connections))
 173   nil)
 174
 175 (defun url-http-find-free-connection (host port)
 176   (let ((conns (gethash (cons host port) url-http-open-connections))
 177         (connection nil))
 178     (while (and conns (not connection))
 179       (if (not (memq (process-status (car conns)) '(run open connect)))
 180           (progn
 181             (url-http-debug "Cleaning up dead process: %s:%d %S"
 182                             host port (car conns))
 183             (url-http-idle-sentinel (car conns) nil))
 184         (setq connection (car conns))
 185         (url-http-debug "Found existing connection: %s:%d %S" host port connection))
 186       (pop conns))
 187     (if connection
 188         (url-http-debug "Reusing existing connection: %s:%d" host port)
 189       (url-http-debug "Contacting host: %s:%d" host port))
 190     (url-lazy-message "Contacting host: %s:%d" host port)
 191
 192     (unless connection
 193       (let ((buf (generate-new-buffer " *url-http-temp*")))
 194         ;; `url-open-stream' needs a buffer in which to do things
 195         ;; like authentication.  But we use another buffer afterwards.
 196         (unwind-protect
 197             (let ((proc (url-open-stream host buf host port)))
 198               ;; url-open-stream might return nil.
 199               (when (processp proc)
 200                 ;; Drop the temp buffer link before killing the buffer.
 201                 (set-process-buffer proc nil)
 202                 (setq connection proc)))
 203           ;; If there was an error on connect, make sure we don't
 204           ;; get queried.
 205           (when (get-buffer-process buf)
 206             (set-process-query-on-exit-flag (get-buffer-process buf) nil))
 207           (kill-buffer buf))))
 208
 209     (if connection
 210         (url-http-mark-connection-as-busy host port connection))))
 211
 212 ;; Building an HTTP request
 213 (defun url-http-user-agent-string ()
 214   (if (or (eq url-privacy-level 'paranoid)
 215           (and (listp url-privacy-level)
 216                (memq 'agent url-privacy-level)))
 217       ""
 218     (format "User-Agent: %sURL/%s\r\n"
 219             (if url-package-name
 220                 (concat url-package-name "/" url-package-version " ")
 221               "")
 222             url-version)))
 223
 224 (defun url-http-create-request (&optional ref-url)
 225   "Create an HTTP request for `url-http-target-url', referred to by REF-URL."
 226   (let* ((extra-headers)
 227          (request nil)
 228          (no-cache (cdr-safe (assoc "Pragma" url-http-extra-headers)))
 229          (using-proxy url-http-proxy)
 230          (proxy-auth (if (or (cdr-safe (assoc "Proxy-Authorization"
 231                                               url-http-extra-headers))
 232                              (not using-proxy))
 233                          nil
 234                        (let ((url-basic-auth-storage
 235                               'url-http-proxy-basic-auth-storage))
 236                          (url-get-authentication url-http-proxy nil 'any nil))))
 237          (real-fname (url-filename url-http-target-url))
 238          (host (url-host url-http-target-url))
 239          (auth (if (cdr-safe (assoc "Authorization" url-http-extra-headers))
 240                    nil
 241                  (url-get-authentication (or
 242                                           (and (boundp 'proxy-info)
 243                                                proxy-info)
 244                                           url-http-target-url) nil 'any nil))))
 245     (if (equal "" real-fname)
 246         (setq real-fname "/"))
 247     (setq no-cache (and no-cache (string-match "no-cache" no-cache)))
 248     (if auth
 249         (setq auth (concat "Authorization: " auth "\r\n")))
 250     (if proxy-auth
 251         (setq proxy-auth (concat "Proxy-Authorization: " proxy-auth "\r\n")))
 252
 253     ;; Protection against stupid values in the referrer
 254     (if (and ref-url (stringp ref-url) (or (string= ref-url "file:nil")
 255                                            (string= ref-url "")))
 256         (setq ref-url nil))
 257
 258     ;; We do not want to expose the referrer if the user is paranoid.
 259     (if (or (memq url-privacy-level '(low high paranoid))
 260             (and (listp url-privacy-level)
 261                  (memq 'lastloc url-privacy-level)))
 262         (setq ref-url nil))
 263
 264     ;; url-http-extra-headers contains an assoc-list of
 265     ;; header/value pairs that we need to put into the request.
 266     (setq extra-headers (mapconcat
 267                          (lambda (x)
 268                            (concat (car x) ": " (cdr x)))
 269                          url-http-extra-headers "\r\n"))
 270     (if (not (equal extra-headers ""))
 271         (setq extra-headers (concat extra-headers "\r\n")))
 272
 273     ;; This was done with a call to `format'.  Concatenating parts has
 274     ;; the advantage of keeping the parts of each header together and
 275     ;; allows us to elide null lines directly, at the cost of making
 276     ;; the layout less clear.
 277     (setq request
 278           ;; We used to concat directly, but if one of the strings happens
 279           ;; to being multibyte (even if it only contains pure ASCII) then
 280           ;; every string gets converted with `string-MAKE-multibyte' which
 281           ;; turns the 127-255 codes into things like latin-1 accented chars
 282           ;; (it would work right if it used `string-TO-multibyte' instead).
 283           ;; So to avoid the problem we force every string to be unibyte.
 284           (mapconcat
 285            ;; FIXME: Instead of `string-AS-unibyte' we'd want
 286            ;; `string-to-unibyte', so as to properly signal an error if one
 287            ;; of the strings contains a multibyte char.
 288            'string-as-unibyte
 289            (delq nil
 290             (list
 291              ;; The request
 292              (or url-http-method "GET") " "
 293              (if using-proxy (url-recreate-url url-http-target-url) real-fname)
 294              " HTTP/" url-http-version "\r\n"
 295              ;; Version of MIME we speak
 296              "MIME-Version: 1.0\r\n"
 297              ;; (maybe) Try to keep the connection open
 298              "Connection: " (if (or using-proxy
 299                                     (not url-http-attempt-keepalives))
 300                                 "close" "keep-alive") "\r\n"
 301                                 ;; HTTP extensions we support
 302              (if url-extensions-header
 303                  (format
 304                   "Extension: %s\r\n" url-extensions-header))
 305              ;; Who we want to talk to
 306              (if (/= (url-port url-http-target-url)
 307                      (url-scheme-get-property
 308                       (url-type url-http-target-url) 'default-port))
 309                  (format
 310                   "Host: %s:%d\r\n" host (url-port url-http-target-url))
 311                (format "Host: %s\r\n" host))
 312              ;; Who its from
 313              (if url-personal-mail-address
 314                  (concat
 315                   "From: " url-personal-mail-address "\r\n"))
 316              ;; Encodings we understand
 317              (if url-mime-encoding-string
 318                  (concat
 319                   "Accept-encoding: " url-mime-encoding-string "\r\n"))
 320              (if url-mime-charset-string
 321                  (concat
 322                   "Accept-charset: " url-mime-charset-string "\r\n"))
 323              ;; Languages we understand
 324              (if url-mime-language-string
 325                  (concat
 326                   "Accept-language: " url-mime-language-string "\r\n"))
 327              ;; Types we understand
 328              "Accept: " (or url-mime-accept-string "*/*") "\r\n"
 329              ;; User agent
 330              (url-http-user-agent-string)
 331              ;; Proxy Authorization
 332              proxy-auth
 333              ;; Authorization
 334              auth
 335              ;; Cookies
 336              (when (url-use-cookies url-http-target-url)
 337                (url-cookie-generate-header-lines
 338                 host real-fname
 339                 (equal "https" (url-type url-http-target-url))))
 340              ;; If-modified-since
 341              (if (and (not no-cache)
 342                       (member url-http-method '("GET" nil)))
 343                  (let ((tm (url-is-cached url-http-target-url)))
 344                    (if tm
 345                        (concat "If-modified-since: "
 346                                (url-get-normalized-date tm) "\r\n"))))
 347              ;; Whence we came
 348              (if ref-url (concat
 349                           "Referer: " ref-url "\r\n"))
 350              extra-headers
 351              ;; Length of data
 352              (if url-http-data
 353                  (concat
 354                   "Content-length: " (number-to-string
 355                                       (length url-http-data))
 356                   "\r\n"))
 357              ;; End request
 358              "\r\n"
 359              ;; Any data
 360              url-http-data
 361              ;; If `url-http-data' is nil, avoid two CRLFs (Bug#8931).
 362              (if url-http-data "\r\n")))
 363            ""))
 364     (url-http-debug "Request is: \n%s" request)
 365     request))
 366
 367 ;; Parsing routines
 368 (defun url-http-clean-headers ()
 369   "Remove trailing \r from header lines.
 370 This allows us to use `mail-fetch-field', etc.
 371 Return the number of characters removed."
 372   (let ((end (marker-position url-http-end-of-headers)))
 373     (goto-char (point-min))
 374     (while (re-search-forward "\r$" url-http-end-of-headers t)
 375       (replace-match ""))
 376     (- end url-http-end-of-headers)))
 377
 378 (defun url-http-handle-authentication (proxy)
 379   (url-http-debug "Handling %s authentication" (if proxy "proxy" "normal"))
 380   (let ((auths (or (nreverse
 381                     (mail-fetch-field
 382                      (if proxy "proxy-authenticate" "www-authenticate")
 383                      nil nil t))
 384                   '("basic")))
 385         (type nil)
 386         (url (url-recreate-url url-current-object))
 387         (auth-url (url-recreate-url
 388                    (if (and proxy (boundp 'url-http-proxy))
 389                        url-http-proxy
 390                      url-current-object)))
 391         (url-basic-auth-storage (if proxy
 392                                     ;; Cheating, but who cares? :)
 393                                     'url-http-proxy-basic-auth-storage
 394                                   'url-http-real-basic-auth-storage))
 395         auth
 396         (strength 0))
 397
 398     ;; find strongest supported auth
 399     (dolist (this-auth auths)
 400       (setq this-auth (url-eat-trailing-space
 401                        (url-strip-leading-spaces
 402                         this-auth)))
 403       (let* ((this-type
 404               (downcase (if (string-match "[ \t]" this-auth)
 405                             (substring this-auth 0 (match-beginning 0))
 406                           this-auth)))
 407              (registered (url-auth-registered this-type))
 408              (this-strength (cddr registered)))
 409         (when (and registered (> this-strength strength))
 410           (setq auth this-auth
 411                 type this-type
 412                 strength this-strength))))
 413
 414     (if (not (url-auth-registered type))
 415         (progn
 416           (widen)
 417           (goto-char (point-max))
 418           (insert "<hr>Sorry, but I do not know how to handle " type
 419                   " authentication.  If you'd like to write it,"
 420                   " send it to " url-bug-address ".<hr>")
 421           ;; We used to set a `status' var (declared "special") but I can't
 422           ;; find the corresponding let-binding, so it's probably an error.
 423           ;; FIXME: Maybe it was supposed to set `success', i.e. to return t?
 424           ;; (setq status t)
 425           nil) ;; Not success yet.
 426
 427       (let* ((args (url-parse-args (subst-char-in-string ?, ?\; auth)))
 428              (auth (url-get-authentication auth-url
 429                                            (cdr-safe (assoc "realm" args))
 430                                            type t args)))
 431         (if (not auth)
 432             t                           ;Success.
 433           (push (cons (if proxy "Proxy-Authorization" "Authorization") auth)
 434                 url-http-extra-headers)
 435           (let ((url-request-method url-http-method)
 436                 (url-request-data url-http-data)
 437                 (url-request-extra-headers url-http-extra-headers))
 438             (url-retrieve-internal url url-callback-function
 439                                    url-callback-arguments))
 440           nil))))) ;; Not success yet.
 441
 442 (defun url-http-parse-response ()
 443   "Parse just the response code."
 444   (if (not url-http-end-of-headers)
 445       (error "Trying to parse HTTP response code in odd buffer: %s" (buffer-name)))
 446   (url-http-debug "url-http-parse-response called in (%s)" (buffer-name))
 447   (goto-char (point-min))
 448   (skip-chars-forward " \t\n")          ; Skip any blank crap
 449   (skip-chars-forward "HTTP/")          ; Skip HTTP Version
 450   (setq url-http-response-version
 451         (buffer-substring (point)
 452                           (progn
 453                             (skip-chars-forward "[0-9].")
 454                             (point))))
 455   (setq url-http-response-status (read (current-buffer))))
 456
 457 (defun url-http-handle-cookies ()
 458   "Handle all set-cookie / set-cookie2 headers in an HTTP response.
 459 The buffer must already be narrowed to the headers, so `mail-fetch-field' will
 460 work correctly."
 461   (let ((cookies (nreverse (mail-fetch-field "Set-Cookie" nil nil t)))
 462         (cookies2 (nreverse (mail-fetch-field "Set-Cookie2" nil nil t))))
 463     (and cookies (url-http-debug "Found %d Set-Cookie headers" (length cookies)))
 464     (and cookies2 (url-http-debug "Found %d Set-Cookie2 headers" (length cookies2)))
 465     (while cookies
 466       (url-cookie-handle-set-cookie (pop cookies)))
 467 ;;;     (while cookies2
 468 ;;;       (url-cookie-handle-set-cookie2 (pop cookies)))
 469     )
 470   )
 471
 472 (defun url-http-parse-headers ()
 473  "Parse and handle HTTP specific headers.
 474 Return t if and only if the current buffer is still active and
 475 should be shown to the user."
 476   ;; The comments after each status code handled are taken from RFC
 477   ;; 2616 (HTTP/1.1)
 478   (url-http-mark-connection-as-free (url-host url-current-object)
 479                                     (url-port url-current-object)
 480                                     url-http-process)
 481
 482   (if (or (not (boundp 'url-http-end-of-headers))
 483           (not url-http-end-of-headers))
 484       (error "Trying to parse headers in odd buffer: %s" (buffer-name)))
 485   (goto-char (point-min))
 486   (url-http-debug "url-http-parse-headers called in (%s)" (buffer-name))
 487   (url-http-parse-response)
 488   (mail-narrow-to-head)
 489   ;;(narrow-to-region (point-min) url-http-end-of-headers)
 490   (let ((connection (mail-fetch-field "Connection")))
 491     ;; In HTTP 1.0, keep the connection only if there is a
 492     ;; "Connection: keep-alive" header.
 493     ;; In HTTP 1.1 (and greater), keep the connection unless there is a
 494     ;; "Connection: close" header
 495     (cond
 496      ((string= url-http-response-version "1.0")
 497       (unless (and connection
 498                    (string= (downcase connection) "keep-alive"))
 499         (delete-process url-http-process)))
 500      (t
 501       (when (and connection
 502                  (string= (downcase connection) "close"))
 503         (delete-process url-http-process)))))
 504   (let* ((buffer (current-buffer))
 505          (class (/ url-http-response-status 100))
 506          (success nil)
 507          ;; other status symbols: jewelry and luxury cars
 508          (status-symbol (cadr (assq url-http-response-status url-http-codes))))
 509     (url-http-debug "Parsed HTTP headers: class=%d status=%d"
 510                     class url-http-response-status)
 511     (when (url-use-cookies url-http-target-url)
 512       (url-http-handle-cookies))
 513
 514     (pcase class
 515       ;; Classes of response codes
 516       ;;
 517       ;; 5xx = Server Error
 518       ;; 4xx = Client Error
 519       ;; 3xx = Redirection
 520       ;; 2xx = Successful
 521       ;; 1xx = Informational
 522       (1                                ; Information messages
 523        ;; 100 = Continue with request
 524        ;; 101 = Switching protocols
 525        ;; 102 = Processing (Added by DAV)
 526        (url-mark-buffer-as-dead buffer)
 527        (error "HTTP responses in class 1xx not supported (%d)"
 528               url-http-response-status))
 529       (2                                ; Success
 530        ;; 200 Ok
 531        ;; 201 Created
 532        ;; 202 Accepted
 533        ;; 203 Non-authoritative information
 534        ;; 204 No content
 535        ;; 205 Reset content
 536        ;; 206 Partial content
 537        ;; 207 Multi-status (Added by DAV)
 538        (pcase status-symbol
 539          ((or `no-content `reset-content)
 540           ;; No new data, just stay at the same document
 541           (url-mark-buffer-as-dead buffer))
 542          (_
 543           ;; Generic success for all others.  Store in the cache, and
 544           ;; mark it as successful.
 545           (widen)
 546           (if (and url-automatic-caching (equal url-http-method "GET"))
 547               (url-store-in-cache buffer))))
 548        (setq success t))
 549       (3                                ; Redirection
 550        ;; 300 Multiple choices
 551        ;; 301 Moved permanently
 552        ;; 302 Found
 553        ;; 303 See other
 554        ;; 304 Not modified
 555        ;; 305 Use proxy
 556        ;; 307 Temporary redirect
 557        (let ((redirect-uri (or (mail-fetch-field "Location")
 558                                (mail-fetch-field "URI"))))
 559          (pcase status-symbol
 560            (`multiple-choices       ; 300
 561             ;; Quoth the spec (section 10.3.1)
 562             ;; -------------------------------
 563             ;; The requested resource corresponds to any one of a set of
 564             ;; representations, each with its own specific location and
 565             ;; agent-driven negotiation information is being provided so
 566             ;; that the user can select a preferred representation and
 567             ;; redirect its request to that location.
 568             ;; [...]
 569             ;; If the server has a preferred choice of representation, it
 570             ;; SHOULD include the specific URI for that representation in
 571             ;; the Location field; user agents MAY use the Location field
 572             ;; value for automatic redirection.
 573             ;; -------------------------------
 574             ;; We do not support agent-driven negotiation, so we just
 575             ;; redirect to the preferred URI if one is provided.
 576             nil)
 577            ((or `moved-permanently `found `temporary-redirect) ; 301 302 307
 578             ;; If the 301|302 status code is received in response to a
 579             ;; request other than GET or HEAD, the user agent MUST NOT
 580             ;; automatically redirect the request unless it can be
 581             ;; confirmed by the user, since this might change the
 582             ;; conditions under which the request was issued.
 583             (unless (member url-http-method '("HEAD" "GET"))
 584               (setq redirect-uri nil)))
 585            (`see-other                  ; 303
 586             ;; The response to the request can be found under a different
 587             ;; URI and SHOULD be retrieved using a GET method on that
 588             ;; resource.
 589             (setq url-http-method "GET"
 590                   url-http-data nil))
 591            (`not-modified               ; 304
 592             ;; The 304 response MUST NOT contain a message-body.
 593             (url-http-debug "Extracting document from cache... (%s)"
 594                             (url-cache-create-filename (url-view-url t)))
 595             (url-cache-extract (url-cache-create-filename (url-view-url t)))
 596             (setq redirect-uri nil
 597                   success t))
 598            (`use-proxy                  ; 305
 599             ;; The requested resource MUST be accessed through the
 600             ;; proxy given by the Location field.  The Location field
 601             ;; gives the URI of the proxy.  The recipient is expected
 602             ;; to repeat this single request via the proxy.  305
 603             ;; responses MUST only be generated by origin servers.
 604             (error "Redirection thru a proxy server not supported: %s"
 605                    redirect-uri))
 606            (_
 607             ;; Treat everything like '300'
 608             nil))
 609          (when redirect-uri
 610            ;; Clean off any whitespace and/or <...> cruft.
 611            (if (string-match "\\([^ \t]+\\)[ \t]" redirect-uri)
 612                (setq redirect-uri (match-string 1 redirect-uri)))
 613            (if (string-match "^<\\(.*\\)>$" redirect-uri)
 614                (setq redirect-uri (match-string 1 redirect-uri)))
 615
 616            ;; Some stupid sites (like sourceforge) send a
 617            ;; non-fully-qualified URL (ie: /), which royally confuses
 618            ;; the URL library.
 619            (if (not (string-match url-nonrelative-link redirect-uri))
 620                ;; Be careful to use the real target URL, otherwise we may
 621                ;; compute the redirection relative to the URL of the proxy.
 622                (setq redirect-uri
 623                      (url-expand-file-name redirect-uri url-http-target-url)))
 624            (let ((url-request-method url-http-method)
 625                  (url-request-data url-http-data)
 626                  (url-request-extra-headers url-http-extra-headers))
 627              ;; Check existing number of redirects
 628              (if (or (< url-max-redirections 0)
 629                      (and (> url-max-redirections 0)
 630                           (let ((events (car url-callback-arguments))
 631                                 (old-redirects 0))
 632                             (while events
 633                               (if (eq (car events) :redirect)
 634                                   (setq old-redirects (1+ old-redirects)))
 635                               (and (setq events (cdr events))
 636                                    (setq events (cdr events))))
 637                             (< old-redirects url-max-redirections))))
 638                  ;; url-max-redirections hasn't been reached, so go
 639                  ;; ahead and redirect.
 640                  (progn
 641                    ;; Remember that the request was redirected.
 642                    (setf (car url-callback-arguments)
 643                          (nconc (list :redirect redirect-uri)
 644                                 (car url-callback-arguments)))
 645                    ;; Put in the current buffer a forwarding pointer to the new
 646                    ;; destination buffer.
 647                    ;; FIXME: This is a hack to fix url-retrieve-synchronously
 648                    ;; without changing the API.  Instead url-retrieve should
 649                    ;; either simply not return the "destination" buffer, or it
 650                    ;; should take an optional `dest-buf' argument.
 651                    (set (make-local-variable 'url-redirect-buffer)
 652                         (url-retrieve-internal
 653                          redirect-uri url-callback-function
 654                          url-callback-arguments
 655                          (url-silent url-current-object)
 656                          (not (url-use-cookies url-current-object))))
 657                    (url-mark-buffer-as-dead buffer))
 658                ;; We hit url-max-redirections, so issue an error and
 659                ;; stop redirecting.
 660                (url-http-debug "Maximum redirections reached")
 661                (setf (car url-callback-arguments)
 662                      (nconc (list :error (list 'error 'http-redirect-limit
 663                                                redirect-uri))
 664                             (car url-callback-arguments)))
 665                (setq success t))))))
 666       (4                                ; Client error
 667        ;; 400 Bad Request
 668        ;; 401 Unauthorized
 669        ;; 402 Payment required
 670        ;; 403 Forbidden
 671        ;; 404 Not found
 672        ;; 405 Method not allowed
 673        ;; 406 Not acceptable
 674        ;; 407 Proxy authentication required
 675        ;; 408 Request time-out
 676        ;; 409 Conflict
 677        ;; 410 Gone
 678        ;; 411 Length required
 679        ;; 412 Precondition failed
 680        ;; 413 Request entity too large
 681        ;; 414 Request-URI too large
 682        ;; 415 Unsupported media type
 683        ;; 416 Requested range not satisfiable
 684        ;; 417 Expectation failed
 685        ;; 422 Unprocessable Entity (Added by DAV)
 686        ;; 423 Locked
 687        ;; 424 Failed Dependency
 688        (setq success
 689              (pcase status-symbol
 690                (`unauthorized                   ; 401
 691                 ;; The request requires user authentication.  The response
 692                 ;; MUST include a WWW-Authenticate header field containing a
 693                 ;; challenge applicable to the requested resource.  The
 694                 ;; client MAY repeat the request with a suitable
 695                 ;; Authorization header field.
 696                 (url-http-handle-authentication nil))
 697                (`payment-required              ; 402
 698                 ;; This code is reserved for future use
 699                 (url-mark-buffer-as-dead buffer)
 700                 (error "Somebody wants you to give them money"))
 701                (`forbidden                      ; 403
 702                 ;; The server understood the request, but is refusing to
 703                 ;; fulfill it.  Authorization will not help and the request
 704                 ;; SHOULD NOT be repeated.
 705                 t)
 706                (`not-found                      ; 404
 707                 ;; Not found
 708                 t)
 709                (`method-not-allowed             ; 405
 710                 ;; The method specified in the Request-Line is not allowed
 711                 ;; for the resource identified by the Request-URI.  The
 712                 ;; response MUST include an Allow header containing a list of
 713                 ;; valid methods for the requested resource.
 714                 t)
 715                (`not-acceptable         ; 406
 716                 ;; The resource identified by the request is only capable of
 717                 ;; generating response entities which have content
 718                 ;; characteristics not acceptable according to the accept
 719                 ;; headers sent in the request.
 720                 t)
 721                (`proxy-authentication-required ; 407
 722                 ;; This code is similar to 401 (Unauthorized), but indicates
 723                 ;; that the client must first authenticate itself with the
 724                 ;; proxy.  The proxy MUST return a Proxy-Authenticate header
 725                 ;; field containing a challenge applicable to the proxy for
 726                 ;; the requested resource.
 727                 (url-http-handle-authentication t))
 728                (`request-timeout                ; 408
 729                 ;; The client did not produce a request within the time that
 730                 ;; the server was prepared to wait.  The client MAY repeat
 731                 ;; the request without modifications at any later time.
 732                 t)
 733                (`conflict                       ; 409
 734                 ;; The request could not be completed due to a conflict with
 735                 ;; the current state of the resource.  This code is only
 736                 ;; allowed in situations where it is expected that the user
 737                 ;; might be able to resolve the conflict and resubmit the
 738                 ;; request.  The response body SHOULD include enough
 739                 ;; information for the user to recognize the source of the
 740                 ;; conflict.
 741                 t)
 742                (`gone                          ; 410
 743                 ;; The requested resource is no longer available at the
 744                 ;; server and no forwarding address is known.
 745                 t)
 746                (`length-required                ; 411
 747                 ;; The server refuses to accept the request without a defined
 748                 ;; Content-Length.  The client MAY repeat the request if it
 749                 ;; adds a valid Content-Length header field containing the
 750                 ;; length of the message-body in the request message.
 751                 ;;
 752                 ;; NOTE - this will never happen because
 753                 ;; `url-http-create-request' automatically calculates the
 754                 ;; content-length.
 755                 t)
 756                (`precondition-failed            ; 412
 757                 ;; The precondition given in one or more of the
 758                 ;; request-header fields evaluated to false when it was
 759                 ;; tested on the server.
 760                 t)
 761                ((or `request-entity-too-large `request-uri-too-large) ; 413 414
 762                 ;; The server is refusing to process a request because the
 763                 ;; request entity|URI is larger than the server is willing or
 764                 ;; able to process.
 765                 t)
 766                (`unsupported-media-type ; 415
 767                 ;; The server is refusing to service the request because the
 768                 ;; entity of the request is in a format not supported by the
 769                 ;; requested resource for the requested method.
 770                 t)
 771                (`requested-range-not-satisfiable ; 416
 772                 ;; A server SHOULD return a response with this status code if
 773                 ;; a request included a Range request-header field, and none
 774                 ;; of the range-specifier values in this field overlap the
 775                 ;; current extent of the selected resource, and the request
 776                 ;; did not include an If-Range request-header field.
 777                 t)
 778                (`expectation-failed             ; 417
 779                 ;; The expectation given in an Expect request-header field
 780                 ;; could not be met by this server, or, if the server is a
 781                 ;; proxy, the server has unambiguous evidence that the
 782                 ;; request could not be met by the next-hop server.
 783                 t)
 784                (_
 785                 ;; The request could not be understood by the server due to
 786                 ;; malformed syntax.  The client SHOULD NOT repeat the
 787                 ;; request without modifications.
 788                 t)))
 789        ;; Tell the callback that an error occurred, and what the
 790        ;; status code was.
 791        (when success
 792          (setf (car url-callback-arguments)
 793                (nconc (list :error (list 'error 'http url-http-response-status))
 794                       (car url-callback-arguments)))))
 795       (5
 796        ;; 500 Internal server error
 797        ;; 501 Not implemented
 798        ;; 502 Bad gateway
 799        ;; 503 Service unavailable
 800        ;; 504 Gateway time-out
 801        ;; 505 HTTP version not supported
 802        ;; 507 Insufficient storage
 803        (setq success t)
 804        (pcase url-http-response-status
 805          (`not-implemented              ; 501
 806           ;; The server does not support the functionality required to
 807           ;; fulfill the request.
 808           nil)
 809          (`bad-gateway                  ; 502
 810           ;; The server, while acting as a gateway or proxy, received
 811           ;; an invalid response from the upstream server it accessed
 812           ;; in attempting to fulfill the request.
 813           nil)
 814          (`service-unavailable          ; 503
 815           ;; The server is currently unable to handle the request due
 816           ;; to a temporary overloading or maintenance of the server.
 817           ;; The implication is that this is a temporary condition
 818           ;; which will be alleviated after some delay.  If known, the
 819           ;; length of the delay MAY be indicated in a Retry-After
 820           ;; header.  If no Retry-After is given, the client SHOULD
 821           ;; handle the response as it would for a 500 response.
 822           nil)
 823          (`gateway-timeout              ; 504
 824           ;; The server, while acting as a gateway or proxy, did not
 825           ;; receive a timely response from the upstream server
 826           ;; specified by the URI (e.g. HTTP, FTP, LDAP) or some other
 827           ;; auxiliary server (e.g. DNS) it needed to access in
 828           ;; attempting to complete the request.
 829           nil)
 830          (`http-version-not-supported   ; 505
 831           ;; The server does not support, or refuses to support, the
 832           ;; HTTP protocol version that was used in the request
 833           ;; message.
 834           nil)
 835          (`insufficient-storage         ; 507 (DAV)
 836           ;; The method could not be performed on the resource
 837           ;; because the server is unable to store the representation
 838           ;; needed to successfully complete the request.  This
 839           ;; condition is considered to be temporary.  If the request
 840           ;; which received this status code was the result of a user
 841           ;; action, the request MUST NOT be repeated until it is
 842           ;; requested by a separate user action.
 843           nil))
 844        ;; Tell the callback that an error occurred, and what the
 845        ;; status code was.
 846        (when success
 847          (setf (car url-callback-arguments)
 848                (nconc (list :error (list 'error 'http url-http-response-status))
 849                       (car url-callback-arguments)))))
 850       (_
 851        (error "Unknown class of HTTP response code: %d (%d)"
 852               class url-http-response-status)))
 853     (if (not success)
 854         (url-mark-buffer-as-dead buffer)
 855       (url-handle-content-transfer-encoding))
 856     (url-http-debug "Finished parsing HTTP headers: %S" success)
 857     (widen)
 858     success))
 859
 860 (defun url-handle-content-transfer-encoding ()
 861   (let ((encoding (mail-fetch-field "content-encoding")))
 862     (when (and encoding
 863                (fboundp 'decompress-gzipped-region)
 864                (equal (downcase encoding) "gzip"))
 865       (save-restriction
 866         (widen)
 867         (goto-char (point-min))
 868         (when (search-forward "\n\n")
 869           (decompress-gzipped-region (point) (point-max)))))))
 870
 871 ;; Miscellaneous
 872 (defun url-http-activate-callback ()
 873   "Activate callback specified when this buffer was created."
 874   (url-http-mark-connection-as-free (url-host url-current-object)
 875                                     (url-port url-current-object)
 876                                     url-http-process)
 877   (url-http-debug "Activating callback in buffer (%s)" (buffer-name))
 878   (apply url-callback-function url-callback-arguments))
 879
 880 ;; )
 881
 882 ;; These unfortunately cannot be macros... please ignore them!
 883 (defun url-http-idle-sentinel (proc why)
 884   "Remove (now defunct) process PROC from the list of open connections."
 885   (maphash (lambda (key val)
 886                 (if (memq proc val)
 887                     (puthash key (delq proc val) url-http-open-connections)))
 888               url-http-open-connections))
 889
 890 (defun url-http-end-of-document-sentinel (proc why)
 891   ;; Sentinel used to handle (i) terminated old HTTP/0.9 connections,
 892   ;; and (ii) closed connection due to reusing a HTTP connection which
 893   ;; we believed was still alive, but which the server closed on us.
 894   ;; We handle case (ii) by calling `url-http' again.
 895   (url-http-debug "url-http-end-of-document-sentinel in buffer (%s)"
 896                   (process-buffer proc))
 897   (url-http-idle-sentinel proc why)
 898   (when (buffer-name (process-buffer proc))
 899     (with-current-buffer (process-buffer proc)
 900       (goto-char (point-min))
 901       (cond ((not (looking-at "HTTP/"))
 902              (if url-http-no-retry
 903                  ;; HTTP/0.9 just gets passed back no matter what
 904                  (url-http-activate-callback)
 905                ;; Call `url-http' again if our connection expired.
 906                (erase-buffer)
 907                (let ((url-request-method url-http-method)
 908                      (url-request-extra-headers url-http-extra-headers)
 909                      (url-request-data url-http-data))
 910                  (url-http url-current-object url-callback-function
 911                            url-callback-arguments (current-buffer)))))
 912             ((url-http-parse-headers)
 913              (url-http-activate-callback))))))
 914
 915 (defun url-http-simple-after-change-function (st nd length)
 916   ;; Function used when we do NOT know how long the document is going to be
 917   ;; Just _very_ simple 'downloaded %d' type of info.
 918   (url-lazy-message "Reading %s..." (url-pretty-length nd)))
 919
 920 (defun url-http-content-length-after-change-function (st nd length)
 921   "Function used when we DO know how long the document is going to be.
 922 More sophisticated percentage downloaded, etc.
 923 Also does minimal parsing of HTTP headers and will actually cause
 924 the callback to be triggered."
 925   (if url-http-content-type
 926       (url-display-percentage
 927        "Reading [%s]... %s of %s (%d%%)"
 928        (url-percentage (- nd url-http-end-of-headers)
 929                        url-http-content-length)
 930        url-http-content-type
 931        (url-pretty-length (- nd url-http-end-of-headers))
 932        (url-pretty-length url-http-content-length)
 933        (url-percentage (- nd url-http-end-of-headers)
 934                        url-http-content-length))
 935     (url-display-percentage
 936      "Reading... %s of %s (%d%%)"
 937      (url-percentage (- nd url-http-end-of-headers)
 938                      url-http-content-length)
 939      (url-pretty-length (- nd url-http-end-of-headers))
 940      (url-pretty-length url-http-content-length)
 941      (url-percentage (- nd url-http-end-of-headers)
 942                      url-http-content-length)))
 943
 944   (if (> (- nd url-http-end-of-headers) url-http-content-length)
 945       (progn
 946         ;; Found the end of the document!  Wheee!
 947         (url-display-percentage nil nil)
 948         (url-lazy-message "Reading... done.")
 949         (if (url-http-parse-headers)
 950             (url-http-activate-callback)))))
 951
 952 (defun url-http-chunked-encoding-after-change-function (st nd length)
 953   "Function used when dealing with 'chunked' encoding.
 954 Cannot give a sophisticated percentage, but we need a different
 955 function to look for the special 0-length chunk that signifies
 956 the end of the document."
 957   (save-excursion
 958     (goto-char st)
 959     (let ((read-next-chunk t)
 960           (case-fold-search t)
 961           (regexp nil)
 962           (no-initial-crlf nil))
 963       ;; We need to loop thru looking for more chunks even within
 964       ;; one after-change-function call.
 965       (while read-next-chunk
 966         (setq no-initial-crlf (= 0 url-http-chunked-counter))
 967         (if url-http-content-type
 968             (url-display-percentage nil
 969              "Reading [%s]... chunk #%d"
 970              url-http-content-type url-http-chunked-counter)
 971           (url-display-percentage nil
 972            "Reading... chunk #%d"
 973            url-http-chunked-counter))
 974         (url-http-debug "Reading chunk %d (%d %d %d)"
 975                         url-http-chunked-counter st nd length)
 976         (setq regexp (if no-initial-crlf
 977                          "\\([0-9a-z]+\\).*\r?\n"
 978                        "\r?\n\\([0-9a-z]+\\).*\r?\n"))
 979
 980         (if url-http-chunked-start
 981             ;; We know how long the chunk is supposed to be, skip over
 982             ;; leading crap if possible.
 983             (if (> nd (+ url-http-chunked-start url-http-chunked-length))
 984                 (progn
 985                   (url-http-debug "Got to the end of chunk #%d!"
 986                                   url-http-chunked-counter)
 987                   (goto-char (+ url-http-chunked-start
 988                                 url-http-chunked-length)))
 989               (url-http-debug "Still need %d bytes to hit end of chunk"
 990                               (- (+ url-http-chunked-start
 991                                     url-http-chunked-length)
 992                                  nd))
 993               (setq read-next-chunk nil)))
 994         (if (not read-next-chunk)
 995             (url-http-debug "Still spinning for next chunk...")
 996           (if no-initial-crlf (skip-chars-forward "\r\n"))
 997           (if (not (looking-at regexp))
 998               (progn
 999            ;; Must not have received the entirety of the chunk header,
1000                 ;; need to spin some more.
1001                 (url-http-debug "Did not see start of chunk @ %d!" (point))
1002                 (setq read-next-chunk nil))
1003             (add-text-properties (match-beginning 0) (match-end 0)
1004                                  (list 'start-open t
1005                                        'end-open t
1006                                        'chunked-encoding t
1007                                        'face 'cursor
1008                                        'invisible t))
1009             (setq url-http-chunked-length (string-to-number (buffer-substring
1010                                                              (match-beginning 1)
1011                                                              (match-end 1))
1012                                                             16)
1013                   url-http-chunked-counter (1+ url-http-chunked-counter)
1014                   url-http-chunked-start (set-marker
1015                                           (or url-http-chunked-start
1016                                               (make-marker))
1017                                           (match-end 0)))
1018 ;           (if (not url-http-debug)
1019                 (delete-region (match-beginning 0) (match-end 0));)
1020             (url-http-debug "Saw start of chunk %d (length=%d, start=%d"
1021                             url-http-chunked-counter url-http-chunked-length
1022                             (marker-position url-http-chunked-start))
1023             (if (= 0 url-http-chunked-length)
1024                 (progn
1025                   ;; Found the end of the document!  Wheee!
1026                   (url-http-debug "Saw end of stream chunk!")
1027                   (setq read-next-chunk nil)
1028                   (url-display-percentage nil nil)
1029                   ;; Every chunk, even the last 0-length one, is
1030                   ;; terminated by CRLF.  Skip it.
1031                   (when (looking-at "\r?\n")
1032                     (url-http-debug "Removing terminator of last chunk")
1033                     (delete-region (match-beginning 0) (match-end 0)))
1034                   (if (re-search-forward "^\r*$" nil t)
1035                       (url-http-debug "Saw end of trailers..."))
1036                   (if (url-http-parse-headers)
1037                       (url-http-activate-callback))))))))))
1038
1039 (defun url-http-wait-for-headers-change-function (st nd length)
1040   ;; This will wait for the headers to arrive and then splice in the
1041   ;; next appropriate after-change-function, etc.
1042   (url-http-debug "url-http-wait-for-headers-change-function (%s)"
1043                   (buffer-name))
1044   (let ((end-of-headers nil)
1045         (old-http nil)
1046         (process-buffer (current-buffer))
1047         (content-length nil))
1048     (when (not (bobp))
1049       (goto-char (point-min))
1050       (if (and (looking-at ".*\n")      ; have one line at least
1051                (not (looking-at "^HTTP/[1-9]\\.[0-9]")))
1052           ;; Not HTTP/x.y data, must be 0.9
1053           ;; God, I wish this could die.
1054           (setq end-of-headers t
1055                 url-http-end-of-headers 0
1056                 old-http t)
1057         ;; Blank line at end of headers.
1058         (when (re-search-forward "^\r?\n" nil t)
1059           (backward-char 1)
1060           ;; Saw the end of the headers
1061           (url-http-debug "Saw end of headers... (%s)" (buffer-name))
1062           (setq url-http-end-of-headers (set-marker (make-marker)
1063                                                     (point))
1064                 end-of-headers t)
1065           (setq nd (- nd (url-http-clean-headers)))))
1066
1067       (if (not end-of-headers)
1068           ;; Haven't seen the end of the headers yet, need to wait
1069           ;; for more data to arrive.
1070           nil
1071         (unless old-http
1072           (url-http-parse-response)
1073           (mail-narrow-to-head)
1074           (setq url-http-transfer-encoding (mail-fetch-field
1075                                             "transfer-encoding")
1076                 url-http-content-type (mail-fetch-field "content-type"))
1077           (if (mail-fetch-field "content-length")
1078               (setq url-http-content-length
1079                     (string-to-number (mail-fetch-field "content-length"))))
1080           (widen))
1081         (when url-http-transfer-encoding
1082           (setq url-http-transfer-encoding
1083                 (downcase url-http-transfer-encoding)))
1084
1085         (cond
1086          ((null url-http-response-status)
1087           ;; We got back a headerless malformed response from the
1088           ;; server.
1089           (url-http-activate-callback))
1090          ((or (= url-http-response-status 204)
1091               (= url-http-response-status 205))
1092           (url-http-debug "%d response must have headers only (%s)."
1093                           url-http-response-status (buffer-name))
1094           (when (url-http-parse-headers)
1095             (url-http-activate-callback)))
1096          ((string= "HEAD" url-http-method)
1097           ;; A HEAD request is _ALWAYS_ terminated by the header
1098           ;; information, regardless of any entity headers,
1099           ;; according to section 4.4 of the HTTP/1.1 draft.
1100           (url-http-debug "HEAD request must have headers only (%s)."
1101                           (buffer-name))
1102           (when (url-http-parse-headers)
1103             (url-http-activate-callback)))
1104          ((string= "CONNECT" url-http-method)
1105           ;; A CONNECT request is finished, but we cannot stick this
1106           ;; back on the free connection list
1107           (url-http-debug "CONNECT request must have headers only.")
1108           (when (url-http-parse-headers)
1109             (url-http-activate-callback)))
1110          ((equal url-http-response-status 304)
1111           ;; Only allowed to have a header section.  We have to handle
1112           ;; this here instead of in url-http-parse-headers because if
1113           ;; you have a cached copy of something without a known
1114           ;; content-length, and try to retrieve it from the cache, we'd
1115           ;; fall into the 'being dumb' section and wait for the
1116           ;; connection to terminate, which means we'd wait for 10
1117           ;; seconds for the keep-alives to time out on some servers.
1118           (when (url-http-parse-headers)
1119             (url-http-activate-callback)))
1120          (old-http
1121           ;; HTTP/0.9 always signaled end-of-connection by closing the
1122           ;; connection.
1123           (url-http-debug
1124            "Saw HTTP/0.9 response, connection closed means end of document.")
1125           (setq url-http-after-change-function
1126                 'url-http-simple-after-change-function))
1127          ((equal url-http-transfer-encoding "chunked")
1128           (url-http-debug "Saw chunked encoding.")
1129           (setq url-http-after-change-function
1130                 'url-http-chunked-encoding-after-change-function)
1131           (when (> nd url-http-end-of-headers)
1132             (url-http-debug
1133              "Calling initial chunked-encoding for extra data at end of headers")
1134             (url-http-chunked-encoding-after-change-function
1135              (marker-position url-http-end-of-headers) nd
1136              (- nd url-http-end-of-headers))))
1137          ((integerp url-http-content-length)
1138           (url-http-debug
1139            "Got a content-length, being smart about document end.")
1140           (setq url-http-after-change-function
1141                 'url-http-content-length-after-change-function)
1142           (cond
1143            ((= 0 url-http-content-length)
1144             ;; We got a NULL body!  Activate the callback
1145             ;; immediately!
1146             (url-http-debug
1147              "Got 0-length content-length, activating callback immediately.")
1148             (when (url-http-parse-headers)
1149               (url-http-activate-callback)))
1150            ((> nd url-http-end-of-headers)
1151             ;; Have some leftover data
1152             (url-http-debug "Calling initial content-length for extra data at end of headers")
1153             (url-http-content-length-after-change-function
1154              (marker-position url-http-end-of-headers)
1155              nd
1156              (- nd url-http-end-of-headers)))
1157            (t
1158             nil)))
1159          (t
1160           (url-http-debug "No content-length, being dumb.")
1161           (setq url-http-after-change-function
1162                 'url-http-simple-after-change-function)))))
1163     ;; We are still at the beginning of the buffer... must just be
1164     ;; waiting for a response.
1165     (url-http-debug "Spinning waiting for headers...")
1166     (when (eq process-buffer (current-buffer))
1167       (goto-char (point-max)))))
1168
1169 (defun url-http (url callback cbargs &optional retry-buffer)
1170   "Retrieve URL via HTTP asynchronously.
1171 URL must be a parsed URL.  See `url-generic-parse-url' for details.
1172
1173 When retrieval is completed, execute the function CALLBACK, using
1174 the arguments listed in CBARGS.  The first element in CBARGS
1175 should be a plist describing what has happened so far during the
1176 request, as described in the docstring of `url-retrieve' (if in
1177 doubt, specify nil).
1178
1179 Optional arg RETRY-BUFFER, if non-nil, specifies the buffer of a
1180 previous `url-http' call, which is being re-attempted."
1181   (cl-check-type url vector "Need a pre-parsed URL.")
1182   (let* ((host (url-host (or url-using-proxy url)))
1183          (port (url-port (or url-using-proxy url)))
1184          (connection (url-http-find-free-connection host port))
1185          (buffer (or retry-buffer
1186                      (generate-new-buffer
1187                       (format " *http %s:%d*" host port)))))
1188     (if (not connection)
1189         ;; Failed to open the connection for some reason
1190         (progn
1191           (kill-buffer buffer)
1192           (setq buffer nil)
1193           (error "Could not create connection to %s:%d" host port))
1194       (with-current-buffer buffer
1195         (mm-disable-multibyte)
1196         (setq url-current-object url
1197               mode-line-format "%b [%s]")
1198
1199         (dolist (var '(url-http-end-of-headers
1200                        url-http-content-type
1201                        url-http-content-length
1202                        url-http-transfer-encoding
1203                        url-http-after-change-function
1204                        url-http-response-version
1205                        url-http-response-status
1206                        url-http-chunked-length
1207                        url-http-chunked-counter
1208                        url-http-chunked-start
1209                        url-callback-function
1210                        url-callback-arguments
1211                        url-show-status
1212                        url-http-process
1213                        url-http-method
1214                        url-http-extra-headers
1215                        url-http-data
1216                        url-http-target-url
1217                        url-http-no-retry
1218                        url-http-connection-opened
1219                        url-http-proxy))
1220           (set (make-local-variable var) nil))
1221
1222         (setq url-http-method (or url-request-method "GET")
1223               url-http-extra-headers url-request-extra-headers
1224               url-http-data url-request-data
1225               url-http-process connection
1226               url-http-chunked-length nil
1227               url-http-chunked-start nil
1228               url-http-chunked-counter 0
1229               url-callback-function callback
1230               url-callback-arguments cbargs
1231               url-http-after-change-function 'url-http-wait-for-headers-change-function
1232               url-http-target-url url-current-object
1233               url-http-no-retry retry-buffer
1234               url-http-connection-opened nil
1235               url-http-proxy url-using-proxy)
1236
1237         (set-process-buffer connection buffer)
1238         (set-process-filter connection 'url-http-generic-filter)
1239         (pcase (process-status connection)
1240           (`connect
1241            ;; Asynchronous connection
1242            (set-process-sentinel connection 'url-http-async-sentinel))
1243           (`failed
1244            ;; Asynchronous connection failed
1245            (error "Could not create connection to %s:%d" host port))
1246           (_
1247            (set-process-sentinel connection
1248                                  'url-http-end-of-document-sentinel)
1249            (process-send-string connection (url-http-create-request))))))
1250     buffer))
1251
1252 (defun url-http-async-sentinel (proc why)
1253   ;; We are performing an asynchronous connection, and a status change
1254   ;; has occurred.
1255   (when (buffer-name (process-buffer proc))
1256     (with-current-buffer (process-buffer proc)
1257       (cond
1258        (url-http-connection-opened
1259         (setq url-http-no-retry t)
1260         (url-http-end-of-document-sentinel proc why))
1261        ((string= (substring why 0 4) "open")
1262         (setq url-http-connection-opened t)
1263         (condition-case error
1264             (process-send-string proc (url-http-create-request))
1265           (file-error
1266            (setq url-http-connection-opened nil)
1267            (message "HTTP error: %s" error))))
1268        (t
1269         (setf (car url-callback-arguments)
1270               (nconc (list :error (list 'error 'connection-failed why
1271                                         :host (url-host (or url-http-proxy url-current-object))
1272                                         :service (url-port (or url-http-proxy url-current-object))))
1273                      (car url-callback-arguments)))
1274         (url-http-activate-callback))))))
1275
1276 ;; Since Emacs 19/20 does not allow you to change the
1277 ;; `after-change-functions' hook in the midst of running them, we fake
1278 ;; an after change by hooking into the process filter and inserting
1279 ;; the data ourselves.  This is slightly less efficient, but there
1280 ;; were tons of weird ways the after-change code was biting us in the
1281 ;; shorts.
1282 ;; FIXME this can probably be simplified since the above is no longer true.
1283 (defun url-http-generic-filter (proc data)
1284   ;; Sometimes we get a zero-length data chunk after the process has
1285   ;; been changed to 'free', which means it has no buffer associated
1286   ;; with it.  Do nothing if there is no buffer, or 0 length data.
1287   (and (process-buffer proc)
1288        (/= (length data) 0)
1289        (with-current-buffer (process-buffer proc)
1290          (url-http-debug "Calling after change function `%s' for `%S'" url-http-after-change-function proc)
1291          (funcall url-http-after-change-function
1292                   (point-max)
1293                   (progn
1294                     (goto-char (point-max))
1295                     (insert data)
1296                     (point-max))
1297                   (length data)))))
1298
1299 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1300 ;;; file-name-handler stuff from here on out
1301 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1302 (defalias 'url-http-symbol-value-in-buffer
1303   (if (fboundp 'symbol-value-in-buffer)
1304       'symbol-value-in-buffer
1305     (lambda (symbol buffer &optional unbound-value)
1306       "Return the value of SYMBOL in BUFFER, or UNBOUND-VALUE if it is unbound."
1307       (with-current-buffer buffer
1308         (if (not (boundp symbol))
1309             unbound-value
1310           (symbol-value symbol))))))
1311
1312 (defun url-http-head (url)
1313   (let ((url-request-method "HEAD")
1314         (url-request-data nil))
1315     (url-retrieve-synchronously url)))
1316
1317 (defun url-http-file-exists-p (url)
1318   (let ((buffer (url-http-head url)))
1319     (when buffer
1320       (let ((status (url-http-symbol-value-in-buffer 'url-http-response-status
1321                                                      buffer 500)))
1322         (prog1
1323             (and (integerp status)
1324                  (>= status 200) (< status 300))
1325           (kill-buffer buffer))))))
1326
1327 (defalias 'url-http-file-readable-p 'url-http-file-exists-p)
1328
1329 (defun url-http-head-file-attributes (url &optional id-format)
1330   (let ((buffer (url-http-head url)))
1331     (when buffer
1332       (prog1
1333           (list
1334            nil                          ;dir / link / normal file
1335            1                            ;number of links to file.
1336            0 0                          ;uid ; gid
1337            nil nil nil                  ;atime ; mtime ; ctime
1338            (url-http-symbol-value-in-buffer 'url-http-content-length
1339                                             buffer -1)
1340            (eval-when-compile (make-string 10 ?-))
1341            nil nil nil)          ;whether gid would change ; inode ; device.
1342         (kill-buffer buffer)))))
1343
1344 (declare-function url-dav-file-attributes "url-dav" (url &optional id-format))
1345
1346 (defun url-http-file-attributes (url &optional id-format)
1347   (if (url-dav-supported-p url)
1348       (url-dav-file-attributes url id-format)
1349     (url-http-head-file-attributes url id-format)))
1350
1351 (defun url-http-options (url)
1352   "Return a property list describing options available for URL.
1353 This list is retrieved using the `OPTIONS' HTTP method.
1354
1355 Property list members:
1356
1357 methods
1358   A list of symbols specifying what HTTP methods the resource
1359   supports.
1360
1361 dav
1362   A list of numbers specifying what DAV protocol/schema versions are
1363   supported.
1364
1365 dasl
1366   A list of supported DASL search types supported (string form)
1367
1368 ranges
1369   A list of the units available for use in partial document fetches.
1370
1371 p3p
1372   The `Platform For Privacy Protection' description for the resource.
1373   Currently this is just the raw header contents.  This is likely to
1374   change once P3P is formally supported by the URL package or
1375   Emacs/W3."
1376   (let* ((url-request-method "OPTIONS")
1377          (url-request-data nil)
1378          (buffer (url-retrieve-synchronously url))
1379          (header nil)
1380          (options nil))
1381     (when (and buffer (= 2 (/ (url-http-symbol-value-in-buffer
1382                                'url-http-response-status buffer 0) 100)))
1383       ;; Only parse the options if we got a 2xx response code!
1384       (with-current-buffer buffer
1385         (save-restriction
1386           (save-match-data
1387             (mail-narrow-to-head)
1388
1389             ;; Figure out what methods are supported.
1390             (when (setq header (mail-fetch-field "allow"))
1391               (setq options (plist-put
1392                              options 'methods
1393                              (mapcar 'intern (split-string header "[ ,]+")))))
1394
1395             ;; Check for DAV
1396             (when (setq header (mail-fetch-field "dav"))
1397               (setq options (plist-put
1398                              options 'dav
1399                              (delq 0
1400                                    (mapcar 'string-to-number
1401                                            (split-string header "[, ]+"))))))
1402
1403             ;; Now for DASL
1404             (when (setq header (mail-fetch-field "dasl"))
1405               (setq options (plist-put
1406                              options 'dasl
1407                              (split-string header "[, ]+"))))
1408
1409             ;; P3P - should get more detailed here.  FIXME
1410             (when (setq header (mail-fetch-field "p3p"))
1411               (setq options (plist-put options 'p3p header)))
1412
1413             ;; Check for whether they accept byte-range requests.
1414             (when (setq header (mail-fetch-field "accept-ranges"))
1415               (setq options (plist-put
1416                              options 'ranges
1417                              (delq 'none
1418                                    (mapcar 'intern
1419                                            (split-string header "[, ]+"))))))
1420             ))))
1421     (if buffer (kill-buffer buffer))
1422     options))
1423
1424 ;; HTTPS.  This used to be in url-https.el, but that file collides
1425 ;; with url-http.el on systems with 8-character file names.
1426 (require 'tls)
1427
1428 (defconst url-https-default-port 443 "Default HTTPS port.")
1429 (defconst url-https-asynchronous-p t "HTTPS retrievals are asynchronous.")
1430
1431 ;; FIXME what is the point of this alias being an autoload?
1432 ;; Trying to use it will not cause url-http to be loaded,
1433 ;; since the full alias just gets dumped into loaddefs.el.
1434
1435 ;;;###autoload (autoload 'url-default-expander "url-expand")
1436 ;;;###autoload
1437 (defalias 'url-https-expand-file-name 'url-default-expander)
1438
1439 (defmacro url-https-create-secure-wrapper (method args)
1440   `(defun ,(intern (format (if method "url-https-%s" "url-https") method)) ,args
1441     ,(format "HTTPS wrapper around `%s' call." (or method "url-http"))
1442     (let ((url-gateway-method 'tls))
1443       (,(intern (format (if method "url-http-%s" "url-http") method))
1444        ,@(remove '&rest (remove '&optional args))))))
1445
1446 ;;;###autoload (autoload 'url-https "url-http")
1447 (url-https-create-secure-wrapper nil (url callback cbargs))
1448 ;;;###autoload (autoload 'url-https-file-exists-p "url-http")
1449 (url-https-create-secure-wrapper file-exists-p (url))
1450 ;;;###autoload (autoload 'url-https-file-readable-p "url-http")
1451 (url-https-create-secure-wrapper file-readable-p (url))
1452 ;;;###autoload (autoload 'url-https-file-attributes "url-http")
1453 (url-https-create-secure-wrapper file-attributes (url &optional id-format))
1454
1455 (provide 'url-http)
1456
1457 ;;; url-http.el ends here