lisp/erc/erc-services.el

   1 ;;; erc-services.el --- Identify to NickServ
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software: you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;; There are two ways to go about identifying yourself automatically to
  23 ;; NickServ with this module.  The more secure way is to listen for identify
  24 ;; requests from the user NickServ.  Another way is to identify yourself to
  25 ;; NickServ directly after a successful connection and every time you change
  26 ;; your nickname.  This method is rather insecure, though, because no checks
  27 ;; are made to test if NickServ is the real NickServ for a given network or
  28 ;; server.
  29
  30 ;; As a default, ERC has the data for the official nickname services on
  31 ;; the networks Austnet, BrasNET, Dalnet, freenode, GalaxyNet, GRnet,
  32 ;; and Slashnet.  You can add more by using M-x customize-variable RET
  33 ;; erc-nickserv-alist.
  34
  35 ;; Usage:
  36 ;;
  37 ;; Put into your .emacs:
  38 ;;
  39 ;; (require 'erc-services)
  40 ;; (erc-services-mode 1)
  41 ;;
  42 ;; Add your nickname and NickServ password to `erc-nickserv-passwords'.
  43 ;; Using the freenode network as an example:
  44 ;;
  45 ;; (setq erc-nickserv-passwords '((freenode (("nickname" "password")))))
  46 ;;
  47 ;; The default automatic identification mode is autodetection of NickServ
  48 ;; identify requests.  Set the variable `erc-nickserv-identify-mode' if
  49 ;; you'd like to change this behavior.  You can also change the way
  50 ;; automatic identification is handled by using:
  51 ;;
  52 ;; M-x erc-nickserv-identify-mode
  53 ;;
  54 ;; If you'd rather not identify yourself automatically but would like access
  55 ;; to the functions contained in this file, just load this file without
  56 ;; enabling `erc-services-mode'.
  57 ;;
  58
  59 ;;; Code:
  60
  61 (require 'erc)
  62 (require 'erc-networks)
  63 (eval-when-compile (require 'cl))
  64
  65 ;; Customization:
  66
  67 (defgroup erc-services nil
  68   "Configuration for IRC services.
  69
  70 On some networks, there exists a special type of automated irc bot,
  71 called Services.  Those usually allow you to register your nickname,
  72 post/read memos to other registered users who are currently offline,
  73 and do various other things.
  74
  75 This group allows you to set variables to somewhat automate
  76 communication with those Services."
  77   :group 'erc)
  78
  79 (defcustom erc-nickserv-identify-mode 'both
  80   "The mode which is used when identifying to Nickserv.
  81
  82 Possible settings are:.
  83
  84 'autodetect  - Identify when the real Nickserv sends an identify request.
  85 'nick-change - Identify when you log in or change your nickname.
  86 'both        - Do the former if the network supports it, otherwise do the
  87                latter.
  88 nil          - Disables automatic Nickserv identification.
  89
  90 You can also use M-x erc-nickserv-identify-mode to change modes."
  91   :group 'erc-services
  92   :type '(choice (const autodetect)
  93                  (const nick-change)
  94                  (const both)
  95                  (const nil))
  96   :set (lambda (sym val)
  97          (set sym val)
  98          ;; avoid recursive load at startup
  99          (when (featurep 'erc-services)
 100            (erc-nickserv-identify-mode val))))
 101
 102 ;;;###autoload (autoload 'erc-services-mode "erc-services" nil t)
 103 (define-erc-module services nickserv
 104   "This mode automates communication with services."
 105   ((erc-nickserv-identify-mode erc-nickserv-identify-mode))
 106   ((remove-hook 'erc-server-NOTICE-functions
 107                 'erc-nickserv-identify-autodetect)
 108    (remove-hook 'erc-after-connect
 109                 'erc-nickserv-identify-on-connect)
 110    (remove-hook 'erc-nick-changed-functions
 111                 'erc-nickserv-identify-on-nick-change)
 112    (remove-hook 'erc-server-NOTICE-functions
 113                 'erc-nickserv-identification-autodetect)))
 114
 115 ;;;###autoload
 116 (defun erc-nickserv-identify-mode (mode)
 117   "Set up hooks according to which MODE the user has chosen."
 118   (interactive
 119    (list (intern (completing-read
 120                   "Choose Nickserv identify mode (RET to disable): "
 121                   '(("autodetect") ("nick-change") ("both")) nil t))))
 122   (add-hook 'erc-server-NOTICE-functions
 123             'erc-nickserv-identification-autodetect)
 124   (unless erc-networks-mode
 125     ;; Force-enable networks module, because we need it to set
 126     ;; erc-network for us.
 127     (erc-networks-enable))
 128   (cond ((eq mode 'autodetect)
 129          (setq erc-nickserv-identify-mode 'autodetect)
 130          (add-hook 'erc-server-NOTICE-functions
 131                    'erc-nickserv-identify-autodetect)
 132          (remove-hook 'erc-nick-changed-functions
 133                       'erc-nickserv-identify-on-nick-change)
 134          (remove-hook 'erc-after-connect
 135                       'erc-nickserv-identify-on-connect))
 136         ((eq mode 'nick-change)
 137          (setq erc-nickserv-identify-mode 'nick-change)
 138          (add-hook 'erc-after-connect
 139                    'erc-nickserv-identify-on-connect)
 140          (add-hook 'erc-nick-changed-functions
 141                    'erc-nickserv-identify-on-nick-change)
 142          (remove-hook 'erc-server-NOTICE-functions
 143                       'erc-nickserv-identify-autodetect))
 144         ((eq mode 'both)
 145          (setq erc-nickserv-identify-mode 'both)
 146          (add-hook 'erc-server-NOTICE-functions
 147                    'erc-nickserv-identify-autodetect)
 148          (add-hook 'erc-after-connect
 149                    'erc-nickserv-identify-on-connect)
 150          (add-hook 'erc-nick-changed-functions
 151                    'erc-nickserv-identify-on-nick-change))
 152         (t
 153          (setq erc-nickserv-identify-mode nil)
 154          (remove-hook 'erc-server-NOTICE-functions
 155                       'erc-nickserv-identify-autodetect)
 156          (remove-hook 'erc-after-connect
 157                       'erc-nickserv-identify-on-connect)
 158          (remove-hook 'erc-nick-changed-functions
 159                       'erc-nickserv-identify-on-nick-change)
 160          (remove-hook 'erc-server-NOTICE-functions
 161                       'erc-nickserv-identification-autodetect))))
 162
 163 (defcustom erc-prompt-for-nickserv-password t
 164   "Ask for the password when identifying to NickServ."
 165   :group 'erc-services
 166   :type 'boolean)
 167
 168 (defcustom erc-nickserv-passwords nil
 169   "Passwords used when identifying to NickServ automatically.
 170
 171 Example of use:
 172   (setq erc-nickserv-passwords
 173         '((freenode ((\"nick-one\" . \"password\")
 174                      (\"nick-two\" . \"password\")))
 175           (DALnet ((\"nick\" . \"password\")))))"
 176   :group 'erc-services
 177   :type '(repeat
 178           (list :tag "Network"
 179                 (choice :tag "Network name"
 180                         (const Ars)
 181                         (const Austnet)
 182                         (const Azzurra)
 183                         (const BitlBee)
 184                         (const BRASnet)
 185                         (const DALnet)
 186                         (const freenode)
 187                         (const GalaxyNet)
 188                         (const GRnet)
 189                         (const iip)
 190                         (const OFTC)
 191                         (const QuakeNet)
 192                         (const Rizon)
 193                         (const SlashNET)
 194                         (symbol :tag "Network name"))
 195                 (repeat :tag "Nickname and password"
 196                         (cons :tag "Identity"
 197                               (string :tag "Nick")
 198                               (string :tag "Password"))))))
 199
 200 ;; Variables:
 201
 202 (defcustom erc-nickserv-alist
 203   '((Ars
 204      nil nil
 205      "Census"
 206      "IDENTIFY" nil nil nil)
 207     (Austnet
 208      "NickOP!service@austnet.org"
 209      "/msg\\s-NickOP@austnet.org\\s-identify\\s-<password>"
 210      "nickop@austnet.org"
 211      "identify" nil nil nil)
 212     (Azzurra
 213      "NickServ!service@azzurra.org"
 214      "\ 2/ns\\s-IDENTIFY\\s-password\ 2"
 215      "NickServ"
 216      "IDENTIFY" nil nil nil)
 217     (BitlBee
 218      nil nil
 219      "&bitlbee"
 220      "identify" nil nil nil)
 221     (BRASnet
 222      "NickServ!services@brasnet.org"
 223      "\ 2/NickServ\\s-IDENTIFY\\s-\1fsenha\1f\ 2"
 224      "NickServ"
 225      "IDENTIFY" nil "" nil)
 226     (DALnet
 227      "NickServ!service@dal.net"
 228      "/msg\\s-NickServ@services.dal.net\\s-IDENTIFY\\s-<password>"
 229      "NickServ@services.dal.net"
 230      "IDENTIFY" nil nil nil)
 231     (freenode
 232      "NickServ!NickServ@services."
 233      ;; freenode also accepts a password at login, see the `erc'
 234      ;; :password argument.
 235      "/msg\\s-NickServ\\s-\ 2IDENTIFY\ 2\\s-<password>"
 236      "NickServ"
 237      "IDENTIFY" nil nil
 238      "Password\\s-accepted\\s--\\s-you\\s-are\\s-now\\s-recognized")
 239     (GalaxyNet
 240      "NS!nickserv@galaxynet.org"
 241      "Please\\s-change\\s-nicks\\s-or\\s-authenticate."
 242      "NS@services.galaxynet.org"
 243      "AUTH" t nil nil)
 244     (GRnet
 245      "NickServ!service@irc.gr"
 246      "This\\s-nickname\\s-is\\s-registered\\s-and\\s-protected."
 247      "NickServ"
 248      "IDENTIFY" nil nil
 249      "Password\\s-accepted\\s--\\s-you\\s-are\\s-now\\s-recognized.")
 250     (iip
 251      "Trent@anon.iip"
 252      "type\\s-/squery\\s-Trent\\s-identify\\s-<password>"
 253      "Trent@anon.iip"
 254      "IDENTIFY" nil "SQUERY" nil)
 255     (OFTC
 256      "NickServ!services@services.oftc.net"
 257      ;; OFTC's NickServ doesn't ask you to identify anymore.
 258      nil
 259      "NickServ"
 260      "IDENTIFY" nil nil
 261      "You\\s-are\\s-successfully\\s-identified\\s-as\\s-\ 2")
 262     (Rizon
 263      "NickServ!service@rizon.net"
 264      "This\\s-nickname\\s-is\\s-registered\\s-and\\s-protected."
 265      "NickServ"
 266      "IDENTIFY" nil nil
 267      "Password\\s-accepted\\s--\\s-you\\s-are\\s-now\\s-recognized.")
 268     (QuakeNet
 269      nil nil
 270      "Q@CServe.quakenet.org"
 271      "auth" t nil nil)
 272     (SlashNET
 273      "NickServ!services@services.slashnet.org"
 274      "/msg\\s-NickServ\\s-IDENTIFY\\s-\1fpassword"
 275      "NickServ@services.slashnet.org"
 276      "IDENTIFY" nil nil nil))
 277    "Alist of NickServer details, sorted by network.
 278 Every element in the list has the form
 279   \(SYMBOL NICKSERV REGEXP NICK KEYWORD USE-CURRENT ANSWER SUCCESS-REGEXP)
 280
 281 SYMBOL is a network identifier, a symbol, as used in `erc-networks-alist'.
 282 NICKSERV is the description of the nickserv in the form nick!user@host.
 283 REGEXP is a regular expression matching the message from nickserv.
 284 NICK is nickserv's nickname.  Use nick@server where necessary/possible.
 285 KEYWORD is the keyword to use in the reply message to identify yourself.
 286 USE-CURRENT indicates whether the current nickname must be used when
 287   identifying.
 288 ANSWER is the command to use for the answer.  The default is 'privmsg.
 289 SUCCESS-REGEXP is a regular expression matching the message nickserv
 290   sends when you've successfully identified.
 291 The last two elements are optional."
 292    :group 'erc-services
 293    :type '(repeat
 294            (list :tag "Nickserv data"
 295                  (symbol :tag "Network name")
 296                  (choice (string :tag "Nickserv's nick!user@host")
 297                          (const :tag "No message sent by Nickserv" nil))
 298                  (choice (regexp :tag "Identify request sent by Nickserv")
 299                          (const :tag "No message sent by Nickserv" nil))
 300                  (string :tag "Identify to")
 301                  (string :tag "Identify keyword")
 302                  (boolean :tag "Use current nick in identify message?")
 303                  (choice :tag "Command to use (optional)"
 304                   (string :tag "Command")
 305                   (const :tag "No special command necessary" nil)))))
 306
 307 (defsubst erc-nickserv-alist-sender (network &optional entry)
 308   (nth 1 (or entry (assoc network erc-nickserv-alist))))
 309
 310 (defsubst erc-nickserv-alist-regexp (network &optional entry)
 311   (nth 2 (or entry (assoc network erc-nickserv-alist))))
 312
 313 (defsubst erc-nickserv-alist-nickserv (network &optional entry)
 314   (nth 3 (or entry (assoc network erc-nickserv-alist))))
 315
 316 (defsubst erc-nickserv-alist-ident-keyword (network &optional entry)
 317   (nth 4 (or entry (assoc network erc-nickserv-alist))))
 318
 319 (defsubst erc-nickserv-alist-use-nick-p (network &optional entry)
 320   (nth 5 (or entry (assoc network erc-nickserv-alist))))
 321
 322 (defsubst erc-nickserv-alist-ident-command (network &optional entry)
 323   (nth 6 (or entry (assoc network erc-nickserv-alist))))
 324
 325 (defsubst erc-nickserv-alist-identified-regexp (network &optional entry)
 326   (nth 7 (or entry (assoc network erc-nickserv-alist))))
 327
 328 ;; Functions:
 329
 330 (defcustom erc-nickserv-identified-hook nil
 331   "Run this hook when NickServ acknowledged successful identification.
 332 Hooks are called with arguments (NETWORK NICK)."
 333   :group 'erc-services
 334   :type 'hook)
 335
 336 (defun erc-nickserv-identification-autodetect (proc parsed)
 337   "Check for NickServ's successful identification notice.
 338 Make sure it is the real NickServ for this network and that it has
 339 specifically confirmed a successful identification attempt.
 340 If this is the case, run `erc-nickserv-identified-hook'."
 341   (let* ((network (erc-network))
 342          (sender (erc-nickserv-alist-sender network))
 343          (success-regex (erc-nickserv-alist-identified-regexp network))
 344          (sspec (erc-response.sender parsed))
 345          (nick (car (erc-response.command-args parsed)))
 346          (msg (erc-response.contents parsed)))
 347     ;; continue only if we're sure it's the real nickserv for this network
 348     ;; and it's told us we've successfully identified
 349     (when (and sender (equal sspec sender)
 350                success-regex
 351                (string-match success-regex msg))
 352       (erc-log "NickServ IDENTIFY success notification detected")
 353       (run-hook-with-args 'erc-nickserv-identified-hook network nick)
 354       nil)))
 355
 356 (defun erc-nickserv-identify-autodetect (proc parsed)
 357   "Identify to NickServ when an identify request is received.
 358 Make sure it is the real NickServ for this network.
 359 If `erc-prompt-for-nickserv-password' is non-nil, prompt the user for the
 360 password for this nickname, otherwise try to send it automatically."
 361   (unless (and (null erc-nickserv-passwords)
 362                (null erc-prompt-for-nickserv-password))
 363     (let* ((network (erc-network))
 364            (sender (erc-nickserv-alist-sender network))
 365            (identify-regex (erc-nickserv-alist-regexp network))
 366            (sspec (erc-response.sender parsed))
 367            (nick (car (erc-response.command-args parsed)))
 368            (msg (erc-response.contents parsed)))
 369       ;; continue only if we're sure it's the real nickserv for this network
 370       ;; and it's asked us to identify
 371       (when (and sender (equal sspec sender)
 372                  identify-regex
 373                  (string-match identify-regex msg))
 374         (erc-log "NickServ IDENTIFY request detected")
 375         (erc-nickserv-call-identify-function nick)
 376         nil))))
 377
 378 (defun erc-nickserv-identify-on-connect (server nick)
 379   "Identify to Nickserv after the connection to the server is established."
 380   (unless (or (and (null erc-nickserv-passwords)
 381                    (null erc-prompt-for-nickserv-password))
 382               (and (eq erc-nickserv-identify-mode 'both)
 383                    (erc-nickserv-alist-regexp (erc-network))))
 384     (erc-nickserv-call-identify-function nick)))
 385
 386 (defun erc-nickserv-identify-on-nick-change (nick old-nick)
 387   "Identify to Nickserv whenever your nick changes."
 388   (unless (or (and (null erc-nickserv-passwords)
 389                    (null erc-prompt-for-nickserv-password))
 390               (and (eq erc-nickserv-identify-mode 'both)
 391                    (erc-nickserv-alist-regexp (erc-network))))
 392     (erc-nickserv-call-identify-function nick)))
 393
 394 (defun erc-nickserv-call-identify-function (nickname)
 395   "Call `erc-nickserv-identify' interactively or run it with NICKNAME's
 396 password.
 397 The action is determined by the value of `erc-prompt-for-nickserv-password'."
 398   (if erc-prompt-for-nickserv-password
 399       (call-interactively 'erc-nickserv-identify)
 400     (when erc-nickserv-passwords
 401       (erc-nickserv-identify
 402        (cdr (assoc nickname
 403                    (nth 1 (assoc (erc-network)
 404                                  erc-nickserv-passwords))))))))
 405
 406 ;;;###autoload
 407 (defun erc-nickserv-identify (password)
 408   "Send an \"identify <PASSWORD>\" message to NickServ.
 409 When called interactively, read the password using `read-passwd'."
 410   (interactive
 411    (list (read-passwd
 412           (format "NickServ password for %s on %s (RET to cancel): "
 413                   (erc-current-nick)
 414                   (or (and (erc-network)
 415                            (symbol-name (erc-network)))
 416                       "Unknown network")))))
 417   (when (and password (not (string= "" password)))
 418     (let* ((erc-auto-discard-away nil)
 419            (network (erc-network))
 420            (nickserv-info (assoc network erc-nickserv-alist))
 421            (nickserv (or (erc-nickserv-alist-nickserv nil nickserv-info)
 422                          "NickServ"))
 423            (identify-word (or (erc-nickserv-alist-ident-keyword
 424                                nil nickserv-info)
 425                               "IDENTIFY"))
 426            (nick (if (erc-nickserv-alist-use-nick-p nil nickserv-info)
 427                      (concat (erc-current-nick) " ")
 428                    ""))
 429            (msgtype (or (erc-nickserv-alist-ident-command nil nickserv-info)
 430                         "PRIVMSG")))
 431       (erc-message msgtype
 432                    (concat nickserv " " identify-word " " nick password)))))
 433
 434 (provide 'erc-services)
 435
 436 ;;; erc-services.el ends here
 437 ;;
 438 ;; Local Variables:
 439 ;; indent-tabs-mode: t
 440 ;; tab-width: 8
 441 ;; End:
 442
 443 ;; arch-tag: d401c8aa-d938-4255-96a9-3efb64c47e58