lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality
   2
   3 ;; Copyright (C) 1993-1994, 1997, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   6 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   7 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   8 ;; Keywords: dired extensions files
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra),
  29 ;; version 1.191, adapted for GNU Emacs.  See the `dired-x' info pages.
  30
  31 ;; USAGE: In your ~/.emacs,
  32 ;;
  33 ;; (add-hook 'dired-load-hook
  34 ;;           (lambda ()
  35 ;;                       (load "dired-x")
  36 ;;                       ;; Set global variables here.  For example:
  37 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  38 ;;                       ))
  39 ;; (add-hook 'dired-mode-hook
  40 ;;           (lambda ()
  41 ;;                       ;; Set buffer-local variables here.  For example:
  42 ;;                       ;; (dired-omit-mode 1)
  43 ;;                       ))
  44 ;;
  45 ;; At load time dired-x.el will install itself and bind some dired keys.
  46 ;; Some dired.el and dired-aux.el functions have extra features if
  47 ;; dired-x is loaded.
  48
  49 ;; User customization: M-x customize-group RET dired-x RET.
  50
  51 ;; *Please* see the `dired-x' info pages for more details.
  52
  53 \f
  54 ;;; Code:
  55
  56 ;; This is a no-op if dired-x is being loaded via `dired-load-hook',
  57 ;; but maybe not if a dired-x function is being autoloaded.
  58 (require 'dired)
  59
  60 ;;; User-defined variables.
  61
  62 (defgroup dired-x nil
  63   "Extended directory editing (dired-x)."
  64   :group 'dired)
  65
  66 (defgroup dired-keys nil
  67   "Dired keys customizations."
  68   :prefix "dired-"
  69   :group 'dired-x)
  70
  71 (defcustom dired-bind-vm nil
  72   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
  73 RMAIL files in the old Babyl format (used before before Emacs 23.1)
  74 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
  75 will run `rmail' on these files.  New RMAIL files use the standard
  76 mbox format, and so cannot be distinguished in this way."
  77   :type 'boolean
  78   :group 'dired-keys)
  79
  80 (defcustom dired-bind-jump t
  81   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not.
  82 Setting this variable directly after dired-x is loaded has no effect -
  83 use \\[customize]."
  84   :type 'boolean
  85   :set (lambda (sym val)
  86          (if (set sym val)
  87              (progn
  88                (define-key global-map "\C-x\C-j" 'dired-jump)
  89                (define-key global-map "\C-x4\C-j" 'dired-jump-other-window))
  90            (if (eq 'dired-jump (lookup-key global-map "\C-x\C-j"))
  91                (define-key global-map "\C-x\C-j" nil))
  92            (if (eq 'dired-jump-other-window (lookup-key global-map "\C-x4\C-j"))
  93                (define-key global-map "\C-x4\C-j" nil))))
  94   :group 'dired-keys)
  95
  96 (defcustom dired-bind-man t
  97   "Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not.
  98 Setting this variable directly after dired-x is loaded has no effect -
  99 use \\[customize]."
 100   :type 'boolean
 101   :set (lambda (sym val)
 102          (if (set sym val)
 103              (define-key dired-mode-map "N" 'dired-man)
 104            (if (eq 'dired-man (lookup-key dired-mode-map "N"))
 105                (define-key dired-mode-map "N" nil))))
 106   :group 'dired-keys)
 107
 108 (defcustom dired-bind-info t
 109   "Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not.
 110 Setting this variable directly after dired-x is loaded has no effect -
 111 use \\[customize]."
 112   :type 'boolean
 113   :set (lambda (sym val)
 114          (if (set sym val)
 115              (define-key dired-mode-map "I" 'dired-info)
 116            (if (eq 'dired-info (lookup-key dired-mode-map "I"))
 117                (define-key dired-mode-map "I" nil))))
 118   :group 'dired-keys)
 119
 120 (defcustom dired-vm-read-only-folders nil
 121   "If non-nil, \\[dired-vm] will visit all folders read-only.
 122 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 123 files not writable by you are visited read-only."
 124   :type '(choice (const :tag "off" nil)
 125                  (const :tag "on" t)
 126                  (other :tag "non-writable only" if-file-read-only))
 127   :group 'dired-x)
 128
 129 (define-minor-mode dired-omit-mode
 130   "Toggle Dired-Omit mode.
 131 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 132 otherwise.  Enabling and disabling is buffer-local.
 133 If enabled, \"uninteresting\" files are not listed.
 134 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 135 plus those ending with extensions in `dired-omit-extensions'.
 136
 137 To enable omitting in every Dired buffer, you can put in your ~/.emacs
 138
 139   (add-hook 'dired-mode-hook (lambda () (dired-omit-mode 1)))
 140
 141 See Info node `(dired-x) Omitting Variables' for more information."
 142   :group 'dired-x
 143   (if dired-omit-mode
 144       ;; This will mention how many lines were omitted:
 145       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 146     (revert-buffer)))
 147
 148 (put 'dired-omit-mode 'safe-local-variable 'booleanp)
 149
 150 ;; For backward compatibility
 151 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 152
 153 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 154   "Filenames matching this regexp will not be displayed.
 155 This only has effect when `dired-omit-mode' is t.  See interactive function
 156 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 157 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 158 files and lock files."
 159   :type 'regexp
 160   :group 'dired-x)
 161
 162 (defcustom dired-omit-verbose t
 163   "When non-nil, show messages when omitting files.
 164 When nil, don't show messages."
 165   :type 'boolean
 166   :group 'dired-x)
 167
 168 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 169   "If non-nil, Dired always finds a directory in a buffer of its own.
 170 If nil, Dired finds the directory as a subdirectory in some other buffer
 171 if it is present as one.
 172
 173 If there are several dired buffers for a directory, the most recently
 174 used is chosen.
 175
 176 Dired avoids switching to the current buffer, so that if you have
 177 a normal and a wildcard buffer for the same directory, \\[dired] will
 178 toggle between those two."
 179   :type 'boolean
 180   :group 'dired-x)
 181
 182 (defcustom dired-omit-size-limit 30000
 183   "Maximum size for the \"omitting\" feature.
 184 If nil, there is no maximum size."
 185   :type '(choice (const :tag "no maximum" nil) integer)
 186   :group 'dired-x)
 187
 188 (defcustom dired-enable-local-variables t
 189   "Control use of local-variables lists in Dired.
 190 This temporarily overrides the value of `enable-local-variables' when
 191 listing a directory.  See also `dired-local-variables-file'."
 192   :risky t
 193   :type '(choice (const :tag "Query Unsafe" t)
 194                  (const :tag "Safe Only" :safe)
 195                  (const :tag "Do all" :all)
 196                  (const :tag "Ignore" nil)
 197                  (other :tag "Query" other))
 198   :group 'dired-x)
 199
 200 (make-obsolete-variable 'dired-enable-local-variables
 201                         "use a standard `dir-locals-file' instead." "24.1")
 202
 203 (defcustom dired-guess-shell-gnutar
 204   (catch 'found
 205     (dolist (exe '("tar" "gtar"))
 206       (if (with-temp-buffer
 207             (ignore-errors (call-process exe nil t nil "--version"))
 208             (and (re-search-backward "GNU tar" nil t) t))
 209           (throw 'found exe))))
 210   "If non-nil, name of GNU tar executable.
 211 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 212 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 213 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 214   ;; Changed from system-type test to testing --version output.
 215   ;; Maybe test --help for -z instead?
 216   :version "24.1"
 217   :type '(choice (const :tag "Not GNU tar" nil)
 218                  (string :tag "Command name"))
 219   :group 'dired-x)
 220
 221 (defcustom dired-guess-shell-gzip-quiet t
 222   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 223   :type 'boolean
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-znew-switches nil
 227   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 228   :type '(choice (const :tag "None" nil)
 229                  (string :tag "Switches"))
 230   :group 'dired-x)
 231
 232 (defcustom dired-clean-up-buffers-too t
 233   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 234   :type 'boolean
 235   :group 'dired-x)
 236
 237 ;;; KEY BINDINGS.
 238
 239 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 240 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 241 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 242 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 243 (define-key dired-mode-map "*." 'dired-mark-extension)
 244 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 245 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 246 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 247 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 248 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 249 (define-key dired-mode-map "V" 'dired-do-run-mail)
 250
 251 ;;; MENU BINDINGS
 252
 253 (require 'easymenu)
 254
 255 (let ((menu (lookup-key dired-mode-map [menu-bar])))
 256   (easy-menu-add-item menu '("Operate")
 257                       ["Find Files" dired-do-find-marked-files
 258                        :help "Find current or marked files"]
 259                       "Shell Command...")
 260   (easy-menu-add-item menu '("Operate")
 261                       ["Relative Symlink to..." dired-do-relsymlink
 262                        :visible (fboundp 'make-symbolic-link)
 263                        :help "Make relative symbolic links for current or \
 264 marked files"]
 265                       "Hardlink to...")
 266   (easy-menu-add-item menu '("Mark")
 267                       ["Flag Extension..." dired-flag-extension
 268                        :help "Flag files with a certain extension for deletion"]
 269                       "Mark Executables")
 270   (easy-menu-add-item menu '("Mark")
 271                       ["Mark Extension..." dired-mark-extension
 272                        :help "Mark files with a certain extension"]
 273                       "Unmark All")
 274   (easy-menu-add-item menu '("Mark")
 275                       ["Mark Omitted" dired-mark-omitted
 276                        :help "Mark files matching `dired-omit-files' \
 277 and `dired-omit-extensions'"]
 278                       "Unmark All")
 279   (easy-menu-add-item menu '("Regexp")
 280                       ["Relative Symlink..." dired-do-relsymlink-regexp
 281                        :visible (fboundp 'make-symbolic-link)
 282                        :help "Make relative symbolic links for files \
 283 matching regexp"]
 284                       "Hardlink...")
 285   (easy-menu-add-item menu '("Immediate")
 286                       ["Omit Mode" dired-omit-mode
 287                        :style toggle :selected dired-omit-mode
 288                        :help "Enable or disable omitting \"uninteresting\" \
 289 files"]
 290                       "Refresh"))
 291
 292 \f
 293 ;; Install into appropriate hooks.
 294
 295 (add-hook 'dired-mode-hook 'dired-extra-startup)
 296 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 297
 298 (defun dired-extra-startup ()
 299   "Automatically put on `dired-mode-hook' to get extra Dired features:
 300 \\<dired-mode-map>
 301   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 302   \\[dired-info]\t-- run info on file
 303   \\[dired-man]\t-- run man on file
 304   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 305   \\[dired-omit-mode]\t-- toggle omitting of files
 306   \\[dired-mark-sexp]\t-- mark by Lisp expression
 307
 308 To see the options you can set, use M-x customize-group RET dired-x RET.
 309 See also the functions:
 310   `dired-flag-extension'
 311   `dired-virtual'
 312   `dired-jump'
 313   `dired-man'
 314   `dired-vm'
 315   `dired-rmail'
 316   `dired-info'
 317   `dired-do-find-marked-files'"
 318   (interactive)
 319   ;; These must be done in each new dired buffer.
 320   (dired-hack-local-variables)
 321   (dired-omit-startup))
 322
 323 \f
 324 ;;; EXTENSION MARKING FUNCTIONS.
 325
 326 ;; Mark files with some extension.
 327 (defun dired-mark-extension (extension &optional marker-char)
 328   "Mark all files with a certain EXTENSION for use in later commands.
 329 A `.' is *not* automatically prepended to the string entered."
 330   ;; EXTENSION may also be a list of extensions instead of a single one.
 331   ;; Optional MARKER-CHAR is marker to use.
 332   (interactive "sMarking extension: \nP")
 333   (or (listp extension)
 334       (setq extension (list extension)))
 335   (dired-mark-files-regexp
 336    (concat ".";; don't match names with nothing but an extension
 337            "\\("
 338            (mapconcat 'regexp-quote extension "\\|")
 339            "\\)$")
 340    marker-char))
 341
 342 (defun dired-flag-extension (extension)
 343   "In dired, flag all files with a certain EXTENSION for deletion.
 344 A `.' is *not* automatically prepended to the string entered."
 345   (interactive "sFlagging extension: ")
 346   (dired-mark-extension extension dired-del-marker))
 347
 348 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 349
 350 (defvar dired-patch-unclean-extensions
 351   '(".rej" ".orig")
 352   "List of extensions of dispensable files created by the `patch' program.")
 353
 354 (defvar dired-tex-unclean-extensions
 355   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 356   "List of extensions of dispensable files created by TeX.")
 357
 358 (defvar dired-latex-unclean-extensions
 359   '(".idx" ".lof" ".lot" ".glo")
 360   "List of extensions of dispensable files created by LaTeX.")
 361
 362 (defvar dired-bibtex-unclean-extensions
 363   '(".blg" ".bbl")
 364   "List of extensions of dispensable files created by BibTeX.")
 365
 366 (defvar dired-texinfo-unclean-extensions
 367   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 368     ".tp" ".tps" ".vr" ".vrs")
 369   "List of extensions of dispensable files created by texinfo.")
 370
 371 (defun dired-clean-patch ()
 372   "Flag dispensable files created by patch for deletion.
 373 See variable `dired-patch-unclean-extensions'."
 374   (interactive)
 375   (dired-flag-extension dired-patch-unclean-extensions))
 376
 377 (defun dired-clean-tex ()
 378   "Flag dispensable files created by [La]TeX etc. for deletion.
 379 See variables `dired-tex-unclean-extensions',
 380 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 381 `dired-texinfo-unclean-extensions'."
 382   (interactive)
 383   (dired-flag-extension (append dired-texinfo-unclean-extensions
 384                                 dired-latex-unclean-extensions
 385                                 dired-bibtex-unclean-extensions
 386                                 dired-tex-unclean-extensions)))
 387
 388 (defun dired-very-clean-tex ()
 389   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 390 See variables `dired-texinfo-unclean-extensions',
 391 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 392 `dired-texinfo-unclean-extensions'."
 393   (interactive)
 394   (dired-flag-extension (append dired-texinfo-unclean-extensions
 395                                 dired-latex-unclean-extensions
 396                                 dired-bibtex-unclean-extensions
 397                                 dired-tex-unclean-extensions
 398                                 (list ".dvi"))))
 399 \f
 400 ;;; JUMP.
 401
 402 ;;;###autoload
 403 (defun dired-jump (&optional other-window file-name)
 404   "Jump to dired buffer corresponding to current buffer.
 405 If in a file, dired the current directory and move to file's line.
 406 If in Dired already, pop up a level and goto old directory's line.
 407 In case the proper dired file line cannot be found, refresh the dired
 408 buffer and try again.
 409 When OTHER-WINDOW is non-nil, jump to dired buffer in other window.
 410 Interactively with prefix argument, read FILE-NAME and
 411 move to its line in dired."
 412   (interactive
 413    (list nil (and current-prefix-arg
 414                   (read-file-name "Jump to dired file: "))))
 415   (let* ((file (or file-name buffer-file-name))
 416          (dir (if file (file-name-directory file) default-directory)))
 417     (if (and (eq major-mode 'dired-mode) (null file-name))
 418         (progn
 419           (setq dir (dired-current-directory))
 420           (dired-up-directory other-window)
 421           (unless (dired-goto-file dir)
 422               ;; refresh and try again
 423             (dired-insert-subdir (file-name-directory dir))
 424             (dired-goto-file dir)))
 425       (if other-window
 426           (dired-other-window dir)
 427         (dired dir))
 428       (if file
 429           (or (dired-goto-file file)
 430               ;; refresh and try again
 431               (progn
 432                 (dired-insert-subdir (file-name-directory file))
 433                 (dired-goto-file file))
 434               ;; Toggle omitting, if it is on, and try again.
 435               (when dired-omit-mode
 436                 (dired-omit-mode)
 437                 (dired-goto-file file)))))))
 438
 439 ;;;###autoload
 440 (defun dired-jump-other-window (&optional file-name)
 441   "Like \\[dired-jump] (`dired-jump') but in other window."
 442   (interactive
 443    (list (and current-prefix-arg
 444               (read-file-name "Jump to dired file: "))))
 445   (dired-jump t file-name))
 446 \f
 447 ;;; OMITTING.
 448
 449 ;; Enhanced omitting of lines from directory listings.
 450 ;; Marked files are never omitted.
 451
 452 ;; should probably get rid of this and always use 'no-dir.
 453 ;; sk 28-Aug-1991 09:37
 454 (defvar dired-omit-localp 'no-dir
 455   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 456 If it is `no-dir', omitting is much faster, but you can only match
 457 against the non-directory part of the file name.  Set it to nil if you
 458 need to match the entire file name.")
 459
 460 ;; \017=^O for Omit - other packages can chose other control characters.
 461 (defvar dired-omit-marker-char ?\017
 462   "Temporary marker used by Dired-Omit.
 463 Should never be used as marker by the user or other packages.")
 464
 465 (defun dired-omit-startup ()
 466   (or (assq 'dired-omit-mode minor-mode-alist)
 467       (setq minor-mode-alist
 468             (append '((dired-omit-mode
 469                        (:eval (if (eq major-mode 'dired-mode)
 470                                   " Omit" ""))))
 471                     minor-mode-alist))))
 472
 473 (defun dired-mark-omitted ()
 474   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 475   (interactive)
 476   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 477   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 478
 479 (defcustom dired-omit-extensions
 480   (append completion-ignored-extensions
 481           dired-latex-unclean-extensions
 482           dired-bibtex-unclean-extensions
 483           dired-texinfo-unclean-extensions)
 484   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 485 Defaults to elements of `completion-ignored-extensions',
 486 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 487 `dired-texinfo-unclean-extensions'.
 488
 489 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 490 variables `dired-omit-mode' and `dired-omit-files'."
 491   :type '(repeat string)
 492   :group 'dired-x)
 493
 494 (defun dired-omit-expunge (&optional regexp)
 495   "Erases all unmarked files matching REGEXP.
 496 Does nothing if global variable `dired-omit-mode' is nil, or if called
 497   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 498 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 499   filenames ending in `dired-omit-extensions'.
 500 If REGEXP is the empty string, this function is a no-op.
 501
 502 This functions works by temporarily binding `dired-marker-char' to
 503 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 504   (interactive "sOmit files (regexp): ")
 505   (if (and dired-omit-mode
 506            (or (called-interactively-p 'interactive)
 507                (not dired-omit-size-limit)
 508                (< (buffer-size) dired-omit-size-limit)
 509                (progn
 510                  (when dired-omit-verbose
 511                    (message "Not omitting: directory larger than %d characters."
 512                             dired-omit-size-limit))
 513                  (setq dired-omit-mode nil)
 514                  nil)))
 515       (let ((omit-re (or regexp (dired-omit-regexp)))
 516             (old-modified-p (buffer-modified-p))
 517             count)
 518         (or (string= omit-re "")
 519             (let ((dired-marker-char dired-omit-marker-char))
 520               (when dired-omit-verbose (message "Omitting..."))
 521               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 522                   (progn
 523                     (setq count (dired-do-kill-lines
 524                                  nil
 525                                  (if dired-omit-verbose "Omitted %d line%s." "")))
 526                     (force-mode-line-update))
 527                 (when dired-omit-verbose (message "(Nothing to omit)")))))
 528         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 529         ;; in mode-line of omitted buffers.
 530         (set-buffer-modified-p (and old-modified-p
 531                                     (save-excursion
 532                                       (goto-char (point-min))
 533                                       (re-search-forward dired-re-mark nil t))))
 534         count)))
 535
 536 (defun dired-omit-regexp ()
 537   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 538           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 539           (if dired-omit-extensions
 540               (concat ".";; a non-extension part should exist
 541                       "\\("
 542                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 543                       "\\)$")
 544             "")))
 545
 546 ;; Returns t if any work was done, nil otherwise.
 547 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 548   "Mark unmarked files matching REGEXP, displaying MSG.
 549 REGEXP is matched against the entire file name.
 550 Does not re-mark files which already have a mark.
 551 With prefix argument, unflag all those files.
 552 Optional fourth argument LOCALP is as in `dired-get-filename'."
 553   (interactive "P")
 554   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 555     (dired-mark-if
 556      (and
 557       ;; not already marked
 558       (looking-at " ")
 559       ;; uninteresting
 560       (let ((fn (dired-get-filename localp t)))
 561         (and fn (string-match regexp fn))))
 562      msg)))
 563
 564 \f
 565 ;;; VIRTUAL DIRED MODE.
 566
 567 ;; For browsing `ls -lR' listings in a dired-like fashion.
 568
 569 (defalias 'virtual-dired 'dired-virtual)
 570 (defun dired-virtual (dirname &optional switches)
 571   "Put this buffer into Virtual Dired mode.
 572
 573 In Virtual Dired mode, all commands that do not actually consult the
 574 filesystem will work.
 575
 576 This is useful if you want to peruse and move around in an ls -lR
 577 output file, for example one you got from an ftp server.  With
 578 ange-ftp, you can even dired a directory containing an ls-lR file,
 579 visit that file and turn on virtual dired mode.  But don't try to save
 580 this file, as dired-virtual indents the listing and thus changes the
 581 buffer.
 582
 583 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 584 resume it in a later session.
 585
 586 Type \\<dired-mode-map>\\[revert-buffer] \
 587 in the Virtual Dired buffer and answer `y' to convert
 588 the virtual to a real dired buffer again.  You don't have to do this, though:
 589 you can relist single subdirs using \\[dired-do-redisplay]."
 590
 591   ;; DIRNAME is the top level directory of the buffer.  It will become
 592   ;; its `default-directory'.  If nil, the old value of
 593   ;; default-directory is used.
 594
 595   ;; Optional SWITCHES are the ls switches to use.
 596
 597   ;; Shell wildcards will be used if there already is a `wildcard'
 598   ;; line in the buffer (thus it is a saved Dired buffer), but there
 599   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 600   ;; hand if you want them.
 601
 602   (interactive
 603    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 604   (goto-char (point-min))
 605   (or (looking-at "  ")
 606       ;; if not already indented, do it now:
 607       (indent-region (point-min) (point-max) 2))
 608   (or dirname (setq dirname default-directory))
 609   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 610   (setq default-directory dirname)      ; contains no wildcards
 611   (let ((wildcard (save-excursion
 612                     (goto-char (point-min))
 613                     (forward-line 1)
 614                     (and (looking-at "^  wildcard ")
 615                          (buffer-substring (match-end 0)
 616                                            (line-end-position))))))
 617   (if wildcard
 618         (setq dirname (expand-file-name wildcard default-directory))))
 619   ;; If raw ls listing (not a saved old dired buffer), give it a
 620   ;; decent subdir headerline:
 621   (goto-char (point-min))
 622   (or (looking-at dired-subdir-regexp)
 623       (insert "  "
 624               (directory-file-name (file-name-directory default-directory))
 625               ":\n"))
 626   (dired-mode dirname (or switches dired-listing-switches))
 627   (setq mode-name "Virtual Dired"
 628         revert-buffer-function 'dired-virtual-revert)
 629   (set (make-local-variable 'dired-subdir-alist) nil)
 630   (dired-build-subdir-alist)
 631   (goto-char (point-min))
 632   (dired-initial-position dirname))
 633
 634 (defun dired-virtual-guess-dir ()
 635   "Guess and return appropriate working directory of this buffer.
 636 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 637 based upon buffer contents.  If nothing could be guessed, returns
 638 nil."
 639
 640   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 641         (subexpr 2))
 642     (goto-char (point-min))
 643     (cond ((looking-at regexp)
 644            ;; If a saved dired buffer, look to which dir and
 645            ;; perhaps wildcard it belongs:
 646            (let ((dir (buffer-substring (match-beginning subexpr)
 647                                         (match-end subexpr))))
 648              (file-name-as-directory dir)))
 649           ;; Else no match for headerline found.  It's a raw ls listing.
 650           ;; In raw ls listings the directory does not have a headerline
 651           ;; try parent of first subdir, if any
 652           ((re-search-forward regexp nil t)
 653            (file-name-directory
 654             (directory-file-name
 655              (file-name-as-directory
 656               (buffer-substring (match-beginning subexpr)
 657                                 (match-end subexpr))))))
 658           (t                            ; if all else fails
 659            nil))))
 660
 661
 662 (defun dired-virtual-revert (&optional arg noconfirm)
 663   (if (not
 664        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 665       (error "Cannot revert a Virtual Dired buffer")
 666     (setq mode-name "Dired"
 667           revert-buffer-function 'dired-revert)
 668     (revert-buffer)))
 669
 670 ;; A zero-arg version of dired-virtual.
 671 (defun dired-virtual-mode ()
 672   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 673 Useful on `magic-mode-alist' with the regexp
 674
 675   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 676
 677 to put saved dired buffers automatically into Virtual Dired mode.
 678
 679 Also useful for `auto-mode-alist' like this:
 680
 681   (add-to-list 'auto-mode-alist
 682                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 683   (interactive)
 684   (dired-virtual (dired-virtual-guess-dir)))
 685
 686 \f
 687 ;;; SMART SHELL.
 688
 689 ;; An Emacs buffer can have but one working directory, stored in the
 690 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 691 ;; several subdirectories inserted, but still has but one working directory:
 692 ;; that of the top level Dired directory in that buffer.  For some commands
 693 ;; it is appropriate that they use the current Dired directory instead of
 694 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 695 ;; mechanism is provided for special handling of the working directory in
 696 ;; special major modes.
 697
 698 (define-obsolete-variable-alias 'default-directory-alist
 699   'dired-default-directory-alist "24.1")
 700
 701 ;; It's easier to add to this alist than redefine function
 702 ;; default-directory while keeping the old information.
 703 (defconst dired-default-directory-alist
 704   '((dired-mode . (if (fboundp 'dired-current-directory)
 705                       (dired-current-directory)
 706                     default-directory)))
 707   "Alist of major modes and their opinion on `default-directory'.
 708 Each element has the form (MAJOR . EXPRESSION).
 709 The function `dired-default-directory' evaluates EXPRESSION to
 710 determine a default directory.")
 711
 712 (put 'dired-default-directory-alist 'risky-local-variable t) ; gets eval'd
 713
 714 (defun dired-default-directory ()
 715   "Return the `dired-default-directory-alist' entry for the current major-mode.
 716 If none, return `default-directory'."
 717   (or (eval (cdr (assq major-mode dired-default-directory-alist)))
 718       default-directory))
 719
 720 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 721   "Like function `shell-command', but in the current Virtual Dired directory."
 722   (interactive
 723    (list
 724     (read-shell-command "Shell command: " nil nil
 725                         (cond
 726                          (buffer-file-name (file-relative-name buffer-file-name))
 727                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 728     current-prefix-arg
 729     shell-command-default-error-buffer))
 730   (let ((default-directory (dired-default-directory)))
 731     (shell-command command output-buffer error-buffer)))
 732
 733 \f
 734 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 735
 736 ;; Brief Description  (This feature is obsolete as of Emacs 24.1)
 737 ;;
 738 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 739 ;;
 740 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 741 ;;
 742 ;; * `dired-hack-local-variables' checks the value of
 743 ;;   `dired-local-variables-file'
 744 ;;
 745 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 746 ;;   filename found in the directory of the Dired Buffer being created.
 747 ;;
 748 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 749 ;;   include it in the Dired Buffer at the bottom.
 750 ;;
 751 ;; * Set `enable-local-variables' temporarily to the user variable
 752 ;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 753 ;;   Dired Buffer.
 754
 755 (defcustom dired-local-variables-file (convert-standard-filename ".dired")
 756   "Filename, as string, containing local dired buffer variables to be hacked.
 757 If this file found in current directory, then it will be inserted into dired
 758 buffer and `hack-local-variables' will be run.  See Info node
 759 `(emacs)File Variables' for more information on local variables.
 760 See also `dired-enable-local-variables'."
 761   :type 'file
 762   :group 'dired)
 763
 764 (make-obsolete-variable 'dired-local-variables-file 'dir-locals-file "24.1")
 765
 766 (defun dired-hack-local-variables ()
 767   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 768   (and (stringp dired-local-variables-file)
 769        (file-exists-p dired-local-variables-file)
 770        (let ((opoint (point-max))
 771              (inhibit-read-only t)
 772              ;; In case user has `enable-local-variables' set to nil we
 773              ;; override it locally with dired's variable.
 774              (enable-local-variables dired-enable-local-variables))
 775          ;; Insert 'em.
 776          (save-excursion
 777            (goto-char opoint)
 778            (insert "\^L\n")
 779            (insert-file-contents dired-local-variables-file))
 780          ;; Hack 'em.
 781          (unwind-protect
 782              (let ((buffer-file-name dired-local-variables-file))
 783                (hack-local-variables))
 784            ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 785            (delete-region opoint (point-max)))
 786          ;; Make sure that the modeline shows the proper information.
 787          (dired-sort-set-modeline))))
 788
 789 (make-obsolete 'dired-hack-local-variables
 790                'hack-dir-local-variables-non-file-buffer "24.1")
 791
 792 ;; Does not seem worth a dedicated command.
 793 ;; See the more general features in files-x.el.
 794 (defun dired-omit-here-always ()
 795   "Create `dir-locals-file' setting `dired-omit-mode' to t in `dired-mode'.
 796 If in a Dired buffer, reverts it."
 797   (interactive)
 798   (if (file-exists-p dired-local-variables-file)
 799       (error "Old-style dired-local-variables-file `./%s' found;
 800 replace it with a dir-locals-file `./%s'"
 801              dired-local-variables-file
 802              dir-locals-file))
 803   (if (file-exists-p dir-locals-file)
 804       (message "File `./%s' already exists." dir-locals-file)
 805     (with-temp-buffer
 806       (insert "\
 807 \((dired-mode . ((subdirs . nil)
 808                 (dired-omit-mode . t))))\n")
 809       (write-file dir-locals-file))
 810     ;; Run extra-hooks and revert directory.
 811     (when (derived-mode-p 'dired-mode)
 812       (hack-dir-local-variables-non-file-buffer)
 813       (dired-extra-startup)
 814       (dired-revert))))
 815
 816 (make-obsolete 'dired-omit-here-always 'add-dir-local-variable "24.1")
 817
 818 \f
 819 ;;; GUESS SHELL COMMAND.
 820
 821 ;; Brief Description:
 822 ;;;
 823 ;; * `dired-do-shell-command' is bound to `!' by dired.el.
 824 ;;;
 825 ;; * `dired-guess-shell-command' provides smarter defaults for
 826 ;;;    dired-aux.el's `dired-read-shell-command'.
 827 ;;;
 828 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 829 ;;;    marked files.
 830 ;;;
 831 ;; * Parse `dired-guess-shell-alist-user' and
 832 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 833 ;;;   that matches the first file in the file list.
 834 ;;;
 835 ;; * If the REGEXP matches all the entries of the file list then evaluate
 836 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 837 ;;;   string.  COMMAND may be a list of commands.
 838 ;;;
 839 ;; * Return this command to `dired-guess-shell-command' which prompts user
 840 ;;;   with it.  The list of commands is put into the list of default values.
 841 ;;;   If a command is used successfully then it is stored permanently in
 842 ;;;   `dired-shell-command-history'.
 843
 844 ;; Guess what shell command to apply to a file.
 845 (defvar dired-shell-command-history nil
 846   "History list for commands that read dired-shell commands.")
 847
 848 ;; Default list of shell commands.
 849
 850 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 851 ;; install GNU zip's version of zcat.
 852
 853 (declare-function Man-support-local-filenames "man" ())
 854
 855 (defvar dired-guess-shell-alist-default
 856   (list
 857    (list "\\.tar\\'"
 858          '(if dired-guess-shell-gnutar
 859               (concat dired-guess-shell-gnutar " xvf")
 860             "tar xvf")
 861          ;; Extract files into a separate subdirectory
 862          '(if dired-guess-shell-gnutar
 863               (concat "mkdir " (file-name-sans-extension file)
 864                       "; " dired-guess-shell-gnutar " -C "
 865                       (file-name-sans-extension file) " -xvf")
 866             (concat "mkdir " (file-name-sans-extension file)
 867                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 868          ;; List archive contents.
 869          '(if dired-guess-shell-gnutar
 870               (concat dired-guess-shell-gnutar " tvf")
 871             "tar tvf"))
 872
 873    ;; REGEXPS for compressed archives must come before the .Z rule to
 874    ;; be recognized:
 875    (list "\\.tar\\.Z\\'"
 876          ;; Untar it.
 877          '(if dired-guess-shell-gnutar
 878               (concat dired-guess-shell-gnutar " zxvf")
 879             (concat "zcat * | tar xvf -"))
 880          ;; Optional conversion to gzip format.
 881          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 882                   " " dired-guess-shell-znew-switches))
 883
 884    ;; gzip'ed archives
 885    (list "\\.t\\(ar\\.\\)?gz\\'"
 886          '(if dired-guess-shell-gnutar
 887               (concat dired-guess-shell-gnutar " zxvf")
 888             (concat "gunzip -qc * | tar xvf -"))
 889          ;; Extract files into a separate subdirectory
 890          '(if dired-guess-shell-gnutar
 891               (concat "mkdir " (file-name-sans-extension file)
 892                       "; " dired-guess-shell-gnutar " -C "
 893                       (file-name-sans-extension file) " -zxvf")
 894             (concat "mkdir " (file-name-sans-extension file)
 895                     "; gunzip -qc * | tar -C "
 896                     (file-name-sans-extension file) " -xvf -"))
 897          ;; Optional decompression.
 898          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 899          ;; List archive contents.
 900          '(if dired-guess-shell-gnutar
 901               (concat dired-guess-shell-gnutar " ztvf")
 902             (concat "gunzip -qc * | tar tvf -")))
 903
 904    ;; bzip2'ed archives
 905    (list "\\.t\\(ar\\.bz2\\|bz\\)\\'"
 906          "bunzip2 -c * | tar xvf -"
 907          ;; Extract files into a separate subdirectory
 908          '(concat "mkdir " (file-name-sans-extension file)
 909                   "; bunzip2 -c * | tar -C "
 910                   (file-name-sans-extension file) " -xvf -")
 911          ;; Optional decompression.
 912          "bunzip2")
 913
 914    ;; xz'ed archives
 915    (list "\\.t\\(ar\\.\\)?xz\\'"
 916          "unxz -c * | tar xvf -"
 917          ;; Extract files into a separate subdirectory
 918          '(concat "mkdir " (file-name-sans-extension file)
 919                   "; unxz -c * | tar -C "
 920                   (file-name-sans-extension file) " -xvf -")
 921          ;; Optional decompression.
 922          "unxz")
 923
 924    '("\\.shar\\.Z\\'" "zcat * | unshar")
 925    '("\\.shar\\.g?z\\'" "gunzip -qc * | unshar")
 926
 927    '("\\.e?ps\\'" "ghostview" "xloadimage" "lpr")
 928    (list "\\.e?ps\\.g?z\\'" "gunzip -qc * | ghostview -"
 929          ;; Optional decompression.
 930          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 931    (list "\\.e?ps\\.Z\\'" "zcat * | ghostview -"
 932          ;; Optional conversion to gzip format.
 933          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 934                   " " dired-guess-shell-znew-switches))
 935
 936    '("\\.patch\\'" "cat * | patch")
 937    (list "\\.patch\\.g?z\\'" "gunzip -qc * | patch"
 938          ;; Optional decompression.
 939          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 940    (list "\\.patch\\.Z\\'" "zcat * | patch"
 941          ;; Optional conversion to gzip format.
 942          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 943                   " " dired-guess-shell-znew-switches))
 944
 945    ;; The following four extensions are useful with dired-man ("N" key)
 946    (list "\\.\\(?:[0-9]\\|man\\)\\'" '(progn (require 'man)
 947                                            (if (Man-support-local-filenames)
 948                                                "man -l"
 949                                              "cat * | tbl | nroff -man -h")))
 950    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z\\'" '(progn (require 'man)
 951                                                  (if (Man-support-local-filenames)
 952                                                      "man -l"
 953                                                    "gunzip -qc * | tbl | nroff -man -h"))
 954          ;; Optional decompression.
 955          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 956    (list "\\.[0-9]\\.Z\\'" '(progn (require 'man)
 957                                  (if (Man-support-local-filenames)
 958                                      "man -l"
 959                                    "zcat * | tbl | nroff -man -h"))
 960          ;; Optional conversion to gzip format.
 961          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 962                   " " dired-guess-shell-znew-switches))
 963    '("\\.pod\\'" "perldoc" "pod2man * | nroff -man")
 964
 965    '("\\.dvi\\'" "xdvi" "dvips")                ; preview and printing
 966    '("\\.au\\'" "play")                 ; play Sun audiofiles
 967    '("\\.mpe?g\\'\\|\\.avi\\'" "xine -p")
 968    '("\\.ogg\\'" "ogg123")
 969    '("\\.mp3\\'" "mpg123")
 970    '("\\.wav\\'" "play")
 971    '("\\.uu\\'" "uudecode")             ; for uudecoded files
 972    '("\\.hqx\\'" "mcvert")
 973    '("\\.sh\\'" "sh")                   ; execute shell scripts
 974    '("\\.xbm\\'" "bitmap")              ; view X11 bitmaps
 975    '("\\.gp\\'" "gnuplot")
 976    '("\\.p[bgpn]m\\'" "xloadimage")
 977    '("\\.gif\\'" "xloadimage")          ; view gif pictures
 978    '("\\.tif\\'" "xloadimage")
 979    '("\\.png\\'" "display")             ; xloadimage 4.1 doesn't grok PNG
 980    '("\\.jpe?g\\'" "xloadimage")
 981    '("\\.fig\\'" "xfig")                        ; edit fig pictures
 982    '("\\.out\\'" "xgraph")              ; for plotting purposes.
 983    '("\\.tex\\'" "latex" "tex")
 984    '("\\.texi\\(nfo\\)?\\'" "makeinfo" "texi2dvi")
 985    '("\\.pdf\\'" "xpdf")
 986    '("\\.doc\\'" "antiword" "strings")
 987    '("\\.rpm\\'" "rpm -qilp" "rpm -ivh")
 988    '("\\.dia\\'" "dia")
 989    '("\\.mgp\\'" "mgp")
 990
 991    ;; Some other popular archivers.
 992    (list "\\.zip\\'" "unzip" "unzip -l"
 993          ;; Extract files into a separate subdirectory
 994          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
 995                   " -d " (file-name-sans-extension file)))
 996    '("\\.zoo\\'" "zoo x//")
 997    '("\\.lzh\\'" "lharc x")
 998    '("\\.arc\\'" "arc x")
 999    '("\\.shar\\'" "unshar")
1000    '("\\.rar\\'" "unrar x")
1001    '("\\.7z\\'" "7z x")
1002
1003    ;; Compression.
1004    (list "\\.g?z\\'" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1005    (list "\\.dz\\'" "dictunzip")
1006    (list "\\.bz2\\'" "bunzip2")
1007    (list "\\.xz\\'" "unxz")
1008    (list "\\.Z\\'" "uncompress"
1009          ;; Optional conversion to gzip format.
1010          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1011                   " " dired-guess-shell-znew-switches))
1012
1013    '("\\.sign?\\'" "gpg --verify"))
1014
1015   "Default alist used for shell command guessing.
1016 See `dired-guess-shell-alist-user'.")
1017
1018 (defcustom dired-guess-shell-alist-user nil
1019   "User-defined alist of rules for suggested commands.
1020 These rules take precedence over the predefined rules in the variable
1021 `dired-guess-shell-alist-default' (to which they are prepended).
1022
1023 Each element of this list looks like
1024
1025     \(REGEXP COMMAND...\)
1026
1027 where each COMMAND can either be a string or a Lisp expression that evaluates
1028 to a string.  If several COMMANDs are given, the first one will be the default
1029 and the rest will be added temporarily to the history and can be retrieved
1030 with \\[previous-history-element] (M-p) .
1031
1032 The variable `dired-guess-shell-case-fold-search' controls whether
1033 REGEXP is matched case-sensitively.
1034
1035 You can set this variable in your ~/.emacs.  For example, to add rules for
1036 `.foo' and `.bar' files, write
1037
1038  \(setq dired-guess-shell-alist-user
1039        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1040               ;; possibly more rules ...
1041               (list \"\\\\.bar\\\\'\";; rule with condition test
1042                     '(if condition
1043                           \"BAR-COMMAND-1\"
1044                         \"BAR-COMMAND-2\")))\)"
1045   :group 'dired-x
1046   :type '(alist :key-type regexp :value-type (repeat sexp)))
1047
1048 (defcustom dired-guess-shell-case-fold-search t
1049   "If non-nil, `dired-guess-shell-alist-default' and
1050 `dired-guess-shell-alist-user' are matched case-insensitively."
1051   :group 'dired-x
1052   :type 'boolean)
1053
1054 (defun dired-guess-default (files)
1055   "Guess a shell commands for FILES.  Return command or list of commands.
1056 See `dired-guess-shell-alist-user'."
1057
1058   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1059          ;; Prepend the user's alist to the default alist.
1060          (alist (append dired-guess-shell-alist-user
1061                         dired-guess-shell-alist-default))
1062          (file (car files))
1063          (flist (cdr files))
1064          elt regexp cmds)
1065
1066     ;; Find the first match in the alist for first file in FILES.
1067     (while alist
1068       (setq elt (car alist)
1069             regexp (car elt)
1070             alist (cdr alist))
1071       (if (string-match regexp file)
1072           (setq cmds (cdr elt)
1073                 alist nil)))
1074
1075     ;; If more than one file, see if all of FILES match regular expression.
1076     (while (and flist
1077                 (string-match regexp (car flist)))
1078       (setq flist (cdr flist)))
1079
1080     ;; If flist is still non-nil, then do not guess since this means that not
1081     ;; all the files in FILES were matched by the regexp.
1082     (setq cmds (and (not flist) cmds))
1083
1084     ;; Return commands or nil if flist is still non-nil.
1085     ;; Evaluate the commands in order that any logical testing will be done.
1086     (if (cdr cmds)
1087         (mapcar #'eval cmds)
1088       (eval (car cmds))))) ; single command
1089
1090 (defun dired-guess-shell-command (prompt files)
1091   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1092   (let ((default (dired-guess-default files))
1093         default-list val)
1094     (if (null default)
1095         ;; Nothing to guess
1096         (read-shell-command prompt nil 'dired-shell-command-history)
1097       (if (listp default)
1098           ;; More than one guess
1099           (setq default-list default
1100                 default (car default)
1101                 prompt (concat
1102                         prompt
1103                         (format "{%d guesses} " (length default-list))))
1104         ;; Just one guess
1105         (setq default-list (list default)))
1106       ;; Put the first guess in the prompt but not in the initial value.
1107       (setq prompt (concat prompt (format "[%s] " default)))
1108       ;; All guesses can be retrieved with M-n
1109       (setq val (read-shell-command prompt nil
1110                                     'dired-shell-command-history
1111                                     default-list))
1112       ;; If we got a return, then return default.
1113       (if (equal val "") default val))))
1114
1115 \f
1116 ;;; RELATIVE SYMBOLIC LINKS.
1117
1118 (declare-function make-symbolic-link "fileio.c")
1119
1120 (defvar dired-keep-marker-relsymlink ?S
1121   "See variable `dired-keep-marker-move'.")
1122
1123 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1124   "Make a symbolic link (pointing to FILE1) in FILE2.
1125 The link is relative (if possible), for example
1126
1127     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1128
1129 results in
1130
1131     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1132   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1133   (let (name1 name2 len1 len2 (index 0) sub)
1134     (setq file1 (expand-file-name file1)
1135           file2 (expand-file-name file2)
1136           len1 (length file1)
1137           len2 (length file2))
1138     ;; Find common initial file name components:
1139     (let (next)
1140       (while (and (setq next (string-match "/" file1 index))
1141                   (< (setq next (1+ next)) (min len1 len2))
1142                   ;; For the comparison, both substrings must end in
1143                   ;; `/', so NEXT is *one plus* the result of the
1144                   ;; string-match.
1145                   ;; E.g., consider the case of linking "/tmp/a/abc"
1146                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1147                   ;; of "/tmp/" as common initial component
1148                   (string-equal (substring file1 0 next)
1149                                 (substring file2 0 next)))
1150         (setq index next))
1151       (setq name2 file2
1152             sub (substring file1 0 index)
1153             name1 (substring file1 index)))
1154     (if (string-equal sub "/")
1155         ;; No common initial file name found
1156         (setq name1 file1)
1157       ;; Else they have a common parent directory
1158       (let ((tem (substring file2 index))
1159             (start 0)
1160             (count 0))
1161         ;; Count number of slashes we must compensate for ...
1162         (while (setq start (string-match "/" tem start))
1163           (setq count (1+ count)
1164                 start (1+ start)))
1165         ;; ... and prepend a "../" for each slash found:
1166         (dotimes (n count)
1167           (setq name1 (concat "../" name1)))))
1168     (make-symbolic-link
1169      (directory-file-name name1)        ; must not link to foo/
1170                                         ; (trailing slash!)
1171      name2 ok-if-already-exists)))
1172
1173 (autoload 'dired-do-create-files "dired-aux")
1174
1175 ;;;###autoload
1176 (defun dired-do-relsymlink (&optional arg)
1177    "Relative symlink all marked (or next ARG) files into a directory.
1178 Otherwise make a relative symbolic link to the current file.
1179 This creates relative symbolic links like
1180
1181     foo -> ../bar/foo
1182
1183 not absolute ones like
1184
1185     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1186
1187 For absolute symlinks, use \\[dired-do-symlink]."
1188   (interactive "P")
1189   (dired-do-create-files 'relsymlink #'dired-make-relative-symlink
1190                            "RelSymLink" arg dired-keep-marker-relsymlink))
1191
1192 (autoload 'dired-mark-read-regexp "dired-aux")
1193 (autoload 'dired-do-create-files-regexp "dired-aux")
1194
1195 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1196   "RelSymlink all marked files containing REGEXP to NEWNAME.
1197 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1198 for more info."
1199   (interactive (dired-mark-read-regexp "RelSymLink"))
1200   (dired-do-create-files-regexp
1201    #'dired-make-relative-symlink
1202    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1203
1204 \f
1205 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1206
1207 ;; Brief Description:
1208 ;;;
1209 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1210 ;;;
1211 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1212 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1213 ;;;
1214 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1215 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1216 ;;;
1217 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1218 ;;;   list each time.
1219 ;;;
1220 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1221 ;;;   element of FILE-LIST.
1222 ;;;
1223 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1224 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1225 ;;;   cognizant of the window-configuration.
1226 ;;;
1227 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1228 ;;;   of FILE-LIST giving each a window of height `size'.
1229
1230 (defun dired-do-find-marked-files (&optional noselect)
1231   "Find all marked files displaying all of them simultaneously.
1232 With optional NOSELECT just find files but do not select them.
1233
1234 The current window is split across all files marked, as evenly as possible.
1235 Remaining lines go to bottom-most window.  The number of files that can be
1236 displayed this way is restricted by the height of the current window and
1237 `window-min-height'.
1238
1239 To keep dired buffer displayed, type \\[split-window-vertically] first.
1240 To display just marked files, type \\[delete-other-windows] first."
1241   (interactive "P")
1242   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1243
1244 (defun dired-simultaneous-find-file (file-list noselect)
1245   "Visit all files in FILE-LIST and display them simultaneously.
1246 The current window is split across all files in FILE-LIST, as evenly as
1247 possible.  Remaining lines go to the bottom-most window.  The number of
1248 files that can be displayed this way is restricted by the height of the
1249 current window and the variable `window-min-height'.  With non-nil
1250 NOSELECT the files are merely found but not selected."
1251   ;; We don't make this function interactive because it is usually too clumsy
1252   ;; to specify FILE-LIST interactively unless via dired.
1253   (let (size)
1254     (if noselect
1255         ;; Do not select the buffer.
1256         (find-file-noselect (car file-list))
1257       ;; We will have to select the buffer.  Calculate and check window size.
1258       (setq size (/ (window-height) (length file-list)))
1259       (or (<= window-min-height size)
1260           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1261       (find-file (car file-list)))
1262     ;; Decrement.
1263     (dolist (file (cdr file-list))
1264       (if noselect
1265           ;; Do not select the buffer.
1266           (find-file-noselect file)
1267         ;; Vertically split off a window of desired size.  Upper window will
1268         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1269         (select-window (split-window nil size))
1270         (find-file file)))))
1271
1272 \f
1273 ;;; MISCELLANEOUS COMMANDS.
1274
1275 ;; Run man on files.
1276
1277 (declare-function Man-getpage-in-background "man" (topic))
1278
1279 (defun dired-man ()
1280   "Run `man' on this file."
1281 ;; Used also to say: "Display old buffer if buffer name matches filename."
1282 ;; but I have no idea what that means.
1283   (interactive)
1284   (require 'man)
1285   (let* ((file (dired-get-filename))
1286          (manual-program (replace-regexp-in-string "\\*" "%s"
1287                           (dired-guess-shell-command
1288                            "Man command: " (list file)))))
1289     (Man-getpage-in-background file)))
1290
1291 ;; Run Info on files.
1292
1293 (defun dired-info ()
1294   "Run `info' on this file."
1295   (interactive)
1296   (info (dired-get-filename)))
1297
1298 ;; Run mail on mail folders.
1299
1300 (declare-function vm-visit-folder "ext:vm" (folder &optional read-only))
1301 (defvar vm-folder-directory)
1302
1303 (defun dired-vm (&optional read-only)
1304   "Run VM on this file.
1305 With optional prefix argument, visits the folder read-only.
1306 Otherwise obeys the value of `dired-vm-read-only-folders'."
1307   (interactive "P")
1308   (let ((dir (dired-current-directory))
1309         (fil (dired-get-filename)))
1310     (vm-visit-folder fil (or read-only
1311                              (eq t dired-vm-read-only-folders)
1312                              (and dired-vm-read-only-folders
1313                                   (not (file-writable-p fil)))))
1314     ;; So that pressing `v' inside VM does prompt within current directory:
1315     (set (make-local-variable 'vm-folder-directory) dir)))
1316
1317 (defun dired-rmail ()
1318   "Run RMAIL on this file."
1319   (interactive)
1320   (rmail (dired-get-filename)))
1321
1322 (defun dired-do-run-mail ()
1323   "If `dired-bind-vm' is non-nil, call `dired-vm', else call `dired-rmail'."
1324   (interactive)
1325   (if dired-bind-vm
1326       ;; Read mail folder using vm.
1327       (dired-vm)
1328     ;; Read mail folder using rmail.
1329     (dired-rmail)))
1330
1331 \f
1332 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1333
1334 ;; This should be a builtin
1335 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1336   "Return t if BUFFER1 is more recently used than BUFFER2.
1337 Considers buffers closer to the car of `buffer-list' to be more recent."
1338   (and (not (equal buffer1 buffer2))
1339        (memq buffer1 (buffer-list))
1340        (not (memq buffer1 (memq buffer2 (buffer-list))))))
1341
1342 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1343 ;; (defun dired-buffers-for-dir-exact (dir)
1344 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1345 ;; ;; at top level, or as subdirectory.
1346 ;; ;; Top level matches must match the wildcard part too, if any.
1347 ;; ;; The list is in reverse order of buffer creation, most recent last.
1348 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1349 ;; ;; dired-buffers.
1350 ;;   (let ((alist dired-buffers) result elt)
1351 ;;     (while alist
1352 ;;       (setq elt (car alist)
1353 ;;             alist (cdr alist))
1354 ;;       (let ((buf (cdr elt)))
1355 ;;         (if (buffer-name buf)
1356 ;;             ;; Top level must match exactly against dired-directory in
1357 ;;             ;; case one of them is a wildcard.
1358 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1359 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1360 ;;                 (setq result (cons buf result)))
1361 ;;           ;; else buffer is killed - clean up:
1362 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1363 ;;     result))
1364
1365 \f
1366 ;; Does anyone use this? - lrd 6/29/93.
1367 ;; Apparently people do use it. - lrd 12/22/97.
1368 (defun dired-mark-sexp (predicate &optional unflag-p)
1369   "Mark files for which PREDICATE returns non-nil.
1370 With a prefix arg, unflag those files instead.
1371
1372 PREDICATE is a lisp expression that can refer to the following symbols:
1373
1374     inode  [integer] the inode of the file (only for ls -i output)
1375     s      [integer] the size of the file for ls -s output
1376                      (usually in blocks or, with -k, in KByte)
1377     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1378     nlink  [integer] number of links to file
1379     uid    [string]  owner
1380     gid    [string]  group  (If the gid is not displayed by ls,
1381                      this will still be set (to the same as uid))
1382     size   [integer] file size in bytes
1383     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1384     name   [string]  the name of the file
1385     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1386
1387 For example, use
1388
1389         (equal 0 size)
1390
1391 to mark all zero length files."
1392   ;; Using sym="" instead of nil avoids the trap of
1393   ;; (string-match "foo" sym) into which a user would soon fall.
1394   ;; Give `equal' instead of `=' in the example, as this works on
1395   ;; integers and strings.
1396   (interactive "xMark if (lisp expr): \nP")
1397   (message "%s" predicate)
1398   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1399         inode s mode nlink uid gid size time name sym)
1400     (dired-mark-if
1401      (save-excursion
1402        (and
1403         ;; Sets vars
1404         ;;                inode s mode nlink uid gid size time name sym
1405
1406         ;; according to current file line.  Returns t for success, nil if
1407         ;; there is no file line.  Upon success, all variables are set, either
1408         ;; to nil or the appropriate value, so they need not be initialized.
1409         ;; Moves point within the current line.
1410         (dired-move-to-filename)
1411         (let (pos
1412               (mode-len 10) ; length of mode string
1413               ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1414               (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1415           (beginning-of-line)
1416           (forward-char 2)
1417           (if (looking-at dired-re-inode-size)
1418               (progn
1419                 (goto-char (match-end 0))
1420                 (setq inode (string-to-number
1421                              (buffer-substring (match-beginning 1)
1422                                                (match-end 1)))
1423                       s (string-to-number
1424                          (buffer-substring (match-beginning 2)
1425                                            (match-end 2)))))
1426             (setq inode nil
1427                   s nil))
1428           (setq mode (buffer-substring (point) (+ mode-len (point))))
1429           (forward-char mode-len)
1430           (setq nlink (read (current-buffer)))
1431           ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1432           (setq uid (buffer-substring (1+ (point))
1433                                       (progn (forward-word 1) (point))))
1434           (re-search-forward directory-listing-before-filename-regexp)
1435           (goto-char (match-beginning 1))
1436           (forward-char -1)
1437           (setq size (string-to-number
1438                       (buffer-substring (save-excursion
1439                                           (backward-word 1)
1440                                           (setq pos (point)))
1441                                         (point))))
1442           (goto-char pos)
1443           (backward-word 1)
1444           ;; if no gid is displayed, gid will be set to uid
1445           ;; but user will then not reference it anyway in PREDICATE.
1446           (setq gid (buffer-substring (save-excursion
1447                                         (forward-word 1) (point))
1448                                       (point))
1449                 time (buffer-substring (match-beginning 1)
1450                                        (1- (dired-move-to-filename)))
1451                 name (buffer-substring (point)
1452                                        (or
1453                                         (dired-move-to-end-of-filename t)
1454                                         (point)))
1455                 sym (if (looking-at " -> ")
1456                         (buffer-substring (progn (forward-char 4) (point))
1457                                           (line-end-position))
1458                       ""))
1459           t)
1460         (eval predicate)))
1461      (format "'%s file" predicate))))
1462
1463 \f
1464 ;;; FIND FILE AT POINT.
1465
1466 (defcustom dired-x-hands-off-my-keys t
1467   "Non-nil means don't remap `find-file' to `dired-x-find-file'.
1468 Similarly for `find-file-other-window' and `dired-x-find-file-other-window'.
1469 If you change this variable without using \\[customize] after `dired-x.el'
1470 is loaded then call \\[dired-x-bind-find-file]."
1471   :type 'boolean
1472   :initialize 'custom-initialize-default
1473   :set (lambda (sym val)
1474          (set sym val)
1475          (dired-x-bind-find-file))
1476   :group 'dired-x)
1477
1478 (defun dired-x-bind-find-file ()
1479   "Bind `dired-x-find-file' in place of `find-file' (or vice-versa).
1480 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1481 Binding direction based on `dired-x-hands-off-my-keys'."
1482   (interactive)
1483   (if (called-interactively-p 'interactive)
1484       (setq dired-x-hands-off-my-keys
1485             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1486   (define-key (current-global-map) [remap find-file]
1487     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file))
1488   (define-key (current-global-map) [remap find-file-other-window]
1489     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file-other-window)))
1490
1491 ;; Now call it so binding is correct.  This could go in the :initialize
1492 ;; slot, but then dired-x-bind-find-file has to be defined before the
1493 ;; defcustom, and we get free variable warnings.
1494 (dired-x-bind-find-file)
1495
1496 (defun dired-x-find-file (filename)
1497   "Edit file FILENAME.
1498 Like `find-file', except that when called interactively with a
1499 prefix argument, it offers the filename near point as a default."
1500   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1501   (find-file filename))
1502
1503 (defun dired-x-find-file-other-window (filename)
1504   "Edit file FILENAME, in another window.
1505 Like `find-file-other-window', except that when called interactively with
1506 a prefix argument, when it offers the filename near point as a default."
1507   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1508   (find-file-other-window filename))
1509
1510 ;;; Internal functions.
1511
1512 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1513 (defun dired-filename-at-point ()
1514   "Return the filename closest to point, expanded.
1515 Point should be in or after a filename."
1516   (save-excursion
1517     ;; First see if just past a filename.
1518     (or (eobp)                             ; why?
1519         (when (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1520           (skip-chars-backward " \n\t\r({[]})")
1521           (or (bobp) (backward-char 1))))
1522     (let ((filename-chars "-.[:alnum:]_/:$+@")
1523           start prefix)
1524       (if (looking-at (format "[%s]" filename-chars))
1525           (progn
1526             (skip-chars-backward filename-chars)
1527             (setq start (point)
1528                   prefix
1529                   ;; This is something to do with ange-ftp filenames.
1530                   ;; It convert foo@bar to /foo@bar.
1531                   ;; But when does the former occur in dired buffers?
1532                   (and (string-match
1533                         "^\\w+@"
1534                         (buffer-substring start (line-end-position)))
1535                        "/"))
1536             (if (string-match "[/~]" (char-to-string (preceding-char)))
1537                 (setq start (1- start)))
1538             (skip-chars-forward filename-chars))
1539         (error "No file found around point!"))
1540       ;; Return string.
1541       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1542
1543 (defun dired-x-read-filename-at-point (prompt)
1544   "Return filename prompting with PROMPT with completion.
1545 If `current-prefix-arg' is non-nil, uses name at point as guess."
1546   (if current-prefix-arg
1547       (let ((guess (dired-filename-at-point)))
1548         (read-file-name prompt
1549                         (file-name-directory guess)
1550                         guess
1551                         nil (file-name-nondirectory guess)))
1552     (read-file-name prompt default-directory)))
1553
1554 (define-obsolete-function-alias 'read-filename-at-point
1555   'dired-x-read-filename-at-point "24.1") ; is this even needed?
1556 \f
1557 ;;; BUG REPORTS
1558
1559 (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1")
1560
1561 \f
1562 ;; As Barry Warsaw would say: "This might be useful..."
1563 (provide 'dired-x)
1564
1565 ;; Local Variables:
1566 ;; byte-compile-dynamic: t
1567 ;; generated-autoload-file: "dired.el"
1568 ;; End:
1569
1570 ;;; dired-x.el ends here