lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999 Free Software Foundation, Inc.
   5
   6 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   7 ;; Maintainer: FSF
   8 ;; Keywords: extensions
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 ;;; PRIVATE: defsubst must be defined before they are first used
  95
  96 (defsubst derived-mode-hook-name (mode)
  97   "Construct the mode hook name based on mode name MODE."
  98   (intern (concat (symbol-name mode) "-hook")))
  99
 100 (defsubst derived-mode-map-name (mode)
 101   "Construct a map name based on a MODE name."
 102   (intern (concat (symbol-name mode) "-map")))
 103
 104 (defsubst derived-mode-syntax-table-name (mode)
 105   "Construct a syntax-table name based on a MODE name."
 106   (intern (concat (symbol-name mode) "-syntax-table")))
 107
 108 (defsubst derived-mode-abbrev-table-name (mode)
 109   "Construct an abbrev-table name based on a MODE name."
 110   (intern (concat (symbol-name mode) "-abbrev-table")))
 111
 112 ;; PUBLIC: define a new major mode which inherits from an existing one.
 113
 114 ;;;###autoload
 115 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 116   "Create a new mode as a variant of an existing mode.
 117
 118 The arguments to this command are as follow:
 119
 120 CHILD:     the name of the command for the derived mode.
 121 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 122            or nil if there is no parent.
 123 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 124 DOCSTRING: an optional documentation string--if you do not supply one,
 125            the function will attempt to invent something useful.
 126 BODY:      forms to execute just before running the
 127            hooks for the new mode.
 128
 129 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 130
 131   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 132
 133 You could then make new key bindings for `LaTeX-thesis-mode-map'
 134 without changing regular LaTeX mode.  In this example, BODY is empty,
 135 and DOCSTRING is generated by default.
 136
 137 On a more complicated level, the following command uses `sgml-mode' as
 138 the parent, and then sets the variable `case-fold-search' to nil:
 139
 140   (define-derived-mode article-mode sgml-mode \"Article\"
 141     \"Major mode for editing technical articles.\"
 142     (setq case-fold-search nil))
 143
 144 Note that if the documentation string had been left out, it would have
 145 been generated automatically, with a reference to the keymap."
 146
 147   (when (and docstring (not (stringp docstring)))
 148     ;; Some trickiness, since what appears to be the docstring may really be
 149     ;; the first element of the body.
 150     (push docstring body)
 151     (setq docstring nil))
 152
 153   (when (eq parent 'fundamental-mode) (setq parent nil))
 154
 155   (let ((map (derived-mode-map-name child))
 156         (syntax (derived-mode-syntax-table-name child))
 157         (abbrev (derived-mode-abbrev-table-name child))
 158         (hook (derived-mode-hook-name child))
 159         (docstring (derived-mode-make-docstring parent child docstring)))
 160
 161     `(progn
 162        (defvar ,map (make-sparse-keymap))
 163        (defvar ,syntax (make-syntax-table))
 164        (defvar ,abbrev)
 165        (define-abbrev-table ',abbrev nil)
 166        (put ',child 'derived-mode-parent ',parent)
 167
 168        (defun ,child ()
 169          ,docstring
 170          (interactive)
 171                                         ; Run the parent.
 172          (delay-mode-hooks
 173
 174           (,(or parent 'kill-all-local-variables))
 175                                         ; Identify the child mode.
 176           (setq major-mode (quote ,child))
 177           (setq mode-name ,name)
 178                                         ; Identify special modes.
 179           ,(when parent
 180              `(progn
 181                 (if (get (quote ,parent) 'special)
 182                     (put (quote ,child) 'special t))
 183                                         ; Set up maps and tables.
 184                 (unless (keymap-parent ,map)
 185                   (set-keymap-parent ,map (current-local-map)))
 186                 (let ((parent (char-table-parent ,syntax)))
 187                   (unless (and parent (not (eq parent (standard-syntax-table))))
 188                     (set-char-table-parent ,syntax (syntax-table))))
 189                 (when local-abbrev-table
 190                   (mapatoms
 191                    (lambda (symbol)
 192                      (or (intern-soft (symbol-name symbol) ,abbrev)
 193                          (define-abbrev ,abbrev (symbol-name symbol)
 194                            (symbol-value symbol) (symbol-function symbol))))
 195                    local-abbrev-table))))
 196
 197           (use-local-map ,map)
 198           (set-syntax-table ,syntax)
 199           (setq local-abbrev-table ,abbrev)
 200                                         ; Splice in the body (if any).
 201           ,@body
 202           )
 203                                         ; Run the hooks, if any.
 204          (run-mode-hooks ',hook)))))
 205
 206 ;; PUBLIC: find if the current mode derives from another.
 207
 208 ;;; ;;;###autoload
 209 (defun derived-mode-p (&rest modes)
 210   "Non-nil if the current major mode is derived from one of MODES.
 211 Uses the `derived-mode-parent' property of the symbol to trace backwards."
 212   (let ((parent major-mode))
 213     (while (and (not (memq parent modes))
 214                 (setq parent (get parent 'derived-mode-parent))))
 215     parent))
 216
 217 ;; PUBLIC: find the ultimate class of a derived mode.
 218
 219 (defun derived-mode-class (mode)
 220   "Find the class of a major MODE.
 221 A mode's class is the first ancestor which is NOT a derived mode.
 222 Use the `derived-mode-parent' property of the symbol to trace backwards.
 223 Since major-modes might derive from each other and from `fundamental-mode',
 224 this function is not very useful.  Use `derived-mode-p' instead."
 225   (while (get mode 'derived-mode-parent)
 226     (setq mode (get mode 'derived-mode-parent)))
 227   mode)
 228
 229 \f
 230 ;;; PRIVATE
 231
 232 (defun derived-mode-make-docstring (parent child &optional docstring)
 233   "Construct a docstring for a new mode if none is provided."
 234
 235   (let ((map (derived-mode-map-name child))
 236         (syntax (derived-mode-syntax-table-name child))
 237         (abbrev (derived-mode-abbrev-table-name child))
 238         (hook (derived-mode-hook-name child)))
 239
 240     (unless (stringp docstring)
 241       ;; Use a default docstring.
 242       (setq docstring
 243             (if (null parent)
 244                 (format "Major-mode.
 245 Uses keymap `%s', abbrev table `%s' and syntax-table `%s'." map abbrev syntax)
 246               (format "Major mode derived from `%s' by `define-derived-mode'.
 247 It inherits all of the parent's attributes, but has its own keymap,
 248 abbrev table and syntax table:
 249
 250   `%s', `%s' and `%s'
 251
 252 which more-or-less shadow %s's corresponding tables."
 253                       parent map abbrev syntax parent))))
 254
 255     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 256       ;; Make sure the docstring mentions the mode's hook
 257       (setq docstring
 258             (concat docstring
 259                     (if (null parent)
 260                         "\n\nThis mode "
 261                       (concat
 262                        "\n\nIn addition to any hooks its parent mode "
 263                        (if (string-match (regexp-quote (format "`%s'" parent))
 264                                          docstring) nil
 265                          (format "`%s' " parent))
 266                        "might have run,\nthis mode "))
 267                     (format "runs the hook `%s'" hook)
 268                     ", as the final step\nduring initialization.")))
 269
 270     (unless (string-match "\\\\[{[]" docstring)
 271       ;; And don't forget to put the mode's keymap
 272       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 273
 274     docstring))
 275
 276 \f
 277 ;;; OBSOLETE
 278 ;; The functions below are only provided for backward compatibility with
 279 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 280
 281 (defsubst derived-mode-setup-function-name (mode)
 282   "Construct a setup-function name based on a MODE name."
 283   (intern (concat (symbol-name mode) "-setup")))
 284
 285 \f
 286 ;; Utility functions for defining a derived mode.
 287
 288 ;;;###autoload
 289 (defun derived-mode-init-mode-variables (mode)
 290   "Initialise variables for a new MODE.
 291 Right now, if they don't already exist, set up a blank keymap, an
 292 empty syntax table, and an empty abbrev table -- these will be merged
 293 the first time the mode is used."
 294
 295   (if (boundp (derived-mode-map-name mode))
 296       t
 297     (eval `(defvar ,(derived-mode-map-name mode)
 298                (make-sparse-keymap)
 299                ,(format "Keymap for %s." mode)))
 300     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 301
 302   (if (boundp (derived-mode-syntax-table-name mode))
 303       t
 304     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 305              ;; Make a syntax table which doesn't specify anything
 306              ;; for any char.  Valid data will be merged in by
 307              ;; derived-mode-merge-syntax-tables.
 308              (make-char-table 'syntax-table nil)
 309              ,(format "Syntax table for %s." mode)))
 310     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 311
 312   (if (boundp (derived-mode-abbrev-table-name mode))
 313       t
 314     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 315              (progn
 316                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 317                (make-abbrev-table))
 318              ,(format "Abbrev table for %s." mode)))))
 319 \f
 320 ;; Utility functions for running a derived mode.
 321
 322 (defun derived-mode-set-keymap (mode)
 323   "Set the keymap of the new MODE, maybe merging with the parent."
 324   (let* ((map-name (derived-mode-map-name mode))
 325          (new-map (eval map-name))
 326          (old-map (current-local-map)))
 327     (and old-map
 328          (get map-name 'derived-mode-unmerged)
 329          (derived-mode-merge-keymaps old-map new-map))
 330     (put map-name 'derived-mode-unmerged nil)
 331     (use-local-map new-map)))
 332
 333 (defun derived-mode-set-syntax-table (mode)
 334   "Set the syntax table of the new MODE, maybe merging with the parent."
 335   (let* ((table-name (derived-mode-syntax-table-name mode))
 336          (old-table (syntax-table))
 337          (new-table (eval table-name)))
 338     (if (get table-name 'derived-mode-unmerged)
 339         (derived-mode-merge-syntax-tables old-table new-table))
 340     (put table-name 'derived-mode-unmerged nil)
 341     (set-syntax-table new-table)))
 342
 343 (defun derived-mode-set-abbrev-table (mode)
 344   "Set the abbrev table for MODE if it exists.
 345 Always merge its parent into it, since the merge is non-destructive."
 346   (let* ((table-name (derived-mode-abbrev-table-name mode))
 347          (old-table local-abbrev-table)
 348          (new-table (eval table-name)))
 349     (derived-mode-merge-abbrev-tables old-table new-table)
 350     (setq local-abbrev-table new-table)))
 351
 352 ;;;(defun derived-mode-run-setup-function (mode)
 353 ;;;  "Run the setup function if it exists."
 354
 355 ;;;  (let ((fname (derived-mode-setup-function-name mode)))
 356 ;;;    (if (fboundp fname)
 357 ;;;     (funcall fname))))
 358
 359 (defun derived-mode-run-hooks (mode)
 360   "Run the mode hook for MODE."
 361   (let ((hooks-name (derived-mode-hook-name mode)))
 362     (if (boundp hooks-name)
 363         (run-hooks hooks-name))))
 364
 365 ;; Functions to merge maps and tables.
 366
 367 (defun derived-mode-merge-keymaps (old new)
 368   "Merge an OLD keymap into a NEW one.
 369 The old keymap is set to be the last cdr of the new one, so that there will
 370 be automatic inheritance."
 371   ;; ?? Can this just use `set-keymap-parent'?
 372   (let ((tail new))
 373     ;; Scan the NEW map for prefix keys.
 374     (while (consp tail)
 375       (and (consp (car tail))
 376            (let* ((key (vector (car (car tail))))
 377                   (subnew (lookup-key new key))
 378                   (subold (lookup-key old key)))
 379              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 380              (and (keymapp subnew) (keymapp subold)
 381                   (derived-mode-merge-keymaps subold subnew))))
 382       (and (vectorp (car tail))
 383            ;; Search a vector of ASCII char bindings for prefix keys.
 384            (let ((i (1- (length (car tail)))))
 385              (while (>= i 0)
 386                (let* ((key (vector i))
 387                       (subnew (lookup-key new key))
 388                       (subold (lookup-key old key)))
 389                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 390                  (and (keymapp subnew) (keymapp subold)
 391                       (derived-mode-merge-keymaps subold subnew)))
 392                (setq i (1- i)))))
 393       (setq tail (cdr tail))))
 394   (setcdr (nthcdr (1- (length new)) new) old))
 395
 396 (defun derived-mode-merge-syntax-tables (old new)
 397   "Merge an OLD syntax table into a NEW one.
 398 Where the new table already has an entry, nothing is copied from the old one."
 399   (set-char-table-parent new old))
 400
 401 ;; Merge an old abbrev table into a new one.
 402 ;; This function requires internal knowledge of how abbrev tables work,
 403 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 404 ;; as the value of the symbol, and the hook as the function definition.
 405 (defun derived-mode-merge-abbrev-tables (old new)
 406   (if old
 407       (mapatoms
 408        (lambda (symbol)
 409          (or (intern-soft (symbol-name symbol) new)
 410              (define-abbrev new (symbol-name symbol)
 411                (symbol-value symbol) (symbol-function symbol))))
 412        old)))
 413
 414 (provide 'derived)
 415
 416 ;;; derived.el ends here