configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 ## For the times when you want to build Emacs but don't have
 181 ## a suitable makeinfo, and can live without the manuals.
 182 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 183 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 184
 185 ## Makefile.in needs the cache file name.
 186 AC_SUBST(cache_file)
 187
 188 ## This is an option because I do not know if all info/man support
 189 ## compressed files, nor how to test if they do so.
 190 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 191 if test $with_compress_info = yes; then
 192    GZIP_INFO=yes
 193 else
 194    GZIP_INFO=
 195 fi
 196 AC_SUBST(GZIP_INFO)
 197
 198 AC_ARG_WITH([pkg-config-prog],dnl
 199 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 200                   [path to pkg-config for finding GTK and librsvg])])
 201 if test "X${with_pkg_config_prog}" != X; then
 202    if test "${with_pkg_config_prog}" != yes; then
 203       PKG_CONFIG="${with_pkg_config_prog}"
 204    fi
 205 fi
 206
 207 CRT_DIR=
 208 AC_ARG_WITH([crt-dir],dnl
 209 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 210 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 211 CRT_DIR="${with_crt_dir}"
 212
 213 AC_ARG_WITH(gameuser,dnl
 214 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 215 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 216   && gameuser="${with_gameuser}"
 217 test "X$gameuser" = X && gameuser=games
 218
 219 AC_ARG_WITH([gnustep-conf],dnl
 220 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 221 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 222   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 223 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 224      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 225
 226 AC_ARG_ENABLE(ns-self-contained,
 227 [AS_HELP_STRING([--disable-ns-self-contained],
 228                 [disable self contained build under NeXTstep])],
 229    EN_NS_SELF_CONTAINED=$enableval,
 230    EN_NS_SELF_CONTAINED=yes)
 231
 232 AC_ARG_ENABLE(asserts,
 233 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 234       USE_XASSERTS=$enableval,
 235       USE_XASSERTS=no)
 236
 237 AC_ARG_ENABLE(maintainer-mode,
 238 [AS_HELP_STRING([--disable-maintainer-mode],
 239                 [disable make rules and dependencies not useful (and sometimes
 240                  confusing) to the casual installer])],
 241       USE_MAINTAINER_MODE=$enableval,
 242       USE_MAINTAINER_MODE=yes)
 243 if test $USE_MAINTAINER_MODE = yes; then
 244   MAINT=
 245 else
 246   MAINT=#
 247 fi
 248 AC_SUBST(MAINT)
 249
 250 AC_ARG_ENABLE(locallisppath,
 251 [AS_HELP_STRING([--enable-locallisppath=PATH],
 252                 [directories Emacs should search for lisp files specific
 253                  to this site])],
 254 if test "${enableval}" = "no"; then
 255   locallisppath=
 256 elif test "${enableval}" != "yes"; then
 257   locallisppath=${enableval}
 258 fi)
 259
 260 AC_ARG_ENABLE(checking,
 261 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 262                 [enable expensive run-time checks.  With LIST,
 263                  enable only specific categories of checks.
 264                  Categories are: all,yes,no.
 265                  Flags are: stringbytes, stringoverrun, stringfreelist,
 266                  xmallocoverrun, conslist])],
 267 [ac_checking_flags="${enableval}"],[])
 268 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 269 for check in $ac_checking_flags
 270 do
 271         case $check in
 272         # these set all the flags to specific states
 273         yes)            ac_enable_checking=1 ;;
 274         no)             ac_enable_checking= ;
 275                         ac_gc_check_stringbytes= ;
 276                         ac_gc_check_string_overrun= ;
 277                         ac_gc_check_string_free_list= ;
 278                         ac_xmalloc_overrun= ;
 279                         ac_gc_check_cons_list= ;;
 280         all)            ac_enable_checking=1 ;
 281                         ac_gc_check_stringbytes=1 ;
 282                         ac_gc_check_string_overrun=1 ;
 283                         ac_gc_check_string_free_list=1 ;
 284                         ac_xmalloc_overrun=1 ;
 285                         ac_gc_check_cons_list=1 ;;
 286         # these enable particular checks
 287         stringbytes)    ac_gc_check_stringbytes=1 ;;
 288         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 289         stringfreelist) ac_gc_check_string_free_list=1 ;;
 290         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 291         conslist)       ac_gc_check_cons_list=1 ;;
 292         *)      AC_MSG_ERROR(unknown check category $check) ;;
 293         esac
 294 done
 295 IFS="$ac_save_IFS"
 296
 297 if test x$ac_enable_checking != x ; then
 298   AC_DEFINE(ENABLE_CHECKING, 1,
 299 [Enable expensive run-time checking of data types?])
 300 fi
 301 if test x$ac_gc_check_stringbytes != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 303 [Define this temporarily to hunt a bug.  If defined, the size of
 304    strings is redundantly recorded in sdata structures so that it can
 305    be compared to the sizes recorded in Lisp strings.])
 306 fi
 307 if test x$ac_gc_check_string_overrun != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 309 [Define this to check for short string overrun.])
 310 fi
 311 if test x$ac_gc_check_string_free_list != x ; then
 312   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 313 [Define this to check the string free list.])
 314 fi
 315 if test x$ac_xmalloc_overrun != x ; then
 316   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 317 [Define this to check for malloc buffer overrun.])
 318 fi
 319 if test x$ac_gc_check_cons_list != x ; then
 320   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 321 [Define this to check for errors in cons list.])
 322 fi
 323
 324 AC_ARG_ENABLE(use-lisp-union-type,
 325 [AS_HELP_STRING([--enable-use-lisp-union-type],
 326                 [use a union for the Lisp_Object data type.
 327                 This is only useful for development for catching certain types of bugs.])],
 328 if test "${enableval}" != "no"; then
 329    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 330    [Define this to use a lisp union for the Lisp_Object data type.])
 331 fi)
 332
 333
 334 AC_ARG_ENABLE(profiling,
 335 [AS_HELP_STRING([--enable-profiling],
 336                 [build emacs with profiling support.
 337                  This might not work on all platforms])],
 338 [ac_enable_profiling="${enableval}"],[])
 339 if test x$ac_enable_profiling != x ; then
 340    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 341 else
 342    PROFILING_CFLAGS=
 343 fi
 344 AC_SUBST(PROFILING_CFLAGS)
 345
 346 AC_ARG_ENABLE(autodepend,
 347 [AS_HELP_STRING([--enable-autodepend],
 348                 [automatically generate dependencies to .h-files.
 349                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 350                  found])],
 351 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 352
 353 #### Make srcdir absolute, if it isn't already.  It's important to
 354 #### avoid running the path through pwd unnecessarily, since pwd can
 355 #### give you automounter prefixes, which can go away.  We do all this
 356 #### so Emacs can find its files when run uninstalled.
 357 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 358 unset CDPATH
 359 case "${srcdir}" in
 360   /* ) ;;
 361   . )
 362     ## We may be able to use the $PWD environment variable to make this
 363     ## absolute.  But sometimes PWD is inaccurate.
 364     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 365     ## but that tested only for a well-formed and valid PWD,
 366     ## it did not object when PWD was well-formed and valid but just wrong.
 367     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 368     then
 369       srcdir="$PWD"
 370     else
 371       srcdir="`(cd ${srcdir}; pwd)`"
 372     fi
 373   ;;
 374   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 375 esac
 376
 377 #### Given the configuration name, set machfile and opsysfile to the
 378 #### names of the m/*.h and s/*.h files we should use.
 379
 380 ### Canonicalize the configuration name.
 381
 382 AC_CANONICAL_HOST
 383 canonical=$host
 384 configuration=${host_alias-${build_alias-$host}}
 385
 386 dnl This used to use changequote, but, apart from `changequote is evil'
 387 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 388 dnl the great gob of text.  Thus it's not processed for possible expansion.
 389 dnl Just make sure the brackets remain balanced.
 390 dnl
 391 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 392 dnl indicated by comments.
 393 dnl quotation begins
 394 [
 395
 396 ### If you add support for a new configuration, add code to this
 397 ### switch statement to recognize your configuration name and select
 398 ### the appropriate operating system and machine description files.
 399
 400 ### You would hope that you could choose an m/*.h file pretty much
 401 ### based on the machine portion of the configuration name, and an s/*.h
 402 ### file based on the operating system portion.  However, it turns out
 403 ### that each m/*.h file is pretty manufacturer-specific - for
 404 ### example mips.h is MIPS
 405 ### So we basically have to have a special case for each
 406 ### configuration name.
 407 ###
 408 ### As far as handling version numbers on operating systems is
 409 ### concerned, make sure things will fail in a fixable way.  If
 410 ### /etc/MACHINES doesn't say anything about version numbers, be
 411 ### prepared to handle anything reasonably.  If version numbers
 412 ### matter, be sure /etc/MACHINES says something about it.
 413
 414 machine='' opsys='' unported=no
 415 case "${canonical}" in
 416
 417   ## GNU/Linux and similar ports
 418   *-*-linux* )
 419     opsys=gnu-linux
 420     case ${canonical} in
 421       alpha*)   machine=alpha ;;
 422       s390x-*)  machine=ibms390x ;;
 423       powerpc*) machine=macppc ;;
 424       sparc*)   machine=sparc ;;
 425       ia64*)    machine=ia64 ;;
 426       m68k*)    machine=m68k ;;
 427       x86_64*)  machine=amdx86-64 ;;
 428     esac
 429   ;;
 430
 431   ## FreeBSD ports
 432   *-*-freebsd* )
 433     opsys=freebsd
 434     case "${canonical}" in
 435       alpha*)           machine=alpha ;;
 436       amd64-*|x86_64-*) machine=amdx86-64 ;;
 437       ia64-*)           machine=ia64 ;;
 438       i[3456]86-*)      machine=intel386 ;;
 439       powerpc-*)        machine=macppc ;;
 440       sparc-*)          machine=sparc ;;
 441       sparc64-*)        machine=sparc ;;
 442     esac
 443   ;;
 444
 445   ## FreeBSD kernel + glibc based userland
 446   *-*-kfreebsd*gnu* )
 447     opsys=gnu-kfreebsd
 448     case "${canonical}" in
 449       alpha*)           machine=alpha ;;
 450       amd64-*|x86_64-*) machine=amdx86-64 ;;
 451       ia64-*)           machine=ia64 ;;
 452       i[3456]86-*)      machine=intel386 ;;
 453       powerpc-*)        machine=macppc ;;
 454       sparc-*)          machine=sparc ;;
 455       sparc64-*)        machine=sparc ;;
 456     esac
 457   ;;
 458
 459   ## NetBSD ports
 460   *-*-netbsd* )
 461     opsys=netbsd
 462     case "${canonical}" in
 463       alpha*)      machine=alpha ;;
 464       x86_64-*)    machine=amdx86-64 ;;
 465       i[3456]86-*) machine=intel386 ;;
 466       m68k-*)      machine=m68k ;;
 467       powerpc-*)   machine=macppc ;;
 468       sparc*-)     machine=sparc ;;
 469       vax-*)       machine=vax ;;
 470     esac
 471   ;;
 472
 473   ## OpenBSD ports
 474   *-*-openbsd* )
 475     opsys=openbsd
 476     case "${canonical}" in
 477       alpha*)    machine=alpha ;;
 478       x86_64-*)  machine=amdx86-64 ;;
 479       i386-*)    machine=intel386 ;;
 480       powerpc-*) machine=macppc ;;
 481       sparc*)    machine=sparc ;;
 482       vax-*)     machine=vax ;;
 483     esac
 484   ;;
 485
 486   ## Apple Darwin / Mac OS X
 487   *-apple-darwin* )
 488     case "${canonical}" in
 489       i[3456]86-* )  machine=intel386 ;;
 490       powerpc-* )    machine=macppc ;;
 491       x86_64-* )     machine=amdx86-64 ;;
 492       * )            unported=yes ;;
 493     esac
 494     opsys=darwin
 495     # Define CPP as follows to make autoconf work correctly.
 496     CPP="${CC-cc} -E -no-cpp-precomp"
 497     # Use fink packages if available.
 498     if test -d /sw/include && test -d /sw/lib; then
 499       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 500       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 501       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 502     fi
 503   ;;
 504
 505   ## HP 9000 series 700 and 800, running HP/UX
 506   hppa*-hp-hpux10.2* )
 507     opsys=hpux10-20
 508   ;;
 509   hppa*-hp-hpux1[1-9]* )
 510     opsys=hpux11
 511     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 512   ;;
 513
 514   ## IBM machines
 515   rs6000-ibm-aix4.[23]* )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   powerpc-ibm-aix4.[23]*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   rs6000-ibm-aix[56]* )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524   powerpc-ibm-aix[56]*  )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527
 528   ## Silicon Graphics machines
 529   ## Iris 4D
 530   mips-sgi-irix6.5 )
 531     opsys=irix6-5
 532     # Without defining _LANGUAGE_C, things get masked out in the headers
 533     # so that, for instance, grepping for `free' in stdlib.h fails and
 534     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 535     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 536     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 537   ;;
 538
 539   ## Suns
 540   *-sun-solaris* \
 541     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 542     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 543     case "${canonical}" in
 544       i[3456]86-*-* )     machine=intel386 ;;
 545       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 546       sparc* )          machine=sparc ;;
 547       * )               unported=yes ;;
 548     esac
 549     case "${canonical}" in
 550       *-sunos5.6* | *-solaris2.6* )
 551                 opsys=sol2-6
 552                 NON_GNU_CPP=/usr/ccs/lib/cpp
 553                 RANLIB="ar -ts"
 554                 ;;
 555       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 556                 opsys=sol2-6
 557                 emacs_check_sunpro_c=yes
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 ;;
 560       *-sunos5* | *-solaris* )
 561                 opsys=sol2-10
 562                 emacs_check_sunpro_c=yes
 563                 NON_GNU_CPP=/usr/ccs/lib/cpp
 564                 ;;
 565     esac
 566     ## Watch out for a compiler that we know will not work.
 567     case "${canonical}" in
 568      *-solaris* | *-sunos5* )
 569                 if [ "x$CC" = x/usr/ucb/cc ]; then
 570                   ## /usr/ucb/cc doesn't work;
 571                   ## we should find some other compiler that does work.
 572                   unset CC
 573                 fi
 574                 ;;
 575       *) ;;
 576     esac
 577   ;;
 578
 579   ## Intel 386 machines where we don't care about the manufacturer.
 580   i[3456]86-*-* )
 581     machine=intel386
 582     case "${canonical}" in
 583       *-cygwin )                opsys=cygwin ;;
 584       *-darwin* )               opsys=darwin
 585                                 CPP="${CC-cc} -E -no-cpp-precomp"
 586                                 ;;
 587       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 588       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 589       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 591     esac
 592   ;;
 593
 594   * )
 595     unported=yes
 596   ;;
 597 esac
 598
 599 ### If the code above didn't choose an operating system, just choose
 600 ### an operating system based on the configuration name.  You really
 601 ### only want to use this when you have no idea what the right
 602 ### operating system is; if you know what operating systems a machine
 603 ### runs, it's cleaner to make it explicit in the case statement
 604 ### above.
 605 if test x"${opsys}" = x; then
 606   case "${canonical}" in
 607     *-gnu* )                            opsys=gnu ;;
 608     * )
 609       unported=yes
 610     ;;
 611   esac
 612 fi
 613
 614 ]
 615 dnl quotation ends
 616
 617 if test $unported = yes; then
 618   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 619 Check `etc/MACHINES' for recognized configuration names.])
 620 fi
 621
 622 if test -n "$machine"; then
 623   machfile="m/${machine}.h"
 624 else
 625   machfile=
 626 fi
 627 opsysfile="s/${opsys}.h"
 628
 629
 630 #### Choose a compiler.
 631 test -n "$CC" && cc_specified=yes
 632
 633 # Save the value of CFLAGS that the user specified.
 634 SPECIFIED_CFLAGS="$CFLAGS"
 635
 636 dnl Sets GCC=yes if using gcc.
 637 AC_PROG_CC
 638 AM_PROG_CC_C_O
 639
 640 # Initialize gnulib right after verifying that the C compiler works.
 641 gl_EARLY
 642
 643 # On Suns, sometimes $CPP names a directory.
 644 if test -n "$CPP" && test -d "$CPP"; then
 645   CPP=
 646 fi
 647
 648 ## If not using gcc, and on Solaris, and no CPP specified, see if
 649 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 650 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 651  test x"$CPP" = x; then
 652   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 653   AC_CACHE_VAL(emacs_cv_sunpro_c,
 654   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 655 [[#ifndef __SUNPRO_C
 656 fail;
 657 #endif
 658 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 659   AC_MSG_RESULT($emacs_cv_sunpro_c)
 660
 661   if test x"$emacs_cv_sunpro_c" = xyes; then
 662     NON_GNU_CPP="$CC -E -Xs"
 663   fi
 664 fi
 665
 666 #### Some systems specify a CPP to use unless we are using GCC.
 667 #### Now that we know whether we are using GCC, we can decide whether
 668 #### to use that one.
 669 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 670 then
 671   CPP="$NON_GNU_CPP"
 672 fi
 673
 674 #### Some systems specify a CC to use unless we are using GCC.
 675 #### Now that we know whether we are using GCC, we can decide whether
 676 #### to use that one.
 677 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 678   test x$cc_specified != xyes
 679 then
 680   CC="$NON_GNU_CC"
 681 fi
 682
 683 if test x$GCC = xyes; then
 684   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 685 else
 686   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 687 fi
 688
 689 AC_ARG_ENABLE([gcc-warnings],
 690   [AS_HELP_STRING([--enable-gcc-warnings],
 691                   [turn on lots of GCC warnings (for developers)])],
 692   [case $enableval in
 693      yes|no) ;;
 694      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 695    esac
 696    gl_gcc_warnings=$enableval],
 697   [gl_gcc_warnings=no]
 698 )
 699
 700 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 701 # ------------------------------------------------
 702 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 703 # Otherwise, run RUN-IF-NOT-FOUND.
 704 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 705   [AC_PREPROC_IFELSE(
 706     [AC_LANG_PROGRAM(
 707       [[
 708 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 709 /* ok */
 710 #else
 711 # error "your version of gcc is older than $1.$2"
 712 #endif
 713       ]]),
 714     ], [$3], [$4])
 715   ]
 716 )
 717
 718 # When compiling with GCC, prefer -isystem to -I when including system
 719 # include files, to avoid generating useless diagnostics for the files.
 720 if test "$gl_gcc_warnings" != yes; then
 721   isystem='-I'
 722 else
 723   isystem='-isystem '
 724
 725   # This, $nw, is the list of warnings we disable.
 726   nw=
 727
 728   case $with_x_toolkit in
 729     lucid | athena | motif)
 730        # Old toolkits mishandle 'const'.
 731        nw="$nw -Wwrite-strings"
 732        ;;
 733     *)
 734        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 735        ;;
 736   esac
 737   AC_SUBST([WERROR_CFLAGS])
 738
 739   nw="$nw -Waggregate-return"       # anachronistic
 740   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
 741   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 742   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 743   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 744   nw="$nw -Wcast-qual"              # Too many warnings for now
 745   nw="$nw -Wconversion"             # Too many warnings for now
 746   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 747   nw="$nw -Wsign-conversion"        # Too many warnings for now
 748   nw="$nw -Woverlength-strings"     # Not a problem these days
 749   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 750   nw="$nw -Wpadded"                 # Our structs are not padded
 751   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 752   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 753   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 754   nw="$nw -Wvla"                    # warnings in gettext.h
 755   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 756   nw="$nw -Wswitch-enum"            # Too many warnings for now
 757   nw="$nw -Wswitch-default"         # Too many warnings for now
 758   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 759   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 760
 761   # Emacs doesn't care about shadowing; see
 762   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 763   nw="$nw -Wshadow"
 764
 765   # The following lines should be removable at some point.
 766   nw="$nw -Wstack-protector"
 767   nw="$nw -Wstrict-overflow"
 768   nw="$nw -Wsuggest-attribute=const"
 769   nw="$nw -Wsuggest-attribute=pure"
 770
 771   gl_MANYWARN_ALL_GCC([ws])
 772   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 773   for w in $ws; do
 774     gl_WARN_ADD([$w])
 775   done
 776   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 777   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 778   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 779   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 780   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 781   gl_WARN_ADD([-Wno-format-nonliteral])
 782
 783   # In spite of excluding -Wlogical-op above, it is enabled, as of
 784   # gcc 4.5.0 20090517.
 785   gl_WARN_ADD([-Wno-logical-op])
 786
 787   gl_WARN_ADD([-fdiagnostics-show-option])
 788   gl_WARN_ADD([-funit-at-a-time])
 789
 790   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 791   AC_DEFINE([_FORTIFY_SOURCE], [2],
 792     [enable compile-time and run-time bounds-checking, and some warnings])
 793   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 794
 795   # We use a slightly smaller set of warning options for lib/.
 796   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 797   nw=
 798   nw="$nw -Wunused-macros"
 799
 800   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 801   AC_SUBST([GNULIB_WARN_CFLAGS])
 802 fi
 803
 804
 805
 806 #### Some other nice autoconf tests.
 807
 808 dnl checks for programs
 809 AC_PROG_CPP
 810 AC_PROG_INSTALL
 811 if test "x$RANLIB" = x; then
 812   AC_PROG_RANLIB
 813 fi
 814
 815 ## Although we're running on an amd64 kernel, we're actually compiling for
 816 ## the x86 architecture.  The user should probably have provided an
 817 ## explicit --build to `configure', but if everything else than the kernel
 818 ## is running in i386 mode, we can help them out.
 819 if test "$machine" = "amdx86-64"; then
 820   AC_CHECK_DECL([i386])
 821   if test "$ac_cv_have_decl_i386" = "yes"; then
 822     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 823     machine=intel386
 824     machfile="m/${machine}.h"
 825   fi
 826 fi
 827
 828 AC_PATH_PROG(INSTALL_INFO, install-info)
 829 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 830 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 831 dnl Don't use GZIP, which is used by gzip for additional parameters.
 832 AC_PATH_PROG(GZIP_PROG, gzip)
 833
 834
 835 ## Need makeinfo >= 4.7 (?) to build the manuals.
 836 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 837 dnl By this stage, configure has already checked for egrep and set EGREP,
 838 dnl or exited with an error if no egrep was found.
 839 if test "$MAKEINFO" != "no" && \
 840   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 841    MAKEINFO=no
 842 fi
 843
 844 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 845 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 846 ## therefore in the category of "special tools" not normally required, which
 847 ## configure does not have to check for (eg autoconf itself).
 848 ## In a Bazaar checkout on the other hand, the manuals are not included.
 849 ## So makeinfo is a requirement to build from Bazaar, and configure
 850 ## should test for it as it does for any other build requirement.
 851 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 852 ## with pre-built manuals, from a Bazaar checkout.
 853 HAVE_MAKEINFO=yes
 854
 855 if test "$MAKEINFO" = "no"; then
 856   MAKEINFO=makeinfo
 857   if test "x${with_makeinfo}" = "xno"; then
 858     HAVE_MAKEINFO=no
 859   elif test ! -e $srcdir/info/emacs; then
 860     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 861 source tree does not seem to have pre-built manuals in the `info' directory.
 862 Either install a suitable version of makeinfo, or re-run configure
 863 with the `--without-makeinfo' option to build without the manuals.] )
 864   fi
 865 fi
 866 AC_SUBST(HAVE_MAKEINFO)
 867
 868 dnl Add our options to ac_link now, after it is set up.
 869
 870 if test x$GCC = xyes; then
 871   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 872     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 873 else
 874   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 875     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 876 fi
 877
 878 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 879 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 880 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 881 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 882 dnl if not built to support GNU ld.
 883
 884 late_LDFLAGS=$LDFLAGS
 885 if test x$GCC = xyes; then
 886   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 887 else
 888   LDFLAGS="$LDFLAGS -znocombreloc"
 889 fi
 890
 891 AC_MSG_CHECKING([for -znocombreloc])
 892 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 893   [AC_MSG_RESULT(yes)],
 894   LDFLAGS=$late_LDFLAGS
 895   [AC_MSG_RESULT(no)])
 896
 897
 898 # The value of CPP is a quoted variable reference, so we need to do this
 899 # to get its actual value...
 900 CPP=`eval "echo $CPP"`
 901
 902
 903 dnl The function dump-emacs will not be defined and temacs will do
 904 dnl (load "loadup") automatically unless told otherwise.
 905 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 906 case "$opsys" in
 907   your-opsys-here) CANNOT_DUMP=yes ;;
 908 esac
 909
 910 test "$CANNOT_DUMP" = "yes" && \
 911   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 912
 913 AC_SUBST(CANNOT_DUMP)
 914
 915
 916 UNEXEC_OBJ=unexelf.o
 917 case "$opsys" in
 918   # MSDOS uses unexcoff.o
 919   # MSWindows uses unexw32.o
 920   aix4-2)
 921    UNEXEC_OBJ=unexaix.o
 922    ;;
 923   cygwin)
 924    UNEXEC_OBJ=unexcw.o
 925    ;;
 926   darwin)
 927    UNEXEC_OBJ=unexmacosx.o
 928    ;;
 929   hpux10-20 | hpux11)
 930    UNEXEC_OBJ=unexhp9k800.o
 931    ;;
 932   sol2-10)
 933    # Use the Solaris dldump() function, called from unexsol.c, to dump
 934    # emacs, instead of the generic ELF dump code found in unexelf.c.
 935    # The resulting binary has a complete symbol table, and is better
 936    # for debugging and other observability tools (debuggers, pstack, etc).
 937    #
 938    # If you encounter a problem using dldump(), please consider sending
 939    # a message to the OpenSolaris tools-linking mailing list:
 940    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 941    #
 942    # It is likely that dldump() works with older Solaris too, but this has
 943    # not been tested, so for now this change is for Solaris 10 or newer.
 944    UNEXEC_OBJ=unexsol.o
 945    ;;
 946 esac
 947
 948 LD_SWITCH_SYSTEM=
 949 case "$opsys" in
 950   freebsd)
 951    ## Let `ld' find image libs and similar things in /usr/local/lib.
 952    ## The system compiler, GCC, has apparently been modified to not
 953    ## look there, contrary to what a stock GCC would do.
 954    LD_SWITCH_SYSTEM=-L/usr/local/lib
 955    ;;
 956
 957   gnu-linux)
 958    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 959    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 960    ;;
 961
 962   netbsd)
 963    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 964    ;;
 965
 966   openbsd)
 967    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 968    ## otherwise Emacs dumps core on elf systems.
 969    LD_SWITCH_SYSTEM="-Z"
 970    ;;
 971 esac
 972 AC_SUBST(LD_SWITCH_SYSTEM)
 973
 974 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 975
 976 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 977 ## which has not been defined yet.  When this was handled with cpp,
 978 ## it was expanded to null when configure sourced the s/*.h file.
 979 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 980 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 981 ## (or somesuch), but because it is supposed to go at the _front_
 982 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 983 ## Compare with the gnu-linux case below, which added to the end
 984 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 985 ## LD_SWITCH_SYSTEM_TEMACS.
 986 case "$opsys" in
 987   netbsd|openbsd)
 988    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 989    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 990 esac
 991
 992
 993 C_SWITCH_MACHINE=
 994 if test "$machine" = "alpha"; then
 995   AC_CHECK_DECL([__ELF__])
 996   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 997     ## With ELF, make sure that all common symbols get allocated to in the
 998     ## data section.  Otherwise, the dump of temacs may miss variables in
 999     ## the shared library that have been initialized.  For example, with
1000     ## GNU libc, __malloc_initialized would normally be resolved to the
1001     ## shared library's .bss section, which is fatal.
1002     if test "x$GCC" = "xyes"; then
1003       C_SWITCH_MACHINE="-fno-common"
1004     else
1005       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1006     fi
1007   else
1008     UNEXEC_OBJ=unexalpha.o
1009   fi
1010 fi
1011 AC_SUBST(C_SWITCH_MACHINE)
1012
1013 AC_SUBST(UNEXEC_OBJ)
1014
1015 C_SWITCH_SYSTEM=
1016 ## Some programs in src produce warnings saying certain subprograms
1017 ## are too complex and need a MAXMEM value greater than 2000 for
1018 ## additional optimization.  --nils@exp-math.uni-essen.de
1019 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1020   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1021 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1022 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1023 AC_SUBST(C_SWITCH_SYSTEM)
1024
1025
1026 LIBS_SYSTEM=
1027 case "$opsys" in
1028   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1029   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1030
1031   freebsd) LIBS_SYSTEM="-lutil" ;;
1032
1033   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1034
1035   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1036
1037   ## Motif needs -lgen.
1038   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1039 esac
1040 AC_SUBST(LIBS_SYSTEM)
1041
1042
1043 ### Make sure subsequent tests use flags consistent with the build flags.
1044
1045 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1046   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1047 else
1048   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1049 fi
1050
1051 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1052 AC_DEFUN([AC_TYPE_SIZE_T])
1053 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1054 AC_DEFUN([AC_TYPE_UID_T])
1055
1056 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1057 AC_SYS_LARGEFILE
1058
1059
1060 LIB_MATH=-lm
1061 LIB_STANDARD=
1062 START_FILES=
1063
1064 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1065 case $opsys in
1066   cygwin )
1067     LIB_MATH=
1068     START_FILES='pre-crt0.o'
1069     ;;
1070   darwin )
1071     ## Adding -lm confuses the dynamic linker, so omit it.
1072     LIB_MATH=
1073     START_FILES='pre-crt0.o'
1074     ;;
1075   freebsd )
1076     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1077     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1078     ;;
1079   gnu-linux | gnu-kfreebsd )
1080     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1081     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1082     ;;
1083   hpux10-20 | hpux11 )
1084     LIB_STANDARD=-lc
1085     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1086     ;;
1087   dnl NB this may be adjusted below.
1088   netbsd | openbsd )
1089     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1090     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1091     ;;
1092 esac
1093
1094 AC_SUBST(LIB_MATH)
1095 AC_SUBST(START_FILES)
1096
1097 dnl Not all platforms use crtn.o files.  Check if the current one does.
1098 crt_files=
1099
1100 for file in x $LIB_STANDARD $START_FILES; do
1101   case "$file" in
1102     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1103   esac
1104 done
1105
1106 if test "x$crt_files" != x; then
1107
1108   ## If user specified a crt-dir, use that unconditionally.
1109   crt_gcc=no
1110
1111   if test "X$CRT_DIR" = "X"; then
1112
1113     CRT_DIR=/usr/lib            # default
1114
1115     case "$canonical" in
1116       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1117       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1118       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1119       ## For anything else (eg /usr/lib32), it is up the user to specify
1120       ## the location (bug#5655).
1121       ## Test for crtn.o, not just the directory, because sometimes the
1122       ## directory exists but does not have the relevant files (bug#1287).
1123       ## FIXME better to test for binary compatibility somehow.
1124       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1125       ;;
1126
1127       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1128     esac
1129
1130     case "$opsys" in
1131       hpux10-20) CRT_DIR=/lib ;;
1132     esac
1133
1134     test "x${GCC}" = xyes && crt_gcc=yes
1135
1136   fi                            # CRT_DIR = ""
1137
1138   crt_missing=
1139
1140   for file in $crt_files; do
1141
1142     ## If we're using gcc, try to determine it automatically by asking
1143     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1144     ## system-dependent default from above.]
1145     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1146
1147        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1148        case "$crt_file" in
1149          */*)
1150            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1151            ;;
1152        esac
1153     fi
1154
1155     dnl We expect all the files to be in a single directory, so after the
1156     dnl first there is no point asking gcc.
1157     crt_gcc=no
1158
1159     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1160   done                          # $crt_files
1161
1162   test "x$crt_missing" = x || \
1163     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1164 Try using the --with-crt-dir option.])
1165
1166 fi                              # crt_files != ""
1167
1168 AC_SUBST(CRT_DIR)
1169
1170 case $opsys in
1171   netbsd | openbsd )
1172     if test -f $CRT_DIR/crti.o; then
1173
1174         test -f $CRT_DIR/crtn.o || \
1175           AC_MSG_ERROR([Required file not found: crtn.o])
1176
1177         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1178         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1179     fi
1180     ;;
1181 esac
1182
1183
1184 dnl This function definition taken from Gnome 2.0
1185 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1186 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1187 dnl also defines GSTUFF_PKG_ERRORS on error
1188 AC_DEFUN([PKG_CHECK_MODULES], [
1189   succeeded=no
1190
1191   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1192
1193   if test "$PKG_CONFIG" = "no" ; then
1194      ifelse([$4], , [AC_MSG_ERROR([
1195       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1196   else
1197      PKG_CONFIG_MIN_VERSION=0.9.0
1198      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1199         AC_MSG_CHECKING(for $2)
1200
1201         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1202            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1203            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1204             edit_cflags="
1205               s,///*,/,g
1206               s/^/ /
1207               s/ -I/ $isystem/g
1208               s/^ //
1209             "
1210             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1211             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1212             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1213             succeeded=yes
1214         else
1215             AC_MSG_RESULT(no)
1216             $1_CFLAGS=""
1217             $1_LIBS=""
1218             ## If we have a custom action on failure, don't print errors, but
1219             ## do set a variable so people can do so.
1220             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1221             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1222         fi
1223
1224         AC_SUBST($1_CFLAGS)
1225         AC_SUBST($1_LIBS)
1226      else
1227         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1228         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1229      fi
1230   fi
1231
1232   if test $succeeded = yes; then
1233      ifelse([$3], , :, [$3])
1234   else
1235      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1236   fi
1237 ])
1238
1239
1240 if test "${with_sound}" != "no"; then
1241   # Sound support for GNU/Linux and the free BSDs.
1242   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1243     have_sound_header=yes)
1244   # Emulation library used on NetBSD.
1245   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1246   AC_SUBST(LIBSOUND)
1247
1248   ALSA_REQUIRED=1.0.0
1249   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1250   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1251   if test $HAVE_ALSA = yes; then
1252     SAVE_CFLAGS="$CFLAGS"
1253     SAVE_LIBS="$LIBS"
1254     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1255     LIBS="$ALSA_LIBS $LIBS"
1256     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1257                     emacs_alsa_normal=yes,
1258                     emacs_alsa_normal=no)
1259     if test "$emacs_alsa_normal" != yes; then
1260       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1261                      [[snd_lib_error_set_handler (0);]])],
1262                      emacs_alsa_subdir=yes,
1263                      emacs_alsa_subdir=no)
1264       if test "$emacs_alsa_subdir" != yes; then
1265         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1266       fi
1267       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1268     fi
1269
1270     CFLAGS="$SAVE_CFLAGS"
1271     LIBS="$SAVE_LIBS"
1272     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1273     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1274     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1275   fi
1276
1277   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1278   dnl compiles only on the specified platforms.  For others, it
1279   dnl probably doesn't make sense to try.
1280   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1281      case "$opsys" in
1282        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1283        gnu-linux|freebsd|netbsd)
1284          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1285          ;;
1286      esac
1287   fi
1288
1289   AC_SUBST(CFLAGS_SOUND)
1290 fi
1291
1292 dnl checks for header files
1293 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1294   linux/version.h sys/systeminfo.h \
1295   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1296   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1297   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1298
1299 AC_MSG_CHECKING(if personality LINUX32 can be set)
1300 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1301                emacs_cv_personality_linux32=yes,
1302                emacs_cv_personality_linux32=no)
1303 AC_MSG_RESULT($emacs_cv_personality_linux32)
1304
1305 if test $emacs_cv_personality_linux32 = yes; then
1306   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1307             [Define to 1 if personality LINUX32 can be set.])
1308 fi
1309
1310 dnl On Solaris 8 there's a compilation warning for term.h because
1311 dnl it doesn't define `bool'.
1312 AC_CHECK_HEADERS(term.h, , , -)
1313 AC_HEADER_TIME
1314 AC_CHECK_DECLS([sys_siglist])
1315 if test $ac_cv_have_decl_sys_siglist != yes; then
1316   # For Tru64, at least:
1317   AC_CHECK_DECLS([__sys_siglist])
1318   if test $ac_cv_have_decl___sys_siglist = yes; then
1319     AC_DEFINE(sys_siglist, __sys_siglist,
1320               [Define to any substitute for sys_siglist.])
1321   fi
1322 fi
1323 AC_HEADER_SYS_WAIT
1324
1325 dnl Some systems have utime.h but don't declare the struct anyplace.
1326 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1327 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1328 #include <sys/time.h>
1329 #include <time.h>
1330 #else
1331 #ifdef HAVE_SYS_TIME_H
1332 #include <sys/time.h>
1333 #else
1334 #include <time.h>
1335 #endif
1336 #endif
1337 #ifdef HAVE_UTIME_H
1338 #include <utime.h>
1339 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1340   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1341 if test $emacs_cv_struct_utimbuf = yes; then
1342   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1343 fi
1344
1345 dnl Check for speed_t typedef.
1346 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1347   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1348     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1349 if test $emacs_cv_speed_t = yes; then
1350   AC_DEFINE(HAVE_SPEED_T, 1,
1351            [Define to 1 if `speed_t' is declared by <termios.h>.])
1352 fi
1353
1354 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1355 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1356 #include <sys/time.h>
1357 #include <time.h>
1358 #else
1359 #ifdef HAVE_SYS_TIME_H
1360 #include <sys/time.h>
1361 #else
1362 #include <time.h>
1363 #endif
1364 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1365   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1366 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1367 if test $emacs_cv_struct_timeval = yes; then
1368   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1369 fi
1370
1371 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1372 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1373 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1374   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1375 HAVE_EXCEPTION=$emacs_cv_struct_exception
1376 if test $emacs_cv_struct_exception != yes; then
1377   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1378 fi
1379
1380 AC_CHECK_HEADERS(sys/socket.h)
1381 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1382 #if HAVE_SYS_SOCKET_H
1383 #include <sys/socket.h>
1384 #endif])
1385 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1386 #if HAVE_SYS_SOCKET_H
1387 #include <sys/socket.h>
1388 #endif])
1389 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1390 #if HAVE_SYS_SOCKET_H
1391 #include <sys/socket.h>
1392 #endif])
1393 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1394
1395 dnl checks for structure members
1396 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1397                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1398                   struct ifreq.ifr_addr,
1399                   struct ifreq.ifr_addr.sa_len], , ,
1400                  [AC_INCLUDES_DEFAULT
1401 #if HAVE_SYS_SOCKET_H
1402 #include <sys/socket.h>
1403 #endif
1404 #if HAVE_NET_IF_H
1405 #include <net/if.h>
1406 #endif])
1407
1408 dnl checks for compiler characteristics
1409
1410 dnl Testing __STDC__ to determine prototype support isn't good enough.
1411 dnl DEC C, for instance, doesn't define it with default options, and
1412 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1413 dnl and void *.
1414 AC_C_PROTOTYPES
1415 AC_C_VOLATILE
1416 AC_C_CONST
1417 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1418   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1419                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1420 if test $emacs_cv_void_star = yes; then
1421   AC_DEFINE(POINTER_TYPE, void)
1422 else
1423   AC_DEFINE(POINTER_TYPE, char)
1424 fi
1425 AH_TEMPLATE(POINTER_TYPE,
1426             [Define as `void' if your compiler accepts `void *'; otherwise
1427              define as `char'.])dnl
1428
1429 dnl Check for endianness.
1430 AC_C_BIGENDIAN
1431
1432 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1433   [emacs_cv_attribute_aligned],
1434   [AC_COMPILE_IFELSE(
1435      [AC_LANG_PROGRAM(
1436         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1437         [[]])],
1438      [emacs_cv_attribute_aligned=yes],
1439      [emacs_cv_attribute_aligned=no])])
1440 if test $emacs_cv_attribute_aligned = yes; then
1441   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1442     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1443 fi
1444
1445 dnl check for Make feature
1446 AC_PROG_MAKE_SET
1447
1448 DEPFLAGS=
1449 MKDEPDIR=":"
1450 deps_frag=deps.mk
1451 dnl check for GNU Make if we have GCC and autodepend is on.
1452 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1453    AC_MSG_CHECKING([whether we are using GNU Make])
1454    HAVE_GNU_MAKE=no
1455    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1456    if test "x$testval" != x; then
1457       HAVE_GNU_MAKE=yes
1458    else
1459       ac_enable_autodepend=no
1460    fi
1461    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1462    if test $HAVE_GNU_MAKE = yes; then
1463       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1464       SAVE_CFLAGS="$CFLAGS"
1465       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1466       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1467       CFLAGS="$SAVE_CFLAGS"
1468       test -f deps.d || ac_enable_autodepend=no
1469       rm -rf deps.d
1470       AC_MSG_RESULT([$ac_enable_autodepend])
1471    fi
1472    if test $ac_enable_autodepend = yes; then
1473       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1474       ## In parallel builds, another make might create depdir between
1475       ## the first test and mkdir, so stick another test on the end.
1476       ## Or use install-sh -d?  mkdir -p is not portable.
1477       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1478       deps_frag=autodeps.mk
1479    fi
1480 fi
1481 deps_frag=$srcdir/src/$deps_frag
1482 AC_SUBST(MKDEPDIR)
1483 AC_SUBST(DEPFLAGS)
1484 AC_SUBST_FILE(deps_frag)
1485
1486
1487 lisp_frag=$srcdir/src/lisp.mk
1488 AC_SUBST_FILE(lisp_frag)
1489
1490
1491 dnl checks for operating system services
1492 AC_SYS_LONG_FILE_NAMES
1493
1494 #### Choose a window system.
1495
1496 AC_PATH_X
1497 if test "$no_x" = yes; then
1498   window_system=none
1499 else
1500   window_system=x11
1501 fi
1502
1503 LD_SWITCH_X_SITE_AUX=
1504 LD_SWITCH_X_SITE_AUX_RPATH=
1505 if test "${x_libraries}" != NONE; then
1506   if test -n "${x_libraries}"; then
1507     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1508     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1509     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1510   fi
1511   x_default_search_path=""
1512   x_search_path=${x_libraries}
1513   if test -z "${x_search_path}"; then
1514     x_search_path=/usr/lib
1515   fi
1516   for x_library in `echo ${x_search_path}: | \
1517                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1518     x_search_path="\
1519 ${x_library}/X11/%L/%T/%N%C%S:\
1520 ${x_library}/X11/%l/%T/%N%C%S:\
1521 ${x_library}/X11/%T/%N%C%S:\
1522 ${x_library}/X11/%L/%T/%N%S:\
1523 ${x_library}/X11/%l/%T/%N%S:\
1524 ${x_library}/X11/%T/%N%S"
1525     if test x"${x_default_search_path}" = x; then
1526       x_default_search_path=${x_search_path}
1527     else
1528       x_default_search_path="${x_search_path}:${x_default_search_path}"
1529     fi
1530   done
1531 fi
1532 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1533 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1534
1535 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1536   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1537 fi
1538
1539 if test x"${x_includes}" = x; then
1540   bitmapdir=/usr/include/X11/bitmaps
1541 else
1542   # accumulate include directories that have X11 bitmap subdirectories
1543   bmd_acc="dummyval"
1544   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1545     if test -d "${bmd}/X11/bitmaps"; then
1546       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1547     fi
1548     if test -d "${bmd}/bitmaps"; then
1549       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1550     fi
1551   done
1552   if test ${bmd_acc} != "dummyval"; then
1553     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1554   fi
1555 fi
1556
1557 HAVE_NS=no
1558 NS_IMPL_COCOA=no
1559 NS_IMPL_GNUSTEP=no
1560 tmp_CPPFLAGS="$CPPFLAGS"
1561 tmp_CFLAGS="$CFLAGS"
1562 CPPFLAGS="$CPPFLAGS -x objective-c"
1563 CFLAGS="$CFLAGS -x objective-c"
1564 TEMACS_LDFLAGS2="\${LDFLAGS}"
1565 GNU_OBJC_CFLAGS=
1566 dnl I don't think it's especially important, but src/Makefile.in
1567 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1568 dnl trailing "/" to it, so now we do it here.
1569 if test "${with_ns}" != no; then
1570   if test "${opsys}" = darwin; then
1571      NS_IMPL_COCOA=yes
1572      ns_appdir=`pwd`/nextstep/Emacs.app
1573      ns_appbindir=${ns_appdir}/Contents/MacOS/
1574      ns_appresdir=${ns_appdir}/Contents/Resources
1575      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1576   elif test -f $GNUSTEP_CONFIG_FILE; then
1577      NS_IMPL_GNUSTEP=yes
1578      ns_appdir=`pwd`/nextstep/Emacs.app
1579      ns_appbindir=${ns_appdir}/
1580      ns_appresdir=${ns_appdir}/Resources
1581      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1582      dnl FIXME sourcing this several times in subshells seems inefficient.
1583      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1584      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1585      dnl I seemed to need these as well with GNUstep-startup 0.25.
1586      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1587      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1588      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1589        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1590      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1591        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1592      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1593      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1594      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1595      LIB_STANDARD=
1596      START_FILES=
1597      TEMACS_LDFLAGS2=
1598      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1599      dnl If they had chosen to either define it or not, we could have
1600      dnl just used AC_CHECK_DECL here.
1601      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1602        emacs_cv_objc_exceptions,
1603 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1604 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1605 1;
1606 #else
1607 fail;
1608 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1609      if test $emacs_cv_objc_exceptions = yes; then
1610        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1611        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1612          [Define if GNUstep uses ObjC exceptions.])
1613        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1614      fi
1615   fi
1616
1617   dnl This is only used while we test the NS headers, it gets reset below.
1618   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1619
1620   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1621                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1622   files are missing or cannot be compiled.])])
1623   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1624                                      [NSInteger i;])],
1625                     ns_have_nsinteger=yes,
1626                     ns_have_nsinteger=no)
1627   if test $ns_have_nsinteger = yes; then
1628     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1629   fi
1630 fi
1631 AC_SUBST(TEMACS_LDFLAGS2)
1632
1633 ns_frag=/dev/null
1634 NS_OBJ=
1635 NS_OBJC_OBJ=
1636 if test "${HAVE_NS}" = yes; then
1637   if test "$with_toolkit_scroll_bars" = "no"; then
1638     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1639   fi
1640
1641   window_system=nextstep
1642   with_xft=no
1643   # set up packaging dirs
1644   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1645      prefix=${ns_appresdir}
1646      exec_prefix=${ns_appbindir}
1647      libexecdir=${ns_appbindir}/libexec
1648   fi
1649   ns_frag=$srcdir/src/ns.mk
1650   NS_OBJ="fontset.o fringe.o image.o"
1651   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1652 fi
1653 CFLAGS="$tmp_CFLAGS"
1654 CPPFLAGS="$tmp_CPPFLAGS"
1655 AC_SUBST(NS_OBJ)
1656 AC_SUBST(NS_OBJC_OBJ)
1657 AC_SUBST(LIB_STANDARD)
1658 AC_SUBST_FILE(ns_frag)
1659
1660 case "${window_system}" in
1661   x11 )
1662     HAVE_X_WINDOWS=yes
1663     HAVE_X11=yes
1664     case "${with_x_toolkit}" in
1665       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1666       motif ) USE_X_TOOLKIT=MOTIF ;;
1667       gtk ) with_gtk=yes
1668 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1669 dnl USE_X_TOOLKIT is set.
1670             USE_X_TOOLKIT=none ;;
1671       gtk3 ) with_gtk3=yes
1672              USE_X_TOOLKIT=none ;;
1673       no ) USE_X_TOOLKIT=none ;;
1674 dnl If user did not say whether to use a toolkit, make this decision later:
1675 dnl use the toolkit if we have gtk, or X11R5 or newer.
1676       * ) USE_X_TOOLKIT=maybe ;;
1677     esac
1678   ;;
1679   nextstep | none )
1680     HAVE_X_WINDOWS=no
1681     HAVE_X11=no
1682     USE_X_TOOLKIT=none
1683   ;;
1684 esac
1685
1686 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1687    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1688    if test "$HAVE_XSERVER" = true ||
1689       test -n "$DISPLAY" ||
1690       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1691         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1692 were found.  You should install the relevant development files for X
1693 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1694 sure you have development files for image handling, i.e.
1695 tiff, gif, jpeg, png and xpm.
1696 If you are sure you want Emacs compiled without X window support, pass
1697   --without-x
1698 to configure.])
1699    fi
1700 fi
1701
1702 ### If we're using X11, we should use the X menu package.
1703 HAVE_MENUS=no
1704 case ${HAVE_X11} in
1705   yes ) HAVE_MENUS=yes ;;
1706 esac
1707
1708 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1709 # Assume not, until told otherwise.
1710 GNU_MALLOC=yes
1711
1712 AC_CACHE_CHECK(
1713   [whether malloc is Doug Lea style],
1714   [emacs_cv_var_doug_lea_malloc],
1715   [AC_LINK_IFELSE(
1716      [AC_LANG_PROGRAM(
1717         [[#include <malloc.h>
1718           static void hook (void) {}]],
1719         [[malloc_set_state (malloc_get_state ());
1720           __after_morecore_hook = hook;
1721           __malloc_initialize_hook = hook;]])],
1722      [emacs_cv_var_doug_lea_malloc=yes],
1723      [emacs_cv_var_doug_lea_malloc=no])])
1724 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1725
1726
1727 dnl See comments in aix4-2.h about maybe using system malloc there.
1728 system_malloc=no
1729 case "$opsys" in
1730   ## darwin ld insists on the use of malloc routines in the System framework.
1731   darwin|sol2-10) system_malloc=yes ;;
1732 esac
1733
1734 if test "${system_malloc}" = "yes"; then
1735   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1736   GNU_MALLOC=no
1737   GNU_MALLOC_reason="
1738     (The GNU allocators don't work with this system configuration.)"
1739   GMALLOC_OBJ=
1740   VMLIMIT_OBJ=
1741 else
1742   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1743   VMLIMIT_OBJ=vm-limit.o
1744 fi
1745 AC_SUBST(GMALLOC_OBJ)
1746 AC_SUBST(VMLIMIT_OBJ)
1747
1748 if test "$doug_lea_malloc" = "yes" ; then
1749   if test "$GNU_MALLOC" = yes ; then
1750     GNU_MALLOC_reason="
1751       (Using Doug Lea's new malloc from the GNU C Library.)"
1752   fi
1753   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1754             [Define to 1 if you are using the GNU C Library.])
1755
1756   ## Use mmap directly for allocating larger buffers.
1757   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1758   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1759   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1760   case "$opsys" in
1761     gnu*) REL_ALLOC=no ;;
1762   esac
1763 fi
1764
1765 if test x"${REL_ALLOC}" = x; then
1766   REL_ALLOC=${GNU_MALLOC}
1767 fi
1768
1769 use_mmap_for_buffers=no
1770 case "$opsys" in
1771   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1772 esac
1773
1774 AC_FUNC_MMAP
1775 if test $use_mmap_for_buffers = yes; then
1776   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1777   REL_ALLOC=no
1778 fi
1779
1780 LIBS="$LIBS_SYSTEM $LIBS"
1781
1782 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1783 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1784 AC_CHECK_LIB(dnet, dnet_ntoa)
1785 dnl This causes -lresolv to get used in subsequent tests,
1786 dnl which causes failures on some systems such as HPUX 9.
1787 dnl AC_CHECK_LIB(resolv, gethostbyname)
1788
1789 dnl FIXME replace main with a function we actually want from this library.
1790 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1791
1792 dnl Check if pthreads is available.
1793 LIB_PTHREAD=
1794 AC_CHECK_HEADERS(pthread.h)
1795 if test "$ac_cv_header_pthread_h"; then
1796   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1797   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1798   dnl testing for pthread_self if Emacs uses gmalloc.c.
1799   if test "$GMALLOC_OBJ" = gmalloc.o; then
1800     emacs_pthread_function=pthread_atfork
1801   else
1802     emacs_pthread_function=pthread_self
1803   fi
1804   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1805 fi
1806 if test "$HAVE_PTHREAD" = yes; then
1807   case "${canonical}" in
1808     *-hpux*) ;;
1809     *) LIB_PTHREAD="-lpthread"
1810        LIBS="$LIB_PTHREAD $LIBS" ;;
1811   esac
1812   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1813 fi
1814 AC_SUBST([LIB_PTHREAD])
1815
1816 AC_CHECK_LIB(pthreads, cma_open)
1817
1818 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1819 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1820 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1821 ## added to LIBS in configure would never contain the pthreads part,
1822 ## but the value used in Makefiles might.  FIXME?
1823 ##
1824 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1825 ## be harmless on older versions of X where it happens to exist.
1826 test "$opsys" = "aix4-2" && \
1827   test $ac_cv_lib_pthreads_cma_open = yes && \
1828   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1829
1830 dnl Check for need for bigtoc support on IBM AIX
1831
1832 case ${host_os} in
1833 aix*)
1834   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1835     case $GCC in
1836     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1837     *) gdb_cv_bigtoc=-bbigtoc ;;
1838     esac
1839
1840     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1841     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1842   ])
1843   ;;
1844 esac
1845
1846 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1847 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1848 # REAL_CPPFLAGS later on.
1849
1850 REAL_CFLAGS="$CFLAGS"
1851 REAL_CPPFLAGS="$CPPFLAGS"
1852
1853 if test "${HAVE_X11}" = "yes"; then
1854   DEFS="$C_SWITCH_X_SITE $DEFS"
1855   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1856   LIBS="-lX11 $LIBS"
1857   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1858   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1859
1860   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1861   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1862   # but it's more convenient here to set LD_RUN_PATH
1863   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1864   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1865     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1866     export LD_RUN_PATH
1867   fi
1868
1869   if test "${opsys}" = "gnu-linux"; then
1870     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1871     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1872      [[XOpenDisplay ("foo");]])],
1873      [xgnu_linux_first_failure=no],
1874      [xgnu_linux_first_failure=yes])
1875     if test "${xgnu_linux_first_failure}" = "yes"; then
1876       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1877       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1878       OLD_CPPFLAGS="$CPPFLAGS"
1879       OLD_LIBS="$LIBS"
1880       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1881       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1882       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1883       LIBS="$LIBS -b i486-linuxaout"
1884       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1885        [[XOpenDisplay ("foo");]])],
1886        [xgnu_linux_second_failure=no],
1887        [xgnu_linux_second_failure=yes])
1888       if test "${xgnu_linux_second_failure}" = "yes"; then
1889         # If we get the same failure with -b, there is no use adding -b.
1890         # So take it out.  This plays safe.
1891         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1892         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1893         CPPFLAGS="$OLD_CPPFLAGS"
1894         LIBS="$OLD_LIBS"
1895         AC_MSG_RESULT(no)
1896       else
1897         AC_MSG_RESULT(yes)
1898       fi
1899     else
1900       AC_MSG_RESULT(no)
1901     fi
1902   fi
1903
1904   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1905   # header files included from there.
1906   AC_MSG_CHECKING(for Xkb)
1907   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1908 #include <X11/XKBlib.h>]],
1909         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1910         emacs_xkb=yes, emacs_xkb=no)
1911   AC_MSG_RESULT($emacs_xkb)
1912   if test $emacs_xkb = yes; then
1913     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1914   fi
1915
1916   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1917 XScreenNumberOfScreen XSetWMProtocols)
1918 fi
1919
1920 if test "${window_system}" = "x11"; then
1921   AC_MSG_CHECKING(X11 version 6)
1922   AC_CACHE_VAL(emacs_cv_x11_version_6,
1923   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1924 [[#if XlibSpecificationRelease < 6
1925 fail;
1926 #endif
1927 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1928   if test $emacs_cv_x11_version_6 = yes; then
1929     AC_MSG_RESULT(6 or newer)
1930     AC_DEFINE(HAVE_X11R6, 1,
1931               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1932     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1933     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1934     ## XIM support.
1935     case "$opsys" in
1936       sol2-*) : ;;
1937       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1938            [Define if you have usable X11R6-style XIM support.])
1939          ;;
1940     esac
1941   else
1942     AC_MSG_RESULT(before 6)
1943   fi
1944 fi
1945
1946
1947 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1948 HAVE_RSVG=no
1949 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1950   if test "${with_rsvg}" != "no"; then
1951     RSVG_REQUIRED=2.11.0
1952     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1953
1954     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1955     AC_SUBST(RSVG_CFLAGS)
1956     AC_SUBST(RSVG_LIBS)
1957
1958     if test $HAVE_RSVG = yes; then
1959       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1960       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1961       LIBS="$RSVG_LIBS $LIBS"
1962     fi
1963   fi
1964 fi
1965
1966 HAVE_IMAGEMAGICK=no
1967 if test "${HAVE_X11}" = "yes"; then
1968   if test "${with_imagemagick}" != "no"; then
1969     ## 6.2.8 is the earliest version known to work, but earlier versions
1970     ## might work - let us know if you find one.
1971     ## 6.0.7 does not work.  See bug#7955.
1972     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1973     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1974     AC_SUBST(IMAGEMAGICK_CFLAGS)
1975     AC_SUBST(IMAGEMAGICK_LIBS)
1976
1977     if test $HAVE_IMAGEMAGICK = yes; then
1978       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1979       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1980       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1981       AC_CHECK_FUNCS(MagickExportImagePixels)
1982     fi
1983   fi
1984 fi
1985
1986
1987 HAVE_GTK=no
1988 GTK_OBJ=
1989 if test "${with_gtk3}" = "yes"; then
1990   GLIB_REQUIRED=2.28
1991   GTK_REQUIRED=3.0
1992   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1993
1994   dnl Checks for libraries.
1995   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1996   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1997      AC_MSG_ERROR($GTK_PKG_ERRORS)
1998   fi
1999   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2000   GTK_OBJ=emacsgtkfixed.o
2001 fi
2002
2003 if test "$pkg_check_gtk" != "yes"; then
2004   HAVE_GTK=no
2005 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2006   GLIB_REQUIRED=2.10
2007   GTK_REQUIRED=2.10
2008   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2009
2010   dnl Checks for libraries.
2011   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2012   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
2013      AC_MSG_ERROR($GTK_PKG_ERRORS)
2014   fi
2015 fi
2016 fi
2017
2018 if test x"$pkg_check_gtk" = xyes; then
2019
2020   AC_SUBST(GTK_CFLAGS)
2021   AC_SUBST(GTK_LIBS)
2022   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2023   CFLAGS="$CFLAGS $GTK_CFLAGS"
2024   LIBS="$GTK_LIBS $LIBS"
2025   dnl Try to compile a simple GTK program.
2026   GTK_COMPILES=no
2027   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
2028   if test "${GTK_COMPILES}" != "yes"; then
2029     if test "$USE_X_TOOLKIT" != "maybe"; then
2030       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2031     fi
2032   else
2033     HAVE_GTK=yes
2034     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2035     GTK_OBJ="gtkutil.o $GTK_OBJ"
2036     USE_X_TOOLKIT=none
2037     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
2038       :
2039     else
2040       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2041        closing open displays.  This is no problem if you just use
2042        one display, but if you use more than one and close one of them
2043        Emacs may crash.]])
2044       sleep 3
2045     fi
2046   fi
2047
2048 fi
2049 AC_SUBST(GTK_OBJ)
2050
2051
2052 if test "${HAVE_GTK}" = "yes"; then
2053
2054   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2055   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2056   if test "$with_toolkit_scroll_bars" != no; then
2057     with_toolkit_scroll_bars=yes
2058   fi
2059
2060   dnl  Check if we have the old file selection dialog declared and
2061   dnl  in the link library.  In 2.x it may be in the library,
2062   dnl  but not declared if deprecated featured has been selected out.
2063   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2064   HAVE_GTK_FILE_SELECTION=no
2065   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2066                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2067 #include <gtk/gtk.h>])
2068   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2069     AC_CHECK_FUNCS(gtk_file_selection_new)
2070   fi
2071
2072
2073   dnl Check for functions introduced in 2.14 and later.
2074   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2075                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2076                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2077                  gtk_orientable_set_orientation \
2078                  gtk_window_set_has_resize_grip)
2079 fi
2080
2081 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2082 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
2083 dnl also not configured.
2084 HAVE_DBUS=no
2085 DBUS_OBJ=
2086 if test "${with_dbus}" = "yes"; then
2087    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2088    if test "$HAVE_DBUS" = yes; then
2089      LIBS="$LIBS $DBUS_LIBS"
2090      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2091      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
2092      DBUS_OBJ=dbusbind.o
2093    fi
2094 fi
2095 AC_SUBST(DBUS_OBJ)
2096
2097 dnl GSettings has been tested under GNU/Linux only.
2098 HAVE_GSETTINGS=no
2099 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2100    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2101    if test "$HAVE_GSETTINGS" = "yes"; then
2102       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2103       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2104       SETTINGS_LIBS="$GSETTINGS_LIBS"
2105    fi
2106 fi
2107
2108 dnl GConf has been tested under GNU/Linux only.
2109 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2110 HAVE_GCONF=no
2111 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2112    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2113    if test "$HAVE_GCONF" = yes; then
2114       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2115       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2116       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2117       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2118    fi
2119 fi
2120
2121 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2122     SAVE_CFLAGS="$CFLAGS"
2123     SAVE_LIBS="$LIBS"
2124     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2125     LIBS="$SETTINGS_LIBS $LIBS"
2126     AC_CHECK_FUNCS([g_type_init])
2127     CFLAGS="$SAVE_CFLAGS"
2128     LIBS="$SAVE_LIBS"
2129 fi
2130 AC_SUBST(SETTINGS_CFLAGS)
2131 AC_SUBST(SETTINGS_LIBS)
2132
2133
2134 dnl SELinux is available for GNU/Linux only.
2135 HAVE_LIBSELINUX=no
2136 LIBSELINUX_LIBS=
2137 if test "${with_selinux}" = "yes"; then
2138    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2139    if test "$HAVE_LIBSELINUX" = yes; then
2140       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2141       LIBSELINUX_LIBS=-lselinux
2142    fi
2143 fi
2144 AC_SUBST(LIBSELINUX_LIBS)
2145
2146 HAVE_GNUTLS=no
2147 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2148 if test "${with_gnutls}" = "yes" ; then
2149   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2150   if test "${HAVE_GNUTLS}" = "yes"; then
2151     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2152   fi
2153
2154   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2155   LIBS="$LIBGNUTLS_LIBS $LIBS"
2156   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2157
2158   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2159     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2160   fi
2161 fi
2162
2163 AC_SUBST(LIBGNUTLS_LIBS)
2164 AC_SUBST(LIBGNUTLS_CFLAGS)
2165
2166 dnl Do not put whitespace before the #include statements below.
2167 dnl Older compilers (eg sunos4 cc) choke on it.
2168 HAVE_XAW3D=no
2169 LUCID_LIBW=
2170 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2171   if test "$with_xaw3d" != no; then
2172     AC_MSG_CHECKING(for xaw3d)
2173     AC_CACHE_VAL(emacs_cv_xaw3d,
2174     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2175 #include <X11/Intrinsic.h>
2176 #include <X11/Xaw3d/Simple.h>]],
2177       [[]])],
2178       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2179                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2180       emacs_cv_xaw3d=no)])
2181   else
2182     emacs_cv_xaw3d=no
2183   fi
2184   if test $emacs_cv_xaw3d = yes; then
2185     AC_MSG_RESULT([yes; using Lucid toolkit])
2186     USE_X_TOOLKIT=LUCID
2187     HAVE_XAW3D=yes
2188     LUCID_LIBW=-lXaw3d
2189     AC_DEFINE(HAVE_XAW3D, 1,
2190               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2191   else
2192     AC_MSG_RESULT(no)
2193     AC_MSG_CHECKING(for libXaw)
2194     AC_CACHE_VAL(emacs_cv_xaw,
2195     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2196 #include <X11/Intrinsic.h>
2197 #include <X11/Xaw/Simple.h>]],
2198       [[]])],
2199       emacs_cv_xaw=yes,
2200       emacs_cv_xaw=no)])
2201     if test $emacs_cv_xaw = yes; then
2202       AC_MSG_RESULT([yes; using Lucid toolkit])
2203       USE_X_TOOLKIT=LUCID
2204       LUCID_LIBW=-lXaw
2205     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2206       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2207     else
2208       AC_MSG_ERROR([No X toolkit could be found.
2209 If you are sure you want Emacs compiled without an X toolkit, pass
2210   --with-x-toolkit=no
2211 to configure.  Otherwise, install the development libraries for the toolkit
2212 that you want to use (e.g. Gtk+) and re-run configure.])
2213     fi
2214   fi
2215 fi
2216
2217 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2218
2219 LIBXTR6=
2220 if test "${USE_X_TOOLKIT}" != "none"; then
2221   AC_MSG_CHECKING(X11 toolkit version)
2222   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2223   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2224 [[#if XtSpecificationRelease < 6
2225 fail;
2226 #endif
2227 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2228   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2229   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2230     AC_MSG_RESULT(6 or newer)
2231     AC_DEFINE(HAVE_X11XTR6, 1,
2232               [Define to 1 if you have the X11R6 or newer version of Xt.])
2233     LIBXTR6="-lSM -lICE"
2234     case "$opsys" in
2235       ## Use libw.a along with X11R6 Xt.
2236       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2237     esac
2238   else
2239     AC_MSG_RESULT(before 6)
2240   fi
2241
2242 dnl If using toolkit, check whether libXmu.a exists.
2243 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2244   OLDLIBS="$LIBS"
2245   if test x$HAVE_X11XTR6 = xyes; then
2246     LIBS="-lXt -lSM -lICE $LIBS"
2247   else
2248     LIBS="-lXt $LIBS"
2249   fi
2250   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2251   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2252 fi
2253 AC_SUBST(LIBXTR6)
2254
2255 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2256 dnl Why not just test for libxmu in the normal way?
2257 LIBXMU=-lXmu
2258 case $opsys in
2259   ## These systems don't supply Xmu.
2260   hpux* | aix4-2 )
2261     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2262     ;;
2263 esac
2264 AC_SUBST(LIBXMU)
2265
2266 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2267 if test "${HAVE_X11}" = "yes"; then
2268   if test "${USE_X_TOOLKIT}" != "none"; then
2269     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2270   fi
2271 fi
2272
2273 LIBXP=
2274 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2275   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2276   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2277     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2278 int x = 5;
2279 #else
2280 Motif version prior to 2.1.
2281 #endif]])],
2282     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2283   if test $emacs_cv_motif_version_2_1 = yes; then
2284     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2285   else
2286     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2287     # We put this in CFLAGS temporarily to precede other -I options
2288     # that might be in CFLAGS temporarily.
2289     # We put this in CPPFLAGS where it precedes the other -I options.
2290     OLD_CPPFLAGS=$CPPFLAGS
2291     OLD_CFLAGS=$CFLAGS
2292     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2293     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2294     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2295       [[int x = 5;]])],
2296       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2297     if test $emacs_cv_lesstif = yes; then
2298       # Make sure this -I option remains in CPPFLAGS after it is set
2299       # back to REAL_CPPFLAGS.
2300       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2301       # have those other -I options anyway.  Ultimately, having this
2302       # directory ultimately in CPPFLAGS will be enough.
2303       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2304       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2305     else
2306       CFLAGS=$OLD_CFLAGS
2307       CPPFLAGS=$OLD_CPPFLAGS
2308     fi
2309   fi
2310   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2311     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2312 fi
2313
2314 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2315 dnl using Motif or Xaw3d is available, and unless
2316 dnl --with-toolkit-scroll-bars=no was specified.
2317
2318 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2319             [Define to 1 if we should use toolkit scroll bars.])dnl
2320 USE_TOOLKIT_SCROLL_BARS=no
2321 if test "${with_toolkit_scroll_bars}" != "no"; then
2322   if test "${USE_X_TOOLKIT}" != "none"; then
2323     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2324       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2325       HAVE_XAW3D=no
2326       USE_TOOLKIT_SCROLL_BARS=yes
2327     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2328       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2329       USE_TOOLKIT_SCROLL_BARS=yes
2330     fi
2331   elif test "${HAVE_GTK}" = "yes"; then
2332     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2333     USE_TOOLKIT_SCROLL_BARS=yes
2334   elif test "${HAVE_NS}" = "yes"; then
2335     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2336     USE_TOOLKIT_SCROLL_BARS=yes
2337   fi
2338 fi
2339
2340 dnl See if XIM is available.
2341 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2342           #include <X11/Xlib.h>
2343           #include <X11/Xresource.h>]],
2344          [[XIMProc  callback;]])],
2345          [HAVE_XIM=yes
2346          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2347          HAVE_XIM=no)
2348
2349 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2350
2351 if test "${with_xim}" != "no"; then
2352   AC_DEFINE(USE_XIM, 1,
2353             [Define to 1 if we should use XIM, if it is available.])
2354 fi
2355
2356
2357 if test "${HAVE_XIM}" != "no"; then
2358   late_CFLAGS=$CFLAGS
2359   if test "$GCC" = yes; then
2360     CFLAGS="$CFLAGS --pedantic-errors"
2361   fi
2362   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2363 #include <X11/Xlib.h>
2364 #include <X11/Xresource.h>]],
2365 [[Display *display;
2366 XrmDatabase db;
2367 char *res_name;
2368 char *res_class;
2369 XIMProc  callback;
2370 XPointer *client_data;
2371 #ifndef __GNUC__
2372 /* If we're not using GCC, it's probably not XFree86, and this is
2373    probably right, but we can't use something like --pedantic-errors.  */
2374 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2375                                            char*, XIMProc, XPointer*);
2376 #endif
2377 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2378    client_data);]])],
2379     [emacs_cv_arg6_star=yes])
2380   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2381          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2382 either XPointer or XPointer*.])dnl
2383   if test "$emacs_cv_arg6_star" = yes; then
2384     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2385   else
2386     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2387   fi
2388   CFLAGS=$late_CFLAGS
2389 fi
2390
2391 ### Start of font-backend (under any platform) section.
2392 # (nothing here yet -- this is a placeholder)
2393 ### End of font-backend (under any platform) section.
2394
2395 ### Start of font-backend (under X11) section.
2396 if test "${HAVE_X11}" = "yes"; then
2397    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2398
2399    ## Use -lXft if available, unless `--with-xft=no'.
2400    HAVE_XFT=maybe
2401     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2402       with_xft="no";
2403     fi
2404     if test "x${with_xft}" != "xno"; then
2405
2406       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2407       ## Because xftfont.c uses XRenderQueryExtension, we also
2408       ## need to link to -lXrender.
2409       HAVE_XRENDER=no
2410       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2411       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2412         OLD_CPPFLAGS="$CPPFLAGS"
2413         OLD_CFLAGS="$CFLAGS"
2414         OLD_LIBS="$LIBS"
2415         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2416         CFLAGS="$CFLAGS $XFT_CFLAGS"
2417         XFT_LIBS="-lXrender $XFT_LIBS"
2418         LIBS="$XFT_LIBS $LIBS"
2419         AC_CHECK_HEADER(X11/Xft/Xft.h,
2420           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2421
2422         if test "${HAVE_XFT}" = "yes"; then
2423           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2424             AC_SUBST(XFT_LIBS)
2425           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2426         else
2427           CPPFLAGS="$OLD_CPPFLAGS"
2428           CFLAGS="$OLD_CFLAGS"
2429           LIBS="$OLD_LIBS"
2430         fi                        # "${HAVE_XFT}" = "yes"
2431       fi                          # "$HAVE_XFT" != no
2432     fi                            # "x${with_xft}" != "xno"
2433
2434     ## We used to allow building with FreeType and without Xft.
2435     ## However, the ftx font backend driver is not in good shape.
2436     if test "$HAVE_XFT" != "yes"; then
2437        dnl For the "Does Emacs use" message at the end.
2438        HAVE_XFT=no
2439        HAVE_FREETYPE=no
2440     else
2441        dnl Strict linkers fail with
2442        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2443        dnl if -lfreetype is not specified.
2444        dnl The following is needed to set FREETYPE_LIBS.
2445        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2446                          HAVE_FREETYPE=no)
2447
2448        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2449     fi
2450
2451     HAVE_LIBOTF=no
2452     if test "${HAVE_FREETYPE}" = "yes"; then
2453       AC_DEFINE(HAVE_FREETYPE, 1,
2454                 [Define to 1 if using the freetype and fontconfig libraries.])
2455       if test "${with_libotf}" != "no"; then
2456         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2457                           HAVE_LIBOTF=no)
2458         if test "$HAVE_LIBOTF" = "yes"; then
2459           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2460           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2461                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2462                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2463           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2464             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2465                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2466           fi
2467         fi
2468       fi
2469     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2470     dnl Does the new font backend require it, or can it work without it?
2471     fi
2472
2473     HAVE_M17N_FLT=no
2474     if test "${HAVE_LIBOTF}" = yes; then
2475       if test "${with_m17n_flt}" != "no"; then
2476         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2477         if test "$HAVE_M17N_FLT" = "yes"; then
2478           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2479         fi
2480       fi
2481     fi
2482 else
2483     HAVE_XFT=no
2484     HAVE_FREETYPE=no
2485     HAVE_LIBOTF=no
2486     HAVE_M17N_FLT=no
2487 fi
2488
2489 ### End of font-backend (under X11) section.
2490
2491 AC_SUBST(FREETYPE_CFLAGS)
2492 AC_SUBST(FREETYPE_LIBS)
2493 AC_SUBST(FONTCONFIG_CFLAGS)
2494 AC_SUBST(FONTCONFIG_LIBS)
2495 AC_SUBST(LIBOTF_CFLAGS)
2496 AC_SUBST(LIBOTF_LIBS)
2497 AC_SUBST(M17N_FLT_CFLAGS)
2498 AC_SUBST(M17N_FLT_LIBS)
2499
2500 ### Use -lXpm if available, unless `--with-xpm=no'.
2501 HAVE_XPM=no
2502 LIBXPM=
2503 if test "${HAVE_X11}" = "yes"; then
2504   if test "${with_xpm}" != "no"; then
2505     AC_CHECK_HEADER(X11/xpm.h,
2506       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2507     if test "${HAVE_XPM}" = "yes"; then
2508       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2509       AC_EGREP_CPP(no_return_alloc_pixels,
2510       [#include "X11/xpm.h"
2511 #ifndef XpmReturnAllocPixels
2512 no_return_alloc_pixels
2513 #endif
2514       ], HAVE_XPM=no, HAVE_XPM=yes)
2515
2516       if test "${HAVE_XPM}" = "yes"; then
2517         AC_MSG_RESULT(yes)
2518       else
2519         AC_MSG_RESULT(no)
2520       fi
2521     fi
2522   fi
2523
2524   if test "${HAVE_XPM}" = "yes"; then
2525     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2526     LIBXPM=-lXpm
2527   fi
2528 fi
2529 AC_SUBST(LIBXPM)
2530
2531 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2532 HAVE_JPEG=no
2533 LIBJPEG=
2534 if test "${HAVE_X11}" = "yes"; then
2535   if test "${with_jpeg}" != "no"; then
2536     dnl Checking for jpeglib.h can lose because of a redefinition of
2537     dnl  HAVE_STDLIB_H.
2538     AC_CHECK_HEADER(jerror.h,
2539       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2540   fi
2541
2542   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2543   if test "${HAVE_JPEG}" = "yes"; then
2544     AC_DEFINE(HAVE_JPEG)
2545     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2546         [#include <jpeglib.h>
2547          version=JPEG_LIB_VERSION
2548 ],
2549         [AC_DEFINE(HAVE_JPEG)],
2550         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2551         HAVE_JPEG=no])
2552   fi
2553   if test "${HAVE_JPEG}" = "yes"; then
2554     LIBJPEG=-ljpeg
2555   fi
2556 fi
2557 AC_SUBST(LIBJPEG)
2558
2559 ### Use -lpng if available, unless `--with-png=no'.
2560 HAVE_PNG=no
2561 LIBPNG=
2562 if test "${HAVE_X11}" = "yes"; then
2563   if test "${with_png}" != "no"; then
2564     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2565     # in /usr/include/libpng.
2566     AC_CHECK_HEADERS(png.h libpng/png.h)
2567     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2568       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2569     fi
2570   fi
2571
2572   if test "${HAVE_PNG}" = "yes"; then
2573     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2574     LIBPNG="-lpng -lz -lm"
2575   fi
2576 fi
2577 AC_SUBST(LIBPNG)
2578
2579 ### Use -ltiff if available, unless `--with-tiff=no'.
2580 HAVE_TIFF=no
2581 LIBTIFF=
2582 if test "${HAVE_X11}" = "yes"; then
2583   if test "${with_tiff}" != "no"; then
2584     AC_CHECK_HEADER(tiffio.h,
2585       [tifflibs="-lz -lm"
2586       # At least one tiff package requires the jpeg library.
2587       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2588       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2589   fi
2590
2591   if test "${HAVE_TIFF}" = "yes"; then
2592     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2593     dnl FIXME -lz -lm, as per libpng?
2594     LIBTIFF=-ltiff
2595   fi
2596 fi
2597 AC_SUBST(LIBTIFF)
2598
2599 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2600 HAVE_GIF=no
2601 LIBGIF=
2602 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2603   AC_CHECK_HEADER(gif_lib.h,
2604 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2605 # Earlier versions can crash Emacs.
2606     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2607
2608   if test "$HAVE_GIF" = yes; then
2609     LIBGIF=-lgif
2610   elif test "$HAVE_GIF" = maybe; then
2611 # If gif_lib.h but no libgif, try libungif.
2612     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2613     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2614   fi
2615
2616   if test "${HAVE_GIF}" = "yes"; then
2617     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2618   fi
2619 fi
2620 AC_SUBST(LIBGIF)
2621
2622 dnl Check for required libraries.
2623 if test "${HAVE_X11}" = "yes"; then
2624   MISSING=""
2625   WITH_NO=""
2626   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2627     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2628   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2629     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2630   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2631     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2632   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2633     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2634   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2635     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2636
2637   if test "X${MISSING}" != X; then
2638     AC_MSG_ERROR([The following required libraries were not found:
2639     $MISSING
2640 Maybe some development libraries/packages are missing?
2641 If you don't want to link with them give
2642     $WITH_NO
2643 as options to configure])
2644   fi
2645 fi
2646
2647 ### Use -lgpm if available, unless `--with-gpm=no'.
2648 HAVE_GPM=no
2649 LIBGPM=
2650 if test "${with_gpm}" != "no"; then
2651   AC_CHECK_HEADER(gpm.h,
2652     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2653
2654   if test "${HAVE_GPM}" = "yes"; then
2655     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2656     LIBGPM=-lgpm
2657   fi
2658 fi
2659 AC_SUBST(LIBGPM)
2660
2661 dnl Check for malloc/malloc.h on darwin
2662 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2663
2664 GNUSTEP_CFLAGS=
2665 ### Use NeXTstep API to implement GUI.
2666 if test "${HAVE_NS}" = "yes"; then
2667   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2668   if test "${NS_IMPL_COCOA}" = "yes"; then
2669     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2670   fi
2671   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2672     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2673     # See also .m.o rule in Makefile.in */
2674     # FIXME: are all these flags really needed?  Document here why.  */
2675     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2676     ## Extra CFLAGS applied to src/*.m files.
2677     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2678   fi
2679   # We also have mouse menus.
2680   HAVE_MENUS=yes
2681   OTHER_FILES=ns-app
2682 fi
2683
2684
2685 ### Use session management (-lSM -lICE) if available
2686 HAVE_X_SM=no
2687 LIBXSM=
2688 if test "${HAVE_X11}" = "yes"; then
2689   AC_CHECK_HEADER(X11/SM/SMlib.h,
2690     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2691
2692   if test "${HAVE_X_SM}" = "yes"; then
2693     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2694     LIBXSM="-lSM -lICE"
2695     case "$LIBS" in
2696       *-lSM*) ;;
2697       *)      LIBS="$LIBXSM $LIBS" ;;
2698     esac
2699   fi
2700 fi
2701 AC_SUBST(LIBXSM)
2702
2703 ### Use libxml (-lxml2) if available
2704 HAVE_LIBXML2=no
2705 if test "${with_xml2}" != "no"; then
2706   ### I'm not sure what the version number should be, so I just guessed.
2707   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2708   if test "${HAVE_LIBXML2}" = "yes"; then
2709     LIBS="$LIBXML2_LIBS $LIBS"
2710     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2711     if test "${HAVE_LIBXML2}" = "yes"; then
2712       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2713     else
2714       LIBXML2_LIBS=""
2715       LIBXML2_CFLAGS=""
2716     fi
2717   fi
2718 fi
2719 AC_SUBST(LIBXML2_LIBS)
2720 AC_SUBST(LIBXML2_CFLAGS)
2721
2722 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2723 AC_CACHE_CHECK(whether netdb declares h_errno,
2724                emacs_cv_netdb_declares_h_errno,
2725 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2726   [[return h_errno;]])],
2727   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2728 if test $emacs_cv_netdb_declares_h_errno = yes; then
2729   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2730 fi
2731
2732 # fmod, logb, and frexp are found in -lm on most systems.
2733 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2734 AC_CHECK_LIB(m, sqrt)
2735
2736 # Check for mail-locking functions in a "mail" library.  Probably this should
2737 # have the same check as for liblockfile below.
2738 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2739 if test $have_mail = yes; then
2740   LIBS_MAIL=-lmail
2741   LIBS="$LIBS_MAIL $LIBS"
2742   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2743 else
2744   LIBS_MAIL=
2745 fi
2746 dnl Debian, at least:
2747 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2748 if test $have_lockfile = yes; then
2749    LIBS_MAIL=-llockfile
2750    LIBS="$LIBS_MAIL $LIBS"
2751    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2752 else
2753 # If we have the shared liblockfile, assume we must use it for mail
2754 # locking (e.g. Debian).  If we couldn't link against liblockfile
2755 # (no liblockfile.a installed), ensure that we don't need to.
2756   dnl This works for files generally, not just executables.
2757   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2758   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2759                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2760   if test $ac_cv_prog_liblockfile = yes; then
2761     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2762 This probably means that movemail could lose mail.
2763 There may be a `development' package to install containing liblockfile.])
2764   fi
2765 fi
2766 AC_CHECK_FUNCS(touchlock)
2767 AC_CHECK_HEADERS(maillock.h)
2768 AC_SUBST(LIBS_MAIL)
2769
2770 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2771 ## interlock access to the mail spool.  The alternative is a lock file named
2772 ## /usr/spool/mail/$USER.lock.
2773 mail_lock=no
2774 case "$opsys" in
2775   aix4-2) mail_lock="lockf" ;;
2776
2777   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2778
2779   ## On GNU/Linux systems, both methods are used by various mail programs.
2780   ## I assume most people are using newer mailers that have heard of flock.
2781   ## Change this if you need to.
2782   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2783   ## configure gets the right answers, and that means *NOT* using flock.
2784   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2785   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2786   ## Debian maintainer hasn't provided a clean fix for Emacs.
2787   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2788   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2789   ## correct logic.  -- fx
2790   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2791   ## liblockfile is a Free Software replacement for libmail, used on
2792   ## Debian systems and elsewhere. -rfr.
2793   gnu-*)
2794     mail_lock="flock"
2795     if test $have_mail = yes || test $have_lockfile = yes; then
2796       test $ac_cv_header_maillock_h = yes && mail_lock=no
2797     fi
2798     ;;
2799 esac
2800
2801 BLESSMAIL_TARGET=
2802 case "$mail_lock" in
2803   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2804
2805   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2806
2807   *) BLESSMAIL_TARGET="need-blessmail" ;;
2808 esac
2809 AC_SUBST(BLESSMAIL_TARGET)
2810
2811
2812 AC_CHECK_FUNCS(gethostname getdomainname \
2813 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2814 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2815 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2816 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2817 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2818 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2819 gai_strerror mkstemp getline getdelim mremap fsync sync \
2820 difftime mempcpy mblen mbrlen posix_memalign \
2821 getpwent endpwent getgrent endgrent \
2822 cfmakeraw cfsetspeed copysign __executable_start)
2823
2824 dnl Cannot use AC_CHECK_FUNCS
2825 AC_CACHE_CHECK([for __builtin_unwind_init],
2826                emacs_cv_func___builtin_unwind_init,
2827 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2828                 emacs_cv_func___builtin_unwind_init=yes,
2829                 emacs_cv_func___builtin_unwind_init=no)])
2830 if test $emacs_cv_func___builtin_unwind_init = yes; then
2831   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2832             [Define to 1 if you have the `__builtin_unwind_init' function.])
2833 fi
2834
2835 AC_CHECK_HEADERS(sys/un.h)
2836
2837 AC_FUNC_FSEEKO
2838
2839 AC_FUNC_GETPGRP
2840
2841 # UNIX98 PTYs.
2842 AC_CHECK_FUNCS(grantpt)
2843
2844 # PTY-related GNU extensions.
2845 AC_CHECK_FUNCS(getpt)
2846
2847 # Check this now, so that we will NOT find the above functions in ncurses.
2848 # That is because we have not set up to link ncurses in lib-src.
2849 # It's better to believe a function is not available
2850 # than to expect to find it in ncurses.
2851 # Also we need tputs and friends to be able to build at all.
2852 AC_MSG_CHECKING([for library containing tputs])
2853 # Run a test program that contains a call to tputs, a call that is
2854 # never executed.  This tests whether a pre-'main' dynamic linker
2855 # works with the library.  It's too much trouble to actually call
2856 # tputs in the test program, due to portability hassles.  When
2857 # cross-compiling, assume the test program will run if it links.
2858 AC_DEFUN([tputs_link_source], [
2859   AC_LANG_SOURCE(
2860      [[extern void tputs (const char *, int, int (*)(int));
2861        int main (int argc, char **argv)
2862        {
2863           if (argc == 10000)
2864             tputs (argv[0], 0, 0);
2865           return 0;
2866        }]])
2867 ])
2868 # Maybe curses should be tried earlier?
2869 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2870 for tputs_library in '' ncurses terminfo termcap curses; do
2871   OLIBS=$LIBS
2872   if test -z "$tputs_library"; then
2873     LIBS_TERMCAP=
2874     msg='none required'
2875   else
2876     LIBS_TERMCAP=-l$tputs_library
2877     msg=$LIBS_TERMCAP
2878     LIBS="$LIBS_TERMCAP $LIBS"
2879   fi
2880   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2881     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2882   LIBS=$OLIBS
2883   if test "X$msg" != Xno; then
2884     break
2885   fi
2886 done
2887 AC_MSG_RESULT([$msg])
2888 if test "X$msg" = Xno; then
2889   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2890 These libraries were tried: libncurses, libterminfo, libtermcap, libcurses.
2891 Please try installing whichever of these libraries is most appropriate
2892 for your system, together with its header files.
2893 For example, a libncurses-dev(el) or similar package.])
2894 fi
2895 # Must define this when any termcap library is found.
2896 AC_DEFINE(HAVE_LIBNCURSES, 1,
2897           [Define to 1 if you have the `ncurses' library (-lncurses).])
2898 ## FIXME This was the cpp logic, but I am not sure it is right.
2899 ## The above test has not necessarily found libncurses.
2900 HAVE_LIBNCURSES=yes
2901
2902 ## Use terminfo instead of termcap?
2903 ## Note only system files NOT using terminfo are:
2904 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2905 ## darwin|gnu without ncurses.
2906 TERMINFO=no
2907 case "$opsys" in
2908   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2909   ## hpux10-20: Use the system provided termcap(3) library.
2910   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2911   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2912   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2913
2914   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2915   ##  The ncurses library has been moved out of the System framework in
2916   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2917   ##  option to use it.
2918   darwin|gnu*)
2919     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2920     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2921       TERMINFO=yes
2922       LIBS_TERMCAP="-lncurses"
2923     fi
2924     ;;
2925
2926   freebsd)
2927     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2928     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2929     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2930 [[#if __FreeBSD_version < 400000
2931 fail;
2932 #endif
2933 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2934
2935     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2936
2937     if test $emacs_cv_freebsd_terminfo = yes; then
2938       TERMINFO=yes
2939       LIBS_TERMCAP="-lncurses"
2940     else
2941       LIBS_TERMCAP="-ltermcap"
2942     fi
2943     ;;
2944
2945   netbsd)
2946     if test $ac_cv_search_tputs = -lterminfo; then
2947       TERMINFO=yes
2948       LIBS_TERMCAP="-lterminfo"
2949     else
2950       LIBS_TERMCAP="-ltermcap"
2951     fi
2952     ;;
2953
2954 esac
2955
2956 case "$opsys" in
2957   ## hpux: Make sure we get select from libc rather than from libcurses
2958   ##  because libcurses on HPUX 10.10 has a broken version of select.
2959   ##  We used to use -lc -lcurses, but this may be cleaner.
2960   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2961
2962   openbsd) LIBS_TERMCAP="-lncurses" ;;
2963
2964   ## Must use system termcap, if we use any termcap.  It does special things.
2965   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2966 esac
2967
2968 TERMCAP_OBJ=tparam.o
2969 if test $TERMINFO = yes; then
2970   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2971   TERMCAP_OBJ=terminfo.o
2972 fi
2973 AC_SUBST(LIBS_TERMCAP)
2974 AC_SUBST(TERMCAP_OBJ)
2975
2976
2977 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2978 resolv=no
2979 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2980 #include <arpa/nameser.h>
2981 #include <resolv.h>]],
2982     [[return res_init();]])],
2983     have_res_init=yes, have_res_init=no)
2984 if test "$have_res_init" = no; then
2985   OLIBS="$LIBS"
2986   LIBS="$LIBS -lresolv"
2987   AC_MSG_CHECKING(for res_init with -lresolv)
2988   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2989 #include <arpa/nameser.h>
2990 #include <resolv.h>]],
2991     [[return res_init();]])],
2992     have_res_init=yes, have_res_init=no)
2993   AC_MSG_RESULT($have_res_init)
2994   if test "$have_res_init" = yes ; then
2995     resolv=yes
2996   fi
2997   LIBS="$OLIBS"
2998 fi
2999
3000 if test "$have_res_init" = yes; then
3001   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3002 fi
3003
3004 # Do we need the Hesiod library to provide the support routines?
3005 LIBHESIOD=
3006 if test "$with_hesiod" != no ; then
3007   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3008   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3009      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3010                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3011   if test "$resolv" = yes ; then
3012     RESOLVLIB=-lresolv
3013   else
3014     RESOLVLIB=
3015   fi
3016   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3017         hesiod=yes, :, $RESOLVLIB)])
3018
3019   if test x"$hesiod" = xyes; then
3020     AC_DEFINE(HAVE_LIBHESIOD, 1,
3021               [Define to 1 if you have the hesiod library (-lhesiod).])
3022     LIBHESIOD=-lhesiod
3023   fi
3024 fi
3025 AC_SUBST(LIBHESIOD)
3026
3027 # Do we need libresolv (due to res_init or Hesiod)?
3028 if test "$resolv" = yes ; then
3029   AC_DEFINE(HAVE_LIBRESOLV, 1,
3030             [Define to 1 if you have the resolv library (-lresolv).])
3031   LIBRESOLV=-lresolv
3032 else
3033   LIBRESOLV=
3034 fi
3035 AC_SUBST(LIBRESOLV)
3036
3037 # These tell us which Kerberos-related libraries to use.
3038 COM_ERRLIB=
3039 CRYPTOLIB=
3040 KRB5LIB=
3041 DESLIB=
3042 KRB4LIB=
3043
3044 if test "${with_kerberos}" != no; then
3045   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3046   if test $have_com_err = yes; then
3047     COM_ERRLIB=-lcom_err
3048     LIBS="$COM_ERRLIB $LIBS"
3049     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3050   fi
3051   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3052   if test $have_crypto = yes; then
3053     CRYPTOLIB=-lcrypto
3054     LIBS="$CRYPTOLIB $LIBS"
3055     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3056   fi
3057   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3058   if test $have_k5crypto = yes; then
3059     CRYPTOLIB=-lk5crypto
3060     LIBS="$CRYPTOLIB $LIBS"
3061     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3062   fi
3063   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3064   if test $have_krb5=yes; then
3065     KRB5LIB=-lkrb5
3066     LIBS="$KRB5LIB $LIBS"
3067     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3068   fi
3069   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3070   if test "${with_kerberos5}" = no; then
3071     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3072     if test $have_des425 = yes; then
3073       DESLIB=-ldes425
3074       LIBS="$DESLIB $LIBS"
3075       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3076     else
3077       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3078       if test $have_des = yes; then
3079         DESLIB=-ldes
3080         LIBS="$DESLIB $LIBS"
3081         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3082       fi
3083     fi
3084     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3085     if test $have_krb4 = yes; then
3086       KRB4LIB=-lkrb4
3087       LIBS="$KRB4LIB $LIBS"
3088       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3089     else
3090       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3091       if test $have_krb = yes; then
3092         KRB4LIB=-lkrb
3093         LIBS="$KRB4LIB $LIBS"
3094         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3095       fi
3096     fi
3097   fi
3098
3099   if test "${with_kerberos5}" != no; then
3100     AC_CHECK_HEADERS(krb5.h,
3101       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3102                         [#include <krb5.h>])])
3103   else
3104     AC_CHECK_HEADERS(des.h,,
3105                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3106                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3107     AC_CHECK_HEADERS(krb.h,,
3108                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3109                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3110   fi
3111   AC_CHECK_HEADERS(com_err.h)
3112 fi
3113
3114 AC_SUBST(COM_ERRLIB)
3115 AC_SUBST(CRYPTOLIB)
3116 AC_SUBST(KRB5LIB)
3117 AC_SUBST(DESLIB)
3118 AC_SUBST(KRB4LIB)
3119
3120 AC_MSG_CHECKING(whether localtime caches TZ)
3121 AC_CACHE_VAL(emacs_cv_localtime_cache,
3122 [if test x$ac_cv_func_tzset = xyes; then
3123 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3124 char TZ_GMT0[] = "TZ=GMT0";
3125 char TZ_PST8[] = "TZ=PST8";
3126 main()
3127 {
3128   time_t now = time ((time_t *) 0);
3129   int hour_GMT0, hour_unset;
3130   if (putenv (TZ_GMT0) != 0)
3131     exit (1);
3132   hour_GMT0 = localtime (&now)->tm_hour;
3133   unsetenv("TZ");
3134   hour_unset = localtime (&now)->tm_hour;
3135   if (putenv (TZ_PST8) != 0)
3136     exit (1);
3137   if (localtime (&now)->tm_hour == hour_GMT0)
3138     exit (1);
3139   unsetenv("TZ");
3140   if (localtime (&now)->tm_hour != hour_unset)
3141     exit (1);
3142   exit (0);
3143 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3144 [# If we have tzset, assume the worst when cross-compiling.
3145 emacs_cv_localtime_cache=yes])
3146 else
3147         # If we lack tzset, report that localtime does not cache TZ,
3148         # since we can't invalidate the cache if we don't have tzset.
3149         emacs_cv_localtime_cache=no
3150 fi])dnl
3151 AC_MSG_RESULT($emacs_cv_localtime_cache)
3152 if test $emacs_cv_localtime_cache = yes; then
3153   AC_DEFINE(LOCALTIME_CACHE, 1,
3154             [Define to 1 if localtime caches TZ.])
3155 fi
3156
3157 if test "x$HAVE_TIMEVAL" = xyes; then
3158   AC_CHECK_FUNCS(gettimeofday)
3159   if test $ac_cv_func_gettimeofday = yes; then
3160     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3161                    emacs_cv_gettimeofday_two_arguments,
3162     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3163 #ifdef TIME_WITH_SYS_TIME
3164 #include <sys/time.h>
3165 #include <time.h>
3166 #else
3167 #ifdef HAVE_SYS_TIME_H
3168 #include <sys/time.h>
3169 #else
3170 #include <time.h>
3171 #endif
3172 #endif]],
3173       [[struct timeval time;
3174        gettimeofday (&time, 0);]])],
3175       emacs_cv_gettimeofday_two_arguments=yes,
3176       emacs_cv_gettimeofday_two_arguments=no)])
3177     if test $emacs_cv_gettimeofday_two_arguments = no; then
3178       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3179                 [Define to 1 if gettimeofday accepts only one argument.])
3180     fi
3181   fi
3182 fi
3183
3184 ok_so_far=yes
3185 AC_CHECK_FUNC(socket, , ok_so_far=no)
3186 if test $ok_so_far = yes; then
3187   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3188 fi
3189 if test $ok_so_far = yes; then
3190   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3191 fi
3192 if test $ok_so_far = yes; then
3193 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3194   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3195             [Define to 1 if you have inet sockets.])
3196 fi
3197
3198 if test -f /usr/lpp/X11/bin/smt.exp; then
3199   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3200             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3201 fi
3202
3203 AC_MSG_CHECKING(whether system supports dynamic ptys)
3204 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3205   AC_MSG_RESULT(yes)
3206   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3207 else
3208   AC_MSG_RESULT(no)
3209 fi
3210
3211 AC_FUNC_FORK
3212
3213 AC_CHECK_FUNCS(snprintf)
3214
3215 dnl Adapted from Haible's version.
3216 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3217   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3218     [[char* cs = nl_langinfo(CODESET);]])],
3219     emacs_cv_langinfo_codeset=yes,
3220     emacs_cv_langinfo_codeset=no)
3221   ])
3222 if test $emacs_cv_langinfo_codeset = yes; then
3223   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3224     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3225 fi
3226
3227 AC_TYPE_MBSTATE_T
3228
3229 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3230   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3231                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3232 if test "$emacs_cv_c_restrict_arr" = yes; then
3233   AC_DEFINE(__restrict_arr, __restrict,
3234     [Define to compiler's equivalent of C99 restrict keyword in array
3235      declarations.  Define as empty for no equivalent.])
3236 fi
3237
3238 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3239 dnl how the tty code is related to POSIX and/or other versions of termios.
3240 dnl The following looks like a useful start.
3241 dnl
3242 dnl AC_SYS_POSIX_TERMIOS
3243 dnl if test $ac_cv_sys_posix_termios = yes; then
3244 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3245 dnl                                and macros for terminal control.])
3246 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3247 dnl fi
3248
3249 # Set up the CFLAGS for real compilation, so we can substitute it.
3250 CFLAGS="$REAL_CFLAGS"
3251 CPPFLAGS="$REAL_CPPFLAGS"
3252
3253 ## Hack to detect a buggy GCC version.
3254 if test "x$GCC" = xyes \
3255    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3256    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3257    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3258    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3259 fi
3260
3261 version=$PACKAGE_VERSION
3262
3263 ### Specify what sort of things we'll be editing into Makefile and config.h.
3264 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3265 AC_SUBST(version)
3266 AC_SUBST(configuration)
3267 ## Unused?
3268 AC_SUBST(canonical)
3269 AC_SUBST(srcdir)
3270 AC_SUBST(prefix)
3271 AC_SUBST(exec_prefix)
3272 AC_SUBST(bindir)
3273 AC_SUBST(datadir)
3274 AC_SUBST(sharedstatedir)
3275 AC_SUBST(libexecdir)
3276 AC_SUBST(mandir)
3277 AC_SUBST(infodir)
3278 AC_SUBST(lispdir)
3279 AC_SUBST(locallisppath)
3280 AC_SUBST(lisppath)
3281 AC_SUBST(x_default_search_path)
3282 AC_SUBST(etcdir)
3283 AC_SUBST(archlibdir)
3284 AC_SUBST(docdir)
3285 AC_SUBST(bitmapdir)
3286 AC_SUBST(gamedir)
3287 AC_SUBST(gameuser)
3288 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3289 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3290 ## end of LIBX_BASE, but nothing ever set it.
3291 AC_SUBST(LD_SWITCH_X_SITE)
3292 AC_SUBST(C_SWITCH_X_SITE)
3293 AC_SUBST(GNUSTEP_CFLAGS)
3294 AC_SUBST(CFLAGS)
3295 ## Used in lwlib/Makefile.in.
3296 AC_SUBST(X_TOOLKIT_TYPE)
3297 if test -n "${machfile}"; then
3298   M_FILE="\$(srcdir)/${machfile}"
3299 else
3300   M_FILE=
3301 fi
3302 S_FILE="\$(srcdir)/${opsysfile}"
3303 AC_SUBST(M_FILE)
3304 AC_SUBST(S_FILE)
3305 AC_SUBST(ns_appdir)
3306 AC_SUBST(ns_appbindir)
3307 AC_SUBST(ns_appresdir)
3308 AC_SUBST(ns_appsrc)
3309 AC_SUBST(GNU_OBJC_CFLAGS)
3310 AC_SUBST(OTHER_FILES)
3311
3312 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3313                    [Define to the canonical Emacs configuration name.])
3314 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3315                    [Define to the options passed to configure.])
3316 if test -n "$machfile"; then
3317   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3318                      [Define to the used machine dependent file.])
3319 fi
3320 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3321                    [Define to the used os dependent file.])
3322
3323 XMENU_OBJ=
3324 XOBJ=
3325 FONT_OBJ=
3326 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3327   AC_DEFINE(HAVE_X_WINDOWS, 1,
3328             [Define to 1 if you want to use the X window system.])
3329   XMENU_OBJ=xmenu.o
3330   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3331   FONT_OBJ=xfont.o
3332   if test "$HAVE_XFT" = "yes"; then
3333     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3334   elif test "$HAVE_FREETYPE" = "yes"; then
3335     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3336   fi
3337   AC_SUBST(FONT_OBJ)
3338 fi
3339 AC_SUBST(XMENU_OBJ)
3340 AC_SUBST(XOBJ)
3341 AC_SUBST(FONT_OBJ)
3342
3343 WIDGET_OBJ=
3344 MOTIF_LIBW=
3345 if test "${USE_X_TOOLKIT}" != "none" ; then
3346   WIDGET_OBJ=widget.o
3347   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3348   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3349     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3350   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3351     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3352     MOTIF_LIBW=-lXm
3353     case "$opsys" in
3354       gnu-linux)
3355         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3356         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3357         ;;
3358
3359       unixware)
3360         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3361         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3362         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3363         ;;
3364
3365       aix4-2)
3366         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3367         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3368         ;;
3369     esac
3370     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3371   fi
3372 fi
3373 AC_SUBST(WIDGET_OBJ)
3374
3375 TOOLKIT_LIBW=
3376 case "$USE_X_TOOLKIT" in
3377   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3378   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3379   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3380 esac
3381 AC_SUBST(TOOLKIT_LIBW)
3382
3383 if test "$USE_X_TOOLKIT" = "none"; then
3384   LIBXT_OTHER="\$(LIBXSM)"
3385   OLDXMENU_TARGET="really-oldXMenu"
3386 else
3387   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3388   OLDXMENU_TARGET="really-lwlib"
3389 fi
3390 AC_SUBST(LIBXT_OTHER)
3391
3392 ## The X Menu stuff is present in the X10 distribution, but missing
3393 ## from X11.  If we have X10, just use the installed library;
3394 ## otherwise, use our own copy.
3395 if test "${HAVE_X11}" = "yes" ; then
3396   AC_DEFINE(HAVE_X11, 1,
3397             [Define to 1 if you want to use version 11 of X windows.
3398              Otherwise, Emacs expects to use version 10.])
3399
3400   if test "$USE_X_TOOLKIT" = "none"; then
3401     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3402   else
3403     OLDXMENU="\${lwlibdir}/liblw.a"
3404   fi
3405   LIBXMENU="\$(OLDXMENU)"
3406   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3407   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3408 else
3409   ## For a syntactically valid Makefile; not actually used for anything.
3410   ## See comments in src/Makefile.in.
3411   OLDXMENU=nothing
3412   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3413   if test "${HAVE_X_WINDOWS}" = "yes"; then
3414     LIBXMENU="-lXMenu"
3415   else
3416     LIBXMENU=
3417   fi
3418   LIBX_OTHER=
3419   OLDXMENU_DEPS=
3420 fi
3421
3422 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3423   OLDXMENU_TARGET=
3424   OLDXMENU=nothing
3425   LIBXMENU=
3426   OLDXMENU_DEPS=
3427 fi
3428
3429 AC_SUBST(OLDXMENU_TARGET)
3430 AC_SUBST(OLDXMENU)
3431 AC_SUBST(LIBXMENU)
3432 AC_SUBST(LIBX_OTHER)
3433 AC_SUBST(OLDXMENU_DEPS)
3434
3435 if test "${HAVE_MENUS}" = "yes" ; then
3436   AC_DEFINE(HAVE_MENUS, 1,
3437             [Define to 1 if you have mouse menus.
3438              (This is automatic if you use X, but the option to specify it remains.)
3439              It is also defined with other window systems that support xmenu.c.])
3440 fi
3441
3442 if test "${GNU_MALLOC}" = "yes" ; then
3443   AC_DEFINE(GNU_MALLOC, 1,
3444             [Define to 1 if you want to use the GNU memory allocator.])
3445 fi
3446
3447 RALLOC_OBJ=
3448 if test "${REL_ALLOC}" = "yes" ; then
3449   AC_DEFINE(REL_ALLOC, 1,
3450             [Define REL_ALLOC if you want to use the relocating allocator for
3451              buffer space.])
3452
3453   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3454 fi
3455 AC_SUBST(RALLOC_OBJ)
3456
3457 if test "$opsys" = "cygwin"; then
3458   CYGWIN_OBJ="sheap.o"
3459   ## Cygwin differs because of its unexec().
3460   PRE_ALLOC_OBJ=
3461   POST_ALLOC_OBJ=lastfile.o
3462 else
3463   CYGWIN_OBJ=
3464   PRE_ALLOC_OBJ=lastfile.o
3465   POST_ALLOC_OBJ=
3466 fi
3467 AC_SUBST(CYGWIN_OBJ)
3468 AC_SUBST(PRE_ALLOC_OBJ)
3469 AC_SUBST(POST_ALLOC_OBJ)
3470
3471 # Configure gnulib here, now that we know LIBS.
3472 gl_ASSERT_NO_GNULIB_POSIXCHECK
3473 gl_ASSERT_NO_GNULIB_TESTS
3474 gl_INIT
3475
3476 case "$opsys" in
3477   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3478
3479   darwin)
3480    ## The -headerpad option tells ld (see man page) to leave room at the
3481    ## end of the header for adding load commands.  Needed for dumping.
3482    ## 0x690 is the total size of 30 segment load commands (at 56
3483    ## each); under Cocoa 31 commands are required.
3484    if test "$HAVE_NS" = "yes"; then
3485      libs_nsgui="-framework AppKit"
3486      headerpad_extra=6C8
3487    else
3488      libs_nsgui=
3489      headerpad_extra=690
3490    fi
3491    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3492
3493    ## This is here because src/Makefile.in did some extra fiddling around
3494    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3495    ##   #ifndef LD_SWITCH_SYSTEM
3496    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3497    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3498    ## not using gcc, darwin system not on an alpha (ie darwin, since
3499    ## darwin + alpha does not occur).
3500    ## Because this was done in src/Makefile.in, the resulting part of
3501    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3502    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3503    ## rather than LD_SWITCH_SYSTEM.
3504    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3505      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3506    ;;
3507
3508   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3509   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3510   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3511   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3512   ## had different values in configure (in ac_link) and src/Makefile.in.
3513   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3514   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX_RPATH)" ;;
3515
3516   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3517 esac
3518
3519 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3520   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3521 fi
3522
3523 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3524
3525
3526 LD_FIRSTFLAG=
3527 ORDINARY_LINK=
3528 case "$opsys" in
3529   ## gnu: GNU needs its own crt0.
3530   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3531
3532   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3533   ## library search parth, i.e. it won't search /usr/lib for libc and
3534   ## friends.  Using -nostartfiles instead avoids this problem, and
3535   ## will also work on earlier NetBSD releases.
3536   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3537
3538   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3539   ##   MkLinux/LinuxPPC needs this.
3540   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3541   gnu-*)
3542     case "$machine" in
3543       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3544     esac
3545     ;;
3546 esac
3547
3548
3549 if test "x$ORDINARY_LINK" = "xyes"; then
3550
3551   LD_FIRSTFLAG=""
3552   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3553
3554 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3555 ## freebsd, gnu-* not on macppc|ibms390x.
3556 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3557
3558   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3559   ## places that are difficult to figure out at make time.  Fortunately,
3560   ## these same versions allow you to pass arbitrary flags on to the
3561   ## linker, so there is no reason not to use it as a linker.
3562   ##
3563   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3564   ## searching for libraries in its internal directories, so we have to
3565   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3566   LD_FIRSTFLAG="-nostdlib"
3567 fi
3568
3569 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3570 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3571
3572 AC_SUBST(LD_FIRSTFLAG)
3573
3574
3575 ## FIXME? The logic here is not precisely the same as that above.
3576 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3577 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3578 LIB_GCC=
3579 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3580
3581   case "$opsys" in
3582     freebsd|netbsd|openbsd) LIB_GCC= ;;
3583
3584     gnu-*)
3585       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3586       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3587       case $host_cpu in
3588       arm*)
3589         LIB_GCC="-lgcc_s"
3590         ;;
3591       *)
3592         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3593         ## immediately undefine it again and redefine it to empty.
3594         ## Was the C_SWITCH_X_SITE part really necessary?
3595 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3596         LIB_GCC=
3597         ;;
3598       esac
3599       ;;
3600
3601     ## Ask GCC where to find libgcc.a.
3602     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3603   esac
3604 fi                              dnl if $GCC
3605 AC_SUBST(LIB_GCC)
3606
3607
3608 ## If we're using X11/GNUstep, define some consequences.
3609 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3610   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3611   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3612 fi
3613
3614
3615 AH_TOP([/* GNU Emacs site configuration template file.
3616
3617 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3618   Free Software Foundation, Inc.
3619
3620 This file is part of GNU Emacs.
3621
3622 GNU Emacs is free software: you can redistribute it and/or modify
3623 it under the terms of the GNU General Public License as published by
3624 the Free Software Foundation, either version 3 of the License, or
3625 (at your option) any later version.
3626
3627 GNU Emacs is distributed in the hope that it will be useful,
3628 but WITHOUT ANY WARRANTY; without even the implied warranty of
3629 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3630 GNU General Public License for more details.
3631
3632 You should have received a copy of the GNU General Public License
3633 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3634
3635
3636 /* No code in Emacs #includes config.h twice, but some bits of code
3637    intended to work with other packages as well (like gmalloc.c)
3638    think they can include it as many times as they like.  */
3639 #ifndef EMACS_CONFIG_H
3640 #define EMACS_CONFIG_H
3641 ])dnl
3642
3643 AH_BOTTOM([
3644 /* On AIX 3 this must be included before any other include file.  */
3645 #include <alloca.h>
3646 #if ! HAVE_ALLOCA
3647 # error "alloca not available on this machine"
3648 #endif
3649
3650 /* Define AMPERSAND_FULL_NAME if you use the convention
3651    that & in the full name stands for the login id.  */
3652 /* Turned on June 1996 supposing nobody will mind it.  */
3653 #define AMPERSAND_FULL_NAME
3654
3655 /* `subprocesses' should be defined if you want to
3656    have code for asynchronous subprocesses
3657    (as used in M-x compile and M-x shell).
3658    Only MSDOS does not support this (it overrides
3659    this in its config_opsysfile below).  */
3660
3661 #define subprocesses
3662
3663 /* Include the os and machine dependent files.  */
3664 #include config_opsysfile
3665 #ifdef config_machfile
3666 # include config_machfile
3667 #endif
3668
3669 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3670    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3671   (There is probably a better place to do this, but right now the
3672    Cocoa side does this in s/darwin.h and we cannot parallel this
3673    exactly since GNUstep is multi-OS.  */
3674 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3675 #  define SYSTEM_PURESIZE_EXTRA 30000
3676 #endif
3677
3678 #ifdef emacs /* Don't do this for lib-src.  */
3679 /* Tell regex.c to use a type compatible with Emacs.  */
3680 #define RE_TRANSLATE_TYPE Lisp_Object
3681 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3682 #ifdef make_number
3683 /* If make_number is a macro, use it.  */
3684 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3685 #else
3686 /* If make_number is a function, avoid it.  */
3687 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3688 #endif
3689 #endif
3690
3691 /* These default definitions are good for almost all machines.
3692    Any exceptions should override them in m/MACHINE.h.
3693    They must be usable in preprocessor conditionals.  */
3694
3695 #ifndef BITS_PER_CHAR
3696 #define BITS_PER_CHAR 8
3697 #endif
3698
3699 #ifndef BITS_PER_SHORT
3700 #define BITS_PER_SHORT 16
3701 #endif
3702
3703 #ifndef BITS_PER_INT
3704 #define BITS_PER_INT 32
3705 #endif
3706
3707 #ifndef BITS_PER_LONG
3708 #ifdef _LP64
3709 #define BITS_PER_LONG 64
3710 #else
3711 #define BITS_PER_LONG 32
3712 #endif
3713 #endif
3714
3715 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3716 #define BITS_PER_LONG_LONG 64
3717 #endif
3718
3719 /* Define if the compiler supports function prototypes.  It may do so but
3720    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3721 #undef PROTOTYPES
3722
3723 #include <string.h>
3724 #include <stdlib.h>
3725
3726 #if defined __GNUC__ && (__GNUC__ > 2 \
3727                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3728 #define NO_RETURN       __attribute__ ((__noreturn__))
3729 #else
3730 #define NO_RETURN       /* nothing */
3731 #endif
3732
3733 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3734 #define NO_INLINE __attribute__((noinline))
3735 #else
3736 #define NO_INLINE
3737 #endif
3738
3739 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3740 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3741 #else
3742 #define EXTERNALLY_VISIBLE
3743 #endif
3744
3745 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3746 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3747 #else
3748 # define ATTRIBUTE_FORMAT(spec) /* empty */
3749 #endif
3750
3751 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3752 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3753    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3754 #else
3755 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3756    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3757 #endif
3758
3759 /* Some versions of GNU/Linux define noinline in their headers.  */
3760 #ifdef noinline
3761 #undef noinline
3762 #endif
3763
3764 /* These won't be used automatically yet.  We also need to know, at least,
3765    that the stack is continuous.  */
3766 #ifdef __GNUC__
3767 #  ifndef GC_SETJMP_WORKS
3768   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3769 #    define GC_SETJMP_WORKS 1
3770 #  endif
3771 #endif
3772
3773 #endif /* EMACS_CONFIG_H */
3774
3775 /*
3776 Local Variables:
3777 mode: c
3778 End:
3779 */
3780 ])dnl
3781
3782 #### Report on what we decided to do.
3783 #### Report GTK as a toolkit, even if it doesn't use Xt.
3784 #### It makes printing result more understandable as using GTK sets
3785 #### toolkit_scroll_bars to yes by default.
3786 if test "${HAVE_GTK}" = "yes"; then
3787   USE_X_TOOLKIT=GTK
3788 fi
3789
3790 and_machfile=
3791 if test -n "$machfile"; then
3792   and_machfile=" and \`${machfile}'"
3793 fi
3794
3795 echo "
3796 Configured for \`${canonical}'.
3797
3798   Where should the build process find the source code?    ${srcdir}
3799   What operating system and machine description files should Emacs use?
3800         \`${opsysfile}'${and_machfile}
3801   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3802   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3803   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3804   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3805   What window system should Emacs use?                    ${window_system}
3806   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3807
3808 if test -n "${x_includes}"; then
3809 echo "  Where do we find X Windows header files?                ${x_includes}"
3810 else
3811 echo "  Where do we find X Windows header files?                Standard dirs"
3812 fi
3813 if test -n "${x_libraries}"; then
3814 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3815 else
3816 echo "  Where do we find X Windows libraries?                   Standard dirs"
3817 fi
3818
3819 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3820 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3821 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3822 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3823 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3824 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3825 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3826 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3827
3828 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3829 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3830 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3831 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3832 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3833 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3834 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3835
3836 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3837 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3838 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3839 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3840
3841 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3842 echo
3843
3844 if test -n "${EMACSDATA}"; then
3845    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3846 fi
3847 if test -n "${EMACSDOC}"; then
3848    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3849 fi
3850
3851 if test $USE_XASSERTS = yes; then
3852    echo "  Compiling with asserts turned on."
3853    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3854 fi
3855
3856 echo
3857
3858 if test "$HAVE_NS" = "yes"; then
3859    echo
3860    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3861 The installed application will go to nextstep/Emacs.app and can be
3862 run or moved from there."
3863    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3864       echo "The application will be fully self-contained."
3865     else
3866       echo "The lisp resources for the application will be installed under ${prefix}.
3867 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3868 to run if these resources are not installed."
3869    fi
3870    echo
3871 fi
3872
3873 if test "${opsys}" = "cygwin"; then
3874   case `uname -r` in
3875     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3876            echo
3877            ;;
3878   esac
3879 fi
3880
3881 # Remove any trailing slashes in these variables.
3882 [test "${prefix}" != NONE &&
3883   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3884 test "${exec_prefix}" != NONE &&
3885   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3886
3887 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3888 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3889 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3890 dnl (else you get "no `Makefile.am' found for any configure output").
3891 dnl This will work, but you get a config.status that is not quite right
3892 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3893 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3894 dnl it seems better to just live with the duplication.
3895 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3896
3897 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3898        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3899        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3900        leim/Makefile])
3901
3902 dnl test/ is not present in release tarfiles.
3903 opt_makefile=test/automated/Makefile
3904
3905 if test -f $srcdir/${opt_makefile}.in; then
3906   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3907   dnl Again, it's best not to use a variable.  Though you can add
3908   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3909   AC_CONFIG_FILES([test/automated/Makefile])
3910 fi
3911
3912
3913 dnl admin/ may or may not be present.
3914 opt_makefile=admin/unidata/Makefile
3915
3916 if test -f $srcdir/${opt_makefile}.in; then
3917   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3918   AC_CONFIG_FILES([admin/unidata/Makefile])
3919 fi
3920
3921
3922 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3923
3924 AC_SUBST(SUBDIR_MAKEFILES_IN)
3925
3926 dnl Make the necessary directories, if they don't exist.
3927 AC_CONFIG_COMMANDS([mkdirs], [
3928 for dir in etc lisp ; do
3929   test -d ${dir} || mkdir ${dir}
3930 done
3931 ])
3932
3933 dnl You might wonder (I did) why epaths.h is generated by running make,
3934 dnl rather than just letting configure generate it from epaths.in.
3935 dnl One reason is that the various paths are not fully expanded (see above);
3936 dnl eg gamedir=${prefix}/var/games/emacs.
3937 dnl Secondly, the GNU Coding standards require that one should be able
3938 dnl to run `make prefix=/some/where/else' and override the values set
3939 dnl by configure.  This also explains the `move-if-change' test and
3940 dnl the use of force in the `epaths-force' rule in Makefile.in.
3941 AC_CONFIG_COMMANDS([epaths], [
3942 echo creating src/epaths.h
3943 ${MAKE-make} epaths-force
3944 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3945
3946 AC_CONFIG_COMMANDS([gdbinit], [
3947 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3948   echo creating src/.gdbinit
3949   echo source $srcdir/src/.gdbinit > src/.gdbinit
3950 fi
3951 ])
3952
3953 AC_OUTPUT
3954
3955 dnl configure.in ends here