lisp/calendar/appt.el

   1 ;;; appt.el --- appointment notification functions
   2
   3 ;; Copyright (C) 1989-1990, 1994, 1998, 2001-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Neil Mager <neilm@juliet.ll.mit.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Package: calendar
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;;
  29 ;; appt.el - visible and/or audible notification of
  30 ;;           appointments from diary file.
  31 ;;
  32 ;;
  33 ;; Thanks to  Edward M. Reingold for much help and many suggestions,
  34 ;; And to many others for bug fixes and suggestions.
  35 ;;
  36 ;;
  37 ;; This functions in this file will alert the user of a
  38 ;; pending appointment based on his/her diary file.  This package
  39 ;; is documented in the Emacs manual.
  40 ;;
  41 ;; To activate this package, simply use (appt-activate 1).
  42 ;; A `diary-file' with appointments of the format described in the
  43 ;; documentation of the function `appt-check' is required.
  44 ;; Relevant customizable variables are also listed in the
  45 ;; documentation of that function.
  46 ;;
  47 ;; Today's appointment list is initialized from the diary when this
  48 ;; package is activated.  Additionally, the appointments list is
  49 ;; recreated automatically at 12:01am for those who do not logout
  50 ;; every day or are programming late.  It is also updated when the
  51 ;; `diary-file' (or a file it includes) is saved.  Calling
  52 ;; `appt-check' with an argument (or re-enabling the package) forces a
  53 ;; re-initialization at any time.
  54 ;;
  55 ;; In order to add or delete items from today's list, without
  56 ;; changing the diary file, use `appt-add' and `appt-delete'.
  57 ;;
  58
  59 ;; Brief internal description - Skip this if you are not interested!
  60 ;;
  61 ;; The function `appt-make-list' creates the appointments list which
  62 ;; `appt-check' reads.
  63 ;;
  64 ;; You can change the way the appointment window is created/deleted by
  65 ;; setting the variables
  66 ;;
  67 ;;           appt-disp-window-function
  68 ;; and
  69 ;;           appt-delete-window-function
  70 ;;
  71 ;; For instance, these variables could be set to functions that display
  72 ;; appointments in pop-up frames, which are lowered or iconified after
  73 ;; `appt-display-interval' minutes.
  74 ;;
  75
  76 ;;; Code:
  77
  78 (require 'diary-lib)
  79
  80
  81 (defgroup appt nil
  82   "Appointment notification."
  83   :prefix "appt-"
  84   :group 'calendar)
  85
  86 (defcustom appt-message-warning-time 12
  87   "Default time in minutes before an appointment that the warning begins."
  88   :type 'integer
  89   :group 'appt)
  90
  91 (defcustom appt-warning-time-regexp "warntime \\([0-9]+\\)"
  92   "Regexp matching a string giving the warning time for an appointment.
  93 The first subexpression matches the time in minutes (an integer).
  94 This overrides the default `appt-message-warning-time'.
  95 You may want to put this inside a diary comment (see `diary-comment-start').
  96 For example, to be warned 30 minutes in advance of an appointment:
  97    2011/06/01 12:00 Do something ## warntime 30
  98 "
  99   :version "24.1"
 100   :type 'regexp
 101   :group 'appt)
 102
 103 (defcustom appt-audible t
 104   "Non-nil means beep to indicate appointment."
 105   :type 'boolean
 106   :group 'appt)
 107
 108 ;; TODO - add popup.
 109 (defcustom appt-display-format 'window
 110   "How appointment reminders should be displayed.
 111 The options are:
 112    window - use a separate window
 113    echo   - use the echo area
 114    nil    - no visible reminder.
 115 See also `appt-audible' and `appt-display-mode-line'."
 116   :type '(choice
 117           (const :tag "Separate window" window)
 118           (const :tag "Echo-area" echo)
 119           (const :tag "No visible display" nil))
 120   :group 'appt
 121   :version "24.1") ; no longer inherit from deleted obsolete variables
 122
 123 (defcustom appt-display-mode-line t
 124   "Non-nil means display minutes to appointment and time on the mode line.
 125 This is in addition to any other display of appointment messages."
 126   :type 'boolean
 127   :group 'appt)
 128
 129 (defcustom appt-display-duration 10
 130   "The number of seconds an appointment message is displayed.
 131 Only relevant if reminders are to be displayed in their own window."
 132   :type 'integer
 133   :group 'appt)
 134
 135 (defcustom appt-display-diary t
 136   "Non-nil displays the diary when the appointment list is first initialized.
 137 This will occur at midnight when the appointment list is updated."
 138   :type 'boolean
 139   :group 'appt)
 140
 141 (defcustom appt-display-interval 3
 142   "Number of minutes to wait between checking the appointment list."
 143   :type 'integer
 144   :group 'appt)
 145
 146 (defcustom appt-disp-window-function 'appt-disp-window
 147   "Function called to display appointment window.
 148 Only relevant if reminders are being displayed in a window.
 149 It should take three string arguments: the number of minutes till
 150 the appointment, the current time, and the text of the appointment."
 151   :type '(choice (const appt-disp-window)
 152                  function)
 153   :group 'appt)
 154
 155 (defcustom appt-delete-window-function 'appt-delete-window
 156   "Function called to remove appointment window and buffer.
 157 Only relevant if reminders are being displayed in a window."
 158   :type '(choice (const appt-delete-window)
 159                  function)
 160   :group 'appt)
 161
 162
 163 ;;; Internal variables below this point.
 164
 165 (defconst appt-buffer-name "*appt-buf*"
 166   "Name of the appointments buffer.")
 167
 168 ;; TODO Turn this into an alist?  It would be easier to add more
 169 ;; optional elements.
 170 ;; TODO There should be a way to set WARNTIME (and other properties)
 171 ;; from the diary-file.  Implementing that would be a good reason
 172 ;; to change this to an alist.
 173 (defvar appt-time-msg-list nil
 174   "The list of appointments for today.
 175 Use `appt-add' and `appt-delete' to add and delete appointments.
 176 The original list is generated from today's `diary-entries-list', and
 177 can be regenerated using the function `appt-check'.
 178 Each element of the generated list has the form
 179 \(MINUTES STRING [FLAG] [WARNTIME])
 180 where MINUTES is the time in minutes of the appointment after midnight,
 181 and STRING is the description of the appointment.
 182 FLAG and WARNTIME are not always present.  A non-nil FLAG
 183 indicates that the element was made with `appt-add', so calling
 184 `appt-make-list' again should preserve it.  If WARNTIME is non-nil,
 185 it is an integer to use in place of `appt-message-warning-time'.")
 186
 187 (defconst appt-max-time (1- (* 24 60))
 188   "11:59pm in minutes - number of minutes in a day minus 1.")
 189
 190 (defvar appt-mode-string nil
 191   "String being displayed in the mode line saying you have an appointment.
 192 The actual string includes the amount of time till the appointment.
 193 Only used if `appt-display-mode-line' is non-nil.")
 194 (put 'appt-mode-string 'risky-local-variable t) ; for 'face property
 195
 196 (defvar appt-prev-comp-time nil
 197   "Time of day (mins since midnight) at which we last checked appointments.
 198 A nil value forces the diary file to be (re-)checked for appointments.")
 199
 200 (defvar appt-display-count nil
 201   "Internal variable used to count number of consecutive reminders.")
 202
 203 (defvar appt-timer nil
 204   "Timer used for diary appointment notifications (`appt-check').
 205 If this is non-nil, appointment checking is active.")
 206
 207
 208 ;;; Functions.
 209
 210 (defun appt-display-message (string mins)
 211   "Display a reminder about an appointment.
 212 The string STRING describes the appointment, due in integer MINS minutes.
 213 The format of the visible reminder is controlled by `appt-display-format'.
 214 The variable `appt-audible' controls the audible reminder."
 215   (if appt-audible (beep 1))
 216   (cond ((eq appt-display-format 'window)
 217          (funcall appt-disp-window-function
 218                   (number-to-string mins)
 219                   ;; TODO - use calendar-month-abbrev-array rather than %b?
 220                   (format-time-string "%a %b %e " (current-time))
 221                   string)
 222          (run-at-time (format "%d sec" appt-display-duration)
 223                       nil
 224                       appt-delete-window-function))
 225         ((eq appt-display-format 'echo)
 226          (message "%s" string))))
 227
 228
 229 (defun appt-check (&optional force)
 230   "Check for an appointment and update any reminder display.
 231 If optional argument FORCE is non-nil, reparse the diary file for
 232 appointments.  Otherwise the diary file is only parsed once per day,
 233 or when it (or a file it includes) is saved.
 234
 235 Note: the time must be the first thing in the line in the diary
 236 for a warning to be issued.  The format of the time can be either
 237 24 hour or am/pm.  For example:
 238
 239               02/23/89
 240                 18:00 Dinner
 241
 242               Thursday
 243                 11:45am Lunch meeting.
 244
 245 Appointments are checked every `appt-display-interval' minutes.
 246 The following variables control appointment notification:
 247
 248 `appt-display-format'
 249         Controls the format in which reminders are displayed.
 250
 251 `appt-audible'
 252         Variable used to determine if reminder is audible.
 253         Default is t.
 254
 255 `appt-message-warning-time'
 256         Variable used to determine when appointment message
 257         should first be displayed.
 258
 259 `appt-display-mode-line'
 260         If non-nil, a generic message giving the time remaining
 261         is shown in the mode-line when an appointment is due.
 262
 263 `appt-display-interval'
 264         Interval in minutes at which to check for pending appointments.
 265
 266 `appt-display-diary'
 267         Display the diary buffer when the appointment list is
 268         initialized for the first time in a day.
 269
 270 The following variables are only relevant if reminders are being
 271 displayed in a window:
 272
 273 `appt-display-duration'
 274         The number of seconds an appointment message is displayed.
 275
 276 `appt-disp-window-function'
 277         Function called to display appointment window.
 278
 279 `appt-delete-window-function'
 280         Function called to remove appointment window and buffer."
 281   (interactive "P")                     ; so people can force updates
 282   (let* ((min-to-app -1)
 283          (prev-appt-mode-string appt-mode-string)
 284          (prev-appt-display-count (or appt-display-count 0))
 285          now cur-comp-time appt-comp-time appt-warn-time)
 286     (save-excursion                   ; FIXME ?
 287       ;; Convert current time to minutes after midnight (12.01am = 1).
 288       (setq now (decode-time)
 289             cur-comp-time (+ (* 60 (nth 2 now)) (nth 1 now)))
 290       ;; At first check in any day, update appointments to today's list.
 291       (if (or force                      ; eg initialize, diary save
 292               (null appt-prev-comp-time) ; first check
 293               (< cur-comp-time appt-prev-comp-time)) ; new day
 294           (ignore-errors
 295             (let ((diary-hook (if (assoc 'appt-make-list diary-hook)
 296                                   diary-hook
 297                                 (cons 'appt-make-list diary-hook))))
 298               (if appt-display-diary
 299                   (diary)
 300                 ;; Not displaying the diary, so we can ignore
 301                 ;; diary-number-of-entries.  Since appt.el only
 302                 ;; works on a daily basis, no need for more entries.
 303                 (diary-list-entries (calendar-current-date) 1 t)))))
 304       (setq appt-prev-comp-time cur-comp-time
 305             appt-mode-string nil
 306             appt-display-count nil)
 307       ;; If there are entries in the list, and the user wants a
 308       ;; message issued, get the first time off of the list and
 309       ;; calculate the number of minutes until the appointment.
 310       (when appt-time-msg-list
 311         (setq appt-comp-time (caar (car appt-time-msg-list))
 312               appt-warn-time (or (nth 3 (car appt-time-msg-list))
 313                                  appt-message-warning-time)
 314               min-to-app (- appt-comp-time cur-comp-time))
 315         (while (and appt-time-msg-list
 316                     (< appt-comp-time cur-comp-time))
 317           (setq appt-time-msg-list (cdr appt-time-msg-list))
 318           (if appt-time-msg-list
 319               (setq appt-comp-time (caar (car appt-time-msg-list)))))
 320         ;; If we have an appointment between midnight and
 321         ;; `appt-warn-time' minutes after midnight, we
 322         ;; must begin to issue a message before midnight.  Midnight
 323         ;; is considered 0 minutes and 11:59pm is 1439
 324         ;; minutes.  Therefore we must recalculate the minutes to
 325         ;; appointment variable.  It is equal to the number of
 326         ;; minutes before midnight plus the number of minutes after
 327         ;; midnight our appointment is.
 328         (if (and (< appt-comp-time appt-warn-time)
 329                  (> (+ cur-comp-time appt-warn-time)
 330                     appt-max-time))
 331             (setq min-to-app (+ (- (1+ appt-max-time) cur-comp-time)
 332                                 appt-comp-time)))
 333         ;; Issue warning if the appointment time is within
 334         ;; appt-message-warning time.
 335         (when (and (<= min-to-app appt-warn-time)
 336                    (>= min-to-app 0))
 337           (setq appt-display-count (1+ prev-appt-display-count))
 338           ;; This is true every appt-display-interval minutes.
 339           (and (zerop (mod prev-appt-display-count appt-display-interval))
 340                (appt-display-message (cadr (car appt-time-msg-list))
 341                                      min-to-app))
 342           (when appt-display-mode-line
 343             (setq appt-mode-string
 344                   (concat " " (propertize
 345                                (format "App't in %s min." min-to-app)
 346                                'face 'mode-line-emphasis))))
 347           ;; When an appointment is reached, delete it from the
 348           ;; list.  Reset the count to 0 in case we display another
 349           ;; appointment on the next cycle.
 350           (if (zerop min-to-app)
 351               (setq appt-time-msg-list (cdr appt-time-msg-list)
 352                     appt-display-count nil))))
 353       ;; If we have changed the mode line string, redisplay all mode lines.
 354       (and appt-display-mode-line
 355            (not (string-equal appt-mode-string
 356                               prev-appt-mode-string))
 357            (progn
 358              (force-mode-line-update t)
 359              ;; If the string now has a notification, redisplay right now.
 360              (if appt-mode-string
 361                  (sit-for 0)))))))
 362
 363 (defun appt-disp-window (min-to-app new-time appt-msg)
 364   "Display appointment due in MIN-TO-APP (a string) minutes.
 365 NEW-TIME is a string giving the date.  Displays the appointment
 366 message APPT-MSG in a separate buffer."
 367   (let ((this-window (selected-window))
 368         (appt-disp-buf (get-buffer-create appt-buffer-name)))
 369     ;; Make sure we're not in the minibuffer before splitting the window.
 370     ;; FIXME this seems needlessly complicated?
 371     (when (minibufferp)
 372       (other-window 1)
 373       (and (minibufferp) (display-multi-frame-p) (other-frame 1)))
 374     (if (cdr (assq 'unsplittable (frame-parameters)))
 375         ;; In an unsplittable frame, use something somewhere else.
 376         (progn
 377           (set-buffer appt-disp-buf)
 378           (display-buffer appt-disp-buf))
 379       (unless (or (special-display-p (buffer-name appt-disp-buf))
 380                   (same-window-p (buffer-name appt-disp-buf)))
 381         ;; By default, split the bottom window and use the lower part.
 382         (appt-select-lowest-window)
 383         ;; Split the window, unless it's too small to do so.
 384         (when (>= (window-height) (* 2 window-min-height))
 385           (select-window (split-window))))
 386       (switch-to-buffer appt-disp-buf))
 387     ;; FIXME Link to diary entry?
 388     (calendar-set-mode-line
 389      (format " Appointment %s. %s "
 390              (if (string-equal "0" min-to-app) "now"
 391                (format "in %s minute%s" min-to-app
 392                        (if (string-equal "1" min-to-app) "" "s")))
 393              new-time))
 394     (setq buffer-read-only nil
 395           buffer-undo-list t)
 396     (erase-buffer)
 397     (insert appt-msg)
 398     (shrink-window-if-larger-than-buffer (get-buffer-window appt-disp-buf t))
 399     (set-buffer-modified-p nil)
 400     (setq buffer-read-only t)
 401     (raise-frame (selected-frame))
 402     (select-window this-window)))
 403
 404 (defun appt-delete-window ()
 405   "Function called to undisplay appointment messages.
 406 Usually just deletes the appointment buffer."
 407   (let ((window (get-buffer-window appt-buffer-name t)))
 408     (and window
 409          (or (eq window (frame-root-window (window-frame window)))
 410              (delete-window window))))
 411   (kill-buffer appt-buffer-name)
 412   (if appt-audible
 413       (beep 1)))
 414
 415 (defun appt-select-lowest-window ()
 416   "Select the lowest window on the frame."
 417   (let ((lowest-window (selected-window))
 418         (bottom-edge (nth 3 (window-edges)))
 419         next-bottom-edge)
 420     (walk-windows (lambda (w)
 421                     (when (< bottom-edge (setq next-bottom-edge
 422                                                (nth 3 (window-edges w))))
 423                       (setq bottom-edge next-bottom-edge
 424                             lowest-window w))) 'nomini)
 425     (select-window lowest-window)))
 426
 427 (defconst appt-time-regexp
 428   "[0-9]?[0-9]\\(h\\([0-9][0-9]\\)?\\|[:.][0-9][0-9]\\)\\(am\\|pm\\)?")
 429
 430 ;;;###autoload
 431 (defun appt-add (time msg &optional warntime)
 432   "Add an appointment for today at TIME with message MSG.
 433 The time should be in either 24 hour format or am/pm format.
 434 Optional argument WARNTIME is an integer (or string) giving the number
 435 of minutes before the appointment at which to start warning.
 436 The default is `appt-message-warning-time'."
 437   (interactive "sTime (hh:mm[am/pm]): \nsMessage:
 438 sMinutes before the appointment to start warning: ")
 439   (unless (string-match appt-time-regexp time)
 440     (error "Unacceptable time-string"))
 441   (and (stringp warntime)
 442        (setq warntime (unless (string-equal warntime "")
 443                         (string-to-number warntime))))
 444   (and warntime
 445        (not (integerp warntime))
 446        (error "Argument WARNTIME must be an integer, or nil"))
 447   (or appt-timer (appt-activate))
 448   (let ((time-msg (list (list (appt-convert-time time))
 449                         (concat time " " msg) t)))
 450     ;; It is presently non-sensical to have multiple warnings about
 451     ;; the same appointment with just different delays, but it might
 452     ;; not always be so.  TODO
 453     (if warntime (setq time-msg (append time-msg (list warntime))))
 454     (unless (member time-msg appt-time-msg-list)
 455       (setq appt-time-msg-list
 456             (appt-sort-list (nconc appt-time-msg-list (list time-msg)))))))
 457
 458 (defun appt-delete ()
 459   "Delete an appointment from the list of appointments."
 460   (interactive)
 461   (let ((tmp-msg-list appt-time-msg-list))
 462     (dolist (element tmp-msg-list)
 463       (if (y-or-n-p (concat "Delete "
 464                             ;; We want to quote any doublequotes in the
 465                             ;; string, as well as put doublequotes around it.
 466                             (prin1-to-string
 467                              (substring-no-properties (cadr element) 0))
 468                             " from list? "))
 469           (setq appt-time-msg-list (delq element appt-time-msg-list)))))
 470   (appt-check)
 471   (message ""))
 472
 473
 474 (defvar number)
 475 (defvar original-date)
 476 (defvar diary-entries-list)
 477
 478 (defun appt-make-list ()
 479   "Update the appointments list from today's diary buffer.
 480 The time must be at the beginning of a line for it to be
 481 put in the appointments list (see examples in documentation of
 482 the function `appt-check').  We assume that the variables DATE and
 483 NUMBER hold the arguments that `diary-list-entries' received.
 484 They specify the range of dates that the diary is being processed for.
 485
 486 Any appointments made with `appt-add' are not affected by this function."
 487   ;; We have something to do if the range of dates that the diary is
 488   ;; considering includes the current date.
 489   (if (and (not (calendar-date-compare
 490                  (list (calendar-current-date))
 491                  (list original-date)))
 492            (calendar-date-compare
 493             (list (calendar-current-date))
 494             (list (calendar-gregorian-from-absolute
 495                    (+ (calendar-absolute-from-gregorian original-date)
 496                       number)))))
 497       (save-excursion
 498         ;; Clear the appointments list, then fill it in from the diary.
 499         (dolist (elt appt-time-msg-list)
 500           ;; Delete any entries that were not made with appt-add.
 501           (unless (nth 2 elt)
 502             (setq appt-time-msg-list
 503                   (delq elt appt-time-msg-list))))
 504         (if diary-entries-list
 505             ;; Cycle through the entry-list (diary-entries-list)
 506             ;; looking for entries beginning with a time.  If the
 507             ;; entry begins with a time, add it to the
 508             ;; appt-time-msg-list.  Then sort the list.
 509             (let ((entry-list diary-entries-list)
 510                   time-string literal)
 511               ;; Below, we assume diary-entries-list was in date
 512               ;; order.  It is, unless something on
 513               ;; diary-list-entries-hook has changed it, eg
 514               ;; diary-include-other-files (bug#7019).  It must be
 515               ;; in date order if number = 1.
 516               (and diary-list-entries-hook
 517                    appt-display-diary
 518                    (not (eq diary-number-of-entries 1))
 519                    (not (memq (car (last diary-list-entries-hook))
 520                               '(diary-sort-entries sort-diary-entries)))
 521                    (setq entry-list (sort entry-list 'diary-entry-compare)))
 522               ;; Skip diary entries for dates before today.
 523               (while (and entry-list
 524                           (calendar-date-compare
 525                            (car entry-list) (list (calendar-current-date))))
 526                 (setq entry-list (cdr entry-list)))
 527               ;; Parse the entries for today.
 528               (while (and entry-list
 529                           (calendar-date-equal
 530                            (calendar-current-date) (caar entry-list)))
 531                 (setq time-string (cadr (car entry-list))
 532                       ;; Including any comments.
 533                       literal (or (nth 2 (nth 3 (car entry-list)))
 534                                   time-string))
 535                 (while (string-match appt-time-regexp time-string)
 536                   (let* ((beg (match-beginning 0))
 537                          ;; Get just the time for this appointment.
 538                          (only-time (match-string 0 time-string))
 539                          ;; Find the end of this appointment
 540                          ;; (the start of the next).
 541                          (end (string-match
 542                                (concat "\n[ \t]*" appt-time-regexp)
 543                                time-string
 544                                (match-end 0)))
 545                          (warntime
 546                           (if (string-match appt-warning-time-regexp literal)
 547                               (string-to-number (match-string 1 literal))))
 548                          ;; Get the whole string for this appointment.
 549                          (appt-time-string
 550                           (substring time-string beg end))
 551                          (appt-time (list (appt-convert-time only-time)))
 552                          (time-msg (append
 553                                     (list appt-time appt-time-string)
 554                                     (if warntime (list nil warntime)))))
 555                     ;; Add this appointment to appt-time-msg-list.
 556                     (setq appt-time-msg-list
 557                           (nconc appt-time-msg-list (list time-msg))
 558                           ;; Discard this appointment from the string.
 559                           ;; (This allows for multiple appts per entry.)
 560                           time-string
 561                           (if end (substring time-string end) ""))
 562                     ;; Similarly, discard the start of literal.
 563                     (and (> (length time-string) 0)
 564                          (string-match appt-time-regexp literal)
 565                          (setq end (string-match
 566                                     (concat "\n[ \t]*" appt-time-regexp)
 567                                     literal (match-end 0)))
 568                          (setq literal (substring literal end)))))
 569                 (setq entry-list (cdr entry-list)))))
 570         (setq appt-time-msg-list (appt-sort-list appt-time-msg-list))
 571         ;; Convert current time to minutes after midnight (12:01am = 1),
 572         ;; and remove elements in the list that are in the past.
 573         (let* ((now (decode-time))
 574                (now-mins (+ (* 60 (nth 2 now)) (nth 1 now))))
 575           (while (and appt-time-msg-list
 576                       (< (caar (car appt-time-msg-list)) now-mins))
 577             (setq appt-time-msg-list (cdr appt-time-msg-list)))))))
 578
 579
 580 (defun appt-sort-list (appt-list)
 581   "Sort an appointment list, putting earlier items at the front.
 582 APPT-LIST is a list of the same format as `appt-time-msg-list'."
 583   (sort appt-list (lambda (e1 e2) (< (caar e1) (caar e2)))))
 584
 585
 586 (defun appt-convert-time (time2conv)
 587   "Convert hour:min[am/pm] format TIME2CONV to minutes from midnight.
 588 A period (.) can be used instead of a colon (:) to separate the
 589 hour and minute parts."
 590   ;; Formats that should be accepted:
 591   ;;   10:00 10.00 10h00 10h 10am 10:00am 10.00am
 592   (let ((min (if (string-match "[h:.]\\([0-9][0-9]\\)" time2conv)
 593                  (string-to-number (match-string 1 time2conv))
 594                0))
 595         (hr (if (string-match "[0-9]*[0-9]" time2conv)
 596                 (string-to-number (match-string 0 time2conv))
 597               0)))
 598     ;; Convert the time appointment time into 24 hour time.
 599     (cond ((and (string-match "pm" time2conv) (< hr 12))
 600            (setq hr (+ 12 hr)))
 601           ((and (string-match "am" time2conv) (= hr 12))
 602            (setq hr 0)))
 603     ;; Convert the actual time into minutes.
 604     (+ (* hr 60) min)))
 605
 606 (defun appt-update-list ()
 607   "If the current buffer is visiting the diary, update appointments.
 608 This function also acts on any file listed in `diary-included-files'.
 609 It is intended for use with `write-file-functions'."
 610   (and (member buffer-file-name (append diary-included-files
 611                                         (list (expand-file-name diary-file))))
 612        appt-timer
 613        (let ((appt-display-diary nil))
 614          (appt-check t)))
 615   nil)
 616
 617 ;;;###autoload
 618 (defun appt-activate (&optional arg)
 619   "Toggle checking of appointments.
 620 With optional numeric argument ARG, turn appointment checking on if
 621 ARG is positive, otherwise off."
 622   (interactive "P")
 623   (let ((appt-active appt-timer))
 624     (setq appt-active (if arg (> (prefix-numeric-value arg) 0)
 625                         (not appt-active)))
 626     (remove-hook 'write-file-functions 'appt-update-list)
 627     (or global-mode-string (setq global-mode-string '("")))
 628     (delq 'appt-mode-string global-mode-string)
 629     (when appt-timer
 630       (cancel-timer appt-timer)
 631       (setq appt-timer nil))
 632     (if appt-active
 633         (progn
 634           (add-hook 'write-file-functions 'appt-update-list)
 635           (setq appt-timer (run-at-time t 60 'appt-check)
 636                 global-mode-string
 637                 (append global-mode-string '(appt-mode-string)))
 638           (appt-check t)
 639           (message "Appointment reminders enabled%s"
 640                    ;; Someone might want to use appt-add without a diary.
 641                    (if (ignore-errors (diary-check-diary-file))
 642                        ""
 643                      " (no diary file found)")))
 644       (message "Appointment reminders disabled"))))
 645
 646
 647 (provide 'appt)
 648
 649 ;;; appt.el ends here