lisp/uniquify.el

   1 ;;; uniquify.el --- unique buffer names dependent on file name
   2
   3 ;; Copyright (c) 1989, 1995, 1996, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Dick King <king@reasoning.com>
   6 ;; Maintainer: Michael Ernst <mernst@alum.mit.edu>
   7 ;; Created: 15 May 86
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Emacs's standard method for making buffer names unique adds <2>, <3>,
  29 ;; etc. to the end of (all but one of) the buffers.  This file replaces
  30 ;; that behavior, for buffers visiting files and dired buffers, with a
  31 ;; uniquification that adds parts of the file name until the buffer names
  32 ;; are unique.  For instance, buffers visiting /u/mernst/tmp/Makefile and
  33 ;; /usr/projects/zaphod/Makefile would be named Makefile|tmp and
  34 ;; Makefile|zaphod, respectively (instead of Makefile and Makefile<2>).
  35 ;; Other buffer name styles are also available.
  36
  37 ;; To use this file, do (require 'uniquify)
  38 ;; and set uniquify-buffer-name-style to one of its non-nil alternative values.
  39
  40 ;; For other options, see "User-visible variables", below.
  41
  42 ;; A version of uniquify.el that works under Emacs 18, Emacs 19, XEmacs,
  43 ;; and InfoDock is available from the maintainer.
  44
  45 ;; Doesn't work under NT when backslash is used as a path separator (forward
  46 ;;   slash path separator works fine).  To fix, check system-type against
  47 ;;   'windows-nt, write a routine that breaks paths down into components.
  48 ;;   (Surprisingly, there isn't one built in.)
  49
  50 ;;; Change Log:
  51
  52 ;; Originally by Dick King <king@reasoning.com> 15 May 86
  53 ;; Converted for Emacs 18 by Stephen Gildea <gildea@lcs.mit.edu>
  54 ;; Make uniquify-min-dir-content 0 truly non-invasive.  gildea 23 May 89
  55 ;; Some cleanup.  uniquify-min-dir-content default 0.  gildea 01 Jun 89
  56 ;; Don't rename to "".  Michael Ernst <mernst@theory.lcs.mit.edu> 15 Jun 94
  57 ;; Add kill-buffer-hook.  Kenneth Manheimer <ken.manheimer@nist.gov> 09 May 95
  58 ;; Add advice for rename-buffer and create-file-buffer, handle dired buffers,
  59 ;;  kill-buffer-rationalize-buffer-names-p, documentation.  mernst 24 May 95
  60 ;; Remove free variables, fix typos.  mernst 5 Jun 95
  61 ;; Efficiently support Emacs 19.27 & earlier.  ken.manheimer, mernst 10 Jun 95
  62 ;; Rename user options to "uniquify-...", add uniquify-reverse-dir-content-p,
  63 ;;  add uniquify-ask-about-buffer-names-p.  king, mernst 13 Jun 95
  64 ;; Prefix functions by "uniquify-..."; rename mnemonic-buffer-names to
  65 ;;  uniquify-buffer-name-style; add 'forward and 'post-forward-angle-brackets
  66 ;;  styles; remove uniquify-reverse-dir-content-p; add
  67 ;;  uniquify-trailing-separator-p.  mernst 4 Aug 95
  68 ;; Don't call expand-file-name on nil.  mernst 7 Jan 96
  69 ;; Check whether list-buffers-directory is bound.  mernst 11 Oct 96
  70 ;; Ignore non-file non-dired buffers. Colin Rafferty <craffert@ml.com> 3 Mar 97
  71 ;; Use last component, not "", for file name of directories.  mernst 27 Jun 97
  72 ;; Use directory-file-name; code cleanup.  mernst 6 Sep 97
  73
  74 ;; Valuable feedback was provided by
  75 ;; Paul Smith <psmith@baynetworks.com>,
  76 ;; Alastair Burt <burt@dfki.uni-kl.de>,
  77 ;; Bob Weiner <weiner@footloose.sps.mot.com>,
  78 ;; Albert L. Ting <alt@vlibs.com>,
  79 ;; gyro@reasoning.com,
  80 ;; Bryan O'Sullivan <bos@eng.sun.com>.
  81
  82
  83 ;;; Code:
  84
  85 (provide 'uniquify)
  86
  87 ;;; User-visible variables
  88
  89 (defgroup uniquify nil
  90   "Unique buffer names dependent on file name"
  91   :group 'applications)
  92
  93
  94 (defcustom uniquify-buffer-name-style nil
  95   "*If non-nil, buffer names are uniquified with parts of directory name.
  96 The value determines the buffer name style and is one of `forward',
  97 `reverse', `post-forward' (the default), or `post-forward-angle-brackets'.
  98 For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name'
  99 would have the following buffer names in the various styles:
 100   forward        bar/mumble/name  quux/mumble/name
 101   reverse        name\\mumble\\bar  name\\mumble\\quux
 102   post-forward   name|bar/mumble  name|quux/mumble
 103   post-forward-angle-brackets   name<bar/mumble>  name<quux/mumble>
 104   nil            name  name<2>"
 105   :type '(radio (const forward)
 106                 (const reverse)
 107                 (const post-forward)
 108                 (const post-forward-angle-brackets)
 109                 (const :tag "standard Emacs behavior (nil)" nil))
 110   :require 'uniquify
 111   :group 'uniquify)
 112
 113 (defcustom uniquify-after-kill-buffer-p nil
 114   "*If non-nil, rerationalize buffer names after a buffer has been killed.
 115 This can be dangerous if Emacs Lisp code is keeping track of buffers by their
 116 names (rather than keeping pointers to the buffers themselves)."
 117   :type 'boolean
 118   :group 'uniquify)
 119
 120 (defcustom uniquify-ask-about-buffer-names-p nil
 121   "*If non-nil, permit user to choose names for buffers with same base file.
 122 If the user chooses to name a buffer, uniquification is preempted and no
 123 other buffer names are changed."
 124   :type 'boolean
 125   :group 'uniquify)
 126
 127 (defcustom uniquify-min-dir-content 0
 128   "*Minimum number of directory name components included in buffer name."
 129   :type 'integer
 130   :group 'uniquify)
 131
 132 (defcustom uniquify-separator nil
 133   "*String separator for buffer name components.
 134 When `uniquify-buffer-name-style' is `post-forward', separates
 135 base file name from directory part in buffer names (default \"|\").
 136 When `uniquify-buffer-name-style' is `reverse', separates all
 137 file name components (default \"\\\")."
 138   :type '(choice (const nil) string)
 139   :group 'uniquify)
 140
 141 (defcustom uniquify-trailing-separator-p nil
 142   "*If non-nil, add a file name separator to dired buffer names.
 143 If `uniquify-buffer-name-style' is `forward', add the separator at the end;
 144 if it is `reverse', add the separator at the beginning; otherwise, this
 145 variable is ignored."
 146   :type 'boolean
 147   :group 'uniquify)
 148
 149
 150 ;;; Utilities
 151
 152 (defmacro uniquify-push (item list)
 153   (` (setq (, list) (cons (, item) (, list)))))
 154
 155 ;; For directories, return the last component, not the empty string.
 156 (defun uniquify-file-name-nondirectory (file-name)
 157   (file-name-nondirectory (directory-file-name file-name)))
 158
 159 ;; uniquify-fix-list data structure
 160 (defmacro uniquify-fix-item-base (a)
 161   (` (car (, a))))
 162 (defmacro uniquify-fix-item-filename (a)
 163   (` (car (cdr (, a)))))
 164 (defmacro uniquify-fix-item-buffer (a)
 165   (` (car (cdr (cdr (, a))))))
 166 ;; Not a macro: passed to mapcar.
 167 (defun uniquify-fix-item-unrationalized-buffer (item)
 168   (or (car (cdr (cdr (cdr item)))) nil))        ;maybe better in the future
 169
 170 (defun uniquify-fix-item-filename-lessp (fixlist1 fixlist2)
 171   (uniquify-filename-lessp (uniquify-fix-item-filename fixlist1)
 172                            (uniquify-fix-item-filename fixlist2)))
 173
 174 ;; Internal variables used free
 175 (defvar uniquify-non-file-buffer-names nil)
 176 (defvar uniquify-possibly-resolvable nil)
 177
 178 ;;; Main entry point.
 179
 180 (defun uniquify-rationalize-file-buffer-names (&optional newbuffile newbuf)
 181   "Makes file buffer names unique by adding segments from file name.
 182 If `uniquify-min-dir-content' > 0, always pulls that many
 183 file name elements.  Arguments cause only a subset of buffers to be renamed."
 184   (interactive)
 185   (let (fix-list
 186         uniquify-non-file-buffer-names)
 187     (let ((buffers (buffer-list)))
 188       (while buffers
 189         (let* ((buffer (car buffers))
 190                (bfn (if (eq buffer newbuf)
 191                         (and newbuffile
 192                              (expand-file-name
 193                               (if (file-directory-p newbuffile)
 194                                   (directory-file-name newbuffile)
 195                                newbuffile)))
 196                       (uniquify-buffer-file-name buffer)))
 197                (rawname (and bfn (uniquify-file-name-nondirectory bfn)))
 198                (deserving (and rawname
 199                                (or (not newbuffile)
 200                                    (equal rawname
 201                                           (uniquify-file-name-nondirectory newbuffile))))))
 202           (if deserving
 203               (uniquify-push (list rawname bfn buffer nil) fix-list)
 204             (uniquify-push (list (buffer-name buffer))
 205                            uniquify-non-file-buffer-names)))
 206         (setq buffers (cdr buffers))))
 207     ;; selects buffers whose names may need changing, and others that
 208     ;; may conflict.
 209     (setq fix-list
 210           (sort fix-list 'uniquify-fix-item-filename-lessp))
 211     ;; bringing conflicting names together
 212     (uniquify-rationalize-a-list fix-list uniquify-min-dir-content)
 213     (mapcar 'uniquify-fix-item-unrationalized-buffer fix-list)))
 214
 215 ;; uniquify's version of buffer-file-name; result never contains trailing slash
 216 (defun uniquify-buffer-file-name (buffer)
 217   "Return name of file BUFFER is visiting, or nil if none.
 218 Works on dired buffers and ordinary file-visiting buffers, but no others."
 219   (or (buffer-file-name buffer)
 220       (and (featurep 'dired)
 221       (save-excursion
 222         (set-buffer buffer)
 223         (and
 224          (eq major-mode 'dired-mode)    ; do nothing if not a dired buffer
 225          (if (boundp 'list-buffers-directory) ; XEmacs mightn't define this
 226              (and list-buffers-directory
 227                   (directory-file-name list-buffers-directory))
 228            ;; don't use default-directory if dired-directory is nil
 229            (and dired-directory
 230                 (expand-file-name
 231                  (directory-file-name
 232                   (if (consp dired-directory)
 233                       (car dired-directory)
 234                     dired-directory))))))))))
 235
 236 ;; This examines the filename components in reverse order.
 237 (defun uniquify-filename-lessp (s1 s2)
 238   (let ((s1f (uniquify-file-name-nondirectory s1))
 239         (s2f (uniquify-file-name-nondirectory s2)))
 240     (and (not (equal s2f ""))
 241          (or (string-lessp s1f s2f)
 242              (and (equal s1f s2f)
 243                   (let ((s1d (file-name-directory s1))
 244                         (s2d (file-name-directory s2)))
 245                     (and (not (<= (length s2d) 1))
 246                          (or (<= (length s1d) 1)
 247                              (uniquify-filename-lessp
 248                               (substring s1d 0 -1)
 249                               (substring s2d 0 -1))))))))))
 250
 251 (defun uniquify-rationalize-a-list (fix-list depth)
 252   (let (conflicting-sublist     ; all elements have the same proposed name
 253         (old-name "")
 254         proposed-name uniquify-possibly-resolvable)
 255     (while fix-list
 256       (let ((item (car fix-list)))
 257         (setq proposed-name (uniquify-get-proposed-name item depth))
 258         (if (not (equal proposed-name old-name))
 259             (progn
 260               (uniquify-rationalize-conflicting-sublist
 261                conflicting-sublist old-name depth)
 262               (setq conflicting-sublist nil)))
 263         (uniquify-push item conflicting-sublist)
 264         (setq old-name proposed-name))
 265       (setq fix-list (cdr fix-list)))
 266     (uniquify-rationalize-conflicting-sublist
 267      conflicting-sublist old-name depth)))
 268
 269 (defun uniquify-get-proposed-name (item depth)
 270   (let (index
 271         (extra-string "")
 272         (n depth)
 273         (base (uniquify-fix-item-base item))
 274         (fn (uniquify-fix-item-filename item)))
 275     (while (and (> n 0)
 276                 (setq index (string-match
 277                              (concat "\\(^\\|/[^/]*\\)/"
 278                                      (regexp-quote extra-string)
 279                                      (regexp-quote base)
 280                                      "\\'")
 281                              fn)))
 282       (setq extra-string (substring fn
 283                                     (if (zerop index) 0 (1+ index))
 284                                     ;; (- (length base)) fails for base = "".
 285                                     ;; Equivalently, we could have used
 286                                     ;; (apply 'substring ...
 287                                     ;;        (and (not (string= "" base))
 288                                     ;;             (list (- (length base)))))
 289                                     (- (length fn) (length base)))
 290             n (1- n)))
 291     (if (zerop n) (setq uniquify-possibly-resolvable t))
 292
 293
 294     ;; Distinguish directories by adding extra separator.
 295     (if (and uniquify-trailing-separator-p
 296              (file-directory-p fn)
 297              (not (string-equal base "")))
 298         (cond ((eq uniquify-buffer-name-style 'forward)
 299                (setq base (concat base "/")))
 300               ((eq uniquify-buffer-name-style 'reverse)
 301                (setq base (concat (or uniquify-separator "\\") base)))))
 302
 303     ;; Trim trailing separator on directory part
 304     (if (and (not (string-equal extra-string ""))
 305              (or (eq uniquify-buffer-name-style 'post-forward)
 306                  (eq uniquify-buffer-name-style 'post-forward-angle-brackets)))
 307         (setq extra-string (substring extra-string 0
 308                                       (- (length extra-string) 1))))
 309
 310     (cond ((string-equal extra-string "")
 311            base)
 312           ((string-equal base "")
 313            extra-string)
 314           ((eq uniquify-buffer-name-style 'forward)
 315            (concat extra-string base))
 316           ((eq uniquify-buffer-name-style 'reverse)
 317            (concat base (uniquify-reverse-components extra-string)))
 318           ((eq uniquify-buffer-name-style 'post-forward)
 319            (concat base (or uniquify-separator "|") extra-string))
 320           ((eq uniquify-buffer-name-style 'post-forward-angle-brackets)
 321            (concat base "<" extra-string ">"))
 322           (t (error "Bad value for uniquify-buffer-name-style: %s"
 323                     uniquify-buffer-name-style)))))
 324
 325
 326 ;; Deal with conflicting-sublist, all of whose elements have identical
 327 ;; "base" components.
 328 (defun uniquify-rationalize-conflicting-sublist (conflicting-sublist old-name depth)
 329   (or (null conflicting-sublist)
 330       (and (null (cdr conflicting-sublist))
 331            (not (assoc old-name uniquify-non-file-buffer-names))
 332            (or (and (not (string= old-name ""))
 333                     (uniquify-rename-buffer (car conflicting-sublist) old-name))
 334                t))
 335       (if uniquify-possibly-resolvable
 336           (uniquify-rationalize-a-list conflicting-sublist (1+ depth)))))
 337
 338 (defun uniquify-rename-buffer (item newname)
 339   (let ((buffer (uniquify-fix-item-buffer item)))
 340     (if (not (equal newname (buffer-name buffer)))
 341         (let ((unset (current-buffer))
 342               ;; avoid hooks on rename-buffer
 343               (uniquify-buffer-name-style nil))
 344           (set-buffer buffer)
 345           (rename-buffer newname)
 346           (set-buffer unset))))
 347   (rplaca (nthcdr 3 item) t))
 348
 349 (defun uniquify-reverse-components (instring)
 350   (let ((sofar '())
 351         (cursor 0)
 352         (len (length instring))
 353         (sep (or uniquify-separator "\\")))
 354     (while (< cursor len)
 355       (if (= (aref instring cursor) ?/)
 356           (setq sofar (cons sep sofar)
 357                 cursor (1+ cursor))
 358         (let ((first-slash (or (string-match "/" instring cursor) len)))
 359           (setq sofar (cons (substring instring cursor first-slash) sofar)
 360                 cursor first-slash))))
 361     (apply (function concat) sofar)))
 362
 363
 364 ;;; Hooks from the rest of Emacs
 365
 366 ;; The logical place to put all this code is in generate-new-buffer-name.
 367 ;; It's written in C, so we would add a generate-new-buffer-name-function
 368 ;; which, if non-nil, would be called instead of the C.  One problem with
 369 ;; that is that generate-new-buffer-name takes a potential buffer name as
 370 ;; its argument -- not other information, such as what file the buffer will
 371 ;; visit.
 372
 373 ;; The below solution works because generate-new-buffer-name is called
 374 ;; only by rename-buffer (which, as of 19.29, is never called from C) and
 375 ;; generate-new-buffer, which is called only by Lisp functions
 376 ;; create-file-buffer and rename-uniquely.  Rename-uniquely generally
 377 ;; isn't used for buffers visiting files, so it's sufficient to hook
 378 ;; rename-buffer and create-file-buffer.  (Setting find-file-hooks isn't
 379 ;; sufficient.)
 380
 381 (defadvice rename-buffer (after rename-buffer-uniquify activate)
 382   "Uniquify buffer names with parts of directory name."
 383   (if (and uniquify-buffer-name-style
 384            ;; UNIQUE argument
 385            (ad-get-arg 1))
 386       (progn
 387         (if uniquify-after-kill-buffer-p
 388             ;; call with no argument; rationalize vs. old name as well as new
 389             (uniquify-rationalize-file-buffer-names)
 390           ;; call with argument: rationalize vs. new name only
 391           (uniquify-rationalize-file-buffer-names
 392            (uniquify-buffer-file-name (current-buffer)) (current-buffer)))
 393         (setq ad-return-value (buffer-name (current-buffer))))))
 394
 395 (defadvice create-file-buffer (after create-file-buffer-uniquify activate)
 396   "Uniquify buffer names with parts of directory name."
 397   (if uniquify-buffer-name-style
 398       (uniquify-rationalize-file-buffer-names (ad-get-arg 0) ad-return-value)))
 399
 400 ;; Buffer deletion
 401 ;; Rerationalize after a buffer is killed, to reduce coinciding buffer names.
 402 ;; This mechanism uses `kill-buffer-hook', which runs *before* deletion.
 403 ;; That means that the kill-buffer-hook function cannot just delete the
 404 ;; buffer -- it has to set something to do the rationalization *later*.
 405 ;; It actually puts another function on `post-command-hook'.  This other
 406 ;; function runs the rationalization and then removes itself from the hook.
 407 ;; Is there a better way to accomplish this?
 408 ;; (This ought to set some global variables so the work is done only for
 409 ;; buffers with names similar to the deleted buffer.  -MDE)
 410
 411 (defun delay-uniquify-rationalize-file-buffer-names ()
 412   "Add `delayed-uniquify-rationalize-file-buffer-names' to `post-command-hook'.
 413 For use on, eg, `kill-buffer-hook', to rationalize *after* buffer deletion."
 414   (if (and uniquify-buffer-name-style
 415            uniquify-after-kill-buffer-p)
 416       (add-hook 'post-command-hook
 417                 'delayed-uniquify-rationalize-file-buffer-names)))
 418
 419 (defun delayed-uniquify-rationalize-file-buffer-names ()
 420   "Rerationalize buffer names and remove self from `post-command-hook'.
 421 See also `delay-rationalize-file-buffer-names' for hook setter."
 422   (uniquify-rationalize-file-buffer-names)
 423   (remove-hook 'post-command-hook
 424                'delayed-uniquify-rationalize-file-buffer-names))
 425
 426 (add-hook 'kill-buffer-hook 'delay-uniquify-rationalize-file-buffer-names)
 427
 428 ;;; uniquify.el ends here