lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992,1993,1994,1995,1996,1998,1999,2000,2001,2002,2004,2005
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   ;; Warning suppression -- can't require x-win in batch:
  33   (autoload 'xw-defined-colors "x-win"))
  34
  35 \f
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; Font selection.
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39
  40 (defgroup font-selection nil
  41   "Influencing face font selection."
  42   :group 'faces)
  43
  44
  45 (defcustom face-font-selection-order
  46   '(:width :height :weight :slant)
  47   "*A list specifying how face font selection chooses fonts.
  48 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  49 must appear once in the list, and the list must not contain any other
  50 elements.  Font selection tries to find a best matching font for
  51 those face attributes first that appear first in the list.  For
  52 example, if `:slant' appears before `:height', font selection first
  53 tries to find a font with a suitable slant, even if this results in
  54 a font height that isn't optimal."
  55   :tag "Font selection order"
  56   :type '(list symbol symbol symbol symbol)
  57   :group 'font-selection
  58   :set #'(lambda (symbol value)
  59            (set-default symbol value)
  60            (internal-set-font-selection-order value)))
  61
  62
  63 ;; This is defined originally in xfaces.c.
  64 (defcustom face-font-family-alternatives
  65   '(("courier" "fixed")
  66     ("helv" "helvetica" "arial" "fixed"))
  67   "*Alist of alternative font family names.
  68 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  69 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  70 ALTERNATIVE2 etc."
  71   :tag "Alternative font families to try"
  72   :type '(repeat (repeat string))
  73   :group 'font-selection
  74   :set #'(lambda (symbol value)
  75            (set-default symbol value)
  76            (internal-set-alternative-font-family-alist value)))
  77
  78
  79 ;; This is defined originally in xfaces.c.
  80 (defcustom face-font-registry-alternatives
  81   (if (eq system-type 'windows-nt)
  82       '(("iso8859-1" "ms-oemlatin")
  83         ("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try"
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame, NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned."
 187   (facep name))
 188 (make-obsolete 'internal-find-face 'facep "21.1")
 189
 190
 191 (defun internal-get-face (name &optional frame)
 192   "Retrieve the face named NAME; error if there is none.
 193 If the optional argument FRAME is given, this gets the face NAME for
 194 that frame; otherwise, it uses the selected frame.
 195 If FRAME is the symbol t, then the global, non-frame face is returned.
 196 If NAME is already a face, it is simply returned."
 197   (or (facep name)
 198       (check-face name)))
 199 (make-obsolete 'internal-get-face "see `facep' and `check-face'." "21.1")
 200
 201 \f
 202 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 203 ;;; Predicates, type checks.
 204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 205
 206 (defun facep (face)
 207   "Return non-nil if FACE is a face name or internal face object.
 208 Return nil otherwise.  A face name can be a string or a symbol.
 209 An internal face object is a vector of the kind used internally
 210 to record face data."
 211   (internal-lisp-face-p face))
 212
 213
 214 (defun check-face (face)
 215   "Signal an error if FACE doesn't name a face.
 216 Value is FACE."
 217   (unless (facep face)
 218     (error "Not a face: %s" face))
 219   face)
 220
 221
 222 ;; The ID returned is not to be confused with the internally used IDs
 223 ;; of realized faces.  The ID assigned to Lisp faces is used to
 224 ;; support faces in display table entries.
 225
 226 (defun face-id (face &optional frame)
 227   "Return the internal ID of face with name FACE.
 228 The optional argument FRAME is ignored, since the internal face ID
 229 of a face name is the same for all frames."
 230   (check-face face)
 231   (get face 'face))
 232
 233
 234 (defun face-equal (face1 face2 &optional frame)
 235   "Non-nil if faces FACE1 and FACE2 are equal.
 236 Faces are considered equal if all their attributes are equal.
 237 If the optional argument FRAME is given, report on FACE1 and FACE2 in that frame.
 238 If FRAME is t, report on the defaults for FACE1 and FACE2 (for new frames).
 239 If FRAME is omitted or nil, use the selected frame."
 240   (internal-lisp-face-equal-p face1 face2 frame))
 241
 242
 243 (defun face-differs-from-default-p (face &optional frame)
 244   "Return non-nil if FACE displays differently from the default face.
 245 If the optional argument FRAME is given, report on face FACE in that frame.
 246 If FRAME is t, report on the defaults for face FACE (for new frames).
 247 If FRAME is omitted or nil, use the selected frame."
 248   (let ((attrs
 249          '(:family :width :height :weight :slant :foreground
 250            :foreground :background :underline :overline
 251            :strike-through :box :inverse-video))
 252         (differs nil))
 253     (while (and attrs (not differs))
 254       (let* ((attr (pop attrs))
 255              (attr-val (face-attribute face attr frame t)))
 256         (when (and
 257                (not (eq attr-val 'unspecified))
 258                (display-supports-face-attributes-p (list attr attr-val)
 259                                                    frame))
 260           (setq differs attr))))
 261     differs))
 262
 263
 264 (defun face-nontrivial-p (face &optional frame)
 265   "True if face FACE has some non-nil attribute.
 266 If the optional argument FRAME is given, report on face FACE in that frame.
 267 If FRAME is t, report on the defaults for face FACE (for new frames).
 268 If FRAME is omitted or nil, use the selected frame."
 269   (not (internal-lisp-face-empty-p face frame)))
 270
 271
 272 \f
 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 274 ;;; Setting face attributes from X resources.
 275 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 276
 277 (defcustom face-x-resources
 278   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 279     (:width (".attributeWidth" . "Face.AttributeWidth"))
 280     (:height (".attributeHeight" . "Face.AttributeHeight"))
 281     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 282     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 283     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 284     (:background (".attributeBackground" . "Face.AttributeBackground"))
 285     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 286     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 287     (:box (".attributeBox" . "Face.AttributeBox"))
 288     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 289     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 290     (:stipple
 291      (".attributeStipple" . "Face.AttributeStipple")
 292      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 293     (:bold (".attributeBold" . "Face.AttributeBold"))
 294     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 295     (:font (".attributeFont" . "Face.AttributeFont"))
 296     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 297   "*List of X resources and classes for face attributes.
 298 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 299 the name of a face attribute, and each ENTRY is a cons of the form
 300 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 301 X resource class for the attribute."
 302   :type '(repeat (cons symbol (repeat (cons string string))))
 303   :group 'faces)
 304
 305
 306 (defun set-face-attribute-from-resource (face attribute resource class frame)
 307   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 308 Value is the attribute value specified by the resource, or nil
 309 if not present.  This function displays a message if the resource
 310 specifies an invalid attribute."
 311   (let* ((face-name (face-name face))
 312          (value (internal-face-x-get-resource (concat face-name resource)
 313                                               class frame)))
 314     (when value
 315       (condition-case ()
 316           (internal-set-lisp-face-attribute-from-resource
 317            face attribute (downcase value) frame)
 318         (error
 319          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 320                   face-name frame attribute value))))
 321     value))
 322
 323
 324 (defun set-face-attributes-from-resources (face frame)
 325   "Set attributes of FACE from X resources for FRAME."
 326   (when (memq (framep frame) '(x w32 mac))
 327     (dolist (definition face-x-resources)
 328       (let ((attribute (car definition)))
 329         (dolist (entry (cdr definition))
 330           (set-face-attribute-from-resource face attribute (car entry)
 331                                             (cdr entry) frame))))))
 332
 333
 334 (defun make-face-x-resource-internal (face &optional frame)
 335   "Fill frame-local FACE on FRAME from X resources.
 336 FRAME nil or not specified means do it for all frames."
 337   (if (null frame)
 338       (dolist (frame (frame-list))
 339         (set-face-attributes-from-resources face frame))
 340     (set-face-attributes-from-resources face frame)))
 341
 342
 343 \f
 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 345 ;;; Retrieving face attributes.
 346 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 347
 348 (defun face-name (face)
 349   "Return the name of face FACE."
 350   (symbol-name (check-face face)))
 351
 352
 353 (defun face-attribute (face attribute &optional frame inherit)
 354   "Return the value of FACE's ATTRIBUTE on FRAME.
 355 If the optional argument FRAME is given, report on face FACE in that frame.
 356 If FRAME is t, report on the defaults for face FACE (for new frames).
 357 If FRAME is omitted or nil, use the selected frame.
 358
 359 If INHERIT is nil, only attributes directly defined by FACE are considered,
 360   so the return value may be `unspecified', or a relative value.
 361 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 362   faces specified by its `:inherit' attribute; however the return value
 363   may still be `unspecified' or relative.
 364 If INHERIT is a face or a list of faces, then the result is further merged
 365   with that face (or faces), until it becomes specified and absolute.
 366
 367 To ensure that the return value is always specified and absolute, use a
 368 value of `default' for INHERIT; this will resolve any unspecified or
 369 relative values by merging with the `default' face (which is always
 370 completely specified)."
 371   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 372     (when (and inherit (face-attribute-relative-p attribute value))
 373       ;; VALUE is relative, so merge with inherited faces
 374       (let ((inh-from (face-attribute face :inherit frame)))
 375         (unless (or (null inh-from) (eq inh-from 'unspecified))
 376           (setq value
 377                 (face-attribute-merged-with attribute value inh-from frame)))))
 378     (when (and inherit
 379                (not (eq inherit t))
 380                (face-attribute-relative-p attribute value))
 381       ;; We should merge with INHERIT as well
 382       (setq value (face-attribute-merged-with attribute value inherit frame)))
 383     value))
 384
 385 (defun face-attribute-merged-with (attribute value faces &optional frame)
 386   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 387 FACES may be either a single face or a list of faces.
 388 \[This is an internal function.]"
 389   (cond ((not (face-attribute-relative-p attribute value))
 390          value)
 391         ((null faces)
 392          value)
 393         ((consp faces)
 394          (face-attribute-merged-with
 395           attribute
 396           (face-attribute-merged-with attribute value (car faces) frame)
 397           (cdr faces)
 398           frame))
 399         (t
 400          (merge-face-attribute attribute
 401                                value
 402                                (face-attribute faces attribute frame t)))))
 403
 404
 405 (defmacro face-attribute-specified-or (value &rest body)
 406   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 407   (let ((temp (make-symbol "value")))
 408     `(let ((,temp ,value))
 409        (if (not (eq ,temp 'unspecified))
 410            ,temp
 411          ,@body))))
 412
 413 (defun face-foreground (face &optional frame inherit)
 414   "Return the foreground color name of FACE, or nil if unspecified.
 415 If the optional argument FRAME is given, report on face FACE in that frame.
 416 If FRAME is t, report on the defaults for face FACE (for new frames).
 417 If FRAME is omitted or nil, use the selected frame.
 418
 419 If INHERIT is nil, only a foreground color directly defined by FACE is
 420   considered, so the return value may be nil.
 421 If INHERIT is t, and FACE doesn't define a foreground color, then any
 422   foreground color that FACE inherits through its `:inherit' attribute
 423   is considered as well; however the return value may still be nil.
 424 If INHERIT is a face or a list of faces, then it is used to try to
 425   resolve an unspecified foreground color.
 426
 427 To ensure that a valid color is always returned, use a value of
 428 `default' for INHERIT; this will resolve any unspecified values by
 429 merging with the `default' face (which is always completely specified)."
 430   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 431                                nil))
 432
 433 (defun face-background (face &optional frame inherit)
 434   "Return the background color name of FACE, or nil if unspecified.
 435 If the optional argument FRAME is given, report on face FACE in that frame.
 436 If FRAME is t, report on the defaults for face FACE (for new frames).
 437 If FRAME is omitted or nil, use the selected frame.
 438
 439 If INHERIT is nil, only a background color directly defined by FACE is
 440   considered, so the return value may be nil.
 441 If INHERIT is t, and FACE doesn't define a background color, then any
 442   background color that FACE inherits through its `:inherit' attribute
 443   is considered as well; however the return value may still be nil.
 444 If INHERIT is a face or a list of faces, then it is used to try to
 445   resolve an unspecified background color.
 446
 447 To ensure that a valid color is always returned, use a value of
 448 `default' for INHERIT; this will resolve any unspecified values by
 449 merging with the `default' face (which is always completely specified)."
 450   (face-attribute-specified-or (face-attribute face :background frame inherit)
 451                                nil))
 452
 453 (defun face-stipple (face &optional frame inherit)
 454  "Return the stipple pixmap name of FACE, or nil if unspecified.
 455 If the optional argument FRAME is given, report on face FACE in that frame.
 456 If FRAME is t, report on the defaults for face FACE (for new frames).
 457 If FRAME is omitted or nil, use the selected frame.
 458
 459 If INHERIT is nil, only a stipple directly defined by FACE is
 460   considered, so the return value may be nil.
 461 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 462   that FACE inherits through its `:inherit' attribute is considered as
 463   well; however the return value may still be nil.
 464 If INHERIT is a face or a list of faces, then it is used to try to
 465   resolve an unspecified stipple.
 466
 467 To ensure that a valid stipple or nil is always returned, use a value of
 468 `default' for INHERIT; this will resolve any unspecified values by merging
 469 with the `default' face (which is always completely specified)."
 470   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 471                                nil))
 472
 473
 474 (defalias 'face-background-pixmap 'face-stipple)
 475
 476
 477 (defun face-underline-p (face &optional frame)
 478  "Return non-nil if FACE is underlined.
 479 If the optional argument FRAME is given, report on face FACE in that frame.
 480 If FRAME is t, report on the defaults for face FACE (for new frames).
 481 If FRAME is omitted or nil, use the selected frame."
 482  (eq (face-attribute face :underline frame) t))
 483
 484
 485 (defun face-inverse-video-p (face &optional frame)
 486  "Return non-nil if FACE is in inverse video on FRAME.
 487 If the optional argument FRAME is given, report on face FACE in that frame.
 488 If FRAME is t, report on the defaults for face FACE (for new frames).
 489 If FRAME is omitted or nil, use the selected frame."
 490  (eq (face-attribute face :inverse-video frame) t))
 491
 492
 493 (defun face-bold-p (face &optional frame)
 494   "Return non-nil if the font of FACE is bold on FRAME.
 495 If the optional argument FRAME is given, report on face FACE in that frame.
 496 If FRAME is t, report on the defaults for face FACE (for new frames).
 497 If FRAME is omitted or nil, use the selected frame.
 498 Use `face-attribute' for finer control."
 499   (let ((bold (face-attribute face :weight frame)))
 500     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 501
 502
 503 (defun face-italic-p (face &optional frame)
 504   "Return non-nil if the font of FACE is italic on FRAME.
 505 If the optional argument FRAME is given, report on face FACE in that frame.
 506 If FRAME is t, report on the defaults for face FACE (for new frames).
 507 If FRAME is omitted or nil, use the selected frame.
 508 Use `face-attribute' for finer control."
 509   (let ((italic (face-attribute face :slant frame)))
 510     (memq italic '(italic oblique))))
 511
 512
 513 \f
 514 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 515 ;;; Face documentation.
 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 517
 518 (defun face-documentation (face)
 519   "Get the documentation string for FACE.
 520 If FACE is a face-alias, get the documentation for the target face."
 521   (let ((alias (get face 'face-alias))
 522         doc)
 523     (if alias
 524         (progn
 525           (setq doc (get alias 'face-documentation))
 526           (format "%s is an alias for the face `%s'.%s" face alias
 527                   (if doc (format "\n%s" doc)
 528                     "")))
 529       (get face 'face-documentation))))
 530
 531
 532 (defun set-face-documentation (face string)
 533   "Set the documentation string for FACE to STRING."
 534   ;; Perhaps the text should go in DOC.
 535   (put face 'face-documentation (purecopy string)))
 536
 537
 538 (defalias 'face-doc-string 'face-documentation)
 539 (defalias 'set-face-doc-string 'set-face-documentation)
 540
 541
 542 \f
 543 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 544 ;; Setting face attributes.
 545 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 546
 547
 548 (defun set-face-attribute (face frame &rest args)
 549   "Set attributes of FACE on FRAME from ARGS.
 550
 551 FRAME nil means change attributes on all frames.  FRAME t means change
 552 the default for new frames (this is done automatically each time an
 553 attribute is changed on all frames).
 554
 555 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 556 face attribute name.  All attributes can be set to `unspecified';
 557 this fact is not further mentioned below.
 558
 559 The following attributes are recognized:
 560
 561 `:family'
 562
 563 VALUE must be a string specifying the font family, e.g. ``courier'',
 564 or a fontset alias name.  If a font family is specified, wild-cards `*'
 565 and `?' are allowed.
 566
 567 `:width'
 568
 569 VALUE specifies the relative proportionate width of the font to use.
 570 It must be one of the symbols `ultra-condensed', `extra-condensed',
 571 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 572 `extra-expanded', or `ultra-expanded'.
 573
 574 `:height'
 575
 576 VALUE must be either an integer specifying the height of the font to use
 577 in 1/10 pt, a floating point number specifying the amount by which to
 578 scale any underlying face, or a function, which is called with the old
 579 height (from the underlying face), and should return the new height.
 580
 581 `:weight'
 582
 583 VALUE specifies the weight of the font to use.  It must be one of the
 584 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 585 `semi-light', `light', `extra-light', `ultra-light'.
 586
 587 `:slant'
 588
 589 VALUE specifies the slant of the font to use.  It must be one of the
 590 symbols `italic', `oblique', `normal', `reverse-italic', or
 591 `reverse-oblique'.
 592
 593 `:foreground', `:background'
 594
 595 VALUE must be a color name, a string.
 596
 597 `:underline'
 598
 599 VALUE specifies whether characters in FACE should be underlined.  If
 600 VALUE is t, underline with foreground color of the face.  If VALUE is
 601 a string, underline with that color.  If VALUE is nil, explicitly
 602 don't underline.
 603
 604 `:overline'
 605
 606 VALUE specifies whether characters in FACE should be overlined.  If
 607 VALUE is t, overline with foreground color of the face.  If VALUE is a
 608 string, overline with that color.  If VALUE is nil, explicitly don't
 609 overline.
 610
 611 `:strike-through'
 612
 613 VALUE specifies whether characters in FACE should be drawn with a line
 614 striking through them.  If VALUE is t, use the foreground color of the
 615 face.  If VALUE is a string, strike-through with that color.  If VALUE
 616 is nil, explicitly don't strike through.
 617
 618 `:box'
 619
 620 VALUE specifies whether characters in FACE should have a box drawn
 621 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 622 VALUE is t, draw a box with lines of width 1 in the foreground color
 623 of the face.  If VALUE is a string, the string must be a color name,
 624 and the box is drawn in that color with a line width of 1.  Otherwise,
 625 VALUE must be a property list of the form `(:line-width WIDTH
 626 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 627 the property list, a default value will be used for the value, as
 628 specified below.  WIDTH specifies the width of the lines to draw; it
 629 defaults to 1.  If WIDTH is negative, the absolute value is the width
 630 of the lines, and draw top/bottom lines inside the characters area,
 631 not around it.  COLOR is the name of the color to draw in, default is
 632 the foreground color of the face for simple boxes, and the background
 633 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 634 should be draw.  If STYLE is `released-button', draw a box looking
 635 like a released 3D button.  If STYLE is `pressed-button' draw a box
 636 that appears like a pressed button.  If STYLE is nil, the default if
 637 the property list doesn't contain a style specification, draw a 2D
 638 box.
 639
 640 `:inverse-video'
 641
 642 VALUE specifies whether characters in FACE should be displayed in
 643 inverse video.  VALUE must be one of t or nil.
 644
 645 `:stipple'
 646
 647 If VALUE is a string, it must be the name of a file of pixmap data.
 648 The directories listed in the `x-bitmap-file-path' variable are
 649 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 650 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 651 is a string containing the raw bits of the bitmap.  VALUE nil means
 652 explicitly don't use a stipple pattern.
 653
 654 For convenience, attributes `:family', `:width', `:height', `:weight',
 655 and `:slant' may also be set in one step from an X font name:
 656
 657 `:font'
 658
 659 Set font-related face attributes from VALUE.  VALUE must be a valid
 660 XLFD font name.  If it is a font name pattern, the first matching font
 661 will be used.
 662
 663 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 664 be used to specify that a bold or italic font should be used.  VALUE
 665 must be t or nil in that case.  A value of `unspecified' is not allowed.
 666
 667 `:inherit'
 668
 669 VALUE is the name of a face from which to inherit attributes, or a list
 670 of face names.  Attributes from inherited faces are merged into the face
 671 like an underlying face would be, with higher priority than underlying faces."
 672   (let ((where (if (null frame) 0 frame)))
 673     (setq args (purecopy args))
 674     ;; If we set the new-frame defaults, this face is modified outside Custom.
 675     (if (memq where '(0 t))
 676         (put (or (get face 'face-alias) face) 'face-modified t))
 677     (while args
 678       (internal-set-lisp-face-attribute face (car args)
 679                                         (purecopy (cadr args))
 680                                         where)
 681       (setq args (cdr (cdr args))))))
 682
 683
 684 (defun make-face-bold (face &optional frame noerror)
 685   "Make the font of FACE be bold, if possible.
 686 FRAME nil or not specified means change face on all frames.
 687 Argument NOERROR is ignored and retained for compatibility.
 688 Use `set-face-attribute' for finer control of the font weight."
 689   (interactive (list (read-face-name "Make which face bold")))
 690   (set-face-attribute face frame :weight 'bold))
 691
 692
 693 (defun make-face-unbold (face &optional frame noerror)
 694   "Make the font of FACE be non-bold, if possible.
 695 FRAME nil or not specified means change face on all frames.
 696 Argument NOERROR is ignored and retained for compatibility."
 697   (interactive (list (read-face-name "Make which face non-bold")))
 698   (set-face-attribute face frame :weight 'normal))
 699
 700
 701 (defun make-face-italic (face &optional frame noerror)
 702   "Make the font of FACE be italic, if possible.
 703 FRAME nil or not specified means change face on all frames.
 704 Argument NOERROR is ignored and retained for compatibility.
 705 Use `set-face-attribute' for finer control of the font slant."
 706   (interactive (list (read-face-name "Make which face italic")))
 707   (set-face-attribute face frame :slant 'italic))
 708
 709
 710 (defun make-face-unitalic (face &optional frame noerror)
 711   "Make the font of FACE be non-italic, if possible.
 712 FRAME nil or not specified means change face on all frames.
 713 Argument NOERROR is ignored and retained for compatibility."
 714   (interactive (list (read-face-name "Make which face non-italic")))
 715   (set-face-attribute face frame :slant 'normal))
 716
 717
 718 (defun make-face-bold-italic (face &optional frame noerror)
 719   "Make the font of FACE be bold and italic, if possible.
 720 FRAME nil or not specified means change face on all frames.
 721 Argument NOERROR is ignored and retained for compatibility.
 722 Use `set-face-attribute' for finer control of font weight and slant."
 723   (interactive (list (read-face-name "Make which face bold-italic")))
 724   (set-face-attribute face frame :weight 'bold :slant 'italic))
 725
 726
 727 (defun set-face-font (face font &optional frame)
 728   "Change font-related attributes of FACE to those of FONT (a string).
 729 FRAME nil or not specified means change face on all frames.
 730 This sets the attributes `:family', `:width', `:height', `:weight',
 731 and `:slant'.  When called interactively, prompt for the face and font."
 732   (interactive (read-face-and-attribute :font))
 733   (set-face-attribute face frame :font font))
 734
 735
 736 ;; Implementation note: Emulating gray background colors with a
 737 ;; stipple pattern is now part of the face realization process, and is
 738 ;; done in C depending on the frame on which the face is realized.
 739
 740 (defun set-face-background (face color &optional frame)
 741   "Change the background color of face FACE to COLOR (a string).
 742 FRAME nil or not specified means change face on all frames.
 743 COLOR can be a system-defined color name (see `list-colors-display')
 744 or a hex spec of the form #RRGGBB.
 745 When called interactively, prompts for the face and color."
 746   (interactive (read-face-and-attribute :background))
 747   (set-face-attribute face frame :background (or color 'unspecified)))
 748
 749
 750 (defun set-face-foreground (face color &optional frame)
 751   "Change the foreground color of face FACE to COLOR (a string).
 752 FRAME nil or not specified means change face on all frames.
 753 COLOR can be a system-defined color name (see `list-colors-display')
 754 or a hex spec of the form #RRGGBB.
 755 When called interactively, prompts for the face and color."
 756   (interactive (read-face-and-attribute :foreground))
 757   (set-face-attribute face frame :foreground (or color 'unspecified)))
 758
 759
 760 (defun set-face-stipple (face stipple &optional frame)
 761   "Change the stipple pixmap of face FACE to STIPPLE.
 762 FRAME nil or not specified means change face on all frames.
 763 STIPPLE should be a string, the name of a file of pixmap data.
 764 The directories listed in the `x-bitmap-file-path' variable are searched.
 765
 766 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 767 where WIDTH and HEIGHT are the size in pixels,
 768 and DATA is a string, containing the raw bits of the bitmap."
 769   (interactive (read-face-and-attribute :stipple))
 770   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 771
 772
 773 (defun set-face-underline (face underline &optional frame)
 774   "Specify whether face FACE is underlined.
 775 UNDERLINE nil means FACE explicitly doesn't underline.
 776 UNDERLINE non-nil means FACE explicitly does underlining
 777 with the same of the foreground color.
 778 If UNDERLINE is a string, underline with the color named UNDERLINE.
 779 FRAME nil or not specified means change face on all frames.
 780 Use `set-face-attribute' to ``unspecify'' underlining."
 781   (interactive
 782    (let ((list (read-face-and-attribute :underline)))
 783      (list (car list) (eq (car (cdr list)) t))))
 784   (set-face-attribute face frame :underline underline))
 785
 786
 787 (defun set-face-underline-p (face underline-p &optional frame)
 788   "Specify whether face FACE is underlined.
 789 UNDERLINE-P nil means FACE explicitly doesn't underline.
 790 UNDERLINE-P non-nil means FACE explicitly does underlining.
 791 FRAME nil or not specified means change face on all frames.
 792 Use `set-face-attribute' to ``unspecify'' underlining."
 793   (interactive
 794    (let ((list (read-face-and-attribute :underline)))
 795      (list (car list) (eq (car (cdr list)) t))))
 796   (set-face-attribute face frame :underline underline-p))
 797
 798
 799 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 800   "Specify whether face FACE is in inverse video.
 801 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 802 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 803 FRAME nil or not specified means change face on all frames.
 804 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 805   (interactive
 806    (let ((list (read-face-and-attribute :inverse-video)))
 807      (list (car list) (eq (car (cdr list)) t))))
 808   (set-face-attribute face frame :inverse-video inverse-video-p))
 809
 810
 811 (defun set-face-bold-p (face bold-p &optional frame)
 812   "Specify whether face FACE is bold.
 813 BOLD-P non-nil means FACE should explicitly display bold.
 814 BOLD-P nil means FACE should explicitly display non-bold.
 815 FRAME nil or not specified means change face on all frames.
 816 Use `set-face-attribute' or `modify-face' for finer control."
 817   (if (null bold-p)
 818       (make-face-unbold face frame)
 819     (make-face-bold face frame)))
 820
 821
 822 (defun set-face-italic-p (face italic-p &optional frame)
 823   "Specify whether face FACE is italic.
 824 ITALIC-P non-nil means FACE should explicitly display italic.
 825 ITALIC-P nil means FACE should explicitly display non-italic.
 826 FRAME nil or not specified means change face on all frames.
 827 Use `set-face-attribute' or `modify-face' for finer control."
 828   (if (null italic-p)
 829       (make-face-unitalic face frame)
 830     (make-face-italic face frame)))
 831
 832
 833 (defalias 'set-face-background-pixmap 'set-face-stipple)
 834
 835
 836 (defun invert-face (face &optional frame)
 837   "Swap the foreground and background colors of FACE.
 838 If FRAME is omitted or nil, it means change face on all frames.
 839 If FACE specifies neither foreground nor background color,
 840 set its foreground and background to the background and foreground
 841 of the default face.  Value is FACE."
 842   (interactive (list (read-face-name "Invert face")))
 843   (let ((fg (face-attribute face :foreground frame))
 844         (bg (face-attribute face :background frame)))
 845     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 846         (set-face-attribute face frame :foreground bg :background fg)
 847       (set-face-attribute face frame
 848                           :foreground
 849                           (face-attribute 'default :background frame)
 850                           :background
 851                           (face-attribute 'default :foreground frame))))
 852   face)
 853
 854 \f
 855 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 856 ;;; Interactively modifying faces.
 857 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 858
 859 (defun read-face-name (prompt &optional string-describing-default multiple)
 860   "Read a face, defaulting to the face or faces on the char after point.
 861 If it has a `read-face-name' property, that overrides the `face' property.
 862 PROMPT describes what you will do with the face (don't end in a space).
 863 STRING-DESCRIBING-DEFAULT describes what default you will use
 864 if this function returns nil.
 865 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 866 Otherwise, return a single face."
 867   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 868                       (get-char-property (point) 'face)))
 869         (aliasfaces nil)
 870         (nonaliasfaces nil)
 871         faces)
 872     ;; Try to get a face name from the buffer.
 873     (if (memq (intern-soft (thing-at-point 'symbol)) (face-list))
 874         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 875     ;; Add the named faces that the `face' property uses.
 876     (if (and (listp faceprop)
 877              ;; Don't treat an attribute spec as a list of faces.
 878              (not (keywordp (car faceprop)))
 879              (not (memq (car faceprop) '(foreground-color background-color))))
 880         (dolist (f faceprop)
 881           (if (symbolp f)
 882               (push f faces)))
 883       (if (symbolp faceprop)
 884           (push faceprop faces)))
 885     (delete-dups faces)
 886
 887     ;; Build up the completion tables.
 888     (mapatoms (lambda (s)
 889                 (if (custom-facep s)
 890                     (if (get s 'face-alias)
 891                         (push (symbol-name s) aliasfaces)
 892                       (push (symbol-name s) nonaliasfaces)))))
 893
 894     ;; If we only want one, and the default is more than one,
 895     ;; discard the unwanted ones now.
 896     (unless multiple
 897       (if faces
 898           (setq faces (list (car faces)))))
 899     (require 'crm)
 900     (let* ((input
 901             ;; Read the input.
 902             (completing-read-multiple
 903              (if (or faces string-describing-default)
 904                  (format "%s (default %s): " prompt
 905                          (if faces (mapconcat 'symbol-name faces ",")
 906                            string-describing-default))
 907                (format "%s: " prompt))
 908              (complete-in-turn nonaliasfaces aliasfaces)
 909              nil t nil nil
 910              (if faces (mapconcat 'symbol-name faces ","))))
 911            ;; Canonicalize the output.
 912            (output
 913             (cond ((or (equal input "") (equal input '("")))
 914                    faces)
 915                   ((stringp input)
 916                    (mapcar 'intern (split-string input ", *" t)))
 917                   ((listp input)
 918                    (mapcar 'intern input))
 919                   (input))))
 920       ;; Return either a list of faces or just one face.
 921       (if multiple
 922           output
 923         (car output)))))
 924
 925
 926 (defun face-valid-attribute-values (attribute &optional frame)
 927   "Return valid values for face attribute ATTRIBUTE.
 928 The optional argument FRAME is used to determine available fonts
 929 and colors.  If it is nil or not specified, the selected frame is
 930 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 931 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 932 an integer value."
 933   (let ((valid
 934          (case attribute
 935            (:family
 936             (if window-system
 937                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 938                         (x-font-family-list))
 939               ;; Only one font on TTYs.
 940               (list (cons "default" "default"))))
 941            ((:width :weight :slant :inverse-video)
 942             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 943                     (internal-lisp-face-attribute-values attribute)))
 944            ((:underline :overline :strike-through :box)
 945             (if window-system
 946                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 947                                (internal-lisp-face-attribute-values attribute))
 948                        (mapcar #'(lambda (c) (cons c c))
 949                                (x-defined-colors frame)))
 950               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 951                       (internal-lisp-face-attribute-values attribute))))
 952            ((:foreground :background)
 953             (mapcar #'(lambda (c) (cons c c))
 954                     (defined-colors frame)))
 955            ((:height)
 956             'integerp)
 957            (:stipple
 958             (and (memq window-system '(x w32 mac))
 959                  (mapcar #'list
 960                          (apply #'nconc
 961                                 (mapcar (lambda (dir)
 962                                           (and (file-readable-p dir)
 963                                                (file-directory-p dir)
 964                                                (directory-files dir)))
 965                                         x-bitmap-file-path)))))
 966            (:inherit
 967             (cons '("none" . nil)
 968                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 969                           (face-list))))
 970            (t
 971             (error "Internal error")))))
 972     (if (and (listp valid) (not (memq attribute '(:inherit))))
 973         (nconc (list (cons "unspecified" 'unspecified)) valid)
 974       valid)))
 975
 976
 977 (defvar face-attribute-name-alist
 978   '((:family . "font family")
 979     (:width . "character set width")
 980     (:height . "height in 1/10 pt")
 981     (:weight . "weight")
 982     (:slant . "slant")
 983     (:underline . "underline")
 984     (:overline . "overline")
 985     (:strike-through . "strike-through")
 986     (:box . "box")
 987     (:inverse-video . "inverse-video display")
 988     (:foreground . "foreground color")
 989     (:background . "background color")
 990     (:stipple . "background stipple")
 991     (:inherit . "inheritance"))
 992   "An alist of descriptive names for face attributes.
 993 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 994 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 995 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 996
 997
 998 (defun face-descriptive-attribute-name (attribute)
 999   "Return a descriptive name for ATTRIBUTE."
1000   (cdr (assq attribute face-attribute-name-alist)))
1001
1002
1003 (defun face-read-string (face default name &optional completion-alist)
1004   "Interactively read a face attribute string value.
1005 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
1006 default string to return if no new value is entered.  NAME is a
1007 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
1008 alist of valid values, if non-nil.
1009
1010 Entering nothing accepts the default string DEFAULT.
1011 Value is the new attribute value."
1012   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
1013   ;; each word in a string separately).
1014   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
1015   (let* ((completion-ignore-case t)
1016          (value (completing-read
1017                  (if default
1018                      (format "%s for face `%s' (default %s): "
1019                              name face default)
1020                    (format "%s for face `%s': " name face))
1021                  completion-alist)))
1022     (if (equal value "") default value)))
1023
1024
1025 (defun face-read-integer (face default name)
1026   "Interactively read an integer face attribute value.
1027 FACE is the face whose attribute is read.  DEFAULT is the default
1028 value to return if no new value is entered.  NAME is a descriptive
1029 name of the attribute for prompting.  Value is the new attribute value."
1030   (let ((new-value
1031          (face-read-string face
1032                            (format "%s" default)
1033                            name
1034                            (list (cons "unspecified" 'unspecified)))))
1035     (cond ((equal new-value "unspecified")
1036            'unspecified)
1037           ((member new-value '("unspecified-fg" "unspecified-bg"))
1038            new-value)
1039           (t
1040            (string-to-number new-value)))))
1041
1042
1043 (defun read-face-attribute (face attribute &optional frame)
1044   "Interactively read a new value for FACE's ATTRIBUTE.
1045 Optional argument FRAME nil or unspecified means read an attribute value
1046 of a global face.  Value is the new attribute value."
1047   (let* ((old-value (face-attribute face attribute frame))
1048          (attribute-name (face-descriptive-attribute-name attribute))
1049          (valid (face-valid-attribute-values attribute frame))
1050          new-value)
1051     ;; Represent complex attribute values as strings by printing them
1052     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1053     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1054     ;; SHADOW)'.
1055     (when (and (or (eq attribute :stipple)
1056                    (eq attribute :box))
1057                (or (consp old-value)
1058                    (vectorp old-value)))
1059       (setq old-value (prin1-to-string old-value)))
1060     (cond ((listp valid)
1061            (let ((default
1062                    (or (car (rassoc old-value valid))
1063                        (format "%s" old-value))))
1064              (setq new-value
1065                    (face-read-string face default attribute-name valid))
1066              (if (equal new-value default)
1067                  ;; Nothing changed, so don't bother with all the stuff
1068                  ;; below.  In particular, this avoids a non-tty color
1069                  ;; from being canonicalized for a tty when the user
1070                  ;; just uses the default.
1071                  (setq new-value old-value)
1072                ;; Terminal frames can support colors that don't appear
1073                ;; explicitly in VALID, using color approximation code
1074                ;; in tty-colors.el.
1075                (when (and (memq attribute '(:foreground :background))
1076                           (not (memq window-system '(x w32 mac)))
1077                           (not (member new-value
1078                                        '("unspecified"
1079                                          "unspecified-fg" "unspecified-bg"))))
1080                  (setq new-value (car (tty-color-desc new-value frame))))
1081                (when (assoc new-value valid)
1082                  (setq new-value (cdr (assoc new-value valid)))))))
1083           ((eq valid 'integerp)
1084            (setq new-value (face-read-integer face old-value attribute-name)))
1085           (t (error "Internal error")))
1086     ;; Convert stipple and box value text we read back to a list or
1087     ;; vector if it looks like one.  This makes the assumption that a
1088     ;; pixmap file name won't start with an open-paren.
1089     (when (and (or (eq attribute :stipple)
1090                    (eq attribute :box))
1091                (stringp new-value)
1092                (string-match "^[[(]" new-value))
1093       (setq new-value (read new-value)))
1094     new-value))
1095
1096
1097 (defun read-face-font (face &optional frame)
1098   "Read the name of a font for FACE on FRAME.
1099 If optional argument FRAME is nil or omitted, use the selected frame."
1100   (let ((completion-ignore-case t))
1101     (completing-read (format "Set font attributes of face `%s' from font: " face)
1102                      (append (fontset-list) (x-list-fonts "*" nil frame)))))
1103
1104
1105 (defun read-all-face-attributes (face &optional frame)
1106   "Interactively read all attributes for FACE.
1107 If optional argument FRAME is nil or omitted, use the selected frame.
1108 Value is a property list of attribute names and new values."
1109   (let (result)
1110     (dolist (attribute face-attribute-name-alist result)
1111       (setq result (cons (car attribute)
1112                          (cons (read-face-attribute face (car attribute) frame)
1113                                result))))))
1114
1115 (defun modify-face (&optional face foreground background stipple
1116                               bold-p italic-p underline-p inverse-p frame)
1117   "Modify attributes of faces interactively.
1118 If optional argument FRAME is nil or omitted, modify the face used
1119 for newly created frame, i.e. the global face.
1120 For non-interactive use, `set-face-attribute' is preferred.
1121 When called from Lisp, if FACE is nil, all arguments but FRAME are ignored
1122 and the face and its settings are obtained by querying the user."
1123   (interactive)
1124   (if face
1125       (set-face-attribute face frame
1126                           :foreground (or foreground 'unspecified)
1127                           :background (or background 'unspecified)
1128                           :stipple stipple
1129                           :bold bold-p
1130                           :italic italic-p
1131                           :underline underline-p
1132                           :inverse-video inverse-p)
1133     (setq face (read-face-name "Modify face"))
1134     (apply #'set-face-attribute face frame
1135            (read-all-face-attributes face frame))))
1136
1137 (defun read-face-and-attribute (attribute &optional frame)
1138   "Read face name and face attribute value.
1139 ATTRIBUTE is the attribute whose new value is read.
1140 FRAME nil or unspecified means read attribute value of global face.
1141 Value is a list (FACE NEW-VALUE) where FACE is the face read
1142 \(a symbol), and NEW-VALUE is value read."
1143   (cond ((eq attribute :font)
1144          (let* ((prompt "Set font-related attributes of face")
1145                 (face (read-face-name prompt))
1146                 (font (read-face-font face frame)))
1147            (list face font)))
1148         (t
1149          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1150                 (prompt (format "Set %s of face" attribute-name))
1151                 (face (read-face-name prompt))
1152                 (new-value (read-face-attribute face attribute frame)))
1153            (list face new-value)))))
1154
1155
1156 \f
1157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1158 ;;; Listing faces.
1159 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1160
1161 (defvar list-faces-sample-text
1162   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1163   "*Text string to display as the sample text for `list-faces-display'.")
1164
1165
1166 ;; The name list-faces would be more consistent, but let's avoid a
1167 ;; conflict with Lucid, which uses that name differently.
1168
1169 (defvar help-xref-stack)
1170 (defun list-faces-display (&optional regexp)
1171   "List all faces, using the same sample text in each.
1172 The sample text is a string that comes from the variable
1173 `list-faces-sample-text'.
1174
1175 If REGEXP is non-nil, list only those faces with names matching
1176 this regular expression.  When called interactively with a prefix
1177 arg, prompt for a regular expression."
1178   (interactive (list (and current-prefix-arg
1179                           (read-string "List faces matching regexp: "))))
1180   (let ((all-faces (zerop (length regexp)))
1181         (frame (selected-frame))
1182         (max-length 0)
1183         faces line-format
1184         disp-frame window face-name)
1185     ;; We filter and take the max length in one pass
1186     (setq faces
1187           (delq nil
1188                 (mapcar (lambda (f)
1189                           (let ((s (symbol-name f)))
1190                             (when (or all-faces (string-match regexp s))
1191                               (setq max-length (max (length s) max-length))
1192                               f)))
1193                         (sort (face-list) #'string-lessp))))
1194     (unless faces
1195       (error "No faces matching \"%s\"" regexp))
1196     (setq max-length (1+ max-length)
1197           line-format (format "%%-%ds" max-length))
1198     (with-output-to-temp-buffer "*Faces*"
1199       (save-excursion
1200         (set-buffer standard-output)
1201         (setq truncate-lines t)
1202         (insert
1203          (substitute-command-keys
1204           (concat
1205            "Use "
1206            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1207            "\\[help-follow] on a face name to customize it\n"
1208            "or on its sample text for a description of the face.\n\n")))
1209         (setq help-xref-stack nil)
1210         (dolist (face faces)
1211           (setq face-name (symbol-name face))
1212           (insert (format line-format face-name))
1213           ;; Hyperlink to a customization buffer for the face.  Using
1214           ;; the help xref mechanism may not be the best way.
1215           (save-excursion
1216             (save-match-data
1217               (search-backward face-name)
1218               (setq help-xref-stack-item `(list-faces-display ,regexp))
1219               (help-xref-button 0 'help-customize-face face)))
1220           (let ((beg (point))
1221                 (line-beg (line-beginning-position)))
1222             (insert list-faces-sample-text)
1223             ;; Hyperlink to a help buffer for the face.
1224             (save-excursion
1225               (save-match-data
1226                 (search-backward list-faces-sample-text)
1227                 (help-xref-button 0 'help-face face)))
1228             (insert "\n")
1229             (put-text-property beg (1- (point)) 'face face)
1230             ;; Make all face commands default to the proper face
1231             ;; anywhere in the line.
1232             (put-text-property line-beg (1- (point)) 'read-face-name face)
1233             ;; If the sample text has multiple lines, line up all of them.
1234             (goto-char beg)
1235             (forward-line 1)
1236             (while (not (eobp))
1237               (insert-char ?\s max-length)
1238               (forward-line 1))))
1239         (goto-char (point-min)))
1240       (print-help-return-message))
1241     ;; If the *Faces* buffer appears in a different frame,
1242     ;; copy all the face definitions from FRAME,
1243     ;; so that the display will reflect the frame that was selected.
1244     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1245     (setq disp-frame (if window (window-frame window)
1246                        (car (frame-list))))
1247     (or (eq frame disp-frame)
1248         (let ((faces (face-list)))
1249           (while faces
1250             (copy-face (car faces) (car faces) frame disp-frame)
1251             (setq faces (cdr faces)))))))
1252
1253
1254 (defun describe-face (face &optional frame)
1255   "Display the properties of face FACE on FRAME.
1256 Interactively, FACE defaults to the faces of the character after point
1257 and FRAME defaults to the selected frame.
1258
1259 If the optional argument FRAME is given, report on face FACE in that frame.
1260 If FRAME is t, report on the defaults for face FACE (for new frames).
1261 If FRAME is omitted or nil, use the selected frame."
1262   (interactive (list (read-face-name "Describe face" "= `default' face" t)))
1263   (let* ((attrs '((:family . "Family")
1264                   (:width . "Width")
1265                   (:height . "Height")
1266                   (:weight . "Weight")
1267                   (:slant . "Slant")
1268                   (:foreground . "Foreground")
1269                   (:background . "Background")
1270                   (:underline . "Underline")
1271                   (:overline . "Overline")
1272                   (:strike-through . "Strike-through")
1273                   (:box . "Box")
1274                   (:inverse-video . "Inverse")
1275                   (:stipple . "Stipple")
1276                   (:font . "Font")
1277                   (:fontset . "Fontset")
1278                   (:inherit . "Inherit")))
1279         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1280                                         attrs))))
1281     (help-setup-xref (list #'describe-face face) (interactive-p))
1282     (unless face
1283       (setq face 'default))
1284     (if (not (listp face))
1285         (setq face (list face)))
1286     (with-output-to-temp-buffer (help-buffer)
1287       (save-excursion
1288         (set-buffer standard-output)
1289         (dolist (f face)
1290           (insert "Face: " (symbol-name f))
1291           (if (not (facep f))
1292               (insert "   undefined face.\n")
1293             (let ((customize-label "customize this face")
1294                   file-name)
1295               (princ (concat " (" customize-label ")\n"))
1296               (insert "Documentation: "
1297                       (or (face-documentation f)
1298                           "Not documented as a face.")
1299                       "\n")
1300               (with-current-buffer standard-output
1301                 (save-excursion
1302                   (re-search-backward
1303                    (concat "\\(" customize-label "\\)") nil t)
1304                   (help-xref-button 1 'help-customize-face f)))
1305               ;; The next 4 sexps are copied from describe-function-1
1306               ;; and simplified.
1307               (setq file-name (symbol-file f 'defface))
1308               (when file-name
1309                 (princ "Defined in `")
1310                 (princ file-name)
1311                 (princ "'")
1312                 ;; Make a hyperlink to the library.
1313                 (save-excursion
1314                   (re-search-backward "`\\([^`']+\\)'" nil t)
1315                   (help-xref-button 1 'help-face-def f file-name))
1316                 (princ ".")
1317                 (terpri)
1318                 (terpri))
1319               (dolist (a attrs)
1320                 (let ((attr (face-attribute f (car a) frame)))
1321                   (insert (make-string (- max-width (length (cdr a))) ?\s)
1322                           (cdr a) ": " (format "%s" attr) "\n")))))
1323           (terpri)))
1324       (print-help-return-message))))
1325
1326 \f
1327 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1328 ;;; Face specifications (defface).
1329 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1330
1331 ;; Parameter FRAME Is kept for call compatibility to with previous
1332 ;; face implementation.
1333
1334 (defun face-attr-construct (face &optional frame)
1335   "Return a `defface'-style attribute list for FACE on FRAME.
1336 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1337 face attributes of FACE where ATTRIBUTE is the attribute name and
1338 VALUE is the specified value of that attribute."
1339   (let (result)
1340     (dolist (entry face-attribute-name-alist result)
1341       (let* ((attribute (car entry))
1342              (value (face-attribute face attribute)))
1343         (unless (eq value 'unspecified)
1344           (setq result (nconc (list attribute value) result)))))))
1345
1346
1347 (defun face-spec-set-match-display (display frame)
1348   "Non-nil if DISPLAY matches FRAME.
1349 DISPLAY is part of a spec such as can be used in `defface'.
1350 If FRAME is nil, the current FRAME is used."
1351   (let* ((conjuncts display)
1352          conjunct req options
1353          ;; t means we have succeeded against all the conjuncts in
1354          ;; DISPLAY that have been tested so far.
1355          (match t))
1356     (if (eq conjuncts t)
1357         (setq conjuncts nil))
1358     (while (and conjuncts match)
1359       (setq conjunct (car conjuncts)
1360             conjuncts (cdr conjuncts)
1361             req (car conjunct)
1362             options (cdr conjunct)
1363             match (cond ((eq req 'type)
1364                          (or (memq window-system options)
1365                              ;; FIXME: This should be revisited to use
1366                              ;; display-graphic-p, provided that the
1367                              ;; color selection depends on the number
1368                              ;; of supported colors, and all defface's
1369                              ;; are changed to look at number of colors
1370                              ;; instead of (type graphic) etc.
1371                              (and (null window-system)
1372                                   (memq 'tty options))
1373                              (and (memq 'motif options)
1374                                   (featurep 'motif))
1375                              (and (memq 'gtk options)
1376                                   (featurep 'gtk))
1377                              (and (memq 'lucid options)
1378                                   (featurep 'x-toolkit)
1379                                   (not (featurep 'motif))
1380                                   (not (featurep 'gtk)))
1381                              (and (memq 'x-toolkit options)
1382                                   (featurep 'x-toolkit))))
1383                         ((eq req 'min-colors)
1384                          (>= (display-color-cells frame) (car options)))
1385                         ((eq req 'class)
1386                          (memq (frame-parameter frame 'display-type) options))
1387                         ((eq req 'background)
1388                          (memq (frame-parameter frame 'background-mode)
1389                                options))
1390                         ((eq req 'supports)
1391                          (display-supports-face-attributes-p options frame))
1392                         (t (error "Unknown req `%S' with options `%S'"
1393                                   req options)))))
1394     match))
1395
1396
1397 (defun face-spec-choose (spec &optional frame)
1398   "Choose the proper attributes for FRAME, out of SPEC.
1399 If SPEC is nil, return nil."
1400   (unless frame
1401     (setq frame (selected-frame)))
1402   (let ((tail spec)
1403         result defaults)
1404     (while tail
1405       (let* ((entry (pop tail))
1406              (display (car entry))
1407              (attrs (cdr entry))
1408              thisval)
1409         ;; Get the attributes as actually specified by this alternative.
1410         (setq thisval
1411               (if (null (cdr attrs)) ;; was (listp (car attrs))
1412                   ;; Old-style entry, the attribute list is the
1413                   ;; first element.
1414                   (car attrs)
1415                 attrs))
1416
1417         ;; If the condition is `default', that sets the default
1418         ;; for following conditions.
1419         (if (eq display 'default)
1420             (setq defaults thisval)
1421           ;; Otherwise, if it matches, use it.
1422           (when (face-spec-set-match-display display frame)
1423             (setq result thisval)
1424             (setq tail nil)))))
1425     (if defaults (append result defaults) result)))
1426
1427
1428 (defun face-spec-reset-face (face &optional frame)
1429   "Reset all attributes of FACE on FRAME to unspecified."
1430   (let ((attrs face-attribute-name-alist))
1431     (while attrs
1432       (let ((attr-and-name (car attrs)))
1433         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1434       (setq attrs (cdr attrs)))))
1435
1436
1437 (defun face-spec-set (face spec &optional frame)
1438   "Set FACE's attributes according to the first matching entry in SPEC.
1439 FRAME is the frame whose frame-local face is set.  FRAME nil means
1440 do it on all frames.  See `defface' for information about SPEC.
1441 If SPEC is nil, do nothing."
1442   (let ((attrs (face-spec-choose spec frame)))
1443     (when attrs
1444       (face-spec-reset-face face frame))
1445     (while attrs
1446       (let ((attribute (car attrs))
1447             (value (car (cdr attrs))))
1448         ;; Support some old-style attribute names and values.
1449         (case attribute
1450           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1451           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1452           ((:foreground :background)
1453            ;; Compatibility with 20.x.  Some bogus face specs seem to
1454            ;; exist containing things like `:foreground nil'.
1455            (if (null value) (setq value 'unspecified)))
1456           (t (unless (assq attribute face-x-resources)
1457                (setq attribute nil))))
1458         (when attribute
1459           (set-face-attribute face frame attribute value)))
1460       (setq attrs (cdr (cdr attrs)))))
1461   ;; When we reset the face based on its spec, then it is unmodified
1462   ;; as far as Custom is concerned.
1463   (if (null frame)
1464       (put (or (get face 'face-alias) face) 'face-modified nil)))
1465
1466
1467 (defun face-attr-match-p (face attrs &optional frame)
1468   "Return t if attributes of FACE match values in plist ATTRS.
1469 Optional parameter FRAME is the frame whose definition of FACE
1470 is used.  If nil or omitted, use the selected frame."
1471   (unless frame
1472     (setq frame (selected-frame)))
1473   (let ((list face-attribute-name-alist)
1474         (match t))
1475     (while (and match (not (null list)))
1476       (let* ((attr (car (car list)))
1477              (specified-value
1478               (if (plist-member attrs attr)
1479                   (plist-get attrs attr)
1480                 'unspecified))
1481              (value-now (face-attribute face attr frame)))
1482         (setq match (equal specified-value value-now))
1483         (setq list (cdr list))))
1484     match))
1485
1486 (defun face-spec-match-p (face spec &optional frame)
1487   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1488   (face-attr-match-p face (face-spec-choose spec frame) frame))
1489
1490 (defsubst face-default-spec (face)
1491   "Return the default face-spec for FACE, ignoring any user customization.
1492 If there is no default for FACE, return nil."
1493   (get face 'face-defface-spec))
1494
1495 (defsubst face-user-default-spec (face)
1496   "Return the user's customized face-spec for FACE, or the default if none.
1497 If there is neither a user setting nor a default for FACE, return nil."
1498   (or (get face 'customized-face)
1499       (get face 'saved-face)
1500       (face-default-spec face)))
1501
1502 \f
1503 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1504 ;;; Frame-type independent color support.
1505 ;;; We keep the old x-* names as aliases for back-compatibility.
1506 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1507
1508 (defun defined-colors (&optional frame)
1509   "Return a list of colors supported for a particular frame.
1510 The argument FRAME specifies which frame to try.
1511 The value may be different for frames on different display types.
1512 If FRAME doesn't support colors, the value is nil."
1513   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1514       (xw-defined-colors frame)
1515     (mapcar 'car (tty-color-alist frame))))
1516 (defalias 'x-defined-colors 'defined-colors)
1517
1518 (defun color-defined-p (color &optional frame)
1519   "Return non-nil if color COLOR is supported on frame FRAME.
1520 If FRAME is omitted or nil, use the selected frame.
1521 If COLOR is the symbol `unspecified' or one of the strings
1522 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1523   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1524       nil
1525     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1526         (xw-color-defined-p color frame)
1527       (numberp (tty-color-translate color frame)))))
1528 (defalias 'x-color-defined-p 'color-defined-p)
1529
1530 (defun color-values (color &optional frame)
1531   "Return a description of the color named COLOR on frame FRAME.
1532 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1533 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1534 If FRAME is omitted or nil, use the selected frame.
1535 If FRAME cannot display COLOR, the value is nil.
1536 If COLOR is the symbol `unspecified' or one of the strings
1537 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1538   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1539       nil
1540     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1541         (xw-color-values color frame)
1542       (tty-color-values color frame))))
1543 (defalias 'x-color-values 'color-values)
1544
1545 (defun display-color-p (&optional display)
1546   "Return t if DISPLAY supports color.
1547 The optional argument DISPLAY specifies which display to ask about.
1548 DISPLAY should be either a frame or a display name (a string).
1549 If omitted or nil, that stands for the selected frame's display."
1550   (if (memq (framep-on-display display) '(x w32 mac))
1551       (xw-display-color-p display)
1552     (tty-display-color-p display)))
1553 (defalias 'x-display-color-p 'display-color-p)
1554
1555 (defun display-grayscale-p (&optional display)
1556   "Return non-nil if frames on DISPLAY can display shades of gray."
1557   (let ((frame-type (framep-on-display display)))
1558     (cond
1559      ((memq frame-type '(x w32 mac))
1560       (x-display-grayscale-p display))
1561      (t
1562       (> (tty-color-gray-shades display) 2)))))
1563
1564 \f
1565 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1566 ;;; Background mode.
1567 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1568
1569 (defcustom frame-background-mode nil
1570   "*The brightness of the background.
1571 Set this to the symbol `dark' if your background color is dark,
1572 `light' if your background is light, or nil (default) if you want Emacs
1573 to examine the brightness for you.  Don't set this variable with `setq';
1574 this won't have the expected effect."
1575   :group 'faces
1576   :set #'(lambda (var value)
1577            (set-default var value)
1578            (mapc 'frame-set-background-mode (frame-list)))
1579   :initialize 'custom-initialize-changed
1580   :type '(choice (choice-item dark)
1581                  (choice-item light)
1582                  (choice-item :tag "default" nil)))
1583
1584 (defvar default-frame-background-mode nil
1585   "Internal variable for the default brightness of the background.
1586 Emacs sets it automatically depending on the terminal type.
1587 The value `nil' means `dark'.  If Emacs runs in non-windowed
1588 mode from `xterm' or a similar terminal emulator, the value is
1589 `light'.  On rxvt terminals, the value depends on the environment
1590 variable COLORFGBG.")
1591
1592 (defun frame-set-background-mode (frame)
1593   "Set up display-dependent faces on FRAME.
1594 Display-dependent faces are those which have different definitions
1595 according to the `background-mode' and `display-type' frame parameters."
1596   (let* ((bg-resource
1597           (and window-system
1598                (x-get-resource "backgroundMode" "BackgroundMode")))
1599          (bg-color (frame-parameter frame 'background-color))
1600          (bg-mode
1601           (cond (frame-background-mode)
1602                 (bg-resource
1603                  (intern (downcase bg-resource)))
1604                 ((and (null window-system) (null bg-color))
1605                  ;; No way to determine this automatically (?).
1606                  (or default-frame-background-mode 'dark))
1607                 ;; Unspecified frame background color can only happen
1608                 ;; on tty's.
1609                 ((member bg-color '(unspecified "unspecified-bg"))
1610                  (or default-frame-background-mode 'dark))
1611                 ((equal bg-color "unspecified-fg") ; inverted colors
1612                  (if (eq default-frame-background-mode 'light) 'dark 'light))
1613                 ((>= (apply '+ (x-color-values bg-color frame))
1614                     ;; Just looking at the screen, colors whose
1615                     ;; values add up to .6 of the white total
1616                     ;; still look dark to me.
1617                     (* (apply '+ (x-color-values "white" frame)) .6))
1618                  'light)
1619                 (t 'dark)))
1620          (display-type
1621           (cond ((null window-system)
1622                  (if (tty-display-color-p frame) 'color 'mono))
1623                 ((x-display-color-p frame)
1624                  'color)
1625                 ((x-display-grayscale-p frame)
1626                  'grayscale)
1627                 (t 'mono)))
1628          (old-bg-mode
1629           (frame-parameter frame 'background-mode))
1630          (old-display-type
1631           (frame-parameter frame 'display-type)))
1632
1633     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1634       (let ((locally-modified-faces nil))
1635         ;; Before modifying the frame parameters, we collect a list of
1636         ;; faces that don't match what their face-spec says they should
1637         ;; look like; we then avoid changing these faces below.  A
1638         ;; negative list is used on the assumption that most faces will
1639         ;; be unmodified, so we can avoid consing in the common case.
1640         (dolist (face (face-list))
1641           (when (not (face-spec-match-p face
1642                                         (face-user-default-spec face)
1643                                         (selected-frame)))
1644             (push face locally-modified-faces)))
1645         ;; Now change to the new frame parameters
1646         (modify-frame-parameters frame
1647                                  (list (cons 'background-mode bg-mode)
1648                                        (cons 'display-type display-type)))
1649         ;; For all named faces, choose face specs matching the new frame
1650         ;; parameters, unless they have been locally modified.
1651         (dolist (face (face-list))
1652           (unless (memq face locally-modified-faces)
1653             (face-spec-set face (face-user-default-spec face) frame)))))))
1654
1655 \f
1656 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1657 ;;; Frame creation.
1658 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1659
1660 (defun x-handle-named-frame-geometry (parameters)
1661   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1662 Value is the new parameter list."
1663   (let* ((name (or (cdr (assq 'name parameters))
1664                    (cdr (assq 'name default-frame-alist))))
1665          (x-resource-name name)
1666          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1667     (when res-geometry
1668       (let ((parsed (x-parse-geometry res-geometry)))
1669         ;; If the resource specifies a position, call the position
1670         ;; and size "user-specified".
1671         (when (or (assq 'top parsed)
1672                   (assq 'left parsed))
1673           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1674         ;; Put the geometry parameters at the end.  Copy
1675         ;; default-frame-alist so that they go after it.
1676         (setq parameters (append parameters default-frame-alist parsed))))
1677     parameters))
1678
1679
1680 (defun x-handle-reverse-video (frame parameters)
1681   "Handle the reverse-video frame parameter and X resource.
1682 `x-create-frame' does not handle this one."
1683   (when (cdr (or (assq 'reverse parameters)
1684                  (assq 'reverse default-frame-alist)
1685                  (let ((resource (x-get-resource "reverseVideo"
1686                                                  "ReverseVideo")))
1687                    (if resource
1688                        (cons nil (member (downcase resource)
1689                                          '("on" "true")))))))
1690       (let* ((params (frame-parameters frame))
1691              (bg (cdr (assq 'foreground-color params)))
1692              (fg (cdr (assq 'background-color params))))
1693         (modify-frame-parameters frame
1694                                  (list (cons 'foreground-color fg)
1695                                        (cons 'background-color bg)))
1696         (if (equal bg (cdr (assq 'border-color params)))
1697             (modify-frame-parameters frame
1698                                      (list (cons 'border-color fg))))
1699         (if (equal bg (cdr (assq 'mouse-color params)))
1700             (modify-frame-parameters frame
1701                                      (list (cons 'mouse-color fg))))
1702         (if (equal bg (cdr (assq 'cursor-color params)))
1703             (modify-frame-parameters frame
1704                                      (list (cons 'cursor-color fg)))))))
1705
1706
1707 (defun x-create-frame-with-faces (&optional parameters)
1708   "Create a frame from optional frame parameters PARAMETERS.
1709 Parameters not specified by PARAMETERS are taken from
1710 `default-frame-alist'.  If PARAMETERS specify a frame name,
1711 handle X geometry resources for that name.  If either PARAMETERS
1712 or `default-frame-alist' contains a `reverse' parameter, or
1713 the X resource ``reverseVideo'' is present, handle that.
1714 Value is the new frame created."
1715   (setq parameters (x-handle-named-frame-geometry parameters))
1716   (let ((visibility-spec (assq 'visibility parameters))
1717         (frame-list (frame-list))
1718         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1719         success)
1720     (unwind-protect
1721         (progn
1722           (x-handle-reverse-video frame parameters)
1723           (frame-set-background-mode frame)
1724           (face-set-after-frame-default frame)
1725           (if (or (null frame-list) (null visibility-spec))
1726               (make-frame-visible frame)
1727             (modify-frame-parameters frame (list visibility-spec)))
1728           (setq success t))
1729       (unless success
1730         (delete-frame frame)))
1731     frame))
1732
1733
1734 (defun face-set-after-frame-default (frame)
1735   "Set frame-local faces of FRAME from face specs and resources.
1736 Initialize colors of certain faces from frame parameters."
1737   (if (face-attribute 'default :font t)
1738       (set-face-attribute 'default frame :font
1739                           (face-attribute 'default :font t))
1740     (set-face-attribute 'default frame :family
1741                         (face-attribute 'default :family t))
1742     (set-face-attribute 'default frame :height
1743                         (face-attribute 'default :height t))
1744     (set-face-attribute 'default frame :slant
1745                         (face-attribute 'default :slant t))
1746     (set-face-attribute 'default frame :weight
1747                         (face-attribute 'default :weight t))
1748     (set-face-attribute 'default frame :width
1749                         (face-attribute 'default :width t)))
1750   (dolist (face (face-list))
1751     ;; Don't let frame creation fail because of an invalid face spec.
1752     (condition-case ()
1753         (when (not (equal face 'default))
1754           (face-spec-set face (face-user-default-spec face) frame)
1755           (internal-merge-in-global-face face frame)
1756           (when (and (memq window-system '(x w32 mac))
1757                      (or (not (boundp 'inhibit-default-face-x-resources))
1758                          (not (eq face 'default))))
1759             (make-face-x-resource-internal face frame)))
1760       (error nil)))
1761   ;; Initialize attributes from frame parameters.
1762   (let ((params '((foreground-color default :foreground)
1763                   (background-color default :background)
1764                   (border-color border :background)
1765                   (cursor-color cursor :background)
1766                   (scroll-bar-foreground scroll-bar :foreground)
1767                   (scroll-bar-background scroll-bar :background)
1768                   (mouse-color mouse :background))))
1769     (dolist (param params)
1770       (let ((frame-param (frame-parameter frame (nth 0 param)))
1771             (face (nth 1 param))
1772             (attr (nth 2 param)))
1773         (when (and frame-param
1774                    ;; Don't override face attributes explicitly
1775                    ;; specified for new frames.
1776                    (eq (face-attribute face attr t) 'unspecified))
1777           (set-face-attribute face frame attr frame-param))))))
1778
1779
1780 (defun tty-handle-reverse-video (frame parameters)
1781   "Handle the reverse-video frame parameter for terminal frames."
1782   (when (cdr (or (assq 'reverse parameters)
1783                  (assq 'reverse default-frame-alist)))
1784     (let* ((params (frame-parameters frame))
1785            (bg (cdr (assq 'foreground-color params)))
1786            (fg (cdr (assq 'background-color params))))
1787       (modify-frame-parameters frame
1788                                (list (cons 'foreground-color fg)
1789                                      (cons 'background-color bg)))
1790       (if (equal bg (cdr (assq 'mouse-color params)))
1791           (modify-frame-parameters frame
1792                                    (list (cons 'mouse-color fg))))
1793       (if (equal bg (cdr (assq 'cursor-color params)))
1794           (modify-frame-parameters frame
1795                                    (list (cons 'cursor-color fg)))))))
1796
1797
1798 (defun tty-create-frame-with-faces (&optional parameters)
1799   "Create a frame from optional frame parameters PARAMETERS.
1800 Parameters not specified by PARAMETERS are taken from
1801 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1802 contains a `reverse' parameter, handle that.  Value is the new frame
1803 created."
1804   (let ((frame (make-terminal-frame parameters))
1805         success)
1806     (unwind-protect
1807         (progn
1808           (tty-handle-reverse-video frame (frame-parameters frame))
1809           (frame-set-background-mode frame)
1810           (face-set-after-frame-default frame)
1811           (setq success t))
1812       (unless success
1813         (delete-frame frame)))
1814     frame))
1815
1816
1817 ;; Called from C function init_display to initialize faces of the
1818 ;; dumped terminal frame on startup.
1819
1820 (defun tty-set-up-initial-frame-faces ()
1821   (let ((frame (selected-frame)))
1822     (frame-set-background-mode frame)
1823     (face-set-after-frame-default frame)))
1824
1825
1826
1827 \f
1828 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1829 ;;; Compatiblity with 20.2
1830 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1831
1832 ;; Update a frame's faces when we change its default font.
1833
1834 (defalias 'frame-update-faces 'ignore "")
1835 (make-obsolete 'frame-update-faces "no longer necessary." "21.1")
1836
1837 ;; Update the colors of FACE, after FRAME's own colors have been
1838 ;; changed.
1839
1840 (define-obsolete-function-alias 'frame-update-face-colors
1841     'frame-set-background-mode "21.1")
1842
1843 \f
1844 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1845 ;;; Standard faces.
1846 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1847
1848 (defgroup basic-faces nil
1849   "The standard faces of Emacs."
1850   :group 'faces)
1851
1852
1853 (defface default
1854   '((t nil))
1855   "Basic default face."
1856   :group 'basic-faces)
1857
1858
1859 (defface mode-line
1860   '((((class color) (min-colors 88))
1861      :box (:line-width -1 :style released-button)
1862      :background "grey75" :foreground "black")
1863     (t
1864      :inverse-video t))
1865   "Basic mode line face for selected window."
1866   :version "21.1"
1867   :group 'modeline
1868   :group 'basic-faces)
1869
1870 (defface mode-line-inactive
1871   '((default
1872      :inherit mode-line)
1873     (((class color) (min-colors 88) (background light))
1874      :weight light
1875      :box (:line-width -1 :color "grey75" :style nil)
1876      :foreground "grey20" :background "grey90")
1877     (((class color) (min-colors 88) (background dark) )
1878      :weight light
1879      :box (:line-width -1 :color "grey40" :style nil)
1880      :foreground "grey80" :background "grey30"))
1881   "Basic mode line face for non-selected windows."
1882   :version "22.1"
1883   :group 'modeline
1884   :group 'basic-faces)
1885
1886 (defface mode-line-highlight
1887   '((((class color) (min-colors 88))
1888      :box (:line-width 2 :color "grey40" :style released-button))
1889     (t
1890      :inherit highlight))
1891   "Basic mode line face for highlighting."
1892   :version "22.1"
1893   :group 'modeline
1894   :group 'basic-faces)
1895
1896 (defface vertical-border
1897   '((((type tty)) :inherit mode-line-inactive))
1898   "Face used for vertical window dividers on ttys."
1899   :version "22.1"
1900   :group 'modeline
1901   :group 'basic-faces)
1902
1903 ;; Make `modeline' an alias for `mode-line', for compatibility.
1904 (put 'modeline 'face-alias 'mode-line)
1905 (put 'modeline-inactive 'face-alias 'mode-line-inactive)
1906 (put 'modeline-highlight 'face-alias 'mode-line-highlight)
1907
1908 (defface header-line
1909   '((default
1910      :inherit mode-line)
1911     (((type tty))
1912      ;; This used to be `:inverse-video t', but that doesn't look very
1913      ;; good when combined with inverse-video mode-lines and multiple
1914      ;; windows.  Underlining looks better, and is more consistent with
1915      ;; the window-system face variants, which deemphasize the
1916      ;; header-line in relation to the mode-line face.  If a terminal
1917      ;; can't underline, then the header-line will end up without any
1918      ;; highlighting; this may be too confusing in general, although it
1919      ;; happens to look good with the only current use of header-lines,
1920      ;; the info browser. XXX
1921      :inverse-video nil        ;Override the value inherited from mode-line.
1922      :underline t)
1923     (((class color grayscale) (background light))
1924      :background "grey90" :foreground "grey20"
1925      :box nil)
1926     (((class color grayscale) (background dark))
1927      :background "grey20" :foreground "grey90"
1928      :box nil)
1929     (((class mono) (background light))
1930      :background "white" :foreground "black"
1931      :inverse-video nil
1932      :box nil
1933      :underline t)
1934     (((class mono) (background dark))
1935      :background "black" :foreground "white"
1936      :inverse-video nil
1937      :box nil
1938      :underline t))
1939   "Basic header-line face."
1940   :version "21.1"
1941   :group 'basic-faces)
1942
1943
1944 (defface tool-bar
1945   '((default
1946      :box (:line-width 1 :style released-button)
1947      :foreground "black")
1948     (((type x w32 mac) (class color))
1949      :background "grey75")
1950     (((type x) (class mono))
1951      :background "grey"))
1952   "Basic tool-bar face."
1953   :version "21.1"
1954   :group 'basic-faces)
1955
1956
1957 (defface minibuffer-prompt '((((background dark)) :foreground "cyan")
1958                              ;; Don't use blue because many users of
1959                              ;; the MS-DOS port customize their
1960                              ;; foreground color to be blue.
1961                              (((type pc)) :foreground "magenta")
1962                              (t :foreground "dark blue"))
1963   "Face for minibuffer prompts."
1964   :version "22.1"
1965   :group 'basic-faces)
1966
1967 (setq minibuffer-prompt-properties
1968       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
1969
1970 (defface region
1971   '((((class color) (min-colors 88) (background dark))
1972      :background "blue3")
1973     (((class color) (min-colors 88) (background light))
1974      :background "lightgoldenrod2")
1975     (((class color) (min-colors 16) (background dark))
1976      :background "blue3")
1977     (((class color) (min-colors 16) (background light))
1978      :background "lightgoldenrod2")
1979     (((class color) (min-colors 8))
1980      :background "blue" :foreground "white")
1981     (((type tty) (class mono))
1982      :inverse-video t)
1983     (t :background "gray"))
1984   "Basic face for highlighting the region."
1985   :version "21.1"
1986   :group 'basic-faces)
1987
1988
1989 (defface fringe
1990   '((((class color) (background light))
1991      :background "grey95")
1992     (((class color) (background dark))
1993      :background "grey10")
1994     (t
1995      :background "gray"))
1996   "Basic face for the fringes to the left and right of windows under X."
1997   :version "21.1"
1998   :group 'frames
1999   :group 'basic-faces)
2000
2001
2002 (defface scroll-bar '()
2003   "Basic face for the scroll bar colors under X."
2004   :version "21.1"
2005   :group 'frames
2006   :group 'basic-faces)
2007
2008
2009 (defface menu
2010   '((((type tty))
2011      :inverse-video t)
2012     (((type x-toolkit))
2013      )
2014     (t
2015      :inverse-video t))
2016   "Basic face for the font and colors of the menu bar and popup menus."
2017   :version "21.1"
2018   :group 'menu
2019   :group 'basic-faces)
2020
2021
2022 (defface border '()
2023   "Basic face for the frame border under X."
2024   :version "21.1"
2025   :group 'frames
2026   :group 'basic-faces)
2027
2028
2029 (defface cursor '()
2030   "Basic face for the cursor color under X.
2031 Note: Other faces cannot inherit from the cursor face."
2032   :version "21.1"
2033   :group 'cursor
2034   :group 'basic-faces)
2035
2036 (put 'cursor 'face-no-inherit t)
2037
2038 (defface mouse '()
2039   "Basic face for the mouse color under X."
2040   :version "21.1"
2041   :group 'mouse
2042   :group 'basic-faces)
2043
2044
2045 (defface bold '((t :weight bold))
2046   "Basic bold face."
2047   :group 'basic-faces)
2048
2049
2050 (defface italic
2051   '((((supports :slant italic))
2052      :slant italic)
2053     (((supports :underline t))
2054      :underline t)
2055     (t
2056      ;; default to italic, even it doesn't appear to be supported,
2057      ;; because in some cases the display engine will do it's own
2058      ;; workaround (to `dim' on ttys)
2059      :slant italic))
2060   "Basic italic face."
2061   :group 'basic-faces)
2062
2063
2064 (defface bold-italic '((t :weight bold :slant italic))
2065   "Basic bold-italic face."
2066   :group 'basic-faces)
2067
2068
2069 (defface underline '((((supports :underline t))
2070                       :underline t)
2071                      (((supports :weight bold))
2072                       :weight bold)
2073                      (t :underline t))
2074   "Basic underlined face."
2075   :group 'basic-faces)
2076
2077
2078 (defface highlight
2079   '((((class color) (min-colors 88) (background light))
2080      :background "darkseagreen2")
2081     (((class color) (min-colors 88) (background dark))
2082      :background "darkolivegreen")
2083     (((class color) (min-colors 16) (background light))
2084      :background "darkseagreen2")
2085     (((class color) (min-colors 16) (background dark))
2086      :background "darkolivegreen")
2087     (((class color) (min-colors 8))
2088      :background "green" :foreground "black")
2089     (t :inverse-video t))
2090   "Basic face for highlighting."
2091   :group 'basic-faces)
2092
2093
2094 (defface secondary-selection
2095   '((((class color) (min-colors 88) (background light))
2096      :background "yellow1")
2097     (((class color) (min-colors 88) (background dark))
2098      :background "SkyBlue4")
2099     (((class color) (min-colors 16) (background light))
2100      :background "yellow")
2101     (((class color) (min-colors 16) (background dark))
2102      :background "SkyBlue4")
2103     (((class color) (min-colors 8))
2104      :background "cyan" :foreground "black")
2105     (t :inverse-video t))
2106   "Basic face for displaying the secondary selection."
2107   :group 'basic-faces)
2108
2109
2110 (defface fixed-pitch '((t :family "courier"))
2111   "The basic fixed-pitch face."
2112   :group 'basic-faces)
2113
2114
2115 (defface variable-pitch '((t :family "helv"))
2116   "The basic variable-pitch face."
2117   :group 'basic-faces)
2118
2119
2120 (defface trailing-whitespace
2121   '((((class color) (background light))
2122      :background "red1")
2123     (((class color) (background dark))
2124      :background "red1")
2125     (t :inverse-video t))
2126   "Basic face for highlighting trailing whitespace."
2127   :version "21.1"
2128   :group 'whitespace            ; like `show-trailing-whitespace'
2129   :group 'basic-faces)
2130
2131 (defface escape-glyph
2132   '((((background dark)) :foreground "cyan")
2133     ;; See the comment in minibuffer-prompt for
2134     ;; the reason not to use blue on MS-DOS.
2135     (((type pc)) :foreground "magenta")
2136     ;; red4 is too dark, but some say blue is too loud.
2137     ;; brown seems to work ok. -- rms.
2138     (t :foreground "brown"))
2139   "Face for characters displayed as ^-sequences or \-sequences."
2140   :group 'basic-faces
2141   :version "22.1")
2142
2143 (defface nobreak-space
2144   '((((class color) (min-colors 88)) :inherit escape-glyph :underline t)
2145     (((class color) (min-colors 8)) :background "magenta")
2146     (t :inverse-video t))
2147   "Face for displaying nobreak space."
2148   :group 'basic-faces
2149   :version "22.1")
2150
2151 (defface shadow
2152   '((((class color grayscale) (min-colors 88) (background light))
2153      :foreground "grey50")
2154     (((class color grayscale) (min-colors 88) (background dark))
2155      :foreground "grey70")
2156     (((class color) (min-colors 8) (background light))
2157      :foreground "green")
2158     (((class color) (min-colors 8) (background dark))
2159      :foreground "yellow"))
2160   "Basic face for shadowed text."
2161   :group 'basic-faces
2162   :version "22.1")
2163
2164 \f
2165 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2166 ;;; Manipulating font names.
2167 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2168
2169 ;; This is here for compatibilty with Emacs 20.2.  For example,
2170 ;; international/fontset.el uses x-resolve-font-name.  The following
2171 ;; functions are not used in the face implementation itself.
2172
2173 (defvar x-font-regexp nil)
2174 (defvar x-font-regexp-head nil)
2175 (defvar x-font-regexp-weight nil)
2176 (defvar x-font-regexp-slant nil)
2177
2178 (defconst x-font-regexp-weight-subnum 1)
2179 (defconst x-font-regexp-slant-subnum 2)
2180 (defconst x-font-regexp-swidth-subnum 3)
2181 (defconst x-font-regexp-adstyle-subnum 4)
2182
2183 ;;; Regexps matching font names in "Host Portable Character Representation."
2184 ;;;
2185 (let ((-                "[-?]")
2186       (foundry          "[^-]+")
2187       (family           "[^-]+")
2188       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2189 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2190       (weight\?         "\\([^-]*\\)")                                  ; 1
2191       (slant            "\\([ior]\\)")                                  ; 2
2192 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2193       (slant\?          "\\([^-]?\\)")                                  ; 2
2194 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2195       (swidth           "\\([^-]*\\)")                                  ; 3
2196 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2197       (adstyle          "\\([^-]*\\)")                                  ; 4
2198       (pixelsize        "[0-9]+")
2199       (pointsize        "[0-9][0-9]+")
2200       (resx             "[0-9][0-9]+")
2201       (resy             "[0-9][0-9]+")
2202       (spacing          "[cmp?*]")
2203       (avgwidth         "[0-9]+")
2204       (registry         "[^-]+")
2205       (encoding         "[^-]+")
2206       )
2207   (setq x-font-regexp
2208         (concat "\\`\\*?[-?*]"
2209                 foundry - family - weight\? - slant\? - swidth - adstyle -
2210                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2211                 registry - encoding "\\*?\\'"
2212                 ))
2213   (setq x-font-regexp-head
2214         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2215                 "\\([-*?]\\|\\'\\)"))
2216   (setq x-font-regexp-slant (concat - slant -))
2217   (setq x-font-regexp-weight (concat - weight -))
2218   nil)
2219
2220
2221 (defun x-resolve-font-name (pattern &optional face frame)
2222   "Return a font name matching PATTERN.
2223 All wildcards in PATTERN are instantiated.
2224 If PATTERN is nil, return the name of the frame's base font, which never
2225 contains wildcards.
2226 Given optional arguments FACE and FRAME, return a font which is
2227 also the same size as FACE on FRAME, or fail."
2228   (or (symbolp face)
2229       (setq face (face-name face)))
2230   (and (eq frame t)
2231        (setq frame nil))
2232   (if pattern
2233       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2234       (let ((fonts (x-list-fonts pattern face frame 1)))
2235         (or fonts
2236             (if face
2237                 (if (string-match "\\*" pattern)
2238                     (if (null (face-font face))
2239                         (error "No matching fonts are the same height as the frame default font")
2240                       (error "No matching fonts are the same height as face `%s'" face))
2241                   (if (null (face-font face))
2242                       (error "Height of font `%s' doesn't match the frame default font"
2243                              pattern)
2244                     (error "Height of font `%s' doesn't match face `%s'"
2245                            pattern face)))
2246               (error "No fonts match `%s'" pattern)))
2247         (car fonts))
2248     (cdr (assq 'font (frame-parameters (selected-frame))))))
2249
2250
2251 (defun x-frob-font-weight (font which)
2252   (let ((case-fold-search t))
2253     (cond ((string-match x-font-regexp font)
2254            (concat (substring font 0
2255                               (match-beginning x-font-regexp-weight-subnum))
2256                    which
2257                    (substring font (match-end x-font-regexp-weight-subnum)
2258                               (match-beginning x-font-regexp-adstyle-subnum))
2259                    ;; Replace the ADD_STYLE_NAME field with *
2260                    ;; because the info in it may not be the same
2261                    ;; for related fonts.
2262                    "*"
2263                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2264           ((string-match x-font-regexp-head font)
2265            (concat (substring font 0 (match-beginning 1)) which
2266                    (substring font (match-end 1))))
2267           ((string-match x-font-regexp-weight font)
2268            (concat (substring font 0 (match-beginning 1)) which
2269                    (substring font (match-end 1)))))))
2270 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2271
2272 (defun x-frob-font-slant (font which)
2273   (let ((case-fold-search t))
2274     (cond ((string-match x-font-regexp font)
2275            (concat (substring font 0
2276                               (match-beginning x-font-regexp-slant-subnum))
2277                    which
2278                    (substring font (match-end x-font-regexp-slant-subnum)
2279                               (match-beginning x-font-regexp-adstyle-subnum))
2280                    ;; Replace the ADD_STYLE_NAME field with *
2281                    ;; because the info in it may not be the same
2282                    ;; for related fonts.
2283                    "*"
2284                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2285           ((string-match x-font-regexp-head font)
2286            (concat (substring font 0 (match-beginning 2)) which
2287                    (substring font (match-end 2))))
2288           ((string-match x-font-regexp-slant font)
2289            (concat (substring font 0 (match-beginning 1)) which
2290                    (substring font (match-end 1)))))))
2291 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2292
2293 ;; These aliases are here so that we don't get warnings about obsolete
2294 ;; functions from the byte compiler.
2295 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2296 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2297
2298 (defun x-make-font-bold (font)
2299   "Given an X font specification, make a bold version of it.
2300 If that can't be done, return nil."
2301   (internal-frob-font-weight font "bold"))
2302 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2303
2304 (defun x-make-font-demibold (font)
2305   "Given an X font specification, make a demibold version of it.
2306 If that can't be done, return nil."
2307   (internal-frob-font-weight font "demibold"))
2308 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2309
2310 (defun x-make-font-unbold (font)
2311   "Given an X font specification, make a non-bold version of it.
2312 If that can't be done, return nil."
2313   (internal-frob-font-weight font "medium"))
2314 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2315
2316 (defun x-make-font-italic (font)
2317   "Given an X font specification, make an italic version of it.
2318 If that can't be done, return nil."
2319   (internal-frob-font-slant font "i"))
2320 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2321
2322 (defun x-make-font-oblique (font) ; you say tomayto...
2323   "Given an X font specification, make an oblique version of it.
2324 If that can't be done, return nil."
2325   (internal-frob-font-slant font "o"))
2326 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2327
2328 (defun x-make-font-unitalic (font)
2329   "Given an X font specification, make a non-italic version of it.
2330 If that can't be done, return nil."
2331   (internal-frob-font-slant font "r"))
2332 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2333
2334 (defun x-make-font-bold-italic (font)
2335   "Given an X font specification, make a bold and italic version of it.
2336 If that can't be done, return nil."
2337   (and (setq font (internal-frob-font-weight font "bold"))
2338        (internal-frob-font-slant font "i")))
2339 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2340
2341 (provide 'faces)
2342
2343 ;; arch-tag: 19a4759f-2963-445f-b004-425b9aadd7d6
2344 ;;; faces.el ends here