lisp/gnus/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2
   3 ;; Copyright (C) 1988, 1989, 1990, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;      2000 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'nnheader)
  32 (require 'nntp)
  33 (require 'nnoo)
  34 (eval-when-compile (require 'cl))
  35
  36 (nnoo-declare nnspool)
  37
  38 (defvoo nnspool-inews-program news-inews-program
  39   "Program to post news.
  40 This is most commonly `inews' or `injnews'.")
  41
  42 (defvoo nnspool-inews-switches '("-h" "-S")
  43   "Switches for nnspool-request-post to pass to `inews' for posting news.
  44 If you are using Cnews, you probably should set this variable to nil.")
  45
  46 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  47   "Local news spool directory.")
  48
  49 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  50   "Local news nov directory.")
  51
  52 (defvoo nnspool-lib-dir "/usr/lib/news/"
  53   "Where the local news library files are stored.")
  54
  55 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  56   "Local news active file.")
  57
  58 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  59   "Local news newsgroups file.")
  60
  61 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  62   "Local news distributions file.")
  63
  64 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  65   "Local news history file.")
  66
  67 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  68   "Local news active date file.")
  69
  70 (defvoo nnspool-large-newsgroup 50
  71   "The number of the articles which indicates a large newsgroup.
  72 If the number of the articles is greater than the value, verbose
  73 messages will be shown to indicate the current status.")
  74
  75 (defvoo nnspool-nov-is-evil nil
  76   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  77
  78 (defconst nnspool-sift-nov-with-sed nil
  79   "If non-nil, use sed to get the relevant portion from the overview file.
  80 If nil, nnspool will load the entire file into a buffer and process it
  81 there.")
  82
  83 (defvoo nnspool-rejected-article-hook nil
  84   "*A hook that will be run when an article has been rejected by the server.")
  85
  86 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  87   "Coding system for nnspool.")
  88
  89 \f
  90
  91 (defconst nnspool-version "nnspool 2.0"
  92   "Version numbers of this version of NNSPOOL.")
  93
  94 (defvoo nnspool-current-directory nil
  95   "Current news group directory.")
  96
  97 (defvoo nnspool-current-group nil)
  98 (defvoo nnspool-status-string "")
  99
 100 \f
 101 ;;; Interface functions.
 102
 103 (nnoo-define-basics nnspool)
 104
 105 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 106   "Retrieve the headers of ARTICLES."
 107   (save-excursion
 108     (set-buffer nntp-server-buffer)
 109     (erase-buffer)
 110     (when (nnspool-possibly-change-directory group)
 111       (let* ((number (length articles))
 112              (count 0)
 113              (default-directory nnspool-current-directory)
 114              (do-message (and (numberp nnspool-large-newsgroup)
 115                               (> number nnspool-large-newsgroup)))
 116              (nnheader-file-coding-system nnspool-file-coding-system)
 117              file beg article ag)
 118         (if (and (numberp (car articles))
 119                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 120             ;; We successfully retrieved the NOV headers.
 121             'nov
 122           ;; No NOV headers here, so we do it the hard way.
 123           (while (setq article (pop articles))
 124             (if (stringp article)
 125                 ;; This is a Message-ID.
 126                 (setq ag (nnspool-find-id article)
 127                       file (and ag (nnspool-article-pathname
 128                                     (car ag) (cdr ag)))
 129                       article (cdr ag))
 130               ;; This is an article in the current group.
 131               (setq file (int-to-string article)))
 132             ;; Insert the head of the article.
 133             (when (and file
 134                        (file-exists-p file))
 135               (insert "221 ")
 136               (princ article (current-buffer))
 137               (insert " Article retrieved.\n")
 138               (setq beg (point))
 139               (inline (nnheader-insert-head file))
 140               (goto-char beg)
 141               (if (search-forward "\n\n" nil t)
 142                   (progn
 143                     (forward-char -1)
 144                     (insert ".\n"))
 145                 (goto-char (point-max))
 146                 (if (bolp)
 147                     (insert ".\n")
 148                   (insert "\n.\n")))
 149               (delete-region (point) (point-max)))
 150
 151             (and do-message
 152                  (zerop (% (incf count) 20))
 153                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 154                                    (/ (* count 100) number))))
 155
 156           (when do-message
 157             (nnheader-message 5 "nnspool: Receiving headers...done"))
 158
 159           ;; Fold continuation lines.
 160           (nnheader-fold-continuation-lines)
 161           'headers)))))
 162
 163 (deffoo nnspool-open-server (server &optional defs)
 164   (nnoo-change-server 'nnspool server defs)
 165   (cond
 166    ((not (file-exists-p nnspool-spool-directory))
 167     (nnspool-close-server)
 168     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 169                      nnspool-spool-directory))
 170    ((not (file-directory-p
 171           (directory-file-name
 172            (file-truename nnspool-spool-directory))))
 173     (nnspool-close-server)
 174     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 175    ((not (file-exists-p nnspool-active-file))
 176     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 177                      nnspool-active-file))
 178    (t
 179     (nnheader-report 'nnspool "Opened server %s using directory %s"
 180                      server nnspool-spool-directory)
 181     t)))
 182
 183 (deffoo nnspool-request-article (id &optional group server buffer)
 184   "Select article by message ID (or number)."
 185   (nnspool-possibly-change-directory group)
 186   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 187         file ag)
 188     (if (stringp id)
 189         ;; This is a Message-ID.
 190         (when (setq ag (nnspool-find-id id))
 191           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 192       (setq file (nnspool-article-pathname nnspool-current-group id)))
 193     (and file
 194          (file-exists-p file)
 195          (not (file-directory-p file))
 196          (save-excursion (nnspool-find-file file))
 197          ;; We return the article number and group name.
 198          (if (numberp id)
 199              (cons nnspool-current-group id)
 200            ag))))
 201
 202 (deffoo nnspool-request-body (id &optional group server)
 203   "Select article body by message ID (or number)."
 204   (nnspool-possibly-change-directory group)
 205   (let ((res (nnspool-request-article id)))
 206     (when res
 207       (save-excursion
 208         (set-buffer nntp-server-buffer)
 209         (goto-char (point-min))
 210         (when (search-forward "\n\n" nil t)
 211           (delete-region (point-min) (point)))
 212         res))))
 213
 214 (deffoo nnspool-request-head (id &optional group server)
 215   "Select article head by message ID (or number)."
 216   (nnspool-possibly-change-directory group)
 217   (let ((res (nnspool-request-article id)))
 218     (when res
 219       (save-excursion
 220         (set-buffer nntp-server-buffer)
 221         (goto-char (point-min))
 222         (when (search-forward "\n\n" nil t)
 223           (delete-region (1- (point)) (point-max)))
 224         (nnheader-fold-continuation-lines)))
 225     res))
 226
 227 (deffoo nnspool-request-group (group &optional server dont-check)
 228   "Select news GROUP."
 229   (let ((pathname (nnspool-article-pathname group))
 230         dir)
 231     (if (not (file-directory-p pathname))
 232         (nnheader-report
 233          'nnspool "Invalid group name (no such directory): %s" group)
 234       (setq nnspool-current-directory pathname)
 235       (nnheader-report 'nnspool "Selected group %s" group)
 236       (if dont-check
 237           (progn
 238             (nnheader-report 'nnspool "Selected group %s" group)
 239             t)
 240         ;; Yes, completely empty spool directories *are* possible.
 241         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 242         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 243           (setq dir
 244                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 245         (if dir
 246             (nnheader-insert
 247              "211 %d %d %d %s\n" (length dir) (car dir)
 248              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 249              group)
 250           (nnheader-report 'nnspool "Empty group %s" group)
 251           (nnheader-insert "211 0 0 0 %s\n" group))))))
 252
 253 (deffoo nnspool-request-type (group &optional article)
 254   'news)
 255
 256 (deffoo nnspool-close-group (group &optional server)
 257   t)
 258
 259 (deffoo nnspool-request-list (&optional server)
 260   "List active newsgroups."
 261   (save-excursion
 262     (or (nnspool-find-file nnspool-active-file)
 263         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 264
 265 (deffoo nnspool-request-list-newsgroups (&optional server)
 266   "List newsgroups (defined in NNTP2)."
 267   (save-excursion
 268     (or (nnspool-find-file nnspool-newsgroups-file)
 269         (nnheader-report 'nnspool (nnheader-file-error
 270                                    nnspool-newsgroups-file)))))
 271
 272 (deffoo nnspool-request-list-distributions (&optional server)
 273   "List distributions (defined in NNTP2)."
 274   (save-excursion
 275     (or (nnspool-find-file nnspool-distributions-file)
 276         (nnheader-report 'nnspool (nnheader-file-error
 277                                    nnspool-distributions-file)))))
 278
 279 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 280 (deffoo nnspool-request-newgroups (date &optional server)
 281   "List groups created after DATE."
 282   (if (nnspool-find-file nnspool-active-times-file)
 283       (save-excursion
 284         ;; Find the last valid line.
 285         (goto-char (point-max))
 286         (while (and (not (looking-at
 287                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 288                     (zerop (forward-line -1))))
 289         (let ((seconds (time-to-seconds (date-to-time date)))
 290               groups)
 291           ;; Go through lines and add the latest groups to a list.
 292           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 293                       (progn
 294                         ;; We insert a .0 to make the list reader
 295                         ;; interpret the number as a float.  It is far
 296                         ;; too big to be stored in a lisp integer.
 297                         (goto-char (1- (match-end 0)))
 298                         (insert ".0")
 299                         (> (progn
 300                              (goto-char (match-end 1))
 301                              (read (current-buffer)))
 302                            seconds))
 303                       (push (buffer-substring
 304                              (match-beginning 1) (match-end 1))
 305                             groups)
 306                       (zerop (forward-line -1))))
 307           (erase-buffer)
 308           (while groups
 309             (insert (car groups) " 0 0 y\n")
 310             (setq groups (cdr groups))))
 311         t)
 312     nil))
 313
 314 (deffoo nnspool-request-post (&optional server)
 315   "Post a new news in current buffer."
 316   (save-excursion
 317     (let* ((process-connection-type nil) ; t bugs out on Solaris
 318            (inews-buffer (generate-new-buffer " *nnspool post*"))
 319            (proc
 320             (condition-case err
 321                 (apply 'start-process "*nnspool inews*" inews-buffer
 322                        nnspool-inews-program nnspool-inews-switches)
 323               (error
 324                (nnheader-report 'nnspool "inews error: %S" err)))))
 325       (if (not proc)
 326           ;; The inews program failed.
 327           ()
 328         (nnheader-report 'nnspool "")
 329         (set-process-sentinel proc 'nnspool-inews-sentinel)
 330         (process-send-region proc (point-min) (point-max))
 331         ;; We slap a condition-case around this, because the process may
 332         ;; have exited already...
 333         (ignore-errors
 334           (process-send-eof proc))
 335         t))))
 336
 337
 338 \f
 339 ;;; Internal functions.
 340
 341 (defun nnspool-inews-sentinel (proc status)
 342   (save-excursion
 343     (set-buffer (process-buffer proc))
 344     (goto-char (point-min))
 345     (if (or (zerop (buffer-size))
 346             (search-forward "spooled" nil t))
 347         (kill-buffer (current-buffer))
 348       ;; Make status message by folding lines.
 349       (while (re-search-forward "[ \t\n]+" nil t)
 350         (replace-match " " t t))
 351       (nnheader-report 'nnspool "%s" (buffer-string))
 352       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 353       (ding)
 354       (run-hooks 'nnspool-rejected-article-hook))))
 355
 356 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 357   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 358       nil
 359     (let ((nov (nnheader-group-pathname
 360                 nnspool-current-group nnspool-nov-directory ".overview"))
 361           (arts articles)
 362           (nnheader-file-coding-system nnspool-file-coding-system)
 363           last)
 364       (if (not (file-exists-p nov))
 365           ()
 366         (save-excursion
 367           (set-buffer nntp-server-buffer)
 368           (erase-buffer)
 369           (if nnspool-sift-nov-with-sed
 370               (nnspool-sift-nov-with-sed articles nov)
 371             (nnheader-insert-file-contents nov)
 372             (if (and fetch-old
 373                      (not (numberp fetch-old)))
 374                 t                       ; We want all the headers.
 375               (ignore-errors
 376                 ;; Delete unwanted NOV lines.
 377                 (nnheader-nov-delete-outside-range
 378                  (if fetch-old (max 1 (- (car articles) fetch-old))
 379                    (car articles))
 380                  (car (last articles)))
 381                 ;; If the buffer is empty, this wasn't very successful.
 382                 (unless (zerop (buffer-size))
 383                   ;; We check what the last article number was.
 384                   ;; The NOV file may be out of sync with the articles
 385                   ;; in the group.
 386                   (forward-line -1)
 387                   (setq last (read (current-buffer)))
 388                   (if (= last (car articles))
 389                       ;; Yup, it's all there.
 390                       t
 391                     ;; Perhaps not.  We try to find the missing articles.
 392                     (while (and arts
 393                                 (<= last (car arts)))
 394                       (pop arts))
 395                     ;; The articles in `arts' are missing from the buffer.
 396                     (while arts
 397                       (nnspool-insert-nov-head (pop arts)))
 398                     t))))))))))
 399
 400 (defun nnspool-insert-nov-head (article)
 401   "Read the head of ARTICLE, convert to NOV headers, and insert."
 402   (save-excursion
 403     (let ((cur (current-buffer))
 404           buf)
 405       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 406       (when (nnheader-insert-head
 407              (nnspool-article-pathname nnspool-current-group article))
 408         (nnheader-insert-article-line article)
 409         (let ((headers (nnheader-parse-head)))
 410           (set-buffer cur)
 411           (goto-char (point-max))
 412           (nnheader-insert-nov headers)))
 413       (kill-buffer buf))))
 414
 415 (defun nnspool-sift-nov-with-sed (articles file)
 416   (let ((first (car articles))
 417         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 418                      (car articles))))
 419     (call-process "awk" nil t nil
 420                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 421                           (1- first) (1+ last))
 422                   file)))
 423
 424 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 425 ;; Find out what group an article identified by a Message-ID is in.
 426 (defun nnspool-find-id (id)
 427   (save-excursion
 428     (set-buffer (get-buffer-create " *nnspool work*"))
 429     (erase-buffer)
 430     (ignore-errors
 431       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 432     (goto-char (point-min))
 433     (prog1
 434         (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 435           (cons (match-string 1) (string-to-int (match-string 2))))
 436       (kill-buffer (current-buffer)))))
 437
 438 (defun nnspool-find-file (file)
 439   "Insert FILE in server buffer safely."
 440   (set-buffer nntp-server-buffer)
 441   (erase-buffer)
 442   (condition-case ()
 443       (let ((coding-system-for-read nnspool-file-coding-system))
 444         (mm-insert-file-contents file)
 445         t)
 446     (file-error nil)))
 447
 448 (defun nnspool-possibly-change-directory (group)
 449   (if (not group)
 450       t
 451     (let ((pathname (nnspool-article-pathname group)))
 452       (if (file-directory-p pathname)
 453           (setq nnspool-current-directory pathname
 454                 nnspool-current-group group)
 455         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 456
 457 (defun nnspool-article-pathname (group &optional article)
 458   "Find the path for GROUP."
 459   (nnheader-group-pathname group nnspool-spool-directory article))
 460
 461 (provide 'nnspool)
 462
 463 ;;; nnspool.el ends here