configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.2.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 dnl Fairly arbitrary, older versions might work too.
  30 AM_INIT_AUTOMAKE(1.11)
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 leimdir='${datadir}/emacs/${version}/leim'
  42 standardlisppath='${lispdir}:${leimdir}'
  43 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  44 '${datadir}/emacs/site-lisp'
  45 lisppath='${locallisppath}:${standardlisppath}'
  46 etcdir='${datadir}/emacs/${version}/etc'
  47 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  48 docdir='${datadir}/emacs/${version}/etc'
  49 gamedir='${localstatedir}/games/emacs'
  50
  51 dnl Special option to disable the most of other options.
  52 AC_ARG_WITH(all,
  53 [AS_HELP_STRING([--without-all],
  54                 [omit almost all features and build
  55                 small executable with minimal dependencies])],
  56   with_features=$withval,
  57   with_features=yes)
  58
  59 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  60 dnl Create a new --with option that defaults to being disabled.
  61 dnl NAME is the base name of the option.  The shell variable with_NAME
  62 dnl   will be set to either the user's value (if the option is
  63 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  64 dnl   option is not specified).  Note that the shell variable name is
  65 dnl   constructed as autoconf does, by replacing non-alphanumeric
  66 dnl   characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  70     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  71 ])dnl
  72
  73 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  74 dnl Create a new --with option that defaults to $enable_features.
  75 dnl NAME is the base name of the option.  The shell variable with_NAME
  76 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  77 dnl   'yes' (if the option is not specified).  Note that the shell
  78 dnl   variable name is constructed as autoconf does, by replacing
  79 dnl   non-alphanumeric characters with "_".
  80 dnl HELP-STRING is the help text for the option.
  81 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  82   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  83    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  84 ])dnl
  85
  86 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  87 if test "$with_pop" = yes; then
  88    AC_DEFINE(MAIL_USE_POP)
  89 fi
  90 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  91
  92 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  93 if test "$with_kerberos" != no; then
  94    AC_DEFINE(KERBEROS)
  95 fi
  96 AH_TEMPLATE(KERBEROS,
  97             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  98
  99 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 100 if test "${with_kerberos5}" != no; then
 101   if test "${with_kerberos}" = no; then
 102     with_kerberos=yes
 103     AC_DEFINE(KERBEROS)
 104   fi
 105   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 109 dnl FIXME hesiod support may not be present, so it seems like an error
 110 dnl to define, or at least use, this unconditionally.
 111 if test "$with_hesiod" != no; then
 112   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 113 fi
 114
 115 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 116 if test "$with_mmdf" != no; then
 117    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 118 fi
 119
 120 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 121 if test "$with_mail_unlink" != no; then
 122    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 123 fi
 124
 125 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 126     [string giving default POP mail host])],
 127     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 128
 129 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 130
 131 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 132 if test "$with_sync_input" = yes; then
 133    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 134 fi
 135
 136 dnl FIXME currently it is not the last.
 137 dnl This should be the last --with option, because --with-x is
 138 dnl added later on when we find the path of X, and it's best to
 139 dnl keep them together visually.
 140 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 141  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 142 [         case "${withval}" in
 143             y | ye | yes )      val=gtk ;;
 144             n | no )            val=no  ;;
 145             l | lu | luc | luci | lucid )       val=lucid ;;
 146             a | at | ath | athe | athen | athena )      val=athena ;;
 147             m | mo | mot | moti | motif )       val=motif ;;
 148             g | gt | gtk  )     val=gtk ;;
 149             gtk3  )     val=gtk3 ;;
 150             * )
 151 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 152 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 153 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 154             ;;
 155           esac
 156           with_x_toolkit=$val
 157 ])
 158
 159 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 160 if test "$with_wide_int" = yes; then
 161   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 162 fi
 163
 164 dnl _ON results in a '--without' option in the --help output, so
 165 dnl the help text should refer to "don't compile", etc.
 166 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 167 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 168 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 169 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 170 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 171 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 172 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 173 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 174
 175 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 176 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 177 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 178
 179 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 180 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 181 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 182 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 183 OPTION_DEFAULT_OFF([w32], [use native Windows GUI])
 184
 185 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 186 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 187 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 188 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 189 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 190 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 191
 192 ## For the times when you want to build Emacs but don't have
 193 ## a suitable makeinfo, and can live without the manuals.
 194 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 195 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 196
 197 ## Makefile.in needs the cache file name.
 198 AC_SUBST(cache_file)
 199
 200 ## This is an option because I do not know if all info/man support
 201 ## compressed files, nor how to test if they do so.
 202 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 203 if test $with_compress_info = yes; then
 204    GZIP_INFO=yes
 205 else
 206    GZIP_INFO=
 207 fi
 208 AC_SUBST(GZIP_INFO)
 209
 210 AC_ARG_WITH([pkg-config-prog],dnl
 211 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 212                   [path to pkg-config for finding GTK and librsvg])])
 213 if test "X${with_pkg_config_prog}" != X; then
 214    if test "${with_pkg_config_prog}" != yes; then
 215       PKG_CONFIG="${with_pkg_config_prog}"
 216    fi
 217 fi
 218
 219 CRT_DIR=
 220 AC_ARG_WITH([crt-dir],dnl
 221 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 222 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 223 CRT_DIR="${with_crt_dir}"
 224
 225 AC_ARG_WITH(gameuser,dnl
 226 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 227 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 228   && gameuser="${with_gameuser}"
 229 test "X$gameuser" = X && gameuser=games
 230
 231 AC_ARG_WITH([gnustep-conf],dnl
 232 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 233 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 234   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 235 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 236      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 237
 238 AC_ARG_ENABLE(ns-self-contained,
 239 [AS_HELP_STRING([--disable-ns-self-contained],
 240                 [disable self contained build under NeXTstep])],
 241    EN_NS_SELF_CONTAINED=$enableval,
 242    EN_NS_SELF_CONTAINED=yes)
 243
 244 AC_ARG_ENABLE(locallisppath,
 245 [AS_HELP_STRING([--enable-locallisppath=PATH],
 246                 [directories Emacs should search for lisp files specific
 247                  to this site])],
 248 if test "${enableval}" = "no"; then
 249   locallisppath=
 250 elif test "${enableval}" != "yes"; then
 251   locallisppath=${enableval}
 252 fi)
 253
 254 AC_ARG_ENABLE(checking,
 255 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 256                 [enable expensive run-time checks.  With LIST,
 257                  enable only specific categories of checks.
 258                  Categories are: all,yes,no.
 259                  Flags are: stringbytes, stringoverrun, stringfreelist,
 260                  xmallocoverrun, conslist, glyphs])],
 261 [ac_checking_flags="${enableval}"],[])
 262 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 263 for check in $ac_checking_flags
 264 do
 265         case $check in
 266         # these set all the flags to specific states
 267         yes)            ac_enable_checking=1 ;;
 268         no)             ac_enable_checking= ;
 269                         ac_gc_check_stringbytes= ;
 270                         ac_gc_check_string_overrun= ;
 271                         ac_gc_check_string_free_list= ;
 272                         ac_xmalloc_overrun= ;
 273                         ac_gc_check_cons_list= ;
 274                         ac_glyphs_debug= ;;
 275         all)            ac_enable_checking=1 ;
 276                         ac_gc_check_stringbytes=1 ;
 277                         ac_gc_check_string_overrun=1 ;
 278                         ac_gc_check_string_free_list=1 ;
 279                         ac_xmalloc_overrun=1 ;
 280                         ac_gc_check_cons_list=1 ;
 281                         ac_glyphs_debug=1 ;;
 282         # these enable particular checks
 283         stringbytes)    ac_gc_check_stringbytes=1 ;;
 284         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 285         stringfreelist) ac_gc_check_string_free_list=1 ;;
 286         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 287         conslist)       ac_gc_check_cons_list=1 ;;
 288         glyphs)         ac_glyphs_debug=1 ;;
 289         *)      AC_MSG_ERROR(unknown check category $check) ;;
 290         esac
 291 done
 292 IFS="$ac_save_IFS"
 293
 294 if test x$ac_enable_checking != x ; then
 295   AC_DEFINE(ENABLE_CHECKING, 1,
 296 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 297 fi
 298 if test x$ac_gc_check_stringbytes != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 300 [Define this temporarily to hunt a bug.  If defined, the size of
 301    strings is redundantly recorded in sdata structures so that it can
 302    be compared to the sizes recorded in Lisp strings.])
 303 fi
 304 if test x$ac_gc_check_string_overrun != x ; then
 305   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 306 [Define this to check for short string overrun.])
 307 fi
 308 if test x$ac_gc_check_string_free_list != x ; then
 309   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 310 [Define this to check the string free list.])
 311 fi
 312 if test x$ac_xmalloc_overrun != x ; then
 313   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 314 [Define this to check for malloc buffer overrun.])
 315 fi
 316 if test x$ac_gc_check_cons_list != x ; then
 317   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 318 [Define this to check for errors in cons list.])
 319 fi
 320 if test x$ac_glyphs_debug != x ; then
 321   AC_DEFINE(GLYPH_DEBUG, 1,
 322 [Define this to enable glyphs debugging code.])
 323 fi
 324
 325 AC_ARG_ENABLE(check-lisp-object-type,
 326 [AS_HELP_STRING([--enable-check-lisp-object-type],
 327                 [enable compile time checks for the Lisp_Object data type.
 328                 This is useful for development for catching certain types of bugs.])],
 329 if test "${enableval}" != "no"; then
 330    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 331    [Define this to enable compile time checks for the Lisp_Object data type.])
 332 fi)
 333
 334
 335 AC_ARG_ENABLE(profiling,
 336 [AS_HELP_STRING([--enable-profiling],
 337                 [build emacs with profiling support.
 338                  This might not work on all platforms])],
 339 [ac_enable_profiling="${enableval}"],[])
 340 if test x$ac_enable_profiling != x ; then
 341    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 342 else
 343    PROFILING_CFLAGS=
 344 fi
 345 AC_SUBST(PROFILING_CFLAGS)
 346
 347 AC_ARG_ENABLE(autodepend,
 348 [AS_HELP_STRING([--enable-autodepend],
 349                 [automatically generate dependencies to .h-files.
 350                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 351                  found])],
 352 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 353
 354 #### Make srcdir absolute, if it isn't already.  It's important to
 355 #### avoid running the path through pwd unnecessarily, since pwd can
 356 #### give you automounter prefixes, which can go away.  We do all this
 357 #### so Emacs can find its files when run uninstalled.
 358 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 359 unset CDPATH
 360 case "${srcdir}" in
 361   /* ) ;;
 362   . )
 363     ## We may be able to use the $PWD environment variable to make this
 364     ## absolute.  But sometimes PWD is inaccurate.
 365     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 366     ## but that tested only for a well-formed and valid PWD,
 367     ## it did not object when PWD was well-formed and valid but just wrong.
 368     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 369     then
 370       srcdir="$PWD"
 371     else
 372       srcdir="`(cd ${srcdir}; pwd)`"
 373     fi
 374   ;;
 375   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 376 esac
 377
 378 ### Canonicalize the configuration name.
 379
 380 AC_CANONICAL_HOST
 381 canonical=$host
 382 configuration=${host_alias-${build_alias-$host}}
 383
 384 dnl This used to use changequote, but, apart from `changequote is evil'
 385 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 386 dnl the great gob of text.  Thus it's not processed for possible expansion.
 387 dnl Just make sure the brackets remain balanced.
 388 dnl
 389 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 390 dnl indicated by comments.
 391 dnl quotation begins
 392 [
 393
 394 ### If you add support for a new configuration, add code to this
 395 ### switch statement to recognize your configuration name and select
 396 ### the appropriate operating system file.
 397
 398 ### You would hope that you could choose an s/*.h
 399 ### file based on the operating system portion.  However, it turns out
 400 ### that each s/*.h file is pretty manufacturer-specific.
 401 ### So we basically have to have a special case for each
 402 ### configuration name.
 403 ###
 404 ### As far as handling version numbers on operating systems is
 405 ### concerned, make sure things will fail in a fixable way.  If
 406 ### /etc/MACHINES doesn't say anything about version numbers, be
 407 ### prepared to handle anything reasonably.  If version numbers
 408 ### matter, be sure /etc/MACHINES says something about it.
 409
 410 opsys='' unported=no
 411 case "${canonical}" in
 412
 413   ## GNU/Linux and similar ports
 414   *-*-linux* )
 415     opsys=gnu-linux
 416   ;;
 417
 418   ## FreeBSD ports
 419   *-*-freebsd* )
 420     opsys=freebsd
 421   ;;
 422
 423   ## FreeBSD kernel + glibc based userland
 424   *-*-kfreebsd*gnu* )
 425     opsys=gnu-kfreebsd
 426   ;;
 427
 428   ## NetBSD ports
 429   *-*-netbsd* )
 430     opsys=netbsd
 431   ;;
 432
 433   ## OpenBSD ports
 434   *-*-openbsd* )
 435     opsys=openbsd
 436   ;;
 437
 438   ## Apple Darwin / Mac OS X
 439   *-apple-darwin* )
 440     case "${canonical}" in
 441       i[3456]86-* )  ;;
 442       powerpc-* )    ;;
 443       x86_64-* )     ;;
 444       * )            unported=yes ;;
 445     esac
 446     opsys=darwin
 447     ## Use fink packages if available.
 448     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 449 ##    if test -d /sw/include && test -d /sw/lib; then
 450 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 451 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 452 ##    fi
 453   ;;
 454
 455   ## HP 9000 series 700 and 800, running HP/UX
 456   hppa*-hp-hpux10.2* )
 457     opsys=hpux10-20
 458   ;;
 459   hppa*-hp-hpux1[1-9]* )
 460     opsys=hpux11
 461     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 462   ;;
 463
 464   ## IBM machines
 465   rs6000-ibm-aix4.[23]* )
 466     opsys=aix4-2
 467   ;;
 468   powerpc-ibm-aix4.[23]*  )
 469     opsys=aix4-2
 470   ;;
 471   rs6000-ibm-aix[56]* )
 472     opsys=aix4-2
 473   ;;
 474   powerpc-ibm-aix[56]*  )
 475     opsys=aix4-2
 476   ;;
 477
 478   ## Silicon Graphics machines
 479   ## Iris 4D
 480   mips-sgi-irix6.5 )
 481     opsys=irix6-5
 482     # Without defining _LANGUAGE_C, things get masked out in the headers
 483     # so that, for instance, grepping for `free' in stdlib.h fails and
 484     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 485     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 486   ;;
 487
 488   ## Suns
 489   *-sun-solaris* \
 490     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 491     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 492     case "${canonical}" in
 493       i[3456]86-*-* )   ;;
 494       amd64-*-*|x86_64-*-*) ;;
 495       sparc* )          ;;
 496       * )               unported=yes ;;
 497     esac
 498     case "${canonical}" in
 499       *-sunos5.6* | *-solaris2.6* )
 500                 opsys=sol2-6
 501                 RANLIB="ar -ts"
 502                 ;;
 503       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 504                 opsys=sol2-6
 505                 emacs_check_sunpro_c=yes
 506                 ;;
 507       *-sunos5* | *-solaris* )
 508                 opsys=sol2-10
 509                 emacs_check_sunpro_c=yes
 510                 ;;
 511     esac
 512     ## Watch out for a compiler that we know will not work.
 513     case "${canonical}" in
 514      *-solaris* | *-sunos5* )
 515                 if [ "x$CC" = x/usr/ucb/cc ]; then
 516                   ## /usr/ucb/cc doesn't work;
 517                   ## we should find some other compiler that does work.
 518                   unset CC
 519                 fi
 520                 ;;
 521       *) ;;
 522     esac
 523   ;;
 524
 525   ## Intel 386 machines where we don't care about the manufacturer.
 526   i[3456]86-*-* )
 527     case "${canonical}" in
 528       *-cygwin )                opsys=cygwin ;;
 529       *-darwin* )               opsys=darwin ;;
 530       *-sysv4.2uw* )            opsys=unixware ;;
 531       *-sysv5uw* )              opsys=unixware ;;
 532       *-sysv5OpenUNIX* )        opsys=unixware ;;
 533       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 534     esac
 535   ;;
 536
 537   * )
 538     unported=yes
 539   ;;
 540 esac
 541
 542 ### If the code above didn't choose an operating system, just choose
 543 ### an operating system based on the configuration name.  You really
 544 ### only want to use this when you have no idea what the right
 545 ### operating system is; if you know what operating systems a machine
 546 ### runs, it's cleaner to make it explicit in the case statement
 547 ### above.
 548 if test x"${opsys}" = x; then
 549   case "${canonical}" in
 550     *-gnu* )                            opsys=gnu ;;
 551     * )
 552       unported=yes
 553     ;;
 554   esac
 555 fi
 556
 557 ]
 558 dnl quotation ends
 559
 560 if test $unported = yes; then
 561   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 562 Check `etc/MACHINES' for recognized configuration names.])
 563 fi
 564
 565
 566 #### Choose a compiler.
 567
 568 dnl Sets GCC=yes if using gcc.
 569 AC_PROG_CC
 570 AM_PROG_CC_C_O
 571
 572 if test x$GCC = xyes; then
 573   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 574 else
 575   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 576 fi
 577
 578 # Initialize gnulib right after choosing the compiler.
 579 gl_EARLY
 580
 581 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 582 # if -g3 works and the user does not specify CFLAGS.
 583 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 584 if test "$ac_test_CFLAGS" != set; then
 585   case $CFLAGS in
 586     '-g')
 587       emacs_g3_CFLAGS='-g3';;
 588     '-g -O2')
 589       emacs_g3_CFLAGS='-g3 -O2';;
 590     *)
 591       emacs_g3_CFLAGS='';;
 592   esac
 593   if test -n "$emacs_g3_CFLAGS"; then
 594     emacs_save_CFLAGS=$CFLAGS
 595     CFLAGS=$emacs_g3_CFLAGS
 596     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 597       [emacs_cv_prog_cc_g3],
 598       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 599          [emacs_cv_prog_cc_g3=yes],
 600          [emacs_cv_prog_cc_g3=no])])
 601     if test $emacs_cv_prog_cc_g3 = yes; then
 602       CFLAGS=$emacs_g3_CFLAGS
 603     else
 604       CFLAGS=$emacs_save_CFLAGS
 605     fi
 606   fi
 607 fi
 608
 609 AC_ARG_ENABLE([gcc-warnings],
 610   [AS_HELP_STRING([--enable-gcc-warnings],
 611                   [turn on lots of GCC warnings. This is intended for
 612                    developers, and may generate false alarms when used
 613                    with older or non-GNU development tools.])],
 614   [case $enableval in
 615      yes|no) ;;
 616      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 617    esac
 618    gl_gcc_warnings=$enableval],
 619   [gl_gcc_warnings=no]
 620 )
 621
 622 AC_ARG_ENABLE(link-time-optimization,
 623 [AS_HELP_STRING([--enable-link-time-optimization],
 624                 [build emacs with link-time optimization.
 625                  This is supported only for GCC since 4.5.0.])],
 626 if test "${enableval}" != "no"; then
 627    AC_MSG_CHECKING([whether link-time optimization is supported])
 628    ac_lto_supported=no
 629    if test x$GCC = xyes; then
 630       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 631       if test x$CPUS != x; then
 632          LTO="-flto=$CPUS"
 633       else
 634          LTO="-flto"
 635       fi
 636       old_CFLAGS=$CFLAGS
 637       CFLAGS="$CFLAGS $LTO"
 638       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 639         [ac_lto_supported=yes], [ac_lto_supported=no])
 640       CFLAGS="$old_CFLAGS"
 641    fi
 642    AC_MSG_RESULT([$ac_lto_supported])
 643    if test "$ac_lto_supported" = "yes"; then
 644       CFLAGS="$CFLAGS $LTO"
 645    fi
 646 fi)
 647
 648 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 649 # ------------------------------------------------
 650 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 651 # Otherwise, run RUN-IF-NOT-FOUND.
 652 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 653   [AC_PREPROC_IFELSE(
 654     [AC_LANG_PROGRAM(
 655       [[
 656 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 657 /* ok */
 658 #else
 659 # error "your version of gcc is older than $1.$2"
 660 #endif
 661       ]]),
 662     ], [$3], [$4])
 663   ]
 664 )
 665
 666 # When compiling with GCC, prefer -isystem to -I when including system
 667 # include files, to avoid generating useless diagnostics for the files.
 668 if test "$gl_gcc_warnings" != yes; then
 669   isystem='-I'
 670 else
 671   isystem='-isystem '
 672
 673   # This, $nw, is the list of warnings we disable.
 674   nw=
 675
 676   case $with_x_toolkit in
 677     lucid | athena | motif)
 678        # Old toolkits mishandle 'const'.
 679        nw="$nw -Wwrite-strings"
 680        ;;
 681     *)
 682        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 683        ;;
 684   esac
 685   AC_SUBST([WERROR_CFLAGS])
 686
 687   nw="$nw -Waggregate-return"       # anachronistic
 688   nw="$nw -Wlong-long"              # C90 is anachronistic
 689   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 690   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 691   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 692   nw="$nw -Wcast-qual"              # Too many warnings for now
 693   nw="$nw -Wconversion"             # Too many warnings for now
 694   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 695   nw="$nw -Wsign-conversion"        # Too many warnings for now
 696   nw="$nw -Woverlength-strings"     # Not a problem these days
 697   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 698   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 699   nw="$nw -Wpadded"                 # Our structs are not padded
 700   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 701   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 702   nw="$nw -Wformat-nonliteral"      # we do this a lot
 703   nw="$nw -Wvla"                    # warnings in gettext.h
 704   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 705   nw="$nw -Wswitch-enum"            # Too many warnings for now
 706   nw="$nw -Wswitch-default"         # Too many warnings for now
 707   nw="$nw -Wfloat-equal"            # warns about high-quality code
 708   nw="$nw -Winline"                 # OK to ignore 'inline'
 709   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 710   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 711
 712   # Emacs doesn't care about shadowing; see
 713   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 714   nw="$nw -Wshadow"
 715
 716   # The following lines should be removable at some point.
 717   nw="$nw -Wstack-protector"
 718   nw="$nw -Wstrict-overflow"
 719   nw="$nw -Wsuggest-attribute=pure"
 720
 721   gl_MANYWARN_ALL_GCC([ws])
 722   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 723   for w in $ws; do
 724     gl_WARN_ADD([$w])
 725   done
 726   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 727   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 728   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 729   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 730   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 731   gl_WARN_ADD([-Wno-format-nonliteral])
 732
 733   # In spite of excluding -Wlogical-op above, it is enabled, as of
 734   # gcc 4.5.0 20090517.
 735   gl_WARN_ADD([-Wno-logical-op])
 736
 737   gl_WARN_ADD([-fdiagnostics-show-option])
 738   gl_WARN_ADD([-funit-at-a-time])
 739
 740   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 741   AH_VERBATIM([FORTIFY_SOURCE],
 742   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 743       without upsetting glibc 2.15+. */
 744    #if defined __OPTIMIZE__ && __OPTIMIZE__
 745    # define _FORTIFY_SOURCE 2
 746    #endif
 747   ])
 748   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 749
 750   # We use a slightly smaller set of warning options for lib/.
 751   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 752   nw=
 753   nw="$nw -Wunused-macros"
 754
 755   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 756   AC_SUBST([GNULIB_WARN_CFLAGS])
 757 fi
 758
 759
 760
 761 dnl Some other nice autoconf tests.
 762 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 763 dnl AC_PROG_INSTALL
 764 dnl AC_PROG_MKDIR_P
 765 dnl if test "x$RANLIB" = x; then
 766 dnl   AC_PROG_RANLIB
 767 dnl fi
 768 AC_PROG_LN_S
 769
 770 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 771   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 772 dnl Don't use GZIP, which is used by gzip for additional parameters.
 773 AC_PATH_PROG(GZIP_PROG, gzip)
 774
 775 if test $opsys = gnu-linux; then
 776   AC_PATH_PROG(PAXCTL, paxctl,,
 777     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 778   if test "X$PAXCTL" != X; then
 779     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 780     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 781       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 782       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 783   fi
 784 fi
 785
 786 ## Need makeinfo >= 4.7 (?) to build the manuals.
 787 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 788 dnl By this stage, configure has already checked for egrep and set EGREP,
 789 dnl or exited with an error if no egrep was found.
 790 if test "$MAKEINFO" != "no" && \
 791   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 792    MAKEINFO=no
 793 fi
 794
 795 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 796 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 797 ## therefore in the category of "special tools" not normally required, which
 798 ## configure does not have to check for (eg autoconf itself).
 799 ## In a Bazaar checkout on the other hand, the manuals are not included.
 800 ## So makeinfo is a requirement to build from Bazaar, and configure
 801 ## should test for it as it does for any other build requirement.
 802 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 803 ## with pre-built manuals, from a Bazaar checkout.
 804 HAVE_MAKEINFO=yes
 805
 806 if test "$MAKEINFO" = "no"; then
 807   MAKEINFO=makeinfo
 808   if test "x${with_makeinfo}" = "xno"; then
 809     HAVE_MAKEINFO=no
 810   elif test ! -e $srcdir/info/emacs; then
 811     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 812 source tree does not seem to have pre-built manuals in the `info' directory.
 813 Either install a suitable version of makeinfo, or re-run configure
 814 with the `--without-makeinfo' option to build without the manuals.] )
 815   fi
 816 fi
 817 AC_SUBST(HAVE_MAKEINFO)
 818
 819 dnl Just so that there is only a single place we need to edit.
 820 INFO_EXT=.info
 821 INFO_OPTS=--no-split
 822 AC_SUBST(INFO_EXT)
 823 AC_SUBST(INFO_OPTS)
 824
 825 dnl Add our options to ac_link now, after it is set up.
 826
 827 if test x$GCC = xyes; then
 828   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 829     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 830 else
 831   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 832     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 833 fi
 834
 835 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 836 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 837 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 838 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 839 dnl if not built to support GNU ld.
 840
 841 late_LDFLAGS=$LDFLAGS
 842 if test x$GCC = xyes; then
 843   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 844 else
 845   LDFLAGS="$LDFLAGS -znocombreloc"
 846 fi
 847
 848 AC_MSG_CHECKING([for -znocombreloc])
 849 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 850   [AC_MSG_RESULT(yes)],
 851   LDFLAGS=$late_LDFLAGS
 852   [AC_MSG_RESULT(no)])
 853
 854
 855 dnl The function dump-emacs will not be defined and temacs will do
 856 dnl (load "loadup") automatically unless told otherwise.
 857 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 858 case "$opsys" in
 859   your-opsys-here) CANNOT_DUMP=yes ;;
 860 esac
 861
 862 test "$CANNOT_DUMP" = "yes" && \
 863   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 864
 865 AC_SUBST(CANNOT_DUMP)
 866
 867
 868 UNEXEC_OBJ=unexelf.o
 869 case "$opsys" in
 870   # MSDOS uses unexcoff.o
 871   # MSWindows uses unexw32.o
 872   aix4-2)
 873    UNEXEC_OBJ=unexaix.o
 874    ;;
 875   cygwin)
 876    UNEXEC_OBJ=unexcw.o
 877    ;;
 878   darwin)
 879    UNEXEC_OBJ=unexmacosx.o
 880    ;;
 881   hpux10-20 | hpux11)
 882    UNEXEC_OBJ=unexhp9k800.o
 883    ;;
 884   sol2-10)
 885    # Use the Solaris dldump() function, called from unexsol.c, to dump
 886    # emacs, instead of the generic ELF dump code found in unexelf.c.
 887    # The resulting binary has a complete symbol table, and is better
 888    # for debugging and other observability tools (debuggers, pstack, etc).
 889    #
 890    # If you encounter a problem using dldump(), please consider sending
 891    # a message to the OpenSolaris tools-linking mailing list:
 892    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 893    #
 894    # It is likely that dldump() works with older Solaris too, but this has
 895    # not been tested, so for now this change is for Solaris 10 or newer.
 896    UNEXEC_OBJ=unexsol.o
 897    ;;
 898 esac
 899
 900 LD_SWITCH_SYSTEM=
 901 case "$opsys" in
 902   freebsd)
 903    ## Let `ld' find image libs and similar things in /usr/local/lib.
 904    ## The system compiler, GCC, has apparently been modified to not
 905    ## look there, contrary to what a stock GCC would do.
 906 ### It's not our place to do this.  See bug#10313#17.
 907 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 908       :
 909    ;;
 910
 911   gnu-linux)
 912    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 913    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 914    ;;
 915
 916   netbsd)
 917 ### It's not our place to do this.  See bug#10313#17.
 918 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 919       :
 920    ;;
 921
 922   openbsd)
 923    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 924    ## otherwise Emacs dumps core on elf systems.
 925    LD_SWITCH_SYSTEM="-Z"
 926    ;;
 927 esac
 928 AC_SUBST(LD_SWITCH_SYSTEM)
 929
 930 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 931
 932 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 933 ## which has not been defined yet.  When this was handled with cpp,
 934 ## it was expanded to null when configure sourced the s/*.h file.
 935 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 936 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 937 ## (or somesuch), but because it is supposed to go at the _front_
 938 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 939 ## Compare with the gnu-linux case below, which added to the end
 940 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 941 ## LD_SWITCH_SYSTEM_TEMACS.
 942 case "$opsys" in
 943   netbsd|openbsd)
 944    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 945 esac
 946
 947
 948 C_SWITCH_MACHINE=
 949 case $canonical in
 950  alpha*)
 951   AC_CHECK_DECL([__ELF__])
 952   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 953     ## With ELF, make sure that all common symbols get allocated to in the
 954     ## data section.  Otherwise, the dump of temacs may miss variables in
 955     ## the shared library that have been initialized.  For example, with
 956     ## GNU libc, __malloc_initialized would normally be resolved to the
 957     ## shared library's .bss section, which is fatal.
 958     if test "x$GCC" = "xyes"; then
 959       C_SWITCH_MACHINE="-fno-common"
 960     else
 961       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 962     fi
 963   else
 964     UNEXEC_OBJ=unexalpha.o
 965   fi
 966   ;;
 967 esac
 968 AC_SUBST(C_SWITCH_MACHINE)
 969
 970 AC_SUBST(UNEXEC_OBJ)
 971
 972 C_SWITCH_SYSTEM=
 973 ## Some programs in src produce warnings saying certain subprograms
 974 ## are too complex and need a MAXMEM value greater than 2000 for
 975 ## additional optimization.  --nils@exp-math.uni-essen.de
 976 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 977   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 978 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 979 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 980 AC_SUBST(C_SWITCH_SYSTEM)
 981
 982
 983 LIBS_SYSTEM=
 984 case "$opsys" in
 985   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 986   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 987
 988   freebsd) LIBS_SYSTEM="-lutil" ;;
 989
 990   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 991
 992   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 993
 994   ## Motif needs -lgen.
 995   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 996 esac
 997 AC_SUBST(LIBS_SYSTEM)
 998
 999
1000 ### Make sure subsequent tests use flags consistent with the build flags.
1001
1002 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1003   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1004 else
1005   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1006 fi
1007
1008 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1009 AC_DEFUN([AC_TYPE_SIZE_T])
1010 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1011 AC_DEFUN([AC_TYPE_UID_T])
1012
1013
1014 LIB_MATH=-lm
1015 LIB_STANDARD=
1016 START_FILES=
1017 dnl Current possibilities handled by sed (aix4-2 -> aix,
1018 dnl gnu-linux -> gnu/linux, etc.):
1019 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1020 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1021 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1022
1023 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1024 case $opsys in
1025   cygwin )
1026     LIB_MATH=
1027     START_FILES='pre-crt0.o'
1028     ;;
1029   darwin )
1030     ## Adding -lm confuses the dynamic linker, so omit it.
1031     LIB_MATH=
1032     START_FILES='pre-crt0.o'
1033     ;;
1034   freebsd )
1035     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1036     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1037     SYSTEM_TYPE=berkeley-unix
1038     ;;
1039   gnu-linux | gnu-kfreebsd )
1040     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1041     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1042     ;;
1043   hpux10-20 | hpux11 )
1044     LIB_STANDARD=-lc
1045     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1046     ;;
1047   dnl NB this may be adjusted below.
1048   netbsd | openbsd )
1049     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1050     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1051     SYSTEM_TYPE=berkeley-unix
1052     ;;
1053
1054   sol2* | unixware )
1055     SYSTEM_TYPE=usg-unix-v
1056     ;;
1057
1058 esac
1059
1060 AC_SUBST(LIB_MATH)
1061 AC_SUBST(START_FILES)
1062 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1063   [The type of system you are compiling for; sets `system-type'.])
1064
1065 dnl Not all platforms use crtn.o files.  Check if the current one does.
1066 crt_files=
1067
1068 for file in x $LIB_STANDARD $START_FILES; do
1069   case "$file" in
1070     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1071   esac
1072 done
1073
1074 if test "x$crt_files" != x; then
1075
1076   ## If user specified a crt-dir, use that unconditionally.
1077   crt_gcc=no
1078
1079   if test "X$CRT_DIR" = "X"; then
1080
1081     CRT_DIR=/usr/lib            # default
1082
1083     case "$canonical" in
1084       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1085       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1086       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1087       ## For anything else (eg /usr/lib32), it is up the user to specify
1088       ## the location (bug#5655).
1089       ## Test for crtn.o, not just the directory, because sometimes the
1090       ## directory exists but does not have the relevant files (bug#1287).
1091       ## FIXME better to test for binary compatibility somehow.
1092       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1093       ;;
1094
1095       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1096     esac
1097
1098     case "$opsys" in
1099       hpux10-20) CRT_DIR=/lib ;;
1100     esac
1101
1102     test "x${GCC}" = xyes && crt_gcc=yes
1103
1104   fi                            # CRT_DIR = ""
1105
1106   crt_missing=
1107
1108   for file in $crt_files; do
1109
1110     ## If we're using gcc, try to determine it automatically by asking
1111     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1112     ## system-dependent default from above.]
1113     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1114
1115        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1116        case "$crt_file" in
1117          */*)
1118            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1119            ;;
1120        esac
1121     fi
1122
1123     dnl We expect all the files to be in a single directory, so after the
1124     dnl first there is no point asking gcc.
1125     crt_gcc=no
1126
1127     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1128   done                          # $crt_files
1129
1130   test "x$crt_missing" = x || \
1131     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1132 Try using the --with-crt-dir option.])
1133
1134 fi                              # crt_files != ""
1135
1136 AC_SUBST(CRT_DIR)
1137
1138 case $opsys in
1139   netbsd | openbsd )
1140     if test -f $CRT_DIR/crti.o; then
1141
1142         test -f $CRT_DIR/crtn.o || \
1143           AC_MSG_ERROR([Required file not found: crtn.o])
1144
1145         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1146         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1147     fi
1148     ;;
1149 esac
1150
1151
1152 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1153 pre_PKG_CONFIG_LIBS=$LIBS
1154
1155 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1156
1157 dnl This function definition taken from Gnome 2.0
1158 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1159 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1160 dnl also defines GSTUFF_PKG_ERRORS on error
1161 AC_DEFUN([PKG_CHECK_MODULES], [
1162   succeeded=no
1163
1164   if test "$PKG_CONFIG" = "no" ; then
1165      ifelse([$4], , [AC_MSG_ERROR([
1166       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1167   else
1168      PKG_CONFIG_MIN_VERSION=0.9.0
1169      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1170         AC_MSG_CHECKING(for $2)
1171
1172         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1173            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1174            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1175             edit_cflags="
1176               s,///*,/,g
1177               s/^/ /
1178               s/ -I/ $isystem/g
1179               s/^ //
1180             "
1181             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1182             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1183             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1184             succeeded=yes
1185         else
1186             AC_MSG_RESULT(no)
1187             $1_CFLAGS=""
1188             $1_LIBS=""
1189             ## If we have a custom action on failure, don't print errors, but
1190             ## do set a variable so people can do so.
1191             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1192             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1193         fi
1194
1195         AC_SUBST($1_CFLAGS)
1196         AC_SUBST($1_LIBS)
1197      else
1198         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1199         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1200      fi
1201   fi
1202
1203   if test $succeeded = yes; then
1204      ifelse([$3], , :, [$3])
1205   else
1206      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1207   fi
1208 ])
1209
1210
1211 if test "${with_sound}" != "no"; then
1212   # Sound support for GNU/Linux and the free BSDs.
1213   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1214     have_sound_header=yes)
1215   # Emulation library used on NetBSD.
1216   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1217   AC_SUBST(LIBSOUND)
1218
1219   ALSA_REQUIRED=1.0.0
1220   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1221   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1222   if test $HAVE_ALSA = yes; then
1223     SAVE_CFLAGS="$CFLAGS"
1224     SAVE_LIBS="$LIBS"
1225     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1226     LIBS="$ALSA_LIBS $LIBS"
1227     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1228                     emacs_alsa_normal=yes,
1229                     emacs_alsa_normal=no)
1230     if test "$emacs_alsa_normal" != yes; then
1231       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1232                      [[snd_lib_error_set_handler (0);]])],
1233                      emacs_alsa_subdir=yes,
1234                      emacs_alsa_subdir=no)
1235       if test "$emacs_alsa_subdir" != yes; then
1236         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1237       fi
1238       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1239     fi
1240
1241     CFLAGS="$SAVE_CFLAGS"
1242     LIBS="$SAVE_LIBS"
1243     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1244     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1245     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1246   fi
1247
1248   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1249   dnl compiles only on the specified platforms.  For others, it
1250   dnl probably doesn't make sense to try.
1251   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1252      case "$opsys" in
1253        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1254        gnu-linux|freebsd|netbsd)
1255          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1256          ;;
1257      esac
1258   fi
1259
1260   AC_SUBST(CFLAGS_SOUND)
1261 fi
1262
1263 dnl checks for header files
1264 AC_CHECK_HEADERS_ONCE(
1265   linux/version.h sys/systeminfo.h
1266   stdio_ext.h fcntl.h coff.h pty.h
1267   sys/vlimit.h sys/resource.h
1268   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1269
1270 AC_MSG_CHECKING(if personality LINUX32 can be set)
1271 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1272                emacs_cv_personality_linux32=yes,
1273                emacs_cv_personality_linux32=no)
1274 AC_MSG_RESULT($emacs_cv_personality_linux32)
1275
1276 if test $emacs_cv_personality_linux32 = yes; then
1277   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1278             [Define to 1 if personality LINUX32 can be set.])
1279 fi
1280
1281 dnl On Solaris 8 there's a compilation warning for term.h because
1282 dnl it doesn't define `bool'.
1283 AC_CHECK_HEADERS(term.h, , , -)
1284 AC_HEADER_TIME
1285 AC_CHECK_DECLS([sys_siglist])
1286 if test $ac_cv_have_decl_sys_siglist != yes; then
1287   # For Tru64, at least:
1288   AC_CHECK_DECLS([__sys_siglist])
1289   if test $ac_cv_have_decl___sys_siglist = yes; then
1290     AC_DEFINE(sys_siglist, __sys_siglist,
1291               [Define to any substitute for sys_siglist.])
1292   fi
1293 fi
1294 AC_HEADER_SYS_WAIT
1295
1296 dnl Check for speed_t typedef.
1297 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1298   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1299     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1300 if test $emacs_cv_speed_t = yes; then
1301   AC_DEFINE(HAVE_SPEED_T, 1,
1302            [Define to 1 if `speed_t' is declared by <termios.h>.])
1303 fi
1304
1305 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1306 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1307 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1308   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1309 HAVE_EXCEPTION=$emacs_cv_struct_exception
1310 dnl Define on Darwin so emacs symbols will not conflict with those
1311 dnl in the System framework.  Otherwise -prebind will not work.
1312 if test $emacs_cv_struct_exception != yes || test $opsys = darwin; then
1313   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1314 fi
1315
1316 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1317 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1318 #if HAVE_SYS_SOCKET_H
1319 #include <sys/socket.h>
1320 #endif])
1321 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1322 #if HAVE_SYS_SOCKET_H
1323 #include <sys/socket.h>
1324 #endif])
1325 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1326 #if HAVE_SYS_SOCKET_H
1327 #include <sys/socket.h>
1328 #endif])
1329
1330 dnl checks for structure members
1331 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1332                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1333                   struct ifreq.ifr_addr,
1334                   struct ifreq.ifr_addr.sa_len], , ,
1335                  [AC_INCLUDES_DEFAULT
1336 #if HAVE_SYS_SOCKET_H
1337 #include <sys/socket.h>
1338 #endif
1339 #if HAVE_NET_IF_H
1340 #include <net/if.h>
1341 #endif])
1342
1343 dnl Check for endianness.
1344 dnl AC_C_BIGENDIAN is done by gnulib.
1345
1346 dnl check for Make feature
1347 dnl AC_PROG_MAKE_SET is done by Automake.
1348
1349 DEPFLAGS=
1350 MKDEPDIR=":"
1351 deps_frag=deps.mk
1352 dnl check for GNU Make if we have GCC and autodepend is on.
1353 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1354    AC_MSG_CHECKING([whether we are using GNU Make])
1355    HAVE_GNU_MAKE=no
1356    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1357    if test "x$testval" != x; then
1358       HAVE_GNU_MAKE=yes
1359    else
1360       ac_enable_autodepend=no
1361    fi
1362    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1363    if test $HAVE_GNU_MAKE = yes; then
1364       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1365       SAVE_CFLAGS="$CFLAGS"
1366       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1367       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1368       CFLAGS="$SAVE_CFLAGS"
1369       test -f deps.d || ac_enable_autodepend=no
1370       rm -rf deps.d
1371       AC_MSG_RESULT([$ac_enable_autodepend])
1372    fi
1373    if test $ac_enable_autodepend = yes; then
1374       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1375       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1376       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1377       deps_frag=autodeps.mk
1378    fi
1379 fi
1380 deps_frag=$srcdir/src/$deps_frag
1381 AC_SUBST(MKDEPDIR)
1382 AC_SUBST(DEPFLAGS)
1383 AC_SUBST_FILE(deps_frag)
1384
1385
1386 lisp_frag=$srcdir/src/lisp.mk
1387 AC_SUBST_FILE(lisp_frag)
1388
1389
1390 dnl checks for operating system services
1391 AC_SYS_LONG_FILE_NAMES
1392
1393 #### Choose a window system.
1394
1395 ## We leave window_system equal to none if
1396 ## we end up building without one.  Any new window system should
1397 ## set window_system to an appropriate value and add objects to
1398 ## window-system-specific substs.
1399
1400 window_system=none
1401 AC_PATH_X
1402 if test "$no_x" != yes; then
1403   window_system=x11
1404 fi
1405
1406 LD_SWITCH_X_SITE_RPATH=
1407 if test "${x_libraries}" != NONE; then
1408   if test -n "${x_libraries}"; then
1409     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1410     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1411   fi
1412   x_default_search_path=""
1413   x_search_path=${x_libraries}
1414   if test -z "${x_search_path}"; then
1415     x_search_path=/usr/lib
1416   fi
1417   for x_library in `echo ${x_search_path}: | \
1418                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1419     x_search_path="\
1420 ${x_library}/X11/%L/%T/%N%C%S:\
1421 ${x_library}/X11/%l/%T/%N%C%S:\
1422 ${x_library}/X11/%T/%N%C%S:\
1423 ${x_library}/X11/%L/%T/%N%S:\
1424 ${x_library}/X11/%l/%T/%N%S:\
1425 ${x_library}/X11/%T/%N%S"
1426     if test x"${x_default_search_path}" = x; then
1427       x_default_search_path=${x_search_path}
1428     else
1429       x_default_search_path="${x_search_path}:${x_default_search_path}"
1430     fi
1431   done
1432 fi
1433 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1434
1435 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1436   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1437 fi
1438
1439 if test x"${x_includes}" = x; then
1440   bitmapdir=/usr/include/X11/bitmaps
1441 else
1442   # accumulate include directories that have X11 bitmap subdirectories
1443   bmd_acc="dummyval"
1444   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1445     if test -d "${bmd}/X11/bitmaps"; then
1446       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1447     fi
1448     if test -d "${bmd}/bitmaps"; then
1449       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1450     fi
1451   done
1452   if test ${bmd_acc} != "dummyval"; then
1453     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1454   fi
1455 fi
1456
1457 HAVE_NS=no
1458 NS_IMPL_COCOA=no
1459 NS_IMPL_GNUSTEP=no
1460 tmp_CPPFLAGS="$CPPFLAGS"
1461 tmp_CFLAGS="$CFLAGS"
1462 CPPFLAGS="$CPPFLAGS -x objective-c"
1463 CFLAGS="$CFLAGS -x objective-c"
1464 TEMACS_LDFLAGS2="\${LDFLAGS}"
1465 GNU_OBJC_CFLAGS=
1466 if test "${with_ns}" != no; then
1467   if test "${opsys}" = darwin; then
1468      NS_IMPL_COCOA=yes
1469      ns_appdir=`pwd`/nextstep/Emacs.app
1470      ns_appbindir=${ns_appdir}/Contents/MacOS
1471      ns_appresdir=${ns_appdir}/Contents/Resources
1472      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1473   elif test -f $GNUSTEP_CONFIG_FILE; then
1474      NS_IMPL_GNUSTEP=yes
1475      ns_appdir=`pwd`/nextstep/Emacs.app
1476      ns_appbindir=${ns_appdir}
1477      ns_appresdir=${ns_appdir}/Resources
1478      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1479      dnl FIXME sourcing this several times in subshells seems inefficient.
1480      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1481      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1482      dnl I seemed to need these as well with GNUstep-startup 0.25.
1483      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1484      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1485      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1486        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1487      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1488        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1489      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1490      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1491      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1492      LIB_STANDARD=
1493      START_FILES=
1494      TEMACS_LDFLAGS2=
1495      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1496      dnl If they had chosen to either define it or not, we could have
1497      dnl just used AC_CHECK_DECL here.
1498      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1499        emacs_cv_objc_exceptions,
1500 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1501 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1502 1;
1503 #else
1504 fail;
1505 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1506      if test $emacs_cv_objc_exceptions = yes; then
1507        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1508        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1509          [Define if GNUstep uses ObjC exceptions.])
1510        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1511      fi
1512   fi
1513
1514   dnl This is only used while we test the NS headers, it gets reset below.
1515   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1516
1517   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1518                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1519   files are missing or cannot be compiled.])])
1520   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1521                                      [NSInteger i;])],
1522                     ns_have_nsinteger=yes,
1523                     ns_have_nsinteger=no)
1524   if test $ns_have_nsinteger = yes; then
1525     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1526   fi
1527 fi
1528
1529 AC_SUBST(TEMACS_LDFLAGS2)
1530
1531 INSTALL_ARCH_INDEP_EXTRA=install-etc
1532 ns_self_contained=no
1533 ns_frag=/dev/null
1534 NS_OBJ=
1535 NS_OBJC_OBJ=
1536 if test "${HAVE_NS}" = yes; then
1537   if test "$with_toolkit_scroll_bars" = "no"; then
1538     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1539   fi
1540
1541   window_system=nextstep
1542   # set up packaging dirs
1543   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1544      ns_self_contained=yes
1545      prefix=${ns_appresdir}
1546      exec_prefix=${ns_appbindir}
1547      dnl This one isn't really used, only archlibdir is.
1548      libexecdir="\${ns_appbindir}/libexec"
1549      archlibdir="\${ns_appbindir}/libexec"
1550      docdir="\${ns_appresdir}/etc"
1551      etcdir="\${ns_appresdir}/etc"
1552      dnl FIXME maybe set datarootdir instead.
1553      dnl That would also get applications, icons, man.
1554      infodir="\${ns_appresdir}/info"
1555      mandir="\${ns_appresdir}/man"
1556      lispdir="\${ns_appresdir}/lisp"
1557      leimdir="\${ns_appresdir}/leim"
1558      INSTALL_ARCH_INDEP_EXTRA=
1559   fi
1560   ns_frag=$srcdir/src/ns.mk
1561   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1562 fi
1563 CFLAGS="$tmp_CFLAGS"
1564 CPPFLAGS="$tmp_CPPFLAGS"
1565 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1566 AC_SUBST(ns_self_contained)
1567 AC_SUBST(NS_OBJ)
1568 AC_SUBST(NS_OBJC_OBJ)
1569 AC_SUBST(LIB_STANDARD)
1570 AC_SUBST_FILE(ns_frag)
1571
1572 HAVE_W32=no
1573 W32_OBJ=
1574 W32_LIBS=
1575 if test "${with_w32}" != no; then
1576   if test "${opsys}" != "cygwin"; then
1577     AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin.])
1578   fi
1579   AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1580                   [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1581                   cannot be found.])])
1582   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native Windows GUI.])
1583   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1584   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1585   W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1586   W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1587 fi
1588 AC_SUBST(W32_OBJ)
1589 AC_SUBST(W32_LIBS)
1590
1591 if test "${HAVE_W32}" = "yes"; then
1592   window_system=w32
1593   with_xft=no
1594 fi
1595
1596 ## $window_system is now set to the window system we will
1597 ## ultimately use.
1598
1599 term_header=
1600 HAVE_X_WINDOWS=no
1601 HAVE_X11=no
1602 USE_X_TOOLKIT=none
1603
1604 case "${window_system}" in
1605   x11 )
1606     HAVE_X_WINDOWS=yes
1607     HAVE_X11=yes
1608     term_header=xterm.h
1609     case "${with_x_toolkit}" in
1610       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1611       motif ) USE_X_TOOLKIT=MOTIF ;;
1612       gtk ) with_gtk=yes
1613             term_header=gtkutil.h
1614 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1615 dnl USE_X_TOOLKIT is set.
1616             USE_X_TOOLKIT=none ;;
1617       gtk3 ) with_gtk3=yes
1618              term_header=gtkutil.h
1619              USE_X_TOOLKIT=none ;;
1620       no ) USE_X_TOOLKIT=none ;;
1621 dnl If user did not say whether to use a toolkit, make this decision later:
1622 dnl use the toolkit if we have gtk, or X11R5 or newer.
1623       * ) USE_X_TOOLKIT=maybe ;;
1624     esac
1625   ;;
1626   nextstep )
1627     term_header=nsterm.h
1628   ;;
1629   w32 )
1630     term_header=w32term.h
1631   ;;
1632 esac
1633
1634 if test -n "${term_header}"; then
1635     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
1636         [Define to the header for the built-in window system.])
1637 fi
1638
1639 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1640    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1641    if test "$HAVE_XSERVER" = true ||
1642       test -n "$DISPLAY" ||
1643       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1644         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1645 were found.  You should install the relevant development files for X
1646 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1647 sure you have development files for image handling, i.e.
1648 tiff, gif, jpeg, png and xpm.
1649 If you are sure you want Emacs compiled without X window support, pass
1650   --without-x
1651 to configure.])
1652    fi
1653 fi
1654
1655 ### If we're using X11, we should use the X menu package.
1656 HAVE_MENUS=no
1657 case ${HAVE_X11} in
1658   yes ) HAVE_MENUS=yes ;;
1659 esac
1660
1661 # Does the opsystem file prohibit the use of the GNU malloc?
1662 # Assume not, until told otherwise.
1663 GNU_MALLOC=yes
1664
1665 AC_CACHE_CHECK(
1666   [whether malloc is Doug Lea style],
1667   [emacs_cv_var_doug_lea_malloc],
1668   [AC_LINK_IFELSE(
1669      [AC_LANG_PROGRAM(
1670         [[#include <malloc.h>
1671           static void hook (void) {}]],
1672         [[malloc_set_state (malloc_get_state ());
1673           __after_morecore_hook = hook;
1674           __malloc_initialize_hook = hook;]])],
1675      [emacs_cv_var_doug_lea_malloc=yes],
1676      [emacs_cv_var_doug_lea_malloc=no])])
1677 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1678
1679
1680 dnl See comments in aix4-2.h about maybe using system malloc there.
1681 system_malloc=no
1682 case "$opsys" in
1683   ## darwin ld insists on the use of malloc routines in the System framework.
1684   darwin|sol2-10) system_malloc=yes ;;
1685 esac
1686
1687 if test "${system_malloc}" = "yes"; then
1688   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1689   GNU_MALLOC=no
1690   GNU_MALLOC_reason="
1691     (The GNU allocators don't work with this system configuration.)"
1692   GMALLOC_OBJ=
1693   VMLIMIT_OBJ=
1694 else
1695   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1696   VMLIMIT_OBJ=vm-limit.o
1697 fi
1698 AC_SUBST(GMALLOC_OBJ)
1699 AC_SUBST(VMLIMIT_OBJ)
1700
1701 if test "$doug_lea_malloc" = "yes" ; then
1702   if test "$GNU_MALLOC" = yes ; then
1703     GNU_MALLOC_reason="
1704       (Using Doug Lea's new malloc from the GNU C Library.)"
1705   fi
1706   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1707             [Define to 1 if you are using the GNU C Library.])
1708
1709   ## Use mmap directly for allocating larger buffers.
1710   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1711   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1712   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1713   case "$opsys" in
1714     gnu*) REL_ALLOC=no ;;
1715   esac
1716 fi
1717
1718 if test x"${REL_ALLOC}" = x; then
1719   REL_ALLOC=${GNU_MALLOC}
1720 fi
1721
1722 use_mmap_for_buffers=no
1723 case "$opsys" in
1724   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1725 esac
1726
1727 AC_FUNC_MMAP
1728 if test $use_mmap_for_buffers = yes; then
1729   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1730   REL_ALLOC=no
1731 fi
1732
1733 LIBS="$LIBS_SYSTEM $LIBS"
1734
1735 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1736 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1737 AC_CHECK_LIB(dnet, dnet_ntoa)
1738 dnl This causes -lresolv to get used in subsequent tests,
1739 dnl which causes failures on some systems such as HPUX 9.
1740 dnl AC_CHECK_LIB(resolv, gethostbyname)
1741
1742 dnl FIXME replace main with a function we actually want from this library.
1743 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1744
1745 dnl Check if pthreads is available.
1746 LIB_PTHREAD=
1747 AC_CHECK_HEADERS_ONCE(pthread.h)
1748 if test "$ac_cv_header_pthread_h"; then
1749   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1750   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1751   dnl testing for pthread_self if Emacs uses gmalloc.c.
1752   if test "$GMALLOC_OBJ" = gmalloc.o; then
1753     emacs_pthread_function=pthread_atfork
1754   else
1755     emacs_pthread_function=pthread_self
1756   fi
1757   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1758 fi
1759 if test "$HAVE_PTHREAD" = yes; then
1760   case "${canonical}" in
1761     *-hpux*) ;;
1762     *) LIB_PTHREAD="-lpthread"
1763        LIBS="$LIB_PTHREAD $LIBS" ;;
1764   esac
1765   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1766 fi
1767 AC_SUBST([LIB_PTHREAD])
1768
1769 AC_CHECK_LIB(pthreads, cma_open)
1770
1771 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1772 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1773 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1774 ## added to LIBS in configure would never contain the pthreads part,
1775 ## but the value used in Makefiles might.  FIXME?
1776 ##
1777 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1778 ## be harmless on older versions of X where it happens to exist.
1779 test "$opsys" = "aix4-2" && \
1780   test $ac_cv_lib_pthreads_cma_open = yes && \
1781   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1782
1783 dnl Check for need for bigtoc support on IBM AIX
1784
1785 case ${host_os} in
1786 aix*)
1787   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1788     case $GCC in
1789     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1790     *) gdb_cv_bigtoc=-bbigtoc ;;
1791     esac
1792
1793     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1794     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1795   ])
1796   ;;
1797 esac
1798
1799 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1800 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1801 # REAL_CPPFLAGS later on.
1802
1803 REAL_CFLAGS="$CFLAGS"
1804 REAL_CPPFLAGS="$CPPFLAGS"
1805
1806 if test "${HAVE_X11}" = "yes"; then
1807   DEFS="$C_SWITCH_X_SITE $DEFS"
1808   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1809   LIBS="-lX11 $LIBS"
1810   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1811   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1812
1813   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1814   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1815   # but it's more convenient here to set LD_RUN_PATH since this
1816   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1817   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1818     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1819     export LD_RUN_PATH
1820   fi
1821
1822   if test "${opsys}" = "gnu-linux"; then
1823     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1824     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1825      [[XOpenDisplay ("foo");]])],
1826      [xgnu_linux_first_failure=no],
1827      [xgnu_linux_first_failure=yes])
1828     if test "${xgnu_linux_first_failure}" = "yes"; then
1829       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1830       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1831       OLD_CPPFLAGS="$CPPFLAGS"
1832       OLD_LIBS="$LIBS"
1833       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1834       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1835       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1836       LIBS="$LIBS -b i486-linuxaout"
1837       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1838        [[XOpenDisplay ("foo");]])],
1839        [xgnu_linux_second_failure=no],
1840        [xgnu_linux_second_failure=yes])
1841       if test "${xgnu_linux_second_failure}" = "yes"; then
1842         # If we get the same failure with -b, there is no use adding -b.
1843         # So take it out.  This plays safe.
1844         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1845         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1846         CPPFLAGS="$OLD_CPPFLAGS"
1847         LIBS="$OLD_LIBS"
1848         AC_MSG_RESULT(no)
1849       else
1850         AC_MSG_RESULT(yes)
1851       fi
1852     else
1853       AC_MSG_RESULT(no)
1854     fi
1855   fi
1856
1857   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1858   # header files included from there.
1859   AC_MSG_CHECKING(for Xkb)
1860   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1861 #include <X11/XKBlib.h>]],
1862         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1863         emacs_xkb=yes, emacs_xkb=no)
1864   AC_MSG_RESULT($emacs_xkb)
1865   if test $emacs_xkb = yes; then
1866     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1867   fi
1868
1869   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1870 XScreenNumberOfScreen)
1871 fi
1872
1873 if test "${window_system}" = "x11"; then
1874   AC_MSG_CHECKING(X11 version 6)
1875   AC_CACHE_VAL(emacs_cv_x11_version_6,
1876   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1877 [[#if XlibSpecificationRelease < 6
1878 fail;
1879 #endif
1880 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1881   if test $emacs_cv_x11_version_6 = yes; then
1882     AC_MSG_RESULT(6 or newer)
1883     AC_DEFINE(HAVE_X11R6, 1,
1884               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1885     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1886     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1887     ## XIM support.
1888     case "$opsys" in
1889       sol2-*) : ;;
1890       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1891            [Define if you have usable X11R6-style XIM support.])
1892          ;;
1893     esac
1894   else
1895     AC_MSG_RESULT(before 6)
1896   fi
1897 fi
1898
1899
1900 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1901 HAVE_RSVG=no
1902 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1903   if test "${with_rsvg}" != "no"; then
1904     RSVG_REQUIRED=2.11.0
1905     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1906
1907     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1908     AC_SUBST(RSVG_CFLAGS)
1909     AC_SUBST(RSVG_LIBS)
1910
1911     if test $HAVE_RSVG = yes; then
1912       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1913       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1914       LIBS="$RSVG_LIBS $LIBS"
1915     fi
1916   fi
1917 fi
1918
1919 HAVE_IMAGEMAGICK=no
1920 if test "${HAVE_X11}" = "yes"; then
1921   if test "${with_imagemagick}" != "no"; then
1922     ## 6.2.8 is the earliest version known to work, but earlier versions
1923     ## might work - let us know if you find one.
1924     ## 6.0.7 does not work.  See bug#7955.
1925     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1926     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1927     AC_SUBST(IMAGEMAGICK_CFLAGS)
1928     AC_SUBST(IMAGEMAGICK_LIBS)
1929
1930     if test $HAVE_IMAGEMAGICK = yes; then
1931       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1932       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1933       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1934       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1935     fi
1936   fi
1937 fi
1938
1939
1940 HAVE_GTK=no
1941 GTK_OBJ=
1942 if test "${with_gtk3}" = "yes"; then
1943   GLIB_REQUIRED=2.28
1944   GTK_REQUIRED=3.0
1945   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1946
1947   dnl Checks for libraries.
1948   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1949   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1950      AC_MSG_ERROR($GTK_PKG_ERRORS)
1951   fi
1952   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1953   GTK_OBJ=emacsgtkfixed.o
1954   term_header=gtkutil.h
1955 fi
1956
1957 if test "$pkg_check_gtk" != "yes"; then
1958   HAVE_GTK=no
1959 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1960   GLIB_REQUIRED=2.10
1961   GTK_REQUIRED=2.10
1962   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1963
1964   dnl Checks for libraries.
1965   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1966   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1967      AC_MSG_ERROR($GTK_PKG_ERRORS)
1968   fi
1969 fi
1970 fi
1971
1972 if test x"$pkg_check_gtk" = xyes; then
1973
1974   AC_SUBST(GTK_CFLAGS)
1975   AC_SUBST(GTK_LIBS)
1976   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1977   CFLAGS="$CFLAGS $GTK_CFLAGS"
1978   LIBS="$GTK_LIBS $LIBS"
1979   dnl Try to compile a simple GTK program.
1980   GTK_COMPILES=no
1981   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1982   if test "${GTK_COMPILES}" != "yes"; then
1983     if test "$USE_X_TOOLKIT" != "maybe"; then
1984       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1985     fi
1986   else
1987     HAVE_GTK=yes
1988     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1989     GTK_OBJ="gtkutil.o $GTK_OBJ"
1990     USE_X_TOOLKIT=none
1991     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1992       :
1993     else
1994       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1995        closing open displays.  This is no problem if you just use
1996        one display, but if you use more than one and close one of them
1997        Emacs may crash.]])
1998       sleep 3
1999     fi
2000   fi
2001
2002 fi
2003 AC_SUBST(GTK_OBJ)
2004
2005
2006 if test "${HAVE_GTK}" = "yes"; then
2007
2008   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2009   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2010   if test "$with_toolkit_scroll_bars" != no; then
2011     with_toolkit_scroll_bars=yes
2012   fi
2013
2014   dnl  Check if we have the old file selection dialog declared and
2015   dnl  in the link library.  In 2.x it may be in the library,
2016   dnl  but not declared if deprecated featured has been selected out.
2017   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2018   HAVE_GTK_FILE_SELECTION=no
2019   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2020                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2021 #include <gtk/gtk.h>])
2022   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2023     AC_CHECK_FUNCS(gtk_file_selection_new)
2024   fi
2025
2026
2027   dnl Check for functions introduced in 2.14 and later.
2028   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2029                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2030                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2031                  gtk_orientable_set_orientation \
2032                  gtk_window_set_has_resize_grip)
2033
2034  term_header=gtkutil.h
2035 fi
2036
2037 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2038 dnl other platforms.
2039 HAVE_DBUS=no
2040 DBUS_OBJ=
2041 if test "${with_dbus}" = "yes"; then
2042    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2043    if test "$HAVE_DBUS" = yes; then
2044      LIBS="$LIBS $DBUS_LIBS"
2045      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2046      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2047      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2048      dnl D-Bus 1.5.12.
2049      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2050                     dbus_type_is_valid \
2051                     dbus_validate_bus_name \
2052                     dbus_validate_path \
2053                     dbus_validate_interface \
2054                     dbus_validate_member)
2055      DBUS_OBJ=dbusbind.o
2056    fi
2057 fi
2058 AC_SUBST(DBUS_OBJ)
2059
2060 dnl GSettings has been tested under GNU/Linux only.
2061 HAVE_GSETTINGS=no
2062 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2063    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2064    if test "$HAVE_GSETTINGS" = "yes"; then
2065       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2066       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2067       SETTINGS_LIBS="$GSETTINGS_LIBS"
2068    fi
2069 fi
2070
2071 dnl GConf has been tested under GNU/Linux only.
2072 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2073 HAVE_GCONF=no
2074 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2075    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2076    if test "$HAVE_GCONF" = yes; then
2077       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2078       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2079       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2080       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2081    fi
2082 fi
2083
2084 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2085     SAVE_CFLAGS="$CFLAGS"
2086     SAVE_LIBS="$LIBS"
2087     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2088     LIBS="$SETTINGS_LIBS $LIBS"
2089     AC_CHECK_FUNCS([g_type_init])
2090     CFLAGS="$SAVE_CFLAGS"
2091     LIBS="$SAVE_LIBS"
2092 fi
2093 AC_SUBST(SETTINGS_CFLAGS)
2094 AC_SUBST(SETTINGS_LIBS)
2095
2096
2097 dnl SELinux is available for GNU/Linux only.
2098 HAVE_LIBSELINUX=no
2099 LIBSELINUX_LIBS=
2100 if test "${with_selinux}" = "yes"; then
2101    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2102    if test "$HAVE_LIBSELINUX" = yes; then
2103       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2104       LIBSELINUX_LIBS=-lselinux
2105    fi
2106 fi
2107 AC_SUBST(LIBSELINUX_LIBS)
2108
2109 HAVE_GNUTLS=no
2110 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2111 if test "${with_gnutls}" = "yes" ; then
2112   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2113   if test "${HAVE_GNUTLS}" = "yes"; then
2114     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2115   fi
2116
2117   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2118   LIBS="$LIBGNUTLS_LIBS $LIBS"
2119   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2120
2121   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2122     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2123   fi
2124 fi
2125
2126 AC_SUBST(LIBGNUTLS_LIBS)
2127 AC_SUBST(LIBGNUTLS_CFLAGS)
2128
2129 dnl Do not put whitespace before the #include statements below.
2130 dnl Older compilers (eg sunos4 cc) choke on it.
2131 HAVE_XAW3D=no
2132 LUCID_LIBW=
2133 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2134   if test "$with_xaw3d" != no; then
2135     AC_MSG_CHECKING(for xaw3d)
2136     AC_CACHE_VAL(emacs_cv_xaw3d,
2137     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2138 #include <X11/Intrinsic.h>
2139 #include <X11/Xaw3d/Simple.h>]],
2140       [[]])],
2141       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2142                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2143       emacs_cv_xaw3d=no)])
2144   else
2145     emacs_cv_xaw3d=no
2146   fi
2147   if test $emacs_cv_xaw3d = yes; then
2148     AC_MSG_RESULT([yes; using Lucid toolkit])
2149     USE_X_TOOLKIT=LUCID
2150     HAVE_XAW3D=yes
2151     LUCID_LIBW=-lXaw3d
2152     AC_DEFINE(HAVE_XAW3D, 1,
2153               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2154   else
2155     AC_MSG_RESULT(no)
2156     AC_MSG_CHECKING(for libXaw)
2157     AC_CACHE_VAL(emacs_cv_xaw,
2158     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2159 #include <X11/Intrinsic.h>
2160 #include <X11/Xaw/Simple.h>]],
2161       [[]])],
2162       emacs_cv_xaw=yes,
2163       emacs_cv_xaw=no)])
2164     if test $emacs_cv_xaw = yes; then
2165       AC_MSG_RESULT([yes; using Lucid toolkit])
2166       USE_X_TOOLKIT=LUCID
2167       LUCID_LIBW=-lXaw
2168     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2169       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2170     else
2171       AC_MSG_ERROR([No X toolkit could be found.
2172 If you are sure you want Emacs compiled without an X toolkit, pass
2173   --with-x-toolkit=no
2174 to configure.  Otherwise, install the development libraries for the toolkit
2175 that you want to use (e.g. Gtk+) and re-run configure.])
2176     fi
2177   fi
2178 fi
2179
2180 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2181
2182 LIBXTR6=
2183 if test "${USE_X_TOOLKIT}" != "none"; then
2184   AC_MSG_CHECKING(X11 toolkit version)
2185   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2186   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2187 [[#if XtSpecificationRelease < 6
2188 fail;
2189 #endif
2190 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2191   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2192   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2193     AC_MSG_RESULT(6 or newer)
2194     AC_DEFINE(HAVE_X11XTR6, 1,
2195               [Define to 1 if you have the X11R6 or newer version of Xt.])
2196     LIBXTR6="-lSM -lICE"
2197     case "$opsys" in
2198       ## Use libw.a along with X11R6 Xt.
2199       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2200     esac
2201   else
2202     AC_MSG_RESULT(before 6)
2203   fi
2204
2205 dnl If using toolkit, check whether libXmu.a exists.
2206 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2207   OLDLIBS="$LIBS"
2208   if test x$HAVE_X11XTR6 = xyes; then
2209     LIBS="-lXt -lSM -lICE $LIBS"
2210   else
2211     LIBS="-lXt $LIBS"
2212   fi
2213   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2214   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2215   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2216 fi
2217 AC_SUBST(LIBXTR6)
2218
2219 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2220 dnl Why not just test for libxmu in the normal way?
2221 LIBXMU=-lXmu
2222 case $opsys in
2223   ## These systems don't supply Xmu.
2224   hpux* | aix4-2 )
2225     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2226     ;;
2227 esac
2228 AC_SUBST(LIBXMU)
2229
2230 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2231 if test "${HAVE_X11}" = "yes"; then
2232   if test "${USE_X_TOOLKIT}" != "none"; then
2233     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2234   fi
2235 fi
2236
2237 LIBXP=
2238 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2239   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2240   if test -d /usr/include/openmotif; then
2241     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2242     emacs_cv_openmotif=yes
2243     case "$canonical" in
2244       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2245       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2246       ;;
2247       *)
2248       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2249     esac
2250   else
2251     emacs_cv_openmotif=no
2252   fi
2253   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2254   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2255     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2256 int x = 5;
2257 #else
2258 Motif version prior to 2.1.
2259 #endif]])],
2260     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2261   if test $emacs_cv_motif_version_2_1 = yes; then
2262     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2263     if test x$emacs_cv_openmotif = xyes; then
2264       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2265     fi
2266   else
2267     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2268     # We put this in CFLAGS temporarily to precede other -I options
2269     # that might be in CFLAGS temporarily.
2270     # We put this in CPPFLAGS where it precedes the other -I options.
2271     OLD_CPPFLAGS=$CPPFLAGS
2272     OLD_CFLAGS=$CFLAGS
2273     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2274     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2275     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2276       [[int x = 5;]])],
2277       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2278     if test $emacs_cv_lesstif = yes; then
2279       # Make sure this -I option remains in CPPFLAGS after it is set
2280       # back to REAL_CPPFLAGS.
2281       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2282       # have those other -I options anyway.  Ultimately, having this
2283       # directory ultimately in CPPFLAGS will be enough.
2284       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2285       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2286     else
2287       CFLAGS=$OLD_CFLAGS
2288       CPPFLAGS=$OLD_CPPFLAGS
2289     fi
2290   fi
2291   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2292     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2293 fi
2294
2295 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2296 dnl using Motif or Xaw3d is available, and unless
2297 dnl --with-toolkit-scroll-bars=no was specified.
2298
2299 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2300             [Define to 1 if we should use toolkit scroll bars.])dnl
2301 USE_TOOLKIT_SCROLL_BARS=no
2302 if test "${with_toolkit_scroll_bars}" != "no"; then
2303   if test "${USE_X_TOOLKIT}" != "none"; then
2304     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2305       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2306       HAVE_XAW3D=no
2307       USE_TOOLKIT_SCROLL_BARS=yes
2308     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2309       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2310       USE_TOOLKIT_SCROLL_BARS=yes
2311     fi
2312   elif test "${HAVE_GTK}" = "yes"; then
2313     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2314     USE_TOOLKIT_SCROLL_BARS=yes
2315   elif test "${HAVE_NS}" = "yes"; then
2316     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2317     USE_TOOLKIT_SCROLL_BARS=yes
2318   elif test "${HAVE_W32}" = "yes"; then
2319     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2320     USE_TOOLKIT_SCROLL_BARS=yes
2321   fi
2322 fi
2323
2324 dnl See if XIM is available.
2325 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2326           #include <X11/Xlib.h>
2327           #include <X11/Xresource.h>]],
2328          [[XIMProc  callback;]])],
2329          [HAVE_XIM=yes
2330          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2331          HAVE_XIM=no)
2332
2333 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2334
2335 if test "${with_xim}" != "no"; then
2336   AC_DEFINE(USE_XIM, 1,
2337             [Define to 1 if we should use XIM, if it is available.])
2338 fi
2339
2340
2341 if test "${HAVE_XIM}" != "no"; then
2342   late_CFLAGS=$CFLAGS
2343   if test "$GCC" = yes; then
2344     CFLAGS="$CFLAGS --pedantic-errors"
2345   fi
2346   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2347 #include <X11/Xlib.h>
2348 #include <X11/Xresource.h>]],
2349 [[Display *display;
2350 XrmDatabase db;
2351 char *res_name;
2352 char *res_class;
2353 XIMProc  callback;
2354 XPointer *client_data;
2355 #ifndef __GNUC__
2356 /* If we're not using GCC, it's probably not XFree86, and this is
2357    probably right, but we can't use something like --pedantic-errors.  */
2358 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2359                                            char*, XIMProc, XPointer*);
2360 #endif
2361 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2362    client_data);]])],
2363     [emacs_cv_arg6_star=yes])
2364   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2365          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2366 either XPointer or XPointer*.])dnl
2367   if test "$emacs_cv_arg6_star" = yes; then
2368     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2369   else
2370     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2371   fi
2372   CFLAGS=$late_CFLAGS
2373 fi
2374
2375 ### Start of font-backend (under any platform) section.
2376 # (nothing here yet -- this is a placeholder)
2377 ### End of font-backend (under any platform) section.
2378
2379 ### Start of font-backend (under X11) section.
2380 if test "${HAVE_X11}" = "yes"; then
2381    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2382
2383    ## Use -lXft if available, unless `--with-xft=no'.
2384    HAVE_XFT=maybe
2385     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2386       with_xft="no";
2387     fi
2388     if test "x${with_xft}" != "xno"; then
2389
2390       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2391       ## Because xftfont.c uses XRenderQueryExtension, we also
2392       ## need to link to -lXrender.
2393       HAVE_XRENDER=no
2394       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2395       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2396         OLD_CPPFLAGS="$CPPFLAGS"
2397         OLD_CFLAGS="$CFLAGS"
2398         OLD_LIBS="$LIBS"
2399         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2400         CFLAGS="$CFLAGS $XFT_CFLAGS"
2401         XFT_LIBS="-lXrender $XFT_LIBS"
2402         LIBS="$XFT_LIBS $LIBS"
2403         AC_CHECK_HEADER(X11/Xft/Xft.h,
2404           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2405
2406         if test "${HAVE_XFT}" = "yes"; then
2407           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2408             AC_SUBST(XFT_LIBS)
2409           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2410         else
2411           CPPFLAGS="$OLD_CPPFLAGS"
2412           CFLAGS="$OLD_CFLAGS"
2413           LIBS="$OLD_LIBS"
2414         fi                        # "${HAVE_XFT}" = "yes"
2415       fi                          # "$HAVE_XFT" != no
2416     fi                            # "x${with_xft}" != "xno"
2417
2418     ## We used to allow building with FreeType and without Xft.
2419     ## However, the ftx font backend driver is not in good shape.
2420     if test "$HAVE_XFT" != "yes"; then
2421        dnl For the "Does Emacs use" message at the end.
2422        HAVE_XFT=no
2423        HAVE_FREETYPE=no
2424     else
2425        dnl Strict linkers fail with
2426        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2427        dnl if -lfreetype is not specified.
2428        dnl The following is needed to set FREETYPE_LIBS.
2429        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2430                          HAVE_FREETYPE=no)
2431
2432        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2433     fi
2434
2435     HAVE_LIBOTF=no
2436     if test "${HAVE_FREETYPE}" = "yes"; then
2437       AC_DEFINE(HAVE_FREETYPE, 1,
2438                 [Define to 1 if using the freetype and fontconfig libraries.])
2439       if test "${with_libotf}" != "no"; then
2440         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2441                           HAVE_LIBOTF=no)
2442         if test "$HAVE_LIBOTF" = "yes"; then
2443           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2444           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2445                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2446                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2447           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2448             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2449                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2450           fi
2451         fi
2452       fi
2453     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2454     dnl Does the new font backend require it, or can it work without it?
2455     fi
2456
2457     HAVE_M17N_FLT=no
2458     if test "${HAVE_LIBOTF}" = yes; then
2459       if test "${with_m17n_flt}" != "no"; then
2460         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2461         if test "$HAVE_M17N_FLT" = "yes"; then
2462           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2463         fi
2464       fi
2465     fi
2466 else
2467     HAVE_XFT=no
2468     HAVE_FREETYPE=no
2469     HAVE_LIBOTF=no
2470     HAVE_M17N_FLT=no
2471 fi
2472
2473 ### End of font-backend (under X11) section.
2474
2475 AC_SUBST(FREETYPE_CFLAGS)
2476 AC_SUBST(FREETYPE_LIBS)
2477 AC_SUBST(FONTCONFIG_CFLAGS)
2478 AC_SUBST(FONTCONFIG_LIBS)
2479 AC_SUBST(LIBOTF_CFLAGS)
2480 AC_SUBST(LIBOTF_LIBS)
2481 AC_SUBST(M17N_FLT_CFLAGS)
2482 AC_SUBST(M17N_FLT_LIBS)
2483
2484 ### Use -lXpm if available, unless `--with-xpm=no'.
2485 HAVE_XPM=no
2486 LIBXPM=
2487
2488 if test "${HAVE_W32}" = "yes"; then
2489   if test "${with_xpm}" != "no"; then
2490     SAVE_CPPFLAGS="$CPPFLAGS"
2491     SAVE_LDFLAGS="$LDFLAGS"
2492     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2493     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2494     AC_CHECK_HEADER(X11/xpm.h,
2495       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2496     if test "${HAVE_XPM}" = "yes"; then
2497       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2498       AC_EGREP_CPP(no_return_alloc_pixels,
2499       [#include "X11/xpm.h"
2500 #ifndef XpmReturnAllocPixels
2501 no_return_alloc_pixels
2502 #endif
2503       ], HAVE_XPM=no, HAVE_XPM=yes)
2504
2505       if test "${HAVE_XPM}" = "yes"; then
2506         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2507         AC_MSG_RESULT(yes)
2508       else
2509         AC_MSG_RESULT(no)
2510         CPPFLAGS="$SAVE_CPPFLAGS"
2511         LDFLAGS="$SAVE_LDFLAGS"
2512       fi
2513     fi
2514   fi
2515
2516   if test "${HAVE_XPM}" = "yes"; then
2517     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2518     LIBXPM=-lXpm
2519   fi
2520 fi
2521
2522 if test "${HAVE_X11}" = "yes"; then
2523   if test "${with_xpm}" != "no"; then
2524     AC_CHECK_HEADER(X11/xpm.h,
2525       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2526     if test "${HAVE_XPM}" = "yes"; then
2527       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2528       AC_EGREP_CPP(no_return_alloc_pixels,
2529       [#include "X11/xpm.h"
2530 #ifndef XpmReturnAllocPixels
2531 no_return_alloc_pixels
2532 #endif
2533       ], HAVE_XPM=no, HAVE_XPM=yes)
2534
2535       if test "${HAVE_XPM}" = "yes"; then
2536         AC_MSG_RESULT(yes)
2537       else
2538         AC_MSG_RESULT(no)
2539       fi
2540     fi
2541   fi
2542
2543   if test "${HAVE_XPM}" = "yes"; then
2544     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2545     LIBXPM=-lXpm
2546   fi
2547 fi
2548
2549 AC_SUBST(LIBXPM)
2550
2551 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2552 HAVE_JPEG=no
2553 LIBJPEG=
2554 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2555   if test "${with_jpeg}" != "no"; then
2556     dnl Checking for jpeglib.h can lose because of a redefinition of
2557     dnl  HAVE_STDLIB_H.
2558     AC_CHECK_HEADER(jerror.h,
2559       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2560   fi
2561
2562   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2563   if test "${HAVE_JPEG}" = "yes"; then
2564     AC_DEFINE(HAVE_JPEG)
2565     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2566         [#include <jpeglib.h>
2567          version=JPEG_LIB_VERSION
2568 ],
2569         [AC_DEFINE(HAVE_JPEG)],
2570         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2571         HAVE_JPEG=no])
2572   fi
2573   if test "${HAVE_JPEG}" = "yes"; then
2574     LIBJPEG=-ljpeg
2575   fi
2576 fi
2577 AC_SUBST(LIBJPEG)
2578
2579 ### Use -lpng if available, unless `--with-png=no'.
2580 HAVE_PNG=no
2581 LIBPNG=
2582 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2583   if test "${with_png}" != "no"; then
2584     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2585     # in /usr/include/libpng.
2586     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2587     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2588       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2589     fi
2590   fi
2591
2592   if test "${HAVE_PNG}" = "yes"; then
2593     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2594     LIBPNG="-lpng -lz -lm"
2595
2596     AC_CHECK_DECL(png_longjmp,
2597       [],
2598       [AC_DEFINE(PNG_DEPSTRUCT, [],
2599          [Define to empty to suppress deprecation warnings when building
2600           with --enable-gcc-warnings and with libpng versions before 1.5,
2601           which lack png_longjmp.])],
2602       [[#ifdef HAVE_LIBPNG_PNG_H
2603         # include <libpng/png.h>
2604         #else
2605         # include <png.h>
2606         #endif
2607       ]])
2608   fi
2609 fi
2610 AC_SUBST(LIBPNG)
2611
2612 ### Use -ltiff if available, unless `--with-tiff=no'.
2613 HAVE_TIFF=no
2614 LIBTIFF=
2615 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2616   if test "${with_tiff}" != "no"; then
2617     AC_CHECK_HEADER(tiffio.h,
2618       [tifflibs="-lz -lm"
2619       # At least one tiff package requires the jpeg library.
2620       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2621       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2622   fi
2623
2624   if test "${HAVE_TIFF}" = "yes"; then
2625     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2626     dnl FIXME -lz -lm, as per libpng?
2627     LIBTIFF=-ltiff
2628   fi
2629 fi
2630 AC_SUBST(LIBTIFF)
2631
2632 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2633 HAVE_GIF=no
2634 LIBGIF=
2635 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
2636         || test "${HAVE_W32}" = "yes"; then
2637   AC_CHECK_HEADER(gif_lib.h,
2638 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2639 # Earlier versions can crash Emacs.
2640     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2641
2642   if test "$HAVE_GIF" = yes; then
2643     LIBGIF=-lgif
2644   elif test "$HAVE_GIF" = maybe; then
2645 # If gif_lib.h but no libgif, try libungif.
2646     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2647     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2648   fi
2649
2650   if test "${HAVE_GIF}" = "yes"; then
2651     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2652   fi
2653 fi
2654 AC_SUBST(LIBGIF)
2655
2656 dnl Check for required libraries.
2657 if test "${HAVE_X11}" = "yes"; then
2658   MISSING=""
2659   WITH_NO=""
2660   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2661     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2662   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2663     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2664   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2665     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2666   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2667     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2668   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2669     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2670
2671   if test "X${MISSING}" != X; then
2672     AC_MSG_ERROR([The following required libraries were not found:
2673     $MISSING
2674 Maybe some development libraries/packages are missing?
2675 If you don't want to link with them give
2676     $WITH_NO
2677 as options to configure])
2678   fi
2679 fi
2680
2681 ### Use -lgpm if available, unless `--with-gpm=no'.
2682 HAVE_GPM=no
2683 LIBGPM=
2684 if test "${with_gpm}" != "no"; then
2685   AC_CHECK_HEADER(gpm.h,
2686     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2687
2688   if test "${HAVE_GPM}" = "yes"; then
2689     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2690     LIBGPM=-lgpm
2691   fi
2692 fi
2693 AC_SUBST(LIBGPM)
2694
2695 dnl Check for malloc/malloc.h on darwin
2696 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2697
2698 GNUSTEP_CFLAGS=
2699 ### Use NeXTstep API to implement GUI.
2700 if test "${HAVE_NS}" = "yes"; then
2701   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2702   if test "${NS_IMPL_COCOA}" = "yes"; then
2703     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2704   fi
2705   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2706     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2707     # See also .m.o rule in Makefile.in */
2708     # FIXME: are all these flags really needed?  Document here why.  */
2709     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2710     ## Extra CFLAGS applied to src/*.m files.
2711     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2712   fi
2713   # We also have mouse menus.
2714   HAVE_MENUS=yes
2715   OTHER_FILES=ns-app
2716 fi
2717
2718 if test "${HAVE_W32}" = "yes"; then
2719   HAVE_MENUS=yes
2720 fi
2721
2722 ### Use session management (-lSM -lICE) if available
2723 HAVE_X_SM=no
2724 LIBXSM=
2725 if test "${HAVE_X11}" = "yes"; then
2726   AC_CHECK_HEADER(X11/SM/SMlib.h,
2727     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2728
2729   if test "${HAVE_X_SM}" = "yes"; then
2730     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2731     LIBXSM="-lSM -lICE"
2732     case "$LIBS" in
2733       *-lSM*) ;;
2734       *)      LIBS="$LIBXSM $LIBS" ;;
2735     esac
2736   fi
2737 fi
2738 AC_SUBST(LIBXSM)
2739
2740 ### Use libxml (-lxml2) if available
2741 HAVE_LIBXML2=no
2742 if test "${with_xml2}" != "no"; then
2743   ### I'm not sure what the version number should be, so I just guessed.
2744   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2745   if test "${HAVE_LIBXML2}" = "yes"; then
2746     LIBS="$LIBXML2_LIBS $LIBS"
2747     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2748     if test "${HAVE_LIBXML2}" = "yes"; then
2749       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2750     else
2751       LIBXML2_LIBS=""
2752       LIBXML2_CFLAGS=""
2753     fi
2754   fi
2755 fi
2756 AC_SUBST(LIBXML2_LIBS)
2757 AC_SUBST(LIBXML2_CFLAGS)
2758
2759 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2760 AC_CACHE_CHECK(whether netdb declares h_errno,
2761                emacs_cv_netdb_declares_h_errno,
2762 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2763   [[return h_errno;]])],
2764   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2765 if test $emacs_cv_netdb_declares_h_errno = yes; then
2766   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2767 fi
2768
2769 # fmod, logb, and frexp are found in -lm on most systems.
2770 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2771 AC_CHECK_LIB(m, sqrt)
2772
2773 # Check for mail-locking functions in a "mail" library.  Probably this should
2774 # have the same check as for liblockfile below.
2775 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2776 if test $have_mail = yes; then
2777   LIBS_MAIL=-lmail
2778   LIBS="$LIBS_MAIL $LIBS"
2779   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2780 else
2781   LIBS_MAIL=
2782 fi
2783 dnl Debian, at least:
2784 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2785 if test $have_lockfile = yes; then
2786    LIBS_MAIL=-llockfile
2787    LIBS="$LIBS_MAIL $LIBS"
2788    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2789 else
2790 # If we have the shared liblockfile, assume we must use it for mail
2791 # locking (e.g. Debian).  If we couldn't link against liblockfile
2792 # (no liblockfile.a installed), ensure that we don't need to.
2793   dnl This works for files generally, not just executables.
2794   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2795   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2796                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2797   if test $ac_cv_prog_liblockfile = yes; then
2798     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2799 This probably means that movemail could lose mail.
2800 There may be a `development' package to install containing liblockfile.])
2801   fi
2802 fi
2803 AC_CHECK_HEADERS_ONCE(maillock.h)
2804 AC_SUBST(LIBS_MAIL)
2805
2806 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2807 ## interlock access to the mail spool.  The alternative is a lock file named
2808 ## /usr/spool/mail/$USER.lock.
2809 mail_lock=no
2810 case "$opsys" in
2811   aix4-2) mail_lock="lockf" ;;
2812
2813   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2814
2815   ## On GNU/Linux systems, both methods are used by various mail programs.
2816   ## I assume most people are using newer mailers that have heard of flock.
2817   ## Change this if you need to.
2818   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2819   ## configure gets the right answers, and that means *NOT* using flock.
2820   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2821   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2822   ## Debian maintainer hasn't provided a clean fix for Emacs.
2823   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2824   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2825   ## correct logic.  -- fx
2826   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2827   ## liblockfile is a Free Software replacement for libmail, used on
2828   ## Debian systems and elsewhere. -rfr.
2829   gnu-*)
2830     mail_lock="flock"
2831     if test $have_mail = yes || test $have_lockfile = yes; then
2832       test $ac_cv_header_maillock_h = yes && mail_lock=no
2833     fi
2834     ;;
2835 esac
2836
2837 BLESSMAIL_TARGET=
2838 case "$mail_lock" in
2839   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2840
2841   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2842
2843   *) BLESSMAIL_TARGET="need-blessmail" ;;
2844 esac
2845 AC_SUBST(BLESSMAIL_TARGET)
2846
2847
2848 AC_CHECK_FUNCS(gethostname \
2849 closedir getrusage get_current_dir_name \
2850 lrand48 logb frexp fmod cbrt setsid \
2851 fpathconf select euidaccess getpagesize setlocale \
2852 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2853 __fpending strsignal setitimer \
2854 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2855 gai_strerror mkstemp getline getdelim fsync sync \
2856 difftime posix_memalign \
2857 getpwent endpwent getgrent endgrent \
2858 touchlock \
2859 cfmakeraw cfsetspeed copysign __executable_start)
2860
2861 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2862 if test $opsys = unixware; then
2863   dnl In case some other test ends up checking for getwd.
2864   AC_DEFINE(BROKEN_GETWD, 1, [Define if getwd should not be used.])
2865 else
2866   AC_CHECK_FUNCS(getwd)
2867 fi
2868
2869 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2870 ## has a broken `rint' in some library versions including math library
2871 ## version number A.09.05.
2872 ## You can fix the math library by installing patch number PHSS_4630.
2873 ## But we can fix it more reliably for Emacs by just not using rint.
2874 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2875 case $opsys in
2876    hpux*) : ;;
2877    *) AC_CHECK_FUNCS(random rint) ;;
2878 esac
2879
2880 dnl Cannot use AC_CHECK_FUNCS
2881 AC_CACHE_CHECK([for __builtin_unwind_init],
2882                emacs_cv_func___builtin_unwind_init,
2883 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2884                 emacs_cv_func___builtin_unwind_init=yes,
2885                 emacs_cv_func___builtin_unwind_init=no)])
2886 if test $emacs_cv_func___builtin_unwind_init = yes; then
2887   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2888             [Define to 1 if you have the `__builtin_unwind_init' function.])
2889 fi
2890
2891 AC_CHECK_HEADERS_ONCE(sys/un.h)
2892
2893 AC_FUNC_FSEEKO
2894
2895 AC_FUNC_GETPGRP
2896
2897 # UNIX98 PTYs.
2898 AC_CHECK_FUNCS(grantpt)
2899
2900 # PTY-related GNU extensions.
2901 AC_CHECK_FUNCS(getpt posix_openpt)
2902
2903 # Check this now, so that we will NOT find the above functions in ncurses.
2904 # That is because we have not set up to link ncurses in lib-src.
2905 # It's better to believe a function is not available
2906 # than to expect to find it in ncurses.
2907 # Also we need tputs and friends to be able to build at all.
2908 AC_MSG_CHECKING([for library containing tputs])
2909 # Run a test program that contains a call to tputs, a call that is
2910 # never executed.  This tests whether a pre-'main' dynamic linker
2911 # works with the library.  It's too much trouble to actually call
2912 # tputs in the test program, due to portability hassles.  When
2913 # cross-compiling, assume the test program will run if it links.
2914 AC_DEFUN([tputs_link_source], [
2915   AC_LANG_SOURCE(
2916      [[extern void tputs (const char *, int, int (*)(int));
2917        int main (int argc, char **argv)
2918        {
2919           if (argc == 10000)
2920             tputs (argv[0], 0, 0);
2921           return 0;
2922        }]])
2923 ])
2924 # Maybe curses should be tried earlier?
2925 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2926 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2927   OLIBS=$LIBS
2928   if test -z "$tputs_library"; then
2929     LIBS_TERMCAP=
2930     msg='none required'
2931   else
2932     LIBS_TERMCAP=-l$tputs_library
2933     msg=$LIBS_TERMCAP
2934     LIBS="$LIBS_TERMCAP $LIBS"
2935   fi
2936   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2937     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2938   LIBS=$OLIBS
2939   if test "X$msg" != Xno; then
2940     break
2941   fi
2942 done
2943 AC_MSG_RESULT([$msg])
2944 if test "X$msg" = Xno; then
2945   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2946 The following libraries were tried (in order):
2947   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2948 Please try installing whichever of these libraries is most appropriate
2949 for your system, together with its header files.
2950 For example, a libncurses-dev(el) or similar package.])
2951 fi
2952
2953 ## Use termcap instead of terminfo?
2954 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2955 TERMINFO=yes
2956 ## FIXME?  In the cases below where we unconditionally set
2957 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2958 ## if that was found above to have tputs.
2959 ## Should we use the gnu* logic everywhere?
2960 case "$opsys" in
2961   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2962   ##  The ncurses library has been moved out of the System framework in
2963   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2964   ##  option to use it.
2965   darwin) LIBS_TERMCAP="-lncurses" ;;
2966
2967   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2968
2969   freebsd)
2970     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2971     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2972     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2973 [[#if __FreeBSD_version < 400000
2974 fail;
2975 #endif
2976 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2977
2978     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2979
2980     if test $emacs_cv_freebsd_terminfo = yes; then
2981       LIBS_TERMCAP="-lncurses"
2982     else
2983       TERMINFO=no
2984       LIBS_TERMCAP="-ltermcap"
2985     fi
2986     ;;
2987
2988   netbsd)
2989     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2990       TERMINFO=no
2991       LIBS_TERMCAP="-ltermcap"
2992     fi
2993     ;;
2994
2995   openbsd) LIBS_TERMCAP="-lncurses" ;;
2996
2997   ## hpux: Make sure we get select from libc rather than from libcurses
2998   ##  because libcurses on HPUX 10.10 has a broken version of select.
2999   ##  We used to use -lc -lcurses, but this may be cleaner.
3000   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3001   # set that way, now it uses the default).  Isn't this a contradiction?
3002   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3003
3004 esac
3005
3006 TERMCAP_OBJ=tparam.o
3007 if test $TERMINFO = yes; then
3008   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3009   TERMCAP_OBJ=terminfo.o
3010 fi
3011 AC_SUBST(LIBS_TERMCAP)
3012 AC_SUBST(TERMCAP_OBJ)
3013
3014
3015 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3016 # On Darwin, res_init appears not to be useful: see bug#562 and
3017 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3018 resolv=no
3019
3020 if test $opsys != darwin; then
3021
3022   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3023 #include <arpa/nameser.h>
3024 #include <resolv.h>]],
3025     [[return res_init();]])],
3026     have_res_init=yes, have_res_init=no)
3027   if test "$have_res_init" = no; then
3028     OLIBS="$LIBS"
3029     LIBS="$LIBS -lresolv"
3030     AC_MSG_CHECKING(for res_init with -lresolv)
3031     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3032 #include <arpa/nameser.h>
3033 #include <resolv.h>]],
3034       [[return res_init();]])],
3035       have_res_init=yes, have_res_init=no)
3036     AC_MSG_RESULT($have_res_init)
3037     if test "$have_res_init" = yes ; then
3038       resolv=yes
3039     fi
3040     LIBS="$OLIBS"
3041   fi
3042
3043   if test "$have_res_init" = yes; then
3044     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3045   fi
3046 fi                              dnl !darwin
3047
3048 # Do we need the Hesiod library to provide the support routines?
3049 dnl FIXME?  Should we be skipping this on Darwin too?
3050 LIBHESIOD=
3051 if test "$with_hesiod" != no ; then
3052   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3053   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3054      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3055                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3056   if test "$resolv" = yes ; then
3057     RESOLVLIB=-lresolv
3058   else
3059     RESOLVLIB=
3060   fi
3061   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3062         hesiod=yes, :, $RESOLVLIB)])
3063
3064   if test x"$hesiod" = xyes; then
3065     AC_DEFINE(HAVE_LIBHESIOD, 1,
3066               [Define to 1 if you have the hesiod library (-lhesiod).])
3067     LIBHESIOD=-lhesiod
3068   fi
3069 fi
3070 AC_SUBST(LIBHESIOD)
3071
3072 # Do we need libresolv (due to res_init or Hesiod)?
3073 if test "$resolv" = yes && test $opsys != darwin; then
3074   AC_DEFINE(HAVE_LIBRESOLV, 1,
3075             [Define to 1 if you have the resolv library (-lresolv).])
3076   LIBRESOLV=-lresolv
3077 else
3078   LIBRESOLV=
3079 fi
3080 AC_SUBST(LIBRESOLV)
3081
3082 # These tell us which Kerberos-related libraries to use.
3083 COM_ERRLIB=
3084 CRYPTOLIB=
3085 KRB5LIB=
3086 DESLIB=
3087 KRB4LIB=
3088
3089 if test "${with_kerberos}" != no; then
3090   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3091   if test $have_com_err = yes; then
3092     COM_ERRLIB=-lcom_err
3093     LIBS="$COM_ERRLIB $LIBS"
3094     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3095   fi
3096   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3097   if test $have_crypto = yes; then
3098     CRYPTOLIB=-lcrypto
3099     LIBS="$CRYPTOLIB $LIBS"
3100     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3101   fi
3102   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3103   if test $have_k5crypto = yes; then
3104     CRYPTOLIB=-lk5crypto
3105     LIBS="$CRYPTOLIB $LIBS"
3106     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3107   fi
3108   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3109   if test $have_krb5=yes; then
3110     KRB5LIB=-lkrb5
3111     LIBS="$KRB5LIB $LIBS"
3112     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3113   fi
3114   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3115   if test "${with_kerberos5}" = no; then
3116     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3117     if test $have_des425 = yes; then
3118       DESLIB=-ldes425
3119       LIBS="$DESLIB $LIBS"
3120       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3121     else
3122       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3123       if test $have_des = yes; then
3124         DESLIB=-ldes
3125         LIBS="$DESLIB $LIBS"
3126         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3127       fi
3128     fi
3129     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3130     if test $have_krb4 = yes; then
3131       KRB4LIB=-lkrb4
3132       LIBS="$KRB4LIB $LIBS"
3133       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3134     else
3135       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3136       if test $have_krb = yes; then
3137         KRB4LIB=-lkrb
3138         LIBS="$KRB4LIB $LIBS"
3139         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3140       fi
3141     fi
3142   fi
3143
3144   if test "${with_kerberos5}" != no; then
3145     AC_CHECK_HEADERS(krb5.h,
3146       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3147                         [#include <krb5.h>])])
3148   else
3149     AC_CHECK_HEADERS(des.h,,
3150                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3151                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3152     AC_CHECK_HEADERS(krb.h,,
3153                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3154                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3155   fi
3156   AC_CHECK_HEADERS(com_err.h)
3157 fi
3158
3159 AC_SUBST(COM_ERRLIB)
3160 AC_SUBST(CRYPTOLIB)
3161 AC_SUBST(KRB5LIB)
3162 AC_SUBST(DESLIB)
3163 AC_SUBST(KRB4LIB)
3164
3165 AC_CHECK_FUNCS_ONCE(tzset)
3166 AC_MSG_CHECKING(whether localtime caches TZ)
3167 AC_CACHE_VAL(emacs_cv_localtime_cache,
3168 [if test x$ac_cv_func_tzset = xyes; then
3169 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3170 char TZ_GMT0[] = "TZ=GMT0";
3171 char TZ_PST8[] = "TZ=PST8";
3172 main()
3173 {
3174   time_t now = time ((time_t *) 0);
3175   int hour_GMT0, hour_unset;
3176   if (putenv (TZ_GMT0) != 0)
3177     exit (1);
3178   hour_GMT0 = localtime (&now)->tm_hour;
3179   unsetenv("TZ");
3180   hour_unset = localtime (&now)->tm_hour;
3181   if (putenv (TZ_PST8) != 0)
3182     exit (1);
3183   if (localtime (&now)->tm_hour == hour_GMT0)
3184     exit (1);
3185   unsetenv("TZ");
3186   if (localtime (&now)->tm_hour != hour_unset)
3187     exit (1);
3188   exit (0);
3189 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3190 [# If we have tzset, assume the worst when cross-compiling.
3191 emacs_cv_localtime_cache=yes])
3192 else
3193         # If we lack tzset, report that localtime does not cache TZ,
3194         # since we can't invalidate the cache if we don't have tzset.
3195         emacs_cv_localtime_cache=no
3196 fi])dnl
3197 AC_MSG_RESULT($emacs_cv_localtime_cache)
3198 if test $emacs_cv_localtime_cache = yes; then
3199   AC_DEFINE(LOCALTIME_CACHE, 1,
3200             [Define to 1 if localtime caches TZ.])
3201 fi
3202
3203 ok_so_far=yes
3204 AC_CHECK_FUNC(socket, , ok_so_far=no)
3205 if test $ok_so_far = yes; then
3206   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3207 fi
3208 if test $ok_so_far = yes; then
3209   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3210 fi
3211 if test $ok_so_far = yes; then
3212 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3213   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3214             [Define to 1 if you have inet sockets.])
3215 fi
3216
3217 if test -f /usr/lpp/X11/bin/smt.exp; then
3218   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3219             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3220 fi
3221
3222 AC_MSG_CHECKING(whether system supports dynamic ptys)
3223 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3224   AC_MSG_RESULT(yes)
3225   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3226 else
3227   AC_MSG_RESULT(no)
3228 fi
3229
3230 AC_FUNC_FORK
3231
3232 AC_CHECK_FUNCS(snprintf)
3233
3234 dnl Adapted from Haible's version.
3235 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3236   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3237     [[char* cs = nl_langinfo(CODESET);]])],
3238     emacs_cv_langinfo_codeset=yes,
3239     emacs_cv_langinfo_codeset=no)
3240   ])
3241 if test $emacs_cv_langinfo_codeset = yes; then
3242   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3243     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3244 fi
3245
3246 AC_TYPE_MBSTATE_T
3247
3248 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3249   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3250                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3251 if test "$emacs_cv_c_restrict_arr" = yes; then
3252   AC_DEFINE(__restrict_arr, __restrict,
3253     [Define to compiler's equivalent of C99 restrict keyword in array
3254      declarations.  Define as empty for no equivalent.])
3255 fi
3256
3257 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3258 dnl how the tty code is related to POSIX and/or other versions of termios.
3259 dnl The following looks like a useful start.
3260 dnl
3261 dnl AC_SYS_POSIX_TERMIOS
3262 dnl if test $ac_cv_sys_posix_termios = yes; then
3263 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3264 dnl                                and macros for terminal control.])
3265 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3266 dnl fi
3267
3268 dnl Turned on June 1996 supposing nobody will mind it.
3269 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3270   in the full name stands for the login id.])
3271
3272 dnl Every platform that uses configure (ie every non-MS platform)
3273 dnl supports this.  There is a create-lockfiles option you can
3274 dnl customize if you do not want the lock files to be written.
3275 dnl So it is not clear that this #define still needs to exist.
3276 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3277   so that Emacs can tell instantly when you try to modify a file that
3278   someone else has modified in his/her Emacs.])
3279
3280 AH_TEMPLATE(FLOAT_CHECK_DOMAIN, [Define if the float library doesn't
3281   handle errors by either setting errno, or signaling SIGFPE/SIGILL.])
3282
3283 AH_TEMPLATE(HAVE_INVERSE_HYPERBOLIC, [Define if you have the functions
3284   acosh, asinh, and atanh.])
3285
3286 dnl Everybody supports this, except MS.
3287 dnl Seems like the kind of thing we should be testing for, though.
3288 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3289 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3290
3291 dnl Everybody supports this, except MS-DOS.
3292 dnl Seems like the kind of thing we should be testing for, though.
3293 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3294 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3295   4.2-compatible sockets.])
3296
3297 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3298
3299 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3300   a null file, or a data sink.])
3301
3302 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3303
3304 dnl Everybody supports this, except MS-DOS.
3305 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3306
3307 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3308
3309
3310 AC_DEFINE(DIRECTORY_SEP, ['/'],
3311   [Character that separates directories in a file name.])
3312
3313 dnl Only used on MS platforms.
3314 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3315
3316 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3317   [Returns true if character is a device separator.])
3318
3319 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3320   [Returns true if character is a directory separator.])
3321
3322 dnl On MS, this also accepts IS_DEVICE_SEP.
3323 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3324   [Returns true if character is any form of separator.])
3325
3326
3327 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3328
3329 case $opsys in
3330   aix4-2)
3331     dnl Unfortunately without libXmu we cannot support EditRes.
3332     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3333       AC_DEFINE(NO_EDITRES, 1)
3334     fi
3335     ;;
3336
3337   hpux*)
3338     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3339     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3340     AC_DEFINE(NO_EDITRES, 1)
3341     ;;
3342 esac
3343
3344
3345 case $opsys in
3346   darwin | gnu | hpux* | *bsd )
3347     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3348     ;;
3349
3350   irix6-5 | sol2* | unixware )
3351     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3352     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3353     dnl need the constant to dimension an array.  So wire in the appropriate
3354     dnl value here.
3355     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3356     ;;
3357 esac
3358
3359
3360 case $opsys in
3361   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3362   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3363   hpux* | irix6-5 | openbsd | sol2* | unixware )
3364     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3365     ;;
3366
3367   aix4-2)
3368     dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3369     AC_DEFINE(BROKEN_FIONREAD, 1, [Define if FIONREAD should not be used.])
3370     dnl As we define BROKEN_FIONREAD, SIGIO will be undefined in systty.h.
3371     dnl But, on AIX, SIGAIO, SIGPTY, and SIGPOLL are defined as SIGIO,
3372     dnl which causes compilation error at init_signals in sysdep.c.
3373     dnl So, we define these macros so that syssignal.h detects them
3374     dnl and undefine SIGAIO, SIGPTY and SIGPOLL.
3375     AC_DEFINE(BROKEN_SIGAIO, 1, [Define if SIGAIO should not be used.])
3376     AC_DEFINE(BROKEN_SIGPOLL,1, [Define if SIGPOLL should not be used.])
3377     AC_DEFINE(BROKEN_SIGPTY, 1, [Define if SIGPTY should not be used.])
3378
3379     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3380     dnl the way this system works, libc functions that return malloced
3381     dnl memory use the libc malloc implementation. Calling xfree or
3382     dnl xrealloc on the results of such functions results in a crash.
3383     dnl
3384     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3385     dnl but that does not currently work on this system.
3386     dnl
3387     dnl It is possible to completely override the malloc implementation on
3388     dnl AIX, but that involves putting the malloc functions in a shared
3389     dnl library and setting the MALLOCTYPE environment variable to point to
3390     dnl that shared library.
3391     dnl
3392     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3393     dnl to avoid a crash just use the Emacs implementation for that function.
3394     dnl
3395     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3396     dnl of this file, so that we do not check for get_current_dir_name
3397     dnl on AIX.  But that might be fragile if something else ends
3398     dnl up testing for get_current_dir_name as a dependency.
3399     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3400       get_current_dir_name should not be used.])
3401     ;;
3402
3403   freebsd)
3404     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3405     dnl writes/reads on a PTY, read(2) returns bogus data:
3406     dnl
3407     dnl write(2)  1022 bytes
3408     dnl write(2)   954 bytes, get EAGAIN
3409     dnl read(2)   1024 bytes in process_read_output
3410     dnl read(2)     11 bytes in process_read_output
3411     dnl
3412     dnl That is, read(2) returns more bytes than have ever been written
3413     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3414     dnl successfully after processing (for example with CRs added if the
3415     dnl terminal is set up that way which it is here).  The same bytes will
3416     dnl be seen again in a later read(2), without the CRs.
3417     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3418       work around an issue when reading from a PTY.])
3419     ;;
3420
3421   dnl Define the following so emacs symbols will not conflict with those
3422   dnl in the System framework.  Otherwise -prebind will not work.
3423   darwin)
3424     AC_DEFINE(NO_ABORT, 1, [Do not define abort in emacs.c.])
3425     ;;
3426 esac
3427
3428 case $opsys in
3429   gnu-* | sol2-10 )
3430     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3431     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3432   ;;
3433 esac
3434
3435 case $opsys in
3436   darwin | freebsd | netbsd | openbsd )
3437     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3438       close a pty to make it a controlling terminal (it is already a
3439       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3440   ;;
3441 esac
3442
3443 dnl FIXME Surely we can test for this rather than hard-code it.
3444 case $opsys in
3445   netbsd | openbsd) sound_device="/dev/audio" ;;
3446   *) sound_device="/dev/dsp" ;;
3447 esac
3448
3449 dnl Used in sound.c
3450 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3451   [Name of the default sound device.])
3452
3453
3454 dnl Emacs can read input using SIGIO and buffering characters itself,
3455 dnl or using CBREAK mode and making C-g cause SIGINT.
3456 dnl The choice is controlled by the variable interrupt_input.
3457 dnl
3458 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3459 dnl
3460 dnl Emacs uses the presence or absence of the SIGIO and BROKEN_SIGIO macros
3461 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3462 dnl INTERRUPT_INPUT to decide whether to use it by default.
3463 dnl
3464 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3465 dnl CBREAK mode has two disadvantages
3466 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3467 dnl I hear that in system V this problem does not exist.
3468 dnl 2) Control-G causes output to be discarded.
3469 dnl I do not know whether this can be fixed in system V.
3470 dnl
3471 dnl Another method of doing input is planned but not implemented.
3472 dnl It would have Emacs fork off a separate process
3473 dnl to read the input and send it to the true Emacs process
3474 dnl through a pipe.
3475 case $opsys in
3476   darwin | gnu-linux | gnu-kfreebsd )
3477     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3478   ;;
3479 esac
3480
3481
3482 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3483 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3484 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3485 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3486 dnl taking float or double parameters.
3487 case $opsys in
3488   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3489     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3490       file defines `NeedWidePrototypes' as `NO'.])
3491   ;;
3492 esac
3493
3494
3495 dnl Used in process.c, this must be a loop, even if it only runs once.
3496 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3497 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3498 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3499 dnl trying suffixes 0-16.
3500 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3501   first PTY, if PTYs are supported.])
3502 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3503 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3504   end of a PTY, if non-standard.])
3505 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3506   end of a PTY, if non-standard.])
3507
3508 case $opsys in
3509   aix4-2 )
3510     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3511     dnl You allocate a pty by opening /dev/ptc to get the master side.
3512     dnl To get the name of the slave side, you just ttyname() the master side.
3513     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3514     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3515     ;;
3516
3517   cygwin )
3518     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3519     dnl multi-line AC_DEFINEs are hard. :(
3520     AC_DEFINE(PTY_OPEN, [ do { int dummy; SIGMASKTYPE mask; mask = sigblock (sigmask (SIGCHLD)); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; sigsetmask (mask); if (fd >= 0) emacs_close (dummy); } while (0)])
3521     AC_DEFINE(PTY_NAME_SPRINTF, [])
3522     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3523     ;;
3524
3525   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3526   darwin )
3527     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3528     dnl Not used, because PTY_ITERATION is defined.
3529     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3530     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3531     dnl But we don't have to block SIGCHLD because it is blocked in the
3532     dnl implementation of grantpt.
3533     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3534     AC_DEFINE(PTY_NAME_SPRINTF, [])
3535     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3536     ;;
3537
3538   gnu | openbsd )
3539     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3540     ;;
3541
3542   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3543     dnl if HAVE_GRANTPT
3544     if test "x$ac_cv_func_grantpt" = xyes; then
3545       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3546       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3547       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3548       dnl to prevent sigchld_handler from intercepting the child's death.
3549       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname; sigblock (sigmask (SIGCHLD)); if (grantpt (fd) == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname(fd))) { sigunblock (sigmask (SIGCHLD)); close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); sigunblock (sigmask (SIGCHLD)); }])
3550       dnl if HAVE_POSIX_OPENPT
3551       if test "x$ac_cv_func_posix_openpt" = xyes; then
3552         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3553         AC_DEFINE(PTY_NAME_SPRINTF, [])
3554       dnl if HAVE_GETPT
3555       elif test "x$ac_cv_func_getpt" = xyes; then
3556         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3557         AC_DEFINE(PTY_NAME_SPRINTF, [])
3558       else
3559         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3560       fi
3561     else
3562       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3563     fi
3564     ;;
3565
3566   hpux*)
3567     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3568     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3569     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3570     ;;
3571
3572   irix6-5 )
3573     dnl It looks like this cannot be right, because it is not a loop.
3574     dnl However, process.c actually does this:
3575     dnl # ifndef __sgi
3576     dnl   continue;
3577     dnl # else
3578     dnl   return -1;
3579     dnl # endif
3580     dnl which presumably makes it OK, since irix == sgi (?).
3581     dnl FIXME it seems like this special treatment is unnecessary?
3582     dnl Why can't irix use a single-trip loop like eg cygwin?
3583     AC_DEFINE(PTY_ITERATION, [])
3584     dnl Not used, because PTY_ITERATION is defined.
3585     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3586     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3587     dnl No need to get the pty name at all.
3588     AC_DEFINE(PTY_NAME_SPRINTF, [])
3589     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3590     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3591     ;;
3592
3593   sol2* )
3594     dnl Uses sigblock/sigunblock rather than sighold/sigrelse,
3595     dnl which appear to be BSD4.1 specific.  It may also be appropriate
3596     dnl for SVR4.x (x<2) but I'm not sure.   fnf@cygnus.com
3597     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3598     dnl from intercepting that death.  If any child but grantpt's should die
3599     dnl within, it should be caught after sigrelse(2).
3600     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock (sigmask (SIGCLD)); if (grantpt (fd) == -1) { emacs_close (fd); return -1; } sigunblock (sigmask (SIGCLD)); if (unlockpt (fd) == -1) { emacs_close (fd); return -1; } if (!(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3601     ;;
3602
3603   unixware )
3604     dnl Comments are as per sol2*.
3605     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock(sigmask(SIGCLD)); if (grantpt(fd) == -1) fatal("could not grant slave pty"); sigunblock(sigmask(SIGCLD)); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3606     ;;
3607 esac
3608
3609
3610 case $opsys in
3611   sol2* | unixware )
3612     dnl This change means that we don't loop through allocate_pty too
3613     dnl many times in the (rare) event of a failure.
3614     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3615     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3616     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3617     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3618     ;;
3619 esac
3620
3621
3622 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3623 "typing" a signal character on the pty.])
3624
3625 case $opsys in
3626   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3627   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3628   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3629     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3630     ;;
3631
3632   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3633   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3634   gnu-linux | gnu-kfreebsd )
3635
3636     AC_MSG_CHECKING([for signals via characters])
3637     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3638 #include <linux/version.h>
3639 #if LINUX_VERSION_CODE < 0x20400
3640 # error "Linux version too old"
3641 #endif
3642       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3643
3644     AC_MSG_RESULT([$emacs_signals_via_chars])
3645     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3646     ;;
3647 esac
3648
3649
3650 dnl Used in dispnew.c
3651 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3652   buffer of a stdio stream.])
3653
3654 AC_MSG_CHECKING([whether we are using the GNU C library])
3655 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3656 #include <features.h>
3657 #ifndef __GNU_LIBRARY__
3658 # error "this is not the GNU C library"
3659 #endif
3660   ]], [[]])], emacs_glibc=yes, emacs_glibc=no)
3661 AC_MSG_RESULT([$emacs_glibc])
3662
3663 if test $emacs_glibc = yes; then
3664
3665   emacs_pending_output=unknown
3666
3667   case $opsys in
3668     gnu | gnu-linux | gnu-kfreebsd )
3669       AC_MSG_CHECKING([for style of pending output formalism])
3670       dnl In autoconf 2.67 and later, we could use a single test
3671       dnl since the preprocessed output is accessible in "conftest.i".
3672       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3673 #include <stdio.h>
3674 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3675 # error "stdio definitions not found"
3676 #endif
3677         ]], [[]])], emacs_pending_output=new, [])
3678
3679       if test $emacs_pending_output = unknown; then
3680         case $opsys in
3681           gnu-linux | gnu-kfreebsd)
3682             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3683 #include <stdio.h>
3684 #ifndef __UCLIBC__
3685 # error "not using uclibc"
3686 #endif
3687             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3688             ;;
3689         esac
3690       fi
3691
3692       AC_MSG_RESULT([$emacs_pending_output])
3693
3694       case $emacs_pending_output in
3695         new)
3696           dnl New C libio names.
3697           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3698             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3699           ;;
3700         uclibc)
3701           dnl Using the uClibc library.
3702           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3703             [((FILE)->__bufpos - (FILE)->__bufstart)])
3704           ;;
3705         old)
3706           dnl Old C++ iostream names.
3707           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3708             [((FILE)->_pptr - (FILE)->_pbase)])
3709           ;;
3710       esac
3711     ;;
3712   esac                          dnl opsys
3713
3714   if test $emacs_pending_output = unknown; then
3715     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__bufp - (FILE)->__buffer)])
3716   fi
3717
3718 else                            dnl !emacs_glibc
3719
3720   case $opsys in
3721     cygwin | darwin | freebsd | netbsd | openbsd )
3722       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3723       ;;
3724
3725     unixware)
3726       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3727       ;;
3728
3729     *)
3730       dnl HAVE_STDIO_EXT_H && HAVE___FPENDING
3731       if test x$ac_cv_header_stdio_ext_h = xyes && \
3732         test x$ac_cv_func___fpending = xyes; then
3733         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [__fpending (FILE)])
3734         AC_DEFINE(DISPNEW_NEEDS_STDIO_EXT, 1,
3735           [Define if dispnew.c should include stdio_ext.h.])
3736       else
3737         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_ptr - (FILE)->_base)])
3738       fi
3739       ;;
3740   esac
3741 fi                              dnl emacs_glibc
3742
3743
3744 dnl Used in vm-limit.c
3745 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3746 dnl Used in lisp.h, emacs.c, mem-limits.h
3747 dnl NEWS.18 describes this as "a number which contains
3748 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3749 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3750 stored in a Lisp_Object.])
3751 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3752
3753 case $opsys in
3754   gnu)
3755     dnl libc defines data_start.
3756     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3757     ;;
3758
3759   hpux*)
3760     dnl The data segment on this machine always starts at address 0x40000000.
3761     AC_DEFINE(DATA_START, [0x40000000])
3762     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3763     ;;
3764   irix6-5)
3765     AC_DEFINE(DATA_START, [0x10000000])
3766     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3767     ;;
3768 esac
3769
3770
3771 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3772 AH_TEMPLATE(TAB3, [Undocumented.])
3773
3774 case $opsys in
3775   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3776
3777   gnu | freebsd | netbsd | openbsd )
3778     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3779     AC_DEFINE(TAB3, OXTABS)
3780     ;;
3781
3782   gnu-linux | gnu-kfreebsd )
3783     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3784     dnl library, we cannot get the maximum address for brk.
3785     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3786 #ifndef __i386__
3787 # error "not i386"
3788 #endif
3789       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3790
3791     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3792 #ifndef __ia64__
3793 # error "not ia64"
3794 #endif
3795       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3796         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3797         [Mark a secondary stack, like the register stack on the ia64.]), [])
3798     ;;
3799
3800   hpux*)
3801     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3802       run_time_remap; for HPUX.])
3803     ;;
3804
3805   irix6-5)
3806     dnl Ulimit(UL_GMEMLIM) is busted...
3807     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3808     ;;
3809 esac
3810
3811
3812 dnl These won't be used automatically yet.  We also need to know, at least,
3813 dnl that the stack is continuous.
3814 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3815   registers relevant for conservative garbage collection in the jmp_buf.])
3816
3817 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3818   conservative garbage collection is not known to work.])
3819
3820
3821 case $opsys in
3822   aix4-2 | hpux* | unixware)
3823     dnl Conservative garbage collection has not been tested, so for now
3824     dnl play it safe and stick with the old-fashioned way of marking.
3825     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3826     ;;
3827
3828   dnl Not all the architectures are tested, but there are Debian packages
3829   dnl for SCM and/or Guile on them, so the technique must work.  See also
3830   dnl comments in alloc.c concerning setjmp and gcc.
3831   dnl Fixme: it's probably safe to just use the GCC conditional below.
3832   gnu-linux | gnu-kfreebsd )
3833     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3834 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3835   || defined __alpha__ || defined __mips__ || defined __s390__ \
3836   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3837   || defined __ia64__ || defined __sh__
3838 /* ok */
3839 #else
3840 # error "setjmp not known to work on this arch"
3841 #endif
3842     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3843       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3844     ;;
3845 esac
3846
3847
3848 if test x$GCC = xyes; then
3849    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3850    AC_DEFINE(GC_SETJMP_WORKS, 1)
3851 else
3852   case $opsys in
3853     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3854     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3855       AC_DEFINE(GC_SETJMP_WORKS, 1)
3856       ;;
3857   esac
3858 fi                              dnl GCC?
3859
3860
3861 case $opsys in
3862   sol2* | unixware )
3863     dnl setjmp and longjmp can safely replace _setjmp and _longjmp,
3864     dnl but they will run more slowly.
3865     AC_DEFINE(_setjmp, setjmp, [Some platforms redefine this.])
3866     AC_DEFINE(_longjmp, longjmp, [Some platforms redefine this.])
3867     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3868     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3869     dnl and this is all we need.
3870     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3871     ;;
3872 esac
3873
3874
3875 case $opsys in
3876   hpux* | sol2* )
3877     dnl Used in xfaces.c.
3878     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3879       some systems, where it requires time.h.])
3880     ;;
3881
3882   netbsd | openbsd )
3883     dnl Greg A. Woods <woods@weird.com> says we must include signal.h
3884     dnl before syssignal.h is included, to work around interface conflicts
3885     dnl that are handled with CPP __RENAME() macro in signal.h.
3886     AC_DEFINE(SIGNAL_H_AHB, 1, [Define if AH_BOTTOM should include signal.h.])
3887     ;;
3888 esac
3889
3890
3891 dnl Define symbols to identify the version of Unix this is.
3892 dnl Define all the symbols that apply correctly.
3893 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3894 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3895 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3896 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3897 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3898 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3899 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3900
3901 case $opsys in
3902   aix4-2)
3903     AC_DEFINE(USG, [])
3904     AC_DEFINE(USG5, [])
3905     dnl This symbol should be defined on AIX Version 3  ???????
3906     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3907 #ifndef _AIX
3908 # error "_AIX not defined"
3909 #endif
3910     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3911     ;;
3912
3913   cygwin)
3914     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3915     ;;
3916
3917   darwin)
3918     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3919     AC_DEFINE(BSD4_2, [])
3920     AC_DEFINE(BSD_SYSTEM, [])
3921     dnl More specific than the above two.  We cannot use __APPLE__ as this
3922     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3923     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3924     dnl distinguish OS X from pure Darwin.
3925     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3926     ;;
3927
3928   freebsd)
3929     AC_DEFINE(BSD4_2, [])
3930     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3931     dnl Would not be needed with autoconf >= 2.67, where the
3932     dnl preprocessed output is accessible in "conftest.i".
3933     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3934     ;;
3935
3936   gnu | netbsd | openbsd )
3937     AC_DEFINE(BSD4_2, [])
3938     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3939 #ifndef BSD_SYSTEM
3940 # error "BSD_SYSTEM not defined"
3941 #endif
3942     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3943     ;;
3944
3945   gnu-linux | gnu-kfreebsd )
3946     AC_DEFINE(USG, [])
3947     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3948     ;;
3949
3950   hpux*)
3951     AC_DEFINE(USG, [])
3952     AC_DEFINE(USG5, [])
3953     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3954     ;;
3955
3956   irix6-5)
3957     AC_DEFINE(USG, [])
3958     AC_DEFINE(USG5, [])
3959     AC_DEFINE(USG5_4, [])
3960     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3961     ;;
3962
3963   sol2*)
3964     AC_DEFINE(USG, [])
3965     AC_DEFINE(USG5, [])
3966     AC_DEFINE(USG5_4, [])
3967     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3968     ;;
3969
3970   unixware)
3971     AC_DEFINE(USG, [])
3972     AC_DEFINE(USG5, [])
3973     AC_DEFINE(USG5_4, [])
3974     ;;
3975 esac
3976
3977
3978 case $opsys in
3979   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3980   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3981   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3982   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3983   cygwin)
3984     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3985       G_SLICE environment variable to "always-malloc" at startup, if
3986       using GTK.])
3987     ;;
3988
3989   hpux11)
3990     dnl See comments in sysdep.c:sys_signal.
3991     dnl SA_RESTART resets the timeout of `select' on hpux11.
3992     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3993     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3994       be used in batch mode.])
3995     dnl It works to open the pty's tty in the parent (Emacs), then
3996     dnl close and reopen it in the child.
3997     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3998       works to open a pty's tty in the parent process, then close and
3999       reopen it in the child.])
4000     ;;
4001
4002   irix6-5)
4003     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4004       use VSUSP instead of VSWTCH.])
4005     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
4006       should not call setpgrp.])
4007     ;;
4008
4009   sol2-10)
4010     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4011       on Solaris.])
4012     ;;
4013 esac
4014
4015 # Set up the CFLAGS for real compilation, so we can substitute it.
4016 CFLAGS="$REAL_CFLAGS"
4017 CPPFLAGS="$REAL_CPPFLAGS"
4018
4019 ## Hack to detect a buggy GCC version.
4020 if test "x$GCC" = xyes \
4021    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4022    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4023    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4024    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4025 fi
4026
4027 version=$PACKAGE_VERSION
4028
4029 ### Specify what sort of things we'll be editing into Makefile and config.h.
4030 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4031 AC_SUBST(version)
4032 AC_SUBST(configuration)
4033 ## Unused?
4034 AC_SUBST(canonical)
4035 AC_SUBST(srcdir)
4036 AC_SUBST(prefix)
4037 AC_SUBST(exec_prefix)
4038 AC_SUBST(bindir)
4039 AC_SUBST(datadir)
4040 AC_SUBST(sharedstatedir)
4041 AC_SUBST(libexecdir)
4042 AC_SUBST(mandir)
4043 AC_SUBST(infodir)
4044 AC_SUBST(lispdir)
4045 AC_SUBST(leimdir)
4046 AC_SUBST(standardlisppath)
4047 AC_SUBST(locallisppath)
4048 AC_SUBST(lisppath)
4049 AC_SUBST(x_default_search_path)
4050 AC_SUBST(etcdir)
4051 AC_SUBST(archlibdir)
4052 AC_SUBST(docdir)
4053 AC_SUBST(bitmapdir)
4054 AC_SUBST(gamedir)
4055 AC_SUBST(gameuser)
4056 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4057 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4058 ## end of LIBX_BASE, but nothing ever set it.
4059 AC_SUBST(LD_SWITCH_X_SITE)
4060 AC_SUBST(C_SWITCH_X_SITE)
4061 AC_SUBST(GNUSTEP_CFLAGS)
4062 AC_SUBST(CFLAGS)
4063 ## Used in lwlib/Makefile.in.
4064 AC_SUBST(X_TOOLKIT_TYPE)
4065 AC_SUBST(ns_appdir)
4066 AC_SUBST(ns_appbindir)
4067 AC_SUBST(ns_appresdir)
4068 AC_SUBST(ns_appsrc)
4069 AC_SUBST(GNU_OBJC_CFLAGS)
4070 AC_SUBST(OTHER_FILES)
4071
4072 if test -n "${term_header}"; then
4073     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4074         [Define to the header for the built-in window system.])
4075 fi
4076
4077 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4078                    [Define to the canonical Emacs configuration name.])
4079 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
4080                    [Define to the options passed to configure.])
4081 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4082   define this to include extra configuration information.])
4083
4084 XMENU_OBJ=
4085 XOBJ=
4086 FONT_OBJ=
4087 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4088   AC_DEFINE(HAVE_X_WINDOWS, 1,
4089             [Define to 1 if you want to use the X window system.])
4090   XMENU_OBJ=xmenu.o
4091   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o xgselect.o"
4092   FONT_OBJ=xfont.o
4093   if test "$HAVE_XFT" = "yes"; then
4094     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4095   elif test "$HAVE_FREETYPE" = "yes"; then
4096     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4097   fi
4098   AC_SUBST(FONT_OBJ)
4099 fi
4100 AC_SUBST(XMENU_OBJ)
4101 AC_SUBST(XOBJ)
4102 AC_SUBST(FONT_OBJ)
4103
4104 WIDGET_OBJ=
4105 MOTIF_LIBW=
4106 if test "${USE_X_TOOLKIT}" != "none" ; then
4107   WIDGET_OBJ=widget.o
4108   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4109   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4110     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4111   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4112     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4113     MOTIF_LIBW=-lXm
4114     case "$opsys" in
4115       gnu-linux)
4116         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4117         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4118         ;;
4119
4120       unixware)
4121         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4122         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4123         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4124         ;;
4125
4126       aix4-2)
4127         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4128         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4129         ;;
4130     esac
4131     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4132   fi
4133 fi
4134 AC_SUBST(WIDGET_OBJ)
4135
4136 TOOLKIT_LIBW=
4137 case "$USE_X_TOOLKIT" in
4138   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4139   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4140   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4141 esac
4142 AC_SUBST(TOOLKIT_LIBW)
4143
4144 if test "$USE_X_TOOLKIT" = "none"; then
4145   LIBXT_OTHER="\$(LIBXSM)"
4146   OLDXMENU_TARGET="really-oldXMenu"
4147 else
4148   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4149   OLDXMENU_TARGET="really-lwlib"
4150 fi
4151 AC_SUBST(LIBXT_OTHER)
4152
4153 ## The X Menu stuff is present in the X10 distribution, but missing
4154 ## from X11.  If we have X10, just use the installed library;
4155 ## otherwise, use our own copy.
4156 if test "${HAVE_X11}" = "yes" ; then
4157   AC_DEFINE(HAVE_X11, 1,
4158             [Define to 1 if you want to use version 11 of X windows.
4159              Otherwise, Emacs expects to use version 10.])
4160
4161   if test "$USE_X_TOOLKIT" = "none"; then
4162     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4163   else
4164     OLDXMENU="\${lwlibdir}/liblw.a"
4165   fi
4166   LIBXMENU="\$(OLDXMENU)"
4167   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4168   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4169 else
4170   ## For a syntactically valid Makefile; not actually used for anything.
4171   ## See comments in src/Makefile.in.
4172   OLDXMENU=nothing
4173   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4174   if test "${HAVE_X_WINDOWS}" = "yes"; then
4175     LIBXMENU="-lXMenu"
4176   else
4177     LIBXMENU=
4178   fi
4179   LIBX_OTHER=
4180   OLDXMENU_DEPS=
4181 fi
4182
4183 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4184   OLDXMENU_TARGET=
4185   OLDXMENU=nothing
4186   LIBXMENU=
4187   OLDXMENU_DEPS=
4188 fi
4189
4190 AC_SUBST(OLDXMENU_TARGET)
4191 AC_SUBST(OLDXMENU)
4192 AC_SUBST(LIBXMENU)
4193 AC_SUBST(LIBX_OTHER)
4194 AC_SUBST(OLDXMENU_DEPS)
4195
4196 if test "${HAVE_MENUS}" = "yes" ; then
4197   AC_DEFINE(HAVE_MENUS, 1,
4198             [Define to 1 if you have mouse menus.
4199              (This is automatic if you use X, but the option to specify it remains.)
4200              It is also defined with other window systems that support xmenu.c.])
4201 fi
4202
4203 if test "${GNU_MALLOC}" = "yes" ; then
4204   AC_DEFINE(GNU_MALLOC, 1,
4205             [Define to 1 if you want to use the GNU memory allocator.])
4206 fi
4207
4208 RALLOC_OBJ=
4209 if test "${REL_ALLOC}" = "yes" ; then
4210   AC_DEFINE(REL_ALLOC, 1,
4211             [Define REL_ALLOC if you want to use the relocating allocator for
4212              buffer space.])
4213
4214   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4215 fi
4216 AC_SUBST(RALLOC_OBJ)
4217
4218 if test "$opsys" = "cygwin"; then
4219   CYGWIN_OBJ="sheap.o cygw32.o"
4220   ## Cygwin differs because of its unexec().
4221   PRE_ALLOC_OBJ=
4222   POST_ALLOC_OBJ=lastfile.o
4223 else
4224   CYGWIN_OBJ=
4225   PRE_ALLOC_OBJ=lastfile.o
4226   POST_ALLOC_OBJ=
4227 fi
4228 AC_SUBST(CYGWIN_OBJ)
4229 AC_SUBST(PRE_ALLOC_OBJ)
4230 AC_SUBST(POST_ALLOC_OBJ)
4231
4232 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4233 # it temporarily reverts them to their pre-pkg-config values,
4234 # because gnulib needs to work with both src (which uses the
4235 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4236 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4237 # and it therefore needs to run in an environment where LIBS does not
4238 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4239 # for some package unrelated to lib-src.
4240 SAVE_CFLAGS=$CFLAGS
4241 SAVE_LIBS=$LIBS
4242 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4243 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4244 gl_ASSERT_NO_GNULIB_POSIXCHECK
4245 gl_ASSERT_NO_GNULIB_TESTS
4246 gl_INIT
4247 CFLAGS=$SAVE_CFLAGS
4248 LIBS=$SAVE_LIBS
4249
4250 case "$opsys" in
4251   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4252
4253   darwin)
4254    ## The -headerpad option tells ld (see man page) to leave room at the
4255    ## end of the header for adding load commands.  Needed for dumping.
4256    ## 0x690 is the total size of 30 segment load commands (at 56
4257    ## each); under Cocoa 31 commands are required.
4258    if test "$HAVE_NS" = "yes"; then
4259      libs_nsgui="-framework AppKit"
4260      headerpad_extra=6C8
4261    else
4262      libs_nsgui=
4263      headerpad_extra=690
4264    fi
4265    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4266
4267    ## This is here because src/Makefile.in did some extra fiddling around
4268    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4269    ##   #ifndef LD_SWITCH_SYSTEM
4270    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4271    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4272    ## not using gcc, darwin.
4273    ## Because this was done in src/Makefile.in, the resulting part of
4274    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4275    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4276    ## rather than LD_SWITCH_SYSTEM.
4277    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4278      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4279    ;;
4280
4281   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4282   ## find X at run-time.
4283   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4284   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4285   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4286   ## had different values in configure (in ac_link) and src/Makefile.in.
4287   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4288   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4289
4290   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4291 esac
4292
4293 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4294   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4295 fi
4296
4297 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4298
4299
4300 LD_FIRSTFLAG=
4301 ORDINARY_LINK=
4302 case "$opsys" in
4303   ## gnu: GNU needs its own crt0.
4304   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4305
4306   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4307   ## library search parth, i.e. it won't search /usr/lib for libc and
4308   ## friends.  Using -nostartfiles instead avoids this problem, and
4309   ## will also work on earlier NetBSD releases.
4310   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4311
4312   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4313   ##   MkLinux/LinuxPPC needs this.
4314   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4315   gnu-*)
4316     case "$canonical" in
4317       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4318     esac
4319     ;;
4320 esac
4321
4322
4323 if test "x$ORDINARY_LINK" = "xyes"; then
4324
4325   LD_FIRSTFLAG=""
4326   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4327
4328 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4329 ## freebsd, gnu-* not on powerpc*|s390x*.
4330 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4331
4332   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4333   ## places that are difficult to figure out at make time.  Fortunately,
4334   ## these same versions allow you to pass arbitrary flags on to the
4335   ## linker, so there is no reason not to use it as a linker.
4336   ##
4337   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4338   ## searching for libraries in its internal directories, so we have to
4339   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4340   LD_FIRSTFLAG="-nostdlib"
4341 fi
4342
4343 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4344 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4345
4346 AC_SUBST(LD_FIRSTFLAG)
4347
4348
4349 ## FIXME? The logic here is not precisely the same as that above.
4350 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4351 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4352 LIB_GCC=
4353 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4354
4355   case "$opsys" in
4356     freebsd|netbsd|openbsd) LIB_GCC= ;;
4357
4358     gnu-*)
4359       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4360       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4361       case $host_cpu in
4362       arm*)
4363         LIB_GCC="-lgcc_s"
4364         ;;
4365       *)
4366         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4367         ## immediately undefine it again and redefine it to empty.
4368         ## Was the C_SWITCH_X_SITE part really necessary?
4369 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4370         LIB_GCC=
4371         ;;
4372       esac
4373       ;;
4374
4375     ## Ask GCC where to find libgcc.a.
4376     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4377   esac
4378 fi                              dnl if $GCC
4379 AC_SUBST(LIB_GCC)
4380
4381 ## Common for all window systems
4382 if test "$window_system" != "none"; then
4383   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4384   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4385   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4386 fi
4387
4388 AC_SUBST(WINDOW_SYSTEM_OBJ)
4389
4390 AH_TOP([/* GNU Emacs site configuration template file.
4391
4392 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4393   Free Software Foundation, Inc.
4394
4395 This file is part of GNU Emacs.
4396
4397 GNU Emacs is free software: you can redistribute it and/or modify
4398 it under the terms of the GNU General Public License as published by
4399 the Free Software Foundation, either version 3 of the License, or
4400 (at your option) any later version.
4401
4402 GNU Emacs is distributed in the hope that it will be useful,
4403 but WITHOUT ANY WARRANTY; without even the implied warranty of
4404 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4405 GNU General Public License for more details.
4406
4407 You should have received a copy of the GNU General Public License
4408 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4409
4410
4411 /* No code in Emacs #includes config.h twice, but some bits of code
4412    intended to work with other packages as well (like gmalloc.c)
4413    think they can include it as many times as they like.  */
4414 #ifndef EMACS_CONFIG_H
4415 #define EMACS_CONFIG_H
4416 ])dnl
4417
4418 AH_BOTTOM([#include <conf_post.h>
4419
4420 #endif /* EMACS_CONFIG_H */
4421
4422 /*
4423 Local Variables:
4424 mode: c
4425 End:
4426 */
4427 ])dnl
4428
4429 #### Report on what we decided to do.
4430 #### Report GTK as a toolkit, even if it doesn't use Xt.
4431 #### It makes printing result more understandable as using GTK sets
4432 #### toolkit_scroll_bars to yes by default.
4433 if test "${HAVE_GTK}" = "yes"; then
4434   if test "${with_gtk3}" = "yes"; then
4435     USE_X_TOOLKIT=GTK3
4436   else
4437     USE_X_TOOLKIT=GTK
4438   fi
4439 fi
4440
4441 echo "
4442 Configured for \`${canonical}'.
4443
4444   Where should the build process find the source code?    ${srcdir}
4445   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4446   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4447   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4448   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4449   What window system should Emacs use?                    ${window_system}
4450   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4451
4452 if test -n "${x_includes}"; then
4453 echo "  Where do we find X Windows header files?                ${x_includes}"
4454 else
4455 echo "  Where do we find X Windows header files?                Standard dirs"
4456 fi
4457 if test -n "${x_libraries}"; then
4458 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4459 else
4460 echo "  Where do we find X Windows libraries?                   Standard dirs"
4461 fi
4462
4463 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4464 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4465 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4466 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4467 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4468 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4469 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4470 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4471
4472 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4473 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4474 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4475 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4476 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4477 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4478 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4479
4480 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4481 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4482 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4483 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4484
4485 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4486 echo
4487
4488 if test -n "${EMACSDATA}"; then
4489    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4490 fi
4491 if test -n "${EMACSDOC}"; then
4492    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4493 fi
4494
4495 echo
4496
4497 if test "$HAVE_NS" = "yes"; then
4498    echo
4499    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4500 The installed application will go to nextstep/Emacs.app and can be
4501 run or moved from there."
4502    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4503       echo "The application will be fully self-contained."
4504     else
4505       echo "The lisp resources for the application will be installed under ${prefix}.
4506 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4507 to run if these resources are not installed."
4508    fi
4509    echo
4510 fi
4511
4512 if test "${opsys}" = "cygwin"; then
4513   case `uname -r` in
4514     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4515            echo
4516            ;;
4517   esac
4518 fi
4519
4520 # Remove any trailing slashes in these variables.
4521 [test "${prefix}" != NONE &&
4522   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4523 test "${exec_prefix}" != NONE &&
4524   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4525
4526 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4527 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4528 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4529 dnl (else you get "no `Makefile.am' found for any configure output").
4530 dnl This will work, but you get a config.status that is not quite right
4531 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4532 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4533 dnl it seems better to just live with the duplication.
4534 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4535
4536 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4537        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4538        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4539        leim/Makefile])
4540
4541 dnl test/ is not present in release tarfiles.
4542 opt_makefile=test/automated/Makefile
4543
4544 if test -f $srcdir/${opt_makefile}.in; then
4545   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4546   dnl Again, it's best not to use a variable.  Though you can add
4547   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4548   AC_CONFIG_FILES([test/automated/Makefile])
4549 fi
4550
4551
4552 dnl admin/ may or may not be present.
4553 opt_makefile=admin/unidata/Makefile
4554
4555 if test -f $srcdir/${opt_makefile}.in; then
4556   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4557   AC_CONFIG_FILES([admin/unidata/Makefile])
4558 fi
4559
4560
4561 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4562
4563 AC_SUBST(SUBDIR_MAKEFILES_IN)
4564
4565 dnl Make the necessary directories, if they don't exist.
4566 AC_CONFIG_COMMANDS([mkdirs], [
4567 for dir in etc lisp ; do
4568   test -d ${dir} || mkdir ${dir}
4569 done
4570 ])
4571
4572 dnl You might wonder (I did) why epaths.h is generated by running make,
4573 dnl rather than just letting configure generate it from epaths.in.
4574 dnl One reason is that the various paths are not fully expanded (see above);
4575 dnl eg gamedir=${prefix}/var/games/emacs.
4576 dnl Secondly, the GNU Coding standards require that one should be able
4577 dnl to run `make prefix=/some/where/else' and override the values set
4578 dnl by configure.  This also explains the `move-if-change' test and
4579 dnl the use of force in the `epaths-force' rule in Makefile.in.
4580 AC_CONFIG_COMMANDS([epaths], [
4581 echo creating src/epaths.h
4582 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4583 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4584
4585 AC_CONFIG_COMMANDS([gdbinit], [
4586 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4587   echo creating src/.gdbinit
4588   echo source $srcdir/src/.gdbinit > src/.gdbinit
4589 fi
4590 ])
4591
4592 AC_OUTPUT