lisp/gnus/gnus-mh.el

   1 ;;; gnus-mh.el --- mh-e interface for Gnus
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Send mail using mh-e.
  30
  31 ;; The following mh-e interface is all cooperative works of
  32 ;; tanaka@flab.fujitsu.CO.JP (TANAKA Hiroshi), kawabe@sra.CO.JP
  33 ;; (Yoshikatsu Kawabe), and shingu@casund.cpr.canon.co.jp (Toshiaki
  34 ;; SHINGU).
  35
  36 ;;; Code:
  37
  38 (require 'gnus)
  39 (require 'mh-e)
  40 (require 'mh-comp)
  41 (require 'gnus-msg)
  42 (require 'gnus-sum)
  43
  44 (defvar mh-lib-progs)
  45
  46 (defun gnus-summary-save-article-folder (&optional arg)
  47   "Append the current article to an mh folder.
  48 If N is a positive number, save the N next articles.
  49 If N is a negative number, save the N previous articles.
  50 If N is nil and any articles have been marked with the process mark,
  51 save those articles instead."
  52   (interactive "P")
  53   (require 'gnus-art)
  54   (let ((gnus-default-article-saver 'gnus-summary-save-in-folder))
  55     (gnus-summary-save-article arg)))
  56
  57 (defun gnus-summary-save-in-folder (&optional folder)
  58   "Save this article to MH folder (using `rcvstore' in MH library).
  59 Optional argument FOLDER specifies folder name."
  60   ;; Thanks to yuki@flab.Fujitsu.JUNET and ohm@kaba.junet.
  61   (mh-find-path)
  62   (let ((folder
  63          (cond ((and (eq folder 'default)
  64                      gnus-newsgroup-last-folder)
  65                 gnus-newsgroup-last-folder)
  66                (folder folder)
  67                (t (mh-prompt-for-folder
  68                    "Save article in"
  69                    (funcall gnus-folder-save-name gnus-newsgroup-name
  70                             gnus-current-headers gnus-newsgroup-last-folder)
  71                    t))))
  72         (errbuf (gnus-get-buffer-create " *Gnus rcvstore*"))
  73         ;; Find the rcvstore program.
  74         (exec-path (cond
  75                     ((and (boundp 'mh-lib-progs) mh-lib-progs)
  76                      (cons mh-lib-progs exec-path))
  77                     (mh-lib (cons mh-lib exec-path))
  78                     (t exec-path))))
  79     (with-current-buffer gnus-original-article-buffer
  80       (save-restriction
  81         (widen)
  82         (unwind-protect
  83             (call-process-region
  84              (point-min) (point-max) "rcvstore" nil errbuf nil folder)
  85           (set-buffer errbuf)
  86           (if (zerop (buffer-size))
  87               (message "Article saved in folder: %s" folder)
  88             (message "%s" (buffer-string)))
  89           (kill-buffer errbuf))))
  90     (setq gnus-newsgroup-last-folder folder)))
  91
  92 (defun gnus-Folder-save-name (newsgroup headers &optional last-folder)
  93   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
  94 If variable `gnus-use-long-file-name' is nil, it is +News.group.
  95 Otherwise, it is like +news/group."
  96   (or last-folder
  97       (concat "+"
  98               (if gnus-use-long-file-name
  99                   (gnus-capitalize-newsgroup newsgroup)
 100                 (gnus-newsgroup-directory-form newsgroup)))))
 101
 102 (defun gnus-folder-save-name (newsgroup headers &optional last-folder)
 103   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
 104 If variable `gnus-use-long-file-name' is nil, it is +news.group.
 105 Otherwise, it is like +news/group."
 106   (or last-folder
 107       (concat "+"
 108               (if gnus-use-long-file-name
 109                   newsgroup
 110                 (gnus-newsgroup-directory-form newsgroup)))))
 111
 112 (provide 'gnus-mh)
 113
 114 ;;; arch-tag: 2d5696d3-b363-48e5-8749-c256be56acca
 115 ;;; gnus-mh.el ends here