lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997-1999, 2001-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Introduction:
  28 ;;
  29 ;; Whenever a file that Emacs is editing has been changed by another
  30 ;; program the user normally has to execute the command `revert-buffer'
  31 ;; to load the new content of the file into Emacs.
  32 ;;
  33 ;; This package contains two minor modes: Global Auto-Revert Mode and
  34 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  35 ;; whenever the corresponding files have been changed on disk and the
  36 ;; buffer contains no unsaved changes.
  37 ;;
  38 ;; Auto-Revert Mode can be activated for individual buffers.  Global
  39 ;; Auto-Revert Mode applies to all file buffers. (If the user option
  40 ;; `global-auto-revert-non-file-buffers' is non-nil, it also applies
  41 ;; to some non-file buffers.  This option is disabled by default.)
  42 ;;
  43 ;; Since checking a remote file is slow, these modes check or revert
  44 ;; remote files only if the user option `auto-revert-remote-files' is
  45 ;; non-nil.  It is recommended to disable version control for remote
  46 ;; files.
  47 ;;
  48 ;; Both modes operate by checking the time stamp of all files at
  49 ;; intervals of `auto-revert-interval'.  The default is every five
  50 ;; seconds.  The check is aborted whenever the user actually uses
  51 ;; Emacs.  You should never even notice that this package is active
  52 ;; (except that your buffers will be reverted, of course).
  53 ;;
  54 ;; If Emacs is compiled with file notification support, notifications
  55 ;; are used instead of checking the time stamp of the files.  You can
  56 ;; disable this by setting the user option `auto-revert-use-notify' to
  57 ;; nil.  Alternatively, a regular expression of directories to be
  58 ;; excluded from file notifications can be specified by
  59 ;; `auto-revert-notify-exclude-dir-regexp'.
  60 ;;
  61 ;; After reverting a file buffer, Auto Revert Mode normally puts point
  62 ;; at the same position that a regular manual revert would.  However,
  63 ;; there is one exception to this rule.  If point is at the end of the
  64 ;; buffer before reverting, it stays at the end.  Similarly if point
  65 ;; is displayed at the end of a file buffer in any window, it will stay
  66 ;; at the end of the buffer in that window, even if the window is not
  67 ;; selected.  This way, you can use Auto Revert Mode to `tail' a file.
  68 ;; Just put point at the end of the buffer and it will stay there.
  69 ;; These rules apply to file buffers. For non-file buffers, the
  70 ;; behavior may be mode dependent.
  71 ;;
  72 ;; While you can use Auto Revert Mode to tail a file, this package
  73 ;; contains a third minor mode, Auto Revert Tail Mode, which does so
  74 ;; more efficiently, as long as you are sure that the file will only
  75 ;; change by growing at the end.  It only appends the new output,
  76 ;; instead of reverting the entire buffer.  It does so even if the
  77 ;; buffer contains unsaved changes.  (Because they will not be lost.)
  78
  79 ;; Usage:
  80 ;;
  81 ;; Go to the appropriate buffer and press either of:
  82 ;;   M-x auto-revert-mode RET
  83 ;;   M-x auto-revert-tail-mode RET
  84 ;;
  85 ;; To activate Global Auto-Revert Mode, press:
  86 ;;   M-x global-auto-revert-mode RET
  87 ;;
  88 ;; To activate Global Auto-Revert Mode every time Emacs is started
  89 ;; customize the option `global-auto-revert-mode' or the following
  90 ;; line could be added to your ~/.emacs:
  91 ;;   (global-auto-revert-mode 1)
  92 ;;
  93 ;; The function `turn-on-auto-revert-mode' could be added to any major
  94 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  95 ;; mode.  For example, the following line will activate Auto-Revert
  96 ;; Mode in all C mode buffers:
  97 ;;
  98 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  99
 100 ;;; Code:
 101
 102 ;; Dependencies:
 103
 104 (eval-when-compile (require 'cl-lib))
 105 (require 'timer)
 106
 107 ;; Custom Group:
 108 ;;
 109 ;; The two modes will be placed next to Auto Save Mode under the
 110 ;; Files group under Emacs.
 111
 112 (defgroup auto-revert nil
 113   "Revert individual buffers when files on disk change.
 114 Auto-Revert mode enables auto-revert in individual buffers.
 115 Global Auto-Revert mode does so in all buffers."
 116   :group 'files
 117   :group 'convenience)
 118
 119
 120 ;; Variables:
 121
 122 ;;; What's this?: ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 123 ;;; What's this?: ;;;###autoload
 124 (defvar auto-revert-mode nil
 125   "Non-nil when Auto-Revert Mode is active.
 126 Never set this variable directly, use the command `auto-revert-mode' instead.")
 127 (put 'auto-revert-mode 'permanent-local t)
 128
 129 (defvar auto-revert-tail-mode nil
 130   "Non-nil when Auto-Revert Tail Mode is active.
 131 Never set this variable directly, use the command
 132 `auto-revert-tail-mode' instead.")
 133 (put 'auto-revert-tail-mode 'permanent-local t)
 134
 135 (defvar auto-revert-timer nil
 136   "Timer used by Auto-Revert Mode.")
 137
 138 (defcustom auto-revert-interval 5
 139   "Time, in seconds, between Auto-Revert Mode file checks.
 140 The value may be an integer or floating point number.
 141
 142 If a timer is already active, there are two ways to make sure
 143 that the new value will take effect immediately.  You can set
 144 this variable through Custom or you can call the command
 145 `auto-revert-set-timer' after setting the variable.  Otherwise,
 146 the new value will take effect the first time Auto Revert Mode
 147 calls `auto-revert-set-timer' for internal reasons or in your
 148 next editing session."
 149   :group 'auto-revert
 150   :type 'number
 151   :set (lambda (variable value)
 152          (set-default variable value)
 153          (and (boundp 'auto-revert-timer)
 154               auto-revert-timer
 155               (auto-revert-set-timer))))
 156
 157 (defcustom auto-revert-stop-on-user-input t
 158   "When non-nil, user input temporarily interrupts Auto-Revert Mode.
 159 With this setting, Auto-Revert Mode checks for user input after
 160 handling each buffer and does not process any further buffers
 161 \(until the next run of the timer) if user input is available.
 162 When nil, Auto-Revert Mode checks files and reverts buffers,
 163 with quitting disabled, without paying attention to user input.
 164 Thus, with this setting, Emacs might be non-responsive at times."
 165   :group 'auto-revert
 166   :type 'boolean)
 167
 168 (defcustom auto-revert-verbose t
 169   "When nil, Auto-Revert Mode does not generate any messages.
 170 When non-nil, a message is generated whenever a file is reverted."
 171   :group 'auto-revert
 172   :type 'boolean)
 173
 174 (defcustom auto-revert-mode-text " ARev"
 175   "String to display in the mode line when Auto-Revert Mode is active.
 176
 177 \(When the string is not empty, make sure that it has a leading space.)"
 178   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 179   :group 'auto-revert
 180   :type 'string)
 181
 182 (defcustom auto-revert-tail-mode-text " Tail"
 183   "String to display in the mode line when Auto-Revert Tail Mode is active.
 184
 185 \(When the string is not empty, make sure that it has a leading space.)"
 186   :group 'auto-revert
 187   :type 'string
 188   :version "22.1")
 189
 190 (defcustom auto-revert-mode-hook nil
 191   "Functions to run when Auto-Revert Mode is activated."
 192   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 193   :group 'auto-revert
 194   :type 'hook)
 195
 196 (defcustom global-auto-revert-mode-text ""
 197   "String to display when Global Auto-Revert Mode is active.
 198
 199 The default is nothing since when this mode is active this text doesn't
 200 vary over time, or between buffers.  Hence mode line text
 201 would only waste precious space."
 202   :group 'auto-revert
 203   :type 'string)
 204
 205 (defcustom global-auto-revert-mode-hook nil
 206   "Hook called when Global Auto-Revert Mode is activated."
 207   :group 'auto-revert
 208   :type 'hook)
 209
 210 (defcustom global-auto-revert-non-file-buffers nil
 211   "When nil, Global Auto-Revert mode operates only on file-visiting buffers.
 212
 213 When non-nil, both file buffers and buffers with a custom
 214 `revert-buffer-function' and a `buffer-stale-function' are
 215 reverted by Global Auto-Revert mode.  These include the Buffer
 216 List buffer displayed by `buffer-menu', and Dired buffers showing
 217 complete local directories.  The Buffer List buffer reverts every
 218 `auto-revert-interval' seconds; Dired buffers when the file list of
 219 the main directory changes.  Dired buffers do not auto-revert as
 220 a result of changes in subdirectories, or in the contents, size,
 221 modes, etc., of files.  You may still sometimes want to revert
 222 them manually.
 223
 224 Use this option with care since it could lead to excessive auto-reverts.
 225 For more information, see Info node `(emacs)Autorevert'."
 226   :group 'auto-revert
 227   :type 'boolean
 228   :link '(info-link "(emacs)Autorevert"))
 229
 230 (defcustom global-auto-revert-ignore-modes ()
 231   "List of major modes Global Auto-Revert Mode should not check."
 232   :group 'auto-revert
 233   :type '(repeat sexp))
 234
 235 (defcustom auto-revert-load-hook nil
 236   "Functions to run when Auto-Revert Mode is first loaded."
 237   :tag "Load Hook"
 238   :group 'auto-revert
 239   :type 'hook)
 240
 241 (defcustom auto-revert-check-vc-info nil
 242   "If non-nil Auto Revert Mode reliably updates version control info.
 243 Auto Revert Mode updates version control info whenever the buffer
 244 needs reverting, regardless of the value of this variable.
 245 However, the version control state can change without changes to
 246 the work file.  If the change is made from the current Emacs
 247 session, all info is updated.  But if, for instance, a new
 248 version is checked in from outside the current Emacs session, the
 249 version control number in the mode line, as well as other version
 250 control related information, may not be properly updated.  If you
 251 are worried about this, set this variable to a non-nil value.
 252
 253 This currently works by automatically updating the version
 254 control info every `auto-revert-interval' seconds.  Nevertheless,
 255 it should not cause excessive CPU usage on a reasonably fast
 256 machine, if it does not apply to too many version controlled
 257 buffers.  CPU usage depends on the version control system."
 258   :group 'auto-revert
 259   :type 'boolean
 260   :version "22.1")
 261
 262 (defvar global-auto-revert-ignore-buffer nil
 263   "When non-nil, Global Auto-Revert Mode will not revert this buffer.
 264 This variable becomes buffer local when set in any fashion.")
 265 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 266
 267 (defcustom auto-revert-remote-files nil
 268   "If non-nil remote files are also reverted."
 269   :group 'auto-revert
 270   :type 'boolean
 271   :version "24.4")
 272
 273 (defconst auto-revert-notify-enabled
 274   (or (featurep 'inotify) (featurep 'w32notify))
 275   "Non-nil when Emacs has been compiled with file notification support.")
 276
 277 (defcustom auto-revert-use-notify auto-revert-notify-enabled
 278   "If non-nil Auto Revert Mode uses file notification functions.
 279 This requires Emacs being compiled with file notification
 280 support (see `auto-revert-notify-enabled').  You should set this
 281 variable through Custom only."
 282   :group 'auto-revert
 283   :type 'boolean
 284   :set (lambda (variable value)
 285          (set-default variable (and auto-revert-notify-enabled value))
 286          (unless (symbol-value variable)
 287            (when auto-revert-notify-enabled
 288              (dolist (buf (buffer-list))
 289                (with-current-buffer buf
 290                  (when (symbol-value 'auto-revert-notify-watch-descriptor)
 291                    (auto-revert-notify-rm-watch)))))))
 292   :version "24.4")
 293
 294 (defcustom auto-revert-notify-exclude-dir-regexp
 295   (concat
 296    ;; No mounted file systems.
 297    "^" (regexp-opt '("/afs/" "/media/" "/mnt" "/net/" "/tmp_mnt/"))
 298    ;; No remote files.
 299    (unless auto-revert-remote-files "\\|^/[^/|:][^/|]+:"))
 300   "Regular expression of directories to be excluded from file notifications."
 301   :group 'auto-revert
 302   :type 'regexp
 303   :version "24.4")
 304
 305 ;; Internal variables:
 306
 307 (defvar auto-revert-buffer-list ()
 308   "List of buffers in Auto-Revert Mode.
 309
 310 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 311 buffers to this list.
 312
 313 The timer function `auto-revert-buffers' is responsible for purging
 314 the list of old buffers.")
 315
 316 (defvar auto-revert-remaining-buffers ()
 317   "Buffers not checked when user input stopped execution.")
 318
 319 (defvar auto-revert-tail-pos 0
 320   "Position of last known end of file.")
 321
 322 (add-hook 'find-file-hook
 323           (lambda ()
 324             (set (make-local-variable 'auto-revert-tail-pos)
 325                  (nth 7 (file-attributes buffer-file-name)))))
 326
 327 (defvar auto-revert-notify-watch-descriptor-hash-list
 328   (make-hash-table :test 'equal)
 329   "A hash table collecting all file watch descriptors.
 330 Hash key is a watch descriptor, hash value is a list of buffers
 331 which are related to files being watched and carrying the same
 332 default directory.")
 333
 334 (defvar auto-revert-notify-watch-descriptor nil
 335   "The file watch descriptor active for the current buffer.")
 336 (make-variable-buffer-local 'auto-revert-notify-watch-descriptor)
 337 (put 'auto-revert-notify-watch-descriptor 'permanent-local t)
 338
 339 (defvar auto-revert-notify-modified-p nil
 340   "Non-nil when file has been modified on the file system.
 341 This has been reported by a file notification event.")
 342 (make-variable-buffer-local 'auto-revert-notify-modified-p)
 343
 344 ;; Functions:
 345
 346 ;;;###autoload
 347 (define-minor-mode auto-revert-mode
 348   "Toggle reverting buffer when the file changes (Auto Revert mode).
 349 With a prefix argument ARG, enable Auto Revert mode if ARG is
 350 positive, and disable it otherwise.  If called from Lisp, enable
 351 the mode if ARG is omitted or nil.
 352
 353 Auto Revert mode is a minor mode that affects only the current
 354 buffer.  When enabled, it reverts the buffer when the file on
 355 disk changes.
 356
 357 Use `global-auto-revert-mode' to automatically revert all buffers.
 358 Use `auto-revert-tail-mode' if you know that the file will only grow
 359 without being changed in the part that is already in the buffer."
 360   :group 'auto-revert :lighter auto-revert-mode-text
 361   (if auto-revert-mode
 362       (if (not (memq (current-buffer) auto-revert-buffer-list))
 363           (push (current-buffer) auto-revert-buffer-list))
 364     (when auto-revert-use-notify (auto-revert-notify-rm-watch))
 365     (setq auto-revert-buffer-list
 366           (delq (current-buffer) auto-revert-buffer-list)))
 367   (auto-revert-set-timer)
 368   (when auto-revert-mode
 369     (auto-revert-buffers)
 370     (setq auto-revert-tail-mode nil)))
 371
 372
 373 ;;;###autoload
 374 (defun turn-on-auto-revert-mode ()
 375   "Turn on Auto-Revert Mode.
 376
 377 This function is designed to be added to hooks, for example:
 378   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 379   (auto-revert-mode 1))
 380
 381
 382 ;;;###autoload
 383 (define-minor-mode auto-revert-tail-mode
 384   "Toggle reverting tail of buffer when the file grows.
 385 With a prefix argument ARG, enable Auto-Revert Tail mode if ARG
 386 is positive, and disable it otherwise.  If called from Lisp,
 387 enable the mode if ARG is omitted or nil.
 388
 389 When Auto Revert Tail mode is enabled, the tail of the file is
 390 constantly followed, as with the shell command `tail -f'.  This
 391 means that whenever the file grows on disk (presumably because
 392 some background process is appending to it from time to time),
 393 this is reflected in the current buffer.
 394
 395 You can edit the buffer and turn this mode off and on again as
 396 you please.  But make sure the background process has stopped
 397 writing before you save the file!
 398
 399 Use `auto-revert-mode' for changes other than appends!"
 400   :group 'find-file :lighter auto-revert-tail-mode-text
 401   (when auto-revert-tail-mode
 402     (unless buffer-file-name
 403       (auto-revert-tail-mode 0)
 404       (error "This buffer is not visiting a file"))
 405     (if (and (buffer-modified-p)
 406              (zerop auto-revert-tail-pos) ; library was loaded only after finding file
 407              (not (y-or-n-p "Buffer is modified, so tail offset may be wrong.  Proceed? ")))
 408         (auto-revert-tail-mode 0)
 409       ;; a-r-tail-pos stores the size of the file at the time of the
 410       ;; last revert. After this package loads, it adds a
 411       ;; find-file-hook to set this variable every time a file is
 412       ;; loaded.  If the package is loaded only _after_ visiting the
 413       ;; file to be reverted, then we have no idea what the value of
 414       ;; a-r-tail-pos should have been when the file was visited.  If
 415       ;; the file has changed on disk in the meantime, all we can do
 416       ;; is offer to revert the whole thing. If you choose not to
 417       ;; revert, then you might miss some output then happened
 418       ;; between visiting the file and activating a-r-t-mode.
 419       (and (zerop auto-revert-tail-pos)
 420            (not (verify-visited-file-modtime (current-buffer)))
 421            (y-or-n-p "File changed on disk, content may be missing.  \
 422 Perform a full revert? ")
 423            ;; Use this (not just revert-buffer) for point-preservation.
 424            (auto-revert-handler))
 425       ;; else we might reappend our own end when we save
 426       (add-hook 'before-save-hook (lambda () (auto-revert-tail-mode 0)) nil t)
 427       (or (local-variable-p 'auto-revert-tail-pos) ; don't lose prior position
 428           (set (make-local-variable 'auto-revert-tail-pos)
 429                (nth 7 (file-attributes buffer-file-name))))
 430       ;; let auto-revert-mode set up the mechanism for us if it isn't already
 431       (or auto-revert-mode
 432           (let ((auto-revert-tail-mode t))
 433             (auto-revert-mode 1)))
 434       (setq auto-revert-mode nil))))
 435
 436
 437 ;;;###autoload
 438 (defun turn-on-auto-revert-tail-mode ()
 439   "Turn on Auto-Revert Tail mode.
 440
 441 This function is designed to be added to hooks, for example:
 442   (add-hook 'my-logfile-mode-hook 'turn-on-auto-revert-tail-mode)"
 443   (auto-revert-tail-mode 1))
 444
 445
 446 ;;;###autoload
 447 (define-minor-mode global-auto-revert-mode
 448   "Toggle Global Auto Revert mode.
 449 With a prefix argument ARG, enable Global Auto Revert mode if ARG
 450 is positive, and disable it otherwise.  If called from Lisp,
 451 enable the mode if ARG is omitted or nil.
 452
 453 Global Auto Revert mode is a global minor mode that reverts any
 454 buffer associated with a file when the file changes on disk.  Use
 455 `auto-revert-mode' to revert a particular buffer.
 456
 457 If `global-auto-revert-non-file-buffers' is non-nil, this mode
 458 may also revert some non-file buffers, as described in the
 459 documentation of that variable.  It ignores buffers with modes
 460 matching `global-auto-revert-ignore-modes', and buffers with a
 461 non-nil vale of `global-auto-revert-ignore-buffer'.
 462
 463 This function calls the hook `global-auto-revert-mode-hook'.
 464 It displays the text that `global-auto-revert-mode-text'
 465 specifies in the mode line."
 466   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 467   (auto-revert-set-timer)
 468   (if global-auto-revert-mode
 469       (auto-revert-buffers)
 470     (dolist (buf (buffer-list))
 471       (with-current-buffer buf
 472         (when auto-revert-use-notify
 473           (auto-revert-notify-rm-watch))))))
 474
 475 (defun auto-revert-set-timer ()
 476   "Restart or cancel the timer used by Auto-Revert Mode.
 477 If such a timer is active, cancel it.  Start a new timer if
 478 Global Auto-Revert Mode is active or if Auto-Revert Mode is active
 479 in some buffer.  Restarting the timer ensures that Auto-Revert Mode
 480 will use an up-to-date value of `auto-revert-interval'"
 481   (interactive)
 482   (if (timerp auto-revert-timer)
 483       (cancel-timer auto-revert-timer))
 484   (setq auto-revert-timer
 485         (if (or global-auto-revert-mode auto-revert-buffer-list)
 486             (run-with-timer auto-revert-interval
 487                             auto-revert-interval
 488                             'auto-revert-buffers))))
 489
 490 (defun auto-revert-notify-rm-watch ()
 491   "Disable file notification for current buffer's associated file."
 492   (when auto-revert-notify-watch-descriptor
 493     (maphash
 494      (lambda (key value)
 495        (when (equal key auto-revert-notify-watch-descriptor)
 496          (setq value (delete (current-buffer) value))
 497          (if value
 498              (puthash key value auto-revert-notify-watch-descriptor-hash-list)
 499            (remhash key auto-revert-notify-watch-descriptor-hash-list)
 500            (ignore-errors
 501              (funcall (if (fboundp 'inotify-rm-watch)
 502                           'inotify-rm-watch 'w32notify-rm-watch)
 503                       auto-revert-notify-watch-descriptor)))))
 504      auto-revert-notify-watch-descriptor-hash-list)
 505     (remove-hook 'kill-buffer-hook 'auto-revert-notify-rm-watch))
 506   (setq auto-revert-notify-watch-descriptor nil
 507         auto-revert-notify-modified-p nil))
 508
 509 (defun auto-revert-notify-add-watch ()
 510   "Enable file notification for current buffer's associated file."
 511   (when (string-match auto-revert-notify-exclude-dir-regexp
 512                       (expand-file-name default-directory))
 513     ;; Fallback to file checks.
 514     (set (make-local-variable 'auto-revert-use-notify) nil))
 515
 516   (when (and buffer-file-name auto-revert-use-notify
 517              (not auto-revert-notify-watch-descriptor))
 518     (let ((func (if (fboundp 'inotify-add-watch)
 519                     'inotify-add-watch 'w32notify-add-watch))
 520           (aspect (if (fboundp 'inotify-add-watch)
 521                       '(create modify moved-to) '(size last-write-time))))
 522       (setq auto-revert-notify-watch-descriptor
 523             (ignore-errors
 524               (funcall
 525                func (directory-file-name (expand-file-name default-directory))
 526                aspect 'auto-revert-notify-handler)))
 527       (if auto-revert-notify-watch-descriptor
 528           (progn
 529             (puthash
 530              auto-revert-notify-watch-descriptor
 531              (cons (current-buffer)
 532                    (gethash auto-revert-notify-watch-descriptor
 533                             auto-revert-notify-watch-descriptor-hash-list))
 534              auto-revert-notify-watch-descriptor-hash-list)
 535             (add-hook (make-local-variable 'kill-buffer-hook)
 536                       'auto-revert-notify-rm-watch))
 537         ;; Fallback to file checks.
 538         (set (make-local-variable 'auto-revert-use-notify) nil)))))
 539
 540 (defun auto-revert-notify-event-p (event)
 541   "Check that event is a file notification event."
 542   (cond ((featurep 'inotify)
 543          (and (listp event) (= (length event) 4)))
 544         ((featurep 'w32notify)
 545          (and (listp event) (= (length event) 3) (stringp (nth 2 event))))))
 546
 547 (defun auto-revert-notify-event-descriptor (event)
 548   "Return watch descriptor of file notification event, or nil."
 549   (and (auto-revert-notify-event-p event) (car event)))
 550
 551 (defun auto-revert-notify-event-action (event)
 552   "Return action of file notification event, or nil."
 553   (and (auto-revert-notify-event-p event) (nth 1 event)))
 554
 555 (defun auto-revert-notify-event-file-name (event)
 556   "Return file name of file notification event, or nil."
 557   (and (auto-revert-notify-event-p event)
 558        (cond ((featurep 'inotify) (nth 3 event))
 559              ((featurep 'w32notify) (nth 2 event)))))
 560
 561 (defun auto-revert-notify-handler (event)
 562   "Handle an event returned from file notification."
 563   (when (auto-revert-notify-event-p event)
 564     (let* ((descriptor (auto-revert-notify-event-descriptor event))
 565            (action (auto-revert-notify-event-action event))
 566            (file (auto-revert-notify-event-file-name event))
 567            (buffers (gethash descriptor
 568                              auto-revert-notify-watch-descriptor-hash-list)))
 569       (ignore-errors
 570         ;; Check, that event is meant for us.
 571         ;; TODO: Filter events which stop watching, like `move' or `removed'.
 572         (cl-assert descriptor)
 573         (when (featurep 'inotify)
 574           (cl-assert (or (memq 'create action)
 575                          (memq 'modify action)
 576                          (memq 'moved-to action))))
 577         (when (featurep 'w32notify) (cl-assert (eq 'modified action)))
 578         ;; Since we watch a directory, a file name must be returned.
 579         (cl-assert (stringp file))
 580         (dolist (buffer buffers)
 581           (when (buffer-live-p buffer)
 582             (with-current-buffer buffer
 583               (when (and (stringp buffer-file-name)
 584                          (string-equal
 585                           (file-name-nondirectory file)
 586                           (file-name-nondirectory buffer-file-name)))
 587                 ;; Mark buffer modified.
 588                 (setq auto-revert-notify-modified-p t)
 589                 ;; No need to check other buffers.
 590                 (cl-return)))))))))
 591
 592 (defun auto-revert-active-p ()
 593   "Check if auto-revert is active (in current buffer or globally)."
 594   (or auto-revert-mode
 595       auto-revert-tail-mode
 596       (and
 597        global-auto-revert-mode
 598        (not global-auto-revert-ignore-buffer)
 599        (not (memq major-mode
 600                   global-auto-revert-ignore-modes)))))
 601
 602 (defun auto-revert-handler ()
 603   "Revert current buffer, if appropriate.
 604 This is an internal function used by Auto-Revert Mode."
 605   (when (or auto-revert-tail-mode (not (buffer-modified-p)))
 606     (let* ((buffer (current-buffer)) size
 607            ;; Tramp caches the file attributes.  Setting
 608            ;; `remote-file-name-inhibit-cache' forces Tramp to reread
 609            ;; the values.
 610            (remote-file-name-inhibit-cache t)
 611            (revert
 612             (or (and buffer-file-name
 613                      (or auto-revert-remote-files
 614                          (not (file-remote-p buffer-file-name)))
 615                      (or (not auto-revert-use-notify)
 616                          auto-revert-notify-modified-p)
 617                      (if auto-revert-tail-mode
 618                          (and (file-readable-p buffer-file-name)
 619                               (/= auto-revert-tail-pos
 620                                   (setq size
 621                                         (nth 7 (file-attributes
 622                                                 buffer-file-name)))))
 623                        (and (file-readable-p buffer-file-name)
 624                             (not (verify-visited-file-modtime buffer)))))
 625                 (and (or auto-revert-mode
 626                          global-auto-revert-non-file-buffers)
 627                      revert-buffer-function
 628                      (boundp 'buffer-stale-function)
 629                      (functionp buffer-stale-function)
 630                      (funcall buffer-stale-function t))))
 631            eob eoblist)
 632       (setq auto-revert-notify-modified-p nil)
 633       (when revert
 634         (when (and auto-revert-verbose
 635                    (not (eq revert 'fast)))
 636           (message "Reverting buffer `%s'." (buffer-name)))
 637         ;; If point (or a window point) is at the end of the buffer,
 638         ;; we want to keep it at the end after reverting.  This allows
 639         ;; to tail a file.
 640         (when buffer-file-name
 641           (setq eob (eobp))
 642           (walk-windows
 643            (lambda (window)
 644              (and (eq (window-buffer window) buffer)
 645                   (= (window-point window) (point-max))
 646                   (push window eoblist)))
 647            'no-mini t))
 648         (if auto-revert-tail-mode
 649             (auto-revert-tail-handler size)
 650           ;; Bind buffer-read-only in case user has done C-x C-q,
 651           ;; so as not to forget that.  This gives undesirable results
 652           ;; when the file's mode changes, but that is less common.
 653           (let ((buffer-read-only buffer-read-only))
 654             (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)))
 655         (when buffer-file-name
 656           (when eob (goto-char (point-max)))
 657           (dolist (window eoblist)
 658             (set-window-point window (point-max)))))
 659       ;; `preserve-modes' avoids changing the (minor) modes.  But we
 660       ;; do want to reset the mode for VC, so we do it manually.
 661       (when (or revert auto-revert-check-vc-info)
 662         (vc-find-file-hook)))))
 663
 664 (defun auto-revert-tail-handler (size)
 665   (let ((modified (buffer-modified-p))
 666         (inhibit-read-only t)           ; Ignore.
 667         (file buffer-file-name)
 668         (buffer-file-name nil))         ; Ignore that file has changed.
 669     (when (/= auto-revert-tail-pos size)
 670       (run-hooks 'before-revert-hook)
 671       (undo-boundary)
 672       (save-restriction
 673         (widen)
 674         (save-excursion
 675           (goto-char (point-max))
 676           (insert-file-contents file nil
 677                                 (and (< auto-revert-tail-pos size)
 678                                      auto-revert-tail-pos)
 679                                 size)))
 680       (run-hooks 'after-revert-hook)
 681       (undo-boundary)
 682       (setq auto-revert-tail-pos size)
 683       (restore-buffer-modified-p modified)))
 684   (set-visited-file-modtime))
 685
 686 (defun auto-revert-buffers ()
 687   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 688
 689 Should `global-auto-revert-mode' be active all file buffers are checked.
 690
 691 Should `auto-revert-mode' be active in some buffers, those buffers
 692 are checked.
 693
 694 Non-file buffers that have a custom `revert-buffer-function' and
 695 a `buffer-stale-function' are reverted either when Auto-Revert
 696 Mode is active in that buffer, or when the variable
 697 `global-auto-revert-non-file-buffers' is non-nil and Global
 698 Auto-Revert Mode is active.
 699
 700 This function stops whenever there is user input.  The buffers not
 701 checked are stored in the variable `auto-revert-remaining-buffers'.
 702
 703 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 704 are checked first the next time this function is called.
 705
 706 This function is also responsible for removing buffers no longer in
 707 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 708 the timer when no buffers need to be checked."
 709   (save-match-data
 710     (let ((bufs (if global-auto-revert-mode
 711                     (buffer-list)
 712                   auto-revert-buffer-list))
 713           (remaining ())
 714           (new ()))
 715       ;; Partition `bufs' into two halves depending on whether or not
 716       ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 717       ;; halves are then re-joined with the "remaining" buffers at the
 718       ;; head of the list.
 719       (dolist (buf auto-revert-remaining-buffers)
 720         (if (memq buf bufs)
 721             (push buf remaining)))
 722       (dolist (buf bufs)
 723         (if (not (memq buf remaining))
 724             (push buf new)))
 725       (setq bufs (nreverse (nconc new remaining)))
 726       (while (and bufs
 727                   (not (and auto-revert-stop-on-user-input
 728                             (input-pending-p))))
 729         (let ((buf (car bufs)))
 730           (if (buffer-live-p buf)
 731               (with-current-buffer buf
 732                 ;; Test if someone has turned off Auto-Revert Mode in a
 733                 ;; non-standard way, for example by changing major mode.
 734                 (if (and (not auto-revert-mode)
 735                          (not auto-revert-tail-mode)
 736                          (memq buf auto-revert-buffer-list))
 737                     (setq auto-revert-buffer-list
 738                           (delq buf auto-revert-buffer-list)))
 739                 (when (auto-revert-active-p)
 740                   ;; Enable file notification.
 741                   (when (and auto-revert-use-notify buffer-file-name
 742                              (not auto-revert-notify-watch-descriptor))
 743                     (auto-revert-notify-add-watch))
 744                   (auto-revert-handler)))
 745             ;; Remove dead buffer from `auto-revert-buffer-list'.
 746             (setq auto-revert-buffer-list
 747                   (delq buf auto-revert-buffer-list))))
 748         (setq bufs (cdr bufs)))
 749       (setq auto-revert-remaining-buffers bufs)
 750       ;; Check if we should cancel the timer.
 751       (when (and (not global-auto-revert-mode)
 752                  (null auto-revert-buffer-list))
 753         (cancel-timer auto-revert-timer)
 754         (setq auto-revert-timer nil)))))
 755
 756
 757 ;; The end:
 758 (provide 'autorevert)
 759
 760 (run-hooks 'auto-revert-load-hook)
 761
 762 ;;; autorevert.el ends here