lisp/textmodes/bibtex-style.el

   1 ;;; bibtex-style.el --- Major mode for BibTeX Style files
   2
   3 ;; Copyright (C) 2005,2007, 2008  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords:
   7
   8 ;; This file is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 3, or (at your option)
  11 ;; any later version.
  12
  13 ;; This file is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  21 ;; Boston, MA 02110-1301, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Done: font-lock, imenu, outline, commenting, indentation.
  26 ;; Todo: tab-completion.
  27 ;; Bugs:
  28
  29 ;;; Code:
  30
  31 (defvar bibtex-style-mode-syntax-table
  32   (let ((st (make-syntax-table)))
  33     (modify-syntax-entry ?%  "<" st)
  34     (modify-syntax-entry ?\n ">" st)
  35     (modify-syntax-entry ?\{ "(}" st)
  36     (modify-syntax-entry ?\} "){" st)
  37     (modify-syntax-entry ?\" "\"" st)
  38     (modify-syntax-entry ?.  "_" st)
  39     (modify-syntax-entry ?'  "'" st)
  40     (modify-syntax-entry ?#  "'" st)
  41     (modify-syntax-entry ?*  "." st)
  42     (modify-syntax-entry ?=  "." st)
  43     (modify-syntax-entry ?$  "_" st)
  44     st))
  45
  46
  47 (defconst bibtex-style-commands
  48   '("ENTRY" "EXECUTE" "FUNCTION" "INTEGERS" "ITERATE" "MACRO" "READ"
  49     "REVERSE" "SORT" "STRINGS"))
  50
  51 (defconst bibtex-style-functions
  52   ;; From http://www.eeng.dcu.ie/local-docs/btxdocs/btxhak/btxhak/node4.html.
  53   '("<" ">" "=" "+" "-" "*" ":="
  54     "add.period$" "call.type$" "change.case$" "chr.to.int$" "cite$"
  55     "duplicate$" "empty$" "format.name$" "if$" "int.to.chr$" "int.to.str$"
  56     "missing$" "newline$" "num.names$" "pop$" "preamble$" "purify$" "quote$"
  57     "skip$" "stack$" "substring$" "swap$" "text.length$" "text.prefix$"
  58     "top$" "type$" "warning$" "while$" "width$" "write$"))
  59
  60 (defvar bibtex-style-font-lock-keywords
  61   `((,(regexp-opt bibtex-style-commands 'words) . font-lock-keyword-face)
  62     ("\\w+\\$" . font-lock-keyword-face)
  63     ("\\<\\(FUNCTION\\|MACRO\\)\\s-+{\\([^}\n]+\\)}"
  64      (2 font-lock-function-name-face))))
  65
  66 ;;;###autoload (add-to-list 'auto-mode-alist '("\\.bst\\'" . bibtex-style-mode))
  67
  68 ;;;###autoload
  69 (define-derived-mode bibtex-style-mode nil "BibStyle"
  70   "Major mode for editing BibTeX style files."
  71   (set (make-local-variable 'comment-start) "%")
  72   (set (make-local-variable 'outline-regexp) "^[a-z]")
  73   (set (make-local-variable 'imenu-generic-expression)
  74        '((nil "\\<\\(FUNCTION\\|MACRO\\)\\s-+{\\([^}\n]+\\)}" 2)))
  75   (set (make-local-variable 'indent-line-function) 'bibtex-style-indent-line)
  76   (set (make-local-variable 'parse-sexp-ignore-comments) t)
  77   (setq font-lock-defaults
  78         '(bibtex-style-font-lock-keywords nil t
  79           ((?. . "w")))))
  80
  81 (defun bibtex-style-indent-line ()
  82   "Indent current line of BibTeX Style code."
  83   (interactive)
  84   (let* ((savep (point))
  85          (indent (condition-case nil
  86                      (save-excursion
  87                        (forward-line 0)
  88                        (skip-chars-forward " \t")
  89                        (if (>= (point) savep) (setq savep nil))
  90                        (max (bibtex-style-calculate-indentation) 0))
  91                    (error 0))))
  92     (if savep
  93         (save-excursion (indent-line-to indent))
  94       (indent-line-to indent))))
  95
  96 (defcustom bibtex-style-indent-basic 2
  97   "Basic amount of indentation to use in BibTeX Style mode."
  98   :type 'integer
  99   :group 'bibtex)
 100
 101 (defun bibtex-style-calculate-indentation (&optional virt)
 102   (or
 103    ;; Stick the first line at column 0.
 104    (and (= (point-min) (line-beginning-position)) 0)
 105    ;; Commands start at column 0.
 106    (and (looking-at (regexp-opt bibtex-style-commands 'words)) 0)
 107    ;; Trust the current indentation, if such info is applicable.
 108    (and virt (save-excursion (skip-chars-backward " \t{") (bolp))
 109         (current-column))
 110    ;; Put leading close-paren where the matching open brace would be.
 111    (and (looking-at "}")
 112         (condition-case nil
 113             (save-excursion
 114               (up-list -1)
 115               (bibtex-style-calculate-indentation 'virt))
 116           (scan-error nil)))
 117    ;; Align leading "if$" with previous command.
 118    (and (looking-at "if\\$")
 119         (condition-case nil
 120             (save-excursion
 121               (backward-sexp 3)
 122               (bibtex-style-calculate-indentation 'virt))
 123           (scan-error
 124            ;; There is no command before the "if$".
 125            (condition-case nil
 126                (save-excursion
 127                  (up-list -1)
 128                  (+ bibtex-style-indent-basic
 129                     (bibtex-style-calculate-indentation 'virt)))
 130              (scan-error nil)))))
 131    ;; Right after an opening brace.
 132    (condition-case err (save-excursion (backward-sexp 1) nil)
 133      (scan-error (goto-char (nth 2 err))
 134                  (+ bibtex-style-indent-basic
 135                     (bibtex-style-calculate-indentation 'virt))))
 136    ;; Default, align with previous command.
 137    (let ((fai ;; First arm of an "if$".
 138           (condition-case nil
 139               (save-excursion
 140                 (forward-sexp 2)
 141                 (forward-comment (point-max))
 142                 (looking-at "if\\$"))
 143             (scan-error nil))))
 144      (save-excursion
 145        (condition-case err
 146            (while (progn
 147                     (backward-sexp 1)
 148                     (save-excursion (skip-chars-backward " \t{") (not (bolp)))))
 149          (scan-error nil))
 150        (+ (current-column)
 151           (if (or fai (looking-at "ENTRY")) bibtex-style-indent-basic 0))))))
 152
 153
 154 (provide 'bibtex-style)
 155 ;; arch-tag: b20ad41a-fd36-466e-8fd2-cc6137f9c55c
 156 ;;; bibtex-style.el ends here