lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function nil
  31   "Window-system dependent function to call to create a new frame.
  32 The window system startup file should set this to its frame creation
  33 function, which should take an alist of parameters as its argument.")
  34
  35 ;; The initial value given here used to ask for a minibuffer.
  36 ;; But that's not necessary, because the default is to have one.
  37 ;; By not specifying it here, we let an X resource specify it.
  38 (defcustom initial-frame-alist nil
  39   "*Alist of frame parameters for creating the initial X window frame.
  40 You can set this in your `.emacs' file; for example,
  41  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  42 Parameters specified here supersede the values given in `default-frame-alist'.
  43
  44 If the value calls for a frame without a minibuffer, and you have not created
  45 a minibuffer frame on your own, one is created according to
  46 `minibuffer-frame-alist'.
  47
  48 You can specify geometry-related options for just the initial frame
  49 by setting this variable in your `.emacs' file; however, they won't
  50 take effect until Emacs reads `.emacs', which happens after first creating
  51 the frame.  If you want the frame to have the proper geometry as soon
  52 as it appears, you need to use this three-step process:
  53 * Specify X resources to give the geometry you want.
  54 * Set `default-frame-alist' to override these options so that they
  55   don't affect subsequent frames.
  56 * Set `initial-frame-alist' in a way that matches the X resources,
  57   to override what you put in `default-frame-alist'."
  58   :type '(repeat (cons :format "%v"
  59                        (symbol :tag "Parameter")
  60                        (sexp :tag "Value")))
  61   :group 'frames)
  62
  63 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  64   "*Alist of frame parameters for initially creating a minibuffer frame.
  65 You can set this in your `.emacs' file; for example,
  66  (setq minibuffer-frame-alist
  67    '((top . 1) (left . 1) (width . 80) (height . 2)))
  68 Parameters specified here supersede the values given in
  69 `default-frame-alist', for a minibuffer frame."
  70   :type '(repeat (cons :format "%v"
  71                        (symbol :tag "Parameter")
  72                        (sexp :tag "Value")))
  73   :group 'frames)
  74
  75 (defcustom pop-up-frame-alist nil
  76   "*Alist of frame parameters used when creating pop-up frames.
  77 Pop-up frames are used for completions, help, and the like.
  78 This variable can be set in your init file, like this:
  79   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  80 These supersede the values given in `default-frame-alist',
  81 for pop-up frames."
  82   :type '(repeat (cons :format "%v"
  83                        (symbol :tag "Parameter")
  84                        (sexp :tag "Value")))
  85   :group 'frames)
  86
  87 (setq pop-up-frame-function
  88       (function (lambda ()
  89                   (make-frame pop-up-frame-alist))))
  90
  91 (defcustom special-display-frame-alist
  92   '((height . 14) (width . 80) (unsplittable . t))
  93   "*Alist of frame parameters used when creating special frames.
  94 Special frames are used for buffers whose names are in
  95 `special-display-buffer-names' and for buffers whose names match
  96 one of the regular expressions in `special-display-regexps'.
  97 This variable can be set in your init file, like this:
  98   (setq special-display-frame-alist '((width . 80) (height . 20)))
  99 These supersede the values given in `default-frame-alist'."
 100   :type '(repeat (cons :format "%v"
 101                          (symbol :tag "Parameter")
 102                          (sexp :tag "Value")))
 103   :group 'frames)
 104
 105 (defun special-display-popup-frame (buffer &optional args)
 106   "Display BUFFER in its own frame, reusing an existing window if any.
 107 Return the window chosen.
 108 Currently we do not insist on selecting the window within its frame.
 109 If ARGS is an alist, use it as a list of frame parameter specs.
 110 If ARGS is a list whose car is a symbol,
 111 use (car ARGS) as a function to do the work.
 112 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 113   (if (and args (symbolp (car args)))
 114       (apply (car args) buffer (cdr args))
 115     (let ((window (get-buffer-window buffer t)))
 116       (or
 117        ;; If we have a window already, make it visible.
 118        (when window
 119          (let ((frame (window-frame window)))
 120            (make-frame-visible frame)
 121            (raise-frame frame)
 122            window))
 123        ;; Reuse the current window if the user requested it.
 124        (when (cdr (assq 'same-window args))
 125          (condition-case nil
 126              (progn (switch-to-buffer buffer) (selected-window))
 127            (error nil)))
 128        ;; Stay on the same frame if requested.
 129        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 130          (let* ((pop-up-frames nil) (pop-up-windows t)
 131                 special-display-regexps special-display-buffer-names
 132                 (window (display-buffer buffer)))
 133            ;; (set-window-dedicated-p window t)
 134            window))
 135        ;; If no window yet, make one in a new frame.
 136        (let ((frame (make-frame (append args special-display-frame-alist))))
 137          (set-window-buffer (frame-selected-window frame) buffer)
 138          (set-window-dedicated-p (frame-selected-window frame) t)
 139          (frame-selected-window frame))))))
 140
 141 (defun handle-delete-frame (event)
 142   "Handle delete-frame events from the X server."
 143   (interactive "e")
 144   (let ((frame (posn-window (event-start event)))
 145         (i 0)
 146         (tail (frame-list)))
 147     (while tail
 148       (and (frame-visible-p (car tail))
 149            (not (eq (car tail) frame))
 150           (setq i (1+ i)))
 151       (setq tail (cdr tail)))
 152     (if (> i 0)
 153         (delete-frame frame t)
 154       ;; Gildea@x.org says it is ok to ask questions before terminating.
 155       (save-buffers-kill-emacs))))
 156 \f
 157 ;;;; Arrangement of frames at startup
 158
 159 ;; 1) Load the window system startup file from the lisp library and read the
 160 ;; high-priority arguments (-q and the like).  The window system startup
 161 ;; file should create any frames specified in the window system defaults.
 162 ;;
 163 ;; 2) If no frames have been opened, we open an initial text frame.
 164 ;;
 165 ;; 3) Once the init file is done, we apply any newly set parameters
 166 ;; in initial-frame-alist to the frame.
 167
 168 ;; These are now called explicitly at the proper times,
 169 ;; since that is easier to understand.
 170 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 171 ;; (add-hook 'before-init-hook 'frame-initialize)
 172 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 173
 174 ;; If we create the initial frame, this is it.
 175 (defvar frame-initial-frame nil)
 176
 177 ;; Record the parameters used in frame-initialize to make the initial frame.
 178 (defvar frame-initial-frame-alist)
 179
 180 (defvar frame-initial-geometry-arguments nil)
 181
 182 ;; startup.el calls this function before loading the user's init
 183 ;; file - if there is no frame with a minibuffer open now, create
 184 ;; one to display messages while loading the init file.
 185 (defun frame-initialize ()
 186   "Create an initial frame if necessary."
 187   ;; Are we actually running under a window system at all?
 188   (if (and window-system (not noninteractive) (not (eq window-system 'pc)))
 189       (progn
 190         ;; Turn on special-display processing only if there's a window system.
 191         (setq special-display-function 'special-display-popup-frame)
 192
 193         ;; If there is no frame with a minibuffer besides the terminal
 194         ;; frame, then we need to create the opening frame.  Make sure
 195         ;; it has a minibuffer, but let initial-frame-alist omit the
 196         ;; minibuffer spec.
 197         (or (delq terminal-frame (minibuffer-frame-list))
 198             (progn
 199               (setq frame-initial-frame-alist
 200                     (append initial-frame-alist default-frame-alist nil))
 201               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 202                   (setq frame-initial-frame-alist
 203                         (cons '(horizontal-scroll-bars . t)
 204                               frame-initial-frame-alist)))
 205               (setq default-minibuffer-frame
 206                     (setq frame-initial-frame
 207                           (make-frame frame-initial-frame-alist)))
 208               ;; Delete any specifications for window geometry parameters
 209               ;; so that we won't reapply them in frame-notice-user-settings.
 210               ;; It would be wrong to reapply them then,
 211               ;; because that would override explicit user resizing.
 212               (setq initial-frame-alist
 213                     (frame-remove-geometry-params initial-frame-alist))))
 214         ;; At this point, we know that we have a frame open, so we
 215         ;; can delete the terminal frame.
 216         (delete-frame terminal-frame)
 217         (setq terminal-frame nil))
 218
 219     ;; No, we're not running a window system.  Use make-terminal-frame if
 220     ;; we support that feature, otherwise arrange to cause errors.
 221     (or (eq window-system 'pc)
 222         (setq frame-creation-function
 223               (if (fboundp 'tty-create-frame-with-faces)
 224                   'tty-create-frame-with-faces
 225                 (function
 226                  (lambda (parameters)
 227                    (error
 228                     "Can't create multiple frames without a window system"))))))))
 229
 230 (defvar frame-notice-user-settings t
 231   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 232
 233 ;; startup.el calls this function after loading the user's init
 234 ;; file.  Now default-frame-alist and initial-frame-alist contain
 235 ;; information to which we must react; do what needs to be done.
 236 (defun frame-notice-user-settings ()
 237   "Act on user's init file settings of frame parameters.
 238 React to settings of `default-frame-alist', `initial-frame-alist' there."
 239   ;; Make menu-bar-mode and default-frame-alist consistent.
 240   (when (boundp 'menu-bar-mode)
 241     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 242       (if default
 243           (setq menu-bar-mode (not (eq (cdr default) 0)))
 244         (setq default-frame-alist
 245               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 246                     default-frame-alist)))))
 247
 248   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 249   ;; it in batch mode since that would leave a tool-bar-lines
 250   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 251   ;; what we want.
 252   (when (and (boundp 'tool-bar-mode)
 253              (not noninteractive))
 254     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 255       (if default
 256           (setq tool-bar-mode (not (eq (cdr default) 0)))
 257         (setq default-frame-alist
 258               (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 259                     default-frame-alist)))))
 260
 261   ;; Creating and deleting frames may shift the selected frame around,
 262   ;; and thus the current buffer.  Protect against that.  We don't
 263   ;; want to use save-excursion here, because that may also try to set
 264   ;; the buffer of the selected window, which fails when the selected
 265   ;; window is the minibuffer.
 266   (let ((old-buffer (current-buffer)))
 267
 268     (when (and frame-notice-user-settings
 269                (null frame-initial-frame))
 270       ;; This case happens when we don't have a window system, and
 271       ;; also for MS-DOS frames.
 272       (let ((parms (frame-parameters frame-initial-frame)))
 273         ;; Don't change the frame names.
 274         (setq parms (delq (assq 'name parms) parms))
 275         ;; Can't modify the minibuffer parameter, so don't try.
 276         (setq parms (delq (assq 'minibuffer parms) parms))
 277         (modify-frame-parameters nil
 278                                  (if (null window-system)
 279                                      (append initial-frame-alist
 280                                              default-frame-alist
 281                                              parms
 282                                              nil)
 283                                    ;; initial-frame-alist and
 284                                    ;; default-frame-alist were already
 285                                    ;; applied in pc-win.el.
 286                                    parms))
 287         (if (null window-system) ;; MS-DOS does this differently in pc-win.el
 288             (let ((newparms (frame-parameters))
 289                   (frame (selected-frame)))
 290               (tty-handle-reverse-video frame newparms)
 291               ;; If we changed the background color, we need to update
 292               ;; the background-mode parameter, and maybe some faces,
 293               ;; too.
 294               (when (assq 'background-color newparms)
 295                 (unless (or (assq 'background-mode initial-frame-alist)
 296                             (assq 'background-mode default-frame-alist))
 297                   (frame-set-background-mode frame))
 298                 (face-set-after-frame-default frame))))))
 299
 300     ;; If the initial frame is still around, apply initial-frame-alist
 301     ;; and default-frame-alist to it.
 302     (when (frame-live-p frame-initial-frame)
 303
 304       ;; When tool-bar has been switched off, correct the frame size
 305       ;; by the lines added in x-create-frame for the tool-bar and
 306       ;; switch `tool-bar-mode' off.
 307       (when (display-graphic-p)
 308         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 309                                   (assq 'tool-bar-lines default-frame-alist))))
 310           (when (and tool-bar-originally-present
 311                      (or (null tool-bar-lines)
 312                          (null (cdr tool-bar-lines))
 313                          (eq 0 (cdr tool-bar-lines))))
 314             (let* ((char-height (frame-char-height frame-initial-frame))
 315                    (image-height tool-bar-images-pixel-height)
 316                    (margin (cond ((and (consp tool-bar-button-margin)
 317                                        (integerp (cdr tool-bar-button-margin))
 318                                        (> tool-bar-button-margin 0))
 319                                   (cdr tool-bar-button-margin))
 320                                  ((and (integerp tool-bar-button-margin)
 321                                        (> tool-bar-button-margin 0))
 322                                   tool-bar-button-margin)
 323                                  (t 0)))
 324                    (relief (if (and (integerp tool-bar-button-relief)
 325                                     (> tool-bar-button-relief 0))
 326                                tool-bar-button-relief 3))
 327                    (lines (/ (+ image-height
 328                                 (* 2 margin)
 329                                 (* 2 relief)
 330                                 (1- char-height))
 331                              char-height))
 332                    (height (frame-parameter frame-initial-frame 'height))
 333                    (newparms (list (cons 'height (- height lines))))
 334                    (initial-top (cdr (assq 'top
 335                                            frame-initial-geometry-arguments)))
 336                    (top (frame-parameter frame-initial-frame 'top)))
 337               (when (and (consp initial-top) (eq '- (car initial-top)))
 338                 (setq newparms
 339                       (append newparms
 340                               `((top . ,(+ top (* lines char-height))))
 341                               nil)))
 342               (modify-frame-parameters frame-initial-frame newparms)
 343               (tool-bar-mode -1)))))
 344
 345       ;; The initial frame we create above always has a minibuffer.
 346       ;; If the user wants to remove it, or make it a minibuffer-only
 347       ;; frame, then we'll have to delete the current frame and make a
 348       ;; new one; you can't remove or add a root window to/from an
 349       ;; existing frame.
 350       ;;
 351       ;; NOTE: default-frame-alist was nil when we created the
 352       ;; existing frame.  We need to explicitly include
 353       ;; default-frame-alist in the parameters of the screen we
 354       ;; create here, so that its new value, gleaned from the user's
 355       ;; .emacs file, will be applied to the existing screen.
 356       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 357                             (assq 'minibuffer default-frame-alist)
 358                             '(minibuffer . t)))
 359                    t))
 360           ;; Create the new frame.
 361           (let (parms new)
 362             ;; If the frame isn't visible yet, wait till it is.
 363             ;; If the user has to position the window,
 364             ;; Emacs doesn't know its real position until
 365             ;; the frame is seen to be visible.
 366             (while (not (cdr (assq 'visibility
 367                                    (frame-parameters frame-initial-frame))))
 368               (sleep-for 1))
 369             (setq parms (frame-parameters frame-initial-frame))
 370
 371        ;; Get rid of `name' unless it was specified explicitly before.
 372             (or (assq 'name frame-initial-frame-alist)
 373                 (setq parms (delq (assq 'name parms) parms)))
 374
 375             (setq parms (append initial-frame-alist
 376                                 default-frame-alist
 377                                 parms
 378                                 nil))
 379
 380             ;; Get rid of `reverse', because that was handled
 381             ;; when we first made the frame.
 382             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 383
 384             (if (assq 'height frame-initial-geometry-arguments)
 385                 (setq parms (assq-delete-all 'height parms)))
 386             (if (assq 'width frame-initial-geometry-arguments)
 387                 (setq parms (assq-delete-all 'width parms)))
 388             (if (assq 'left frame-initial-geometry-arguments)
 389                 (setq parms (assq-delete-all 'left parms)))
 390             (if (assq 'top frame-initial-geometry-arguments)
 391                 (setq parms (assq-delete-all 'top parms)))
 392             (setq new
 393                   (make-frame
 394                    ;; Use the geometry args that created the existing
 395                    ;; frame, rather than the parms we get for it.
 396                    (append frame-initial-geometry-arguments
 397                            '((user-size . t) (user-position . t))
 398                            parms)))
 399             ;; The initial frame, which we are about to delete, may be
 400             ;; the only frame with a minibuffer.  If it is, create a
 401             ;; new one.
 402             (or (delq frame-initial-frame (minibuffer-frame-list))
 403                 (make-initial-minibuffer-frame nil))
 404
 405             ;; If the initial frame is serving as a surrogate
 406             ;; minibuffer frame for any frames, we need to wean them
 407             ;; onto a new frame.  The default-minibuffer-frame
 408             ;; variable must be handled similarly.
 409             (let ((users-of-initial
 410                    (filtered-frame-list
 411                     (function (lambda (frame)
 412                                 (and (not (eq frame frame-initial-frame))
 413                                      (eq (window-frame
 414                                           (minibuffer-window frame))
 415                                          frame-initial-frame)))))))
 416               (if (or users-of-initial
 417                       (eq default-minibuffer-frame frame-initial-frame))
 418
 419                   ;; Choose an appropriate frame.  Prefer frames which
 420                   ;; are only minibuffers.
 421                   (let* ((new-surrogate
 422                           (car
 423                            (or (filtered-frame-list
 424                                 (function
 425                                  (lambda (frame)
 426                                    (eq (cdr (assq 'minibuffer
 427                                                   (frame-parameters frame)))
 428                                        'only))))
 429                                (minibuffer-frame-list))))
 430                          (new-minibuffer (minibuffer-window new-surrogate)))
 431
 432                     (if (eq default-minibuffer-frame frame-initial-frame)
 433                         (setq default-minibuffer-frame new-surrogate))
 434
 435                     ;; Wean the frames using frame-initial-frame as
 436                     ;; their minibuffer frame.
 437                     (mapcar
 438                      (function
 439                       (lambda (frame)
 440                         (modify-frame-parameters
 441                          frame (list (cons 'minibuffer new-minibuffer)))))
 442                      users-of-initial))))
 443
 444            ;; Redirect events enqueued at this frame to the new frame.
 445             ;; Is this a good idea?
 446             (redirect-frame-focus frame-initial-frame new)
 447
 448             ;; Finally, get rid of the old frame.
 449             (delete-frame frame-initial-frame t))
 450
 451         ;; Otherwise, we don't need all that rigamarole; just apply
 452         ;; the new parameters.
 453         (let (newparms allparms tail)
 454           (setq allparms (append initial-frame-alist
 455                                  default-frame-alist nil))
 456           (if (assq 'height frame-initial-geometry-arguments)
 457               (setq allparms (assq-delete-all 'height allparms)))
 458           (if (assq 'width frame-initial-geometry-arguments)
 459               (setq allparms (assq-delete-all 'width allparms)))
 460           (if (assq 'left frame-initial-geometry-arguments)
 461               (setq allparms (assq-delete-all 'left allparms)))
 462           (if (assq 'top frame-initial-geometry-arguments)
 463               (setq allparms (assq-delete-all 'top allparms)))
 464           (setq tail allparms)
 465           ;; Find just the parms that have changed since we first
 466           ;; made this frame.  Those are the ones actually set by
 467        ;; the init file.  For those parms whose values we already knew
 468           ;; (such as those spec'd by command line options)
 469           ;; it is undesirable to specify the parm again
 470          ;; once the user has seen the frame and been able to alter it
 471           ;; manually.
 472           (while tail
 473             (let (newval oldval)
 474               (setq oldval (assq (car (car tail))
 475                                  frame-initial-frame-alist))
 476               (setq newval (cdr (assq (car (car tail)) allparms)))
 477               (or (and oldval (eq (cdr oldval) newval))
 478                   (setq newparms
 479                         (cons (cons (car (car tail)) newval) newparms))))
 480             (setq tail (cdr tail)))
 481           (setq newparms (nreverse newparms))
 482           (modify-frame-parameters frame-initial-frame
 483                                    newparms)
 484           ;; If we changed the background color,
 485           ;; we need to update the background-mode parameter
 486           ;; and maybe some faces too.
 487           (when (assq 'background-color newparms)
 488             (unless (assq 'background-mode newparms)
 489               (frame-set-background-mode frame-initial-frame))
 490             (face-set-after-frame-default frame-initial-frame)))))
 491
 492     ;; Restore the original buffer.
 493     (set-buffer old-buffer)
 494
 495     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 496     ;; Make sure frame-notice-user-settings does nothing if called twice.
 497     (setq frame-notice-user-settings nil)
 498     (setq frame-initial-frame nil)))
 499
 500 (defun make-initial-minibuffer-frame (display)
 501   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 502     (if display
 503         (make-frame-on-display display parms)
 504       (make-frame parms))))
 505
 506 ;;;; Creation of additional frames, and other frame miscellanea
 507
 508 (defun get-other-frame ()
 509   "Return some frame other than the current frame.
 510 Create one if necessary.  Note that the minibuffer frame, if separate,
 511 is not considered (see `next-frame')."
 512   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 513                (make-frame)
 514              (next-frame (selected-frame)))))
 515     s))
 516
 517 (defun next-multiframe-window ()
 518   "Select the next window, regardless of which frame it is on."
 519   (interactive)
 520   (select-window (next-window (selected-window)
 521                               (> (minibuffer-depth) 0)
 522                               t))
 523   (select-frame-set-input-focus (selected-frame)))
 524
 525 (defun previous-multiframe-window ()
 526   "Select the previous window, regardless of which frame it is on."
 527   (interactive)
 528   (select-window (previous-window (selected-window)
 529                                   (> (minibuffer-depth) 0)
 530                                   t))
 531   (select-frame-set-input-focus (selected-frame)))
 532
 533 (defun make-frame-on-display (display &optional parameters)
 534   "Make a frame on display DISPLAY.
 535 The optional second argument PARAMETERS specifies additional frame parameters."
 536   (interactive "sMake frame on display: ")
 537   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 538       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 539   (make-frame (cons (cons 'display display) parameters)))
 540
 541 (defun make-frame-command ()
 542   "Make a new frame, and select it if the terminal displays only one frame."
 543   (interactive)
 544   (if (and window-system (not (eq window-system 'pc)))
 545       (make-frame)
 546     (select-frame (make-frame))))
 547
 548 (defvar before-make-frame-hook nil
 549   "Functions to run before a frame is created.")
 550
 551 (defvar after-make-frame-functions nil
 552   "Functions to run after a frame is created.
 553 The functions are run with one arg, the newly created frame.")
 554
 555 (defvar after-setting-font-hook nil
 556   "Functions to run after a frame's font has been changed.")
 557
 558 ;; Alias, kept temporarily.
 559 (defalias 'new-frame 'make-frame)
 560
 561 (defun make-frame (&optional parameters)
 562   "Return a newly created frame displaying the current buffer.
 563 Optional argument PARAMETERS is an alist of parameters for the new frame.
 564 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 565
 566  (name . STRING)        The frame should be named STRING.
 567
 568  (width . NUMBER)       The frame should be NUMBER characters in width.
 569  (height . NUMBER)      The frame should be NUMBER text lines high.
 570
 571 You cannot specify either `width' or `height', you must use neither or both.
 572
 573  (minibuffer . t)       The frame should have a minibuffer.
 574  (minibuffer . nil)     The frame should have no minibuffer.
 575  (minibuffer . only)    The frame should contain only a minibuffer.
 576  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 577
 578 Before the frame is created (via `frame-creation-function'), functions on the
 579 hook `before-make-frame-hook' are run.  After the frame is created, functions
 580 on `after-make-frame-functions' are run with one arg, the newly created frame."
 581   (interactive)
 582   (run-hooks 'before-make-frame-hook)
 583   (let ((frame (funcall frame-creation-function parameters)))
 584     (run-hook-with-args 'after-make-frame-functions frame)
 585     frame))
 586
 587 (defun filtered-frame-list (predicate)
 588   "Return a list of all live frames which satisfy PREDICATE."
 589   (let* ((frames (frame-list))
 590          (list frames))
 591     (while (consp frames)
 592       (unless (funcall predicate (car frames))
 593         (setcar frames nil))
 594       (setq frames (cdr frames)))
 595     (delq nil list)))
 596
 597 (defun minibuffer-frame-list ()
 598   "Return a list of all frames with their own minibuffers."
 599   (filtered-frame-list
 600    (function (lambda (frame)
 601                (eq frame (window-frame (minibuffer-window frame)))))))
 602
 603 (defun frames-on-display-list (&optional display)
 604   "Return a list of all frames on DISPLAY.
 605 DISPLAY is a name of a display, a string of the form HOST:SERVER.SCREEN.
 606 If DISPLAY is omitted or nil, it defaults to the selected frame's display."
 607   (let* ((display (or display (frame-parameter nil 'display)))
 608          (func #'(lambda (frame)
 609                    (eq (frame-parameter frame 'display) display))))
 610     (filtered-frame-list func)))
 611
 612 (defun framep-on-display (&optional display)
 613   "Return the type of frames on DISPLAY.
 614 DISPLAY may be a display name or a frame.  If it is a frame, its type is
 615 returned.
 616 If DISPLAY is omitted or nil, it defaults to the selected frame's display.
 617 All frames on a given display are of the same type."
 618   (or (framep display)
 619       (framep (car (frames-on-display-list display)))))
 620
 621 (defun frame-remove-geometry-params (param-list)
 622   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 623 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 624 `height', `user-size' and `user-position' parameters.
 625 Emacs uses this to avoid overriding explicit moves and resizings from
 626 the user during startup."
 627   (setq param-list (cons nil param-list))
 628   (let ((tail param-list))
 629     (while (consp (cdr tail))
 630       (if (and (consp (car (cdr tail)))
 631                (memq (car (car (cdr tail)))
 632                      '(height width top left user-position user-size)))
 633           (progn
 634             (setq frame-initial-geometry-arguments
 635                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 636             (setcdr tail (cdr (cdr tail))))
 637         (setq tail (cdr tail)))))
 638   (setq frame-initial-geometry-arguments
 639         (nreverse frame-initial-geometry-arguments))
 640   (cdr param-list))
 641
 642
 643 (defcustom focus-follows-mouse t
 644   "*Non-nil if window system changes focus when you move the mouse."
 645   :type 'boolean
 646   :group 'frames
 647   :version "20.3")
 648
 649 (defun select-frame-set-input-focus (frame)
 650   "Select FRAME, raise it, and set input focus, if possible."
 651     (select-frame frame)
 652     (raise-frame frame)
 653     ;; Ensure, if possible, that frame gets input focus.
 654     (when (eq window-system 'w32)
 655       (w32-focus-frame frame))
 656     (cond (focus-follows-mouse
 657            (unless (eq window-system 'w32)
 658              (set-mouse-position (selected-frame) (1- (frame-width)) 0)))
 659           (t
 660            (when (eq window-system 'x)
 661              (x-focus-frame frame)))))
 662
 663 (defun other-frame (arg)
 664   "Select the ARG'th different visible frame on current display, and raise it.
 665 All frames are arranged in a cyclic order.
 666 This command selects the frame ARG steps away in that order.
 667 A negative ARG moves in the opposite order."
 668   (interactive "p")
 669   (let ((frame (selected-frame)))
 670     (while (> arg 0)
 671       (setq frame (next-frame frame))
 672       (while (not (eq (frame-visible-p frame) t))
 673         (setq frame (next-frame frame)))
 674       (setq arg (1- arg)))
 675     (while (< arg 0)
 676       (setq frame (previous-frame frame))
 677       (while (not (eq (frame-visible-p frame) t))
 678         (setq frame (previous-frame frame)))
 679       (setq arg (1+ arg)))
 680     (select-frame-set-input-focus frame)))
 681
 682 (defun make-frame-names-alist ()
 683   (let* ((current-frame (selected-frame))
 684          (falist
 685           (cons
 686            (cons (frame-parameter current-frame 'name) current-frame) nil))
 687          (frame (next-frame nil t)))
 688     (while (not (eq frame current-frame))
 689       (progn
 690         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 691         (setq frame (next-frame frame t))))
 692     falist))
 693
 694 (defvar frame-name-history nil)
 695 (defun select-frame-by-name (name)
 696   "Select the frame on the current terminal whose name is NAME and raise it.
 697 If there is no frame by that name, signal an error."
 698   (interactive
 699    (let* ((frame-names-alist (make-frame-names-alist))
 700            (default (car (car frame-names-alist)))
 701            (input (completing-read
 702                    (format "Select Frame (default %s): " default)
 703                    frame-names-alist nil t nil 'frame-name-history)))
 704      (if (= (length input) 0)
 705          (list default)
 706        (list input))))
 707   (let* ((frame-names-alist (make-frame-names-alist))
 708          (frame (cdr (assoc name frame-names-alist))))
 709     (or frame
 710         (error "There is no frame named `%s'" name))
 711     (make-frame-visible frame)
 712     (raise-frame frame)
 713     (select-frame frame)
 714     ;; Ensure, if possible, that frame gets input focus.
 715     (if (eq window-system 'w32)
 716         (w32-focus-frame frame)
 717       (when focus-follows-mouse
 718         (set-mouse-position (selected-frame) (1- (frame-width)) 0)))))
 719 \f
 720 ;;;; Frame configurations
 721
 722 (defun current-frame-configuration ()
 723   "Return a list describing the positions and states of all frames.
 724 Its car is `frame-configuration'.
 725 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 726 where
 727   FRAME is a frame object,
 728   ALIST is an association list specifying some of FRAME's parameters, and
 729   WINDOW-CONFIG is a window configuration object for FRAME."
 730   (cons 'frame-configuration
 731         (mapcar (function
 732                  (lambda (frame)
 733                    (list frame
 734                          (frame-parameters frame)
 735                          (current-window-configuration frame))))
 736                 (frame-list))))
 737
 738 (defun set-frame-configuration (configuration &optional nodelete)
 739   "Restore the frames to the state described by CONFIGURATION.
 740 Each frame listed in CONFIGURATION has its position, size, window
 741 configuration, and other parameters set as specified in CONFIGURATION.
 742 Ordinarily, this function deletes all existing frames not
 743 listed in CONFIGURATION.  But if optional second argument NODELETE
 744 is given and non-nil, the unwanted frames are iconified instead."
 745   (or (frame-configuration-p configuration)
 746       (signal 'wrong-type-argument
 747               (list 'frame-configuration-p configuration)))
 748   (let ((config-alist (cdr configuration))
 749         frames-to-delete)
 750     (mapcar (function
 751              (lambda (frame)
 752                (let ((parameters (assq frame config-alist)))
 753                  (if parameters
 754                      (progn
 755                        (modify-frame-parameters
 756                         frame
 757                         ;; Since we can't set a frame's minibuffer status,
 758                         ;; we might as well omit the parameter altogether.
 759                         (let* ((parms (nth 1 parameters))
 760                                (mini (assq 'minibuffer parms)))
 761                           (if mini (setq parms (delq mini parms)))
 762                           parms))
 763                        (set-window-configuration (nth 2 parameters)))
 764                    (setq frames-to-delete (cons frame frames-to-delete))))))
 765             (frame-list))
 766     (if nodelete
 767         ;; Note: making frames invisible here was tried
 768         ;; but led to some strange behavior--each time the frame
 769         ;; was made visible again, the window manager asked afresh
 770         ;; for where to put it.
 771         (mapcar 'iconify-frame frames-to-delete)
 772       (mapcar 'delete-frame frames-to-delete))))
 773 \f
 774 ;;;; Convenience functions for accessing and interactively changing
 775 ;;;; frame parameters.
 776
 777 (defun frame-height (&optional frame)
 778   "Return number of lines available for display on FRAME.
 779 If FRAME is omitted, describe the currently selected frame."
 780   (cdr (assq 'height (frame-parameters frame))))
 781
 782 (defun frame-width (&optional frame)
 783   "Return number of columns available for display on FRAME.
 784 If FRAME is omitted, describe the currently selected frame."
 785   (cdr (assq 'width (frame-parameters frame))))
 786
 787 (defalias 'set-default-font 'set-frame-font)
 788 (defun set-frame-font (font-name)
 789   "Set the font of the selected frame to FONT-NAME.
 790 When called interactively, prompt for the name of the font to use.
 791 To get the frame's current default font, use `frame-parameters'."
 792   (interactive
 793    (list
 794     (let ((completion-ignore-case t))
 795       (completing-read "Font name: "
 796                        (mapcar #'list
 797                                ;; x-list-fonts will fail with an error
 798                                ;; if this frame doesn't support fonts.
 799                                (x-list-fonts "*" nil (selected-frame)))))))
 800   (modify-frame-parameters (selected-frame)
 801                            (list (cons 'font font-name)))
 802   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
 803
 804 (defun set-frame-parameter (frame parameter value)
 805   (modify-frame-parameters frame (list (cons parameter value))))
 806
 807 (defun set-background-color (color-name)
 808   "Set the background color of the selected frame to COLOR-NAME.
 809 When called interactively, prompt for the name of the color to use.
 810 To get the frame's current background color, use `frame-parameters'."
 811   (interactive (list (facemenu-read-color)))
 812   (modify-frame-parameters (selected-frame)
 813                            (list (cons 'background-color color-name)))
 814   (or window-system
 815       (face-set-after-frame-default (selected-frame))))
 816
 817 (defun set-foreground-color (color-name)
 818   "Set the foreground color of the selected frame to COLOR-NAME.
 819 When called interactively, prompt for the name of the color to use.
 820 To get the frame's current foreground color, use `frame-parameters'."
 821   (interactive (list (facemenu-read-color)))
 822   (modify-frame-parameters (selected-frame)
 823                            (list (cons 'foreground-color color-name)))
 824   (or window-system
 825       (face-set-after-frame-default (selected-frame))))
 826
 827 (defun set-cursor-color (color-name)
 828   "Set the text cursor color of the selected frame to COLOR-NAME.
 829 When called interactively, prompt for the name of the color to use.
 830 To get the frame's current cursor color, use `frame-parameters'."
 831   (interactive (list (facemenu-read-color)))
 832   (modify-frame-parameters (selected-frame)
 833                            (list (cons 'cursor-color color-name))))
 834
 835 (defun set-mouse-color (color-name)
 836   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
 837 When called interactively, prompt for the name of the color to use.
 838 To get the frame's current mouse color, use `frame-parameters'."
 839   (interactive (list (facemenu-read-color)))
 840   (modify-frame-parameters (selected-frame)
 841                            (list (cons 'mouse-color
 842                                        (or color-name
 843                                            (cdr (assq 'mouse-color
 844                                                       (frame-parameters))))))))
 845
 846 (defun set-border-color (color-name)
 847   "Set the color of the border of the selected frame to COLOR-NAME.
 848 When called interactively, prompt for the name of the color to use.
 849 To get the frame's current border color, use `frame-parameters'."
 850   (interactive (list (facemenu-read-color)))
 851   (modify-frame-parameters (selected-frame)
 852                            (list (cons 'border-color color-name))))
 853
 854 (defun auto-raise-mode (arg)
 855   "Toggle whether or not the selected frame should auto-raise.
 856 With arg, turn auto-raise mode on if and only if arg is positive.
 857 Note that this controls Emacs's own auto-raise feature.
 858 Some window managers allow you to enable auto-raise for certain windows.
 859 You can use that for Emacs windows if you wish, but if you do,
 860 that is beyond the control of Emacs and this command has no effect on it."
 861   (interactive "P")
 862   (if (null arg)
 863       (setq arg
 864             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
 865                 -1 1)))
 866   (if (> arg 0)
 867       (raise-frame (selected-frame)))
 868   (modify-frame-parameters (selected-frame)
 869                            (list (cons 'auto-raise (> arg 0)))))
 870
 871 (defun auto-lower-mode (arg)
 872   "Toggle whether or not the selected frame should auto-lower.
 873 With arg, turn auto-lower mode on if and only if arg is positive.
 874 Note that this controls Emacs's own auto-lower feature.
 875 Some window managers allow you to enable auto-lower for certain windows.
 876 You can use that for Emacs windows if you wish, but if you do,
 877 that is beyond the control of Emacs and this command has no effect on it."
 878   (interactive "P")
 879   (if (null arg)
 880       (setq arg
 881             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
 882                 -1 1)))
 883   (modify-frame-parameters (selected-frame)
 884                            (list (cons 'auto-lower (> arg 0)))))
 885 (defun set-frame-name (name)
 886   "Set the name of the selected frame to NAME.
 887 When called interactively, prompt for the name of the frame.
 888 The frame name is displayed on the modeline if the terminal displays only
 889 one frame, otherwise the name is displayed on the frame's caption bar."
 890   (interactive "sFrame name: ")
 891   (modify-frame-parameters (selected-frame)
 892                            (list (cons 'name name))))
 893 \f
 894 ;;;; Frame/display capabilities.
 895 (defun display-mouse-p (&optional display)
 896   "Return non-nil if DISPLAY has a mouse available.
 897 DISPLAY can be a display name, a frame, or nil (meaning the selected
 898 frame's display)."
 899   (let ((frame-type (framep-on-display display)))
 900     (cond
 901      ((eq frame-type 'pc)
 902       (msdos-mouse-p))
 903      ((eq system-type 'windows-nt)
 904       (> w32-num-mouse-buttons 0))
 905      ((memq frame-type '(x mac))
 906       t)    ;; We assume X and Mac *always* have a pointing device
 907      (t
 908       (or (and (featurep 'xt-mouse)
 909                xterm-mouse-mode)
 910           ;; t-mouse is distributed with the GPM package.  It doesn't have
 911           ;; a toggle.
 912           (featurep 't-mouse))))))
 913
 914 (defun display-popup-menus-p (&optional display)
 915   "Return non-nil if popup menus are supported on DISPLAY.
 916 DISPLAY can be a display name, a frame, or nil (meaning the selected
 917 frame's display).
 918 Support for popup menus requires that the mouse be available."
 919   (and
 920    (let ((frame-type (framep-on-display display)))
 921      (memq frame-type '(x w32 pc mac)))
 922    (display-mouse-p display)))
 923
 924 (defun display-graphic-p (&optional display)
 925   "Return non-nil if DISPLAY is a graphic display.
 926 Graphical displays are those which are capable of displaying several
 927 frames and several different fonts at once.  This is true for displays
 928 that use a window system such as X, and false for text-only terminals.
 929 DISPLAY can be a display name, a frame, or nil (meaning the selected
 930 frame's display)."
 931   (not (null (memq (framep-on-display display) '(x w32 mac)))))
 932
 933 (defun display-images-p (&optional display)
 934   "Return non-nil if DISPLAY can display images.
 935
 936 DISPLAY can be a display name, a frame, or nil (meaning the selected
 937 frame's display)."
 938   (and (display-graphic-p display)
 939        (fboundp 'image-mask-p)
 940        (fboundp 'image-size)
 941        ;; FIXME: this will need to be revisited when the Windows port
 942        ;; supports images.
 943        (not (eq (framep-on-display display) 'w32))))
 944
 945 (defalias 'display-multi-frame-p 'display-graphic-p)
 946 (defalias 'display-multi-font-p 'display-graphic-p)
 947
 948 (defun display-selections-p (&optional display)
 949   "Return non-nil if DISPLAY supports selections.
 950 A selection is a way to transfer text or other data between programs
 951 via special system buffers called `selection' or `cut buffer' or
 952 `clipboard'.
 953 DISPLAY can be a display name, a frame, or nil (meaning the selected
 954 frame's display)."
 955   (let ((frame-type (framep-on-display display)))
 956     (cond
 957      ((eq frame-type 'pc)
 958       ;; MS-DOG frames support selections when Emacs runs inside
 959       ;; the Windows' DOS Box.
 960       (not (null dos-windows-version)))
 961      ((memq frame-type '(x w32 mac))
 962       t)    ;; FIXME?
 963      (t
 964       nil))))
 965
 966 (defun display-screens (&optional display)
 967   "Return the number of screens associated with DISPLAY."
 968   (let ((frame-type (framep-on-display display)))
 969     (cond
 970      ((memq frame-type '(x w32))
 971       (x-display-screens display))
 972      (t ;; FIXME: is this correct for the Mac?
 973       1))))
 974
 975 (defun display-pixel-height (&optional display)
 976   "Return the height of DISPLAY's screen in pixels.
 977 For character terminals, each character counts as a single pixel."
 978   (let ((frame-type (framep-on-display display)))
 979     (cond
 980      ((memq frame-type '(x w32 mac))
 981       (x-display-pixel-height display))
 982      (t
 983       (frame-height (if (framep display) display (selected-frame)))))))
 984
 985 (defun display-pixel-width (&optional display)
 986   "Return the width of DISPLAY's screen in pixels.
 987 For character terminals, each character counts as a single pixel."
 988   (let ((frame-type (framep-on-display display)))
 989     (cond
 990      ((memq frame-type '(x w32 mac))
 991       (x-display-pixel-width display))
 992      (t
 993       (frame-width (if (framep display) display (selected-frame)))))))
 994
 995 (defun display-mm-height (&optional display)
 996   "Return the height of DISPLAY's screen in millimeters.
 997 If the information is unavailable, value is nil."
 998   (and (memq (framep-on-display display) '(x w32 mac))
 999        (x-display-mm-height display)))
1000
1001 (defun display-mm-width (&optional display)
1002   "Return the width of DISPLAY's screen in millimeters.
1003 If the information is unavailable, value is nil."
1004   (and (memq (framep-on-display display) '(x w32 mac))
1005        (x-display-mm-width display)))
1006
1007 (defun display-backing-store (&optional display)
1008   "Return the backing store capability of DISPLAY's screen.
1009 The value may be `always', `when-mapped', `not-useful', or nil if
1010 the question is inapplicable to a certain kind of display."
1011   (let ((frame-type (framep-on-display display)))
1012     (cond
1013      ((memq frame-type '(x w32 mac))
1014       (x-display-backing-store display))
1015      (t
1016       'not-useful))))
1017
1018 (defun display-save-under (&optional display)
1019   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1020   (let ((frame-type (framep-on-display display)))
1021     (cond
1022      ((memq frame-type '(x w32 mac))
1023       (x-display-save-under display))
1024      (t
1025       'not-useful))))
1026
1027 (defun display-planes (&optional display)
1028   "Return the number of planes supported by DISPLAY."
1029   (let ((frame-type (framep-on-display display)))
1030     (cond
1031      ((memq frame-type '(x w32 mac))
1032       (x-display-planes display))
1033      ((eq frame-type 'pc)
1034       4)
1035      (t
1036       (truncate (log (length (tty-color-alist)) 2))))))
1037
1038 (defun display-color-cells (&optional display)
1039   "Return the number of color cells supported by DISPLAY."
1040   (let ((frame-type (framep-on-display display)))
1041     (cond
1042      ((memq frame-type '(x w32 mac))
1043       (x-display-color-cells display))
1044      ((eq frame-type 'pc)
1045       16)
1046      (t
1047       (length (tty-color-alist))))))
1048
1049 (defun display-visual-class (&optional display)
1050   "Returns the visual class of DISPLAY.
1051 The value is one of the symbols `static-gray', `gray-scale',
1052 `static-color', `pseudo-color', `true-color', or `direct-color'."
1053   (let ((frame-type (framep-on-display display)))
1054     (cond
1055      ((memq frame-type '(x w32 mac))
1056       (x-display-visual-class display))
1057      ((and (memq frame-type '(pc t))
1058            (tty-display-color-p display))
1059       'static-color)
1060      (t
1061       'static-gray))))
1062
1063 \f
1064 ;;;; Aliases for backward compatibility with Emacs 18.
1065 (defalias 'screen-height 'frame-height)
1066 (defalias 'screen-width 'frame-width)
1067
1068 (defun set-screen-width (cols &optional pretend)
1069   "Obsolete function to change the size of the screen to COLS columns.
1070 Optional second arg non-nil means that redisplay should use COLS columns
1071 but that the idea of the actual width of the frame should not be changed.
1072 This function is provided only for compatibility with Emacs 18; new code
1073 should use `set-frame-width instead'."
1074   (set-frame-width (selected-frame) cols pretend))
1075
1076 (defun set-screen-height (lines &optional pretend)
1077   "Obsolete function to change the height of the screen to LINES lines.
1078 Optional second arg non-nil means that redisplay should use LINES lines
1079 but that the idea of the actual height of the screen should not be changed.
1080 This function is provided only for compatibility with Emacs 18; new code
1081 should use `set-frame-height' instead."
1082   (set-frame-height (selected-frame) lines pretend))
1083
1084 (defun delete-other-frames (&optional frame)
1085   "Delete all frames except FRAME.
1086 If FRAME uses another frame's minibuffer, the minibuffer frame is
1087 left untouched.  FRAME nil or omitted means use the selected frame."
1088   (interactive)
1089   (unless frame
1090     (setq frame (selected-frame)))
1091   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1092          (frames (delq mini-frame (delq frame (frame-list)))))
1093     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1094     ;; signals an error when trying to delete a mini-frame that's
1095     ;; still in use by another frame.
1096     (dolist (frame frames)
1097       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1098         (delete-frame frame)))
1099     ;; Delete minibuffer-only frames.
1100     (dolist (frame frames)
1101       (when (eq (frame-parameter frame 'minibuffer) 'only)
1102         (delete-frame frame)))))
1103
1104
1105 (make-obsolete 'screen-height 'frame-height) ;before 19.15
1106 (make-obsolete 'screen-width  'frame-width) ;before 19.15
1107 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1108 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1109
1110 \f
1111 ;; Highlighting trailing whitespace.
1112
1113 (make-variable-buffer-local 'show-trailing-whitespace)
1114
1115 (defcustom show-trailing-whitespace nil
1116   "*Non-nil means highlight trailing whitespace in face `trailing-whitespace'.
1117
1118 Setting this variable makes it local to the current buffer."
1119   :tag "Highlight trailing whitespace."
1120   :set #'(lambda (symbol value) (set-default symbol value))
1121   :type 'boolean
1122   :group 'font-lock)
1123
1124
1125 \f
1126 ;; Scrolling
1127
1128 (defgroup scrolling nil
1129   "Scrolling windows."
1130   :version "21.1"
1131   :group 'frames)
1132
1133 (defcustom automatic-hscrolling t
1134   "*Allow or disallow automatic scrolling windows horizontally.
1135 If non-nil, windows are automatically scrolled horizontally to make
1136 point visible."
1137   :version "21.1"
1138   :type 'boolean
1139   :group 'scrolling)
1140
1141 \f
1142 ;; Blinking cursor
1143
1144 (defgroup cursor nil
1145   "Displaying text cursors."
1146   :version "21.1"
1147   :group 'frames)
1148
1149 (defcustom blink-cursor-delay 0.5
1150   "*Seconds of idle time after which cursor starts to blink."
1151   :tag "Delay in seconds."
1152   :type 'number
1153   :group 'cursor)
1154
1155 (defcustom blink-cursor-interval 0.5
1156   "*Length of cursor blink interval in seconds."
1157   :tag "Blink interval in seconds."
1158   :type 'number
1159   :group 'cursor)
1160
1161 (defvar blink-cursor-idle-timer nil
1162   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1163 The function `blink-cursor-start' is called when the timer fires.")
1164
1165 (defvar blink-cursor-timer nil
1166   "Timer started from `blink-cursor-start'.
1167 This timer calls `blink-cursor' every `blink-cursor-interval' seconds.")
1168
1169 (defvar blink-cursor-mode nil
1170   "Non-nil means blinking cursor is active.")
1171
1172 (defun blink-cursor-mode (arg)
1173   "Toggle blinking cursor mode.
1174 With a numeric argument, turn blinking cursor mode on iff ARG is positive.
1175 When blinking cursor mode is enabled, the cursor of the selected
1176 window blinks.
1177
1178 Note that this command is effective only when Emacs
1179 displays through a window system, because then Emacs does its own
1180 cursor display.  On a text-only terminal, this is not implemented."
1181   (interactive "P")
1182   (let ((on-p (if (null arg)
1183                   (not blink-cursor-mode)
1184                 (> (prefix-numeric-value arg) 0))))
1185     (if blink-cursor-idle-timer
1186         (cancel-timer blink-cursor-idle-timer))
1187     (if blink-cursor-timer
1188         (cancel-timer blink-cursor-timer))
1189     (setq blink-cursor-idle-timer nil
1190           blink-cursor-timer nil
1191           blink-cursor-mode nil)
1192     (if on-p
1193         (progn
1194           ;; Hide the cursor.
1195           ;(internal-show-cursor nil nil)
1196           (setq blink-cursor-idle-timer
1197                 (run-with-idle-timer blink-cursor-delay
1198                                      blink-cursor-delay
1199                                      'blink-cursor-start))
1200           (setq blink-cursor-mode t))
1201       (internal-show-cursor nil t))))
1202
1203 ;; Note that this is really initialized from startup.el before
1204 ;; the init-file is read.
1205
1206 (defcustom blink-cursor nil
1207   "*Non-nil means blinking cursor mode is active."
1208   :group 'cursor
1209   :tag "Blinking cursor"
1210   :type 'boolean
1211   :set #'(lambda (symbol value)
1212            (set-default symbol value)
1213            (blink-cursor-mode (or value 0))))
1214
1215 (defun blink-cursor-start ()
1216   "Timer function called from the timer `blink-cursor-idle-timer'.
1217 This starts the timer `blink-cursor-timer', which makes the cursor blink
1218 if appropriate.  It also arranges to cancel that timer when the next
1219 command starts, by installing a pre-command hook."
1220   (when (null blink-cursor-timer)
1221     (add-hook 'pre-command-hook 'blink-cursor-end)
1222     (setq blink-cursor-timer
1223           (run-with-timer blink-cursor-interval blink-cursor-interval
1224                           'blink-cursor-timer-function))))
1225
1226 (defun blink-cursor-timer-function ()
1227   "Timer function of timer `blink-cursor-timer'."
1228   (internal-show-cursor nil (not (internal-show-cursor-p))))
1229
1230 (defun blink-cursor-end ()
1231   "Stop cursor blinking.
1232 This is installed as a pre-command hook by `blink-cursor-start'.
1233 When run, it cancels the timer `blink-cursor-timer' and removes
1234 itself as a pre-command hook."
1235   (remove-hook 'pre-command-hook 'blink-cursor-end)
1236   (internal-show-cursor nil t)
1237   (cancel-timer blink-cursor-timer)
1238   (setq blink-cursor-timer nil))
1239
1240
1241 \f
1242 ;; Hourglass pointer
1243
1244 (defcustom display-hourglass t
1245   "*Non-nil means show an hourglass pointer when running under a window system."
1246   :tag "Hourglass pointer"
1247   :type 'boolean
1248   :group 'cursor)
1249
1250 (defcustom hourglass-delay 1
1251   "*Seconds to wait before displaying an hourglass pointer."
1252   :tag "Hourglass delay"
1253   :type 'number
1254   :group 'cursor)
1255
1256 \f
1257 (defcustom cursor-in-non-selected-windows t
1258   "*Non-nil means show a hollow box cursor in non-selected-windows.
1259 If nil, don't show a cursor except in the selected window.
1260 Use Custom to set this variable to get the display updated."
1261   :tag "Cursor in non-selected windows"
1262   :type 'boolean
1263   :group 'cursor
1264   :set #'(lambda (symbol value)
1265            (set-default symbol value)
1266            (force-mode-line-update t)))
1267
1268 \f
1269 ;;;; Key bindings
1270
1271 (define-key ctl-x-5-map "2" 'make-frame-command)
1272 (define-key ctl-x-5-map "1" 'delete-other-frames)
1273 (define-key ctl-x-5-map "0" 'delete-frame)
1274 (define-key ctl-x-5-map "o" 'other-frame)
1275
1276 (provide 'frame)
1277
1278 ;;; frame.el ends here