lisp/international/isearch-x.el

   1 ;;; isearch-x.el --- extended isearch handling commands
   2
   3 ;; Copyright (C) 1995 Electrotechnical Laboratory, JAPAN.
   4 ;; Licensed to the Free Software Foundation.
   5 ;; Copyright (C) 2001 Free Software Foundation, Inc.
   6
   7 ;; Keywords: multilingual, isearch
   8
   9 ;; Author: Kenichi HANDA <handa@etl.go.jp>
  10 ;; Maintainer: Kenichi HANDA <handa@etl.go.jp>
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28
  29 ;;; Commentary:
  30
  31 ;;; Code:
  32
  33 ;;;###autoload
  34 (defun isearch-toggle-specified-input-method ()
  35   "Select an input method and turn it on in interactive search."
  36   (interactive)
  37   (let ((overriding-terminal-local-map nil))
  38     (toggle-input-method t))
  39   (setq isearch-input-method-function input-method-function
  40         isearch-input-method-local-p t)
  41   (setq input-method-function nil)
  42   (isearch-update))
  43
  44 ;;;###autoload
  45 (defun isearch-toggle-input-method ()
  46   "Toggle input method in interactive search."
  47   (interactive)
  48   (let ((overriding-terminal-local-map nil))
  49     (toggle-input-method))
  50   (setq isearch-input-method-function input-method-function
  51         isearch-input-method-local-p t)
  52   (setq input-method-function nil)
  53   (isearch-update))
  54
  55 (defvar isearch-minibuffer-local-map
  56   (let ((map (copy-keymap minibuffer-local-map)))
  57     (define-key map [with-keyboard-coding] 'isearch-with-keyboard-coding)
  58     (define-key map [with-input-method] 'isearch-with-input-method)
  59     map)
  60   "Keymap to use in minibuffer for multibyte character inputting in isearch.")
  61
  62 ;; Exit from recursive edit safely.  Set in `after-change-functions'
  63 ;; by isearch-with-keyboard-coding.
  64 (defun isearch-exit-recursive-edit (start end length)
  65   (interactive)
  66   (throw 'exit nil))
  67
  68 ;; Simulate character decoding by the keyboard coding system in the
  69 ;; current buffer (minibuffer).  As soon as a character is inserted,
  70 ;; it exits from minibuffer.
  71
  72 (defun isearch-with-keyboard-coding ()
  73   (interactive)
  74   (let ((after-change-functions '(isearch-exit-recursive-edit)))
  75     (recursive-edit))
  76   (exit-minibuffer))
  77
  78 ;; Simulate the work of the current input method in the current buffer
  79 ;; (minibuffer).
  80
  81 (defun isearch-with-input-method ()
  82   (interactive)
  83   (let ((key (car unread-command-events))
  84         events)
  85     (setq unread-command-events (cdr unread-command-events)
  86           events (funcall input-method-function key))
  87     ;; EVENTS is a list of events the input method has generated.  It
  88     ;; contains a character event and/or the special event
  89     ;; `compose-last-chars'.  We extract only character events and
  90     ;; insert the corresponding characters.
  91     (while events
  92       (if (integerp (car events)) (insert (car events)))
  93       (setq events (cdr events)))
  94     (exit-minibuffer)))
  95
  96 ;;;###autoload
  97 (defun isearch-process-search-multibyte-characters (last-char)
  98   (if (eq this-command 'isearch-printing-char)
  99       (let ((overriding-terminal-local-map nil)
 100             (prompt (concat (isearch-message-prefix) isearch-message))
 101             (minibuffer-local-map isearch-minibuffer-local-map)
 102             str)
 103         (if isearch-input-method-function
 104             (let (;; Let input method work rather tersely.
 105                   (input-method-verbose-flag nil))
 106               (setq unread-command-events
 107                     (cons 'with-input-method
 108                           (cons last-char unread-command-events))
 109                     ;; Inherit current-input-method in a minibuffer.
 110                     str (read-string prompt nil nil nil t))
 111               (if (not str)
 112                   ;; All inputs were deleted while the input method
 113                   ;; was working.
 114                   (setq str "")
 115                 (if (and (= (length str) 1)
 116                          (= (aref str 0) last-char)
 117                          (>= last-char 128))
 118                     ;; The input method couldn't handle LAST-CHAR.
 119                     (setq str nil)))))
 120
 121         (if (and (not str) (keyboard-coding-system))
 122             (setq unread-command-events
 123                   (cons 'with-keyboard-coding
 124                         (cons last-char unread-command-events))
 125                   str (read-string prompt)))
 126
 127         (if (and str (> (length str) 0))
 128             (let ((unread-command-events nil))
 129               (isearch-process-search-string str str))
 130           (isearch-update)))
 131     (isearch-process-search-char last-char)))
 132
 133 ;;; isearch-x.el ends here