lisp/apropos.el

   1 ;;; apropos.el --- apropos commands for users and programmers.
   2
   3 ;; Copyright (C) 1989, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Joe Wells <jbw@bigbird.bu.edu>
   6 ;; Rewritten: Daniel.Pfeiffer@Informatik.START.dbp.de, fax (+49 69) 7588-2389
   7 ;; Keywords: help
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The ideas for this package were derived from the C code in
  29 ;; src/keymap.c and elsewhere.  The functions in this file should
  30 ;; always be byte-compiled for speed.  Someone should rewrite this in
  31 ;; C (as part of src/keymap.c) for speed.
  32
  33 ;; The idea for super-apropos is based on the original implementation
  34 ;; by Lynn Slater <lrs@esl.com>.
  35
  36 ;; History:
  37 ;; Fixed bug, current-local-map can return nil.
  38 ;; Change, doesn't calculate key-bindings unless needed.
  39 ;; Added super-apropos capability, changed print functions.
  40 ;;; Made fast-apropos and super-apropos share code.
  41 ;;; Sped up fast-apropos again.
  42 ;; Added apropos-do-all option.
  43 ;;; Added fast-command-apropos.
  44 ;; Changed doc strings to comments for helping functions.
  45 ;;; Made doc file buffer read-only, buried it.
  46 ;; Only call substitute-command-keys if do-all set.
  47
  48 ;; Optionally use configurable faces to make the output more legible.
  49 ;; Differentiate between command, function and macro.
  50 ;; Apropos-command (ex command-apropos) does cmd and optionally user var.
  51 ;; Apropos shows all 3 aspects of symbols (fn, var and plist)
  52 ;; Apropos-documentation (ex super-apropos) now finds all it should.
  53 ;; New apropos-value snoops through all values and optionally plists.
  54 ;; Reading DOC file doesn't load nroff.
  55 ;; Added hypertext following of documentation, mouse-2 on variable gives value
  56 ;;   from buffer in active window.
  57
  58 ;;; Code:
  59
  60 (defgroup apropos nil
  61   "Apropos commands for users and programmers"
  62   :group 'Help
  63   :prefix "apropos")
  64
  65 ;; I see a degradation of maybe 10-20% only.
  66 (defcustom apropos-do-all nil
  67   "*Whether the apropos commands should do more.
  68
  69 Slows them down more or less.  Set this non-nil if you have a fast machine."
  70   :group 'apropos
  71   :type 'boolean)
  72
  73
  74 (defcustom apropos-symbol-face (if window-system 'bold)
  75   "*Face for symbol name in apropos output or `nil'.
  76 This looks good, but slows down the commands several times."
  77   :group 'apropos
  78   :type 'face)
  79
  80 (defcustom apropos-keybinding-face (if window-system 'underline)
  81   "*Face for keybinding display in apropos output or `nil'.
  82 This looks good, but slows down the commands several times."
  83   :group 'apropos
  84   :type 'face)
  85
  86 (defcustom apropos-label-face (if window-system 'italic)
  87   "*Face for label (Command, Variable ...) in apropos output or `nil'.
  88 If this is `nil' no mouse highlighting occurs.
  89 This looks good, but slows down the commands several times.
  90 When this is a face name, as it is initially, it gets transformed to a
  91 text-property list for efficiency."
  92   :group 'apropos
  93   :type 'face)
  94
  95 (defcustom apropos-property-face (if window-system 'bold-italic)
  96   "*Face for property name in apropos output or `nil'.
  97 This looks good, but slows down the commands several times."
  98   :group 'apropos
  99   :type 'face)
 100
 101 (defcustom apropos-match-face (if window-system 'secondary-selection)
 102   "*Face for matching part in apropos-documentation/value output or `nil'.
 103 This looks good, but slows down the commands several times."
 104   :group 'apropos
 105   :type 'face)
 106
 107
 108 (defvar apropos-mode-map
 109   (let ((map (make-sparse-keymap)))
 110     (define-key map "\C-m" 'apropos-follow)
 111     (define-key map " "      'scroll-up)
 112     (define-key map "\177"   'scroll-down)
 113     (define-key map [mouse-2] 'apropos-mouse-follow)
 114     (define-key map [down-mouse-2] nil)
 115     map)
 116   "Keymap used in Apropos mode.")
 117
 118
 119 (defvar apropos-regexp nil
 120   "Regexp used in current apropos run.")
 121
 122 (defvar apropos-files-scanned ()
 123   "List of elc files already scanned in current run of `apropos-documentation'.")
 124
 125 (defvar apropos-accumulator ()
 126   "Alist of symbols already found in current apropos run.")
 127
 128 (defvar apropos-item ()
 129   "Current item in or for apropos-accumulator.")
 130 \f
 131 (defun apropos-mode ()
 132   "Major mode for following hyperlinks in output of apropos commands.
 133
 134 \\{apropos-mode-map}"
 135   (interactive)
 136   (kill-all-local-variables)
 137   (use-local-map apropos-mode-map)
 138   (setq major-mode 'apropos-mode
 139         mode-name "Apropos"))
 140
 141 ;;;###autoload
 142 (defun apropos-variable (regexp)
 143   (interactive (list (read-string "Apropos variable (regexp): ")))
 144   (apropos-command regexp nil t))
 145
 146 ;; For auld lang syne:
 147 ;;;###autoload
 148 (fset 'command-apropos 'apropos-command)
 149 ;;;###autoload
 150 (defun apropos-command (apropos-regexp &optional do-all just-vars)
 151   "Show commands (interactively callable functions) that match REGEXP.
 152 With optional prefix ARG, or if `apropos-do-all' is non-nil, also show
 153 variables.  If JUST-VARS is non-nil, show only variables."
 154   (interactive (list (read-string (concat
 155                                    "Apropos command "
 156                                    (if (or current-prefix-arg
 157                                            apropos-do-all)
 158                                        "or variable ")
 159                                    "(regexp): "))
 160                      current-prefix-arg))
 161   (let ((message
 162          (let ((standard-output (get-buffer-create "*Apropos*")))
 163            (print-help-return-message 'identity))))
 164     (or do-all (setq do-all apropos-do-all))
 165     (setq apropos-accumulator
 166           (apropos-internal apropos-regexp
 167                             (if do-all
 168                                 (lambda (symbol) (or (commandp symbol)
 169                                                      (user-variable-p symbol)))
 170                               (if just-vars 'user-variable-p
 171                                 'commandp))))
 172     (let ((tem apropos-accumulator))
 173       (while tem
 174         (if (get (car tem) 'apropos-inhibit)
 175             (setq apropos-accumulator (delq (car tem) apropos-accumulator)))
 176         (setq tem (cdr tem))))
 177     (if (apropos-print
 178          t
 179          (lambda (p)
 180            (let (doc symbol)
 181              (while p
 182                (setcar p (list
 183                           (setq symbol (car p))
 184                           (if (or do-all (not just-vars))
 185                               (if (commandp symbol)
 186                                   (if (setq doc (documentation symbol t))
 187                                       (substring doc 0 (string-match "\n" doc))
 188                                     "(not documented)")))
 189                           (and do-all
 190                                (user-variable-p symbol)
 191                                (if (setq doc (documentation-property
 192                                               symbol 'variable-documentation t))
 193                                    (substring doc 0
 194                                               (string-match "\n" doc))))))
 195                (setq p (cdr p)))))
 196          nil)
 197         (and message (message message)))))
 198
 199
 200 ;;;###autoload
 201 (defun apropos (apropos-regexp &optional do-all)
 202   "Show all bound symbols whose names match REGEXP.
 203 With optional prefix ARG or if `apropos-do-all' is non-nil, also show unbound
 204 symbols and key bindings, which is a little more time-consuming.
 205 Returns list of symbols and documentation found."
 206   (interactive "sApropos symbol (regexp): \nP")
 207   (setq apropos-accumulator
 208         (apropos-internal apropos-regexp
 209                           (and (not do-all)
 210                                (not apropos-do-all)
 211                                (lambda (symbol)
 212                                  (or (fboundp symbol)
 213                                      (boundp symbol)
 214                                      (facep symbol)
 215                                      (symbol-plist symbol))))))
 216   (let ((tem apropos-accumulator))
 217     (while tem
 218       (if (get (car tem) 'apropos-inhibit)
 219           (setq apropos-accumulator (delq (car tem) apropos-accumulator)))
 220       (setq tem (cdr tem))))
 221   (apropos-print
 222    (or do-all apropos-do-all)
 223    (lambda (p)
 224      (let (symbol doc properties)
 225        (while p
 226          (setcar p (list
 227                     (setq symbol (car p))
 228                     (when (fboundp symbol)
 229                       (if (setq doc (documentation symbol t))
 230                           (substring doc 0 (string-match "\n" doc))
 231                         "(not documented)"))
 232                     (when (boundp symbol)
 233                       (if (setq doc (documentation-property
 234                                      symbol 'variable-documentation t))
 235                           (substring doc 0 (string-match "\n" doc))
 236                         "(not documented)"))
 237                     (when (setq properties (symbol-plist symbol))
 238                       (setq doc (list (car properties)))
 239                       (while (setq properties (cdr (cdr properties)))
 240                         (setq doc (cons (car properties) doc)))
 241                       (mapconcat #'symbol-name (nreverse doc) " "))
 242                     (when (get symbol 'widget-type)
 243                       (if (setq doc (documentation-property
 244                                      symbol 'widget-documentation t))
 245                           (substring doc 0
 246                                      (string-match "\n" doc))
 247                         "(not documented)"))
 248                     (when (facep symbol)
 249                       (if (setq doc (documentation-property
 250                                      symbol 'face-documentation t))
 251                           (substring doc 0
 252                                      (string-match "\n" doc))
 253                         "(not documented)"))
 254                     (when (get symbol 'custom-group)
 255                       (if (setq doc (documentation-property
 256                                      symbol 'group-documentation t))
 257                           (substring doc 0
 258                                      (string-match "\n" doc))
 259                         "(not documented)"))))
 260          (setq p (cdr p)))))
 261    nil))
 262
 263
 264 ;;;###autoload
 265 (defun apropos-value (apropos-regexp &optional do-all)
 266   "Show all symbols whose value's printed image matches REGEXP.
 267 With optional prefix ARG or if `apropos-do-all' is non-nil, also looks
 268 at the function and at the names and values of properties.
 269 Returns list of symbols and values found."
 270   (interactive "sApropos value (regexp): \nP")
 271   (or do-all (setq do-all apropos-do-all))
 272   (setq apropos-accumulator ())
 273    (let (f v p)
 274      (mapatoms
 275       (lambda (symbol)
 276         (setq f nil v nil p nil)
 277         (or (memq symbol '(apropos-regexp do-all apropos-accumulator
 278                                           symbol f v p))
 279             (setq v (apropos-value-internal 'boundp symbol 'symbol-value)))
 280         (if do-all
 281             (setq f (apropos-value-internal 'fboundp symbol 'symbol-function)
 282                   p (apropos-format-plist symbol "\n    " t)))
 283         (if (or f v p)
 284             (setq apropos-accumulator (cons (list symbol f v p)
 285                                             apropos-accumulator))))))
 286   (apropos-print nil nil t))
 287
 288
 289 ;;;###autoload
 290 (defun apropos-documentation (apropos-regexp &optional do-all)
 291   "Show symbols whose documentation contain matches for REGEXP.
 292 With optional prefix ARG or if `apropos-do-all' is non-nil, also use
 293 documentation that is not stored in the documentation file and show key
 294 bindings.
 295 Returns list of symbols and documentation found."
 296   (interactive "sApropos documentation (regexp): \nP")
 297   (or do-all (setq do-all apropos-do-all))
 298   (setq apropos-accumulator () apropos-files-scanned ())
 299   (let ((standard-input (get-buffer-create " apropos-temp"))
 300         f v)
 301     (unwind-protect
 302         (save-excursion
 303           (set-buffer standard-input)
 304           (apropos-documentation-check-doc-file)
 305           (if do-all
 306               (mapatoms
 307                (lambda (symbol)
 308                  (setq f (apropos-safe-documentation symbol)
 309                        v (get symbol 'variable-documentation))
 310                  (if (integerp v) (setq v))
 311                  (setq f (apropos-documentation-internal f)
 312                        v (apropos-documentation-internal v))
 313                  (if (or f v)
 314                      (if (setq apropos-item
 315                                (cdr (assq symbol apropos-accumulator)))
 316                          (progn
 317                            (if f
 318                                (setcar apropos-item f))
 319                            (if v
 320                                (setcar (cdr apropos-item) v)))
 321                        (setq apropos-accumulator
 322                              (cons (list symbol f v)
 323                                    apropos-accumulator)))))))
 324           (apropos-print nil nil t))
 325       (kill-buffer standard-input))))
 326
 327 \f
 328 (defun apropos-value-internal (predicate symbol function)
 329   (if (funcall predicate symbol)
 330       (progn
 331         (setq symbol (prin1-to-string (funcall function symbol)))
 332         (if (string-match apropos-regexp symbol)
 333             (progn
 334               (if apropos-match-face
 335                   (put-text-property (match-beginning 0) (match-end 0)
 336                                      'face apropos-match-face
 337                                      symbol))
 338               symbol)))))
 339
 340 (defun apropos-documentation-internal (doc)
 341   (if (consp doc)
 342       (apropos-documentation-check-elc-file (car doc))
 343     (and doc
 344          (string-match apropos-regexp doc)
 345          (progn
 346            (if apropos-match-face
 347                (put-text-property (match-beginning 0)
 348                                   (match-end 0)
 349                                   'face apropos-match-face
 350                                   (setq doc (copy-sequence doc))))
 351            doc))))
 352
 353 (defun apropos-format-plist (pl sep &optional compare)
 354   (setq pl (symbol-plist pl))
 355   (let (p p-out)
 356     (while pl
 357       (setq p (format "%s %S" (car pl) (nth 1 pl)))
 358       (if (or (not compare) (string-match apropos-regexp p))
 359           (if apropos-property-face
 360               (put-text-property 0 (length (symbol-name (car pl)))
 361                                  'face apropos-property-face p))
 362         (setq p nil))
 363       (if p
 364           (progn
 365             (and compare apropos-match-face
 366                  (put-text-property (match-beginning 0) (match-end 0)
 367                                     'face apropos-match-face
 368                                     p))
 369             (setq p-out (concat p-out (if p-out sep) p))))
 370       (setq pl (nthcdr 2 pl)))
 371     p-out))
 372
 373
 374 ;; Finds all documentation related to APROPOS-REGEXP in internal-doc-file-name.
 375
 376 (defun apropos-documentation-check-doc-file ()
 377   (let (type symbol (sepa 2) sepb beg end)
 378     (insert ?\^_)
 379     (backward-char)
 380     (insert-file-contents (concat doc-directory internal-doc-file-name))
 381     (forward-char)
 382     (while (save-excursion
 383              (setq sepb (search-forward "\^_"))
 384              (not (eobp)))
 385       (beginning-of-line 2)
 386       (if (save-restriction
 387             (narrow-to-region (point) (1- sepb))
 388             (re-search-forward apropos-regexp nil t))
 389           (progn
 390             (setq beg (match-beginning 0)
 391                   end (point))
 392             (goto-char (1+ sepa))
 393             (or (setq type (if (eq ?F (preceding-char))
 394                                1        ; function documentation
 395                              2)         ; variable documentation
 396                       symbol (read)
 397                       beg (- beg (point) 1)
 398                       end (- end (point) 1)
 399                       doc (buffer-substring (1+ (point)) (1- sepb))
 400                       apropos-item (assq symbol apropos-accumulator))
 401                 (setq apropos-item (list symbol nil nil)
 402                       apropos-accumulator (cons apropos-item
 403                                                 apropos-accumulator)))
 404             (if apropos-match-face
 405                 (put-text-property beg end 'face apropos-match-face doc))
 406             (setcar (nthcdr type apropos-item) doc)))
 407       (setq sepa (goto-char sepb)))))
 408
 409 (defun apropos-documentation-check-elc-file (file)
 410   (if (member file apropos-files-scanned)
 411       nil
 412     (let (symbol doc beg end this-is-a-variable)
 413       (setq apropos-files-scanned (cons file apropos-files-scanned))
 414       (erase-buffer)
 415       (insert-file-contents file)
 416       (while (search-forward "\n#@" nil t)
 417         ;; Read the comment length, and advance over it.
 418         (setq end (read)
 419               beg (1+ (point))
 420               end (+ (point) end -1))
 421         (forward-char)
 422         (if (save-restriction
 423               ;; match ^ and $ relative to doc string
 424               (narrow-to-region beg end)
 425               (re-search-forward apropos-regexp nil t))
 426             (progn
 427               (goto-char (+ end 2))
 428               (setq doc (buffer-substring beg end)
 429                     end (- (match-end 0) beg)
 430                     beg (- (match-beginning 0) beg)
 431                     this-is-a-variable (looking-at "(def\\(var\\|const\\) ")
 432                     symbol (progn
 433                              (skip-chars-forward "(a-z")
 434                              (forward-char)
 435                              (read))
 436                     symbol (if (consp symbol)
 437                                (nth 1 symbol)
 438                              symbol))
 439               (if (if this-is-a-variable
 440                       (get symbol 'variable-documentation)
 441                     (and (fboundp symbol) (apropos-safe-documentation symbol)))
 442                   (progn
 443                     (or (setq apropos-item (assq symbol apropos-accumulator))
 444                         (setq apropos-item (list symbol nil nil)
 445                               apropos-accumulator (cons apropos-item
 446                                                         apropos-accumulator)))
 447                     (if apropos-match-face
 448                         (put-text-property beg end 'face apropos-match-face
 449                                            doc))
 450                     (setcar (nthcdr (if this-is-a-variable 2 1)
 451                                     apropos-item)
 452                             doc)))))))))
 453
 454
 455
 456 (defun apropos-safe-documentation (function)
 457   "Like documentation, except it avoids calling `get_doc_string'.
 458 Will return nil instead."
 459   (while (and function (symbolp function))
 460     (setq function (if (fboundp function)
 461                        (symbol-function function))))
 462   (if (eq (car-safe function) 'macro)
 463       (setq function (cdr function)))
 464   (setq function (if (byte-code-function-p function)
 465                      (if (> (length function) 4)
 466                          (aref function 4))
 467                    (if (eq (car-safe function) 'autoload)
 468                        (nth 2 function)
 469                      (if (eq (car-safe function) 'lambda)
 470                          (if (stringp (nth 2 function))
 471                              (nth 2 function)
 472                            (if (stringp (nth 3 function))
 473                                (nth 3 function)))))))
 474   (if (integerp function)
 475       nil
 476     function))
 477
 478
 479
 480 (defun apropos-print (do-keys doc-fn spacing)
 481   "Output result of various apropos commands with `apropos-regexp'.
 482 APROPOS-ACCUMULATOR is a list.  Optional DOC-FN is called for each element
 483 of apropos-accumulator and may modify it resulting in (symbol fn-doc
 484 var-doc [plist-doc]).  Returns sorted list of symbols and documentation
 485 found."
 486   (if (null apropos-accumulator)
 487       (message "No apropos matches for `%s'" apropos-regexp)
 488     (if doc-fn
 489         (funcall doc-fn apropos-accumulator))
 490     (setq apropos-accumulator
 491           (sort apropos-accumulator (lambda (a b)
 492                                       (string-lessp (car a) (car b)))))
 493     (and apropos-label-face
 494          (symbolp apropos-label-face)
 495          (setq apropos-label-face `(face ,apropos-label-face
 496                                          mouse-face highlight)))
 497     (with-output-to-temp-buffer "*Apropos*"
 498       (let ((p apropos-accumulator)
 499             (old-buffer (current-buffer))
 500             symbol item point1 point2)
 501         (set-buffer standard-output)
 502         (apropos-mode)
 503         (if window-system
 504             (insert "If you move the mouse over text that changes color,\n"
 505                     (substitute-command-keys
 506                      "you can click \\[apropos-mouse-follow] to get more information.\n")))
 507         (insert (substitute-command-keys
 508                  "In this buffer, type \\[apropos-follow] to get full documentation.\n\n"))
 509         (while (consp p)
 510           (or (not spacing) (bobp) (terpri))
 511           (setq apropos-item (car p)
 512                 symbol (car apropos-item)
 513                 p (cdr p)
 514                 point1 (point))
 515           (princ symbol)                        ; print symbol name
 516           (setq point2 (point))
 517           ;; Calculate key-bindings if we want them.
 518           (and do-keys
 519                (commandp symbol)
 520                (indent-to 30 1)
 521                (if (let ((keys
 522                           (save-excursion
 523                             (set-buffer old-buffer)
 524                             (where-is-internal symbol)))
 525                          filtered)
 526                      ;; Copy over the list of key sequences,
 527                      ;; omitting any that contain a buffer or a frame.
 528                      (while keys
 529                        (let ((key (car keys))
 530                              (i 0)
 531                              loser)
 532                          (while (< i (length key))
 533                            (if (or (framep (aref key i))
 534                                    (bufferp (aref key i)))
 535                                (setq loser t))
 536                            (setq i (1+ i)))
 537                          (or loser
 538                              (setq filtered (cons key filtered))))
 539                        (setq keys (cdr keys)))
 540                      (setq item filtered))
 541                    ;; Convert the remaining keys to a string and insert.
 542                    (insert
 543                     (mapconcat
 544                      (lambda (key)
 545                        (setq key (key-description key))
 546                        (if apropos-keybinding-face
 547                            (put-text-property 0 (length key)
 548                                               'face apropos-keybinding-face
 549                                               key))
 550                        key)
 551                      item ", "))
 552                  (insert "M-x")
 553                  (put-text-property (- (point) 3) (point)
 554                                     'face apropos-keybinding-face)
 555                  (insert " " (symbol-name symbol) " ")
 556                  (insert "RET")
 557                  (put-text-property (- (point) 3) (point)
 558                                     'face apropos-keybinding-face)))
 559           (terpri)
 560           ;; only now so we don't propagate text attributes all over
 561           (put-text-property point1 point2 'item
 562                              (if (eval `(or ,@(cdr apropos-item)))
 563                                  (car apropos-item)
 564                                apropos-item))
 565           (if apropos-symbol-face
 566               (put-text-property point1 point2 'face apropos-symbol-face))
 567           (apropos-print-doc 'describe-function 1
 568                              (if (commandp symbol)
 569                                  "Command"
 570                                (if (apropos-macrop symbol)
 571                                    "Macro"
 572                                  "Function"))
 573                              t)
 574           (if (get symbol 'custom-type)
 575               (apropos-print-doc 'customize-variable-other-window 2
 576                                  "User Option" t)
 577             (apropos-print-doc 'describe-variable 2
 578                                "Variable" t))
 579           (apropos-print-doc 'customize-group-other-window 6 "Group" t)
 580           (apropos-print-doc 'customize-face-other-window 5 "Face" t)
 581           (apropos-print-doc 'widget-browse-other-window 4 "Widget" t)
 582           (apropos-print-doc 'apropos-describe-plist 3
 583                              "Plist" nil)))))
 584   (prog1 apropos-accumulator
 585     (setq apropos-accumulator ())))     ; permit gc
 586
 587
 588 (defun apropos-macrop (symbol)
 589   "T if SYMBOL is a Lisp macro."
 590   (and (fboundp symbol)
 591        (consp (setq symbol
 592                     (symbol-function symbol)))
 593        (or (eq (car symbol) 'macro)
 594            (if (eq (car symbol) 'autoload)
 595                (memq (nth 4 symbol)
 596                      '(macro t))))))
 597
 598
 599 (defun apropos-print-doc (action i str do-keys)
 600   (if (stringp (setq i (nth i apropos-item)))
 601       (progn
 602         (insert "  ")
 603         (put-text-property (- (point) 2) (1- (point))
 604                            'action action)
 605         (insert str ": ")
 606         (if apropos-label-face
 607             (add-text-properties (- (point) (length str) 2)
 608                                  (1- (point))
 609                                  apropos-label-face))
 610         (insert (if do-keys (substitute-command-keys i) i))
 611         (or (bolp) (terpri)))))
 612
 613
 614 (defun apropos-mouse-follow (event)
 615   (interactive "e")
 616   (let ((other (if (eq (current-buffer) (get-buffer "*Apropos*"))
 617                    ()
 618                  (current-buffer))))
 619     (save-excursion
 620       (set-buffer (window-buffer (posn-window (event-start event))))
 621       (goto-char (posn-point (event-start event)))
 622       (or (and (not (eobp)) (get-text-property (point) 'mouse-face))
 623           (and (not (bobp)) (get-text-property (1- (point)) 'mouse-face))
 624           (error "There is nothing to follow here"))
 625       (apropos-follow other))))
 626
 627
 628 (defun apropos-follow (&optional other)
 629   (interactive)
 630   (let* (;; Properties are always found at the beginning of the line.
 631          (bol (save-excursion (beginning-of-line) (point)))
 632          ;; If there is no `item' property here, look behind us.
 633          (item (get-text-property bol 'item))
 634          (item-at (if item nil (previous-single-property-change bol 'item)))
 635          ;; Likewise, if there is no `action' property here, look in front.
 636          (action (get-text-property bol 'action))
 637          (action-at (if action nil (next-single-property-change bol 'action))))
 638     (and (null item) item-at
 639          (setq item (get-text-property (1- item-at) 'item)))
 640     (and (null action) action-at
 641          (setq action (get-text-property action-at 'action)))
 642     (if (not (and item action))
 643         (error "There is nothing to follow here"))
 644     (if (consp item) (error "There is nothing to follow in `%s'" (car item)))
 645     (if other (set-buffer other))
 646     (funcall action item)))
 647
 648
 649
 650 (defun apropos-describe-plist (symbol)
 651   "Display a pretty listing of SYMBOL's plist."
 652   (with-output-to-temp-buffer "*Help*"
 653     (set-buffer standard-output)
 654     (princ "Symbol ")
 655     (prin1 symbol)
 656     (princ "'s plist is\n (")
 657     (if apropos-symbol-face
 658         (put-text-property 8 (- (point) 14) 'face apropos-symbol-face))
 659     (insert (apropos-format-plist symbol "\n  "))
 660     (princ ")")
 661     (print-help-return-message)))
 662
 663 (provide 'apropos)
 664
 665 ;;; apropos.el ends here