configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 standardlisppath='${lispdir}:${leimdir}'
  42 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  43 '${datadir}/emacs/site-lisp'
  44 lisppath='${locallisppath}:${standardlisppath}'
  45 etcdir='${datadir}/emacs/${version}/etc'
  46 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  47 docdir='${datadir}/emacs/${version}/etc'
  48 gamedir='${localstatedir}/games/emacs'
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 151 if test "$with_wide_int" = yes; then
 152   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 153 fi
 154
 155 dnl _ON results in a '--without' option in the --help output, so
 156 dnl the help text should refer to "don't compile", etc.
 157 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 158 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 159 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 160 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 161 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 162 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 163 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 164 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 165
 166 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 167 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 168 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 169
 170 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 171 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 172 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 173 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 174
 175 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 176 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 177 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 178 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 179 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 180 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 181
 182 ## For the times when you want to build Emacs but don't have
 183 ## a suitable makeinfo, and can live without the manuals.
 184 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 185 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 186
 187 ## Makefile.in needs the cache file name.
 188 AC_SUBST(cache_file)
 189
 190 ## This is an option because I do not know if all info/man support
 191 ## compressed files, nor how to test if they do so.
 192 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 193 if test $with_compress_info = yes; then
 194    GZIP_INFO=yes
 195 else
 196    GZIP_INFO=
 197 fi
 198 AC_SUBST(GZIP_INFO)
 199
 200 AC_ARG_WITH([pkg-config-prog],dnl
 201 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 202                   [path to pkg-config for finding GTK and librsvg])])
 203 if test "X${with_pkg_config_prog}" != X; then
 204    if test "${with_pkg_config_prog}" != yes; then
 205       PKG_CONFIG="${with_pkg_config_prog}"
 206    fi
 207 fi
 208
 209 CRT_DIR=
 210 AC_ARG_WITH([crt-dir],dnl
 211 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 212 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 213 CRT_DIR="${with_crt_dir}"
 214
 215 AC_ARG_WITH(gameuser,dnl
 216 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 217 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 218   && gameuser="${with_gameuser}"
 219 test "X$gameuser" = X && gameuser=games
 220
 221 AC_ARG_WITH([gnustep-conf],dnl
 222 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 223 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 224   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 225 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 226      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 227
 228 AC_ARG_ENABLE(ns-self-contained,
 229 [AS_HELP_STRING([--disable-ns-self-contained],
 230                 [disable self contained build under NeXTstep])],
 231    EN_NS_SELF_CONTAINED=$enableval,
 232    EN_NS_SELF_CONTAINED=yes)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist, glyphs])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;
 264                         ac_glyphs_debug= ;;
 265         all)            ac_enable_checking=1 ;
 266                         ac_gc_check_stringbytes=1 ;
 267                         ac_gc_check_string_overrun=1 ;
 268                         ac_gc_check_string_free_list=1 ;
 269                         ac_xmalloc_overrun=1 ;
 270                         ac_gc_check_cons_list=1 ;
 271                         ac_glyphs_debug=1 ;;
 272         # these enable particular checks
 273         stringbytes)    ac_gc_check_stringbytes=1 ;;
 274         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 275         stringfreelist) ac_gc_check_string_free_list=1 ;;
 276         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 277         conslist)       ac_gc_check_cons_list=1 ;;
 278         glyphs)         ac_glyphs_debug=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_string_overrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310 if test x$ac_glyphs_debug != x ; then
 311   AC_DEFINE(GLYPH_DEBUG, 1,
 312 [Define this to enable glyphs debugging code.])
 313 fi
 314
 315 AC_ARG_ENABLE(check-lisp-object-type,
 316 [AS_HELP_STRING([--enable-check-lisp-object-type],
 317                 [enable compile time checks for the Lisp_Object data type.
 318                 This is useful for development for catching certain types of bugs.])],
 319 if test "${enableval}" != "no"; then
 320    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 321    [Define this to enable compile time checks for the Lisp_Object data type.])
 322 fi)
 323
 324
 325 AC_ARG_ENABLE(profiling,
 326 [AS_HELP_STRING([--enable-profiling],
 327                 [build emacs with profiling support.
 328                  This might not work on all platforms])],
 329 [ac_enable_profiling="${enableval}"],[])
 330 if test x$ac_enable_profiling != x ; then
 331    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 332 else
 333    PROFILING_CFLAGS=
 334 fi
 335 AC_SUBST(PROFILING_CFLAGS)
 336
 337 AC_ARG_ENABLE(autodepend,
 338 [AS_HELP_STRING([--enable-autodepend],
 339                 [automatically generate dependencies to .h-files.
 340                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 341                  found])],
 342 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 343
 344 #### Make srcdir absolute, if it isn't already.  It's important to
 345 #### avoid running the path through pwd unnecessarily, since pwd can
 346 #### give you automounter prefixes, which can go away.  We do all this
 347 #### so Emacs can find its files when run uninstalled.
 348 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 349 unset CDPATH
 350 case "${srcdir}" in
 351   /* ) ;;
 352   . )
 353     ## We may be able to use the $PWD environment variable to make this
 354     ## absolute.  But sometimes PWD is inaccurate.
 355     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 356     ## but that tested only for a well-formed and valid PWD,
 357     ## it did not object when PWD was well-formed and valid but just wrong.
 358     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 359     then
 360       srcdir="$PWD"
 361     else
 362       srcdir="`(cd ${srcdir}; pwd)`"
 363     fi
 364   ;;
 365   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 366 esac
 367
 368 #### Given the configuration name, set opsysfile to the
 369 #### name of s/*.h file we should use.
 370
 371 ### Canonicalize the configuration name.
 372
 373 AC_CANONICAL_HOST
 374 canonical=$host
 375 configuration=${host_alias-${build_alias-$host}}
 376
 377 dnl This used to use changequote, but, apart from `changequote is evil'
 378 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 379 dnl the great gob of text.  Thus it's not processed for possible expansion.
 380 dnl Just make sure the brackets remain balanced.
 381 dnl
 382 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 383 dnl indicated by comments.
 384 dnl quotation begins
 385 [
 386
 387 ### If you add support for a new configuration, add code to this
 388 ### switch statement to recognize your configuration name and select
 389 ### the appropriate operating system file.
 390
 391 ### You would hope that you could choose an s/*.h
 392 ### file based on the operating system portion.  However, it turns out
 393 ### that each s/*.h file is pretty manufacturer-specific.
 394 ### So we basically have to have a special case for each
 395 ### configuration name.
 396 ###
 397 ### As far as handling version numbers on operating systems is
 398 ### concerned, make sure things will fail in a fixable way.  If
 399 ### /etc/MACHINES doesn't say anything about version numbers, be
 400 ### prepared to handle anything reasonably.  If version numbers
 401 ### matter, be sure /etc/MACHINES says something about it.
 402
 403 opsys='' unported=no
 404 case "${canonical}" in
 405
 406   ## GNU/Linux and similar ports
 407   *-*-linux* )
 408     opsys=gnu-linux
 409   ;;
 410
 411   ## FreeBSD ports
 412   *-*-freebsd* )
 413     opsys=freebsd
 414   ;;
 415
 416   ## FreeBSD kernel + glibc based userland
 417   *-*-kfreebsd*gnu* )
 418     opsys=gnu-kfreebsd
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424   ;;
 425
 426   ## OpenBSD ports
 427   *-*-openbsd* )
 428     opsys=openbsd
 429   ;;
 430
 431   ## Apple Darwin / Mac OS X
 432   *-apple-darwin* )
 433     case "${canonical}" in
 434       i[3456]86-* )  ;;
 435       powerpc-* )    ;;
 436       x86_64-* )     ;;
 437       * )            unported=yes ;;
 438     esac
 439     opsys=darwin
 440     ## Use fink packages if available.
 441     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 442 ##    if test -d /sw/include && test -d /sw/lib; then
 443 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 444 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 445 ##    fi
 446   ;;
 447
 448   ## HP 9000 series 700 and 800, running HP/UX
 449   hppa*-hp-hpux10.2* )
 450     opsys=hpux10-20
 451   ;;
 452   hppa*-hp-hpux1[1-9]* )
 453     opsys=hpux11
 454     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 455   ;;
 456
 457   ## IBM machines
 458   rs6000-ibm-aix4.[23]* )
 459     opsys=aix4-2
 460   ;;
 461   powerpc-ibm-aix4.[23]*  )
 462     opsys=aix4-2
 463   ;;
 464   rs6000-ibm-aix[56]* )
 465     opsys=aix4-2
 466   ;;
 467   powerpc-ibm-aix[56]*  )
 468     opsys=aix4-2
 469   ;;
 470
 471   ## Silicon Graphics machines
 472   ## Iris 4D
 473   mips-sgi-irix6.5 )
 474     opsys=irix6-5
 475     # Without defining _LANGUAGE_C, things get masked out in the headers
 476     # so that, for instance, grepping for `free' in stdlib.h fails and
 477     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 478     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 479   ;;
 480
 481   ## Suns
 482   *-sun-solaris* \
 483     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 484     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 485     case "${canonical}" in
 486       i[3456]86-*-* )   ;;
 487       amd64-*-*|x86_64-*-*) ;;
 488       sparc* )          ;;
 489       * )               unported=yes ;;
 490     esac
 491     case "${canonical}" in
 492       *-sunos5.6* | *-solaris2.6* )
 493                 opsys=sol2-6
 494                 RANLIB="ar -ts"
 495                 ;;
 496       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 497                 opsys=sol2-6
 498                 emacs_check_sunpro_c=yes
 499                 ;;
 500       *-sunos5* | *-solaris* )
 501                 opsys=sol2-10
 502                 emacs_check_sunpro_c=yes
 503                 ;;
 504     esac
 505     ## Watch out for a compiler that we know will not work.
 506     case "${canonical}" in
 507      *-solaris* | *-sunos5* )
 508                 if [ "x$CC" = x/usr/ucb/cc ]; then
 509                   ## /usr/ucb/cc doesn't work;
 510                   ## we should find some other compiler that does work.
 511                   unset CC
 512                 fi
 513                 ;;
 514       *) ;;
 515     esac
 516   ;;
 517
 518   ## Intel 386 machines where we don't care about the manufacturer.
 519   i[3456]86-*-* )
 520     case "${canonical}" in
 521       *-cygwin )                opsys=cygwin ;;
 522       *-darwin* )               opsys=darwin ;;
 523       *-sysv4.2uw* )            opsys=unixware ;;
 524       *-sysv5uw* )              opsys=unixware ;;
 525       *-sysv5OpenUNIX* )        opsys=unixware ;;
 526       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 527     esac
 528   ;;
 529
 530   * )
 531     unported=yes
 532   ;;
 533 esac
 534
 535 ### If the code above didn't choose an operating system, just choose
 536 ### an operating system based on the configuration name.  You really
 537 ### only want to use this when you have no idea what the right
 538 ### operating system is; if you know what operating systems a machine
 539 ### runs, it's cleaner to make it explicit in the case statement
 540 ### above.
 541 if test x"${opsys}" = x; then
 542   case "${canonical}" in
 543     *-gnu* )                            opsys=gnu ;;
 544     * )
 545       unported=yes
 546     ;;
 547   esac
 548 fi
 549
 550 ]
 551 dnl quotation ends
 552
 553 if test $unported = yes; then
 554   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 555 Check `etc/MACHINES' for recognized configuration names.])
 556 fi
 557
 558 opsysfile="s/${opsys}.h"
 559
 560
 561 #### Choose a compiler.
 562
 563 dnl Sets GCC=yes if using gcc.
 564 AC_PROG_CC
 565 AM_PROG_CC_C_O
 566
 567 if test x$GCC = xyes; then
 568   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 569 else
 570   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 571 fi
 572
 573 # Initialize gnulib right after choosing the compiler.
 574 gl_EARLY
 575
 576 AC_ARG_ENABLE([gcc-warnings],
 577   [AS_HELP_STRING([--enable-gcc-warnings],
 578                   [turn on lots of GCC warnings. This is intended for
 579                    developers, and may generate false alarms when used
 580                    with older or non-GNU development tools.])],
 581   [case $enableval in
 582      yes|no) ;;
 583      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 584    esac
 585    gl_gcc_warnings=$enableval],
 586   [gl_gcc_warnings=no]
 587 )
 588
 589 AC_ARG_ENABLE(link-time-optimization,
 590 [AS_HELP_STRING([--enable-link-time-optimization],
 591                 [build emacs with link-time optimization.
 592                  This is supported only for GCC since 4.5.0.])],
 593 if test "${enableval}" != "no"; then
 594    AC_MSG_CHECKING([whether link-time optimization is supported])
 595    ac_lto_supported=no
 596    if test x$GCC = xyes; then
 597       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 598       if test x$CPUS != x; then
 599          LTO="-flto=$CPUS"
 600       else
 601          LTO="-flto"
 602       fi
 603       old_CFLAGS=$CFLAGS
 604       CFLAGS="$CFLAGS $LTO"
 605       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 606         [ac_lto_supported=yes], [ac_lto_supported=no])
 607       CFLAGS="$old_CFLAGS"
 608    fi
 609    AC_MSG_RESULT([$ac_lto_supported])
 610    if test "$ac_lto_supported" = "yes"; then
 611       CFLAGS="$CFLAGS $LTO"
 612    fi
 613 fi)
 614
 615 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 616 # ------------------------------------------------
 617 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 618 # Otherwise, run RUN-IF-NOT-FOUND.
 619 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 620   [AC_PREPROC_IFELSE(
 621     [AC_LANG_PROGRAM(
 622       [[
 623 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 624 /* ok */
 625 #else
 626 # error "your version of gcc is older than $1.$2"
 627 #endif
 628       ]]),
 629     ], [$3], [$4])
 630   ]
 631 )
 632
 633 # When compiling with GCC, prefer -isystem to -I when including system
 634 # include files, to avoid generating useless diagnostics for the files.
 635 if test "$gl_gcc_warnings" != yes; then
 636   isystem='-I'
 637 else
 638   isystem='-isystem '
 639
 640   # This, $nw, is the list of warnings we disable.
 641   nw=
 642
 643   case $with_x_toolkit in
 644     lucid | athena | motif)
 645        # Old toolkits mishandle 'const'.
 646        nw="$nw -Wwrite-strings"
 647        ;;
 648     *)
 649        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 650        ;;
 651   esac
 652   AC_SUBST([WERROR_CFLAGS])
 653
 654   nw="$nw -Waggregate-return"       # anachronistic
 655   nw="$nw -Wlong-long"              # C90 is anachronistic
 656   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 657   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 658   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 659   nw="$nw -Wcast-qual"              # Too many warnings for now
 660   nw="$nw -Wconversion"             # Too many warnings for now
 661   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 662   nw="$nw -Wsign-conversion"        # Too many warnings for now
 663   nw="$nw -Woverlength-strings"     # Not a problem these days
 664   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 665   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 666   nw="$nw -Wpadded"                 # Our structs are not padded
 667   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 668   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 669   nw="$nw -Wformat-nonliteral"      # we do this a lot
 670   nw="$nw -Wvla"                    # warnings in gettext.h
 671   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 672   nw="$nw -Wswitch-enum"            # Too many warnings for now
 673   nw="$nw -Wswitch-default"         # Too many warnings for now
 674   nw="$nw -Wfloat-equal"            # warns about high-quality code
 675   nw="$nw -Winline"                 # OK to ignore 'inline'
 676   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 677   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 678
 679   # Emacs doesn't care about shadowing; see
 680   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 681   nw="$nw -Wshadow"
 682
 683   # The following lines should be removable at some point.
 684   nw="$nw -Wstack-protector"
 685   nw="$nw -Wstrict-overflow"
 686   nw="$nw -Wsuggest-attribute=const"
 687   nw="$nw -Wsuggest-attribute=pure"
 688
 689   gl_MANYWARN_ALL_GCC([ws])
 690   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 691   for w in $ws; do
 692     gl_WARN_ADD([$w])
 693   done
 694   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 695   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 696   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 697   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 698   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 699   gl_WARN_ADD([-Wno-format-nonliteral])
 700
 701   # In spite of excluding -Wlogical-op above, it is enabled, as of
 702   # gcc 4.5.0 20090517.
 703   gl_WARN_ADD([-Wno-logical-op])
 704
 705   gl_WARN_ADD([-fdiagnostics-show-option])
 706   gl_WARN_ADD([-funit-at-a-time])
 707
 708   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 709   AC_DEFINE([_FORTIFY_SOURCE], [2],
 710     [enable compile-time and run-time bounds-checking, and some warnings])
 711   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 712
 713   # We use a slightly smaller set of warning options for lib/.
 714   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 715   nw=
 716   nw="$nw -Wunused-macros"
 717
 718   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 719   AC_SUBST([GNULIB_WARN_CFLAGS])
 720 fi
 721
 722
 723
 724 dnl Some other nice autoconf tests.
 725 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 726 dnl AC_PROG_INSTALL
 727 dnl AC_PROG_MKDIR_P
 728 dnl if test "x$RANLIB" = x; then
 729 dnl   AC_PROG_RANLIB
 730 dnl fi
 731
 732 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 733   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 734 dnl Don't use GZIP, which is used by gzip for additional parameters.
 735 AC_PATH_PROG(GZIP_PROG, gzip)
 736
 737 if test $opsys = gnu-linux; then
 738   AC_PATH_PROG(PAXCTL, paxctl,,
 739     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 740 fi
 741
 742 ## Need makeinfo >= 4.7 (?) to build the manuals.
 743 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 744 dnl By this stage, configure has already checked for egrep and set EGREP,
 745 dnl or exited with an error if no egrep was found.
 746 if test "$MAKEINFO" != "no" && \
 747   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 748    MAKEINFO=no
 749 fi
 750
 751 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 752 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 753 ## therefore in the category of "special tools" not normally required, which
 754 ## configure does not have to check for (eg autoconf itself).
 755 ## In a Bazaar checkout on the other hand, the manuals are not included.
 756 ## So makeinfo is a requirement to build from Bazaar, and configure
 757 ## should test for it as it does for any other build requirement.
 758 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 759 ## with pre-built manuals, from a Bazaar checkout.
 760 HAVE_MAKEINFO=yes
 761
 762 if test "$MAKEINFO" = "no"; then
 763   MAKEINFO=makeinfo
 764   if test "x${with_makeinfo}" = "xno"; then
 765     HAVE_MAKEINFO=no
 766   elif test ! -e $srcdir/info/emacs; then
 767     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 768 source tree does not seem to have pre-built manuals in the `info' directory.
 769 Either install a suitable version of makeinfo, or re-run configure
 770 with the `--without-makeinfo' option to build without the manuals.] )
 771   fi
 772 fi
 773 AC_SUBST(HAVE_MAKEINFO)
 774
 775 dnl Just so that there is only a single place we need to edit.
 776 INFO_EXT=.info
 777 INFO_OPTS=--no-split
 778 AC_SUBST(INFO_EXT)
 779 AC_SUBST(INFO_OPTS)
 780
 781 dnl Add our options to ac_link now, after it is set up.
 782
 783 if test x$GCC = xyes; then
 784   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 785     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 786 else
 787   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 788     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 789 fi
 790
 791 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 792 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 793 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 794 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 795 dnl if not built to support GNU ld.
 796
 797 late_LDFLAGS=$LDFLAGS
 798 if test x$GCC = xyes; then
 799   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 800 else
 801   LDFLAGS="$LDFLAGS -znocombreloc"
 802 fi
 803
 804 AC_MSG_CHECKING([for -znocombreloc])
 805 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 806   [AC_MSG_RESULT(yes)],
 807   LDFLAGS=$late_LDFLAGS
 808   [AC_MSG_RESULT(no)])
 809
 810
 811 dnl The function dump-emacs will not be defined and temacs will do
 812 dnl (load "loadup") automatically unless told otherwise.
 813 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 814 case "$opsys" in
 815   your-opsys-here) CANNOT_DUMP=yes ;;
 816 esac
 817
 818 test "$CANNOT_DUMP" = "yes" && \
 819   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 820
 821 AC_SUBST(CANNOT_DUMP)
 822
 823
 824 UNEXEC_OBJ=unexelf.o
 825 case "$opsys" in
 826   # MSDOS uses unexcoff.o
 827   # MSWindows uses unexw32.o
 828   aix4-2)
 829    UNEXEC_OBJ=unexaix.o
 830    ;;
 831   cygwin)
 832    UNEXEC_OBJ=unexcw.o
 833    ;;
 834   darwin)
 835    UNEXEC_OBJ=unexmacosx.o
 836    ;;
 837   hpux10-20 | hpux11)
 838    UNEXEC_OBJ=unexhp9k800.o
 839    ;;
 840   sol2-10)
 841    # Use the Solaris dldump() function, called from unexsol.c, to dump
 842    # emacs, instead of the generic ELF dump code found in unexelf.c.
 843    # The resulting binary has a complete symbol table, and is better
 844    # for debugging and other observability tools (debuggers, pstack, etc).
 845    #
 846    # If you encounter a problem using dldump(), please consider sending
 847    # a message to the OpenSolaris tools-linking mailing list:
 848    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 849    #
 850    # It is likely that dldump() works with older Solaris too, but this has
 851    # not been tested, so for now this change is for Solaris 10 or newer.
 852    UNEXEC_OBJ=unexsol.o
 853    ;;
 854 esac
 855
 856 LD_SWITCH_SYSTEM=
 857 case "$opsys" in
 858   freebsd)
 859    ## Let `ld' find image libs and similar things in /usr/local/lib.
 860    ## The system compiler, GCC, has apparently been modified to not
 861    ## look there, contrary to what a stock GCC would do.
 862 ### It's not our place to do this.  See bug#10313#17.
 863 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 864       :
 865    ;;
 866
 867   gnu-linux)
 868    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 869    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 870    ;;
 871
 872   netbsd)
 873 ### It's not our place to do this.  See bug#10313#17.
 874 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 875       :
 876    ;;
 877
 878   openbsd)
 879    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 880    ## otherwise Emacs dumps core on elf systems.
 881    LD_SWITCH_SYSTEM="-Z"
 882    ;;
 883 esac
 884 AC_SUBST(LD_SWITCH_SYSTEM)
 885
 886 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 887
 888 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 889 ## which has not been defined yet.  When this was handled with cpp,
 890 ## it was expanded to null when configure sourced the s/*.h file.
 891 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 892 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 893 ## (or somesuch), but because it is supposed to go at the _front_
 894 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 895 ## Compare with the gnu-linux case below, which added to the end
 896 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 897 ## LD_SWITCH_SYSTEM_TEMACS.
 898 case "$opsys" in
 899   netbsd|openbsd)
 900    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 901 esac
 902
 903
 904 C_SWITCH_MACHINE=
 905 case $canonical in
 906  alpha*)
 907   AC_CHECK_DECL([__ELF__])
 908   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 909     ## With ELF, make sure that all common symbols get allocated to in the
 910     ## data section.  Otherwise, the dump of temacs may miss variables in
 911     ## the shared library that have been initialized.  For example, with
 912     ## GNU libc, __malloc_initialized would normally be resolved to the
 913     ## shared library's .bss section, which is fatal.
 914     if test "x$GCC" = "xyes"; then
 915       C_SWITCH_MACHINE="-fno-common"
 916     else
 917       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 918     fi
 919   else
 920     UNEXEC_OBJ=unexalpha.o
 921   fi
 922   ;;
 923 esac
 924 AC_SUBST(C_SWITCH_MACHINE)
 925
 926 AC_SUBST(UNEXEC_OBJ)
 927
 928 C_SWITCH_SYSTEM=
 929 ## Some programs in src produce warnings saying certain subprograms
 930 ## are too complex and need a MAXMEM value greater than 2000 for
 931 ## additional optimization.  --nils@exp-math.uni-essen.de
 932 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 933   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 934 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 935 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 936 AC_SUBST(C_SWITCH_SYSTEM)
 937
 938
 939 LIBS_SYSTEM=
 940 case "$opsys" in
 941   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 942   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 943
 944   freebsd) LIBS_SYSTEM="-lutil" ;;
 945
 946   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 947
 948   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 949
 950   ## Motif needs -lgen.
 951   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 952 esac
 953 AC_SUBST(LIBS_SYSTEM)
 954
 955
 956 ### Make sure subsequent tests use flags consistent with the build flags.
 957
 958 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 959   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 960 else
 961   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 962 fi
 963
 964 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 965 AC_DEFUN([AC_TYPE_SIZE_T])
 966 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 967 AC_DEFUN([AC_TYPE_UID_T])
 968
 969
 970 LIB_MATH=-lm
 971 LIB_STANDARD=
 972 START_FILES=
 973 dnl Current possibilities handled by sed (aix4-2 -> aix,
 974 dnl gnu-linux -> gnu/linux, etc.):
 975 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 976 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 977 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 978
 979 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 980 case $opsys in
 981   cygwin )
 982     LIB_MATH=
 983     START_FILES='pre-crt0.o'
 984     ;;
 985   darwin )
 986     ## Adding -lm confuses the dynamic linker, so omit it.
 987     LIB_MATH=
 988     START_FILES='pre-crt0.o'
 989     ;;
 990   freebsd )
 991     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 992     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 993     SYSTEM_TYPE=berkeley-unix
 994     ;;
 995   gnu-linux | gnu-kfreebsd )
 996     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 997     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 998     ;;
 999   hpux10-20 | hpux11 )
1000     LIB_STANDARD=-lc
1001     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1002     ;;
1003   dnl NB this may be adjusted below.
1004   netbsd | openbsd )
1005     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1006     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1007     SYSTEM_TYPE=berkeley-unix
1008     ;;
1009
1010   sol2* | unixware )
1011     SYSTEM_TYPE=usg-unix-v
1012     ;;
1013
1014 esac
1015
1016 AC_SUBST(LIB_MATH)
1017 AC_SUBST(START_FILES)
1018 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1019   [The type of system you are compiling for; sets `system-type'.])
1020
1021 dnl Not all platforms use crtn.o files.  Check if the current one does.
1022 crt_files=
1023
1024 for file in x $LIB_STANDARD $START_FILES; do
1025   case "$file" in
1026     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1027   esac
1028 done
1029
1030 if test "x$crt_files" != x; then
1031
1032   ## If user specified a crt-dir, use that unconditionally.
1033   crt_gcc=no
1034
1035   if test "X$CRT_DIR" = "X"; then
1036
1037     CRT_DIR=/usr/lib            # default
1038
1039     case "$canonical" in
1040       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1041       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1042       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1043       ## For anything else (eg /usr/lib32), it is up the user to specify
1044       ## the location (bug#5655).
1045       ## Test for crtn.o, not just the directory, because sometimes the
1046       ## directory exists but does not have the relevant files (bug#1287).
1047       ## FIXME better to test for binary compatibility somehow.
1048       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1049       ;;
1050
1051       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1052     esac
1053
1054     case "$opsys" in
1055       hpux10-20) CRT_DIR=/lib ;;
1056     esac
1057
1058     test "x${GCC}" = xyes && crt_gcc=yes
1059
1060   fi                            # CRT_DIR = ""
1061
1062   crt_missing=
1063
1064   for file in $crt_files; do
1065
1066     ## If we're using gcc, try to determine it automatically by asking
1067     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1068     ## system-dependent default from above.]
1069     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1070
1071        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1072        case "$crt_file" in
1073          */*)
1074            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1075            ;;
1076        esac
1077     fi
1078
1079     dnl We expect all the files to be in a single directory, so after the
1080     dnl first there is no point asking gcc.
1081     crt_gcc=no
1082
1083     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1084   done                          # $crt_files
1085
1086   test "x$crt_missing" = x || \
1087     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1088 Try using the --with-crt-dir option.])
1089
1090 fi                              # crt_files != ""
1091
1092 AC_SUBST(CRT_DIR)
1093
1094 case $opsys in
1095   netbsd | openbsd )
1096     if test -f $CRT_DIR/crti.o; then
1097
1098         test -f $CRT_DIR/crtn.o || \
1099           AC_MSG_ERROR([Required file not found: crtn.o])
1100
1101         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1102         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1103     fi
1104     ;;
1105 esac
1106
1107
1108 # Configure gnulib before invoking PKG_CHECK_MODULES, as the latter might
1109 # for example add -lrt to RSVG_LIBS, which would then cause gnulib to
1110 # incorrectly conclude that -lrt is not needed to link clock_gettime.
1111 gl_ASSERT_NO_GNULIB_POSIXCHECK
1112 gl_ASSERT_NO_GNULIB_TESTS
1113 gl_INIT
1114
1115 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1116
1117 dnl This function definition taken from Gnome 2.0
1118 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1119 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1120 dnl also defines GSTUFF_PKG_ERRORS on error
1121 AC_DEFUN([PKG_CHECK_MODULES], [
1122   succeeded=no
1123
1124   if test "$PKG_CONFIG" = "no" ; then
1125      ifelse([$4], , [AC_MSG_ERROR([
1126       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1127   else
1128      PKG_CONFIG_MIN_VERSION=0.9.0
1129      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1130         AC_MSG_CHECKING(for $2)
1131
1132         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1133            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1134            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1135             edit_cflags="
1136               s,///*,/,g
1137               s/^/ /
1138               s/ -I/ $isystem/g
1139               s/^ //
1140             "
1141             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1142             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1143             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1144             succeeded=yes
1145         else
1146             AC_MSG_RESULT(no)
1147             $1_CFLAGS=""
1148             $1_LIBS=""
1149             ## If we have a custom action on failure, don't print errors, but
1150             ## do set a variable so people can do so.
1151             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1152             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1153         fi
1154
1155         AC_SUBST($1_CFLAGS)
1156         AC_SUBST($1_LIBS)
1157      else
1158         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1159         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1160      fi
1161   fi
1162
1163   if test $succeeded = yes; then
1164      ifelse([$3], , :, [$3])
1165   else
1166      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1167   fi
1168 ])
1169
1170
1171 if test "${with_sound}" != "no"; then
1172   # Sound support for GNU/Linux and the free BSDs.
1173   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1174     have_sound_header=yes)
1175   # Emulation library used on NetBSD.
1176   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1177   AC_SUBST(LIBSOUND)
1178
1179   ALSA_REQUIRED=1.0.0
1180   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1181   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1182   if test $HAVE_ALSA = yes; then
1183     SAVE_CFLAGS="$CFLAGS"
1184     SAVE_LIBS="$LIBS"
1185     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1186     LIBS="$ALSA_LIBS $LIBS"
1187     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1188                     emacs_alsa_normal=yes,
1189                     emacs_alsa_normal=no)
1190     if test "$emacs_alsa_normal" != yes; then
1191       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1192                      [[snd_lib_error_set_handler (0);]])],
1193                      emacs_alsa_subdir=yes,
1194                      emacs_alsa_subdir=no)
1195       if test "$emacs_alsa_subdir" != yes; then
1196         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1197       fi
1198       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1199     fi
1200
1201     CFLAGS="$SAVE_CFLAGS"
1202     LIBS="$SAVE_LIBS"
1203     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1204     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1205     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1206   fi
1207
1208   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1209   dnl compiles only on the specified platforms.  For others, it
1210   dnl probably doesn't make sense to try.
1211   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1212      case "$opsys" in
1213        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1214        gnu-linux|freebsd|netbsd)
1215          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1216          ;;
1217      esac
1218   fi
1219
1220   AC_SUBST(CFLAGS_SOUND)
1221 fi
1222
1223 dnl checks for header files
1224 AC_CHECK_HEADERS_ONCE(
1225   linux/version.h sys/systeminfo.h
1226   stdio_ext.h fcntl.h coff.h pty.h
1227   sys/vlimit.h sys/resource.h
1228   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1229
1230 AC_MSG_CHECKING(if personality LINUX32 can be set)
1231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1232                emacs_cv_personality_linux32=yes,
1233                emacs_cv_personality_linux32=no)
1234 AC_MSG_RESULT($emacs_cv_personality_linux32)
1235
1236 if test $emacs_cv_personality_linux32 = yes; then
1237   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1238             [Define to 1 if personality LINUX32 can be set.])
1239 fi
1240
1241 dnl On Solaris 8 there's a compilation warning for term.h because
1242 dnl it doesn't define `bool'.
1243 AC_CHECK_HEADERS(term.h, , , -)
1244 AC_HEADER_TIME
1245 AC_CHECK_DECLS([sys_siglist])
1246 if test $ac_cv_have_decl_sys_siglist != yes; then
1247   # For Tru64, at least:
1248   AC_CHECK_DECLS([__sys_siglist])
1249   if test $ac_cv_have_decl___sys_siglist = yes; then
1250     AC_DEFINE(sys_siglist, __sys_siglist,
1251               [Define to any substitute for sys_siglist.])
1252   fi
1253 fi
1254 AC_HEADER_SYS_WAIT
1255
1256 dnl Check for speed_t typedef.
1257 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1258   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1259     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1260 if test $emacs_cv_speed_t = yes; then
1261   AC_DEFINE(HAVE_SPEED_T, 1,
1262            [Define to 1 if `speed_t' is declared by <termios.h>.])
1263 fi
1264
1265 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1266 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1267 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1268   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1269 HAVE_EXCEPTION=$emacs_cv_struct_exception
1270 if test $emacs_cv_struct_exception != yes; then
1271   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1272 fi
1273
1274 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1275 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1276 #if HAVE_SYS_SOCKET_H
1277 #include <sys/socket.h>
1278 #endif])
1279 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1280 #if HAVE_SYS_SOCKET_H
1281 #include <sys/socket.h>
1282 #endif])
1283 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1284 #if HAVE_SYS_SOCKET_H
1285 #include <sys/socket.h>
1286 #endif])
1287
1288 dnl checks for structure members
1289 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1290                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1291                   struct ifreq.ifr_addr,
1292                   struct ifreq.ifr_addr.sa_len], , ,
1293                  [AC_INCLUDES_DEFAULT
1294 #if HAVE_SYS_SOCKET_H
1295 #include <sys/socket.h>
1296 #endif
1297 #if HAVE_NET_IF_H
1298 #include <net/if.h>
1299 #endif])
1300
1301 dnl Check for endianness.
1302 dnl AC_C_BIGENDIAN is done by gnulib.
1303
1304 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1305   [emacs_cv_attribute_aligned],
1306   [AC_COMPILE_IFELSE(
1307      [AC_LANG_PROGRAM(
1308         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1309         [[]])],
1310      [emacs_cv_attribute_aligned=yes],
1311      [emacs_cv_attribute_aligned=no])])
1312 if test $emacs_cv_attribute_aligned = yes; then
1313   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1314     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1315 fi
1316
1317 dnl check for Make feature
1318 dnl AC_PROG_MAKE_SET is done by Automake.
1319
1320 DEPFLAGS=
1321 MKDEPDIR=":"
1322 deps_frag=deps.mk
1323 dnl check for GNU Make if we have GCC and autodepend is on.
1324 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1325    AC_MSG_CHECKING([whether we are using GNU Make])
1326    HAVE_GNU_MAKE=no
1327    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1328    if test "x$testval" != x; then
1329       HAVE_GNU_MAKE=yes
1330    else
1331       ac_enable_autodepend=no
1332    fi
1333    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1334    if test $HAVE_GNU_MAKE = yes; then
1335       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1336       SAVE_CFLAGS="$CFLAGS"
1337       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1338       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1339       CFLAGS="$SAVE_CFLAGS"
1340       test -f deps.d || ac_enable_autodepend=no
1341       rm -rf deps.d
1342       AC_MSG_RESULT([$ac_enable_autodepend])
1343    fi
1344    if test $ac_enable_autodepend = yes; then
1345       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1346       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1347       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1348       deps_frag=autodeps.mk
1349    fi
1350 fi
1351 deps_frag=$srcdir/src/$deps_frag
1352 AC_SUBST(MKDEPDIR)
1353 AC_SUBST(DEPFLAGS)
1354 AC_SUBST_FILE(deps_frag)
1355
1356
1357 lisp_frag=$srcdir/src/lisp.mk
1358 AC_SUBST_FILE(lisp_frag)
1359
1360
1361 dnl checks for operating system services
1362 AC_SYS_LONG_FILE_NAMES
1363
1364 #### Choose a window system.
1365
1366 AC_PATH_X
1367 if test "$no_x" = yes; then
1368   window_system=none
1369 else
1370   window_system=x11
1371 fi
1372
1373 LD_SWITCH_X_SITE_RPATH=
1374 if test "${x_libraries}" != NONE; then
1375   if test -n "${x_libraries}"; then
1376     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1377     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1378   fi
1379   x_default_search_path=""
1380   x_search_path=${x_libraries}
1381   if test -z "${x_search_path}"; then
1382     x_search_path=/usr/lib
1383   fi
1384   for x_library in `echo ${x_search_path}: | \
1385                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1386     x_search_path="\
1387 ${x_library}/X11/%L/%T/%N%C%S:\
1388 ${x_library}/X11/%l/%T/%N%C%S:\
1389 ${x_library}/X11/%T/%N%C%S:\
1390 ${x_library}/X11/%L/%T/%N%S:\
1391 ${x_library}/X11/%l/%T/%N%S:\
1392 ${x_library}/X11/%T/%N%S"
1393     if test x"${x_default_search_path}" = x; then
1394       x_default_search_path=${x_search_path}
1395     else
1396       x_default_search_path="${x_search_path}:${x_default_search_path}"
1397     fi
1398   done
1399 fi
1400 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1401
1402 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1403   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1404 fi
1405
1406 if test x"${x_includes}" = x; then
1407   bitmapdir=/usr/include/X11/bitmaps
1408 else
1409   # accumulate include directories that have X11 bitmap subdirectories
1410   bmd_acc="dummyval"
1411   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1412     if test -d "${bmd}/X11/bitmaps"; then
1413       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1414     fi
1415     if test -d "${bmd}/bitmaps"; then
1416       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1417     fi
1418   done
1419   if test ${bmd_acc} != "dummyval"; then
1420     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1421   fi
1422 fi
1423
1424 HAVE_NS=no
1425 NS_IMPL_COCOA=no
1426 NS_IMPL_GNUSTEP=no
1427 tmp_CPPFLAGS="$CPPFLAGS"
1428 tmp_CFLAGS="$CFLAGS"
1429 CPPFLAGS="$CPPFLAGS -x objective-c"
1430 CFLAGS="$CFLAGS -x objective-c"
1431 TEMACS_LDFLAGS2="\${LDFLAGS}"
1432 GNU_OBJC_CFLAGS=
1433 if test "${with_ns}" != no; then
1434   if test "${opsys}" = darwin; then
1435      NS_IMPL_COCOA=yes
1436      ns_appdir=`pwd`/nextstep/Emacs.app
1437      ns_appbindir=${ns_appdir}/Contents/MacOS
1438      ns_appresdir=${ns_appdir}/Contents/Resources
1439      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1440   elif test -f $GNUSTEP_CONFIG_FILE; then
1441      NS_IMPL_GNUSTEP=yes
1442      ns_appdir=`pwd`/nextstep/Emacs.app
1443      ns_appbindir=${ns_appdir}
1444      ns_appresdir=${ns_appdir}/Resources
1445      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1446      dnl FIXME sourcing this several times in subshells seems inefficient.
1447      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1448      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1449      dnl I seemed to need these as well with GNUstep-startup 0.25.
1450      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1451      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1452      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1453        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1454      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1455        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1456      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1457      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1458      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1459      LIB_STANDARD=
1460      START_FILES=
1461      TEMACS_LDFLAGS2=
1462      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1463      dnl If they had chosen to either define it or not, we could have
1464      dnl just used AC_CHECK_DECL here.
1465      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1466        emacs_cv_objc_exceptions,
1467 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1468 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1469 1;
1470 #else
1471 fail;
1472 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1473      if test $emacs_cv_objc_exceptions = yes; then
1474        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1475        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1476          [Define if GNUstep uses ObjC exceptions.])
1477        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1478      fi
1479   fi
1480
1481   dnl This is only used while we test the NS headers, it gets reset below.
1482   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1483
1484   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1485                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1486   files are missing or cannot be compiled.])])
1487   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1488                                      [NSInteger i;])],
1489                     ns_have_nsinteger=yes,
1490                     ns_have_nsinteger=no)
1491   if test $ns_have_nsinteger = yes; then
1492     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1493   fi
1494 fi
1495 AC_SUBST(TEMACS_LDFLAGS2)
1496
1497 INSTALL_ARCH_INDEP_EXTRA=install-etc
1498 ns_self_contained=no
1499 ns_frag=/dev/null
1500 NS_OBJ=
1501 NS_OBJC_OBJ=
1502 if test "${HAVE_NS}" = yes; then
1503   if test "$with_toolkit_scroll_bars" = "no"; then
1504     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1505   fi
1506
1507   window_system=nextstep
1508   with_xft=no
1509   # set up packaging dirs
1510   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1511      ns_self_contained=yes
1512      prefix=${ns_appresdir}
1513      exec_prefix=${ns_appbindir}
1514      dnl This one isn't really used, only archlibdir is.
1515      libexecdir="\${ns_appbindir}/libexec"
1516      archlibdir="\${ns_appbindir}/libexec"
1517      docdir="\${ns_appresdir}/etc"
1518      etcdir="\${ns_appresdir}/etc"
1519      dnl FIXME maybe set datarootdir instead.
1520      dnl That would also get applications, icons, man.
1521      infodir="\${ns_appresdir}/info"
1522      mandir="\${ns_appresdir}/man"
1523      lispdir="\${ns_appresdir}/lisp"
1524      leimdir="\${ns_appresdir}/leim"
1525      INSTALL_ARCH_INDEP_EXTRA=
1526   fi
1527   ns_frag=$srcdir/src/ns.mk
1528   NS_OBJ="fontset.o fringe.o image.o"
1529   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1530 fi
1531 CFLAGS="$tmp_CFLAGS"
1532 CPPFLAGS="$tmp_CPPFLAGS"
1533 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1534 AC_SUBST(ns_self_contained)
1535 AC_SUBST(NS_OBJ)
1536 AC_SUBST(NS_OBJC_OBJ)
1537 AC_SUBST(LIB_STANDARD)
1538 AC_SUBST_FILE(ns_frag)
1539
1540 case "${window_system}" in
1541   x11 )
1542     HAVE_X_WINDOWS=yes
1543     HAVE_X11=yes
1544     case "${with_x_toolkit}" in
1545       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1546       motif ) USE_X_TOOLKIT=MOTIF ;;
1547       gtk ) with_gtk=yes
1548 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1549 dnl USE_X_TOOLKIT is set.
1550             USE_X_TOOLKIT=none ;;
1551       gtk3 ) with_gtk3=yes
1552              USE_X_TOOLKIT=none ;;
1553       no ) USE_X_TOOLKIT=none ;;
1554 dnl If user did not say whether to use a toolkit, make this decision later:
1555 dnl use the toolkit if we have gtk, or X11R5 or newer.
1556       * ) USE_X_TOOLKIT=maybe ;;
1557     esac
1558   ;;
1559   nextstep | none )
1560     HAVE_X_WINDOWS=no
1561     HAVE_X11=no
1562     USE_X_TOOLKIT=none
1563   ;;
1564 esac
1565
1566 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1567    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1568    if test "$HAVE_XSERVER" = true ||
1569       test -n "$DISPLAY" ||
1570       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1571         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1572 were found.  You should install the relevant development files for X
1573 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1574 sure you have development files for image handling, i.e.
1575 tiff, gif, jpeg, png and xpm.
1576 If you are sure you want Emacs compiled without X window support, pass
1577   --without-x
1578 to configure.])
1579    fi
1580 fi
1581
1582 ### If we're using X11, we should use the X menu package.
1583 HAVE_MENUS=no
1584 case ${HAVE_X11} in
1585   yes ) HAVE_MENUS=yes ;;
1586 esac
1587
1588 # Does the opsystem file prohibit the use of the GNU malloc?
1589 # Assume not, until told otherwise.
1590 GNU_MALLOC=yes
1591
1592 AC_CACHE_CHECK(
1593   [whether malloc is Doug Lea style],
1594   [emacs_cv_var_doug_lea_malloc],
1595   [AC_LINK_IFELSE(
1596      [AC_LANG_PROGRAM(
1597         [[#include <malloc.h>
1598           static void hook (void) {}]],
1599         [[malloc_set_state (malloc_get_state ());
1600           __after_morecore_hook = hook;
1601           __malloc_initialize_hook = hook;]])],
1602      [emacs_cv_var_doug_lea_malloc=yes],
1603      [emacs_cv_var_doug_lea_malloc=no])])
1604 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1605
1606
1607 dnl See comments in aix4-2.h about maybe using system malloc there.
1608 system_malloc=no
1609 case "$opsys" in
1610   ## darwin ld insists on the use of malloc routines in the System framework.
1611   darwin|sol2-10) system_malloc=yes ;;
1612 esac
1613
1614 if test "${system_malloc}" = "yes"; then
1615   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1616   GNU_MALLOC=no
1617   GNU_MALLOC_reason="
1618     (The GNU allocators don't work with this system configuration.)"
1619   GMALLOC_OBJ=
1620   VMLIMIT_OBJ=
1621 else
1622   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1623   VMLIMIT_OBJ=vm-limit.o
1624 fi
1625 AC_SUBST(GMALLOC_OBJ)
1626 AC_SUBST(VMLIMIT_OBJ)
1627
1628 if test "$doug_lea_malloc" = "yes" ; then
1629   if test "$GNU_MALLOC" = yes ; then
1630     GNU_MALLOC_reason="
1631       (Using Doug Lea's new malloc from the GNU C Library.)"
1632   fi
1633   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1634             [Define to 1 if you are using the GNU C Library.])
1635
1636   ## Use mmap directly for allocating larger buffers.
1637   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1638   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1639   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1640   case "$opsys" in
1641     gnu*) REL_ALLOC=no ;;
1642   esac
1643 fi
1644
1645 if test x"${REL_ALLOC}" = x; then
1646   REL_ALLOC=${GNU_MALLOC}
1647 fi
1648
1649 use_mmap_for_buffers=no
1650 case "$opsys" in
1651   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1652 esac
1653
1654 AC_FUNC_MMAP
1655 if test $use_mmap_for_buffers = yes; then
1656   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1657   REL_ALLOC=no
1658 fi
1659
1660 LIBS="$LIBS_SYSTEM $LIBS"
1661
1662 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1663 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1664 AC_CHECK_LIB(dnet, dnet_ntoa)
1665 dnl This causes -lresolv to get used in subsequent tests,
1666 dnl which causes failures on some systems such as HPUX 9.
1667 dnl AC_CHECK_LIB(resolv, gethostbyname)
1668
1669 dnl FIXME replace main with a function we actually want from this library.
1670 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1671
1672 dnl Check if pthreads is available.
1673 LIB_PTHREAD=
1674 AC_CHECK_HEADERS_ONCE(pthread.h)
1675 if test "$ac_cv_header_pthread_h"; then
1676   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1677   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1678   dnl testing for pthread_self if Emacs uses gmalloc.c.
1679   if test "$GMALLOC_OBJ" = gmalloc.o; then
1680     emacs_pthread_function=pthread_atfork
1681   else
1682     emacs_pthread_function=pthread_self
1683   fi
1684   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1685 fi
1686 if test "$HAVE_PTHREAD" = yes; then
1687   case "${canonical}" in
1688     *-hpux*) ;;
1689     *) LIB_PTHREAD="-lpthread"
1690        LIBS="$LIB_PTHREAD $LIBS" ;;
1691   esac
1692   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1693 fi
1694 AC_SUBST([LIB_PTHREAD])
1695
1696 AC_CHECK_LIB(pthreads, cma_open)
1697
1698 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1699 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1700 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1701 ## added to LIBS in configure would never contain the pthreads part,
1702 ## but the value used in Makefiles might.  FIXME?
1703 ##
1704 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1705 ## be harmless on older versions of X where it happens to exist.
1706 test "$opsys" = "aix4-2" && \
1707   test $ac_cv_lib_pthreads_cma_open = yes && \
1708   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1709
1710 dnl Check for need for bigtoc support on IBM AIX
1711
1712 case ${host_os} in
1713 aix*)
1714   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1715     case $GCC in
1716     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1717     *) gdb_cv_bigtoc=-bbigtoc ;;
1718     esac
1719
1720     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1721     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1722   ])
1723   ;;
1724 esac
1725
1726 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1727 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1728 # REAL_CPPFLAGS later on.
1729
1730 REAL_CFLAGS="$CFLAGS"
1731 REAL_CPPFLAGS="$CPPFLAGS"
1732
1733 if test "${HAVE_X11}" = "yes"; then
1734   DEFS="$C_SWITCH_X_SITE $DEFS"
1735   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1736   LIBS="-lX11 $LIBS"
1737   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1738   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1739
1740   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1741   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1742   # but it's more convenient here to set LD_RUN_PATH since this
1743   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1744   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1745     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1746     export LD_RUN_PATH
1747   fi
1748
1749   if test "${opsys}" = "gnu-linux"; then
1750     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1751     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1752      [[XOpenDisplay ("foo");]])],
1753      [xgnu_linux_first_failure=no],
1754      [xgnu_linux_first_failure=yes])
1755     if test "${xgnu_linux_first_failure}" = "yes"; then
1756       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1757       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1758       OLD_CPPFLAGS="$CPPFLAGS"
1759       OLD_LIBS="$LIBS"
1760       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1761       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1762       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1763       LIBS="$LIBS -b i486-linuxaout"
1764       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1765        [[XOpenDisplay ("foo");]])],
1766        [xgnu_linux_second_failure=no],
1767        [xgnu_linux_second_failure=yes])
1768       if test "${xgnu_linux_second_failure}" = "yes"; then
1769         # If we get the same failure with -b, there is no use adding -b.
1770         # So take it out.  This plays safe.
1771         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1772         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1773         CPPFLAGS="$OLD_CPPFLAGS"
1774         LIBS="$OLD_LIBS"
1775         AC_MSG_RESULT(no)
1776       else
1777         AC_MSG_RESULT(yes)
1778       fi
1779     else
1780       AC_MSG_RESULT(no)
1781     fi
1782   fi
1783
1784   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1785   # header files included from there.
1786   AC_MSG_CHECKING(for Xkb)
1787   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1788 #include <X11/XKBlib.h>]],
1789         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1790         emacs_xkb=yes, emacs_xkb=no)
1791   AC_MSG_RESULT($emacs_xkb)
1792   if test $emacs_xkb = yes; then
1793     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1794   fi
1795
1796   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1797 XScreenNumberOfScreen)
1798 fi
1799
1800 if test "${window_system}" = "x11"; then
1801   AC_MSG_CHECKING(X11 version 6)
1802   AC_CACHE_VAL(emacs_cv_x11_version_6,
1803   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1804 [[#if XlibSpecificationRelease < 6
1805 fail;
1806 #endif
1807 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1808   if test $emacs_cv_x11_version_6 = yes; then
1809     AC_MSG_RESULT(6 or newer)
1810     AC_DEFINE(HAVE_X11R6, 1,
1811               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1812     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1813     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1814     ## XIM support.
1815     case "$opsys" in
1816       sol2-*) : ;;
1817       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1818            [Define if you have usable X11R6-style XIM support.])
1819          ;;
1820     esac
1821   else
1822     AC_MSG_RESULT(before 6)
1823   fi
1824 fi
1825
1826
1827 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1828 HAVE_RSVG=no
1829 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1830   if test "${with_rsvg}" != "no"; then
1831     RSVG_REQUIRED=2.11.0
1832     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1833
1834     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1835     AC_SUBST(RSVG_CFLAGS)
1836     AC_SUBST(RSVG_LIBS)
1837
1838     if test $HAVE_RSVG = yes; then
1839       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1840       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1841       LIBS="$RSVG_LIBS $LIBS"
1842     fi
1843   fi
1844 fi
1845
1846 HAVE_IMAGEMAGICK=no
1847 if test "${HAVE_X11}" = "yes"; then
1848   if test "${with_imagemagick}" != "no"; then
1849     ## 6.2.8 is the earliest version known to work, but earlier versions
1850     ## might work - let us know if you find one.
1851     ## 6.0.7 does not work.  See bug#7955.
1852     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1853     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1854     AC_SUBST(IMAGEMAGICK_CFLAGS)
1855     AC_SUBST(IMAGEMAGICK_LIBS)
1856
1857     if test $HAVE_IMAGEMAGICK = yes; then
1858       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1859       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1860       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1861       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1862     fi
1863   fi
1864 fi
1865
1866
1867 HAVE_GTK=no
1868 GTK_OBJ=
1869 if test "${with_gtk3}" = "yes"; then
1870   GLIB_REQUIRED=2.28
1871   GTK_REQUIRED=3.0
1872   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1873
1874   dnl Checks for libraries.
1875   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1876   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1877      AC_MSG_ERROR($GTK_PKG_ERRORS)
1878   fi
1879   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1880   GTK_OBJ=emacsgtkfixed.o
1881 fi
1882
1883 if test "$pkg_check_gtk" != "yes"; then
1884   HAVE_GTK=no
1885 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1886   GLIB_REQUIRED=2.10
1887   GTK_REQUIRED=2.10
1888   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1889
1890   dnl Checks for libraries.
1891   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1892   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1893      AC_MSG_ERROR($GTK_PKG_ERRORS)
1894   fi
1895 fi
1896 fi
1897
1898 if test x"$pkg_check_gtk" = xyes; then
1899
1900   AC_SUBST(GTK_CFLAGS)
1901   AC_SUBST(GTK_LIBS)
1902   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1903   CFLAGS="$CFLAGS $GTK_CFLAGS"
1904   LIBS="$GTK_LIBS $LIBS"
1905   dnl Try to compile a simple GTK program.
1906   GTK_COMPILES=no
1907   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1908   if test "${GTK_COMPILES}" != "yes"; then
1909     if test "$USE_X_TOOLKIT" != "maybe"; then
1910       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1911     fi
1912   else
1913     HAVE_GTK=yes
1914     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1915     GTK_OBJ="gtkutil.o $GTK_OBJ"
1916     USE_X_TOOLKIT=none
1917     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1918       :
1919     else
1920       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1921        closing open displays.  This is no problem if you just use
1922        one display, but if you use more than one and close one of them
1923        Emacs may crash.]])
1924       sleep 3
1925     fi
1926   fi
1927
1928 fi
1929 AC_SUBST(GTK_OBJ)
1930
1931
1932 if test "${HAVE_GTK}" = "yes"; then
1933
1934   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1935   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1936   if test "$with_toolkit_scroll_bars" != no; then
1937     with_toolkit_scroll_bars=yes
1938   fi
1939
1940   dnl  Check if we have the old file selection dialog declared and
1941   dnl  in the link library.  In 2.x it may be in the library,
1942   dnl  but not declared if deprecated featured has been selected out.
1943   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1944   HAVE_GTK_FILE_SELECTION=no
1945   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1946                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1947 #include <gtk/gtk.h>])
1948   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1949     AC_CHECK_FUNCS(gtk_file_selection_new)
1950   fi
1951
1952
1953   dnl Check for functions introduced in 2.14 and later.
1954   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1955                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1956                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1957                  gtk_orientable_set_orientation \
1958                  gtk_window_set_has_resize_grip)
1959 fi
1960
1961 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1962 dnl other platforms.
1963 HAVE_DBUS=no
1964 DBUS_OBJ=
1965 if test "${with_dbus}" = "yes"; then
1966    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1967    if test "$HAVE_DBUS" = yes; then
1968      LIBS="$LIBS $DBUS_LIBS"
1969      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1970      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1971      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1972      dnl D-Bus 1.5.12.
1973      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1974                     dbus_type_is_valid \
1975                     dbus_validate_bus_name \
1976                     dbus_validate_path \
1977                     dbus_validate_interface \
1978                     dbus_validate_member)
1979      DBUS_OBJ=dbusbind.o
1980    fi
1981 fi
1982 AC_SUBST(DBUS_OBJ)
1983
1984 dnl GSettings has been tested under GNU/Linux only.
1985 HAVE_GSETTINGS=no
1986 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1987    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1988    if test "$HAVE_GSETTINGS" = "yes"; then
1989       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1990       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1991       SETTINGS_LIBS="$GSETTINGS_LIBS"
1992    fi
1993 fi
1994
1995 dnl GConf has been tested under GNU/Linux only.
1996 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1997 HAVE_GCONF=no
1998 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1999    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2000    if test "$HAVE_GCONF" = yes; then
2001       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2002       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2003       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2004       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2005    fi
2006 fi
2007
2008 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2009     SAVE_CFLAGS="$CFLAGS"
2010     SAVE_LIBS="$LIBS"
2011     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2012     LIBS="$SETTINGS_LIBS $LIBS"
2013     AC_CHECK_FUNCS([g_type_init])
2014     CFLAGS="$SAVE_CFLAGS"
2015     LIBS="$SAVE_LIBS"
2016 fi
2017 AC_SUBST(SETTINGS_CFLAGS)
2018 AC_SUBST(SETTINGS_LIBS)
2019
2020
2021 dnl SELinux is available for GNU/Linux only.
2022 HAVE_LIBSELINUX=no
2023 LIBSELINUX_LIBS=
2024 if test "${with_selinux}" = "yes"; then
2025    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2026    if test "$HAVE_LIBSELINUX" = yes; then
2027       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2028       LIBSELINUX_LIBS=-lselinux
2029    fi
2030 fi
2031 AC_SUBST(LIBSELINUX_LIBS)
2032
2033 HAVE_GNUTLS=no
2034 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2035 if test "${with_gnutls}" = "yes" ; then
2036   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2037   if test "${HAVE_GNUTLS}" = "yes"; then
2038     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2039   fi
2040
2041   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2042   LIBS="$LIBGNUTLS_LIBS $LIBS"
2043   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2044
2045   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2046     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2047   fi
2048 fi
2049
2050 AC_SUBST(LIBGNUTLS_LIBS)
2051 AC_SUBST(LIBGNUTLS_CFLAGS)
2052
2053 dnl Do not put whitespace before the #include statements below.
2054 dnl Older compilers (eg sunos4 cc) choke on it.
2055 HAVE_XAW3D=no
2056 LUCID_LIBW=
2057 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2058   if test "$with_xaw3d" != no; then
2059     AC_MSG_CHECKING(for xaw3d)
2060     AC_CACHE_VAL(emacs_cv_xaw3d,
2061     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2062 #include <X11/Intrinsic.h>
2063 #include <X11/Xaw3d/Simple.h>]],
2064       [[]])],
2065       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2066                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2067       emacs_cv_xaw3d=no)])
2068   else
2069     emacs_cv_xaw3d=no
2070   fi
2071   if test $emacs_cv_xaw3d = yes; then
2072     AC_MSG_RESULT([yes; using Lucid toolkit])
2073     USE_X_TOOLKIT=LUCID
2074     HAVE_XAW3D=yes
2075     LUCID_LIBW=-lXaw3d
2076     AC_DEFINE(HAVE_XAW3D, 1,
2077               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2078   else
2079     AC_MSG_RESULT(no)
2080     AC_MSG_CHECKING(for libXaw)
2081     AC_CACHE_VAL(emacs_cv_xaw,
2082     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2083 #include <X11/Intrinsic.h>
2084 #include <X11/Xaw/Simple.h>]],
2085       [[]])],
2086       emacs_cv_xaw=yes,
2087       emacs_cv_xaw=no)])
2088     if test $emacs_cv_xaw = yes; then
2089       AC_MSG_RESULT([yes; using Lucid toolkit])
2090       USE_X_TOOLKIT=LUCID
2091       LUCID_LIBW=-lXaw
2092     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2093       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2094     else
2095       AC_MSG_ERROR([No X toolkit could be found.
2096 If you are sure you want Emacs compiled without an X toolkit, pass
2097   --with-x-toolkit=no
2098 to configure.  Otherwise, install the development libraries for the toolkit
2099 that you want to use (e.g. Gtk+) and re-run configure.])
2100     fi
2101   fi
2102 fi
2103
2104 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2105
2106 LIBXTR6=
2107 if test "${USE_X_TOOLKIT}" != "none"; then
2108   AC_MSG_CHECKING(X11 toolkit version)
2109   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2110   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2111 [[#if XtSpecificationRelease < 6
2112 fail;
2113 #endif
2114 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2115   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2116   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2117     AC_MSG_RESULT(6 or newer)
2118     AC_DEFINE(HAVE_X11XTR6, 1,
2119               [Define to 1 if you have the X11R6 or newer version of Xt.])
2120     LIBXTR6="-lSM -lICE"
2121     case "$opsys" in
2122       ## Use libw.a along with X11R6 Xt.
2123       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2124     esac
2125   else
2126     AC_MSG_RESULT(before 6)
2127   fi
2128
2129 dnl If using toolkit, check whether libXmu.a exists.
2130 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2131   OLDLIBS="$LIBS"
2132   if test x$HAVE_X11XTR6 = xyes; then
2133     LIBS="-lXt -lSM -lICE $LIBS"
2134   else
2135     LIBS="-lXt $LIBS"
2136   fi
2137   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2138   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2139 fi
2140 AC_SUBST(LIBXTR6)
2141
2142 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2143 dnl Why not just test for libxmu in the normal way?
2144 LIBXMU=-lXmu
2145 case $opsys in
2146   ## These systems don't supply Xmu.
2147   hpux* | aix4-2 )
2148     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2149     ;;
2150 esac
2151 AC_SUBST(LIBXMU)
2152
2153 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2154 if test "${HAVE_X11}" = "yes"; then
2155   if test "${USE_X_TOOLKIT}" != "none"; then
2156     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2157   fi
2158 fi
2159
2160 LIBXP=
2161 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2162   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2163   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2164     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2165 int x = 5;
2166 #else
2167 Motif version prior to 2.1.
2168 #endif]])],
2169     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2170   if test $emacs_cv_motif_version_2_1 = yes; then
2171     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2172   else
2173     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2174     # We put this in CFLAGS temporarily to precede other -I options
2175     # that might be in CFLAGS temporarily.
2176     # We put this in CPPFLAGS where it precedes the other -I options.
2177     OLD_CPPFLAGS=$CPPFLAGS
2178     OLD_CFLAGS=$CFLAGS
2179     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2180     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2181     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2182       [[int x = 5;]])],
2183       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2184     if test $emacs_cv_lesstif = yes; then
2185       # Make sure this -I option remains in CPPFLAGS after it is set
2186       # back to REAL_CPPFLAGS.
2187       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2188       # have those other -I options anyway.  Ultimately, having this
2189       # directory ultimately in CPPFLAGS will be enough.
2190       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2191       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2192     else
2193       CFLAGS=$OLD_CFLAGS
2194       CPPFLAGS=$OLD_CPPFLAGS
2195     fi
2196   fi
2197   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2198     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2199 fi
2200
2201 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2202 dnl using Motif or Xaw3d is available, and unless
2203 dnl --with-toolkit-scroll-bars=no was specified.
2204
2205 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2206             [Define to 1 if we should use toolkit scroll bars.])dnl
2207 USE_TOOLKIT_SCROLL_BARS=no
2208 if test "${with_toolkit_scroll_bars}" != "no"; then
2209   if test "${USE_X_TOOLKIT}" != "none"; then
2210     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2211       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2212       HAVE_XAW3D=no
2213       USE_TOOLKIT_SCROLL_BARS=yes
2214     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2215       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2216       USE_TOOLKIT_SCROLL_BARS=yes
2217     fi
2218   elif test "${HAVE_GTK}" = "yes"; then
2219     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2220     USE_TOOLKIT_SCROLL_BARS=yes
2221   elif test "${HAVE_NS}" = "yes"; then
2222     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2223     USE_TOOLKIT_SCROLL_BARS=yes
2224   fi
2225 fi
2226
2227 dnl See if XIM is available.
2228 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2229           #include <X11/Xlib.h>
2230           #include <X11/Xresource.h>]],
2231          [[XIMProc  callback;]])],
2232          [HAVE_XIM=yes
2233          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2234          HAVE_XIM=no)
2235
2236 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2237
2238 if test "${with_xim}" != "no"; then
2239   AC_DEFINE(USE_XIM, 1,
2240             [Define to 1 if we should use XIM, if it is available.])
2241 fi
2242
2243
2244 if test "${HAVE_XIM}" != "no"; then
2245   late_CFLAGS=$CFLAGS
2246   if test "$GCC" = yes; then
2247     CFLAGS="$CFLAGS --pedantic-errors"
2248   fi
2249   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2250 #include <X11/Xlib.h>
2251 #include <X11/Xresource.h>]],
2252 [[Display *display;
2253 XrmDatabase db;
2254 char *res_name;
2255 char *res_class;
2256 XIMProc  callback;
2257 XPointer *client_data;
2258 #ifndef __GNUC__
2259 /* If we're not using GCC, it's probably not XFree86, and this is
2260    probably right, but we can't use something like --pedantic-errors.  */
2261 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2262                                            char*, XIMProc, XPointer*);
2263 #endif
2264 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2265    client_data);]])],
2266     [emacs_cv_arg6_star=yes])
2267   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2268          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2269 either XPointer or XPointer*.])dnl
2270   if test "$emacs_cv_arg6_star" = yes; then
2271     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2272   else
2273     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2274   fi
2275   CFLAGS=$late_CFLAGS
2276 fi
2277
2278 ### Start of font-backend (under any platform) section.
2279 # (nothing here yet -- this is a placeholder)
2280 ### End of font-backend (under any platform) section.
2281
2282 ### Start of font-backend (under X11) section.
2283 if test "${HAVE_X11}" = "yes"; then
2284    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2285
2286    ## Use -lXft if available, unless `--with-xft=no'.
2287    HAVE_XFT=maybe
2288     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2289       with_xft="no";
2290     fi
2291     if test "x${with_xft}" != "xno"; then
2292
2293       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2294       ## Because xftfont.c uses XRenderQueryExtension, we also
2295       ## need to link to -lXrender.
2296       HAVE_XRENDER=no
2297       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2298       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2299         OLD_CPPFLAGS="$CPPFLAGS"
2300         OLD_CFLAGS="$CFLAGS"
2301         OLD_LIBS="$LIBS"
2302         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2303         CFLAGS="$CFLAGS $XFT_CFLAGS"
2304         XFT_LIBS="-lXrender $XFT_LIBS"
2305         LIBS="$XFT_LIBS $LIBS"
2306         AC_CHECK_HEADER(X11/Xft/Xft.h,
2307           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2308
2309         if test "${HAVE_XFT}" = "yes"; then
2310           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2311             AC_SUBST(XFT_LIBS)
2312           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2313         else
2314           CPPFLAGS="$OLD_CPPFLAGS"
2315           CFLAGS="$OLD_CFLAGS"
2316           LIBS="$OLD_LIBS"
2317         fi                        # "${HAVE_XFT}" = "yes"
2318       fi                          # "$HAVE_XFT" != no
2319     fi                            # "x${with_xft}" != "xno"
2320
2321     ## We used to allow building with FreeType and without Xft.
2322     ## However, the ftx font backend driver is not in good shape.
2323     if test "$HAVE_XFT" != "yes"; then
2324        dnl For the "Does Emacs use" message at the end.
2325        HAVE_XFT=no
2326        HAVE_FREETYPE=no
2327     else
2328        dnl Strict linkers fail with
2329        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2330        dnl if -lfreetype is not specified.
2331        dnl The following is needed to set FREETYPE_LIBS.
2332        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2333                          HAVE_FREETYPE=no)
2334
2335        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2336     fi
2337
2338     HAVE_LIBOTF=no
2339     if test "${HAVE_FREETYPE}" = "yes"; then
2340       AC_DEFINE(HAVE_FREETYPE, 1,
2341                 [Define to 1 if using the freetype and fontconfig libraries.])
2342       if test "${with_libotf}" != "no"; then
2343         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2344                           HAVE_LIBOTF=no)
2345         if test "$HAVE_LIBOTF" = "yes"; then
2346           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2347           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2348                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2349                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2350           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2351             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2352                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2353           fi
2354         fi
2355       fi
2356     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2357     dnl Does the new font backend require it, or can it work without it?
2358     fi
2359
2360     HAVE_M17N_FLT=no
2361     if test "${HAVE_LIBOTF}" = yes; then
2362       if test "${with_m17n_flt}" != "no"; then
2363         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2364         if test "$HAVE_M17N_FLT" = "yes"; then
2365           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2366         fi
2367       fi
2368     fi
2369 else
2370     HAVE_XFT=no
2371     HAVE_FREETYPE=no
2372     HAVE_LIBOTF=no
2373     HAVE_M17N_FLT=no
2374 fi
2375
2376 ### End of font-backend (under X11) section.
2377
2378 AC_SUBST(FREETYPE_CFLAGS)
2379 AC_SUBST(FREETYPE_LIBS)
2380 AC_SUBST(FONTCONFIG_CFLAGS)
2381 AC_SUBST(FONTCONFIG_LIBS)
2382 AC_SUBST(LIBOTF_CFLAGS)
2383 AC_SUBST(LIBOTF_LIBS)
2384 AC_SUBST(M17N_FLT_CFLAGS)
2385 AC_SUBST(M17N_FLT_LIBS)
2386
2387 ### Use -lXpm if available, unless `--with-xpm=no'.
2388 HAVE_XPM=no
2389 LIBXPM=
2390 if test "${HAVE_X11}" = "yes"; then
2391   if test "${with_xpm}" != "no"; then
2392     AC_CHECK_HEADER(X11/xpm.h,
2393       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2394     if test "${HAVE_XPM}" = "yes"; then
2395       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2396       AC_EGREP_CPP(no_return_alloc_pixels,
2397       [#include "X11/xpm.h"
2398 #ifndef XpmReturnAllocPixels
2399 no_return_alloc_pixels
2400 #endif
2401       ], HAVE_XPM=no, HAVE_XPM=yes)
2402
2403       if test "${HAVE_XPM}" = "yes"; then
2404         AC_MSG_RESULT(yes)
2405       else
2406         AC_MSG_RESULT(no)
2407       fi
2408     fi
2409   fi
2410
2411   if test "${HAVE_XPM}" = "yes"; then
2412     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2413     LIBXPM=-lXpm
2414   fi
2415 fi
2416 AC_SUBST(LIBXPM)
2417
2418 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2419 HAVE_JPEG=no
2420 LIBJPEG=
2421 if test "${HAVE_X11}" = "yes"; then
2422   if test "${with_jpeg}" != "no"; then
2423     dnl Checking for jpeglib.h can lose because of a redefinition of
2424     dnl  HAVE_STDLIB_H.
2425     AC_CHECK_HEADER(jerror.h,
2426       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2427   fi
2428
2429   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2430   if test "${HAVE_JPEG}" = "yes"; then
2431     AC_DEFINE(HAVE_JPEG)
2432     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2433         [#include <jpeglib.h>
2434          version=JPEG_LIB_VERSION
2435 ],
2436         [AC_DEFINE(HAVE_JPEG)],
2437         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2438         HAVE_JPEG=no])
2439   fi
2440   if test "${HAVE_JPEG}" = "yes"; then
2441     LIBJPEG=-ljpeg
2442   fi
2443 fi
2444 AC_SUBST(LIBJPEG)
2445
2446 ### Use -lpng if available, unless `--with-png=no'.
2447 HAVE_PNG=no
2448 LIBPNG=
2449 if test "${HAVE_X11}" = "yes"; then
2450   if test "${with_png}" != "no"; then
2451     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2452     # in /usr/include/libpng.
2453     AC_CHECK_HEADERS(png.h libpng/png.h)
2454     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2455       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2456     fi
2457   fi
2458
2459   if test "${HAVE_PNG}" = "yes"; then
2460     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2461     LIBPNG="-lpng -lz -lm"
2462   fi
2463 fi
2464 AC_SUBST(LIBPNG)
2465
2466 ### Use -ltiff if available, unless `--with-tiff=no'.
2467 HAVE_TIFF=no
2468 LIBTIFF=
2469 if test "${HAVE_X11}" = "yes"; then
2470   if test "${with_tiff}" != "no"; then
2471     AC_CHECK_HEADER(tiffio.h,
2472       [tifflibs="-lz -lm"
2473       # At least one tiff package requires the jpeg library.
2474       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2475       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2476   fi
2477
2478   if test "${HAVE_TIFF}" = "yes"; then
2479     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2480     dnl FIXME -lz -lm, as per libpng?
2481     LIBTIFF=-ltiff
2482   fi
2483 fi
2484 AC_SUBST(LIBTIFF)
2485
2486 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2487 HAVE_GIF=no
2488 LIBGIF=
2489 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2490   AC_CHECK_HEADER(gif_lib.h,
2491 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2492 # Earlier versions can crash Emacs.
2493     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2494
2495   if test "$HAVE_GIF" = yes; then
2496     LIBGIF=-lgif
2497   elif test "$HAVE_GIF" = maybe; then
2498 # If gif_lib.h but no libgif, try libungif.
2499     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2500     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2501   fi
2502
2503   if test "${HAVE_GIF}" = "yes"; then
2504     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2505   fi
2506 fi
2507 AC_SUBST(LIBGIF)
2508
2509 dnl Check for required libraries.
2510 if test "${HAVE_X11}" = "yes"; then
2511   MISSING=""
2512   WITH_NO=""
2513   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2514     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2515   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2516     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2517   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2518     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2519   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2520     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2521   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2522     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2523
2524   if test "X${MISSING}" != X; then
2525     AC_MSG_ERROR([The following required libraries were not found:
2526     $MISSING
2527 Maybe some development libraries/packages are missing?
2528 If you don't want to link with them give
2529     $WITH_NO
2530 as options to configure])
2531   fi
2532 fi
2533
2534 ### Use -lgpm if available, unless `--with-gpm=no'.
2535 HAVE_GPM=no
2536 LIBGPM=
2537 if test "${with_gpm}" != "no"; then
2538   AC_CHECK_HEADER(gpm.h,
2539     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2540
2541   if test "${HAVE_GPM}" = "yes"; then
2542     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2543     LIBGPM=-lgpm
2544   fi
2545 fi
2546 AC_SUBST(LIBGPM)
2547
2548 dnl Check for malloc/malloc.h on darwin
2549 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2550
2551 GNUSTEP_CFLAGS=
2552 ### Use NeXTstep API to implement GUI.
2553 if test "${HAVE_NS}" = "yes"; then
2554   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2555   if test "${NS_IMPL_COCOA}" = "yes"; then
2556     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2557   fi
2558   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2559     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2560     # See also .m.o rule in Makefile.in */
2561     # FIXME: are all these flags really needed?  Document here why.  */
2562     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2563     ## Extra CFLAGS applied to src/*.m files.
2564     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2565   fi
2566   # We also have mouse menus.
2567   HAVE_MENUS=yes
2568   OTHER_FILES=ns-app
2569 fi
2570
2571
2572 ### Use session management (-lSM -lICE) if available
2573 HAVE_X_SM=no
2574 LIBXSM=
2575 if test "${HAVE_X11}" = "yes"; then
2576   AC_CHECK_HEADER(X11/SM/SMlib.h,
2577     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2578
2579   if test "${HAVE_X_SM}" = "yes"; then
2580     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2581     LIBXSM="-lSM -lICE"
2582     case "$LIBS" in
2583       *-lSM*) ;;
2584       *)      LIBS="$LIBXSM $LIBS" ;;
2585     esac
2586   fi
2587 fi
2588 AC_SUBST(LIBXSM)
2589
2590 ### Use libxml (-lxml2) if available
2591 HAVE_LIBXML2=no
2592 if test "${with_xml2}" != "no"; then
2593   ### I'm not sure what the version number should be, so I just guessed.
2594   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2595   if test "${HAVE_LIBXML2}" = "yes"; then
2596     LIBS="$LIBXML2_LIBS $LIBS"
2597     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2598     if test "${HAVE_LIBXML2}" = "yes"; then
2599       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2600     else
2601       LIBXML2_LIBS=""
2602       LIBXML2_CFLAGS=""
2603     fi
2604   fi
2605 fi
2606 AC_SUBST(LIBXML2_LIBS)
2607 AC_SUBST(LIBXML2_CFLAGS)
2608
2609 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2610 AC_CACHE_CHECK(whether netdb declares h_errno,
2611                emacs_cv_netdb_declares_h_errno,
2612 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2613   [[return h_errno;]])],
2614   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2615 if test $emacs_cv_netdb_declares_h_errno = yes; then
2616   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2617 fi
2618
2619 # fmod, logb, and frexp are found in -lm on most systems.
2620 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2621 AC_CHECK_LIB(m, sqrt)
2622
2623 # Check for mail-locking functions in a "mail" library.  Probably this should
2624 # have the same check as for liblockfile below.
2625 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2626 if test $have_mail = yes; then
2627   LIBS_MAIL=-lmail
2628   LIBS="$LIBS_MAIL $LIBS"
2629   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2630 else
2631   LIBS_MAIL=
2632 fi
2633 dnl Debian, at least:
2634 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2635 if test $have_lockfile = yes; then
2636    LIBS_MAIL=-llockfile
2637    LIBS="$LIBS_MAIL $LIBS"
2638    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2639 else
2640 # If we have the shared liblockfile, assume we must use it for mail
2641 # locking (e.g. Debian).  If we couldn't link against liblockfile
2642 # (no liblockfile.a installed), ensure that we don't need to.
2643   dnl This works for files generally, not just executables.
2644   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2645   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2646                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2647   if test $ac_cv_prog_liblockfile = yes; then
2648     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2649 This probably means that movemail could lose mail.
2650 There may be a `development' package to install containing liblockfile.])
2651   fi
2652 fi
2653 AC_CHECK_HEADERS_ONCE(maillock.h)
2654 AC_SUBST(LIBS_MAIL)
2655
2656 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2657 ## interlock access to the mail spool.  The alternative is a lock file named
2658 ## /usr/spool/mail/$USER.lock.
2659 mail_lock=no
2660 case "$opsys" in
2661   aix4-2) mail_lock="lockf" ;;
2662
2663   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2664
2665   ## On GNU/Linux systems, both methods are used by various mail programs.
2666   ## I assume most people are using newer mailers that have heard of flock.
2667   ## Change this if you need to.
2668   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2669   ## configure gets the right answers, and that means *NOT* using flock.
2670   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2671   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2672   ## Debian maintainer hasn't provided a clean fix for Emacs.
2673   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2674   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2675   ## correct logic.  -- fx
2676   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2677   ## liblockfile is a Free Software replacement for libmail, used on
2678   ## Debian systems and elsewhere. -rfr.
2679   gnu-*)
2680     mail_lock="flock"
2681     if test $have_mail = yes || test $have_lockfile = yes; then
2682       test $ac_cv_header_maillock_h = yes && mail_lock=no
2683     fi
2684     ;;
2685 esac
2686
2687 BLESSMAIL_TARGET=
2688 case "$mail_lock" in
2689   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2690
2691   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2692
2693   *) BLESSMAIL_TARGET="need-blessmail" ;;
2694 esac
2695 AC_SUBST(BLESSMAIL_TARGET)
2696
2697
2698 AC_CHECK_FUNCS(gethostname \
2699 rename closedir mkdir rmdir getrusage get_current_dir_name \
2700 lrand48 logb frexp fmod cbrt setsid \
2701 strerror fpathconf select euidaccess getpagesize setlocale \
2702 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2703 __fpending strsignal setitimer \
2704 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2705 gai_strerror mkstemp getline getdelim fsync sync \
2706 difftime posix_memalign \
2707 getpwent endpwent getgrent endgrent \
2708 touchlock \
2709 cfmakeraw cfsetspeed copysign __executable_start)
2710
2711 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2712 if test $opsys != unixware; then
2713   AC_CHECK_FUNCS(getwd)
2714 fi
2715
2716 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2717 ## has a broken `rint' in some library versions including math library
2718 ## version number A.09.05.
2719 ## You can fix the math library by installing patch number PHSS_4630.
2720 ## But we can fix it more reliably for Emacs by just not using rint.
2721 ## We also skip HAVE_RANDOM - see comments in src/s/hpux10-20.h.
2722 case $opsys in
2723    hpux*) : ;;
2724    *) AC_CHECK_FUNCS(random rint) ;;
2725 esac
2726
2727 dnl Cannot use AC_CHECK_FUNCS
2728 AC_CACHE_CHECK([for __builtin_unwind_init],
2729                emacs_cv_func___builtin_unwind_init,
2730 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2731                 emacs_cv_func___builtin_unwind_init=yes,
2732                 emacs_cv_func___builtin_unwind_init=no)])
2733 if test $emacs_cv_func___builtin_unwind_init = yes; then
2734   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2735             [Define to 1 if you have the `__builtin_unwind_init' function.])
2736 fi
2737
2738 AC_CHECK_HEADERS_ONCE(sys/un.h)
2739
2740 AC_FUNC_FSEEKO
2741
2742 AC_FUNC_GETPGRP
2743
2744 # UNIX98 PTYs.
2745 AC_CHECK_FUNCS(grantpt)
2746
2747 # PTY-related GNU extensions.
2748 AC_CHECK_FUNCS(getpt)
2749
2750 # Check this now, so that we will NOT find the above functions in ncurses.
2751 # That is because we have not set up to link ncurses in lib-src.
2752 # It's better to believe a function is not available
2753 # than to expect to find it in ncurses.
2754 # Also we need tputs and friends to be able to build at all.
2755 AC_MSG_CHECKING([for library containing tputs])
2756 # Run a test program that contains a call to tputs, a call that is
2757 # never executed.  This tests whether a pre-'main' dynamic linker
2758 # works with the library.  It's too much trouble to actually call
2759 # tputs in the test program, due to portability hassles.  When
2760 # cross-compiling, assume the test program will run if it links.
2761 AC_DEFUN([tputs_link_source], [
2762   AC_LANG_SOURCE(
2763      [[extern void tputs (const char *, int, int (*)(int));
2764        int main (int argc, char **argv)
2765        {
2766           if (argc == 10000)
2767             tputs (argv[0], 0, 0);
2768           return 0;
2769        }]])
2770 ])
2771 # Maybe curses should be tried earlier?
2772 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2773 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2774   OLIBS=$LIBS
2775   if test -z "$tputs_library"; then
2776     LIBS_TERMCAP=
2777     msg='none required'
2778   else
2779     LIBS_TERMCAP=-l$tputs_library
2780     msg=$LIBS_TERMCAP
2781     LIBS="$LIBS_TERMCAP $LIBS"
2782   fi
2783   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2784     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2785   LIBS=$OLIBS
2786   if test "X$msg" != Xno; then
2787     break
2788   fi
2789 done
2790 AC_MSG_RESULT([$msg])
2791 if test "X$msg" = Xno; then
2792   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2793 The following libraries were tried (in order):
2794   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2795 Please try installing whichever of these libraries is most appropriate
2796 for your system, together with its header files.
2797 For example, a libncurses-dev(el) or similar package.])
2798 fi
2799
2800 ## Use termcap instead of terminfo?
2801 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2802 TERMINFO=yes
2803 ## FIXME?  In the cases below where we unconditionally set
2804 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2805 ## if that was found above to have tputs.
2806 ## Should we use the gnu* logic everywhere?
2807 case "$opsys" in
2808   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2809   ##  The ncurses library has been moved out of the System framework in
2810   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2811   ##  option to use it.
2812   darwin) LIBS_TERMCAP="-lncurses" ;;
2813
2814   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2815
2816   freebsd)
2817     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2818     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2819     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2820 [[#if __FreeBSD_version < 400000
2821 fail;
2822 #endif
2823 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2824
2825     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2826
2827     if test $emacs_cv_freebsd_terminfo = yes; then
2828       LIBS_TERMCAP="-lncurses"
2829     else
2830       TERMINFO=no
2831       LIBS_TERMCAP="-ltermcap"
2832     fi
2833     ;;
2834
2835   netbsd)
2836     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2837       TERMINFO=no
2838       LIBS_TERMCAP="-ltermcap"
2839     fi
2840     ;;
2841
2842   openbsd) LIBS_TERMCAP="-lncurses" ;;
2843
2844   ## hpux: Make sure we get select from libc rather than from libcurses
2845   ##  because libcurses on HPUX 10.10 has a broken version of select.
2846   ##  We used to use -lc -lcurses, but this may be cleaner.
2847   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2848   # set that way, now it uses the default).  Isn't this a contradiction?
2849   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2850
2851 esac
2852
2853 TERMCAP_OBJ=tparam.o
2854 if test $TERMINFO = yes; then
2855   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2856   TERMCAP_OBJ=terminfo.o
2857 fi
2858 AC_SUBST(LIBS_TERMCAP)
2859 AC_SUBST(TERMCAP_OBJ)
2860
2861
2862 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2863 # On Darwin, res_init appears not to be useful: see bug#562 and
2864 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2865 resolv=no
2866
2867 if test $opsys != darwin; then
2868
2869   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2870 #include <arpa/nameser.h>
2871 #include <resolv.h>]],
2872     [[return res_init();]])],
2873     have_res_init=yes, have_res_init=no)
2874   if test "$have_res_init" = no; then
2875     OLIBS="$LIBS"
2876     LIBS="$LIBS -lresolv"
2877     AC_MSG_CHECKING(for res_init with -lresolv)
2878     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2879 #include <arpa/nameser.h>
2880 #include <resolv.h>]],
2881       [[return res_init();]])],
2882       have_res_init=yes, have_res_init=no)
2883     AC_MSG_RESULT($have_res_init)
2884     if test "$have_res_init" = yes ; then
2885       resolv=yes
2886     fi
2887     LIBS="$OLIBS"
2888   fi
2889
2890   if test "$have_res_init" = yes; then
2891     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2892   fi
2893 fi                              dnl !darwin
2894
2895 # Do we need the Hesiod library to provide the support routines?
2896 dnl FIXME?  Should we be skipping this on Darwin too?
2897 LIBHESIOD=
2898 if test "$with_hesiod" != no ; then
2899   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2900   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2901      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2902                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2903   if test "$resolv" = yes ; then
2904     RESOLVLIB=-lresolv
2905   else
2906     RESOLVLIB=
2907   fi
2908   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2909         hesiod=yes, :, $RESOLVLIB)])
2910
2911   if test x"$hesiod" = xyes; then
2912     AC_DEFINE(HAVE_LIBHESIOD, 1,
2913               [Define to 1 if you have the hesiod library (-lhesiod).])
2914     LIBHESIOD=-lhesiod
2915   fi
2916 fi
2917 AC_SUBST(LIBHESIOD)
2918
2919 # Do we need libresolv (due to res_init or Hesiod)?
2920 if test "$resolv" = yes && test $opsys != darwin; then
2921   AC_DEFINE(HAVE_LIBRESOLV, 1,
2922             [Define to 1 if you have the resolv library (-lresolv).])
2923   LIBRESOLV=-lresolv
2924 else
2925   LIBRESOLV=
2926 fi
2927 AC_SUBST(LIBRESOLV)
2928
2929 # These tell us which Kerberos-related libraries to use.
2930 COM_ERRLIB=
2931 CRYPTOLIB=
2932 KRB5LIB=
2933 DESLIB=
2934 KRB4LIB=
2935
2936 if test "${with_kerberos}" != no; then
2937   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2938   if test $have_com_err = yes; then
2939     COM_ERRLIB=-lcom_err
2940     LIBS="$COM_ERRLIB $LIBS"
2941     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2942   fi
2943   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2944   if test $have_crypto = yes; then
2945     CRYPTOLIB=-lcrypto
2946     LIBS="$CRYPTOLIB $LIBS"
2947     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2948   fi
2949   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2950   if test $have_k5crypto = yes; then
2951     CRYPTOLIB=-lk5crypto
2952     LIBS="$CRYPTOLIB $LIBS"
2953     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2954   fi
2955   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2956   if test $have_krb5=yes; then
2957     KRB5LIB=-lkrb5
2958     LIBS="$KRB5LIB $LIBS"
2959     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2960   fi
2961   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2962   if test "${with_kerberos5}" = no; then
2963     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2964     if test $have_des425 = yes; then
2965       DESLIB=-ldes425
2966       LIBS="$DESLIB $LIBS"
2967       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2968     else
2969       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2970       if test $have_des = yes; then
2971         DESLIB=-ldes
2972         LIBS="$DESLIB $LIBS"
2973         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2974       fi
2975     fi
2976     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2977     if test $have_krb4 = yes; then
2978       KRB4LIB=-lkrb4
2979       LIBS="$KRB4LIB $LIBS"
2980       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2981     else
2982       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2983       if test $have_krb = yes; then
2984         KRB4LIB=-lkrb
2985         LIBS="$KRB4LIB $LIBS"
2986         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2987       fi
2988     fi
2989   fi
2990
2991   if test "${with_kerberos5}" != no; then
2992     AC_CHECK_HEADERS(krb5.h,
2993       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2994                         [#include <krb5.h>])])
2995   else
2996     AC_CHECK_HEADERS(des.h,,
2997                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2998                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2999     AC_CHECK_HEADERS(krb.h,,
3000                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3001                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3002   fi
3003   AC_CHECK_HEADERS(com_err.h)
3004 fi
3005
3006 AC_SUBST(COM_ERRLIB)
3007 AC_SUBST(CRYPTOLIB)
3008 AC_SUBST(KRB5LIB)
3009 AC_SUBST(DESLIB)
3010 AC_SUBST(KRB4LIB)
3011
3012 AC_CHECK_FUNCS(tzset)
3013 AC_MSG_CHECKING(whether localtime caches TZ)
3014 AC_CACHE_VAL(emacs_cv_localtime_cache,
3015 [if test x$ac_cv_func_tzset = xyes; then
3016 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3017 char TZ_GMT0[] = "TZ=GMT0";
3018 char TZ_PST8[] = "TZ=PST8";
3019 main()
3020 {
3021   time_t now = time ((time_t *) 0);
3022   int hour_GMT0, hour_unset;
3023   if (putenv (TZ_GMT0) != 0)
3024     exit (1);
3025   hour_GMT0 = localtime (&now)->tm_hour;
3026   unsetenv("TZ");
3027   hour_unset = localtime (&now)->tm_hour;
3028   if (putenv (TZ_PST8) != 0)
3029     exit (1);
3030   if (localtime (&now)->tm_hour == hour_GMT0)
3031     exit (1);
3032   unsetenv("TZ");
3033   if (localtime (&now)->tm_hour != hour_unset)
3034     exit (1);
3035   exit (0);
3036 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3037 [# If we have tzset, assume the worst when cross-compiling.
3038 emacs_cv_localtime_cache=yes])
3039 else
3040         # If we lack tzset, report that localtime does not cache TZ,
3041         # since we can't invalidate the cache if we don't have tzset.
3042         emacs_cv_localtime_cache=no
3043 fi])dnl
3044 AC_MSG_RESULT($emacs_cv_localtime_cache)
3045 if test $emacs_cv_localtime_cache = yes; then
3046   AC_DEFINE(LOCALTIME_CACHE, 1,
3047             [Define to 1 if localtime caches TZ.])
3048 fi
3049
3050 ok_so_far=yes
3051 AC_CHECK_FUNC(socket, , ok_so_far=no)
3052 if test $ok_so_far = yes; then
3053   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3054 fi
3055 if test $ok_so_far = yes; then
3056   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3057 fi
3058 if test $ok_so_far = yes; then
3059 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3060   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3061             [Define to 1 if you have inet sockets.])
3062 fi
3063
3064 if test -f /usr/lpp/X11/bin/smt.exp; then
3065   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3066             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3067 fi
3068
3069 AC_MSG_CHECKING(whether system supports dynamic ptys)
3070 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3071   AC_MSG_RESULT(yes)
3072   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3073 else
3074   AC_MSG_RESULT(no)
3075 fi
3076
3077 AC_FUNC_FORK
3078
3079 AC_CHECK_FUNCS(snprintf)
3080
3081 dnl Adapted from Haible's version.
3082 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3083   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3084     [[char* cs = nl_langinfo(CODESET);]])],
3085     emacs_cv_langinfo_codeset=yes,
3086     emacs_cv_langinfo_codeset=no)
3087   ])
3088 if test $emacs_cv_langinfo_codeset = yes; then
3089   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3090     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3091 fi
3092
3093 AC_TYPE_MBSTATE_T
3094
3095 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3096   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3097                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3098 if test "$emacs_cv_c_restrict_arr" = yes; then
3099   AC_DEFINE(__restrict_arr, __restrict,
3100     [Define to compiler's equivalent of C99 restrict keyword in array
3101      declarations.  Define as empty for no equivalent.])
3102 fi
3103
3104 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3105 dnl how the tty code is related to POSIX and/or other versions of termios.
3106 dnl The following looks like a useful start.
3107 dnl
3108 dnl AC_SYS_POSIX_TERMIOS
3109 dnl if test $ac_cv_sys_posix_termios = yes; then
3110 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3111 dnl                                and macros for terminal control.])
3112 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3113 dnl fi
3114
3115 case $opsys in
3116   darwin | gnu | hpux* | *bsd )
3117     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3118   ;;
3119 esac
3120
3121 dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3122 dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3123 case $opsys in
3124   hpux* | irix6-5 | openbsd | sol2* | unixware )
3125     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3126   ;;
3127 esac
3128
3129 case $opsys in
3130   gnu-* | sol2-10 )
3131     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3132     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3133   ;;
3134 esac
3135
3136 case $opsys in
3137    gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3138
3139    hpux11)
3140      dnl See comments in sysdep.c:sys_signal.
3141      dnl SA_RESTART resets the timeout of `select' on hpux11.
3142      dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3143      AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3144        be used in batch mode.])
3145      dnl It works to open the pty's tty in the parent (Emacs), then
3146      dnl close and reopen it in the child.
3147      AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3148        works to open a pty's tty in the parent process, then close and
3149        reopen it in the child.])
3150
3151      opsysfile="s/hpux10-20.h"
3152    ;;
3153
3154    openbsd) opsysfile="s/netbsd.h" ;;
3155
3156    sol2-10)
3157      AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3158        on Solaris.])
3159      opsysfile="s/sol2-6.h"
3160    ;;
3161 esac
3162
3163 # Set up the CFLAGS for real compilation, so we can substitute it.
3164 CFLAGS="$REAL_CFLAGS"
3165 CPPFLAGS="$REAL_CPPFLAGS"
3166
3167 ## Hack to detect a buggy GCC version.
3168 if test "x$GCC" = xyes \
3169    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3170    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3171    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3172    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3173 fi
3174
3175 version=$PACKAGE_VERSION
3176
3177 ### Specify what sort of things we'll be editing into Makefile and config.h.
3178 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3179 AC_SUBST(version)
3180 AC_SUBST(configuration)
3181 ## Unused?
3182 AC_SUBST(canonical)
3183 AC_SUBST(srcdir)
3184 AC_SUBST(prefix)
3185 AC_SUBST(exec_prefix)
3186 AC_SUBST(bindir)
3187 AC_SUBST(datadir)
3188 AC_SUBST(sharedstatedir)
3189 AC_SUBST(libexecdir)
3190 AC_SUBST(mandir)
3191 AC_SUBST(infodir)
3192 AC_SUBST(lispdir)
3193 AC_SUBST(leimdir)
3194 AC_SUBST(standardlisppath)
3195 AC_SUBST(locallisppath)
3196 AC_SUBST(lisppath)
3197 AC_SUBST(x_default_search_path)
3198 AC_SUBST(etcdir)
3199 AC_SUBST(archlibdir)
3200 AC_SUBST(docdir)
3201 AC_SUBST(bitmapdir)
3202 AC_SUBST(gamedir)
3203 AC_SUBST(gameuser)
3204 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3205 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3206 ## end of LIBX_BASE, but nothing ever set it.
3207 AC_SUBST(LD_SWITCH_X_SITE)
3208 AC_SUBST(C_SWITCH_X_SITE)
3209 AC_SUBST(GNUSTEP_CFLAGS)
3210 AC_SUBST(CFLAGS)
3211 ## Used in lwlib/Makefile.in.
3212 AC_SUBST(X_TOOLKIT_TYPE)
3213 if test -n "${opsysfile}"; then
3214   S_FILE="\$(srcdir)/${opsysfile}"
3215 else
3216   S_FILE=
3217 fi
3218 AC_SUBST(S_FILE)
3219 AC_SUBST(ns_appdir)
3220 AC_SUBST(ns_appbindir)
3221 AC_SUBST(ns_appresdir)
3222 AC_SUBST(ns_appsrc)
3223 AC_SUBST(GNU_OBJC_CFLAGS)
3224 AC_SUBST(OTHER_FILES)
3225
3226 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3227                    [Define to the canonical Emacs configuration name.])
3228 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3229                    [Define to the options passed to configure.])
3230 if test -n "$opsysfile"; then
3231   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3232                      [Define to the used os dependent file.])
3233 fi
3234
3235 XMENU_OBJ=
3236 XOBJ=
3237 FONT_OBJ=
3238 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3239   AC_DEFINE(HAVE_X_WINDOWS, 1,
3240             [Define to 1 if you want to use the X window system.])
3241   XMENU_OBJ=xmenu.o
3242   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3243   FONT_OBJ=xfont.o
3244   if test "$HAVE_XFT" = "yes"; then
3245     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3246   elif test "$HAVE_FREETYPE" = "yes"; then
3247     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3248   fi
3249   AC_SUBST(FONT_OBJ)
3250 fi
3251 AC_SUBST(XMENU_OBJ)
3252 AC_SUBST(XOBJ)
3253 AC_SUBST(FONT_OBJ)
3254
3255 WIDGET_OBJ=
3256 MOTIF_LIBW=
3257 if test "${USE_X_TOOLKIT}" != "none" ; then
3258   WIDGET_OBJ=widget.o
3259   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3260   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3261     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3262   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3263     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3264     MOTIF_LIBW=-lXm
3265     case "$opsys" in
3266       gnu-linux)
3267         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3268         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3269         ;;
3270
3271       unixware)
3272         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3273         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3274         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3275         ;;
3276
3277       aix4-2)
3278         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3279         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3280         ;;
3281     esac
3282     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3283   fi
3284 fi
3285 AC_SUBST(WIDGET_OBJ)
3286
3287 TOOLKIT_LIBW=
3288 case "$USE_X_TOOLKIT" in
3289   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3290   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3291   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3292 esac
3293 AC_SUBST(TOOLKIT_LIBW)
3294
3295 if test "$USE_X_TOOLKIT" = "none"; then
3296   LIBXT_OTHER="\$(LIBXSM)"
3297   OLDXMENU_TARGET="really-oldXMenu"
3298 else
3299   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3300   OLDXMENU_TARGET="really-lwlib"
3301 fi
3302 AC_SUBST(LIBXT_OTHER)
3303
3304 ## The X Menu stuff is present in the X10 distribution, but missing
3305 ## from X11.  If we have X10, just use the installed library;
3306 ## otherwise, use our own copy.
3307 if test "${HAVE_X11}" = "yes" ; then
3308   AC_DEFINE(HAVE_X11, 1,
3309             [Define to 1 if you want to use version 11 of X windows.
3310              Otherwise, Emacs expects to use version 10.])
3311
3312   if test "$USE_X_TOOLKIT" = "none"; then
3313     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3314   else
3315     OLDXMENU="\${lwlibdir}/liblw.a"
3316   fi
3317   LIBXMENU="\$(OLDXMENU)"
3318   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3319   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3320 else
3321   ## For a syntactically valid Makefile; not actually used for anything.
3322   ## See comments in src/Makefile.in.
3323   OLDXMENU=nothing
3324   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3325   if test "${HAVE_X_WINDOWS}" = "yes"; then
3326     LIBXMENU="-lXMenu"
3327   else
3328     LIBXMENU=
3329   fi
3330   LIBX_OTHER=
3331   OLDXMENU_DEPS=
3332 fi
3333
3334 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3335   OLDXMENU_TARGET=
3336   OLDXMENU=nothing
3337   LIBXMENU=
3338   OLDXMENU_DEPS=
3339 fi
3340
3341 AC_SUBST(OLDXMENU_TARGET)
3342 AC_SUBST(OLDXMENU)
3343 AC_SUBST(LIBXMENU)
3344 AC_SUBST(LIBX_OTHER)
3345 AC_SUBST(OLDXMENU_DEPS)
3346
3347 if test "${HAVE_MENUS}" = "yes" ; then
3348   AC_DEFINE(HAVE_MENUS, 1,
3349             [Define to 1 if you have mouse menus.
3350              (This is automatic if you use X, but the option to specify it remains.)
3351              It is also defined with other window systems that support xmenu.c.])
3352 fi
3353
3354 if test "${GNU_MALLOC}" = "yes" ; then
3355   AC_DEFINE(GNU_MALLOC, 1,
3356             [Define to 1 if you want to use the GNU memory allocator.])
3357 fi
3358
3359 RALLOC_OBJ=
3360 if test "${REL_ALLOC}" = "yes" ; then
3361   AC_DEFINE(REL_ALLOC, 1,
3362             [Define REL_ALLOC if you want to use the relocating allocator for
3363              buffer space.])
3364
3365   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3366 fi
3367 AC_SUBST(RALLOC_OBJ)
3368
3369 if test "$opsys" = "cygwin"; then
3370   CYGWIN_OBJ="sheap.o"
3371   ## Cygwin differs because of its unexec().
3372   PRE_ALLOC_OBJ=
3373   POST_ALLOC_OBJ=lastfile.o
3374 else
3375   CYGWIN_OBJ=
3376   PRE_ALLOC_OBJ=lastfile.o
3377   POST_ALLOC_OBJ=
3378 fi
3379 AC_SUBST(CYGWIN_OBJ)
3380 AC_SUBST(PRE_ALLOC_OBJ)
3381 AC_SUBST(POST_ALLOC_OBJ)
3382
3383 case "$opsys" in
3384   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3385
3386   darwin)
3387    ## The -headerpad option tells ld (see man page) to leave room at the
3388    ## end of the header for adding load commands.  Needed for dumping.
3389    ## 0x690 is the total size of 30 segment load commands (at 56
3390    ## each); under Cocoa 31 commands are required.
3391    if test "$HAVE_NS" = "yes"; then
3392      libs_nsgui="-framework AppKit"
3393      headerpad_extra=6C8
3394    else
3395      libs_nsgui=
3396      headerpad_extra=690
3397    fi
3398    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3399
3400    ## This is here because src/Makefile.in did some extra fiddling around
3401    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3402    ##   #ifndef LD_SWITCH_SYSTEM
3403    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3404    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3405    ## not using gcc, darwin.
3406    ## Because this was done in src/Makefile.in, the resulting part of
3407    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3408    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3409    ## rather than LD_SWITCH_SYSTEM.
3410    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3411      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3412    ;;
3413
3414   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3415   ## find X at run-time.
3416   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3417   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3418   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3419   ## had different values in configure (in ac_link) and src/Makefile.in.
3420   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3421   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3422
3423   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3424 esac
3425
3426 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3427   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3428 fi
3429
3430 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3431
3432
3433 LD_FIRSTFLAG=
3434 ORDINARY_LINK=
3435 case "$opsys" in
3436   ## gnu: GNU needs its own crt0.
3437   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3438
3439   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3440   ## library search parth, i.e. it won't search /usr/lib for libc and
3441   ## friends.  Using -nostartfiles instead avoids this problem, and
3442   ## will also work on earlier NetBSD releases.
3443   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3444
3445   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3446   ##   MkLinux/LinuxPPC needs this.
3447   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3448   gnu-*)
3449     case "$canonical" in
3450       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3451     esac
3452     ;;
3453 esac
3454
3455
3456 if test "x$ORDINARY_LINK" = "xyes"; then
3457
3458   LD_FIRSTFLAG=""
3459   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3460
3461 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3462 ## freebsd, gnu-* not on powerpc*|s390x*.
3463 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3464
3465   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3466   ## places that are difficult to figure out at make time.  Fortunately,
3467   ## these same versions allow you to pass arbitrary flags on to the
3468   ## linker, so there is no reason not to use it as a linker.
3469   ##
3470   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3471   ## searching for libraries in its internal directories, so we have to
3472   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3473   LD_FIRSTFLAG="-nostdlib"
3474 fi
3475
3476 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3477 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3478
3479 AC_SUBST(LD_FIRSTFLAG)
3480
3481
3482 ## FIXME? The logic here is not precisely the same as that above.
3483 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3484 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3485 LIB_GCC=
3486 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3487
3488   case "$opsys" in
3489     freebsd|netbsd|openbsd) LIB_GCC= ;;
3490
3491     gnu-*)
3492       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3493       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3494       case $host_cpu in
3495       arm*)
3496         LIB_GCC="-lgcc_s"
3497         ;;
3498       *)
3499         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3500         ## immediately undefine it again and redefine it to empty.
3501         ## Was the C_SWITCH_X_SITE part really necessary?
3502 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3503         LIB_GCC=
3504         ;;
3505       esac
3506       ;;
3507
3508     ## Ask GCC where to find libgcc.a.
3509     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3510   esac
3511 fi                              dnl if $GCC
3512 AC_SUBST(LIB_GCC)
3513
3514
3515 ## If we're using X11/GNUstep, define some consequences.
3516 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3517   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3518   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3519 fi
3520
3521
3522 AH_TOP([/* GNU Emacs site configuration template file.
3523
3524 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3525   Free Software Foundation, Inc.
3526
3527 This file is part of GNU Emacs.
3528
3529 GNU Emacs is free software: you can redistribute it and/or modify
3530 it under the terms of the GNU General Public License as published by
3531 the Free Software Foundation, either version 3 of the License, or
3532 (at your option) any later version.
3533
3534 GNU Emacs is distributed in the hope that it will be useful,
3535 but WITHOUT ANY WARRANTY; without even the implied warranty of
3536 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3537 GNU General Public License for more details.
3538
3539 You should have received a copy of the GNU General Public License
3540 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3541
3542
3543 /* No code in Emacs #includes config.h twice, but some bits of code
3544    intended to work with other packages as well (like gmalloc.c)
3545    think they can include it as many times as they like.  */
3546 #ifndef EMACS_CONFIG_H
3547 #define EMACS_CONFIG_H
3548 ])dnl
3549
3550 AH_BOTTOM([
3551 /* On AIX 3 this must be included before any other include file.  */
3552 #include <alloca.h>
3553 #if ! HAVE_ALLOCA
3554 # error "alloca not available on this machine"
3555 #endif
3556
3557 /* Define AMPERSAND_FULL_NAME if you use the convention
3558    that & in the full name stands for the login id.  */
3559 /* Turned on June 1996 supposing nobody will mind it.  */
3560 #define AMPERSAND_FULL_NAME
3561
3562 /* `subprocesses' should be defined if you want to
3563    have code for asynchronous subprocesses
3564    (as used in M-x compile and M-x shell).
3565    Only MSDOS does not support this (it overrides
3566    this in its config_opsysfile below).  */
3567
3568 #define subprocesses
3569
3570 /* Include the os dependent file.  */
3571 #ifdef config_opsysfile
3572 # include config_opsysfile
3573 #endif
3574
3575 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3576    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3577   (There is probably a better place to do this, but right now the
3578    Cocoa side does this in s/darwin.h and we cannot parallel this
3579    exactly since GNUstep is multi-OS.  */
3580 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3581 #  define SYSTEM_PURESIZE_EXTRA 30000
3582 #endif
3583
3584 #ifdef emacs /* Don't do this for lib-src.  */
3585 /* Tell regex.c to use a type compatible with Emacs.  */
3586 #define RE_TRANSLATE_TYPE Lisp_Object
3587 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3588 #ifdef make_number
3589 /* If make_number is a macro, use it.  */
3590 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3591 #else
3592 /* If make_number is a function, avoid it.  */
3593 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3594 #endif
3595 #endif
3596
3597 #include <string.h>
3598 #include <stdlib.h>
3599
3600 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3601 #define NO_INLINE __attribute__((noinline))
3602 #else
3603 #define NO_INLINE
3604 #endif
3605
3606 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3607 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3608 #else
3609 #define EXTERNALLY_VISIBLE
3610 #endif
3611
3612 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3613 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3614 #else
3615 # define ATTRIBUTE_FORMAT(spec) /* empty */
3616 #endif
3617
3618 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3619 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3620    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3621 #else
3622 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3623    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3624 #endif
3625
3626 /* Some versions of GNU/Linux define noinline in their headers.  */
3627 #ifdef noinline
3628 #undef noinline
3629 #endif
3630
3631 /* These won't be used automatically yet.  We also need to know, at least,
3632    that the stack is continuous.  */
3633 #ifdef __GNUC__
3634 #  ifndef GC_SETJMP_WORKS
3635   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3636 #    define GC_SETJMP_WORKS 1
3637 #  endif
3638 #endif
3639
3640 #endif /* EMACS_CONFIG_H */
3641
3642 /*
3643 Local Variables:
3644 mode: c
3645 End:
3646 */
3647 ])dnl
3648
3649 #### Report on what we decided to do.
3650 #### Report GTK as a toolkit, even if it doesn't use Xt.
3651 #### It makes printing result more understandable as using GTK sets
3652 #### toolkit_scroll_bars to yes by default.
3653 if test "${HAVE_GTK}" = "yes"; then
3654   USE_X_TOOLKIT=GTK
3655 fi
3656
3657 echo "
3658 Configured for \`${canonical}'.
3659
3660   Where should the build process find the source code?    ${srcdir}
3661   What operating system file should Emacs use?            ${opsysfile-none}
3662   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3663   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3664   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3665   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3666   What window system should Emacs use?                    ${window_system}
3667   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3668
3669 if test -n "${x_includes}"; then
3670 echo "  Where do we find X Windows header files?                ${x_includes}"
3671 else
3672 echo "  Where do we find X Windows header files?                Standard dirs"
3673 fi
3674 if test -n "${x_libraries}"; then
3675 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3676 else
3677 echo "  Where do we find X Windows libraries?                   Standard dirs"
3678 fi
3679
3680 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3681 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3682 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3683 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3684 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3685 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3686 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3687 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3688
3689 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3690 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3691 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3692 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3693 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3694 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3695 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3696
3697 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3698 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3699 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3700 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3701
3702 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3703 echo
3704
3705 if test -n "${EMACSDATA}"; then
3706    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3707 fi
3708 if test -n "${EMACSDOC}"; then
3709    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3710 fi
3711
3712 echo
3713
3714 if test "$HAVE_NS" = "yes"; then
3715    echo
3716    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3717 The installed application will go to nextstep/Emacs.app and can be
3718 run or moved from there."
3719    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3720       echo "The application will be fully self-contained."
3721     else
3722       echo "The lisp resources for the application will be installed under ${prefix}.
3723 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3724 to run if these resources are not installed."
3725    fi
3726    echo
3727 fi
3728
3729 if test "${opsys}" = "cygwin"; then
3730   case `uname -r` in
3731     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3732            echo
3733            ;;
3734   esac
3735 fi
3736
3737 # Remove any trailing slashes in these variables.
3738 [test "${prefix}" != NONE &&
3739   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3740 test "${exec_prefix}" != NONE &&
3741   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3742
3743 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3744 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3745 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3746 dnl (else you get "no `Makefile.am' found for any configure output").
3747 dnl This will work, but you get a config.status that is not quite right
3748 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3749 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3750 dnl it seems better to just live with the duplication.
3751 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3752
3753 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3754        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3755        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3756        leim/Makefile])
3757
3758 dnl test/ is not present in release tarfiles.
3759 opt_makefile=test/automated/Makefile
3760
3761 if test -f $srcdir/${opt_makefile}.in; then
3762   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3763   dnl Again, it's best not to use a variable.  Though you can add
3764   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3765   AC_CONFIG_FILES([test/automated/Makefile])
3766 fi
3767
3768
3769 dnl admin/ may or may not be present.
3770 opt_makefile=admin/unidata/Makefile
3771
3772 if test -f $srcdir/${opt_makefile}.in; then
3773   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3774   AC_CONFIG_FILES([admin/unidata/Makefile])
3775 fi
3776
3777
3778 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3779
3780 AC_SUBST(SUBDIR_MAKEFILES_IN)
3781
3782 dnl Make the necessary directories, if they don't exist.
3783 AC_CONFIG_COMMANDS([mkdirs], [
3784 for dir in etc lisp ; do
3785   test -d ${dir} || mkdir ${dir}
3786 done
3787 ])
3788
3789 dnl You might wonder (I did) why epaths.h is generated by running make,
3790 dnl rather than just letting configure generate it from epaths.in.
3791 dnl One reason is that the various paths are not fully expanded (see above);
3792 dnl eg gamedir=${prefix}/var/games/emacs.
3793 dnl Secondly, the GNU Coding standards require that one should be able
3794 dnl to run `make prefix=/some/where/else' and override the values set
3795 dnl by configure.  This also explains the `move-if-change' test and
3796 dnl the use of force in the `epaths-force' rule in Makefile.in.
3797 AC_CONFIG_COMMANDS([epaths], [
3798 echo creating src/epaths.h
3799 ${MAKE-make} epaths-force
3800 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3801
3802 AC_CONFIG_COMMANDS([gdbinit], [
3803 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3804   echo creating src/.gdbinit
3805   echo source $srcdir/src/.gdbinit > src/.gdbinit
3806 fi
3807 ])
3808
3809 AC_OUTPUT
3810
3811 dnl configure.in ends here