lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process
   2
   3 ;; Copyright (C) 1986, 1987, 1992, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: processes
   9
  10 ;; Changes by peck@sun.com and by rms.
  11 ;; Overhaul by Karoly Lorentey <lorentey@elte.hu> for multi-tty support.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This Lisp code is run in Emacs when it is to operate as
  33 ;; a server for other processes.
  34
  35 ;; Load this library and do M-x server-edit to enable Emacs as a server.
  36 ;; Emacs opens up a socket for communication with clients.  If there are no
  37 ;; client buffers to edit, server-edit acts like (switch-to-buffer
  38 ;; (other-buffer))
  39
  40 ;; When some other program runs "the editor" to edit a file,
  41 ;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  42 ;; This program transmits the file names to Emacs through
  43 ;; the server subprocess, and Emacs visits them and lets you edit them.
  44
  45 ;; Note that any number of clients may dispatch files to Emacs to be edited.
  46
  47 ;; When you finish editing a Server buffer, again call server-edit
  48 ;; to mark that buffer as done for the client and switch to the next
  49 ;; Server buffer.  When all the buffers for a client have been edited
  50 ;; and exited with server-edit, the client "editor" will return
  51 ;; to the program that invoked it.
  52
  53 ;; Your editing commands and Emacs's display output go to and from
  54 ;; the terminal in the usual way.  Thus, server operation is possible
  55 ;; only when Emacs can talk to the terminal at the time you invoke
  56 ;; the client.  This is possible in four cases:
  57
  58 ;; 1. On a window system, where Emacs runs in one window and the
  59 ;; program that wants to use "the editor" runs in another.
  60
  61 ;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  62 ;; program that wants to use "the editor" runs on another.
  63
  64 ;; 3. When the program that wants to use "the editor" is running
  65 ;; as a subprocess of Emacs.
  66
  67 ;; 4. On a system with job control, when Emacs is suspended, the program
  68 ;; that wants to use "the editor" will stop and display
  69 ;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  70 ;; brought into the foreground for editing.  When done editing, Emacs is
  71 ;; suspended again, and the client program is brought into the foreground.
  72
  73 ;; The buffer local variable "server-buffer-clients" lists
  74 ;; the clients who are waiting for this buffer to be edited.
  75 ;; The global variable "server-clients" lists all the waiting clients,
  76 ;; and which files are yet to be edited for each.
  77
  78 ;;; Code:
  79
  80 (eval-when-compile (require 'cl))
  81
  82 (defgroup server nil
  83   "Emacs running as a server process."
  84   :group 'external)
  85
  86 (defcustom server-visit-hook nil
  87   "*Hook run when visiting a file for the Emacs server."
  88   :group 'server
  89   :type 'hook)
  90
  91 (defcustom server-switch-hook nil
  92   "*Hook run when switching to a buffer for the Emacs server."
  93   :group 'server
  94   :type 'hook)
  95
  96 (defcustom server-done-hook nil
  97   "*Hook run when done editing a buffer for the Emacs server."
  98   :group 'server
  99   :type 'hook)
 100
 101 (defvar server-process nil
 102   "The current server process.")
 103
 104 (defvar server-clients nil
 105   "List of current server clients.
 106 Each element is (PROC PROPERTIES...) where PROC is a process object,
 107 and PROPERTIES is an association list of client properties.")
 108
 109 (defvar server-buffer-clients nil
 110   "List of client ids for clients requesting editing of current buffer.")
 111 (make-variable-buffer-local 'server-buffer-clients)
 112 ;; Changing major modes should not erase this local.
 113 (put 'server-buffer-clients 'permanent-local t)
 114
 115 (defcustom server-window nil
 116   "*Specification of the window to use for selecting Emacs server buffers.
 117 If nil, use the selected window.
 118 If it is a function, it should take one argument (a buffer) and
 119 display and select it.  A common value is `pop-to-buffer'.
 120 If it is a window, use that.
 121 If it is a frame, use the frame's selected window.
 122
 123 It is not meaningful to set this to a specific frame or window with Custom.
 124 Only programs can do so."
 125   :group 'server
 126   :version "22.1"
 127   :type '(choice (const :tag "Use selected window"
 128                         :match (lambda (widget value)
 129                                  (not (functionp value)))
 130                         nil)
 131                  (function-item :tag "Use pop-to-buffer" pop-to-buffer)
 132                  (function :tag "Other function")))
 133
 134 (defcustom server-temp-file-regexp "^/tmp/Re\\|/draft$"
 135   "*Regexp matching names of temporary files.
 136 These are deleted and reused after each edit by the programs that
 137 invoke the Emacs server."
 138   :group 'server
 139   :type 'regexp)
 140
 141 (defcustom server-kill-new-buffers t
 142   "*Whether to kill buffers when done with them.
 143 If non-nil, kill a buffer unless it already existed before editing
 144 it with Emacs server.  If nil, kill only buffers as specified by
 145 `server-temp-file-regexp'.
 146 Please note that only buffers are killed that still have a client,
 147 i.e. buffers visited which \"emacsclient --no-wait\" are never killed in
 148 this way."
 149   :group 'server
 150   :type 'boolean
 151   :version "21.1")
 152
 153 (or (assq 'server-buffer-clients minor-mode-alist)
 154     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
 155
 156 (defvar server-existing-buffer nil
 157   "Non-nil means the buffer existed before the server was asked to visit it.
 158 This means that the server should not kill the buffer when you say you
 159 are done with it in the server.")
 160 (make-variable-buffer-local 'server-existing-buffer)
 161
 162 (defvar server-name "server")
 163
 164 (defvar server-socket-dir nil
 165   "The directory in which to place the server socket.
 166 Initialized by `server-start'.")
 167
 168 (defun server-client (proc)
 169   "Return the Emacs client corresponding to PROC.
 170 PROC must be a process object.
 171 The car of the result is PROC; the cdr is an association list.
 172 See `server-client-get' and `server-client-set'."
 173   (assq proc server-clients))
 174
 175 (defun server-client-get (client property)
 176   "Get the value of PROPERTY in CLIENT.
 177 CLIENT may be a process object, or a client returned by `server-client'.
 178 Return nil if CLIENT has no such property."
 179   (or (listp client) (setq client (server-client client)))
 180   (cdr (assq property (cdr client))))
 181
 182 (defun server-client-set (client property value)
 183   "Set the PROPERTY to VALUE in CLIENT, and return VALUE.
 184 CLIENT may be a process object, or a client returned by `server-client'."
 185   (let (p proc)
 186     (if (listp client)
 187         (setq proc (car client))
 188       (setq proc client
 189             client (server-client client)))
 190     (setq p (assq property client))
 191     (cond
 192      (p (setcdr p value))
 193      (client (setcdr client (cons (cons property value) (cdr client))))
 194      (t (setq server-clients
 195               `((,proc (,property . ,value)) . ,server-clients))))
 196     value))
 197
 198 (defun server-clients-with (property value)
 199   "Return a list of clients with PROPERTY set to VALUE."
 200   (let (result)
 201     (dolist (client server-clients result)
 202       (when (equal value (server-client-get client property))
 203         (setq result (cons (car client) result))))))
 204
 205 (defun server-add-client (proc)
 206   "Create a client for process PROC, if it doesn't already have one.
 207 New clients have no properties."
 208   (unless (server-client proc)
 209     (setq server-clients (cons (cons proc nil)
 210                                server-clients))))
 211
 212 (defun server-getenv-from (env variable)
 213   "Get the value of VARIABLE in ENV.
 214 VARIABLE should be a string.  Value is nil if VARIABLE is
 215 undefined in ENV.  Otherwise, value is a string.
 216
 217 ENV should be in the same format as `process-environment'."
 218   (let (entry result)
 219     (while (and env (null result))
 220       (setq entry (car env)
 221             env (cdr env))
 222       (if (and (> (length entry) (length variable))
 223                (eq ?= (aref entry (length variable)))
 224                (equal variable (substring entry 0 (length variable))))
 225           (setq result (substring entry (+ (length variable) 1)))))
 226     result))
 227
 228 (defmacro server-with-environment (env vars &rest body)
 229   "Evaluate BODY with environment variables VARS set to those in ENV.
 230 The environment variables are then restored to their previous values.
 231
 232 VARS should be a list of strings.
 233 ENV should be in the same format as `process-environment'."
 234   (declare (indent 2))
 235   (let ((oldvalues (make-symbol "oldvalues"))
 236         (var (make-symbol "var"))
 237         (value (make-symbol "value"))
 238         (pair (make-symbol "pair")))
 239     `(let (,oldvalues)
 240        (dolist (,var ,vars)
 241          (let ((,value (server-getenv-from ,env ,var)))
 242            (setq ,oldvalues (cons (cons ,var (getenv ,var)) ,oldvalues))
 243            (setenv ,var ,value)))
 244        (unwind-protect
 245            (progn ,@body)
 246          (dolist (,pair ,oldvalues)
 247            (setenv (car ,pair) (cdr ,pair)))))))
 248
 249 (defun server-delete-client (client &optional noframe)
 250   "Delete CLIENT, including its buffers, terminals and frames.
 251 If NOFRAME is non-nil, let the frames live.  (To be used from
 252 `delete-frame-functions'."
 253   ;; Force a new lookup of client (prevents infinite recursion).
 254   (setq client (server-client
 255                 (if (listp client) (car client) client)))
 256   (let ((proc (car client))
 257         (buffers (server-client-get client 'buffers)))
 258     (when client
 259       (setq server-clients (delq client server-clients))
 260
 261       (dolist (buf buffers)
 262         (when (buffer-live-p buf)
 263           (with-current-buffer buf
 264             ;; Remove PROC from the clients of each buffer.
 265             (setq server-buffer-clients (delq proc server-buffer-clients))
 266             ;; Kill the buffer if necessary.
 267             (when (and (null server-buffer-clients)
 268                        (or (and server-kill-new-buffers
 269                                 (not server-existing-buffer))
 270                            (server-temp-file-p)))
 271               (kill-buffer (current-buffer))))))
 272
 273       ;; Delete the client's tty.
 274       (let ((terminal (server-client-get client 'terminal)))
 275         (when (eq (terminal-live-p terminal) t)
 276           (delete-terminal terminal)))
 277
 278       ;; Delete the client's frames.
 279       (unless noframe
 280         (dolist (frame (frame-list))
 281           (if (and (frame-live-p frame)
 282                    (equal (car client) (frame-parameter frame 'client)))
 283               (delete-frame frame))))
 284
 285       ;; Delete the client's process.
 286       (if (eq (process-status (car client)) 'open)
 287           (delete-process (car client)))
 288
 289       (server-log "Deleted" proc))))
 290
 291 (defun server-log (string &optional client)
 292   "If a *server* buffer exists, write STRING to it for logging purposes.
 293 If CLIENT is non-nil, add a description of it to the logged
 294 message."
 295   (if (get-buffer "*server*")
 296       (with-current-buffer "*server*"
 297         (goto-char (point-max))
 298         (insert (current-time-string)
 299                 (cond
 300                  ((null client) " ")
 301                  ((listp client) (format " %s: " (car client)))
 302                  (t (format " %s: " client)))
 303                 string)
 304         (or (bolp) (newline)))))
 305
 306 (defun server-sentinel (proc msg)
 307   "The process sentinel for Emacs server connections."
 308   ;; If this is a new client process, set the query-on-exit flag to nil
 309   ;; for this process (it isn't inherited from the server process).
 310   (when (and (eq (process-status proc) 'open)
 311              (process-query-on-exit-flag proc))
 312     (set-process-query-on-exit-flag proc nil))
 313   (server-log (format "Status changed to %s: %s" (process-status proc) msg) proc)
 314   (server-delete-client proc))
 315
 316 (defun server-handle-delete-frame (frame)
 317   "Delete the client connection when the emacsclient frame is deleted."
 318   (let ((proc (frame-parameter frame 'client)))
 319     (when (and (frame-live-p frame)
 320                proc
 321                (or (window-system frame)
 322                    ;; A terminal device must not yet be deleted if
 323                    ;; there are other frames on it.
 324                    (< 0 (let ((frame-num 0))
 325                           (mapc (lambda (f)
 326                                   (when (eq (frame-terminal f)
 327                                             (frame-terminal frame))
 328                                     (setq frame-num (1+ frame-num))))
 329                                 (frame-list))
 330                           frame-num))))
 331       (server-log (format "server-handle-delete-frame, frame %s" frame) proc)
 332       (server-delete-client proc 'noframe)))) ; Let delete-frame delete the frame later.
 333
 334 (defun server-handle-suspend-tty (terminal)
 335   "Notify the emacsclient process to suspend itself when its tty device is suspended."
 336   (dolist (proc (server-clients-with 'terminal terminal))
 337     (server-log (format "server-handle-suspend-tty, terminal %s" terminal) proc)
 338     (condition-case err
 339         (server-send-string proc "-suspend \n")
 340       (file-error (condition-case nil (server-delete-client proc) (error nil))))))
 341
 342 (defun server-unquote-arg (arg)
 343   "Remove &-quotation from ARG.
 344 See `server-quote-arg' and `server-process-filter'."
 345   (replace-regexp-in-string
 346    "&." (lambda (s)
 347           (case (aref s 1)
 348             (?& "&")
 349             (?- "-")
 350             (?n "\n")
 351             (t " ")))
 352    arg t t))
 353
 354 (defun server-quote-arg (arg)
 355   "In ARG, insert a & before each &, each space, each newline, and -.
 356 Change spaces to underscores, too, so that the return value never
 357 contains a space.
 358
 359 See `server-unquote-arg' and `server-process-filter'."
 360   (replace-regexp-in-string
 361    "[-&\n ]" (lambda (s)
 362                (case (aref s 0)
 363                  (?& "&&")
 364                  (?- "&-")
 365                  (?\n "&n")
 366                  (?\s "&_")))
 367    arg t t))
 368
 369 (defun server-send-string (proc string)
 370   "A wrapper around `proc-send-string' for logging."
 371   (server-log (concat "Sent " string) proc)
 372   (process-send-string proc string))
 373
 374 (defun server-ensure-safe-dir (dir)
 375   "Make sure DIR is a directory with no race-condition issues.
 376 Creates the directory if necessary and makes sure:
 377 - there's no symlink involved
 378 - it's owned by us
 379 - it's not readable/writable by anybody else."
 380   (setq dir (directory-file-name dir))
 381   (let ((attrs (file-attributes dir)))
 382     (unless attrs
 383       (letf (((default-file-modes) ?\700)) (make-directory dir))
 384       (setq attrs (file-attributes dir)))
 385     ;; Check that it's safe for use.
 386     (unless (and (eq t (car attrs)) (eq (nth 2 attrs) (user-uid))
 387                  (zerop (logand ?\077 (file-modes dir))))
 388       (error "The directory %s is unsafe" dir))))
 389
 390 ;;;###autoload
 391 (defun server-start (&optional leave-dead)
 392   "Allow this Emacs process to be a server for client processes.
 393 This starts a server communications subprocess through which
 394 client \"editors\" can send your editing commands to this Emacs
 395 job.  To use the server, set up the program `emacsclient' in the
 396 Emacs distribution as your standard \"editor\".
 397
 398 Prefix arg LEAVE-DEAD means just kill any existing server
 399 communications subprocess."
 400   (interactive "P")
 401   (when (or
 402          (not server-clients)
 403          (yes-or-no-p
 404           "The current server still has clients; delete them? "))
 405     ;; It is safe to get the user id now.
 406     (setq server-socket-dir (or server-socket-dir
 407                                 (format "/tmp/emacs%d" (user-uid))))
 408     ;; Make sure there is a safe directory in which to place the socket.
 409     (server-ensure-safe-dir server-socket-dir)
 410     ;; kill it dead!
 411     (if server-process
 412         (condition-case () (delete-process server-process) (error nil)))
 413     ;; Delete the socket files made by previous server invocations.
 414     (condition-case ()
 415         (delete-file (expand-file-name server-name server-socket-dir))
 416       (error nil))
 417     ;; If this Emacs already had a server, clear out associated status.
 418     (while server-clients
 419       (server-delete-client (car server-clients)))
 420     (if leave-dead
 421         (progn
 422           (server-log (message "Server stopped"))
 423           (setq server-process nil))
 424       (if server-process
 425           (server-log (message "Restarting server"))
 426         (server-log (message "Starting server")))
 427       (letf (((default-file-modes) ?\700))
 428         (add-hook 'suspend-tty-functions 'server-handle-suspend-tty)
 429         (add-hook 'delete-frame-functions 'server-handle-delete-frame)
 430         (add-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function)
 431         (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
 432         (setq server-process
 433               (make-network-process
 434                :name "server" :family 'local :server t :noquery t
 435                :service (expand-file-name server-name server-socket-dir)
 436                :sentinel 'server-sentinel :filter 'server-process-filter
 437                ;; We must receive file names without being decoded.
 438                ;; Those are decoded by server-process-filter according
 439                ;; to file-name-coding-system.
 440                :coding 'raw-text))))))
 441
 442 ;;;###autoload
 443 (define-minor-mode server-mode
 444   "Toggle Server mode.
 445 With ARG, turn Server mode on if ARG is positive, off otherwise.
 446 Server mode runs a process that accepts commands from the
 447 `emacsclient' program.  See `server-start' and Info node `Emacs server'."
 448   :global t
 449   :group 'server
 450   :version "22.1"
 451   ;; Fixme: Should this check for an existing server socket and do
 452   ;; nothing if there is one (for multiple Emacs sessions)?
 453   (server-start (not server-mode)))
 454 \f
 455 (defun server-process-filter (proc string)
 456   "Process a request from the server to edit some files.
 457 PROC is the server process.  STRING consists of a sequence of
 458 commands prefixed by a dash.  Some commands have arguments; these
 459 are &-quoted and need to be decoded by `server-unquote-arg'.  The
 460 filter parses and executes these commands.
 461
 462 To illustrate the protocol, here is an example command that
 463 emacsclient sends to create a new X frame (note that the whole
 464 sequence is sent on a single line):
 465
 466         -version 21.3.50 xterm
 467         -env HOME /home/lorentey
 468         -env DISPLAY :0.0
 469         ... lots of other -env commands
 470         -display :0.0
 471         -window-system
 472
 473 The server normally sends back the single command `-good-version'
 474 as a response.
 475
 476 The following commands are accepted by the server:
 477
 478 `-version CLIENT-VERSION'
 479   Check version numbers between server and client, and signal an
 480   error if there is a mismatch.  The server replies with
 481   `-good-version' to confirm the match.
 482
 483 `-env NAME=VALUE'
 484   An environment variable on the client side.
 485
 486 `-current-frame'
 487   Forbid the creation of new frames.
 488
 489 `-nowait'
 490   Request that the next frame created should not be
 491   associated with this client.
 492
 493 `-display DISPLAY'
 494   Set the display name to open X frames on.
 495
 496 `-position LINE[:COLUMN]'
 497   Go to the given line and column number
 498   in the next file opened.
 499
 500 `-file FILENAME'
 501   Load the given file in the current frame.
 502
 503 `-eval EXPR'
 504   Evaluate EXPR as a Lisp expression and return the
 505   result in -print commands.
 506
 507 `-window-system'
 508   Open a new X frame.
 509
 510 `-tty DEVICENAME TYPE'
 511   Open a new tty frame at the client.
 512
 513 `-resume'
 514   Resume this tty frame. The client sends this string when it
 515   gets the SIGCONT signal and it is the foreground process on its
 516   controlling tty.
 517
 518 `-suspend'
 519   Suspend this tty frame.  The client sends this string in
 520   response to SIGTSTP and SIGTTOU.  The server must cease all I/O
 521   on this tty until it gets a -resume command.
 522
 523 `-ignore COMMENT'
 524   Do nothing, but put the comment in the server
 525   log.  Useful for debugging.
 526
 527
 528 The following commands are accepted by the client:
 529
 530 `-good-version'
 531   Signals a version match between the client and the server.
 532
 533 `-emacs-pid PID'
 534   Describes the process id of the Emacs process;
 535   used to forward window change signals to it.
 536
 537 `-window-system-unsupported'
 538   Signals that the server does not
 539   support creating X frames; the client must try again with a tty
 540   frame.
 541
 542 `-print STRING'
 543   Print STRING on stdout.  Used to send values
 544   returned by -eval.
 545
 546 `-error DESCRIPTION'
 547   Signal an error (but continue processing).
 548
 549 `-suspend'
 550   Suspend this terminal, i.e., stop the client process.  Sent
 551   when the user presses C-z."
 552   (server-log (concat "Received " string) proc)
 553   (let ((prev (process-get proc 'previous-string)))
 554     (when prev
 555       (setq string (concat prev string))
 556       (process-put proc 'previous-string nil)))
 557   (condition-case err
 558       (progn
 559         (server-add-client proc)
 560         ;; If the input is multiple lines,
 561         ;; process each line individually.
 562         (while (string-match "\n" string)
 563           (let ((request (substring string 0 (match-beginning 0)))
 564                 (coding-system (and default-enable-multibyte-characters
 565                                     (or file-name-coding-system
 566                                         default-file-name-coding-system)))
 567                 (client (server-client proc))
 568                 current-frame
 569                 nowait ; t if emacsclient does not want to wait for us.
 570                 frame ; The frame that was opened for the client (if any).
 571                 display              ; Open the frame on this display.
 572                 dontkill       ; t if the client should not be killed.
 573                 env
 574                 (files nil)
 575                 (lineno 1)
 576                 (columnno 0))
 577             ;; Remove this line from STRING.
 578             (setq string (substring string (match-end 0)))
 579             (while (string-match " *[^ ]* " request)
 580               (let ((arg (substring request (match-beginning 0) (1- (match-end 0)))))
 581                 (setq request (substring request (match-end 0)))
 582                 (cond
 583                  ;; -version CLIENT-VERSION:
 584                  ;; Check version numbers, signal an error if there is a mismatch.
 585                  ((and (equal "-version" arg)
 586                        (string-match "\\([0-9.]+\\) " request))
 587                   (let* ((client-version (match-string 1 request))
 588                          (truncated-emacs-version
 589                           (substring emacs-version 0 (length client-version))))
 590                     (setq request (substring request (match-end 0)))
 591                     (if (equal client-version truncated-emacs-version)
 592                         (progn
 593                           (server-send-string proc "-good-version \n")
 594                           (server-client-set client 'version client-version))
 595                       (error (concat "Version mismatch: Emacs is "
 596                                      truncated-emacs-version
 597                                      ", emacsclient is " client-version)))))
 598
 599                  ;; -nowait:  Emacsclient won't wait for a result.
 600                  ((equal "-nowait" arg) (setq nowait t))
 601
 602                  ;; -current-frame:  Don't create frames.
 603                  ((equal "-current-frame" arg) (setq current-frame t))
 604
 605                  ;; -display DISPLAY:
 606                  ;; Open X frames on the given display instead of the default.
 607                  ((and (equal "-display" arg) (string-match "\\([^ ]*\\) " request))
 608                   (setq display (match-string 1 request)
 609                         request (substring request (match-end 0))))
 610
 611                  ;; -window-system:  Open a new X frame.
 612                  ((equal "-window-system" arg)
 613                   (unless (server-client-get client 'version)
 614                     (error "Protocol error; make sure to use the correct version of emacsclient"))
 615                   (unless current-frame
 616                     (if (fboundp 'x-create-frame)
 617                         (let ((params (if nowait
 618                                           ;; Flag frame as client-created, but use a dummy client.
 619                                           ;; This will prevent the frame from being deleted when
 620                                           ;; emacsclient quits while also preventing
 621                                           ;; `server-save-buffers-kill-terminal' from unexpectedly
 622                                           ;; killing emacs on that frame.
 623                                           (list (cons 'client 'nowait) (cons 'environment env))
 624                                         (list (cons 'client proc) (cons 'environment env)))))
 625                           (setq frame (make-frame-on-display
 626                                        (or display
 627                                            (frame-parameter nil 'display)
 628                                            (getenv "DISPLAY")
 629                                            (error "Please specify display"))
 630                                        params))
 631                           (server-log (format "%s created" frame) proc)
 632                           ;; XXX We need to ensure the parameters are
 633                           ;; really set because Emacs forgets unhandled
 634                           ;; initialization parameters for X frames at
 635                           ;; the moment.
 636                           (modify-frame-parameters frame params)
 637                           (select-frame frame)
 638                           (server-client-set client 'frame frame)
 639                           (server-client-set client 'terminal (frame-terminal frame))
 640                           (setq dontkill t))
 641                       ;; This emacs does not support X.
 642                       (server-log "Window system unsupported" proc)
 643                       (server-send-string proc "-window-system-unsupported \n")
 644                       (setq dontkill t))))
 645
 646                  ;; -resume:  Resume a suspended tty frame.
 647                  ((equal "-resume" arg)
 648                   (let ((terminal (server-client-get client 'terminal)))
 649                     (setq dontkill t)
 650                     (when (eq (terminal-live-p terminal) t)
 651                       (resume-tty terminal))))
 652
 653                  ;; -suspend:  Suspend the client's frame.  (In case we
 654                  ;; get out of sync, and a C-z sends a SIGTSTP to
 655                  ;; emacsclient.)
 656                  ((equal "-suspend" arg)
 657                   (let ((terminal (server-client-get client 'terminal)))
 658                     (setq dontkill t)
 659                     (when (eq (terminal-live-p terminal) t)
 660                       (suspend-tty terminal))))
 661
 662                  ;; -ignore COMMENT:  Noop; useful for debugging emacsclient.
 663                  ;; (The given comment appears in the server log.)
 664                  ((and (equal "-ignore" arg) (string-match "\\([^ ]*\\) " request))
 665                   (setq dontkill t
 666                         request (substring request (match-end 0))))
 667
 668                  ;; -tty DEVICE-NAME TYPE:  Open a new tty frame at the client.
 669                  ((and (equal "-tty" arg) (string-match "\\([^ ]*\\) \\([^ ]*\\) " request))
 670                   (let ((tty (server-unquote-arg (match-string 1 request)))
 671                         (type (server-unquote-arg (match-string 2 request))))
 672                     (setq request (substring request (match-end 0)))
 673                     (unless (server-client-get client 'version)
 674                       (error "Protocol error; make sure you use the correct version of emacsclient"))
 675                     (unless current-frame
 676                       (server-with-environment env
 677                           '("LANG" "LC_CTYPE" "LC_ALL"
 678                             ;; For tgetent(3); list according to ncurses(3).
 679                             "BAUDRATE" "COLUMNS" "ESCDELAY" "HOME" "LINES"
 680                             "NCURSES_ASSUMED_COLORS" "NCURSES_NO_PADDING"
 681                             "NCURSES_NO_SETBUF" "TERM" "TERMCAP" "TERMINFO"
 682                             "TERMINFO_DIRS" "TERMPATH")
 683                         (setq frame (make-frame-on-tty tty type
 684                                                        ;; Ignore nowait here; we always need to clean
 685                                                        ;; up opened ttys when the client dies.
 686                                                        `((client . ,proc)
 687                                                          (environment . ,env)))))
 688                       (select-frame frame)
 689                       (server-client-set client 'frame frame)
 690                       (server-client-set client 'tty (terminal-name frame))
 691                       (server-client-set client 'terminal (frame-terminal frame))
 692
 693                       ;; Reply with our pid.
 694                       (server-send-string proc (concat "-emacs-pid " (number-to-string (emacs-pid)) "\n"))
 695                       (setq dontkill t))))
 696
 697                  ;; -position LINE:  Go to the given line in the next file.
 698                  ((and (equal "-position" arg) (string-match "\\(\\+[0-9]+\\) " request))
 699                   (setq lineno (string-to-number (substring (match-string 1 request) 1))
 700                         request (substring request (match-end 0))))
 701
 702                  ;; -position LINE:COLUMN:  Set point to the given position in the next file.
 703                  ((and (equal "-position" arg) (string-match "\\+\\([0-9]+\\):\\([0-9]+\\) " request))
 704                   (setq lineno (string-to-number (match-string 1 request))
 705                         columnno (string-to-number (match-string 2 request))
 706                         request (substring request (match-end 0))))
 707
 708                  ;; -file FILENAME:  Load the given file.
 709                  ((and (equal "-file" arg) (string-match "\\([^ ]+\\) " request))
 710                   (let ((file (server-unquote-arg (match-string 1 request))))
 711                     (setq request (substring request (match-end 0)))
 712                     (if coding-system
 713                         (setq file (decode-coding-string file coding-system)))
 714                     (setq file (command-line-normalize-file-name file))
 715                     (push (list file lineno columnno) files)
 716                     (server-log (format "New file: %s (%d:%d)" file lineno columnno) proc))
 717                   (setq lineno 1
 718                         columnno 0))
 719
 720                  ;; -eval EXPR:  Evaluate a Lisp expression.
 721                  ((and (equal "-eval" arg) (string-match "\\([^ ]+\\) " request))
 722                   (let ((expr (server-unquote-arg (match-string 1 request))))
 723                     (setq request (substring request (match-end 0)))
 724                     (if coding-system
 725                         (setq expr (decode-coding-string expr coding-system)))
 726                     (let ((v (eval (car (read-from-string expr)))))
 727                       (when (and (not frame) v)
 728                         (with-temp-buffer
 729                           (let ((standard-output (current-buffer)))
 730                             (pp v)
 731                             (server-send-string
 732                              proc (format "-print %s\n"
 733                                           (server-quote-arg
 734                                            (buffer-substring-no-properties (point-min)
 735                                                                            (point-max)))))))))
 736                     (setq lineno 1
 737                           columnno 0)))
 738
 739                  ;; -env NAME=VALUE:  An environment variable.
 740                  ((and (equal "-env" arg) (string-match "\\([^ ]+\\) " request))
 741                   (let ((var (server-unquote-arg (match-string 1 request))))
 742                     ;; XXX Variables should be encoded as in getenv/setenv.
 743                     (setq request (substring request (match-end 0)))
 744                     (setq env (cons var env))))
 745
 746                  ;; Unknown command.
 747                  (t (error "Unknown command: %s" arg)))))
 748
 749             (let (buffers)
 750               (when files
 751                 (run-hooks 'pre-command-hook)
 752                 (setq buffers (server-visit-files files client nowait))
 753                 (run-hooks 'post-command-hook))
 754
 755               ;; Delete the client if necessary.
 756               (cond
 757                (nowait
 758                 ;; Client requested nowait; return immediately.
 759                 (server-log "Close nowait client" proc)
 760                 (server-delete-client proc))
 761                ((and (not dontkill) (null buffers))
 762                 ;; This client is empty; get rid of it immediately.
 763                 (server-log "Close empty client" proc)
 764                 (server-delete-client proc)))
 765               (cond
 766                ((or isearch-mode (minibufferp))
 767                 nil)
 768                ((and frame (null buffers))
 769                 (message "%s" (substitute-command-keys
 770                                "When done with this frame, type \\[delete-frame]")))
 771                ((not (null buffers))
 772                 (server-switch-buffer (car buffers))
 773                 (run-hooks 'server-switch-hook)
 774                 (unless nowait
 775                   (message "%s" (substitute-command-keys
 776                                  "When done with a buffer, type \\[server-edit]"))))))))
 777
 778         ;; Save for later any partial line that remains.
 779         (when (> (length string) 0)
 780           (process-put proc 'previous-string string)))
 781     ;; condition-case
 782     (error (ignore-errors
 783              (server-send-string
 784               proc (concat "-error " (server-quote-arg (error-message-string err))))
 785              (setq string "")
 786              (server-log (error-message-string err) proc)
 787              (delete-process proc)))))
 788
 789 (defun server-goto-line-column (file-line-col)
 790   "Move point to the position indicated in FILE-LINE-COL.
 791 FILE-LINE-COL should be a three-element list as described in
 792 `server-visit-files'."
 793   (goto-line (nth 1 file-line-col))
 794   (let ((column-number (nth 2 file-line-col)))
 795     (if (> column-number 0)
 796         (move-to-column (1- column-number)))))
 797
 798 (defun server-visit-files (files client &optional nowait)
 799   "Find FILES and return a list of buffers created.
 800 FILES is an alist whose elements are (FILENAME LINENUMBER COLUMNNUMBER).
 801 CLIENT is the client that requested this operation.
 802 NOWAIT non-nil means this client is not waiting for the results,
 803 so don't mark these buffers specially, just visit them normally."
 804   ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries.
 805   (let ((last-nonmenu-event t) client-record)
 806     ;; Restore the current buffer afterward, but not using save-excursion,
 807     ;; because we don't want to save point in this buffer
 808     ;; if it happens to be one of those specified by the server.
 809     (save-current-buffer
 810       (dolist (file files)
 811         ;; If there is an existing buffer modified or the file is
 812         ;; modified, revert it.  If there is an existing buffer with
 813         ;; deleted file, offer to write it.
 814         (let* ((filen (car file))
 815                (obuf (get-file-buffer filen)))
 816           (push filen file-name-history)
 817           (if (and obuf (set-buffer obuf))
 818               (progn
 819                 (cond ((file-exists-p filen)
 820                        (if (not (verify-visited-file-modtime obuf))
 821                            (revert-buffer t nil)))
 822                       (t
 823                        (if (y-or-n-p
 824                             (concat "File no longer exists: " filen
 825                                     ", write buffer to file? "))
 826                            (write-file filen))))
 827                 (setq server-existing-buffer t)
 828                 (server-goto-line-column file))
 829             (set-buffer (find-file-noselect filen))
 830             (server-goto-line-column file)
 831             (run-hooks 'server-visit-hook)))
 832         (unless nowait
 833           ;; When the buffer is killed, inform the clients.
 834           (add-hook 'kill-buffer-hook 'server-kill-buffer nil t)
 835           (push (car client) server-buffer-clients))
 836         (push (current-buffer) client-record)))
 837     (unless nowait
 838       (server-client-set
 839        client 'buffers
 840        (nconc (server-client-get client 'buffers) client-record)))
 841     client-record))
 842 \f
 843 (defun server-buffer-done (buffer &optional for-killing)
 844   "Mark BUFFER as \"done\" for its client(s).
 845 This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
 846 NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
 847 or nil.  KILLED is t if we killed BUFFER (typically, because it was visiting
 848 a temp file).
 849 FOR-KILLING if non-nil indicates that we are called from `kill-buffer'."
 850   (let ((next-buffer nil)
 851         (killed nil))
 852     (dolist (client server-clients)
 853       (let ((buffers (server-client-get client 'buffers)))
 854         (or next-buffer
 855             (setq next-buffer (nth 1 (memq buffer buffers))))
 856         (when buffers                   ; Ignore bufferless clients.
 857           (setq buffers (delq buffer buffers))
 858           ;; Delete all dead buffers from CLIENT.
 859           (dolist (b buffers)
 860             (and (bufferp b)
 861                  (not (buffer-live-p b))
 862                  (setq buffers (delq b buffers))))
 863           (server-client-set client 'buffers buffers)
 864           ;; If client now has no pending buffers,
 865           ;; tell it that it is done, and forget it entirely.
 866           (unless buffers
 867             (server-log "Close" client)
 868             (server-delete-client client)))))
 869     (if (and (bufferp buffer) (buffer-name buffer))
 870         ;; We may or may not kill this buffer;
 871         ;; if we do, do not call server-buffer-done recursively
 872         ;; from kill-buffer-hook.
 873         (let ((server-kill-buffer-running t))
 874           (with-current-buffer buffer
 875             (setq server-buffer-clients nil)
 876             (run-hooks 'server-done-hook))
 877           ;; Notice whether server-done-hook killed the buffer.
 878           (if (null (buffer-name buffer))
 879               (setq killed t)
 880             ;; Don't bother killing or burying the buffer
 881             ;; when we are called from kill-buffer.
 882             (unless for-killing
 883               (when (and (not killed)
 884                          server-kill-new-buffers
 885                          (with-current-buffer buffer
 886                            (not server-existing-buffer)))
 887                 (setq killed t)
 888                 (bury-buffer buffer)
 889                 (kill-buffer buffer))
 890               (unless killed
 891                 (if (server-temp-file-p buffer)
 892                     (progn
 893                       (kill-buffer buffer)
 894                       (setq killed t))
 895                   (bury-buffer buffer)))))))
 896     (list next-buffer killed)))
 897
 898 (defun server-temp-file-p (&optional buffer)
 899   "Return non-nil if BUFFER contains a file considered temporary.
 900 These are files whose names suggest they are repeatedly
 901 reused to pass information to another program.
 902
 903 The variable `server-temp-file-regexp' controls which filenames
 904 are considered temporary."
 905   (and (buffer-file-name buffer)
 906        (string-match server-temp-file-regexp (buffer-file-name buffer))))
 907
 908 (defun server-done ()
 909   "Offer to save current buffer, mark it as \"done\" for clients.
 910 This kills or buries the buffer, then returns a list
 911 of the form (NEXT-BUFFER KILLED).  NEXT-BUFFER is another server buffer,
 912 as a suggestion for what to select next, or nil.
 913 KILLED is t if we killed BUFFER, which happens if it was created
 914 specifically for the clients and did not exist before their request for it."
 915   (when server-buffer-clients
 916     (if (server-temp-file-p)
 917         ;; For a temp file, save, and do make a non-numeric backup
 918         ;; (unless make-backup-files is nil).
 919         (let ((version-control nil)
 920               (buffer-backed-up nil))
 921           (save-buffer))
 922       (if (and (buffer-modified-p)
 923                buffer-file-name
 924                (y-or-n-p (concat "Save file " buffer-file-name "? ")))
 925           (save-buffer)))
 926     (server-buffer-done (current-buffer))))
 927
 928 ;; Ask before killing a server buffer.
 929 ;; It was suggested to release its client instead,
 930 ;; but I think that is dangerous--the client would proceed
 931 ;; using whatever is on disk in that file. -- rms.
 932 (defun server-kill-buffer-query-function ()
 933   "Ask before killing a server buffer."
 934   (or (not server-buffer-clients)
 935       (let ((res t))
 936         (dolist (proc server-buffer-clients res)
 937           (let ((client (server-client proc)))
 938             (when (and client (eq (process-status proc) 'open))
 939               (setq res nil)))))
 940       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
 941                            (buffer-name (current-buffer))))))
 942
 943 (defun server-kill-emacs-query-function ()
 944   "Ask before exiting Emacs it has live clients."
 945   (or (not server-clients)
 946       (let (live-client)
 947         (dolist (client server-clients live-client)
 948           (if (memq t (mapcar 'buffer-live-p (server-client-get
 949                                               client 'buffers)))
 950               (setq live-client t))))
 951       (yes-or-no-p "This Emacs session has clients; exit anyway? ")))
 952
 953 (defvar server-kill-buffer-running nil
 954   "Non-nil while `server-kill-buffer' or `server-buffer-done' is running.")
 955
 956 (defun server-kill-buffer ()
 957   "Remove the current buffer from its clients' buffer list.
 958 Designed to be added to `kill-buffer-hook'."
 959   ;; Prevent infinite recursion if user has made server-done-hook
 960   ;; call kill-buffer.
 961   (or server-kill-buffer-running
 962       (and server-buffer-clients
 963            (let ((server-kill-buffer-running t))
 964              (when server-process
 965                (server-buffer-done (current-buffer) t))))))
 966 \f
 967 (defun server-edit (&optional arg)
 968   "Switch to next server editing buffer; say \"Done\" for current buffer.
 969 If a server buffer is current, it is marked \"done\" and optionally saved.
 970 The buffer is also killed if it did not exist before the clients asked for it.
 971 When all of a client's buffers are marked as \"done\", the client is notified.
 972
 973 Temporary files such as MH <draft> files are always saved and backed up,
 974 no questions asked.  (The variable `make-backup-files', if nil, still
 975 inhibits a backup; you can set it locally in a particular buffer to
 976 prevent a backup for it.)  The variable `server-temp-file-regexp' controls
 977 which filenames are considered temporary.
 978
 979 If invoked with a prefix argument, or if there is no server process running,
 980 starts server process and that is all.  Invoked by \\[server-edit]."
 981   (interactive "P")
 982   (if (or arg
 983           (not server-process)
 984           (memq (process-status server-process) '(signal exit)))
 985       (server-start nil)
 986     (apply 'server-switch-buffer (server-done))))
 987
 988 (defun server-switch-buffer (&optional next-buffer killed-one)
 989   "Switch to another buffer, preferably one that has a client.
 990 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it.
 991
 992 KILLED-ONE is t in a recursive call if we have already killed one
 993 temp-file server buffer.  This means we should avoid the final
 994 \"switch to some other buffer\" since we've already effectively
 995 done that."
 996   (if (null next-buffer)
 997       (progn
 998         (let ((rest server-clients))
 999           (while (and rest (not next-buffer))
1000             (let ((client (car rest)))
1001               ;; Only look at frameless clients.
1002               (when (not (server-client-get client 'frame))
1003                 (setq next-buffer (car (server-client-get client 'buffers))))
1004               (setq rest (cdr rest)))))
1005         (and next-buffer (server-switch-buffer next-buffer killed-one))
1006         (unless (or next-buffer killed-one (window-dedicated-p (selected-window)))
1007           ;; (switch-to-buffer (other-buffer))
1008           (message "No server buffers remain to edit")))
1009     (if (not (buffer-live-p next-buffer))
1010         ;; If NEXT-BUFFER is a dead buffer, remove the server records for it
1011         ;; and try the next surviving server buffer.
1012         (apply 'server-switch-buffer (server-buffer-done next-buffer))
1013       ;; OK, we know next-buffer is live, let's display and select it.
1014       (if (functionp server-window)
1015           (funcall server-window next-buffer)
1016         (let ((win (get-buffer-window next-buffer 0)))
1017           (if (and win (not server-window))
1018               ;; The buffer is already displayed: just reuse the window.
1019               (let ((frame (window-frame win)))
1020                 (if (eq (frame-visible-p frame) 'icon)
1021                     (raise-frame frame))
1022                 (select-window win)
1023                 (set-buffer next-buffer))
1024             ;; Otherwise, let's find an appropriate window.
1025             (cond ((and (windowp server-window)
1026                         (window-live-p server-window))
1027                    (select-window server-window))
1028                   ((framep server-window)
1029                    (if (not (frame-live-p server-window))
1030                        (setq server-window (make-frame)))
1031                    (select-window (frame-selected-window server-window))))
1032             (if (window-minibuffer-p (selected-window))
1033                 (select-window (next-window nil 'nomini 0)))
1034             ;; Move to a non-dedicated window, if we have one.
1035             (when (window-dedicated-p (selected-window))
1036               (select-window
1037                (get-window-with-predicate
1038                 (lambda (w)
1039                   (and (not (window-dedicated-p w))
1040                        (equal (frame-terminal (window-frame w))
1041                               (frame-terminal (selected-frame)))))
1042                 'nomini 'visible (selected-window))))
1043             (condition-case nil
1044                 (switch-to-buffer next-buffer)
1045               ;; After all the above, we might still have ended up with
1046               ;; a minibuffer/dedicated-window (if there's no other).
1047               (error (pop-to-buffer next-buffer)))))))))
1048
1049 ;;;###autoload
1050 (defun server-save-buffers-kill-terminal (proc &optional arg)
1051   "Offer to save each buffer, then kill PROC.
1052
1053 With prefix arg, silently save all file-visiting buffers, then kill.
1054
1055 If emacsclient was started with a list of filenames to edit, then
1056 only these files will be asked to be saved."
1057   (let ((buffers (server-client-get proc 'buffers)))
1058     ;; If client is bufferless, emulate a normal Emacs session
1059     ;; exit and offer to save all buffers.  Otherwise, offer to
1060     ;; save only the buffers belonging to the client.
1061     (save-some-buffers arg
1062                        (if buffers
1063                            (lambda () (memq (current-buffer) buffers))
1064                          t))
1065     (server-delete-client proc)))
1066
1067 (define-key ctl-x-map "#" 'server-edit)
1068
1069 (defun server-unload-hook ()
1070   "Unload the server library."
1071   (server-start t)
1072   (remove-hook 'suspend-tty-functions 'server-handle-suspend-tty)
1073   (remove-hook 'delete-frame-functions 'server-handle-delete-frame)
1074   (remove-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function)
1075   (remove-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
1076   (remove-hook 'kill-buffer-hook 'server-kill-buffer))
1077
1078 (add-hook 'server-unload-hook 'server-unload-hook)
1079 \f
1080 (provide 'server)
1081
1082 ;;; arch-tag: 1f7ecb42-f00a-49f8-906d-61995d84c8d6
1083 ;;; server.el ends here