lisp/net/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (eval-when-compile (require 'url))      ;For url-filename's setf handler.
  35 (require 'browse-url)
  36
  37 (defgroup shr nil
  38   "Simple HTML Renderer"
  39   :version "24.1"
  40   :group 'hypermedia)
  41
  42 (defcustom shr-max-image-proportion 0.9
  43   "How big pictures displayed are in relation to the window they're in.
  44 A value of 0.7 means that they are allowed to take up 70% of the
  45 width and height of the window.  If they are larger than this,
  46 and Emacs supports it, then the images will be rescaled down to
  47 fit these criteria."
  48   :version "24.1"
  49   :group 'shr
  50   :type 'float)
  51
  52 (defcustom shr-blocked-images nil
  53   "Images that have URLs matching this regexp will be blocked."
  54   :version "24.1"
  55   :group 'shr
  56   :type '(choice (const nil) regexp))
  57
  58 (defcustom shr-table-horizontal-line nil
  59   "Character used to draw horizontal table lines.
  60 If nil, don't draw horizontal table lines."
  61   :group 'shr
  62   :type 'character)
  63
  64 (defcustom shr-table-vertical-line ?\s
  65   "Character used to draw vertical table lines."
  66   :group 'shr
  67   :type 'character)
  68
  69 (defcustom shr-table-corner ?\s
  70   "Character used to draw table corners."
  71   :group 'shr
  72   :type 'character)
  73
  74 (defcustom shr-hr-line ?-
  75   "Character used to draw hr lines."
  76   :group 'shr
  77   :type 'character)
  78
  79 (defcustom shr-width fill-column
  80   "Frame width to use for rendering.
  81 May either be an integer specifying a fixed width in characters,
  82 or nil, meaning that the full width of the window should be
  83 used."
  84   :type '(choice (integer :tag "Fixed width in characters")
  85                  (const   :tag "Use the width of the window" nil))
  86   :group 'shr)
  87
  88 (defcustom shr-bullet "* "
  89   "Bullet used for unordered lists.
  90 Alternative suggestions are:
  91 - \"  \"
  92 - \"  \""
  93   :type 'string
  94   :group 'shr)
  95
  96 (defcustom shr-external-browser 'browse-url-default-browser
  97   "Function used to launch an external browser."
  98   :version "24.4"
  99   :group 'shr
 100   :type 'function)
 101
 102 (defvar shr-content-function nil
 103   "If bound, this should be a function that will return the content.
 104 This is used for cid: URLs, and the function is called with the
 105 cid: URL as the argument.")
 106
 107 (defvar shr-put-image-function 'shr-put-image
 108   "Function called to put image and alt string.")
 109
 110 (defface shr-strike-through '((t (:strike-through t)))
 111   "Font for <s> elements."
 112   :group 'shr)
 113
 114 (defface shr-link
 115   '((t (:inherit link)))
 116   "Font for link elements."
 117   :group 'shr)
 118
 119 ;;; Internal variables.
 120
 121 (defvar shr-folding-mode nil)
 122 (defvar shr-state nil)
 123 (defvar shr-start nil)
 124 (defvar shr-indentation 0)
 125 (defvar shr-inhibit-images nil)
 126 (defvar shr-list-mode nil)
 127 (defvar shr-content-cache nil)
 128 (defvar shr-kinsoku-shorten nil)
 129 (defvar shr-table-depth 0)
 130 (defvar shr-stylesheet nil)
 131 (defvar shr-base nil)
 132 (defvar shr-ignore-cache nil)
 133 (defvar shr-external-rendering-functions nil)
 134 (defvar shr-target-id nil)
 135 (defvar shr-inhibit-decoration nil)
 136 (defvar shr-table-separator-length 1)
 137
 138 (defvar shr-map
 139   (let ((map (make-sparse-keymap)))
 140     (define-key map "a" 'shr-show-alt-text)
 141     (define-key map "i" 'shr-browse-image)
 142     (define-key map "z" 'shr-zoom-image)
 143     (define-key map [tab] 'shr-next-link)
 144     (define-key map [backtab] 'shr-previous-link)
 145     (define-key map [follow-link] 'mouse-face)
 146     (define-key map [mouse-2] 'shr-mouse-browse-url)
 147     (define-key map "I" 'shr-insert-image)
 148     (define-key map "w" 'shr-copy-url)
 149     (define-key map "u" 'shr-copy-url)
 150     (define-key map "v" 'shr-browse-url)
 151     (define-key map "o" 'shr-save-contents)
 152     (define-key map "\r" 'shr-browse-url)
 153     map))
 154
 155 ;; Public functions and commands.
 156 (declare-function libxml-parse-html-region "xml.c"
 157                   (start end &optional base-url))
 158
 159 (defun shr-render-buffer (buffer)
 160   "Display the HTML rendering of the current buffer."
 161   (interactive (list (current-buffer)))
 162   (or (fboundp 'libxml-parse-html-region)
 163       (error "This function requires Emacs to be compiled with libxml2"))
 164   (pop-to-buffer "*html*")
 165   (erase-buffer)
 166   (shr-insert-document
 167    (with-current-buffer buffer
 168      (libxml-parse-html-region (point-min) (point-max))))
 169   (goto-char (point-min)))
 170
 171 (defun shr-render-region (begin end &optional buffer)
 172   "Display the HTML rendering of the region between BEGIN and END."
 173   (interactive "r")
 174   (unless (fboundp 'libxml-parse-html-region)
 175     (error "This function requires Emacs to be compiled with libxml2"))
 176   (with-current-buffer (or buffer (current-buffer))
 177     (let ((dom (libxml-parse-html-region begin end)))
 178       (delete-region begin end)
 179       (goto-char begin)
 180       (shr-insert-document dom))))
 181
 182 (defun shr-visit-file (file)
 183   "Parse FILE as an HTML document, and render it in a new buffer."
 184   (interactive "fHTML file name: ")
 185   (with-temp-buffer
 186     (insert-file-contents file)
 187     (shr-render-buffer (current-buffer))))
 188
 189 ;;;###autoload
 190 (defun shr-insert-document (dom)
 191   "Render the parsed document DOM into the current buffer.
 192 DOM should be a parse tree as generated by
 193 `libxml-parse-html-region' or similar."
 194   (setq shr-content-cache nil)
 195   (let ((start (point))
 196         (shr-state nil)
 197         (shr-start nil)
 198         (shr-base nil)
 199         (shr-preliminary-table-render 0)
 200         (shr-width (or shr-width (1- (window-width)))))
 201     (shr-descend (shr-transform-dom dom))
 202     (shr-remove-trailing-whitespace start (point))))
 203
 204 (defun shr-remove-trailing-whitespace (start end)
 205   (let ((width (window-width)))
 206     (save-restriction
 207       (narrow-to-region start end)
 208       (goto-char start)
 209       (while (not (eobp))
 210         (end-of-line)
 211         (when (> (shr-previous-newline-padding-width (current-column)) width)
 212           (dolist (overlay (overlays-at (point)))
 213             (when (overlay-get overlay 'before-string)
 214               (overlay-put overlay 'before-string nil))))
 215         (forward-line 1)))))
 216
 217 (defun shr-copy-url ()
 218   "Copy the URL under point to the kill ring.
 219 If called twice, then try to fetch the URL and see whether it
 220 redirects somewhere else."
 221   (interactive)
 222   (let ((url (get-text-property (point) 'shr-url)))
 223     (cond
 224      ((not url)
 225       (message "No URL under point"))
 226      ;; Resolve redirected URLs.
 227      ((equal url (car kill-ring))
 228       (url-retrieve
 229        url
 230        (lambda (a)
 231          (when (and (consp a)
 232                     (eq (car a) :redirect))
 233            (with-temp-buffer
 234              (insert (cadr a))
 235              (goto-char (point-min))
 236              ;; Remove common tracking junk from the URL.
 237              (when (re-search-forward ".utm_.*" nil t)
 238                (replace-match "" t t))
 239              (message "Copied %s" (buffer-string))
 240              (copy-region-as-kill (point-min) (point-max)))))
 241        nil t))
 242      ;; Copy the URL to the kill ring.
 243      (t
 244       (with-temp-buffer
 245         (insert url)
 246         (copy-region-as-kill (point-min) (point-max))
 247         (message "Copied %s" url))))))
 248
 249 (defun shr-next-link ()
 250   "Skip to the next link."
 251   (interactive)
 252   (let ((skip (text-property-any (point) (point-max) 'help-echo nil)))
 253     (if (not (setq skip (text-property-not-all skip (point-max)
 254                                                'help-echo nil)))
 255         (message "No next link")
 256       (goto-char skip)
 257       (message "%s" (get-text-property (point) 'help-echo)))))
 258
 259 (defun shr-previous-link ()
 260   "Skip to the previous link."
 261   (interactive)
 262   (let ((start (point))
 263         (found nil))
 264     ;; Skip past the current link.
 265     (while (and (not (bobp))
 266                 (get-text-property (point) 'help-echo))
 267       (forward-char -1))
 268     ;; Find the previous link.
 269     (while (and (not (bobp))
 270                 (not (setq found (get-text-property (point) 'help-echo))))
 271       (forward-char -1))
 272     (if (not found)
 273         (progn
 274           (message "No previous link")
 275           (goto-char start))
 276       ;; Put point at the start of the link.
 277       (while (and (not (bobp))
 278                   (get-text-property (point) 'help-echo))
 279         (forward-char -1))
 280       (forward-char 1)
 281       (message "%s" (get-text-property (point) 'help-echo)))))
 282
 283 (defun shr-show-alt-text ()
 284   "Show the ALT text of the image under point."
 285   (interactive)
 286   (let ((text (get-text-property (point) 'shr-alt)))
 287     (if (not text)
 288         (message "No image under point")
 289       (message "%s" text))))
 290
 291 (defun shr-browse-image (&optional copy-url)
 292   "Browse the image under point.
 293 If COPY-URL (the prefix if called interactively) is non-nil, copy
 294 the URL of the image to the kill buffer instead."
 295   (interactive "P")
 296   (let ((url (get-text-property (point) 'image-url)))
 297     (cond
 298      ((not url)
 299       (message "No image under point"))
 300      (copy-url
 301       (with-temp-buffer
 302         (insert url)
 303         (copy-region-as-kill (point-min) (point-max))
 304         (message "Copied %s" url)))
 305      (t
 306       (message "Browsing %s..." url)
 307       (browse-url url)))))
 308
 309 (defun shr-insert-image ()
 310   "Insert the image under point into the buffer."
 311   (interactive)
 312   (let ((url (get-text-property (point) 'image-url)))
 313     (if (not url)
 314         (message "No image under point")
 315       (message "Inserting %s..." url)
 316       (url-retrieve url 'shr-image-fetched
 317                     (list (current-buffer) (1- (point)) (point-marker))
 318                     t t))))
 319
 320 (defun shr-zoom-image ()
 321   "Toggle the image size.
 322 The size will be rotated between the default size, the original
 323 size, and full-buffer size."
 324   (interactive)
 325   (let ((url (get-text-property (point) 'image-url))
 326         (size (get-text-property (point) 'image-size))
 327         (buffer-read-only nil))
 328     (if (not url)
 329         (message "No image under point")
 330       ;; Delete the old picture.
 331       (while (get-text-property (point) 'image-url)
 332         (forward-char -1))
 333       (forward-char 1)
 334       (let ((start (point)))
 335         (while (get-text-property (point) 'image-url)
 336           (forward-char 1))
 337         (forward-char -1)
 338         (put-text-property start (point) 'display nil)
 339         (when (> (- (point) start) 2)
 340           (delete-region start (1- (point)))))
 341       (message "Inserting %s..." url)
 342       (url-retrieve url 'shr-image-fetched
 343                     (list (current-buffer) (1- (point)) (point-marker)
 344                           (list (cons 'size
 345                                       (cond ((or (eq size 'default)
 346                                                  (null size))
 347                                              'original)
 348                                             ((eq size 'original)
 349                                              'full)
 350                                             ((eq size 'full)
 351                                              'default)))))
 352                     t))))
 353
 354 ;;; Utility functions.
 355
 356 (defun shr-transform-dom (dom)
 357   (let ((result (list (pop dom))))
 358     (dolist (arg (pop dom))
 359       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 360                   (cdr arg))
 361             result))
 362     (dolist (sub dom)
 363       (if (stringp sub)
 364           (push (cons 'text sub) result)
 365         (push (shr-transform-dom sub) result)))
 366     (nreverse result)))
 367
 368 (defun shr-descend (dom)
 369   (let ((function
 370          (or
 371           ;; Allow other packages to override (or provide) rendering
 372           ;; of elements.
 373           (cdr (assq (car dom) shr-external-rendering-functions))
 374           (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
 375         (style (cdr (assq :style (cdr dom))))
 376         (shr-stylesheet shr-stylesheet)
 377         (start (point)))
 378     (when style
 379       (if (string-match "color\\|display\\|border-collapse" style)
 380           (setq shr-stylesheet (nconc (shr-parse-style style)
 381                                       shr-stylesheet))
 382         (setq style nil)))
 383     ;; If we have a display:none, then just ignore this part of the
 384     ;; DOM.
 385     (unless (equal (cdr (assq 'display shr-stylesheet)) "none")
 386       (if (fboundp function)
 387           (funcall function (cdr dom))
 388         (shr-generic (cdr dom)))
 389       (when (and shr-target-id
 390                  (equal (cdr (assq :id (cdr dom))) shr-target-id))
 391         (put-text-property start (1+ start) 'shr-target-id shr-target-id))
 392       ;; If style is set, then this node has set the color.
 393       (when style
 394         (shr-colorize-region start (point)
 395                              (cdr (assq 'color shr-stylesheet))
 396                              (cdr (assq 'background-color shr-stylesheet)))))))
 397
 398 (defun shr-generic (cont)
 399   (dolist (sub cont)
 400     (cond
 401      ((eq (car sub) 'text)
 402       (shr-insert (cdr sub)))
 403      ((listp (cdr sub))
 404       (shr-descend sub)))))
 405
 406 (defmacro shr-char-breakable-p (char)
 407   "Return non-nil if a line can be broken before and after CHAR."
 408   `(aref fill-find-break-point-function-table ,char))
 409 (defmacro shr-char-nospace-p (char)
 410   "Return non-nil if no space is required before and after CHAR."
 411   `(aref fill-nospace-between-words-table ,char))
 412
 413 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 414 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 415 ;; parentheses, and so on, that should not be placed in the beginning
 416 ;; of a line or the end of a line.
 417 (defmacro shr-char-kinsoku-bol-p (char)
 418   "Return non-nil if a line ought not to begin with CHAR."
 419   `(aref (char-category-set ,char) ?>))
 420 (defmacro shr-char-kinsoku-eol-p (char)
 421   "Return non-nil if a line ought not to end with CHAR."
 422   `(aref (char-category-set ,char) ?<))
 423 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 424   (load "kinsoku" nil t))
 425
 426 (defun shr-insert (text)
 427   (when (and (eq shr-state 'image)
 428              (not (bolp))
 429              (not (string-match "\\`[ \t\n]+\\'" text)))
 430     (insert "\n")
 431     (setq shr-state nil))
 432   (cond
 433    ((eq shr-folding-mode 'none)
 434     (insert text))
 435    (t
 436     (when (and (string-match "\\`[ \t\n ]" text)
 437                (not (bolp))
 438                (not (eq (char-after (1- (point))) ? )))
 439       (insert " "))
 440     (dolist (elem (split-string text "[ \f\t\n\r\v ]+" t))
 441       (when (and (bolp)
 442                  (> shr-indentation 0))
 443         (shr-indent))
 444       ;; No space is needed behind a wide character categorized as
 445       ;; kinsoku-bol, between characters both categorized as nospace,
 446       ;; or at the beginning of a line.
 447       (let (prev)
 448         (when (and (> (current-column) shr-indentation)
 449                    (eq (preceding-char) ? )
 450                    (or (= (line-beginning-position) (1- (point)))
 451                        (and (shr-char-breakable-p
 452                              (setq prev (char-after (- (point) 2))))
 453                             (shr-char-kinsoku-bol-p prev))
 454                        (and (shr-char-nospace-p prev)
 455                             (shr-char-nospace-p (aref elem 0)))))
 456           (delete-char -1)))
 457       ;; The shr-start is a special variable that is used to pass
 458       ;; upwards the first point in the buffer where the text really
 459       ;; starts.
 460       (unless shr-start
 461         (setq shr-start (point)))
 462       (insert elem)
 463       (setq shr-state nil)
 464       (let (found)
 465         (while (and (> (current-column) shr-width)
 466                     (progn
 467                       (setq found (shr-find-fill-point))
 468                       (not (eolp))))
 469           (when (eq (preceding-char) ? )
 470             (delete-char -1))
 471           (insert "\n")
 472           (unless found
 473             ;; No space is needed at the beginning of a line.
 474             (when (eq (following-char) ? )
 475               (delete-char 1)))
 476           (when (> shr-indentation 0)
 477             (shr-indent))
 478           (end-of-line))
 479         (insert " ")))
 480     (unless (string-match "[ \t\r\n ]\\'" text)
 481       (delete-char -1)))))
 482
 483 (defun shr-find-fill-point ()
 484   (when (> (move-to-column shr-width) shr-width)
 485     (backward-char 1))
 486   (let ((bp (point))
 487         failed)
 488     (while (not (or (setq failed (= (current-column) shr-indentation))
 489                     (eq (preceding-char) ? )
 490                     (eq (following-char) ? )
 491                     (shr-char-breakable-p (preceding-char))
 492                     (shr-char-breakable-p (following-char))
 493                     (if (eq (preceding-char) ?')
 494                         (not (memq (char-after (- (point) 2))
 495                                    (list nil ?\n ? )))
 496                       (and (shr-char-kinsoku-bol-p (preceding-char))
 497                            (shr-char-breakable-p (following-char))
 498                            (not (shr-char-kinsoku-bol-p (following-char)))))
 499                     (shr-char-kinsoku-eol-p (following-char))))
 500       (backward-char 1))
 501     (if (and (not (or failed (eolp)))
 502              (eq (preceding-char) ?'))
 503         (while (not (or (setq failed (eolp))
 504                         (eq (following-char) ? )
 505                         (shr-char-breakable-p (following-char))
 506                         (shr-char-kinsoku-eol-p (following-char))))
 507           (forward-char 1)))
 508     (if failed
 509         ;; There's no breakable point, so we give it up.
 510         (let (found)
 511           (goto-char bp)
 512           (unless shr-kinsoku-shorten
 513             (while (and (setq found (re-search-forward
 514                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 515                                      (line-end-position) 'move))
 516                         (eq (preceding-char) ?')))
 517             (if (and found (not (match-beginning 1)))
 518                 (goto-char (match-beginning 0)))))
 519       (or
 520        (eolp)
 521        ;; Don't put kinsoku-bol characters at the beginning of a line,
 522        ;; or kinsoku-eol characters at the end of a line.
 523        (cond
 524         (shr-kinsoku-shorten
 525          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 526                      (shr-char-kinsoku-eol-p (preceding-char)))
 527            (backward-char 1))
 528          (when (setq failed (= (current-column) shr-indentation))
 529            ;; There's no breakable point that doesn't violate kinsoku,
 530            ;; so we look for the second best position.
 531            (while (and (progn
 532                          (forward-char 1)
 533                          (<= (current-column) shr-width))
 534                        (progn
 535                          (setq bp (point))
 536                          (shr-char-kinsoku-eol-p (following-char)))))
 537            (goto-char bp)))
 538         ((shr-char-kinsoku-eol-p (preceding-char))
 539          ;; Find backward the point where kinsoku-eol characters begin.
 540          (let ((count 4))
 541            (while
 542                (progn
 543                  (backward-char 1)
 544                  (and (> (setq count (1- count)) 0)
 545                       (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 546                       (or (shr-char-kinsoku-eol-p (preceding-char))
 547                           (shr-char-kinsoku-bol-p (following-char)))))))
 548          (if (setq failed (= (current-column) shr-indentation))
 549              ;; There's no breakable point that doesn't violate kinsoku,
 550              ;; so we go to the second best position.
 551              (if (looking-at "\\(\\c<+\\)\\c<")
 552                  (goto-char (match-end 1))
 553                (forward-char 1))))
 554         ((shr-char-kinsoku-bol-p (following-char))
 555          ;; Find forward the point where kinsoku-bol characters end.
 556          (let ((count 4))
 557            (while (progn
 558                     (forward-char 1)
 559                     (and (>= (setq count (1- count)) 0)
 560                          (shr-char-kinsoku-bol-p (following-char))
 561                          (shr-char-breakable-p (following-char))))))))
 562        (when (eq (following-char) ? )
 563          (forward-char 1))))
 564     (not failed)))
 565
 566 (defun shr-parse-base (url)
 567   ;; Always chop off anchors.
 568   (when (string-match "#.*" url)
 569     (setq url (substring url 0 (match-beginning 0))))
 570   (let* ((parsed (url-generic-parse-url url))
 571          (local (url-filename parsed)))
 572     (setf (url-filename parsed) "")
 573     ;; Chop off the bit after the last slash.
 574     (when (string-match "\\`\\(.*/\\)[^/]+\\'" local)
 575       (setq local (match-string 1 local)))
 576     ;; Always make the local bit end with a slash.
 577     (when (and (not (zerop (length local)))
 578                (not (eq (aref local (1- (length local))) ?/)))
 579       (setq local (concat local "/")))
 580     (list (url-recreate-url parsed)
 581           local
 582           (url-type parsed)
 583           url)))
 584
 585 (defun shr-expand-url (url &optional base)
 586   (setq base
 587         (if base
 588             (shr-parse-base base)
 589           ;; Bound by the parser.
 590           shr-base))
 591   (when (zerop (length url))
 592     (setq url nil))
 593   (cond ((or (not url)
 594              (not base)
 595              (string-match "\\`[a-z]*:" url))
 596          ;; Absolute URL.
 597          (or url (car base)))
 598         ((eq (aref url 0) ?/)
 599          (if (and (> (length url) 1)
 600                   (eq (aref url 1) ?/))
 601              ;; //host...; just use the protocol
 602              (concat (nth 2 base) ":" url)
 603            ;; Just use the host name part.
 604            (concat (car base) url)))
 605         ((eq (aref url 0) ?#)
 606          ;; A link to an anchor.
 607          (concat (nth 3 base) url))
 608         (t
 609          ;; Totally relative.
 610          (concat (car base) (cadr base) url))))
 611
 612 (defun shr-ensure-newline ()
 613   (unless (zerop (current-column))
 614     (insert "\n")))
 615
 616 (defun shr-ensure-paragraph ()
 617   (unless (bobp)
 618     (if (<= (current-column) shr-indentation)
 619         (unless (save-excursion
 620                   (forward-line -1)
 621                   (looking-at " *$"))
 622           (insert "\n"))
 623       (if (save-excursion
 624             (beginning-of-line)
 625             ;; If the current line is totally blank, and doesn't even
 626             ;; have any face properties set, then delete the blank
 627             ;; space.
 628             (and (looking-at " *$")
 629                  (not (get-text-property (point) 'face))
 630                  (not (= (next-single-property-change (point) 'face nil
 631                                                       (line-end-position))
 632                          (line-end-position)))))
 633           (delete-region (match-beginning 0) (match-end 0))
 634         (insert "\n\n")))))
 635
 636 (defun shr-indent ()
 637   (when (> shr-indentation 0)
 638     (insert (make-string shr-indentation ? ))))
 639
 640 (defun shr-fontize-cont (cont &rest types)
 641   (let (shr-start)
 642     (shr-generic cont)
 643     (dolist (type types)
 644       (shr-add-font (or shr-start (point)) (point) type))))
 645
 646 ;; Add face to the region, but avoid putting the font properties on
 647 ;; blank text at the start of the line, and the newline at the end, to
 648 ;; avoid ugliness.
 649 (defun shr-add-font (start end type)
 650   (unless shr-inhibit-decoration
 651     (save-excursion
 652       (goto-char start)
 653       (while (< (point) end)
 654         (when (bolp)
 655           (skip-chars-forward " "))
 656         (add-face-text-property (point) (min (line-end-position) end) type t)
 657         (if (< (line-end-position) end)
 658             (forward-line 1)
 659           (goto-char end))))))
 660
 661 (defun shr-mouse-browse-url (ev)
 662   "Browse the URL under the mouse cursor."
 663   (interactive "e")
 664   (mouse-set-point ev)
 665   (shr-browse-url))
 666
 667 (defun shr-browse-url (&optional external)
 668   "Browse the URL under point.
 669 If EXTERNAL, browse the URL using `shr-external-browser'."
 670   (interactive "P")
 671   (let ((url (get-text-property (point) 'shr-url)))
 672     (cond
 673      ((not url)
 674       (message "No link under point"))
 675      ((string-match "^mailto:" url)
 676       (browse-url-mail url))
 677      (t
 678       (if external
 679           (funcall shr-external-browser url)
 680         (browse-url url))))))
 681
 682 (defun shr-save-contents (directory)
 683   "Save the contents from URL in a file."
 684   (interactive "DSave contents of URL to directory: ")
 685   (let ((url (get-text-property (point) 'shr-url)))
 686     (if (not url)
 687         (message "No link under point")
 688       (url-retrieve (shr-encode-url url)
 689                     'shr-store-contents (list url directory)
 690                     nil t))))
 691
 692 (defun shr-store-contents (status url directory)
 693   (unless (plist-get status :error)
 694     (when (or (search-forward "\n\n" nil t)
 695               (search-forward "\r\n\r\n" nil t))
 696       (write-region (point) (point-max)
 697                     (expand-file-name (file-name-nondirectory url)
 698                                       directory)))))
 699
 700 (defun shr-image-fetched (status buffer start end &optional flags)
 701   (let ((image-buffer (current-buffer)))
 702     (when (and (buffer-name buffer)
 703                (not (plist-get status :error)))
 704       (url-store-in-cache image-buffer)
 705       (when (or (search-forward "\n\n" nil t)
 706                 (search-forward "\r\n\r\n" nil t))
 707         (let ((data (buffer-substring (point) (point-max))))
 708           (with-current-buffer buffer
 709             (save-excursion
 710               (let ((alt (buffer-substring start end))
 711                     (properties (text-properties-at start))
 712                     (inhibit-read-only t))
 713                 (delete-region start end)
 714                 (goto-char start)
 715                 (funcall shr-put-image-function data alt flags)
 716                 (while properties
 717                   (let ((type (pop properties))
 718                         (value (pop properties)))
 719                     (unless (memq type '(display image-size))
 720                       (put-text-property start (point) type value))))))))))
 721     (kill-buffer image-buffer)))
 722
 723 (defun shr-image-from-data (data)
 724   "Return an image from the data: URI content DATA."
 725   (when (string-match
 726          "\\(\\([^/;,]+\\(/[^;,]+\\)?\\)\\(;[^;,]+\\)*\\)?,\\(.*\\)"
 727          data)
 728     (let ((param (match-string 4 data))
 729           (payload (url-unhex-string (match-string 5 data))))
 730       (when (string-match "^.*\\(;[ \t]*base64\\)$" param)
 731         (setq payload (base64-decode-string payload)))
 732       payload)))
 733
 734 (defun shr-put-image (data alt &optional flags)
 735   "Put image DATA with a string ALT.  Return image."
 736   (if (display-graphic-p)
 737       (let* ((size (cdr (assq 'size flags)))
 738              (start (point))
 739              (image (cond
 740                      ((eq size 'original)
 741                       (create-image data nil t :ascent 100))
 742                      ((eq size 'full)
 743                       (ignore-errors
 744                         (shr-rescale-image data t)))
 745                      (t
 746                       (ignore-errors
 747                         (shr-rescale-image data))))))
 748         (when image
 749           ;; When inserting big-ish pictures, put them at the
 750           ;; beginning of the line.
 751           (when (and (> (current-column) 0)
 752                      (> (car (image-size image t)) 400))
 753             (insert "\n"))
 754           (if (eq size 'original)
 755               (insert-sliced-image image (or alt "*") nil 20 1)
 756             (insert-image image (or alt "*")))
 757           (put-text-property start (point) 'image-size size)
 758           (when (cond ((fboundp 'image-multi-frame-p)
 759                        ;; Only animate multi-frame things that specify a
 760                        ;; delay; eg animated gifs as opposed to
 761                        ;; multi-page tiffs.  FIXME?
 762                        (cdr (image-multi-frame-p image)))
 763                       ((fboundp 'image-animated-p)
 764                        (image-animated-p image)))
 765             (image-animate image nil 60)))
 766         image)
 767     (insert alt)))
 768
 769 (defun shr-rescale-image (data &optional force)
 770   "Rescale DATA, if too big, to fit the current buffer.
 771 If FORCE, rescale the image anyway."
 772   (if (or (not (fboundp 'imagemagick-types))
 773           (eq (image-type-from-data data) 'gif)
 774           (not (get-buffer-window (current-buffer))))
 775       (create-image data nil t :ascent 100)
 776     (let ((edges (window-inside-pixel-edges
 777                   (get-buffer-window (current-buffer)))))
 778       (create-image
 779        data 'imagemagick t
 780        :ascent 100
 781        :max-width (truncate (* shr-max-image-proportion
 782                                (- (nth 2 edges) (nth 0 edges))))
 783        :max-height (truncate (* shr-max-image-proportion
 784                                 (- (nth 3 edges) (nth 1 edges))))))))
 785
 786 ;; url-cache-extract autoloads url-cache.
 787 (declare-function url-cache-create-filename "url-cache" (url))
 788 (autoload 'mm-disable-multibyte "mm-util")
 789 (autoload 'browse-url-mail "browse-url")
 790
 791 (defun shr-get-image-data (url)
 792   "Get image data for URL.
 793 Return a string with image data."
 794   (with-temp-buffer
 795     (mm-disable-multibyte)
 796     (when (ignore-errors
 797             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 798             t)
 799       (when (or (search-forward "\n\n" nil t)
 800                 (search-forward "\r\n\r\n" nil t))
 801         (buffer-substring (point) (point-max))))))
 802
 803 (defun shr-image-displayer (content-function)
 804   "Return a function to display an image.
 805 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 806 is an argument.  The function to be returned takes three arguments URL,
 807 START, and END.  Note that START and END should be markers."
 808   `(lambda (url start end)
 809      (when url
 810        (if (string-match "\\`cid:" url)
 811            ,(when content-function
 812               `(let ((image (funcall ,content-function
 813                                      (substring url (match-end 0)))))
 814                  (when image
 815                    (goto-char start)
 816                    (funcall shr-put-image-function
 817                             image (buffer-substring start end))
 818                    (delete-region (point) end))))
 819          (url-retrieve url 'shr-image-fetched
 820                        (list (current-buffer) start end)
 821                        t t)))))
 822
 823 (defun shr-heading (cont &rest types)
 824   (shr-ensure-paragraph)
 825   (apply #'shr-fontize-cont cont types)
 826   (shr-ensure-paragraph))
 827
 828 (defun shr-urlify (start url &optional title)
 829   (when (and title (string-match "ctx" title)) (debug))
 830   (shr-add-font start (point) 'shr-link)
 831   (add-text-properties
 832    start (point)
 833    (list 'shr-url url
 834          'help-echo (if title (format "%s (%s)" url title) url)
 835          'follow-link t
 836          'mouse-face 'highlight
 837          'keymap shr-map)))
 838
 839 (defun shr-encode-url (url)
 840   "Encode URL."
 841   (browse-url-url-encode-chars url "[)$ ]"))
 842
 843 (autoload 'shr-color-visible "shr-color")
 844 (autoload 'shr-color->hexadecimal "shr-color")
 845
 846 (defun shr-color-check (fg bg)
 847   "Check that FG is visible on BG.
 848 Returns (fg bg) with corrected values.
 849 Returns nil if the colors that would be used are the default
 850 ones, in case fg and bg are nil."
 851   (when (or fg bg)
 852     (let ((fixed (cond ((null fg) 'fg)
 853                        ((null bg) 'bg))))
 854       ;; Convert colors to hexadecimal, or set them to default.
 855       (let ((fg (or (shr-color->hexadecimal fg)
 856                     (frame-parameter nil 'foreground-color)))
 857             (bg (or (shr-color->hexadecimal bg)
 858                     (frame-parameter nil 'background-color))))
 859         (cond ((eq fixed 'bg)
 860                ;; Only return the new fg
 861                (list nil (cadr (shr-color-visible bg fg t))))
 862               ((eq fixed 'fg)
 863                ;; Invert args and results and return only the new bg
 864                (list (cadr (shr-color-visible fg bg t)) nil))
 865               (t
 866                (shr-color-visible bg fg)))))))
 867
 868 (defun shr-colorize-region (start end fg &optional bg)
 869   (when (and (not shr-inhibit-decoration)
 870              (or fg bg))
 871     (let ((new-colors (shr-color-check fg bg)))
 872       (when new-colors
 873         (when fg
 874           (add-face-text-property start end
 875                                   (list :foreground (cadr new-colors))
 876                                   t))
 877         (when bg
 878           (add-face-text-property start end
 879                                   (list :background (car new-colors))
 880                                   t)))
 881       new-colors)))
 882
 883 (defun shr-expand-newlines (start end color)
 884   (save-restriction
 885     ;; Skip past all white space at the start and ends.
 886     (goto-char start)
 887     (skip-chars-forward " \t\n")
 888     (beginning-of-line)
 889     (setq start (point))
 890     (goto-char end)
 891     (skip-chars-backward " \t\n")
 892     (forward-line 1)
 893     (setq end (point))
 894     (narrow-to-region start end)
 895     (let ((width (shr-buffer-width))
 896           column)
 897       (goto-char (point-min))
 898       (while (not (eobp))
 899         (end-of-line)
 900         (when (and (< (setq column (current-column)) width)
 901                    (< (setq column (shr-previous-newline-padding-width column))
 902                       width))
 903           (let ((overlay (make-overlay (point) (1+ (point)))))
 904             (overlay-put overlay 'before-string
 905                          (concat
 906                           (mapconcat
 907                            (lambda (overlay)
 908                              (let ((string (plist-get
 909                                             (overlay-properties overlay)
 910                                             'before-string)))
 911                                (if (not string)
 912                                    ""
 913                                  (overlay-put overlay 'before-string "")
 914                                  string)))
 915                            (overlays-at (point))
 916                            "")
 917                           (propertize (make-string (- width column) ? )
 918                                       'face (list :background color))))))
 919         (forward-line 1)))))
 920
 921 (defun shr-previous-newline-padding-width (width)
 922   (let ((overlays (overlays-at (point)))
 923         (previous-width 0))
 924     (if (null overlays)
 925         width
 926       (dolist (overlay overlays)
 927         (setq previous-width
 928               (+ previous-width
 929                  (length (plist-get (overlay-properties overlay)
 930                                     'before-string)))))
 931       (+ width previous-width))))
 932
 933 ;;; Tag-specific rendering rules.
 934
 935 (defun shr-tag-body (cont)
 936   (let* ((start (point))
 937          (fgcolor (cdr (or (assq :fgcolor cont)
 938                            (assq :text cont))))
 939          (bgcolor (cdr (assq :bgcolor cont)))
 940          (shr-stylesheet (list (cons 'color fgcolor)
 941                                (cons 'background-color bgcolor))))
 942     (shr-generic cont)
 943     (shr-colorize-region start (point) fgcolor bgcolor)))
 944
 945 (defun shr-tag-style (cont)
 946   )
 947
 948 (defun shr-tag-script (cont)
 949   )
 950
 951 (defun shr-tag-comment (cont)
 952   )
 953
 954 (defun shr-dom-to-xml (dom)
 955   "Convert DOM into a string containing the xml representation."
 956   (let ((arg " ")
 957         (text ""))
 958     (dolist (sub (cdr dom))
 959       (cond
 960        ((listp (cdr sub))
 961         (setq text (concat text (shr-dom-to-xml sub))))
 962        ((eq (car sub) 'text)
 963         (setq text (concat text (cdr sub))))
 964        (t
 965         (setq arg (concat arg (format "%s=\"%s\" "
 966                                       (substring (symbol-name (car sub)) 1)
 967                                       (cdr sub)))))))
 968     (format "<%s%s>%s</%s>"
 969             (car dom)
 970             (substring arg 0 (1- (length arg)))
 971             text
 972             (car dom))))
 973
 974 (defun shr-tag-svg (cont)
 975   (when (image-type-available-p 'svg)
 976     (funcall shr-put-image-function
 977              (shr-dom-to-xml (cons 'svg cont))
 978              "SVG Image")))
 979
 980 (defun shr-tag-sup (cont)
 981   (let ((start (point)))
 982     (shr-generic cont)
 983     (put-text-property start (point) 'display '(raise 0.5))))
 984
 985 (defun shr-tag-sub (cont)
 986   (let ((start (point)))
 987     (shr-generic cont)
 988     (put-text-property start (point) 'display '(raise -0.5))))
 989
 990 (defun shr-tag-label (cont)
 991   (shr-generic cont)
 992   (shr-ensure-paragraph))
 993
 994 (defun shr-tag-p (cont)
 995   (shr-ensure-paragraph)
 996   (shr-indent)
 997   (shr-generic cont)
 998   (shr-ensure-paragraph))
 999
1000 (defun shr-tag-div (cont)
1001   (shr-ensure-newline)
1002   (shr-indent)
1003   (shr-generic cont)
1004   (shr-ensure-newline))
1005
1006 (defun shr-tag-s (cont)
1007   (shr-fontize-cont cont 'shr-strike-through))
1008
1009 (defun shr-tag-del (cont)
1010   (shr-fontize-cont cont 'shr-strike-through))
1011
1012 (defun shr-tag-b (cont)
1013   (shr-fontize-cont cont 'bold))
1014
1015 (defun shr-tag-i (cont)
1016   (shr-fontize-cont cont 'italic))
1017
1018 (defun shr-tag-em (cont)
1019   (shr-fontize-cont cont 'italic))
1020
1021 (defun shr-tag-strong (cont)
1022   (shr-fontize-cont cont 'bold))
1023
1024 (defun shr-tag-u (cont)
1025   (shr-fontize-cont cont 'underline))
1026
1027 (defun shr-parse-style (style)
1028   (when style
1029     (save-match-data
1030       (when (string-match "\n" style)
1031         (setq style (replace-match " " t t style))))
1032     (let ((plist nil))
1033       (dolist (elem (split-string style ";"))
1034         (when elem
1035           (setq elem (split-string elem ":"))
1036           (when (and (car elem)
1037                      (cadr elem))
1038             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
1039                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
1040               (when (string-match " *!important\\'" value)
1041                 (setq value (substring value 0 (match-beginning 0))))
1042               (push (cons (intern name obarray)
1043                           value)
1044                     plist)))))
1045       plist)))
1046
1047 (defun shr-tag-base (cont)
1048   (let ((base (cdr (assq :href cont))))
1049     (when base
1050       (setq shr-base (shr-parse-base base))))
1051   (shr-generic cont))
1052
1053 (defun shr-tag-a (cont)
1054   (let ((url (cdr (assq :href cont)))
1055         (title (cdr (assq :title cont)))
1056         (start (point))
1057         shr-start)
1058     (shr-generic cont)
1059     (when (and url
1060                (not shr-inhibit-decoration))
1061       (shr-urlify (or shr-start start) (shr-expand-url url) title))))
1062
1063 (defun shr-tag-object (cont)
1064   (let ((start (point))
1065         url)
1066     (dolist (elem cont)
1067       (when (eq (car elem) 'embed)
1068         (setq url (or url (cdr (assq :src (cdr elem))))))
1069       (when (and (eq (car elem) 'param)
1070                  (equal (cdr (assq :name (cdr elem))) "movie"))
1071         (setq url (or url (cdr (assq :value (cdr elem)))))))
1072     (when url
1073       (shr-insert " [multimedia] ")
1074       (shr-urlify start (shr-expand-url url)))
1075     (shr-generic cont)))
1076
1077 (defun shr-tag-video (cont)
1078   (let ((image (cdr (assq :poster cont)))
1079         (url (cdr (assq :src cont)))
1080         (start (point)))
1081     (shr-tag-img nil image)
1082     (shr-urlify start (shr-expand-url url))))
1083
1084 (defun shr-tag-img (cont &optional url)
1085   (when (or url
1086             (and cont
1087                  (cdr (assq :src cont))))
1088     (when (and (> (current-column) 0)
1089                (not (eq shr-state 'image)))
1090       (insert "\n"))
1091     (let ((alt (cdr (assq :alt cont)))
1092           (url (shr-expand-url (or url (cdr (assq :src cont))))))
1093       (let ((start (point-marker)))
1094         (when (zerop (length alt))
1095           (setq alt "*"))
1096         (cond
1097          ((or (member (cdr (assq :height cont)) '("0" "1"))
1098               (member (cdr (assq :width cont)) '("0" "1")))
1099           ;; Ignore zero-sized or single-pixel images.
1100           )
1101          ((and (not shr-inhibit-images)
1102                (string-match "\\`data:" url))
1103           (let ((image (shr-image-from-data (substring url (match-end 0)))))
1104             (if image
1105                 (funcall shr-put-image-function image alt)
1106               (insert alt))))
1107          ((and (not shr-inhibit-images)
1108                (string-match "\\`cid:" url))
1109           (let ((url (substring url (match-end 0)))
1110                 image)
1111             (if (or (not shr-content-function)
1112                     (not (setq image (funcall shr-content-function url))))
1113                 (insert alt)
1114               (funcall shr-put-image-function image alt))))
1115          ((or shr-inhibit-images
1116               (and shr-blocked-images
1117                    (string-match shr-blocked-images url)))
1118           (setq shr-start (point))
1119           (let ((shr-state 'space))
1120             (if (> (string-width alt) 8)
1121                 (shr-insert (truncate-string-to-width alt 8))
1122               (shr-insert alt))))
1123          ((and (not shr-ignore-cache)
1124                (url-is-cached (shr-encode-url url)))
1125           (funcall shr-put-image-function (shr-get-image-data url) alt))
1126          (t
1127           (insert alt " ")
1128           (when (and shr-ignore-cache
1129                      (url-is-cached (shr-encode-url url)))
1130             (let ((file (url-cache-create-filename (shr-encode-url url))))
1131               (when (file-exists-p file)
1132                 (delete-file file))))
1133           (url-queue-retrieve
1134            (shr-encode-url url) 'shr-image-fetched
1135            (list (current-buffer) start (set-marker (make-marker) (1- (point))))
1136            t t)))
1137         (when (zerop shr-table-depth) ;; We are not in a table.
1138           (put-text-property start (point) 'keymap shr-map)
1139           (put-text-property start (point) 'shr-alt alt)
1140           (put-text-property start (point) 'image-url url)
1141           (put-text-property start (point) 'image-displayer
1142                              (shr-image-displayer shr-content-function))
1143           (put-text-property start (point) 'help-echo alt))
1144         (setq shr-state 'image)))))
1145
1146 (defun shr-tag-pre (cont)
1147   (let ((shr-folding-mode 'none))
1148     (shr-ensure-newline)
1149     (shr-indent)
1150     (shr-generic cont)
1151     (shr-ensure-newline)))
1152
1153 (defun shr-tag-blockquote (cont)
1154   (shr-ensure-paragraph)
1155   (shr-indent)
1156   (let ((shr-indentation (+ shr-indentation 4)))
1157     (shr-generic cont))
1158   (shr-ensure-paragraph))
1159
1160 (defun shr-tag-dl (cont)
1161   (shr-ensure-paragraph)
1162   (shr-generic cont)
1163   (shr-ensure-paragraph))
1164
1165 (defun shr-tag-dt (cont)
1166   (shr-ensure-newline)
1167   (shr-generic cont)
1168   (shr-ensure-newline))
1169
1170 (defun shr-tag-dd (cont)
1171   (shr-ensure-newline)
1172   (let ((shr-indentation (+ shr-indentation 4)))
1173     (shr-generic cont)))
1174
1175 (defun shr-tag-ul (cont)
1176   (shr-ensure-paragraph)
1177   (let ((shr-list-mode 'ul))
1178     (shr-generic cont))
1179   (shr-ensure-paragraph))
1180
1181 (defun shr-tag-ol (cont)
1182   (shr-ensure-paragraph)
1183   (let ((shr-list-mode 1))
1184     (shr-generic cont))
1185   (shr-ensure-paragraph))
1186
1187 (defun shr-tag-li (cont)
1188   (shr-ensure-newline)
1189   (shr-indent)
1190   (let* ((bullet
1191           (if (numberp shr-list-mode)
1192               (prog1
1193                   (format "%d " shr-list-mode)
1194                 (setq shr-list-mode (1+ shr-list-mode)))
1195             shr-bullet))
1196          (shr-indentation (+ shr-indentation (length bullet))))
1197     (insert bullet)
1198     (shr-generic cont)))
1199
1200 (defun shr-tag-br (cont)
1201   (when (and (not (bobp))
1202              ;; Only add a newline if we break the current line, or
1203              ;; the previous line isn't a blank line.
1204              (or (not (bolp))
1205                  (and (> (- (point) 2) (point-min))
1206                       (not (= (char-after (- (point) 2)) ?\n)))))
1207     (insert "\n")
1208     (shr-indent))
1209   (shr-generic cont))
1210
1211 (defun shr-tag-span (cont)
1212   (shr-generic cont))
1213
1214 (defun shr-tag-h1 (cont)
1215   (shr-heading cont 'bold 'underline))
1216
1217 (defun shr-tag-h2 (cont)
1218   (shr-heading cont 'bold))
1219
1220 (defun shr-tag-h3 (cont)
1221   (shr-heading cont 'italic))
1222
1223 (defun shr-tag-h4 (cont)
1224   (shr-heading cont))
1225
1226 (defun shr-tag-h5 (cont)
1227   (shr-heading cont))
1228
1229 (defun shr-tag-h6 (cont)
1230   (shr-heading cont))
1231
1232 (defun shr-tag-hr (cont)
1233   (shr-ensure-newline)
1234   (insert (make-string shr-width shr-hr-line) "\n"))
1235
1236 (defun shr-tag-title (cont)
1237   (shr-heading cont 'bold 'underline))
1238
1239 (defun shr-tag-font (cont)
1240   (let* ((start (point))
1241          (color (cdr (assq :color cont)))
1242          (shr-stylesheet (nconc (list (cons 'color color))
1243                                 shr-stylesheet)))
1244     (shr-generic cont)
1245     (when color
1246       (shr-colorize-region start (point) color
1247                            (cdr (assq 'background-color shr-stylesheet))))))
1248
1249 ;;; Table rendering algorithm.
1250
1251 ;; Table rendering is the only complicated thing here.  We do this by
1252 ;; first counting how many TDs there are in each TR, and registering
1253 ;; how wide they think they should be ("width=45%", etc).  Then we
1254 ;; render each TD separately (this is done in temporary buffers, so
1255 ;; that we can use all the rendering machinery as if we were in the
1256 ;; main buffer).  Now we know how much space each TD really takes, so
1257 ;; we then render everything again with the new widths, and finally
1258 ;; insert all these boxes into the main buffer.
1259 (defun shr-tag-table-1 (cont)
1260   (setq cont (or (cdr (assq 'tbody cont))
1261                  cont))
1262   (let* ((shr-inhibit-images t)
1263          (shr-table-depth (1+ shr-table-depth))
1264          (shr-kinsoku-shorten t)
1265          ;; Find all suggested widths.
1266          (columns (shr-column-specs cont))
1267          ;; Compute how many characters wide each TD should be.
1268          (suggested-widths (shr-pro-rate-columns columns))
1269          ;; Do a "test rendering" to see how big each TD is (this can
1270          ;; be smaller (if there's little text) or bigger (if there's
1271          ;; unbreakable text).
1272          (sketch (shr-make-table cont suggested-widths))
1273          ;; Compute the "natural" width by setting each column to 500
1274          ;; characters and see how wide they really render.
1275          (natural (shr-make-table cont (make-vector (length columns) 500)))
1276          (sketch-widths (shr-table-widths sketch natural suggested-widths)))
1277     ;; This probably won't work very well.
1278     (when (> (+ (loop for width across sketch-widths
1279                       summing (1+ width))
1280                 shr-indentation 1)
1281              (frame-width))
1282       (setq truncate-lines t))
1283     ;; Then render the table again with these new "hard" widths.
1284     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths)))
1285
1286 (defun shr-tag-table (cont)
1287   (shr-ensure-paragraph)
1288   (let* ((caption (cdr (assq 'caption cont)))
1289          (header (cdr (assq 'thead cont)))
1290          (body (or (cdr (assq 'tbody cont)) cont))
1291          (footer (cdr (assq 'tfoot cont)))
1292          (bgcolor (cdr (assq :bgcolor cont)))
1293          (start (point))
1294          (shr-stylesheet (nconc (list (cons 'background-color bgcolor))
1295                                 shr-stylesheet))
1296          (nheader (if header (shr-max-columns header)))
1297          (nbody (if body (shr-max-columns body)))
1298          (nfooter (if footer (shr-max-columns footer))))
1299     (if (and (not caption)
1300              (not header)
1301              (not (cdr (assq 'tbody cont)))
1302              (not (cdr (assq 'tr cont)))
1303              (not footer))
1304         ;; The table is totally invalid and just contains random junk.
1305         ;; Try to output it anyway.
1306         (shr-generic cont)
1307       ;; It's a real table, so render it.
1308       (shr-tag-table-1
1309        (nconc
1310         (if caption `((tr (td ,@caption))))
1311         (if header
1312             (if footer
1313                 ;; hader + body + footer
1314                 (if (= nheader nbody)
1315                     (if (= nbody nfooter)
1316                         `((tr (td (table (tbody ,@header ,@body ,@footer)))))
1317                       (nconc `((tr (td (table (tbody ,@header ,@body)))))
1318                              (if (= nfooter 1)
1319                                  footer
1320                                `((tr (td (table (tbody ,@footer))))))))
1321                   (nconc `((tr (td (table (tbody ,@header)))))
1322                          (if (= nbody nfooter)
1323                              `((tr (td (table (tbody ,@body ,@footer)))))
1324                            (nconc `((tr (td (table (tbody ,@body)))))
1325                                   (if (= nfooter 1)
1326                                       footer
1327                                     `((tr (td (table (tbody ,@footer))))))))))
1328               ;; header + body
1329               (if (= nheader nbody)
1330                   `((tr (td (table (tbody ,@header ,@body)))))
1331                 (if (= nheader 1)
1332                     `(,@header (tr (td (table (tbody ,@body)))))
1333                   `((tr (td (table (tbody ,@header))))
1334                     (tr (td (table (tbody ,@body))))))))
1335           (if footer
1336               ;; body + footer
1337               (if (= nbody nfooter)
1338                   `((tr (td (table (tbody ,@body ,@footer)))))
1339                 (nconc `((tr (td (table (tbody ,@body)))))
1340                        (if (= nfooter 1)
1341                            footer
1342                          `((tr (td (table (tbody ,@footer))))))))
1343             (if caption
1344                 `((tr (td (table (tbody ,@body)))))
1345               body))))))
1346     (when bgcolor
1347       (shr-colorize-region start (point) (cdr (assq 'color shr-stylesheet))
1348                            bgcolor))
1349     ;; Finally, insert all the images after the table.  The Emacs buffer
1350     ;; model isn't strong enough to allow us to put the images actually
1351     ;; into the tables.
1352     (when (zerop shr-table-depth)
1353       (dolist (elem (shr-find-elements cont 'img))
1354         (shr-tag-img (cdr elem))))))
1355
1356 (defun shr-find-elements (cont type)
1357   (let (result)
1358     (dolist (elem cont)
1359       (cond ((eq (car elem) type)
1360              (push elem result))
1361             ((consp (cdr elem))
1362              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
1363     (nreverse result)))
1364
1365 (defun shr-insert-table (table widths)
1366   (let* ((collapse (equal (cdr (assq 'border-collapse shr-stylesheet))
1367                           "collapse"))
1368          (shr-table-separator-length (if collapse 0 1))
1369          (shr-table-vertical-line (if collapse "" shr-table-vertical-line)))
1370     (unless collapse
1371       (shr-insert-table-ruler widths))
1372     (dolist (row table)
1373       (let ((start (point))
1374             (height (let ((max 0))
1375                       (dolist (column row)
1376                         (setq max (max max (cadr column))))
1377                       max)))
1378         (dotimes (i height)
1379           (shr-indent)
1380           (insert shr-table-vertical-line "\n"))
1381         (dolist (column row)
1382           (goto-char start)
1383           (let ((lines (nth 2 column)))
1384             (dolist (line lines)
1385               (end-of-line)
1386               (insert line shr-table-vertical-line)
1387               (forward-line 1))
1388             ;; Add blank lines at padding at the bottom of the TD,
1389             ;; possibly.
1390             (dotimes (i (- height (length lines)))
1391               (end-of-line)
1392               (let ((start (point)))
1393                 (insert (make-string (string-width (car lines)) ? )
1394                         shr-table-vertical-line)
1395                 (when (nth 4 column)
1396                   (shr-add-font start (1- (point))
1397                                 (list :background (nth 4 column)))))
1398               (forward-line 1)))))
1399       (unless collapse
1400         (shr-insert-table-ruler widths)))))
1401
1402 (defun shr-insert-table-ruler (widths)
1403   (when shr-table-horizontal-line
1404     (when (and (bolp)
1405                (> shr-indentation 0))
1406       (shr-indent))
1407     (insert shr-table-corner)
1408     (dotimes (i (length widths))
1409       (insert (make-string (aref widths i) shr-table-horizontal-line)
1410               shr-table-corner))
1411     (insert "\n")))
1412
1413 (defun shr-table-widths (table natural-table suggested-widths)
1414   (let* ((length (length suggested-widths))
1415          (widths (make-vector length 0))
1416          (natural-widths (make-vector length 0)))
1417     (dolist (row table)
1418       (let ((i 0))
1419         (dolist (column row)
1420           (aset widths i (max (aref widths i) column))
1421           (setq i (1+ i)))))
1422     (dolist (row natural-table)
1423       (let ((i 0))
1424         (dolist (column row)
1425           (aset natural-widths i (max (aref natural-widths i) column))
1426           (setq i (1+ i)))))
1427     (let ((extra (- (apply '+ (append suggested-widths nil))
1428                     (apply '+ (append widths nil))))
1429           (expanded-columns 0))
1430       ;; We have extra, unused space, so divide this space amongst the
1431       ;; columns.
1432       (when (> extra 0)
1433         ;; If the natural width is wider than the rendered width, we
1434         ;; want to allow the column to expand.
1435         (dotimes (i length)
1436           (when (> (aref natural-widths i) (aref widths i))
1437             (setq expanded-columns (1+ expanded-columns))))
1438         (dotimes (i length)
1439           (when (> (aref natural-widths i) (aref widths i))
1440             (aset widths i (min
1441                             (aref natural-widths i)
1442                             (+ (/ extra expanded-columns)
1443                                (aref widths i))))))))
1444     widths))
1445
1446 (defun shr-make-table (cont widths &optional fill)
1447   (or (cadr (assoc (list cont widths fill) shr-content-cache))
1448       (let ((data (shr-make-table-1 cont widths fill)))
1449         (push (list (list cont widths fill) data)
1450               shr-content-cache)
1451         data)))
1452
1453 (defun shr-make-table-1 (cont widths &optional fill)
1454   (let ((trs nil)
1455         (shr-inhibit-decoration (not fill))
1456         (rowspans (make-vector (length widths) 0))
1457         width colspan)
1458     (dolist (row cont)
1459       (when (eq (car row) 'tr)
1460         (let ((tds nil)
1461               (columns (cdr row))
1462               (i 0)
1463               (width-column 0)
1464               column)
1465           (while (< i (length widths))
1466             ;; If we previously had a rowspan definition, then that
1467             ;; means that we now have a "missing" td/th element here.
1468             ;; So just insert a dummy, empty one to (sort of) emulate
1469             ;; rowspan.
1470             (setq column
1471                   (if (zerop (aref rowspans i))
1472                       (pop columns)
1473                     (aset rowspans i (1- (aref rowspans i)))
1474                     '(td)))
1475             (when (or (memq (car column) '(td th))
1476                       (not column))
1477               (when (cdr (assq :rowspan (cdr column)))
1478                 (aset rowspans i (+ (aref rowspans i)
1479                                     (1- (string-to-number
1480                                          (cdr (assq :rowspan (cdr column))))))))
1481               ;; Sanity check for invalid column-spans.
1482               (when (>= width-column (length widths))
1483                 (setq width-column 0))
1484               (setq width
1485                     (if column
1486                         (aref widths width-column)
1487                       10))
1488               (when (and fill
1489                          (setq colspan (cdr (assq :colspan (cdr column)))))
1490                 (setq colspan (string-to-number colspan))
1491                 (dotimes (j (1- colspan))
1492                   (if (> (+ i 1 j) (1- (length widths)))
1493                       (setq width (aref widths (1- (length widths))))
1494                     (setq width (+ width
1495                                    shr-table-separator-length
1496                                    (aref widths (+ i 1 j))))))
1497                 (setq width-column (+ width-column (1- colspan))))
1498               (when (or column
1499                         (not fill))
1500                 ;; Sanity check for degenerate tables.
1501                 (when (zerop width)
1502                   (setq width 10))
1503                 (push (shr-render-td (cdr column) width fill)
1504                       tds))
1505               (setq i (1+ i)
1506                     width-column (1+ width-column))))
1507           (push (nreverse tds) trs))))
1508     (nreverse trs)))
1509
1510 (defun shr-render-td (cont width fill)
1511   (when (= width 0) (debug))
1512   (with-temp-buffer
1513     (let ((bgcolor (cdr (assq :bgcolor cont)))
1514           (fgcolor (cdr (assq :fgcolor cont)))
1515           (style (cdr (assq :style cont)))
1516           (shr-stylesheet shr-stylesheet)
1517           actual-colors)
1518       (when style
1519         (setq style (and (string-match "color" style)
1520                          (shr-parse-style style))))
1521       (when bgcolor
1522         (setq style (nconc (list (cons 'background-color bgcolor)) style)))
1523       (when fgcolor
1524         (setq style (nconc (list (cons 'color fgcolor)) style)))
1525       (when style
1526         (setq shr-stylesheet (append style shr-stylesheet)))
1527       (let ((shr-width width)
1528             (shr-indentation 0))
1529         (shr-descend (cons 'td cont)))
1530       ;; Delete padding at the bottom of the TDs.
1531       (delete-region
1532        (point)
1533        (progn
1534          (skip-chars-backward " \t\n")
1535          (end-of-line)
1536          (point)))
1537       (goto-char (point-min))
1538       (let ((max 0))
1539         (while (not (eobp))
1540           (end-of-line)
1541           (setq max (max max (current-column)))
1542           (forward-line 1))
1543         (when fill
1544           (goto-char (point-min))
1545           ;; If the buffer is totally empty, then put a single blank
1546           ;; line here.
1547           (if (zerop (buffer-size))
1548               (insert (make-string width ? ))
1549             ;; Otherwise, fill the buffer.
1550             (let ((align (cdr (assq :align cont)))
1551                   length)
1552               (while (not (eobp))
1553                 (end-of-line)
1554                 (setq length (- width (current-column)))
1555                 (when (> length 0)
1556                   (cond
1557                    ((equal align "right")
1558                     (beginning-of-line)
1559                     (insert (make-string length ? )))
1560                    ((equal align "center")
1561                     (insert (make-string (/ length 2) ? ))
1562                     (beginning-of-line)
1563                     (insert (make-string (- length (/ length 2)) ? )))
1564                    (t
1565                     (insert (make-string length ? )))))
1566                 (forward-line 1))))
1567           (when style
1568             (setq actual-colors
1569                   (shr-colorize-region
1570                    (point-min) (point-max)
1571                    (cdr (assq 'color shr-stylesheet))
1572                    (cdr (assq 'background-color shr-stylesheet))))))
1573         (if fill
1574             (list max
1575                   (count-lines (point-min) (point-max))
1576                   (split-string (buffer-string) "\n")
1577                   nil
1578                   (car actual-colors))
1579           max)))))
1580
1581 (defun shr-buffer-width ()
1582   (goto-char (point-min))
1583   (let ((max 0))
1584     (while (not (eobp))
1585       (end-of-line)
1586       (setq max (max max (current-column)))
1587       (forward-line 1))
1588     max))
1589
1590 (defun shr-pro-rate-columns (columns)
1591   (let ((total-percentage 0)
1592         (widths (make-vector (length columns) 0)))
1593     (dotimes (i (length columns))
1594       (setq total-percentage (+ total-percentage (aref columns i))))
1595     (setq total-percentage (/ 1.0 total-percentage))
1596     (dotimes (i (length columns))
1597       (aset widths i (max (truncate (* (aref columns i)
1598                                        total-percentage
1599                                        (- shr-width (1+ (length columns)))))
1600                           10)))
1601     widths))
1602
1603 ;; Return a summary of the number and shape of the TDs in the table.
1604 (defun shr-column-specs (cont)
1605   (let ((columns (make-vector (shr-max-columns cont) 1)))
1606     (dolist (row cont)
1607       (when (eq (car row) 'tr)
1608         (let ((i 0))
1609           (dolist (column (cdr row))
1610             (when (memq (car column) '(td th))
1611               (let ((width (cdr (assq :width (cdr column)))))
1612                 (when (and width
1613                            (string-match "\\([0-9]+\\)%" width)
1614                            (not (zerop (setq width (string-to-number
1615                                                     (match-string 1 width))))))
1616                   (aset columns i (/ width 100.0))))
1617               (setq i (1+ i)))))))
1618     columns))
1619
1620 (defun shr-count (cont elem)
1621   (let ((i 0))
1622     (dolist (sub cont)
1623       (when (eq (car sub) elem)
1624         (setq i (1+ i))))
1625     i))
1626
1627 (defun shr-max-columns (cont)
1628   (let ((max 0))
1629     (dolist (row cont)
1630       (when (eq (car row) 'tr)
1631         (setq max (max max (+ (shr-count (cdr row) 'td)
1632                               (shr-count (cdr row) 'th))))))
1633     max))
1634
1635 (provide 'shr)
1636
1637 ;; Local Variables:
1638 ;; coding: utf-8
1639 ;; End:
1640
1641 ;;; shr.el ends here