lisp/add-log.el

   1 ;;; add-log.el --- change log maintenance commands for Emacs
   2
   3 ;; Copyright (C) 1985, 86, 88, 93, 94, 97, 98, 2000 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This facility is documented in the Emacs Manual.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'timezone))
  33
  34 (defgroup change-log nil
  35   "Change log maintenance"
  36   :group 'tools
  37   :link '(custom-manual "(emacs)Change Log")
  38   :prefix "change-log-"
  39   :prefix "add-log-")
  40
  41
  42 (defcustom change-log-default-name nil
  43   "*Name of a change log file for \\[add-change-log-entry]."
  44   :type '(choice (const :tag "default" nil)
  45                  string)
  46   :group 'change-log)
  47
  48 (defcustom change-log-mode-hook nil
  49   "Normal hook run by `change-log-mode'."
  50   :type 'hook
  51   :group 'change-log)
  52
  53 (defcustom add-log-current-defun-function nil
  54   "*If non-nil, function to guess name of surrounding function.
  55 It is used by `add-log-current-defun' in preference to built-in rules.
  56 Returns function's name as a string, or nil if outside a function."
  57   :type '(choice (const nil) function)
  58   :group 'change-log)
  59
  60 ;;;###autoload
  61 (defcustom add-log-full-name nil
  62   "*Full name of user, for inclusion in ChangeLog daily headers.
  63 This defaults to the value returned by the function `user-full-name'."
  64   :type '(choice (const :tag "Default" nil)
  65                  string)
  66   :group 'change-log)
  67
  68 ;;;###autoload
  69 (defcustom add-log-mailing-address nil
  70   "*Electronic mail addresses of user, for inclusion in ChangeLog headers.
  71 This defaults to the value of `user-mail-address'.  In addition to
  72 being a simple string, this value can also be a list.  All elements
  73 will be recognized as referring to the same user; when creating a new
  74 ChangeLog entry, one element will be chosen at random."
  75   :type '(choice (const :tag "Default" nil)
  76                  (string :tag "String")
  77                  (repeat :tag "List of Strings" string))
  78   :group 'change-log)
  79
  80 (defcustom add-log-time-format 'add-log-iso8601-time-string
  81   "*Function that defines the time format.
  82 For example, `add-log-iso8601-time-string', which gives the
  83 date in international ISO 8601 format,
  84 and `current-time-string' are two valid values."
  85   :type '(radio (const :tag "International ISO 8601 format"
  86                        add-log-iso8601-time-string)
  87                 (const :tag "Old format, as returned by `current-time-string'"
  88                        current-time-string)
  89                 (function :tag "Other"))
  90   :group 'change-log)
  91
  92 (defcustom add-log-keep-changes-together nil
  93   "*If non-nil, normally keep day's log entries for one file together.
  94
  95 Log entries for a given file made with \\[add-change-log-entry] or
  96 \\[add-change-log-entry-other-window] will only be added to others \
  97 for that file made
  98 today if this variable is non-nil or that file comes first in today's
  99 entries.  Otherwise another entry for that file will be started.  An
 100 original log:
 101
 102         * foo (...): ...
 103         * bar (...): change 1
 104
 105 in the latter case, \\[add-change-log-entry-other-window] in a \
 106 buffer visiting `bar', yields:
 107
 108         * bar (...): -!-
 109         * foo (...): ...
 110         * bar (...): change 1
 111
 112 and in the former:
 113
 114         * foo (...): ...
 115         * bar (...): change 1
 116         (...): -!-
 117
 118 The NEW-ENTRY arg to `add-change-log-entry' can override the effect of
 119 this variable."
 120   :version "20.3"
 121   :type 'boolean
 122   :group 'change-log)
 123
 124 (defcustom add-log-always-start-new-record nil
 125   "*If non-nil, `add-change-log-entry' will always start a new record."
 126   :version "21.4"
 127   :type 'boolean
 128   :group 'change-log)
 129
 130 (defcustom add-log-buffer-file-name-function nil
 131   "*If non-nil, function to call to identify the full filename of a buffer.
 132 This function is called with no argument.  If this is nil, the default is to
 133 use `buffer-file-name'."
 134   :type '(choice (const nil) function)
 135   :group 'change-log)
 136
 137 (defcustom add-log-file-name-function nil
 138   "*If non-nil, function to call to identify the filename for a ChangeLog entry.
 139 This function is called with one argument, the value of variable
 140 `buffer-file-name' in that buffer.  If this is nil, the default is to
 141 use the file's name relative to the directory of the change log file."
 142   :type '(choice (const nil) function)
 143   :group 'change-log)
 144
 145
 146 (defcustom change-log-version-info-enabled nil
 147   "*If non-nil, enable recording version numbers with the changes."
 148   :version "21.1"
 149   :type 'boolean
 150   :group 'change-log)
 151
 152 (defcustom change-log-version-number-regexp-list
 153   (let ((re    "\\([0-9]+\.[0-9.]+\\)"))
 154     (list
 155      ;;  (defconst ad-version "2.15"
 156      (concat "^(def[^ \t\n]+[ \t]+[^ \t\n][ \t]\"" re)
 157      ;; Revision: pcl-cvs.el,v 1.72 1999/09/05 20:21:54 monnier Exp
 158      (concat "^;+ *Revision: +[^ \t\n]+[ \t]+" re)))
 159   "*List of regexps to search for version number.
 160 The version number must be in group 1.
 161 Note: The search is conducted only within 10%, at the beginning of the file."
 162   :version "21.1"
 163   :type '(repeat regexp)
 164   :group 'change-log)
 165
 166 (defface change-log-date-face
 167   '((t (:inherit font-lock-string-face)))
 168   "Face used to highlight dates in date lines."
 169   :version "21.1"
 170   :group 'change-log)
 171
 172 (defface change-log-name-face
 173   '((t (:inherit font-lock-constant-face)))
 174   "Face for highlighting author names."
 175   :version "21.1"
 176   :group 'change-log)
 177
 178 (defface change-log-email-face
 179   '((t (:inherit font-lock-variable-name-face)))
 180   "Face for highlighting author email addresses."
 181   :version "21.1"
 182   :group 'change-log)
 183
 184 (defface change-log-file-face
 185   '((t (:inherit font-lock-function-name-face)))
 186   "Face for highlighting file names."
 187   :version "21.1"
 188   :group 'change-log)
 189
 190 (defface change-log-list-face
 191   '((t (:inherit font-lock-keyword-face)))
 192   "Face for highlighting parenthesized lists of functions or variables."
 193   :version "21.1"
 194   :group 'change-log)
 195
 196 (defface change-log-conditionals-face
 197   '((t (:inherit font-lock-variable-name-face)))
 198   "Face for highlighting conditionals of the form `[...]'."
 199   :version "21.1"
 200   :group 'change-log)
 201
 202 (defface change-log-function-face
 203   '((t (:inherit font-lock-variable-name-face)))
 204   "Face for highlighting items of the form `<....>'."
 205   :version "21.1"
 206   :group 'change-log)
 207
 208 (defface change-log-acknowledgement-face
 209   '((t (:inherit font-lock-comment-face)))
 210   "Face for highlighting acknowledgments."
 211   :version "21.1"
 212   :group 'change-log)
 213
 214 (defvar change-log-font-lock-keywords
 215   '(;;
 216     ;; Date lines, new and old styles.
 217     ("^\\sw.........[0-9:+ ]*"
 218      (0 'change-log-date-face)
 219      ;; Name and e-mail; some people put e-mail in parens, not angles.
 220      ("\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.-]+@[A-Za-z0-9_.-]+\\)[>)]" nil nil
 221       (1 'change-log-name-face)
 222       (2 'change-log-email-face)))
 223     ;;
 224     ;; File names.
 225     ("^\t\\* \\([^ ,:([\n]+\\)"
 226      (1 'change-log-file-face)
 227      ;; Possibly further names in a list:
 228      ("\\=, \\([^ ,:([\n]+\\)" nil nil (1 'change-log-file-face))
 229      ;; Possibly a parenthesized list of names:
 230      ("\\= (\\([^) ,:\n]+\\)" nil nil (1 'change-log-list-face))
 231      ("\\=, *\\([^) ,:\n]+\\)" nil nil (1 'change-log-list-face)))
 232     ;;
 233     ;; Function or variable names.
 234     ("^\t(\\([^) ,:\n]+\\)"
 235      (1 'change-log-list-face)
 236      ("\\=, *\\([^) ,:\n]+\\)" nil nil (1 'change-log-list-face)))
 237     ;;
 238     ;; Conditionals.
 239     ("\\[!?\\([^]\n]+\\)\\]\\(:\\| (\\)" (1 'change-log-conditionals-face))
 240     ;;
 241     ;; Function of change.
 242     ("<\\([^>\n]+\\)>\\(:\\| (\\)" (1 'change-log-function-face))
 243     ;;
 244     ;; Acknowledgements.
 245     ("\\(^\t\\|  \\)\\(From\\|Patch\\(es\\)? by\\|Report\\(ed by\\| from\\)\\|Suggest\\(ed by\\|ion from\\)\\)"
 246      2 'change-log-acknowledgement-face))
 247   "Additional expressions to highlight in Change Log mode.")
 248
 249 (defvar change-log-mode-map (make-sparse-keymap)
 250   "Keymap for Change Log major mode.")
 251
 252 (defvar change-log-time-zone-rule nil
 253   "Time zone used for calculating change log time stamps.
 254 It takes the same format as the TZ argument of `set-time-zone-rule'.
 255 If nil, use local time.")
 256
 257 (defun add-log-iso8601-time-zone (time)
 258   (let* ((utc-offset (or (car (current-time-zone time)) 0))
 259          (sign (if (< utc-offset 0) ?- ?+))
 260          (sec (abs utc-offset))
 261          (ss (% sec 60))
 262          (min (/ sec 60))
 263          (mm (% min 60))
 264          (hh (/ min 60)))
 265     (format (cond ((not (zerop ss)) "%c%02d:%02d:%02d")
 266                   ((not (zerop mm)) "%c%02d:%02d")
 267                   (t "%c%02d"))
 268             sign hh mm ss)))
 269
 270 (defun add-log-iso8601-time-string ()
 271   (if change-log-time-zone-rule
 272       (let ((tz (getenv "TZ"))
 273             (now (current-time)))
 274         (unwind-protect
 275             (progn
 276               (set-time-zone-rule change-log-time-zone-rule)
 277               (concat
 278                (format-time-string "%Y-%m-%d " now)
 279                (add-log-iso8601-time-zone now)))
 280           (set-time-zone-rule tz)))
 281     (format-time-string "%Y-%m-%d")))
 282
 283 (defun change-log-name ()
 284   "Return (system-dependent) default name for a change log file."
 285   (or change-log-default-name
 286       (if (eq system-type 'vax-vms)
 287           "$CHANGE_LOG$.TXT"
 288         "ChangeLog")))
 289
 290 ;;;###autoload
 291 (defun prompt-for-change-log-name ()
 292   "Prompt for a change log name."
 293   (let* ((default (change-log-name))
 294          (name (expand-file-name
 295                 (read-file-name (format "Log file (default %s): " default)
 296                                 nil default))))
 297     ;; Handle something that is syntactically a directory name.
 298     ;; Look for ChangeLog or whatever in that directory.
 299     (if (string= (file-name-nondirectory name) "")
 300         (expand-file-name (file-name-nondirectory default)
 301                           name)
 302       ;; Handle specifying a file that is a directory.
 303       (if (file-directory-p name)
 304           (expand-file-name (file-name-nondirectory default)
 305                             (file-name-as-directory name))
 306         name))))
 307
 308 (defun change-log-version-number-search ()
 309   "Return version number of current buffer's file.
 310 This is the value returned by `vc-workfile-version' or, if that is
 311 nil, by matching `change-log-version-number-regexp-list'."
 312   (let* ((size (buffer-size))
 313          (end
 314           ;; The version number can be anywhere in the file, but
 315           ;; restrict search to the file beginning: 10% should be
 316           ;; enough to prevent some mishits.
 317           ;;
 318           ;; Apply percentage only if buffer size is bigger than
 319           ;; approx 100 lines.
 320           (if (> size (* 100 80))
 321               (/ size 10)
 322             size))
 323          version)
 324     (or (and buffer-file-name (vc-workfile-version buffer-file-name))
 325         (save-restriction
 326           (widen)
 327           (let ((regexps change-log-version-number-regexp-list))
 328             (while regexps
 329               (save-excursion
 330                 (goto-char (point-min))
 331                 (when (re-search-forward (pop regexps) end t)
 332                   (setq version (match-string 1)
 333                         regexps nil)))))))))
 334
 335
 336 ;;;###autoload
 337 (defun find-change-log (&optional file-name buffer-file)
 338   "Find a change log file for \\[add-change-log-entry] and return the name.
 339
 340 Optional arg FILE-NAME specifies the file to use.
 341 If FILE-NAME is nil, use the value of `change-log-default-name'.
 342 If 'change-log-default-name' is nil, behave as though it were 'ChangeLog'
 343 \(or whatever we use on this operating system).
 344
 345 If 'change-log-default-name' contains a leading directory component, then
 346 simply find it in the current directory.  Otherwise, search in the current
 347 directory and its successive parents for a file so named.
 348
 349 Once a file is found, `change-log-default-name' is set locally in the
 350 current buffer to the complete file name.
 351 Optional arg BUFFER-FILE overrides `buffer-file-name'."
 352   ;; If user specified a file name or if this buffer knows which one to use,
 353   ;; just use that.
 354   (or file-name
 355       (setq file-name (and change-log-default-name
 356                            (file-name-directory change-log-default-name)
 357                            change-log-default-name))
 358       (progn
 359         ;; Chase links in the source file
 360         ;; and use the change log in the dir where it points.
 361         (setq file-name (or (and (or buffer-file buffer-file-name)
 362                                  (file-name-directory
 363                                   (file-chase-links
 364                                    (or buffer-file buffer-file-name))))
 365                             default-directory))
 366         (if (file-directory-p file-name)
 367             (setq file-name (expand-file-name (change-log-name) file-name)))
 368         ;; Chase links before visiting the file.
 369         ;; This makes it easier to use a single change log file
 370         ;; for several related directories.
 371         (setq file-name (file-chase-links file-name))
 372         (setq file-name (expand-file-name file-name))
 373         ;; Move up in the dir hierarchy till we find a change log file.
 374         (let ((file1 file-name)
 375               parent-dir)
 376           (while (and (not (or (get-file-buffer file1) (file-exists-p file1)))
 377                       (progn (setq parent-dir
 378                                    (file-name-directory
 379                                     (directory-file-name
 380                                      (file-name-directory file1))))
 381                              ;; Give up if we are already at the root dir.
 382                              (not (string= (file-name-directory file1)
 383                                            parent-dir))))
 384             ;; Move up to the parent dir and try again.
 385             (setq file1 (expand-file-name
 386                          (file-name-nondirectory (change-log-name))
 387                          parent-dir)))
 388           ;; If we found a change log in a parent, use that.
 389           (if (or (get-file-buffer file1) (file-exists-p file1))
 390               (setq file-name file1)))))
 391   ;; Make a local variable in this buffer so we needn't search again.
 392   (set (make-local-variable 'change-log-default-name) file-name)
 393   file-name)
 394
 395 (defun add-log-file-name (buffer-file log-file)
 396   ;; Never want to add a change log entry for the ChangeLog file itself.
 397   (unless (or (null buffer-file) (string= buffer-file log-file))
 398     (if add-log-file-name-function
 399         (funcall add-log-file-name-function buffer-file)
 400       (setq buffer-file
 401             (if (string-match
 402                  (concat "^" (regexp-quote (file-name-directory log-file)))
 403                  buffer-file)
 404                 (substring buffer-file (match-end 0))
 405               (file-name-nondirectory buffer-file)))
 406       ;; If we have a backup file, it's presumably because we're
 407       ;; comparing old and new versions (e.g. for deleted
 408       ;; functions) and we'll want to use the original name.
 409       (if (backup-file-name-p buffer-file)
 410           (file-name-sans-versions buffer-file)
 411         buffer-file))))
 412
 413 ;;;###autoload
 414 (defun add-change-log-entry (&optional whoami file-name other-window new-entry)
 415   "Find change log file, and add an entry for today and an item for this file.
 416 Optional arg WHOAMI (interactive prefix) non-nil means prompt for user
 417 name and site.
 418
 419 Second arg FILE-NAME is file name of the change log.
 420 If nil, use the value of `change-log-default-name'.
 421
 422 Third arg OTHER-WINDOW non-nil means visit in other window.
 423
 424 Fourth arg NEW-ENTRY non-nil means always create a new entry at the front;
 425 never append to an existing entry.  Option `add-log-keep-changes-together'
 426 otherwise affects whether a new entry is created.
 427
 428 Option `add-log-always-start-new-record' non-nil means always create a
 429 new record, even when the last record was made on the same date and by
 430 the same person.
 431
 432 The change log file can start with a copyright notice and a copying
 433 permission notice.  The first blank line indicates the end of these
 434 notices.
 435
 436 Today's date is calculated according to `change-log-time-zone-rule' if
 437 non-nil, otherwise in local time."
 438   (interactive (list current-prefix-arg
 439                      (prompt-for-change-log-name)))
 440   (or add-log-full-name
 441       (setq add-log-full-name (user-full-name)))
 442   (or add-log-mailing-address
 443       (setq add-log-mailing-address user-mail-address))
 444   (if whoami
 445       (progn
 446         (setq add-log-full-name (read-input "Full name: " add-log-full-name))
 447          ;; Note that some sites have room and phone number fields in
 448          ;; full name which look silly when inserted.  Rather than do
 449          ;; anything about that here, let user give prefix argument so that
 450          ;; s/he can edit the full name field in prompter if s/he wants.
 451         (setq add-log-mailing-address
 452               (read-input "Mailing address: " add-log-mailing-address))))
 453
 454   (let* ((defun (add-log-current-defun))
 455          (version (and change-log-version-info-enabled
 456                        (change-log-version-number-search)))
 457          (buf-file-name (if add-log-buffer-file-name-function
 458                             (funcall add-log-buffer-file-name-function)
 459                           buffer-file-name))
 460          (buffer-file (if buf-file-name (expand-file-name buf-file-name)))
 461          (file-name (expand-file-name
 462                      (or file-name (find-change-log file-name buffer-file))))
 463          ;; Set ITEM to the file name to use in the new item.
 464          (item (add-log-file-name buffer-file file-name))
 465          bound)
 466
 467     (unless (equal file-name buffer-file-name)
 468       (if (or other-window (window-dedicated-p (selected-window)))
 469           (find-file-other-window file-name)
 470         (find-file file-name)))
 471     (or (eq major-mode 'change-log-mode)
 472         (change-log-mode))
 473     (undo-boundary)
 474     (goto-char (point-min))
 475
 476     ;; If file starts with a copyright and permission notice, skip them.
 477     ;; Assume they end at first blank line.
 478     (when (looking-at "Copyright")
 479       (search-forward "\n\n")
 480       (skip-chars-forward "\n"))
 481
 482     ;; Advance into first entry if it is usable; else make new one.
 483     (let ((new-entries (mapcar (lambda (addr)
 484                                  (concat (funcall add-log-time-format)
 485                                          "  " add-log-full-name
 486                                          "  <" addr ">"))
 487                                (if (consp add-log-mailing-address)
 488                                    add-log-mailing-address
 489                                  (list add-log-mailing-address)))))
 490       (if (and (not add-log-always-start-new-record)
 491                (let ((hit nil))
 492                  (dolist (entry new-entries hit)
 493                    (when (looking-at (regexp-quote entry))
 494                      (setq hit t)))))
 495           (forward-line 1)
 496         (insert (nth (random (length new-entries))
 497                      new-entries)
 498                 "\n\n")
 499         (forward-line -1)))
 500
 501     ;; Determine where we should stop searching for a usable
 502     ;; item to add to, within this entry.
 503     (setq bound
 504           (save-excursion
 505             (if (looking-at "\n*[^\n* \t]")
 506                 (skip-chars-forward "\n")
 507               (if add-log-keep-changes-together
 508                   (forward-page)        ; page delimits entries for date
 509                 (forward-paragraph)))   ; paragraph delimits entries for file
 510             (point)))
 511
 512     ;; Now insert the new line for this item.
 513     (cond ((re-search-forward "^\\s *\\*\\s *$" bound t)
 514            ;; Put this file name into the existing empty item.
 515            (if item
 516                (insert item)))
 517           ((and (not new-entry)
 518                 (let (case-fold-search)
 519                   (re-search-forward
 520                    (concat (regexp-quote (concat "* " item))
 521                            ;; Don't accept `foo.bar' when
 522                            ;; looking for `foo':
 523                            "\\(\\s \\|[(),:]\\)")
 524                    bound t)))
 525            ;; Add to the existing item for the same file.
 526            (re-search-forward "^\\s *$\\|^\\s \\*")
 527            (goto-char (match-beginning 0))
 528            ;; Delete excess empty lines; make just 2.
 529            (while (and (not (eobp)) (looking-at "^\\s *$"))
 530              (delete-region (point) (line-beginning-position 2)))
 531            (insert-char ?\n 2)
 532            (forward-line -2)
 533            (indent-relative-maybe))
 534           (t
 535            ;; Make a new item.
 536            (while (looking-at "\\sW")
 537              (forward-line 1))
 538            (while (and (not (eobp)) (looking-at "^\\s *$"))
 539              (delete-region (point) (line-beginning-position 2)))
 540            (insert-char ?\n 3)
 541            (forward-line -2)
 542            (indent-to left-margin)
 543            (insert "* ")
 544            (if item (insert item))))
 545     ;; Now insert the function name, if we have one.
 546     ;; Point is at the item for this file,
 547     ;; either at the end of the line or at the first blank line.
 548     (if (not defun)
 549         ;; No function name, so put in a colon unless we have just a star.
 550         (unless (save-excursion
 551                   (beginning-of-line 1)
 552                   (looking-at "\\s *\\(\\*\\s *\\)?$"))
 553           (insert ": ")
 554           (if version (insert version ?\ )))
 555       ;; Make it easy to get rid of the function name.
 556       (undo-boundary)
 557       (unless (save-excursion
 558                 (beginning-of-line 1)
 559                 (looking-at "\\s *$"))
 560         (insert ?\ ))
 561       ;; See if the prev function name has a message yet or not.
 562       ;; If not, merge the two items.
 563       (let ((pos (point-marker)))
 564         (skip-syntax-backward " ")
 565         (skip-chars-backward "):")
 566         (if (and (looking-at "):")
 567                  (> fill-column (+ (current-column) (length defun) 4)))
 568             (progn (delete-region (point) pos) (insert ", "))
 569           (if (looking-at "):")
 570               (delete-region (+ 1 (point)) (line-end-position)))
 571           (goto-char pos)
 572           (insert "("))
 573         (set-marker pos nil))
 574       (insert defun "): ")
 575       (if version (insert version ?\ )))))
 576
 577 ;;;###autoload
 578 (defun add-change-log-entry-other-window (&optional whoami file-name)
 579   "Find change log file in other window and add entry and item.
 580 This is just like `add-change-log-entry' except that it displays
 581 the change log file in another window."
 582   (interactive (if current-prefix-arg
 583                    (list current-prefix-arg
 584                          (prompt-for-change-log-name))))
 585   (add-change-log-entry whoami file-name t))
 586 ;;;###autoload (define-key ctl-x-4-map "a" 'add-change-log-entry-other-window)
 587
 588 ;;;###autoload
 589 (define-derived-mode change-log-mode text-mode "Change Log"
 590   "Major mode for editing change logs; like Indented Text Mode.
 591 Prevents numeric backups and sets `left-margin' to 8 and `fill-column' to 74.
 592 New log entries are usually made with \\[add-change-log-entry] or \\[add-change-log-entry-other-window].
 593 Each entry behaves as a paragraph, and the entries for one day as a page.
 594 Runs `change-log-mode-hook'."
 595   (setq left-margin 8
 596         fill-column 74
 597         indent-tabs-mode t
 598         tab-width 8)
 599   (set (make-local-variable 'fill-paragraph-function)
 600        'change-log-fill-paragraph)
 601   (set (make-local-variable 'indent-line-function) 'indent-to-left-margin)
 602   ;; We really do want "^" in paragraph-start below: it is only the
 603   ;; lines that begin at column 0 (despite the left-margin of 8) that
 604   ;; we are looking for.  Adding `* ' allows eliding the blank line
 605   ;; between entries for different files.
 606   (set (make-local-variable 'paragraph-start) "\\s *$\\|\f\\|^\\<")
 607   (set (make-local-variable 'paragraph-separate) paragraph-start)
 608   ;; Match null string on the date-line so that the date-line
 609   ;; is grouped with what follows.
 610   (set (make-local-variable 'page-delimiter) "^\\<\\|^\f")
 611   (set (make-local-variable 'version-control) 'never)
 612   (set (make-local-variable 'smerge-resolve-function)
 613        'change-log-resolve-conflict)
 614   (set (make-local-variable 'adaptive-fill-regexp) "\\s *")
 615   (set (make-local-variable 'font-lock-defaults)
 616        '(change-log-font-lock-keywords t nil nil backward-paragraph)))
 617
 618 ;; It might be nice to have a general feature to replace this.  The idea I
 619 ;; have is a variable giving a regexp matching text which should not be
 620 ;; moved from bol by filling.  change-log-mode would set this to "^\\s *\\s(".
 621 ;; But I don't feel up to implementing that today.
 622 (defun change-log-fill-paragraph (&optional justify)
 623   "Fill the paragraph, but preserve open parentheses at beginning of lines.
 624 Prefix arg means justify as well."
 625   (interactive "P")
 626   (let ((end (progn (forward-paragraph) (point)))
 627         (beg (progn (backward-paragraph) (point)))
 628         (paragraph-start (concat paragraph-start "\\|\\s *\\s(")))
 629     (fill-region beg end justify)
 630     t))
 631 \f
 632 (defcustom add-log-current-defun-header-regexp
 633   "^\\([[:upper:]][[:upper:]_ ]*[[:upper:]_]\\|[-_[:alpha:]]+\\)[ \t]*[:=]"
 634   "*Heuristic regexp used by `add-log-current-defun' for unknown major modes."
 635   :type 'regexp
 636   :group 'change-log)
 637
 638 ;;;###autoload
 639 (defvar add-log-lisp-like-modes
 640     '(emacs-lisp-mode lisp-mode scheme-mode dsssl-mode lisp-interaction-mode)
 641   "*Modes that look like Lisp to `add-log-current-defun'.")
 642
 643 ;;;###autoload
 644 (defvar add-log-c-like-modes
 645     '(c-mode c++-mode c++-c-mode objc-mode)
 646   "*Modes that look like C to `add-log-current-defun'.")
 647
 648 ;;;###autoload
 649 (defvar add-log-tex-like-modes
 650     '(TeX-mode plain-TeX-mode LaTeX-mode plain-tex-mode latex-mode)
 651   "*Modes that look like TeX to `add-log-current-defun'.")
 652
 653 ;;;###autoload
 654 (defun add-log-current-defun ()
 655   "Return name of function definition point is in, or nil.
 656
 657 Understands C, Lisp, LaTeX (\"functions\" are chapters, sections, ...),
 658 Texinfo (@node titles) and Perl.
 659
 660 Other modes are handled by a heuristic that looks in the 10K before
 661 point for uppercase headings starting in the first column or
 662 identifiers followed by `:' or `='.  See variables
 663 `add-log-current-defun-header-regexp' and
 664 `add-log-current-defun-function'.
 665
 666 Has a preference of looking backwards."
 667   (condition-case nil
 668       (save-excursion
 669         (let ((location (point)))
 670           (cond (add-log-current-defun-function
 671                  (funcall add-log-current-defun-function))
 672                 ((memq major-mode add-log-lisp-like-modes)
 673                  ;; If we are now precisely at the beginning of a defun,
 674                  ;; make sure beginning-of-defun finds that one
 675                  ;; rather than the previous one.
 676                  (or (eobp) (forward-char 1))
 677                  (beginning-of-defun)
 678                  ;; Make sure we are really inside the defun found,
 679                  ;; not after it.
 680                  (when (and (looking-at "\\s(")
 681                             (progn (end-of-defun)
 682                                    (< location (point)))
 683                             (progn (forward-sexp -1)
 684                                    (>= location (point))))
 685                    (if (looking-at "\\s(")
 686                        (forward-char 1))
 687                    ;; Skip the defining construct name, typically "defun"
 688                    ;; or "defvar".
 689                    (forward-sexp 1)
 690                    ;; The second element is usually a symbol being defined.
 691                    ;; If it is not, use the first symbol in it.
 692                    (skip-chars-forward " \t\n'(")
 693                    (buffer-substring-no-properties (point)
 694                                                    (progn (forward-sexp 1)
 695                                                           (point)))))
 696                 ((and (memq major-mode add-log-c-like-modes)
 697                       (save-excursion
 698                         (beginning-of-line)
 699                         ;; Use eq instead of = here to avoid
 700                         ;; error when at bob and char-after
 701                         ;; returns nil.
 702                         (while (eq (char-after (- (point) 2)) ?\\)
 703                           (forward-line -1))
 704                         (looking-at "[ \t]*#[ \t]*define[ \t]")))
 705                  ;; Handle a C macro definition.
 706                  (beginning-of-line)
 707                  (while (eq (char-after (- (point) 2)) ?\\) ;not =; note above
 708                    (forward-line -1))
 709                  (search-forward "define")
 710                  (skip-chars-forward " \t")
 711                  (buffer-substring-no-properties (point)
 712                                                  (progn (forward-sexp 1)
 713                                                         (point))))
 714                 ((memq major-mode add-log-c-like-modes)
 715                  (beginning-of-line)
 716                  ;; See if we are in the beginning part of a function,
 717                  ;; before the open brace.  If so, advance forward.
 718                  (while (not (looking-at "{\\|\\(\\s *$\\)"))
 719                    (forward-line 1))
 720                  (or (eobp)
 721                      (forward-char 1))
 722                  (beginning-of-defun)
 723                  (when (progn (end-of-defun)
 724                               (< location (point)))
 725                    (backward-sexp 1)
 726                    (let (beg tem)
 727
 728                      (forward-line -1)
 729                      ;; Skip back over typedefs of arglist.
 730                      (while (and (not (bobp))
 731                                  (looking-at "[ \t\n]"))
 732                        (forward-line -1))
 733                      ;; See if this is using the DEFUN macro used in Emacs,
 734                      ;; or the DEFUN macro used by the C library.
 735                      (if (condition-case nil
 736                              (and (save-excursion
 737                                     (end-of-line)
 738                                     (while (= (preceding-char) ?\\)
 739                                       (end-of-line 2))
 740                                     (backward-sexp 1)
 741                                     (beginning-of-line)
 742                                     (setq tem (point))
 743                                     (looking-at "DEFUN\\b"))
 744                                   (>= location tem))
 745                            (error nil))
 746                          (progn
 747                            (goto-char tem)
 748                            (down-list 1)
 749                            (if (= (char-after (point)) ?\")
 750                                (progn
 751                                  (forward-sexp 1)
 752                                  (skip-chars-forward " ,")))
 753                            (buffer-substring-no-properties
 754                             (point)
 755                             (progn (forward-sexp 1)
 756                                    (point))))
 757                        (if (looking-at "^[+-]")
 758                            (change-log-get-method-definition)
 759                          ;; Ordinary C function syntax.
 760                          (setq beg (point))
 761                          (if (and
 762                               ;; Protect against "Unbalanced parens" error.
 763                               (condition-case nil
 764                                   (progn
 765                                     (down-list 1) ; into arglist
 766                                     (backward-up-list 1)
 767                                     (skip-chars-backward " \t")
 768                                     t)
 769                                 (error nil))
 770                               ;; Verify initial pos was after
 771                               ;; real start of function.
 772                               (save-excursion
 773                                 (goto-char beg)
 774                                 ;; For this purpose, include the line
 775                                 ;; that has the decl keywords.  This
 776                                 ;; may also include some of the
 777                                 ;; comments before the function.
 778                                 (while (and (not (bobp))
 779                                             (save-excursion
 780                                               (forward-line -1)
 781                                               (looking-at "[^\n\f]")))
 782                                   (forward-line -1))
 783                                 (>= location (point)))
 784                               ;; Consistency check: going down and up
 785                               ;; shouldn't take us back before BEG.
 786                               (> (point) beg))
 787                              (let (end middle)
 788                                ;; Don't include any final whitespace
 789                                ;; in the name we use.
 790                                (skip-chars-backward " \t\n")
 791                                (setq end (point))
 792                                (backward-sexp 1)
 793                                ;; Now find the right beginning of the name.
 794                                ;; Include certain keywords if they
 795                                ;; precede the name.
 796                                (setq middle (point))
 797                                (forward-word -1)
 798                                ;; Ignore these subparts of a class decl
 799                                ;; and move back to the class name itself.
 800                                (while (looking-at "public \\|private ")
 801                                  (skip-chars-backward " \t:")
 802                                  (setq end (point))
 803                                  (backward-sexp 1)
 804                                  (setq middle (point))
 805                                  (forward-word -1))
 806                                (and (bolp)
 807                                     (looking-at
 808                                      "enum \\|struct \\|union \\|class ")
 809                                     (setq middle (point)))
 810                                (goto-char end)
 811                                (when (eq (preceding-char) ?=)
 812                                  (forward-char -1)
 813                                  (skip-chars-backward " \t")
 814                                  (setq end (point)))
 815                                (buffer-substring-no-properties
 816                                 middle end))))))))
 817                 ((memq major-mode add-log-tex-like-modes)
 818                  (if (re-search-backward
 819                       "\\\\\\(sub\\)*\\(section\\|paragraph\\|chapter\\)"
 820                       nil t)
 821                      (progn
 822                        (goto-char (match-beginning 0))
 823                        (buffer-substring-no-properties
 824                         (1+ (point))    ; without initial backslash
 825                         (line-end-position)))))
 826                 ((eq major-mode 'texinfo-mode)
 827                  (if (re-search-backward "^@node[ \t]+\\([^,\n]+\\)" nil t)
 828                      (match-string-no-properties 1)))
 829                 ((memq major-mode '(perl-mode cperl-mode))
 830                  (if (re-search-backward "^sub[ \t]+\\([^({ \t\n]+\\)" nil t)
 831                      (match-string-no-properties 1)))
 832                 ;; Emacs's autoconf-mode installs its own
 833                 ;; `add-log-current-defun-function'.  This applies to
 834                 ;; a different mode apparently for editing .m4
 835                 ;; autoconf source.
 836                 ((eq major-mode 'autoconf-mode)
 837                  (if (re-search-backward
 838                       "^\\(\\(m4_\\)?define\\|A._DEFUN\\)(\\[?\\([A-Za-z0-9_]+\\)" nil t)
 839                      (match-string-no-properties 3)))
 840                 (t
 841                  ;; If all else fails, try heuristics
 842                  (let (case-fold-search
 843                        result)
 844                    (end-of-line)
 845                    (when (re-search-backward
 846                           add-log-current-defun-header-regexp
 847                           (- (point) 10000)
 848                           t)
 849                      (setq result (or (match-string-no-properties 1)
 850                                       (match-string-no-properties 0)))
 851                      ;; Strip whitespace away
 852                      (when (string-match "\\([^ \t\n\r\f].*[^ \t\n\r\f]\\)"
 853                                          result)
 854                        (setq result (match-string-no-properties 1 result)))
 855                      result))))))
 856     (error nil)))
 857
 858 (defvar change-log-get-method-definition-md)
 859
 860 ;; Subroutine used within change-log-get-method-definition.
 861 ;; Add the last match in the buffer to the end of `md',
 862 ;; followed by the string END; move to the end of that match.
 863 (defun change-log-get-method-definition-1 (end)
 864   (setq change-log-get-method-definition-md
 865         (concat change-log-get-method-definition-md
 866                 (match-string 1)
 867                 end))
 868   (goto-char (match-end 0)))
 869
 870 (defun change-log-get-method-definition ()
 871 "For objective C, return the method name if we are in a method."
 872   (let ((change-log-get-method-definition-md "["))
 873     (save-excursion
 874       (if (re-search-backward "^@implementation\\s-*\\([A-Za-z_]*\\)" nil t)
 875           (change-log-get-method-definition-1 " ")))
 876     (save-excursion
 877       (cond
 878        ((re-search-forward "^\\([-+]\\)[ \t\n\f\r]*\\(([^)]*)\\)?\\s-*" nil t)
 879         (change-log-get-method-definition-1 "")
 880         (while (not (looking-at "[{;]"))
 881           (looking-at
 882            "\\([A-Za-z_]*:?\\)\\s-*\\(([^)]*)\\)?[A-Za-z_]*[ \t\n\f\r]*")
 883           (change-log-get-method-definition-1 ""))
 884         (concat change-log-get-method-definition-md "]"))))))
 885 \f
 886 (defun change-log-sortable-date-at ()
 887   "Return date of log entry in a consistent form for sorting.
 888 Point is assumed to be at the start of the entry."
 889   (require 'timezone)
 890   (if (looking-at "^\\sw.........[0-9:+ ]*")
 891       (let ((date (match-string-no-properties 0)))
 892         (if date
 893             (if (string-match "\\(....\\)-\\(..\\)-\\(..\\)\\s-+" date)
 894                 (concat (match-string 1 date) (match-string 2 date)
 895                         (match-string 3 date))
 896               (condition-case nil
 897                   (timezone-make-date-sortable date)
 898                 (error nil)))))
 899     (error "Bad date")))
 900
 901 (defun change-log-resolve-conflict ()
 902   "Function to be used in `smerge-resolve-function'."
 903   (let ((buf (current-buffer)))
 904     (with-temp-buffer
 905       (insert-buffer-substring buf (match-beginning 1) (match-end 1))
 906       (save-match-data (change-log-mode))
 907       (let ((other-buf (current-buffer)))
 908         (with-current-buffer buf
 909           (save-excursion
 910             (save-restriction
 911               (narrow-to-region (match-beginning 0) (match-end 0))
 912               (replace-match (match-string 3) t t)
 913               (change-log-merge other-buf))))))))
 914
 915 ;;;###autoload
 916 (defun change-log-merge (other-log)
 917   "Merge the contents of ChangeLog file OTHER-LOG with this buffer.
 918 Both must be found in Change Log mode (since the merging depends on
 919 the appropriate motion commands).  OTHER-LOG can be either a file name
 920 or a buffer.
 921
 922 Entries are inserted in chronological order.  Both the current and
 923 old-style time formats for entries are supported."
 924   (interactive "*fLog file name to merge: ")
 925   (if (not (eq major-mode 'change-log-mode))
 926       (error "Not in Change Log mode"))
 927   (let ((other-buf (if (bufferp other-log) other-log
 928                      (find-file-noselect other-log)))
 929         (buf (current-buffer))
 930         date1 start end)
 931     (save-excursion
 932       (goto-char (point-min))
 933       (set-buffer other-buf)
 934       (goto-char (point-min))
 935       (if (not (eq major-mode 'change-log-mode))
 936           (error "%s not found in Change Log mode" other-log))
 937       ;; Loop through all the entries in OTHER-LOG.
 938       (while (not (eobp))
 939         (setq date1 (change-log-sortable-date-at))
 940         (setq start (point)
 941               end (progn (forward-page) (point)))
 942         ;; Look for an entry in original buffer that isn't later.
 943         (with-current-buffer buf
 944           (while (and (not (eobp))
 945                       (string< date1 (change-log-sortable-date-at)))
 946             (forward-page))
 947           (if (not (eobp))
 948               (insert-buffer-substring other-buf start end)
 949             ;; At the end of the original buffer, insert a newline to
 950             ;; separate entries and then the rest of the file being
 951             ;; merged.
 952             (unless (or (bobp)
 953                         (and (= ?\n (char-before))
 954                              (or (<= (1- (point)) (point-min))
 955                                  (= ?\n (char-before (1- (point)))))))
 956               (insert "\n"))
 957             ;; Move to the end of it to terminate outer loop.
 958             (with-current-buffer other-buf
 959               (goto-char (point-max)))
 960             (insert-buffer-substring other-buf start)))))))
 961
 962 ;;;###autoload
 963 (defun change-log-redate ()
 964   "Fix any old-style date entries in the current log file to default format."
 965   (interactive)
 966   (require 'timezone)
 967   (save-excursion
 968     (goto-char (point-min))
 969     (while (re-search-forward "^\\sw.........[0-9:+ ]*" nil t)
 970       (unless (= 12 (- (match-end 0) (match-beginning 0)))
 971         (let* ((date (save-match-data
 972                        (timezone-fix-time (match-string 0) nil nil)))
 973                (zone (if (consp (aref date 6))
 974                          (nth 1 (aref date 6)))))
 975           (replace-match (format-time-string
 976                           "%Y-%m-%d  "
 977                           (encode-time (aref date 5)
 978                                        (aref date 4)
 979                                        (aref date 3)
 980                                        (aref date 2)
 981                                        (aref date 1)
 982                                        (aref date 0)
 983                                        zone))))))))
 984
 985 (provide 'add-log)
 986
 987 ;;; add-log.el ends here