lisp/gnus/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   7 ;;         Jim Radford <radford@robby.caltech.edu>
   8 ;; Keywords: mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Todo, major things:
  28 ;;
  29 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  30 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  31 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  32 ;;   o Sieve
  33 ;;   o MIME (partial article fetches)
  34 ;;   o Split to other backends, different split rules for different
  35 ;;     servers/inboxes
  36 ;;
  37 ;; Todo, minor things:
  38 ;;
  39 ;;   o Don't require half of Gnus -- backends should be standalone
  40 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  41 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  42 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  43 ;;   o What do I do with gnus-newsgroup-*?
  44 ;;   o Tell Gnus about new groups (how can we tell?)
  45 ;;   o Respooling (fix Gnus?) (unnecessary?)
  46 ;;   o Add support for the following: (if applicable)
  47 ;;       request-list-newsgroups, request-regenerate
  48 ;;       list-active-group,
  49 ;;       request-associate-buffer, request-restore-buffer,
  50 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  51 ;;   o Support RFC2221 (Login referrals)
  52 ;;   o IMAP2BIS compatibility? (RFC2061)
  53 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  54 ;;     .newsrc.eld)
  55 ;;   o What about Gnus's article editing, can we support it?  NO!
  56 ;;   o Use \Draft to support the draft group??
  57 ;;   o Duplicate suppression
  58 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  59
  60 ;;; Code:
  61
  62 (require 'imap)
  63 (require 'nnoo)
  64 (require 'nnmail)
  65 (require 'nnheader)
  66 (require 'mm-util)
  67 (require 'gnus)
  68 (require 'gnus-range)
  69 (require 'gnus-start)
  70 (require 'gnus-int)
  71
  72 (eval-when-compile (require 'cl))
  73
  74 (nnoo-declare nnimap)
  75
  76 (defconst nnimap-version "nnimap 1.0")
  77
  78 (defgroup nnimap nil
  79   "Reading IMAP mail with Gnus."
  80   :group 'gnus)
  81
  82 (defvoo nnimap-address nil
  83   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  84
  85 (defvoo nnimap-server-port nil
  86   "Port number on physical IMAP server.
  87 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  88
  89 ;; Splitting variables
  90
  91 (defcustom nnimap-split-crosspost t
  92   "If non-nil, do crossposting if several split methods match the mail.
  93 If nil, the first match found will be used."
  94   :group 'nnimap
  95   :type 'boolean)
  96
  97 (defcustom nnimap-split-inbox nil
  98   "Name of mailbox to split mail from.
  99
 100 Mail is read from this mailbox and split according to rules in
 101 `nnimap-split-rule'.
 102
 103 This can be a string or a list of strings."
 104   :group 'nnimap
 105   :type '(choice (string)
 106                  (repeat string)))
 107
 108 (define-widget 'nnimap-strict-function 'function
 109   "This widget only matches values that are functionp.
 110
 111 Warning: This means that a value that is the symbol of a not yet
 112 loaded function will not match.  Use with care."
 113   :match 'nnimap-strict-function-match)
 114
 115 (defun nnimap-strict-function-match (widget value)
 116   "Ignoring WIDGET, match if VALUE is a function."
 117   (functionp value))
 118
 119 (defcustom nnimap-split-rule nil
 120   "Mail will be split according to these rules.
 121
 122 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 123
 124 If you'd like, for instance, one mail group for mail from the
 125 \"gnus-imap\" mailing list, one group for junk mail and leave
 126 everything else in the incoming mailbox, you could do something like
 127 this:
 128
 129 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 130                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 131
 132 As you can see, `nnimap-split-rule' is a list of lists, where the
 133 first element in each \"rule\" is the name of the IMAP mailbox (or the
 134 symbol `junk' if you want to remove the mail), and the second is a
 135 regexp that nnimap will try to match on the header to find a fit.
 136
 137 The second element can also be a function.  In that case, it will be
 138 called narrowed to the headers with the first element of the rule as
 139 the argument.  It should return a non-nil value if it thinks that the
 140 mail belongs in that group.
 141
 142 This variable can also have a function as its value, the function will
 143 be called with the headers narrowed and should return a group where it
 144 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 145
 146 To allow for different split rules on different virtual servers, and
 147 even different split rules in different inboxes on the same server,
 148 the syntax of this variable have been extended along the lines of:
 149
 150 \(setq nnimap-split-rule
 151       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 152                                   (\"junk\"    \"From:.*Simon\")))
 153         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 154         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 155                                   (\"junk\"    my-junk-func)))))
 156
 157 The virtual server name is in fact a regexp, so that the same rules
 158 may apply to several servers.  In the example, the servers
 159 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 160 the inbox string is also a regexp.  The actual splitting rules are as
 161 before, either a function, or a list with group/regexp or
 162 group/function elements."
 163   :group 'nnimap
 164   :type '(choice :tag "Rule type"
 165                  (repeat :menu-tag "Single-server"
 166                          :tag "Single-server list"
 167                          (list (string :tag "Mailbox")
 168                                (choice :tag "Predicate"
 169                                        (regexp :tag "A regexp")
 170                                        (nnimap-strict-function :tag "A function"))))
 171                  (choice :menu-tag "A function"
 172                          :tag "A function"
 173                          (function-item nnimap-split-fancy)
 174                          (function-item nnmail-split-fancy)
 175                          (nnimap-strict-function :tag "User-defined function"))
 176                  (repeat :menu-tag "Multi-server (extended)"
 177                          :tag "Multi-server list"
 178                          (list (regexp :tag "Server regexp")
 179                                (list (regexp :tag "Incoming Mailbox regexp")
 180                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 181                                              (list (string :tag "Destination mailbox")
 182                                                    (choice :tag "Predicate"
 183                                                            (regexp :tag "A Regexp")
 184                                                            (nnimap-strict-function :tag "A Function")))))))))
 185
 186 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 187   "The predicate used to find articles to split.
 188 If you use another IMAP client to peek on articles but always would
 189 like nnimap to split them once it's started, you could change this to
 190 \"UNDELETED\". Other available predicates are available in
 191 RFC2060 section 6.4.4."
 192   :group 'nnimap
 193   :type 'string)
 194
 195 (defcustom nnimap-split-fancy nil
 196   "Like the variable `nnmail-split-fancy'."
 197   :group 'nnimap
 198   :type 'sexp)
 199
 200 (defvar nnimap-split-download-body-default nil
 201   "Internal variable with default value for `nnimap-split-download-body'.")
 202
 203 (defcustom nnimap-split-download-body 'default
 204   "Whether to download entire articles during splitting.
 205 This is generally not required, and will slow things down considerably.
 206 You may need it if you want to use an advanced splitting function that
 207 analyzes the body before splitting the article.
 208 If this variable is nil, bodies will not be downloaded; if this
 209 variable is the symbol `default' the default behavior is
 210 used (which currently is nil, unless you use a statistical
 211 spam.el test); if this variable is another non-nil value bodies
 212 will be downloaded."
 213   :version "22.1"
 214   :group 'nnimap
 215   :type '(choice (const :tag "Let system decide" deault)
 216                  boolean))
 217
 218 ;; Performance / bug workaround variables
 219
 220 (defcustom nnimap-close-asynchronous t
 221   "Close mailboxes asynchronously in `nnimap-close-group'.
 222 This means that errors caught by nnimap when closing the mailbox will
 223 not prevent Gnus from updating the group status, which may be harmful.
 224 However, it increases speed."
 225   :version "22.1"
 226   :type 'boolean
 227   :group 'nnimap)
 228
 229 (defcustom nnimap-dont-close t
 230   "Never close mailboxes.
 231 This increases the speed of closing mailboxes (quiting group) but may
 232 decrease the speed of selecting another mailbox later.  Re-selecting
 233 the same mailbox will be faster though."
 234   :version "22.1"
 235   :type 'boolean
 236   :group 'nnimap)
 237
 238 (defcustom nnimap-retrieve-groups-asynchronous t
 239   "Send asynchronous STATUS commands for each mailbox before checking mail.
 240 If you have mailboxes that rarely receives mail, this speeds up new
 241 mail checking.  It works by first sending STATUS commands for each
 242 mailbox, and then only checking groups which has a modified UIDNEXT
 243 more carefully for new mail.
 244
 245 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 246 it O(n).  If p is small, then the default is probably faster."
 247   :version "22.1"
 248   :type 'boolean
 249   :group 'nnimap)
 250
 251 (defvoo nnimap-need-unselect-to-notice-new-mail t
 252   "Unselect mailboxes before looking for new mail in them.
 253 Some servers seem to need this under some circumstances.")
 254
 255 (defvoo nnimap-logout-timeout nil
 256   "Close server immediately if it can't logout in this number of seconds.
 257 If it is nil, never close server until logout completes.  This variable
 258 overrides `imap-logout-timeout' on a per-server basis.")
 259
 260 ;; Authorization / Privacy variables
 261
 262 (defvoo nnimap-auth-method nil
 263   "Obsolete.")
 264
 265 (defvoo nnimap-stream nil
 266   "How nnimap will connect to the server.
 267
 268 The default, nil, will try to use the \"best\" method the server can
 269 handle.
 270
 271 Change this if
 272
 273 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 274    with IMAP is suboptimal so you'll have to tell it
 275    specifically.
 276
 277 2) your server is more capable than your environment -- i.e. your
 278    server accept Kerberos login's but you haven't installed the
 279    `imtest' program or your machine isn't configured for Kerberos.
 280
 281 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 282 See also `imap-streams' and `imap-stream-alist'.")
 283
 284 (defvoo nnimap-authenticator nil
 285   "How nnimap authenticate itself to the server.
 286
 287 The default, nil, will try to use the \"best\" method the server can
 288 handle.
 289
 290 There is only one reason for fiddling with this variable, and that is
 291 if your server is more capable than your environment -- i.e. you
 292 connect to a server that accept Kerberos login's but you haven't
 293 installed the `imtest' program or your machine isn't configured for
 294 Kerberos.
 295
 296 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 297 See also `imap-authenticators' and `imap-authenticator-alist'")
 298
 299 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 300   "Directory to keep NOV cache files for nnimap groups.
 301 See also `nnimap-nov-file-name'.")
 302
 303 (defvoo nnimap-nov-file-name "nnimap."
 304   "NOV cache base filename.
 305 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 306 typical complete file name would be
 307 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 308 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 309 `nnmail-use-long-file-names' is nil")
 310
 311 (defvoo nnimap-nov-file-name-suffix ".novcache"
 312   "Suffix for NOV cache base filename.")
 313
 314 (defvoo nnimap-nov-is-evil gnus-agent
 315   "If non-nil, never generate or use a local nov database for this backend.
 316 Using nov databases should speed up header fetching considerably.
 317 However, it will invoke a UID SEARCH UID command on the server, and
 318 some servers implement this command inefficiently by opening each and
 319 every message in the group, thus making it quite slow.
 320 Unlike other backends, you do not need to take special care if you
 321 flip this variable.")
 322
 323 (defvoo nnimap-search-uids-not-since-is-evil nil
 324   "If non-nil, avoid \"UID SEARCH UID ... NOT SINCE\" queries when expiring.
 325 Instead, use \"UID SEARCH SINCE\" to prune the list of expirable
 326 articles within Gnus.  This seems to be faster on Courier in some cases.")
 327
 328 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 329   "Whether to expunge a group when it is closed.
 330 When a IMAP group with articles marked for deletion is closed, this
 331 variable determine if nnimap should actually remove the articles or
 332 not.
 333
 334 If always, nnimap always perform a expunge when closing the group.
 335 If never, nnimap never expunges articles marked for deletion.
 336 If ask, nnimap will ask you if you wish to expunge marked articles.
 337
 338 When setting this variable to `never', you can only expunge articles
 339 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 340
 341 (defvoo nnimap-list-pattern "*"
 342   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 343 See below for available wildcards.
 344
 345 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 346 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 347 semantics of this are server specific, on the University of Washington
 348 server you can specify a directory.
 349
 350 Example:
 351  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 352
 353 There are two wildcards * and %. * matches everything, % matches
 354 everything in the current hierarchy.")
 355
 356 (defvoo nnimap-news-groups nil
 357   "IMAP support a news-like mode, also known as bulletin board mode,
 358 where replies is sent via IMAP instead of SMTP.
 359
 360 This variable should contain a regexp matching groups where you wish
 361 replies to be stored to the mailbox directly.
 362
 363 Example:
 364   '(\"^[^I][^N][^B][^O][^X].*$\")
 365
 366 This will match all groups not beginning with \"INBOX\".
 367
 368 Note that there is nothing technically different between mail-like and
 369 news-like mailboxes.  If you wish to have a group with todo items or
 370 similar which you wouldn't want to set up a mailing list for, you can
 371 use this to make replies go directly to the group.")
 372
 373 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 374   "IMAP search command to use for articles that are to be expired.
 375 The first %s is replaced by a UID set of articles to search on,
 376 and the second %s is replaced by a date criterium.
 377
 378 One useful (and perhaps the only useful) value to change this to would
 379 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 380 instead of the internal date of messages.  See section 6.4.4 of RFC
 381 2060 for more information on valid strings.
 382
 383 However, if `nnimap-search-uids-not-since-is-evil' is true, this
 384 variable has no effect since the search logic is reversed.")
 385
 386 (defvoo nnimap-importantize-dormant t
 387   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 388 Note that within Gnus, dormant articles will still (only) be
 389 marked as ticked.  This is to make \"dormant\" articles stand out,
 390 just like \"ticked\" articles, in other IMAP clients.")
 391
 392 (defvoo nnimap-server-address nil
 393   "Obsolete.  Use `nnimap-address'.")
 394
 395 (defcustom nnimap-authinfo-file "~/.authinfo"
 396   "Authorization information for IMAP servers.  In .netrc format."
 397   :type
 398   '(choice file
 399            (repeat :tag "Entries"
 400                    :menu-tag "Inline"
 401                    (list :format "%v"
 402                          :value ("" ("login" . "") ("password" . ""))
 403                          (string :tag "Host")
 404                          (checklist :inline t
 405                                     (cons :format "%v"
 406                                           (const :format "" "login")
 407                                           (string :format "Login: %v"))
 408                                     (cons :format "%v"
 409                                           (const :format "" "password")
 410                                           (string :format "Password: %v"))))))
 411   :group 'nnimap)
 412
 413 (defcustom nnimap-prune-cache t
 414   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 415   :type 'boolean
 416   :group 'nnimap)
 417
 418 (defvar nnimap-request-list-method 'imap-mailbox-list
 419   "Method to use to request a list of all folders from the server.
 420 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 421 restrict visible folders.")
 422
 423 (defcustom nnimap-id nil
 424   "Plist with client identity to send to server upon login.
 425 Nil means no information is sent, symbol `no' to disable ID query
 426 alltogheter, or plist with identifier-value pairs to send to
 427 server.  RFC 2971 describes the list as follows:
 428
 429    Any string may be sent as a field, but the following are defined to
 430    describe certain values that might be sent.  Implementations are free
 431    to send none, any, or all of these.  Strings are not case-sensitive.
 432    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 433    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 434    than 30 field-value pairs.
 435
 436      name            Name of the program
 437      version         Version number of the program
 438      os              Name of the operating system
 439      os-version      Version of the operating system
 440      vendor          Vendor of the client/server
 441      support-url     URL to contact for support
 442      address         Postal address of contact/vendor
 443      date            Date program was released, specified as a date-time
 444                        in IMAP4rev1
 445      command         Command used to start the program
 446      arguments       Arguments supplied on the command line, if any
 447                        if any
 448      environment     Description of environment, i.e., UNIX environment
 449                        variables or Windows registry settings
 450
 451    Implementations MUST NOT send the same field name more than once.
 452
 453 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 454 \"os\" system-configuration \"vendor\" \"GNU\")."
 455   :group 'nnimap
 456   :type '(choice (const :tag "No information" nil)
 457                  (const :tag "Disable ID query" no)
 458                  (plist :key-type string :value-type string)))
 459
 460 (defcustom nnimap-debug nil
 461   "If non-nil, random debug spews are placed in *nnimap-debug* buffer.
 462 Note that username, passwords and other privacy sensitive
 463 information (such as e-mail) may be stored in the *nnimap-debug*
 464 buffer.  It is not written to disk, however.  Do not enable this
 465 variable unless you are comfortable with that."
 466   :group 'nnimap
 467   :type 'boolean)
 468
 469 ;; Internal variables:
 470
 471 (defvar nnimap-debug-buffer "*nnimap-debug*")
 472 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 473 (defvar nnimap-current-move-server nil)
 474 (defvar nnimap-current-move-group nil)
 475 (defvar nnimap-current-move-article nil)
 476 (defvar nnimap-length)
 477 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 478 (defvar nnimap-progress-how-often 20)
 479 (defvar nnimap-counter)
 480 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 481 (defvar nnimap-current-server nil) ;; Current server
 482 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 483
 484 \f
 485
 486 (nnoo-define-basics nnimap)
 487
 488 ;; Utility functions:
 489
 490 (defsubst nnimap-get-server-buffer (server)
 491   "Return buffer for SERVER, if nil use current server."
 492   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 493
 494 (defun nnimap-remove-server-from-buffer-alist (server list)
 495   "Remove SERVER from LIST."
 496   (let (l)
 497     (dolist (e list)
 498       (unless (equal server (car-safe e))
 499         (push e l)))
 500     l))
 501
 502 (defun nnimap-possibly-change-server (server)
 503   "Return buffer for SERVER, changing the current server as a side-effect.
 504 If SERVER is nil, uses the current server."
 505   (setq nnimap-current-server (or server nnimap-current-server)
 506         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 507
 508 (defun nnimap-verify-uidvalidity (group server)
 509   "Verify stored uidvalidity match current one in GROUP on SERVER."
 510   (let* ((gnusgroup (gnus-group-prefixed-name
 511                      group (gnus-server-to-method
 512                             (format "nnimap:%s" server))))
 513          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 514          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 515          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 516          (nameuid (nnheader-translate-file-chars
 517                    (concat nnimap-nov-file-name
 518                            (if (equal server "")
 519                                "unnamed"
 520                              server) "." group "." old-uidvalidity
 521                            nnimap-nov-file-name-suffix) t))
 522          (file (if (or nnmail-use-long-file-names
 523                        (file-exists-p (expand-file-name nameuid dir)))
 524                    (expand-file-name nameuid dir)
 525                  (expand-file-name
 526                   (mm-encode-coding-string
 527                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 528                    nnmail-pathname-coding-system)
 529                   dir))))
 530     (if old-uidvalidity
 531         (if (not (equal old-uidvalidity new-uidvalidity))
 532             ;; uidvalidity clash
 533             (gnus-delete-file file)
 534           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 535           t)
 536       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 537       t)))
 538
 539 (defun nnimap-before-find-minmax-bugworkaround ()
 540   "Function called before iterating through mailboxes with
 541 `nnimap-find-minmax-uid'."
 542   (when nnimap-need-unselect-to-notice-new-mail
 543     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 544     ;; currently selected mailbox without a re-select/examine.
 545     (or (null (imap-current-mailbox nnimap-server-buffer))
 546         (imap-mailbox-unselect nnimap-server-buffer))))
 547
 548 (defun nnimap-find-minmax-uid (group &optional examine)
 549   "Find lowest and highest active article number in GROUP.
 550 If EXAMINE is non-nil the group is selected read-only."
 551   (with-current-buffer nnimap-server-buffer
 552     (when (or (string= group (imap-current-mailbox))
 553               (imap-mailbox-select group examine))
 554       (let (minuid maxuid)
 555         (when (> (imap-mailbox-get 'exists) 0)
 556           (imap-fetch (if imap-enable-exchange-bug-workaround "1,*:*" "1,*")
 557                       "UID" nil 'nouidfetch)
 558           (imap-message-map (lambda (uid Uid)
 559                               (setq minuid (if minuid (min minuid uid) uid)
 560                                     maxuid (if maxuid (max maxuid uid) uid)))
 561                             'UID))
 562         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 563
 564 (defun nnimap-possibly-change-group (group &optional server)
 565   "Make GROUP the current group, and SERVER the current server."
 566   (when (nnimap-possibly-change-server server)
 567     (with-current-buffer nnimap-server-buffer
 568       (if (or (null group) (imap-current-mailbox-p group))
 569           imap-current-mailbox
 570         (if (imap-mailbox-select group)
 571             (if (or (nnimap-verify-uidvalidity
 572                      group (or server nnimap-current-server))
 573                     (zerop (imap-mailbox-get 'exists group))
 574                     t ;; for OGnus to see if ignoring uidvalidity
 575                     ;; changes has any bad effects.
 576                     (yes-or-no-p
 577                      (format
 578                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 579                 imap-current-mailbox
 580               (imap-mailbox-unselect)
 581               (error "nnimap: Group %s is not uid-valid" group))
 582           (nnheader-report 'nnimap (imap-error-text)))))))
 583
 584 (defun nnimap-replace-whitespace (string)
 585   "Return STRING with all whitespace replaced with space."
 586   (when string
 587     (while (string-match "[\r\n\t]+" string)
 588       (setq string (replace-match " " t t string)))
 589     string))
 590
 591 ;; Required backend functions
 592
 593 (defun nnimap-retrieve-headers-progress ()
 594   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 595   (and (numberp nnmail-large-newsgroup)
 596        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 597        (> nnimap-length nnmail-large-newsgroup)
 598        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 599                          (nth (/ (% nnimap-counter
 600                                     (* (length nnimap-progress-chars)
 601                                        nnimap-progress-how-often))
 602                                  nnimap-progress-how-often)
 603                               nnimap-progress-chars)))
 604   (with-current-buffer nntp-server-buffer
 605     (let (headers lines chars uid mbx)
 606       (with-current-buffer nnimap-server-buffer
 607         (setq uid imap-current-message
 608               mbx imap-current-mailbox
 609               headers (nnimap-demule
 610                        (if (imap-capability 'IMAP4rev1)
 611                            ;; xxx don't just use car? alist doesn't contain
 612                            ;; anything else now, but it might...
 613                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 614                          (imap-message-get uid 'RFC822.HEADER)))
 615               lines (imap-body-lines (imap-message-body imap-current-message))
 616               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 617       (nnheader-insert-nov
 618        ;; At this stage, we only have bytes, so let's use unibyte buffers
 619        ;; to make it more clear.
 620        (mm-with-unibyte-buffer
 621          (buffer-disable-undo)
 622          (insert headers)
 623          (let ((head (nnheader-parse-naked-head uid)))
 624            (mail-header-set-number head uid)
 625            (mail-header-set-chars head chars)
 626            (mail-header-set-lines head lines)
 627            (mail-header-set-xref
 628             head (format "%s %s:%d" (system-name) mbx uid))
 629            head))))))
 630
 631 (defun nnimap-retrieve-which-headers (articles fetch-old)
 632   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 633   (with-current-buffer nnimap-server-buffer
 634     (if (numberp (car-safe articles))
 635         (imap-search
 636          (concat "UID "
 637                  (imap-range-to-message-set
 638                   (gnus-compress-sequence
 639                    (append (gnus-uncompress-sequence
 640                             (and fetch-old
 641                                  (cons (if (numberp fetch-old)
 642                                            (max 1 (- (car articles) fetch-old))
 643                                          1)
 644                                        (1- (car articles)))))
 645                            articles)))))
 646       (mapcar (lambda (msgid)
 647                 (imap-search
 648                  (format "HEADER Message-Id \"%s\"" msgid)))
 649               articles))))
 650
 651 (defun nnimap-group-overview-filename (group server)
 652   "Make file name for GROUP on SERVER."
 653   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 654          (uidvalidity (gnus-group-get-parameter
 655                        (gnus-group-prefixed-name
 656                         group (gnus-server-to-method
 657                                (format "nnimap:%s" server)))
 658                        'uidvalidity))
 659          (name (nnheader-translate-file-chars
 660                 (concat nnimap-nov-file-name
 661                         (if (equal server "")
 662                             "unnamed"
 663                           server) "." group nnimap-nov-file-name-suffix) t))
 664          (nameuid (nnheader-translate-file-chars
 665                    (concat nnimap-nov-file-name
 666                            (if (equal server "")
 667                                "unnamed"
 668                              server) "." group "." uidvalidity
 669                            nnimap-nov-file-name-suffix) t))
 670          (oldfile (if (or nnmail-use-long-file-names
 671                           (file-exists-p (expand-file-name name dir)))
 672                       (expand-file-name name dir)
 673                     (expand-file-name
 674                      (mm-encode-coding-string
 675                       (nnheader-replace-chars-in-string name ?. ?/)
 676                       nnmail-pathname-coding-system)
 677                      dir)))
 678          (newfile (if (or nnmail-use-long-file-names
 679                           (file-exists-p (expand-file-name nameuid dir)))
 680                       (expand-file-name nameuid dir)
 681                     (expand-file-name
 682                      (mm-encode-coding-string
 683                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 684                       nnmail-pathname-coding-system)
 685                      dir))))
 686     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 687       (message "nnimap: Upgrading novcache filename...")
 688       (sit-for 1)
 689       (gnus-make-directory (file-name-directory newfile))
 690       (unless (ignore-errors (rename-file oldfile newfile) t)
 691         (if (ignore-errors (copy-file oldfile newfile) t)
 692             (delete-file oldfile)
 693           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 694     newfile))
 695
 696 (defun nnimap-retrieve-headers-from-file (group server)
 697   (with-current-buffer nntp-server-buffer
 698     (let ((nov (nnimap-group-overview-filename group server)))
 699       (when (file-exists-p nov)
 700         (mm-insert-file-contents nov)
 701         (set-buffer-modified-p nil)
 702         (let ((min (ignore-errors (goto-char (point-min))
 703                                   (read (current-buffer))))
 704               (max (ignore-errors (goto-char (point-max))
 705                                   (forward-line -1)
 706                                   (read (current-buffer)))))
 707           (if (and (numberp min) (numberp max))
 708               (cons min max)
 709             ;; junk, remove it, it's saved later
 710             (erase-buffer)
 711             nil))))))
 712
 713 (defun nnimap-retrieve-headers-from-server (articles group server)
 714   (with-current-buffer nnimap-server-buffer
 715     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 716           (nnimap-length (gnus-range-length articles))
 717           (nnimap-counter 0))
 718       (imap-fetch (imap-range-to-message-set articles)
 719                   (concat "(UID RFC822.SIZE BODY "
 720                           (let ((headers
 721                                  (append '(Subject From Date Message-Id
 722                                                    References In-Reply-To Xref)
 723                                          (copy-sequence
 724                                           nnmail-extra-headers))))
 725                             (if (imap-capability 'IMAP4rev1)
 726                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 727                               (format "RFC822.HEADER.LINES %s)" headers)))))
 728       (with-current-buffer nntp-server-buffer
 729         (sort-numeric-fields 1 (point-min) (point-max)))
 730       (and (numberp nnmail-large-newsgroup)
 731            (> nnimap-length nnmail-large-newsgroup)
 732            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 733
 734 (defun nnimap-dont-use-nov-p (group server)
 735   (or gnus-nov-is-evil nnimap-nov-is-evil
 736       (unless (and (gnus-make-directory
 737                     (file-name-directory
 738                      (nnimap-group-overview-filename group server)))
 739                    (file-writable-p
 740                     (nnimap-group-overview-filename group server)))
 741         (message "nnimap: Nov cache not writable, %s"
 742                  (nnimap-group-overview-filename group server)))))
 743
 744 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 745   (when (nnimap-possibly-change-group group server)
 746     (with-current-buffer nntp-server-buffer
 747       (erase-buffer)
 748       (if (nnimap-dont-use-nov-p group server)
 749           (nnimap-retrieve-headers-from-server
 750            (gnus-compress-sequence articles) group server)
 751         (let (uids cached low high)
 752           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 753                       low (car uids)
 754                       high (car (last uids)))
 755             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 756                 (progn
 757                   ;; fetch articles with uids before cache block
 758                   (when (< low (car cached))
 759                     (goto-char (point-min))
 760                     (nnimap-retrieve-headers-from-server
 761                      (cons low (1- (car cached))) group server))
 762                   ;; fetch articles with uids after cache block
 763                   (when (> high (cdr cached))
 764                     (goto-char (point-max))
 765                     (nnimap-retrieve-headers-from-server
 766                      (cons (1+ (cdr cached)) high) group server))
 767                   (when nnimap-prune-cache
 768                     ;; remove nov's for articles which has expired on server
 769                     (goto-char (point-min))
 770                     (dolist (uid (gnus-set-difference articles uids))
 771                       (when (re-search-forward (format "^%d\t" uid) nil t)
 772                         (gnus-delete-line)))))
 773               ;; nothing cached, fetch whole range from server
 774               (nnimap-retrieve-headers-from-server
 775                (cons low high) group server))
 776             (when (buffer-modified-p)
 777               (nnmail-write-region
 778                (point-min) (point-max)
 779                (nnimap-group-overview-filename group server) nil 'nomesg))
 780             (nnheader-nov-delete-outside-range low high))))
 781       'nov)))
 782
 783 (defun nnimap-open-connection (server)
 784   ;; Note: `nnimap-open-server' that calls this function binds
 785   ;; `imap-logout-timeout' to `nnimap-logout-timeout'.
 786   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 787                       nnimap-authenticator nnimap-server-buffer))
 788       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 789     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 790                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 791       (imap-close nnimap-server-buffer)
 792       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 793     (let* ((list (progn (gnus-message 7 "Parsing authinfo file `%s'."
 794                                       nnimap-authinfo-file)
 795                         (netrc-parse nnimap-authinfo-file)))
 796            (port (if nnimap-server-port
 797                      (int-to-string nnimap-server-port)
 798                    "imap"))
 799            (user (netrc-machine-user-or-password
 800                   "login"
 801                   list
 802                   (list server
 803                         (or nnimap-server-address
 804                             nnimap-address))
 805                   (list port)
 806                   (list "imap" "imaps" "143" "993")))
 807            (passwd (netrc-machine-user-or-password
 808                     "password"
 809                     list
 810                     (list server
 811                           (or nnimap-server-address
 812                               nnimap-address))
 813                     (list port)
 814                     (list "imap" "imaps" "143" "993"))))
 815       (if (imap-authenticate user passwd nnimap-server-buffer)
 816           (prog2
 817               (setq nnimap-server-buffer-alist
 818                     (nnimap-remove-server-from-buffer-alist
 819                      server
 820                      nnimap-server-buffer-alist))
 821               (push (list server nnimap-server-buffer)
 822                     nnimap-server-buffer-alist)
 823             (imap-id nnimap-id nnimap-server-buffer)
 824             (nnimap-possibly-change-server server))
 825         (imap-close nnimap-server-buffer)
 826         (kill-buffer nnimap-server-buffer)
 827         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 828
 829 (deffoo nnimap-open-server (server &optional defs)
 830   (nnheader-init-server-buffer)
 831   (if (nnimap-server-opened server)
 832       t
 833     (unless (assq 'nnimap-server-buffer defs)
 834       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 835     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 836     ;; for people that configured nnimap with a very old version
 837     (unless (assq 'nnimap-address defs)
 838       (if (assq 'nnimap-server-address defs)
 839           (push (list 'nnimap-address
 840                       (cadr (assq 'nnimap-server-address defs))) defs)
 841         (push (list 'nnimap-address server) defs)))
 842     (nnoo-change-server 'nnimap server defs)
 843     (or nnimap-server-buffer
 844         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 845     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 846       (nnoo-change-server 'nnimap server defs))
 847     (let ((imap-logout-timeout nnimap-logout-timeout))
 848       (or (and nnimap-server-buffer
 849                (imap-opened nnimap-server-buffer)
 850                (if (with-current-buffer nnimap-server-buffer
 851                      (memq imap-state '(auth selected examine)))
 852                    t
 853                  (imap-close nnimap-server-buffer)
 854                  (nnimap-open-connection server)))
 855           (nnimap-open-connection server)))))
 856
 857 (deffoo nnimap-server-opened (&optional server)
 858   "Whether SERVER is opened.
 859 If SERVER is the current virtual server, and the connection to the
 860 physical server is alive, this function return a non-nil value.  If
 861 SERVER is nil, it is treated as the current server."
 862   ;; clean up autologouts??
 863   (and (or server nnimap-current-server)
 864        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 865        (imap-opened (nnimap-get-server-buffer server))))
 866
 867 (deffoo nnimap-close-server (&optional server)
 868   "Close connection to server and free all resources connected to it.
 869 Return nil if the server couldn't be closed for some reason."
 870   (let ((server (or server nnimap-current-server))
 871         (imap-logout-timeout nnimap-logout-timeout))
 872     (when (or (nnimap-server-opened server)
 873               (imap-opened (nnimap-get-server-buffer server)))
 874       (imap-close (nnimap-get-server-buffer server))
 875       (kill-buffer (nnimap-get-server-buffer server))
 876       (setq nnimap-server-buffer nil
 877             nnimap-current-server nil
 878             nnimap-server-buffer-alist
 879             (nnimap-remove-server-from-buffer-alist
 880              server
 881              nnimap-server-buffer-alist)))
 882     (nnoo-close-server 'nnimap server)))
 883
 884 (deffoo nnimap-request-close ()
 885   "Close connection to all servers and free all resources that the backend have reserved.
 886 All buffers that have been created by that
 887 backend should be killed.  (Not the nntp-server-buffer, though.) This
 888 function is generally only called when Gnus is shutting down."
 889   (mapc (lambda (server) (nnimap-close-server (car server)))
 890         nnimap-server-buffer-alist)
 891   (setq nnimap-server-buffer-alist nil))
 892
 893 (deffoo nnimap-status-message (&optional server)
 894   "This function returns the last error message from server."
 895   (when (nnimap-possibly-change-server server)
 896     (nnoo-status-message 'nnimap server)))
 897
 898 (defun nnimap-demule (string)
 899   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 900   ;; because it will turn accidental emacs-mule-valid byte sequences
 901   ;; into multibyte chars.  --Stef
 902   ;; Reverted, braindead got 7.5 out of 10 on imdb, so it can't be
 903   ;; that bad. --Simon
 904   (funcall (if (and (fboundp 'string-as-multibyte)
 905                     (subrp (symbol-function 'string-as-multibyte)))
 906                'string-as-multibyte
 907              'identity)
 908            (or string "")))
 909
 910 (defun nnimap-make-callback (article gnus-callback buffer)
 911   "Return a callback function."
 912   `(lambda ()
 913      (nnimap-callback ,article ,gnus-callback ,buffer)))
 914
 915 (defun nnimap-callback (article gnus-callback buffer)
 916   (when (eq article (imap-current-message))
 917     (remove-hook 'imap-fetch-data-hook
 918                  (nnimap-make-callback article gnus-callback buffer))
 919     (with-current-buffer buffer
 920       (insert
 921        (with-current-buffer nnimap-server-buffer
 922          (nnimap-demule
 923           (if (imap-capability 'IMAP4rev1)
 924               ;; xxx don't just use car? alist doesn't contain
 925               ;; anything else now, but it might...
 926               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 927             (imap-message-get article 'RFC822)))))
 928       (nnheader-ms-strip-cr)
 929       (funcall gnus-callback t))))
 930
 931 (defun nnimap-request-article-part (article part prop &optional
 932                                             group server to-buffer detail)
 933   (when (nnimap-possibly-change-group group server)
 934     (let ((article (if (stringp article)
 935                        (car-safe (imap-search
 936                                   (format "HEADER Message-Id \"%s\"" article)
 937                                   nnimap-server-buffer))
 938                      article)))
 939       (when article
 940         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 941                       article (or group imap-current-mailbox
 942                                   gnus-newsgroup-name))
 943         (if (not nnheader-callback-function)
 944             (with-current-buffer (or to-buffer nntp-server-buffer)
 945               (erase-buffer)
 946               (let ((data (imap-fetch article part prop nil
 947                                       nnimap-server-buffer)))
 948                 (insert (nnimap-demule (if detail
 949                                            (nth 2 (car data))
 950                                          data))))
 951               (nnheader-ms-strip-cr)
 952               (gnus-message
 953                10 "nnimap: Fetching (part of) article %d from %s...done"
 954                article (or group imap-current-mailbox gnus-newsgroup-name))
 955               (if (bobp)
 956                   (nnheader-report 'nnimap "No such article %d in %s: %s"
 957                                    article (or group imap-current-mailbox
 958                                                gnus-newsgroup-name)
 959                                    (imap-error-text nnimap-server-buffer))
 960                 (cons group article)))
 961           (add-hook 'imap-fetch-data-hook
 962                     (nnimap-make-callback article
 963                                           nnheader-callback-function
 964                                           nntp-server-buffer))
 965           (imap-fetch-asynch article part nil nnimap-server-buffer)
 966           (cons group article))))))
 967
 968 (deffoo nnimap-asynchronous-p ()
 969   t)
 970
 971 (deffoo nnimap-request-article (article &optional group server to-buffer)
 972   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 973       (nnimap-request-article-part
 974        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 975     (nnimap-request-article-part
 976      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 977
 978 (deffoo nnimap-request-head (article &optional group server to-buffer)
 979   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 980       (nnimap-request-article-part
 981        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 982     (nnimap-request-article-part
 983      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 984
 985 (deffoo nnimap-request-body (article &optional group server to-buffer)
 986   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 987       (nnimap-request-article-part
 988        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 989     (nnimap-request-article-part
 990      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 991
 992 (deffoo nnimap-request-group (group &optional server fast)
 993   (nnimap-request-update-info-internal
 994    group
 995    (gnus-get-info (gnus-group-prefixed-name
 996                    group (gnus-server-to-method (format "nnimap:%s" server))))
 997    server)
 998   (when (nnimap-possibly-change-group group server)
 999     (nnimap-before-find-minmax-bugworkaround)
1000     (let (info)
1001       (cond (fast group)
1002             ((null (setq info (nnimap-find-minmax-uid group t)))
1003              (nnheader-report 'nnimap "Could not get active info for %s"
1004                               group))
1005             (t
1006              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
1007                               (max 1 (or (nth 1 info) 1))
1008                               (or (nth 2 info) 0) group)
1009              (nnheader-report 'nnimap "Group %s selected" group)
1010              t)))))
1011
1012 (defun nnimap-update-unseen (group &optional server)
1013   "Update the unseen count in `nnimap-mailbox-info'."
1014   (gnus-sethash
1015    (gnus-group-prefixed-name group server)
1016    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
1017                                  nnimap-mailbox-info)))
1018      (list (nth 0 old) (nth 1 old)
1019            (imap-mailbox-status group 'unseen nnimap-server-buffer)
1020            (nth 3 old)))
1021    nnimap-mailbox-info))
1022
1023 (defun nnimap-close-group (group &optional server)
1024   (with-current-buffer nnimap-server-buffer
1025     (when (and (imap-opened)
1026                (nnimap-possibly-change-group group server))
1027       (nnimap-update-unseen group server)
1028       (case nnimap-expunge-on-close
1029         (always (progn
1030                   (imap-mailbox-expunge nnimap-close-asynchronous)
1031                   (unless nnimap-dont-close
1032                     (imap-mailbox-close nnimap-close-asynchronous))))
1033         (ask (if (and (imap-search "DELETED")
1034                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
1035                                              imap-current-mailbox)))
1036                  (progn
1037                    (imap-mailbox-expunge nnimap-close-asynchronous)
1038                    (unless nnimap-dont-close
1039                      (imap-mailbox-close nnimap-close-asynchronous)))
1040                (imap-mailbox-unselect)))
1041         (t (imap-mailbox-unselect)))
1042       (not imap-current-mailbox))))
1043
1044 (defun nnimap-pattern-to-list-arguments (pattern)
1045   (mapcar (lambda (p)
1046             (cons (car-safe p) (or (cdr-safe p) p)))
1047           (if (and (listp pattern)
1048                    (listp (cdr pattern)))
1049               pattern
1050             (list pattern))))
1051
1052 (deffoo nnimap-request-list (&optional server)
1053   (when (nnimap-possibly-change-server server)
1054     (with-current-buffer nntp-server-buffer
1055       (erase-buffer))
1056     (gnus-message 5 "nnimap: Generating active list%s..."
1057                   (if (> (length server) 0) (concat " for " server) ""))
1058     (nnimap-before-find-minmax-bugworkaround)
1059     (with-current-buffer nnimap-server-buffer
1060       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1061         (dolist (mbx (funcall nnimap-request-list-method
1062                               (cdr pattern) (car pattern)))
1063           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1064               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1065                 (when info
1066                   (with-current-buffer nntp-server-buffer
1067                     (insert (format "\"%s\" %d %d y\n"
1068                                     mbx (or (nth 2 info) 0)
1069                                     (max 1 (or (nth 1 info) 1)))))))))))
1070     (gnus-message 5 "nnimap: Generating active list%s...done"
1071                   (if (> (length server) 0) (concat " for " server) ""))
1072     t))
1073
1074 (deffoo nnimap-request-post (&optional server)
1075   (let ((success t))
1076     (dolist (mbx (message-unquote-tokens
1077                   (message-tokenize-header
1078                    (message-fetch-field "Newsgroups") ", ")) success)
1079       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1080         (or (gnus-active to-newsgroup)
1081             (gnus-activate-group to-newsgroup)
1082             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1083                                        to-newsgroup))
1084                 (or (and (gnus-request-create-group
1085                           to-newsgroup gnus-command-method)
1086                          (gnus-activate-group to-newsgroup nil nil
1087                                               gnus-command-method))
1088                     (error "Couldn't create group %s" to-newsgroup)))
1089             (error "No such group: %s" to-newsgroup))
1090         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1091           (setq success nil))))))
1092
1093 ;; Optional backend functions
1094
1095 (defun nnimap-string-lessp-numerical (s1 s2)
1096   "Return t if first arg string is less than second in numerical order."
1097   (cond ((string= s1 s2)
1098          nil)
1099         ((> (length s1) (length s2))
1100          nil)
1101         ((< (length s1) (length s2))
1102          t)
1103         ((< (string-to-number (substring s1 0 1))
1104             (string-to-number (substring s2 0 1)))
1105          t)
1106         ((> (string-to-number (substring s1 0 1))
1107             (string-to-number (substring s2 0 1)))
1108          nil)
1109         (t
1110          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1111
1112 (deffoo nnimap-retrieve-groups (groups &optional server)
1113   (when (nnimap-possibly-change-server server)
1114     (gnus-message 5 "nnimap: Checking mailboxes...")
1115     (with-current-buffer nntp-server-buffer
1116       (erase-buffer)
1117       (nnimap-before-find-minmax-bugworkaround)
1118       (let (asyncgroups slowgroups)
1119         (if (null nnimap-retrieve-groups-asynchronous)
1120             (setq slowgroups groups)
1121           (dolist (group groups)
1122             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1123             (add-to-list (if (gnus-gethash-safe
1124                               (gnus-group-prefixed-name group server)
1125                               nnimap-mailbox-info)
1126                              'asyncgroups
1127                            'slowgroups)
1128                          (list group (imap-mailbox-status-asynch
1129                                       group '(uidvalidity uidnext unseen)
1130                                       nnimap-server-buffer))))
1131           (dolist (asyncgroup asyncgroups)
1132             (let ((group (nth 0 asyncgroup))
1133                   (tag   (nth 1 asyncgroup))
1134                   new old)
1135               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1136                 (if (or (not (string=
1137                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1138                                                     group server)
1139                                                    nnimap-mailbox-info))
1140                               (imap-mailbox-get 'uidvalidity group
1141                                                 nnimap-server-buffer)))
1142                         (not (string=
1143                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1144                                                     group server)
1145                                                    nnimap-mailbox-info))
1146                               (imap-mailbox-get 'uidnext group
1147                                                 nnimap-server-buffer))))
1148                     (push (list group) slowgroups)
1149                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1150                                                 group server)
1151                                                nnimap-mailbox-info))))))))
1152         (dolist (group slowgroups)
1153           (if nnimap-retrieve-groups-asynchronous
1154               (setq group (car group)))
1155           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1156           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1157           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1158                                                      nnimap-server-buffer))
1159               (let* ((info (nnimap-find-minmax-uid group 'examine))
1160                      (str (format "\"%s\" %d %d y\n" group
1161                                   (or (nth 2 info) 0)
1162                                   (max 1 (or (nth 1 info) 1)))))
1163                 (when (> (or (imap-mailbox-get 'recent group
1164                                                nnimap-server-buffer) 0)
1165                          0)
1166                   (push (list (cons group 0)) nnmail-split-history))
1167                 (insert str)
1168                 (when nnimap-retrieve-groups-asynchronous
1169                   (gnus-sethash
1170                    (gnus-group-prefixed-name group server)
1171                    (list (or (imap-mailbox-get
1172                               'uidvalidity group nnimap-server-buffer)
1173                              (imap-mailbox-status
1174                               group 'uidvalidity nnimap-server-buffer))
1175                          (or (imap-mailbox-get
1176                               'uidnext group nnimap-server-buffer)
1177                              (imap-mailbox-status
1178                               group 'uidnext nnimap-server-buffer))
1179                          (or (imap-mailbox-get
1180                               'unseen group nnimap-server-buffer)
1181                              (imap-mailbox-status
1182                               group 'unseen nnimap-server-buffer))
1183                          str)
1184                    nnimap-mailbox-info)))))))
1185     (gnus-message 5 "nnimap: Checking mailboxes...done")
1186     'active))
1187
1188 (deffoo nnimap-request-update-info-internal (group info &optional server)
1189   (when (nnimap-possibly-change-group group server)
1190     (when info ;; xxx what does this mean? should we create a info?
1191       (with-current-buffer nnimap-server-buffer
1192         (gnus-message 5 "nnimap: Updating info for %s..."
1193                       (gnus-info-group info))
1194
1195         (when (nnimap-mark-permanent-p 'read)
1196           (let (seen unseen)
1197             ;; read info could contain articles marked unread by other
1198             ;; imap clients!  we correct this
1199             (setq unseen (gnus-compress-sequence
1200                           (imap-search "UNSEEN UNDELETED"))
1201                   seen (gnus-range-difference (gnus-info-read info) unseen)
1202                   seen (gnus-range-add seen
1203                                        (gnus-compress-sequence
1204                                         (imap-search "SEEN")))
1205                   seen (if (and (integerp (car seen))
1206                                 (null (cdr seen)))
1207                            (list (cons (car seen) (car seen)))
1208                          seen))
1209             (gnus-info-set-read info seen)))
1210
1211         (dolist (pred gnus-article-mark-lists)
1212           (when (or (eq (cdr pred) 'recent)
1213                     (and (nnimap-mark-permanent-p (cdr pred))
1214                          (member (nnimap-mark-to-flag (cdr pred))
1215                                  (imap-mailbox-get 'flags))))
1216             (gnus-info-set-marks
1217              info
1218              (gnus-update-alist-soft
1219               (cdr pred)
1220               (gnus-compress-sequence
1221                (imap-search (nnimap-mark-to-predicate (cdr pred))))
1222               (gnus-info-marks info))
1223              t)))
1224
1225         (when nnimap-importantize-dormant
1226           ;; nnimap mark dormant article as ticked too (for other clients)
1227           ;; so we remove that mark for gnus since we support dormant
1228           (gnus-info-set-marks
1229            info
1230            (gnus-update-alist-soft
1231             'tick
1232             (gnus-remove-from-range
1233              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1234              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1235             (gnus-info-marks info))
1236            t))
1237
1238         (gnus-message 5 "nnimap: Updating info for %s...done"
1239                       (gnus-info-group info))
1240
1241         info))))
1242
1243 (deffoo nnimap-request-type (group &optional article)
1244   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1245       'news
1246     'mail))
1247
1248 (deffoo nnimap-request-set-mark (group actions &optional server)
1249   (when (nnimap-possibly-change-group group server)
1250     (with-current-buffer nnimap-server-buffer
1251       (let (action)
1252         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1253         (while (setq action (pop actions))
1254           (let ((range (nth 0 action))
1255                 (what  (nth 1 action))
1256                 (cmdmarks (nth 2 action))
1257                 marks)
1258             ;; bookmark can't be stored (not list/range
1259             (setq cmdmarks (delq 'bookmark cmdmarks))
1260             ;; killed can't be stored (not list/range
1261             (setq cmdmarks (delq 'killed cmdmarks))
1262             ;; unsent are for nndraft groups only
1263             (setq cmdmarks (delq 'unsent cmdmarks))
1264             ;; cache flags are pointless on the server
1265             (setq cmdmarks (delq 'cache cmdmarks))
1266             ;; seen flags are local to each gnus
1267             (setq cmdmarks (delq 'seen cmdmarks))
1268             ;; recent marks can't be set
1269             (setq cmdmarks (delq 'recent cmdmarks))
1270             (when nnimap-importantize-dormant
1271               ;; flag dormant articles as ticked
1272               (if (memq 'dormant cmdmarks)
1273                   (setq cmdmarks (cons 'tick cmdmarks))))
1274             ;; remove stuff we are forbidden to store
1275             (mapc (lambda (mark)
1276                     (if (imap-message-flag-permanent-p
1277                          (nnimap-mark-to-flag mark))
1278                         (setq marks (cons mark marks))))
1279                   cmdmarks)
1280             (when (and range marks)
1281               (cond ((eq what 'del)
1282                      (imap-message-flags-del
1283                       (imap-range-to-message-set range)
1284                       (nnimap-mark-to-flag marks nil t)))
1285                     ((eq what 'add)
1286                      (imap-message-flags-add
1287                       (imap-range-to-message-set range)
1288                       (nnimap-mark-to-flag marks nil t)))
1289                     ((eq what 'set)
1290                      (imap-message-flags-set
1291                       (imap-range-to-message-set range)
1292                       (nnimap-mark-to-flag marks nil t)))))))
1293         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1294   nil)
1295
1296 (defun nnimap-split-fancy ()
1297   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1298   (let ((nnmail-split-fancy nnimap-split-fancy))
1299     (nnmail-split-fancy)))
1300
1301 (defun nnimap-split-to-groups (rules)
1302   ;; tries to match all rules in nnimap-split-rule against content of
1303   ;; nntp-server-buffer, returns a list of groups that matched.
1304   (with-current-buffer nntp-server-buffer
1305     ;; Fold continuation lines.
1306     (goto-char (point-min))
1307     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1308       (replace-match " " t t))
1309     (if (functionp rules)
1310         (funcall rules)
1311       (let (to-groups regrepp)
1312         (catch 'split-done
1313           (dolist (rule rules to-groups)
1314             (let ((group (car rule))
1315                   (regexp (cadr rule)))
1316               (goto-char (point-min))
1317               (when (and (if (stringp regexp)
1318                              (progn
1319                                (if (not (stringp group))
1320                                    (setq group (eval group))
1321                                  (setq regrepp
1322                                        (string-match "\\\\[0-9&]" group)))
1323                                (re-search-forward regexp nil t))
1324                            (funcall regexp group))
1325                          ;; Don't enter the article into the same group twice.
1326                          (not (assoc group to-groups)))
1327                 (push (if regrepp
1328                           (nnmail-expand-newtext group)
1329                         group)
1330                       to-groups)
1331                 (or nnimap-split-crosspost
1332                     (throw 'split-done to-groups))))))))))
1333
1334 (defun nnimap-assoc-match (key alist)
1335   (let (element)
1336     (while (and alist (not element))
1337       (if (string-match (car (car alist)) key)
1338           (setq element (car alist)))
1339       (setq alist (cdr alist)))
1340     element))
1341
1342 (defun nnimap-split-find-rule (server inbox)
1343   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1344            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1345       ;; extended format
1346       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1347                                             server nnimap-split-rule))))
1348     nnimap-split-rule))
1349
1350 (defun nnimap-split-find-inbox (server)
1351   (if (listp nnimap-split-inbox)
1352       nnimap-split-inbox
1353     (list nnimap-split-inbox)))
1354
1355 (defun nnimap-split-articles (&optional group server)
1356   (when (nnimap-possibly-change-server server)
1357     (with-current-buffer nnimap-server-buffer
1358       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1359         ;; iterate over inboxes
1360         (while (and (setq inbox (pop inboxes))
1361                     (nnimap-possibly-change-group inbox)) ;; SELECT
1362           ;; find split rule for this server / inbox
1363           (when (setq rule (nnimap-split-find-rule server inbox))
1364             ;; iterate over articles
1365             (dolist (article (imap-search nnimap-split-predicate))
1366               (when (if (if (eq nnimap-split-download-body 'default)
1367                             nnimap-split-download-body-default
1368                           nnimap-split-download-body)
1369                         (and (nnimap-request-article article)
1370                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1371                       (nnimap-request-head article))
1372                 ;; copy article to right group(s)
1373                 (setq removeorig nil)
1374                 (dolist (to-group (nnimap-split-to-groups rule))
1375                   (cond ((eq to-group 'junk)
1376                          (message "IMAP split removed %s:%s:%d" server inbox
1377                                   article)
1378                          (setq removeorig t))
1379                         ((imap-message-copy (number-to-string article)
1380                                             to-group nil 'nocopyuid)
1381                          (message "IMAP split moved %s:%s:%d to %s" server
1382                                   inbox article to-group)
1383                          (setq removeorig t)
1384                          (when nnmail-cache-accepted-message-ids
1385                            (with-current-buffer nntp-server-buffer
1386                              (let (msgid)
1387                                (and (setq msgid
1388                                           (nnmail-fetch-field "message-id"))
1389                                     (nnmail-cache-insert msgid
1390                                                          to-group
1391                                                          (nnmail-fetch-field "subject"))))))
1392                          ;; Add the group-art list to the history list.
1393                          (push (list (cons to-group 0)) nnmail-split-history))
1394                         (t
1395                          (message "IMAP split failed to move %s:%s:%d to %s"
1396                                   server inbox article to-group))))
1397                 (if (if (eq nnimap-split-download-body 'default)
1398                         nnimap-split-download-body-default
1399                       nnimap-split-download-body)
1400                     (widen))
1401                 ;; remove article if it was successfully copied somewhere
1402                 (and removeorig
1403                      (imap-message-flags-add (format "%d" article)
1404                                              "\\Seen \\Deleted")))))
1405           (when (imap-mailbox-select inbox) ;; just in case
1406             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1407             (imap-mailbox-expunge)
1408             (imap-mailbox-close)))
1409         (when nnmail-cache-accepted-message-ids
1410           (nnmail-cache-close))
1411         t))))
1412
1413 (deffoo nnimap-request-scan (&optional group server)
1414   (nnimap-split-articles group server))
1415
1416 (deffoo nnimap-request-newgroups (date &optional server)
1417   (when (nnimap-possibly-change-server server)
1418     (with-current-buffer nntp-server-buffer
1419       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1420                     (if (> (length server) 0) " on " "") server)
1421       (erase-buffer)
1422       (nnimap-before-find-minmax-bugworkaround)
1423       (dolist (pattern (nnimap-pattern-to-list-arguments
1424                         nnimap-list-pattern))
1425         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1426                                         nnimap-server-buffer))
1427           (or (catch 'found
1428                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1429                                                    nnimap-server-buffer))
1430                   (if (string= (downcase mailbox) "\\noselect")
1431                       (throw 'found t)))
1432                 nil)
1433               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1434                 (when info
1435                   (insert (format "\"%s\" %d %d y\n"
1436                                   mbx (or (nth 2 info) 0)
1437                                   (max 1 (or (nth 1 info) 1)))))))))
1438       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1439                     (if (> (length server) 0) " on " "") server))
1440     t))
1441
1442 (deffoo nnimap-request-create-group (group &optional server args)
1443   (when (nnimap-possibly-change-server server)
1444     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1445         (imap-mailbox-create group nnimap-server-buffer)
1446         (nnheader-report 'nnimap "%S"
1447                          (imap-error-text nnimap-server-buffer)))))
1448
1449 (defun nnimap-time-substract (time1 time2)
1450   "Return TIME for TIME1 - TIME2."
1451   (let* ((ms (- (car time1) (car time2)))
1452          (ls (- (nth 1 time1) (nth 1 time2))))
1453     (if (< ls 0)
1454         (list (- ms 1) (+ (expt 2 16) ls))
1455       (list ms ls))))
1456
1457 (eval-when-compile (require 'parse-time))
1458 (defun nnimap-date-days-ago (daysago)
1459   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1460   (require 'parse-time)
1461   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1462          (date (format-time-string
1463                 (format "%%d-%s-%%Y"
1464                         (capitalize (car (rassoc (nth 4 (decode-time time))
1465                                                  parse-time-months))))
1466                 time)))
1467     (if (eq ?0 (string-to-char date))
1468         (substring date 1)
1469       date)))
1470
1471 (defun nnimap-request-expire-articles-progress ()
1472   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1473                 imap-current-message))
1474
1475 (defun nnimap-expiry-target (arts group server)
1476   (unless (eq nnmail-expiry-target 'delete)
1477     (with-temp-buffer
1478       (dolist (art arts)
1479         (nnimap-request-article art group server (current-buffer))
1480         ;; hints for optimization in `nnimap-request-accept-article'
1481         (let ((nnimap-current-move-article art)
1482               (nnimap-current-move-group group)
1483               (nnimap-current-move-server server))
1484           (nnmail-expiry-target-group nnmail-expiry-target group))))
1485     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1486     ;; current group to be changed or not, so we make sure here.
1487     (nnimap-possibly-change-group group server)))
1488
1489 ;; Notice that we don't actually delete anything, we just mark them deleted.
1490 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1491   (let ((artseq (gnus-compress-sequence articles)))
1492     (when (and artseq (nnimap-possibly-change-group group server))
1493       (with-current-buffer nnimap-server-buffer
1494         (let ((days (or (and nnmail-expiry-wait-function
1495                              (funcall nnmail-expiry-wait-function group))
1496                         nnmail-expiry-wait)))
1497           (cond ((or force (eq days 'immediate))
1498                  (let ((oldarts (imap-search
1499                                  (concat "UID "
1500                                          (imap-range-to-message-set artseq)))))
1501                    (when oldarts
1502                      (nnimap-expiry-target oldarts group server)
1503                      (when (imap-message-flags-add
1504                             (imap-range-to-message-set
1505                              (gnus-compress-sequence oldarts)) "\\Deleted")
1506                        (setq articles (gnus-set-difference
1507                                        articles oldarts))))))
1508                 ((and nnimap-search-uids-not-since-is-evil (numberp days))
1509                  (let* ((all-new-articles
1510                          (gnus-compress-sequence
1511                           (imap-search (format "SINCE %s"
1512                                                (nnimap-date-days-ago days)))))
1513                         (oldartseq
1514                          (gnus-range-difference artseq all-new-articles))
1515                         (oldarts (gnus-uncompress-range oldartseq)))
1516                    (when oldarts
1517                      (nnimap-expiry-target oldarts group server)
1518                      (when (imap-message-flags-add
1519                             (imap-range-to-message-set oldartseq)
1520                             "\\Deleted")
1521                        (setq articles (gnus-set-difference
1522                                        articles oldarts))))))
1523                 ((numberp days)
1524                  (let ((oldarts (imap-search
1525                                  (format nnimap-expunge-search-string
1526                                          (imap-range-to-message-set artseq)
1527                                          (nnimap-date-days-ago days))))
1528                        (imap-fetch-data-hook
1529                         '(nnimap-request-expire-articles-progress)))
1530                    (when oldarts
1531                      (nnimap-expiry-target oldarts group server)
1532                      (when (imap-message-flags-add
1533                             (imap-range-to-message-set
1534                              (gnus-compress-sequence oldarts)) "\\Deleted")
1535                        (setq articles (gnus-set-difference
1536                                        articles oldarts)))))))))))
1537   ;; return articles not deleted
1538   articles)
1539
1540 (deffoo nnimap-request-move-article (article group server accept-form
1541                                              &optional last move-is-internal)
1542   (when (nnimap-possibly-change-server server)
1543     (save-excursion
1544       (let ((buf (get-buffer-create " *nnimap move*"))
1545             (nnimap-current-move-article article)
1546             (nnimap-current-move-group group)
1547             (nnimap-current-move-server nnimap-current-server)
1548             result)
1549         (gnus-message 10 "nnimap-request-move-article: this is an %s move"
1550                       (if move-is-internal
1551                           "internal"
1552                         "external"))
1553         ;; request the article only when the move is NOT internal
1554         (and (or move-is-internal
1555                  (nnimap-request-article article group server))
1556              (with-current-buffer buf
1557                (buffer-disable-undo (current-buffer))
1558                (insert-buffer-substring nntp-server-buffer)
1559                (setq result (eval accept-form))
1560                (kill-buffer buf)
1561                result)
1562              (nnimap-possibly-change-group group server)
1563              (imap-message-flags-add
1564               (imap-range-to-message-set (list article))
1565               "\\Deleted" 'silent nnimap-server-buffer))
1566         result))))
1567
1568 (deffoo nnimap-request-accept-article (group &optional server last)
1569   (when (nnimap-possibly-change-server server)
1570     (let (uid)
1571       (if (setq uid
1572                 (if (string= nnimap-current-server nnimap-current-move-server)
1573                     ;; moving article within same server, speed it up...
1574                     (and (nnimap-possibly-change-group
1575                           nnimap-current-move-group)
1576                          (imap-message-copy (number-to-string
1577                                              nnimap-current-move-article)
1578                                             group 'dontcreate nil
1579                                             nnimap-server-buffer))
1580                   (with-current-buffer (current-buffer)
1581                     (goto-char (point-min))
1582                     ;; remove any 'From blabla' lines, some IMAP servers
1583                     ;; reject the entire message otherwise.
1584                     (when (looking-at "^From[^:]")
1585                       (delete-region (point) (progn (forward-line) (point))))
1586                     ;; turn into rfc822 format (\r\n eol's)
1587                     (while (search-forward "\n" nil t)
1588                       (replace-match "\r\n"))
1589                     (when nnmail-cache-accepted-message-ids
1590                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1591                                            group
1592                                            (nnmail-fetch-field "subject"))))
1593                   (when (and last nnmail-cache-accepted-message-ids)
1594                     (nnmail-cache-close))
1595                   ;; this 'or' is for Cyrus server bug
1596                   (or (null (imap-current-mailbox nnimap-server-buffer))
1597                       (imap-mailbox-unselect nnimap-server-buffer))
1598                   (imap-message-append group (current-buffer) nil nil
1599                                        nnimap-server-buffer)))
1600           (cons group (nth 1 uid))
1601         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1602
1603 (deffoo nnimap-request-delete-group (group force &optional server)
1604   (when (nnimap-possibly-change-server server)
1605     (with-current-buffer nnimap-server-buffer
1606       (if force
1607           (or (null (imap-mailbox-status group 'uidvalidity))
1608               (imap-mailbox-delete group))
1609         ;; UNSUBSCRIBE?
1610         t))))
1611
1612 (deffoo nnimap-request-rename-group (group new-name &optional server)
1613   (when (nnimap-possibly-change-server server)
1614     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1615
1616 (defun nnimap-expunge (mailbox server)
1617   (when (nnimap-possibly-change-group mailbox server)
1618     (imap-mailbox-expunge nil nnimap-server-buffer)))
1619
1620 (defun nnimap-acl-get (mailbox server)
1621   (when (nnimap-possibly-change-server server)
1622     (and (imap-capability 'ACL nnimap-server-buffer)
1623          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1624
1625 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1626   (when (nnimap-possibly-change-server (cadr method))
1627     (unless (imap-capability 'ACL nnimap-server-buffer)
1628       (error "Your server does not support ACL editing"))
1629     (with-current-buffer nnimap-server-buffer
1630       ;; delete all removed identifiers
1631       (mapc (lambda (old-acl)
1632               (unless (assoc (car old-acl) new-acls)
1633                 (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1634                     (error "Can't delete ACL for %s" (car old-acl)))))
1635             old-acls)
1636       ;; set all changed acl's
1637       (mapc (lambda (new-acl)
1638               (let ((new-rights (cdr new-acl))
1639                     (old-rights (cdr (assoc (car new-acl) old-acls))))
1640                 (unless (and old-rights new-rights
1641                              (string= old-rights new-rights))
1642                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1643                       (error "Can't set ACL for %s to %s" (car new-acl)
1644                              new-rights)))))
1645             new-acls)
1646       t)))
1647
1648 \f
1649 ;;; Internal functions
1650
1651 ;;
1652 ;; This is confusing.
1653 ;;
1654 ;; mark      => read, tick, draft, reply etc
1655 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1656 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1657 ;;
1658 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1659 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1660 ;;
1661
1662 (defconst nnimap-mark-to-predicate-alist
1663   (mapcar
1664    (lambda (pair)                       ; cdr is the mark
1665      (or (assoc (cdr pair)
1666                 '((read . "SEEN")
1667                   (tick . "FLAGGED")
1668                   (draft . "DRAFT")
1669                   (recent . "RECENT")
1670                   (reply . "ANSWERED")))
1671          (cons (cdr pair)
1672                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1673    (cons '(read . read) gnus-article-mark-lists)))
1674
1675 (defun nnimap-mark-to-predicate (pred)
1676   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1677 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1678 to be used within a IMAP SEARCH query."
1679   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1680
1681 (defconst nnimap-mark-to-flag-alist
1682   (mapcar
1683    (lambda (pair)
1684      (or (assoc (cdr pair)
1685                 '((read . "\\Seen")
1686                   (tick . "\\Flagged")
1687                   (draft . "\\Draft")
1688                   (recent . "\\Recent")
1689                   (reply . "\\Answered")))
1690          (cons (cdr pair)
1691                (format "gnus-%s" (symbol-name (cdr pair))))))
1692    (cons '(read . read) gnus-article-mark-lists)))
1693
1694 (defun nnimap-mark-to-flag-1 (preds)
1695   (if (and (not (null preds)) (listp preds))
1696       (cons (nnimap-mark-to-flag (car preds))
1697             (nnimap-mark-to-flag (cdr preds)))
1698     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1699
1700 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1701   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1702 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1703 be used in a STORE FLAGS command."
1704   (let ((result (nnimap-mark-to-flag-1 preds)))
1705     (setq result (if (and (or make-string always-list)
1706                           (not (listp result)))
1707                      (list result)
1708                    result))
1709     (if make-string
1710         (mapconcat (lambda (flag)
1711                      (if (listp flag)
1712                          (mapconcat 'identity flag " ")
1713                        flag))
1714                    result " ")
1715       result)))
1716
1717 (defun nnimap-mark-permanent-p (mark &optional group)
1718   "Return t if MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1719   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1720
1721 (when nnimap-debug
1722   (require 'trace)
1723   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1724   (mapc (lambda (f) (trace-function-background f nnimap-debug-buffer))
1725         '(
1726           nnimap-possibly-change-server
1727           nnimap-verify-uidvalidity
1728           nnimap-find-minmax-uid
1729           nnimap-before-find-minmax-bugworkaround
1730           nnimap-possibly-change-group
1731           ;;nnimap-replace-whitespace
1732           nnimap-retrieve-headers-progress
1733           nnimap-retrieve-which-headers
1734           nnimap-group-overview-filename
1735           nnimap-retrieve-headers-from-file
1736           nnimap-retrieve-headers-from-server
1737           nnimap-retrieve-headers
1738           nnimap-open-connection
1739           nnimap-open-server
1740           nnimap-server-opened
1741           nnimap-close-server
1742           nnimap-request-close
1743           nnimap-status-message
1744           ;;nnimap-demule
1745           nnimap-request-article-part
1746           nnimap-request-article
1747           nnimap-request-head
1748           nnimap-request-body
1749           nnimap-request-group
1750           nnimap-close-group
1751           nnimap-pattern-to-list-arguments
1752           nnimap-request-list
1753           nnimap-request-post
1754           nnimap-retrieve-groups
1755           nnimap-request-update-info-internal
1756           nnimap-request-type
1757           nnimap-request-set-mark
1758           nnimap-split-to-groups
1759           nnimap-split-find-rule
1760           nnimap-split-find-inbox
1761           nnimap-split-articles
1762           nnimap-request-scan
1763           nnimap-request-newgroups
1764           nnimap-request-create-group
1765           nnimap-time-substract
1766           nnimap-date-days-ago
1767           nnimap-request-expire-articles-progress
1768           nnimap-request-expire-articles
1769           nnimap-request-move-article
1770           nnimap-request-accept-article
1771           nnimap-request-delete-group
1772           nnimap-request-rename-group
1773           gnus-group-nnimap-expunge
1774           gnus-group-nnimap-edit-acl
1775           gnus-group-nnimap-edit-acl-done
1776           nnimap-group-mode-hook
1777           nnimap-mark-to-predicate
1778           nnimap-mark-to-flag-1
1779           nnimap-mark-to-flag
1780           nnimap-mark-permanent-p
1781           )))
1782
1783 (provide 'nnimap)
1784
1785 ;; arch-tag: 2b001f20-3ff9-4094-a0ad-46807c1ba70b
1786 ;;; nnimap.el ends here