lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a valid Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defun PC-bindings (bind)
 145   (let ((completion-map minibuffer-local-completion-map)
 146         (must-match-map minibuffer-local-must-match-map))
 147     (cond ((not bind)
 148            ;; These bindings are the default bindings.  It would be better to
 149            ;; restore the previous bindings.
 150            (define-key completion-map "\t"      'minibuffer-complete)
 151            (define-key completion-map " "       'minibuffer-complete-word)
 152            (define-key completion-map "?"       'minibuffer-completion-help)
 153
 154            (define-key must-match-map "\t"      'minibuffer-complete)
 155            (define-key must-match-map " "       'minibuffer-complete-word)
 156            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 157            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 158            (define-key must-match-map "?"       'minibuffer-completion-help)
 159
 160            (define-key global-map "\e\t"        'complete-symbol))
 161           (PC-default-bindings
 162            (define-key completion-map "\t"      'PC-complete)
 163            (define-key completion-map " "       'PC-complete-word)
 164            (define-key completion-map "?"       'PC-completion-help)
 165
 166            (define-key completion-map "\e\t"    'PC-complete)
 167            (define-key completion-map "\e "     'PC-complete-word)
 168            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 169            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 170            (define-key completion-map "\e?"     'PC-completion-help)
 171
 172            (define-key must-match-map "\t"      'PC-complete)
 173            (define-key must-match-map " "       'PC-complete-word)
 174            (define-key must-match-map "\r"      'PC-complete-and-exit)
 175            (define-key must-match-map "\n"      'PC-complete-and-exit)
 176            (define-key must-match-map "?"       'PC-completion-help)
 177
 178            (define-key must-match-map "\e\t"    'PC-complete)
 179            (define-key must-match-map "\e "     'PC-complete-word)
 180            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 181            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 182            (define-key must-match-map "\e?"     'PC-completion-help)
 183
 184            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 185
 186 ;;;###autoload
 187 (define-minor-mode partial-completion-mode
 188   "Toggle Partial Completion mode.
 189 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 190
 191 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 192 nil) is enhanced so that if some string is divided into words and each word is
 193 delimited by a character in `PC-word-delimiters', partial words are completed
 194 as much as possible and `*' characters are treated likewise in file names.
 195
 196 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 197 command begins with that sequence of characters, and
 198 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 199 other file in that directory begins with that sequence of characters.
 200
 201 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 202 specially in \\[find-file].  For example,
 203 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 204 See also the variable `PC-include-file-path'.
 205
 206 Partial Completion mode extends the meaning of `completion-auto-help' (which
 207 see), so that if it is neither nil nor t, Emacs shows the `*Completions*'
 208 buffer only on the second attempt to complete.  That is, if TAB finds nothing
 209 to complete, the first TAB just says \"Next char not unique\" and the
 210 second TAB brings up the `*Completions*' buffer."
 211   :global t :group 'partial-completion
 212   ;; Deal with key bindings...
 213   (PC-bindings partial-completion-mode)
 214   ;; Deal with include file feature...
 215   (cond ((not partial-completion-mode)
 216          (remove-hook 'find-file-not-found-functions 'PC-look-for-include-file))
 217         ((not PC-disable-includes)
 218          (add-hook 'find-file-not-found-functions 'PC-look-for-include-file)))
 219   ;; ... with some underhand redefining.
 220   (cond ((not partial-completion-mode)
 221          (ad-disable-advice 'read-file-name-internal 'around 'PC-include-file)
 222          (ad-activate 'read-file-name-internal))
 223         ((not PC-disable-includes)
 224          (ad-enable-advice 'read-file-name-internal 'around 'PC-include-file)
 225          (ad-activate 'read-file-name-internal)))
 226   ;; Adjust the completion selection in *Completion* buffers to the way
 227   ;; we work.  The default minibuffer completion code only completes the
 228   ;; text before point and leaves the text after point alone (new in
 229   ;; Emacs-22).  In contrast we use the whole text and we even sometimes
 230   ;; move point to a place before EOB, to indicate the first position where
 231   ;; there's a difference, so when the user uses choose-completion, we have
 232   ;; to trick choose-completion into replacing the whole minibuffer text
 233   ;; rather than only the text before point.  --Stef
 234   (funcall
 235    (if partial-completion-mode 'add-hook 'remove-hook)
 236    'choose-completion-string-functions
 237    (lambda (choice buffer mini-p base-size)
 238      (if mini-p (goto-char (point-max)))
 239      nil))
 240   ;; Build the env-completion and mapping table.
 241   (when (and partial-completion-mode (null PC-env-vars-alist))
 242     (setq PC-env-vars-alist
 243           (mapcar (lambda (string)
 244                     (let ((d (string-match "=" string)))
 245                       (cons (concat "$" (substring string 0 d))
 246                             (and d (substring string (1+ d))))))
 247                   process-environment))))
 248
 249 \f
 250 (defun PC-complete ()
 251   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 252 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 253 name which consists of three or more words, the first beginning with \"b\"
 254 and the third beginning with \"di\".
 255
 256 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 257 `beginning-of-defun', so this would produce a list of completions
 258 just like when normal Emacs completions are ambiguous.
 259
 260 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 261 \".\", and SPC."
 262   (interactive)
 263   (if (PC-was-meta-key)
 264       (minibuffer-complete)
 265     ;; If the previous command was not this one,
 266     ;; never scroll, always retry completion.
 267     (or (eq last-command this-command)
 268         (setq minibuffer-scroll-window nil))
 269     (let ((window minibuffer-scroll-window))
 270       ;; If there's a fresh completion window with a live buffer,
 271       ;; and this command is repeated, scroll that window.
 272       (if (and window (window-buffer window)
 273                (buffer-name (window-buffer window)))
 274           (with-current-buffer (window-buffer window)
 275             (if (pos-visible-in-window-p (point-max) window)
 276                 (set-window-start window (point-min) nil)
 277               (scroll-other-window)))
 278         (PC-do-completion nil)))))
 279
 280
 281 (defun PC-complete-word ()
 282   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 283 See `PC-complete' for details.
 284 This can be bound to other keys, like `-' and `.', if you wish."
 285   (interactive)
 286   (if (eq (PC-was-meta-key) PC-meta-flag)
 287       (if (eq last-command-char ? )
 288           (minibuffer-complete-word)
 289         (self-insert-command 1))
 290     (self-insert-command 1)
 291     (if (eobp)
 292         (PC-do-completion 'word))))
 293
 294
 295 (defun PC-complete-space ()
 296   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 297 See `PC-complete' for details.
 298 This is suitable for binding to other keys which should act just like SPC."
 299   (interactive)
 300   (if (eq (PC-was-meta-key) PC-meta-flag)
 301       (minibuffer-complete-word)
 302     (insert " ")
 303     (if (eobp)
 304         (PC-do-completion 'word))))
 305
 306
 307 (defun PC-complete-and-exit ()
 308   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 309 See `PC-complete' for details."
 310   (interactive)
 311   (if (eq (PC-was-meta-key) PC-meta-flag)
 312       (minibuffer-complete-and-exit)
 313     (PC-do-complete-and-exit)))
 314
 315 (defun PC-force-complete-and-exit ()
 316   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 317 See `PC-complete' for details."
 318   (interactive)
 319   (let ((minibuffer-completion-confirm nil))
 320     (PC-do-complete-and-exit)))
 321
 322 (defun PC-do-complete-and-exit ()
 323   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 324       (exit-minibuffer)
 325     (let ((flag (PC-do-completion 'exit)))
 326       (and flag
 327            (if (or (eq flag 'complete)
 328                    (not minibuffer-completion-confirm))
 329                (exit-minibuffer)
 330              (PC-temp-minibuffer-message " [Confirm]"))))))
 331
 332
 333 (defun PC-completion-help ()
 334   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 335 See `PC-complete' for details."
 336   (interactive)
 337   (if (eq (PC-was-meta-key) PC-meta-flag)
 338       (minibuffer-completion-help)
 339     (PC-do-completion 'help)))
 340
 341 (defun PC-was-meta-key ()
 342   (or (/= (length (this-command-keys)) 1)
 343       (let ((key (aref (this-command-keys) 0)))
 344         (if (integerp key)
 345             (>= key 128)
 346           (not (null (memq 'meta (event-modifiers key))))))))
 347
 348
 349 (defvar PC-ignored-extensions 'empty-cache)
 350 (defvar PC-delims 'empty-cache)
 351 (defvar PC-ignored-regexp nil)
 352 (defvar PC-word-failed-flag nil)
 353 (defvar PC-delim-regex nil)
 354 (defvar PC-ndelims-regex nil)
 355 (defvar PC-delims-list nil)
 356
 357 (defvar PC-completion-as-file-name-predicate
 358   (lambda () minibuffer-completing-file-name)
 359   "A function testing whether a minibuffer completion now will work filename-style.
 360 The function takes no arguments, and typically looks at the value
 361 of `minibuffer-completion-table' and the minibuffer contents.")
 362
 363 ;; Returns the sequence of non-delimiter characters that follow regexp in string.
 364 (defun PC-chunk-after (string regexp)
 365   (if (not (string-match regexp string))
 366       (let ((message (format "String %s didn't match regexp %s" string regexp)))
 367         (message message)
 368         (error message)))
 369   (let ((result (substring string (match-end 0))))
 370     ;; result may contain multiple chunks
 371     (if (string-match PC-delim-regex result)
 372         (setq result (substring result 0 (match-beginning 0))))
 373     result))
 374
 375 (defun test-completion-ignore-case (str table pred)
 376   "Like `test-completion', but ignores case when possible."
 377   ;; Binding completion-ignore-case to nil ensures, for compatibility with
 378   ;; standard completion, that the return value is exactly one of the
 379   ;; possibilities.  Do this binding only if pred is nil, out of paranoia;
 380   ;; perhaps it is safe even if pred is non-nil.
 381   (if pred
 382       (test-completion str table pred)
 383     (let ((completion-ignore-case nil))
 384       (test-completion str table pred))))
 385
 386 (defun PC-do-completion (&optional mode beg end)
 387   (or beg (setq beg (minibuffer-prompt-end)))
 388   (or end (setq end (point-max)))
 389   (let* ((table minibuffer-completion-table)
 390          (pred minibuffer-completion-predicate)
 391          (filename (funcall PC-completion-as-file-name-predicate))
 392          (dirname nil)          ; non-nil only if a filename is being completed
 393          (dirlength 0)
 394          (str (buffer-substring beg end))
 395          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 396          (ambig nil)
 397          basestr origstr
 398          env-on
 399          regex
 400          p offset
 401          (poss nil)
 402          helpposs
 403          (case-fold-search completion-ignore-case))
 404
 405     ;; Check if buffer contents can already be considered complete
 406     (if (and (eq mode 'exit)
 407              (test-completion-ignore-case str table pred))
 408         'complete
 409
 410       ;; Do substitutions in directory names
 411       (and filename
 412            (setq basestr (or (file-name-directory str) ""))
 413            (setq dirlength (length basestr))
 414            ;; Do substitutions in directory names
 415            (setq p (substitute-in-file-name basestr))
 416            (not (string-equal basestr p))
 417            (setq str (concat p (file-name-nondirectory str)))
 418            (progn
 419              (delete-region beg end)
 420              (insert str)
 421              (setq end (+ beg (length str)))))
 422
 423       ;; Prepare various delimiter strings
 424       (or (equal PC-word-delimiters PC-delims)
 425           (setq PC-delims PC-word-delimiters
 426                 PC-delim-regex (concat "[" PC-delims "]")
 427                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 428                 PC-delims-list (append PC-delims nil)))
 429
 430       ;; Add wildcards if necessary
 431       (and filename
 432            (let ((dir (file-name-directory str))
 433                  (file (file-name-nondirectory str))
 434                  ;; The base dir for file-completion is passed in `predicate'.
 435                  (default-directory (expand-file-name pred)))
 436              (while (and (stringp dir) (not (file-directory-p dir)))
 437                (setq dir (directory-file-name dir))
 438                (setq file (concat (replace-regexp-in-string
 439                                    PC-delim-regex "*\\&"
 440                                    (file-name-nondirectory dir))
 441                                   "*/" file))
 442                (setq dir (file-name-directory dir)))
 443              (setq origstr str str (concat dir file))))
 444
 445       ;; Look for wildcard expansions in directory name
 446       (and filename
 447            (string-match "\\*.*/" str)
 448            (let ((pat str)
 449                  ;; The base dir for file-completion is passed in `predicate'.
 450                  (default-directory (expand-file-name pred))
 451                  files)
 452              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 453              (while (setq p (string-match PC-delim-regex pat p))
 454                (setq pat (concat (substring pat 0 p)
 455                                  "*"
 456                                  (substring pat p))
 457                      p (+ p 2)))
 458              (setq files (PC-expand-many-files (concat pat "*")))
 459              (if files
 460                  (let ((dir (file-name-directory (car files)))
 461                        (p files))
 462                    (while (and (setq p (cdr p))
 463                                (equal dir (file-name-directory (car p)))))
 464                    (if p
 465                        (setq filename nil table nil pred nil
 466                              ambig t)
 467                      (delete-region beg end)
 468                      (setq str (concat dir (file-name-nondirectory str)))
 469                      (insert str)
 470                      (setq end (+ beg (length str)))))
 471                (if origstr
 472                    ;; If the wildcards were introduced by us, it's possible
 473                    ;; that read-file-name-internal (especially our
 474                    ;; PC-include-file advice) can still find matches for the
 475                    ;; original string even if we couldn't, so remove the
 476                    ;; added wildcards.
 477                    (setq str origstr)
 478                  (setq filename nil table nil pred nil)))))
 479
 480       ;; Strip directory name if appropriate
 481       (if filename
 482           (if incname
 483               (setq basestr (substring str incname)
 484                     dirname (substring str 0 incname))
 485             (setq basestr (file-name-nondirectory str)
 486                   dirname (file-name-directory str))
 487             ;; Make sure str is consistent with its directory and basename
 488             ;; parts.  This is important on DOZe'NT systems when str only
 489             ;; includes a drive letter, like in "d:".
 490             (setq str (concat dirname basestr)))
 491         (setq basestr str))
 492
 493       ;; Convert search pattern to a standard regular expression
 494       (setq regex (regexp-quote basestr)
 495             offset (if (and (> (length regex) 0)
 496                             (not (eq (aref basestr 0) ?\*))
 497                             (or (eq PC-first-char t)
 498                                 (and PC-first-char filename))) 1 0)
 499             p offset)
 500       (while (setq p (string-match PC-delim-regex regex p))
 501         (if (eq (aref regex p) ? )
 502             (setq regex (concat (substring regex 0 p)
 503                                 PC-ndelims-regex
 504                                 PC-delim-regex
 505                                 (substring regex (1+ p)))
 506                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 507           (let ((bump (if (memq (aref regex p)
 508                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 509                           -1 0)))
 510             (setq regex (concat (substring regex 0 (+ p bump))
 511                                 PC-ndelims-regex
 512                                 (substring regex (+ p bump)))
 513                   p (+ p (length PC-ndelims-regex) 1)))))
 514       (setq p 0)
 515       (if filename
 516           (while (setq p (string-match "\\\\\\*" regex p))
 517             (setq regex (concat (substring regex 0 p)
 518                                 "[^/]*"
 519                                 (substring regex (+ p 2))))))
 520       ;;(setq the-regex regex)
 521       (setq regex (concat "\\`" regex))
 522
 523       (and (> (length basestr) 0)
 524            (= (aref basestr 0) ?$)
 525            (setq env-on t
 526                  table PC-env-vars-alist
 527                  pred nil))
 528
 529       ;; Find an initial list of possible completions
 530       (if (not (setq p (string-match (concat PC-delim-regex
 531                                              (if filename "\\|\\*" ""))
 532                                      str
 533                                      (+ (length dirname) offset))))
 534
 535           ;; Minibuffer contains no hyphens -- simple case!
 536           (setq poss (all-completions (if env-on
 537                                           basestr str)
 538                                       table
 539                                       pred))
 540
 541         ;; Use all-completions to do an initial cull.  This is a big win,
 542         ;; since all-completions is written in C!
 543         (let ((compl (all-completions (if env-on
 544                                           (file-name-nondirectory (substring str 0 p))
 545                                         (substring str 0 p))
 546                                         table
 547                                         pred)))
 548           (setq p compl)
 549           (while p
 550             (and (string-match regex (car p))
 551                  (progn
 552                    (set-text-properties 0 (length (car p)) '() (car p))
 553                    (setq poss (cons (car p) poss))))
 554             (setq p (cdr p)))))
 555
 556       ;; Now we have a list of possible completions
 557       (cond
 558
 559        ;; No valid completions found
 560        ((null poss)
 561         (if (and (eq mode 'word)
 562                  (not PC-word-failed-flag))
 563             (let ((PC-word-failed-flag t))
 564               (delete-backward-char 1)
 565               (PC-do-completion 'word))
 566           (beep)
 567           (PC-temp-minibuffer-message (if ambig
 568                                           " [Ambiguous dir name]"
 569                                         (if (eq mode 'help)
 570                                             " [No completions]"
 571                                           " [No match]")))
 572           nil))
 573
 574        ;; More than one valid completion found
 575        ((or (cdr (setq helpposs poss))
 576             (memq mode '(help word)))
 577
 578         ;; Handle completion-ignored-extensions
 579         (and filename
 580              (not (eq mode 'help))
 581              (let ((p2 poss))
 582
 583                ;; Build a regular expression representing the extensions list
 584                (or (equal completion-ignored-extensions PC-ignored-extensions)
 585                    (setq PC-ignored-regexp
 586                          (concat "\\("
 587                                  (mapconcat
 588                                   'regexp-quote
 589                                   (setq PC-ignored-extensions
 590                                         completion-ignored-extensions)
 591                                   "\\|")
 592                                  "\\)\\'")))
 593
 594                ;; Check if there are any without an ignored extension.
 595                ;; Also ignore `.' and `..'.
 596                (setq p nil)
 597                (while p2
 598                  (or (string-match PC-ignored-regexp (car p2))
 599                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 600                      (setq p (cons (car p2) p)))
 601                  (setq p2 (cdr p2)))
 602
 603                ;; If there are "good" names, use them
 604                (and p (setq poss p))))
 605
 606         ;; Is the actual string one of the possible completions?
 607         (setq p (and (not (eq mode 'help)) poss))
 608         (while (and p
 609                     (not (string-equal (car p) basestr)))
 610           (setq p (cdr p)))
 611         (and p (null mode)
 612              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 613         (if (and p
 614                  (not (and (null mode)
 615                            (eq this-command last-command))))
 616             t
 617
 618           ;; If ambiguous, try for a partial completion
 619           (let ((improved nil)
 620                 prefix
 621                 (pt nil)
 622                 (skip "\\`"))
 623
 624             ;; Check if next few letters are the same in all cases
 625             (if (and (not (eq mode 'help))
 626                      (setq prefix (try-completion (PC-chunk-after basestr skip) (mapcar 'list poss))))
 627                 (let ((first t) i)
 628                   ;; Retain capitalization of user input even if
 629                   ;; completion-ignore-case is set.
 630                   (if (eq mode 'word)
 631                       (setq prefix (PC-chop-word prefix basestr)))
 632                   (goto-char (+ beg (length dirname)))
 633                   (while (and (progn
 634                                 (setq i 0) ; index into prefix string
 635                                 (while (< i (length prefix))
 636                                   (if (and (< (point) end)
 637                                            (eq (downcase (aref prefix i))
 638                                                (downcase (following-char))))
 639                                       ;; same char (modulo case); no action
 640                                       (forward-char 1)
 641                                     (if (and (< (point) end)
 642                                              (and (looking-at " ")
 643                                                       (memq (aref prefix i)
 644                                                         PC-delims-list)))
 645                                         ;; replace " " by the actual delimiter
 646                                         (progn
 647                                           (delete-char 1)
 648                                           (insert (substring prefix i (1+ i))))
 649                                       ;; insert a new character
 650                                       (progn
 651                                       (and filename (looking-at "\\*")
 652                                            (progn
 653                                              (delete-char 1)
 654                                              (setq end (1- end))))
 655                                         (setq improved t)
 656                                     (insert (substring prefix i (1+ i)))
 657                                         (setq end (1+ end)))))
 658                                   (setq i (1+ i)))
 659                                 (or pt (setq pt (point)))
 660                                 (looking-at PC-delim-regex))
 661                               (setq skip (concat skip
 662                                                  (regexp-quote prefix)
 663                                                  PC-ndelims-regex)
 664                                     prefix (try-completion
 665                                             (PC-chunk-after
 666                                              ;; not basestr, because that does
 667                                              ;; not reflect insertions
 668                                              (buffer-substring
 669                                               (+ beg (length dirname)) end)
 670                                              skip)
 671                                             (mapcar
 672                                              (function
 673                                               (lambda (x)
 674                                                 (list
 675                                                  (and (string-match skip x)
 676                                                       (substring
 677                                                        x
 678                                                        (match-end 0))))))
 679                                              poss)))
 680                               (or (> i 0) (> (length prefix) 0))
 681                               (or (not (eq mode 'word))
 682                                   (and first (> (length prefix) 0)
 683                                        (setq first nil
 684                                              prefix (substring prefix 0 1))))))
 685                   (goto-char (if (eq mode 'word) end
 686                                (or pt beg)))))
 687
 688             (if (and (eq mode 'word)
 689                      (not PC-word-failed-flag))
 690
 691                 (if improved
 692
 693                     ;; We changed it... would it be complete without the space?
 694                     (if (test-completion (buffer-substring 1 (1- end))
 695                                           table pred)
 696                         (delete-region (1- end) end)))
 697
 698               (if improved
 699
 700                   ;; We changed it... enough to be complete?
 701                   (and (eq mode 'exit)
 702                        (test-completion-ignore-case (field-string) table pred))
 703
 704                 ;; If totally ambiguous, display a list of completions
 705                 (if (or (eq completion-auto-help t)
 706                         (and completion-auto-help
 707                              (eq last-command this-command))
 708                         (eq mode 'help))
 709                     (with-output-to-temp-buffer "*Completions*"
 710                       (display-completion-list (sort helpposs 'string-lessp))
 711                       (with-current-buffer standard-output
 712                         ;; Record which part of the buffer we are completing
 713                         ;; so that choosing a completion from the list
 714                         ;; knows how much old text to replace.
 715                         (setq completion-base-size dirlength)))
 716                   (PC-temp-minibuffer-message " [Next char not unique]"))
 717                 nil)))))
 718
 719        ;; Only one possible completion
 720        (t
 721         (if (and (equal basestr (car poss))
 722                  (not (and env-on filename)))
 723             (if (null mode)
 724                 (PC-temp-minibuffer-message " [Sole completion]"))
 725           (delete-region beg end)
 726           (insert (format "%s"
 727                           (if filename
 728                               (substitute-in-file-name (concat dirname (car poss)))
 729                             (car poss)))))
 730         t)))))
 731
 732 (defun PC-chop-word (new old)
 733   (let ((i -1)
 734         (j -1))
 735     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 736                 (setq j (string-match PC-delim-regex new (1+ j)))))
 737     (if (and j
 738              (or (not PC-word-failed-flag)
 739                  (setq j (string-match PC-delim-regex new (1+ j)))))
 740         (substring new 0 (1+ j))
 741       new)))
 742
 743 (defvar PC-not-minibuffer nil)
 744
 745 (defun PC-temp-minibuffer-message (message)
 746   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 747   (cond (PC-not-minibuffer
 748          (message message)
 749          (sit-for 2)
 750          (message ""))
 751         ((fboundp 'temp-minibuffer-message)
 752          (temp-minibuffer-message message))
 753         (t
 754          (let ((point-max (point-max)))
 755            (save-excursion
 756              (goto-char point-max)
 757              (insert message))
 758            (let ((inhibit-quit t))
 759              (sit-for 2)
 760              (delete-region point-max (point-max))
 761              (when quit-flag
 762                (setq quit-flag nil
 763                      unread-command-events '(7))))))))
 764
 765
 766 (defun PC-lisp-complete-symbol ()
 767   "Perform completion on Lisp symbol preceding point.
 768 That symbol is compared against the symbols that exist
 769 and any additional characters determined by what is there
 770 are inserted.
 771 If the symbol starts just after an open-parenthesis,
 772 only symbols with function definitions are considered.
 773 Otherwise, all symbols with function definitions, values
 774 or properties are considered."
 775   (interactive)
 776   (let* ((end (point))
 777          (beg (save-excursion
 778                 (with-syntax-table lisp-mode-syntax-table
 779                   (backward-sexp 1)
 780                   (while (= (char-syntax (following-char)) ?\')
 781                     (forward-char 1))
 782                   (point))))
 783          (minibuffer-completion-table obarray)
 784          (minibuffer-completion-predicate
 785           (if (eq (char-after (1- beg)) ?\()
 786               'fboundp
 787             (function (lambda (sym)
 788                         (or (boundp sym) (fboundp sym)
 789                             (symbol-plist sym))))))
 790          (PC-not-minibuffer t))
 791     (PC-do-completion nil beg end)))
 792
 793 (defun PC-complete-as-file-name ()
 794    "Perform completion on file names preceding point.
 795  Environment vars are converted to their values."
 796    (interactive)
 797    (let* ((end (point))
 798           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 799                                        (point-min) t)
 800                    (+ (point) 2)
 801                    (point-min)))
 802           (minibuffer-completion-table 'read-file-name-internal)
 803           (minibuffer-completion-predicate "")
 804           (PC-not-minibuffer t))
 805      (goto-char end)
 806      (PC-do-completion nil beg end)))
 807
 808 ;; Use the shell to do globbing.
 809 ;; This could now use file-expand-wildcards instead.
 810
 811 (defun PC-expand-many-files (name)
 812   (with-current-buffer (generate-new-buffer " *Glob Output*")
 813     (erase-buffer)
 814     (shell-command (concat "echo " name) t)
 815     (goto-char (point-min))
 816     ;; CSH-style shells were known to output "No match", whereas
 817     ;; SH-style shells tend to simply output `name' when no match is found.
 818     (if (looking-at (concat ".*No match\\|\\(^\\| \\)\\("
 819                             (regexp-quote name)
 820                             "\\|"
 821                             (regexp-quote (expand-file-name name))
 822                             "\\)\\( \\|$\\)"))
 823         nil
 824       (insert "(\"")
 825       (while (search-forward " " nil t)
 826         (delete-backward-char 1)
 827         (insert "\" \""))
 828       (goto-char (point-max))
 829       (delete-backward-char 1)
 830       (insert "\")")
 831       (goto-char (point-min))
 832       (let ((files (read (current-buffer))) (p nil))
 833         (kill-buffer (current-buffer))
 834         (or (equal completion-ignored-extensions PC-ignored-extensions)
 835             (setq PC-ignored-regexp
 836                   (concat "\\("
 837                           (mapconcat
 838                            'regexp-quote
 839                            (setq PC-ignored-extensions
 840                                  completion-ignored-extensions)
 841                            "\\|")
 842                           "\\)\\'")))
 843         (setq p nil)
 844         (while files
 845           ;; This whole process of going through to shell, to echo, and
 846           ;; finally parsing the output is a hack.  It breaks as soon as
 847           ;; there are spaces in the file names or when the no-match
 848           ;; message changes.  To make up for it, we check that what we read
 849           ;; indeed exists, so we may miss some files, but we at least won't
 850           ;; list non-existent ones.
 851           (or (not (file-exists-p (car files)))
 852               (string-match PC-ignored-regexp (car files))
 853               (setq p (cons (car files) p)))
 854           (setq files (cdr files)))
 855         p))))
 856
 857 ;; Facilities for loading C header files.  This is independent from the
 858 ;; main completion code.  See also the variable `PC-include-file-path'
 859 ;; at top of this file.
 860
 861 (defun PC-look-for-include-file ()
 862   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 863       (let ((name (substring (buffer-file-name)
 864                              (match-beginning 1) (match-end 1)))
 865             (punc (aref (buffer-file-name) (match-beginning 0)))
 866             (path nil)
 867             new-buf)
 868         (kill-buffer (current-buffer))
 869         (if (equal name "")
 870             (with-current-buffer (car (buffer-list))
 871               (save-excursion
 872                 (beginning-of-line)
 873                 (if (looking-at
 874                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 875                     (setq name (buffer-substring (match-beginning 1)
 876                                                  (match-end 1))
 877                           punc (char-after (1- (match-beginning 1))))
 878                   ;; Suggested by Frank Siebenlist:
 879                   (if (or (looking-at
 880                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 881                           (looking-at
 882                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 883                           (looking-at
 884                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 885                       (progn
 886                         (setq name (buffer-substring (match-beginning 1)
 887                                                      (match-end 1))
 888                               punc ?\<
 889                               path load-path)
 890                         (if (string-match "\\.elc$" name)
 891                             (setq name (substring name 0 -1))
 892                           (or (string-match "\\.el$" name)
 893                               (setq name (concat name ".el")))))
 894                     (error "Not on an #include line"))))))
 895         (or (string-match "\\.[[:alnum:]]+$" name)
 896             (setq name (concat name ".h")))
 897         (if (eq punc ?\<)
 898             (let ((path (or path (PC-include-file-path))))
 899               (while (and path
 900                           (not (file-exists-p
 901                                 (concat (file-name-as-directory (car path))
 902                                         name))))
 903                 (setq path (cdr path)))
 904               (if path
 905                   (setq name (concat (file-name-as-directory (car path)) name))
 906                 (error "No such include file: <%s>" name)))
 907           (let ((dir (with-current-buffer (car (buffer-list))
 908                        default-directory)))
 909             (if (file-exists-p (concat dir name))
 910                 (setq name (concat dir name))
 911               (error "No such include file: `%s'" name))))
 912         (setq new-buf (get-file-buffer name))
 913         (if new-buf
 914             ;; no need to verify last-modified time for this!
 915             (set-buffer new-buf)
 916           (set-buffer (create-file-buffer name))
 917           (erase-buffer)
 918           (insert-file-contents name t))
 919         ;; Returning non-nil with the new buffer current
 920         ;; is sufficient to tell find-file to use it.
 921         t)
 922     nil))
 923
 924 (defun PC-include-file-path ()
 925   (or PC-include-file-path
 926       (let ((env (getenv "INCPATH"))
 927             (path nil)
 928             pos)
 929         (or env (error "No include file path specified"))
 930         (while (setq pos (string-match ":[^:]+$" env))
 931           (setq path (cons (substring env (1+ pos)) path)
 932                 env (substring env 0 pos)))
 933         path)))
 934
 935 ;; This is adapted from lib-complete.el, by Mike Williams.
 936 (defun PC-include-file-all-completions (file search-path &optional full)
 937   "Return all completions for FILE in any directory on SEARCH-PATH.
 938 If optional third argument FULL is non-nil, returned pathnames should be
 939 absolute rather than relative to some directory on the SEARCH-PATH."
 940   (setq search-path
 941         (mapcar (lambda (dir)
 942                   (if dir (file-name-as-directory dir) default-directory))
 943                 search-path))
 944   (if (file-name-absolute-p file)
 945       ;; It's an absolute file name, so don't need search-path
 946       (progn
 947         (setq file (expand-file-name file))
 948         (file-name-all-completions
 949          (file-name-nondirectory file) (file-name-directory file)))
 950     (let ((subdir (file-name-directory file))
 951           (ndfile (file-name-nondirectory file))
 952           file-lists)
 953       ;; Append subdirectory part to each element of search-path
 954       (if subdir
 955           (setq search-path
 956                 (mapcar (lambda (dir) (concat dir subdir))
 957                         search-path)
 958                 file ))
 959       ;; Make list of completions in each directory on search-path
 960       (while search-path
 961         (let* ((dir (car search-path))
 962                (subdir (if full dir subdir)))
 963           (if (file-directory-p dir)
 964               (progn
 965                 (setq file-lists
 966                       (cons
 967                        (mapcar (lambda (file) (concat subdir file))
 968                                (file-name-all-completions ndfile
 969                                                           (car search-path)))
 970                        file-lists))))
 971           (setq search-path (cdr search-path))))
 972       ;; Compress out duplicates while building complete list (slloooow!)
 973       (let ((sorted (sort (apply 'nconc file-lists)
 974                           (lambda (x y) (not (string-lessp x y)))))
 975             compressed)
 976         (while sorted
 977           (if (equal (car sorted) (car compressed)) nil
 978             (setq compressed (cons (car sorted) compressed)))
 979           (setq sorted (cdr sorted)))
 980         compressed))))
 981
 982 (defadvice read-file-name-internal (around PC-include-file disable)
 983   (if (string-match "<\\([^\"<>]*\\)>?\\'" (ad-get-arg 0))
 984       (let* ((string (ad-get-arg 0))
 985              (action (ad-get-arg 2))
 986              (name (substring string (match-beginning 1) (match-end 1)))
 987              (str2 (substring string (match-beginning 0)))
 988              (completion-table
 989               (mapcar (lambda (x) (format "<%s>" x))
 990                       (PC-include-file-all-completions
 991                        name (PC-include-file-path)))))
 992         (setq ad-return-value
 993               (cond
 994                ((not completion-table) nil)
 995                ((eq action 'lambda) (test-completion str2 completion-table nil))
 996                ((eq action nil) (try-completion str2 completion-table nil))
 997                ((eq action t) (all-completions str2 completion-table nil)))))
 998     ad-do-it))
 999 \f
1000
1001 (provide 'complete)
1002
1003 ;; arch-tag: fc7e2768-ff44-4e22-b579-4d825b968458
1004 ;;; complete.el ends here