lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add GIT to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'GIT)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        ?? PROBABLY NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * workfile-version (file)                       OK
  57 ;; - latest-on-branch-p (file)                     ??
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       NOT NEEDED
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-version (file)                           ??
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NEEDED
  68 ;; - receive-file (file rev)                       ??
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-version (file rev buffer)                OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              ?? PROBABLY NOT NEEDED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional version)           NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (version)                      NOT NEEDED, DEFAULT IS GOOD
  85 ;; - wash-log (file)                               ??
  86 ;; - logentry-check ()                             ??
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      ??
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (file)              NEEDED?
  91 ;; - diff-tree (dir &optional rev1 rev2)           OK
  92 ;; - annotate-command (file buf &optional rev)     OK
  93 ;; - annotate-time ()                              OK
  94 ;; - annotate-current-time ()                      ?? NOT NEEDED
  95 ;; - annotate-extract-revision-at-line ()          OK
  96 ;; SNAPSHOT SYSTEM
  97 ;; - create-snapshot (dir name branchp)            OK
  98 ;; - assign-name (file name)                       NOT NEEDED
  99 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
 100 ;; MISCELLANEOUS
 101 ;; - make-version-backups-p (file)                 ??
 102 ;; - repository-hostname (dirname)                 ??
 103 ;; - previous-version (file rev)                   OK
 104 ;; - next-version (file rev)                       OK
 105 ;; - check-headers ()                              ??
 106 ;; - clear-headers ()                              ??
 107 ;; - delete-file (file)                            OK
 108 ;; - rename-file (old new)                         OK
 109 ;; - find-file-hook ()                             PROBABLY NOT NEEDED
 110 ;; - find-file-not-found-hook ()                   PROBABLY NOT NEEDED
 111
 112 (eval-when-compile (require 'cl) (require 'vc))
 113
 114 (defvar git-commits-coding-system 'utf-8
 115   "Default coding system for git commits.")
 116
 117 ;; XXX when this backend is considered sufficiently reliable this
 118 ;; should be moved to vc-hooks.el
 119 (add-to-list 'vc-handled-backends 'GIT)
 120 (eval-after-load "vc"
 121   '(add-to-list 'vc-directory-exclusion-list ".git" t))
 122
 123 ;;; BACKEND PROPERTIES
 124
 125 (defun vc-git-revision-granularity ()
 126      'repository)
 127
 128 ;;; STATE-QUERYING FUNCTIONS
 129
 130 ;;;###autoload (defun vc-git-registered (file)
 131 ;;;###autoload   "Return non-nil if FILE is registered with git."
 132 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 133 ;;;###autoload       (progn
 134 ;;;###autoload         (load "vc-git")
 135 ;;;###autoload         (vc-git-registered file))))
 136
 137 (defun vc-git-registered (file)
 138   "Check whether FILE is registered with git."
 139   (when (vc-git-root file)
 140     (with-temp-buffer
 141       (let* ((dir (file-name-directory file))
 142              (name (file-relative-name file dir)))
 143         (and (ignore-errors
 144               (when dir (cd dir))
 145               (eq 0 (call-process "git" nil '(t nil) nil "ls-files" "-c" "-z" "--" name)))
 146              (let ((str (buffer-string)))
 147                (and (> (length str) (length name))
 148                     (string= (substring str 0 (1+ (length name))) (concat name "\0")))))))))
 149
 150 (defun vc-git-state (file)
 151   "Git-specific version of `vc-state'."
 152   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 153     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0" diff))
 154         'edited
 155       'up-to-date)))
 156
 157 (defun vc-git-dir-state (dir)
 158   (with-temp-buffer
 159     (vc-git-command (current-buffer) nil nil "ls-files" "-t")
 160     (goto-char (point-min))
 161     (let ((status-char nil)
 162           (file nil))
 163       (while (not (eobp))
 164         (setq status-char (char-after))
 165         (setq file
 166               (expand-file-name
 167                (buffer-substring-no-properties (+ (point) 2) (line-end-position))))
 168         (cond
 169          ;; The rest of the possible states in "git ls-files -t" output:
 170          ;;      R              removed/deleted
 171          ;;      K              to be killed
 172          ;; should not show up in vc-dired, so don't deal with them
 173          ;; here.
 174          ((eq status-char ?H)
 175           (vc-file-setprop file 'vc-state 'up-to-date))
 176          ((eq status-char ?M)
 177           (vc-file-setprop file 'vc-state 'edited))
 178          ((eq status-char ?C)
 179           (vc-file-setprop file 'vc-state 'edited))
 180          ((eq status-char ??)
 181           (vc-file-setprop file 'vc-backend 'none)
 182           (vc-file-setprop file 'vc-state 'nil)))
 183         (forward-line)))))
 184
 185 (defun vc-git-workfile-version (file)
 186   "Git-specific version of `vc-workfile-version'."
 187   (let ((str (with-output-to-string
 188                (with-current-buffer standard-output
 189                  (call-process "git" nil '(t nil) nil "symbolic-ref" "HEAD")))))
 190     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 191         (match-string 2 str)
 192       str)))
 193
 194 (defun vc-git-checkout-model (file)
 195   'implicit)
 196
 197 (defun vc-git-workfile-unchanged-p (file)
 198   ;; The reason this does not use the result of vc-git-state is that
 199   ;; git-diff-index (used by vc-git-state) doesn't refresh the cached
 200   ;; stat info, so if the file has been modified it will always show
 201   ;; up as modified in vc-git-state, even if the change has been
 202   ;; undone, until git-update-index --refresh is run.
 203
 204   ;; OTOH the vc-git-workfile-unchanged-p implementation checks the
 205   ;; actual content, so it will detect the case of a file reverted
 206   ;; back to its original state.
 207
 208   ;; The ideal implementation would be to refresh the stat cache and
 209   ;; then call vc-git-state, but at the moment there's no git command
 210   ;; to refresh a single file, so this will have to be added first.
 211   (let ((sha1 (vc-git--run-command-string file "hash-object" "--"))
 212         (head (vc-git--run-command-string file "ls-tree" "-z" "HEAD" "--")))
 213     (and head
 214          (string-match "[0-7]\\{6\\} blob \\([0-9a-f]\\{40\\}\\)\t[^\0]+\0" head)
 215          (string= (car (split-string sha1 "\n")) (match-string 1 head)))))
 216
 217 (defun vc-git-dired-state-info (file)
 218   "Git-specific version of `vc-dired-state-info'."
 219   (let ((git-state (vc-state file)))
 220     (if (eq git-state 'edited)
 221         "(modified)"
 222       ;; fall back to the default VC representation
 223       (vc-default-dired-state-info 'GIT file))))
 224
 225 ;;; STATE-CHANGING FUNCTIONS
 226
 227 (defun vc-git-create-repo ()
 228   "Create a new GIT repository."
 229   (vc-git-command "init" nil 0 nil))
 230
 231 (defun vc-git-register (files &optional rev comment)
 232   "Register FILE into the git version-control system."
 233   (vc-git-command nil 0 files "update-index" "--add" "--"))
 234
 235 (defalias 'vc-git-responsible-p 'vc-git-root)
 236
 237 (defun vc-git-unregister (file)
 238   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 239
 240
 241 (defun vc-git-checkin (files rev comment)
 242   (let ((coding-system-for-write git-commits-coding-system))
 243     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 244
 245 (defun vc-git-find-version (file rev buffer)
 246   (let ((coding-system-for-read 'binary)
 247         (coding-system-for-write 'binary)
 248         (fullname (substring
 249                    (vc-git--run-command-string
 250                     file "ls-files" "-z" "--full-name" "--")
 251                    0 -1)))
 252     (vc-git-command
 253      buffer 0
 254      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 255
 256 (defun vc-git-checkout (file &optional editable rev)
 257   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 258
 259 (defun vc-git-revert (file &optional contents-done)
 260   "Revert FILE to the version stored in the git repository."
 261   (if contents-done
 262       (vc-git-command nil 0 file "update-index" "--")
 263     (vc-git-command nil 0 file "checkout" "HEAD")))
 264
 265 ;;; HISTORY FUNCTIONS
 266
 267 (defun vc-git-print-log (files &optional buffer)
 268   "Get change log associated with FILES."
 269   (let ((coding-system-for-read git-commits-coding-system))
 270     ;; `vc-do-command' creates the buffer, but we need it before running
 271     ;; the command.
 272     (vc-setup-buffer buffer)
 273     ;; If the buffer exists from a previous invocation it might be
 274     ;; read-only.
 275     (let ((inhibit-read-only t))
 276       ;; XXX `log-view-mode' needs to have something to identify where
 277       ;; the log for each individual file starts. It seems that by
 278       ;; default git does not output this info. So loop here and call
 279       ;; "git rev-list" on each file separately to make sure that each
 280       ;; file gets a "File:" header before the corresponding
 281       ;; log. Maybe there is a way to do this with one command...
 282       (dolist (file files)
 283         (with-current-buffer
 284             buffer
 285           (insert "File: " (file-name-nondirectory file) "\n"))
 286         (vc-git-command buffer 'async (file-relative-name file)
 287                         "rev-list" "--pretty" "HEAD" "--")))))
 288
 289 (defvar log-view-message-re)
 290 (defvar log-view-file-re)
 291 (defvar log-view-font-lock-keywords)
 292
 293 (define-derived-mode vc-git-log-view-mode log-view-mode "GIT-Log-View"
 294   (require 'add-log) ;; we need the faces add-log
 295   ;; Don't have file markers, so use impossible regexp.
 296   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 297   (set (make-local-variable 'log-view-message-re)
 298        "^commit *\\([0-9a-z]+\\)")
 299   (set (make-local-variable 'log-view-font-lock-keywords)
 300        (append
 301        `((,log-view-message-re  (1 'change-log-acknowledgement))
 302          (,log-view-file-re (1 'change-log-file-face)))
 303          ;; Handle the case:
 304          ;; user: foo@bar
 305          '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 306             (1 'change-log-email))
 307            ;; Handle the case:
 308            ;; user: FirstName LastName <foo@bar>
 309            ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 310             (1 'change-log-name)
 311             (2 'change-log-email))
 312            ("^Date:   \\(.+\\)" (1 'change-log-date))
 313            ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 314
 315 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 316   (let ((buf (or buffer "*vc-diff*")))
 317     (if (and rev1 rev2)
 318         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p" rev1 rev2 "--")
 319       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p" (or rev1 "HEAD") "--"))))
 320
 321 (defun vc-git-diff-tree (dir &optional rev1 rev2)
 322   (vc-git-diff dir rev1 rev2))
 323
 324 (defun vc-git-annotate-command (file buf &optional rev)
 325   ;; FIXME: rev is ignored
 326   (let ((name (file-relative-name file)))
 327     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 328
 329 (defun vc-git-annotate-time ()
 330   (and (re-search-forward "[0-9a-f]+ (.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+)" nil t)
 331        (vc-annotate-convert-time
 332         (apply #'encode-time (mapcar (lambda (match) (string-to-number (match-string match))) '(6 5 4 3 2 1 7))))))
 333
 334 (defun vc-git-annotate-extract-revision-at-line ()
 335  (save-excursion
 336    (move-beginning-of-line 1)
 337    (and (looking-at "[0-9a-f]+")
 338         (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 339
 340 ;;; SNAPSHOT SYSTEM
 341
 342 (defun vc-git-create-snapshot (dir name branchp)
 343   (let ((default-directory dir))
 344     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 345          (if branchp
 346              (vc-git-command nil 0 nil "checkout" "-b" name)
 347            (vc-git-command nil 0 nil "tag" name)))))
 348
 349 (defun vc-git-retrieve-snapshot (dir name update)
 350   (let ((default-directory dir))
 351     (vc-git-command nil 0 nil "checkout" name)
 352     ;; FIXME: update buffers if `update' is true
 353     ))
 354
 355
 356 ;;; MISCELLANEOUS
 357
 358 (defun vc-git-previous-version (file rev)
 359   "Git-specific version of `vc-previous-version'."
 360   (let ((default-directory (file-name-directory (expand-file-name file)))
 361         (file (file-name-nondirectory file)))
 362     (vc-git-symbolic-commit
 363      (with-temp-buffer
 364        (and
 365         (zerop
 366          (call-process "git" nil '(t nil) nil "rev-list"
 367                        "-2" rev "--" file))
 368         (goto-char (point-max))
 369         (bolp)
 370         (zerop (forward-line -1))
 371         (not (bobp))
 372         (buffer-substring-no-properties
 373            (point)
 374            (1- (point-max))))))))
 375
 376 (defun vc-git-next-version (file rev)
 377   "Git-specific version of `vc-next-version'."
 378   (let* ((default-directory (file-name-directory
 379                              (expand-file-name file)))
 380         (file (file-name-nondirectory file))
 381         (current-rev
 382          (with-temp-buffer
 383            (and
 384             (zerop
 385              (call-process "git" nil '(t nil) nil "rev-list"
 386                            "-1" rev "--" file))
 387             (goto-char (point-max))
 388             (bolp)
 389             (zerop (forward-line -1))
 390             (bobp)
 391             (buffer-substring-no-properties
 392              (point)
 393              (1- (point-max)))))))
 394     (and current-rev
 395          (vc-git-symbolic-commit
 396           (with-temp-buffer
 397             (and
 398              (zerop
 399               (call-process "git" nil '(t nil) nil "rev-list"
 400                             "HEAD" "--" file))
 401              (goto-char (point-min))
 402              (search-forward current-rev nil t)
 403              (zerop (forward-line -1))
 404              (buffer-substring-no-properties
 405               (point)
 406               (progn (forward-line 1) (1- (point))))))))))
 407
 408 (defun vc-git-delete-file (file)
 409   (vc-git-command nil 0 file "rm" "-f" "--"))
 410
 411 (defun vc-git-rename-file (old new)
 412   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 413
 414 \f
 415 ;;; Internal commands
 416
 417 (defun vc-git-root (file)
 418   (vc-find-root file ".git"))
 419
 420 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 421   "A wrapper around `vc-do-command' for use in vc-git.el.
 422 The difference to vc-do-command is that this function always invokes `git'."
 423   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 424
 425 (defun vc-git--run-command-string (file &rest args)
 426   "Run a git command on FILE and return its output as string."
 427   (let* ((ok t)
 428          (str (with-output-to-string
 429                 (with-current-buffer standard-output
 430                   (unless (eq 0 (apply #'call-process "git" nil '(t nil) nil
 431                                        (append args (list (file-relative-name file)))))
 432                     (setq ok nil))))))
 433     (and ok str)))
 434
 435 (defun vc-git-symbolic-commit (commit)
 436   "Translate COMMIT string into symbolic form.
 437 Returns nil if not possible."
 438   (and commit
 439        (with-temp-buffer
 440          (and
 441           (zerop
 442            (call-process "git" nil '(t nil) nil "name-rev"
 443                          "--name-only" "--tags"
 444                          commit))
 445           (goto-char (point-min))
 446           (= (forward-line 2) 1)
 447           (bolp)
 448           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 449
 450 (provide 'vc-git)
 451
 452 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 453 ;;; vc-git.el ends here