lisp/filecache.el

   1 ;;; filecache.el --- find files using a pre-loaded cache
   2
   3 ;; Copyright (C) 1996, 2000-2012  Free Software Foundation, Inc.
   4
   5 ;; Author:  Peter Breton <pbreton@cs.umb.edu>
   6 ;; Created: Sun Nov 10 1996
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;;
  26 ;; The file-cache package is an attempt to make it easy to locate files
  27 ;; by name, without having to remember exactly where they are located.
  28 ;; This is very handy when working with source trees. You can also add
  29 ;; frequently used files to the cache to create a hotlist effect.
  30 ;; The cache can be used with any interactive command which takes a
  31 ;; filename as an argument.
  32 ;;
  33 ;; It is worth noting that this package works best when most of the files
  34 ;; in the cache have unique names, or (if they have the same name) exist in
  35 ;; only a few directories. The worst case is many files all with
  36 ;; the same name and in different directories, for example a big source tree
  37 ;; with a Makefile in each directory. In such a case, you should probably
  38 ;; use an alternate strategy to find the files.
  39 ;;
  40 ;; ADDING FILES TO THE CACHE:
  41 ;;
  42 ;; Use the following functions to add items to the file cache:
  43 ;;
  44 ;;   * `file-cache-add-file': Adds a single file to the cache
  45 ;;
  46 ;;   * `file-cache-add-file-list': Adds a list of files to the cache
  47 ;;
  48 ;; The following functions use the regular expressions in
  49 ;; `file-cache-delete-regexps' to eliminate unwanted files:
  50 ;;
  51 ;;   * `file-cache-add-directory': Adds the files in a directory to the
  52 ;;     cache. You can also specify a regular expression to match the files
  53 ;;     which should be added.
  54 ;;
  55 ;;   * `file-cache-add-directory-list': Same as above, but acts on a list
  56 ;;     of directories. You can use `load-path', `exec-path' and the like.
  57 ;;
  58 ;;   * `file-cache-add-directory-using-find': Uses the `find' command to
  59 ;;     add a directory tree to the cache.
  60 ;;
  61 ;;   * `file-cache-add-directory-using-locate': Uses the `locate' command to
  62 ;;     add files matching a pattern to the cache.
  63 ;;
  64 ;;   * `file-cache-add-directory-recursively': Uses the find-lisp package to
  65 ;;     add all files matching a pattern to the cache.
  66 ;;
  67 ;; Use the function `file-cache-clear-cache' to remove all items from the
  68 ;; cache. There are a number of `file-cache-delete' functions provided
  69 ;; as well, but in general it is probably better to not worry too much
  70 ;; about extra files in the cache.
  71 ;;
  72 ;; The most convenient way to initialize the cache is with an
  73 ;; `eval-after-load' function, as noted in the ADDING FILES
  74 ;; AUTOMATICALLY section.
  75 ;;
  76 ;; FINDING FILES USING THE CACHE:
  77 ;;
  78 ;; You can use the file-cache with any function that expects a filename as
  79 ;; an argument. For example:
  80 ;;
  81 ;; 1) Invoke a function which expects a filename as an argument:
  82 ;;    M-x find-file
  83 ;;
  84 ;; 2) Begin typing a file name.
  85 ;;
  86 ;; 3) Invoke `file-cache-minibuffer-complete' (bound by default to
  87 ;; C-TAB) to complete on the filename using the cache.
  88 ;;
  89 ;; 4) When you have found a unique completion, the minibuffer contents
  90 ;; will change to the full name of that file.
  91 ;;
  92 ;; If there are a number of directories which contain the completion,
  93 ;; invoking `file-cache-minibuffer-complete' repeatedly will cycle through
  94 ;; them.
  95 ;;
  96 ;; 5) You can then edit the minibuffer contents, or press RETURN.
  97 ;;
  98 ;; It is much easier to simply try it than trying to explain it :)
  99 ;;
 100 ;;; ADDING FILES AUTOMATICALLY
 101 ;;
 102 ;; For maximum utility, you should probably define an `eval-after-load'
 103 ;; form which loads your favorite files:
 104 ;;
 105 ;;      (eval-after-load
 106 ;;       "filecache"
 107 ;;       '(progn
 108 ;;          (message "Loading file cache...")
 109 ;;          (file-cache-add-directory-using-find "~/projects")
 110 ;;          (file-cache-add-directory-list load-path)
 111 ;;          (file-cache-add-directory "~/")
 112 ;;          (file-cache-add-file-list (list "~/foo/bar" "~/baz/bar"))
 113 ;;         ))
 114 ;;
 115 ;; If you clear and reload the cache frequently, it is probably easiest
 116 ;; to put your initializations in a function:
 117 ;;
 118 ;;   (eval-after-load
 119 ;;     "filecache"
 120 ;;      '(my-file-cache-initialize))
 121 ;;
 122 ;;   (defun my-file-cache-initialize ()
 123 ;;      (interactive)
 124 ;;      (message "Loading file cache...")
 125 ;;      (file-cache-add-directory-using-find "~/projects")
 126 ;;      (file-cache-add-directory-list load-path)
 127 ;;      (file-cache-add-directory "~/")
 128 ;;      (file-cache-add-file-list (list "~/foo/bar" "~/baz/bar"))
 129 ;;   ))
 130 ;;
 131 ;; Of course, you can still add files to the cache afterwards, via
 132 ;; Lisp functions.
 133 ;;
 134 ;; RELATED WORK:
 135 ;;
 136 ;; This package is a distant relative of Noah Friedman's fff utilities.
 137 ;; Our goal is pretty similar, but the implementation strategies are
 138 ;; different.
 139
 140 ;;; Code:
 141
 142 (defgroup file-cache nil
 143   "Find files using a pre-loaded cache."
 144   :group 'files
 145   :group 'convenience
 146   :prefix "file-cache-")
 147
 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 149 ;; Customization Variables
 150 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 151
 152 ;; User-modifiable variables
 153 (defcustom file-cache-filter-regexps
 154   ;; These are also used in buffers containing lines of file names,
 155   ;; so the end-of-name is matched with $ rather than \\'.
 156   (list "~$" "\\.o$" "\\.exe$" "\\.a$" "\\.elc$" ",v$" "\\.output$"
 157         "\\.$" "#$" "\\.class$")
 158   "List of regular expressions used as filters by the file cache.
 159 File names which match these expressions will not be added to the cache.
 160 Note that the functions `file-cache-add-file' and `file-cache-add-file-list'
 161 do not use this variable."
 162   :type '(repeat regexp)
 163   :group 'file-cache)
 164
 165 (defcustom file-cache-find-command "find"
 166   "External program used by `file-cache-add-directory-using-find'."
 167   :type 'string
 168   :group 'file-cache)
 169
 170 (defcustom file-cache-find-command-posix-flag 'not-defined
 171   "Set to t, if `file-cache-find-command' handles wildcards POSIX style.
 172 This variable is automatically set to nil or non-nil
 173 if it has the initial value `not-defined' whenever you first
 174 call the `file-cache-add-directory-using-find'.
 175
 176 Under Windows operating system where Cygwin is available, this value
 177 should be t."
 178   :type  '(choice (const :tag "Yes" t)
 179                   (const :tag "No" nil)
 180                   (const :tag "Unknown" not-defined))
 181   :group 'file-cache)
 182
 183 (defcustom file-cache-locate-command "locate"
 184   "External program used by `file-cache-add-directory-using-locate'."
 185   :type 'string
 186   :group 'file-cache)
 187
 188 ;; Minibuffer messages
 189 (defcustom file-cache-no-match-message " [File Cache: No match]"
 190   "Message to display when there is no completion."
 191   :type 'string
 192   :group 'file-cache)
 193
 194 (defcustom file-cache-sole-match-message " [File Cache: sole completion]"
 195   "Message to display when there is only one completion."
 196   :type 'string
 197   :group 'file-cache)
 198
 199 (defcustom file-cache-non-unique-message
 200   " [File Cache: complete but not unique]"
 201   "Message to display when there is a non-unique completion."
 202   :type 'string
 203   :group 'file-cache)
 204
 205 (defcustom file-cache-completion-ignore-case
 206   (if (memq system-type '(ms-dos windows-nt cygwin))
 207       t
 208      completion-ignore-case)
 209   "If non-nil, file-cache completion should ignore case.
 210 Defaults to the value of `completion-ignore-case'."
 211   :type 'boolean
 212   :group 'file-cache)
 213
 214 (defcustom file-cache-case-fold-search
 215   (if (memq system-type '(ms-dos windows-nt cygwin))
 216       t
 217     case-fold-search)
 218   "If non-nil, file-cache completion should ignore case.
 219 Defaults to the value of `case-fold-search'."
 220   :type 'boolean
 221   :group 'file-cache)
 222
 223 (defcustom file-cache-ignore-case
 224   (memq system-type '(ms-dos windows-nt cygwin))
 225   "Non-nil means ignore case when checking completions in the file cache.
 226 Defaults to nil on DOS and Windows, and t on other systems."
 227   :type 'boolean
 228   :group 'file-cache)
 229
 230 (defvar file-cache-multiple-directory-message nil)
 231
 232 ;; Internal variables
 233 ;; This should be named *Completions* because that's what the function
 234 ;; switch-to-completions in simple.el expects
 235 (defcustom file-cache-completions-buffer "*Completions*"
 236   "Buffer to display completions when using the file cache."
 237   :type 'string
 238   :group 'file-cache)
 239
 240 (defcustom file-cache-buffer "*File Cache*"
 241   "Buffer to hold the cache of file names."
 242   :type 'string
 243   :group 'file-cache)
 244
 245 (defcustom file-cache-buffer-default-regexp "^.+$"
 246   "Regexp to match files in `file-cache-buffer'."
 247   :type 'regexp
 248   :group 'file-cache)
 249
 250 (defvar file-cache-last-completion nil)
 251
 252 (defvar file-cache-alist nil
 253   "Internal data structure to hold cache of file names.
 254 It is a list of entries of the form (FILENAME DIRNAME1 DIRNAME2 ...)
 255 where FILENAME is a file name component and the entry represents N
 256 files of names DIRNAME1/FILENAME, DIRNAME2/FILENAME, ...")
 257
 258 (defvar file-cache-completions-keymap
 259   (let ((map (make-sparse-keymap)))
 260     (set-keymap-parent map completion-list-mode-map)
 261     (define-key map [mouse-2] 'file-cache-choose-completion)
 262     (define-key map "\C-m" 'file-cache-choose-completion)
 263     map)
 264   "Keymap for file cache completions buffer.")
 265
 266 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 267 ;; Functions to add files to the cache
 268 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 269
 270 ;;;###autoload
 271 (defun file-cache-add-directory (directory &optional regexp)
 272   "Add DIRECTORY to the file cache.
 273 If the optional REGEXP argument is non-nil, only files which match it will
 274 be added to the cache."
 275   (interactive "DAdd files from directory: ")
 276   ;; Not an error, because otherwise we can't use load-paths that
 277   ;; contain non-existent directories.
 278   (if (not (file-accessible-directory-p directory))
 279       (message "Directory %s does not exist" directory)
 280     (let* ((dir       (expand-file-name directory))
 281            (dir-files (directory-files dir t regexp)))
 282       ;; Filter out files we don't want to see
 283       (dolist (file dir-files)
 284         (if (file-directory-p file)
 285             (setq dir-files (delq file dir-files))
 286           (dolist (regexp file-cache-filter-regexps)
 287             (if (string-match regexp file)
 288                 (setq dir-files (delq file dir-files))))))
 289       (file-cache-add-file-list dir-files))))
 290
 291 ;;;###autoload
 292 (defun file-cache-add-directory-list (directory-list &optional regexp)
 293   "Add DIRECTORY-LIST (a list of directory names) to the file cache.
 294 If the optional REGEXP argument is non-nil, only files which match it
 295 will be added to the cache.  Note that the REGEXP is applied to the
 296 files in each directory, not to the directory list itself."
 297   (interactive "XAdd files from directory list: ")
 298   (mapcar
 299    (lambda (dir) (file-cache-add-directory dir regexp))
 300    directory-list))
 301
 302 (defun file-cache-add-file-list  (file-list)
 303   "Add FILE-LIST (a list of files names) to the file cache."
 304   (interactive "XFile List: ")
 305   (mapcar 'file-cache-add-file file-list))
 306
 307 ;; Workhorse function
 308
 309 ;;;###autoload
 310 (defun file-cache-add-file (file)
 311   "Add FILE to the file cache."
 312   (interactive "fAdd File: ")
 313   (if (not (file-exists-p file))
 314       (message "Filecache: file %s does not exist" file)
 315     (let* ((file-name (file-name-nondirectory file))
 316            (dir-name  (file-name-directory    file))
 317            (the-entry (assoc-string
 318                        file-name file-cache-alist
 319                        file-cache-ignore-case)))
 320       ;; Does the entry exist already?
 321       (if the-entry
 322           (if (or (and (stringp (cdr the-entry))
 323                        (string= dir-name (cdr the-entry)))
 324                   (and (listp (cdr the-entry))
 325                        (member dir-name (cdr the-entry))))
 326               nil
 327             (setcdr the-entry (cons dir-name (cdr the-entry))))
 328         ;; If not, add it to the cache
 329         (push (list file-name dir-name) file-cache-alist)))))
 330
 331 ;;;###autoload
 332 (defun file-cache-add-directory-using-find (directory)
 333   "Use the `find' command to add files to the file cache.
 334 Find is run in DIRECTORY."
 335   (interactive "DAdd files under directory: ")
 336   (let ((dir (expand-file-name directory)))
 337     (when (memq system-type '(windows-nt cygwin))
 338       (if (eq file-cache-find-command-posix-flag 'not-defined)
 339           (setq file-cache-find-command-posix-flag
 340                 (executable-command-find-posix-p file-cache-find-command))))
 341     (set-buffer (get-buffer-create file-cache-buffer))
 342     (erase-buffer)
 343     (call-process file-cache-find-command nil
 344                   (get-buffer file-cache-buffer) nil
 345                   dir "-name"
 346                   (if (memq system-type '(windows-nt cygwin))
 347                       (if file-cache-find-command-posix-flag
 348                           "\\*"
 349                         "'*'")
 350                     "*")
 351                   "-print")
 352     (file-cache-add-from-file-cache-buffer)))
 353
 354 ;;;###autoload
 355 (defun file-cache-add-directory-using-locate (string)
 356   "Use the `locate' command to add files to the file cache.
 357 STRING is passed as an argument to the locate command."
 358   (interactive "sAdd files using locate string: ")
 359   (set-buffer (get-buffer-create file-cache-buffer))
 360   (erase-buffer)
 361   (call-process file-cache-locate-command nil
 362                 (get-buffer file-cache-buffer) nil
 363                 string)
 364   (file-cache-add-from-file-cache-buffer))
 365
 366 (autoload 'find-lisp-find-files "find-lisp")
 367
 368 ;;;###autoload
 369 (defun file-cache-add-directory-recursively  (dir &optional regexp)
 370   "Adds DIR and any subdirectories to the file-cache.
 371 This function does not use any external programs.
 372 If the optional REGEXP argument is non-nil, only files which match it
 373 will be added to the cache.  Note that the REGEXP is applied to the
 374 files in each directory, not to the directory list itself."
 375   (interactive "DAdd directory: ")
 376   (mapcar
 377    (lambda (file)
 378      (or (file-directory-p file)
 379          (let (filtered)
 380            (dolist (regexp file-cache-filter-regexps)
 381              (and (string-match regexp file)
 382                   (setq filtered t)))
 383            filtered)
 384          (file-cache-add-file file)))
 385    (find-lisp-find-files dir (or regexp "^"))))
 386
 387 (defun file-cache-add-from-file-cache-buffer (&optional regexp)
 388   "Add any entries found in the file cache buffer.
 389 Each entry matches the regular expression `file-cache-buffer-default-regexp'
 390 or the optional REGEXP argument."
 391   (set-buffer file-cache-buffer)
 392   (dolist (elt file-cache-filter-regexps)
 393     (goto-char (point-min))
 394     (delete-matching-lines elt))
 395   (goto-char (point-min))
 396   (let ((full-filename))
 397     (while (re-search-forward
 398             (or regexp file-cache-buffer-default-regexp)
 399             (point-max) t)
 400       (setq full-filename (buffer-substring-no-properties
 401                       (match-beginning 0) (match-end 0)))
 402       (file-cache-add-file full-filename))))
 403
 404 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 405 ;; Functions to delete from the cache
 406 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 407
 408 (defun file-cache-clear-cache ()
 409   "Clear the file cache."
 410   (interactive)
 411   (setq file-cache-alist nil))
 412
 413 ;; This clears *all* files with the given name
 414 (defun file-cache-delete-file (file)
 415   "Delete FILE from the file cache."
 416   (interactive
 417    (list (completing-read "Delete file from cache: " file-cache-alist)))
 418   (setq file-cache-alist
 419         (delq (assoc-string file file-cache-alist file-cache-ignore-case)
 420               file-cache-alist)))
 421
 422 (defun file-cache-delete-file-list (file-list)
 423   "Delete FILE-LIST (a list of files) from the file cache."
 424   (interactive "XFile List: ")
 425   (mapcar 'file-cache-delete-file file-list))
 426
 427 (defun file-cache-delete-file-regexp (regexp)
 428   "Delete files matching REGEXP from the file cache."
 429   (interactive "sRegexp: ")
 430   (let ((delete-list))
 431     (dolist (elt file-cache-alist)
 432       (and (string-match regexp (car elt))
 433            (push (car elt) delete-list)))
 434     (file-cache-delete-file-list delete-list)
 435     (message "Filecache: deleted %d files from file cache"
 436              (length delete-list))))
 437
 438 (defun file-cache-delete-directory (directory)
 439   "Delete DIRECTORY from the file cache."
 440   (interactive "DDelete directory from file cache: ")
 441   (let ((dir (expand-file-name directory))
 442         (result 0))
 443     (dolist (entry file-cache-alist)
 444       (if (file-cache-do-delete-directory dir entry)
 445           (setq result (1+ result))))
 446     (if (zerop result)
 447         (error "Filecache: no entries containing %s found in cache" directory)
 448       (message "Filecache: deleted %d entries" result))))
 449
 450 (defun file-cache-do-delete-directory (dir entry)
 451   (let ((directory-list (cdr entry))
 452         (directory (file-cache-canonical-directory dir)))
 453     (and (member directory directory-list)
 454          (if (equal 1 (length directory-list))
 455              (setq file-cache-alist
 456                    (delq entry file-cache-alist))
 457            (setcdr entry (delete directory directory-list))))))
 458
 459 (defun file-cache-delete-directory-list (directory-list)
 460   "Delete DIRECTORY-LIST (a list of directories) from the file cache."
 461   (interactive "XDirectory List: ")
 462   (mapcar 'file-cache-delete-directory directory-list))
 463
 464 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 465 ;; Utility functions
 466 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 467
 468 ;; Returns the name of a directory for a file in the cache
 469 (defun file-cache-directory-name  (file)
 470   (let* ((directory-list (cdr (assoc-string
 471                                file file-cache-alist
 472                                file-cache-ignore-case)))
 473          (len            (length directory-list))
 474          (directory)
 475          (num))
 476     (if (not (listp directory-list))
 477         (error "Filecache: unknown type in file-cache-alist for key %s" file))
 478     (cond
 479      ;; Single element
 480      ((eq 1 len)
 481       (setq directory (elt directory-list 0)))
 482      ;; No elements
 483      ((eq 0 len)
 484       (error "Filecache: no directory found for key %s" file))
 485      ;; Multiple elements
 486      (t
 487       (let* ((minibuffer-dir (file-name-directory (minibuffer-contents)))
 488              (dir-list       (member minibuffer-dir directory-list)))
 489         (setq directory
 490               ;; If the directory is in the list, return the next element
 491               ;; Otherwise, return the first element
 492               (if dir-list
 493                   (or (elt directory-list
 494                            (setq num (1+ (- len (length dir-list)))))
 495                       (elt directory-list (setq num 0)))
 496                 (elt directory-list (setq num 0)))))))
 497     ;; If there were multiple directories, set up a minibuffer message
 498     (setq file-cache-multiple-directory-message
 499           (and num (format " [%d of %d]" (1+ num) len)))
 500     directory))
 501
 502 ;; Returns the name of a file in the cache
 503 (defun file-cache-file-name  (file)
 504   (let ((directory (file-cache-directory-name file)))
 505     (concat directory file)))
 506
 507 ;; Return a canonical directory for comparison purposes.
 508 ;; Such a directory ends with a forward slash.
 509 (defun file-cache-canonical-directory (dir)
 510   (let ((directory dir))
 511     (if (not (char-equal ?/ (string-to-char (substring directory -1))))
 512         (concat directory "/")
 513       directory)))
 514
 515 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 516 ;; Minibuffer functions
 517 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 518
 519 ;; The prefix argument works around a bug in the minibuffer completion.
 520 ;; The completion function doesn't distinguish between the states:
 521 ;;
 522 ;;   "Multiple completions of name" (eg, Makefile, Makefile.in)
 523 ;;   "Name available in multiple directories" (/tmp/Makefile, ~me/Makefile)
 524 ;;
 525 ;; The default is to do the former; a prefix arg forces the latter.
 526
 527 ;;;###autoload
 528 (defun file-cache-minibuffer-complete (arg)
 529   "Complete a filename in the minibuffer using a preloaded cache.
 530 Filecache does two kinds of substitution: it completes on names in
 531 the cache, and, once it has found a unique name, it cycles through
 532 the directories that the name is available in.  With a prefix argument,
 533 the name is considered already unique; only the second substitution
 534 \(directories) is done."
 535   (interactive "P")
 536   (let*
 537       (
 538        (completion-ignore-case file-cache-completion-ignore-case)
 539        (case-fold-search       file-cache-case-fold-search)
 540        (string                 (file-name-nondirectory (minibuffer-contents)))
 541        (completion-string      (try-completion string file-cache-alist))
 542        (completion-list)
 543        (len)
 544        (file-cache-string))
 545     (cond
 546      ;; If it's the only match, replace the original contents
 547      ((or arg (eq completion-string t))
 548       (setq file-cache-string (file-cache-file-name string))
 549       (if (string= file-cache-string (minibuffer-contents))
 550           (minibuffer-message file-cache-sole-match-message)
 551         (delete-minibuffer-contents)
 552         (insert file-cache-string)
 553         (if file-cache-multiple-directory-message
 554             (minibuffer-message file-cache-multiple-directory-message))))
 555
 556      ;; If it's the longest match, insert it
 557      ((stringp completion-string)
 558       ;; If we've already inserted a unique string, see if the user
 559       ;; wants to use that one
 560       (if (and (string= string completion-string)
 561                (assoc-string string file-cache-alist
 562                              file-cache-ignore-case))
 563           (if (and (eq last-command this-command)
 564                    (string= file-cache-last-completion completion-string))
 565               (progn
 566                 (delete-minibuffer-contents)
 567                 (insert (file-cache-file-name completion-string))
 568                 (setq file-cache-last-completion nil))
 569             (minibuffer-message file-cache-non-unique-message)
 570             (setq file-cache-last-completion string))
 571         (setq file-cache-last-completion string)
 572         (setq completion-list (all-completions string file-cache-alist)
 573               len             (length completion-list))
 574         (if (> len 1)
 575             (progn
 576               (goto-char (point-max))
 577               (insert
 578                (substring completion-string (length string)))
 579               ;; Add our own setup function to the Completions Buffer
 580               (let ((completion-setup-hook
 581                      (append completion-setup-hook
 582                              (list 'file-cache-completion-setup-function))))
 583                 (with-output-to-temp-buffer file-cache-completions-buffer
 584                   (display-completion-list completion-list string))))
 585           (setq file-cache-string (file-cache-file-name completion-string))
 586           (if (string= file-cache-string (minibuffer-contents))
 587               (minibuffer-message file-cache-sole-match-message)
 588             (delete-minibuffer-contents)
 589             (insert file-cache-string)
 590             (if file-cache-multiple-directory-message
 591                 (minibuffer-message file-cache-multiple-directory-message)))
 592           )))
 593
 594      ;; No match
 595      ((eq completion-string nil)
 596       (minibuffer-message file-cache-no-match-message)))))
 597
 598 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 599 ;; Completion functions
 600 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 601
 602 (defun file-cache-completion-setup-function  ()
 603   (with-current-buffer standard-output ;; i.e. file-cache-completions-buffer
 604     (use-local-map file-cache-completions-keymap)))
 605
 606 (defun file-cache-choose-completion (&optional event)
 607   "Choose a completion in the `*Completions*' buffer."
 608   (interactive (list last-nonmenu-event))
 609   (let ((completion-no-auto-exit t))
 610     (choose-completion event)
 611     (select-window (active-minibuffer-window))
 612     (file-cache-minibuffer-complete nil)))
 613
 614 (define-obsolete-function-alias 'file-cache-mouse-choose-completion
 615   'file-cache-choose-completion "23.2")
 616
 617 (defun file-cache-complete  ()
 618   "Complete the word at point, using the filecache."
 619   (interactive)
 620   (let ((start
 621     (save-excursion
 622       (skip-syntax-backward "^\"")
 623            (point))))
 624     (completion-in-region start (point) file-cache-alist)))
 625
 626 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 627 ;; Show parts of the cache
 628 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 629
 630 (defun file-cache-files-matching-internal (regexp)
 631   "Output a list of files whose names (not including directories)
 632 match REGEXP."
 633   (let ((results))
 634     (dolist (cache-element file-cache-alist)
 635       (and (string-match regexp (elt cache-element 0))
 636            (push (elt cache-element 0) results)))
 637     (nreverse results)))
 638
 639 (defun file-cache-files-matching (regexp)
 640   "Output a list of files whose names (not including directories)
 641 match REGEXP."
 642   (interactive "sFind files matching regexp: ")
 643   (let ((results
 644          (file-cache-files-matching-internal regexp))
 645         buf)
 646     (set-buffer
 647      (setq buf (get-buffer-create
 648                 "*File Cache Files Matching*")))
 649     (erase-buffer)
 650     (insert
 651      (mapconcat
 652       'identity
 653       results
 654       "\n"))
 655     (goto-char (point-min))
 656     (display-buffer buf)))
 657
 658 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 659 ;; Debugging functions
 660 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 661
 662 (defun file-cache-debug-read-from-minibuffer (file)
 663   "Debugging function."
 664   (interactive
 665    (list (completing-read "File Cache: " file-cache-alist)))
 666   (message "%s" (assoc-string file file-cache-alist
 667                               file-cache-ignore-case)))
 668
 669 (defun file-cache-display  ()
 670   "Display the file cache."
 671   (interactive)
 672   (let ((buf "*File Cache Contents*"))
 673     (with-current-buffer
 674         (get-buffer-create buf)
 675       (erase-buffer)
 676       (dolist (item file-cache-alist)
 677         (insert (nth 1 item) (nth 0 item) "\n"))
 678       (pop-to-buffer buf))))
 679
 680 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 681 ;; Keybindings
 682 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 683
 684 (provide 'filecache)
 685
 686 ;;; filecache.el ends here