HCoop / bpt / emacs.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
(XTread_socket): Fix last change.
[bpt/emacs.git] / configure.in
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
25
26 AC_PREREQ(2.53)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
29
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
33
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir='${localstatedir}/games/emacs'
42
43 gameuser=games
44
45 AC_ARG_WITH(gcc,
46 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
47 AC_ARG_WITH(pop,
48 [ --without-pop don't support POP mail retrieval with movemail],
49 [if test "$withval" = yes; then
50 AC_DEFINE(MAIL_USE_POP)
51 else :
52 fi],
53 AC_DEFINE(MAIL_USE_POP))
54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
55 AC_ARG_WITH(kerberos,
56 [ --with-kerberos support Kerberos-authenticated POP],
57 [AC_DEFINE(KERBEROS)])
58 AH_TEMPLATE(KERBEROS,
59 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
60 AC_ARG_WITH(kerberos5,
61 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
62 [if test "${with_kerberos5+set}" = set; then
63 if test "${with_kerberos+set}" != set; then
64 with_kerberos=yes
65 AC_DEFINE(KERBEROS)
66 fi
67 fi
68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
69 AC_ARG_WITH(hesiod,
70 [ --with-hesiod support Hesiod to get the POP server host],
71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
72
73 AC_ARG_WITH(sound,
74 [ --without-sound don't compile with sound support])
75
76 dnl This should be the last --with option, because --with-x is
77 dnl added later on when we find the path of X, and it's best to
78 dnl keep them together visually.
79 AC_ARG_WITH(x-toolkit,
80 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
81 [ case "${withval}" in
82 y | ye | yes ) val=athena ;;
83 n | no ) val=no ;;
84 l | lu | luc | luci | lucid ) val=lucid ;;
85 a | at | ath | athe | athen | athena ) val=athena ;;
86 m | mo | mot | moti | motif ) val=motif ;;
87 dnl These don't currently work.
88 dnl o | op | ope | open | open- | open-l | open-lo \
89 dnl | open-loo | open-look ) val=open-look ;;
90 * )
91 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
92 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
93 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
94 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
95 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
96 ;;
97 esac
98 with_x_toolkit=$val
99 ])
100 AC_ARG_WITH(xpm,
101 [ --with-xpm use -lXpm for displaying XPM images])
102 AC_ARG_WITH(jpeg,
103 [ --with-jpeg use -ljpeg for displaying JPEG images])
104 AC_ARG_WITH(tiff,
105 [ --with-tiff use -ltiff for displaying TIFF images])
106 AC_ARG_WITH(gif,
107 [ --with-gif use -lungif for displaying GIF images])
108 AC_ARG_WITH(png,
109 [ --with-png use -lpng for displaying PNG images])
110 AC_ARG_WITH(toolkit-scroll-bars,
111 [ --without-toolkit-scroll-bars
112 don't use Motif or Xaw3d scroll bars])
113 AC_ARG_WITH(xim,
114 [ --without-xim don't use X11 XIM])
115 AC_ARG_WITH(carbon,
116 [ --without-carbon don't use Carbon GUI on Mac OS X])
117
118 #### Make srcdir absolute, if it isn't already. It's important to
119 #### avoid running the path through pwd unnecessarily, since pwd can
120 #### give you automounter prefixes, which can go away. We do all this
121 #### so Emacs can find its files when run uninstalled.
122 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
123 unset CDPATH
124 case "${srcdir}" in
125 /* ) ;;
126 . )
127 ## We may be able to use the $PWD environment variable to make this
128 ## absolute. But sometimes PWD is inaccurate.
129 ## Note: we used to use ${PWD} at the end instead of `pwd`,
130 ## but that tested only for a well-formed and valid PWD,
131 ## it did not object when PWD was well-formed and valid but just wrong.
132 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
133 then
134 srcdir="$PWD"
135 else
136 srcdir="`(cd ${srcdir}; pwd)`"
137 fi
138 ;;
139 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
140 esac
141
142 #### Check if the source directory already has a configured system in it.
143 if test `pwd` != `(cd ${srcdir} && pwd)` \
144 && test -f "${srcdir}/src/config.h" ; then
145 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
146 as a build directory right now; it has been configured in its own
147 right. To configure in another directory as well, you MUST
148 use GNU make. If you do not have GNU make, then you must
149 now do \`make distclean' in ${srcdir},
150 and then run $0 again.])
151
152 changequote(, )dnl
153 extrasub='/^VPATH[ ]*=/c\
154 changequote([, ])dnl
155 vpath %.c $(srcdir)\
156 vpath %.h $(srcdir)\
157 vpath %.y $(srcdir)\
158 vpath %.l $(srcdir)\
159 vpath %.s $(srcdir)\
160 vpath %.in $(srcdir)\
161 vpath %.texi $(srcdir)'
162 fi
163
164 #### Given the configuration name, set machfile and opsysfile to the
165 #### names of the m/*.h and s/*.h files we should use.
166
167 ### Canonicalize the configuration name.
168
169 AC_CANONICAL_HOST
170 canonical=$host
171 configuration=${host_alias-$host}
172
173 changequote(, )dnl
174
175 ### If you add support for a new configuration, add code to this
176 ### switch statement to recognize your configuration name and select
177 ### the appropriate operating system and machine description files.
178
179 ### You would hope that you could choose an m/*.h file pretty much
180 ### based on the machine portion of the configuration name, and an s-
181 ### file based on the operating system portion. However, it turns out
182 ### that each m/*.h file is pretty manufacturer-specific - for
183 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
184 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
185 ### machines. So we basically have to have a special case for each
186 ### configuration name.
187 ###
188 ### As far as handling version numbers on operating systems is
189 ### concerned, make sure things will fail in a fixable way. If
190 ### /etc/MACHINES doesn't say anything about version numbers, be
191 ### prepared to handle anything reasonably. If version numbers
192 ### matter, be sure /etc/MACHINES says something about it.
193 ###
194 ### Eric Raymond says we should accept strings like "sysvr4" to mean
195 ### "System V Release 4"; he writes, "The old convention encouraged
196 ### confusion between `system' and `release' levels'."
197
198 machine='' opsys='' unported=no
199 case "${canonical}" in
200
201 ## FreeBSD ports
202 *-*-freebsd* )
203 opsys=freebsd
204 case "${canonical}" in
205 alpha*-*-freebsd*) machine=alpha ;;
206 i[3456]86-*-freebsd*) machine=intel386 ;;
207 esac
208 ;;
209
210 ## NetBSD ports
211 *-*-netbsd* )
212 opsys=netbsd
213 case "${canonical}" in
214 alpha*-*-netbsd*) machine=alpha ;;
215 i[3456]86-*-netbsd*) machine=intel386 ;;
216 m68k-*-netbsd*)
217 # This is somewhat bogus.
218 machine=hp9000s300 ;;
219 powerpc-apple-netbsd*) machine=macppc ;;
220 mips-*-netbsd*) machine=pmax ;;
221 mipsel-*-netbsd*) machine=pmax ;;
222 mipseb-*-netbsd*) machine=pmax ;;
223 ns32k-*-netbsd*) machine=ns32000 ;;
224 powerpc-*-netbsd*) machine=macppc ;;
225 sparc*-*-netbsd*) machine=sparc ;;
226 vax-*-netbsd*) machine=vax ;;
227 arm-*-netbsd*) machine=arm ;;
228 esac
229 ;;
230
231 ## OpenBSD ports
232 *-*-openbsd* )
233 opsys=openbsd
234 case "${canonical}" in
235 alpha*-*-openbsd*) machine=alpha ;;
236 i386-*-openbsd*) machine=intel386 ;;
237 m68k-*-openbsd*) machine=hp9000s300 ;;
238 mipsel-*-openbsd*) machine=pmax ;;
239 ns32k-*-openbsd*) machine=ns32000 ;;
240 sparc-*-openbsd*) machine=sparc ;;
241 vax-*-openbsd*) machine=vax ;;
242 esac
243 ;;
244
245 ## Acorn RISCiX:
246 arm-acorn-riscix1.1* )
247 machine=acorn opsys=riscix1-1
248 ;;
249 arm-acorn-riscix1.2* | arm-acorn-riscix )
250 ## This name is riscix12 instead of riscix1.2
251 ## to avoid a file name conflict on MSDOS.
252 machine=acorn opsys=riscix12
253 ;;
254
255 ## BSDI ports
256 *-*-bsdi* )
257 opsys=bsdi
258 case "${canonical}" in
259 i[345]86-*-bsdi*) machine=intel386 ;;
260 sparc-*-bsdi*) machine=sparc ;;
261 powerpc-*-bsdi*) machine=macppc ;;
262 esac
263 case "${canonical}" in
264 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
265 *-*-bsdi2.0* ) opsys=bsdos2 ;;
266 *-*-bsdi2* ) opsys=bsdos2-1 ;;
267 *-*-bsdi3* ) opsys=bsdos3 ;;
268 *-*-bsdi[45]* ) opsys=bsdos4 ;;
269 esac
270 ;;
271
272 ## Alliant machines
273 ## Strictly speaking, we need the version of the alliant operating
274 ## system to choose the right machine file, but currently the
275 ## configuration name doesn't tell us enough to choose the right
276 ## one; we need to give alliants their own operating system name to
277 ## do this right. When someone cares, they can help us.
278 fx80-alliant-* )
279 machine=alliant4 opsys=bsd4-2
280 ;;
281 i860-alliant-* )
282 machine=alliant-2800 opsys=bsd4-3
283 ;;
284
285 ## Alpha (DEC) machines.
286 alpha*-dec-osf* )
287 machine=alpha opsys=osf1
288 # This is needed to find X11R6.1 libraries for certain tests.
289 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
290 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
291 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
292 # due to non-traditional preprocessing with the current compiler
293 # defaults. OSF 4 can also have that compiler version, and there
294 # seems always to have been a usable /usr/bin/cpp.
295 NON_GNU_CPP=/usr/bin/cpp
296 case "${canonical}" in
297 alpha*-dec-osf[5-9]*)
298 opsys=osf5-0 ;;
299 esac
300 ;;
301
302 alpha*-*-linux-gnu* )
303 machine=alpha opsys=gnu-linux
304 ;;
305
306 arm*-*-linux-gnu* )
307 machine=arm opsys=gnu-linux
308 ;;
309
310 ppc-*-linux | \
311 powerpc-*-linux* )
312 machine=macppc opsys=gnu-linux
313 ;;
314
315 ## Altos 3068
316 m68*-altos-sysv* )
317 machine=altos opsys=usg5-2
318 ;;
319
320 ## Amdahl UTS
321 580-amdahl-sysv* )
322 machine=amdahl opsys=usg5-2-2
323 ;;
324
325 ## Apollo, Domain/OS
326 m68*-apollo-* )
327 machine=apollo opsys=bsd4-3
328 ;;
329
330 ## AT&T 3b2, 3b5, 3b15, 3b20
331 we32k-att-sysv* )
332 machine=att3b opsys=usg5-2-2
333 ;;
334
335 ## AT&T 3b1 - The Mighty Unix PC!
336 m68*-att-sysv* )
337 machine=7300 opsys=usg5-2-2
338 ;;
339
340 ## Bull dpx20
341 rs6000-bull-bosx* )
342 machine=ibmrs6000 opsys=aix3-2
343 ;;
344
345 ## Bull dpx2
346 m68*-bull-sysv3* )
347 machine=dpx2 opsys=usg5-3
348 ;;
349
350 ## Bull sps7
351 m68*-bull-sysv2* )
352 machine=sps7 opsys=usg5-2
353 ;;
354
355 ## CCI 5/32, 6/32 -- see "Tahoe".
356
357 ## Celerity
358 ## I don't know what configuration name to use for this; config.sub
359 ## doesn't seem to know anything about it. Hey, Celerity users, get
360 ## in touch with us!
361 celerity-celerity-bsd* )
362 machine=celerity opsys=bsd4-2
363 ;;
364
365 ## Clipper
366 ## What operating systems does this chip run that Emacs has been
367 ## tested on?
368 clipper-* )
369 machine=clipper
370 ## We'll use the catch-all code at the bottom to guess the
371 ## operating system.
372 ;;
373
374 ## Compaq Nonstop
375 mips-compaq-nonstopux* )
376 machine=nonstopux opsys=nonstopux
377 ;;
378
379 ## Convex
380 *-convex-bsd* | *-convex-convexos* )
381 machine=convex opsys=bsd4-3
382 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
383 NON_GNU_CPP="cc -E -P"
384 ;;
385
386 ## Cubix QBx/386
387 i[3456]86-cubix-sysv* )
388 machine=intel386 opsys=usg5-3
389 ;;
390
391 ## Cydra 5
392 cydra*-cydrome-sysv* )
393 machine=cydra5 opsys=usg5-3
394 ;;
395
396 ## Data General AViiON Machines
397 ## DG changed naming conventions with the release of 5.4.4.10, they
398 ## dropped the initial 5.4 but left the intervening R. Because of the
399 ## R this shouldn't conflict with older versions of the OS (which I
400 ## think were named like dgux4.*). In addition, DG new AViiONs series
401 ## uses either Motorola M88k or Intel Pentium CPUs.
402 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
403 machine=aviion opsys=dgux4
404 ;;
405 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
406 ## This name is dgux5-4-3 instead of dgux5-4r3
407 ## to avoid a file name conflict on MSDOS.
408 machine=aviion opsys=dgux5-4-3
409 ;;
410 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
411 machine=aviion opsys=dgux5-4r2
412 ;;
413 m88k-dg-dgux* )
414 machine=aviion opsys=dgux
415 ;;
416
417 ## Data General AViiON Intel (x86) Machines
418 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
419 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
420 i[345]86-dg-dguxR4* )
421 machine=aviion-intel opsys=dgux4
422 ;;
423
424 ## DECstations
425 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
426 machine=pmax opsys=bsd4-2
427 ;;
428 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
429 machine=pmax opsys=bsd4-3
430 ;;
431 mips-dec-ultrix* )
432 machine=pmax opsys=ultrix4-3
433 ;;
434 mips-dec-osf* )
435 machine=pmax opsys=osf1
436 ;;
437 mips-dec-mach_bsd4.3* )
438 machine=pmax opsys=mach-bsd4-3
439 ;;
440
441 ## Motorola Delta machines
442 m68k-motorola-sysv* | m68000-motorola-sysv* )
443 machine=delta opsys=usg5-3
444 if test -z "`type gnucc | grep 'not found'`"
445 then
446 if test -s /etc/167config
447 then CC="gnucc -m68040"
448 else CC="gnucc -m68881"
449 fi
450 else
451 if test -z "`type gcc | grep 'not found'`"
452 then CC=gcc
453 else CC=cc
454 fi
455 fi
456 ;;
457 m88k-motorola-sysv4* )
458 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
459 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
460 # I hope there are not other 4.0 versions for this machine
461 # which really need usg5-4 instead.
462 machine=delta88k opsys=usg5-4-2
463 ;;
464 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
465 machine=delta88k opsys=usg5-3
466 ;;
467
468 ## Dual machines
469 m68*-dual-sysv* )
470 machine=dual opsys=usg5-2
471 ;;
472 m68*-dual-uniplus* )
473 machine=dual opsys=unipl5-2
474 ;;
475
476 ## Elxsi 6400
477 elxsi-elxsi-sysv* )
478 machine=elxsi opsys=usg5-2
479 ;;
480
481 ## Encore machines
482 ns16k-encore-bsd* )
483 machine=ns16000 opsys=umax
484 ;;
485
486 ## The GEC 63 - apparently, this port isn't really finished yet.
487 # I'm sure we finished off the last of the machines, though. -- fx
488
489 ## Gould Power Node and NP1
490 pn-gould-bsd4.2* )
491 machine=gould opsys=bsd4-2
492 ;;
493 pn-gould-bsd4.3* )
494 machine=gould opsys=bsd4-3
495 ;;
496 np1-gould-bsd* )
497 machine=gould-np1 opsys=bsd4-3
498 ;;
499
500 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
501 ## as far as Emacs is concerned).
502 m88k-harris-cxux* )
503 # Build needs to be different on 7.0 and later releases
504 case "`uname -r`" in
505 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
506 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
507 esac
508 NON_GNU_CPP="/lib/cpp"
509 ;;
510 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
511 m68k-harris-cxux* )
512 machine=nh3000 opsys=cxux
513 ;;
514 ## Harris power pc NightHawk running Power UNIX (Series 6000)
515 powerpc-harris-powerunix )
516 machine=nh6000 opsys=powerunix
517 NON_GNU_CPP="cc -Xo -E -P"
518 ;;
519 ## SR2001/SR2201 running HI-UX/MPP
520 hppa1.1-hitachi-hiuxmpp* )
521 machine=sr2k opsys=hiuxmpp
522 ;;
523 hppa1.1-hitachi-hiuxwe2* )
524 machine=sr2k opsys=hiuxwe2
525 ;;
526 ## Honeywell XPS100
527 xps*-honeywell-sysv* )
528 machine=xps100 opsys=usg5-2
529 ;;
530
531 ## HP 9000 series 200 or 300
532 m68*-hp-bsd* )
533 machine=hp9000s300 opsys=bsd4-3
534 ;;
535 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
536 m68*-hp-hpux* )
537 case "`uname -r`" in
538 ## Someone's system reports A.B8.05 for this.
539 ## I wonder what other possibilities there are.
540 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
541 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
542 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
543 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
544 *) machine=hp9000s300 opsys=hpux ;;
545 esac
546 ;;
547
548 ## HP 9000 series 700 and 800, running HP/UX
549 hppa*-hp-hpux7* )
550 machine=hp800 opsys=hpux
551 ;;
552 hppa*-hp-hpux8* )
553 machine=hp800 opsys=hpux8
554 ;;
555 hppa*-hp-hpux9shr* )
556 machine=hp800 opsys=hpux9shr
557 ;;
558 hppa*-hp-hpux9* )
559 machine=hp800 opsys=hpux9
560 ;;
561 hppa*-hp-hpux10* )
562 machine=hp800 opsys=hpux10
563 ;;
564 hppa*-hp-hpux1[1-9]* )
565 machine=hp800 opsys=hpux11
566 ;;
567
568 hppa*-*-linux-gnu* )
569 machine=hp800 opsys=gnu-linux
570 ;;
571
572 ## HP 9000 series 700 and 800, running HP/UX
573 hppa*-hp-hpux* )
574 ## Cross-compilation? Nah!
575 case "`uname -r`" in
576 ## Someone's system reports A.B8.05 for this.
577 ## I wonder what other possibilities there are.
578 *.B8.* ) machine=hp800 opsys=hpux8 ;;
579 *.08.* ) machine=hp800 opsys=hpux8 ;;
580 *.09.* ) machine=hp800 opsys=hpux9 ;;
581 *) machine=hp800 opsys=hpux10 ;;
582 esac
583 ;;
584 hppa*-*-nextstep* )
585 machine=hp800 opsys=nextstep
586 ;;
587
588 ## Orion machines
589 orion-orion-bsd* )
590 machine=orion opsys=bsd4-2
591 ;;
592 clipper-orion-bsd* )
593 machine=orion105 opsys=bsd4-2
594 ;;
595
596 ## IBM machines
597 i[3456]86-ibm-aix1.1* )
598 machine=ibmps2-aix opsys=usg5-2-2
599 ;;
600 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
601 machine=ibmps2-aix opsys=usg5-3
602 ;;
603 i370-ibm-aix*)
604 machine=ibm370aix opsys=usg5-3
605 ;;
606 s390-*-linux-gnu)
607 machine=ibms390 opsys=gnu-linux
608 ;;
609 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
610 machine=ibmrs6000 opsys=aix3-1
611 ;;
612 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
613 machine=ibmrs6000 opsys=aix3-2-5
614 ;;
615 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
616 machine=ibmrs6000 opsys=aix4-1
617 ;;
618 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
619 machine=ibmrs6000 opsys=aix4-2
620 ;;
621 rs6000-ibm-aix5.1* | powerpc-ibm-aix5.1* )
622 machine=ibmrs6000 opsys=aix4-2
623 ;;
624 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
625 machine=ibmrs6000 opsys=aix4
626 ;;
627 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
628 machine=ibmrs6000 opsys=aix4-1
629 ;;
630 rs6000-ibm-aix* | powerpc-ibm-aix* )
631 machine=ibmrs6000 opsys=aix3-2
632 ;;
633 romp-ibm-bsd4.3* )
634 machine=ibmrt opsys=bsd4-3
635 ;;
636 romp-ibm-bsd4.2* )
637 machine=ibmrt opsys=bsd4-2
638 ;;
639 romp-ibm-aos4.3* )
640 machine=ibmrt opsys=bsd4-3
641 ;;
642 romp-ibm-aos4.2* )
643 machine=ibmrt opsys=bsd4-2
644 ;;
645 romp-ibm-aos* )
646 machine=ibmrt opsys=bsd4-3
647 ;;
648 romp-ibm-bsd* )
649 machine=ibmrt opsys=bsd4-3
650 ;;
651 romp-ibm-aix* )
652 machine=ibmrt-aix opsys=usg5-2-2
653 ;;
654
655 ## Integrated Solutions `Optimum V'
656 m68*-isi-bsd4.2* )
657 machine=isi-ov opsys=bsd4-2
658 ;;
659 m68*-isi-bsd4.3* )
660 machine=isi-ov opsys=bsd4-3
661 ;;
662
663 ## Intel 386 machines where we do care about the manufacturer
664 i[3456]86-intsys-sysv* )
665 machine=is386 opsys=usg5-2-2
666 ;;
667
668 ## Prime EXL
669 i[3456]86-prime-sysv* )
670 machine=i386 opsys=usg5-3
671 ;;
672
673 ## Sequent Symmetry running Dynix
674 i[3456]86-sequent-bsd* )
675 machine=symmetry opsys=bsd4-3
676 ;;
677
678 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
679 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
680 machine=sequent-ptx opsys=ptx4
681 NON_GNU_CPP=/lib/cpp
682 ;;
683
684 ## Sequent Symmetry running DYNIX/ptx
685 ## Use the old cpp rather than the newer ANSI one.
686 i[3456]86-sequent-ptx* )
687 machine=sequent-ptx opsys=ptx
688 NON_GNU_CPP="/lib/cpp"
689 ;;
690
691 ## ncr machine running svr4.3.
692 i[3456]86-ncr-sysv4.3 )
693 machine=ncr386 opsys=usg5-4-3
694 ;;
695
696 ## Unspecified sysv on an ncr machine defaults to svr4.2.
697 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
698 i[3456]86-ncr-sysv* )
699 machine=ncr386 opsys=usg5-4-2
700 ;;
701
702 ## Intel Paragon OSF/1
703 i860-intel-osf1* )
704 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
705 ;;
706
707 ## Intel 860
708 i860-*-sysv4* )
709 machine=i860 opsys=usg5-4
710 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
711 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
712 ;;
713
714 ## Macintosh PowerPC
715 powerpc*-*-linux-gnu* )
716 machine=macppc opsys=gnu-linux
717 ;;
718
719 ## Masscomp machines
720 m68*-masscomp-rtu* )
721 machine=masscomp opsys=rtu
722 ;;
723
724 ## Megatest machines
725 m68*-megatest-bsd* )
726 machine=mega68 opsys=bsd4-2
727 ;;
728
729 ## Workstations sold by MIPS
730 ## This is not necessarily all workstations using the MIPS processor -
731 ## Irises are produced by SGI, and DECstations by DEC.
732
733 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
734 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
735 ## it gives for choosing between the alternatives seems to be "Use
736 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
737 ## the BSD world." I'll assume that these are instructions for
738 ## handling two odd situations, and that every other situation
739 ## should use mips.h and usg5-2-2, they being listed first.
740 mips-mips-usg* )
741 machine=mips4
742 ## Fall through to the general code at the bottom to decide on the OS.
743 ;;
744 mips-mips-riscos4* )
745 machine=mips4 opsys=bsd4-3
746 NON_GNU_CC="cc -systype bsd43"
747 NON_GNU_CPP="cc -systype bsd43 -E"
748 ;;
749 mips-mips-riscos5* )
750 machine=mips4 opsys=riscos5
751 NON_GNU_CC="cc -systype bsd43"
752 NON_GNU_CPP="cc -systype bsd43 -E"
753 ;;
754 mips-mips-bsd* )
755 machine=mips opsys=bsd4-3
756 ;;
757 mips-mips-* )
758 machine=mips opsys=usg5-2-2
759 ;;
760
761 ## NeXT
762 m68*-next-* | m68k-*-nextstep* )
763 machine=m68k opsys=nextstep
764 ;;
765
766 ## The complete machine from National Semiconductor
767 ns32k-ns-genix* )
768 machine=ns32000 opsys=usg5-2
769 ;;
770
771 ## NCR machines
772 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
773 machine=tower32 opsys=usg5-2-2
774 ;;
775 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
776 machine=tower32v3 opsys=usg5-3
777 ;;
778
779 ## NEC EWS4800
780 mips-nec-sysv4*)
781 machine=ews4800 opsys=ux4800
782 ;;
783
784 ## Nixdorf Targon 31
785 m68*-nixdorf-sysv* )
786 machine=targon31 opsys=usg5-2-2
787 ;;
788
789 ## Nu (TI or LMI)
790 m68*-nu-sysv* )
791 machine=nu opsys=usg5-2
792 ;;
793
794 ## Plexus
795 m68*-plexus-sysv* )
796 machine=plexus opsys=usg5-2
797 ;;
798
799 ## PowerPC reference platform
800 powerpcle-*-solaris2.5* )
801 machine=prep
802 opsys=sol2-5
803 ;;
804
805 ## PowerPC reference platform
806 powerpcle-*-solaris2* )
807 machine=prep
808 opsys=sol2-6
809 ;;
810
811 ## Pyramid machines
812 ## I don't really have any idea what sort of processor the Pyramid has,
813 ## so I'm assuming it is its own architecture.
814 pyramid-pyramid-bsd* )
815 machine=pyramid opsys=bsd4-2
816 ;;
817
818 ## Sequent Balance
819 ns32k-sequent-bsd4.2* )
820 machine=sequent opsys=bsd4-2
821 ;;
822 ns32k-sequent-bsd4.3* )
823 machine=sequent opsys=bsd4-3
824 ;;
825
826 ## Siemens Nixdorf
827 mips-siemens-sysv* | mips-sni-sysv*)
828 machine=mips-siemens opsys=usg5-4
829 NON_GNU_CC=/usr/ccs/bin/cc
830 NON_GNU_CPP=/usr/ccs/lib/cpp
831 ;;
832
833 ## Silicon Graphics machines
834 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
835 m68*-sgi-iris3.5* )
836 machine=irist opsys=iris3-5
837 ;;
838 m68*-sgi-iris3.6* | m68*-sgi-iris*)
839 machine=irist opsys=iris3-6
840 ;;
841 ## Iris 4D
842 mips-sgi-irix3* )
843 machine=iris4d opsys=irix3-3
844 ;;
845 mips-sgi-irix4* )
846 machine=iris4d opsys=irix4-0
847 ;;
848 mips-sgi-irix6.5 )
849 machine=iris4d opsys=irix6-5
850 # Without defining _LANGUAGE_C, things get masked out in the headers
851 # so that, for instance, grepping for `free' in stdlib.h fails and
852 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
853 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
854 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
855 ;;
856 mips-sgi-irix6* )
857 machine=iris4d opsys=irix6-0
858 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
859 # but presumably it does no harm.
860 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
861 # -32 probably isn't necessary in later v.6s -- anyone know which?
862 NON_GCC_TEST_OPTIONS=-32
863 ;;
864 mips-sgi-irix5.[01]* )
865 machine=iris4d opsys=irix5-0
866 ;;
867 mips-sgi-irix5* | mips-sgi-irix* )
868 machine=iris4d opsys=irix5-2
869 ;;
870
871 ## SONY machines
872 m68*-sony-bsd4.2* )
873 machine=news opsys=bsd4-2
874 ;;
875 m68*-sony-bsd4.3* )
876 machine=news opsys=bsd4-3
877 ;;
878 m68*-sony-newsos3* | m68*-sony-news3*)
879 machine=news opsys=bsd4-3
880 ;;
881 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
882 machine=news-risc opsys=bsd4-3
883 ;;
884 mips-sony-newsos6* )
885 machine=news-r6 opsys=newsos6
886 ;;
887 mips-sony-news* )
888 machine=news-risc opsys=newsos5
889 ;;
890
891 ## Stride
892 m68*-stride-sysv* )
893 machine=stride opsys=usg5-2
894 ;;
895
896 ## Suns
897 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
898 machine=sparc opsys=gnu-linux
899 ;;
900
901 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
902 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
903 | rs6000-*-solaris2*)
904 case "${canonical}" in
905 m68*-sunos1* ) machine=sun1 ;;
906 m68*-sunos2* ) machine=sun2 ;;
907 m68* ) machine=sun3 ;;
908 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
909 i[3456]86-*-* ) machine=intel386 ;;
910 powerpcle* ) machine=powerpcle ;;
911 powerpc* | rs6000* ) machine=ibmrs6000 ;;
912 sparc* ) machine=sparc ;;
913 * ) unported=yes ;;
914 esac
915 case "${canonical}" in
916 ## The Sun386 didn't get past 4.0.
917 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
918 *-sunos4.0* ) opsys=sunos4-0 ;;
919 *-sunos4.1.[3-9]*noshare )
920 ## This name is sunos413 instead of sunos4-1-3
921 ## to avoid a file name conflict on MSDOS.
922 opsys=sunos413
923 NON_GNU_CPP=/usr/lib/cpp
924 NON_GCC_TEST_OPTIONS=-Bstatic
925 GCC_TEST_OPTIONS=-static
926 ;;
927 *-sunos4.1.[3-9]* | *-sunos4shr*)
928 opsys=sunos4shr
929 NON_GNU_CPP=/usr/lib/cpp
930 ;;
931 *-sunos4* | *-sunos )
932 opsys=sunos4-1
933 NON_GCC_TEST_OPTIONS=-Bstatic
934 GCC_TEST_OPTIONS=-static
935 ;;
936 *-sunos5.3* | *-solaris2.3* )
937 opsys=sol2-3
938 NON_GNU_CPP=/usr/ccs/lib/cpp
939 ;;
940 *-sunos5.4* | *-solaris2.4* )
941 opsys=sol2-4
942 NON_GNU_CPP=/usr/ccs/lib/cpp
943 RANLIB="ar -ts"
944 ;;
945 *-sunos5.5* | *-solaris2.5* )
946 opsys=sol2-5
947 NON_GNU_CPP=/usr/ccs/lib/cpp
948 RANLIB="ar -ts"
949 ;;
950 *-sunos5.6* | *-solaris2.6* )
951 opsys=sol2-6
952 NON_GNU_CPP=/usr/ccs/lib/cpp
953 RANLIB="ar -ts"
954 ;;
955 *-sunos5* | *-solaris* )
956 opsys=sol2-6
957 NON_GNU_CPP=/usr/ccs/lib/cpp
958 ;;
959 * ) opsys=bsd4-2 ;;
960 esac
961 ## Watch out for a compiler that we know will not work.
962 case "${canonical}" in
963 *-solaris* | *-sunos5* )
964 if [ "x$CC" = x/usr/ucb/cc ]; then
965 ## /usr/ucb/cc doesn't work;
966 ## we should find some other compiler that does work.
967 unset CC
968 fi
969 ;;
970 *) ;;
971 esac
972 ;;
973 sparc-*-nextstep* )
974 machine=sparc opsys=nextstep
975 ;;
976
977 ## Tadpole 68k
978 m68*-tadpole-sysv* )
979 machine=tad68k opsys=usg5-3
980 ;;
981
982 ## Tahoe machines
983 tahoe-tahoe-bsd4.2* )
984 machine=tahoe opsys=bsd4-2
985 ;;
986 tahoe-tahoe-bsd4.3* )
987 machine=tahoe opsys=bsd4-3
988 ;;
989
990 ## Tandem Integrity S2
991 mips-tandem-sysv* )
992 machine=tandem-s2 opsys=usg5-3
993 ;;
994
995 ## Tektronix XD88
996 m88k-tektronix-sysv3* )
997 machine=tekxd88 opsys=usg5-3
998 ;;
999
1000 ## Tektronix 16000 box (6130?)
1001 ns16k-tektronix-bsd* )
1002 machine=ns16000 opsys=bsd4-2
1003 ;;
1004 ## Tektronix 4300
1005 ## src/m/tek4300.h hints that this is a m68k machine.
1006 m68*-tektronix-bsd* )
1007 machine=tek4300 opsys=bsd4-3
1008 ;;
1009
1010 ## Titan P2 or P3
1011 ## We seem to have lost the machine-description file titan.h!
1012 titan-titan-sysv* )
1013 machine=titan opsys=usg5-3
1014 ;;
1015
1016 ## Ustation E30 (SS5E)
1017 m68*-unisys-uniplus* )
1018 machine=ustation opsystem=unipl5-2
1019 ;;
1020
1021 ## Vaxen.
1022 vax-dec-* )
1023 machine=vax
1024 case "${canonical}" in
1025 *-bsd4.1* ) opsys=bsd4-1 ;;
1026 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1027 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1028 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1029 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1030 *-vms* ) opsys=vms ;;
1031 * ) unported=yes
1032 esac
1033 ;;
1034
1035 ## Whitechapel MG1
1036 ns16k-whitechapel-* )
1037 machine=mg1
1038 ## We don't know what sort of OS runs on these; we'll let the
1039 ## operating system guessing code below try.
1040 ;;
1041
1042 ## Wicat
1043 m68*-wicat-sysv* )
1044 machine=wicat opsys=usg5-2
1045 ;;
1046
1047 ## IA-64
1048 ia64*-*-linux* )
1049 machine=ia64 opsys=gnu-linux
1050 ;;
1051
1052 ## Intel 386 machines where we don't care about the manufacturer
1053 i[3456]86-*-* )
1054 machine=intel386
1055 case "${canonical}" in
1056 *-lynxos* ) opsys=lynxos ;;
1057 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1058 *-isc2.2* ) opsys=isc2-2 ;;
1059 *-isc4.0* ) opsys=isc4-0 ;;
1060 *-isc4.* ) opsys=isc4-1
1061 GCC_TEST_OPTIONS=-posix
1062 NON_GCC_TEST_OPTIONS=-Xp
1063 ;;
1064 *-isc* ) opsys=isc3-0 ;;
1065 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1066 *-esix* ) opsys=esix ;;
1067 *-xenix* ) opsys=xenix ;;
1068 *-linux-gnu* ) opsys=gnu-linux ;;
1069 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1070 *-sco3.2v5* ) opsys=sco5
1071 NON_GNU_CPP=/lib/cpp
1072 # Prevent -belf from being passed to $CPP.
1073 # /lib/cpp does not accept it.
1074 OVERRIDE_CPPFLAGS=" "
1075 ;;
1076 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1077 *-386bsd* ) opsys=386bsd ;;
1078 *-nextstep* ) opsys=nextstep ;;
1079 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1080 esac
1081 ;;
1082
1083 ## m68k Linux-based GNU system
1084 m68k-*-linux-gnu* )
1085 machine=m68k opsys=gnu-linux
1086 ;;
1087
1088 ## Mips Linux-based GNU system
1089 mips-*-linux-gnu* )
1090 machine=mips opsys=gnu-linux
1091 ;;
1092
1093 ## UXP/DS
1094 sparc-fujitsu-sysv4* )
1095 machine=sparc opsys=uxpds
1096 NON_GNU_CPP=/usr/ccs/lib/cpp
1097 RANLIB="ar -ts"
1098 ;;
1099
1100 ## UXP/V
1101 f301-fujitsu-uxpv4.1)
1102 machine=f301 opsys=uxpv
1103 ;;
1104
1105 ## Darwin / Mac OS X
1106 powerpc-apple-darwin* )
1107 machine=powermac opsys=darwin
1108 # Define CPP as follows to make autoconf work correctly.
1109 CPP="cc -E -traditional-cpp"
1110 ;;
1111
1112 ## AMD x86-64 Linux-based GNU system
1113 x86_64-*-linux-gnu* )
1114 machine=amdx86-64 opsys=gnu-linux
1115 ;;
1116
1117 * )
1118 unported=yes
1119 ;;
1120 esac
1121
1122 ### If the code above didn't choose an operating system, just choose
1123 ### an operating system based on the configuration name. You really
1124 ### only want to use this when you have no idea what the right
1125 ### operating system is; if you know what operating systems a machine
1126 ### runs, it's cleaner to make it explicit in the case statement
1127 ### above.
1128 if test x"${opsys}" = x; then
1129 case "${canonical}" in
1130 *-gnu* ) opsys=gnu ;;
1131 *-bsd4.[01] ) opsys=bsd4-1 ;;
1132 *-bsd4.2 ) opsys=bsd4-2 ;;
1133 *-bsd4.3 ) opsys=bsd4-3 ;;
1134 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1135 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1136 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1137 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1138 *-sysv4.2uw* ) opsys=unixware ;;
1139 *-sysv4.1* | *-sysvr4.1* )
1140 NON_GNU_CPP=/usr/lib/cpp
1141 opsys=usg5-4 ;;
1142 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1143 if [ x$NON_GNU_CPP = x ]; then
1144 if [ -f /usr/ccs/lib/cpp ]; then
1145 NON_GNU_CPP=/usr/ccs/lib/cpp
1146 else
1147 NON_GNU_CPP=/lib/cpp
1148 fi
1149 fi
1150 opsys=usg5-4-2 ;;
1151 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1152 * )
1153 unported=yes
1154 ;;
1155 esac
1156 fi
1157
1158 changequote([, ])dnl
1159
1160 if test $unported = yes; then
1161 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1162 Check \`etc/MACHINES' for recognized configuration names.])
1163 fi
1164
1165 machfile="m/${machine}.h"
1166 opsysfile="s/${opsys}.h"
1167
1168
1169 #### Choose a compiler.
1170 test -n "$CC" && cc_specified=yes
1171
1172 # Save the value of CFLAGS that the user specified.
1173 SPECIFIED_CFLAGS="$CFLAGS"
1174
1175 case ${with_gcc} in
1176 "yes" ) CC="gcc" GCC=yes ;;
1177 "no" ) : ${CC=cc} ;;
1178 * )
1179 esac
1180 AC_PROG_CC
1181
1182 # On Suns, sometimes $CPP names a directory.
1183 if test -n "$CPP" && test -d "$CPP"; then
1184 CPP=
1185 fi
1186
1187 #### Some systems specify a CPP to use unless we are using GCC.
1188 #### Now that we know whether we are using GCC, we can decide whether
1189 #### to use that one.
1190 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1191 then
1192 CPP="$NON_GNU_CPP"
1193 fi
1194
1195 #### Some systems specify a CC to use unless we are using GCC.
1196 #### Now that we know whether we are using GCC, we can decide whether
1197 #### to use that one.
1198 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1199 test x$cc_specified != xyes
1200 then
1201 CC="$NON_GNU_CC"
1202 fi
1203
1204 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1205 then
1206 CC="$CC $GCC_TEST_OPTIONS"
1207 fi
1208
1209 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1210 then
1211 CC="$CC $NON_GCC_TEST_OPTIONS"
1212 fi
1213
1214 #### Some other nice autoconf tests. If you add a test here which
1215 #### should make an entry in src/config.h, don't forget to add an
1216 #### #undef clause to src/config.h.in for autoconf to modify.
1217
1218 dnl checks for programs
1219 AC_PROG_LN_S
1220 AC_PROG_CPP
1221 AC_PROG_INSTALL
1222 if test "x$RANLIB" = x; then
1223 AC_PROG_RANLIB
1224 fi
1225
1226 dnl Add our options to ac_link now, after it is set up.
1227
1228 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1229 then
1230 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1231 fi
1232
1233 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1234 then
1235 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1236 fi
1237
1238 dnl checks for Unix variants
1239 AC_AIX
1240
1241 #### Extract some information from the operating system and machine files.
1242
1243 AC_CHECKING([the machine- and system-dependent files to find out
1244 - which libraries the lib-src programs will want, and
1245 - whether the GNU malloc routines are usable])
1246
1247 ### First figure out CFLAGS (which we use for running the compiler here)
1248 ### and REAL_CFLAGS (which we use for real compilation).
1249 ### The two are the same except on a few systems, where they are made
1250 ### different to work around various lossages. For example,
1251 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1252 ### as implying static linking.
1253
1254 ### If the CFLAGS env var is specified, we use that value
1255 ### instead of the default.
1256
1257 ### It's not important that this name contain the PID; you can't run
1258 ### two configures in the same directory and have anything work
1259 ### anyway.
1260 tempcname="conftest.c"
1261
1262 echo '
1263 #include "'${srcdir}'/src/'${opsysfile}'"
1264 #include "'${srcdir}'/src/'${machfile}'"
1265 #ifndef LIBS_MACHINE
1266 #define LIBS_MACHINE
1267 #endif
1268 #ifndef LIBS_SYSTEM
1269 #define LIBS_SYSTEM
1270 #endif
1271 #ifndef C_SWITCH_SYSTEM
1272 #define C_SWITCH_SYSTEM
1273 #endif
1274 #ifndef C_SWITCH_MACHINE
1275 #define C_SWITCH_MACHINE
1276 #endif
1277 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1278 configure___ c_switch_system=C_SWITCH_SYSTEM
1279 configure___ c_switch_machine=C_SWITCH_MACHINE
1280
1281 #ifndef LIB_X11_LIB
1282 #define LIB_X11_LIB -lX11
1283 #endif
1284
1285 #ifndef LIBX11_MACHINE
1286 #define LIBX11_MACHINE
1287 #endif
1288
1289 #ifndef LIBX11_SYSTEM
1290 #define LIBX11_SYSTEM
1291 #endif
1292 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1293
1294 #ifdef UNEXEC
1295 configure___ unexec=UNEXEC
1296 #else
1297 configure___ unexec=unexec.o
1298 #endif
1299
1300 #ifdef SYSTEM_MALLOC
1301 configure___ system_malloc=yes
1302 #else
1303 configure___ system_malloc=no
1304 #endif
1305
1306 #ifdef USE_MMAP_FOR_BUFFERS
1307 configure___ use_mmap_for_buffers=yes
1308 #else
1309 configure___ use_mmap_for_buffers=no
1310 #endif
1311
1312 #ifndef C_DEBUG_SWITCH
1313 #define C_DEBUG_SWITCH -g
1314 #endif
1315
1316 #ifndef C_OPTIMIZE_SWITCH
1317 #ifdef __GNUC__
1318 #define C_OPTIMIZE_SWITCH -O2
1319 #else
1320 #define C_OPTIMIZE_SWITCH -O
1321 #endif
1322 #endif
1323
1324 #ifndef LD_SWITCH_MACHINE
1325 #define LD_SWITCH_MACHINE
1326 #endif
1327
1328 #ifndef LD_SWITCH_SYSTEM
1329 #define LD_SWITCH_SYSTEM
1330 #endif
1331
1332 #ifndef LD_SWITCH_X_SITE_AUX
1333 #define LD_SWITCH_X_SITE_AUX
1334 #endif
1335
1336 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1337 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1338
1339 #ifdef THIS_IS_CONFIGURE
1340
1341 /* Get the CFLAGS for tests in configure. */
1342 #ifdef __GNUC__
1343 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1344 #else
1345 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1346 #endif
1347
1348 #else /* not THIS_IS_CONFIGURE */
1349
1350 /* Get the CFLAGS for real compilation. */
1351 #ifdef __GNUC__
1352 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1353 #else
1354 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1355 #endif
1356
1357 #endif /* not THIS_IS_CONFIGURE */
1358 ' > ${tempcname}
1359
1360 # The value of CPP is a quoted variable reference, so we need to do this
1361 # to get its actual value...
1362 CPP=`eval "echo $CPP"`
1363 changequote(, )dnl
1364 eval `${CPP} -Isrc ${tempcname} \
1365 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1366 if test "x$SPECIFIED_CFLAGS" = x; then
1367 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1368 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1369 else
1370 REAL_CFLAGS="$CFLAGS"
1371 fi
1372 changequote([, ])dnl
1373 rm ${tempcname}
1374
1375 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1376
1377 ### Make sure subsequent tests use flags consistent with the build flags.
1378
1379 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1380 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1381 else
1382 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1383 fi
1384
1385 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1386 AC_SYS_LARGEFILE
1387
1388 if test "${with_sound}" != "no"; then
1389 # Sound support for GNU/Linux and the free BSDs.
1390 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1391 # Emulation library used on NetBSD.
1392 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1393 AC_SUBST(LIBSOUND)
1394 fi
1395
1396 dnl checks for header files
1397 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1398 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1399 termcap.h stdio_ext.h fcntl.h term.h strings.h coff.h pty.h sys/mman.h \
1400 sys/param.h)
1401 AC_HEADER_STDC
1402 AC_HEADER_TIME
1403 AC_DECL_SYS_SIGLIST
1404 AC_HEADER_SYS_WAIT
1405
1406 dnl Some systems have utime.h but don't declare the struct anyplace.
1407 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1408 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1409 #include <sys/time.h>
1410 #include <time.h>
1411 #else
1412 #ifdef HAVE_SYS_TIME_H
1413 #include <sys/time.h>
1414 #else
1415 #include <time.h>
1416 #endif
1417 #endif
1418 #ifdef HAVE_UTIME_H
1419 #include <utime.h>
1420 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1421 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1422 if test $emacs_cv_struct_utimbuf = yes; then
1423 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1424 fi
1425
1426 dnl checks for typedefs
1427 AC_TYPE_SIGNAL
1428
1429 dnl Check for speed_t typedef.
1430 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1431 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1432 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1433 if test $emacs_cv_speed_t = yes; then
1434 AC_DEFINE(HAVE_SPEED_T, 1,
1435 [Define to 1 if `speed_t' is declared by <termios.h>.])
1436 fi
1437
1438 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1439 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1440 #include <sys/time.h>
1441 #include <time.h>
1442 #else
1443 #ifdef HAVE_SYS_TIME_H
1444 #include <sys/time.h>
1445 #else
1446 #include <time.h>
1447 #endif
1448 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1449 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1450 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1451 if test $emacs_cv_struct_timeval = yes; then
1452 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1453 fi
1454
1455 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1456 AC_TRY_COMPILE([#include <math.h>],
1457 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1458 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1459 HAVE_EXCEPTION=$emacs_cv_struct_exception
1460 if test $emacs_cv_struct_exception != yes; then
1461 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1462 fi
1463
1464 dnl checks for structure members
1465 AC_STRUCT_TM
1466 AC_STRUCT_TIMEZONE
1467 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1468 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1469 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1470 [#include <time.h>])
1471
1472 dnl checks for compiler characteristics
1473
1474 dnl Testing __STDC__ to determine prototype support isn't good enough.
1475 dnl DEC C, for instance, doesn't define it with default options, and
1476 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1477 dnl and void *.
1478 AC_C_PROTOTYPES
1479 AC_C_VOLATILE
1480 AC_C_CONST
1481 dnl This isn't useful because we can't turn on use of `inline' unless
1482 dnl the compiler groks `extern inline'.
1483 dnl AC_C_INLINE
1484 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1485 [AC_TRY_COMPILE(, [void * foo;],
1486 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1487 if test $emacs_cv_void_star = yes; then
1488 AC_DEFINE(POINTER_TYPE, void)
1489 else
1490 AC_DEFINE(POINTER_TYPE, char)
1491 fi
1492 AH_TEMPLATE(POINTER_TYPE,
1493 [Define as `void' if your compiler accepts `void *'; otherwise
1494 define as `char'.])dnl
1495
1496 dnl check for Make feature
1497 AC_PROG_MAKE_SET
1498
1499 dnl checks for operating system services
1500 AC_SYS_LONG_FILE_NAMES
1501
1502 #### Choose a window system.
1503
1504 AC_PATH_X
1505 if test "$no_x" = yes; then
1506 window_system=none
1507 else
1508 window_system=x11
1509 fi
1510
1511 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1512 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1513 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1514 x_default_search_path=""
1515 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1516 x_search_path="\
1517 ${x_library}/X11/%L/%T/%N%C%S:\
1518 ${x_library}/X11/%l/%T/%N%C%S:\
1519 ${x_library}/X11/%T/%N%C%S:\
1520 ${x_library}/X11/%L/%T/%N%S:\
1521 ${x_library}/X11/%l/%T/%N%S:\
1522 ${x_library}/X11/%T/%N%S"
1523 if test x"${x_default_search_path}" = x; then
1524 x_default_search_path=${x_search_path}
1525 else
1526 x_default_search_path="${x_search_path}:${x_default_search_path}"
1527 fi
1528 done
1529 fi
1530 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1531 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1532 fi
1533
1534 if test x"${x_includes}" = x; then
1535 bitmapdir=/usr/include/X11/bitmaps
1536 else
1537 # accumulate include directories that have X11 bitmap subdirectories
1538 bmd_acc="dummyval"
1539 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1540 if test -d "${bmd}/X11/bitmaps"; then
1541 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1542 fi
1543 if test -d "${bmd}/bitmaps"; then
1544 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1545 fi
1546 done
1547 if test ${bmd_acc} != "dummyval"; then
1548 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1549 fi
1550 fi
1551
1552 case "${window_system}" in
1553 x11 )
1554 HAVE_X_WINDOWS=yes
1555 HAVE_X11=yes
1556 case "${with_x_toolkit}" in
1557 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1558 motif ) USE_X_TOOLKIT=MOTIF ;;
1559 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1560 no ) USE_X_TOOLKIT=none ;;
1561 dnl If user did not say whether to use a toolkit,
1562 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1563 * ) USE_X_TOOLKIT=maybe ;;
1564 esac
1565 ;;
1566 none )
1567 HAVE_X_WINDOWS=no
1568 HAVE_X11=no
1569 USE_X_TOOLKIT=none
1570 ;;
1571 esac
1572
1573 ### If we're using X11, we should use the X menu package.
1574 HAVE_MENUS=no
1575 case ${HAVE_X11} in
1576 yes ) HAVE_MENUS=yes ;;
1577 esac
1578
1579 if test "${opsys}" = "hpux9"; then
1580 case "${x_libraries}" in
1581 *X11R4* )
1582 opsysfile="s/hpux9-x11r4.h"
1583 ;;
1584 esac
1585 fi
1586
1587 if test "${opsys}" = "hpux9shr"; then
1588 case "${x_libraries}" in
1589 *X11R4* )
1590 opsysfile="s/hpux9shxr4.h"
1591 ;;
1592 esac
1593 fi
1594
1595 ### Compute the unexec source name from the object name.
1596 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1597
1598 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1599 # Assume not, until told otherwise.
1600 GNU_MALLOC=yes
1601 doug_lea_malloc=yes
1602 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1603 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1604 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1605 emacs_cv_var___after_morecore_hook,
1606 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1607 emacs_cv_var___after_morecore_hook=yes,
1608 emacs_cv_var___after_morecore_hook=no)])
1609 if test $emacs_cv_var___after_morecore_hook = no; then
1610 doug_lea_malloc=no
1611 fi
1612 if test "${system_malloc}" = "yes"; then
1613 GNU_MALLOC=no
1614 GNU_MALLOC_reason="
1615 (The GNU allocators don't work with this system configuration.)"
1616 fi
1617 if test "$doug_lea_malloc" = "yes" ; then
1618 if test "$GNU_MALLOC" = yes ; then
1619 GNU_MALLOC_reason="
1620 (Using Doug Lea's new malloc from the GNU C Library.)"
1621 fi
1622 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1623 [Define to 1 if you are using the GNU C Library.])
1624 fi
1625
1626 if test x"${REL_ALLOC}" = x; then
1627 REL_ALLOC=${GNU_MALLOC}
1628 fi
1629
1630 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1631 dnl the system configuration file (s/*.h) to turn the use of mmap
1632 dnl in the relocating allocator on.
1633
1634 AC_FUNC_MMAP
1635 if test $use_mmap_for_buffers = yes; then
1636 REL_ALLOC=no
1637 fi
1638
1639 LIBS="$libsrc_libs $LIBS"
1640
1641 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1642 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1643 AC_CHECK_LIB(dnet, dnet_ntoa)
1644 dnl This causes -lresolv to get used in subsequent tests,
1645 dnl which causes failures on some systems such as HPUX 9.
1646 dnl AC_CHECK_LIB(resolv, gethostbyname)
1647
1648 dnl FIXME replace main with a function we actually want from this library.
1649 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1650
1651 AC_CHECK_LIB(pthreads, cma_open)
1652
1653 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1654 if test -d /usr/X386/include; then
1655 HAVE_XFREE386=yes
1656 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1657 else
1658 HAVE_XFREE386=no
1659 fi
1660 AC_MSG_RESULT($HAVE_XFREE386)
1661
1662 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1663 # used for the tests that follow. We set them back to REAL_CFLAGS and
1664 # REAL_CPPFLAGS later on.
1665
1666 REAL_CPPFLAGS="$CPPFLAGS"
1667
1668 if test "${HAVE_X11}" = "yes"; then
1669 DEFS="$C_SWITCH_X_SITE $DEFS"
1670 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1671 LIBS="$LIBX $LIBS"
1672 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1673 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1674
1675 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1676 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1677 # but it's more convenient here to set LD_RUN_PATH
1678 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1679 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1680 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1681 export LD_RUN_PATH
1682 fi
1683
1684 if test "${opsys}" = "gnu-linux"; then
1685 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1686 AC_TRY_LINK([],
1687 [XOpenDisplay ("foo");],
1688 [xlinux_first_failure=no],
1689 [xlinux_first_failure=yes])
1690 if test "${xlinux_first_failure}" = "yes"; then
1691 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1692 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1693 OLD_CPPFLAGS="$CPPFLAGS"
1694 OLD_LIBS="$LIBS"
1695 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1696 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1697 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1698 LIBS="$LIBS -b i486-linuxaout"
1699 AC_TRY_LINK([],
1700 [XOpenDisplay ("foo");],
1701 [xlinux_second_failure=no],
1702 [xlinux_second_failure=yes])
1703 if test "${xlinux_second_failure}" = "yes"; then
1704 # If we get the same failure with -b, there is no use adding -b.
1705 # So take it out. This plays safe.
1706 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1707 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1708 CPPFLAGS="$OLD_CPPFLAGS"
1709 LIBS="$OLD_LIBS"
1710 AC_MSG_RESULT(no)
1711 else
1712 AC_MSG_RESULT(yes)
1713 fi
1714 else
1715 AC_MSG_RESULT(no)
1716 fi
1717 fi
1718
1719 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1720 # header files included from there.
1721 AC_MSG_CHECKING(for Xkb)
1722 AC_TRY_LINK([#include <X11/Xlib.h>
1723 #include <X11/XKBlib.h>],
1724 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1725 emacs_xkb=yes, emacs_xkb=no)
1726 AC_MSG_RESULT($emacs_xkb)
1727 if test $emacs_xkb = yes; then
1728 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1729 fi
1730
1731 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1732 XScreenNumberOfScreen XSetWMProtocols)
1733 fi
1734
1735 if test "${window_system}" = "x11"; then
1736 AC_MSG_CHECKING(X11 version 6)
1737 AC_CACHE_VAL(emacs_cv_x11_version_6,
1738 [AC_TRY_LINK([#include <X11/Xlib.h>],
1739 [#if XlibSpecificationRelease < 6
1740 fail;
1741 #endif
1742 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1743 if test $emacs_cv_x11_version_6 = yes; then
1744 AC_MSG_RESULT(6 or newer)
1745 AC_DEFINE(HAVE_X11R6, 1,
1746 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1747 else
1748 AC_MSG_RESULT(before 6)
1749 fi
1750 fi
1751
1752 if test "${window_system}" = "x11"; then
1753 AC_MSG_CHECKING(X11 version 5)
1754 AC_CACHE_VAL(emacs_cv_x11_version_5,
1755 [AC_TRY_LINK([#include <X11/Xlib.h>],
1756 [#if XlibSpecificationRelease < 5
1757 fail;
1758 #endif
1759 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1760 if test $emacs_cv_x11_version_5 = yes; then
1761 AC_MSG_RESULT(5 or newer)
1762 HAVE_X11R5=yes
1763 AC_DEFINE(HAVE_X11R5, 1,
1764 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1765 else
1766 HAVE_X11R5=no
1767 AC_MSG_RESULT(before 5)
1768 fi
1769 fi
1770
1771 dnl Do not put whitespace before the #include statements below.
1772 dnl Older compilers (eg sunos4 cc) choke on it.
1773 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1774 if test x"${HAVE_X11R5}" = xyes; then
1775 AC_MSG_CHECKING(X11 version 5 with Xaw)
1776 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1777 [AC_TRY_LINK([
1778 #include <X11/Intrinsic.h>
1779 #include <X11/Xaw/Simple.h>],
1780 [],
1781 emacs_cv_x11_version_5_with_xaw=yes,
1782 emacs_cv_x11_version_5_with_xaw=no)])
1783 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1784 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1785 USE_X_TOOLKIT=LUCID
1786 else
1787 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1788 USE_X_TOOLKIT=none
1789 fi
1790 else
1791 USE_X_TOOLKIT=none
1792 fi
1793 fi
1794
1795 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1796
1797 if test "${USE_X_TOOLKIT}" != "none"; then
1798 AC_MSG_CHECKING(X11 toolkit version)
1799 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1800 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1801 [#if XtSpecificationRelease < 6
1802 fail;
1803 #endif
1804 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1805 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1806 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1807 AC_MSG_RESULT(6 or newer)
1808 AC_DEFINE(HAVE_X11XTR6, 1,
1809 [Define to 1 if you have the X11R6 or newer version of Xt.])
1810 else
1811 AC_MSG_RESULT(before 6)
1812 fi
1813
1814 dnl If using toolkit, check whether libXmu.a exists.
1815 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1816 OLDLIBS="$LIBS"
1817 if test x$HAVE_X11XTR6 = xyes; then
1818 LIBS="-lXt -lSM -lICE $LIBS"
1819 else
1820 LIBS="-lXt $LIBS"
1821 fi
1822 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1823 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1824 fi
1825
1826 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1827 if test "${HAVE_X11}" = "yes"; then
1828 if test "${USE_X_TOOLKIT}" != "none"; then
1829 AC_CHECK_LIB(Xext, XShapeQueryExtension)
1830 fi
1831 fi
1832
1833 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1834 AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1835 # We put this in CFLAGS temporarily to precede other -I options
1836 # that might be in CFLAGS temporarily.
1837 # We put this in CPPFLAGS where it precedes the other -I options.
1838 OLD_CPPFLAGS=$CPPFLAGS
1839 OLD_CFLAGS=$CFLAGS
1840 CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1841 CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1842 [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1843 [int x = 5;],
1844 emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1845 if test $emacs_cv_lesstif = yes; then
1846 # Make sure this -I option remains in CPPFLAGS after it is set
1847 # back to REAL_CPPFLAGS.
1848 # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1849 # have those other -I options anyway. Ultimately, having this
1850 # directory ultimately in CPPFLAGS will be enough.
1851 REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1852 LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1853 else
1854 CFLAGS=$OLD_CFLAGS
1855 CPPFLAGS=$OLD_CPPFLAGS
1856 fi
1857 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1858 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1859 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1860 int x = 5;
1861 #else
1862 Motif version prior to 2.1.
1863 #endif],
1864 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1865 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1866 if test $emacs_cv_motif_version_2_1 = yes; then
1867 HAVE_LIBXP=no
1868 AC_DEFINE(HAVE_MOTIF_2_1, 1,
1869 [Define to 1 if you have Motif 2.1 or newer.])
1870 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1871 if test ${HAVE_LIBXP} = yes; then
1872 AC_DEFINE(HAVE_LIBXP, 1,
1873 [Define to 1 if you have the Xp library (-lXp).])
1874 fi
1875 fi
1876 fi
1877
1878 ### Is -lXaw3d available?
1879 HAVE_XAW3D=no
1880 if test "${HAVE_X11}" = "yes"; then
1881 if test "${USE_X_TOOLKIT}" != "none"; then
1882 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1883 AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes))
1884 if test "${HAVE_XAW3D}" = "yes"; then
1885 AC_DEFINE(HAVE_XAW3D, 1,
1886 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1887 fi
1888 fi
1889 fi
1890
1891 dnl Use toolkit scroll bars if configured for X toolkit and either
1892 dnl using Motif or Xaw3d is available, and unless
1893 dnl --with-toolkit-scroll-bars=no was specified.
1894
1895 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1896 [Define to 1 if we should use toolkit scroll bars.])dnl
1897 USE_TOOLKIT_SCROLL_BARS=no
1898 if test "${with_toolkit_scroll_bars}" != "no"; then
1899 if test "${USE_X_TOOLKIT}" != "none"; then
1900 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1901 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1902 HAVE_XAW3D=no
1903 USE_TOOLKIT_SCROLL_BARS=yes
1904 elif test "${HAVE_XAW3D}" = "yes"; then
1905 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1906 USE_TOOLKIT_SCROLL_BARS=yes
1907 fi
1908 fi
1909 fi
1910
1911 dnl Don't use X11 input methods if user specifies he doesn't want it
1912 dnl with `--with-xim=no'.
1913
1914 if test "${with_xim}" != "no"; then
1915 AC_DEFINE(USE_XIM, 1,
1916 [Define to 1 if we should use XIM, if it is available.])
1917 fi
1918
1919 ### Use -lXpm if available, unless `--with-xpm=no'.
1920 HAVE_XPM=no
1921 if test "${HAVE_X11}" = "yes"; then
1922 if test "${with_xpm}" != "no"; then
1923 AC_CHECK_HEADER(X11/xpm.h,
1924 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1925 if test "${HAVE_XPM}" = "yes"; then
1926 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1927 AC_EGREP_CPP(no_return_alloc_pixels,
1928 [#include "X11/xpm.h"
1929 #ifndef XpmReturnAllocPixels
1930 no_return_alloc_pixels
1931 #endif
1932 ], HAVE_XPM=no, HAVE_XPM=yes)
1933
1934 if test "${HAVE_XPM}" = "yes"; then
1935 AC_MSG_RESULT(yes)
1936 else
1937 AC_MSG_RESULT(no)
1938 fi
1939 fi
1940 fi
1941
1942 if test "${HAVE_XPM}" = "yes"; then
1943 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1944 fi
1945 fi
1946
1947 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1948 HAVE_JPEG=no
1949 if test "${HAVE_X11}" = "yes"; then
1950 if test "${with_jpeg}" != "no"; then
1951 dnl Checking for jpeglib.h can lose becsue of a redefinition of
1952 dnl HAVE_STDLIB_H.
1953 AC_CHECK_HEADER(jerror.h,
1954 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
1955 fi
1956
1957 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1958 if test "${HAVE_JPEG}" = "yes"; then
1959 AC_DEFINE(HAVE_JPEG)
1960 AC_EGREP_CPP(
1961 changequote({, })dnl avoid leadingspace on the next line
1962 {version= *(6[2-9]|[7-9][0-9])},
1963 changequote([, ])dnl
1964 [#include <jpeglib.h>
1965 version=JPEG_LIB_VERSION
1966 ],
1967 AC_DEFINE(HAVE_JPEG),
1968 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1969 HAVE_JPEG=no])
1970 fi
1971 fi
1972
1973 ### Use -lpng if available, unless `--with-png=no'.
1974 HAVE_PNG=no
1975 if test "${HAVE_X11}" = "yes"; then
1976 if test "${with_png}" != "no"; then
1977 AC_CHECK_HEADER(png.h,
1978 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm))
1979 fi
1980
1981 if test "${HAVE_PNG}" = "yes"; then
1982 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1983 fi
1984 fi
1985
1986 ### Use -ltiff if available, unless `--with-tiff=no'.
1987 HAVE_TIFF=no
1988 if test "${HAVE_X11}" = "yes"; then
1989 if test "${with_tiff}" != "no"; then
1990 AC_CHECK_HEADER(tiffio.h,
1991 tifflibs="-lz -lm"
1992 # At least one tiff package requires the jpeg library.
1993 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1994 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1995 fi
1996
1997 if test "${HAVE_TIFF}" = "yes"; then
1998 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
1999 fi
2000 fi
2001
2002 ### Use -lgif if available, unless `--with-gif=no'.
2003 HAVE_GIF=no
2004 if test "${HAVE_X11}" = "yes"; then
2005 if test "${with_gif}" != "no"; then
2006 AC_CHECK_HEADER(gif_lib.h,
2007 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2008 # Earlier versions can crash Emacs.
2009 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2010 fi
2011
2012 if test "${HAVE_GIF}" = "yes"; then
2013 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2014 fi
2015 fi
2016
2017 ### Use Mac OS X Carbon API to implement GUI.
2018 HAVE_CARBON=no
2019 if test "${with_carbon}" != "no"; then
2020 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
2021 fi
2022
2023 if test "${HAVE_CARBON}" = "yes"; then
2024 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2025 fi
2026
2027 ### Use session management (-lSM -lICE) if available
2028 HAVE_X_SM=no
2029 if test "${HAVE_X11}" = "yes"; then
2030 AC_CHECK_HEADER(X11/SM/SMlib.h,
2031 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, -lICE))
2032
2033 if test "${HAVE_X_SM}" = "yes"; then
2034 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2035 case "$LIBS" in
2036 *-lSM*) ;;
2037 *) LIBS="-lSM -lICE $LIBS" ;;
2038 esac
2039 fi
2040 fi
2041
2042 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2043 AC_CACHE_CHECK(whether netdb declares h_errno,
2044 emacs_cv_netdb_declares_h_errno,
2045 [AC_TRY_LINK([#include <netdb.h>],
2046 [return h_errno;],
2047 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2048 if test $emacs_cv_netdb_declares_h_errno = yes; then
2049 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2050 fi
2051
2052 AC_FUNC_ALLOCA
2053
2054 # fmod, logb, and frexp are found in -lm on most systems.
2055 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2056 AC_CHECK_LIB(m, sqrt)
2057
2058 # Check for mail-locking functions in a "mail" library
2059 AC_CHECK_LIB(mail, maillock)
2060 dnl Debian, at least:
2061 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
2062 AC_CHECK_LIB(lockfile, maillock)
2063 # If we have the shared liblockfile, assume we must use it for mail
2064 # locking (e.g. Debian). If we couldn't link against liblockfile
2065 # (no liblockfile.a installed), ensure that we don't need to.
2066 if test "$ac_cv_lib_lockfile_maillock" = no; then
2067 dnl This works for files generally, not just executables.
2068 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2069 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2070 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2071 if test $ac_cv_prog_liblockfile = yes; then
2072 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2073 This probably means that movemail could lose mail.
2074 There may be a \`development' package to install containing liblockfile.])
2075 else AC_DEFINE(LIBMAIL, -llockfile, [Define to -llockfile if it is usable.])
2076 fi
2077 else :
2078 fi
2079 AC_CHECK_FUNCS(touchlock)
2080 AC_CHECK_HEADERS(maillock.h)
2081
2082 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2083 rename closedir mkdir rmdir sysinfo \
2084 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2085 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2086 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
2087 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2088 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2089 gai_strerror mkstemp getline getdelim mremap memmove)
2090
2091 AC_CHECK_HEADERS(sys/un.h)
2092
2093 AC_FUNC_MKTIME
2094 if test "$ac_cv_func_working_mktime" = no; then
2095 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2096 fi
2097
2098 AC_FUNC_GETLOADAVG
2099
2100 AC_FUNC_FSEEKO
2101
2102 # UNIX98 PTYs.
2103 AC_CHECK_FUNCS(grantpt)
2104
2105 # PTY-related GNU extensions.
2106 AC_CHECK_FUNCS(getpt)
2107
2108 # Check this now, so that we will NOT find the above functions in ncurses.
2109 # That is because we have not set up to link ncurses in lib-src.
2110 # It's better to believe a function is not available
2111 # than to expect to find it in ncurses.
2112 AC_CHECK_LIB(ncurses, tparm)
2113
2114 # Do we need the Hesiod library to provide the support routines?
2115 if test "$with_hesiod" = yes ; then
2116 # Don't set $LIBS here -- see comments above.
2117 resolv=no
2118 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2119 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2120 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2121 if test "$resolv" = yes ; then
2122 RESOLVLIB=-lresolv
2123 AC_DEFINE(HAVE_LIBRESOLV, 1,
2124 [Define to 1 if you have the resolv library (-lresolv).])
2125 else
2126 RESOLVLIB=
2127 fi
2128 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2129 AC_DEFINE(HAVE_LIBHESIOD, 1,
2130 [Define to 1 if you have the hesiod library (-lhesiod).]),
2131 :, $RESOLVLIB)])
2132 fi
2133
2134 # These tell us which Kerberos-related libraries to use.
2135 if test "${with_kerberos+set}" = set; then
2136 AC_CHECK_LIB(com_err, com_err)
2137 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2138 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2139 AC_CHECK_LIB(krb5, krb5_init_context)
2140 if test "${with_kerberos5+set}" != set; then
2141 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2142 AC_CHECK_LIB(des, des_cbc_encrypt))
2143 AC_CHECK_LIB(krb4, krb_get_cred,,
2144 AC_CHECK_LIB(krb, krb_get_cred))
2145 fi
2146
2147 if test "${with_kerberos5+set}" = set; then
2148 AC_CHECK_HEADERS(krb5.h)
2149 else
2150 AC_CHECK_HEADERS(des.h,,
2151 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2152 [AC_CHECK_HEADERS(kerberos/des.h)])])
2153 AC_CHECK_HEADERS(krb.h,,
2154 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2155 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2156 fi
2157 AC_CHECK_HEADERS(com_err.h)
2158 fi
2159
2160 # Solaris requires -lintl if you want strerror (which calls dgettext)
2161 # to return localized messages.
2162 AC_CHECK_LIB(intl, dgettext)
2163
2164 AC_MSG_CHECKING(whether localtime caches TZ)
2165 AC_CACHE_VAL(emacs_cv_localtime_cache,
2166 [if test x$ac_cv_func_tzset = xyes; then
2167 AC_TRY_RUN([#include <time.h>
2168 extern char **environ;
2169 unset_TZ ()
2170 {
2171 char **from, **to;
2172 for (to = from = environ; (*to = *from); from++)
2173 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2174 to++;
2175 }
2176 char TZ_GMT0[] = "TZ=GMT0";
2177 char TZ_PST8[] = "TZ=PST8";
2178 main()
2179 {
2180 time_t now = time ((time_t *) 0);
2181 int hour_GMT0, hour_unset;
2182 if (putenv (TZ_GMT0) != 0)
2183 exit (1);
2184 hour_GMT0 = localtime (&now)->tm_hour;
2185 unset_TZ ();
2186 hour_unset = localtime (&now)->tm_hour;
2187 if (putenv (TZ_PST8) != 0)
2188 exit (1);
2189 if (localtime (&now)->tm_hour == hour_GMT0)
2190 exit (1);
2191 unset_TZ ();
2192 if (localtime (&now)->tm_hour != hour_unset)
2193 exit (1);
2194 exit (0);
2195 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2196 [# If we have tzset, assume the worst when cross-compiling.
2197 emacs_cv_localtime_cache=yes])
2198 else
2199 # If we lack tzset, report that localtime does not cache TZ,
2200 # since we can't invalidate the cache if we don't have tzset.
2201 emacs_cv_localtime_cache=no
2202 fi])dnl
2203 AC_MSG_RESULT($emacs_cv_localtime_cache)
2204 if test $emacs_cv_localtime_cache = yes; then
2205 AC_DEFINE(LOCALTIME_CACHE, 1,
2206 [Define to 1 if localtime caches TZ.])
2207 fi
2208
2209 if test "x$HAVE_TIMEVAL" = xyes; then
2210 AC_CHECK_FUNCS(gettimeofday)
2211 if test $ac_cv_func_gettimeofday = yes; then
2212 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2213 emacs_cv_gettimeofday_two_arguments,
2214 [AC_TRY_COMPILE([
2215 #ifdef TIME_WITH_SYS_TIME
2216 #include <sys/time.h>
2217 #include <time.h>
2218 #else
2219 #ifdef HAVE_SYS_TIME_H
2220 #include <sys/time.h>
2221 #else
2222 #include <time.h>
2223 #endif
2224 #endif],
2225 [struct timeval time;
2226 gettimeofday (&time, 0);],
2227 emacs_cv_gettimeofday_two_arguments=yes,
2228 emacs_cv_gettimeofday_two_arguments=no)])
2229 if test $emacs_cv_gettimeofday_two_arguments = no; then
2230 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2231 [Define to 1 if gettimeofday accepts only one argument.])
2232 fi
2233 fi
2234 fi
2235
2236 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2237 if test "$ac_cv_func_gettimeofday" = yes; then
2238 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2239 [AC_TRY_COMPILE([#include <sys/time.h>],
2240 [struct timezone tz;],
2241 dnl It may be that we can't call gettimeofday with a non-null pointer,
2242 dnl even though we have struct timezone (e.g. HPUX). In that case
2243 dnl we'll lie about struct timezone.
2244 [AC_TRY_RUN([
2245 #ifdef TIME_WITH_SYS_TIME
2246 #include <sys/time.h>
2247 #include <time.h>
2248 #else
2249 #ifdef HAVE_SYS_TIME_H
2250 #include <sys/time.h>
2251 #else
2252 #include <time.h>
2253 #endif
2254 #endif
2255 main () {
2256 struct timeval time;
2257 struct timezone dummy;
2258 exit (gettimeofday (&time, &dummy));
2259 }],
2260 emacs_cv_struct_timezone=yes,
2261 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2262 emacs_cv_struct_timezone=no)])
2263 fi
2264
2265 ok_so_far=yes
2266 AC_CHECK_FUNC(socket, , ok_so_far=no)
2267 if test $ok_so_far = yes; then
2268 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2269 fi
2270 if test $ok_so_far = yes; then
2271 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2272 fi
2273 if test $ok_so_far = yes; then
2274 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2275 [Define to 1 if you have inet sockets.])
2276 fi
2277
2278 if test -f /usr/lpp/X11/bin/smt.exp; then
2279 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2280 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2281 fi
2282
2283 AC_MSG_CHECKING(whether system supports dynamic ptys)
2284 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2285 AC_MSG_RESULT(yes)
2286 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2287 else
2288 AC_MSG_RESULT(no)
2289 fi
2290
2291 AC_FUNC_FORK
2292
2293 AC_CHECK_TYPES(size_t)
2294
2295 # Set up the CFLAGS for real compilation, so we can substitute it.
2296 CFLAGS="$REAL_CFLAGS"
2297 CPPFLAGS="$REAL_CPPFLAGS"
2298
2299 changequote(, )dnl
2300 #### Find out which version of Emacs this is.
2301 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2302 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2303 changequote([, ])dnl
2304 if test x"${version}" = x; then
2305 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2306 fi
2307
2308 ### Specify what sort of things we'll be editing into Makefile and config.h.
2309 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2310 AC_SUBST(version)
2311 AC_SUBST(configuration)
2312 AC_SUBST(canonical)
2313 AC_SUBST(srcdir)
2314 AC_SUBST(prefix)
2315 AC_SUBST(exec_prefix)
2316 AC_SUBST(bindir)
2317 AC_SUBST(datadir)
2318 AC_SUBST(sharedstatedir)
2319 AC_SUBST(libexecdir)
2320 AC_SUBST(mandir)
2321 AC_SUBST(infodir)
2322 AC_SUBST(lispdir)
2323 AC_SUBST(locallisppath)
2324 AC_SUBST(lisppath)
2325 AC_SUBST(x_default_search_path)
2326 AC_SUBST(etcdir)
2327 AC_SUBST(archlibdir)
2328 AC_SUBST(docdir)
2329 AC_SUBST(bitmapdir)
2330 AC_SUBST(gamedir)
2331 AC_SUBST(gameuser)
2332 AC_SUBST(c_switch_system)
2333 AC_SUBST(c_switch_machine)
2334 AC_SUBST(LD_SWITCH_X_SITE)
2335 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2336 AC_SUBST(C_SWITCH_X_SITE)
2337 AC_SUBST(CFLAGS)
2338 AC_SUBST(X_TOOLKIT_TYPE)
2339 AC_SUBST(machfile)
2340 AC_SUBST(opsysfile)
2341 AC_SUBST(GETLOADAVG_LIBS)
2342
2343 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2344 [Define to the canonical Emacs configuration name.])
2345 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2346 [Define to the options passed to configure.])
2347 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2348 [Define to the used machine dependent file.])
2349 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2350 [Define to the used os dependent file.])
2351 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2352 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2353 may need to deal with X Windows. For instance, if you've defined
2354 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2355 your loader can find on its own, you might want to add "-L/..." or
2356 something similar.])
2357 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2358 [Define LD_SWITCH_X_SITE_AUX with an -R option
2359 in case it's needed (for Solaris, for example).])
2360 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2361 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2362 may need to deal with X Windows. For instance, if you've defined
2363 HAVE_X_WINDOWS above and your X include files aren't in a place
2364 that your compiler can find on its own, you might want to add
2365 "-I/..." or something similar.])
2366 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2367 [Define to the unexec source file name.])
2368
2369 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2370 AC_DEFINE(HAVE_X_WINDOWS, 1,
2371 [Define to 1 if you want to use the X window system.])
2372 fi
2373 if test "${USE_X_TOOLKIT}" != "none" ; then
2374 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2375 fi
2376 if test "${HAVE_X11}" = "yes" ; then
2377 AC_DEFINE(HAVE_X11, 1,
2378 [Define to 1 if you want to use version 11 of X windows.
2379 Otherwise, Emacs expects to use version 10.])
2380 fi
2381 if test "${HAVE_XFREE386}" = "yes" ; then
2382 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2383 fi
2384 if test "${HAVE_MENUS}" = "yes" ; then
2385 AC_DEFINE(HAVE_MENUS, 1,
2386 [Define to 1 if you have mouse menus.
2387 (This is automatic if you use X, but the option to specify it remains.)
2388 It is also defined with other window systems that support xmenu.c.])
2389 fi
2390 if test "${GNU_MALLOC}" = "yes" ; then
2391 AC_DEFINE(GNU_MALLOC, 1,
2392 [Define to 1 if you want to use the GNU memory allocator.])
2393 fi
2394 if test "${REL_ALLOC}" = "yes" ; then
2395 AC_DEFINE(REL_ALLOC, 1,
2396 [Define REL_ALLOC if you want to use the relocating allocator for
2397 buffer space.])
2398 fi
2399
2400 AC_CHECK_HEADERS(nlist.h, [AC_DEFINE(NLIST_STRUCT, 1,
2401 [Define to 1 if you have <nlist.h>.])])
2402
2403 AH_TOP([/* GNU Emacs site configuration template file.
2404 Copyright (C) 1988, 93, 94, 99, 2000, 2002 Free Software Foundation, Inc.
2405
2406 This file is part of GNU Emacs.
2407
2408 GNU Emacs is free software; you can redistribute it and/or modify
2409 it under the terms of the GNU General Public License as published by
2410 the Free Software Foundation; either version 2, or (at your option)
2411 any later version.
2412
2413 GNU Emacs is distributed in the hope that it will be useful,
2414 but WITHOUT ANY WARRANTY; without even the implied warranty of
2415 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2416 GNU General Public License for more details.
2417
2418 You should have received a copy of the GNU General Public License
2419 along with GNU Emacs; see the file COPYING. If not, write to the
2420 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2421 Boston, MA 02111-1307, USA. */
2422
2423
2424 /* No code in Emacs #includes config.h twice, but some of the code
2425 intended to work with other packages as well (like gmalloc.c)
2426 think they can include it as many times as they like. */
2427 #ifndef EMACS_CONFIG_H
2428 #define EMACS_CONFIG_H
2429 ])dnl
2430
2431 AH_BOTTOM([
2432 /* If we're using any sort of window system, define some consequences. */
2433 #ifdef HAVE_X_WINDOWS
2434 #define HAVE_WINDOW_SYSTEM
2435 #define MULTI_KBOARD
2436 #define HAVE_MOUSE
2437 #endif
2438
2439 /* If we're using the Carbon API on Mac OS X, define a few more
2440 variables as well. */
2441 #ifdef HAVE_CARBON
2442 #define HAVE_WINDOW_SYSTEM
2443 #define HAVE_MOUSE
2444 #define HAVE_MENUS
2445 #endif
2446
2447 /* Define USER_FULL_NAME to return a string
2448 that is the user's full name.
2449 It can assume that the variable `pw'
2450 points to the password file entry for this user.
2451
2452 At some sites, the pw_gecos field contains
2453 the user's full name. If neither this nor any other
2454 field contains the right thing, use pw_name,
2455 giving the user's login name, since that is better than nothing. */
2456 #define USER_FULL_NAME pw->pw_gecos
2457
2458 /* Define AMPERSAND_FULL_NAME if you use the convention
2459 that & in the full name stands for the login id. */
2460 /* Turned on June 1996 supposing nobody will mind it. */
2461 #define AMPERSAND_FULL_NAME
2462
2463 /* Define HAVE_SOUND if we have sound support. We know it works
2464 and compiles only on the specified platforms. For others,
2465 it probably doesn't make sense to try. */
2466
2467 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2468 #ifdef HAVE_MACHINE_SOUNDCARD_H
2469 #define HAVE_SOUND 1
2470 #endif
2471 #ifdef HAVE_SYS_SOUNDCARD_H
2472 #define HAVE_SOUND 1
2473 #endif
2474 #ifdef HAVE_SOUNDCARD_H
2475 #define HAVE_SOUND 1
2476 #endif
2477 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2478
2479 /* If using GNU, then support inline function declarations. */
2480 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2481 generally, because even if non-gcc compilers accept `inline', they
2482 may reject `extern inline'. */
2483 #ifdef __GNUC__
2484 #define INLINE __inline__
2485 #else
2486 #define INLINE
2487 #endif
2488
2489 /* Include the os and machine dependent files. */
2490 #include config_opsysfile
2491 #include config_machfile
2492
2493 /* Load in the conversion definitions if this system
2494 needs them and the source file being compiled has not
2495 said to inhibit this. There should be no need for you
2496 to alter these lines. */
2497
2498 #ifdef SHORTNAMES
2499 #ifndef NO_SHORTNAMES
2500 #include "../shortnames/remap.h"
2501 #endif /* not NO_SHORTNAMES */
2502 #endif /* SHORTNAMES */
2503
2504 /* If no remapping takes place, static variables cannot be dumped as
2505 pure, so don't worry about the `static' keyword. */
2506 #ifdef NO_REMAP
2507 #undef static
2508 #endif
2509
2510 /* Define `subprocesses' should be defined if you want to
2511 have code for asynchronous subprocesses
2512 (as used in M-x compile and M-x shell).
2513 These do not work for some USG systems yet;
2514 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2515
2516 #ifndef VMS
2517 #ifndef USG
2518 /* #define subprocesses */
2519 #endif
2520 #endif
2521
2522 /* SIGTYPE is the macro we actually use. */
2523 #ifndef SIGTYPE
2524 #define SIGTYPE RETSIGTYPE
2525 #endif
2526
2527 #ifdef emacs /* Don't do this for lib-src. */
2528 /* Tell regex.c to use a type compatible with Emacs. */
2529 #define RE_TRANSLATE_TYPE Lisp_Object
2530 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2531 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2532 #endif
2533
2534 /* Avoid link-time collision with system mktime if we will use our own. */
2535 #if ! HAVE_MKTIME || BROKEN_MKTIME
2536 #define mktime emacs_mktime
2537 #endif
2538
2539 /* The rest of the code currently tests the CPP symbol BSTRING.
2540 Override any claims made by the system-description files.
2541 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2542 #undef BSTRING
2543 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2544 #define BSTRING
2545 #endif
2546
2547 /* Some of the files of Emacs which are intended for use with other
2548 programs assume that if you have a config.h file, you must declare
2549 the type of getenv.
2550
2551 This declaration shouldn't appear when alloca.s or Makefile.in
2552 includes config.h. */
2553 #ifndef NOT_C_CODE
2554 extern char *getenv ();
2555 #endif
2556
2557 #endif /* EMACS_CONFIG_H */
2558
2559 /* These default definitions are good for almost all machines.
2560 The exceptions override them in m/MACHINE.h. */
2561
2562 #ifndef BITS_PER_CHAR
2563 #define BITS_PER_CHAR 8
2564 #endif
2565
2566 #ifndef BITS_PER_SHORT
2567 #define BITS_PER_SHORT 16
2568 #endif
2569
2570 /* Note that lisp.h uses this in a preprocessor conditional, so it
2571 would not work to use sizeof. That being so, we do all of them
2572 without sizeof, for uniformity's sake. */
2573 #ifndef BITS_PER_INT
2574 #define BITS_PER_INT 32
2575 #endif
2576
2577 #ifndef BITS_PER_LONG
2578 #ifdef _LP64
2579 #define BITS_PER_LONG 64
2580 #else
2581 #define BITS_PER_LONG 32
2582 #endif
2583 #endif
2584
2585 /* Define if the compiler supports function prototypes. It may do so
2586 but not define __STDC__ (e.g. DEC C by default) or may define it as
2587 zero. */
2588 #undef PROTOTYPES
2589 /* For mktime.c: */
2590 #ifndef __P
2591 # if defined PROTOTYPES
2592 # define __P(args) args
2593 # else
2594 # define __P(args) ()
2595 # endif /* GCC. */
2596 #endif /* __P */
2597
2598
2599 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2600 #ifndef NOT_C_CODE
2601 #ifdef HAVE_STRING_H
2602 #include "string.h"
2603 #endif
2604 #ifdef HAVE_STRINGS_H
2605 #include "strings.h" /* May be needed for bcopy & al. */
2606 #endif
2607 #ifdef HAVE_STDLIB_H
2608 #include <stdlib.h>
2609 #endif
2610 #endif
2611
2612 /* Define HAVE_X_I18N if we have usable i18n support. */
2613
2614 #ifdef HAVE_X11R6
2615 #define HAVE_X_I18N
2616 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2617 #define HAVE_X_I18N
2618 #endif
2619
2620 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
2621
2622 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2623 #define HAVE_X11R6_XIM
2624 #endif
2625
2626 /* Should we enable expensive run-time checking of data types? */
2627 #undef ENABLE_CHECKING
2628
2629 #if defined __GNUC__ && (__GNUC__ > 2 \
2630 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2631 #define NO_RETURN __attribute__ ((__noreturn__))
2632 #else
2633 #define NO_RETURN /* nothing */
2634 #endif
2635
2636 /*
2637 Local variables:
2638 mode: c
2639 End:
2640 */
2641 ])dnl
2642
2643 #### Report on what we decided to do.
2644 echo "
2645 Configured for \`${canonical}'.
2646
2647 Where should the build process find the source code? ${srcdir}
2648 What operating system and machine description files should Emacs use?
2649 \`${opsysfile}' and \`${machfile}'
2650 What compiler should emacs be built with? ${CC} ${CFLAGS}
2651 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2652 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
2653 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
2654 What window system should Emacs use? ${window_system}
2655 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
2656
2657 if test -n "${x_includes}"; then
2658 echo " Where do we find X Windows header files? ${x_includes}"
2659 else
2660 echo " Where do we find X Windows header files? Standard dirs"
2661 fi
2662 if test -n "${x_libraries}"; then
2663 echo " Where do we find X Windows libraries? ${x_libraries}"
2664 else
2665 echo " Where do we find X Windows libraries? Standard dirs"
2666 fi
2667
2668 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2669 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2670 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2671 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2672 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2673 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2674 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2675 echo
2676
2677 # Remove any trailing slashes in these variables.
2678 changequote(, )dnl
2679 test "${prefix}" != NONE &&
2680 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2681 test "${exec_prefix}" != NONE &&
2682 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2683 changequote([, ])dnl
2684
2685 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
2686 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2687 ## from Makefile.c can correctly provide the arg `-traditional' to the
2688 ## C preprocessor.
2689
2690 AC_EGREP_CPP(yes..yes,
2691 [yes..yes],
2692 CPP_NEED_TRADITIONAL=no,
2693 CPP_NEED_TRADITIONAL=yes)
2694
2695 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2696 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2697 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
2698
2699 ### Make the necessary directories, if they don't exist.
2700 for dir in etc lisp ; do
2701 test -d ${dir} || mkdir ${dir}
2702 done
2703
2704 # Build src/Makefile from ${srcdir}/src/Makefile.c
2705 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2706 # This must be done after src/config.h is built, since we rely on that file.
2707
2708 changequote(, )dnl The horror, the horror.
2709 # Now get this: Some word that is part of the ${srcdir} directory name
2710 # or the ${configuration} value might, just might, happen to be an
2711 # identifier like `sun4' or `i386' or something, and be predefined by
2712 # the C preprocessor to some helpful value like 1, or maybe the empty
2713 # string. Needless to say consequent macro substitutions are less
2714 # than conducive to the makefile finding the correct directory.
2715 undefs="`echo $top_srcdir $configuration $canonical |
2716 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2717 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2718 `"
2719 changequote([, ])dnl
2720
2721 echo creating src/epaths.h
2722 ${MAKE-make} epaths-force
2723
2724 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2725 # `..' to `. .' unless invoked with -traditional
2726
2727 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2728 CPPFLAGS="$CPPFLAGS -traditional"
2729 fi
2730
2731 echo creating lib-src/Makefile
2732 ( cd lib-src
2733 rm -f junk.c junk1.c junk2.c
2734 sed -e '/start of cpp stuff/q' \
2735 < Makefile.c > junk1.c
2736 sed -e '1,/start of cpp stuff/d'\
2737 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2738 < Makefile.c > junk.c
2739 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2740 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2741 cat junk1.c junk2.c > Makefile.new
2742 rm -f junk.c junk1.c junk2.c
2743 chmod 444 Makefile.new
2744 mv -f Makefile.new Makefile
2745 )
2746
2747 echo creating src/Makefile
2748 ( cd src
2749 rm -f junk.c junk1.c junk2.c
2750 sed -e '/start of cpp stuff/q' \
2751 < Makefile.c > junk1.c
2752 sed -e '1,/start of cpp stuff/d'\
2753 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2754 < Makefile.c > junk.c
2755 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2756 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2757 cat junk1.c junk2.c > Makefile.new
2758 rm -f junk.c junk1.c junk2.c
2759 chmod 444 Makefile.new
2760 mv -f Makefile.new Makefile
2761 )
2762
2763 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2764 echo creating src/.gdbinit
2765 echo source $srcdir/src/.gdbinit > src/.gdbinit
2766 fi
2767
2768 # This is how we know whether to re-run configure in certain cases.
2769 touch src/config.stamp
2770
2771 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
2772
Unnamed repository; edit this file 'description' to name the repository.