configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010, 2011
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30 AM_INIT_AUTOMAKE
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 dnl _ON results in a '--without' option in the --help output, so
 150 dnl the help text should refer to "don't compile", etc.
 151 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 152 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 153 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 154 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 155 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 156 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 157 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 158 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 159
 160 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 161 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 162 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 163
 164 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 165 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 166 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 167 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 168
 169 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 170 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 171 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 172 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 173 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 174
 175 ## For the times when you want to build Emacs but don't have
 176 ## a suitable makeinfo, and can live without the manuals.
 177 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 178 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 179
 180 ## This is an option because I do not know if all info/man support
 181 ## compressed files, nor how to test if they do so.
 182 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 183 if test $with_compress_info = yes; then
 184    GZIP_INFO=yes
 185 else
 186    GZIP_INFO=
 187 fi
 188 AC_SUBST(GZIP_INFO)
 189
 190 AC_ARG_WITH([pkg-config-prog],dnl
 191 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 192                   [path to pkg-config for finding GTK and librsvg])])
 193 if test "X${with_pkg_config_prog}" != X; then
 194    if test "${with_pkg_config_prog}" != yes; then
 195       PKG_CONFIG="${with_pkg_config_prog}"
 196    fi
 197 fi
 198
 199 CRT_DIR=
 200 AC_ARG_WITH([crt-dir],dnl
 201 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 202 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 203 CRT_DIR="${with_crt_dir}"
 204
 205 AC_ARG_WITH(gameuser,dnl
 206 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 207 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 208   && gameuser="${with_gameuser}"
 209 test "X$gameuser" = X && gameuser=games
 210
 211 AC_ARG_WITH([gnustep-conf],dnl
 212 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 213 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 214   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 215 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 216      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 217
 218 AC_ARG_ENABLE(ns-self-contained,
 219 [AS_HELP_STRING([--disable-ns-self-contained],
 220                 [disable self contained build under NeXTstep])],
 221    EN_NS_SELF_CONTAINED=$enableval,
 222    EN_NS_SELF_CONTAINED=yes)
 223
 224 AC_ARG_ENABLE(asserts,
 225 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 226       USE_XASSERTS=$enableval,
 227       USE_XASSERTS=no)
 228
 229 AC_ARG_ENABLE(maintainer-mode,
 230 [AS_HELP_STRING([--enable-maintainer-mode],
 231                 [enable make rules and dependencies not useful (and sometimes
 232                  confusing) to the casual installer])],
 233       USE_MAINTAINER_MODE=$enableval,
 234       USE_MAINTAINER_MODE=no)
 235 if test $USE_MAINTAINER_MODE = yes; then
 236   MAINT=
 237 else
 238   MAINT=#
 239 fi
 240 AC_SUBST(MAINT)
 241
 242 AC_ARG_ENABLE(locallisppath,
 243 [AS_HELP_STRING([--enable-locallisppath=PATH],
 244                 [directories Emacs should search for lisp files specific
 245                  to this site])],
 246 if test "${enableval}" = "no"; then
 247   locallisppath=
 248 elif test "${enableval}" != "yes"; then
 249   locallisppath=${enableval}
 250 fi)
 251
 252 AC_ARG_ENABLE(checking,
 253 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 254                 [enable expensive run-time checks.  With LIST,
 255                  enable only specific categories of checks.
 256                  Categories are: all,yes,no.
 257                  Flags are: stringbytes, stringoverrun, stringfreelist,
 258                  xmallocoverrun, conslist])],
 259 [ac_checking_flags="${enableval}"],[])
 260 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 261 for check in $ac_checking_flags
 262 do
 263         case $check in
 264         # these set all the flags to specific states
 265         yes)            ac_enable_checking=1 ;;
 266         no)             ac_enable_checking= ;
 267                         ac_gc_check_stringbytes= ;
 268                         ac_gc_check_string_overrun= ;
 269                         ac_gc_check_string_free_list= ;
 270                         ac_xmalloc_overrun= ;
 271                         ac_gc_check_cons_list= ;;
 272         all)            ac_enable_checking=1 ;
 273                         ac_gc_check_stringbytes=1 ;
 274                         ac_gc_check_string_overrun=1 ;
 275                         ac_gc_check_string_free_list=1 ;
 276                         ac_xmalloc_overrun=1 ;
 277                         ac_gc_check_cons_list=1 ;;
 278         # these enable particular checks
 279         stringbytes)    ac_gc_check_stringbytes=1 ;;
 280         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 281         stringfreelist) ac_gc_check_string_free_list=1 ;;
 282         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 283         conslist)       ac_gc_check_cons_list=1 ;;
 284         *)      AC_MSG_ERROR(unknown check category $check) ;;
 285         esac
 286 done
 287 IFS="$ac_save_IFS"
 288
 289 if test x$ac_enable_checking != x ; then
 290   AC_DEFINE(ENABLE_CHECKING, 1,
 291 [Enable expensive run-time checking of data types?])
 292 fi
 293 if test x$ac_gc_check_stringbytes != x ; then
 294   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 295 [Define this temporarily to hunt a bug.  If defined, the size of
 296    strings is redundantly recorded in sdata structures so that it can
 297    be compared to the sizes recorded in Lisp strings.])
 298 fi
 299 if test x$ac_gc_check_stringoverrun != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 301 [Define this to check for short string overrun.])
 302 fi
 303 if test x$ac_gc_check_string_free_list != x ; then
 304   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 305 [Define this to check the string free list.])
 306 fi
 307 if test x$ac_xmalloc_overrun != x ; then
 308   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 309 [Define this to check for malloc buffer overrun.])
 310 fi
 311 if test x$ac_gc_check_cons_list != x ; then
 312   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 313 [Define this to check for errors in cons list.])
 314 fi
 315
 316 AC_ARG_ENABLE(use-lisp-union-type,
 317 [AS_HELP_STRING([--enable-use-lisp-union-type],
 318                 [use a union for the Lisp_Object data type.
 319                 This is only useful for development for catching certain types of bugs.])],
 320 if test "${enableval}" != "no"; then
 321    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 322    [Define this to use a lisp union for the Lisp_Object data type.])
 323 fi)
 324
 325
 326 AC_ARG_ENABLE(profiling,
 327 [AS_HELP_STRING([--enable-profiling],
 328                 [build emacs with profiling support.
 329                  This might not work on all platforms])],
 330 [ac_enable_profiling="${enableval}"],[])
 331 if test x$ac_enable_profiling != x ; then
 332    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 333 else
 334    PROFILING_CFLAGS=
 335 fi
 336 AC_SUBST(PROFILING_CFLAGS)
 337
 338 AC_ARG_ENABLE(autodepend,
 339 [AS_HELP_STRING([--enable-autodepend],
 340                 [automatically generate dependencies to .h-files.
 341                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 342                  found])],
 343 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 344
 345 #### Make srcdir absolute, if it isn't already.  It's important to
 346 #### avoid running the path through pwd unnecessarily, since pwd can
 347 #### give you automounter prefixes, which can go away.  We do all this
 348 #### so Emacs can find its files when run uninstalled.
 349 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 350 unset CDPATH
 351 case "${srcdir}" in
 352   /* ) ;;
 353   . )
 354     ## We may be able to use the $PWD environment variable to make this
 355     ## absolute.  But sometimes PWD is inaccurate.
 356     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 357     ## but that tested only for a well-formed and valid PWD,
 358     ## it did not object when PWD was well-formed and valid but just wrong.
 359     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 360     then
 361       srcdir="$PWD"
 362     else
 363       srcdir="`(cd ${srcdir}; pwd)`"
 364     fi
 365   ;;
 366   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 367 esac
 368
 369 #### Check if the source directory already has a configured system in it.
 370 if test `pwd` != `(cd ${srcdir} && pwd)` \
 371    && test -f "${srcdir}/src/config.h" ; then
 372   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 373    as a build directory right now; it has been configured in its own
 374    right.  To configure in another directory as well, you MUST
 375    use GNU make.  If you do not have GNU make, then you must
 376    now do `make distclean' in ${srcdir},
 377    and then run $0 again.]])
 378 fi
 379
 380 #### Given the configuration name, set machfile and opsysfile to the
 381 #### names of the m/*.h and s/*.h files we should use.
 382
 383 ### Canonicalize the configuration name.
 384
 385 AC_CANONICAL_HOST
 386 canonical=$host
 387 configuration=${host_alias-${build_alias-$host}}
 388
 389 dnl This used to use changequote, but, apart from `changequote is evil'
 390 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 391 dnl the great gob of text.  Thus it's not processed for possible expansion.
 392 dnl Just make sure the brackets remain balanced.
 393 dnl
 394 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 395 dnl indicated by comments.
 396 dnl quotation begins
 397 [
 398
 399 ### If you add support for a new configuration, add code to this
 400 ### switch statement to recognize your configuration name and select
 401 ### the appropriate operating system and machine description files.
 402
 403 ### You would hope that you could choose an m/*.h file pretty much
 404 ### based on the machine portion of the configuration name, and an s/*.h
 405 ### file based on the operating system portion.  However, it turns out
 406 ### that each m/*.h file is pretty manufacturer-specific - for
 407 ### example mips.h is MIPS
 408 ### So we basically have to have a special case for each
 409 ### configuration name.
 410 ###
 411 ### As far as handling version numbers on operating systems is
 412 ### concerned, make sure things will fail in a fixable way.  If
 413 ### /etc/MACHINES doesn't say anything about version numbers, be
 414 ### prepared to handle anything reasonably.  If version numbers
 415 ### matter, be sure /etc/MACHINES says something about it.
 416
 417 machine='' opsys='' unported=no
 418 case "${canonical}" in
 419
 420   ## GNU/Linux ports
 421   *-*-linux-gnu*)
 422     opsys=gnu-linux
 423     case ${canonical} in
 424       alpha*)   machine=alpha ;;
 425       s390-*)   machine=ibms390 ;;
 426       s390x-*)  machine=ibms390x ;;
 427       powerpc*) machine=macppc ;;
 428       sparc*)   machine=sparc ;;
 429       ia64*)    machine=ia64 ;;
 430       m68k*)    machine=m68k ;;
 431       x86_64*)  machine=amdx86-64 ;;
 432     esac
 433   ;;
 434
 435   ## FreeBSD ports
 436   *-*-freebsd* )
 437     opsys=freebsd
 438     case "${canonical}" in
 439       alpha*)           machine=alpha ;;
 440       amd64-*|x86_64-*) machine=amdx86-64 ;;
 441       ia64-*)           machine=ia64 ;;
 442       i[3456]86-*)      machine=intel386 ;;
 443       powerpc-*)        machine=macppc ;;
 444       sparc-*)          machine=sparc ;;
 445       sparc64-*)        machine=sparc ;;
 446     esac
 447   ;;
 448
 449   ## FreeBSD kernel + glibc based userland
 450   *-*-kfreebsd*gnu* )
 451     opsys=gnu-kfreebsd
 452     case "${canonical}" in
 453       alpha*)           machine=alpha ;;
 454       amd64-*|x86_64-*) machine=amdx86-64 ;;
 455       ia64-*)           machine=ia64 ;;
 456       i[3456]86-*)      machine=intel386 ;;
 457       powerpc-*)        machine=macppc ;;
 458       sparc-*)          machine=sparc ;;
 459       sparc64-*)        machine=sparc ;;
 460     esac
 461   ;;
 462
 463   ## NetBSD ports
 464   *-*-netbsd* )
 465     opsys=netbsd
 466     case "${canonical}" in
 467       alpha*)      machine=alpha ;;
 468       x86_64-*)    machine=amdx86-64 ;;
 469       i[3456]86-*) machine=intel386 ;;
 470       m68k-*)      machine=m68k ;;
 471       powerpc-*)   machine=macppc ;;
 472       sparc*-)     machine=sparc ;;
 473       vax-*)       machine=vax ;;
 474     esac
 475   ;;
 476
 477   ## OpenBSD ports
 478   *-*-openbsd* )
 479     opsys=openbsd
 480     case "${canonical}" in
 481       alpha*)    machine=alpha ;;
 482       x86_64-*)  machine=amdx86-64 ;;
 483       i386-*)    machine=intel386 ;;
 484       powerpc-*) machine=macppc ;;
 485       sparc*)    machine=sparc ;;
 486       vax-*)     machine=vax ;;
 487     esac
 488   ;;
 489
 490   ## Apple Darwin / Mac OS X
 491   *-apple-darwin* )
 492     case "${canonical}" in
 493       i[3456]86-* )  machine=intel386 ;;
 494       powerpc-* )    machine=macppc ;;
 495       x86_64-* )     machine=amdx86-64 ;;
 496       * )            unported=yes ;;
 497     esac
 498     opsys=darwin
 499     # Define CPP as follows to make autoconf work correctly.
 500     CPP="${CC-cc} -E -no-cpp-precomp"
 501     # Use fink packages if available.
 502     if test -d /sw/include && test -d /sw/lib; then
 503       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 504       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 505       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 506     fi
 507   ;;
 508
 509   ## HP 9000 series 700 and 800, running HP/UX
 510   hppa*-hp-hpux10.2* )
 511     opsys=hpux10-20
 512   ;;
 513   hppa*-hp-hpux1[1-9]* )
 514     opsys=hpux11
 515     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 516   ;;
 517
 518   ia64*-hp-hpux1[1-9]* )
 519     machine=hp800 opsys=hpux11
 520     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 521     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 522     CANNOT_DUMP=yes
 523   ;;
 524
 525   hppa*-*-linux-gnu* )
 526     machine=hp800 opsys=gnu-linux
 527   ;;
 528
 529   ## IBM machines
 530   rs6000-ibm-aix4.[23]* )
 531     machine=ibmrs6000 opsys=aix4-2
 532   ;;
 533   powerpc-ibm-aix4.[23]*  )
 534     machine=ibmrs6000 opsys=aix4-2
 535   ;;
 536   rs6000-ibm-aix[56]* )
 537     machine=ibmrs6000 opsys=aix4-2
 538   ;;
 539   powerpc-ibm-aix[56]*  )
 540     machine=ibmrs6000 opsys=aix4-2
 541   ;;
 542
 543   ## Silicon Graphics machines
 544   ## Iris 4D
 545   mips-sgi-irix6.5 )
 546     machine=iris4d opsys=irix6-5
 547     # Without defining _LANGUAGE_C, things get masked out in the headers
 548     # so that, for instance, grepping for `free' in stdlib.h fails and
 549     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 550     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 551     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 552   ;;
 553
 554   ## Suns
 555   *-sun-solaris* \
 556     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 557     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 558     case "${canonical}" in
 559       i[3456]86-*-* )     machine=intel386 ;;
 560       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 561       sparc* )          machine=sparc ;;
 562       * )               unported=yes ;;
 563     esac
 564     case "${canonical}" in
 565       *-sunos5.6* | *-solaris2.6* )
 566                 opsys=sol2-6
 567                 NON_GNU_CPP=/usr/ccs/lib/cpp
 568                 RANLIB="ar -ts"
 569                 ;;
 570       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 571                 opsys=sol2-6
 572                 emacs_check_sunpro_c=yes
 573                 NON_GNU_CPP=/usr/ccs/lib/cpp
 574                 ;;
 575       *-sunos5* | *-solaris* )
 576                 opsys=sol2-10
 577                 emacs_check_sunpro_c=yes
 578                 NON_GNU_CPP=/usr/ccs/lib/cpp
 579                 ;;
 580     esac
 581     ## Watch out for a compiler that we know will not work.
 582     case "${canonical}" in
 583      *-solaris* | *-sunos5* )
 584                 if [ "x$CC" = x/usr/ucb/cc ]; then
 585                   ## /usr/ucb/cc doesn't work;
 586                   ## we should find some other compiler that does work.
 587                   unset CC
 588                 fi
 589                 ;;
 590       *) ;;
 591     esac
 592   ;;
 593
 594   ## Intel 386 machines where we don't care about the manufacturer.
 595   i[3456]86-*-* )
 596     machine=intel386
 597     case "${canonical}" in
 598       *-cygwin )                opsys=cygwin ;;
 599       *-darwin* )               opsys=darwin
 600                                 CPP="${CC-cc} -E -no-cpp-precomp"
 601                                 ;;
 602       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 604       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 605       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 606     esac
 607   ;;
 608
 609   * )
 610     unported=yes
 611   ;;
 612 esac
 613
 614 ### If the code above didn't choose an operating system, just choose
 615 ### an operating system based on the configuration name.  You really
 616 ### only want to use this when you have no idea what the right
 617 ### operating system is; if you know what operating systems a machine
 618 ### runs, it's cleaner to make it explicit in the case statement
 619 ### above.
 620 if test x"${opsys}" = x; then
 621   case "${canonical}" in
 622     *-gnu* )                            opsys=gnu ;;
 623     * )
 624       unported=yes
 625     ;;
 626   esac
 627 fi
 628
 629 ]
 630 dnl quotation ends
 631
 632 if test $unported = yes; then
 633   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 634 Check `etc/MACHINES' for recognized configuration names.])
 635 fi
 636
 637 if test -n "$machine"; then
 638   machfile="m/${machine}.h"
 639 else
 640   machfile=
 641 fi
 642 opsysfile="s/${opsys}.h"
 643
 644
 645 #### Choose a compiler.
 646 test -n "$CC" && cc_specified=yes
 647
 648 # Save the value of CFLAGS that the user specified.
 649 SPECIFIED_CFLAGS="$CFLAGS"
 650
 651 dnl Sets GCC=yes if using gcc.
 652 AC_PROG_CC
 653 AM_PROG_CC_C_O
 654
 655 # Initialize gnulib right after verifying that the C compiler works.
 656 gl_EARLY
 657
 658 # On Suns, sometimes $CPP names a directory.
 659 if test -n "$CPP" && test -d "$CPP"; then
 660   CPP=
 661 fi
 662
 663 ## If not using gcc, and on Solaris, and no CPP specified, see if
 664 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 665 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 666  test x"$CPP" = x; then
 667   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 668   AC_CACHE_VAL(emacs_cv_sunpro_c,
 669   [AC_TRY_LINK([],
 670 [#ifndef __SUNPRO_C
 671 fail;
 672 #endif
 673 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 674   AC_MSG_RESULT($emacs_cv_sunpro_c)
 675
 676   if test x"$emacs_cv_sunpro_c" = xyes; then
 677     NON_GNU_CPP="$CC -E -Xs"
 678   fi
 679 fi
 680
 681 #### Some systems specify a CPP to use unless we are using GCC.
 682 #### Now that we know whether we are using GCC, we can decide whether
 683 #### to use that one.
 684 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 685 then
 686   CPP="$NON_GNU_CPP"
 687 fi
 688
 689 #### Some systems specify a CC to use unless we are using GCC.
 690 #### Now that we know whether we are using GCC, we can decide whether
 691 #### to use that one.
 692 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 693   test x$cc_specified != xyes
 694 then
 695   CC="$NON_GNU_CC"
 696 fi
 697
 698 if test x$GCC = xyes; then
 699   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 700 else
 701   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 702 fi
 703
 704 ### Use -Wno-pointer-sign if the compiler supports it
 705 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 706 SAVE_CFLAGS="$CFLAGS"
 707 CFLAGS="$CFLAGS -Wno-pointer-sign"
 708 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 709 if test $has_option = yes; then
 710    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 711 fi
 712 AC_MSG_RESULT($has_option)
 713 CFLAGS="$SAVE_CFLAGS"
 714 unset has_option
 715 unset SAVE_CFLAGS
 716
 717 ### Use -Wdeclaration-after-statement if the compiler supports it
 718 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 719 SAVE_CFLAGS="$CFLAGS"
 720 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 721 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 722 if test $has_option = yes; then
 723    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 724 fi
 725 AC_MSG_RESULT($has_option)
 726 CFLAGS="$SAVE_CFLAGS"
 727 unset has_option
 728 unset SAVE_CFLAGS
 729
 730 ### Use -Wold-style-definition if the compiler supports it
 731 # This can be removed when conversion to standard C is finished.
 732 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 733 SAVE_CFLAGS="$CFLAGS"
 734 CFLAGS="$CFLAGS -Wold-style-definition"
 735 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 736 if test $has_option = yes; then
 737    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 738 fi
 739 AC_MSG_RESULT($has_option)
 740 CFLAGS="$SAVE_CFLAGS"
 741 unset has_option
 742 unset SAVE_CFLAGS
 743
 744 ### Use -Wimplicit-function-declaration if the compiler supports it
 745 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 746 SAVE_CFLAGS="$CFLAGS"
 747 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 748 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 749 if test $has_option = yes; then
 750    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 751 fi
 752 AC_MSG_RESULT($has_option)
 753 CFLAGS="$SAVE_CFLAGS"
 754 unset has_option
 755 unset SAVE_CFLAGS
 756
 757 AC_SUBST(C_WARNINGS_SWITCH)
 758
 759
 760 #### Some other nice autoconf tests.
 761
 762 dnl checks for programs
 763 AC_PROG_CPP
 764 AC_PROG_INSTALL
 765 if test "x$RANLIB" = x; then
 766   AC_PROG_RANLIB
 767 fi
 768
 769 ## Although we're running on an amd64 kernel, we're actually compiling for
 770 ## the x86 architecture.  The user should probably have provided an
 771 ## explicit --build to `configure', but if everything else than the kernel
 772 ## is running in i386 mode, we can help them out.
 773 if test "$machine" = "amdx86-64"; then
 774   AC_CHECK_DECL([i386])
 775   if test "$ac_cv_have_decl_i386" = "yes"; then
 776     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 777     machine=intel386
 778     machfile="m/${machine}.h"
 779   fi
 780 fi
 781
 782 AC_PATH_PROG(INSTALL_INFO, install-info)
 783 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 784 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 785 dnl Don't use GZIP, which is used by gzip for additional parameters.
 786 AC_PATH_PROG(GZIP_PROG, gzip)
 787
 788
 789 ## Need makeinfo >= 4.6 (?) to build the manuals.
 790 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 791 dnl By this stage, configure has already checked for egrep and set EGREP,
 792 dnl or exited with an error if no egrep was found.
 793 if test "$MAKEINFO" != "no" && \
 794   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 795    MAKEINFO=no
 796 fi
 797
 798 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 799 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 800 ## therefore in the category of "special tools" not normally required, which
 801 ## configure does not have to check for (eg autoconf itself).
 802 ## In a Bazaar checkout on the other hand, the manuals are not included.
 803 ## So makeinfo is a requirement to build from Bazaar, and configure
 804 ## should test for it as it does for any other build requirement.
 805 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 806 ## with pre-built manuals, from a Bazaar checkout.
 807 HAVE_MAKEINFO=yes
 808
 809 if test "$MAKEINFO" = "no"; then
 810   MAKEINFO=makeinfo
 811   if test "x${with_makeinfo}" = "xno"; then
 812     HAVE_MAKEINFO=no
 813   elif test ! -e $srcdir/info/emacs; then
 814     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 815 source tree does not seem to have pre-built manuals in the `info' directory.
 816 Either install a suitable version of makeinfo, or re-run configure
 817 with the `--without-makeinfo' option to build without the manuals.] )
 818   fi
 819 fi
 820 AC_SUBST(HAVE_MAKEINFO)
 821
 822 dnl Add our options to ac_link now, after it is set up.
 823
 824 if test x$GCC = xyes; then
 825   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 826     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 827 else
 828   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 829     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 830 fi
 831
 832 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 833 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 834 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 835 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 836 dnl if not built to support GNU ld.
 837
 838 late_LDFLAGS=$LDFLAGS
 839 if test x$GCC = xyes; then
 840   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 841 else
 842   LDFLAGS="$LDFLAGS -znocombreloc"
 843 fi
 844
 845 AC_MSG_CHECKING([for -znocombreloc])
 846 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 847   [AC_MSG_RESULT(yes)],
 848   LDFLAGS=$late_LDFLAGS
 849   [AC_MSG_RESULT(no)])
 850
 851
 852 # The value of CPP is a quoted variable reference, so we need to do this
 853 # to get its actual value...
 854 CPP=`eval "echo $CPP"`
 855
 856
 857 dnl The function dump-emacs will not be defined and temacs will do
 858 dnl (load "loadup") automatically unless told otherwise.
 859 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 860 case "$opsys" in
 861   your-opsys-here) CANNOT_DUMP=yes ;;
 862 esac
 863
 864 test "$CANNOT_DUMP" = "yes" && \
 865   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 866
 867 AC_SUBST(CANNOT_DUMP)
 868
 869
 870 UNEXEC_OBJ=unexelf.o
 871 case "$opsys" in
 872   # MSDOS uses unexcoff.o
 873   # MSWindows uses unexw32.o
 874   aix4-2)
 875    UNEXEC_OBJ=unexaix.o
 876    ;;
 877   cygwin)
 878    UNEXEC_OBJ=unexcw.o
 879    ;;
 880   darwin)
 881    UNEXEC_OBJ=unexmacosx.o
 882    ;;
 883   hpux10-20 | hpux11)
 884    UNEXEC_OBJ=unexhp9k800.o
 885    ;;
 886   sol2-10)
 887    # Use the Solaris dldump() function, called from unexsol.c, to dump
 888    # emacs, instead of the generic ELF dump code found in unexelf.c.
 889    # The resulting binary has a complete symbol table, and is better
 890    # for debugging and other observability tools (debuggers, pstack, etc).
 891    #
 892    # If you encounter a problem using dldump(), please consider sending
 893    # a message to the OpenSolaris tools-linking mailing list:
 894    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 895    #
 896    # It is likely that dldump() works with older Solaris too, but this has
 897    # not been tested, so for now this change is for Solaris 10 or newer.
 898    UNEXEC_OBJ=unexsol.o
 899    ;;
 900 esac
 901
 902 LD_SWITCH_SYSTEM=
 903 case "$opsys" in
 904   freebsd)
 905    ## Let `ld' find image libs and similar things in /usr/local/lib.
 906    ## The system compiler, GCC, has apparently been modified to not
 907    ## look there, contrary to what a stock GCC would do.
 908    LD_SWITCH_SYSTEM=-L/usr/local/lib
 909    ;;
 910
 911   gnu-linux)
 912    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 913    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 914    ;;
 915
 916   netbsd)
 917    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 918    ;;
 919
 920   openbsd)
 921    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 922    ## otherwise Emacs dumps core on elf systems.
 923    LD_SWITCH_SYSTEM="-Z"
 924    ;;
 925 esac
 926 AC_SUBST(LD_SWITCH_SYSTEM)
 927
 928 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 929
 930 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 931 ## which has not been defined yet.  When this was handled with cpp,
 932 ## it was expanded to null when configure sourced the s/*.h file.
 933 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 934 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 935 ## (or somesuch), but because it is supposed to go at the _front_
 936 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 937 ## Compare with the gnu-linux case below, which added to the end
 938 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 939 ## LD_SWITCH_SYSTEM_TEMACS.
 940 case "$opsys" in
 941   netbsd|openbsd)
 942    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 943    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 944 esac
 945
 946
 947 C_SWITCH_MACHINE=
 948 if test "$machine" = "alpha"; then
 949   AC_CHECK_DECL([__ELF__])
 950   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 951     ## With ELF, make sure that all common symbols get allocated to in the
 952     ## data section.  Otherwise, the dump of temacs may miss variables in
 953     ## the shared library that have been initialized.  For example, with
 954     ## GNU libc, __malloc_initialized would normally be resolved to the
 955     ## shared library's .bss section, which is fatal.
 956     if test "x$GCC" = "xyes"; then
 957       C_SWITCH_MACHINE="-fno-common"
 958     else
 959       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 960     fi
 961   else
 962     UNEXEC_OBJ=unexalpha.o
 963   fi
 964 fi
 965 AC_SUBST(C_SWITCH_MACHINE)
 966
 967 AC_SUBST(UNEXEC_OBJ)
 968
 969 C_SWITCH_SYSTEM=
 970 ## Some programs in src produce warnings saying certain subprograms
 971 ## are too complex and need a MAXMEM value greater than 2000 for
 972 ## additional optimization.  --nils@exp-math.uni-essen.de
 973 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 974   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 975 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 976 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 977 AC_SUBST(C_SWITCH_SYSTEM)
 978
 979
 980 LIBS_SYSTEM=
 981 case "$opsys" in
 982   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 983   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 984
 985   freebsd) LIBS_SYSTEM="-lutil" ;;
 986
 987   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 988
 989   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 990
 991   ## Motif needs -lgen.
 992   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 993 esac
 994 AC_SUBST(LIBS_SYSTEM)
 995
 996
 997 ### Make sure subsequent tests use flags consistent with the build flags.
 998
 999 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1000   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1001 else
1002   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1003 fi
1004
1005 dnl For AC_FUNC_GETLOADAVG, at least:
1006 AC_CONFIG_LIBOBJ_DIR(src)
1007
1008 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1009 AC_SYS_LARGEFILE
1010
1011
1012 ## If user specified a crt-dir, use that unconditionally.
1013 if test "X$CRT_DIR" = "X"; then
1014
1015   case "$canonical" in
1016     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1017     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1018     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1019     ## For anything else (eg /usr/lib32), it is up the user to specify
1020     ## the location (bug#5655).
1021     ## Test for crtn.o, not just the directory, because sometimes the
1022     ## directory exists but does not have the relevant files (bug#1287).
1023     ## FIXME better to test for binary compatibility somehow.
1024     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1025     ;;
1026
1027     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1028   esac
1029
1030   case "$opsys" in
1031     hpux10-20) CRT_DIR=/lib ;;
1032   esac
1033
1034   ## Default is /usr/lib.
1035   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1036
1037 else
1038
1039   ## Some platforms don't use any of these files, so it is not
1040   ## appropriate to put this test outside the if block.
1041   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1042     AC_MSG_ERROR([crt*.o not found in specified location.])
1043
1044 fi
1045
1046 AC_SUBST(CRT_DIR)
1047
1048 LIB_MATH=-lm
1049 LIB_STANDARD=
1050 START_FILES=
1051
1052 case $opsys in
1053   cygwin )
1054     LIB_MATH=
1055     START_FILES='pre-crt0.o'
1056     ;;
1057   darwin )
1058     ## Adding -lm confuses the dynamic linker, so omit it.
1059     LIB_MATH=
1060     START_FILES='pre-crt0.o'
1061     ;;
1062   freebsd )
1063     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1064     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1065     ;;
1066   gnu-linux | gnu-kfreebsd )
1067     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1068     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1069     ;;
1070   hpux10-20 | hpux11 )
1071     LIB_STANDARD=-lc
1072     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1073     ;;
1074   netbsd | openbsd )
1075     if test -f $CRT_DIR/crti.o; then
1076         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1077         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1078     else
1079         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1080         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1081     fi
1082     ;;
1083 esac
1084
1085 AC_SUBST(LIB_MATH)
1086 AC_SUBST(START_FILES)
1087
1088 dnl This function definition taken from Gnome 2.0
1089 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1090 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1091 dnl also defines GSTUFF_PKG_ERRORS on error
1092 AC_DEFUN([PKG_CHECK_MODULES], [
1093   succeeded=no
1094
1095   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1096
1097   if test "$PKG_CONFIG" = "no" ; then
1098      ifelse([$4], , [AC_MSG_ERROR([
1099       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1100   else
1101      PKG_CONFIG_MIN_VERSION=0.9.0
1102      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1103         AC_MSG_CHECKING(for $2)
1104
1105         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1106             AC_MSG_RESULT(yes)
1107             succeeded=yes
1108
1109             AC_MSG_CHECKING($1_CFLAGS)
1110             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1111             AC_MSG_RESULT($$1_CFLAGS)
1112
1113             AC_MSG_CHECKING($1_LIBS)
1114             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1115             AC_MSG_RESULT($$1_LIBS)
1116         else
1117             AC_MSG_RESULT(no)
1118             $1_CFLAGS=""
1119             $1_LIBS=""
1120             ## If we have a custom action on failure, don't print errors, but
1121             ## do set a variable so people can do so.
1122             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1123             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1124         fi
1125
1126         AC_SUBST($1_CFLAGS)
1127         AC_SUBST($1_LIBS)
1128      else
1129         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1130         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1131      fi
1132   fi
1133
1134   if test $succeeded = yes; then
1135      ifelse([$3], , :, [$3])
1136   else
1137      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1138   fi
1139 ])
1140
1141
1142 if test "${with_sound}" != "no"; then
1143   # Sound support for GNU/Linux and the free BSDs.
1144   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1145     have_sound_header=yes)
1146   # Emulation library used on NetBSD.
1147   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1148   AC_SUBST(LIBSOUND)
1149
1150   ALSA_REQUIRED=1.0.0
1151   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1152   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1153   if test $HAVE_ALSA = yes; then
1154     SAVE_CFLAGS="$CFLAGS"
1155     SAVE_LDFLAGS="$LDFLAGS"
1156     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1157     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1158     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1159                     emacs_alsa_normal=yes,
1160                     emacs_alsa_normal=no)
1161     if test "$emacs_alsa_normal" != yes; then
1162       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1163                      [snd_lib_error_set_handler (0);],
1164                      emacs_alsa_subdir=yes,
1165                      emacs_alsa_subdir=no)
1166       if test "$emacs_alsa_subdir" != yes; then
1167         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1168       fi
1169       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1170     fi
1171
1172     CFLAGS="$SAVE_CFLAGS"
1173     LDFLAGS="$SAVE_LDFLAGS"
1174     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1175     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1176     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1177   fi
1178
1179   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1180   dnl compiles only on the specified platforms.  For others, it
1181   dnl probably doesn't make sense to try.
1182   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1183      case "$opsys" in
1184        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1185        gnu-linux|freebsd|netbsd)
1186          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1187          ;;
1188      esac
1189   fi
1190
1191   AC_SUBST(CFLAGS_SOUND)
1192 fi
1193
1194 dnl checks for header files
1195 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1196   linux/version.h sys/systeminfo.h limits.h \
1197   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1198   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1199   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1200
1201 AC_MSG_CHECKING(if personality LINUX32 can be set)
1202 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1203                emacs_cv_personality_linux32=yes,
1204                emacs_cv_personality_linux32=no)
1205 AC_MSG_RESULT($emacs_cv_personality_linux32)
1206
1207 if test $emacs_cv_personality_linux32 = yes; then
1208   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1209             [Define to 1 if personality LINUX32 can be set.])
1210 fi
1211
1212 dnl On Solaris 8 there's a compilation warning for term.h because
1213 dnl it doesn't define `bool'.
1214 AC_CHECK_HEADERS(term.h, , , -)
1215 AC_HEADER_STDC
1216 AC_HEADER_TIME
1217 AC_CHECK_DECLS([sys_siglist])
1218 if test $ac_cv_have_decl_sys_siglist != yes; then
1219   # For Tru64, at least:
1220   AC_CHECK_DECLS([__sys_siglist])
1221   if test $ac_cv_have_decl___sys_siglist = yes; then
1222     AC_DEFINE(sys_siglist, __sys_siglist,
1223               [Define to any substitute for sys_siglist.])
1224   fi
1225 fi
1226 AC_HEADER_SYS_WAIT
1227
1228 dnl Some systems have utime.h but don't declare the struct anyplace.
1229 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1230 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1231 #include <sys/time.h>
1232 #include <time.h>
1233 #else
1234 #ifdef HAVE_SYS_TIME_H
1235 #include <sys/time.h>
1236 #else
1237 #include <time.h>
1238 #endif
1239 #endif
1240 #ifdef HAVE_UTIME_H
1241 #include <utime.h>
1242 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1243   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1244 if test $emacs_cv_struct_utimbuf = yes; then
1245   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1246 fi
1247
1248 dnl checks for typedefs
1249 AC_TYPE_SIGNAL
1250
1251 dnl Check for speed_t typedef.
1252 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1253   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1254     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1255 if test $emacs_cv_speed_t = yes; then
1256   AC_DEFINE(HAVE_SPEED_T, 1,
1257            [Define to 1 if `speed_t' is declared by <termios.h>.])
1258 fi
1259
1260 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1261 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1262 #include <sys/time.h>
1263 #include <time.h>
1264 #else
1265 #ifdef HAVE_SYS_TIME_H
1266 #include <sys/time.h>
1267 #else
1268 #include <time.h>
1269 #endif
1270 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1271   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1272 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1273 if test $emacs_cv_struct_timeval = yes; then
1274   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1275 fi
1276
1277 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1278 AC_TRY_COMPILE([#include <math.h>],
1279 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1280   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1281 HAVE_EXCEPTION=$emacs_cv_struct_exception
1282 if test $emacs_cv_struct_exception != yes; then
1283   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1284 fi
1285
1286 AC_CHECK_HEADERS(sys/socket.h)
1287 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1288 #if HAVE_SYS_SOCKET_H
1289 #include <sys/socket.h>
1290 #endif])
1291
1292 dnl checks for structure members
1293 AC_STRUCT_TM
1294 AC_STRUCT_TIMEZONE
1295 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1296                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1297                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1298                 [#include <time.h>])
1299 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1300                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1301                   struct ifreq.ifr_addr], , ,
1302                  [AC_INCLUDES_DEFAULT
1303 #if HAVE_SYS_SOCKET_H
1304 #include <sys/socket.h>
1305 #endif
1306 #if HAVE_NET_IF_H
1307 #include <net/if.h>
1308 #endif])
1309
1310 dnl checks for compiler characteristics
1311
1312 dnl Testing __STDC__ to determine prototype support isn't good enough.
1313 dnl DEC C, for instance, doesn't define it with default options, and
1314 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1315 dnl and void *.
1316 AC_C_PROTOTYPES
1317 AC_C_VOLATILE
1318 AC_C_CONST
1319 dnl This isn't useful because we can't turn on use of `inline' unless
1320 dnl the compiler groks `extern inline'.
1321 dnl AC_C_INLINE
1322 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1323   [AC_TRY_COMPILE(, [void * foo;],
1324                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1325 if test $emacs_cv_void_star = yes; then
1326   AC_DEFINE(POINTER_TYPE, void)
1327 else
1328   AC_DEFINE(POINTER_TYPE, char)
1329 fi
1330 AH_TEMPLATE(POINTER_TYPE,
1331             [Define as `void' if your compiler accepts `void *'; otherwise
1332              define as `char'.])dnl
1333
1334 dnl Check for endianess
1335 AC_C_BIGENDIAN
1336
1337 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1338   [emacs_cv_attribute_aligned],
1339   [AC_COMPILE_IFELSE(
1340      [AC_LANG_PROGRAM(
1341         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1342         [[]])],
1343      [emacs_cv_attribute_aligned=yes],
1344      [emacs_cv_attribute_aligned=no])])
1345 if test $emacs_cv_attribute_aligned = yes; then
1346   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1347     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1348 fi
1349
1350 dnl check for Make feature
1351 AC_PROG_MAKE_SET
1352
1353 DEPFLAGS=
1354 MKDEPDIR=":"
1355 deps_frag=deps.mk
1356 dnl check for GNU Make if we have GCC and autodepend is on.
1357 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1358    AC_MSG_CHECKING([whether we are using GNU Make])
1359    HAVE_GNU_MAKE=no
1360    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1361    if test "x$testval" != x; then
1362       HAVE_GNU_MAKE=yes
1363    else
1364       ac_enable_autodepend=no
1365    fi
1366    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1367    if test $HAVE_GNU_MAKE = yes; then
1368       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1369       SAVE_CFLAGS="$CFLAGS"
1370       CFLAGS="$CFLAGS -MMD -MF deps.d"
1371       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1372       CFLAGS="$SAVE_CFLAGS"
1373       test -f deps.d || ac_enable_autodepend=no
1374       rm -rf deps.d
1375       AC_MSG_RESULT([$ac_enable_autodepend])
1376    fi
1377    if test $ac_enable_autodepend = yes; then
1378       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1379       ## In parallel builds, another make might create depdir between
1380       ## the first test and mkdir, so stick another test on the end.
1381       ## Or use mkinstalldirs?  mkdir -p is not portable.
1382       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1383       deps_frag=autodeps.mk
1384    fi
1385 fi
1386 deps_frag=$srcdir/src/$deps_frag
1387 AC_SUBST(MKDEPDIR)
1388 AC_SUBST(DEPFLAGS)
1389 AC_SUBST_FILE(deps_frag)
1390
1391
1392 dnl checks for operating system services
1393 AC_SYS_LONG_FILE_NAMES
1394
1395 #### Choose a window system.
1396
1397 AC_PATH_X
1398 if test "$no_x" = yes; then
1399   window_system=none
1400 else
1401   window_system=x11
1402 fi
1403
1404 ## Workaround for bug in autoconf <= 2.62.
1405 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1406 ## No need to do anything special for these standard directories.
1407 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1408
1409    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1410
1411 fi
1412
1413 LD_SWITCH_X_SITE_AUX=
1414 LD_SWITCH_X_SITE_AUX_RPATH=
1415 if test "${x_libraries}" != NONE; then
1416   if test -n "${x_libraries}"; then
1417     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1418     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1419     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1420   fi
1421   x_default_search_path=""
1422   x_search_path=${x_libraries}
1423   if test -z "${x_search_path}"; then
1424     x_search_path=/usr/lib
1425   fi
1426   for x_library in `echo ${x_search_path}: | \
1427                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1428     x_search_path="\
1429 ${x_library}/X11/%L/%T/%N%C%S:\
1430 ${x_library}/X11/%l/%T/%N%C%S:\
1431 ${x_library}/X11/%T/%N%C%S:\
1432 ${x_library}/X11/%L/%T/%N%S:\
1433 ${x_library}/X11/%l/%T/%N%S:\
1434 ${x_library}/X11/%T/%N%S"
1435     if test x"${x_default_search_path}" = x; then
1436       x_default_search_path=${x_search_path}
1437     else
1438       x_default_search_path="${x_search_path}:${x_default_search_path}"
1439     fi
1440   done
1441 fi
1442 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1443 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1444
1445 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1446   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1447 fi
1448
1449 if test x"${x_includes}" = x; then
1450   bitmapdir=/usr/include/X11/bitmaps
1451 else
1452   # accumulate include directories that have X11 bitmap subdirectories
1453   bmd_acc="dummyval"
1454   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1455     if test -d "${bmd}/X11/bitmaps"; then
1456       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1457     fi
1458     if test -d "${bmd}/bitmaps"; then
1459       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1460     fi
1461   done
1462   if test ${bmd_acc} != "dummyval"; then
1463     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1464   fi
1465 fi
1466
1467 HAVE_NS=no
1468 NS_IMPL_COCOA=no
1469 NS_IMPL_GNUSTEP=no
1470 tmp_CPPFLAGS="$CPPFLAGS"
1471 tmp_CFLAGS="$CFLAGS"
1472 CPPFLAGS="$CPPFLAGS -x objective-c"
1473 CFLAGS="$CFLAGS -x objective-c"
1474 TEMACS_LDFLAGS2="\${LDFLAGS}"
1475 dnl I don't think it's especially important, but src/Makefile.in
1476 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1477 dnl trailing "/" to it, so now we do it here.
1478 if test "${with_ns}" != no; then
1479   if test "${opsys}" = darwin; then
1480      NS_IMPL_COCOA=yes
1481      ns_appdir=`pwd`/nextstep/Emacs.app
1482      ns_appbindir=${ns_appdir}/Contents/MacOS/
1483      ns_appresdir=${ns_appdir}/Contents/Resources
1484      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1485   elif test -f $GNUSTEP_CONFIG_FILE; then
1486      NS_IMPL_GNUSTEP=yes
1487      ns_appdir=`pwd`/nextstep/Emacs.app
1488      ns_appbindir=${ns_appdir}/
1489      ns_appresdir=${ns_appdir}/Resources
1490      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1491      dnl FIXME sourcing this several times in subshells seems inefficient.
1492      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1493      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1494      dnl I seemed to need these as well with GNUstep-startup 0.25.
1495      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1496      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1497      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1498        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1499      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1500        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1501      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1502      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1503      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1504      LIB_STANDARD=
1505      START_FILES=
1506      TEMACS_LDFLAGS2=
1507   fi
1508   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1509                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1510   files are missing or cannot be compiled.])])
1511   NS_HAVE_NSINTEGER=yes
1512   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1513                                      [NSInteger i;])],
1514                     ns_have_nsinteger=yes,
1515                     ns_have_nsinteger=no)
1516   if test $ns_have_nsinteger = no; then
1517     NS_HAVE_NSINTEGER=no
1518   fi
1519 fi
1520 AC_SUBST(TEMACS_LDFLAGS2)
1521
1522 ns_frag=/dev/null
1523 NS_OBJ=
1524 NS_SUPPORT=
1525 if test "${HAVE_NS}" = yes; then
1526   window_system=nextstep
1527   with_xft=no
1528   # set up packaging dirs
1529   exec_prefix=${ns_appbindir}
1530   libexecdir=${ns_appbindir}/libexec
1531   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1532      prefix=${ns_appresdir}
1533   fi
1534   ns_frag=$srcdir/src/ns.mk
1535   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1536   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1537 fi
1538 CFLAGS="$tmp_CFLAGS"
1539 CPPFLAGS="$tmp_CPPFLAGS"
1540 AC_SUBST(NS_OBJ)
1541 AC_SUBST(NS_SUPPORT)
1542 AC_SUBST(LIB_STANDARD)
1543 AC_SUBST_FILE(ns_frag)
1544
1545 case "${window_system}" in
1546   x11 )
1547     HAVE_X_WINDOWS=yes
1548     HAVE_X11=yes
1549     case "${with_x_toolkit}" in
1550       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1551       motif ) USE_X_TOOLKIT=MOTIF ;;
1552       gtk ) with_gtk=yes
1553 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1554 dnl USE_X_TOOLKIT is set.
1555             USE_X_TOOLKIT=none ;;
1556       gtk3 ) with_gtk3=yes
1557              USE_X_TOOLKIT=none ;;
1558       no ) USE_X_TOOLKIT=none ;;
1559 dnl If user did not say whether to use a toolkit, make this decision later:
1560 dnl use the toolkit if we have gtk, or X11R5 or newer.
1561       * ) USE_X_TOOLKIT=maybe ;;
1562     esac
1563   ;;
1564   nextstep | none )
1565     HAVE_X_WINDOWS=no
1566     HAVE_X11=no
1567     USE_X_TOOLKIT=none
1568   ;;
1569 esac
1570
1571 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1572    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1573    if test "$HAVE_XSERVER" = true ||
1574       test -n "$DISPLAY" ||
1575       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1576         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1577 were found.  You should install the relevant development files for X
1578 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1579 sure you have development files for image handling, i.e.
1580 tiff, gif, jpeg, png and xpm.
1581 If you are sure you want Emacs compiled without X window support, pass
1582   --without-x
1583 to configure.])
1584    fi
1585 fi
1586
1587 ### If we're using X11, we should use the X menu package.
1588 HAVE_MENUS=no
1589 case ${HAVE_X11} in
1590   yes ) HAVE_MENUS=yes ;;
1591 esac
1592
1593 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1594 # Assume not, until told otherwise.
1595 GNU_MALLOC=yes
1596 doug_lea_malloc=yes
1597 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1598 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1599 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1600                emacs_cv_var___after_morecore_hook,
1601 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1602   emacs_cv_var___after_morecore_hook=yes,
1603   emacs_cv_var___after_morecore_hook=no)])
1604 if test $emacs_cv_var___after_morecore_hook = no; then
1605   doug_lea_malloc=no
1606 fi
1607
1608
1609 dnl See comments in aix4-2.h about maybe using system malloc there.
1610 system_malloc=no
1611 case "$opsys" in
1612   ## darwin ld insists on the use of malloc routines in the System framework.
1613   darwin|sol2-10) system_malloc=yes ;;
1614 esac
1615
1616 if test "${system_malloc}" = "yes"; then
1617   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1618   GNU_MALLOC=no
1619   GNU_MALLOC_reason="
1620     (The GNU allocators don't work with this system configuration.)"
1621   GMALLOC_OBJ=
1622   VMLIMIT_OBJ=
1623 else
1624   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1625   VMLIMIT_OBJ=vm-limit.o
1626 fi
1627 AC_SUBST(GMALLOC_OBJ)
1628 AC_SUBST(VMLIMIT_OBJ)
1629
1630 if test "$doug_lea_malloc" = "yes" ; then
1631   if test "$GNU_MALLOC" = yes ; then
1632     GNU_MALLOC_reason="
1633       (Using Doug Lea's new malloc from the GNU C Library.)"
1634   fi
1635   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1636             [Define to 1 if you are using the GNU C Library.])
1637
1638   ## Use mmap directly for allocating larger buffers.
1639   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1640   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1641   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1642   case "$opsys" in
1643     gnu*) REL_ALLOC=no ;;
1644   esac
1645 fi
1646
1647 if test x"${REL_ALLOC}" = x; then
1648   REL_ALLOC=${GNU_MALLOC}
1649 fi
1650
1651 use_mmap_for_buffers=no
1652 case "$opsys" in
1653   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1654 esac
1655
1656 AC_FUNC_MMAP
1657 if test $use_mmap_for_buffers = yes; then
1658   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1659   REL_ALLOC=no
1660 fi
1661
1662 LIBS="$LIBS_SYSTEM $LIBS"
1663
1664 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1665 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1666 AC_CHECK_LIB(dnet, dnet_ntoa)
1667 dnl This causes -lresolv to get used in subsequent tests,
1668 dnl which causes failures on some systems such as HPUX 9.
1669 dnl AC_CHECK_LIB(resolv, gethostbyname)
1670
1671 dnl FIXME replace main with a function we actually want from this library.
1672 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1673
1674 AC_CHECK_LIB(pthreads, cma_open)
1675
1676 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1677 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1678 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1679 ## added to LIBS in configure would never contain the pthreads part,
1680 ## but the value used in Makefiles might.  FIXME?
1681 ##
1682 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1683 ## be harmless on older versions of X where it happens to exist.
1684 test "$opsys" = "aix4-2" && \
1685   test $ac_cv_lib_pthreads_cma_open = yes && \
1686   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1687
1688 dnl Check for need for bigtoc support on IBM AIX
1689
1690 case ${host_os} in
1691 aix*)
1692   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1693     case $GCC in
1694     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1695     *) gdb_cv_bigtoc=-bbigtoc ;;
1696     esac
1697
1698     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1699     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1700   ])
1701   ;;
1702 esac
1703
1704 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1705 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1706 # REAL_CPPFLAGS later on.
1707
1708 REAL_CFLAGS="$CFLAGS"
1709 REAL_CPPFLAGS="$CPPFLAGS"
1710
1711 if test "${HAVE_X11}" = "yes"; then
1712   DEFS="$C_SWITCH_X_SITE $DEFS"
1713   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1714   LIBS="-lX11 $LIBS"
1715   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1716   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1717
1718   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1719   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1720   # but it's more convenient here to set LD_RUN_PATH
1721   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1722   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1723     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1724     export LD_RUN_PATH
1725   fi
1726
1727   if test "${opsys}" = "gnu-linux"; then
1728     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1729     AC_TRY_LINK([],
1730      [XOpenDisplay ("foo");],
1731      [xlinux_first_failure=no],
1732      [xlinux_first_failure=yes])
1733     if test "${xlinux_first_failure}" = "yes"; then
1734       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1735       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1736       OLD_CPPFLAGS="$CPPFLAGS"
1737       OLD_LIBS="$LIBS"
1738       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1739       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1740       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1741       LIBS="$LIBS -b i486-linuxaout"
1742       AC_TRY_LINK([],
1743        [XOpenDisplay ("foo");],
1744        [xlinux_second_failure=no],
1745        [xlinux_second_failure=yes])
1746       if test "${xlinux_second_failure}" = "yes"; then
1747         # If we get the same failure with -b, there is no use adding -b.
1748         # So take it out.  This plays safe.
1749         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1750         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1751         CPPFLAGS="$OLD_CPPFLAGS"
1752         LIBS="$OLD_LIBS"
1753         AC_MSG_RESULT(no)
1754       else
1755         AC_MSG_RESULT(yes)
1756       fi
1757     else
1758       AC_MSG_RESULT(no)
1759     fi
1760   fi
1761
1762   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1763   # header files included from there.
1764   AC_MSG_CHECKING(for Xkb)
1765   AC_TRY_LINK([#include <X11/Xlib.h>
1766 #include <X11/XKBlib.h>],
1767         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1768         emacs_xkb=yes, emacs_xkb=no)
1769   AC_MSG_RESULT($emacs_xkb)
1770   if test $emacs_xkb = yes; then
1771     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1772   fi
1773
1774   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1775 XScreenNumberOfScreen XSetWMProtocols)
1776 fi
1777
1778 if test "${window_system}" = "x11"; then
1779   AC_MSG_CHECKING(X11 version 6)
1780   AC_CACHE_VAL(emacs_cv_x11_version_6,
1781   [AC_TRY_LINK([#include <X11/Xlib.h>],
1782 [#if XlibSpecificationRelease < 6
1783 fail;
1784 #endif
1785 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1786   if test $emacs_cv_x11_version_6 = yes; then
1787     AC_MSG_RESULT(6 or newer)
1788     AC_DEFINE(HAVE_X11R6, 1,
1789               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1790     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1791     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1792     ## XIM support.
1793     case "$opsys" in
1794       sol2-*) : ;;
1795       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1796            [Define if you have usable X11R6-style XIM support.])
1797          ;;
1798     esac
1799   else
1800     AC_MSG_RESULT(before 6)
1801   fi
1802 fi
1803
1804
1805 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1806 HAVE_RSVG=no
1807 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1808   if test "${with_rsvg}" != "no"; then
1809     RSVG_REQUIRED=2.11.0
1810     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1811
1812     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1813     AC_SUBST(RSVG_CFLAGS)
1814     AC_SUBST(RSVG_LIBS)
1815
1816     if test $HAVE_RSVG = yes; then
1817       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1818       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1819       LIBS="$RSVG_LIBS $LIBS"
1820     fi
1821   fi
1822 fi
1823
1824 HAVE_IMAGEMAGICK=no
1825 if test "${HAVE_X11}" = "yes"; then
1826   if test "${with_imagemagick}" != "no"; then
1827     IMAGEMAGICK_MODULE="Wand"
1828     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1829     AC_SUBST(IMAGEMAGICK_CFLAGS)
1830     AC_SUBST(IMAGEMAGICK_LIBS)
1831
1832     if test $HAVE_IMAGEMAGICK = yes; then
1833       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1834       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1835       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1836       AC_CHECK_FUNCS(MagickExportImagePixels)
1837     fi
1838   fi
1839 fi
1840
1841
1842 HAVE_GTK=no
1843 if test "${with_gtk3}" = "yes"; then
1844   GLIB_REQUIRED=2.6
1845   GTK_REQUIRED=2.90
1846   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1847
1848   dnl Checks for libraries.
1849   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1850   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1851      AC_MSG_ERROR($GTK_PKG_ERRORS)
1852   fi
1853 fi
1854
1855 if test "$pkg_check_gtk" != "yes"; then
1856   HAVE_GTK=no
1857 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1858   GLIB_REQUIRED=2.6
1859   GTK_REQUIRED=2.6
1860   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1861
1862   dnl Checks for libraries.
1863   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1864   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1865      AC_MSG_ERROR($GTK_PKG_ERRORS)
1866   fi
1867 fi
1868 fi
1869
1870 GTK_OBJ=
1871 if test x"$pkg_check_gtk" = xyes; then
1872
1873   AC_SUBST(GTK_CFLAGS)
1874   AC_SUBST(GTK_LIBS)
1875   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1876   CFLAGS="$CFLAGS $GTK_CFLAGS"
1877   LIBS="$GTK_LIBS $LIBS"
1878   dnl Try to compile a simple GTK program.
1879   GTK_COMPILES=no
1880   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1881   if test "${GTK_COMPILES}" != "yes"; then
1882     if test "$USE_X_TOOLKIT" != "maybe"; then
1883       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1884     fi
1885   else
1886     HAVE_GTK=yes
1887     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1888     GTK_OBJ=gtkutil.o
1889     USE_X_TOOLKIT=none
1890     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1891       :
1892     else
1893       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1894        closing open displays.  This is no problem if you just use
1895        one display, but if you use more than one and close one of them
1896        Emacs may crash.]])
1897       sleep 3
1898     fi
1899   fi
1900
1901 fi
1902 AC_SUBST(GTK_OBJ)
1903
1904
1905 if test "${HAVE_GTK}" = "yes"; then
1906
1907   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1908   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1909   if test "$with_toolkit_scroll_bars" != no; then
1910     with_toolkit_scroll_bars=yes
1911   fi
1912
1913   dnl  Check if we have the old file selection dialog declared and
1914   dnl  in the link library.  In 2.x it may be in the library,
1915   dnl  but not declared if deprecated featured has been selected out.
1916   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1917   HAVE_GTK_FILE_SELECTION=no
1918   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1919                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1920 #include <gtk/gtk.h>])
1921   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1922     AC_CHECK_FUNCS(gtk_file_selection_new)
1923   fi
1924
1925   dnl Check if pthreads are available.  Emacs only needs this when using
1926   dnl gtk_file_chooser under Gnome.
1927     HAVE_GTK_AND_PTHREAD=no
1928     AC_CHECK_HEADERS(pthread.h)
1929     if test "$ac_cv_header_pthread_h"; then
1930       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1931     fi
1932     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1933       case "${canonical}" in
1934         *-hpux*) ;;
1935         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1936       esac
1937       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1938                [Define to 1 if you have GTK and pthread (-lpthread).])
1939     fi
1940
1941   dnl Check for functions introduced in 2.14 and later.
1942   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1943                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1944                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1945                  gtk_orientable_set_orientation)
1946
1947 fi
1948
1949 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1950 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1951 dnl also not configured.
1952 HAVE_DBUS=no
1953 DBUS_OBJ=
1954 if test "${with_dbus}" = "yes"; then
1955    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1956    if test "$HAVE_DBUS" = yes; then
1957      LIBS="$LIBS $DBUS_LIBS"
1958      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1959      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1960      DBUS_OBJ=dbusbind.o
1961    fi
1962 fi
1963 AC_SUBST(DBUS_OBJ)
1964
1965 dnl GConf has been tested under GNU/Linux only.
1966 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1967 HAVE_GCONF=no
1968 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1969    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1970    if test "$HAVE_GCONF" = yes; then
1971       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1972       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1973       AC_CHECK_FUNCS([g_type_init])
1974    fi
1975 fi
1976
1977 dnl SELinux is available for GNU/Linux only.
1978 HAVE_LIBSELINUX=no
1979 LIBSELINUX_LIBS=
1980 if test "${with_selinux}" = "yes"; then
1981    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1982    if test "$HAVE_LIBSELINUX" = yes; then
1983       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1984       LIBSELINUX_LIBS=-lselinux
1985    fi
1986 fi
1987 AC_SUBST(LIBSELINUX_LIBS)
1988
1989 HAVE_GNUTLS=no
1990 if test "${with_gnutls}" = "yes" ; then
1991   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1992   if test "${HAVE_GNUTLS}" = "yes"; then
1993     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1994   fi
1995 fi
1996 AC_SUBST(LIBGNUTLS_LIBS)
1997 AC_SUBST(LIBGNUTLS_CFLAGS)
1998
1999 dnl Do not put whitespace before the #include statements below.
2000 dnl Older compilers (eg sunos4 cc) choke on it.
2001 HAVE_XAW3D=no
2002 LUCID_LIBW=
2003 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2004   if test "$with_xaw3d" != no; then
2005     AC_MSG_CHECKING(for xaw3d)
2006     AC_CACHE_VAL(emacs_cv_xaw3d,
2007     [AC_TRY_LINK([
2008 #include <X11/Intrinsic.h>
2009 #include <X11/Xaw3d/Simple.h>],
2010       [],
2011       emacs_cv_xaw3d=yes,
2012       emacs_cv_xaw3d=no)])
2013   else
2014     emacs_cv_xaw3d=no
2015   fi
2016   if test $emacs_cv_xaw3d = yes; then
2017     AC_MSG_RESULT([yes; using Lucid toolkit])
2018     USE_X_TOOLKIT=LUCID
2019     HAVE_XAW3D=yes
2020     LUCID_LIBW=-lXaw3d
2021     AC_DEFINE(HAVE_XAW3D, 1,
2022               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2023   else
2024     AC_MSG_RESULT(no)
2025     AC_MSG_CHECKING(for libXaw)
2026     AC_CACHE_VAL(emacs_cv_xaw,
2027     [AC_TRY_LINK([
2028 #include <X11/Intrinsic.h>
2029 #include <X11/Xaw/Simple.h>],
2030       [],
2031       emacs_cv_xaw=yes,
2032       emacs_cv_xaw=no)])
2033     if test $emacs_cv_xaw = yes; then
2034       AC_MSG_RESULT([yes; using Lucid toolkit])
2035       USE_X_TOOLKIT=LUCID
2036       LUCID_LIBW=-lXaw
2037     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2038       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2039     else
2040       AC_MSG_RESULT([no; do not use toolkit by default])
2041       USE_X_TOOLKIT=none
2042     fi
2043   fi
2044 fi
2045
2046 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2047
2048 LIBXTR6=
2049 if test "${USE_X_TOOLKIT}" != "none"; then
2050   AC_MSG_CHECKING(X11 toolkit version)
2051   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2052   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2053 [#if XtSpecificationRelease < 6
2054 fail;
2055 #endif
2056 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2057   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2058   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2059     AC_MSG_RESULT(6 or newer)
2060     AC_DEFINE(HAVE_X11XTR6, 1,
2061               [Define to 1 if you have the X11R6 or newer version of Xt.])
2062     LIBXTR6="-lSM -lICE"
2063     case "$opsys" in
2064       ## Use libw.a along with X11R6 Xt.
2065       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2066     esac
2067   else
2068     AC_MSG_RESULT(before 6)
2069   fi
2070
2071 dnl If using toolkit, check whether libXmu.a exists.
2072 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2073   OLDLIBS="$LIBS"
2074   if test x$HAVE_X11XTR6 = xyes; then
2075     LIBS="-lXt -lSM -lICE $LIBS"
2076   else
2077     LIBS="-lXt $LIBS"
2078   fi
2079   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2080   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2081 fi
2082 AC_SUBST(LIBXTR6)
2083
2084 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2085 dnl Why not just test for libxmu in the normal way?
2086 LIBXMU=-lXmu
2087 case $opsys in
2088   ## These systems don't supply Xmu.
2089   hpux* | aix4-2 )
2090     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2091     ;;
2092 esac
2093 AC_SUBST(LIBXMU)
2094
2095 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2096 if test "${HAVE_X11}" = "yes"; then
2097   if test "${USE_X_TOOLKIT}" != "none"; then
2098     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2099   fi
2100 fi
2101
2102 LIBXP=
2103 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2104   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2105   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2106     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2107 int x = 5;
2108 #else
2109 Motif version prior to 2.1.
2110 #endif],
2111     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2112   if test $emacs_cv_motif_version_2_1 = yes; then
2113     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2114   else
2115     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2116     # We put this in CFLAGS temporarily to precede other -I options
2117     # that might be in CFLAGS temporarily.
2118     # We put this in CPPFLAGS where it precedes the other -I options.
2119     OLD_CPPFLAGS=$CPPFLAGS
2120     OLD_CFLAGS=$CFLAGS
2121     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2122     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2123     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2124       [int x = 5;],
2125       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2126     if test $emacs_cv_lesstif = yes; then
2127       # Make sure this -I option remains in CPPFLAGS after it is set
2128       # back to REAL_CPPFLAGS.
2129       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2130       # have those other -I options anyway.  Ultimately, having this
2131       # directory ultimately in CPPFLAGS will be enough.
2132       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2133       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2134     else
2135       CFLAGS=$OLD_CFLAGS
2136       CPPFLAGS=$OLD_CPPFLAGS
2137     fi
2138   fi
2139 fi
2140
2141 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2142 dnl using Motif or Xaw3d is available, and unless
2143 dnl --with-toolkit-scroll-bars=no was specified.
2144
2145 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2146             [Define to 1 if we should use toolkit scroll bars.])dnl
2147 USE_TOOLKIT_SCROLL_BARS=no
2148 if test "${with_toolkit_scroll_bars}" != "no"; then
2149   if test "${USE_X_TOOLKIT}" != "none"; then
2150     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2151       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2152       HAVE_XAW3D=no
2153       USE_TOOLKIT_SCROLL_BARS=yes
2154     elif test "${HAVE_XAW3D}" = "yes"; then
2155       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2156       USE_TOOLKIT_SCROLL_BARS=yes
2157     fi
2158   elif test "${HAVE_GTK}" = "yes"; then
2159     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2160     USE_TOOLKIT_SCROLL_BARS=yes
2161   elif test "${HAVE_NS}" = "yes"; then
2162     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2163     USE_TOOLKIT_SCROLL_BARS=yes
2164   fi
2165 fi
2166
2167 dnl See if XIM is available.
2168 AC_TRY_COMPILE([
2169           #include <X11/Xlib.h>
2170           #include <X11/Xresource.h>],
2171          [XIMProc  callback;],
2172          [HAVE_XIM=yes
2173          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2174          HAVE_XIM=no)
2175
2176 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2177
2178 if test "${with_xim}" != "no"; then
2179   AC_DEFINE(USE_XIM, 1,
2180             [Define to 1 if we should use XIM, if it is available.])
2181 fi
2182
2183
2184 if test "${HAVE_XIM}" != "no"; then
2185   late_CFLAGS=$CFLAGS
2186   if test "$GCC" = yes; then
2187     CFLAGS="$CFLAGS --pedantic-errors"
2188   fi
2189   AC_TRY_COMPILE([
2190 #include <X11/Xlib.h>
2191 #include <X11/Xresource.h>],
2192 [Display *display;
2193 XrmDatabase db;
2194 char *res_name;
2195 char *res_class;
2196 XIMProc  callback;
2197 XPointer *client_data;
2198 #ifndef __GNUC__
2199 /* If we're not using GCC, it's probably not XFree86, and this is
2200    probably right, but we can't use something like --pedantic-errors.  */
2201 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2202                                            char*, XIMProc, XPointer*);
2203 #endif
2204 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2205    client_data);],
2206     [emacs_cv_arg6_star=yes])
2207   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2208          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2209 either XPointer or XPointer*.])dnl
2210   if test "$emacs_cv_arg6_star" = yes; then
2211     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2212   else
2213     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2214   fi
2215   CFLAGS=$late_CFLAGS
2216 fi
2217
2218 ### Start of font-backend (under any platform) section.
2219 # (nothing here yet -- this is a placeholder)
2220 ### End of font-backend (under any platform) section.
2221
2222 ### Start of font-backend (under X11) section.
2223 if test "${HAVE_X11}" = "yes"; then
2224    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2225
2226    ## Use -lXft if available, unless `--with-xft=no'.
2227    HAVE_XFT=maybe
2228     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2229       with_xft="no";
2230     fi
2231     if test "x${with_xft}" != "xno"; then
2232
2233       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2234       ## Because xftfont.c uses XRenderQueryExtension, we also
2235       ## need to link to -lXrender.
2236       HAVE_XRENDER=no
2237       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2238       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2239         OLD_CPPFLAGS="$CPPFLAGS"
2240         OLD_CFLAGS="$CFLAGS"
2241         OLD_LIBS="$LIBS"
2242         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2243         CFLAGS="$CFLAGS $XFT_CFLAGS"
2244         XFT_LIBS="-lXrender $XFT_LIBS"
2245         LIBS="$XFT_LIBS $LIBS"
2246         AC_CHECK_HEADER(X11/Xft/Xft.h,
2247           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2248
2249         if test "${HAVE_XFT}" = "yes"; then
2250           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2251             AC_SUBST(XFT_LIBS)
2252           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2253         else
2254           CPPFLAGS="$OLD_CPPFLAGS"
2255           CFLAGS="$OLD_CFLAGS"
2256           LIBS="$OLD_LIBS"
2257         fi                        # "${HAVE_XFT}" = "yes"
2258       fi                          # "$HAVE_XFT" != no
2259     fi                            # "x${with_xft}" != "xno"
2260
2261     dnl For the "Does Emacs use" message at the end.
2262     if test "$HAVE_XFT" != "yes"; then
2263        HAVE_XFT=no
2264     fi
2265
2266     ## We used to allow building with FreeType and without Xft.
2267     ## However, the ftx font backend driver is not in good shape.
2268     HAVE_FREETYPE=$HAVE_XFT
2269
2270     HAVE_LIBOTF=no
2271     if test "${HAVE_FREETYPE}" = "yes"; then
2272       AC_DEFINE(HAVE_FREETYPE, 1,
2273                 [Define to 1 if using the freetype and fontconfig libraries.])
2274       if test "${with_libotf}" != "no"; then
2275         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2276                           HAVE_LIBOTF=no)
2277         if test "$HAVE_LIBOTF" = "yes"; then
2278           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2279           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2280                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2281                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2282           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2283             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2284                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2285           fi
2286         fi
2287       fi
2288     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2289     dnl Does the new font backend require it, or can it work without it?
2290     fi
2291
2292     HAVE_M17N_FLT=no
2293     if test "${HAVE_LIBOTF}" = yes; then
2294       if test "${with_m17n_flt}" != "no"; then
2295         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2296         if test "$HAVE_M17N_FLT" = "yes"; then
2297           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2298         fi
2299       fi
2300     fi
2301 else
2302     HAVE_XFT=no
2303     HAVE_FREETYPE=no
2304     HAVE_LIBOTF=no
2305     HAVE_M17N_FLT=no
2306 fi
2307
2308 ### End of font-backend (under X11) section.
2309
2310 AC_SUBST(FREETYPE_CFLAGS)
2311 AC_SUBST(FREETYPE_LIBS)
2312 AC_SUBST(FONTCONFIG_CFLAGS)
2313 AC_SUBST(FONTCONFIG_LIBS)
2314 AC_SUBST(LIBOTF_CFLAGS)
2315 AC_SUBST(LIBOTF_LIBS)
2316 AC_SUBST(M17N_FLT_CFLAGS)
2317 AC_SUBST(M17N_FLT_LIBS)
2318
2319 ### Use -lXpm if available, unless `--with-xpm=no'.
2320 HAVE_XPM=no
2321 LIBXPM=
2322 if test "${HAVE_X11}" = "yes"; then
2323   if test "${with_xpm}" != "no"; then
2324     AC_CHECK_HEADER(X11/xpm.h,
2325       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2326     if test "${HAVE_XPM}" = "yes"; then
2327       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2328       AC_EGREP_CPP(no_return_alloc_pixels,
2329       [#include "X11/xpm.h"
2330 #ifndef XpmReturnAllocPixels
2331 no_return_alloc_pixels
2332 #endif
2333       ], HAVE_XPM=no, HAVE_XPM=yes)
2334
2335       if test "${HAVE_XPM}" = "yes"; then
2336         AC_MSG_RESULT(yes)
2337       else
2338         AC_MSG_RESULT(no)
2339       fi
2340     fi
2341   fi
2342
2343   if test "${HAVE_XPM}" = "yes"; then
2344     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2345     LIBXPM=-lXpm
2346   fi
2347 fi
2348 AC_SUBST(LIBXPM)
2349
2350 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2351 HAVE_JPEG=no
2352 LIBJPEG=
2353 if test "${HAVE_X11}" = "yes"; then
2354   if test "${with_jpeg}" != "no"; then
2355     dnl Checking for jpeglib.h can lose because of a redefinition of
2356     dnl  HAVE_STDLIB_H.
2357     AC_CHECK_HEADER(jerror.h,
2358       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2359   fi
2360
2361   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2362   if test "${HAVE_JPEG}" = "yes"; then
2363     AC_DEFINE(HAVE_JPEG)
2364     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2365         [#include <jpeglib.h>
2366          version=JPEG_LIB_VERSION
2367 ],
2368         [AC_DEFINE(HAVE_JPEG)],
2369         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2370         HAVE_JPEG=no])
2371   fi
2372   if test "${HAVE_JPEG}" = "yes"; then
2373     LIBJPEG=-ljpeg
2374   fi
2375 fi
2376 AC_SUBST(LIBJPEG)
2377
2378 ### Use -lpng if available, unless `--with-png=no'.
2379 HAVE_PNG=no
2380 LIBPNG=
2381 if test "${HAVE_X11}" = "yes"; then
2382   if test "${with_png}" != "no"; then
2383     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2384     # in /usr/include/libpng.
2385     AC_CHECK_HEADERS(png.h libpng/png.h)
2386     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2387       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2388     fi
2389   fi
2390
2391   if test "${HAVE_PNG}" = "yes"; then
2392     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2393     LIBPNG="-lpng -lz -lm"
2394   fi
2395 fi
2396 AC_SUBST(LIBPNG)
2397
2398 ### Use -ltiff if available, unless `--with-tiff=no'.
2399 HAVE_TIFF=no
2400 LIBTIFF=
2401 if test "${HAVE_X11}" = "yes"; then
2402   if test "${with_tiff}" != "no"; then
2403     AC_CHECK_HEADER(tiffio.h,
2404       [tifflibs="-lz -lm"
2405       # At least one tiff package requires the jpeg library.
2406       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2407       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2408   fi
2409
2410   if test "${HAVE_TIFF}" = "yes"; then
2411     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2412     dnl FIXME -lz -lm, as per libpng?
2413     LIBTIFF=-ltiff
2414   fi
2415 fi
2416 AC_SUBST(LIBTIFF)
2417
2418 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2419 HAVE_GIF=no
2420 LIBGIF=
2421 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2422   AC_CHECK_HEADER(gif_lib.h,
2423 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2424 # Earlier versions can crash Emacs.
2425     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2426
2427   if test "$HAVE_GIF" = yes; then
2428     LIBGIF=-lgif
2429   elif test "$HAVE_GIF" = maybe; then
2430 # If gif_lib.h but no libgif, try libungif.
2431     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2432     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2433   fi
2434
2435   if test "${HAVE_GIF}" = "yes"; then
2436     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2437   fi
2438 fi
2439 AC_SUBST(LIBGIF)
2440
2441 dnl Check for required libraries.
2442 if test "${HAVE_X11}" = "yes"; then
2443   MISSING=""
2444   WITH_NO=""
2445   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2446     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2447   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2448     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2449   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2450     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2451   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2452     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2453   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2454     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2455
2456   if test "X${MISSING}" != X; then
2457     AC_MSG_ERROR([The following required libraries were not found:
2458     $MISSING
2459 Maybe some development libraries/packages are missing?
2460 If you don't want to link with them give
2461     $WITH_NO
2462 as options to configure])
2463   fi
2464 fi
2465
2466 ### Use -lgpm if available, unless `--with-gpm=no'.
2467 HAVE_GPM=no
2468 LIBGPM=
2469 MOUSE_SUPPORT=
2470 if test "${with_gpm}" != "no"; then
2471   AC_CHECK_HEADER(gpm.h,
2472     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2473
2474   if test "${HAVE_GPM}" = "yes"; then
2475     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2476     LIBGPM=-lgpm
2477     ## May be reset below.
2478     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2479   fi
2480 fi
2481 AC_SUBST(LIBGPM)
2482
2483 dnl Check for malloc/malloc.h on darwin
2484 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2485
2486 C_SWITCH_X_SYSTEM=
2487 ### Use NeXTstep API to implement GUI.
2488 if test "${HAVE_NS}" = "yes"; then
2489   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2490   if test "${NS_IMPL_COCOA}" = "yes"; then
2491     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2492     GNU_OBJC_CFLAGS=
2493   fi
2494   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2495     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2496     # See also .m.o rule in Makefile.in */
2497     # FIXME: are all these flags really needed?  Document here why.  */
2498     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2499     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2500   fi
2501   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2502     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2503   fi
2504   # We also have mouse menus.
2505   HAVE_MENUS=yes
2506   OTHER_FILES=ns-app
2507 fi
2508
2509
2510 ### Use session management (-lSM -lICE) if available
2511 HAVE_X_SM=no
2512 LIBXSM=
2513 if test "${HAVE_X11}" = "yes"; then
2514   AC_CHECK_HEADER(X11/SM/SMlib.h,
2515     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2516
2517   if test "${HAVE_X_SM}" = "yes"; then
2518     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2519     LIBXSM="-lSM -lICE"
2520     case "$LIBS" in
2521       *-lSM*) ;;
2522       *)      LIBS="$LIBXSM $LIBS" ;;
2523     esac
2524   fi
2525 fi
2526 AC_SUBST(LIBXSM)
2527
2528 ### Use libxml (-lxml2) if available
2529 if test "${with_xml2}" != "no"; then
2530   ### I'm not sure what the version number should be, so I just guessed.
2531   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2532   if test "${HAVE_LIBXML2}" = "yes"; then
2533     LIBS="$LIBXML2_LIBS $LIBS"
2534     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2535     if test "${HAVE_LIBXML2}" = "yes"; then
2536       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2537     else
2538       LIBXML2_LIBS=""
2539       LIBXML2_CFLAGS=""
2540     fi
2541   fi
2542 fi
2543 AC_SUBST(LIBXML2_LIBS)
2544 AC_SUBST(LIBXML2_CFLAGS)
2545
2546 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2547 AC_CACHE_CHECK(whether netdb declares h_errno,
2548                emacs_cv_netdb_declares_h_errno,
2549 [AC_TRY_LINK([#include <netdb.h>],
2550   [return h_errno;],
2551   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2552 if test $emacs_cv_netdb_declares_h_errno = yes; then
2553   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2554 fi
2555
2556 AC_FUNC_ALLOCA
2557
2558 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2559 dnl FIXME is there an autoconf test that does the right thing, without
2560 dnl needing to call A_M_E afterwards?
2561 if test x"$ac_cv_func_alloca_works" != xyes; then
2562    AC_MSG_ERROR( [a system implementation of alloca is required] )
2563 fi
2564
2565 # fmod, logb, and frexp are found in -lm on most systems.
2566 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2567 AC_CHECK_LIB(m, sqrt)
2568
2569 # Check for mail-locking functions in a "mail" library.  Probably this should
2570 # have the same check as for liblockfile below.
2571 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2572 if test $have_mail = yes; then
2573   LIBS_MAIL=-lmail
2574   LIBS="$LIBS_MAIL $LIBS"
2575   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2576 else
2577   LIBS_MAIL=
2578 fi
2579 dnl Debian, at least:
2580 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2581 if test $have_lockfile = yes; then
2582    LIBS_MAIL=-llockfile
2583    LIBS="$LIBS_MAIL $LIBS"
2584    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2585 else
2586 # If we have the shared liblockfile, assume we must use it for mail
2587 # locking (e.g. Debian).  If we couldn't link against liblockfile
2588 # (no liblockfile.a installed), ensure that we don't need to.
2589   dnl This works for files generally, not just executables.
2590   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2591   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2592                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2593   if test $ac_cv_prog_liblockfile = yes; then
2594     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2595 This probably means that movemail could lose mail.
2596 There may be a `development' package to install containing liblockfile.])
2597   fi
2598 fi
2599 AC_CHECK_FUNCS(touchlock)
2600 AC_CHECK_HEADERS(maillock.h)
2601 AC_SUBST(LIBS_MAIL)
2602
2603 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2604 ## interlock access to the mail spool.  The alternative is a lock file named
2605 ## /usr/spool/mail/$USER.lock.
2606 mail_lock=no
2607 case "$opsys" in
2608   aix4-2) mail_lock="lockf" ;;
2609
2610   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2611
2612   ## On GNU/Linux systems, both methods are used by various mail programs.
2613   ## I assume most people are using newer mailers that have heard of flock.
2614   ## Change this if you need to.
2615   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2616   ## configure gets the right answers, and that means *NOT* using flock.
2617   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2618   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2619   ## Debian maintainer hasn't provided a clean fix for Emacs.
2620   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2621   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2622   ## correct logic.  -- fx
2623   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2624   ## liblockfile is a Free Software replacement for libmail, used on
2625   ## Debian systems and elsewhere. -rfr.
2626   gnu-*)
2627     mail_lock="flock"
2628     if test $have_mail = yes || test $have_lockfile = yes; then
2629       test $ac_cv_header_maillock_h = yes && mail_lock=no
2630     fi
2631     ;;
2632 esac
2633
2634 BLESSMAIL_TARGET=
2635 case "$mail_lock" in
2636   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2637
2638   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2639
2640   *) BLESSMAIL_TARGET="need-blessmail" ;;
2641 esac
2642 AC_SUBST(BLESSMAIL_TARGET)
2643
2644
2645 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2646 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2647 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2648 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2649 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2650 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2651 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2652 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2653 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2654 cfmakeraw cfsetspeed isnan copysign __executable_start)
2655
2656 dnl Cannot use AC_CHECK_FUNCS
2657 AC_CACHE_CHECK([for __builtin_unwind_init],
2658                emacs_cv_func___builtin_unwind_init,
2659 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2660                 emacs_cv_func___builtin_unwind_init=yes,
2661                 emacs_cv_func___builtin_unwind_init=no)])
2662 if test $emacs_cv_func___builtin_unwind_init = yes; then
2663   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2664             [Define to 1 if you have the `__builtin_unwind_init' function.])
2665 fi
2666
2667 AC_CHECK_HEADERS(sys/un.h)
2668
2669 AC_FUNC_GETLOADAVG
2670
2671 AC_FUNC_FSEEKO
2672
2673 AC_FUNC_GETPGRP
2674
2675 # Configure gnulib.
2676 gl_ASSERT_NO_GNULIB_POSIXCHECK
2677 gl_ASSERT_NO_GNULIB_TESTS
2678 gl_INIT
2679
2680 AC_FUNC_STRFTIME
2681
2682 # UNIX98 PTYs.
2683 AC_CHECK_FUNCS(grantpt)
2684
2685 # PTY-related GNU extensions.
2686 AC_CHECK_FUNCS(getpt)
2687
2688 # Check this now, so that we will NOT find the above functions in ncurses.
2689 # That is because we have not set up to link ncurses in lib-src.
2690 # It's better to believe a function is not available
2691 # than to expect to find it in ncurses.
2692 # Also we need tputs and friends to be able to build at all.
2693 have_tputs_et_al=true
2694 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2695 if test "$have_tputs_et_al" != true; then
2696   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2697 Maybe some development libraries/packages are missing?  Try installing
2698 libncurses-dev(el), libterminfo-dev(el) or similar.])
2699 fi
2700 # Must define this when any termcap library is found.
2701 AC_DEFINE(HAVE_LIBNCURSES, 1,
2702           [Define to 1 if you have the `ncurses' library (-lncurses).])
2703 ## FIXME This was the cpp logic, but I am not sure it is right.
2704 ## The above test has not necessarily found libncurses.
2705 HAVE_LIBNCURSES=yes
2706
2707 ## Use terminfo instead of termcap?
2708 ## Note only system files NOT using terminfo are:
2709 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2710 ## darwin|gnu without ncurses.
2711 TERMINFO=no
2712 LIBS_TERMCAP=
2713 case "$opsys" in
2714   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2715   ## hpux10-20: Use the system provided termcap(3) library.
2716   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2717   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2718   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2719
2720   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2721   ##  The ncurses library has been moved out of the System framework in
2722   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2723   ##  option to use it.
2724   darwin|gnu*)
2725     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2726     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2727       TERMINFO=yes
2728       LIBS_TERMCAP="-lncurses"
2729     fi
2730     ;;
2731
2732   freebsd)
2733     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2734     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2735     [AC_TRY_LINK([#include <osreldate.h>],
2736 [#if __FreeBSD_version < 400000
2737 fail;
2738 #endif
2739 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2740
2741     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2742
2743     if test $emacs_cv_freebsd_terminfo = yes; then
2744       TERMINFO=yes
2745       LIBS_TERMCAP="-lncurses"
2746     else
2747       LIBS_TERMCAP="-ltermcap"
2748     fi
2749     ;;
2750
2751   netbsd)
2752     if test $ac_cv_search_tputs = -lterminfo; then
2753       TERMINFO=yes
2754       LIBS_TERMCAP="-lterminfo"
2755     else
2756       LIBS_TERMCAP="-ltermcap"
2757     fi
2758     ;;
2759
2760 esac
2761
2762 case "$opsys" in
2763   ## hpux: Make sure we get select from libc rather than from libcurses
2764   ##  because libcurses on HPUX 10.10 has a broken version of select.
2765   ##  We used to use -lc -lcurses, but this may be cleaner.
2766   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2767
2768   openbsd) LIBS_TERMCAP="-lncurses" ;;
2769
2770   ## Must use system termcap, if we use any termcap.  It does special things.
2771   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2772 esac
2773
2774 TERMCAP_OBJ=tparam.o
2775 if test $TERMINFO = yes; then
2776   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2777
2778   ## Default used to be -ltermcap.  Add a case above if need something else.
2779   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2780
2781   TERMCAP_OBJ=terminfo.o
2782 fi
2783 AC_SUBST(LIBS_TERMCAP)
2784 AC_SUBST(TERMCAP_OBJ)
2785
2786
2787 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2788 resolv=no
2789 AC_TRY_LINK([#include <netinet/in.h>
2790 #include <arpa/nameser.h>
2791 #include <resolv.h>],
2792     [return res_init();],
2793     have_res_init=yes, have_res_init=no)
2794 if test "$have_res_init" = no; then
2795   OLIBS="$LIBS"
2796   LIBS="$LIBS -lresolv"
2797   AC_MSG_CHECKING(for res_init with -lresolv)
2798   AC_TRY_LINK([#include <netinet/in.h>
2799 #include <arpa/nameser.h>
2800 #include <resolv.h>],
2801     [return res_init();],
2802     have_res_init=yes, have_res_init=no)
2803   AC_MSG_RESULT($have_res_init)
2804   if test "$have_res_init" = yes ; then
2805     resolv=yes
2806   fi
2807   LIBS="$OLIBS"
2808 fi
2809
2810 if test "$have_res_init" = yes; then
2811   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2812 fi
2813
2814 # Do we need the Hesiod library to provide the support routines?
2815 LIBHESIOD=
2816 if test "$with_hesiod" != no ; then
2817   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2818   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2819      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2820                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2821   if test "$resolv" = yes ; then
2822     RESOLVLIB=-lresolv
2823   else
2824     RESOLVLIB=
2825   fi
2826   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2827         hesiod=yes, :, $RESOLVLIB)])
2828
2829   if test x"$hesiod" = xyes; then
2830     AC_DEFINE(HAVE_LIBHESIOD, 1,
2831               [Define to 1 if you have the hesiod library (-lhesiod).])
2832     LIBHESIOD=-lhesiod
2833   fi
2834 fi
2835 AC_SUBST(LIBHESIOD)
2836
2837 # Do we need libresolv (due to res_init or Hesiod)?
2838 if test "$resolv" = yes ; then
2839   AC_DEFINE(HAVE_LIBRESOLV, 1,
2840             [Define to 1 if you have the resolv library (-lresolv).])
2841   LIBRESOLV=-lresolv
2842 else
2843   LIBRESOLV=
2844 fi
2845 AC_SUBST(LIBRESOLV)
2846
2847 # These tell us which Kerberos-related libraries to use.
2848 COM_ERRLIB=
2849 CRYPTOLIB=
2850 KRB5LIB=
2851 DESLIB=
2852 KRB4LIB=
2853
2854 if test "${with_kerberos}" != no; then
2855   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2856   if test $have_com_err = yes; then
2857     COM_ERRLIB=-lcom_err
2858     LIBS="$COM_ERRLIB $LIBS"
2859     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2860   fi
2861   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2862   if test $have_crypto = yes; then
2863     CRYPTOLIB=-lcrypto
2864     LIBS="$CRYPTOLIB $LIBS"
2865     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2866   fi
2867   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2868   if test $have_k5crypto = yes; then
2869     CRYPTOLIB=-lk5crypto
2870     LIBS="$CRYPTOLIB $LIBS"
2871     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2872   fi
2873   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2874   if test $have_krb5=yes; then
2875     KRB5LIB=-lkrb5
2876     LIBS="$KRB5LIB $LIBS"
2877     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2878   fi
2879   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2880   if test "${with_kerberos5}" = no; then
2881     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2882     if test $have_des425 = yes; then
2883       DESLIB=-ldes425
2884       LIBS="$DESLIB $LIBS"
2885       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2886     else
2887       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2888       if test $have_des = yes; then
2889         DESLIB=-ldes
2890         LIBS="$DESLIB $LIBS"
2891         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2892       fi
2893     fi
2894     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2895     if test $have_krb4 = yes; then
2896       KRB4LIB=-lkrb4
2897       LIBS="$KRB4LIB $LIBS"
2898       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2899     else
2900       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2901       if test $have_krb = yes; then
2902         KRB4LIB=-lkrb
2903         LIBS="$KRB4LIB $LIBS"
2904         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2905       fi
2906     fi
2907   fi
2908
2909   if test "${with_kerberos5}" != no; then
2910     AC_CHECK_HEADERS(krb5.h,
2911       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2912                         [#include <krb5.h>])])
2913   else
2914     AC_CHECK_HEADERS(des.h,,
2915                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2916                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2917     AC_CHECK_HEADERS(krb.h,,
2918                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2919                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2920   fi
2921   AC_CHECK_HEADERS(com_err.h)
2922 fi
2923
2924 AC_SUBST(COM_ERRLIB)
2925 AC_SUBST(CRYPTOLIB)
2926 AC_SUBST(KRB5LIB)
2927 AC_SUBST(DESLIB)
2928 AC_SUBST(KRB4LIB)
2929
2930 # Solaris requires -lintl if you want strerror (which calls dgettext)
2931 # to return localized messages.
2932 AC_CHECK_LIB(intl, dgettext)
2933
2934 AC_MSG_CHECKING(whether localtime caches TZ)
2935 AC_CACHE_VAL(emacs_cv_localtime_cache,
2936 [if test x$ac_cv_func_tzset = xyes; then
2937 AC_TRY_RUN([#include <time.h>
2938 char TZ_GMT0[] = "TZ=GMT0";
2939 char TZ_PST8[] = "TZ=PST8";
2940 main()
2941 {
2942   time_t now = time ((time_t *) 0);
2943   int hour_GMT0, hour_unset;
2944   if (putenv (TZ_GMT0) != 0)
2945     exit (1);
2946   hour_GMT0 = localtime (&now)->tm_hour;
2947   unsetenv("TZ");
2948   hour_unset = localtime (&now)->tm_hour;
2949   if (putenv (TZ_PST8) != 0)
2950     exit (1);
2951   if (localtime (&now)->tm_hour == hour_GMT0)
2952     exit (1);
2953   unsetenv("TZ");
2954   if (localtime (&now)->tm_hour != hour_unset)
2955     exit (1);
2956   exit (0);
2957 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2958 [# If we have tzset, assume the worst when cross-compiling.
2959 emacs_cv_localtime_cache=yes])
2960 else
2961         # If we lack tzset, report that localtime does not cache TZ,
2962         # since we can't invalidate the cache if we don't have tzset.
2963         emacs_cv_localtime_cache=no
2964 fi])dnl
2965 AC_MSG_RESULT($emacs_cv_localtime_cache)
2966 if test $emacs_cv_localtime_cache = yes; then
2967   AC_DEFINE(LOCALTIME_CACHE, 1,
2968             [Define to 1 if localtime caches TZ.])
2969 fi
2970
2971 if test "x$HAVE_TIMEVAL" = xyes; then
2972   AC_CHECK_FUNCS(gettimeofday)
2973   if test $ac_cv_func_gettimeofday = yes; then
2974     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2975                    emacs_cv_gettimeofday_two_arguments,
2976     [AC_TRY_COMPILE([
2977 #ifdef TIME_WITH_SYS_TIME
2978 #include <sys/time.h>
2979 #include <time.h>
2980 #else
2981 #ifdef HAVE_SYS_TIME_H
2982 #include <sys/time.h>
2983 #else
2984 #include <time.h>
2985 #endif
2986 #endif],
2987       [struct timeval time;
2988        gettimeofday (&time, 0);],
2989       emacs_cv_gettimeofday_two_arguments=yes,
2990       emacs_cv_gettimeofday_two_arguments=no)])
2991     if test $emacs_cv_gettimeofday_two_arguments = no; then
2992       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2993                 [Define to 1 if gettimeofday accepts only one argument.])
2994     fi
2995   fi
2996 fi
2997
2998 ok_so_far=yes
2999 AC_CHECK_FUNC(socket, , ok_so_far=no)
3000 if test $ok_so_far = yes; then
3001   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3002 fi
3003 if test $ok_so_far = yes; then
3004   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3005 fi
3006 if test $ok_so_far = yes; then
3007 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3008   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3009             [Define to 1 if you have inet sockets.])
3010 fi
3011
3012 if test -f /usr/lpp/X11/bin/smt.exp; then
3013   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3014             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3015 fi
3016
3017 AC_MSG_CHECKING(whether system supports dynamic ptys)
3018 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3019   AC_MSG_RESULT(yes)
3020   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3021 else
3022   AC_MSG_RESULT(no)
3023 fi
3024
3025 AC_FUNC_FORK
3026
3027 dnl Adapted from Haible's version.
3028 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3029   [AC_TRY_LINK([#include <langinfo.h>],
3030     [char* cs = nl_langinfo(CODESET);],
3031     emacs_cv_langinfo_codeset=yes,
3032     emacs_cv_langinfo_codeset=no)
3033   ])
3034 if test $emacs_cv_langinfo_codeset = yes; then
3035   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3036     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3037 fi
3038
3039 AC_CHECK_TYPES(size_t)
3040
3041 AC_TYPE_MBSTATE_T
3042
3043 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3044   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3045                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3046 if test "$emacs_cv_c_restrict_arr" = yes; then
3047   AC_DEFINE(__restrict_arr, __restrict,
3048     [Define to compiler's equivalent of C99 restrict keyword in array
3049      declarations.  Define as empty for no equivalent.])
3050 fi
3051
3052 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3053 dnl how the tty code is related to POSIX and/or other versions of termios.
3054 dnl The following looks like a useful start.
3055 dnl
3056 dnl AC_SYS_POSIX_TERMIOS
3057 dnl if test $ac_cv_sys_posix_termios = yes; then
3058 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3059 dnl                                and macros for terminal control.])
3060 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3061 dnl fi
3062
3063 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3064
3065 # Set up the CFLAGS for real compilation, so we can substitute it.
3066 CFLAGS="$REAL_CFLAGS"
3067 CPPFLAGS="$REAL_CPPFLAGS"
3068
3069 ## Hack to detect a buggy GCC version.
3070 if test "x$GCC" = xyes \
3071    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3072    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3073    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3074    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3075 fi
3076
3077 #### Find out which version of Emacs this is.
3078 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3079          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3080 if test x"${version}" = x; then
3081   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3082 fi
3083 if test x"${version}" != x"$PACKAGE_VERSION"; then
3084   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3085 fi
3086
3087 ### Specify what sort of things we'll be editing into Makefile and config.h.
3088 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3089 AC_SUBST(version)
3090 AC_SUBST(configuration)
3091 ## Unused?
3092 AC_SUBST(canonical)
3093 AC_SUBST(srcdir)
3094 AC_SUBST(prefix)
3095 AC_SUBST(exec_prefix)
3096 AC_SUBST(bindir)
3097 AC_SUBST(datadir)
3098 AC_SUBST(sharedstatedir)
3099 AC_SUBST(libexecdir)
3100 AC_SUBST(mandir)
3101 AC_SUBST(infodir)
3102 AC_SUBST(lispdir)
3103 AC_SUBST(locallisppath)
3104 AC_SUBST(lisppath)
3105 AC_SUBST(x_default_search_path)
3106 AC_SUBST(etcdir)
3107 AC_SUBST(archlibdir)
3108 AC_SUBST(docdir)
3109 AC_SUBST(bitmapdir)
3110 AC_SUBST(gamedir)
3111 AC_SUBST(gameuser)
3112 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3113 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3114 ## end of LIBX_BASE, but nothing ever set it.
3115 AC_SUBST(LD_SWITCH_X_SITE)
3116 AC_SUBST(C_SWITCH_X_SITE)
3117 AC_SUBST(C_SWITCH_X_SYSTEM)
3118 AC_SUBST(CFLAGS)
3119 ## Used in lwlib/Makefile.in.
3120 AC_SUBST(X_TOOLKIT_TYPE)
3121 if test -n "${machfile}"; then
3122   M_FILE="\$(srcdir)/${machfile}"
3123 else
3124   M_FILE=
3125 fi
3126 S_FILE="\$(srcdir)/${opsysfile}"
3127 AC_SUBST(M_FILE)
3128 AC_SUBST(S_FILE)
3129 AC_SUBST(GETLOADAVG_LIBS)
3130 AC_SUBST(ns_appdir)
3131 AC_SUBST(ns_appbindir)
3132 AC_SUBST(ns_appresdir)
3133 AC_SUBST(ns_appsrc)
3134 AC_SUBST(GNU_OBJC_CFLAGS)
3135 AC_SUBST(OTHER_FILES)
3136
3137 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3138                    [Define to the canonical Emacs configuration name.])
3139 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3140                    [Define to the options passed to configure.])
3141 if test -n "$machfile"; then
3142   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3143                      [Define to the used machine dependent file.])
3144 fi
3145 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3146                    [Define to the used os dependent file.])
3147
3148 XMENU_OBJ=
3149 XOBJ=
3150 FONT_OBJ=
3151 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3152   AC_DEFINE(HAVE_X_WINDOWS, 1,
3153             [Define to 1 if you want to use the X window system.])
3154   XMENU_OBJ=xmenu.o
3155   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3156   FONT_OBJ=xfont.o
3157   if test "$HAVE_XFT" = "yes"; then
3158     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3159   elif test "$HAVE_FREETYPE" = "yes"; then
3160     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3161   fi
3162   AC_SUBST(FONT_OBJ)
3163 fi
3164 AC_SUBST(XMENU_OBJ)
3165 AC_SUBST(XOBJ)
3166 AC_SUBST(FONT_OBJ)
3167
3168 WIDGET_OBJ=
3169 MOTIF_LIBW=
3170 if test "${USE_X_TOOLKIT}" != "none" ; then
3171   WIDGET_OBJ=widget.o
3172   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3173   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3174     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3175   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3176     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3177     MOTIF_LIBW=-lXm
3178     case "$opsys" in
3179       gnu-linux)
3180         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3181         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3182         ;;
3183
3184       unixware)
3185         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3186         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3187         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3188         ;;
3189
3190       aix4-2)
3191         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3192         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3193         ;;
3194     esac
3195     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3196   fi
3197 fi
3198 AC_SUBST(WIDGET_OBJ)
3199
3200 TOOLKIT_LIBW=
3201 case "$USE_X_TOOLKIT" in
3202   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3203   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3204   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3205 esac
3206 AC_SUBST(TOOLKIT_LIBW)
3207
3208 if test "$USE_X_TOOLKIT" = "none"; then
3209   LIBXT_OTHER="\$(LIBXSM)"
3210   OLDXMENU_TARGET="really-oldXMenu"
3211 else
3212   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3213   OLDXMENU_TARGET="really-lwlib"
3214 fi
3215 AC_SUBST(LIBXT_OTHER)
3216
3217 ## The X Menu stuff is present in the X10 distribution, but missing
3218 ## from X11.  If we have X10, just use the installed library;
3219 ## otherwise, use our own copy.
3220 if test "${HAVE_X11}" = "yes" ; then
3221   AC_DEFINE(HAVE_X11, 1,
3222             [Define to 1 if you want to use version 11 of X windows.
3223              Otherwise, Emacs expects to use version 10.])
3224
3225   if test "$USE_X_TOOLKIT" = "none"; then
3226     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3227   else
3228     OLDXMENU="\${lwlibdir}/liblw.a"
3229   fi
3230   LIBXMENU="\$(OLDXMENU)"
3231   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3232   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3233 else
3234   ## For a syntactically valid Makefile; not actually used for anything.
3235   ## See comments in src/Makefile.in.
3236   OLDXMENU=nothing
3237   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3238   if test "${HAVE_X_WINDOWS}" = "yes"; then
3239     LIBXMENU="-lXMenu"
3240   else
3241     LIBXMENU=
3242   fi
3243   LIBX_OTHER=
3244   OLDXMENU_DEPS=
3245 fi
3246
3247 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3248   OLDXMENU_TARGET=
3249   OLDXMENU=nothing
3250   LIBXMENU=
3251   OLDXMENU_DEPS=
3252 fi
3253
3254 AC_SUBST(OLDXMENU_TARGET)
3255 AC_SUBST(OLDXMENU)
3256 AC_SUBST(LIBXMENU)
3257 AC_SUBST(LIBX_OTHER)
3258 AC_SUBST(OLDXMENU_DEPS)
3259
3260 if test "${HAVE_MENUS}" = "yes" ; then
3261   AC_DEFINE(HAVE_MENUS, 1,
3262             [Define to 1 if you have mouse menus.
3263              (This is automatic if you use X, but the option to specify it remains.)
3264              It is also defined with other window systems that support xmenu.c.])
3265 fi
3266
3267 if test "${GNU_MALLOC}" = "yes" ; then
3268   AC_DEFINE(GNU_MALLOC, 1,
3269             [Define to 1 if you want to use the GNU memory allocator.])
3270 fi
3271
3272 RALLOC_OBJ=
3273 if test "${REL_ALLOC}" = "yes" ; then
3274   AC_DEFINE(REL_ALLOC, 1,
3275             [Define REL_ALLOC if you want to use the relocating allocator for
3276              buffer space.])
3277
3278   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3279 fi
3280 AC_SUBST(RALLOC_OBJ)
3281
3282 if test "$opsys" = "cygwin"; then
3283   CYGWIN_OBJ="sheap.o"
3284   ## Cygwin differs because of its unexec().
3285   PRE_ALLOC_OBJ=
3286   POST_ALLOC_OBJ=lastfile.o
3287 else
3288   CYGWIN_OBJ=
3289   PRE_ALLOC_OBJ=lastfile.o
3290   POST_ALLOC_OBJ=
3291 fi
3292 AC_SUBST(CYGWIN_OBJ)
3293 AC_SUBST(PRE_ALLOC_OBJ)
3294 AC_SUBST(POST_ALLOC_OBJ)
3295
3296
3297 case "$opsys" in
3298   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3299
3300   darwin)
3301    ## The -headerpad option tells ld (see man page) to leave room at the
3302    ## end of the header for adding load commands.  Needed for dumping.
3303    ## 0x690 is the total size of 30 segment load commands (at 56
3304    ## each); under Cocoa 31 commands are required.
3305    if test "$HAVE_NS" = "yes"; then
3306      libs_nsgui="-framework AppKit"
3307      headerpad_extra=6C8
3308    else
3309      libs_nsgui=
3310      headerpad_extra=690
3311    fi
3312    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3313
3314    ## This is here because src/Makefile.in did some extra fiddling around
3315    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3316    ##   #ifndef LD_SWITCH_SYSTEM
3317    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3318    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3319    ## not using gcc, darwin system not on an alpha (ie darwin, since
3320    ## darwin + alpha does not occur).
3321    ## Because this was done in src/Makefile.in, the resulting part of
3322    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3323    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3324    ## rather than LD_SWITCH_SYSTEM.
3325    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3326      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3327    ;;
3328
3329   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3330   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3331   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3332   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3333   ## had different values in configure (in ac_link) and src/Makefile.in.
3334   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3335   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3336
3337   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3338 esac
3339
3340 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3341   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3342 fi
3343
3344 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3345
3346
3347 LD_FIRSTFLAG=
3348 ORDINARY_LINK=
3349 case "$opsys" in
3350   ## gnu: GNU needs its own crt0.
3351   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3352
3353   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3354   ## library search parth, i.e. it won't search /usr/lib for libc and
3355   ## friends.  Using -nostartfiles instead avoids this problem, and
3356   ## will also work on earlier NetBSD releases.
3357   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3358
3359   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3360   ##   MkLinux/LinuxPPC needs this.
3361   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3362   gnu-*)
3363     case "$machine" in
3364       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3365     esac
3366     ;;
3367 esac
3368
3369
3370 if test "x$ORDINARY_LINK" = "xyes"; then
3371
3372   LD_FIRSTFLAG=""
3373   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3374
3375 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3376 ## freebsd, gnu-* not on macppc|ibms390x.
3377 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3378
3379   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3380   ## places that are difficult to figure out at make time.  Fortunately,
3381   ## these same versions allow you to pass arbitrary flags on to the
3382   ## linker, so there is no reason not to use it as a linker.
3383   ##
3384   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3385   ## searching for libraries in its internal directories, so we have to
3386   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3387   LD_FIRSTFLAG="-nostdlib"
3388 fi
3389
3390 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3391 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3392
3393 AC_SUBST(LD_FIRSTFLAG)
3394
3395
3396 ## FIXME? The logic here is not precisely the same as that above.
3397 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3398 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3399 LIB_GCC=
3400 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3401
3402   case "$opsys" in
3403     freebsd|netbsd|openbsd) LIB_GCC= ;;
3404
3405     gnu-*)
3406       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3407       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3408       case $host_cpu in
3409       arm*)
3410         LIB_GCC="-lgcc_s"
3411         ;;
3412       *)
3413         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3414         ## immediately undefine it again and redefine it to empty.
3415         ## Was the C_SWITCH_X_SITE part really necessary?
3416 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3417         LIB_GCC=
3418         ;;
3419       esac
3420       ;;
3421
3422     ## Ask GCC where to find libgcc.a.
3423     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3424   esac
3425 fi                              dnl if $GCC
3426 AC_SUBST(LIB_GCC)
3427
3428
3429 TOOLTIP_SUPPORT=
3430 WINDOW_SUPPORT=
3431 ## If we're using X11/GNUstep, define some consequences.
3432 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3433   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3434   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3435   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3436   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3437
3438   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3439   test "$HAVE_X_WINDOWS" = "yes" && \
3440     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3441
3442 fi
3443 AC_SUBST(MOUSE_SUPPORT)
3444 AC_SUBST(TOOLTIP_SUPPORT)
3445 AC_SUBST(WINDOW_SUPPORT)
3446
3447
3448 AH_TOP([/* GNU Emacs site configuration template file.
3449    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3450      2006, 2007, 2008, 2009, 2010, 2011  Free Software Foundation, Inc.
3451
3452 This file is part of GNU Emacs.
3453
3454 GNU Emacs is free software: you can redistribute it and/or modify
3455 it under the terms of the GNU General Public License as published by
3456 the Free Software Foundation, either version 3 of the License, or
3457 (at your option) any later version.
3458
3459 GNU Emacs is distributed in the hope that it will be useful,
3460 but WITHOUT ANY WARRANTY; without even the implied warranty of
3461 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3462 GNU General Public License for more details.
3463
3464 You should have received a copy of the GNU General Public License
3465 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3466
3467
3468 /* No code in Emacs #includes config.h twice, but some bits of code
3469    intended to work with other packages as well (like gmalloc.c)
3470    think they can include it as many times as they like.  */
3471 #ifndef EMACS_CONFIG_H
3472 #define EMACS_CONFIG_H
3473 ])dnl
3474
3475 AH_BOTTOM([
3476 /* Define AMPERSAND_FULL_NAME if you use the convention
3477    that & in the full name stands for the login id.  */
3478 /* Turned on June 1996 supposing nobody will mind it.  */
3479 #define AMPERSAND_FULL_NAME
3480
3481 /* If using GNU, then support inline function declarations.  */
3482 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3483    generally, because even if non-gcc compilers accept `inline', they
3484    may reject `extern inline'.  */
3485 #if defined (__GNUC__)
3486 #define INLINE __inline__
3487 #else
3488 #define INLINE
3489 #endif
3490
3491 /* `subprocesses' should be defined if you want to
3492    have code for asynchronous subprocesses
3493    (as used in M-x compile and M-x shell).
3494    Only MSDOS does not support this (it overrides
3495    this in its config_opsysfile below).  */
3496
3497 #define subprocesses
3498
3499 /* Include the os and machine dependent files.  */
3500 #include config_opsysfile
3501 #ifdef config_machfile
3502 # include config_machfile
3503 #endif
3504
3505 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3506    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3507   (There is probably a better place to do this, but right now the
3508    Cocoa side does this in s/darwin.h and we cannot parallel this
3509    exactly since GNUstep is multi-OS.  */
3510 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3511 #  define SYSTEM_PURESIZE_EXTRA 30000
3512 #endif
3513
3514 /* SIGTYPE is the macro we actually use.  */
3515 #ifndef SIGTYPE
3516 #define SIGTYPE RETSIGTYPE
3517 #endif
3518
3519 #ifdef emacs /* Don't do this for lib-src.  */
3520 /* Tell regex.c to use a type compatible with Emacs.  */
3521 #define RE_TRANSLATE_TYPE Lisp_Object
3522 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3523 #ifdef make_number
3524 /* If make_number is a macro, use it.  */
3525 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3526 #else
3527 /* If make_number is a function, avoid it.  */
3528 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3529 #endif
3530 #endif
3531
3532 #define my_strftime nstrftime   /* for strftime.c */
3533
3534 /* These default definitions are good for almost all machines.
3535    The exceptions override them in m/MACHINE.h.  */
3536
3537 #ifndef BITS_PER_CHAR
3538 #define BITS_PER_CHAR 8
3539 #endif
3540
3541 #ifndef BITS_PER_SHORT
3542 #define BITS_PER_SHORT 16
3543 #endif
3544
3545 /* Note that lisp.h uses this in a preprocessor conditional, so it
3546    would not work to use sizeof.  That being so, we do all of them
3547    without sizeof, for uniformity's sake.  */
3548 #ifndef BITS_PER_INT
3549 #define BITS_PER_INT 32
3550 #endif
3551
3552 #ifndef BITS_PER_LONG
3553 #ifdef _LP64
3554 #define BITS_PER_LONG 64
3555 #else
3556 #define BITS_PER_LONG 32
3557 #endif
3558 #endif
3559
3560 /* Define if the compiler supports function prototypes.  It may do so but
3561    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3562 #undef PROTOTYPES
3563
3564 #include <string.h>
3565 #include <stdlib.h>
3566
3567 #ifdef HAVE_ALLOCA_H
3568 # include <alloca.h>
3569 #elif defined __GNUC__
3570 # define alloca __builtin_alloca
3571 #elif defined _AIX
3572 # define alloca __alloca
3573 #else
3574 # include <stddef.h>
3575 # ifdef  __cplusplus
3576 extern "C"
3577 # endif
3578 void *alloca (size_t);
3579 #endif
3580
3581 #ifndef HAVE_SIZE_T
3582 typedef unsigned size_t;
3583 #endif
3584
3585 #ifndef HAVE_STRCHR
3586 #define strchr(a, b) index (a, b)
3587 #endif
3588
3589 #ifndef HAVE_STRRCHR
3590 #define strrchr(a, b) rindex (a, b)
3591 #endif
3592
3593 #if defined __GNUC__ && (__GNUC__ > 2 \
3594                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3595 #define NO_RETURN       __attribute__ ((__noreturn__))
3596 #else
3597 #define NO_RETURN       /* nothing */
3598 #endif
3599
3600 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3601 #define NO_INLINE __attribute__((noinline))
3602 #else
3603 #define NO_INLINE
3604 #endif
3605
3606 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3607 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3608 #else
3609 #define EXTERNALLY_VISIBLE
3610 #endif
3611
3612 /* Some versions of GNU/Linux define noinline in their headers.  */
3613 #ifdef noinline
3614 #undef noinline
3615 #endif
3616
3617 /* These won't be used automatically yet.  We also need to know, at least,
3618    that the stack is continuous.  */
3619 #ifdef __GNUC__
3620 #  ifndef GC_SETJMP_WORKS
3621   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3622 #    define GC_SETJMP_WORKS 1
3623 #  endif
3624 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3625 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3626 #  endif
3627 #endif
3628
3629 #endif /* EMACS_CONFIG_H */
3630
3631 /*
3632 Local Variables:
3633 mode: c
3634 End:
3635 */
3636 ])dnl
3637
3638 #### Report on what we decided to do.
3639 #### Report GTK as a toolkit, even if it doesn't use Xt.
3640 #### It makes printing result more understandable as using GTK sets
3641 #### toolkit_scroll_bars to yes by default.
3642 if test "${HAVE_GTK}" = "yes"; then
3643   USE_X_TOOLKIT=GTK
3644 fi
3645
3646 and_machfile=
3647 if test -n "$machfile"; then
3648   and_machfile=" and \`${machfile}'"
3649 fi
3650
3651 echo "
3652 Configured for \`${canonical}'.
3653
3654   Where should the build process find the source code?    ${srcdir}
3655   What operating system and machine description files should Emacs use?
3656         \`${opsysfile}'${and_machfile}
3657   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3658   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3659   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3660   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3661   What window system should Emacs use?                    ${window_system}
3662   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3663
3664 if test -n "${x_includes}"; then
3665 echo "  Where do we find X Windows header files?                ${x_includes}"
3666 else
3667 echo "  Where do we find X Windows header files?                Standard dirs"
3668 fi
3669 if test -n "${x_libraries}"; then
3670 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3671 else
3672 echo "  Where do we find X Windows libraries?                   Standard dirs"
3673 fi
3674
3675 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3676 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3677 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3678 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3679 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3680 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3681 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3682 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3683
3684 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3685 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3686 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3687 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3688 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3689 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3690
3691 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3692 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3693 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3694 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3695
3696 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3697 echo
3698
3699 if test $USE_XASSERTS = yes; then
3700    echo "  Compiling with asserts turned on."
3701    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3702 fi
3703
3704 echo
3705
3706 if test "$HAVE_NS" = "yes"; then
3707    echo
3708    echo "You must run \"make install\" in order to test the built application.
3709 The installed application will go to nextstep/Emacs.app and can be
3710 run or moved from there."
3711    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3712       echo "The application will be fully self-contained."
3713     else
3714       echo "The lisp resources for the application will be installed under ${prefix}.
3715 You may need to run \"make install\" with sudo.  The application will fail
3716 to run if these resources are not installed."
3717    fi
3718    echo
3719 fi
3720
3721
3722 # Remove any trailing slashes in these variables.
3723 [test "${prefix}" != NONE &&
3724   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3725 test "${exec_prefix}" != NONE &&
3726   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3727
3728 dnl You might wonder (I did) why epaths.h is generated by running make,
3729 dnl rather than just letting configure generate it from epaths.in.
3730 dnl One reason is that the various paths are not fully expanded (see above);
3731 dnl eg gamedir=${prefix}/var/games/emacs.
3732 dnl Secondly, the GNU Coding standards require that one should be able
3733 dnl to run `make prefix=/some/where/else' and override the values set
3734 dnl by configure.  This also explains the `move-if-change' test and
3735 dnl the use of force in the `epaths-force' rule in Makefile.in.
3736 AC_OUTPUT(Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3737         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3738         doc/lispref/Makefile src/Makefile \
3739         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile, [
3740
3741 ### Make the necessary directories, if they don't exist.
3742 for dir in etc lisp ; do
3743   test -d ${dir} || mkdir ${dir}
3744 done
3745
3746 echo creating src/epaths.h
3747 ${MAKE-make} epaths-force
3748
3749 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3750   echo creating src/.gdbinit
3751   echo source $srcdir/src/.gdbinit > src/.gdbinit
3752 fi
3753
3754 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])