lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el.
   2
   3 ;; Copyright (C) 1988, 1994, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;    This is a customisation of comint-mode (see comint.el)
  29 ;;
  30 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  31 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  32 ;; 8/88
  33 ;;
  34 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  35 ;; merge them into the master source.
  36 ;;
  37 ;; The changelog is at the end of this file.
  38 ;;
  39 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  40 ;; interface that communicates process state back to the superior emacs by
  41 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  42 ;; lots and lots of special purpose code to read these control sequences, and
  43 ;; so is very tightly integrated with the cscheme process. The cscheme
  44 ;; interrupt handler and debugger read single character commands in cbreak
  45 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  46 ;; the single letter command keys to emacs functions that directly send the
  47 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  48 ;; functionality. If you are a cscheme user, you may prefer to use the
  49 ;; xscheme.el/cscheme -emacs interaction.
  50 ;;
  51 ;; Here's a summary of the pros and cons, as I see them.
  52 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  53 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  54 ;;           history only keeps the immediately prior input. Bizarre
  55 ;;           keybindings.
  56 ;;
  57 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  58 ;;            Carefully integrated functionality with the entire suite of
  59 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  60 ;;            Zwei and Hemlock. Good input history. A few commands not in
  61 ;;            xscheme.
  62 ;;
  63 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  64 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  65 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  66 ;; invited to port xscheme functionality on top of comint mode...
  67
  68 ;;; Code:
  69
  70 (require 'scheme)
  71 (require 'comint)
  72
  73 ;;; INFERIOR SCHEME MODE STUFF
  74 ;;;============================================================================
  75
  76 (defvar inferior-scheme-mode-hook nil
  77   "*Hook for customising inferior-scheme mode.")
  78 (defvar inferior-scheme-mode-map nil)
  79
  80 (cond ((not inferior-scheme-mode-map)
  81        (setq inferior-scheme-mode-map
  82              (copy-keymap comint-mode-map))
  83        (define-key inferior-scheme-mode-map "\M-\C-x" ;gnu convention
  84                    'scheme-send-definition)
  85        (define-key inferior-scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp)
  86        (define-key inferior-scheme-mode-map "\C-c\C-l" 'scheme-load-file)
  87        (define-key inferior-scheme-mode-map "\C-c\C-k" 'scheme-compile-file)
  88        (scheme-mode-commands inferior-scheme-mode-map)))
  89
  90 ;; Install the process communication commands in the scheme-mode keymap.
  91 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
  92 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
  93 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
  94 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
  95 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
  96 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
  97 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
  98 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
  99 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 100 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 101 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 102
 103 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 104   (define-key map [separator-eval] '("--"))
 105   (define-key map [compile-file]
 106     '("Compile Scheme File" . scheme-compile-file))
 107   (define-key map [load-file]
 108     '("Load Scheme File" . scheme-load-file))
 109   (define-key map [switch]
 110     '("Switch to Scheme" . switch-to-scheme))
 111   (define-key map [com-def-go]
 112     '("Compile Definitiion & Go" . scheme-compile-definition-and-go))
 113   (define-key map [com-def]
 114     '("Compile Definitiion" . scheme-compile-definition))
 115   (define-key map [send-def-go]
 116     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 117   (define-key map [send-def]
 118     '("Evaluate Last Definition" . scheme-send-definition))
 119   (define-key map [send-region-go]
 120     '("Evaluate Region & Go" . scheme-send-region-and-go))
 121   (define-key map [send-region]
 122     '("Evaluate Region" . scheme-send-region))
 123   (define-key map [send-sexp]
 124     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 125 )
 126
 127 (defvar scheme-buffer)
 128
 129 (defun inferior-scheme-mode ()
 130   "Major mode for interacting with an inferior Scheme process.
 131
 132 The following commands are available:
 133 \\{inferior-scheme-mode-map}
 134
 135 A Scheme process can be fired up with M-x run-scheme.
 136
 137 Customisation: Entry to this mode runs the hooks on comint-mode-hook and
 138 inferior-scheme-mode-hook (in that order).
 139
 140 You can send text to the inferior Scheme process from other buffers containing
 141 Scheme source.
 142     switch-to-scheme switches the current buffer to the Scheme process buffer.
 143     scheme-send-definition sends the current definition to the Scheme process.
 144     scheme-compile-definition compiles the current definition.
 145     scheme-send-region sends the current region to the Scheme process.
 146     scheme-compile-region compiles the current region.
 147
 148     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 149         scheme-send-region-and-go, and scheme-compile-region-and-go
 150         switch to the Scheme process buffer after sending their text.
 151 For information on running multiple processes in multiple buffers, see
 152 documentation for variable scheme-buffer.
 153
 154 Commands:
 155 Return after the end of the process' output sends the text from the
 156     end of process to point.
 157 Return before the end of the process' output copies the sexp ending at point
 158     to the end of the process' output, and sends it.
 159 Delete converts tabs to spaces as it moves back.
 160 Tab indents for Scheme; with argument, shifts rest
 161     of expression rigidly with the current line.
 162 C-M-q does Tab on each line starting within following expression.
 163 Paragraphs are separated only by blank lines.  Semicolons start comments.
 164 If you accidentally suspend your process, use \\[comint-continue-subjob]
 165 to continue it."
 166   (interactive)
 167   (comint-mode)
 168   ;; Customise in inferior-scheme-mode-hook
 169   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 170   (scheme-mode-variables)
 171   (setq major-mode 'inferior-scheme-mode)
 172   (setq mode-name "Inferior Scheme")
 173   (setq mode-line-process '(":%s"))
 174   (use-local-map inferior-scheme-mode-map)
 175   (setq comint-input-filter (function scheme-input-filter))
 176   (setq comint-get-old-input (function scheme-get-old-input))
 177   (run-hooks 'inferior-scheme-mode-hook))
 178
 179 (defvar inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 180   "*Input matching this regexp are not saved on the history list.
 181 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters.")
 182
 183 (defun scheme-input-filter (str)
 184   "Don't save anything matching inferior-scheme-filter-regexp"
 185   (not (string-match inferior-scheme-filter-regexp str)))
 186
 187 (defun scheme-get-old-input ()
 188   "Snarf the sexp ending at point"
 189   (save-excursion
 190     (let ((end (point)))
 191       (backward-sexp)
 192       (buffer-substring (point) end))))
 193
 194 (defun scheme-args-to-list (string)
 195   (let ((where (string-match "[ \t]" string)))
 196     (cond ((null where) (list string))
 197           ((not (= where 0))
 198            (cons (substring string 0 where)
 199                  (scheme-args-to-list (substring string (+ 1 where)
 200                                                  (length string)))))
 201           (t (let ((pos (string-match "[^ \t]" string)))
 202                (if (null pos)
 203                    nil
 204                  (scheme-args-to-list (substring string pos
 205                                                  (length string)))))))))
 206
 207 (defvar scheme-program-name "scheme"
 208   "*Program invoked by the run-scheme command")
 209
 210 ;;;###autoload
 211 (defun run-scheme (cmd)
 212   "Run an inferior Scheme process, input and output via buffer *scheme*.
 213 If there is a process already running in `*scheme*', switch to that buffer.
 214 With argument, allows you to edit the command line (default is value
 215 of `scheme-program-name').  Runs the hooks `inferior-scheme-mode-hook'
 216 \(after the `comint-mode-hook' is run).
 217 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 218
 219   (interactive (list (if current-prefix-arg
 220                          (read-string "Run Scheme: " scheme-program-name)
 221                          scheme-program-name)))
 222   (if (not (comint-check-proc "*scheme*"))
 223       (let ((cmdlist (scheme-args-to-list cmd)))
 224         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 225                            nil (cdr cmdlist)))
 226         (inferior-scheme-mode)))
 227   (setq scheme-program-name cmd)
 228   (setq scheme-buffer "*scheme*")
 229   (pop-to-buffer "*scheme*"))
 230 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 231
 232 (defun scheme-send-region (start end)
 233   "Send the current region to the inferior Scheme process."
 234   (interactive "r")
 235   (comint-send-region (scheme-proc) start end)
 236   (comint-send-string (scheme-proc) "\n"))
 237
 238 (defun scheme-send-definition ()
 239   "Send the current definition to the inferior Scheme process."
 240   (interactive)
 241   (save-excursion
 242    (end-of-defun)
 243    (let ((end (point)))
 244      (beginning-of-defun)
 245      (scheme-send-region (point) end))))
 246
 247 (defun scheme-send-last-sexp ()
 248   "Send the previous sexp to the inferior Scheme process."
 249   (interactive)
 250   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 251
 252 (defvar scheme-compile-exp-command "(compile '%s)"
 253   "*Template for issuing commands to compile arbitrary Scheme expressions.")
 254
 255 (defun scheme-compile-region (start end)
 256   "Compile the current region in the inferior Scheme process.
 257 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 258   (interactive "r")
 259   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 260                                             (format "(begin %s)"
 261                                                     (buffer-substring start end))))
 262   (comint-send-string (scheme-proc) "\n"))
 263
 264 (defun scheme-compile-definition ()
 265   "Compile the current definition in the inferior Scheme process."
 266   (interactive)
 267   (save-excursion
 268    (end-of-defun)
 269    (let ((end (point)))
 270      (beginning-of-defun)
 271      (scheme-compile-region (point) end))))
 272
 273 (defun switch-to-scheme (eob-p)
 274   "Switch to the scheme process buffer.
 275 With argument, positions cursor at end of buffer."
 276   (interactive "P")
 277   (if (get-buffer scheme-buffer)
 278       (pop-to-buffer scheme-buffer)
 279       (error "No current process buffer. See variable scheme-buffer."))
 280   (cond (eob-p
 281          (push-mark)
 282          (goto-char (point-max)))))
 283
 284 (defun scheme-send-region-and-go (start end)
 285   "Send the current region to the inferior Scheme process.
 286 Then switch to the process buffer."
 287   (interactive "r")
 288   (scheme-send-region start end)
 289   (switch-to-scheme t))
 290
 291 (defun scheme-send-definition-and-go ()
 292   "Send the current definition to the inferior Scheme.
 293 Then switch to the process buffer."
 294   (interactive)
 295   (scheme-send-definition)
 296   (switch-to-scheme t))
 297
 298 (defun scheme-compile-definition-and-go ()
 299   "Compile the current definition in the inferior Scheme.
 300 Then switch to the process buffer."
 301   (interactive)
 302   (scheme-compile-definition)
 303   (switch-to-scheme t))
 304
 305 (defun scheme-compile-region-and-go (start end)
 306   "Compile the current region in the inferior Scheme.
 307 Then switch to the process buffer."
 308   (interactive "r")
 309   (scheme-compile-region start end)
 310   (switch-to-scheme t))
 311
 312 (defvar scheme-source-modes '(scheme-mode)
 313   "*Used to determine if a buffer contains Scheme source code.
 314 If it's loaded into a buffer that is in one of these major modes, it's
 315 considered a scheme source file by scheme-load-file and scheme-compile-file.
 316 Used by these commands to determine defaults.")
 317
 318 (defvar scheme-prev-l/c-dir/file nil
 319   "Caches the last (directory . file) pair.
 320 Caches the last pair used in the last scheme-load-file or
 321 scheme-compile-file command. Used for determining the default in the
 322 next one.")
 323
 324 (defun scheme-load-file (file-name)
 325   "Load a Scheme file into the inferior Scheme process."
 326   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 327                                   scheme-source-modes t)) ; T because LOAD
 328                                                           ; needs an exact name
 329   (comint-check-source file-name) ; Check to see if buffer needs saved.
 330   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 331                                        (file-name-nondirectory file-name)))
 332   (comint-send-string (scheme-proc) (concat "(load \""
 333                                             file-name
 334                                             "\"\)\n")))
 335
 336 (defun scheme-compile-file (file-name)
 337   "Compile a Scheme file in the inferior Scheme process."
 338   (interactive (comint-get-source "Compile Scheme file: "
 339                                   scheme-prev-l/c-dir/file
 340                                   scheme-source-modes
 341                                   nil)) ; NIL because COMPILE doesn't
 342                                         ; need an exact name.
 343   (comint-check-source file-name) ; Check to see if buffer needs saved.
 344   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 345                                        (file-name-nondirectory file-name)))
 346   (comint-send-string (scheme-proc) (concat "(compile-file \""
 347                                             file-name
 348                                             "\"\)\n")))
 349
 350 \f
 351 (defvar scheme-buffer nil "*The current scheme process buffer.
 352
 353 MULTIPLE PROCESS SUPPORT
 354 ===========================================================================
 355 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 356 processes. To run multiple Scheme processes, you start the first up with
 357 \\[run-scheme]. It will be in a buffer named *scheme*. Rename this buffer
 358 with \\[rename-buffer]. You may now start up a new process with another
 359 \\[run-scheme]. It will be in a new buffer, named *scheme*. You can
 360 switch between the different process buffers with \\[switch-to-buffer].
 361
 362 Commands that send text from source buffers to Scheme processes --
 363 like scheme-send-definition or scheme-compile-region -- have to choose a
 364 process to send to, when you have more than one Scheme process around. This
 365 is determined by the global variable scheme-buffer. Suppose you
 366 have three inferior Schemes running:
 367     Buffer      Process
 368     foo         scheme
 369     bar         scheme<2>
 370     *scheme*    scheme<3>
 371 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 372 code, what process do you send it to?
 373
 374 - If you're in a process buffer (foo, bar, or *scheme*),
 375   you send it to that process.
 376 - If you're in some other buffer (e.g., a source file), you
 377   send it to the process attached to buffer scheme-buffer.
 378 This process selection is performed by function scheme-proc.
 379
 380 Whenever \\[run-scheme] fires up a new process, it resets scheme-buffer
 381 to be the new process's buffer. If you only run one process, this will
 382 do the right thing. If you run multiple processes, you can change
 383 scheme-buffer to another process buffer with \\[set-variable].
 384
 385 More sophisticated approaches are, of course, possible. If you find yourself
 386 needing to switch back and forth between multiple processes frequently,
 387 you may wish to consider ilisp.el, a larger, more sophisticated package
 388 for running inferior Lisp and Scheme processes. The approach taken here is
 389 for a minimal, simple implementation. Feel free to extend it.")
 390
 391 (defun scheme-proc ()
 392   "Returns the current scheme process. See variable scheme-buffer."
 393   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 394                                       (current-buffer)
 395                                       scheme-buffer))))
 396     (or proc
 397         (error "No current process. See variable scheme-buffer"))))
 398
 399
 400 ;;; Do the user's customisation...
 401
 402 (defvar cmuscheme-load-hook nil
 403   "This hook is run when cmuscheme is loaded in.
 404 This is a good place to put keybindings.")
 405
 406 (run-hooks 'cmuscheme-load-hook)
 407
 408
 409 ;;; CHANGE LOG
 410 ;;; ===========================================================================
 411 ;;; 8/88 Olin
 412 ;;; Created.
 413 ;;;
 414 ;;; 2/15/89 Olin
 415 ;;; Removed -emacs flag from process invocation. It's only useful for
 416 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
 417 ;;; which messes things up royally. A bug.
 418 ;;;
 419 ;;; 5/22/90 Olin
 420 ;;; - Upgraded to use comint-send-string and comint-send-region.
 421 ;;; - run-scheme now offers to let you edit the command line if
 422 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
 423 ;;;   has been removed.
 424 ;;; - Explicit references to process "scheme" have been replaced with
 425 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
 426 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
 427 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
 428 ;;;   and friends, but interested hackers might find a useful application
 429 ;;;   of this facility.
 430 ;;;
 431 ;;; 3/12/90 Olin
 432 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
 433 ;;;   Tale suggested this.
 434
 435 (provide 'cmuscheme)
 436
 437 ;;; cmuscheme.el ends here