configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 standardlisppath='${lispdir}:${leimdir}'
  42 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  43 '${datadir}/emacs/site-lisp'
  44 lisppath='${locallisppath}:${standardlisppath}'
  45 etcdir='${datadir}/emacs/${version}/etc'
  46 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  47 docdir='${datadir}/emacs/${version}/etc'
  48 gamedir='${localstatedir}/games/emacs'
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 151 if test "$with_wide_int" = yes; then
 152   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 153 fi
 154
 155 dnl _ON results in a '--without' option in the --help output, so
 156 dnl the help text should refer to "don't compile", etc.
 157 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 158 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 159 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 160 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 161 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 162 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 163 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 164 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 165
 166 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 167 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 168 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 169
 170 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 171 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 172 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 173 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 174
 175 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 176 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 177 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 178 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 179 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 180 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 181
 182 ## For the times when you want to build Emacs but don't have
 183 ## a suitable makeinfo, and can live without the manuals.
 184 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 185 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 186
 187 ## Makefile.in needs the cache file name.
 188 AC_SUBST(cache_file)
 189
 190 ## This is an option because I do not know if all info/man support
 191 ## compressed files, nor how to test if they do so.
 192 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 193 if test $with_compress_info = yes; then
 194    GZIP_INFO=yes
 195 else
 196    GZIP_INFO=
 197 fi
 198 AC_SUBST(GZIP_INFO)
 199
 200 AC_ARG_WITH([pkg-config-prog],dnl
 201 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 202                   [path to pkg-config for finding GTK and librsvg])])
 203 if test "X${with_pkg_config_prog}" != X; then
 204    if test "${with_pkg_config_prog}" != yes; then
 205       PKG_CONFIG="${with_pkg_config_prog}"
 206    fi
 207 fi
 208
 209 CRT_DIR=
 210 AC_ARG_WITH([crt-dir],dnl
 211 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 212 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 213 CRT_DIR="${with_crt_dir}"
 214
 215 AC_ARG_WITH(gameuser,dnl
 216 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 217 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 218   && gameuser="${with_gameuser}"
 219 test "X$gameuser" = X && gameuser=games
 220
 221 AC_ARG_WITH([gnustep-conf],dnl
 222 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 223 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 224   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 225 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 226      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 227
 228 AC_ARG_ENABLE(ns-self-contained,
 229 [AS_HELP_STRING([--disable-ns-self-contained],
 230                 [disable self contained build under NeXTstep])],
 231    EN_NS_SELF_CONTAINED=$enableval,
 232    EN_NS_SELF_CONTAINED=yes)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist, glyphs])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;
 264                         ac_glyphs_debug= ;;
 265         all)            ac_enable_checking=1 ;
 266                         ac_gc_check_stringbytes=1 ;
 267                         ac_gc_check_string_overrun=1 ;
 268                         ac_gc_check_string_free_list=1 ;
 269                         ac_xmalloc_overrun=1 ;
 270                         ac_gc_check_cons_list=1 ;
 271                         ac_glyphs_debug=1 ;;
 272         # these enable particular checks
 273         stringbytes)    ac_gc_check_stringbytes=1 ;;
 274         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 275         stringfreelist) ac_gc_check_string_free_list=1 ;;
 276         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 277         conslist)       ac_gc_check_cons_list=1 ;;
 278         glyphs)         ac_glyphs_debug=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_string_overrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310 if test x$ac_glyphs_debug != x ; then
 311   AC_DEFINE(GLYPH_DEBUG, 1,
 312 [Define this to enable glyphs debugging code.])
 313 fi
 314
 315 AC_ARG_ENABLE(check-lisp-object-type,
 316 [AS_HELP_STRING([--enable-check-lisp-object-type],
 317                 [enable compile time checks for the Lisp_Object data type.
 318                 This is useful for development for catching certain types of bugs.])],
 319 if test "${enableval}" != "no"; then
 320    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 321    [Define this to enable compile time checks for the Lisp_Object data type.])
 322 fi)
 323
 324
 325 AC_ARG_ENABLE(profiling,
 326 [AS_HELP_STRING([--enable-profiling],
 327                 [build emacs with profiling support.
 328                  This might not work on all platforms])],
 329 [ac_enable_profiling="${enableval}"],[])
 330 if test x$ac_enable_profiling != x ; then
 331    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 332 else
 333    PROFILING_CFLAGS=
 334 fi
 335 AC_SUBST(PROFILING_CFLAGS)
 336
 337 AC_ARG_ENABLE(autodepend,
 338 [AS_HELP_STRING([--enable-autodepend],
 339                 [automatically generate dependencies to .h-files.
 340                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 341                  found])],
 342 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 343
 344 #### Make srcdir absolute, if it isn't already.  It's important to
 345 #### avoid running the path through pwd unnecessarily, since pwd can
 346 #### give you automounter prefixes, which can go away.  We do all this
 347 #### so Emacs can find its files when run uninstalled.
 348 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 349 unset CDPATH
 350 case "${srcdir}" in
 351   /* ) ;;
 352   . )
 353     ## We may be able to use the $PWD environment variable to make this
 354     ## absolute.  But sometimes PWD is inaccurate.
 355     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 356     ## but that tested only for a well-formed and valid PWD,
 357     ## it did not object when PWD was well-formed and valid but just wrong.
 358     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 359     then
 360       srcdir="$PWD"
 361     else
 362       srcdir="`(cd ${srcdir}; pwd)`"
 363     fi
 364   ;;
 365   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 366 esac
 367
 368 #### Given the configuration name, set opsysfile to the
 369 #### name of s/*.h file we should use.
 370
 371 ### Canonicalize the configuration name.
 372
 373 AC_CANONICAL_HOST
 374 canonical=$host
 375 configuration=${host_alias-${build_alias-$host}}
 376
 377 dnl This used to use changequote, but, apart from `changequote is evil'
 378 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 379 dnl the great gob of text.  Thus it's not processed for possible expansion.
 380 dnl Just make sure the brackets remain balanced.
 381 dnl
 382 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 383 dnl indicated by comments.
 384 dnl quotation begins
 385 [
 386
 387 ### If you add support for a new configuration, add code to this
 388 ### switch statement to recognize your configuration name and select
 389 ### the appropriate operating system file.
 390
 391 ### You would hope that you could choose an s/*.h
 392 ### file based on the operating system portion.  However, it turns out
 393 ### that each s/*.h file is pretty manufacturer-specific.
 394 ### So we basically have to have a special case for each
 395 ### configuration name.
 396 ###
 397 ### As far as handling version numbers on operating systems is
 398 ### concerned, make sure things will fail in a fixable way.  If
 399 ### /etc/MACHINES doesn't say anything about version numbers, be
 400 ### prepared to handle anything reasonably.  If version numbers
 401 ### matter, be sure /etc/MACHINES says something about it.
 402
 403 opsys='' unported=no
 404 case "${canonical}" in
 405
 406   ## GNU/Linux and similar ports
 407   *-*-linux* )
 408     opsys=gnu-linux
 409   ;;
 410
 411   ## FreeBSD ports
 412   *-*-freebsd* )
 413     opsys=freebsd
 414   ;;
 415
 416   ## FreeBSD kernel + glibc based userland
 417   *-*-kfreebsd*gnu* )
 418     opsys=gnu-kfreebsd
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424   ;;
 425
 426   ## OpenBSD ports
 427   *-*-openbsd* )
 428     opsys=openbsd
 429   ;;
 430
 431   ## Apple Darwin / Mac OS X
 432   *-apple-darwin* )
 433     case "${canonical}" in
 434       i[3456]86-* )  ;;
 435       powerpc-* )    ;;
 436       x86_64-* )     ;;
 437       * )            unported=yes ;;
 438     esac
 439     opsys=darwin
 440     ## Use fink packages if available.
 441     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 442 ##    if test -d /sw/include && test -d /sw/lib; then
 443 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 444 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 445 ##    fi
 446   ;;
 447
 448   ## HP 9000 series 700 and 800, running HP/UX
 449   hppa*-hp-hpux10.2* )
 450     opsys=hpux10-20
 451   ;;
 452   hppa*-hp-hpux1[1-9]* )
 453     opsys=hpux11
 454     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 455   ;;
 456
 457   ## IBM machines
 458   rs6000-ibm-aix4.[23]* )
 459     opsys=aix4-2
 460   ;;
 461   powerpc-ibm-aix4.[23]*  )
 462     opsys=aix4-2
 463   ;;
 464   rs6000-ibm-aix[56]* )
 465     opsys=aix4-2
 466   ;;
 467   powerpc-ibm-aix[56]*  )
 468     opsys=aix4-2
 469   ;;
 470
 471   ## Silicon Graphics machines
 472   ## Iris 4D
 473   mips-sgi-irix6.5 )
 474     opsys=irix6-5
 475     # Without defining _LANGUAGE_C, things get masked out in the headers
 476     # so that, for instance, grepping for `free' in stdlib.h fails and
 477     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 478     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 479   ;;
 480
 481   ## Suns
 482   *-sun-solaris* \
 483     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 484     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 485     case "${canonical}" in
 486       i[3456]86-*-* )   ;;
 487       amd64-*-*|x86_64-*-*) ;;
 488       sparc* )          ;;
 489       * )               unported=yes ;;
 490     esac
 491     case "${canonical}" in
 492       *-sunos5.6* | *-solaris2.6* )
 493                 opsys=sol2-6
 494                 RANLIB="ar -ts"
 495                 ;;
 496       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 497                 opsys=sol2-6
 498                 emacs_check_sunpro_c=yes
 499                 ;;
 500       *-sunos5* | *-solaris* )
 501                 opsys=sol2-10
 502                 emacs_check_sunpro_c=yes
 503                 ;;
 504     esac
 505     ## Watch out for a compiler that we know will not work.
 506     case "${canonical}" in
 507      *-solaris* | *-sunos5* )
 508                 if [ "x$CC" = x/usr/ucb/cc ]; then
 509                   ## /usr/ucb/cc doesn't work;
 510                   ## we should find some other compiler that does work.
 511                   unset CC
 512                 fi
 513                 ;;
 514       *) ;;
 515     esac
 516   ;;
 517
 518   ## Intel 386 machines where we don't care about the manufacturer.
 519   i[3456]86-*-* )
 520     case "${canonical}" in
 521       *-cygwin )                opsys=cygwin ;;
 522       *-darwin* )               opsys=darwin ;;
 523       *-sysv4.2uw* )            opsys=unixware ;;
 524       *-sysv5uw* )              opsys=unixware ;;
 525       *-sysv5OpenUNIX* )        opsys=unixware ;;
 526       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 527     esac
 528   ;;
 529
 530   * )
 531     unported=yes
 532   ;;
 533 esac
 534
 535 ### If the code above didn't choose an operating system, just choose
 536 ### an operating system based on the configuration name.  You really
 537 ### only want to use this when you have no idea what the right
 538 ### operating system is; if you know what operating systems a machine
 539 ### runs, it's cleaner to make it explicit in the case statement
 540 ### above.
 541 if test x"${opsys}" = x; then
 542   case "${canonical}" in
 543     *-gnu* )                            opsys=gnu ;;
 544     * )
 545       unported=yes
 546     ;;
 547   esac
 548 fi
 549
 550 ]
 551 dnl quotation ends
 552
 553 if test $unported = yes; then
 554   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 555 Check `etc/MACHINES' for recognized configuration names.])
 556 fi
 557
 558 opsysfile="s/${opsys}.h"
 559
 560
 561 #### Choose a compiler.
 562
 563 dnl Sets GCC=yes if using gcc.
 564 AC_PROG_CC
 565 AM_PROG_CC_C_O
 566
 567 if test x$GCC = xyes; then
 568   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 569 else
 570   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 571 fi
 572
 573 # Initialize gnulib right after choosing the compiler.
 574 gl_EARLY
 575
 576 AC_ARG_ENABLE([gcc-warnings],
 577   [AS_HELP_STRING([--enable-gcc-warnings],
 578                   [turn on lots of GCC warnings. This is intended for
 579                    developers, and may generate false alarms when used
 580                    with older or non-GNU development tools.])],
 581   [case $enableval in
 582      yes|no) ;;
 583      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 584    esac
 585    gl_gcc_warnings=$enableval],
 586   [gl_gcc_warnings=no]
 587 )
 588
 589 AC_ARG_ENABLE(link-time-optimization,
 590 [AS_HELP_STRING([--enable-link-time-optimization],
 591                 [build emacs with link-time optimization.
 592                  This is supported only for GCC since 4.5.0.])],
 593 if test "${enableval}" != "no"; then
 594    AC_MSG_CHECKING([whether link-time optimization is supported])
 595    ac_lto_supported=no
 596    if test x$GCC = xyes; then
 597       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 598       if test x$CPUS != x; then
 599          LTO="-flto=$CPUS"
 600       else
 601          LTO="-flto"
 602       fi
 603       old_CFLAGS=$CFLAGS
 604       CFLAGS="$CFLAGS $LTO"
 605       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 606         [ac_lto_supported=yes], [ac_lto_supported=no])
 607       CFLAGS="$old_CFLAGS"
 608    fi
 609    AC_MSG_RESULT([$ac_lto_supported])
 610    if test "$ac_lto_supported" = "yes"; then
 611       CFLAGS="$CFLAGS $LTO"
 612    fi
 613 fi)
 614
 615 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 616 # ------------------------------------------------
 617 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 618 # Otherwise, run RUN-IF-NOT-FOUND.
 619 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 620   [AC_PREPROC_IFELSE(
 621     [AC_LANG_PROGRAM(
 622       [[
 623 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 624 /* ok */
 625 #else
 626 # error "your version of gcc is older than $1.$2"
 627 #endif
 628       ]]),
 629     ], [$3], [$4])
 630   ]
 631 )
 632
 633 # When compiling with GCC, prefer -isystem to -I when including system
 634 # include files, to avoid generating useless diagnostics for the files.
 635 if test "$gl_gcc_warnings" != yes; then
 636   isystem='-I'
 637 else
 638   isystem='-isystem '
 639
 640   # This, $nw, is the list of warnings we disable.
 641   nw=
 642
 643   case $with_x_toolkit in
 644     lucid | athena | motif)
 645        # Old toolkits mishandle 'const'.
 646        nw="$nw -Wwrite-strings"
 647        ;;
 648     *)
 649        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 650        ;;
 651   esac
 652   AC_SUBST([WERROR_CFLAGS])
 653
 654   nw="$nw -Waggregate-return"       # anachronistic
 655   nw="$nw -Wlong-long"              # C90 is anachronistic
 656   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 657   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 658   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 659   nw="$nw -Wcast-qual"              # Too many warnings for now
 660   nw="$nw -Wconversion"             # Too many warnings for now
 661   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 662   nw="$nw -Wsign-conversion"        # Too many warnings for now
 663   nw="$nw -Woverlength-strings"     # Not a problem these days
 664   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 665   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 666   nw="$nw -Wpadded"                 # Our structs are not padded
 667   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 668   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 669   nw="$nw -Wformat-nonliteral"      # we do this a lot
 670   nw="$nw -Wvla"                    # warnings in gettext.h
 671   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 672   nw="$nw -Wswitch-enum"            # Too many warnings for now
 673   nw="$nw -Wswitch-default"         # Too many warnings for now
 674   nw="$nw -Wfloat-equal"            # warns about high-quality code
 675   nw="$nw -Winline"                 # OK to ignore 'inline'
 676   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 677   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 678
 679   # Emacs doesn't care about shadowing; see
 680   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 681   nw="$nw -Wshadow"
 682
 683   # The following lines should be removable at some point.
 684   nw="$nw -Wstack-protector"
 685   nw="$nw -Wstrict-overflow"
 686   nw="$nw -Wsuggest-attribute=pure"
 687
 688   gl_MANYWARN_ALL_GCC([ws])
 689   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 690   for w in $ws; do
 691     gl_WARN_ADD([$w])
 692   done
 693   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 694   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 695   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 696   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 697   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 698   gl_WARN_ADD([-Wno-format-nonliteral])
 699
 700   # In spite of excluding -Wlogical-op above, it is enabled, as of
 701   # gcc 4.5.0 20090517.
 702   gl_WARN_ADD([-Wno-logical-op])
 703
 704   gl_WARN_ADD([-fdiagnostics-show-option])
 705   gl_WARN_ADD([-funit-at-a-time])
 706
 707   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 708   AC_DEFINE([_FORTIFY_SOURCE], [2],
 709     [enable compile-time and run-time bounds-checking, and some warnings])
 710   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 711
 712   # We use a slightly smaller set of warning options for lib/.
 713   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 714   nw=
 715   nw="$nw -Wunused-macros"
 716
 717   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 718   AC_SUBST([GNULIB_WARN_CFLAGS])
 719 fi
 720
 721
 722
 723 dnl Some other nice autoconf tests.
 724 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 725 dnl AC_PROG_INSTALL
 726 dnl AC_PROG_MKDIR_P
 727 dnl if test "x$RANLIB" = x; then
 728 dnl   AC_PROG_RANLIB
 729 dnl fi
 730
 731 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 732   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 733 dnl Don't use GZIP, which is used by gzip for additional parameters.
 734 AC_PATH_PROG(GZIP_PROG, gzip)
 735
 736 if test $opsys = gnu-linux; then
 737   AC_PATH_PROG(PAXCTL, paxctl,,
 738     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 739 fi
 740
 741 ## Need makeinfo >= 4.7 (?) to build the manuals.
 742 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 743 dnl By this stage, configure has already checked for egrep and set EGREP,
 744 dnl or exited with an error if no egrep was found.
 745 if test "$MAKEINFO" != "no" && \
 746   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 747    MAKEINFO=no
 748 fi
 749
 750 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 751 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 752 ## therefore in the category of "special tools" not normally required, which
 753 ## configure does not have to check for (eg autoconf itself).
 754 ## In a Bazaar checkout on the other hand, the manuals are not included.
 755 ## So makeinfo is a requirement to build from Bazaar, and configure
 756 ## should test for it as it does for any other build requirement.
 757 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 758 ## with pre-built manuals, from a Bazaar checkout.
 759 HAVE_MAKEINFO=yes
 760
 761 if test "$MAKEINFO" = "no"; then
 762   MAKEINFO=makeinfo
 763   if test "x${with_makeinfo}" = "xno"; then
 764     HAVE_MAKEINFO=no
 765   elif test ! -e $srcdir/info/emacs; then
 766     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 767 source tree does not seem to have pre-built manuals in the `info' directory.
 768 Either install a suitable version of makeinfo, or re-run configure
 769 with the `--without-makeinfo' option to build without the manuals.] )
 770   fi
 771 fi
 772 AC_SUBST(HAVE_MAKEINFO)
 773
 774 dnl Just so that there is only a single place we need to edit.
 775 INFO_EXT=.info
 776 INFO_OPTS=--no-split
 777 AC_SUBST(INFO_EXT)
 778 AC_SUBST(INFO_OPTS)
 779
 780 dnl Add our options to ac_link now, after it is set up.
 781
 782 if test x$GCC = xyes; then
 783   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 784     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 785 else
 786   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 787     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 788 fi
 789
 790 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 791 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 792 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 793 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 794 dnl if not built to support GNU ld.
 795
 796 late_LDFLAGS=$LDFLAGS
 797 if test x$GCC = xyes; then
 798   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 799 else
 800   LDFLAGS="$LDFLAGS -znocombreloc"
 801 fi
 802
 803 AC_MSG_CHECKING([for -znocombreloc])
 804 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 805   [AC_MSG_RESULT(yes)],
 806   LDFLAGS=$late_LDFLAGS
 807   [AC_MSG_RESULT(no)])
 808
 809
 810 dnl The function dump-emacs will not be defined and temacs will do
 811 dnl (load "loadup") automatically unless told otherwise.
 812 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 813 case "$opsys" in
 814   your-opsys-here) CANNOT_DUMP=yes ;;
 815 esac
 816
 817 test "$CANNOT_DUMP" = "yes" && \
 818   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 819
 820 AC_SUBST(CANNOT_DUMP)
 821
 822
 823 UNEXEC_OBJ=unexelf.o
 824 case "$opsys" in
 825   # MSDOS uses unexcoff.o
 826   # MSWindows uses unexw32.o
 827   aix4-2)
 828    UNEXEC_OBJ=unexaix.o
 829    ;;
 830   cygwin)
 831    UNEXEC_OBJ=unexcw.o
 832    ;;
 833   darwin)
 834    UNEXEC_OBJ=unexmacosx.o
 835    ;;
 836   hpux10-20 | hpux11)
 837    UNEXEC_OBJ=unexhp9k800.o
 838    ;;
 839   sol2-10)
 840    # Use the Solaris dldump() function, called from unexsol.c, to dump
 841    # emacs, instead of the generic ELF dump code found in unexelf.c.
 842    # The resulting binary has a complete symbol table, and is better
 843    # for debugging and other observability tools (debuggers, pstack, etc).
 844    #
 845    # If you encounter a problem using dldump(), please consider sending
 846    # a message to the OpenSolaris tools-linking mailing list:
 847    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 848    #
 849    # It is likely that dldump() works with older Solaris too, but this has
 850    # not been tested, so for now this change is for Solaris 10 or newer.
 851    UNEXEC_OBJ=unexsol.o
 852    ;;
 853 esac
 854
 855 LD_SWITCH_SYSTEM=
 856 case "$opsys" in
 857   freebsd)
 858    ## Let `ld' find image libs and similar things in /usr/local/lib.
 859    ## The system compiler, GCC, has apparently been modified to not
 860    ## look there, contrary to what a stock GCC would do.
 861 ### It's not our place to do this.  See bug#10313#17.
 862 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 863       :
 864    ;;
 865
 866   gnu-linux)
 867    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 868    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 869    ;;
 870
 871   netbsd)
 872 ### It's not our place to do this.  See bug#10313#17.
 873 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 874       :
 875    ;;
 876
 877   openbsd)
 878    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 879    ## otherwise Emacs dumps core on elf systems.
 880    LD_SWITCH_SYSTEM="-Z"
 881    ;;
 882 esac
 883 AC_SUBST(LD_SWITCH_SYSTEM)
 884
 885 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 886
 887 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 888 ## which has not been defined yet.  When this was handled with cpp,
 889 ## it was expanded to null when configure sourced the s/*.h file.
 890 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 891 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 892 ## (or somesuch), but because it is supposed to go at the _front_
 893 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 894 ## Compare with the gnu-linux case below, which added to the end
 895 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 896 ## LD_SWITCH_SYSTEM_TEMACS.
 897 case "$opsys" in
 898   netbsd|openbsd)
 899    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 900 esac
 901
 902
 903 C_SWITCH_MACHINE=
 904 case $canonical in
 905  alpha*)
 906   AC_CHECK_DECL([__ELF__])
 907   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 908     ## With ELF, make sure that all common symbols get allocated to in the
 909     ## data section.  Otherwise, the dump of temacs may miss variables in
 910     ## the shared library that have been initialized.  For example, with
 911     ## GNU libc, __malloc_initialized would normally be resolved to the
 912     ## shared library's .bss section, which is fatal.
 913     if test "x$GCC" = "xyes"; then
 914       C_SWITCH_MACHINE="-fno-common"
 915     else
 916       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 917     fi
 918   else
 919     UNEXEC_OBJ=unexalpha.o
 920   fi
 921   ;;
 922 esac
 923 AC_SUBST(C_SWITCH_MACHINE)
 924
 925 AC_SUBST(UNEXEC_OBJ)
 926
 927 C_SWITCH_SYSTEM=
 928 ## Some programs in src produce warnings saying certain subprograms
 929 ## are too complex and need a MAXMEM value greater than 2000 for
 930 ## additional optimization.  --nils@exp-math.uni-essen.de
 931 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 932   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 933 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 934 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 935 AC_SUBST(C_SWITCH_SYSTEM)
 936
 937
 938 LIBS_SYSTEM=
 939 case "$opsys" in
 940   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 941   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 942
 943   freebsd) LIBS_SYSTEM="-lutil" ;;
 944
 945   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 946
 947   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 948
 949   ## Motif needs -lgen.
 950   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 951 esac
 952 AC_SUBST(LIBS_SYSTEM)
 953
 954
 955 ### Make sure subsequent tests use flags consistent with the build flags.
 956
 957 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 958   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 959 else
 960   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 961 fi
 962
 963 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 964 AC_DEFUN([AC_TYPE_SIZE_T])
 965 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 966 AC_DEFUN([AC_TYPE_UID_T])
 967
 968
 969 LIB_MATH=-lm
 970 LIB_STANDARD=
 971 START_FILES=
 972 dnl Current possibilities handled by sed (aix4-2 -> aix,
 973 dnl gnu-linux -> gnu/linux, etc.):
 974 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 975 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 976 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 977
 978 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 979 case $opsys in
 980   cygwin )
 981     LIB_MATH=
 982     START_FILES='pre-crt0.o'
 983     ;;
 984   darwin )
 985     ## Adding -lm confuses the dynamic linker, so omit it.
 986     LIB_MATH=
 987     START_FILES='pre-crt0.o'
 988     ;;
 989   freebsd )
 990     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 991     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 992     SYSTEM_TYPE=berkeley-unix
 993     ;;
 994   gnu-linux | gnu-kfreebsd )
 995     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 996     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 997     ;;
 998   hpux10-20 | hpux11 )
 999     LIB_STANDARD=-lc
1000     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1001     ;;
1002   dnl NB this may be adjusted below.
1003   netbsd | openbsd )
1004     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1005     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1006     SYSTEM_TYPE=berkeley-unix
1007     ;;
1008
1009   sol2* | unixware )
1010     SYSTEM_TYPE=usg-unix-v
1011     ;;
1012
1013 esac
1014
1015 AC_SUBST(LIB_MATH)
1016 AC_SUBST(START_FILES)
1017 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1018   [The type of system you are compiling for; sets `system-type'.])
1019
1020 dnl Not all platforms use crtn.o files.  Check if the current one does.
1021 crt_files=
1022
1023 for file in x $LIB_STANDARD $START_FILES; do
1024   case "$file" in
1025     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1026   esac
1027 done
1028
1029 if test "x$crt_files" != x; then
1030
1031   ## If user specified a crt-dir, use that unconditionally.
1032   crt_gcc=no
1033
1034   if test "X$CRT_DIR" = "X"; then
1035
1036     CRT_DIR=/usr/lib            # default
1037
1038     case "$canonical" in
1039       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1040       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1041       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1042       ## For anything else (eg /usr/lib32), it is up the user to specify
1043       ## the location (bug#5655).
1044       ## Test for crtn.o, not just the directory, because sometimes the
1045       ## directory exists but does not have the relevant files (bug#1287).
1046       ## FIXME better to test for binary compatibility somehow.
1047       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1048       ;;
1049
1050       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1051     esac
1052
1053     case "$opsys" in
1054       hpux10-20) CRT_DIR=/lib ;;
1055     esac
1056
1057     test "x${GCC}" = xyes && crt_gcc=yes
1058
1059   fi                            # CRT_DIR = ""
1060
1061   crt_missing=
1062
1063   for file in $crt_files; do
1064
1065     ## If we're using gcc, try to determine it automatically by asking
1066     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1067     ## system-dependent default from above.]
1068     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1069
1070        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1071        case "$crt_file" in
1072          */*)
1073            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1074            ;;
1075        esac
1076     fi
1077
1078     dnl We expect all the files to be in a single directory, so after the
1079     dnl first there is no point asking gcc.
1080     crt_gcc=no
1081
1082     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1083   done                          # $crt_files
1084
1085   test "x$crt_missing" = x || \
1086     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1087 Try using the --with-crt-dir option.])
1088
1089 fi                              # crt_files != ""
1090
1091 AC_SUBST(CRT_DIR)
1092
1093 case $opsys in
1094   netbsd | openbsd )
1095     if test -f $CRT_DIR/crti.o; then
1096
1097         test -f $CRT_DIR/crtn.o || \
1098           AC_MSG_ERROR([Required file not found: crtn.o])
1099
1100         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1101         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1102     fi
1103     ;;
1104 esac
1105
1106
1107 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1108 pre_PKG_CONFIG_LIBS=$LIBS
1109
1110 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1111
1112 dnl This function definition taken from Gnome 2.0
1113 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1114 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1115 dnl also defines GSTUFF_PKG_ERRORS on error
1116 AC_DEFUN([PKG_CHECK_MODULES], [
1117   succeeded=no
1118
1119   if test "$PKG_CONFIG" = "no" ; then
1120      ifelse([$4], , [AC_MSG_ERROR([
1121       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1122   else
1123      PKG_CONFIG_MIN_VERSION=0.9.0
1124      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1125         AC_MSG_CHECKING(for $2)
1126
1127         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1128            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1129            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1130             edit_cflags="
1131               s,///*,/,g
1132               s/^/ /
1133               s/ -I/ $isystem/g
1134               s/^ //
1135             "
1136             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1137             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1138             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1139             succeeded=yes
1140         else
1141             AC_MSG_RESULT(no)
1142             $1_CFLAGS=""
1143             $1_LIBS=""
1144             ## If we have a custom action on failure, don't print errors, but
1145             ## do set a variable so people can do so.
1146             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1147             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1148         fi
1149
1150         AC_SUBST($1_CFLAGS)
1151         AC_SUBST($1_LIBS)
1152      else
1153         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1154         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1155      fi
1156   fi
1157
1158   if test $succeeded = yes; then
1159      ifelse([$3], , :, [$3])
1160   else
1161      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1162   fi
1163 ])
1164
1165
1166 if test "${with_sound}" != "no"; then
1167   # Sound support for GNU/Linux and the free BSDs.
1168   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1169     have_sound_header=yes)
1170   # Emulation library used on NetBSD.
1171   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1172   AC_SUBST(LIBSOUND)
1173
1174   ALSA_REQUIRED=1.0.0
1175   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1176   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1177   if test $HAVE_ALSA = yes; then
1178     SAVE_CFLAGS="$CFLAGS"
1179     SAVE_LIBS="$LIBS"
1180     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1181     LIBS="$ALSA_LIBS $LIBS"
1182     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1183                     emacs_alsa_normal=yes,
1184                     emacs_alsa_normal=no)
1185     if test "$emacs_alsa_normal" != yes; then
1186       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1187                      [[snd_lib_error_set_handler (0);]])],
1188                      emacs_alsa_subdir=yes,
1189                      emacs_alsa_subdir=no)
1190       if test "$emacs_alsa_subdir" != yes; then
1191         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1192       fi
1193       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1194     fi
1195
1196     CFLAGS="$SAVE_CFLAGS"
1197     LIBS="$SAVE_LIBS"
1198     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1199     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1200     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1201   fi
1202
1203   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1204   dnl compiles only on the specified platforms.  For others, it
1205   dnl probably doesn't make sense to try.
1206   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1207      case "$opsys" in
1208        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1209        gnu-linux|freebsd|netbsd)
1210          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1211          ;;
1212      esac
1213   fi
1214
1215   AC_SUBST(CFLAGS_SOUND)
1216 fi
1217
1218 dnl checks for header files
1219 AC_CHECK_HEADERS_ONCE(
1220   linux/version.h sys/systeminfo.h
1221   stdio_ext.h fcntl.h coff.h pty.h
1222   sys/vlimit.h sys/resource.h
1223   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1224
1225 AC_MSG_CHECKING(if personality LINUX32 can be set)
1226 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1227                emacs_cv_personality_linux32=yes,
1228                emacs_cv_personality_linux32=no)
1229 AC_MSG_RESULT($emacs_cv_personality_linux32)
1230
1231 if test $emacs_cv_personality_linux32 = yes; then
1232   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1233             [Define to 1 if personality LINUX32 can be set.])
1234 fi
1235
1236 dnl On Solaris 8 there's a compilation warning for term.h because
1237 dnl it doesn't define `bool'.
1238 AC_CHECK_HEADERS(term.h, , , -)
1239 AC_HEADER_TIME
1240 AC_CHECK_DECLS([sys_siglist])
1241 if test $ac_cv_have_decl_sys_siglist != yes; then
1242   # For Tru64, at least:
1243   AC_CHECK_DECLS([__sys_siglist])
1244   if test $ac_cv_have_decl___sys_siglist = yes; then
1245     AC_DEFINE(sys_siglist, __sys_siglist,
1246               [Define to any substitute for sys_siglist.])
1247   fi
1248 fi
1249 AC_HEADER_SYS_WAIT
1250
1251 dnl Check for speed_t typedef.
1252 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1253   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1254     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1255 if test $emacs_cv_speed_t = yes; then
1256   AC_DEFINE(HAVE_SPEED_T, 1,
1257            [Define to 1 if `speed_t' is declared by <termios.h>.])
1258 fi
1259
1260 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1261 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1262 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1263   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1264 HAVE_EXCEPTION=$emacs_cv_struct_exception
1265 dnl Define on Darwin so emacs symbols will not conflict with those
1266 dnl in the System framework.  Otherwise -prebind will not work.
1267 if test $emacs_cv_struct_exception != yes || test $opsys = darwin; then
1268   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1269 fi
1270
1271 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1272 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1273 #if HAVE_SYS_SOCKET_H
1274 #include <sys/socket.h>
1275 #endif])
1276 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1277 #if HAVE_SYS_SOCKET_H
1278 #include <sys/socket.h>
1279 #endif])
1280 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1281 #if HAVE_SYS_SOCKET_H
1282 #include <sys/socket.h>
1283 #endif])
1284
1285 dnl checks for structure members
1286 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1287                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1288                   struct ifreq.ifr_addr,
1289                   struct ifreq.ifr_addr.sa_len], , ,
1290                  [AC_INCLUDES_DEFAULT
1291 #if HAVE_SYS_SOCKET_H
1292 #include <sys/socket.h>
1293 #endif
1294 #if HAVE_NET_IF_H
1295 #include <net/if.h>
1296 #endif])
1297
1298 dnl Check for endianness.
1299 dnl AC_C_BIGENDIAN is done by gnulib.
1300
1301 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1302   [emacs_cv_attribute_aligned],
1303   [AC_COMPILE_IFELSE(
1304      [AC_LANG_PROGRAM(
1305         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1306         [[]])],
1307      [emacs_cv_attribute_aligned=yes],
1308      [emacs_cv_attribute_aligned=no])])
1309 if test $emacs_cv_attribute_aligned = yes; then
1310   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1311     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1312 fi
1313
1314 dnl check for Make feature
1315 dnl AC_PROG_MAKE_SET is done by Automake.
1316
1317 DEPFLAGS=
1318 MKDEPDIR=":"
1319 deps_frag=deps.mk
1320 dnl check for GNU Make if we have GCC and autodepend is on.
1321 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1322    AC_MSG_CHECKING([whether we are using GNU Make])
1323    HAVE_GNU_MAKE=no
1324    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1325    if test "x$testval" != x; then
1326       HAVE_GNU_MAKE=yes
1327    else
1328       ac_enable_autodepend=no
1329    fi
1330    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1331    if test $HAVE_GNU_MAKE = yes; then
1332       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1333       SAVE_CFLAGS="$CFLAGS"
1334       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1335       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1336       CFLAGS="$SAVE_CFLAGS"
1337       test -f deps.d || ac_enable_autodepend=no
1338       rm -rf deps.d
1339       AC_MSG_RESULT([$ac_enable_autodepend])
1340    fi
1341    if test $ac_enable_autodepend = yes; then
1342       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1343       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1344       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1345       deps_frag=autodeps.mk
1346    fi
1347 fi
1348 deps_frag=$srcdir/src/$deps_frag
1349 AC_SUBST(MKDEPDIR)
1350 AC_SUBST(DEPFLAGS)
1351 AC_SUBST_FILE(deps_frag)
1352
1353
1354 lisp_frag=$srcdir/src/lisp.mk
1355 AC_SUBST_FILE(lisp_frag)
1356
1357
1358 dnl checks for operating system services
1359 AC_SYS_LONG_FILE_NAMES
1360
1361 #### Choose a window system.
1362
1363 AC_PATH_X
1364 if test "$no_x" = yes; then
1365   window_system=none
1366 else
1367   window_system=x11
1368 fi
1369
1370 LD_SWITCH_X_SITE_RPATH=
1371 if test "${x_libraries}" != NONE; then
1372   if test -n "${x_libraries}"; then
1373     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1374     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1375   fi
1376   x_default_search_path=""
1377   x_search_path=${x_libraries}
1378   if test -z "${x_search_path}"; then
1379     x_search_path=/usr/lib
1380   fi
1381   for x_library in `echo ${x_search_path}: | \
1382                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1383     x_search_path="\
1384 ${x_library}/X11/%L/%T/%N%C%S:\
1385 ${x_library}/X11/%l/%T/%N%C%S:\
1386 ${x_library}/X11/%T/%N%C%S:\
1387 ${x_library}/X11/%L/%T/%N%S:\
1388 ${x_library}/X11/%l/%T/%N%S:\
1389 ${x_library}/X11/%T/%N%S"
1390     if test x"${x_default_search_path}" = x; then
1391       x_default_search_path=${x_search_path}
1392     else
1393       x_default_search_path="${x_search_path}:${x_default_search_path}"
1394     fi
1395   done
1396 fi
1397 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1398
1399 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1400   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1401 fi
1402
1403 if test x"${x_includes}" = x; then
1404   bitmapdir=/usr/include/X11/bitmaps
1405 else
1406   # accumulate include directories that have X11 bitmap subdirectories
1407   bmd_acc="dummyval"
1408   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1409     if test -d "${bmd}/X11/bitmaps"; then
1410       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1411     fi
1412     if test -d "${bmd}/bitmaps"; then
1413       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1414     fi
1415   done
1416   if test ${bmd_acc} != "dummyval"; then
1417     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1418   fi
1419 fi
1420
1421 HAVE_NS=no
1422 NS_IMPL_COCOA=no
1423 NS_IMPL_GNUSTEP=no
1424 tmp_CPPFLAGS="$CPPFLAGS"
1425 tmp_CFLAGS="$CFLAGS"
1426 CPPFLAGS="$CPPFLAGS -x objective-c"
1427 CFLAGS="$CFLAGS -x objective-c"
1428 TEMACS_LDFLAGS2="\${LDFLAGS}"
1429 GNU_OBJC_CFLAGS=
1430 if test "${with_ns}" != no; then
1431   if test "${opsys}" = darwin; then
1432      NS_IMPL_COCOA=yes
1433      ns_appdir=`pwd`/nextstep/Emacs.app
1434      ns_appbindir=${ns_appdir}/Contents/MacOS
1435      ns_appresdir=${ns_appdir}/Contents/Resources
1436      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1437   elif test -f $GNUSTEP_CONFIG_FILE; then
1438      NS_IMPL_GNUSTEP=yes
1439      ns_appdir=`pwd`/nextstep/Emacs.app
1440      ns_appbindir=${ns_appdir}
1441      ns_appresdir=${ns_appdir}/Resources
1442      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1443      dnl FIXME sourcing this several times in subshells seems inefficient.
1444      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1445      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1446      dnl I seemed to need these as well with GNUstep-startup 0.25.
1447      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1448      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1449      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1450        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1451      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1452        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1453      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1454      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1455      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1456      LIB_STANDARD=
1457      START_FILES=
1458      TEMACS_LDFLAGS2=
1459      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1460      dnl If they had chosen to either define it or not, we could have
1461      dnl just used AC_CHECK_DECL here.
1462      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1463        emacs_cv_objc_exceptions,
1464 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1465 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1466 1;
1467 #else
1468 fail;
1469 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1470      if test $emacs_cv_objc_exceptions = yes; then
1471        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1472        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1473          [Define if GNUstep uses ObjC exceptions.])
1474        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1475      fi
1476   fi
1477
1478   dnl This is only used while we test the NS headers, it gets reset below.
1479   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1480
1481   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1482                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1483   files are missing or cannot be compiled.])])
1484   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1485                                      [NSInteger i;])],
1486                     ns_have_nsinteger=yes,
1487                     ns_have_nsinteger=no)
1488   if test $ns_have_nsinteger = yes; then
1489     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1490   fi
1491 fi
1492 AC_SUBST(TEMACS_LDFLAGS2)
1493
1494 INSTALL_ARCH_INDEP_EXTRA=install-etc
1495 ns_self_contained=no
1496 ns_frag=/dev/null
1497 NS_OBJ=
1498 NS_OBJC_OBJ=
1499 if test "${HAVE_NS}" = yes; then
1500   if test "$with_toolkit_scroll_bars" = "no"; then
1501     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1502   fi
1503
1504   window_system=nextstep
1505   with_xft=no
1506   # set up packaging dirs
1507   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1508      ns_self_contained=yes
1509      prefix=${ns_appresdir}
1510      exec_prefix=${ns_appbindir}
1511      dnl This one isn't really used, only archlibdir is.
1512      libexecdir="\${ns_appbindir}/libexec"
1513      archlibdir="\${ns_appbindir}/libexec"
1514      docdir="\${ns_appresdir}/etc"
1515      etcdir="\${ns_appresdir}/etc"
1516      dnl FIXME maybe set datarootdir instead.
1517      dnl That would also get applications, icons, man.
1518      infodir="\${ns_appresdir}/info"
1519      mandir="\${ns_appresdir}/man"
1520      lispdir="\${ns_appresdir}/lisp"
1521      leimdir="\${ns_appresdir}/leim"
1522      INSTALL_ARCH_INDEP_EXTRA=
1523   fi
1524   ns_frag=$srcdir/src/ns.mk
1525   NS_OBJ="fontset.o fringe.o image.o"
1526   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1527 fi
1528 CFLAGS="$tmp_CFLAGS"
1529 CPPFLAGS="$tmp_CPPFLAGS"
1530 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1531 AC_SUBST(ns_self_contained)
1532 AC_SUBST(NS_OBJ)
1533 AC_SUBST(NS_OBJC_OBJ)
1534 AC_SUBST(LIB_STANDARD)
1535 AC_SUBST_FILE(ns_frag)
1536
1537 case "${window_system}" in
1538   x11 )
1539     HAVE_X_WINDOWS=yes
1540     HAVE_X11=yes
1541     case "${with_x_toolkit}" in
1542       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1543       motif ) USE_X_TOOLKIT=MOTIF ;;
1544       gtk ) with_gtk=yes
1545 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1546 dnl USE_X_TOOLKIT is set.
1547             USE_X_TOOLKIT=none ;;
1548       gtk3 ) with_gtk3=yes
1549              USE_X_TOOLKIT=none ;;
1550       no ) USE_X_TOOLKIT=none ;;
1551 dnl If user did not say whether to use a toolkit, make this decision later:
1552 dnl use the toolkit if we have gtk, or X11R5 or newer.
1553       * ) USE_X_TOOLKIT=maybe ;;
1554     esac
1555   ;;
1556   nextstep | none )
1557     HAVE_X_WINDOWS=no
1558     HAVE_X11=no
1559     USE_X_TOOLKIT=none
1560   ;;
1561 esac
1562
1563 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1564    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1565    if test "$HAVE_XSERVER" = true ||
1566       test -n "$DISPLAY" ||
1567       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1568         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1569 were found.  You should install the relevant development files for X
1570 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1571 sure you have development files for image handling, i.e.
1572 tiff, gif, jpeg, png and xpm.
1573 If you are sure you want Emacs compiled without X window support, pass
1574   --without-x
1575 to configure.])
1576    fi
1577 fi
1578
1579 ### If we're using X11, we should use the X menu package.
1580 HAVE_MENUS=no
1581 case ${HAVE_X11} in
1582   yes ) HAVE_MENUS=yes ;;
1583 esac
1584
1585 # Does the opsystem file prohibit the use of the GNU malloc?
1586 # Assume not, until told otherwise.
1587 GNU_MALLOC=yes
1588
1589 AC_CACHE_CHECK(
1590   [whether malloc is Doug Lea style],
1591   [emacs_cv_var_doug_lea_malloc],
1592   [AC_LINK_IFELSE(
1593      [AC_LANG_PROGRAM(
1594         [[#include <malloc.h>
1595           static void hook (void) {}]],
1596         [[malloc_set_state (malloc_get_state ());
1597           __after_morecore_hook = hook;
1598           __malloc_initialize_hook = hook;]])],
1599      [emacs_cv_var_doug_lea_malloc=yes],
1600      [emacs_cv_var_doug_lea_malloc=no])])
1601 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1602
1603
1604 dnl See comments in aix4-2.h about maybe using system malloc there.
1605 system_malloc=no
1606 case "$opsys" in
1607   ## darwin ld insists on the use of malloc routines in the System framework.
1608   darwin|sol2-10) system_malloc=yes ;;
1609 esac
1610
1611 if test "${system_malloc}" = "yes"; then
1612   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1613   GNU_MALLOC=no
1614   GNU_MALLOC_reason="
1615     (The GNU allocators don't work with this system configuration.)"
1616   GMALLOC_OBJ=
1617   VMLIMIT_OBJ=
1618 else
1619   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1620   VMLIMIT_OBJ=vm-limit.o
1621 fi
1622 AC_SUBST(GMALLOC_OBJ)
1623 AC_SUBST(VMLIMIT_OBJ)
1624
1625 if test "$doug_lea_malloc" = "yes" ; then
1626   if test "$GNU_MALLOC" = yes ; then
1627     GNU_MALLOC_reason="
1628       (Using Doug Lea's new malloc from the GNU C Library.)"
1629   fi
1630   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1631             [Define to 1 if you are using the GNU C Library.])
1632
1633   ## Use mmap directly for allocating larger buffers.
1634   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1635   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1636   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1637   case "$opsys" in
1638     gnu*) REL_ALLOC=no ;;
1639   esac
1640 fi
1641
1642 if test x"${REL_ALLOC}" = x; then
1643   REL_ALLOC=${GNU_MALLOC}
1644 fi
1645
1646 use_mmap_for_buffers=no
1647 case "$opsys" in
1648   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1649 esac
1650
1651 AC_FUNC_MMAP
1652 if test $use_mmap_for_buffers = yes; then
1653   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1654   REL_ALLOC=no
1655 fi
1656
1657 LIBS="$LIBS_SYSTEM $LIBS"
1658
1659 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1660 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1661 AC_CHECK_LIB(dnet, dnet_ntoa)
1662 dnl This causes -lresolv to get used in subsequent tests,
1663 dnl which causes failures on some systems such as HPUX 9.
1664 dnl AC_CHECK_LIB(resolv, gethostbyname)
1665
1666 dnl FIXME replace main with a function we actually want from this library.
1667 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1668
1669 dnl Check if pthreads is available.
1670 LIB_PTHREAD=
1671 AC_CHECK_HEADERS_ONCE(pthread.h)
1672 if test "$ac_cv_header_pthread_h"; then
1673   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1674   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1675   dnl testing for pthread_self if Emacs uses gmalloc.c.
1676   if test "$GMALLOC_OBJ" = gmalloc.o; then
1677     emacs_pthread_function=pthread_atfork
1678   else
1679     emacs_pthread_function=pthread_self
1680   fi
1681   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1682 fi
1683 if test "$HAVE_PTHREAD" = yes; then
1684   case "${canonical}" in
1685     *-hpux*) ;;
1686     *) LIB_PTHREAD="-lpthread"
1687        LIBS="$LIB_PTHREAD $LIBS" ;;
1688   esac
1689   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1690 fi
1691 AC_SUBST([LIB_PTHREAD])
1692
1693 AC_CHECK_LIB(pthreads, cma_open)
1694
1695 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1696 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1697 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1698 ## added to LIBS in configure would never contain the pthreads part,
1699 ## but the value used in Makefiles might.  FIXME?
1700 ##
1701 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1702 ## be harmless on older versions of X where it happens to exist.
1703 test "$opsys" = "aix4-2" && \
1704   test $ac_cv_lib_pthreads_cma_open = yes && \
1705   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1706
1707 dnl Check for need for bigtoc support on IBM AIX
1708
1709 case ${host_os} in
1710 aix*)
1711   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1712     case $GCC in
1713     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1714     *) gdb_cv_bigtoc=-bbigtoc ;;
1715     esac
1716
1717     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1718     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1719   ])
1720   ;;
1721 esac
1722
1723 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1724 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1725 # REAL_CPPFLAGS later on.
1726
1727 REAL_CFLAGS="$CFLAGS"
1728 REAL_CPPFLAGS="$CPPFLAGS"
1729
1730 if test "${HAVE_X11}" = "yes"; then
1731   DEFS="$C_SWITCH_X_SITE $DEFS"
1732   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1733   LIBS="-lX11 $LIBS"
1734   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1735   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1736
1737   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1738   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1739   # but it's more convenient here to set LD_RUN_PATH since this
1740   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1741   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1742     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1743     export LD_RUN_PATH
1744   fi
1745
1746   if test "${opsys}" = "gnu-linux"; then
1747     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1748     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1749      [[XOpenDisplay ("foo");]])],
1750      [xgnu_linux_first_failure=no],
1751      [xgnu_linux_first_failure=yes])
1752     if test "${xgnu_linux_first_failure}" = "yes"; then
1753       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1754       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1755       OLD_CPPFLAGS="$CPPFLAGS"
1756       OLD_LIBS="$LIBS"
1757       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1758       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1759       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1760       LIBS="$LIBS -b i486-linuxaout"
1761       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1762        [[XOpenDisplay ("foo");]])],
1763        [xgnu_linux_second_failure=no],
1764        [xgnu_linux_second_failure=yes])
1765       if test "${xgnu_linux_second_failure}" = "yes"; then
1766         # If we get the same failure with -b, there is no use adding -b.
1767         # So take it out.  This plays safe.
1768         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1769         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1770         CPPFLAGS="$OLD_CPPFLAGS"
1771         LIBS="$OLD_LIBS"
1772         AC_MSG_RESULT(no)
1773       else
1774         AC_MSG_RESULT(yes)
1775       fi
1776     else
1777       AC_MSG_RESULT(no)
1778     fi
1779   fi
1780
1781   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1782   # header files included from there.
1783   AC_MSG_CHECKING(for Xkb)
1784   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1785 #include <X11/XKBlib.h>]],
1786         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1787         emacs_xkb=yes, emacs_xkb=no)
1788   AC_MSG_RESULT($emacs_xkb)
1789   if test $emacs_xkb = yes; then
1790     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1791   fi
1792
1793   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1794 XScreenNumberOfScreen)
1795 fi
1796
1797 if test "${window_system}" = "x11"; then
1798   AC_MSG_CHECKING(X11 version 6)
1799   AC_CACHE_VAL(emacs_cv_x11_version_6,
1800   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1801 [[#if XlibSpecificationRelease < 6
1802 fail;
1803 #endif
1804 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1805   if test $emacs_cv_x11_version_6 = yes; then
1806     AC_MSG_RESULT(6 or newer)
1807     AC_DEFINE(HAVE_X11R6, 1,
1808               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1809     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1810     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1811     ## XIM support.
1812     case "$opsys" in
1813       sol2-*) : ;;
1814       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1815            [Define if you have usable X11R6-style XIM support.])
1816          ;;
1817     esac
1818   else
1819     AC_MSG_RESULT(before 6)
1820   fi
1821 fi
1822
1823
1824 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1825 HAVE_RSVG=no
1826 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1827   if test "${with_rsvg}" != "no"; then
1828     RSVG_REQUIRED=2.11.0
1829     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1830
1831     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1832     AC_SUBST(RSVG_CFLAGS)
1833     AC_SUBST(RSVG_LIBS)
1834
1835     if test $HAVE_RSVG = yes; then
1836       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1837       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1838       LIBS="$RSVG_LIBS $LIBS"
1839     fi
1840   fi
1841 fi
1842
1843 HAVE_IMAGEMAGICK=no
1844 if test "${HAVE_X11}" = "yes"; then
1845   if test "${with_imagemagick}" != "no"; then
1846     ## 6.2.8 is the earliest version known to work, but earlier versions
1847     ## might work - let us know if you find one.
1848     ## 6.0.7 does not work.  See bug#7955.
1849     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1850     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1851     AC_SUBST(IMAGEMAGICK_CFLAGS)
1852     AC_SUBST(IMAGEMAGICK_LIBS)
1853
1854     if test $HAVE_IMAGEMAGICK = yes; then
1855       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1856       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1857       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1858       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1859     fi
1860   fi
1861 fi
1862
1863
1864 HAVE_GTK=no
1865 GTK_OBJ=
1866 if test "${with_gtk3}" = "yes"; then
1867   GLIB_REQUIRED=2.28
1868   GTK_REQUIRED=3.0
1869   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1870
1871   dnl Checks for libraries.
1872   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1873   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1874      AC_MSG_ERROR($GTK_PKG_ERRORS)
1875   fi
1876   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1877   GTK_OBJ=emacsgtkfixed.o
1878 fi
1879
1880 if test "$pkg_check_gtk" != "yes"; then
1881   HAVE_GTK=no
1882 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1883   GLIB_REQUIRED=2.10
1884   GTK_REQUIRED=2.10
1885   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1886
1887   dnl Checks for libraries.
1888   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1889   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1890      AC_MSG_ERROR($GTK_PKG_ERRORS)
1891   fi
1892 fi
1893 fi
1894
1895 if test x"$pkg_check_gtk" = xyes; then
1896
1897   AC_SUBST(GTK_CFLAGS)
1898   AC_SUBST(GTK_LIBS)
1899   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1900   CFLAGS="$CFLAGS $GTK_CFLAGS"
1901   LIBS="$GTK_LIBS $LIBS"
1902   dnl Try to compile a simple GTK program.
1903   GTK_COMPILES=no
1904   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1905   if test "${GTK_COMPILES}" != "yes"; then
1906     if test "$USE_X_TOOLKIT" != "maybe"; then
1907       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1908     fi
1909   else
1910     HAVE_GTK=yes
1911     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1912     GTK_OBJ="gtkutil.o $GTK_OBJ"
1913     USE_X_TOOLKIT=none
1914     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1915       :
1916     else
1917       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1918        closing open displays.  This is no problem if you just use
1919        one display, but if you use more than one and close one of them
1920        Emacs may crash.]])
1921       sleep 3
1922     fi
1923   fi
1924
1925 fi
1926 AC_SUBST(GTK_OBJ)
1927
1928
1929 if test "${HAVE_GTK}" = "yes"; then
1930
1931   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1932   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1933   if test "$with_toolkit_scroll_bars" != no; then
1934     with_toolkit_scroll_bars=yes
1935   fi
1936
1937   dnl  Check if we have the old file selection dialog declared and
1938   dnl  in the link library.  In 2.x it may be in the library,
1939   dnl  but not declared if deprecated featured has been selected out.
1940   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1941   HAVE_GTK_FILE_SELECTION=no
1942   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1943                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1944 #include <gtk/gtk.h>])
1945   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1946     AC_CHECK_FUNCS(gtk_file_selection_new)
1947   fi
1948
1949
1950   dnl Check for functions introduced in 2.14 and later.
1951   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1952                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1953                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1954                  gtk_orientable_set_orientation \
1955                  gtk_window_set_has_resize_grip)
1956 fi
1957
1958 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1959 dnl other platforms.
1960 HAVE_DBUS=no
1961 DBUS_OBJ=
1962 if test "${with_dbus}" = "yes"; then
1963    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1964    if test "$HAVE_DBUS" = yes; then
1965      LIBS="$LIBS $DBUS_LIBS"
1966      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1967      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1968      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1969      dnl D-Bus 1.5.12.
1970      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1971                     dbus_type_is_valid \
1972                     dbus_validate_bus_name \
1973                     dbus_validate_path \
1974                     dbus_validate_interface \
1975                     dbus_validate_member)
1976      DBUS_OBJ=dbusbind.o
1977    fi
1978 fi
1979 AC_SUBST(DBUS_OBJ)
1980
1981 dnl GSettings has been tested under GNU/Linux only.
1982 HAVE_GSETTINGS=no
1983 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1984    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1985    if test "$HAVE_GSETTINGS" = "yes"; then
1986       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1987       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1988       SETTINGS_LIBS="$GSETTINGS_LIBS"
1989    fi
1990 fi
1991
1992 dnl GConf has been tested under GNU/Linux only.
1993 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1994 HAVE_GCONF=no
1995 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1996    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1997    if test "$HAVE_GCONF" = yes; then
1998       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1999       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2000       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2001       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2002    fi
2003 fi
2004
2005 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2006     SAVE_CFLAGS="$CFLAGS"
2007     SAVE_LIBS="$LIBS"
2008     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2009     LIBS="$SETTINGS_LIBS $LIBS"
2010     AC_CHECK_FUNCS([g_type_init])
2011     CFLAGS="$SAVE_CFLAGS"
2012     LIBS="$SAVE_LIBS"
2013 fi
2014 AC_SUBST(SETTINGS_CFLAGS)
2015 AC_SUBST(SETTINGS_LIBS)
2016
2017
2018 dnl SELinux is available for GNU/Linux only.
2019 HAVE_LIBSELINUX=no
2020 LIBSELINUX_LIBS=
2021 if test "${with_selinux}" = "yes"; then
2022    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2023    if test "$HAVE_LIBSELINUX" = yes; then
2024       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2025       LIBSELINUX_LIBS=-lselinux
2026    fi
2027 fi
2028 AC_SUBST(LIBSELINUX_LIBS)
2029
2030 HAVE_GNUTLS=no
2031 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2032 if test "${with_gnutls}" = "yes" ; then
2033   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2034   if test "${HAVE_GNUTLS}" = "yes"; then
2035     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2036   fi
2037
2038   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2039   LIBS="$LIBGNUTLS_LIBS $LIBS"
2040   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2041
2042   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2043     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2044   fi
2045 fi
2046
2047 AC_SUBST(LIBGNUTLS_LIBS)
2048 AC_SUBST(LIBGNUTLS_CFLAGS)
2049
2050 dnl Do not put whitespace before the #include statements below.
2051 dnl Older compilers (eg sunos4 cc) choke on it.
2052 HAVE_XAW3D=no
2053 LUCID_LIBW=
2054 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2055   if test "$with_xaw3d" != no; then
2056     AC_MSG_CHECKING(for xaw3d)
2057     AC_CACHE_VAL(emacs_cv_xaw3d,
2058     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2059 #include <X11/Intrinsic.h>
2060 #include <X11/Xaw3d/Simple.h>]],
2061       [[]])],
2062       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2063                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2064       emacs_cv_xaw3d=no)])
2065   else
2066     emacs_cv_xaw3d=no
2067   fi
2068   if test $emacs_cv_xaw3d = yes; then
2069     AC_MSG_RESULT([yes; using Lucid toolkit])
2070     USE_X_TOOLKIT=LUCID
2071     HAVE_XAW3D=yes
2072     LUCID_LIBW=-lXaw3d
2073     AC_DEFINE(HAVE_XAW3D, 1,
2074               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2075   else
2076     AC_MSG_RESULT(no)
2077     AC_MSG_CHECKING(for libXaw)
2078     AC_CACHE_VAL(emacs_cv_xaw,
2079     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2080 #include <X11/Intrinsic.h>
2081 #include <X11/Xaw/Simple.h>]],
2082       [[]])],
2083       emacs_cv_xaw=yes,
2084       emacs_cv_xaw=no)])
2085     if test $emacs_cv_xaw = yes; then
2086       AC_MSG_RESULT([yes; using Lucid toolkit])
2087       USE_X_TOOLKIT=LUCID
2088       LUCID_LIBW=-lXaw
2089     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2090       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2091     else
2092       AC_MSG_ERROR([No X toolkit could be found.
2093 If you are sure you want Emacs compiled without an X toolkit, pass
2094   --with-x-toolkit=no
2095 to configure.  Otherwise, install the development libraries for the toolkit
2096 that you want to use (e.g. Gtk+) and re-run configure.])
2097     fi
2098   fi
2099 fi
2100
2101 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2102
2103 LIBXTR6=
2104 if test "${USE_X_TOOLKIT}" != "none"; then
2105   AC_MSG_CHECKING(X11 toolkit version)
2106   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2107   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2108 [[#if XtSpecificationRelease < 6
2109 fail;
2110 #endif
2111 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2112   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2113   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2114     AC_MSG_RESULT(6 or newer)
2115     AC_DEFINE(HAVE_X11XTR6, 1,
2116               [Define to 1 if you have the X11R6 or newer version of Xt.])
2117     LIBXTR6="-lSM -lICE"
2118     case "$opsys" in
2119       ## Use libw.a along with X11R6 Xt.
2120       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2121     esac
2122   else
2123     AC_MSG_RESULT(before 6)
2124   fi
2125
2126 dnl If using toolkit, check whether libXmu.a exists.
2127 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2128   OLDLIBS="$LIBS"
2129   if test x$HAVE_X11XTR6 = xyes; then
2130     LIBS="-lXt -lSM -lICE $LIBS"
2131   else
2132     LIBS="-lXt $LIBS"
2133   fi
2134   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2135   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2136   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2137 fi
2138 AC_SUBST(LIBXTR6)
2139
2140 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2141 dnl Why not just test for libxmu in the normal way?
2142 LIBXMU=-lXmu
2143 case $opsys in
2144   ## These systems don't supply Xmu.
2145   hpux* | aix4-2 )
2146     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2147     ;;
2148 esac
2149 AC_SUBST(LIBXMU)
2150
2151 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2152 if test "${HAVE_X11}" = "yes"; then
2153   if test "${USE_X_TOOLKIT}" != "none"; then
2154     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2155   fi
2156 fi
2157
2158 LIBXP=
2159 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2160   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2161   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2162     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2163 int x = 5;
2164 #else
2165 Motif version prior to 2.1.
2166 #endif]])],
2167     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2168   if test $emacs_cv_motif_version_2_1 = yes; then
2169     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2170   else
2171     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2172     # We put this in CFLAGS temporarily to precede other -I options
2173     # that might be in CFLAGS temporarily.
2174     # We put this in CPPFLAGS where it precedes the other -I options.
2175     OLD_CPPFLAGS=$CPPFLAGS
2176     OLD_CFLAGS=$CFLAGS
2177     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2178     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2179     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2180       [[int x = 5;]])],
2181       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2182     if test $emacs_cv_lesstif = yes; then
2183       # Make sure this -I option remains in CPPFLAGS after it is set
2184       # back to REAL_CPPFLAGS.
2185       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2186       # have those other -I options anyway.  Ultimately, having this
2187       # directory ultimately in CPPFLAGS will be enough.
2188       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2189       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2190     else
2191       CFLAGS=$OLD_CFLAGS
2192       CPPFLAGS=$OLD_CPPFLAGS
2193     fi
2194   fi
2195   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2196     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2197 fi
2198
2199 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2200 dnl using Motif or Xaw3d is available, and unless
2201 dnl --with-toolkit-scroll-bars=no was specified.
2202
2203 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2204             [Define to 1 if we should use toolkit scroll bars.])dnl
2205 USE_TOOLKIT_SCROLL_BARS=no
2206 if test "${with_toolkit_scroll_bars}" != "no"; then
2207   if test "${USE_X_TOOLKIT}" != "none"; then
2208     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2209       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2210       HAVE_XAW3D=no
2211       USE_TOOLKIT_SCROLL_BARS=yes
2212     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2213       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2214       USE_TOOLKIT_SCROLL_BARS=yes
2215     fi
2216   elif test "${HAVE_GTK}" = "yes"; then
2217     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2218     USE_TOOLKIT_SCROLL_BARS=yes
2219   elif test "${HAVE_NS}" = "yes"; then
2220     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2221     USE_TOOLKIT_SCROLL_BARS=yes
2222   fi
2223 fi
2224
2225 dnl See if XIM is available.
2226 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2227           #include <X11/Xlib.h>
2228           #include <X11/Xresource.h>]],
2229          [[XIMProc  callback;]])],
2230          [HAVE_XIM=yes
2231          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2232          HAVE_XIM=no)
2233
2234 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2235
2236 if test "${with_xim}" != "no"; then
2237   AC_DEFINE(USE_XIM, 1,
2238             [Define to 1 if we should use XIM, if it is available.])
2239 fi
2240
2241
2242 if test "${HAVE_XIM}" != "no"; then
2243   late_CFLAGS=$CFLAGS
2244   if test "$GCC" = yes; then
2245     CFLAGS="$CFLAGS --pedantic-errors"
2246   fi
2247   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2248 #include <X11/Xlib.h>
2249 #include <X11/Xresource.h>]],
2250 [[Display *display;
2251 XrmDatabase db;
2252 char *res_name;
2253 char *res_class;
2254 XIMProc  callback;
2255 XPointer *client_data;
2256 #ifndef __GNUC__
2257 /* If we're not using GCC, it's probably not XFree86, and this is
2258    probably right, but we can't use something like --pedantic-errors.  */
2259 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2260                                            char*, XIMProc, XPointer*);
2261 #endif
2262 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2263    client_data);]])],
2264     [emacs_cv_arg6_star=yes])
2265   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2266          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2267 either XPointer or XPointer*.])dnl
2268   if test "$emacs_cv_arg6_star" = yes; then
2269     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2270   else
2271     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2272   fi
2273   CFLAGS=$late_CFLAGS
2274 fi
2275
2276 ### Start of font-backend (under any platform) section.
2277 # (nothing here yet -- this is a placeholder)
2278 ### End of font-backend (under any platform) section.
2279
2280 ### Start of font-backend (under X11) section.
2281 if test "${HAVE_X11}" = "yes"; then
2282    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2283
2284    ## Use -lXft if available, unless `--with-xft=no'.
2285    HAVE_XFT=maybe
2286     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2287       with_xft="no";
2288     fi
2289     if test "x${with_xft}" != "xno"; then
2290
2291       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2292       ## Because xftfont.c uses XRenderQueryExtension, we also
2293       ## need to link to -lXrender.
2294       HAVE_XRENDER=no
2295       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2296       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2297         OLD_CPPFLAGS="$CPPFLAGS"
2298         OLD_CFLAGS="$CFLAGS"
2299         OLD_LIBS="$LIBS"
2300         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2301         CFLAGS="$CFLAGS $XFT_CFLAGS"
2302         XFT_LIBS="-lXrender $XFT_LIBS"
2303         LIBS="$XFT_LIBS $LIBS"
2304         AC_CHECK_HEADER(X11/Xft/Xft.h,
2305           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2306
2307         if test "${HAVE_XFT}" = "yes"; then
2308           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2309             AC_SUBST(XFT_LIBS)
2310           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2311         else
2312           CPPFLAGS="$OLD_CPPFLAGS"
2313           CFLAGS="$OLD_CFLAGS"
2314           LIBS="$OLD_LIBS"
2315         fi                        # "${HAVE_XFT}" = "yes"
2316       fi                          # "$HAVE_XFT" != no
2317     fi                            # "x${with_xft}" != "xno"
2318
2319     ## We used to allow building with FreeType and without Xft.
2320     ## However, the ftx font backend driver is not in good shape.
2321     if test "$HAVE_XFT" != "yes"; then
2322        dnl For the "Does Emacs use" message at the end.
2323        HAVE_XFT=no
2324        HAVE_FREETYPE=no
2325     else
2326        dnl Strict linkers fail with
2327        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2328        dnl if -lfreetype is not specified.
2329        dnl The following is needed to set FREETYPE_LIBS.
2330        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2331                          HAVE_FREETYPE=no)
2332
2333        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2334     fi
2335
2336     HAVE_LIBOTF=no
2337     if test "${HAVE_FREETYPE}" = "yes"; then
2338       AC_DEFINE(HAVE_FREETYPE, 1,
2339                 [Define to 1 if using the freetype and fontconfig libraries.])
2340       if test "${with_libotf}" != "no"; then
2341         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2342                           HAVE_LIBOTF=no)
2343         if test "$HAVE_LIBOTF" = "yes"; then
2344           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2345           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2346                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2347                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2348           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2349             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2350                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2351           fi
2352         fi
2353       fi
2354     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2355     dnl Does the new font backend require it, or can it work without it?
2356     fi
2357
2358     HAVE_M17N_FLT=no
2359     if test "${HAVE_LIBOTF}" = yes; then
2360       if test "${with_m17n_flt}" != "no"; then
2361         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2362         if test "$HAVE_M17N_FLT" = "yes"; then
2363           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2364         fi
2365       fi
2366     fi
2367 else
2368     HAVE_XFT=no
2369     HAVE_FREETYPE=no
2370     HAVE_LIBOTF=no
2371     HAVE_M17N_FLT=no
2372 fi
2373
2374 ### End of font-backend (under X11) section.
2375
2376 AC_SUBST(FREETYPE_CFLAGS)
2377 AC_SUBST(FREETYPE_LIBS)
2378 AC_SUBST(FONTCONFIG_CFLAGS)
2379 AC_SUBST(FONTCONFIG_LIBS)
2380 AC_SUBST(LIBOTF_CFLAGS)
2381 AC_SUBST(LIBOTF_LIBS)
2382 AC_SUBST(M17N_FLT_CFLAGS)
2383 AC_SUBST(M17N_FLT_LIBS)
2384
2385 ### Use -lXpm if available, unless `--with-xpm=no'.
2386 HAVE_XPM=no
2387 LIBXPM=
2388 if test "${HAVE_X11}" = "yes"; then
2389   if test "${with_xpm}" != "no"; then
2390     AC_CHECK_HEADER(X11/xpm.h,
2391       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2392     if test "${HAVE_XPM}" = "yes"; then
2393       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2394       AC_EGREP_CPP(no_return_alloc_pixels,
2395       [#include "X11/xpm.h"
2396 #ifndef XpmReturnAllocPixels
2397 no_return_alloc_pixels
2398 #endif
2399       ], HAVE_XPM=no, HAVE_XPM=yes)
2400
2401       if test "${HAVE_XPM}" = "yes"; then
2402         AC_MSG_RESULT(yes)
2403       else
2404         AC_MSG_RESULT(no)
2405       fi
2406     fi
2407   fi
2408
2409   if test "${HAVE_XPM}" = "yes"; then
2410     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2411     LIBXPM=-lXpm
2412   fi
2413 fi
2414 AC_SUBST(LIBXPM)
2415
2416 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2417 HAVE_JPEG=no
2418 LIBJPEG=
2419 if test "${HAVE_X11}" = "yes"; then
2420   if test "${with_jpeg}" != "no"; then
2421     dnl Checking for jpeglib.h can lose because of a redefinition of
2422     dnl  HAVE_STDLIB_H.
2423     AC_CHECK_HEADER(jerror.h,
2424       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2425   fi
2426
2427   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2428   if test "${HAVE_JPEG}" = "yes"; then
2429     AC_DEFINE(HAVE_JPEG)
2430     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2431         [#include <jpeglib.h>
2432          version=JPEG_LIB_VERSION
2433 ],
2434         [AC_DEFINE(HAVE_JPEG)],
2435         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2436         HAVE_JPEG=no])
2437   fi
2438   if test "${HAVE_JPEG}" = "yes"; then
2439     LIBJPEG=-ljpeg
2440   fi
2441 fi
2442 AC_SUBST(LIBJPEG)
2443
2444 ### Use -lpng if available, unless `--with-png=no'.
2445 HAVE_PNG=no
2446 LIBPNG=
2447 if test "${HAVE_X11}" = "yes"; then
2448   if test "${with_png}" != "no"; then
2449     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2450     # in /usr/include/libpng.
2451     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2452     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2453       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2454     fi
2455   fi
2456
2457   if test "${HAVE_PNG}" = "yes"; then
2458     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2459     LIBPNG="-lpng -lz -lm"
2460
2461     AC_CHECK_DECL(png_longjmp,
2462       [],
2463       [AC_DEFINE(PNG_DEPSTRUCT, [],
2464          [Define to empty to suppress deprecation warnings when building
2465           with --enable-gcc-warnings and with libpng versions before 1.5,
2466           which lack png_longjmp.])],
2467       [[#ifdef HAVE_LIBPNG_PNG_H
2468         # include <libpng/png.h>
2469         #else
2470         # include <png.h>
2471         #endif
2472       ]])
2473   fi
2474 fi
2475 AC_SUBST(LIBPNG)
2476
2477 ### Use -ltiff if available, unless `--with-tiff=no'.
2478 HAVE_TIFF=no
2479 LIBTIFF=
2480 if test "${HAVE_X11}" = "yes"; then
2481   if test "${with_tiff}" != "no"; then
2482     AC_CHECK_HEADER(tiffio.h,
2483       [tifflibs="-lz -lm"
2484       # At least one tiff package requires the jpeg library.
2485       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2486       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2487   fi
2488
2489   if test "${HAVE_TIFF}" = "yes"; then
2490     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2491     dnl FIXME -lz -lm, as per libpng?
2492     LIBTIFF=-ltiff
2493   fi
2494 fi
2495 AC_SUBST(LIBTIFF)
2496
2497 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2498 HAVE_GIF=no
2499 LIBGIF=
2500 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2501   AC_CHECK_HEADER(gif_lib.h,
2502 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2503 # Earlier versions can crash Emacs.
2504     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2505
2506   if test "$HAVE_GIF" = yes; then
2507     LIBGIF=-lgif
2508   elif test "$HAVE_GIF" = maybe; then
2509 # If gif_lib.h but no libgif, try libungif.
2510     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2511     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2512   fi
2513
2514   if test "${HAVE_GIF}" = "yes"; then
2515     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2516   fi
2517 fi
2518 AC_SUBST(LIBGIF)
2519
2520 dnl Check for required libraries.
2521 if test "${HAVE_X11}" = "yes"; then
2522   MISSING=""
2523   WITH_NO=""
2524   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2525     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2526   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2527     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2528   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2529     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2530   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2531     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2532   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2533     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2534
2535   if test "X${MISSING}" != X; then
2536     AC_MSG_ERROR([The following required libraries were not found:
2537     $MISSING
2538 Maybe some development libraries/packages are missing?
2539 If you don't want to link with them give
2540     $WITH_NO
2541 as options to configure])
2542   fi
2543 fi
2544
2545 ### Use -lgpm if available, unless `--with-gpm=no'.
2546 HAVE_GPM=no
2547 LIBGPM=
2548 if test "${with_gpm}" != "no"; then
2549   AC_CHECK_HEADER(gpm.h,
2550     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2551
2552   if test "${HAVE_GPM}" = "yes"; then
2553     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2554     LIBGPM=-lgpm
2555   fi
2556 fi
2557 AC_SUBST(LIBGPM)
2558
2559 dnl Check for malloc/malloc.h on darwin
2560 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2561
2562 GNUSTEP_CFLAGS=
2563 ### Use NeXTstep API to implement GUI.
2564 if test "${HAVE_NS}" = "yes"; then
2565   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2566   if test "${NS_IMPL_COCOA}" = "yes"; then
2567     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2568   fi
2569   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2570     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2571     # See also .m.o rule in Makefile.in */
2572     # FIXME: are all these flags really needed?  Document here why.  */
2573     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2574     ## Extra CFLAGS applied to src/*.m files.
2575     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2576   fi
2577   # We also have mouse menus.
2578   HAVE_MENUS=yes
2579   OTHER_FILES=ns-app
2580 fi
2581
2582
2583 ### Use session management (-lSM -lICE) if available
2584 HAVE_X_SM=no
2585 LIBXSM=
2586 if test "${HAVE_X11}" = "yes"; then
2587   AC_CHECK_HEADER(X11/SM/SMlib.h,
2588     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2589
2590   if test "${HAVE_X_SM}" = "yes"; then
2591     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2592     LIBXSM="-lSM -lICE"
2593     case "$LIBS" in
2594       *-lSM*) ;;
2595       *)      LIBS="$LIBXSM $LIBS" ;;
2596     esac
2597   fi
2598 fi
2599 AC_SUBST(LIBXSM)
2600
2601 ### Use libxml (-lxml2) if available
2602 HAVE_LIBXML2=no
2603 if test "${with_xml2}" != "no"; then
2604   ### I'm not sure what the version number should be, so I just guessed.
2605   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2606   if test "${HAVE_LIBXML2}" = "yes"; then
2607     LIBS="$LIBXML2_LIBS $LIBS"
2608     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2609     if test "${HAVE_LIBXML2}" = "yes"; then
2610       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2611     else
2612       LIBXML2_LIBS=""
2613       LIBXML2_CFLAGS=""
2614     fi
2615   fi
2616 fi
2617 AC_SUBST(LIBXML2_LIBS)
2618 AC_SUBST(LIBXML2_CFLAGS)
2619
2620 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2621 AC_CACHE_CHECK(whether netdb declares h_errno,
2622                emacs_cv_netdb_declares_h_errno,
2623 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2624   [[return h_errno;]])],
2625   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2626 if test $emacs_cv_netdb_declares_h_errno = yes; then
2627   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2628 fi
2629
2630 # fmod, logb, and frexp are found in -lm on most systems.
2631 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2632 AC_CHECK_LIB(m, sqrt)
2633
2634 # Check for mail-locking functions in a "mail" library.  Probably this should
2635 # have the same check as for liblockfile below.
2636 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2637 if test $have_mail = yes; then
2638   LIBS_MAIL=-lmail
2639   LIBS="$LIBS_MAIL $LIBS"
2640   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2641 else
2642   LIBS_MAIL=
2643 fi
2644 dnl Debian, at least:
2645 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2646 if test $have_lockfile = yes; then
2647    LIBS_MAIL=-llockfile
2648    LIBS="$LIBS_MAIL $LIBS"
2649    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2650 else
2651 # If we have the shared liblockfile, assume we must use it for mail
2652 # locking (e.g. Debian).  If we couldn't link against liblockfile
2653 # (no liblockfile.a installed), ensure that we don't need to.
2654   dnl This works for files generally, not just executables.
2655   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2656   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2657                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2658   if test $ac_cv_prog_liblockfile = yes; then
2659     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2660 This probably means that movemail could lose mail.
2661 There may be a `development' package to install containing liblockfile.])
2662   fi
2663 fi
2664 AC_CHECK_HEADERS_ONCE(maillock.h)
2665 AC_SUBST(LIBS_MAIL)
2666
2667 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2668 ## interlock access to the mail spool.  The alternative is a lock file named
2669 ## /usr/spool/mail/$USER.lock.
2670 mail_lock=no
2671 case "$opsys" in
2672   aix4-2) mail_lock="lockf" ;;
2673
2674   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2675
2676   ## On GNU/Linux systems, both methods are used by various mail programs.
2677   ## I assume most people are using newer mailers that have heard of flock.
2678   ## Change this if you need to.
2679   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2680   ## configure gets the right answers, and that means *NOT* using flock.
2681   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2682   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2683   ## Debian maintainer hasn't provided a clean fix for Emacs.
2684   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2685   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2686   ## correct logic.  -- fx
2687   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2688   ## liblockfile is a Free Software replacement for libmail, used on
2689   ## Debian systems and elsewhere. -rfr.
2690   gnu-*)
2691     mail_lock="flock"
2692     if test $have_mail = yes || test $have_lockfile = yes; then
2693       test $ac_cv_header_maillock_h = yes && mail_lock=no
2694     fi
2695     ;;
2696 esac
2697
2698 BLESSMAIL_TARGET=
2699 case "$mail_lock" in
2700   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2701
2702   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2703
2704   *) BLESSMAIL_TARGET="need-blessmail" ;;
2705 esac
2706 AC_SUBST(BLESSMAIL_TARGET)
2707
2708
2709 AC_CHECK_FUNCS(gethostname \
2710 closedir getrusage get_current_dir_name \
2711 lrand48 logb frexp fmod cbrt setsid \
2712 fpathconf select euidaccess getpagesize setlocale \
2713 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2714 __fpending strsignal setitimer \
2715 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2716 gai_strerror mkstemp getline getdelim fsync sync \
2717 difftime posix_memalign \
2718 getpwent endpwent getgrent endgrent \
2719 touchlock \
2720 cfmakeraw cfsetspeed copysign __executable_start)
2721
2722 dnl FIXME Fragile: something else may test for getwd as a dependency.
2723 dnl Change to defining BROKEN_xxx ?
2724 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2725 if test $opsys != unixware; then
2726   AC_CHECK_FUNCS(getwd)
2727 fi
2728
2729 dnl FIXME Fragile: see above.
2730 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2731 ## has a broken `rint' in some library versions including math library
2732 ## version number A.09.05.
2733 ## You can fix the math library by installing patch number PHSS_4630.
2734 ## But we can fix it more reliably for Emacs by just not using rint.
2735 ## We also skip HAVE_RANDOM - see comments in src/s/hpux10-20.h.
2736 case $opsys in
2737    hpux*) : ;;
2738    *) AC_CHECK_FUNCS(random rint) ;;
2739 esac
2740
2741 dnl Cannot use AC_CHECK_FUNCS
2742 AC_CACHE_CHECK([for __builtin_unwind_init],
2743                emacs_cv_func___builtin_unwind_init,
2744 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2745                 emacs_cv_func___builtin_unwind_init=yes,
2746                 emacs_cv_func___builtin_unwind_init=no)])
2747 if test $emacs_cv_func___builtin_unwind_init = yes; then
2748   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2749             [Define to 1 if you have the `__builtin_unwind_init' function.])
2750 fi
2751
2752 AC_CHECK_HEADERS_ONCE(sys/un.h)
2753
2754 AC_FUNC_FSEEKO
2755
2756 AC_FUNC_GETPGRP
2757
2758 # UNIX98 PTYs.
2759 AC_CHECK_FUNCS(grantpt)
2760
2761 # PTY-related GNU extensions.
2762 AC_CHECK_FUNCS(getpt)
2763
2764 # Check this now, so that we will NOT find the above functions in ncurses.
2765 # That is because we have not set up to link ncurses in lib-src.
2766 # It's better to believe a function is not available
2767 # than to expect to find it in ncurses.
2768 # Also we need tputs and friends to be able to build at all.
2769 AC_MSG_CHECKING([for library containing tputs])
2770 # Run a test program that contains a call to tputs, a call that is
2771 # never executed.  This tests whether a pre-'main' dynamic linker
2772 # works with the library.  It's too much trouble to actually call
2773 # tputs in the test program, due to portability hassles.  When
2774 # cross-compiling, assume the test program will run if it links.
2775 AC_DEFUN([tputs_link_source], [
2776   AC_LANG_SOURCE(
2777      [[extern void tputs (const char *, int, int (*)(int));
2778        int main (int argc, char **argv)
2779        {
2780           if (argc == 10000)
2781             tputs (argv[0], 0, 0);
2782           return 0;
2783        }]])
2784 ])
2785 # Maybe curses should be tried earlier?
2786 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2787 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2788   OLIBS=$LIBS
2789   if test -z "$tputs_library"; then
2790     LIBS_TERMCAP=
2791     msg='none required'
2792   else
2793     LIBS_TERMCAP=-l$tputs_library
2794     msg=$LIBS_TERMCAP
2795     LIBS="$LIBS_TERMCAP $LIBS"
2796   fi
2797   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2798     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2799   LIBS=$OLIBS
2800   if test "X$msg" != Xno; then
2801     break
2802   fi
2803 done
2804 AC_MSG_RESULT([$msg])
2805 if test "X$msg" = Xno; then
2806   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2807 The following libraries were tried (in order):
2808   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2809 Please try installing whichever of these libraries is most appropriate
2810 for your system, together with its header files.
2811 For example, a libncurses-dev(el) or similar package.])
2812 fi
2813
2814 ## Use termcap instead of terminfo?
2815 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2816 TERMINFO=yes
2817 ## FIXME?  In the cases below where we unconditionally set
2818 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2819 ## if that was found above to have tputs.
2820 ## Should we use the gnu* logic everywhere?
2821 case "$opsys" in
2822   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2823   ##  The ncurses library has been moved out of the System framework in
2824   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2825   ##  option to use it.
2826   darwin) LIBS_TERMCAP="-lncurses" ;;
2827
2828   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2829
2830   freebsd)
2831     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2832     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2833     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2834 [[#if __FreeBSD_version < 400000
2835 fail;
2836 #endif
2837 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2838
2839     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2840
2841     if test $emacs_cv_freebsd_terminfo = yes; then
2842       LIBS_TERMCAP="-lncurses"
2843     else
2844       TERMINFO=no
2845       LIBS_TERMCAP="-ltermcap"
2846     fi
2847     ;;
2848
2849   netbsd)
2850     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2851       TERMINFO=no
2852       LIBS_TERMCAP="-ltermcap"
2853     fi
2854     ;;
2855
2856   openbsd) LIBS_TERMCAP="-lncurses" ;;
2857
2858   ## hpux: Make sure we get select from libc rather than from libcurses
2859   ##  because libcurses on HPUX 10.10 has a broken version of select.
2860   ##  We used to use -lc -lcurses, but this may be cleaner.
2861   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2862   # set that way, now it uses the default).  Isn't this a contradiction?
2863   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2864
2865 esac
2866
2867 TERMCAP_OBJ=tparam.o
2868 if test $TERMINFO = yes; then
2869   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2870   TERMCAP_OBJ=terminfo.o
2871 fi
2872 AC_SUBST(LIBS_TERMCAP)
2873 AC_SUBST(TERMCAP_OBJ)
2874
2875
2876 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2877 # On Darwin, res_init appears not to be useful: see bug#562 and
2878 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2879 resolv=no
2880
2881 if test $opsys != darwin; then
2882
2883   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2884 #include <arpa/nameser.h>
2885 #include <resolv.h>]],
2886     [[return res_init();]])],
2887     have_res_init=yes, have_res_init=no)
2888   if test "$have_res_init" = no; then
2889     OLIBS="$LIBS"
2890     LIBS="$LIBS -lresolv"
2891     AC_MSG_CHECKING(for res_init with -lresolv)
2892     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2893 #include <arpa/nameser.h>
2894 #include <resolv.h>]],
2895       [[return res_init();]])],
2896       have_res_init=yes, have_res_init=no)
2897     AC_MSG_RESULT($have_res_init)
2898     if test "$have_res_init" = yes ; then
2899       resolv=yes
2900     fi
2901     LIBS="$OLIBS"
2902   fi
2903
2904   if test "$have_res_init" = yes; then
2905     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2906   fi
2907 fi                              dnl !darwin
2908
2909 # Do we need the Hesiod library to provide the support routines?
2910 dnl FIXME?  Should we be skipping this on Darwin too?
2911 LIBHESIOD=
2912 if test "$with_hesiod" != no ; then
2913   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2914   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2915      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2916                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2917   if test "$resolv" = yes ; then
2918     RESOLVLIB=-lresolv
2919   else
2920     RESOLVLIB=
2921   fi
2922   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2923         hesiod=yes, :, $RESOLVLIB)])
2924
2925   if test x"$hesiod" = xyes; then
2926     AC_DEFINE(HAVE_LIBHESIOD, 1,
2927               [Define to 1 if you have the hesiod library (-lhesiod).])
2928     LIBHESIOD=-lhesiod
2929   fi
2930 fi
2931 AC_SUBST(LIBHESIOD)
2932
2933 # Do we need libresolv (due to res_init or Hesiod)?
2934 if test "$resolv" = yes && test $opsys != darwin; then
2935   AC_DEFINE(HAVE_LIBRESOLV, 1,
2936             [Define to 1 if you have the resolv library (-lresolv).])
2937   LIBRESOLV=-lresolv
2938 else
2939   LIBRESOLV=
2940 fi
2941 AC_SUBST(LIBRESOLV)
2942
2943 # These tell us which Kerberos-related libraries to use.
2944 COM_ERRLIB=
2945 CRYPTOLIB=
2946 KRB5LIB=
2947 DESLIB=
2948 KRB4LIB=
2949
2950 if test "${with_kerberos}" != no; then
2951   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2952   if test $have_com_err = yes; then
2953     COM_ERRLIB=-lcom_err
2954     LIBS="$COM_ERRLIB $LIBS"
2955     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2956   fi
2957   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2958   if test $have_crypto = yes; then
2959     CRYPTOLIB=-lcrypto
2960     LIBS="$CRYPTOLIB $LIBS"
2961     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2962   fi
2963   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2964   if test $have_k5crypto = yes; then
2965     CRYPTOLIB=-lk5crypto
2966     LIBS="$CRYPTOLIB $LIBS"
2967     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2968   fi
2969   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2970   if test $have_krb5=yes; then
2971     KRB5LIB=-lkrb5
2972     LIBS="$KRB5LIB $LIBS"
2973     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2974   fi
2975   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2976   if test "${with_kerberos5}" = no; then
2977     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2978     if test $have_des425 = yes; then
2979       DESLIB=-ldes425
2980       LIBS="$DESLIB $LIBS"
2981       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2982     else
2983       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2984       if test $have_des = yes; then
2985         DESLIB=-ldes
2986         LIBS="$DESLIB $LIBS"
2987         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2988       fi
2989     fi
2990     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2991     if test $have_krb4 = yes; then
2992       KRB4LIB=-lkrb4
2993       LIBS="$KRB4LIB $LIBS"
2994       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2995     else
2996       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2997       if test $have_krb = yes; then
2998         KRB4LIB=-lkrb
2999         LIBS="$KRB4LIB $LIBS"
3000         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3001       fi
3002     fi
3003   fi
3004
3005   if test "${with_kerberos5}" != no; then
3006     AC_CHECK_HEADERS(krb5.h,
3007       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3008                         [#include <krb5.h>])])
3009   else
3010     AC_CHECK_HEADERS(des.h,,
3011                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3012                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3013     AC_CHECK_HEADERS(krb.h,,
3014                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3015                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3016   fi
3017   AC_CHECK_HEADERS(com_err.h)
3018 fi
3019
3020 AC_SUBST(COM_ERRLIB)
3021 AC_SUBST(CRYPTOLIB)
3022 AC_SUBST(KRB5LIB)
3023 AC_SUBST(DESLIB)
3024 AC_SUBST(KRB4LIB)
3025
3026 AC_CHECK_FUNCS_ONCE(tzset)
3027 AC_MSG_CHECKING(whether localtime caches TZ)
3028 AC_CACHE_VAL(emacs_cv_localtime_cache,
3029 [if test x$ac_cv_func_tzset = xyes; then
3030 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3031 char TZ_GMT0[] = "TZ=GMT0";
3032 char TZ_PST8[] = "TZ=PST8";
3033 main()
3034 {
3035   time_t now = time ((time_t *) 0);
3036   int hour_GMT0, hour_unset;
3037   if (putenv (TZ_GMT0) != 0)
3038     exit (1);
3039   hour_GMT0 = localtime (&now)->tm_hour;
3040   unsetenv("TZ");
3041   hour_unset = localtime (&now)->tm_hour;
3042   if (putenv (TZ_PST8) != 0)
3043     exit (1);
3044   if (localtime (&now)->tm_hour == hour_GMT0)
3045     exit (1);
3046   unsetenv("TZ");
3047   if (localtime (&now)->tm_hour != hour_unset)
3048     exit (1);
3049   exit (0);
3050 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3051 [# If we have tzset, assume the worst when cross-compiling.
3052 emacs_cv_localtime_cache=yes])
3053 else
3054         # If we lack tzset, report that localtime does not cache TZ,
3055         # since we can't invalidate the cache if we don't have tzset.
3056         emacs_cv_localtime_cache=no
3057 fi])dnl
3058 AC_MSG_RESULT($emacs_cv_localtime_cache)
3059 if test $emacs_cv_localtime_cache = yes; then
3060   AC_DEFINE(LOCALTIME_CACHE, 1,
3061             [Define to 1 if localtime caches TZ.])
3062 fi
3063
3064 ok_so_far=yes
3065 AC_CHECK_FUNC(socket, , ok_so_far=no)
3066 if test $ok_so_far = yes; then
3067   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3068 fi
3069 if test $ok_so_far = yes; then
3070   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3071 fi
3072 if test $ok_so_far = yes; then
3073 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3074   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3075             [Define to 1 if you have inet sockets.])
3076 fi
3077
3078 if test -f /usr/lpp/X11/bin/smt.exp; then
3079   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3080             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3081 fi
3082
3083 AC_MSG_CHECKING(whether system supports dynamic ptys)
3084 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3085   AC_MSG_RESULT(yes)
3086   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3087 else
3088   AC_MSG_RESULT(no)
3089 fi
3090
3091 AC_FUNC_FORK
3092
3093 AC_CHECK_FUNCS(snprintf)
3094
3095 dnl Adapted from Haible's version.
3096 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3097   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3098     [[char* cs = nl_langinfo(CODESET);]])],
3099     emacs_cv_langinfo_codeset=yes,
3100     emacs_cv_langinfo_codeset=no)
3101   ])
3102 if test $emacs_cv_langinfo_codeset = yes; then
3103   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3104     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3105 fi
3106
3107 AC_TYPE_MBSTATE_T
3108
3109 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3110   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3111                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3112 if test "$emacs_cv_c_restrict_arr" = yes; then
3113   AC_DEFINE(__restrict_arr, __restrict,
3114     [Define to compiler's equivalent of C99 restrict keyword in array
3115      declarations.  Define as empty for no equivalent.])
3116 fi
3117
3118 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3119 dnl how the tty code is related to POSIX and/or other versions of termios.
3120 dnl The following looks like a useful start.
3121 dnl
3122 dnl AC_SYS_POSIX_TERMIOS
3123 dnl if test $ac_cv_sys_posix_termios = yes; then
3124 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3125 dnl                                and macros for terminal control.])
3126 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3127 dnl fi
3128
3129 dnl Every platform that uses configure (ie every non-MS platform)
3130 dnl supports this.  There is a create-lockfiles option you can
3131 dnl customize if you do not want the lock files to be written.
3132 dnl So it is not clear that this #define still needs to exist.
3133 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3134   so that Emacs can tell instantly when you try to modify a file that
3135   someone else has modified in his/her Emacs.])
3136
3137 dnl Everybody supports this, except MS.
3138 dnl Seems like the kind of thing we should be testing for, though.
3139 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3140 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3141
3142 dnl Everybody supports this, except MS-DOS.
3143 dnl Seems like the kind of thing we should be testing for, though.
3144 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3145 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3146   4.2-compatible sockets.])
3147
3148
3149 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3150
3151 case $opsys in
3152   aix4-2)
3153     dnl Unfortunately without libXmu we cannot support EditRes.
3154     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3155       AC_DEFINE(NO_EDITRES, 1)
3156     fi
3157     ;;
3158
3159   hpux*)
3160     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3161     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3162     AC_DEFINE(NO_EDITRES, 1)
3163     ;;
3164 esac
3165
3166
3167 case $opsys in
3168   darwin | gnu | hpux* | *bsd )
3169     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3170     ;;
3171
3172   irix6-5 | sol2* | unixware )
3173     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3174     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3175     dnl need the constant to dimension an array.  So wire in the appropriate
3176     dnl value here.
3177     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3178     ;;
3179 esac
3180
3181
3182 case $opsys in
3183   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3184   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3185   hpux* | irix6-5 | openbsd | sol2* | unixware )
3186     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3187     ;;
3188
3189   aix4-2)
3190     dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3191     AC_DEFINE(BROKEN_FIONREAD, 1, [Define if FIONREAD should not be used.])
3192     dnl As we define BROKEN_FIONREAD, SIGIO will be undefined in systty.h.
3193     dnl But, on AIX, SIGAIO, SIGPTY, and SIGPOLL are defined as SIGIO,
3194     dnl which causes compilation error at init_signals in sysdep.c.
3195     dnl So, we define these macros so that syssignal.h detects them
3196     dnl and undefine SIGAIO, SIGPTY and SIGPOLL.
3197     AC_DEFINE(BROKEN_SIGAIO, 1, [Define if SIGAIO should not be used.])
3198     AC_DEFINE(BROKEN_SIGPOLL,1, [Define if SIGPOLL should not be used.])
3199     AC_DEFINE(BROKEN_SIGPTY, 1, [Define if SIGPTY should not be used.])
3200
3201     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3202     dnl the way this system works, libc functions that return malloced
3203     dnl memory use the libc malloc implementation. Calling xfree or
3204     dnl xrealloc on the results of such functions results in a crash.
3205     dnl
3206     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3207     dnl but that does not currently work on this system.
3208     dnl
3209     dnl It is possible to completely override the malloc implementation on
3210     dnl AIX, but that involves putting the malloc functions in a shared
3211     dnl library and setting the MALLOCTYPE environment variable to point to
3212     dnl that shared library.
3213     dnl
3214     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3215     dnl to avoid a crash just use the Emacs implementation for that function.
3216     dnl
3217     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3218     dnl of this file, so that we do not check for get_current_dir_name
3219     dnl on AIX.  But that might be fragile if something else ends
3220     dnl up testing for get_current_dir_name as a dependency.
3221     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3222       get_current_dir_name should not be used.])
3223     ;;
3224
3225   freebsd)
3226     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3227     dnl writes/reads on a PTY, read(2) returns bogus data:
3228     dnl
3229     dnl write(2)  1022 bytes
3230     dnl write(2)   954 bytes, get EAGAIN
3231     dnl read(2)   1024 bytes in process_read_output
3232     dnl read(2)     11 bytes in process_read_output
3233     dnl
3234     dnl That is, read(2) returns more bytes than have ever been written
3235     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3236     dnl successfully after processing (for example with CRs added if the
3237     dnl terminal is set up that way which it is here).  The same bytes will
3238     dnl be seen again in a later read(2), without the CRs.
3239     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3240       work around an issue when reading from a PTY.])
3241     ;;
3242
3243   dnl Define the following so emacs symbols will not conflict with those
3244   dnl in the System framework.  Otherwise -prebind will not work.
3245   darwin)
3246     AC_DEFINE(NO_ABORT, 1, [Do not define abort in emacs.c.])
3247     ;;
3248 esac
3249
3250 case $opsys in
3251   gnu-* | sol2-10 )
3252     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3253     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3254   ;;
3255 esac
3256
3257 case $opsys in
3258   darwin | freebsd | netbsd | openbsd )
3259     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3260       close a pty to make it a controlling terminal (it is already a
3261       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3262   ;;
3263 esac
3264
3265 dnl FIXME Surely we can test for this rather than hard-code it.
3266 case $opsys in
3267   netbsd | openbsd) sound_device="/dev/audio" ;;
3268   *) sound_device="/dev/dsp" ;;
3269 esac
3270
3271 dnl Used in sound.c
3272 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3273   [Name of the default sound device.])
3274
3275
3276 dnl Emacs can read input using SIGIO and buffering characters itself,
3277 dnl or using CBREAK mode and making C-g cause SIGINT.
3278 dnl The choice is controlled by the variable interrupt_input.
3279 dnl
3280 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3281 dnl
3282 dnl Emacs uses the presence or absence of the SIGIO and BROKEN_SIGIO macros
3283 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3284 dnl INTERRUPT_INPUT to decide whether to use it by default.
3285 dnl
3286 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3287 dnl CBREAK mode has two disadvantages
3288 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3289 dnl I hear that in system V this problem does not exist.
3290 dnl 2) Control-G causes output to be discarded.
3291 dnl I do not know whether this can be fixed in system V.
3292 dnl
3293 dnl Another method of doing input is planned but not implemented.
3294 dnl It would have Emacs fork off a separate process
3295 dnl to read the input and send it to the true Emacs process
3296 dnl through a pipe.
3297 case $opsys in
3298   darwin | gnu-linux | gnu-kfreebsd )
3299     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3300   ;;
3301 esac
3302
3303
3304 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3305 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3306 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3307 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3308 dnl taking float or double parameters.
3309 case $opsys in
3310   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3311     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3312       file defines `NeedWidePrototypes' as `NO'.])
3313   ;;
3314 esac
3315
3316
3317 dnl Used in process.c, this must be a loop, even if it only runs once.
3318 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3319 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3320 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3321 dnl trying suffixes 0-16.
3322 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3323   first PTY, if PTYs are supported.])
3324 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3325 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3326   end of a PTY, if non-standard.])
3327 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3328   end of a PTY, if non-standard.])
3329
3330 case $opsys in
3331   aix4-2 )
3332     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)] )
3333     dnl You allocate a pty by opening /dev/ptc to get the master side.
3334     dnl To get the name of the slave side, you just ttyname() the master side.
3335     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");] )
3336     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));] )
3337     ;;
3338
3339   cygwin )
3340     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)] )
3341     dnl multi-line AC_DEFINEs are hard. :(
3342     AC_DEFINE(PTY_OPEN, [ do { int dummy; SIGMASKTYPE mask; mask = sigblock (sigmask (SIGCHLD)); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; sigsetmask (mask); if (fd >= 0) emacs_close (dummy); } while (0)] )
3343     AC_DEFINE(PTY_NAME_SPRINTF, [] )
3344     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [] )
3345     ;;
3346
3347   darwin )
3348     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)] )
3349     dnl Not used, because PTY_ITERATION is defined.
3350     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3351     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3352     dnl But we don't have to block SIGCHLD because it is blocked in the
3353     dnl implementation of grantpt.
3354     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)] )
3355     AC_DEFINE(PTY_NAME_SPRINTF, [] )
3356     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [] )
3357     ;;
3358
3359   gnu | freebsd | netbsd | openbsd )
3360     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3361     ;;
3362
3363   gnu-linux | gnu-kfreebsd )
3364     dnl if HAVE_GRANTPT
3365     if test "x$ac_cv_func_grantpt" = xyes; then
3366       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3367       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)] )
3368       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3369       dnl to prevent sigchld_handler from intercepting the child's death.
3370       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname; sigblock (sigmask (SIGCHLD)); if (grantpt (fd) == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname(fd))) { sigunblock (sigmask (SIGCHLD)); close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); sigunblock (sigmask (SIGCHLD)); }] )
3371       dnl if HAVE_GETPT
3372       if test "x$ac_cv_func_getpt" = xyes; then
3373         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3374         AC_DEFINE(PTY_NAME_SPRINTF, [] )
3375       else
3376         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");] )
3377       fi
3378     else
3379       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3380     fi
3381     ;;
3382
3383   hpux*)
3384     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3385     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);] )
3386     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);] )
3387     ;;
3388
3389   irix6-5 )
3390     dnl It looks like this cannot be right, because it is not a loop.
3391     dnl However, process.c actually does this:
3392     dnl # ifndef __sgi
3393     dnl   continue;
3394     dnl # else
3395     dnl   return -1;
3396     dnl # endif
3397     dnl which presumably makes it OK, since irix == sgi (?).
3398     dnl FIXME it seems like this special treatment is unnecessary?
3399     dnl Why can't irix use a single-trip loop like eg cygwin?
3400     AC_DEFINE(PTY_ITERATION, [])
3401     dnl Not used, because PTY_ITERATION is defined.
3402     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3403     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }] )
3404     dnl No need to get the pty name at all.
3405     AC_DEFINE(PTY_NAME_SPRINTF, [] )
3406     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3407     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [] )
3408     ;;
3409
3410   sol2* )
3411     dnl Uses sigblock/sigunblock rather than sighold/sigrelse,
3412     dnl which appear to be BSD4.1 specific.  It may also be appropriate
3413     dnl for SVR4.x (x<2) but I'm not sure.   fnf@cygnus.com
3414     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3415     dnl from intercepting that death.  If any child but grantpt's should die
3416     dnl within, it should be caught after sigrelse(2).
3417     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock (sigmask (SIGCLD)); if (grantpt (fd) == -1) { emacs_close (fd); return -1; } sigunblock (sigmask (SIGCLD)); if (unlockpt (fd) == -1) { emacs_close (fd); return -1; } if (!(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }] )
3418     ;;
3419
3420   unixware )
3421     dnl Comments are as per sol2*.
3422     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock(sigmask(SIGCLD)); if (grantpt(fd) == -1) fatal("could not grant slave pty"); sigunblock(sigmask(SIGCLD)); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }] )
3423     ;;
3424 esac
3425
3426
3427 case $opsys in
3428   sol2* | unixware )
3429     dnl This change means that we don't loop through allocate_pty too
3430     dnl many times in the (rare) event of a failure.
3431     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3432     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");] )
3433     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3434     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3435     ;;
3436 esac
3437
3438
3439 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3440 "typing" a signal character on the pty.])
3441
3442 case $opsys in
3443   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3444   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3445   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3446     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3447     ;;
3448
3449   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3450   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3451   gnu-linux | gnu-kfreebsd )
3452
3453     AC_MSG_CHECKING([for signals via characters])
3454     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3455 #include <linux/version.h>
3456 #if LINUX_VERSION_CODE < 0x20400
3457 # error "Linux version too old"
3458 #endif
3459       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3460
3461     AC_MSG_RESULT([$emacs_signals_via_chars])
3462     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3463     ;;
3464 esac
3465
3466
3467 dnl Used in dispnew.c
3468 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3469 buffer of a stdio stream.])
3470
3471 dnl FIXME just PENDING_OUTPUT_COUNT should suffice.
3472 AH_TEMPLATE(GNU_LIBRARY_PENDING_OUTPUT_COUNT, [Value of
3473 PENDING_OUTPUT_COUNT if using the GNU C library.])
3474
3475 case $opsys in
3476   cygwin | darwin | freebsd | netbsd | openbsd )
3477     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3478     ;;
3479
3480   unixware)
3481     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3482     ;;
3483
3484   gnu | gnu-linux | gnu-kfreebsd )
3485     AC_MSG_CHECKING([for style of pending output formalism])
3486     dnl In autoconf 2.67 and later, we could use a single test
3487     dnl since the preprocessed output is accessible in "conftest.i".
3488     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3489 #include <stdio.h>
3490 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3491 # error "stdio definitions not found"
3492 #endif
3493       ]], [[]])], emacs_pending_output=new, emacs_pending_output=unknown)
3494
3495       if test $emacs_pending_output = unknown; then
3496         case $opsys in
3497           gnu-linux | gnu-kfreebsd)
3498             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3499 #include <stdio.h>
3500 #ifndef __UCLIBC__
3501 # error "not using uclibc"
3502 #endif
3503             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3504             ;;
3505         esac
3506       fi
3507
3508       AC_MSG_RESULT([$emacs_pending_output])
3509
3510       case $emacs_pending_output in
3511         new)
3512           dnl New C libio names.
3513           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3514             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3515           ;;
3516         uclibc)
3517           dnl Using the uClibc library.
3518           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3519             [((FILE)->__bufpos - (FILE)->__bufstart)])
3520           ;;
3521         old)
3522           dnl Old C++ iostream names.
3523           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3524             [((FILE)->_pptr - (FILE)->_pbase)])
3525           ;;
3526       esac
3527     ;;
3528 esac
3529
3530
3531 dnl Used in vm-limit.c
3532 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3533 dnl Used in lisp.h, emacs.c, mem-limits.h
3534 dnl NEWS.18 describes this as "a number which contains
3535 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3536 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3537 stored in a Lisp_Object.])
3538 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3539
3540 case $opsys in
3541   gnu)
3542     dnl libc defines data_start.
3543     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3544     ;;
3545
3546   hpux*)
3547     dnl The data segment on this machine always starts at address 0x40000000.
3548     AC_DEFINE(DATA_START, [0x40000000])
3549     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3550     ;;
3551   irix6-5)
3552     AC_DEFINE(DATA_START, [0x10000000])
3553     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3554     ;;
3555 esac
3556
3557
3558 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3559 AH_TEMPLATE(TAB3, [Undocumented.])
3560
3561 case $opsys in
3562   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3563
3564   gnu | freebsd | netbsd | openbsd )
3565     AC_DEFINE(TABDLY, OXTABS, [Undocumented.] )
3566     AC_DEFINE(TAB3, OXTABS)
3567     ;;
3568
3569   gnu-linux | gnu-kfreebsd )
3570     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3571     dnl library, we cannot get the maximum address for brk.
3572     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3573 #ifndef __i386__
3574 # error "not i386"
3575 #endif
3576       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3577
3578     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3579 #ifndef __ia64__
3580 # error "not ia64"
3581 #endif
3582       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3583         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3584         [Mark a secondary stack, like the register stack on the ia64.]), [])
3585     ;;
3586
3587   hpux*)
3588     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3589       run_time_remap; for HPUX.])
3590     ;;
3591
3592   irix6-5)
3593     dnl Ulimit(UL_GMEMLIM) is busted...
3594     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3595     ;;
3596 esac
3597
3598
3599 dnl These won't be used automatically yet.  We also need to know, at least,
3600 dnl that the stack is continuous.
3601 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3602   registers relevant for conservative garbage collection in the jmp_buf.])
3603
3604 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3605   conservative garbage collection is not known to work.])
3606
3607
3608 case $opsys in
3609   aix4-2 | hpux* | unixware)
3610     dnl Conservative garbage collection has not been tested, so for now
3611     dnl play it safe and stick with the old-fashioned way of marking.
3612     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3613     ;;
3614
3615   dnl Not all the architectures are tested, but there are Debian packages
3616   dnl for SCM and/or Guile on them, so the technique must work.  See also
3617   dnl comments in alloc.c concerning setjmp and gcc.
3618   dnl Fixme: it's probably safe to just use the GCC conditional below.
3619   gnu-linux | gnu-kfreebsd )
3620     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3621 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3622   || defined __alpha__ || defined __mips__ || defined __s390__ \
3623   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3624   || defined __ia64__ || defined __sh__
3625 /* ok */
3626 #else
3627 # error "setjmp not known to work on this arch"
3628 #endif
3629     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3630       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3631     ;;
3632 esac
3633
3634
3635 if test x$GCC = xyes; then
3636    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3637    AC_DEFINE(GC_SETJMP_WORKS, 1)
3638 else
3639   case $opsys in
3640     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3641     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3642       AC_DEFINE(GC_SETJMP_WORKS, 1)
3643       ;;
3644   esac
3645 fi                              dnl GCC?
3646
3647
3648 dnl Used in xfaces.c.
3649 case $opsys in
3650   hpux* | sol2* )
3651     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3652       some systems, where it requires time.h.])
3653     ;;
3654 esac
3655
3656
3657 dnl Define symbols to identify the version of Unix this is.
3658 dnl Define all the symbols that apply correctly.
3659 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3660 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3661 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3662 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3663
3664 case $opsys in
3665   aix4-2)
3666     AC_DEFINE(USG, [])
3667     AC_DEFINE(USG5, [])
3668     dnl This symbol should be defined on AIX Version 3  ???????
3669     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3670 #ifndef _AIX
3671 # error "_AIX not defined"
3672 #endif
3673     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3674     ;;
3675
3676   cygwin)
3677     opsysfile=
3678     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3679     ;;
3680
3681   darwin)
3682     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3683     AC_DEFINE(BSD4_2, [])
3684     AC_DEFINE(BSD_SYSTEM, [])
3685     dnl More specific than the above two.  We cannot use __APPLE__ as this
3686     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3687     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3688     dnl distinguish OS X from pure Darwin.
3689     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3690     ;;
3691
3692   freebsd)
3693     AC_DEFINE(BSD4_2, [])
3694     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3695     dnl Would not be needed with autoconf >= 2.67, where the
3696     dnl preprocessed output is accessible in "conftest.i".
3697     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3698     ;;
3699
3700   gnu | netbsd | openbsd )
3701     AC_DEFINE(BSD4_2, [])
3702     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3703 #ifndef BSD_SYSTEM
3704 # error "BSD_SYSTEM not defined"
3705 #endif
3706     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3707     ;;
3708
3709   gnu-linux | gnu-kfreebsd )
3710     AC_DEFINE(USG, [])
3711     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3712     ;;
3713
3714   hpux*)
3715     AC_DEFINE(USG, [])
3716     AC_DEFINE(USG5, [])
3717     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3718     ;;
3719
3720   irix6-5)
3721     AC_DEFINE(USG, [])
3722     AC_DEFINE(USG5, [])
3723     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3724     ;;
3725
3726   sol2*)
3727     AC_DEFINE(USG, [])
3728     AC_DEFINE(USG5, [])
3729     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3730     ;;
3731
3732   unixware)
3733     AC_DEFINE(USG, [])
3734     AC_DEFINE(USG5, [])
3735     ;;
3736 esac
3737
3738
3739 case $opsys in
3740   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3741   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3742   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3743   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3744   cygwin)
3745     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3746       G_SLICE environment variable to "always-malloc" at startup, if
3747       using GTK.])
3748     ;;
3749
3750   gnu) opsysfile= ;;
3751
3752   gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3753
3754   hpux11)
3755     dnl See comments in sysdep.c:sys_signal.
3756     dnl SA_RESTART resets the timeout of `select' on hpux11.
3757     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3758     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3759       be used in batch mode.])
3760     dnl It works to open the pty's tty in the parent (Emacs), then
3761     dnl close and reopen it in the child.
3762     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3763       works to open a pty's tty in the parent process, then close and
3764       reopen it in the child.])
3765
3766     opsysfile="s/hpux10-20.h"
3767     ;;
3768
3769   irix6-5)
3770     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3771       use VSUSP instead of VSWTCH.])
3772     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
3773       should not call setpgrp.])
3774     ;;
3775
3776   openbsd) opsysfile="s/netbsd.h" ;;
3777
3778   sol2-10)
3779     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3780       on Solaris.])
3781     opsysfile="s/sol2-6.h"
3782     ;;
3783 esac
3784
3785 # Set up the CFLAGS for real compilation, so we can substitute it.
3786 CFLAGS="$REAL_CFLAGS"
3787 CPPFLAGS="$REAL_CPPFLAGS"
3788
3789 ## Hack to detect a buggy GCC version.
3790 if test "x$GCC" = xyes \
3791    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3792    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3793    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3794    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3795 fi
3796
3797 version=$PACKAGE_VERSION
3798
3799 ### Specify what sort of things we'll be editing into Makefile and config.h.
3800 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3801 AC_SUBST(version)
3802 AC_SUBST(configuration)
3803 ## Unused?
3804 AC_SUBST(canonical)
3805 AC_SUBST(srcdir)
3806 AC_SUBST(prefix)
3807 AC_SUBST(exec_prefix)
3808 AC_SUBST(bindir)
3809 AC_SUBST(datadir)
3810 AC_SUBST(sharedstatedir)
3811 AC_SUBST(libexecdir)
3812 AC_SUBST(mandir)
3813 AC_SUBST(infodir)
3814 AC_SUBST(lispdir)
3815 AC_SUBST(leimdir)
3816 AC_SUBST(standardlisppath)
3817 AC_SUBST(locallisppath)
3818 AC_SUBST(lisppath)
3819 AC_SUBST(x_default_search_path)
3820 AC_SUBST(etcdir)
3821 AC_SUBST(archlibdir)
3822 AC_SUBST(docdir)
3823 AC_SUBST(bitmapdir)
3824 AC_SUBST(gamedir)
3825 AC_SUBST(gameuser)
3826 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3827 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3828 ## end of LIBX_BASE, but nothing ever set it.
3829 AC_SUBST(LD_SWITCH_X_SITE)
3830 AC_SUBST(C_SWITCH_X_SITE)
3831 AC_SUBST(GNUSTEP_CFLAGS)
3832 AC_SUBST(CFLAGS)
3833 ## Used in lwlib/Makefile.in.
3834 AC_SUBST(X_TOOLKIT_TYPE)
3835 if test -n "${opsysfile}"; then
3836   S_FILE="\$(srcdir)/${opsysfile}"
3837 else
3838   S_FILE=
3839 fi
3840 AC_SUBST(S_FILE)
3841 AC_SUBST(ns_appdir)
3842 AC_SUBST(ns_appbindir)
3843 AC_SUBST(ns_appresdir)
3844 AC_SUBST(ns_appsrc)
3845 AC_SUBST(GNU_OBJC_CFLAGS)
3846 AC_SUBST(OTHER_FILES)
3847
3848 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3849                    [Define to the canonical Emacs configuration name.])
3850 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3851                    [Define to the options passed to configure.])
3852 if test -n "$opsysfile"; then
3853   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3854                      [Define to the used os dependent file.])
3855 fi
3856
3857 XMENU_OBJ=
3858 XOBJ=
3859 FONT_OBJ=
3860 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3861   AC_DEFINE(HAVE_X_WINDOWS, 1,
3862             [Define to 1 if you want to use the X window system.])
3863   XMENU_OBJ=xmenu.o
3864   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3865   FONT_OBJ=xfont.o
3866   if test "$HAVE_XFT" = "yes"; then
3867     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3868   elif test "$HAVE_FREETYPE" = "yes"; then
3869     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3870   fi
3871   AC_SUBST(FONT_OBJ)
3872 fi
3873 AC_SUBST(XMENU_OBJ)
3874 AC_SUBST(XOBJ)
3875 AC_SUBST(FONT_OBJ)
3876
3877 WIDGET_OBJ=
3878 MOTIF_LIBW=
3879 if test "${USE_X_TOOLKIT}" != "none" ; then
3880   WIDGET_OBJ=widget.o
3881   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3882   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3883     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3884   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3885     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3886     MOTIF_LIBW=-lXm
3887     case "$opsys" in
3888       gnu-linux)
3889         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3890         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3891         ;;
3892
3893       unixware)
3894         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3895         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3896         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3897         ;;
3898
3899       aix4-2)
3900         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3901         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3902         ;;
3903     esac
3904     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3905   fi
3906 fi
3907 AC_SUBST(WIDGET_OBJ)
3908
3909 TOOLKIT_LIBW=
3910 case "$USE_X_TOOLKIT" in
3911   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3912   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3913   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3914 esac
3915 AC_SUBST(TOOLKIT_LIBW)
3916
3917 if test "$USE_X_TOOLKIT" = "none"; then
3918   LIBXT_OTHER="\$(LIBXSM)"
3919   OLDXMENU_TARGET="really-oldXMenu"
3920 else
3921   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3922   OLDXMENU_TARGET="really-lwlib"
3923 fi
3924 AC_SUBST(LIBXT_OTHER)
3925
3926 ## The X Menu stuff is present in the X10 distribution, but missing
3927 ## from X11.  If we have X10, just use the installed library;
3928 ## otherwise, use our own copy.
3929 if test "${HAVE_X11}" = "yes" ; then
3930   AC_DEFINE(HAVE_X11, 1,
3931             [Define to 1 if you want to use version 11 of X windows.
3932              Otherwise, Emacs expects to use version 10.])
3933
3934   if test "$USE_X_TOOLKIT" = "none"; then
3935     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3936   else
3937     OLDXMENU="\${lwlibdir}/liblw.a"
3938   fi
3939   LIBXMENU="\$(OLDXMENU)"
3940   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3941   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3942 else
3943   ## For a syntactically valid Makefile; not actually used for anything.
3944   ## See comments in src/Makefile.in.
3945   OLDXMENU=nothing
3946   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3947   if test "${HAVE_X_WINDOWS}" = "yes"; then
3948     LIBXMENU="-lXMenu"
3949   else
3950     LIBXMENU=
3951   fi
3952   LIBX_OTHER=
3953   OLDXMENU_DEPS=
3954 fi
3955
3956 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3957   OLDXMENU_TARGET=
3958   OLDXMENU=nothing
3959   LIBXMENU=
3960   OLDXMENU_DEPS=
3961 fi
3962
3963 AC_SUBST(OLDXMENU_TARGET)
3964 AC_SUBST(OLDXMENU)
3965 AC_SUBST(LIBXMENU)
3966 AC_SUBST(LIBX_OTHER)
3967 AC_SUBST(OLDXMENU_DEPS)
3968
3969 if test "${HAVE_MENUS}" = "yes" ; then
3970   AC_DEFINE(HAVE_MENUS, 1,
3971             [Define to 1 if you have mouse menus.
3972              (This is automatic if you use X, but the option to specify it remains.)
3973              It is also defined with other window systems that support xmenu.c.])
3974 fi
3975
3976 if test "${GNU_MALLOC}" = "yes" ; then
3977   AC_DEFINE(GNU_MALLOC, 1,
3978             [Define to 1 if you want to use the GNU memory allocator.])
3979 fi
3980
3981 RALLOC_OBJ=
3982 if test "${REL_ALLOC}" = "yes" ; then
3983   AC_DEFINE(REL_ALLOC, 1,
3984             [Define REL_ALLOC if you want to use the relocating allocator for
3985              buffer space.])
3986
3987   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3988 fi
3989 AC_SUBST(RALLOC_OBJ)
3990
3991 if test "$opsys" = "cygwin"; then
3992   CYGWIN_OBJ="sheap.o"
3993   ## Cygwin differs because of its unexec().
3994   PRE_ALLOC_OBJ=
3995   POST_ALLOC_OBJ=lastfile.o
3996 else
3997   CYGWIN_OBJ=
3998   PRE_ALLOC_OBJ=lastfile.o
3999   POST_ALLOC_OBJ=
4000 fi
4001 AC_SUBST(CYGWIN_OBJ)
4002 AC_SUBST(PRE_ALLOC_OBJ)
4003 AC_SUBST(POST_ALLOC_OBJ)
4004
4005 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4006 # it temporarily reverts them to their pre-pkg-config values,
4007 # because gnulib needs to work with both src (which uses the
4008 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4009 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4010 # and it therefore needs to run in an environment where LIBS does not
4011 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4012 # for some package unrelated to lib-src.
4013 SAVE_CFLAGS=$CFLAGS
4014 SAVE_LIBS=$LIBS
4015 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4016 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4017 gl_ASSERT_NO_GNULIB_POSIXCHECK
4018 gl_ASSERT_NO_GNULIB_TESTS
4019 gl_INIT
4020 CFLAGS=$SAVE_CFLAGS
4021 LIBS=$SAVE_LIBS
4022
4023 case "$opsys" in
4024   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4025
4026   darwin)
4027    ## The -headerpad option tells ld (see man page) to leave room at the
4028    ## end of the header for adding load commands.  Needed for dumping.
4029    ## 0x690 is the total size of 30 segment load commands (at 56
4030    ## each); under Cocoa 31 commands are required.
4031    if test "$HAVE_NS" = "yes"; then
4032      libs_nsgui="-framework AppKit"
4033      headerpad_extra=6C8
4034    else
4035      libs_nsgui=
4036      headerpad_extra=690
4037    fi
4038    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4039
4040    ## This is here because src/Makefile.in did some extra fiddling around
4041    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4042    ##   #ifndef LD_SWITCH_SYSTEM
4043    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4044    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4045    ## not using gcc, darwin.
4046    ## Because this was done in src/Makefile.in, the resulting part of
4047    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4048    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4049    ## rather than LD_SWITCH_SYSTEM.
4050    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4051      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4052    ;;
4053
4054   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4055   ## find X at run-time.
4056   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4057   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4058   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4059   ## had different values in configure (in ac_link) and src/Makefile.in.
4060   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4061   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4062
4063   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4064 esac
4065
4066 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4067   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4068 fi
4069
4070 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4071
4072
4073 LD_FIRSTFLAG=
4074 ORDINARY_LINK=
4075 case "$opsys" in
4076   ## gnu: GNU needs its own crt0.
4077   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4078
4079   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4080   ## library search parth, i.e. it won't search /usr/lib for libc and
4081   ## friends.  Using -nostartfiles instead avoids this problem, and
4082   ## will also work on earlier NetBSD releases.
4083   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4084
4085   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4086   ##   MkLinux/LinuxPPC needs this.
4087   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4088   gnu-*)
4089     case "$canonical" in
4090       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4091     esac
4092     ;;
4093 esac
4094
4095
4096 if test "x$ORDINARY_LINK" = "xyes"; then
4097
4098   LD_FIRSTFLAG=""
4099   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4100
4101 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4102 ## freebsd, gnu-* not on powerpc*|s390x*.
4103 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4104
4105   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4106   ## places that are difficult to figure out at make time.  Fortunately,
4107   ## these same versions allow you to pass arbitrary flags on to the
4108   ## linker, so there is no reason not to use it as a linker.
4109   ##
4110   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4111   ## searching for libraries in its internal directories, so we have to
4112   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4113   LD_FIRSTFLAG="-nostdlib"
4114 fi
4115
4116 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4117 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4118
4119 AC_SUBST(LD_FIRSTFLAG)
4120
4121
4122 ## FIXME? The logic here is not precisely the same as that above.
4123 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4124 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4125 LIB_GCC=
4126 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4127
4128   case "$opsys" in
4129     freebsd|netbsd|openbsd) LIB_GCC= ;;
4130
4131     gnu-*)
4132       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4133       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4134       case $host_cpu in
4135       arm*)
4136         LIB_GCC="-lgcc_s"
4137         ;;
4138       *)
4139         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4140         ## immediately undefine it again and redefine it to empty.
4141         ## Was the C_SWITCH_X_SITE part really necessary?
4142 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4143         LIB_GCC=
4144         ;;
4145       esac
4146       ;;
4147
4148     ## Ask GCC where to find libgcc.a.
4149     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4150   esac
4151 fi                              dnl if $GCC
4152 AC_SUBST(LIB_GCC)
4153
4154
4155 ## If we're using X11/GNUstep, define some consequences.
4156 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
4157   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4158   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4159 fi
4160
4161
4162 AH_TOP([/* GNU Emacs site configuration template file.
4163
4164 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4165   Free Software Foundation, Inc.
4166
4167 This file is part of GNU Emacs.
4168
4169 GNU Emacs is free software: you can redistribute it and/or modify
4170 it under the terms of the GNU General Public License as published by
4171 the Free Software Foundation, either version 3 of the License, or
4172 (at your option) any later version.
4173
4174 GNU Emacs is distributed in the hope that it will be useful,
4175 but WITHOUT ANY WARRANTY; without even the implied warranty of
4176 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4177 GNU General Public License for more details.
4178
4179 You should have received a copy of the GNU General Public License
4180 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4181
4182
4183 /* No code in Emacs #includes config.h twice, but some bits of code
4184    intended to work with other packages as well (like gmalloc.c)
4185    think they can include it as many times as they like.  */
4186 #ifndef EMACS_CONFIG_H
4187 #define EMACS_CONFIG_H
4188 ])dnl
4189
4190 AH_BOTTOM([
4191 /* On AIX 3 this must be included before any other include file.  */
4192 #include <alloca.h>
4193 #if ! HAVE_ALLOCA
4194 # error "alloca not available on this machine"
4195 #endif
4196
4197 /* This silences a few compilation warnings on FreeBSD.  */
4198 #ifdef BSD_SYSTEM_AHB
4199 #undef BSD_SYSTEM_AHB
4200 #undef BSD_SYSTEM
4201 #if __FreeBSD__ == 1
4202 #define BSD_SYSTEM 199103
4203 #elif __FreeBSD__ == 2
4204 #define BSD_SYSTEM 199306
4205 #elif __FreeBSD__ >= 3
4206 #define BSD_SYSTEM 199506
4207 #endif
4208 #endif
4209
4210 /* Define AMPERSAND_FULL_NAME if you use the convention
4211    that & in the full name stands for the login id.  */
4212 /* Turned on June 1996 supposing nobody will mind it.  */
4213 #define AMPERSAND_FULL_NAME
4214
4215 /* `subprocesses' should be defined if you want to
4216    have code for asynchronous subprocesses
4217    (as used in M-x compile and M-x shell).
4218    Only MSDOS does not support this (it overrides
4219    this in its config_opsysfile below).  */
4220
4221 #define subprocesses
4222
4223 /* Include the os dependent file.  */
4224 #ifdef config_opsysfile
4225 # include config_opsysfile
4226 #endif
4227
4228 /* Mac OS X / GNUstep need a bit more pure memory.  Of the existing knobs,
4229    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
4230 #ifdef HAVE_NS
4231 #if defined NS_IMPL_GNUSTEP
4232 #  define SYSTEM_PURESIZE_EXTRA 30000
4233 #elif defined DARWIN_OS
4234 #  define SYSTEM_PURESIZE_EXTRA 200000
4235 #endif
4236 #endif
4237
4238 #ifdef emacs /* Don't do this for lib-src.  */
4239 /* Tell regex.c to use a type compatible with Emacs.  */
4240 #define RE_TRANSLATE_TYPE Lisp_Object
4241 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
4242 #ifdef make_number
4243 /* If make_number is a macro, use it.  */
4244 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
4245 #else
4246 /* If make_number is a function, avoid it.  */
4247 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
4248 #endif
4249 #endif
4250
4251 #include <string.h>
4252 #include <stdlib.h>
4253
4254 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
4255 #define NO_INLINE __attribute__((noinline))
4256 #else
4257 #define NO_INLINE
4258 #endif
4259
4260 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
4261 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
4262 #else
4263 #define EXTERNALLY_VISIBLE
4264 #endif
4265
4266 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
4267 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
4268 #else
4269 # define ATTRIBUTE_FORMAT(spec) /* empty */
4270 #endif
4271
4272 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
4273 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
4274    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
4275 #else
4276 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
4277    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
4278 #endif
4279
4280 #define ATTRIBUTE_CONST _GL_ATTRIBUTE_CONST
4281
4282 /* Some versions of GNU/Linux define noinline in their headers.  */
4283 #ifdef noinline
4284 #undef noinline
4285 #endif
4286
4287 #endif /* EMACS_CONFIG_H */
4288
4289 /*
4290 Local Variables:
4291 mode: c
4292 End:
4293 */
4294 ])dnl
4295
4296 #### Report on what we decided to do.
4297 #### Report GTK as a toolkit, even if it doesn't use Xt.
4298 #### It makes printing result more understandable as using GTK sets
4299 #### toolkit_scroll_bars to yes by default.
4300 if test "${HAVE_GTK}" = "yes"; then
4301   if test "${with_gtk3}" = "yes"; then
4302     USE_X_TOOLKIT=GTK3
4303   else
4304     USE_X_TOOLKIT=GTK
4305   fi
4306 fi
4307
4308 echo "
4309 Configured for \`${canonical}'.
4310
4311   Where should the build process find the source code?    ${srcdir}
4312   What operating system file should Emacs use?            ${opsysfile-none}
4313   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4314   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4315   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4316   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4317   What window system should Emacs use?                    ${window_system}
4318   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4319
4320 if test -n "${x_includes}"; then
4321 echo "  Where do we find X Windows header files?                ${x_includes}"
4322 else
4323 echo "  Where do we find X Windows header files?                Standard dirs"
4324 fi
4325 if test -n "${x_libraries}"; then
4326 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4327 else
4328 echo "  Where do we find X Windows libraries?                   Standard dirs"
4329 fi
4330
4331 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4332 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4333 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4334 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4335 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4336 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4337 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4338 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4339
4340 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4341 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4342 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4343 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4344 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4345 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4346 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4347
4348 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4349 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4350 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4351 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4352
4353 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4354 echo
4355
4356 if test -n "${EMACSDATA}"; then
4357    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4358 fi
4359 if test -n "${EMACSDOC}"; then
4360    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4361 fi
4362
4363 echo
4364
4365 if test "$HAVE_NS" = "yes"; then
4366    echo
4367    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4368 The installed application will go to nextstep/Emacs.app and can be
4369 run or moved from there."
4370    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4371       echo "The application will be fully self-contained."
4372     else
4373       echo "The lisp resources for the application will be installed under ${prefix}.
4374 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4375 to run if these resources are not installed."
4376    fi
4377    echo
4378 fi
4379
4380 if test "${opsys}" = "cygwin"; then
4381   case `uname -r` in
4382     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4383            echo
4384            ;;
4385   esac
4386 fi
4387
4388 # Remove any trailing slashes in these variables.
4389 [test "${prefix}" != NONE &&
4390   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4391 test "${exec_prefix}" != NONE &&
4392   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4393
4394 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4395 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4396 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4397 dnl (else you get "no `Makefile.am' found for any configure output").
4398 dnl This will work, but you get a config.status that is not quite right
4399 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4400 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4401 dnl it seems better to just live with the duplication.
4402 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4403
4404 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4405        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4406        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4407        leim/Makefile])
4408
4409 dnl test/ is not present in release tarfiles.
4410 opt_makefile=test/automated/Makefile
4411
4412 if test -f $srcdir/${opt_makefile}.in; then
4413   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4414   dnl Again, it's best not to use a variable.  Though you can add
4415   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4416   AC_CONFIG_FILES([test/automated/Makefile])
4417 fi
4418
4419
4420 dnl admin/ may or may not be present.
4421 opt_makefile=admin/unidata/Makefile
4422
4423 if test -f $srcdir/${opt_makefile}.in; then
4424   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4425   AC_CONFIG_FILES([admin/unidata/Makefile])
4426 fi
4427
4428
4429 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4430
4431 AC_SUBST(SUBDIR_MAKEFILES_IN)
4432
4433 dnl Make the necessary directories, if they don't exist.
4434 AC_CONFIG_COMMANDS([mkdirs], [
4435 for dir in etc lisp ; do
4436   test -d ${dir} || mkdir ${dir}
4437 done
4438 ])
4439
4440 dnl You might wonder (I did) why epaths.h is generated by running make,
4441 dnl rather than just letting configure generate it from epaths.in.
4442 dnl One reason is that the various paths are not fully expanded (see above);
4443 dnl eg gamedir=${prefix}/var/games/emacs.
4444 dnl Secondly, the GNU Coding standards require that one should be able
4445 dnl to run `make prefix=/some/where/else' and override the values set
4446 dnl by configure.  This also explains the `move-if-change' test and
4447 dnl the use of force in the `epaths-force' rule in Makefile.in.
4448 AC_CONFIG_COMMANDS([epaths], [
4449 echo creating src/epaths.h
4450 ${MAKE-make} epaths-force
4451 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4452
4453 AC_CONFIG_COMMANDS([gdbinit], [
4454 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4455   echo creating src/.gdbinit
4456   echo source $srcdir/src/.gdbinit > src/.gdbinit
4457 fi
4458 ])
4459
4460 AC_OUTPUT