configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000 Free Software Foundation, Inc.
   7 dnl
   8 dnl  This file is part of GNU Emacs.
   9 dnl
  10 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  11 dnl  it under the terms of the GNU General Public License as published by
  12 dnl  the Free Software Foundation; either version 2, or (at your option)
  13 dnl  any later version.
  14 dnl
  15 dnl  GNU Emacs is distributed in the hope that it will be useful,
  16 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 dnl  GNU General Public License for more details.
  19 dnl
  20 dnl  You should have received a copy of the GNU General Public License
  21 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  22 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 dnl  Boston, MA 02111-1307, USA.
  24
  25 AC_PREREQ(2.8)dnl
  26 AC_INIT(src/lisp.h)
  27 AC_CONFIG_HEADER(src/config.h:src/config.in)
  28
  29 lispdir='${datadir}/emacs/${version}/lisp'
  30 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  31 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
  32 lisppath='${locallisppath}:${lispdir}'
  33 etcdir='${datadir}/emacs/${version}/etc'
  34 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  35 docdir='${datadir}/emacs/${version}/etc'
  36
  37 AC_ARG_WITH(gcc,
  38 [  --without-gcc           don't use GCC to compile Emacs if GCC is found])
  39 AC_ARG_WITH(pop,
  40 [  --without-pop           don't support POP mail retrieval with movemail],
  41 [if test "$withval" = yes; then
  42    AC_DEFINE(MAIL_USE_POP)
  43 else :
  44 fi],
  45 AC_DEFINE(MAIL_USE_POP))
  46 AC_ARG_WITH(kerberos,
  47 [  --with-kerberos         support Kerberos-authenticated POP],
  48 [AC_DEFINE(KERBEROS)])
  49 AC_ARG_WITH(kerberos5,
  50 [  --with-kerberos5        support Kerberos version 5 authenticated POP],
  51 [if test "${with_kerberos5+set}" = set; then
  52   if test "${with_kerberos+set}" != set; then
  53     with_kerberos=yes
  54     AC_DEFINE(KERBEROS)
  55   fi
  56 fi
  57 AC_DEFINE(KERBEROS5)])
  58 AC_ARG_WITH(hesiod,
  59 [  --with-hesiod           support Hesiod to get the POP server host],
  60 [AC_DEFINE(HESIOD)])
  61 dnl This should be the last --with option, because --with-x is
  62 dnl added later on when we find the path of X, and it's best to
  63 dnl keep them together visually.
  64 AC_ARG_WITH(x-toolkit,
  65 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif/no)],
  66 [         case "${withval}" in
  67             y | ye | yes )      val=athena ;;
  68             n | no )            val=no  ;;
  69             l | lu | luc | luci | lucid )       val=lucid ;;
  70             a | at | ath | athe | athen | athena )      val=athena ;;
  71             m | mo | mot | moti | motif )       val=motif ;;
  72 dnl These don't currently work.
  73 dnl         o | op | ope | open | open- | open-l | open-lo \
  74 dnl             | open-loo | open-look )        val=open-look ;;
  75             * )
  76 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  77 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  78 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
  79 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
  80 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  81             ;;
  82           esac
  83           with_x_toolkit=$val
  84 ])
  85 AC_ARG_WITH(xpm,
  86 [  --with-xpm              use -lXpm for displaying XPM images])
  87 AC_ARG_WITH(jpeg,
  88 [  --with-jpeg             use -ljpeg for displaying JPEG images])
  89 AC_ARG_WITH(tiff,
  90 [  --with-tiff             use -ltiff for displaying TIFF images])
  91 AC_ARG_WITH(gif,
  92 [  --with-gif              use -lungif for displaying GIF images])
  93 AC_ARG_WITH(png,
  94 [  --with-png              use -lpng for displaying PNG images])
  95 AC_ARG_WITH(toolkit-scroll-bars,
  96 [  --without-toolkit-scroll-bars
  97                            don't use Motif or Xaw3d scroll bars])
  98 AC_ARG_WITH(xim,
  99 [  --without-xim           don't use X11 XIM])
 100
 101 #### Make srcdir absolute, if it isn't already.  It's important to
 102 #### avoid running the path through pwd unnecessary, since pwd can
 103 #### give you automounter prefixes, which can go away.  We do all this
 104 #### so Emacs can find its files when run uninstalled.
 105 case "${srcdir}" in
 106   /* ) ;;
 107   . )
 108     ## We may be able to use the $PWD environment variable to make this
 109     ## absolute.  But sometimes PWD is inaccurate.
 110     ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 111     unset CDPATH
 112     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
 113     then
 114       srcdir="$PWD"
 115     else
 116       srcdir="`(cd ${srcdir}; pwd)`"
 117     fi
 118   ;;
 119   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 120 esac
 121
 122 #### Check if the source directory already has a configured system in it.
 123 if test `pwd` != `(cd ${srcdir} && pwd)` \
 124    && test -f "${srcdir}/src/config.h" ; then
 125   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
 126    as a build directory right now; it has been configured in its own
 127    right.  To configure in another directory as well, you MUST
 128    use GNU make.  If you do not have GNU make, then you must
 129    now do \`make distclean' in ${srcdir},
 130    and then run $0 again.])
 131
 132 changequote(, )dnl
 133   extrasub='/^VPATH[     ]*=/c\
 134 changequote([, ])dnl
 135 vpath %.c $(srcdir)\
 136 vpath %.h $(srcdir)\
 137 vpath %.y $(srcdir)\
 138 vpath %.l $(srcdir)\
 139 vpath %.s $(srcdir)\
 140 vpath %.in $(srcdir)\
 141 vpath %.texi $(srcdir)'
 142 fi
 143
 144 #### Given the configuration name, set machfile and opsysfile to the
 145 #### names of the m/*.h and s/*.h files we should use.
 146
 147 ### Canonicalize the configuration name.
 148
 149 AC_CANONICAL_HOST
 150 canonical=$host
 151 configuration=$host_alias
 152
 153 changequote(, )dnl
 154
 155 ### If you add support for a new configuration, add code to this
 156 ### switch statement to recognize your configuration name and select
 157 ### the appropriate operating system and machine description files.
 158
 159 ### You would hope that you could choose an m/*.h file pretty much
 160 ### based on the machine portion of the configuration name, and an s-
 161 ### file based on the operating system portion.  However, it turns out
 162 ### that each m/*.h file is pretty manufacturer-specific - for
 163 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 164 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 165 ### machines.  So we basically have to have a special case for each
 166 ### configuration name.
 167 ###
 168 ### As far as handling version numbers on operating systems is
 169 ### concerned, make sure things will fail in a fixable way.  If
 170 ### /etc/MACHINES doesn't say anything about version numbers, be
 171 ### prepared to handle anything reasonably.  If version numbers
 172 ### matter, be sure /etc/MACHINES says something about it.
 173 ###
 174 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 175 ### "System V Release 4"; he writes, "The old convention encouraged
 176 ### confusion between `system' and `release' levels'."
 177
 178 machine='' opsys='' unported=no
 179 case "${canonical}" in
 180
 181   ## NetBSD ports
 182   *-*-netbsd* )
 183     opsys=netbsd
 184     case "${canonical}" in
 185       alpha*-*-netbsd*) machine=alpha ;;
 186       i[3456]86-*-netbsd*) machine=intel386 ;;
 187       m68k-*-netbsd*)
 188                         # This is somewhat bogus.
 189                         machine=hp9000s300 ;;
 190       powerpc-apple-netbsd*) machine=macppc ;;
 191       mips-*-netbsd*)   machine=pmax ;;
 192       mipsel-*-netbsd*) machine=pmax ;;
 193       ns32k-*-netbsd*)  machine=ns32000 ;;
 194       powerpc-*-netbsd*) machine=macppc ;;
 195       sparc-*-netbsd*)  machine=sparc ;;
 196       vax-*-netbsd*)    machine=vax ;;
 197       arm-*-netbsd*)    machine=arm ;;
 198     esac
 199   ;;
 200
 201   ## OpenBSD ports
 202   *-*-openbsd* )
 203     opsys=openbsd
 204     case "${canonical}" in
 205       alpha*-*-openbsd*)        machine=alpha ;;
 206       i386-*-openbsd*)  machine=intel386 ;;
 207       m68k-*-openbsd*)  machine=hp9000s300 ;;
 208       mipsel-*-openbsd*) machine=pmax ;;
 209       ns32k-*-openbsd*) machine=ns32000 ;;
 210       sparc-*-openbsd*) machine=sparc ;;
 211       vax-*-openbsd*)   machine=vax ;;
 212     esac
 213   ;;
 214
 215   ## Acorn RISCiX:
 216   arm-acorn-riscix1.1* )
 217     machine=acorn opsys=riscix1-1
 218   ;;
 219   arm-acorn-riscix1.2* | arm-acorn-riscix )
 220     ## This name is riscix12 instead of riscix1.2
 221     ## to avoid a file name conflict on MSDOS.
 222     machine=acorn opsys=riscix12
 223   ;;
 224
 225   ## BSDI ports
 226   *-*-bsdi* )
 227     opsys=bsdi
 228     case "${canonical}" in
 229       i[345]86-*-bsdi*) machine=intel386 ;;
 230       sparc-*-bsdi*)  machine=sparc ;;
 231       powerpc-*-bsdi*)  machine=powerpc ;;
 232     esac
 233     case "${canonical}" in
 234       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 235       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 236       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 237       *-*-bsdi3* )              opsys=bsdos3 ;;
 238       *-*-bsdi4* )              opsys=bsdos4 ;;
 239     esac
 240   ;;
 241
 242   ## Alliant machines
 243   ## Strictly speaking, we need the version of the alliant operating
 244   ## system to choose the right machine file, but currently the
 245   ## configuration name doesn't tell us enough to choose the right
 246   ## one; we need to give alliants their own operating system name to
 247   ## do this right.  When someone cares, they can help us.
 248   fx80-alliant-* )
 249     machine=alliant4 opsys=bsd4-2
 250   ;;
 251   i860-alliant-* )
 252     machine=alliant-2800 opsys=bsd4-3
 253   ;;
 254
 255   ## Alpha (DEC) machines.
 256   alpha*-dec-osf* )
 257     machine=alpha opsys=osf1
 258     # This is needed to find X11R6.1 libraries for certain tests.
 259     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 260     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 261     case "${canonical}" in
 262     # This is necessary on 5.0 to avoid mangling src/Makefile.
 263     # Separated out in case it causes problems on earlier versions.
 264     alpha*-dec-osf[5-9]*)
 265       opsys=osf5-0
 266       NON_GNU_CPP='cpp' ;;
 267     esac
 268   ;;
 269
 270   alpha*-*-linux-gnu* )
 271     machine=alpha opsys=gnu-linux
 272   ;;
 273
 274   arm*-*-linux-gnu* )
 275     machine=arm opsys=gnu-linux
 276   ;;
 277
 278   ppc-*-linux | \
 279   powerpc-*-linux* )
 280     machine=powerpc opsys=gnu-linux
 281   ;;
 282
 283   ## Altos 3068
 284   m68*-altos-sysv* )
 285     machine=altos opsys=usg5-2
 286   ;;
 287
 288   ## Amdahl UTS
 289   580-amdahl-sysv* )
 290     machine=amdahl opsys=usg5-2-2
 291   ;;
 292
 293   ## Apollo, Domain/OS
 294   m68*-apollo-* )
 295     machine=apollo opsys=bsd4-3
 296   ;;
 297
 298   ## AT&T 3b2, 3b5, 3b15, 3b20
 299   we32k-att-sysv* )
 300     machine=att3b opsys=usg5-2-2
 301   ;;
 302
 303   ## AT&T 3b1 - The Mighty Unix PC!
 304   m68*-att-sysv* )
 305     machine=7300 opsys=usg5-2-2
 306   ;;
 307
 308   ## Bull dpx20
 309   rs6000-bull-bosx* )
 310     machine=ibmrs6000 opsys=aix3-2
 311   ;;
 312
 313   ## Bull dpx2
 314   m68*-bull-sysv3* )
 315     machine=dpx2 opsys=usg5-3
 316   ;;
 317
 318   ## Bull sps7
 319   m68*-bull-sysv2* )
 320     machine=sps7 opsys=usg5-2
 321   ;;
 322
 323   ## CCI 5/32, 6/32 -- see "Tahoe".
 324
 325   ## Celerity
 326   ## I don't know what configuration name to use for this; config.sub
 327   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 328   ## in touch with us!
 329   celerity-celerity-bsd* )
 330     machine=celerity opsys=bsd4-2
 331   ;;
 332
 333   ## Clipper
 334   ## What operating systems does this chip run that Emacs has been
 335   ## tested on?
 336   clipper-* )
 337     machine=clipper
 338     ## We'll use the catch-all code at the bottom to guess the
 339     ## operating system.
 340   ;;
 341
 342   ## Convex
 343   *-convex-bsd* | *-convex-convexos* )
 344     machine=convex opsys=bsd4-3
 345     ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
 346     NON_GNU_CPP="cc -E -P"
 347   ;;
 348
 349   ## Cubix QBx/386
 350   i[3456]86-cubix-sysv* )
 351     machine=intel386 opsys=usg5-3
 352   ;;
 353
 354   ## Cydra 5
 355   cydra*-cydrome-sysv* )
 356     machine=cydra5 opsys=usg5-3
 357   ;;
 358
 359   ## Data General AViiON Machines
 360   ## DG changed naming conventions with the release of 5.4.4.10, they
 361   ## dropped the initial 5.4 but left the intervening R.  Because of the
 362   ## R this shouldn't conflict with older versions of the OS (which I
 363   ## think were named like dgux4.*). In addition, DG new AViiONs series
 364   ## uses either Motorola M88k or Intel Pentium CPUs.
 365   m88k-dg-dguxR4.* | m88k-dg-dgux4* )
 366     machine=aviion opsys=dgux4
 367   ;;
 368   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 369     ## This name is dgux5-4-3 instead of dgux5-4r3
 370     ## to avoid a file name conflict on MSDOS.
 371     machine=aviion opsys=dgux5-4-3
 372   ;;
 373   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 374     machine=aviion opsys=dgux5-4r2
 375   ;;
 376   m88k-dg-dgux* )
 377     machine=aviion opsys=dgux
 378   ;;
 379
 380   ## Data General AViiON Intel (x86) Machines
 381   ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
 382   ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
 383   i[345]86-dg-dguxR4* )
 384     machine=aviion-intel opsys=dgux4
 385   ;;
 386
 387   ## DECstations
 388   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 389     machine=pmax opsys=bsd4-2
 390   ;;
 391   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 392     machine=pmax opsys=bsd4-3
 393   ;;
 394   mips-dec-ultrix* )
 395     machine=pmax opsys=ultrix4-3
 396   ;;
 397   mips-dec-osf* )
 398     machine=pmax opsys=osf1
 399   ;;
 400   mips-dec-mach_bsd4.3* )
 401     machine=pmax opsys=mach-bsd4-3
 402   ;;
 403
 404   ## Motorola Delta machines
 405   m68k-motorola-sysv* | m68000-motorola-sysv* )
 406     machine=delta opsys=usg5-3
 407     if test -z "`type gnucc | grep 'not found'`"
 408     then
 409       if test -s /etc/167config
 410       then CC="gnucc -m68040"
 411       else CC="gnucc -m68881"
 412       fi
 413     else
 414       if test -z "`type gcc | grep 'not found'`"
 415       then CC=gcc
 416       else CC=cc
 417       fi
 418     fi
 419   ;;
 420   m88k-motorola-sysv4* )
 421     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 422     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 423     # I hope there are not other 4.0 versions for this machine
 424     # which really need usg5-4 instead.
 425     machine=delta88k opsys=usg5-4-2
 426   ;;
 427   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 428     machine=delta88k opsys=usg5-3
 429   ;;
 430
 431   ## Dual machines
 432   m68*-dual-sysv* )
 433     machine=dual opsys=usg5-2
 434   ;;
 435   m68*-dual-uniplus* )
 436     machine=dual opsys=unipl5-2
 437   ;;
 438
 439   ## Elxsi 6400
 440   elxsi-elxsi-sysv* )
 441     machine=elxsi opsys=usg5-2
 442   ;;
 443
 444   ## Encore machines
 445   ns16k-encore-bsd* )
 446     machine=ns16000 opsys=umax
 447   ;;
 448
 449   ## The GEC 63 - apparently, this port isn't really finished yet.
 450   #  I'm sure we finished off the last of the machines, though.  -- fx
 451
 452   ## Gould Power Node and NP1
 453   pn-gould-bsd4.2* )
 454     machine=gould opsys=bsd4-2
 455   ;;
 456   pn-gould-bsd4.3* )
 457     machine=gould opsys=bsd4-3
 458   ;;
 459   np1-gould-bsd* )
 460     machine=gould-np1 opsys=bsd4-3
 461   ;;
 462
 463   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 464   ## as far as Emacs is concerned).
 465   m88k-harris-cxux* )
 466     # Build needs to be different on 7.0 and later releases
 467     case "`uname -r`" in
 468        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 469        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 470     esac
 471     NON_GNU_CPP="/lib/cpp"
 472   ;;
 473   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 474   m68k-harris-cxux* )
 475     machine=nh3000 opsys=cxux
 476   ;;
 477   ## Harris power pc NightHawk running Power UNIX (Series 6000)
 478   powerpc-harris-powerunix )
 479     machine=nh6000 opsys=powerunix
 480     NON_GNU_CPP="cc -Xo -E -P"
 481   ;;
 482   ## SR2001/SR2201 running HI-UX/MPP
 483   hppa1.1-hitachi-hiuxmpp* )
 484     machine=sr2k opsys=hiuxmpp
 485   ;;
 486   ## Honeywell XPS100
 487   xps*-honeywell-sysv* )
 488     machine=xps100 opsys=usg5-2
 489   ;;
 490
 491   ## HP 9000 series 200 or 300
 492   m68*-hp-bsd* )
 493     machine=hp9000s300 opsys=bsd4-3
 494   ;;
 495   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 496   m68*-hp-hpux* )
 497     case "`uname -r`" in
 498       ## Someone's system reports A.B8.05 for this.
 499       ## I wonder what other possibilities there are.
 500       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 501       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 502       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 503       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 504       *) machine=hp9000s300 opsys=hpux ;;
 505     esac
 506   ;;
 507
 508   ## HP 9000 series 700 and 800, running HP/UX
 509   hppa*-hp-hpux7* )
 510     machine=hp800 opsys=hpux
 511   ;;
 512   hppa*-hp-hpux8* )
 513     machine=hp800 opsys=hpux8
 514   ;;
 515   hppa*-hp-hpux9shr* )
 516     machine=hp800 opsys=hpux9shr
 517   ;;
 518   hppa*-hp-hpux9* )
 519     machine=hp800 opsys=hpux9
 520   ;;
 521   hppa*-hp-hpux1[0-9]* )
 522     machine=hp800 opsys=hpux10
 523   ;;
 524
 525   ## HP 9000 series 700 and 800, running HP/UX
 526   hppa*-hp-hpux* )
 527     ## Cross-compilation?  Nah!
 528     case "`uname -r`" in
 529       ## Someone's system reports A.B8.05 for this.
 530       ## I wonder what other possibilities there are.
 531       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 532       *.08.* ) machine=hp800 opsys=hpux8 ;;
 533       *.09.* ) machine=hp800 opsys=hpux9 ;;
 534       *) machine=hp800 opsys=hpux10 ;;
 535     esac
 536   ;;
 537   hppa*-*-nextstep* )
 538     machine=hp800 opsys=nextstep
 539   ;;
 540
 541   ## Orion machines
 542   orion-orion-bsd* )
 543     machine=orion opsys=bsd4-2
 544   ;;
 545   clipper-orion-bsd* )
 546     machine=orion105 opsys=bsd4-2
 547   ;;
 548
 549   ## IBM machines
 550   i[3456]86-ibm-aix1.1* )
 551     machine=ibmps2-aix opsys=usg5-2-2
 552   ;;
 553   i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
 554     machine=ibmps2-aix opsys=usg5-3
 555   ;;
 556   i370-ibm-aix*)
 557     machine=ibm370aix opsys=usg5-3
 558   ;;
 559   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 560     machine=ibmrs6000 opsys=aix3-1
 561   ;;
 562   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 563     machine=ibmrs6000 opsys=aix3-2-5
 564   ;;
 565   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 566     machine=ibmrs6000 opsys=aix4-1
 567   ;;
 568   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 569     machine=ibmrs6000 opsys=aix4-2
 570   ;;
 571   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 572     machine=ibmrs6000 opsys=aix4
 573   ;;
 574   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 575     machine=ibmrs6000 opsys=aix4-1
 576   ;;
 577   rs6000-ibm-aix* | powerpc-ibm-aix* )
 578     machine=ibmrs6000 opsys=aix3-2
 579   ;;
 580   romp-ibm-bsd4.3* )
 581     machine=ibmrt opsys=bsd4-3
 582   ;;
 583   romp-ibm-bsd4.2* )
 584     machine=ibmrt opsys=bsd4-2
 585   ;;
 586   romp-ibm-aos4.3* )
 587     machine=ibmrt opsys=bsd4-3
 588   ;;
 589   romp-ibm-aos4.2* )
 590     machine=ibmrt opsys=bsd4-2
 591   ;;
 592   romp-ibm-aos* )
 593     machine=ibmrt opsys=bsd4-3
 594   ;;
 595   romp-ibm-bsd* )
 596     machine=ibmrt opsys=bsd4-3
 597   ;;
 598   romp-ibm-aix* )
 599     machine=ibmrt-aix opsys=usg5-2-2
 600   ;;
 601
 602   ## Integrated Solutions `Optimum V'
 603   m68*-isi-bsd4.2* )
 604     machine=isi-ov opsys=bsd4-2
 605   ;;
 606   m68*-isi-bsd4.3* )
 607     machine=isi-ov opsys=bsd4-3
 608   ;;
 609
 610   ## Intel 386 machines where we do care about the manufacturer
 611   i[3456]86-intsys-sysv* )
 612     machine=is386 opsys=usg5-2-2
 613   ;;
 614
 615   ## Prime EXL
 616   i[3456]86-prime-sysv* )
 617     machine=i386 opsys=usg5-3
 618   ;;
 619
 620   ## Sequent Symmetry running Dynix
 621   i[3456]86-sequent-bsd* )
 622     machine=symmetry opsys=bsd4-3
 623   ;;
 624
 625   ## Sequent Symmetry running ptx 4, which is a modified SVR4.
 626   i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
 627     machine=sequent-ptx opsys=ptx4
 628     NON_GNU_CPP=/lib/cpp
 629   ;;
 630
 631   ## Sequent Symmetry running DYNIX/ptx
 632   ## Use the old cpp rather than the newer ANSI one.
 633   i[3456]86-sequent-ptx* )
 634     machine=sequent-ptx opsys=ptx
 635     NON_GNU_CPP="/lib/cpp"
 636   ;;
 637
 638   ## ncr machine running svr4.3.
 639   i[3456]86-ncr-sysv4.3 )
 640     machine=ncr386 opsys=usg5-4-3
 641   ;;
 642
 643   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 644   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 645   i[3456]86-ncr-sysv* )
 646     machine=ncr386 opsys=usg5-4-2
 647   ;;
 648
 649   ## Intel Paragon OSF/1
 650   i860-intel-osf1* )
 651     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 652   ;;
 653
 654   ## Intel 860
 655   i860-*-sysv4* )
 656     machine=i860 opsys=usg5-4
 657     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 658     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 659   ;;
 660
 661   ## Macintosh PowerPC
 662   powerpc*-*-linux-gnu* )
 663     machine=macppc opsys=gnu-linux
 664   ;;
 665
 666   ## Masscomp machines
 667   m68*-masscomp-rtu* )
 668     machine=masscomp opsys=rtu
 669   ;;
 670
 671   ## Megatest machines
 672   m68*-megatest-bsd* )
 673     machine=mega68 opsys=bsd4-2
 674   ;;
 675
 676   ## Workstations sold by MIPS
 677   ## This is not necessarily all workstations using the MIPS processor -
 678   ## Irises are produced by SGI, and DECstations by DEC.
 679
 680   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 681   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 682   ## it gives for choosing between the alternatives seems to be "Use
 683   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 684   ## the BSD world."  I'll assume that these are instructions for
 685   ## handling two odd situations, and that every other situation
 686   ## should use mips.h and usg5-2-2, they being listed first.
 687   mips-mips-usg* )
 688     machine=mips4
 689     ## Fall through to the general code at the bottom to decide on the OS.
 690   ;;
 691   mips-mips-riscos4* )
 692     machine=mips4 opsys=bsd4-3
 693     NON_GNU_CC="cc -systype bsd43"
 694     NON_GNU_CPP="cc -systype bsd43 -E"
 695   ;;
 696   mips-mips-riscos5* )
 697     machine=mips4 opsys=riscos5
 698     NON_GNU_CC="cc -systype bsd43"
 699     NON_GNU_CPP="cc -systype bsd43 -E"
 700   ;;
 701   mips-mips-bsd* )
 702     machine=mips opsys=bsd4-3
 703   ;;
 704   mips-mips-* )
 705     machine=mips opsys=usg5-2-2
 706   ;;
 707
 708   ## NeXT
 709   m68*-next-* | m68k-*-nextstep* )
 710     machine=m68k opsys=nextstep
 711   ;;
 712
 713   ## The complete machine from National Semiconductor
 714   ns32k-ns-genix* )
 715     machine=ns32000 opsys=usg5-2
 716   ;;
 717
 718   ## NCR machines
 719   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 720     machine=tower32 opsys=usg5-2-2
 721   ;;
 722   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 723     machine=tower32v3 opsys=usg5-3
 724   ;;
 725
 726   ## NEC EWS4800
 727   mips-nec-sysv4*)
 728   machine=ews4800 opsys=ux4800
 729   ;;
 730
 731   ## Nixdorf Targon 31
 732   m68*-nixdorf-sysv* )
 733     machine=targon31 opsys=usg5-2-2
 734   ;;
 735
 736   ## Nu (TI or LMI)
 737   m68*-nu-sysv* )
 738     machine=nu opsys=usg5-2
 739   ;;
 740
 741   ## Plexus
 742   m68*-plexus-sysv* )
 743     machine=plexus opsys=usg5-2
 744   ;;
 745
 746   ## PowerPC reference platform
 747   powerpcle-*-solaris2* )
 748     machine=prep
 749     opsys=sol2-5
 750   ;;
 751
 752   ## Pyramid machines
 753   ## I don't really have any idea what sort of processor the Pyramid has,
 754   ## so I'm assuming it is its own architecture.
 755   pyramid-pyramid-bsd* )
 756     machine=pyramid opsys=bsd4-2
 757   ;;
 758
 759   ## Sequent Balance
 760   ns32k-sequent-bsd4.2* )
 761     machine=sequent opsys=bsd4-2
 762   ;;
 763   ns32k-sequent-bsd4.3* )
 764     machine=sequent opsys=bsd4-3
 765   ;;
 766
 767   ## Siemens Nixdorf
 768   mips-siemens-sysv* | mips-sni-sysv*)
 769     machine=mips-siemens opsys=usg5-4
 770     NON_GNU_CC=/usr/ccs/bin/cc
 771     NON_GNU_CPP=/usr/ccs/lib/cpp
 772   ;;
 773
 774   ## Silicon Graphics machines
 775   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 776   m68*-sgi-iris3.5* )
 777     machine=irist opsys=iris3-5
 778   ;;
 779   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 780     machine=irist opsys=iris3-6
 781   ;;
 782   ## Iris 4D
 783   mips-sgi-irix3* )
 784     machine=iris4d opsys=irix3-3
 785   ;;
 786   mips-sgi-irix4* )
 787     machine=iris4d opsys=irix4-0
 788   ;;
 789   mips-sgi-irix6.5 )
 790     machine=iris4d opsys=irix6-5
 791     # Without defining _LANGUAGE_C, things get masked out in the headers
 792     # so that, for instance, grepping for `free' in stdlib.h fails and
 793     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 794     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 795     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 796   ;;
 797   mips-sgi-irix6* )
 798     machine=iris4d opsys=irix6-0
 799     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 800     # but presumably it does no harm.
 801     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 802     # -32 probably isn't necessary in later v.6s -- anyone know which?
 803     NON_GCC_TEST_OPTIONS=-32
 804   ;;
 805   mips-sgi-irix5.[01]* )
 806     machine=iris4d opsys=irix5-0
 807   ;;
 808   mips-sgi-irix5* | mips-sgi-irix* )
 809     machine=iris4d opsys=irix5-2
 810   ;;
 811
 812   ## SONY machines
 813   m68*-sony-bsd4.2* )
 814     machine=news opsys=bsd4-2
 815   ;;
 816   m68*-sony-bsd4.3* )
 817     machine=news opsys=bsd4-3
 818   ;;
 819   m68*-sony-newsos3* | m68*-sony-news3*)
 820     machine=news opsys=bsd4-3
 821   ;;
 822   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 823     machine=news-risc opsys=bsd4-3
 824   ;;
 825   mips-sony-newsos6* )
 826     machine=news-r6 opsys=newsos6
 827   ;;
 828   mips-sony-news* )
 829     machine=news-risc opsys=newsos5
 830   ;;
 831
 832   ## Stride
 833   m68*-stride-sysv* )
 834     machine=stride opsys=usg5-2
 835   ;;
 836
 837   ## Suns
 838   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 839     machine=sparc opsys=gnu-linux
 840   ;;
 841
 842   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 843     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 844     | rs6000-*-solaris2*)
 845     case "${canonical}" in
 846       m68*-sunos1* )    machine=sun1 ;;
 847       m68*-sunos2* )    machine=sun2 ;;
 848       m68* )            machine=sun3 ;;
 849       i[3456]86-sun-sunos[34]* )        machine=sun386 ;;
 850       i[3456]86-*-* )     machine=intel386 ;;
 851       powerpcle* )      machine=powerpcle ;;
 852       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 853       sparc* )          machine=sparc ;;
 854       * )               unported=yes ;;
 855     esac
 856     case "${canonical}" in
 857       ## The Sun386 didn't get past 4.0.
 858       i[3456]86-*-sunos4          ) opsys=sunos4-0 ;;
 859       *-sunos4.0*         ) opsys=sunos4-0 ;;
 860       *-sunos4.1.[3-9]*noshare )
 861                 ## This name is sunos413 instead of sunos4-1-3
 862                 ## to avoid a file name conflict on MSDOS.
 863                 opsys=sunos413
 864                 NON_GNU_CPP=/usr/lib/cpp
 865                 NON_GCC_TEST_OPTIONS=-Bstatic
 866                 GCC_TEST_OPTIONS=-static
 867                 ;;
 868       *-sunos4.1.[3-9]* | *-sunos4shr*)
 869                 opsys=sunos4shr
 870                 NON_GNU_CPP=/usr/lib/cpp
 871                 ;;
 872       *-sunos4* | *-sunos )
 873                 opsys=sunos4-1
 874                 NON_GCC_TEST_OPTIONS=-Bstatic
 875                 GCC_TEST_OPTIONS=-static
 876                 ;;
 877       *-sunos5.3* | *-solaris2.3* )
 878                 opsys=sol2-3
 879                 NON_GNU_CPP=/usr/ccs/lib/cpp
 880                 ;;
 881       *-sunos5.4* | *-solaris2.4* )
 882                 opsys=sol2-4
 883                 NON_GNU_CPP=/usr/ccs/lib/cpp
 884                 RANLIB="ar -ts"
 885                 ;;
 886       *-sunos5.5* | *-solaris2.5* )
 887                 opsys=sol2-5
 888                 NON_GNU_CPP=/usr/ccs/lib/cpp
 889                 RANLIB="ar -ts"
 890                 ;;
 891       *-sunos5* | *-solaris* )
 892                 opsys=sol2-5
 893                 NON_GNU_CPP=/usr/ccs/lib/cpp
 894                 ;;
 895       *                   ) opsys=bsd4-2   ;;
 896     esac
 897     ## Watch out for a compiler that we know will not work.
 898     case "${canonical}" in
 899      *-solaris* | *-sunos5* )
 900                 if [ "x$CC" = x/usr/ucb/cc ]; then
 901                   ## /usr/ucb/cc doesn't work;
 902                   ## we should find some other compiler that does work.
 903                   unset CC
 904                 fi
 905                 ;;
 906       *) ;;
 907     esac
 908   ;;
 909   sparc-*-nextstep* )
 910     machine=sparc opsys=nextstep
 911   ;;
 912
 913   ## Tadpole 68k
 914   m68*-tadpole-sysv* )
 915     machine=tad68k opsys=usg5-3
 916   ;;
 917
 918   ## Tahoe machines
 919   tahoe-tahoe-bsd4.2* )
 920     machine=tahoe opsys=bsd4-2
 921   ;;
 922   tahoe-tahoe-bsd4.3* )
 923     machine=tahoe opsys=bsd4-3
 924   ;;
 925
 926   ## Tandem Integrity S2
 927   mips-tandem-sysv* )
 928     machine=tandem-s2 opsys=usg5-3
 929   ;;
 930
 931   ## Tektronix XD88
 932   m88k-tektronix-sysv3* )
 933   machine=tekxd88 opsys=usg5-3
 934   ;;
 935
 936   ## Tektronix 16000 box (6130?)
 937   ns16k-tektronix-bsd* )
 938     machine=ns16000 opsys=bsd4-2
 939   ;;
 940   ## Tektronix 4300
 941   ## src/m/tek4300.h hints that this is a m68k machine.
 942   m68*-tektronix-bsd* )
 943     machine=tek4300 opsys=bsd4-3
 944   ;;
 945
 946   ## Titan P2 or P3
 947   ## We seem to have lost the machine-description file titan.h!
 948   titan-titan-sysv* )
 949     machine=titan opsys=usg5-3
 950   ;;
 951
 952   ## Ustation E30 (SS5E)
 953   m68*-unisys-uniplus* )
 954     machine=ustation opsystem=unipl5-2
 955   ;;
 956
 957   ## Vaxen.
 958   vax-dec-* )
 959     machine=vax
 960     case "${canonical}" in
 961       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 962       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 963       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 964       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 965       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 966       *-vms* )                                          opsys=vms ;;
 967       * )                                               unported=yes
 968     esac
 969   ;;
 970
 971   ## Whitechapel MG1
 972   ns16k-whitechapel-* )
 973     machine=mg1
 974     ## We don't know what sort of OS runs on these; we'll let the
 975     ## operating system guessing code below try.
 976   ;;
 977
 978   ## Wicat
 979   m68*-wicat-sysv* )
 980     machine=wicat opsys=usg5-2
 981   ;;
 982
 983   ## Intel 386 machines where we don't care about the manufacturer
 984   i[3456]86-*-* )
 985     machine=intel386
 986     case "${canonical}" in
 987       *-lynxos* )               opsys=lynxos ;;
 988       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 989       *-isc2.2* )               opsys=isc2-2 ;;
 990       *-isc4.0* )               opsys=isc4-0 ;;
 991       *-isc4.* )                opsys=isc4-1
 992                                 GCC_TEST_OPTIONS=-posix
 993                                 NON_GCC_TEST_OPTIONS=-Xp
 994                                 ;;
 995       *-isc* )                  opsys=isc3-0 ;;
 996       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 997       *-esix* )                 opsys=esix ;;
 998       *-xenix* )                opsys=xenix ;;
 999       *-linux-gnu* )            opsys=gnu-linux ;;
1000       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
1001       *-sco3.2v5* )             opsys=sco5
1002                                 NON_GNU_CPP=/lib/cpp
1003                                 # Prevent -belf from being passed to $CPP.
1004                                 # /lib/cpp does not accept it.
1005                                 OVERRIDE_CPPFLAGS=" "
1006                                 ;;
1007       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1008       *-386bsd* )               opsys=386bsd ;;
1009       *-freebsd* )              opsys=freebsd ;;
1010       *-nextstep* )             opsys=nextstep ;;
1011       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1012     esac
1013   ;;
1014
1015   ## m68k Linux-based GNU system
1016   m68k-*-linux-gnu* )
1017     machine=m68k opsys=gnu-linux
1018   ;;
1019
1020   ## Mips Linux-based GNU system
1021   mips-*-linux-gnu* )
1022     machine=mips opsys=gnu-linux
1023   ;;
1024
1025   ## UXP/DS
1026   sparc-fujitsu-sysv4* )
1027     machine=sparc opsys=uxpds
1028     NON_GNU_CPP=/usr/ccs/lib/cpp
1029     RANLIB="ar -ts"
1030   ;;
1031
1032   ## UXP/V
1033   f301-fujitsu-uxpv4.1)
1034     machine=f301 opsys=uxpv
1035   ;;
1036
1037   * )
1038     unported=yes
1039   ;;
1040 esac
1041
1042 ### If the code above didn't choose an operating system, just choose
1043 ### an operating system based on the configuration name.  You really
1044 ### only want to use this when you have no idea what the right
1045 ### operating system is; if you know what operating systems a machine
1046 ### runs, it's cleaner to make it explicit in the case statement
1047 ### above.
1048 if test x"${opsys}" = x; then
1049   case "${canonical}" in
1050     *-gnu* )                            opsys=gnu ;;
1051     *-bsd4.[01] )                       opsys=bsd4-1 ;;
1052     *-bsd4.2 )                          opsys=bsd4-2 ;;
1053     *-bsd4.3 )                          opsys=bsd4-3 ;;
1054     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
1055     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
1056     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
1057     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
1058     *-sysv4.2uw* )                      opsys=unixware ;;
1059     *-sysv4.1* | *-sysvr4.1* )
1060         NON_GNU_CPP=/usr/lib/cpp
1061         opsys=usg5-4 ;;
1062     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1063         if [ x$NON_GNU_CPP = x ]; then
1064           if [ -f /usr/ccs/lib/cpp ]; then
1065             NON_GNU_CPP=/usr/ccs/lib/cpp
1066           else
1067             NON_GNU_CPP=/lib/cpp
1068           fi
1069         fi
1070         opsys=usg5-4-2 ;;
1071     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
1072     * )
1073       unported=yes
1074     ;;
1075   esac
1076 fi
1077
1078 changequote([, ])dnl
1079
1080 if test $unported = yes; then
1081   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1082 Check \`etc/MACHINES' for recognized configuration names.])
1083 fi
1084
1085 machfile="m/${machine}.h"
1086 opsysfile="s/${opsys}.h"
1087
1088
1089 #### Choose a compiler.
1090 test -n "$CC" && cc_specified=yes
1091
1092 # Save the value of CFLAGS that the user specified.
1093 SPECIFIED_CFLAGS="$CFLAGS"
1094
1095 case ${with_gcc} in
1096   "yes" ) CC="gcc" GCC=yes ;;
1097   "no"  ) : ${CC=cc} ;;
1098   * ) AC_PROG_CC
1099 esac
1100
1101 # On Suns, sometimes $CPP names a directory.
1102 if test -n "$CPP" && test -d "$CPP"; then
1103   CPP=
1104 fi
1105
1106 #### Some systems specify a CPP to use unless we are using GCC.
1107 #### Now that we know whether we are using GCC, we can decide whether
1108 #### to use that one.
1109 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1110 then
1111   CPP="$NON_GNU_CPP"
1112 fi
1113
1114 #### Some systems specify a CC to use unless we are using GCC.
1115 #### Now that we know whether we are using GCC, we can decide whether
1116 #### to use that one.
1117 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1118   test x$cc_specified != xyes
1119 then
1120   CC="$NON_GNU_CC"
1121 fi
1122
1123 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1124 then
1125   CC="$CC $GCC_TEST_OPTIONS"
1126 fi
1127
1128 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1129 then
1130   CC="$CC $NON_GCC_TEST_OPTIONS"
1131 fi
1132
1133 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1134 then
1135   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1136 fi
1137
1138 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1139 then
1140   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1141 fi
1142
1143 #### Some other nice autoconf tests.  If you add a test here which
1144 #### should make an entry in src/config.h, don't forget to add an
1145 #### #undef clause to src/config.h.in for autoconf to modify.
1146
1147 dnl checks for programs
1148 AC_PROG_LN_S
1149 AC_PROG_CPP
1150 AC_PROG_INSTALL
1151 AC_PROG_YACC
1152 if test "x$RANLIB" = x; then
1153   AC_PROG_RANLIB
1154 fi
1155
1156 dnl checks for Unix variants
1157 AC_AIX
1158
1159 # Sound support for GNU/Linux and the free BSDs.
1160 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1161 # Emulation library used on NetBSD.
1162 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1163 AC_SUBST(LIBSOUND)
1164
1165 dnl checks for header files
1166 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1167   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1168   termcap.h stdio_ext.h fcntl.h term.h)
1169 AC_HEADER_STDC
1170 AC_HEADER_TIME
1171 AC_DECL_SYS_SIGLIST
1172 AC_HEADER_SYS_WAIT
1173
1174 dnl Some systems have utime.h but don't declare the struct anyplace.
1175 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1176 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1177 #include <sys/time.h>
1178 #include <time.h>
1179 #else
1180 #ifdef HAVE_SYS_TIME_H
1181 #include <sys/time.h>
1182 #else
1183 #include <time.h>
1184 #endif
1185 #endif
1186 #ifdef HAVE_UTIME_H
1187 #include <utime.h>
1188 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1189   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1190 if test $emacs_cv_struct_utimbuf = yes; then
1191   AC_DEFINE(HAVE_STRUCT_UTIMBUF)
1192 fi
1193
1194 dnl checks for typedefs
1195 AC_TYPE_SIGNAL
1196
1197 dnl Check for speed_t typedef.
1198 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1199 AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1200   emacs_cv_speed_t=yes))
1201 if test $emacs_cv_speed_t = yes; then
1202   AC_DEFINE(HAVE_SPEED_T)
1203 fi
1204
1205 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1206 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1207 #include <sys/time.h>
1208 #include <time.h>
1209 #else
1210 #ifdef HAVE_SYS_TIME_H
1211 #include <sys/time.h>
1212 #else
1213 #include <time.h>
1214 #endif
1215 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1216   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1217 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1218 if test $emacs_cv_struct_timeval = yes; then
1219   AC_DEFINE(HAVE_TIMEVAL)
1220 fi
1221
1222 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1223 AC_TRY_COMPILE([#include <math.h>],
1224 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1225   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1226 HAVE_EXCEPTION=$emacs_cv_struct_exception
1227 if test $emacs_cv_struct_exception != yes; then
1228   AC_DEFINE(NO_MATHERR)
1229 fi
1230
1231 dnl checks for structure members
1232 AC_STRUCT_TM
1233 AC_STRUCT_TIMEZONE
1234 AC_CACHE_CHECK(for tm_gmtoff in struct tm, emacs_cv_tm_gmtoff,
1235 AC_TRY_LINK([#include <time.h>], [struct tm t; t.tm_gmtoff = 0],
1236   emacs_cv_tm_gmtoff=yes,
1237   emacs_cv_tm_gmtoff=no))
1238 if test $emacs_cv_tm_gmtoff = yes; then
1239   AC_DEFINE(HAVE_TM_GMTOFF)
1240 fi
1241
1242 dnl checks for compiler characteristics
1243
1244 dnl Testing __STDC__ to determine prototype support isn't good enough.
1245 dnl DEC C, for instance, doesn't define it with default options, and
1246 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1247 dnl and void *.
1248 AC_C_PROTOTYPES
1249 AC_C_VOLATILE
1250 AC_C_CONST
1251 dnl This isn't useful because we can't turn on use of `inline' unless
1252 dnl the compiler groks `extern inline'.
1253 dnl AC_C_INLINE
1254 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1255   [AC_TRY_COMPILE(, [void * foo;],
1256                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1257 if test $emacs_cv_void_star = yes; then
1258   AC_DEFINE(POINTER_TYPE, void)
1259 else
1260   AC_DEFINE(POINTER_TYPE, char)
1261 fi
1262
1263 dnl check for Make feature
1264 AC_PROG_MAKE_SET
1265
1266 dnl checks for operating system services
1267 AC_SYS_LONG_FILE_NAMES
1268
1269 #### Choose a window system.
1270
1271 AC_PATH_X
1272 if test "$no_x" = yes; then
1273   window_system=none
1274 else
1275   window_system=x11
1276 fi
1277
1278 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1279   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1280   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1281   x_default_search_path=""
1282   for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1283     x_search_path="${x_library}/X11/%L/%T/%N%C%S:\
1284 ${x_library}/X11/%L/%T/%N%C%S:${x_libary}/X11/%l/%T/%N%C%S:\
1285 ${x_library}/X11/%T/%N%C%S:${x_library}/X11/%L/%T/%N%S:\
1286 ${x_library}/X11/%l/%T/%N%S:${x_library}/X11/%T/%N%S"
1287     if test x"${x_default_search_path}" = x; then
1288       x_default_search_path=${x_search_path}
1289     else
1290       x_default_search_path="${x_search_path}:${x_default_search_path}"
1291     fi
1292   done
1293 fi
1294 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1295   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1296 fi
1297
1298 if test x"${x_includes}" = x; then
1299   bitmapdir=/usr/include/X11/bitmaps
1300 else
1301   # accumulate include directories that have X11 bitmap subdirectories
1302   bmd_acc="dummyval"
1303   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1304     if test -d "${bmd}/X11/bitmaps"; then
1305       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1306     fi
1307     if test -d "${bmd}/bitmaps"; then
1308       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1309     fi
1310   done
1311   if test ${bmd_acc} != "dummyval"; then
1312     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1313   fi
1314 fi
1315
1316 case "${window_system}" in
1317   x11 )
1318     HAVE_X_WINDOWS=yes
1319     HAVE_X11=yes
1320     case "${with_x_toolkit}" in
1321       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1322       motif ) USE_X_TOOLKIT=MOTIF ;;
1323 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1324       no ) USE_X_TOOLKIT=none ;;
1325 dnl If user did not say whether to use a toolkit,
1326 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1327       * ) USE_X_TOOLKIT=maybe ;;
1328     esac
1329   ;;
1330   none )
1331     HAVE_X_WINDOWS=no
1332     HAVE_X11=no
1333     USE_X_TOOLKIT=none
1334   ;;
1335 esac
1336
1337 ### If we're using X11, we should use the X menu package.
1338 HAVE_MENUS=no
1339 case ${HAVE_X11} in
1340   yes ) HAVE_MENUS=yes ;;
1341 esac
1342
1343 if test "${opsys}" = "hpux9"; then
1344   case "${x_libraries}" in
1345     *X11R4* )
1346       opsysfile="s/hpux9-x11r4.h"
1347       ;;
1348   esac
1349 fi
1350
1351 if test "${opsys}" = "hpux9shr"; then
1352   case "${x_libraries}" in
1353     *X11R4* )
1354       opsysfile="s/hpux9shxr4.h"
1355       ;;
1356   esac
1357 fi
1358
1359 #### Extract some information from the operating system and machine files.
1360
1361 AC_CHECKING([the machine- and system-dependent files to find out
1362  - which libraries the lib-src programs will want, and
1363  - whether the GNU malloc routines are usable])
1364
1365 ### First figure out CFLAGS (which we use for running the compiler here)
1366 ### and REAL_CFLAGS (which we use for real compilation).
1367 ### The two are the same except on a few systems, where they are made
1368 ### different to work around various lossages.  For example,
1369 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1370 ### as implying static linking.
1371
1372 ### If the CFLAGS env var is specified, we use that value
1373 ### instead of the default.
1374
1375 ### It's not important that this name contain the PID; you can't run
1376 ### two configures in the same directory and have anything work
1377 ### anyway.
1378 tempcname="conftest.c"
1379
1380 echo '
1381 #include "'${srcdir}'/src/'${opsysfile}'"
1382 #include "'${srcdir}'/src/'${machfile}'"
1383 #ifndef LIBS_MACHINE
1384 #define LIBS_MACHINE
1385 #endif
1386 #ifndef LIBS_SYSTEM
1387 #define LIBS_SYSTEM
1388 #endif
1389 #ifndef C_SWITCH_SYSTEM
1390 #define C_SWITCH_SYSTEM
1391 #endif
1392 #ifndef C_SWITCH_MACHINE
1393 #define C_SWITCH_MACHINE
1394 #endif
1395 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1396 configure___ c_switch_system=C_SWITCH_SYSTEM
1397 configure___ c_switch_machine=C_SWITCH_MACHINE
1398
1399 #ifndef LIB_X11_LIB
1400 #define LIB_X11_LIB -lX11
1401 #endif
1402
1403 #ifndef LIBX11_MACHINE
1404 #define LIBX11_MACHINE
1405 #endif
1406
1407 #ifndef LIBX11_SYSTEM
1408 #define LIBX11_SYSTEM
1409 #endif
1410 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1411
1412 #ifdef UNEXEC
1413 configure___ unexec=UNEXEC
1414 #else
1415 configure___ unexec=unexec.o
1416 #endif
1417
1418 #ifdef SYSTEM_MALLOC
1419 configure___ system_malloc=yes
1420 #else
1421 configure___ system_malloc=no
1422 #endif
1423
1424 #ifndef C_DEBUG_SWITCH
1425 #define C_DEBUG_SWITCH -g
1426 #endif
1427
1428 #ifndef C_OPTIMIZE_SWITCH
1429 #ifdef __GNUC__
1430 #define C_OPTIMIZE_SWITCH -O2
1431 #else
1432 #define C_OPTIMIZE_SWITCH -O
1433 #endif
1434 #endif
1435
1436 #ifndef LD_SWITCH_MACHINE
1437 #define LD_SWITCH_MACHINE
1438 #endif
1439
1440 #ifndef LD_SWITCH_SYSTEM
1441 #define LD_SWITCH_SYSTEM
1442 #endif
1443
1444 #ifndef LD_SWITCH_X_SITE_AUX
1445 #define LD_SWITCH_X_SITE_AUX
1446 #endif
1447
1448 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1449 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1450
1451 #ifdef THIS_IS_CONFIGURE
1452
1453 /* Get the CFLAGS for tests in configure.  */
1454 #ifdef __GNUC__
1455 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1456 #else
1457 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1458 #endif
1459
1460 #else /* not THIS_IS_CONFIGURE */
1461
1462 /* Get the CFLAGS for real compilation.  */
1463 #ifdef __GNUC__
1464 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1465 #else
1466 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1467 #endif
1468
1469 #endif /* not THIS_IS_CONFIGURE */
1470 ' > ${tempcname}
1471
1472 # The value of CPP is a quoted variable reference, so we need to do this
1473 # to get its actual value...
1474 CPP=`eval "echo $CPP"`
1475 changequote(, )dnl
1476 eval `${CPP} -Isrc ${tempcname} \
1477        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1478 if test "x$SPECIFIED_CFLAGS" = x; then
1479   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1480          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1481 else
1482   REAL_CFLAGS="$CFLAGS"
1483 fi
1484 changequote([, ])dnl
1485 rm ${tempcname}
1486
1487 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1488
1489 ### Compute the unexec source name from the object name.
1490 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1491
1492 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1493 # Assume not, until told otherwise.
1494 GNU_MALLOC=yes
1495 doug_lea_malloc=yes
1496 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1497 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1498 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1499                emacs_cv_var___after_morecore_hook,
1500 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1501   emacs_cv_var___after_morecore_hook=yes,
1502   emacs_cv_var___after_morecore_hook=no))
1503 if test $emacs_cv_var___after_morecore_hook = no; then
1504   doug_lea_malloc=no
1505 fi
1506 if test "${system_malloc}" = "yes"; then
1507   GNU_MALLOC=no
1508   GNU_MALLOC_reason="
1509     (The GNU allocators don't work with this system configuration.)"
1510 fi
1511 if test "$doug_lea_malloc" = "yes" ; then
1512   if test "$GNU_MALLOC" = yes ; then
1513     GNU_MALLOC_reason="
1514       (Using Doug Lea's new malloc from the GNU C Library.)"
1515   fi
1516   AC_DEFINE(DOUG_LEA_MALLOC)
1517 fi
1518
1519 if test x"${REL_ALLOC}" = x; then
1520   REL_ALLOC=${GNU_MALLOC}
1521 fi
1522
1523 #### Add the libraries to LIBS and check for some functions.
1524
1525 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1526   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1527 else
1528   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1529 fi
1530
1531 LIBS="$libsrc_libs $LIBS"
1532
1533 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1534 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1535 AC_CHECK_LIB(dnet, dnet_ntoa)
1536 dnl This causes -lresolv to get used in subsequent tests,
1537 dnl which causes failures on some systems such as HPUX 9.
1538 dnl AC_CHECK_LIB(resolv, gethostbyname)
1539
1540 dnl FIXME replace main with a function we actually want from this library.
1541 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1542
1543 AC_CHECK_LIB(pthreads, cma_open)
1544
1545 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1546 if test -d /usr/X386/include; then
1547   HAVE_XFREE386=yes
1548   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1549 else
1550   HAVE_XFREE386=no
1551 fi
1552 AC_MSG_RESULT($HAVE_XFREE386)
1553
1554 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1555 # for the tests that follow.  We set it back to REAL_CFLAGS later on.
1556
1557 REAL_CPPFLAGS="$CPPFLAGS"
1558
1559 if test "${HAVE_X11}" = "yes"; then
1560   DEFS="$C_SWITCH_X_SITE $DEFS"
1561   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1562   LIBS="$LIBX $LIBS"
1563   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1564   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1565
1566   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1567   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1568   # but it's more convenient here to set LD_RUN_PATH
1569   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1570   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1571     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1572     export LD_RUN_PATH
1573   fi
1574
1575   if test "${opsys}" = "gnu-linux"; then
1576     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1577     AC_TRY_LINK([],
1578      [XOpenDisplay ("foo");],
1579      [xlinux_first_failure=no],
1580      [xlinux_first_failure=yes])
1581     if test "${xlinux_first_failure}" = "yes"; then
1582       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1583       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1584       OLD_CPPFLAGS="$CPPFLAGS"
1585       OLD_LIBS="$LIBS"
1586       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1587       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1588       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1589       LIBS="$LIBS -b i486-linuxaout"
1590       AC_TRY_LINK([],
1591        [XOpenDisplay ("foo");],
1592        [xlinux_second_failure=no],
1593        [xlinux_second_failure=yes])
1594       if test "${xlinux_second_failure}" = "yes"; then
1595         # If we get the same failure with -b, there is no use adding -b.
1596         # So take it out.  This plays safe.
1597         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1598         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1599         CPPFLAGS="$OLD_CPPFLAGS"
1600         LIBS="$OLD_LIBS"
1601         AC_MSG_RESULT(no)
1602       else
1603         AC_MSG_RESULT(yes)
1604       fi
1605     else
1606       AC_MSG_RESULT(no)
1607     fi
1608   fi
1609
1610   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1611 XScreenNumberOfScreen XSetWMProtocols)
1612 fi
1613
1614 if test "${window_system}" = "x11"; then
1615   AC_MSG_CHECKING(X11 version 6)
1616   AC_CACHE_VAL(emacs_cv_x11_version_6,
1617   AC_TRY_LINK([#include <X11/Xlib.h>],
1618 [#if XlibSpecificationRelease < 6
1619 fail;
1620 #endif
1621 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no))
1622   if test $emacs_cv_x11_version_6 = yes; then
1623     AC_MSG_RESULT(6 or newer)
1624     AC_DEFINE(HAVE_X11R6)
1625   else
1626     AC_MSG_RESULT(before 6)
1627   fi
1628 fi
1629
1630 if test "${window_system}" = "x11"; then
1631   AC_MSG_CHECKING(X11 version 5)
1632   AC_CACHE_VAL(emacs_cv_x11_version_5,
1633   AC_TRY_LINK([#include <X11/Xlib.h>],
1634 [#if XlibSpecificationRelease < 5
1635 fail;
1636 #endif
1637 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no))
1638   if test $emacs_cv_x11_version_5 = yes; then
1639     AC_MSG_RESULT(5 or newer)
1640     HAVE_X11R5=yes
1641     AC_DEFINE(HAVE_X11R5)
1642   else
1643     HAVE_X11R5=no
1644     AC_MSG_RESULT(before 5)
1645   fi
1646 fi
1647
1648 dnl Do not put whitespace before the #include statements below.
1649 dnl Older compilers (eg sunos4 cc) choke on it.
1650 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1651   if test x"${HAVE_X11R5}" = xyes; then
1652     AC_MSG_CHECKING(X11 version 5 with Xaw)
1653     AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1654     AC_TRY_LINK([
1655 #include <X11/Intrinsic.h>
1656 #include <X11/Xaw/Simple.h>],
1657       [],
1658       emacs_cv_x11_version_5_with_xaw=yes,
1659       emacs_cv_x11_version_5_with_xaw=no))
1660     if test $emacs_cv_x11_version_5_with_xaw = yes; then
1661       AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1662       USE_X_TOOLKIT=LUCID
1663     else
1664       AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1665       USE_X_TOOLKIT=none
1666     fi
1667   else
1668     USE_X_TOOLKIT=none
1669   fi
1670 fi
1671
1672 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1673
1674 if test "${USE_X_TOOLKIT}" != "none"; then
1675   AC_MSG_CHECKING(X11 toolkit version)
1676   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1677   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1678 [#if XtSpecificationRelease < 6
1679 fail;
1680 #endif
1681 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no))
1682   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1683   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1684     AC_MSG_RESULT(6 or newer)
1685     AC_DEFINE(HAVE_X11XTR6)
1686   else
1687     AC_MSG_RESULT(before 6)
1688   fi
1689
1690 dnl If using toolkit, check whether libXmu.a exists.
1691 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1692   OLDLIBS="$LIBS"
1693   if test x$HAVE_X11XTR6 = xyes; then
1694     LIBS="-lXt -lSM -lICE $LIBS"
1695   else
1696     LIBS="-lXt $LIBS"
1697   fi
1698   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1699   LIBS="$OLDLIBS"
1700 fi
1701
1702 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1703   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1704   AC_TRY_COMPILE([#include <Xm/Xm.h>],
1705     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1706 int x = 5;
1707 #else
1708 Motif version prior to 2.1.
1709 #endif],
1710     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no))
1711   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1712   if test $emacs_cv_motif_version_2_1 = yes; then
1713     AC_DEFINE(HAVE_MOTIF_2_1)
1714     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes, , -lXext)
1715     if test ${HAVE_LIBXP} = yes; then
1716       AC_DEFINE(HAVE_LIBXP)
1717     fi
1718   fi
1719 fi
1720
1721 ### Is -lXaw3d available?
1722 HAVE_XAW3D=no
1723 if test "${HAVE_X11}" = "yes"; then
1724   if test "${USE_X_TOOLKIT}" != "none"; then
1725     old_c_flags="${CFLAGS}"
1726     CFLAGS="${LD_SWITCH_X_SITE}"
1727     AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1728         AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes, , -lX11))
1729     CFLAGS="${old_c_flags}"
1730
1731     if test "${HAVE_XAW3D}" = "yes"; then
1732         AC_DEFINE(HAVE_XAW3D)
1733     fi
1734   fi
1735 fi
1736
1737 dnl Use toolkit scroll bars if configured for X toolkit and either
1738 dnl using Motif or Xaw3d is available, and unless
1739 dnl --with-toolkit-scroll-bars=no was specified.
1740
1741 USE_TOOLKIT_SCROLL_BARS=no
1742 if test "${with_toolkit_scroll_bars}" != "no"; then
1743   if test "${USE_X_TOOLKIT}" != "none"; then
1744     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1745       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1746       HAVE_XAW3D=no
1747       USE_TOOLKIT_SCROLL_BARS=yes
1748     elif test "${HAVE_XAW3D}" = "yes"; then
1749       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1750       USE_TOOLKIT_SCROLL_BARS=yes
1751     fi
1752   fi
1753 fi
1754
1755 dnl Don't use X11 input methods if user specifies he doesn't want it
1756 dnl with `--with-xim=no'.
1757
1758 if test "${with_xim}" != "no"; then
1759   AC_DEFINE(USE_XIM)
1760 fi
1761
1762 ### Use -lXpm if available, unless `--with-xpm=no'.
1763 HAVE_XPM=no
1764 if test "${HAVE_X11}" = "yes"; then
1765   if test "${with_xpm}" != "no"; then
1766     old_c_flags="${CFLAGS}"
1767     CFLAGS="${LD_SWITCH_X_SITE}"
1768     AC_CHECK_HEADER(X11/xpm.h,
1769       AC_CHECK_LIB(Xpm, XpmReturnAllocPixels, HAVE_XPM=yes, , -lX11))
1770     CFLAGS="${old_c_flags}"
1771   fi
1772
1773   if test "${HAVE_XPM}" = "yes"; then
1774     AC_DEFINE(HAVE_XPM)
1775   fi
1776 fi
1777
1778 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1779 HAVE_JPEG=no
1780 if test "${HAVE_X11}" = "yes"; then
1781   if test "${with_jpeg}" != "no"; then
1782     old_c_flags="${CFLAGS}"
1783     CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1784     dnl Checking for jpeglib.h can lose becsue of a redefinition of
1785     dnl  HAVE_STDLIB_H.
1786     AC_CHECK_HEADER(jerror.h,
1787       AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes, , -lX11))
1788     CFLAGS="${old_c_flags}"
1789   fi
1790
1791   if test "${HAVE_JPEG}" = "yes"; then
1792     AC_DEFINE(HAVE_JPEG)
1793   fi
1794 fi
1795
1796 ### Use -lpng if available, unless `--with-png=no'.
1797 HAVE_PNG=no
1798 if test "${HAVE_X11}" = "yes"; then
1799   if test "${with_png}" != "no"; then
1800     old_c_flags="${CFLAGS}"
1801     CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1802     AC_CHECK_HEADER(png.h,
1803       AC_CHECK_LIB(png, png_set_expand, HAVE_PNG=yes, , -lX11 -lz -lm))
1804     CFLAGS="${old_c_flags}"
1805   fi
1806
1807   if test "${HAVE_PNG}" = "yes"; then
1808     AC_DEFINE(HAVE_PNG)
1809   fi
1810 fi
1811
1812 ### Use -ltiff if available, unless `--with-tiff=no'.
1813 HAVE_TIFF=no
1814 if test "${HAVE_X11}" = "yes"; then
1815   if test "${with_tiff}" != "no"; then
1816     old_c_flags="${CFLAGS}"
1817     CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1818     AC_CHECK_HEADER(tiffio.h,
1819       tifflibs="-lX11 -lz -lm"
1820       # At least one tiff package requires the jpeg library.
1821       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1822       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1823     CFLAGS="${old_c_flags}"
1824   fi
1825
1826   if test "${HAVE_TIFF}" = "yes"; then
1827     AC_DEFINE(HAVE_TIFF)
1828   fi
1829 fi
1830
1831 ### Use -lgif if available, unless `--with-gif=no'.
1832 HAVE_GIF=no
1833 if test "${HAVE_X11}" = "yes"; then
1834   if test "${with_gif}" != "no"; then
1835     old_c_flags="${CFLAGS}"
1836     CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1837     AC_CHECK_HEADER(gif_lib.h,
1838       AC_CHECK_LIB(ungif, DGifOpen, HAVE_GIF=yes, , -lX11))
1839     CFLAGS="${old_c_flags}"
1840   fi
1841
1842   if test "${HAVE_GIF}" = "yes"; then
1843     AC_DEFINE(HAVE_GIF)
1844   fi
1845 fi
1846
1847 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1848 AC_CACHE_CHECK(whether netdb declares h_errno,
1849                emacs_cv_netdb_declares_h_errno,
1850 AC_TRY_LINK([#include <netdb.h>],
1851   [return h_errno;],
1852   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no))
1853 if test $emacs_cv_netdb_declares_h_errno = yes; then
1854   AC_DEFINE(HAVE_H_ERRNO)
1855 fi
1856
1857 AC_FUNC_ALLOCA
1858
1859 # fmod, logb, and frexp are found in -lm on most systems.
1860 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1861 AC_CHECK_LIB(m, sqrt)
1862
1863 # Check for mail-locking functions in a "mail" library
1864 AC_CHECK_LIB(mail, maillock)
1865 dnl Debian, at least:
1866 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
1867 AC_CHECK_LIB(lockfile, maillock)
1868 # If we have the shared liblockfile, assume we must use it for mail
1869 # locking (e.g. Debian).  If we couldn't link against liblockfile
1870 # (no liblockfile.a installed), ensure that we don't need to.
1871 if test "$ac_cv_lib_lockfile_maillock" = no; then
1872   dnl This works for files generally, not just executables.
1873   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
1874   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
1875                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
1876   if test $ac_cv_prog_liblockfile = yes; then
1877     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
1878 This probably means that movemail could lose mail.
1879 There may be a \`development' package to install containing liblockfile.])
1880   else AC_DEFINE(LIBMAIL, -llockfile)
1881   fi
1882   else :
1883 fi
1884 AC_CHECK_FUNCS(touchlock)
1885 AC_CHECK_HEADERS(maillock.h)
1886
1887 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
1888 rename closedir mkdir rmdir sysinfo \
1889 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1890 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1891 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
1892 __fpending mblen mbrlen strsignal setitimer ualarm)
1893
1894 AC_FUNC_MKTIME
1895 if test "$ac_cv_func_working_mktime" = no; then
1896   AC_DEFINE(BROKEN_MKTIME)
1897 fi
1898
1899 AC_FUNC_GETLOADAVG
1900
1901 AC_SYS_LARGEFILE
1902 AC_CHECK_FUNCS(ftello)
1903
1904 # UNIX98 PTYs.  AC_SYS_LARGEFILE should have defined _XOPEN_SOURCE
1905 # if we need it.
1906 AC_CHECK_FUNCS(grantpt)
1907
1908 # PTY-related GNU extensions.
1909 AC_CHECK_FUNCS(getpt)
1910
1911 # Check this now, so that we will NOT find the above functions in ncurses.
1912 # That is because we have not set up to link ncurses in lib-src.
1913 # It's better to believe a function is not available
1914 # than to expect to find it in ncurses.
1915 AC_CHECK_LIB(ncurses, tparm)
1916
1917 # These tell us which Kerberos-related libraries to use.
1918 if test "${with_kerberos+set}" = set; then
1919   AC_CHECK_LIB(com_err, com_err)
1920   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
1921   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
1922   AC_CHECK_LIB(krb5, krb5_init_context)
1923   if test "${with_kerberos5+set}" != set; then
1924     AC_CHECK_LIB(des425, des_cbc_encrypt,,
1925                  AC_CHECK_LIB(des, des_cbc_encrypt))
1926     AC_CHECK_LIB(krb4, krb_get_cred,,
1927                  AC_CHECK_LIB(krb, krb_get_cred))
1928   fi
1929
1930   if test "${with_kerberos5+set}" = set; then
1931     AC_CHECK_HEADERS(krb5.h)
1932   else
1933     AC_CHECK_HEADERS(des.h,,
1934                      AC_CHECK_HEADERS(kerberosIV/des.h,,
1935                                       AC_CHECK_HEADERS(kerberos/des.h)))
1936     AC_CHECK_HEADERS(krb.h,,
1937                      AC_CHECK_HEADERS(kerberosIV/krb.h,,
1938                                       AC_CHECK_HEADERS(kerberos/krb.h)))
1939   fi
1940   AC_CHECK_HEADERS(com_err.h)
1941 fi
1942
1943 # Solaris requires -lintl if you want strerror (which calls dgettext)
1944 # to return localized messages.
1945 AC_CHECK_LIB(intl, dgettext)
1946
1947 AC_MSG_CHECKING(whether localtime caches TZ)
1948 AC_CACHE_VAL(emacs_cv_localtime_cache,
1949 [if test x$ac_cv_func_tzset = xyes; then
1950 AC_TRY_RUN([#include <time.h>
1951 extern char **environ;
1952 unset_TZ ()
1953 {
1954   char **from, **to;
1955   for (to = from = environ; (*to = *from); from++)
1956     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1957       to++;
1958 }
1959 char TZ_GMT0[] = "TZ=GMT0";
1960 char TZ_PST8[] = "TZ=PST8";
1961 main()
1962 {
1963   time_t now = time ((time_t *) 0);
1964   int hour_GMT0, hour_unset;
1965   if (putenv (TZ_GMT0) != 0)
1966     exit (1);
1967   hour_GMT0 = localtime (&now)->tm_hour;
1968   unset_TZ ();
1969   hour_unset = localtime (&now)->tm_hour;
1970   if (putenv (TZ_PST8) != 0)
1971     exit (1);
1972   if (localtime (&now)->tm_hour == hour_GMT0)
1973     exit (1);
1974   unset_TZ ();
1975   if (localtime (&now)->tm_hour != hour_unset)
1976     exit (1);
1977   exit (0);
1978 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1979 [# If we have tzset, assume the worst when cross-compiling.
1980 emacs_cv_localtime_cache=yes])
1981 else
1982         # If we lack tzset, report that localtime does not cache TZ,
1983         # since we can't invalidate the cache if we don't have tzset.
1984         emacs_cv_localtime_cache=no
1985 fi])dnl
1986 AC_MSG_RESULT($emacs_cv_localtime_cache)
1987 if test $emacs_cv_localtime_cache = yes; then
1988   AC_DEFINE(LOCALTIME_CACHE)
1989 fi
1990
1991 if test "x$HAVE_TIMEVAL" = xyes; then
1992   AC_CHECK_FUNCS(gettimeofday)
1993   AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
1994                  emacs_cv_gettimeofday_two_arguments,
1995   AC_TRY_COMPILE([
1996 #ifdef TIME_WITH_SYS_TIME
1997 #include <sys/time.h>
1998 #include <time.h>
1999 #else
2000 #ifdef HAVE_SYS_TIME_H
2001 #include <sys/time.h>
2002 #else
2003 #include <time.h>
2004 #endif
2005 #endif],
2006     [struct timeval time;
2007      gettimeofday (&time, 0);],
2008     emacs_cv_gettimeofday_two_arguments=yes,
2009     emacs_cv_gettimeofday_two_arguments=no))
2010   if test $emacs_cv_gettimeofday_two_arguments = no; then
2011     AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)
2012   fi
2013 fi
2014
2015 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2016 if test "$ac_cv_func_gettimeofday" = yes; then
2017   AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2018     [AC_TRY_COMPILE([#include <sys/time.h>],
2019     [struct timezone tz;],
2020     dnl It may be that we can't call gettimeofday with a non-null pointer,
2021     dnl even though we have struct timezone (e.g. HPUX).  In that case
2022     dnl we'll lie about struct timezone.
2023     [AC_TRY_RUN([
2024 #ifdef TIME_WITH_SYS_TIME
2025 #include <sys/time.h>
2026 #include <time.h>
2027 #else
2028 #ifdef HAVE_SYS_TIME_H
2029 #include <sys/time.h>
2030 #else
2031 #include <time.h>
2032 #endif
2033 #endif
2034 main () {
2035   struct timeval time;
2036   struct timezone dummy;
2037   exit (gettimeofday (&time, &dummy));
2038 }],
2039       emacs_cv_struct_timezone=yes,
2040       emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2041     emacs_cv_struct_timezone=no)])
2042 fi
2043
2044 ok_so_far=yes
2045 AC_CHECK_FUNC(socket, , ok_so_far=no)
2046 if test $ok_so_far = yes; then
2047   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2048 fi
2049 if test $ok_so_far = yes; then
2050   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2051 fi
2052 if test $ok_so_far = yes; then
2053   AC_DEFINE(HAVE_INET_SOCKETS)
2054 fi
2055
2056 if test -f /usr/lpp/X11/bin/smt.exp; then
2057   AC_DEFINE(HAVE_AIX_SMT_EXP)
2058 fi
2059
2060 AC_MSG_CHECKING(whether system supports dynamic ptys)
2061 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2062   AC_MSG_RESULT(yes)
2063   AC_DEFINE(HAVE_DEV_PTMX)
2064 else
2065   AC_MSG_RESULT(no)
2066 fi
2067
2068 AC_FUNC_VFORK
2069
2070 # Set up the CFLAGS for real compilation, so we can substitute it.
2071 CFLAGS="$REAL_CFLAGS"
2072 CPPFLAGS="$REAL_CPPFLAGS"
2073
2074 changequote(, )dnl
2075 #### Find out which version of Emacs this is.
2076 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
2077          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2078 changequote([, ])dnl
2079 if test x"${version}" = x; then
2080   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2081 fi
2082
2083 ### Specify what sort of things we'll be editing into Makefile and config.h.
2084 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2085 AC_SUBST(version)
2086 AC_SUBST(configuration)
2087 AC_SUBST(canonical)
2088 AC_SUBST(srcdir)
2089 AC_SUBST(prefix)
2090 AC_SUBST(exec_prefix)
2091 AC_SUBST(bindir)
2092 AC_SUBST(datadir)
2093 AC_SUBST(sharedstatedir)
2094 AC_SUBST(libexecdir)
2095 AC_SUBST(mandir)
2096 AC_SUBST(infodir)
2097 AC_SUBST(lispdir)
2098 AC_SUBST(locallisppath)
2099 AC_SUBST(lisppath)
2100 AC_SUBST(x_default_search_path)
2101 AC_SUBST(etcdir)
2102 AC_SUBST(archlibdir)
2103 AC_SUBST(docdir)
2104 AC_SUBST(bitmapdir)
2105 AC_SUBST(c_switch_system)
2106 AC_SUBST(c_switch_machine)
2107 AC_SUBST(LD_SWITCH_X_SITE)
2108 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2109 AC_SUBST(C_SWITCH_X_SITE)
2110 AC_SUBST(CFLAGS)
2111 AC_SUBST(X_TOOLKIT_TYPE)
2112 AC_SUBST(machfile)
2113 AC_SUBST(opsysfile)
2114 AC_SUBST(GETLOADAVG_LIBS)
2115
2116 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
2117 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
2118 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
2119 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
2120 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
2121 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
2122 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
2123 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
2124
2125 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2126   AC_DEFINE(HAVE_X_WINDOWS)
2127 fi
2128 if test "${USE_X_TOOLKIT}" != "none" ; then
2129   AC_DEFINE(USE_X_TOOLKIT)
2130 fi
2131 if test "${HAVE_X11}" = "yes" ; then
2132   AC_DEFINE(HAVE_X11)
2133 fi
2134 if test "${HAVE_XFREE386}" = "yes" ; then
2135   AC_DEFINE(HAVE_XFREE386)
2136 fi
2137 if test "${HAVE_MENUS}" = "yes" ; then
2138   AC_DEFINE(HAVE_MENUS)
2139 fi
2140 if test "${GNU_MALLOC}" = "yes" ; then
2141   AC_DEFINE(GNU_MALLOC)
2142 fi
2143 if test "${REL_ALLOC}" = "yes" ; then
2144   AC_DEFINE(REL_ALLOC)
2145 fi
2146
2147 #### Report on what we decided to do.
2148 echo "
2149 Configured for \`${canonical}'.
2150
2151   Where should the build process find the source code?    ${srcdir}
2152   What operating system and machine description files should Emacs use?
2153         \`${opsysfile}' and \`${machfile}'
2154   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2155   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2156   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
2157   What window system should Emacs use?                    ${window_system}
2158   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2159
2160 if test -n "${x_includes}"; then
2161 echo "  Where do we find X Windows header files?                ${x_includes}"
2162 else
2163 echo "  Where do we find X Windows header files?                Standard dirs"
2164 fi
2165 if test -n "${x_libraries}"; then
2166 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2167 else
2168 echo "  Where do we find X Windows libraries?                   Standard dirs"
2169 fi
2170
2171 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2172 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2173 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2174 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2175 echo "  Does Emacs use -lungif?                                 ${HAVE_GIF}"
2176 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2177 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
2178 echo
2179
2180 # Remove any trailing slashes in these variables.
2181 changequote(, )dnl
2182 test "${prefix}" != NONE &&
2183   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2184 test "${exec_prefix}" != NONE &&
2185   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2186 changequote([, ])dnl
2187
2188 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2189         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2190         lisp/Makefile leim/Makefile, [
2191
2192 ### Make the necessary directories, if they don't exist.
2193 for dir in etc lisp ; do
2194   test -d ${dir} || mkdir ${dir}
2195 done
2196
2197 # Build src/Makefile from ${srcdir}/src/Makefile.c
2198 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2199 # This must be done after src/config.h is built, since we rely on that file.
2200
2201 changequote(, )dnl The horror, the horror.
2202 # Now get this: Some word that is part of the ${srcdir} directory name
2203 # or the ${configuration} value might, just might, happen to be an
2204 # identifier like `sun4' or `i386' or something, and be predefined by
2205 # the C preprocessor to some helpful value like 1, or maybe the empty
2206 # string.  Needless to say consequent macro substitutions are less
2207 # than conducive to the makefile finding the correct directory.
2208 undefs="`echo $top_srcdir $configuration $canonical |
2209 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2210     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2211 `"
2212 changequote([, ])dnl
2213
2214 echo creating src/epaths.h
2215 make epaths-force
2216
2217 echo creating lib-src/Makefile
2218 ( cd lib-src
2219   rm -f junk.c junk1.c junk2.c
2220   sed -e '/start of cpp stuff/q' \
2221       < Makefile.c > junk1.c
2222   sed -e '1,/start of cpp stuff/d'\
2223       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
2224       < Makefile.c > junk.c
2225   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2226       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2227   cat junk1.c junk2.c > Makefile.new
2228   rm -f junk.c junk1.c junk2.c
2229   chmod 444 Makefile.new
2230   mv -f Makefile.new Makefile
2231 )
2232
2233 echo creating src/Makefile
2234 ( cd src
2235   rm -f junk.c junk1.c junk2.c
2236   sed -e '/start of cpp stuff/q' \
2237       < Makefile.c > junk1.c
2238   sed -e '1,/start of cpp stuff/d'\
2239       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
2240       < Makefile.c > junk.c
2241   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2242       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2243   cat junk1.c junk2.c > Makefile.new
2244   rm -f junk.c junk1.c junk2.c
2245   chmod 444 Makefile.new
2246   mv -f Makefile.new Makefile
2247 )
2248
2249 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
2250   echo creating src/.gdbinit
2251   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
2252 fi
2253
2254 # This is how we know whether to re-run configure in certain cases.
2255 touch src/config.stamp
2256
2257 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])