configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 23.2.91)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 CRT_DIR=
 173 AC_ARG_WITH([crt-dir],dnl
 174 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 175 This option is only used on x86-64 and s390x GNU/Linux architectures.])])
 176 CRT_DIR="${with_crt_dir}"
 177
 178 AC_ARG_WITH([gnustep-conf],dnl
 179 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 180 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 181   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 182 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 183      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 184
 185 AC_ARG_ENABLE(ns-self-contained,
 186 [AS_HELP_STRING([--disable-ns-self-contained],
 187                 [disable self contained build under NeXTstep])],
 188    EN_NS_SELF_CONTAINED=$enableval,
 189    EN_NS_SELF_CONTAINED=yes)
 190
 191 AC_ARG_ENABLE(asserts,
 192 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 193       USE_XASSERTS=$enableval,
 194       USE_XASSERTS=no)
 195
 196 AC_ARG_ENABLE(maintainer-mode,
 197 [AS_HELP_STRING([--enable-maintainer-mode],
 198                 [enable make rules and dependencies not useful (and sometimes
 199                  confusing) to the casual installer])],
 200       USE_MAINTAINER_MODE=$enableval,
 201       USE_MAINTAINER_MODE=no)
 202 if test $USE_MAINTAINER_MODE = yes; then
 203   MAINT=
 204 else
 205   MAINT=#
 206 fi
 207 AC_SUBST(MAINT)
 208
 209 AC_ARG_ENABLE(locallisppath,
 210 [AS_HELP_STRING([--enable-locallisppath=PATH],
 211                 [directories Emacs should search for lisp files specific
 212                  to this site])],
 213 if test "${enableval}" = "no"; then
 214   locallisppath=
 215 elif test "${enableval}" != "yes"; then
 216   locallisppath=${enableval}
 217 fi)
 218
 219 AC_ARG_ENABLE(checking,
 220 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 221                 [enable expensive run-time checks.  With LIST,
 222                  enable only specific categories of checks.
 223                  Categories are: all,yes,no.
 224                  Flags are: stringbytes, stringoverrun, stringfreelist,
 225                  xmallocoverrun, conslist])],
 226 [ac_checking_flags="${enableval}"],[])
 227 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 228 for check in $ac_checking_flags
 229 do
 230         case $check in
 231         # these set all the flags to specific states
 232         yes)            ac_enable_checking=1 ;;
 233         no)             ac_enable_checking= ;
 234                         ac_gc_check_stringbytes= ;
 235                         ac_gc_check_string_overrun= ;
 236                         ac_gc_check_string_free_list= ;
 237                         ac_xmalloc_overrun= ;
 238                         ac_gc_check_cons_list= ;;
 239         all)            ac_enable_checking=1 ;
 240                         ac_gc_check_stringbytes=1 ;
 241                         ac_gc_check_string_overrun=1 ;
 242                         ac_gc_check_string_free_list=1 ;
 243                         ac_xmalloc_overrun=1 ;
 244                         ac_gc_check_cons_list=1 ;;
 245         # these enable particular checks
 246         stringbytes)    ac_gc_check_stringbytes=1 ;;
 247         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 248         stringfreelist) ac_gc_check_string_free_list=1 ;;
 249         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 250         conslist)       ac_gc_check_cons_list=1 ;;
 251         *)      AC_MSG_ERROR(unknown check category $check) ;;
 252         esac
 253 done
 254 IFS="$ac_save_IFS"
 255
 256 if test x$ac_enable_checking != x ; then
 257   AC_DEFINE(ENABLE_CHECKING, 1,
 258 [Enable expensive run-time checking of data types?])
 259 fi
 260 if test x$ac_gc_check_stringbytes != x ; then
 261   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 262 [Define this temporarily to hunt a bug.  If defined, the size of
 263    strings is redundantly recorded in sdata structures so that it can
 264    be compared to the sizes recorded in Lisp strings.])
 265 fi
 266 if test x$ac_gc_check_stringoverrun != x ; then
 267   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 268 [Define this to check for short string overrun.])
 269 fi
 270 if test x$ac_gc_check_string_free_list != x ; then
 271   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 272 [Define this to check the string free list.])
 273 fi
 274 if test x$ac_xmalloc_overrun != x ; then
 275   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 276 [Define this to check for malloc buffer overrun.])
 277 fi
 278 if test x$ac_gc_check_cons_list != x ; then
 279   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 280 [Define this to check for errors in cons list.])
 281 fi
 282
 283 AC_ARG_ENABLE(profiling,
 284 [AS_HELP_STRING([--enable-profiling],
 285                 [build emacs with profiling support.
 286                  This might not work on all platforms])],
 287 [ac_enable_profiling="${enableval}"],[])
 288 if test x$ac_enable_profiling != x ; then
 289    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 290    PROFILING_LDFLAGS="-pg"
 291 else
 292    PROFILING_CFLAGS=
 293    PROFILING_LDFLAGS=
 294 fi
 295
 296 AC_ARG_ENABLE(autodepend,
 297 [AS_HELP_STRING([--enable-autodepend],
 298                 [automatically generate dependencies to .h-files.
 299                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 300                  found])],
 301 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 302
 303 #### Make srcdir absolute, if it isn't already.  It's important to
 304 #### avoid running the path through pwd unnecessarily, since pwd can
 305 #### give you automounter prefixes, which can go away.  We do all this
 306 #### so Emacs can find its files when run uninstalled.
 307 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 308 unset CDPATH
 309 case "${srcdir}" in
 310   /* ) ;;
 311   . )
 312     ## We may be able to use the $PWD environment variable to make this
 313     ## absolute.  But sometimes PWD is inaccurate.
 314     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 315     ## but that tested only for a well-formed and valid PWD,
 316     ## it did not object when PWD was well-formed and valid but just wrong.
 317     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 318     then
 319       srcdir="$PWD"
 320     else
 321       srcdir="`(cd ${srcdir}; pwd)`"
 322     fi
 323   ;;
 324   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 325 esac
 326
 327 #### Check if the source directory already has a configured system in it.
 328 if test `pwd` != `(cd ${srcdir} && pwd)` \
 329    && test -f "${srcdir}/src/config.h" ; then
 330   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 331    as a build directory right now; it has been configured in its own
 332    right.  To configure in another directory as well, you MUST
 333    use GNU make.  If you do not have GNU make, then you must
 334    now do `make distclean' in ${srcdir},
 335    and then run $0 again.]])
 336 fi
 337
 338 #### Given the configuration name, set machfile and opsysfile to the
 339 #### names of the m/*.h and s/*.h files we should use.
 340
 341 ### Canonicalize the configuration name.
 342
 343 AC_CANONICAL_HOST
 344 canonical=$host
 345 configuration=${host_alias-${build_alias-$host}}
 346
 347 dnl This used to use changequote, but, apart from `changequote is evil'
 348 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 349 dnl the great gob of text.  Thus it's not processed for possible expansion.
 350 dnl Just make sure the brackets remain balanced.
 351 dnl
 352 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 353 dnl indicated by comments.
 354 dnl quotation begins
 355 [
 356
 357 ### If you add support for a new configuration, add code to this
 358 ### switch statement to recognize your configuration name and select
 359 ### the appropriate operating system and machine description files.
 360
 361 ### You would hope that you could choose an m/*.h file pretty much
 362 ### based on the machine portion of the configuration name, and an s-
 363 ### file based on the operating system portion.  However, it turns out
 364 ### that each m/*.h file is pretty manufacturer-specific - for
 365 ### example mips.h is MIPS
 366 ### So we basically have to have a special case for each
 367 ### configuration name.
 368 ###
 369 ### As far as handling version numbers on operating systems is
 370 ### concerned, make sure things will fail in a fixable way.  If
 371 ### /etc/MACHINES doesn't say anything about version numbers, be
 372 ### prepared to handle anything reasonably.  If version numbers
 373 ### matter, be sure /etc/MACHINES says something about it.
 374 ###
 375 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 376 ### "System V Release 4"; he writes, "The old convention encouraged
 377 ### confusion between `system' and `release' levels'."
 378
 379 machine='' opsys='' unported=no
 380 case "${canonical}" in
 381
 382   ## FreeBSD ports
 383   *-*-freebsd* )
 384     opsys=freebsd
 385     case "${canonical}" in
 386       alpha*-*-freebsd*)        machine=alpha ;;
 387       arm*-*-freebsd*)          machine=arm ;;
 388       ia64-*-freebsd*)          machine=ia64 ;;
 389       sparc-*-freebsd*)         machine=sparc ;;
 390       sparc64-*-freebsd*)       machine=sparc ;;
 391       powerpc-*-freebsd*)       machine=macppc ;;
 392       i[3456]86-*-freebsd*)     machine=intel386 ;;
 393       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 394     esac
 395   ;;
 396
 397   ## FreeBSD kernel + glibc based userland
 398   *-*-kfreebsd*gnu* )
 399     opsys=gnu-kfreebsd
 400     case "${canonical}" in
 401       alpha*-*-kfreebsd*)       machine=alpha ;;
 402       ia64-*-kfreebsd*)         machine=ia64 ;;
 403       sparc-*-kfreebsd*)        machine=sparc ;;
 404       sparc64-*-kfreebsd*)      machine=sparc ;;
 405       powerpc-*-kfreebsd*)      machine=macppc ;;
 406       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 407       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 408     esac
 409   ;;
 410
 411   ## NetBSD ports
 412   *-*-netbsd* )
 413     opsys=netbsd
 414     if test -f /usr/lib/crti.o; then]
 415 dnl The close and open brackets here are because this section is quoted --
 416 dnl see the `changequote' comment above.
 417       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 418 [   fi
 419
 420     case "${canonical}" in
 421       alpha*-*-netbsd*) machine=alpha ;;
 422       i[3456]86-*-netbsd*) machine=intel386 ;;
 423       mips-*-netbsd*)   machine=mips ;;
 424       mipsel-*-netbsd*) machine=mips ;;
 425       mipseb-*-netbsd*) machine=mips ;;
 426       powerpc-*-netbsd*) machine=macppc ;;
 427       sparc*-*-netbsd*) machine=sparc ;;
 428       vax-*-netbsd*)    machine=vax ;;
 429       arm-*-netbsd*)    machine=arm ;;
 430       x86_64-*-netbsd*) machine=amdx86-64 ;;
 431       hppa-*-netbsd*)   machine=hp800 ;;
 432       m68k-*-netbsd*)   machine=m68k ;;
 433     esac
 434   ;;
 435
 436   ## OpenBSD ports
 437   *-*-openbsd* )
 438     opsys=openbsd
 439     case "${canonical}" in
 440       alpha*-*-openbsd*)        machine=alpha ;;
 441       arm-*-openbsd*)          machine=arm ;;
 442       i386-*-openbsd*)         machine=intel386 ;;
 443       powerpc-*-openbsd*)      machine=macppc ;;
 444       sparc*-*-openbsd*)       machine=sparc ;;
 445       vax-*-openbsd*)          machine=vax ;;
 446       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 447       hppa-*-openbsd*)         machine=hp800 ;;
 448     esac
 449   ;;
 450
 451   ## LynxOS ports
 452   *-*-lynxos* )
 453     opsys=lynxos
 454     case "${canonical}" in
 455       i[3456]86-*-lynxos*) machine=intel386 ;;
 456       powerpc-*-lynxos*) machine=powerpc ;;
 457     esac
 458   ;;
 459
 460   alpha*-*-linux-gnu* )
 461     machine=alpha opsys=gnu-linux
 462   ;;
 463
 464   arm*-*-linux-gnu* )
 465     machine=arm opsys=gnu-linux
 466   ;;
 467
 468   ## Apple Darwin / Mac OS X
 469   *-apple-darwin* )
 470     case "${canonical}" in
 471       i[3456]86-* )  machine=intel386 ;;
 472       powerpc-* )    machine=macppc ;;
 473       x86_64-* )     machine=amdx86-64 ;;
 474       * )            unported=yes ;;
 475     esac
 476     opsys=darwin
 477     # Define CPP as follows to make autoconf work correctly.
 478     CPP="${CC-cc} -E -no-cpp-precomp"
 479     # Use fink packages if available.
 480     if test -d /sw/include && test -d /sw/lib; then
 481       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 482       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 483       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 484     fi
 485   ;;
 486
 487   ## HP 9000 series 700 and 800, running HP/UX
 488   hppa*-hp-hpux10.2* )
 489     machine=hp800 opsys=hpux10-20
 490   ;;
 491   hppa*-hp-hpux1[1-9]* )
 492     machine=hp800 opsys=hpux11
 493     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 494   ;;
 495
 496   hppa*-*-linux-gnu* )
 497     machine=hp800 opsys=gnu-linux
 498   ;;
 499
 500   ## IBM machines
 501   s390-*-linux-gnu* )
 502     machine=ibms390 opsys=gnu-linux
 503   ;;
 504   s390x-*-linux-gnu* )
 505     machine=ibms390x opsys=gnu-linux
 506   ;;
 507   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 508     machine=ibmrs6000 opsys=aix4-2
 509   ;;
 510   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 511     machine=ibmrs6000 opsys=aix4-2
 512   ;;
 513   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 514     machine=ibmrs6000 opsys=aix4-2
 515   ;;
 516   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 517     machine=ibmrs6000 opsys=aix4-2
 518   ;;
 519
 520   ## Macintosh PowerPC
 521   powerpc*-*-linux-gnu* )
 522     machine=macppc opsys=gnu-linux
 523   ;;
 524
 525   ## Silicon Graphics machines
 526   ## Iris 4D
 527   mips-sgi-irix6.5 )
 528     machine=iris4d opsys=irix6-5
 529     # Without defining _LANGUAGE_C, things get masked out in the headers
 530     # so that, for instance, grepping for `free' in stdlib.h fails and
 531     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 532     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 533     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 534   ;;
 535
 536   ## Suns
 537   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 538     machine=sparc opsys=gnu-linux
 539   ;;
 540
 541   *-sun-solaris* \
 542     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 543     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 544     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 545     case "${canonical}" in
 546       i[3456]86-*-* )     machine=intel386 ;;
 547       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 548       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 549       sparc* )          machine=sparc ;;
 550       * )               unported=yes ;;
 551     esac
 552     case "${canonical}" in
 553       *-sunos5.3* | *-solaris2.3* )
 554                 opsys=sol2-3
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 ;;
 557       *-sunos5.4* | *-solaris2.4* )
 558                 opsys=sol2-4
 559                 NON_GNU_CPP=/usr/ccs/lib/cpp
 560                 RANLIB="ar -ts"
 561                 ;;
 562       *-sunos5.5* | *-solaris2.5* )
 563                 opsys=sol2-5
 564                 NON_GNU_CPP=/usr/ccs/lib/cpp
 565                 RANLIB="ar -ts"
 566                 ;;
 567       *-sunos5.6* | *-solaris2.6* )
 568                 opsys=sol2-6
 569                 NON_GNU_CPP=/usr/ccs/lib/cpp
 570                 RANLIB="ar -ts"
 571                 ;;
 572       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 573                 opsys=sol2-6
 574                 emacs_check_sunpro_c=yes
 575                 NON_GNU_CPP=/usr/ccs/lib/cpp
 576                 ;;
 577       *-sunos5* | *-solaris* )
 578                 opsys=sol2-10
 579                 emacs_check_sunpro_c=yes
 580                 NON_GNU_CPP=/usr/ccs/lib/cpp
 581                 ;;
 582     esac
 583     ## Watch out for a compiler that we know will not work.
 584     case "${canonical}" in
 585      *-solaris* | *-sunos5* )
 586                 if [ "x$CC" = x/usr/ucb/cc ]; then
 587                   ## /usr/ucb/cc doesn't work;
 588                   ## we should find some other compiler that does work.
 589                   unset CC
 590                 fi
 591                 ;;
 592       *) ;;
 593     esac
 594   ;;
 595
 596   ## IA-64
 597   ia64*-*-linux* )
 598     machine=ia64 opsys=gnu-linux
 599   ;;
 600
 601   ## Intel 386 machines where we don't care about the manufacturer
 602   i[3456]86-*-* )
 603     machine=intel386
 604     case "${canonical}" in
 605       *-cygwin )                opsys=cygwin ;;
 606       *-darwin* )               opsys=darwin
 607                                 CPP="${CC-cc} -E -no-cpp-precomp"
 608                                 ;;
 609       *-linux-gnu* )            opsys=gnu-linux ;;
 610       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 611       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 612       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 613       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 614     esac
 615   ;;
 616
 617   ## m68k Linux-based GNU system
 618   m68k-*-linux-gnu* )
 619     machine=m68k opsys=gnu-linux
 620   ;;
 621
 622   ## Mips Linux-based GNU system
 623   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 624     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 625     machine=mips opsys=gnu-linux
 626   ;;
 627
 628   ## AMD x86-64 Linux-based GNU system
 629   x86_64-*-linux-gnu* )
 630     machine=amdx86-64 opsys=gnu-linux
 631   ;;
 632
 633   ## Tensilica Xtensa Linux-based GNU system
 634   xtensa*-*-linux-gnu* )
 635     machine=xtensa opsys=gnu-linux
 636     ;;
 637
 638   ## SuperH Linux-based GNU system
 639   sh[34]*-*-linux-gnu* )
 640     machine=sh3 opsys=gnu-linux
 641   ;;
 642
 643   * )
 644     unported=yes
 645   ;;
 646 esac
 647
 648 ### If the code above didn't choose an operating system, just choose
 649 ### an operating system based on the configuration name.  You really
 650 ### only want to use this when you have no idea what the right
 651 ### operating system is; if you know what operating systems a machine
 652 ### runs, it's cleaner to make it explicit in the case statement
 653 ### above.
 654 if test x"${opsys}" = x; then
 655   case "${canonical}" in
 656     *-gnu* )                            opsys=gnu ;;
 657     *-sysv4.2uw* )                      opsys=unixware ;;
 658     *-sysv5uw* )                        opsys=unixware ;;
 659     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 660     *-sysv4.1* | *-sysvr4.1* )
 661         NON_GNU_CPP=/usr/lib/cpp
 662         opsys=usg5-4 ;;
 663     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 664         if [ x$NON_GNU_CPP = x ]; then
 665           if [ -f /usr/ccs/lib/cpp ]; then
 666             NON_GNU_CPP=/usr/ccs/lib/cpp
 667           else
 668             NON_GNU_CPP=/lib/cpp
 669           fi
 670         fi
 671         opsys=usg5-4-2 ;;
 672     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 673     * )
 674       unported=yes
 675     ;;
 676   esac
 677 fi
 678
 679 ]
 680 dnl quotation ends
 681
 682 if test $unported = yes; then
 683   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 684 Check `etc/MACHINES' for recognized configuration names.])
 685 fi
 686
 687 machfile="m/${machine}.h"
 688 opsysfile="s/${opsys}.h"
 689
 690
 691 #### Choose a compiler.
 692 test -n "$CC" && cc_specified=yes
 693
 694 # Save the value of CFLAGS that the user specified.
 695 SPECIFIED_CFLAGS="$CFLAGS"
 696
 697 dnl Sets GCC=yes if using gcc.
 698 AC_PROG_CC
 699
 700 # On Suns, sometimes $CPP names a directory.
 701 if test -n "$CPP" && test -d "$CPP"; then
 702   CPP=
 703 fi
 704
 705 ## If not using gcc, and on Solaris, and no CPP specified, see if
 706 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 707 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 708  test x"$CPP" = x; then
 709   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 710   AC_CACHE_VAL(emacs_cv_sunpro_c,
 711   [AC_TRY_LINK([],
 712 [#ifndef __SUNPRO_C
 713 fail;
 714 #endif
 715 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 716   AC_MSG_RESULT($emacs_cv_sunpro_c)
 717
 718   if test x"$emacs_cv_sunpro_c" = xyes; then
 719     NON_GNU_CPP="$CC -E -Xs"
 720   fi
 721 fi
 722
 723 #### Some systems specify a CPP to use unless we are using GCC.
 724 #### Now that we know whether we are using GCC, we can decide whether
 725 #### to use that one.
 726 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 727 then
 728   CPP="$NON_GNU_CPP"
 729 fi
 730
 731 #### Some systems specify a CC to use unless we are using GCC.
 732 #### Now that we know whether we are using GCC, we can decide whether
 733 #### to use that one.
 734 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 735   test x$cc_specified != xyes
 736 then
 737   CC="$NON_GNU_CC"
 738 fi
 739
 740 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 741 then
 742   CC="$CC $GCC_TEST_OPTIONS"
 743 fi
 744
 745 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 746 then
 747   CC="$CC $NON_GCC_TEST_OPTIONS"
 748 fi
 749
 750 dnl checks for Unix variants
 751 AC_USE_SYSTEM_EXTENSIONS
 752
 753 ### Use -Wno-pointer-sign if the compiler supports it
 754 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 755 SAVE_CFLAGS="$CFLAGS"
 756 CFLAGS="$CFLAGS -Wno-pointer-sign"
 757 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 758 if test $has_option = yes; then
 759    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 760 fi
 761 AC_MSG_RESULT($has_option)
 762 CFLAGS="$SAVE_CFLAGS"
 763 unset has_option
 764 unset SAVE_CFLAGS
 765
 766 ### Use -Wdeclaration-after-statement if the compiler supports it
 767 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 768 SAVE_CFLAGS="$CFLAGS"
 769 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 770 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 771 if test $has_option = yes; then
 772    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 773 fi
 774 AC_MSG_RESULT($has_option)
 775 CFLAGS="$SAVE_CFLAGS"
 776 unset has_option
 777 unset SAVE_CFLAGS
 778
 779 #### Some other nice autoconf tests.
 780
 781 dnl checks for programs
 782 AC_PROG_LN_S
 783 AC_PROG_CPP
 784 AC_PROG_INSTALL
 785 if test "x$RANLIB" = x; then
 786   AC_PROG_RANLIB
 787 fi
 788 AC_PATH_PROG(INSTALL_INFO, install-info)
 789 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 790 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 791 dnl Don't use GZIP, which is used by gzip for additional parameters.
 792 AC_PATH_PROG(GZIP_PROG, gzip)
 793
 794
 795 ## Need makeinfo >= 4.6 (?) to build the manuals.
 796 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 797 dnl By this stage, configure has already checked for egrep and set EGREP,
 798 dnl or exited with an error if no egrep was found.
 799 if test "$MAKEINFO" != "no" && \
 800   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 801    MAKEINFO=no
 802 fi
 803
 804 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 805 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 806 ## therefore in the category of "special tools" not normally required, which
 807 ## configure does not have to check for (eg autoconf itself).
 808 ## In a Bazaar checkout on the other hand, the manuals are not included.
 809 ## So makeinfo is a requirement to build from Bazaar, and configure
 810 ## should test for it as it does for any other build requirement.
 811 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 812 ## with pre-built manuals, from a Bazaar checkout.
 813 if test "$MAKEINFO" = "no"; then
 814   if test "x${with_makeinfo}" = "xno"; then
 815     MAKEINFO=off
 816   elif ! test -e $srcdir/info/emacs; then
 817     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 818 source tree does not seem to have pre-built manuals in the `info' directory.
 819 Either install a suitable version of makeinfo, or re-run configure
 820 with the `--without-makeinfo' option to build without the manuals.] )
 821   fi
 822 fi
 823
 824 dnl Add our options to ac_link now, after it is set up.
 825
 826 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 827 then
 828   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 829 fi
 830
 831 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 832 then
 833   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 834 fi
 835
 836 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 837 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 838 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 839 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 840 dnl if not built to support GNU ld.
 841
 842 late_LDFLAGS=$LDFLAGS
 843 if test "$GCC" = yes; then
 844   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 845 else
 846   LDFLAGS="$LDFLAGS -znocombreloc"
 847 fi
 848
 849 AC_MSG_CHECKING([for -znocombreloc])
 850 AC_LINK_IFELSE([main(){return 0;}],
 851   [AC_MSG_RESULT(yes)],
 852   LDFLAGS=$late_LDFLAGS
 853   [AC_MSG_RESULT(no)])
 854
 855 #### Extract some information from the operating system and machine files.
 856
 857 AC_CHECKING([the machine- and system-dependent files to find out
 858  - which libraries the lib-src programs will want, and
 859  - whether the GNU malloc routines are usable])
 860
 861 ### First figure out CFLAGS (which we use for running the compiler here)
 862 ### and REAL_CFLAGS (which we use for real compilation).
 863 ### The two are the same except on a few systems, where they are made
 864 ### different to work around various lossages.  For example,
 865 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 866 ### as implying static linking.
 867
 868 ### If the CFLAGS env var is specified, we use that value
 869 ### instead of the default.
 870
 871 ### It's not important that this name contain the PID; you can't run
 872 ### two configures in the same directory and have anything work
 873 ### anyway.
 874 tempcname="conftest.c"
 875
 876 echo '
 877 #include "'${srcdir}'/src/'${opsysfile}'"
 878 #include "'${srcdir}'/src/'${machfile}'"
 879 #ifndef LIBS_MACHINE
 880 #define LIBS_MACHINE
 881 #endif
 882 #ifndef LIBS_SYSTEM
 883 #define LIBS_SYSTEM
 884 #endif
 885 #ifndef C_SWITCH_SYSTEM
 886 #define C_SWITCH_SYSTEM
 887 #endif
 888 #ifndef C_SWITCH_MACHINE
 889 #define C_SWITCH_MACHINE
 890 #endif
 891 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 892 configure___ c_switch_system=C_SWITCH_SYSTEM
 893 configure___ c_switch_machine=C_SWITCH_MACHINE
 894
 895 #ifndef LIB_X11_LIB
 896 #define LIB_X11_LIB -lX11
 897 #endif
 898
 899 #ifndef LIBX11_SYSTEM
 900 #define LIBX11_SYSTEM
 901 #endif
 902 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 903
 904 #ifdef UNEXEC
 905 configure___ unexec=UNEXEC
 906 #else
 907 configure___ unexec=unexec.o
 908 #endif
 909
 910 #ifdef SYSTEM_MALLOC
 911 configure___ system_malloc=yes
 912 #else
 913 configure___ system_malloc=no
 914 #endif
 915
 916 #ifdef USE_MMAP_FOR_BUFFERS
 917 configure___ use_mmap_for_buffers=yes
 918 #else
 919 configure___ use_mmap_for_buffers=no
 920 #endif
 921
 922 #ifndef C_DEBUG_SWITCH
 923 #define C_DEBUG_SWITCH -g
 924 #endif
 925
 926 #ifndef C_OPTIMIZE_SWITCH
 927 #ifdef __GNUC__
 928 #define C_OPTIMIZE_SWITCH -O2
 929 #else
 930 #define C_OPTIMIZE_SWITCH -O
 931 #endif
 932 #endif
 933
 934 #ifndef C_WARNINGS_SWITCH
 935 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 936 #endif
 937
 938 #ifndef LD_SWITCH_MACHINE
 939 #define LD_SWITCH_MACHINE
 940 #endif
 941
 942 #ifndef LD_SWITCH_SYSTEM
 943 #define LD_SWITCH_SYSTEM
 944 #endif
 945
 946 #ifndef LD_SWITCH_X_SITE_AUX
 947 #define LD_SWITCH_X_SITE_AUX
 948 #endif
 949
 950 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 951 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 952
 953 #ifdef THIS_IS_CONFIGURE
 954
 955 /* Get the CFLAGS for tests in configure.  */
 956 #ifdef __GNUC__
 957 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 958 #else
 959 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 960 #endif
 961
 962 #else /* not THIS_IS_CONFIGURE */
 963
 964 /* Get the CFLAGS for real compilation.  */
 965 #ifdef __GNUC__
 966 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 967 #else
 968 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 969 #endif
 970
 971 #endif /* not THIS_IS_CONFIGURE */
 972 ' > ${tempcname}
 973
 974 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 975
 976 # The value of CPP is a quoted variable reference, so we need to do this
 977 # to get its actual value...
 978 CPP=`eval "echo $CPP"`
 979 [eval `${CPP} -Isrc ${tempcname} \
 980        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 981 if test "x$SPECIFIED_CFLAGS" = x; then
 982   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 983          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 984 else
 985   REAL_CFLAGS="$CFLAGS"
 986 fi]
 987 rm ${tempcname}
 988
 989 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 990
 991 ### Make sure subsequent tests use flags consistent with the build flags.
 992
 993 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 994   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 995 else
 996   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 997 fi
 998
 999 dnl For AC_FUNC_GETLOADAVG, at least:
1000 AC_CONFIG_LIBOBJ_DIR(src)
1001
1002 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1003 AC_SYS_LARGEFILE
1004
1005 ## Note: at present CRT_DIR is only used for amdx86-64 and ibms390x.
1006 ## Other machine types hard-code the location in src/[ms]/*.h.
1007 case "${canonical}" in
1008   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1009    ## On x86-64 and s390x GNU/Linux distributions, the standard library
1010    ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1011    ## For anything else (eg /usr/lib32), it is up the user to specify
1012    ## the location (bug#5655).
1013    ## Test for crtn.o, not just the directory, because sometimes the
1014    ## directory exists but does not have the relevant files (bug#1287).
1015    ## If user specified a crt-dir, use that unconditionally.
1016    if test "X$CRT_DIR" = "X"; then
1017      CRT_DIR=/usr/lib
1018      test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1019    fi
1020
1021    test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1022      AC_MSG_ERROR([crt*.o not found.  Use --with-crt-dir to specify the location.])
1023    ;;
1024 esac
1025 test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1026 AC_SUBST(CRT_DIR)
1027
1028 dnl This function defintion taken from Gnome 2.0
1029 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1030 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1031 dnl also defines GSTUFF_PKG_ERRORS on error
1032 AC_DEFUN([PKG_CHECK_MODULES], [
1033   succeeded=no
1034
1035   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1036
1037   if test "$PKG_CONFIG" = "no" ; then
1038      ifelse([$4], , [AC_MSG_ERROR([
1039       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1040   else
1041      PKG_CONFIG_MIN_VERSION=0.9.0
1042      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1043         AC_MSG_CHECKING(for $2)
1044
1045         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1046             AC_MSG_RESULT(yes)
1047             succeeded=yes
1048
1049             AC_MSG_CHECKING($1_CFLAGS)
1050             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1051             AC_MSG_RESULT($$1_CFLAGS)
1052
1053             AC_MSG_CHECKING($1_LIBS)
1054             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1055             AC_MSG_RESULT($$1_LIBS)
1056         else
1057             AC_MSG_RESULT(no)
1058             $1_CFLAGS=""
1059             $1_LIBS=""
1060             ## If we have a custom action on failure, don't print errors, but
1061             ## do set a variable so people can do so.
1062             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1063             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1064         fi
1065
1066         AC_SUBST($1_CFLAGS)
1067         AC_SUBST($1_LIBS)
1068      else
1069         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1070         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1071      fi
1072   fi
1073
1074   if test $succeeded = yes; then
1075      ifelse([$3], , :, [$3])
1076   else
1077      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1078   fi
1079 ])
1080
1081
1082 if test "${with_sound}" != "no"; then
1083   # Sound support for GNU/Linux and the free BSDs.
1084   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1085   # Emulation library used on NetBSD.
1086   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1087   AC_SUBST(LIBSOUND)
1088
1089   ALSA_REQUIRED=1.0.0
1090   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1091   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1092   if test $HAVE_ALSA = yes; then
1093     SAVE_CFLAGS="$CFLAGS"
1094     SAVE_LDFLAGS="$LDFLAGS"
1095     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1096     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1097     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1098                     emacs_alsa_normal=yes,
1099                     emacs_alsa_normal=no)
1100     if test "$emacs_alsa_normal" != yes; then
1101       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1102                      [snd_lib_error_set_handler (0);],
1103                      emacs_alsa_subdir=yes,
1104                      emacs_alsa_subdir=no)
1105       if test "$emacs_alsa_subdir" != yes; then
1106         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1107       fi
1108       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1109     fi
1110
1111     CFLAGS="$SAVE_CFLAGS"
1112     LDFLAGS="$SAVE_LDFLAGS"
1113     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1114     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1115     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1116   fi
1117   AC_SUBST(CFLAGS_SOUND)
1118 fi
1119
1120 dnl checks for header files
1121 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1122   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1123   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1124   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1125   sys/utsname.h pwd.h utmp.h)
1126
1127 AC_MSG_CHECKING(if personality LINUX32 can be set)
1128 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1129                emacs_cv_personality_linux32=yes,
1130                emacs_cv_personality_linux32=no)
1131 AC_MSG_RESULT($emacs_cv_personality_linux32)
1132
1133 if test $emacs_cv_personality_linux32 = yes; then
1134   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1135             [Define to 1 if personality LINUX32 can be set.])
1136 fi
1137
1138 dnl On Solaris 8 there's a compilation warning for term.h because
1139 dnl it doesn't define `bool'.
1140 AC_CHECK_HEADERS(term.h, , , -)
1141 AC_HEADER_STDC
1142 AC_HEADER_TIME
1143 AC_CHECK_DECLS([sys_siglist])
1144 if test $ac_cv_have_decl_sys_siglist != yes; then
1145   # For Tru64, at least:
1146   AC_CHECK_DECLS([__sys_siglist])
1147   if test $ac_cv_have_decl___sys_siglist = yes; then
1148     AC_DEFINE(sys_siglist, __sys_siglist,
1149               [Define to any substitute for sys_siglist.])
1150   fi
1151 fi
1152 AC_HEADER_SYS_WAIT
1153
1154 dnl Some systems have utime.h but don't declare the struct anyplace.
1155 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1156 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1157 #include <sys/time.h>
1158 #include <time.h>
1159 #else
1160 #ifdef HAVE_SYS_TIME_H
1161 #include <sys/time.h>
1162 #else
1163 #include <time.h>
1164 #endif
1165 #endif
1166 #ifdef HAVE_UTIME_H
1167 #include <utime.h>
1168 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1169   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1170 if test $emacs_cv_struct_utimbuf = yes; then
1171   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1172 fi
1173
1174 dnl checks for typedefs
1175 AC_TYPE_SIGNAL
1176
1177 dnl Check for speed_t typedef.
1178 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1179   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1180     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1181 if test $emacs_cv_speed_t = yes; then
1182   AC_DEFINE(HAVE_SPEED_T, 1,
1183            [Define to 1 if `speed_t' is declared by <termios.h>.])
1184 fi
1185
1186 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1187 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1188 #include <sys/time.h>
1189 #include <time.h>
1190 #else
1191 #ifdef HAVE_SYS_TIME_H
1192 #include <sys/time.h>
1193 #else
1194 #include <time.h>
1195 #endif
1196 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1197   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1198 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1199 if test $emacs_cv_struct_timeval = yes; then
1200   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1201 fi
1202
1203 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1204 AC_TRY_COMPILE([#include <math.h>],
1205 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1206   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1207 HAVE_EXCEPTION=$emacs_cv_struct_exception
1208 if test $emacs_cv_struct_exception != yes; then
1209   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1210 fi
1211
1212 AC_CHECK_HEADERS(sys/socket.h)
1213 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1214 #if HAVE_SYS_SOCKET_H
1215 #include <sys/socket.h>
1216 #endif])
1217
1218 dnl checks for structure members
1219 AC_STRUCT_TM
1220 AC_STRUCT_TIMEZONE
1221 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1222                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1223                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1224                 [#include <time.h>])
1225 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1226                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1227                   struct ifreq.ifr_addr], , ,
1228                  [AC_INCLUDES_DEFAULT
1229 #if HAVE_SYS_SOCKET_H
1230 #include <sys/socket.h>
1231 #endif
1232 #if HAVE_NET_IF_H
1233 #include <net/if.h>
1234 #endif])
1235
1236 dnl checks for compiler characteristics
1237
1238 dnl Testing __STDC__ to determine prototype support isn't good enough.
1239 dnl DEC C, for instance, doesn't define it with default options, and
1240 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1241 dnl and void *.
1242 AC_C_PROTOTYPES
1243 AC_C_VOLATILE
1244 AC_C_CONST
1245 dnl This isn't useful because we can't turn on use of `inline' unless
1246 dnl the compiler groks `extern inline'.
1247 dnl AC_C_INLINE
1248 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1249   [AC_TRY_COMPILE(, [void * foo;],
1250                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1251 if test $emacs_cv_void_star = yes; then
1252   AC_DEFINE(POINTER_TYPE, void)
1253 else
1254   AC_DEFINE(POINTER_TYPE, char)
1255 fi
1256 AH_TEMPLATE(POINTER_TYPE,
1257             [Define as `void' if your compiler accepts `void *'; otherwise
1258              define as `char'.])dnl
1259
1260
1261
1262 dnl This could be used for targets which can have both byte sexes.
1263 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1264 dnl AC_C_BIGENDIAN
1265
1266 dnl check for Make feature
1267 AC_PROG_MAKE_SET
1268
1269 dnl check for GNU Make if we have GCC and autodepend is on.
1270 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1271    AC_MSG_CHECKING([whether we are using GNU Make])
1272    HAVE_GNU_MAKE=no
1273    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1274    if test "x$testval" != x; then
1275       HAVE_GNU_MAKE=yes
1276    else
1277       ac_enable_autodepend=no
1278    fi
1279    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1280    if test $HAVE_GNU_MAKE = yes; then
1281       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1282       SAVE_CFLAGS="$CFLAGS"
1283       CFLAGS="$CFLAGS -MMD -MF deps.d"
1284       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1285       CFLAGS="$SAVE_CFLAGS"
1286       test -f deps.d || ac_enable_autodepend=no
1287       rm -rf deps.d
1288       AC_MSG_RESULT([$ac_enable_autodepend])
1289    fi
1290    if test $ac_enable_autodepend = yes; then
1291       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1292    fi
1293 fi
1294
1295 dnl checks for operating system services
1296 AC_SYS_LONG_FILE_NAMES
1297
1298 #### Choose a window system.
1299
1300 AC_PATH_X
1301 if test "$no_x" = yes; then
1302   window_system=none
1303 else
1304   window_system=x11
1305 fi
1306
1307 ## Workaround for bug in autoconf <= 2.62.
1308 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1309 ## No need to do anything special for these standard directories.
1310 ## This is an experiment, take it out if it causes problems.
1311 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1312
1313    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1314
1315 fi
1316
1317 if test "${x_libraries}" != NONE; then
1318   if test -n "${x_libraries}"; then
1319     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1320     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1321   fi
1322   x_default_search_path=""
1323   x_search_path=${x_libraries}
1324   if test -z "${x_search_path}"; then
1325     x_search_path=/usr/lib
1326   fi
1327   for x_library in `echo ${x_search_path}: | \
1328                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1329     x_search_path="\
1330 ${x_library}/X11/%L/%T/%N%C%S:\
1331 ${x_library}/X11/%l/%T/%N%C%S:\
1332 ${x_library}/X11/%T/%N%C%S:\
1333 ${x_library}/X11/%L/%T/%N%S:\
1334 ${x_library}/X11/%l/%T/%N%S:\
1335 ${x_library}/X11/%T/%N%S"
1336     if test x"${x_default_search_path}" = x; then
1337       x_default_search_path=${x_search_path}
1338     else
1339       x_default_search_path="${x_search_path}:${x_default_search_path}"
1340     fi
1341   done
1342 fi
1343 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1344   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1345 fi
1346
1347 if test x"${x_includes}" = x; then
1348   bitmapdir=/usr/include/X11/bitmaps
1349 else
1350   # accumulate include directories that have X11 bitmap subdirectories
1351   bmd_acc="dummyval"
1352   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1353     if test -d "${bmd}/X11/bitmaps"; then
1354       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1355     fi
1356     if test -d "${bmd}/bitmaps"; then
1357       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1358     fi
1359   done
1360   if test ${bmd_acc} != "dummyval"; then
1361     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1362   fi
1363 fi
1364
1365 HAVE_NS=no
1366 NS_IMPL_COCOA=no
1367 NS_IMPL_GNUSTEP=no
1368 tmp_CPPFLAGS="$CPPFLAGS"
1369 tmp_CFLAGS="$CFLAGS"
1370 CPPFLAGS="$CPPFLAGS -x objective-c"
1371 CFLAGS="$CFLAGS -x objective-c"
1372 if test "${with_ns}" != no; then
1373   if test "${opsys}" = darwin; then
1374      NS_IMPL_COCOA=yes
1375      ns_appdir=`pwd`/nextstep/Emacs.app
1376      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1377      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1378      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1379   elif test -f $GNUSTEP_CONFIG_FILE; then
1380      NS_IMPL_GNUSTEP=yes
1381      ns_appdir=`pwd`/nextstep/Emacs.app
1382      ns_appbindir=`pwd`/nextstep/Emacs.app
1383      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1384      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1385      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1386      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1387      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1388      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1389      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1390      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1391      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1392      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1393   fi
1394   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1395                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1396   files are missing or cannot be compiled.])])
1397   NS_HAVE_NSINTEGER=yes
1398   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1399                                      [NSInteger i;])],
1400                     ns_have_nsinteger=yes,
1401                     ns_have_nsinteger=no)
1402   if test $ns_have_nsinteger = no; then
1403     NS_HAVE_NSINTEGER=no
1404   fi
1405 fi
1406 if test "${HAVE_NS}" = yes; then
1407   window_system=nextstep
1408   with_xft=no
1409   # set up packaging dirs
1410   exec_prefix=${ns_appbindir}
1411   libexecdir=${ns_appbindir}/libexec
1412   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1413      prefix=${ns_appresdir}
1414   fi
1415 fi
1416 CFLAGS="$tmp_CFLAGS"
1417 CPPFLAGS="$tmp_CPPFLAGS"
1418
1419 case "${window_system}" in
1420   x11 )
1421     HAVE_X_WINDOWS=yes
1422     HAVE_X11=yes
1423     case "${with_x_toolkit}" in
1424       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1425       motif ) USE_X_TOOLKIT=MOTIF ;;
1426       gtk ) with_gtk=yes
1427 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1428 dnl USE_X_TOOLKIT is set.
1429             USE_X_TOOLKIT=none ;;
1430       no ) USE_X_TOOLKIT=none ;;
1431 dnl If user did not say whether to use a toolkit, make this decision later:
1432 dnl use the toolkit if we have gtk, or X11R5 or newer.
1433       * ) USE_X_TOOLKIT=maybe ;;
1434     esac
1435   ;;
1436   nextstep | none )
1437     HAVE_X_WINDOWS=no
1438     HAVE_X11=no
1439     USE_X_TOOLKIT=none
1440   ;;
1441 esac
1442
1443 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1444    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1445    if test "$HAVE_XSERVER" = true ||
1446       test -n "$DISPLAY" ||
1447       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1448         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1449 were found.  You should install the relevant development files for X
1450 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1451 sure you have development files for image handling, i.e.
1452 tiff, gif, jpeg, png and xpm.
1453 If you are sure you want Emacs compiled without X window support, pass
1454   --without-x
1455 to configure.])
1456    fi
1457 fi
1458
1459 ### If we're using X11, we should use the X menu package.
1460 HAVE_MENUS=no
1461 case ${HAVE_X11} in
1462   yes ) HAVE_MENUS=yes ;;
1463 esac
1464
1465 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1466 # Assume not, until told otherwise.
1467 GNU_MALLOC=yes
1468 doug_lea_malloc=yes
1469 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1470 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1471 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1472                emacs_cv_var___after_morecore_hook,
1473 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1474   emacs_cv_var___after_morecore_hook=yes,
1475   emacs_cv_var___after_morecore_hook=no)])
1476 if test $emacs_cv_var___after_morecore_hook = no; then
1477   doug_lea_malloc=no
1478 fi
1479 if test "${system_malloc}" = "yes"; then
1480   GNU_MALLOC=no
1481   GNU_MALLOC_reason="
1482     (The GNU allocators don't work with this system configuration.)"
1483 fi
1484 if test "$doug_lea_malloc" = "yes" ; then
1485   if test "$GNU_MALLOC" = yes ; then
1486     GNU_MALLOC_reason="
1487       (Using Doug Lea's new malloc from the GNU C Library.)"
1488   fi
1489   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1490             [Define to 1 if you are using the GNU C Library.])
1491 fi
1492
1493 if test x"${REL_ALLOC}" = x; then
1494   REL_ALLOC=${GNU_MALLOC}
1495 fi
1496
1497 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1498 dnl the system configuration file (s/*.h) to turn the use of mmap
1499 dnl in the relocating allocator on.
1500
1501 AC_FUNC_MMAP
1502 if test $use_mmap_for_buffers = yes; then
1503   REL_ALLOC=no
1504 fi
1505
1506 LIBS="$libsrc_libs $LIBS"
1507
1508 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1509 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1510 AC_CHECK_LIB(dnet, dnet_ntoa)
1511 dnl This causes -lresolv to get used in subsequent tests,
1512 dnl which causes failures on some systems such as HPUX 9.
1513 dnl AC_CHECK_LIB(resolv, gethostbyname)
1514
1515 dnl FIXME replace main with a function we actually want from this library.
1516 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1517
1518 AC_CHECK_LIB(pthreads, cma_open)
1519
1520 dnl Check for need for bigtoc support on IBM AIX
1521
1522 case ${host_os} in
1523 aix*)
1524   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1525     case $GCC in
1526     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1527     *) gdb_cv_bigtoc=-bbigtoc ;;
1528     esac
1529
1530     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1531     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1532   ])
1533   ;;
1534 esac
1535
1536 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1537 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1538 # REAL_CPPFLAGS later on.
1539
1540 REAL_CPPFLAGS="$CPPFLAGS"
1541
1542 if test "${HAVE_X11}" = "yes"; then
1543   DEFS="$C_SWITCH_X_SITE $DEFS"
1544   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1545   LIBS="$LIBX $LIBS"
1546   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1547   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1548
1549   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1550   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1551   # but it's more convenient here to set LD_RUN_PATH
1552   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1553   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1554     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1555     export LD_RUN_PATH
1556   fi
1557
1558   if test "${opsys}" = "gnu-linux"; then
1559     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1560     AC_TRY_LINK([],
1561      [XOpenDisplay ("foo");],
1562      [xlinux_first_failure=no],
1563      [xlinux_first_failure=yes])
1564     if test "${xlinux_first_failure}" = "yes"; then
1565       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1566       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1567       OLD_CPPFLAGS="$CPPFLAGS"
1568       OLD_LIBS="$LIBS"
1569       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1570       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1571       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1572       LIBS="$LIBS -b i486-linuxaout"
1573       AC_TRY_LINK([],
1574        [XOpenDisplay ("foo");],
1575        [xlinux_second_failure=no],
1576        [xlinux_second_failure=yes])
1577       if test "${xlinux_second_failure}" = "yes"; then
1578         # If we get the same failure with -b, there is no use adding -b.
1579         # So take it out.  This plays safe.
1580         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1581         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1582         CPPFLAGS="$OLD_CPPFLAGS"
1583         LIBS="$OLD_LIBS"
1584         AC_MSG_RESULT(no)
1585       else
1586         AC_MSG_RESULT(yes)
1587       fi
1588     else
1589       AC_MSG_RESULT(no)
1590     fi
1591   fi
1592
1593   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1594   # header files included from there.
1595   AC_MSG_CHECKING(for Xkb)
1596   AC_TRY_LINK([#include <X11/Xlib.h>
1597 #include <X11/XKBlib.h>],
1598         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1599         emacs_xkb=yes, emacs_xkb=no)
1600   AC_MSG_RESULT($emacs_xkb)
1601   if test $emacs_xkb = yes; then
1602     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1603   fi
1604
1605   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1606 XScreenNumberOfScreen XSetWMProtocols)
1607 fi
1608
1609 if test "${window_system}" = "x11"; then
1610   AC_MSG_CHECKING(X11 version 6)
1611   AC_CACHE_VAL(emacs_cv_x11_version_6,
1612   [AC_TRY_LINK([#include <X11/Xlib.h>],
1613 [#if XlibSpecificationRelease < 6
1614 fail;
1615 #endif
1616 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1617   if test $emacs_cv_x11_version_6 = yes; then
1618     AC_MSG_RESULT(6 or newer)
1619     AC_DEFINE(HAVE_X11R6, 1,
1620               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1621   else
1622     AC_MSG_RESULT(before 6)
1623   fi
1624 fi
1625
1626
1627 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1628 HAVE_RSVG=no
1629 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1630   if test "${with_rsvg}" != "no"; then
1631     RSVG_REQUIRED=2.11.0
1632     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1633
1634     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1635     AC_SUBST(RSVG_CFLAGS)
1636     AC_SUBST(RSVG_LIBS)
1637
1638     if test ".${RSVG_CFLAGS}" != "."; then
1639       HAVE_RSVG=yes
1640       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1641       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1642       LIBS="$RSVG_LIBS $LIBS"
1643     fi
1644   fi
1645 fi
1646
1647
1648 HAVE_GTK=no
1649 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1650   GLIB_REQUIRED=2.6
1651   GTK_REQUIRED=2.6
1652   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1653
1654   dnl Checks for libraries.
1655   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1656   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1657      AC_MSG_ERROR($GTK_PKG_ERRORS)
1658   fi
1659 fi
1660
1661
1662 if test x"$pkg_check_gtk" = xyes; then
1663
1664   AC_SUBST(GTK_CFLAGS)
1665   AC_SUBST(GTK_LIBS)
1666   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1667   CFLAGS="$CFLAGS $GTK_CFLAGS"
1668   LIBS="$GTK_LIBS $LIBS"
1669   dnl Try to compile a simple GTK program.
1670   GTK_COMPILES=no
1671   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1672   if test "${GTK_COMPILES}" != "yes"; then
1673     if test "$USE_X_TOOLKIT" != "maybe"; then
1674       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1675     fi
1676   else
1677     HAVE_GTK=yes
1678     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1679     USE_X_TOOLKIT=none
1680     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1681       :
1682     else
1683       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1684        closing open displays.  This is no problem if you just use
1685        one display, but if you use more than one and close one of them
1686        Emacs may crash.]])
1687       sleep 3
1688     fi
1689   fi
1690
1691 fi
1692
1693
1694 if test "${HAVE_GTK}" = "yes"; then
1695
1696   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1697   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1698   if test "$with_toolkit_scroll_bars" != no; then
1699     with_toolkit_scroll_bars=yes
1700   fi
1701
1702   dnl  Check if we can use multiple displays with this GTK version.
1703   dnl  If gdk_display_open exists, assume all others are there also.
1704   HAVE_GTK_MULTIDISPLAY=no
1705   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1706   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1707     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1708               [Define to 1 if GTK can handle more than one display.])
1709   fi
1710
1711   dnl  Check if we have the old file selection dialog declared and
1712   dnl  in the link library.  In 2.x it may be in the library,
1713   dnl  but not declared if deprecated featured has been selected out.
1714   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1715   HAVE_GTK_FILE_SELECTION=no
1716   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1717                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1718 #include <gtk/gtk.h>])
1719   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1720     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1721                    HAVE_GTK_FILE_SELECTION=no)
1722   fi
1723
1724   dnl  Check if we have the new file chooser dialog
1725   HAVE_GTK_FILE_CHOOSER=no
1726   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1727                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1728 #include <gtk/gtk.h>])
1729   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1730     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1731                    HAVE_GTK_FILE_CHOOSER=no)
1732   fi
1733
1734   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1735      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1736     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1737               [Define to 1 if GTK has both file selection and chooser dialog.])
1738   fi
1739
1740   dnl Check if pthreads are available.  Emacs only needs this when using
1741   dnl gtk_file_chooser under Gnome.
1742   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1743     HAVE_GTK_AND_PTHREAD=no
1744     AC_CHECK_HEADERS(pthread.h)
1745     if test "$ac_cv_header_pthread_h"; then
1746       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1747     fi
1748     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1749       case "${canonical}" in
1750         *-hpux*) ;;
1751         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1752       esac
1753       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1754                [Define to 1 if you have GTK and pthread (-lpthread).])
1755     fi
1756   fi
1757 fi
1758
1759 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1760 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1761 dnl also not configured.
1762 HAVE_DBUS=no
1763 if test "${with_dbus}" = "yes"; then
1764    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1765    if test "$HAVE_DBUS" = yes; then
1766      LIBS="$LIBS $DBUS_LIBS"
1767      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1768      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1769    fi
1770 fi
1771
1772 dnl GConf has been tested under GNU/Linux only.
1773 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1774 HAVE_GCONF=no
1775 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1776    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1777    if test "$HAVE_GCONF" = yes; then
1778       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1779       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1780       AC_CHECK_FUNCS([g_type_init])
1781    fi
1782 fi
1783
1784 dnl Do not put whitespace before the #include statements below.
1785 dnl Older compilers (eg sunos4 cc) choke on it.
1786 HAVE_XAW3D=no
1787 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1788   if test "$with_xaw3d" != no; then
1789     AC_MSG_CHECKING(for xaw3d)
1790     AC_CACHE_VAL(emacs_cv_xaw3d,
1791     [AC_TRY_LINK([
1792 #include <X11/Intrinsic.h>
1793 #include <X11/Xaw3d/Simple.h>],
1794       [],
1795       emacs_cv_xaw3d=yes,
1796       emacs_cv_xaw3d=no)])
1797   else
1798     emacs_cv_xaw3d=no
1799   fi
1800   if test $emacs_cv_xaw3d = yes; then
1801     AC_MSG_RESULT([yes; using Lucid toolkit])
1802     USE_X_TOOLKIT=LUCID
1803     HAVE_XAW3D=yes
1804     AC_DEFINE(HAVE_XAW3D, 1,
1805               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1806   else
1807     AC_MSG_RESULT(no)
1808     AC_MSG_CHECKING(for libXaw)
1809     AC_CACHE_VAL(emacs_cv_xaw,
1810     [AC_TRY_LINK([
1811 #include <X11/Intrinsic.h>
1812 #include <X11/Xaw/Simple.h>],
1813       [],
1814       emacs_cv_xaw=yes,
1815       emacs_cv_xaw=no)])
1816     if test $emacs_cv_xaw = yes; then
1817       AC_MSG_RESULT([yes; using Lucid toolkit])
1818       USE_X_TOOLKIT=LUCID
1819     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1820       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1821     else
1822       AC_MSG_RESULT([no; do not use toolkit by default])
1823       USE_X_TOOLKIT=none
1824     fi
1825   fi
1826 fi
1827
1828 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1829
1830 if test "${USE_X_TOOLKIT}" != "none"; then
1831   AC_MSG_CHECKING(X11 toolkit version)
1832   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1833   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1834 [#if XtSpecificationRelease < 6
1835 fail;
1836 #endif
1837 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1838   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1839   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1840     AC_MSG_RESULT(6 or newer)
1841     AC_DEFINE(HAVE_X11XTR6, 1,
1842               [Define to 1 if you have the X11R6 or newer version of Xt.])
1843   else
1844     AC_MSG_RESULT(before 6)
1845   fi
1846
1847 dnl If using toolkit, check whether libXmu.a exists.
1848 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1849   OLDLIBS="$LIBS"
1850   if test x$HAVE_X11XTR6 = xyes; then
1851     LIBS="-lXt -lSM -lICE $LIBS"
1852   else
1853     LIBS="-lXt $LIBS"
1854   fi
1855   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1856   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1857 fi
1858
1859 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1860 if test "${HAVE_X11}" = "yes"; then
1861   if test "${USE_X_TOOLKIT}" != "none"; then
1862     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1863   fi
1864 fi
1865
1866 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1867   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1868   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1869     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1870 int x = 5;
1871 #else
1872 Motif version prior to 2.1.
1873 #endif],
1874     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1875   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1876   if test $emacs_cv_motif_version_2_1 = yes; then
1877     HAVE_LIBXP=no
1878     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1879               [Define to 1 if you have Motif 2.1 or newer.])
1880     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1881     if test ${HAVE_LIBXP} = yes; then
1882       AC_DEFINE(HAVE_LIBXP, 1,
1883                 [Define to 1 if you have the Xp library (-lXp).])
1884     fi
1885   else
1886     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1887     # We put this in CFLAGS temporarily to precede other -I options
1888     # that might be in CFLAGS temporarily.
1889     # We put this in CPPFLAGS where it precedes the other -I options.
1890     OLD_CPPFLAGS=$CPPFLAGS
1891     OLD_CFLAGS=$CFLAGS
1892     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1893     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1894     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1895       [int x = 5;],
1896       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1897     if test $emacs_cv_lesstif = yes; then
1898       # Make sure this -I option remains in CPPFLAGS after it is set
1899       # back to REAL_CPPFLAGS.
1900       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1901       # have those other -I options anyway.  Ultimately, having this
1902       # directory ultimately in CPPFLAGS will be enough.
1903       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1904       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1905     else
1906       CFLAGS=$OLD_CFLAGS
1907       CPPFLAGS=$OLD_CPPFLAGS
1908     fi
1909   fi
1910 fi
1911
1912 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1913 dnl using Motif or Xaw3d is available, and unless
1914 dnl --with-toolkit-scroll-bars=no was specified.
1915
1916 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1917             [Define to 1 if we should use toolkit scroll bars.])dnl
1918 USE_TOOLKIT_SCROLL_BARS=no
1919 if test "${with_toolkit_scroll_bars}" != "no"; then
1920   if test "${USE_X_TOOLKIT}" != "none"; then
1921     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1922       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1923       HAVE_XAW3D=no
1924       USE_TOOLKIT_SCROLL_BARS=yes
1925     elif test "${HAVE_XAW3D}" = "yes"; then
1926       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1927       USE_TOOLKIT_SCROLL_BARS=yes
1928     fi
1929   elif test "${HAVE_GTK}" = "yes"; then
1930     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1931     USE_TOOLKIT_SCROLL_BARS=yes
1932   elif test "${HAVE_NS}" = "yes"; then
1933     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1934     USE_TOOLKIT_SCROLL_BARS=yes
1935   fi
1936 fi
1937
1938 dnl See if XIM is available.
1939 AC_TRY_COMPILE([
1940           #include <X11/Xlib.h>
1941           #include <X11/Xresource.h>],
1942          [XIMProc  callback;],
1943          [HAVE_XIM=yes
1944          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1945          HAVE_XIM=no)
1946
1947 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1948
1949 if test "${with_xim}" != "no"; then
1950   AC_DEFINE(USE_XIM, 1,
1951             [Define to 1 if we should use XIM, if it is available.])
1952 fi
1953
1954
1955 if test "${HAVE_XIM}" != "no"; then
1956   late_CFLAGS=$CFLAGS
1957   if test "$GCC" = yes; then
1958     CFLAGS="$CFLAGS --pedantic-errors"
1959   fi
1960   AC_TRY_COMPILE([
1961 #include <X11/Xlib.h>
1962 #include <X11/Xresource.h>],
1963 [Display *display;
1964 XrmDatabase db;
1965 char *res_name;
1966 char *res_class;
1967 XIMProc  callback;
1968 XPointer *client_data;
1969 #ifndef __GNUC__
1970 /* If we're not using GCC, it's probably not XFree86, and this is
1971    probably right, but we can't use something like --pedantic-errors.  */
1972 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1973                                            char*, XIMProc, XPointer*);
1974 #endif
1975 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1976    client_data);],
1977     [emacs_cv_arg6_star=yes])
1978   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1979          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1980 either XPointer or XPointer*.])dnl
1981   if test "$emacs_cv_arg6_star" = yes; then
1982     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1983   else
1984     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1985   fi
1986   CFLAGS=$late_CFLAGS
1987 fi
1988
1989 ### Start of font-backend (under any platform) section.
1990 # (nothing here yet -- this is a placeholder)
1991 ### End of font-backend (under any platform) section.
1992
1993 ### Start of font-backend (under X11) section.
1994 if test "${HAVE_X11}" = "yes"; then
1995    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1996
1997    ## Use -lXft if available, unless `--with-xft=no'.
1998    HAVE_XFT=maybe
1999     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2000       with_xft="no";
2001     fi
2002     if test "x${with_xft}" != "xno"; then
2003
2004       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2005       ## Because xftfont.c uses XRenderQueryExtension, we also
2006       ## need to link to -lXrender.
2007       HAVE_XRENDER=no
2008       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2009       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2010         OLD_CPPFLAGS="$CPPFLAGS"
2011         OLD_CFLAGS="$CFLAGS"
2012         OLD_LIBS="$LIBS"
2013         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2014         CFLAGS="$CFLAGS $XFT_CFLAGS"
2015         XFT_LIBS="-lXrender $XFT_LIBS"
2016         LIBS="$XFT_LIBS $LIBS"
2017         AC_CHECK_HEADER(X11/Xft/Xft.h,
2018           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2019
2020         if test "${HAVE_XFT}" = "yes"; then
2021           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2022             AC_SUBST(XFT_LIBS)
2023           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2024         else
2025           CPPFLAGS="$OLD_CPPFLAGS"
2026           CFLAGS="$OLD_CFLAGS"
2027           LIBS="$OLD_LIBS"
2028         fi                        # "${HAVE_XFT}" = "yes"
2029       fi                          # "$HAVE_XFT" != no
2030     fi                            # "x${with_xft}" != "xno"
2031
2032     dnl For the "Does Emacs use" message at the end.
2033     if test "$HAVE_XFT" != "yes"; then
2034        HAVE_XFT=no
2035     fi
2036
2037
2038     HAVE_FREETYPE=no
2039     ## We used to allow building with FreeType and without Xft.
2040     ## However, the ftx font backend driver is not in good shape.
2041     if test "${HAVE_XFT}" = "yes"; then
2042       dnl As we use Xft, we anyway use freetype.
2043       dnl There's no need for additional CFLAGS and LIBS.
2044       HAVE_FREETYPE=yes
2045       FONTCONFIG_CFLAGS=
2046       FONTCONFIG_LIBS=
2047     fi
2048
2049     HAVE_LIBOTF=no
2050     if test "${HAVE_FREETYPE}" = "yes"; then
2051       AC_DEFINE(HAVE_FREETYPE, 1,
2052                 [Define to 1 if using the freetype and fontconfig libraries.])
2053       if test "${with_libotf}" != "no"; then
2054         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2055                           HAVE_LIBOTF=no)
2056         if test "$HAVE_LIBOTF" = "yes"; then
2057           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2058           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2059                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2060                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2061           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2062             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2063                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2064           fi
2065         fi
2066       fi
2067     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2068     dnl Does the new font backend require it, or can it work without it?
2069     fi
2070
2071     HAVE_M17N_FLT=no
2072     if test "${HAVE_LIBOTF}" = yes; then
2073       if test "${with_m17n_flt}" != "no"; then
2074         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2075         if test "$HAVE_M17N_FLT" = "yes"; then
2076           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2077         fi
2078       fi
2079     fi
2080 else
2081     HAVE_XFT=no
2082     HAVE_FREETYPE=no
2083     HAVE_LIBOTF=no
2084     HAVE_M17N_FLT=no
2085 fi
2086 ### End of font-backend (under X11) section.
2087
2088 AC_SUBST(FREETYPE_CFLAGS)
2089 AC_SUBST(FREETYPE_LIBS)
2090 AC_SUBST(FONTCONFIG_CFLAGS)
2091 AC_SUBST(FONTCONFIG_LIBS)
2092 AC_SUBST(LIBOTF_CFLAGS)
2093 AC_SUBST(LIBOTF_LIBS)
2094 AC_SUBST(M17N_FLT_CFLAGS)
2095 AC_SUBST(M17N_FLT_LIBS)
2096
2097 ### Use -lXpm if available, unless `--with-xpm=no'.
2098 HAVE_XPM=no
2099 if test "${HAVE_X11}" = "yes"; then
2100   if test "${with_xpm}" != "no"; then
2101     AC_CHECK_HEADER(X11/xpm.h,
2102       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2103     if test "${HAVE_XPM}" = "yes"; then
2104       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2105       AC_EGREP_CPP(no_return_alloc_pixels,
2106       [#include "X11/xpm.h"
2107 #ifndef XpmReturnAllocPixels
2108 no_return_alloc_pixels
2109 #endif
2110       ], HAVE_XPM=no, HAVE_XPM=yes)
2111
2112       if test "${HAVE_XPM}" = "yes"; then
2113         AC_MSG_RESULT(yes)
2114       else
2115         AC_MSG_RESULT(no)
2116       fi
2117     fi
2118   fi
2119
2120   if test "${HAVE_XPM}" = "yes"; then
2121     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2122   fi
2123 fi
2124
2125 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2126 HAVE_JPEG=no
2127 if test "${HAVE_X11}" = "yes"; then
2128   if test "${with_jpeg}" != "no"; then
2129     dnl Checking for jpeglib.h can lose because of a redefinition of
2130     dnl  HAVE_STDLIB_H.
2131     AC_CHECK_HEADER(jerror.h,
2132       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2133   fi
2134
2135   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2136   if test "${HAVE_JPEG}" = "yes"; then
2137     AC_DEFINE(HAVE_JPEG)
2138     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2139         [#include <jpeglib.h>
2140          version=JPEG_LIB_VERSION
2141 ],
2142         [AC_DEFINE(HAVE_JPEG)],
2143         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2144         HAVE_JPEG=no])
2145   fi
2146 fi
2147
2148 ### Use -lpng if available, unless `--with-png=no'.
2149 HAVE_PNG=no
2150 if test "${HAVE_X11}" = "yes"; then
2151   if test "${with_png}" != "no"; then
2152     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2153     # in /usr/include/libpng.
2154     AC_CHECK_HEADERS(png.h libpng/png.h)
2155     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2156       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2157     fi
2158   fi
2159
2160   if test "${HAVE_PNG}" = "yes"; then
2161     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2162   fi
2163 fi
2164
2165 ### Use -ltiff if available, unless `--with-tiff=no'.
2166 HAVE_TIFF=no
2167 if test "${HAVE_X11}" = "yes"; then
2168   if test "${with_tiff}" != "no"; then
2169     AC_CHECK_HEADER(tiffio.h,
2170       [tifflibs="-lz -lm"
2171       # At least one tiff package requires the jpeg library.
2172       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2173       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2174   fi
2175
2176   if test "${HAVE_TIFF}" = "yes"; then
2177     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2178   fi
2179 fi
2180
2181 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2182 HAVE_GIF=no
2183 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2184   AC_CHECK_HEADER(gif_lib.h,
2185 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2186 # Earlier versions can crash Emacs.
2187     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2188
2189   if test "$HAVE_GIF" = yes; then
2190       ac_gif_lib_name="-lgif"
2191   fi
2192
2193 # If gif_lib.h but no libgif, try libungif.
2194   if test x"$try_libungif" = xyes; then
2195     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2196
2197     if test "$HAVE_GIF" = yes; then
2198       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2199       ac_gif_lib_name="-lungif"
2200     fi
2201   fi
2202
2203   if test "${HAVE_GIF}" = "yes"; then
2204     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2205   fi
2206 fi
2207
2208 dnl Check for required libraries.
2209 if test "${HAVE_X11}" = "yes"; then
2210   MISSING=""
2211   WITH_NO=""
2212   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2213     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2214   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2215     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2216   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2217     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2218   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2219     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2220   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2221     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2222
2223   if test "X${MISSING}" != X; then
2224     AC_MSG_ERROR([The following required libraries were not found:
2225     $MISSING
2226 Maybe some development libraries/packages are missing?
2227 If you don't want to link with them give
2228     $WITH_NO
2229 as options to configure])
2230   fi
2231 fi
2232
2233 ### Use -lgpm if available, unless `--with-gpm=no'.
2234 HAVE_GPM=no
2235 if test "${with_gpm}" != "no"; then
2236   AC_CHECK_HEADER(gpm.h,
2237     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2238 fi
2239
2240 if test "${HAVE_GPM}" = "yes"; then
2241   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2242 fi
2243
2244 dnl Check for malloc/malloc.h on darwin
2245 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2246
2247 ### Use NeXTstep API to implement GUI.
2248 if test "${HAVE_NS}" = "yes"; then
2249   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2250   if test "${NS_IMPL_COCOA}" = "yes"; then
2251     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2252     GNU_OBJC_CFLAGS=
2253   fi
2254   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2255     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2256     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2257   fi
2258   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2259     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2260   fi
2261   # We also have mouse menus.
2262   HAVE_MENUS=yes
2263   OTHER_FILES=ns-app
2264 fi
2265
2266
2267 ### Use session management (-lSM -lICE) if available
2268 HAVE_X_SM=no
2269 if test "${HAVE_X11}" = "yes"; then
2270   AC_CHECK_HEADER(X11/SM/SMlib.h,
2271     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2272
2273   if test "${HAVE_X_SM}" = "yes"; then
2274     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2275     case "$LIBS" in
2276       *-lSM*) ;;
2277       *)      LIBS="-lSM -lICE $LIBS" ;;
2278     esac
2279   fi
2280 fi
2281
2282 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2283 AC_CACHE_CHECK(whether netdb declares h_errno,
2284                emacs_cv_netdb_declares_h_errno,
2285 [AC_TRY_LINK([#include <netdb.h>],
2286   [return h_errno;],
2287   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2288 if test $emacs_cv_netdb_declares_h_errno = yes; then
2289   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2290 fi
2291
2292 AC_FUNC_ALLOCA
2293
2294 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2295 dnl FIXME is there an autoconf test that does the right thing, without
2296 dnl needing to call A_M_E afterwards?
2297 if test x"$ac_cv_func_alloca_works" != xyes; then
2298    AC_MSG_ERROR( [a system implementation of alloca is required] )
2299 fi
2300
2301 # fmod, logb, and frexp are found in -lm on most systems.
2302 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2303 AC_CHECK_LIB(m, sqrt)
2304
2305 # Check for mail-locking functions in a "mail" library.  Probably this should
2306 # have the same check as for liblockfile below.
2307 AC_CHECK_LIB(mail, maillock)
2308 dnl Debian, at least:
2309 AC_CHECK_LIB(lockfile, maillock)
2310 # If we have the shared liblockfile, assume we must use it for mail
2311 # locking (e.g. Debian).  If we couldn't link against liblockfile
2312 # (no liblockfile.a installed), ensure that we don't need to.
2313 if test "$ac_cv_lib_lockfile_maillock" = no; then
2314   dnl This works for files generally, not just executables.
2315   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2316   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2317                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2318   if test $ac_cv_prog_liblockfile = yes; then
2319     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2320 This probably means that movemail could lose mail.
2321 There may be a `development' package to install containing liblockfile.])
2322   else :
2323   fi
2324 fi
2325 AC_CHECK_FUNCS(touchlock)
2326 AC_CHECK_HEADERS(maillock.h)
2327
2328 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2329 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2330 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2331 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2332 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2333 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2334 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2335 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2336 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2337 cfmakeraw cfsetspeed)
2338
2339 AC_CHECK_HEADERS(sys/un.h)
2340
2341 AC_FUNC_MKTIME
2342 if test "$ac_cv_func_working_mktime" = no; then
2343   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2344 fi
2345
2346 AC_FUNC_GETLOADAVG
2347
2348 AC_FUNC_FSEEKO
2349
2350 # Configure getopt.
2351 m4_include([m4/getopt.m4])
2352 gl_GETOPT_IFELSE([
2353   gl_GETOPT_SUBSTITUTE_HEADER
2354   gl_PREREQ_GETOPT
2355   GETOPTOBJS='getopt.o getopt1.o'
2356 ])
2357 AC_SUBST(GETOPTOBJS)
2358
2359 AC_FUNC_GETPGRP
2360
2361 AC_FUNC_STRFTIME
2362
2363 # UNIX98 PTYs.
2364 AC_CHECK_FUNCS(grantpt)
2365
2366 # PTY-related GNU extensions.
2367 AC_CHECK_FUNCS(getpt)
2368
2369 # Check this now, so that we will NOT find the above functions in ncurses.
2370 # That is because we have not set up to link ncurses in lib-src.
2371 # It's better to believe a function is not available
2372 # than to expect to find it in ncurses.
2373 AC_CHECK_LIB(ncurses, tparm)
2374
2375 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2376
2377 resolv=no
2378 AC_TRY_LINK([#include <netinet/in.h>
2379 #include <arpa/nameser.h>
2380 #include <resolv.h>],
2381     [return res_init();],
2382     have_res_init=yes, have_res_init=no)
2383 if test "$have_res_init" = no; then
2384   OLIBS="$LIBS"
2385   LIBS="$LIBS -lresolv"
2386   AC_MSG_CHECKING(for res_init with -lresolv)
2387   AC_TRY_LINK([#include <netinet/in.h>
2388 #include <arpa/nameser.h>
2389 #include <resolv.h>],
2390     [return res_init();],
2391     have_res_init=yes, have_res_init=no)
2392   AC_MSG_RESULT($have_res_init)
2393   if test "$have_res_init" = yes ; then
2394     resolv=yes
2395   fi
2396   LIBS="$OLIBS"
2397 fi
2398
2399 if test "$have_res_init" = yes; then
2400   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2401 fi
2402
2403 # Do we need the Hesiod library to provide the support routines?
2404 if test "$with_hesiod" != no ; then
2405   # Don't set $LIBS here -- see comments above.
2406   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2407      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2408                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2409   if test "$resolv" = yes ; then
2410     RESOLVLIB=-lresolv
2411   else
2412     RESOLVLIB=
2413   fi
2414   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2415         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2416                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2417         :, $RESOLVLIB)])
2418 fi
2419
2420 # Do we need libresolv (due to res_init or Hesiod)?
2421 if test "$resolv" = yes ; then
2422   AC_DEFINE(HAVE_LIBRESOLV, 1,
2423             [Define to 1 if you have the resolv library (-lresolv).])
2424 fi
2425
2426 # These tell us which Kerberos-related libraries to use.
2427 if test "${with_kerberos}" != no; then
2428   AC_CHECK_LIB(com_err, com_err)
2429   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2430   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2431   AC_CHECK_LIB(krb5, krb5_init_context)
2432   if test "${with_kerberos5}" = no; then
2433     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2434                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2435     AC_CHECK_LIB(krb4, krb_get_cred,,
2436                  [AC_CHECK_LIB(krb, krb_get_cred)])
2437   fi
2438
2439   if test "${with_kerberos5}" != no; then
2440     AC_CHECK_HEADERS(krb5.h,
2441       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2442                         [#include <krb5.h>])])
2443   else
2444     AC_CHECK_HEADERS(des.h,,
2445                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2446                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2447     AC_CHECK_HEADERS(krb.h,,
2448                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2449                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2450   fi
2451   AC_CHECK_HEADERS(com_err.h)
2452 fi
2453
2454 # Solaris requires -lintl if you want strerror (which calls dgettext)
2455 # to return localized messages.
2456 AC_CHECK_LIB(intl, dgettext)
2457
2458 AC_MSG_CHECKING(whether localtime caches TZ)
2459 AC_CACHE_VAL(emacs_cv_localtime_cache,
2460 [if test x$ac_cv_func_tzset = xyes; then
2461 AC_TRY_RUN([#include <time.h>
2462 extern char **environ;
2463 unset_TZ ()
2464 {
2465   char **from, **to;
2466   for (to = from = environ; (*to = *from); from++)
2467     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2468       to++;
2469 }
2470 char TZ_GMT0[] = "TZ=GMT0";
2471 char TZ_PST8[] = "TZ=PST8";
2472 main()
2473 {
2474   time_t now = time ((time_t *) 0);
2475   int hour_GMT0, hour_unset;
2476   if (putenv (TZ_GMT0) != 0)
2477     exit (1);
2478   hour_GMT0 = localtime (&now)->tm_hour;
2479   unset_TZ ();
2480   hour_unset = localtime (&now)->tm_hour;
2481   if (putenv (TZ_PST8) != 0)
2482     exit (1);
2483   if (localtime (&now)->tm_hour == hour_GMT0)
2484     exit (1);
2485   unset_TZ ();
2486   if (localtime (&now)->tm_hour != hour_unset)
2487     exit (1);
2488   exit (0);
2489 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2490 [# If we have tzset, assume the worst when cross-compiling.
2491 emacs_cv_localtime_cache=yes])
2492 else
2493         # If we lack tzset, report that localtime does not cache TZ,
2494         # since we can't invalidate the cache if we don't have tzset.
2495         emacs_cv_localtime_cache=no
2496 fi])dnl
2497 AC_MSG_RESULT($emacs_cv_localtime_cache)
2498 if test $emacs_cv_localtime_cache = yes; then
2499   AC_DEFINE(LOCALTIME_CACHE, 1,
2500             [Define to 1 if localtime caches TZ.])
2501 fi
2502
2503 if test "x$HAVE_TIMEVAL" = xyes; then
2504   AC_CHECK_FUNCS(gettimeofday)
2505   if test $ac_cv_func_gettimeofday = yes; then
2506     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2507                    emacs_cv_gettimeofday_two_arguments,
2508     [AC_TRY_COMPILE([
2509 #ifdef TIME_WITH_SYS_TIME
2510 #include <sys/time.h>
2511 #include <time.h>
2512 #else
2513 #ifdef HAVE_SYS_TIME_H
2514 #include <sys/time.h>
2515 #else
2516 #include <time.h>
2517 #endif
2518 #endif],
2519       [struct timeval time;
2520        gettimeofday (&time, 0);],
2521       emacs_cv_gettimeofday_two_arguments=yes,
2522       emacs_cv_gettimeofday_two_arguments=no)])
2523     if test $emacs_cv_gettimeofday_two_arguments = no; then
2524       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2525                 [Define to 1 if gettimeofday accepts only one argument.])
2526     fi
2527   fi
2528 fi
2529
2530 ok_so_far=yes
2531 AC_CHECK_FUNC(socket, , ok_so_far=no)
2532 if test $ok_so_far = yes; then
2533   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2534 fi
2535 if test $ok_so_far = yes; then
2536   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2537 fi
2538 if test $ok_so_far = yes; then
2539 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2540   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2541             [Define to 1 if you have inet sockets.])
2542 fi
2543
2544 AC_CHECK_HEADERS(sys/ioctl.h)
2545
2546 if test -f /usr/lpp/X11/bin/smt.exp; then
2547   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2548             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2549 fi
2550
2551 AC_MSG_CHECKING(whether system supports dynamic ptys)
2552 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2553   AC_MSG_RESULT(yes)
2554   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2555 else
2556   AC_MSG_RESULT(no)
2557 fi
2558
2559 AC_FUNC_FORK
2560
2561 dnl Adapted from Haible's version.
2562 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2563   [AC_TRY_LINK([#include <langinfo.h>],
2564     [char* cs = nl_langinfo(CODESET);],
2565     emacs_cv_langinfo_codeset=yes,
2566     emacs_cv_langinfo_codeset=no)
2567   ])
2568 if test $emacs_cv_langinfo_codeset = yes; then
2569   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2570     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2571 fi
2572
2573 AC_CHECK_TYPES(size_t)
2574
2575 AC_TYPE_MBSTATE_T
2576
2577 dnl Restrict could probably be used effectively other than in regex.c.
2578 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2579   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2580                   emacs_cv_c_restrict=yes,
2581                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2582                                   emacs_cv_c_restrict=__restrict,
2583                                   emacs_cv_c_restrict=no)])])
2584 case "$emacs_cv_c_restrict" in
2585   yes) emacs_restrict=restrict;;
2586   no) emacs_restrict="";;
2587   *) emacs_restrict="$emacs_cv_c_restrict";;
2588 esac
2589 if test "$emacs_restrict" != __restrict; then
2590   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2591     [Define to compiler's equivalent of C99 restrict keyword.
2592      Don't define if equivalent is `__restrict'.])
2593 fi
2594
2595 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2596   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2597                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2598 if test "$emacs_cv_c_restrict_arr" = yes; then
2599   AC_DEFINE(__restrict_arr, __restrict,
2600     [Define to compiler's equivalent of C99 restrict keyword in array
2601      declarations.  Define as empty for no equivalent.])
2602 fi
2603
2604 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2605 dnl how the tty code is related to POSIX and/or other versions of termios.
2606 dnl The following looks like a useful start.
2607 dnl
2608 dnl AC_SYS_POSIX_TERMIOS
2609 dnl if test $ac_cv_sys_posix_termios = yes; then
2610 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2611 dnl                                and macros for terminal control.])
2612 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2613 dnl fi
2614
2615 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2616
2617 # Set up the CFLAGS for real compilation, so we can substitute it.
2618 CFLAGS="$REAL_CFLAGS"
2619 CPPFLAGS="$REAL_CPPFLAGS"
2620
2621 ## Hack to detect a buggy GCC version.
2622 if test "x$GCC" = xyes \
2623    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
2624    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
2625    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
2626    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
2627 fi
2628
2629 #### Find out which version of Emacs this is.
2630 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2631          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2632 if test x"${version}" = x; then
2633   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2634 fi
2635 if test x"${version}" != x"$PACKAGE_VERSION"; then
2636   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2637 fi
2638
2639 ### Specify what sort of things we'll be editing into Makefile and config.h.
2640 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2641 AC_SUBST(version)
2642 AC_SUBST(configuration)
2643 AC_SUBST(canonical)
2644 AC_SUBST(srcdir)
2645 AC_SUBST(prefix)
2646 AC_SUBST(exec_prefix)
2647 AC_SUBST(bindir)
2648 AC_SUBST(datadir)
2649 AC_SUBST(sharedstatedir)
2650 AC_SUBST(libexecdir)
2651 AC_SUBST(mandir)
2652 AC_SUBST(infodir)
2653 AC_SUBST(lispdir)
2654 AC_SUBST(locallisppath)
2655 AC_SUBST(lisppath)
2656 AC_SUBST(x_default_search_path)
2657 AC_SUBST(etcdir)
2658 AC_SUBST(archlibdir)
2659 AC_SUBST(docdir)
2660 AC_SUBST(bitmapdir)
2661 AC_SUBST(gamedir)
2662 AC_SUBST(gameuser)
2663 AC_SUBST(c_switch_system)
2664 AC_SUBST(c_switch_machine)
2665 AC_SUBST(LD_SWITCH_X_SITE)
2666 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2667 AC_SUBST(C_SWITCH_X_SITE)
2668 AC_SUBST(CFLAGS)
2669 AC_SUBST(X_TOOLKIT_TYPE)
2670 AC_SUBST(machfile)
2671 AC_SUBST(opsysfile)
2672 AC_SUBST(GETLOADAVG_LIBS)
2673 AC_SUBST(ns_appdir)
2674 AC_SUBST(ns_appbindir)
2675 AC_SUBST(ns_appresdir)
2676 AC_SUBST(ns_appsrc)
2677 AC_SUBST(GNUSTEP_MAKEFILES)
2678 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2679 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2680 AC_SUBST(GNU_OBJC_CFLAGS)
2681 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2682 AC_SUBST(OTHER_FILES)
2683
2684 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2685                    [Define to the canonical Emacs configuration name.])
2686 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2687                    [Define to the options passed to configure.])
2688 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2689                    [Define to the used machine dependent file.])
2690 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2691                    [Define to the used os dependent file.])
2692 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2693 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2694  may need to deal with X Windows.  For instance, if you've defined
2695  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2696  your loader can find on its own, you might want to add "-L/..." or
2697  something similar.])
2698 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2699                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2700                     in case it's needed (for Solaris, for example).])
2701 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2702 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2703  may need to deal with X Windows.  For instance, if you've defined
2704  HAVE_X_WINDOWS above and your X include files aren't in a place
2705  that your compiler can find on its own, you might want to add
2706  "-I/..." or something similar.])
2707 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2708                    [Define to the unexec source file name.])
2709
2710 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2711   AC_DEFINE(HAVE_X_WINDOWS, 1,
2712             [Define to 1 if you want to use the X window system.])
2713 fi
2714 if test "${USE_X_TOOLKIT}" != "none" ; then
2715   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2716   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2717     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2718   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2719     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2720   fi
2721 fi
2722 if test "${HAVE_X11}" = "yes" ; then
2723   AC_DEFINE(HAVE_X11, 1,
2724             [Define to 1 if you want to use version 11 of X windows.
2725              Otherwise, Emacs expects to use version 10.])
2726 fi
2727 if test "${HAVE_MENUS}" = "yes" ; then
2728   AC_DEFINE(HAVE_MENUS, 1,
2729             [Define to 1 if you have mouse menus.
2730              (This is automatic if you use X, but the option to specify it remains.)
2731              It is also defined with other window systems that support xmenu.c.])
2732 fi
2733 if test "${GNU_MALLOC}" = "yes" ; then
2734   AC_DEFINE(GNU_MALLOC, 1,
2735             [Define to 1 if you want to use the GNU memory allocator.])
2736 fi
2737 if test "${REL_ALLOC}" = "yes" ; then
2738   AC_DEFINE(REL_ALLOC, 1,
2739             [Define REL_ALLOC if you want to use the relocating allocator for
2740              buffer space.])
2741 fi
2742
2743
2744 AH_TOP([/* GNU Emacs site configuration template file.
2745    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2746      2006, 2007, 2008, 2009, 2010, 2011  Free Software Foundation, Inc.
2747
2748 This file is part of GNU Emacs.
2749
2750 GNU Emacs is free software: you can redistribute it and/or modify
2751 it under the terms of the GNU General Public License as published by
2752 the Free Software Foundation, either version 3 of the License, or
2753 (at your option) any later version.
2754
2755 GNU Emacs is distributed in the hope that it will be useful,
2756 but WITHOUT ANY WARRANTY; without even the implied warranty of
2757 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2758 GNU General Public License for more details.
2759
2760 You should have received a copy of the GNU General Public License
2761 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2762
2763
2764 /* No code in Emacs #includes config.h twice, but some bits of code
2765    intended to work with other packages as well (like gmalloc.c)
2766    think they can include it as many times as they like.  */
2767 #ifndef EMACS_CONFIG_H
2768 #define EMACS_CONFIG_H
2769 ])dnl
2770
2771 AH_BOTTOM([
2772 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2773 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2774 #define HAVE_WINDOW_SYSTEM
2775 #define HAVE_MOUSE
2776 #endif
2777
2778 /* Define AMPERSAND_FULL_NAME if you use the convention
2779    that & in the full name stands for the login id.  */
2780 /* Turned on June 1996 supposing nobody will mind it.  */
2781 #define AMPERSAND_FULL_NAME
2782
2783 /* Define HAVE_SOUND if we have sound support.  We know it works
2784    and compiles only on the specified platforms.   For others,
2785    it probably doesn't make sense to try.  */
2786
2787 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2788 #ifdef HAVE_MACHINE_SOUNDCARD_H
2789 #define HAVE_SOUND 1
2790 #endif
2791 #ifdef HAVE_SYS_SOUNDCARD_H
2792 #define HAVE_SOUND 1
2793 #endif
2794 #ifdef HAVE_SOUNDCARD_H
2795 #define HAVE_SOUND 1
2796 #endif
2797 #ifdef HAVE_ALSA
2798 #define HAVE_SOUND 1
2799 #endif
2800 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2801
2802 /* If using GNU, then support inline function declarations. */
2803 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2804    generally, because even if non-gcc compilers accept `inline', they
2805    may reject `extern inline'.  */
2806 #if defined (__GNUC__) && defined (OPTIMIZE)
2807 #define INLINE __inline__
2808 #else
2809 #define INLINE
2810 #endif
2811
2812 /* `subprocesses' should be defined if you want to
2813    have code for asynchronous subprocesses
2814    (as used in M-x compile and M-x shell).
2815    Only MSDOS does not support this (it overrides
2816    this in its config_opsysfile below).  */
2817
2818 #define subprocesses
2819
2820 /* Include the os and machine dependent files.  */
2821 #include config_opsysfile
2822 #include config_machfile
2823
2824 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2825   (There is probably a better place to do this, but right now the Cocoa
2826    side does this in s/darwin.h and we cannot
2827    parallel this exactly since GNUstep is multi-OS. */
2828 #ifdef HAVE_NS
2829 # ifdef NS_IMPL_GNUSTEP
2830 /* See also .m.o rule in Makefile.in */
2831 /* FIXME: are all these flags really needed?  Document here why.  */
2832 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2833 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2834 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2835 #  define SYSTEM_PURESIZE_EXTRA 30000
2836 # endif /* NS_IMPL_GNUSTEP */
2837 #endif /* HAVE_NS */
2838
2839 /* SIGTYPE is the macro we actually use.  */
2840 #ifndef SIGTYPE
2841 #define SIGTYPE RETSIGTYPE
2842 #endif
2843
2844 #ifdef emacs /* Don't do this for lib-src.  */
2845 /* Tell regex.c to use a type compatible with Emacs.  */
2846 #define RE_TRANSLATE_TYPE Lisp_Object
2847 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2848 #ifdef make_number
2849 /* If make_number is a macro, use it.  */
2850 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2851 #else
2852 /* If make_number is a function, avoid it.  */
2853 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2854 #endif
2855 #endif
2856
2857 /* Avoid link-time collision with system mktime if we will use our own.  */
2858 #if ! HAVE_MKTIME || BROKEN_MKTIME
2859 #define mktime emacs_mktime
2860 #endif
2861
2862 #define my_strftime nstrftime   /* for strftime.c */
2863
2864 /* The rest of the code currently tests the CPP symbol BSTRING.
2865    Override any claims made by the system-description files.
2866    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2867 #undef BSTRING
2868 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2869 #define BSTRING
2870 #endif
2871
2872 /* Some of the files of Emacs which are intended for use with other
2873    programs assume that if you have a config.h file, you must declare
2874    the type of getenv.
2875
2876    This declaration shouldn't appear when alloca.s or Makefile.in
2877    includes config.h.  */
2878 #ifndef NOT_C_CODE
2879 extern char *getenv ();
2880 #endif
2881
2882 /* These default definitions are good for almost all machines.
2883    The exceptions override them in m/MACHINE.h.  */
2884
2885 #ifndef BITS_PER_CHAR
2886 #define BITS_PER_CHAR 8
2887 #endif
2888
2889 #ifndef BITS_PER_SHORT
2890 #define BITS_PER_SHORT 16
2891 #endif
2892
2893 /* Note that lisp.h uses this in a preprocessor conditional, so it
2894    would not work to use sizeof.  That being so, we do all of them
2895    without sizeof, for uniformity's sake.  */
2896 #ifndef BITS_PER_INT
2897 #define BITS_PER_INT 32
2898 #endif
2899
2900 #ifndef BITS_PER_LONG
2901 #ifdef _LP64
2902 #define BITS_PER_LONG 64
2903 #else
2904 #define BITS_PER_LONG 32
2905 #endif
2906 #endif
2907
2908 /* Define if the compiler supports function prototypes.  It may do so
2909    but not define __STDC__ (e.g. DEC C by default) or may define it as
2910    zero.  */
2911 #undef PROTOTYPES
2912 /* For mktime.c:  */
2913 #ifndef __P
2914 # if defined PROTOTYPES
2915 #  define __P(args) args
2916 # else
2917 #  define __P(args) ()
2918 # endif  /* GCC.  */
2919 #endif /* __P */
2920
2921 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2922 #ifndef NOT_C_CODE
2923 #ifdef HAVE_STRING_H
2924 #include "string.h"
2925 #endif
2926 #ifdef HAVE_STRINGS_H
2927 #include "strings.h"  /* May be needed for bcopy & al. */
2928 #endif
2929 #ifdef HAVE_STDLIB_H
2930 #include <stdlib.h>
2931 #endif
2932 #ifdef HAVE_ALLOCA_H
2933 # include <alloca.h>
2934 #elif defined __GNUC__
2935 # define alloca __builtin_alloca
2936 #elif defined _AIX
2937 # define alloca __alloca
2938 #else
2939 # include <stddef.h>
2940 # ifdef  __cplusplus
2941 extern "C"
2942 # endif
2943 void *alloca (size_t);
2944 #endif
2945 #ifndef HAVE_SIZE_T
2946 typedef unsigned size_t;
2947 #endif
2948 #endif /* NOT_C_CODE */
2949
2950 /* Define HAVE_X_I18N if we have usable i18n support.  */
2951
2952 #ifdef HAVE_X11R6
2953 #define HAVE_X_I18N
2954 #elif !defined X11R5_INHIBIT_I18N
2955 #define HAVE_X_I18N
2956 #endif
2957
2958 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2959
2960 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2961 #define HAVE_X11R6_XIM
2962 #endif
2963
2964 #if defined __GNUC__ && (__GNUC__ > 2 \
2965                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2966 #define NO_RETURN       __attribute__ ((__noreturn__))
2967 #else
2968 #define NO_RETURN       /* nothing */
2969 #endif
2970
2971 /* These won't be used automatically yet.  We also need to know, at least,
2972    that the stack is continuous.  */
2973 #ifdef __GNUC__
2974 #  ifndef GC_SETJMP_WORKS
2975   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2976      see NON_SAVING_SETJMP in the target descriptions.  */
2977   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2978      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2979      Fixme: Deal with SVR3.  */
2980 #    define GC_SETJMP_WORKS 1
2981 #  endif
2982 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2983 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2984 #  endif
2985 #endif
2986
2987 #ifndef HAVE_BCOPY
2988 #define bcopy(a,b,s) memcpy (b,a,s)
2989 #endif
2990 #ifndef HAVE_BZERO
2991 #define bzero(a,s) memset (a,0,s)
2992 #endif
2993 #ifndef HAVE_BCMP
2994 #define BCMP memcmp
2995 #endif
2996
2997 #endif /* EMACS_CONFIG_H */
2998
2999 /*
3000 Local Variables:
3001 mode: c
3002 End:
3003 */
3004 ])dnl
3005
3006 #### Report on what we decided to do.
3007 #### Report GTK as a toolkit, even if it doesn't use Xt.
3008 #### It makes printing result more understandable as using GTK sets
3009 #### toolkit_scroll_bars to yes by default.
3010 if test "${HAVE_GTK}" = "yes"; then
3011   USE_X_TOOLKIT=GTK
3012 fi
3013
3014 echo "
3015 Configured for \`${canonical}'.
3016
3017   Where should the build process find the source code?    ${srcdir}
3018   What operating system and machine description files should Emacs use?
3019         \`${opsysfile}' and \`${machfile}'
3020   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3021   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3022   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3023   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3024   What window system should Emacs use?                    ${window_system}
3025   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3026
3027 if test -n "${x_includes}"; then
3028 echo "  Where do we find X Windows header files?                ${x_includes}"
3029 else
3030 echo "  Where do we find X Windows header files?                Standard dirs"
3031 fi
3032 if test -n "${x_libraries}"; then
3033 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3034 else
3035 echo "  Where do we find X Windows libraries?                   Standard dirs"
3036 fi
3037
3038 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3039 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3040 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3041 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3042 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3043 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3044 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3045 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3046 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3047 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3048
3049 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3050 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3051 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3052 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3053
3054 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3055 echo
3056
3057 if test $USE_XASSERTS = yes; then
3058    echo "  Compiling with asserts turned on."
3059    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3060 fi
3061
3062 echo
3063
3064 if test "$HAVE_NS" = "yes"; then
3065    echo
3066    echo "You must run \"make install\" in order to test the built application.
3067 The installed application will go to nextstep/Emacs.app and can be
3068 run or moved from there."
3069    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3070       echo "The application will be fully self-contained."
3071     else
3072       echo "The lisp resources for the application will be installed under ${prefix}.
3073 You may need to run \"make install\" with sudo.  The application will fail
3074 to run if these resources are not installed."
3075    fi
3076    echo
3077 fi
3078
3079
3080 # Remove any trailing slashes in these variables.
3081 [test "${prefix}" != NONE &&
3082   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3083 test "${exec_prefix}" != NONE &&
3084   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3085
3086 # Now get this: Some word that is part of the ${srcdir} directory name
3087 # or the ${configuration} value might, just might, happen to be an
3088 # identifier like `sun4' or `i386' or something, and be predefined by
3089 # the C preprocessor to some helpful value like 1, or maybe the empty
3090 # string.  Needless to say consequent macro substitutions are less
3091 # than conducive to the makefile finding the correct directory.
3092 [cpp_undefs="`echo $srcdir $configuration $canonical unix |
3093   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3094   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3095
3096 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3097 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3098 ## from Makefile.c can correctly provide the arg `-traditional' to the
3099 ## C preprocessor.
3100
3101 AC_EGREP_CPP(yes..yes,
3102         [yes..yes],
3103         CPP_NEED_TRADITIONAL=no,
3104         CPP_NEED_TRADITIONAL=yes)
3105
3106 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3107         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3108         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3109         lwlib/Makefile lisp/Makefile leim/Makefile, [
3110
3111 ### Make the necessary directories, if they don't exist.
3112 for dir in etc lisp ; do
3113   test -d ${dir} || mkdir ${dir}
3114 done
3115
3116 # Build src/Makefile from ${srcdir}/src/Makefile.c
3117 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3118 # This must be done after src/config.h is built, since we rely on that file.
3119
3120 echo creating src/epaths.h
3121 ${MAKE-make} epaths-force
3122
3123 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3124 # `..' to `. .'  unless invoked with -traditional
3125
3126 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3127   CPPFLAGS="$CPPFLAGS -traditional"
3128 fi
3129
3130 echo creating lib-src/Makefile
3131 ( cd lib-src
3132   rm -f junk.c junk1.c junk2.c
3133   sed -e '/start of cpp stuff/q' \
3134       < Makefile.c > junk1.c
3135   sed -e '1,/start of cpp stuff/d'\
3136       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3137       < Makefile.c > junk.c
3138   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3139       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3140   cat junk1.c junk2.c > Makefile.new
3141   rm -f junk.c junk1.c junk2.c
3142   chmod 444 Makefile.new
3143   mv -f Makefile.new Makefile
3144 )
3145
3146 echo creating src/Makefile
3147 ( cd src
3148   rm -f junk.c junk1.c junk2.c
3149   sed -e '/start of cpp stuff/q' \
3150       < Makefile.c > junk1.c
3151   sed -e '1,/start of cpp stuff/d'\
3152       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3153       < Makefile.c > junk.c
3154   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3155       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3156   cat junk1.c junk2.c > Makefile.new
3157   rm -f junk.c junk1.c junk2.c
3158   chmod 444 Makefile.new
3159   mv -f Makefile.new Makefile
3160 )
3161
3162 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3163   echo creating src/.gdbinit
3164   echo source $srcdir/src/.gdbinit > src/.gdbinit
3165 fi
3166
3167 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3168
3169 m4_if(dnl       Do not change this comment
3170    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3171 )dnl